qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2
   3 #include "g_damage.qh"
   4 #include "race.qh"
   5 #include "../common/triggers/teleporters.qh"
   6
   7 #include "mutators/all.qh"
   8
   9 #include "weapons/tracing.qh"
  10
  11 #include "../common/constants.qh"
  12 #include "../common/deathtypes/all.qh"
  13 #include "../common/util.qh"
  14
  15 #include "../common/monsters/all.qh"
  16
  17 #include "../common/weapons/all.qh"
  18
  19 #include "../common/triggers/subs.qh"
  20
  21 #include "../common/triggers/func/breakable.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/anglestransform.qh"
  26 #include "../lib/warpzone/util_server.qh"
  27
  28 void CopyBody(float keepvelocity);
  29
  30 #ifdef NOCHEATS
  31
  32 float CheatImpulse(float i) { return 0; }
  33 float CheatCommand(float argc) { return 0; }
  34 float CheatFrame() { return 0; }
  35 void CheatInit() { cheatcount_total = world.cheatcount; }
  36 void CheatShutdown() { }
  37 void CheatShutdownClient() { }
  38 void Drag_MoveDrag(entity from, entity to) { }
  39
  40 #else
  41
  42 .float maycheat;
  43 float gamestart_sv_cheats;
  44
  45
  46
  47 void CheatInit()
  48 {
  49         gamestart_sv_cheats = autocvar_sv_cheats;
  50 }
  51
  52 void CheatShutdown()
  53 {
  54 }
  55
  56 void CheatShutdownClient()
  57 {
  58 }
  59
  60 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  61 {SELFPARAM();
  62         // dead people cannot cheat
  63         if(self.deadflag != DEAD_NO)
  64                 return 0;
  65         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  66                 return 0;
  67
  68         // sv_clones
  69         if(i == CHIMPULSE_CLONE_MOVING.impulse || i == CHIMPULSE_CLONE_STANDING.impulse)
  70                 if(self.lip < sv_clones)
  71                         return 1;
  72
  73         // haha
  74         if(self.maycheat)
  75                 return 1;
  76
  77         // sv_cheats
  78         if(gamestart_sv_cheats && autocvar_sv_cheats)
  79                 return 1;
  80
  81         // if we get here, player is not allowed to cheat. Log it.
  82         if(i)
  83                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  84         else if(argc)
  85                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  86         else if(fr)
  87                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
  88         else
  89                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
  90
  91         return 0;
  92 }
  93
  94 #define BEGIN_CHEAT_FUNCTION() \
  95         float cheating, attempting; \
  96         cheating = 0; attempting = 0
  97 #define DID_CHEAT() \
  98         ++cheating
  99 #define ADD_CHEATS(e,n) \
 100         cheatcount_total += n; \
 101         e.cheatcount += n
 102 #define END_CHEAT_FUNCTION() \
 103         ADD_CHEATS(self,cheating); \
 104         return attempting
 105 #define IS_CHEAT(i,argc,fr) \
 106         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 107                 break
 108
 109 float num_autoscreenshot;
 110 void info_autoscreenshot_findtarget()
 111 {SELFPARAM();
 112         entity e;
 113         e = find(world, targetname, self.target);
 114         if(!e)
 115         {
 116                 objerror("Missing target. FAIL!");
 117                 return;
 118         }
 119         vector a = vectoangles(e.origin - self.origin);
 120         a.x = -a.x; // don't ask
 121         self.angles_x = a.x;
 122         self.angles_y = a.y;
 123         // we leave Rick Roll alone
 124 }
 125 spawnfunc(info_autoscreenshot)
 126 {
 127         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 128         {
 129                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 130                 return;
 131         }
 132         if(self.target != "")
 133                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 134         // this one just has to exist
 135 }
 136
 137 float CheatImpulse(float i)
 138 {SELFPARAM();
 139         BEGIN_CHEAT_FUNCTION();
 140         switch(i)
 141         {
 142                 entity e, e2;
 143
 144                 case CHIMPULSE_SPEEDRUN_INIT.impulse: // deploy personal waypoint
 145                         // shared with regular waypoint init, so this is not a cheat by itself
 146                         if(!self.personal)
 147                         {
 148                                 self.personal = new(personal_wp);
 149                         }
 150                         self.personal.origin = self.origin;
 151                         self.personal.v_angle = self.v_angle;
 152                         self.personal.velocity = self.velocity;
 153                         self.personal.ammo_rockets = self.ammo_rockets;
 154                         self.personal.ammo_nails = self.ammo_nails;
 155                         self.personal.ammo_cells = self.ammo_cells;
 156                         self.personal.ammo_plasma = self.ammo_plasma;
 157                         self.personal.ammo_shells = self.ammo_shells;
 158                         self.personal.ammo_fuel = self.ammo_fuel;
 159                         self.personal.health = self.health;
 160                         self.personal.armorvalue = self.armorvalue;
 161                         self.personal.weapons = self.weapons;
 162                         self.personal.items = self.items;
 163                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 164                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 165                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 166                         self.personal.pauseregen_finished = self.pauseregen_finished;
 167                         self.personal.strength_finished = self.strength_finished;
 168                         self.personal.invincible_finished = self.invincible_finished;
 169                         self.personal.teleport_time = time;
 170                         break; // this part itself doesn't cheat, so let's not count this
 171                 case CHIMPULSE_CLONE_MOVING.impulse:
 172                         IS_CHEAT(i, 0, 0);
 173                         makevectors (self.v_angle);
 174                         self.velocity = self.velocity + v_forward * 300;
 175                         CopyBody(1);
 176                         self.lip += 1;
 177                         self.velocity = self.velocity - v_forward * 300;
 178                         DID_CHEAT();
 179                         break;
 180                 case CHIMPULSE_CLONE_STANDING.impulse:
 181                         IS_CHEAT(i, 0, 0);
 182                         CopyBody(0);
 183                         self.lip += 1;
 184                         DID_CHEAT();
 185                         break;
 186                 case CHIMPULSE_GIVE_ALL.impulse:
 187                         IS_CHEAT(i, 0, 0);
 188                         CheatCommand(tokenize_console("give all"));
 189                         break; // already counted as cheat
 190                 case CHIMPULSE_SPEEDRUN.impulse:
 191                         IS_CHEAT(i, 0, 0);
 192                         if(self.personal)
 193                         {
 194                                 self.speedrunning = true;
 195                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 196                                 if(trace_startsolid)
 197                                 {
 198                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 199                                 }
 200                                 else
 201                                 {
 202                                         // Abort speedrun, teleport back
 203                                         setorigin(self, self.personal.origin);
 204                                         self.oldvelocity = self.velocity = self.personal.velocity;
 205                                         self.angles = self.personal.v_angle;
 206                                         self.fixangle = true;
 207
 208                                         MUTATOR_CALLHOOK(AbortSpeedrun, self);
 209                                 }
 210
 211                                 self.ammo_rockets = self.personal.ammo_rockets;
 212                                 self.ammo_nails = self.personal.ammo_nails;
 213                                 self.ammo_cells = self.personal.ammo_cells;
 214                                 self.ammo_plasma = self.personal.ammo_plasma;
 215                                 self.ammo_shells = self.personal.ammo_shells;
 216                                 self.ammo_fuel = self.personal.ammo_fuel;
 217                                 self.health = self.personal.health;
 218                                 self.armorvalue = self.personal.armorvalue;
 219                                 self.weapons = self.personal.weapons;
 220                                 self.items = self.personal.items;
 221                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 222                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 223                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 224                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 225                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 226                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 227
 228                                 DID_CHEAT();
 229                                 break;
 230                         }
 231                         if(self.deadflag != DEAD_NO)
 232                                 sprint(self, "UR DEAD AHAHAH))\n");
 233                         else
 234                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 235                         break;
 236                 case CHIMPULSE_TELEPORT.impulse:
 237                         IS_CHEAT(i, 0, 0);
 238                         if(self.movetype == MOVETYPE_NOCLIP)
 239                         {
 240                                 e = find(world, classname, "info_autoscreenshot");
 241                                 if(e)
 242                                 {
 243                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 244                                         setorigin(self, e.origin);
 245                                         self.angles = e.angles;
 246                                         remove(e);
 247                                         // should we? self.angles_x = -self.angles_x;
 248                                         self.fixangle = true;
 249                                         self.velocity = '0 0 0';
 250                                         DID_CHEAT();
 251                                         break;
 252                                 }
 253                         }
 254                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 255                         {
 256                                 sprint(self, "Emergency teleport used random location\n");
 257                                 self.angles_x = -self.angles.x;
 258                                 self.fixangle = true;
 259                                 self.velocity = '0 0 0';
 260                                 DID_CHEAT();
 261                                 break;
 262                         }
 263                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 264                         break;
 265                 case CHIMPULSE_R00T.impulse:
 266                         IS_CHEAT(i, 0, 0);
 267                         RandomSelection_Init();
 268                         FOR_EACH_PLAYER(e)
 269                                 if(e.deadflag == DEAD_NO)
 270                                         if(DIFF_TEAM(e, self))
 271                                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 272                         if(RandomSelection_chosen_ent)
 273                                 e = RandomSelection_chosen_ent;
 274                         else
 275                                 e = self;
 276
 277                         Send_Effect(EFFECT_ROCKET_EXPLODE, e.origin, '0 0 0', 1);
 278                         sound(e, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 279
 280                         e2 = spawn();
 281                         setorigin(e2, e.origin);
 282                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT.m_id, e);
 283                         remove(e2);
 284
 285                         LOG_INFO("404 Sportsmanship not found.\n");
 286                         DID_CHEAT();
 287                         break;
 288         }
 289
 290         END_CHEAT_FUNCTION();
 291 }
 292
 293 void DragBox_Think();
 294 float drag_lastcnt;
 295 float CheatCommand(float argc)
 296 {SELFPARAM();
 297         BEGIN_CHEAT_FUNCTION();
 298         string cmd;
 299         cmd = argv(0);
 300         switch(cmd)
 301         {
 302                 float effectnum, f;
 303                 vector start, end;
 304                 entity oldself;
 305
 306                 case "pointparticles":
 307                         IS_CHEAT(0, argc, 0);
 308                         if(argc == 5)
 309                         {
 310                                 // arguments:
 311                                 //   effectname
 312                                 //   origin (0..1, on crosshair line)
 313                                 //   velocity
 314                                 //   howmany
 315                                 f = stof(argv(2));
 316                                 crosshair_trace(self);
 317                                 start = (1-f) * self.origin + f * trace_endpos;
 318                                 end = stov(argv(3));
 319                                 f = stof(argv(4));
 320                                 Send_Effect_(argv(1), start, end, f);
 321                                 DID_CHEAT();
 322                                 break;
 323                         }
 324                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 325                         break;
 326                 case "trailparticles":
 327                         IS_CHEAT(0, argc, 0);
 328                         if(argc == 2)
 329                         {
 330                                 // arguments:
 331                                 //   effectname
 332                                 effectnum = _particleeffectnum(argv(1));
 333                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 334                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 335                                 __trailparticles(self, effectnum, w_shotorg, trace_endpos);
 336                                 DID_CHEAT();
 337                                 break;
 338                         }
 339                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 340                         break;
 341                 case "make":
 342                         IS_CHEAT(0, argc, 0);
 343                         if(argc == 3)
 344                         {
 345                                 // arguments:
 346                                 //   modelname mode
 347                                 f = stof(argv(2));
 348                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 349                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 350                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 351                                 {
 352                                         sprint(self, "cannot make stuff there (bad surface)\n");
 353                                 }
 354                                 else
 355                                 {
 356                                         entity e = spawn();
 357                                         e.model = strzone(argv(1));
 358                                         e.mdl = "rocket_explode";
 359                                         e.health = 1000;
 360                                         setorigin(e, trace_endpos);
 361                                         e.effects = EF_NOMODELFLAGS;
 362                                         if(f == 1)
 363                                         {
 364                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 365                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 366                                         }
 367                                         WITH(entity, self, e, spawnfunc_func_breakable(e));
 368                                         // now, is it valid?
 369                                         if(f == 0)
 370                                         {
 371                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 372                                                 if(trace_startsolid)
 373                                                 {
 374                                                         remove(e);
 375                                                         sprint(self, "cannot make stuff there (no space)\n");
 376                                                 }
 377                                                 else
 378                                                         DID_CHEAT();
 379                                         }
 380                                         else
 381                                                 DID_CHEAT();
 382                                 }
 383                         }
 384                         else
 385                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 386                         break;
 387                 case "penalty":
 388                         IS_CHEAT(0, argc, 0);
 389                         if(argc == 3)
 390                         {
 391                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 392                                 DID_CHEAT();
 393                                 break;
 394                         }
 395                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 396                         break;
 397                 case "dragbox_spawn": {
 398                         IS_CHEAT(0, argc, 0);
 399                         entity e = new(dragbox_box);
 400                         e.think = DragBox_Think;
 401                         e.nextthink = time;
 402                         e.solid = -1; // black
 403                         setmodel(e, MDL_Null); // network it
 404                         if(argc == 4)
 405                                 e.cnt = stof(argv(1));
 406                         else
 407                                 e.cnt = max(0, drag_lastcnt);
 408
 409                         e.aiment = new(dragbox_corner_1);
 410                         e.aiment.owner = e;
 411                         setmodel(e.aiment, MDL_MARKER);
 412                         e.aiment.skin = 0;
 413                         setsize(e.aiment, '0 0 0', '0 0 0');
 414                         if(argc == 4)
 415                                 setorigin(e.aiment, stov(argv(2)));
 416                         else
 417                         {
 418                                 crosshair_trace(self);
 419                                 setorigin(e.aiment, trace_endpos);
 420                         }
 421
 422                         e.enemy = new(dragbox_corner_2);
 423                         e.enemy.owner = e;
 424                         setmodel(e.enemy, MDL_MARKER);
 425                         e.enemy.skin = 1;
 426                         setsize(e.enemy, '0 0 0', '0 0 0');
 427                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 428                         end.x = (end.x > 0) * 2 - 1;
 429                         end.y = (end.y > 0) * 2 - 1;
 430                         end.z = (end.z > 0) * 2 - 1;
 431                         if(argc == 4)
 432                                 setorigin(e.enemy, stov(argv(3)));
 433                         else
 434                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 435
 436                         e.killindicator = new(drag_digit);
 437                         e.killindicator.owner = e;
 438                         setattachment(e.killindicator, e, "");
 439                         setorigin(e.killindicator, '0 0 -8');
 440                         e.killindicator.killindicator = new(drag_digit);
 441                         e.killindicator.killindicator.owner = e;
 442                         setattachment(e.killindicator.killindicator, e, "");
 443                         setorigin(e.killindicator.killindicator, '0 0 8');
 444                         DID_CHEAT();
 445                         break;
 446                 }
 447                 case "dragpoint_spawn": {
 448                         IS_CHEAT(0, argc, 0);
 449                         entity e = new(dragpoint);
 450                         e.think = DragBox_Think;
 451                         e.nextthink = time;
 452                         e.solid = 0; // nothing special
 453                         setmodel(e, MDL_MARKER);
 454                         setsize(e, PL_MIN, PL_MAX);
 455                         e.skin = 2;
 456                         if(argc == 3)
 457                                 e.cnt = stof(argv(1));
 458                         else
 459                                 e.cnt = drag_lastcnt;
 460                         if(argc == 3)
 461                                 setorigin(e, stov(argv(2)));
 462                         else
 463                         {
 464                                 crosshair_trace(self);
 465                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 466                                 move_out_of_solid(e);
 467                         }
 468
 469                         e.killindicator = new(drag_digit);
 470                         e.killindicator.owner = e;
 471                         setattachment(e.killindicator, e, "");
 472                         setorigin(e.killindicator, '0 0 40');
 473                         e.killindicator.killindicator = new(drag_digit);
 474                         e.killindicator.killindicator.owner = e;
 475                         setattachment(e.killindicator.killindicator, e, "");
 476                         setorigin(e.killindicator.killindicator, '0 0 56');
 477                         DID_CHEAT();
 478                         break;
 479                 }
 480                 case "drag_remove":
 481                         IS_CHEAT(0, argc, 0);
 482                         RandomSelection_Init();
 483                         crosshair_trace(self);
 484                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 485                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 486                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 487                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 488                         if(RandomSelection_chosen_ent)
 489                         {
 490                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 491                                 remove(RandomSelection_chosen_ent.killindicator);
 492                                 if(RandomSelection_chosen_ent.aiment)
 493                                         remove(RandomSelection_chosen_ent.aiment);
 494                                 if(RandomSelection_chosen_ent.enemy)
 495                                         remove(RandomSelection_chosen_ent.enemy);
 496                                 remove(RandomSelection_chosen_ent);
 497                         }
 498                         DID_CHEAT();
 499                         break;
 500                 case "drag_setcnt":
 501                         IS_CHEAT(0, argc, 0);
 502                         if(argc == 2)
 503                         {
 504                                 RandomSelection_Init();
 505                                 crosshair_trace(self);
 506                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 507                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 508                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 509                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 510                                 if(RandomSelection_chosen_ent)
 511                                 {
 512                                         if(substring(argv(1), 0, 1) == "*")
 513                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 514                                         else
 515                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 516                                 }
 517                                 DID_CHEAT();
 518                                 break;
 519                         }
 520                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 521                         break;
 522                 case "drag_save":
 523                         IS_CHEAT(0, argc, 0);
 524                         if(argc == 2)
 525                         {
 526                                 f = fopen(argv(1), FILE_WRITE);
 527                                 fputs(f, "cmd drag_clear\n");
 528                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 529                                 {
 530                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 531                                 }
 532                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 533                                 {
 534                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 535                                 }
 536                                 fclose(f);
 537                                 DID_CHEAT();
 538                                 break;
 539                         }
 540                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 541                         break;
 542                 case "drag_saveraceent":
 543                         IS_CHEAT(0, argc, 0);
 544                         if(argc == 2)
 545                         {
 546                                 f = fopen(argv(1), FILE_WRITE);
 547                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 548                                 {
 549                                         fputs(f, "{\n");
 550                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 551                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 552                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 553                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 554                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 555                                         fputs(f, "}\n");
 556                                 }
 557                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 558                                 {
 559                                         start = '0 0 0';
 560                                         effectnum = 0;
 561                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 562                                         {
 563                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 564                                                 {
 565                                                         start = start + oldself.origin;
 566                                                         ++effectnum;
 567                                                 }
 568                                         }
 569                                         start *= 1 / effectnum;
 570                                         fputs(f, "{\n");
 571                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 572                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 573                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 574                                         if(e.cnt == -2)
 575                                         {
 576                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 577                                                 fputs(f, "\"race_place\" \"0\"\n");
 578                                         }
 579                                         else if(e.cnt == -1)
 580                                         {
 581                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 582                                                 fputs(f, "\"race_place\" \"-1\"\n");
 583                                         }
 584                                         else
 585                                         {
 586                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 587                                                 if(e.cnt == 0)
 588                                                 {
 589                                                         // these need race_place
 590                                                         // counting...
 591                                                         effectnum = 1;
 592                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 593                                                         if(oldself.cnt == 0)
 594                                                         {
 595                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 596                                                                         ++effectnum;
 597                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && etof(oldself) < etof(e))
 598                                                                         ++effectnum;
 599                                                         }
 600                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 601                                                 }
 602                                         }
 603                                         fputs(f, "}\n");
 604                                 }
 605                                 fclose(f);
 606                                 DID_CHEAT();
 607                                 break;
 608                         }
 609                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 610                         break;
 611                 case "drag_clear":
 612                         IS_CHEAT(0, argc, 0);
 613                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 614                                 remove(e);
 615                         for(entity e = world; (e = find(e, classname, "dragbox_corner_1")); )
 616                                 remove(e);
 617                         for(entity e = world; (e = find(e, classname, "dragbox_corner_2")); )
 618                                 remove(e);
 619                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 620                                 remove(e);
 621                         for(entity e = world; (e = find(e, classname, "drag_digit")); )
 622                                 remove(e);
 623                         DID_CHEAT();
 624                         break;
 625                 case "god":
 626                         IS_CHEAT(0, argc, 0);
 627                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 628                         if(self.flags & FL_GODMODE)
 629                         {
 630                                 sprint(self, "godmode ON\n");
 631                                 DID_CHEAT();
 632                         }
 633                         else
 634                                 sprint(self, "godmode OFF\n");
 635                         break;
 636                 case "notarget":
 637                         IS_CHEAT(0, argc, 0);
 638                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 639                         if(self.flags & FL_NOTARGET)
 640                         {
 641                                 sprint(self, "notarget ON\n");
 642                                 DID_CHEAT();
 643                         }
 644                         else
 645                                 sprint(self, "notarget OFF\n");
 646                         break;
 647                 case "noclip":
 648                         IS_CHEAT(0, argc, 0);
 649                         if(self.movetype != MOVETYPE_NOCLIP)
 650                         {
 651                                 self.movetype = MOVETYPE_NOCLIP;
 652                                 sprint(self, "noclip ON\n");
 653                                 DID_CHEAT();
 654                         }
 655                         else
 656                         {
 657                                 self.movetype = MOVETYPE_WALK;
 658                                 sprint(self, "noclip OFF\n");
 659                         }
 660                         break;
 661                 case "fly":
 662                         IS_CHEAT(0, argc, 0);
 663                         if(self.movetype != MOVETYPE_FLY)
 664                         {
 665                                 self.movetype = MOVETYPE_FLY;
 666                                 sprint(self, "flymode ON\n");
 667                                 DID_CHEAT();
 668                         }
 669                         else
 670                         {
 671                                 self.movetype = MOVETYPE_WALK;
 672                                 sprint(self, "flymode OFF\n");
 673                         }
 674                         break;
 675                 case "give":
 676                         IS_CHEAT(0, argc, 0);
 677                         if(GiveItems(self, 1, argc))
 678                                 DID_CHEAT();
 679                         break;
 680                 case "usetarget":
 681                         IS_CHEAT(0, argc, 0);
 682                         setself(spawn());
 683                         self.target = argv(1);
 684                         activator = this;
 685                         SUB_UseTargets();
 686                         remove(self);
 687                         setself(this);
 688                         DID_CHEAT();
 689                         break;
 690                 case "killtarget":
 691                         IS_CHEAT(0, argc, 0);
 692                         setself(spawn());
 693                         self.killtarget = argv(1);
 694                         activator = this;
 695                         SUB_UseTargets();
 696                         remove(self);
 697                         setself(this);
 698                         DID_CHEAT();
 699                         break;
 700                 case "teleporttotarget":
 701                         IS_CHEAT(0, argc, 0);
 702                         setself(new(cheattriggerteleport));
 703                         setorigin(self, self.origin);
 704                         self.target = argv(1);
 705                         teleport_findtarget();
 706                         if(!wasfreed(self))
 707                         {
 708                                 Simple_TeleportPlayer(self, this);
 709                                 remove(self);
 710                                 DID_CHEAT();
 711                         }
 712                         setself(this);
 713                         break;
 714         }
 715
 716         END_CHEAT_FUNCTION();
 717 }
 718
 719 float Drag(float force_allow_pick, float ischeat);
 720 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 721 void Drag_Finish(entity dragger);
 722 float Drag_IsDraggable(entity draggee);
 723 float Drag_MayChangeAngles(entity draggee);
 724 void Drag_MoveForward(entity dragger);
 725 void Drag_SetSpeed(entity dragger, float s);
 726 void Drag_MoveBackward(entity dragger);
 727 void Drag_Update(entity dragger);
 728 float Drag_CanDrag(entity dragger);
 729 float Drag_IsDragging(entity dragger);
 730 void Drag_MoveDrag(entity from, entity to);
 731 .entity dragentity;
 732
 733 float CheatFrame()
 734 {SELFPARAM();
 735         BEGIN_CHEAT_FUNCTION();
 736
 737         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 738         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 739         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 740         // grabbing itself no longer being accounted as cheating.
 741
 742         switch(0)
 743         {
 744                 default:
 745                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 746                         {
 747                                 // use cheat dragging if cheats are enabled
 748                                 crosshair_trace_plusvisibletriggers(self);
 749                                 Drag(true, true);
 750                         }
 751                         else
 752                         {
 753                                 Drag(false, false); // execute dragging
 754                         }
 755                         break;
 756         }
 757
 758         END_CHEAT_FUNCTION();
 759 }
 760
 761
 762
 763
 764
 765 // ENTITY DRAGGING
 766
 767 // on dragger:
 768 .float draggravity;
 769 .float dragspeed; // speed of mouse wheel action
 770 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 771 .vector draglocalvector; // local attachment vector of the dragentity
 772 .float draglocalangle;
 773 // on draggee:
 774 .entity draggedby;
 775 .float dragmovetype;
 776
 777 float Drag(float force_allow_pick, float ischeat)
 778 {SELFPARAM();
 779         BEGIN_CHEAT_FUNCTION();
 780
 781         // returns true when an entity has been picked up
 782         // If pick is true, the object can also be picked up if it's not being held already
 783         // If pick is false, only keep dragging the object if it's already being held
 784
 785         switch(0)
 786         {
 787                 default:
 788                         if(Drag_IsDragging(self))
 789                         {
 790                                 if(self.BUTTON_DRAG)
 791                                 {
 792                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 793                                         {
 794                                                 Drag_MoveForward(self);
 795                                                 self.impulse = 0;
 796                                         }
 797                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 798                                         {
 799                                                 Drag_MoveBackward(self);
 800                                                 self.impulse = 0;
 801                                         }
 802                                         else if(self.impulse >= 1 && self.impulse <= 9)
 803                                         {
 804                                                 Drag_SetSpeed(self, self.impulse - 1);
 805                                         }
 806                                         else if(self.impulse == 14)
 807                                         {
 808                                                 Drag_SetSpeed(self, 9);
 809                                         }
 810
 811                                         if(frametime)
 812                                                 Drag_Update(self);
 813                                 }
 814                                 else
 815                                 {
 816                                         Drag_Finish(self);
 817                                 }
 818                         }
 819                         else
 820                         {
 821                                 if(Drag_CanDrag(self))
 822                                         if(self.BUTTON_DRAG)
 823                                         {
 824                                                 crosshair_trace_plusvisibletriggers(self);
 825                                                 entity e = trace_ent;
 826                                                 float pick = force_allow_pick;
 827                                                 if (e && !pick)
 828                                                 {
 829                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 830                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 831                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 832                                                         // it goes out of range while slinging it around.
 833
 834                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 835                                                         {
 836                                                                 switch(e.grab)
 837                                                                 {
 838                                                                         case 0: // can't grab
 839                                                                                 break;
 840                                                                         case 1: // owner can grab
 841                                                                                 if(e.owner == self || e.realowner == self)
 842                                                                                         pick = true;
 843                                                                                 break;
 844                                                                         case 2: // owner and team mates can grab
 845                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 846                                                                                         pick = true;
 847                                                                                 break;
 848                                                                         case 3: // anyone can grab
 849                                                                                 pick = true;
 850                                                                                 break;
 851                                                                         default:
 852                                                                                 break;
 853                                                                 }
 854                                                         }
 855                                                 }
 856                                                 // Find e and pick
 857                                                 if(e && pick)
 858                                                         if(Drag_IsDraggable(e))
 859                                                         {
 860                                                                 if(ischeat)
 861                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 862                                                                 if(e.draggedby)
 863                                                                         Drag_Finish(e.draggedby);
 864                                                                 if(e.tag_entity)
 865                                                                         detach_sameorigin(e);
 866                                                                 Drag_Begin(self, e, trace_endpos);
 867                                                                 if(ischeat)
 868                                                                         DID_CHEAT();
 869                                                                 return true;
 870                                                         }
 871                                         }
 872                         }
 873                         break;
 874         }
 875         return false;
 876 }
 877
 878 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 879 {
 880         float tagscale;
 881
 882         draggee.dragmovetype = draggee.movetype;
 883         draggee.draggravity = draggee.gravity;
 884         draggee.movetype = MOVETYPE_WALK;
 885         draggee.gravity = 0.00001;
 886         draggee.flags &= ~FL_ONGROUND;
 887         draggee.draggedby = dragger;
 888
 889         dragger.dragentity = draggee;
 890
 891         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 892         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 893         touchpoint = touchpoint - gettaginfo(draggee, 0);
 894         tagscale = pow(vlen(v_forward), -2);
 895         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 896         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 897         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 898
 899         dragger.dragspeed = 64;
 900 }
 901
 902 void Drag_Finish(entity dragger)
 903 {
 904         entity draggee;
 905         draggee = dragger.dragentity;
 906         if(dragger)
 907                 dragger.dragentity = world;
 908         draggee.draggedby = world;
 909         draggee.movetype = draggee.dragmovetype;
 910         draggee.gravity = draggee.draggravity;
 911
 912         switch(draggee.movetype)
 913         {
 914                 case MOVETYPE_TOSS:
 915                 case MOVETYPE_WALK:
 916                 case MOVETYPE_STEP:
 917                 case MOVETYPE_FLYMISSILE:
 918                 case MOVETYPE_BOUNCE:
 919                 case MOVETYPE_BOUNCEMISSILE:
 920                 case MOVETYPE_PHYSICS:
 921                         break;
 922                 default:
 923                         draggee.velocity = '0 0 0';
 924                         break;
 925         }
 926
 927         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 928         {
 929                 draggee.velocity = '0 0 0';
 930                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 931         }
 932 }
 933
 934 float Drag_IsDraggable(entity draggee)
 935 {
 936         // TODO add more checks for bad stuff here
 937         if(draggee == world)
 938                 return false;
 939         if(draggee.classname == "func_bobbing")
 940                 return false;
 941         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 942                 return false;
 943         if(draggee.classname == "plat")
 944                 return false;
 945         if(draggee.classname == "func_button")
 946                 return false;
 947 //      if(draggee.model == "")
 948 //              return false;
 949         if(IS_SPEC(draggee))
 950                 return false;
 951         if(IS_OBSERVER(draggee))
 952                 return false;
 953         if(draggee.classname == "exteriorweaponentity")
 954                 return false;
 955         if(draggee.classname == "weaponentity")
 956                 return false;
 957
 958         return true;
 959 }
 960
 961 float Drag_MayChangeAngles(entity draggee)
 962 {
 963         // TODO add more checks for bad stuff here
 964         if(substring(draggee.model, 0, 1) == "*")
 965                 return false;
 966         return true;
 967 }
 968
 969 void Drag_MoveForward(entity dragger)
 970 {
 971         dragger.dragdistance += dragger.dragspeed;
 972 }
 973
 974 void Drag_SetSpeed(entity dragger, float s)
 975 {
 976         dragger.dragspeed = pow(2, s);
 977 }
 978
 979 void Drag_MoveBackward(entity dragger)
 980 {
 981         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 982 }
 983
 984 void Drag_Update(entity dragger)
 985 {
 986         vector curorigin, neworigin, goodvelocity;
 987         float f;
 988         entity draggee;
 989
 990         draggee = dragger.dragentity;
 991         draggee.flags &= ~FL_ONGROUND;
 992
 993         curorigin = gettaginfo(draggee, 0);
 994         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
 995         makevectors(dragger.v_angle);
 996         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 997         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 998
 999         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
1000                 dragger.draglocalangle += 360;
1001         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
1002                 dragger.draglocalangle -= 360;
1003
1004         f = min(frametime * 10, 1);
1005         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1006
1007         if(Drag_MayChangeAngles(draggee))
1008                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1009
1010         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1011
1012         vector vecs = '0 0 0';
1013         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1014         if(dragger.(weaponentity).movedir.x > 0)
1015                 vecs = dragger.(weaponentity).movedir;
1016
1017         vector dv = v_right * -vecs_y + v_up * vecs_z;
1018
1019         te_lightning1(draggee, dragger.origin + dragger.view_ofs + dv, curorigin);
1020 }
1021
1022 float Drag_CanDrag(entity dragger)
1023 {
1024         return (dragger.deadflag == DEAD_NO) || (IS_PLAYER(dragger));
1025 }
1026
1027 float Drag_IsDragging(entity dragger)
1028 {
1029         if(!dragger.dragentity)
1030                 return false;
1031         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1032         {
1033                 dragger.dragentity = world;
1034                 return false;
1035         }
1036         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1037         {
1038                 Drag_Finish(dragger);
1039                 return false;
1040         }
1041         return true;
1042 }
1043
1044 void Drag_MoveDrag(entity from, entity to)
1045 {
1046         if(from.draggedby)
1047         {
1048                 to.draggedby = from.draggedby;
1049                 to.draggedby.dragentity = to;
1050                 from.draggedby = world;
1051         }
1052 }
1053
1054 void DragBox_Think()
1055 {SELFPARAM();
1056         if(self.aiment && self.enemy)
1057         {
1058                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1059                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1060                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1061                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1062                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1063                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1064                 self.mins = -1 * self.maxs;
1065                 setorigin(self, self.origin);
1066                 setsize(self, self.mins, self.maxs); // link edict
1067         }
1068
1069         if(self.cnt == -1) // actually race_place -1
1070         {
1071                 // show "10 10" for qualifying spawns
1072                 setmodel(self.killindicator, MDL_NUM(10));
1073                 setmodel(self.killindicator.killindicator, MDL_NUM(10));
1074         }
1075         else if(self.cnt == -2) // actually race_place 0
1076         {
1077                 // show "10 0" for loser spawns
1078                 setmodel(self.killindicator, MDL_NUM(10));
1079                 setmodel(self.killindicator.killindicator, MDL_NUM(0));
1080         }
1081         else
1082         {
1083                 setmodel(self.killindicator, MDL_NUM(self.cnt % 10));
1084                 setmodel(self.killindicator.killindicator, MDL_NUM(floor(self.cnt / 10)));
1085         }
1086
1087         self.nextthink = time;
1088 }
1089
1090 #endif