qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!warmup_stage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         self.weapons = '0 0 0';
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                 {
 301                         defaultmodel = argv(floor(n * self.model_randomizer));
 302                         // However, do NOT randomize if the player-selected model is in the list.
 303                         for (i = 0; i < n; ++i)
 304                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 305                                         defaultmodel = argv(i);
 306                 }
 307
 308                 i = strstrofs(defaultmodel, ":", 0);
 309                 if(i >= 0)
 310                 {
 311                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 312                         defaultmodel = substring(defaultmodel, 0, i);
 313                 }
 314         }
 315
 316         if(defaultmodel != "")
 317         {
 318                 if (defaultmodel != self.model)
 319                 {
 320                         m1 = self.mins;
 321                         m2 = self.maxs;
 322                         setplayermodel (self, defaultmodel);
 323                         setsize (self, m1, m2);
 324                         chmdl = TRUE;
 325                 }
 326
 327                 oldskin = self.skin;
 328                 self.skin = defaultskin;
 329         } else {
 330                 if (self.playermodel != self.model || self.playermodel == "")
 331                 {
 332                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 333                         m1 = self.mins;
 334                         m2 = self.maxs;
 335                         setplayermodel (self, self.playermodel);
 336                         setsize (self, m1, m2);
 337                         chmdl = TRUE;
 338                 }
 339
 340                 oldskin = self.skin;
 341                 self.skin = stof(self.playerskin);
 342         }
 343
 344         if(chmdl || oldskin != self.skin) // model or skin has changed
 345         {
 346                 self.species = player_getspecies(); // update species
 347                 UpdatePlayerSounds(); // update skin sounds
 348         }
 349
 350         if(!teamplay)
 351                 if(strlen(autocvar_sv_defaultplayercolors))
 352                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 353                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 354 }
 355
 356 /*
 357 =============
 358 PutClientInServer
 359
 360 Called when a client spawns in the server
 361 =============
 362 */
 363 void PutClientInServer (void)
 364 {
 365         if(IS_BOT_CLIENT(self))
 366                 self.classname = "player";
 367         else if(IS_REAL_CLIENT(self))
 368         {
 369                 msg_entity = self;
 370                 WriteByte(MSG_ONE, SVC_SETVIEW);
 371                 WriteEntity(MSG_ONE, self);
 372         }
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 race_PreSpawn();
 393
 394                 spot = SelectSpawnPoint (FALSE);
 395                 if(!spot)
 396                 {
 397                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 398                         return; // spawn failed
 399                 }
 400
 401                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 402
 403                 self.classname = "player";
 404                 self.wasplayer = TRUE;
 405                 self.iscreature = TRUE;
 406                 self.teleportable = TELEPORT_NORMAL;
 407                 self.damagedbycontents = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 411                 if(autocvar_g_playerclip_collisions)
 412                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 413                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 414                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 415                 self.frags = FRAGS_PLAYER;
 416                 if(INDEPENDENT_PLAYERS)
 417                         MAKE_INDEPENDENT_PLAYER(self);
 418                 self.flags = FL_CLIENT;
 419                 if(autocvar__notarget)
 420                         self.flags |= FL_NOTARGET;
 421                 self.takedamage = DAMAGE_AIM;
 422                 self.effects = 0;
 423                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 424                 self.air_finished = time + 12;
 425                 self.dmg = 2;
 426                 if(autocvar_g_balance_nex_charge)
 427                 {
 428                         if(autocvar_g_balance_nex_secondary_chargepool)
 429                                 self.nex_chargepool_ammo = 1;
 430                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 431                 }
 432
 433                 if(warmup_stage)
 434                 {
 435                         self.ammo_shells = warmup_start_ammo_shells;
 436                         self.ammo_nails = warmup_start_ammo_nails;
 437                         self.ammo_rockets = warmup_start_ammo_rockets;
 438                         self.ammo_cells = warmup_start_ammo_cells;
 439                         self.ammo_fuel = warmup_start_ammo_fuel;
 440                         self.health = warmup_start_health;
 441                         self.armorvalue = warmup_start_armorvalue;
 442                         self.weapons = WARMUP_START_WEAPONS;
 443                 }
 444                 else
 445                 {
 446                         self.ammo_shells = start_ammo_shells;
 447                         self.ammo_nails = start_ammo_nails;
 448                         self.ammo_rockets = start_ammo_rockets;
 449                         self.ammo_cells = start_ammo_cells;
 450                         self.ammo_fuel = start_ammo_fuel;
 451                         self.health = start_health;
 452                         self.armorvalue = start_armorvalue;
 453                         self.weapons = start_weapons;
 454                 }
 455
 456                 if(self.weapons & WEPSET_SUPERWEAPONS)
 457                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 458                 else
 459                         self.superweapons_finished = 0;
 460
 461                 if(g_weaponarena_random)
 462                 {
 463                         if(g_weaponarena_random_with_laser)
 464                                 self.weapons &= ~WEPSET_LASER;
 465                         W_RandomWeapons(self, g_weaponarena_random);
 466                         if(g_weaponarena_random_with_laser)
 467                                 self.weapons |= WEPSET_LASER;
 468                 }
 469
 470                 self.items = start_items;
 471
 472                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 473                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 474                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 475                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 476                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 477                 //extend the pause of rotting if client was reset at the beginning of the countdown
 478                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 479                         self.spawnshieldtime += game_starttime - time;
 480                         self.pauserotarmor_finished += game_starttime - time;
 481                         self.pauserothealth_finished += game_starttime - time;
 482                         self.pauseregen_finished += game_starttime - time;
 483                 }
 484                 self.damageforcescale = 2;
 485                 self.death_time = 0;
 486                 self.respawn_flags = 0;
 487                 self.respawn_time = 0;
 488                 self.stat_respawn_time = 0;
 489                 self.scale = 0;
 490                 self.fade_time = 0;
 491                 self.pain_frame = 0;
 492                 self.pain_finished = 0;
 493                 self.strength_finished = 0;
 494                 self.invincible_finished = 0;
 495                 self.pushltime = 0;
 496                 // players have no think function
 497                 self.think = func_null;
 498                 self.nextthink = 0;
 499                 self.hook_time = 0;
 500                 self.dmg_team = 0;
 501                 self.ballistics_density = autocvar_g_ballistics_density_player;
 502
 503                 self.metertime = 0;
 504
 505                 self.deadflag = DEAD_NO;
 506
 507                 self.angles = spot.angles;
 508
 509                 self.angles_z = 0; // never spawn tilted even if the spot says to
 510                 self.fixangle = TRUE; // turn this way immediately
 511                 self.velocity = '0 0 0';
 512                 self.avelocity = '0 0 0';
 513                 self.punchangle = '0 0 0';
 514                 self.punchvector = '0 0 0';
 515                 self.oldvelocity = self.velocity;
 516                 self.fire_endtime = -1;
 517
 518                 entity spawnevent = spawn();
 519                 spawnevent.owner = self;
 520                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 521
 522                 self.model = "";
 523                 FixPlayermodel();
 524                 self.drawonlytoclient = world;
 525
 526                 self.crouch = FALSE;
 527                 self.view_ofs = PL_VIEW_OFS;
 528                 setsize (self, PL_MIN, PL_MAX);
 529                 self.spawnorigin = spot.origin;
 530                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 531                 // don't reset back to last position, even if new position is stuck in solid
 532                 self.oldorigin = self.origin;
 533                 self.prevorigin = self.origin;
 534                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 535                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 536         self.hud = HUD_NORMAL;
 537
 538                 self.event_damage = PlayerDamage;
 539
 540                 self.bot_attack = TRUE;
 541
 542                 self.statdraintime = time + 5;
 543                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 544
 545                 if(self.killcount == -666) {
 546                         PlayerScore_Clear(self);
 547                         self.killcount = 0;
 548                 }
 549
 550                 CL_SpawnWeaponentity();
 551                 self.alpha = default_player_alpha;
 552                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 553                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 554
 555                 self.speedrunning = FALSE;
 556
 557                 race_PostSpawn(spot);
 558
 559                 //stuffcmd(self, "chase_active 0");
 560                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 561
 562                 target_voicescript_clear(self);
 563
 564                 // reset fields the weapons may use
 565                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 566                 {
 567                         weapon_action(j, WR_RESETPLAYER);
 568
 569                         // all weapons must be fully loaded when we spawn
 570                         entity e;
 571                         e = get_weaponinfo(j);
 572                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 573                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 574                 }
 575
 576                 oldself = self;
 577                 self = spot;
 578                         activator = oldself;
 579                                 string s;
 580                                 s = self.target;
 581                                 self.target = string_null;
 582                                 SUB_UseTargets();
 583                                 self.target = s;
 584                         activator = world;
 585                 self = oldself;
 586
 587                 spawn_spot = spot;
 588                 MUTATOR_CALLHOOK(PlayerSpawn);
 589
 590                 if(autocvar_spawn_debug)
 591                 {
 592                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 593                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 594                 }
 595
 596                 self.switchweapon = w_getbestweapon(self);
 597                 self.cnt = -1; // W_LastWeapon will not complain
 598                 self.weapon = 0;
 599                 self.weaponname = "";
 600                 self.switchingweapon = 0;
 601
 602                 if(!warmup_stage)
 603                         if(!self.alivetime)
 604                                 self.alivetime = time;
 605
 606                 antilag_clear(self);
 607         }
 608         else if(IS_OBSERVER(self))
 609         {
 610                 PutObserverInServer ();
 611         }
 612 }
 613
 614 .float ebouncefactor, ebouncestop; // electro's values
 615 // TODO do we need all these fields, or should we stop autodetecting runtime
 616 // changes and just have a console command to update this?
 617 float ClientInit_SendEntity(entity to, float sf)
 618 {
 619         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 620         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 633         if(sv_foginterval && world.fog != "")
 634                 WriteString(MSG_ENTITY, world.fog);
 635         else
 636                 WriteString(MSG_ENTITY, "");
 637         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 638         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 639         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 640         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 641         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 642         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 644         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 645         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 647         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 649         return TRUE;
 650 }
 651
 652 void ClientInit_CheckUpdate()
 653 {
 654         self.nextthink = time;
 655         if(self.count != autocvar_g_balance_armor_blockpercent)
 656         {
 657                 self.count = autocvar_g_balance_armor_blockpercent;
 658                 self.SendFlags |= 1;
 659         }
 660         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 661         {
 662                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 666         {
 667                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 671         {
 672                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 673                 self.SendFlags |= 1;
 674         }
 675         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 676         {
 677                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 678                 self.SendFlags |= 1;
 679         }
 680 }
 681
 682 void ClientInit_Spawn()
 683 {
 684         entity o;
 685         entity e;
 686         e = spawn();
 687         e.classname = "clientinit";
 688         e.think = ClientInit_CheckUpdate;
 689         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 690
 691         o = self;
 692         self = e;
 693         ClientInit_CheckUpdate();
 694         self = o;
 695 }
 696
 697 /*
 698 =============
 699 SetNewParms
 700 =============
 701 */
 702 void SetNewParms (void)
 703 {
 704         // initialize parms for a new player
 705         parm1 = -(86400 * 366);
 706 }
 707
 708 /*
 709 =============
 710 SetChangeParms
 711 =============
 712 */
 713 void SetChangeParms (void)
 714 {
 715         // save parms for level change
 716         parm1 = self.parm_idlesince - time;
 717 }
 718
 719 /*
 720 =============
 721 DecodeLevelParms
 722 =============
 723 */
 724 void DecodeLevelParms (void)
 725 {
 726         // load parms
 727         self.parm_idlesince = parm1;
 728         if(self.parm_idlesince == -(86400 * 366))
 729                 self.parm_idlesince = time;
 730
 731         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 732         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 733 }
 734
 735 /*
 736 =============
 737 ClientKill
 738
 739 Called when a client types 'kill' in the console
 740 =============
 741 */
 742
 743 .float clientkill_nexttime;
 744 void ClientKill_Now_TeamChange()
 745 {
 746         if(self.killindicator_teamchange == -1)
 747         {
 748                 JoinBestTeam( self, FALSE, TRUE );
 749         }
 750         else if(self.killindicator_teamchange == -2)
 751         {
 752                 if(blockSpectators)
 753                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 754                 PutObserverInServer();
 755         }
 756         else
 757                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 758         self.killindicator_teamchange = 0;
 759 }
 760
 761 void ClientKill_Now()
 762 {
 763         if(self.vehicle)
 764         {
 765             vehicles_exit(VHEF_RELESE);
 766             if(!self.killindicator_teamchange)
 767             {
 768             self.vehicle_health = -1;
 769             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 770             }
 771         }
 772
 773         if(self.killindicator && !wasfreed(self.killindicator))
 774                 remove(self.killindicator);
 775
 776         self.killindicator = world;
 777
 778         if(self.killindicator_teamchange)
 779                 ClientKill_Now_TeamChange();
 780
 781         // in any case:
 782         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 783
 784         // now I am sure the player IS dead
 785 }
 786 void KillIndicator_Think()
 787 {
 788         if (gameover)
 789         {
 790                 self.owner.killindicator = world;
 791                 remove(self);
 792                 return;
 793         }
 794
 795         if (self.owner.alpha < 0 && !self.owner.vehicle)
 796         {
 797                 self.owner.killindicator = world;
 798                 remove(self);
 799                 return;
 800         }
 801
 802         if(self.cnt <= 0)
 803         {
 804                 self = self.owner;
 805                 ClientKill_Now(); // no oldself needed
 806                 return;
 807         }
 808     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 809     {
 810         self.nextthink = time + 1;
 811         self.cnt -= 1;
 812     }
 813         else
 814         {
 815                 if(self.cnt <= 10)
 816                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 817                 if(IS_REAL_CLIENT(self.owner))
 818                 {
 819                         if(self.cnt <= 10)
 820                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 821                 }
 822                 self.nextthink = time + 1;
 823                 self.cnt -= 1;
 824         }
 825 }
 826
 827 float clientkilltime;
 828 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 829 {
 830         float killtime;
 831         float starttime;
 832         entity e;
 833
 834         if (gameover)
 835                 return;
 836
 837         killtime = autocvar_g_balance_kill_delay;
 838
 839         if(g_race_qualifying || g_cts)
 840                 killtime = 0;
 841
 842     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 843     {
 844                 remove(self.killindicator);
 845                 self.killindicator = world;
 846
 847         ClientKill_Now(); // allow instant kill in this case
 848         return;
 849     }
 850
 851         self.killindicator_teamchange = targetteam;
 852
 853     if(!self.killindicator)
 854         {
 855                 if(self.deadflag == DEAD_NO)
 856                 {
 857                         killtime = max(killtime, self.clientkill_nexttime - time);
 858                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 859                 }
 860
 861                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 862                 {
 863                         ClientKill_Now();
 864                 }
 865                 else
 866                 {
 867                         starttime = max(time, clientkilltime);
 868
 869                         self.killindicator = spawn();
 870                         self.killindicator.owner = self;
 871                         self.killindicator.scale = 0.5;
 872                         setattachment(self.killindicator, self, "");
 873                         setorigin(self.killindicator, '0 0 52');
 874                         self.killindicator.think = KillIndicator_Think;
 875                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 876                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 877                         self.killindicator.cnt = ceil(killtime);
 878                         self.killindicator.count = bound(0, ceil(killtime), 10);
 879                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 880
 881                         for(e = world; (e = find(e, classname, "body")) != world; )
 882                         {
 883                                 if(e.enemy != self)
 884                                         continue;
 885                                 e.killindicator = spawn();
 886                                 e.killindicator.owner = e;
 887                                 e.killindicator.scale = 0.5;
 888                                 setattachment(e.killindicator, e, "");
 889                                 setorigin(e.killindicator, '0 0 52');
 890                                 e.killindicator.think = KillIndicator_Think;
 891                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 892                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 893                                 e.killindicator.cnt = ceil(killtime);
 894                         }
 895                         self.lip = 0;
 896                 }
 897         }
 898         if(self.killindicator)
 899         {
 900                 if(targetteam == 0) // just die
 901                 {
 902                         self.killindicator.colormod = '0 0 0';
 903                         if(IS_REAL_CLIENT(self))
 904                         if(self.killindicator.cnt > 0)
 905                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 906                 }
 907                 else if(targetteam == -1) // auto
 908                 {
 909                         self.killindicator.colormod = '0 1 0';
 910                         if(IS_REAL_CLIENT(self))
 911                         if(self.killindicator.cnt > 0)
 912                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 913                 }
 914                 else if(targetteam == -2) // spectate
 915                 {
 916                         self.killindicator.colormod = '0.5 0.5 0.5';
 917                         if(IS_REAL_CLIENT(self))
 918                         if(self.killindicator.cnt > 0)
 919                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 920                 }
 921                 else
 922                 {
 923                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 924                         if(IS_REAL_CLIENT(self))
 925                         if(self.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 927                 }
 928         }
 929
 930 }
 931
 932 void ClientKill (void)
 933 {
 934         if(gameover) return;
 935         if(self.player_blocked) return;
 936         if(self.freezetag_frozen) return;
 937
 938         ClientKill_TeamChange(0);
 939 }
 940
 941 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 942 {
 943     e.killindicator = spawn();
 944     e.killindicator.owner = e;
 945     e.killindicator.think = KillIndicator_Think;
 946     e.killindicator.nextthink = time + (e.lip) * 0.05;
 947     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 948     e.killindicator.health = 1; // this is used to indicate that it should be silent
 949     e.lip = 0;
 950 }
 951
 952 void FixClientCvars(entity e)
 953 {
 954         // send prediction settings to the client
 955         stuffcmd(e, "\nin_bindmap 0 0\n");
 956         if(g_race || g_cts)
 957                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 958         if(autocvar_g_antilag == 3) // client side hitscan
 959                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 960         if(autocvar_sv_gentle)
 961                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 962         /*
 963          * we no longer need to stuff this. Remove this comment block if you feel
 964          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 965         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 966         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 967         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 968         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 969         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 970         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 971         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 972         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 973         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 975         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 976         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 977         stuffcmd(e, "cl_movement_edgefriction 1\n");
 978          */
 979 }
 980
 981 float PlayerInIDList(entity p, string idlist)
 982 {
 983         float n, i;
 984         string s;
 985
 986         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 987         if not(p.crypto_idfp)
 988                 return 0;
 989
 990         // this function allows abbreviated player IDs too!
 991         n = tokenize_console(idlist);
 992         for(i = 0; i < n; ++i)
 993         {
 994                 s = argv(i);
 995                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 996                         return 1;
 997         }
 998
 999         return 0;
1000 }
1001
1002 /*
1003 =============
1004 ClientConnect
1005
1006 Called when a client connects to the server
1007 =============
1008 */
1009 void DecodeLevelParms (void);
1010 //void dom_player_join_team(entity pl);
1011 void set_dom_state(entity e);
1012 void ClientConnect (void)
1013 {
1014         float t;
1015
1016         if(IS_CLIENT(self))
1017         {
1018                 print("Warning: ClientConnect, but already connected!\n");
1019                 return;
1020         }
1021
1022         if(Ban_MaybeEnforceBanOnce(self))
1023                 return;
1024
1025         DecodeLevelParms();
1026
1027 #ifdef WATERMARK
1028         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1029 #endif
1030
1031         self.classname = "player_joining";
1032
1033         self.flags = FL_CLIENT;
1034         self.version_nagtime = time + 10 + random() * 10;
1035
1036         if(player_count<0)
1037         {
1038                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1039                 player_count = 0;
1040         }
1041
1042         PlayerScore_Attach(self);
1043         ClientData_Attach();
1044         accuracy_init(self);
1045
1046         bot_clientconnect();
1047
1048         playerdemo_init();
1049
1050         anticheat_init();
1051
1052         race_PreSpawnObserver();
1053
1054         // identify the right forced team
1055         if(autocvar_g_campaign)
1056         {
1057                 if(IS_REAL_CLIENT(self)) // only players, not bots
1058                 {
1059                         switch(autocvar_g_campaign_forceteam)
1060                         {
1061                                 case 1: self.team_forced = NUM_TEAM_1; break;
1062                                 case 2: self.team_forced = NUM_TEAM_2; break;
1063                                 case 3: self.team_forced = NUM_TEAM_3; break;
1064                                 case 4: self.team_forced = NUM_TEAM_4; break;
1065                                 default: self.team_forced = 0;
1066                         }
1067                 }
1068         }
1069         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1070                 self.team_forced = NUM_TEAM_1;
1071         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1072                 self.team_forced = NUM_TEAM_2;
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1074                 self.team_forced = NUM_TEAM_3;
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1076                 self.team_forced = NUM_TEAM_4;
1077         else if(autocvar_g_forced_team_otherwise == "red")
1078                 self.team_forced = NUM_TEAM_1;
1079         else if(autocvar_g_forced_team_otherwise == "blue")
1080                 self.team_forced = NUM_TEAM_2;
1081         else if(autocvar_g_forced_team_otherwise == "yellow")
1082                 self.team_forced = NUM_TEAM_3;
1083         else if(autocvar_g_forced_team_otherwise == "pink")
1084                 self.team_forced = NUM_TEAM_4;
1085         else if(autocvar_g_forced_team_otherwise == "spectate")
1086                 self.team_forced = -1;
1087         else if(autocvar_g_forced_team_otherwise == "spectator")
1088                 self.team_forced = -1;
1089         else
1090                 self.team_forced = 0;
1091
1092         if(!teamplay)
1093                 if(self.team_forced > 0)
1094                         self.team_forced = 0;
1095
1096         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1097
1098         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1099                 self.classname = "observer";
1100         } else {
1101                 if(teamplay)
1102                 {
1103                         if(autocvar_g_balance_teams)
1104                         {
1105                                 self.classname = "player";
1106                                 campaign_bots_may_start = 1;
1107                         }
1108                         else
1109                         {
1110                                 self.classname = "observer"; // do it anyway
1111                         }
1112                 }
1113                 else
1114                 {
1115                         self.classname = "player";
1116                         campaign_bots_may_start = 1;
1117                 }
1118         }
1119
1120         self.playerid = (playerid_last = playerid_last + 1);
1121
1122         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1123
1124     if(IS_BOT_CLIENT(self))
1125         PlayerStats_AddPlayer(self);
1126
1127         if(autocvar_sv_eventlog)
1128                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1129
1130         LogTeamchange(self.playerid, self.team, 1);
1131
1132         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1133
1134         self.netname_previous = strzone(self.netname);
1135
1136         if(IS_PLAYER(self) && teamplay)
1137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1138         else
1139                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1140
1141         stuffcmd(self, strcat(clientstuff, "\n"));
1142         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1143
1144         FixClientCvars(self);
1145
1146         // spawnfunc_waypoint sprites
1147         WaypointSprite_InitClient(self);
1148
1149         // Wazat's grappling hook
1150         SetGrappleHookBindings();
1151
1152         // get version info from player
1153         stuffcmd(self, "cmd clientversion $gameversion\n");
1154
1155         // get other cvars from player
1156         GetCvars(0);
1157
1158         // notify about available teams
1159         if(teamplay)
1160         {
1161                 CheckAllowedTeams(self);
1162                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1163                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1164         }
1165         else
1166                 stuffcmd(self, "set _teams_available 0\n");
1167
1168         attach_entcs();
1169
1170         bot_relinkplayerlist();
1171
1172         self.spectatortime = time;
1173         if(blockSpectators)
1174         {
1175                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1176         }
1177
1178         self.jointime = time;
1179         self.allowed_timeouts = autocvar_sv_timeout_number;
1180
1181         if(IS_REAL_CLIENT(self))
1182         {
1183                 if(!autocvar_g_campaign)
1184                 {
1185                         self.motd_actived_time = -1;
1186                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1187                 }
1188
1189                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1190                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1191         }
1192
1193         if(!sv_foginterval && world.fog != "")
1194                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1195
1196         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1197         {
1198                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1199                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1200         }
1201         else
1202                 self.hitplotfh = -1;
1203
1204         if(g_race || g_cts) {
1205                 string rr;
1206                 if(g_cts)
1207                         rr = CTS_RECORD;
1208                 else
1209                         rr = RACE_RECORD;
1210
1211                 msg_entity = self;
1212                 race_send_recordtime(MSG_ONE);
1213                 race_send_speedaward(MSG_ONE);
1214
1215                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1216                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1217                 race_send_speedaward_alltimebest(MSG_ONE);
1218
1219                 float i;
1220                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1221                         race_SendRankings(i, 0, 0, MSG_ONE);
1222                 }
1223         }
1224         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1225                 send_CSQC_teamnagger();
1226
1227         CheatInitClient();
1228
1229         CSQCMODEL_AUTOINIT();
1230
1231         self.model_randomizer = random();
1232
1233         if(IS_REAL_CLIENT(self))
1234                 sv_notice_join();
1235
1236         MUTATOR_CALLHOOK(ClientConnect);
1237 }
1238 /*
1239 =============
1240 ClientDisconnect
1241
1242 Called when a client disconnects from the server
1243 =============
1244 */
1245 .entity chatbubbleentity;
1246 void ReadyCount();
1247 void ClientDisconnect (void)
1248 {
1249         if(self.vehicle)
1250             vehicles_exit(VHEF_RELESE);
1251
1252         if not(IS_CLIENT(self))
1253         {
1254                 print("Warning: ClientDisconnect without ClientConnect\n");
1255                 return;
1256         }
1257
1258         PlayerStats_AddGlobalInfo(self);
1259
1260         CheatShutdownClient();
1261
1262         if(self.hitplotfh >= 0)
1263         {
1264                 fclose(self.hitplotfh);
1265                 self.hitplotfh = -1;
1266         }
1267
1268         anticheat_report();
1269         anticheat_shutdown();
1270
1271         playerdemo_shutdown();
1272
1273         bot_clientdisconnect();
1274
1275         if(self.entcs)
1276                 detach_entcs();
1277
1278         if(autocvar_sv_eventlog)
1279                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1280
1281         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1282
1283         MUTATOR_CALLHOOK(ClientDisconnect);
1284
1285         Portal_ClearAll(self);
1286
1287         RemoveGrapplingHook(self);
1288
1289         // Here, everything has been done that requires this player to be a client.
1290
1291         self.flags &= ~FL_CLIENT;
1292
1293         if (self.chatbubbleentity)
1294                 remove (self.chatbubbleentity);
1295
1296         if (self.killindicator)
1297                 remove (self.killindicator);
1298
1299         WaypointSprite_PlayerGone();
1300
1301         bot_relinkplayerlist();
1302
1303         accuracy_free(self);
1304         ClientData_Detach();
1305         PlayerScore_Detach(self);
1306
1307         if(self.netname_previous)
1308                 strunzone(self.netname_previous);
1309         if(self.clientstatus)
1310                 strunzone(self.clientstatus);
1311         if(self.weaponorder_byimpulse)
1312                 strunzone(self.weaponorder_byimpulse);
1313
1314         ClearPlayerSounds();
1315
1316         if(self.personal)
1317                 remove(self.personal);
1318
1319         self.playerid = 0;
1320         ReadyCount();
1321
1322         // free cvars
1323         GetCvars(-1);
1324 }
1325
1326 .float BUTTON_CHAT;
1327 void ChatBubbleThink()
1328 {
1329         self.nextthink = time;
1330         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1331         {
1332                 if(self.owner) // but why can that ever be world?
1333                         self.owner.chatbubbleentity = world;
1334                 remove(self);
1335                 return;
1336         }
1337         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1338 #ifdef TETRIS
1339                 || self.owner.tetris_on
1340 #endif
1341         )
1342                 self.model = self.mdl;
1343         else
1344                 self.model = "";
1345 }
1346
1347 void UpdateChatBubble()
1348 {
1349         if (self.alpha < 0)
1350                 return;
1351         // spawn a chatbubble entity if needed
1352         if (!self.chatbubbleentity)
1353         {
1354                 self.chatbubbleentity = spawn();
1355                 self.chatbubbleentity.owner = self;
1356                 self.chatbubbleentity.exteriormodeltoclient = self;
1357                 self.chatbubbleentity.think = ChatBubbleThink;
1358                 self.chatbubbleentity.nextthink = time;
1359                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1360                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1361                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1362                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1363                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1364                 self.chatbubbleentity.model = "";
1365                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1366         }
1367 }
1368
1369
1370 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1371 // added to the model skins
1372 /*void UpdateColorModHack()
1373 {
1374         float c;
1375         c = self.clientcolors & 15;
1376         // LordHavoc: only bothering to support white, green, red, yellow, blue
1377              if (!teamplay) self.colormod = '0 0 0';
1378         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1379         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1380         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1381         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1382         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1383         else self.colormod = '1 1 1';
1384 }*/
1385
1386 void respawn(void)
1387 {
1388         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1389         {
1390                 self.solid = SOLID_NOT;
1391                 self.takedamage = DAMAGE_NO;
1392                 self.movetype = MOVETYPE_FLY;
1393                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1394                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1395                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1396                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1397                 if(autocvar_g_respawn_ghosts_maxtime)
1398                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1399         }
1400
1401         CopyBody(1);
1402
1403         self.effects |= EF_NODRAW; // prevent another CopyBody
1404         PutClientInServer();
1405 }
1406
1407 void play_countdown(float finished, string samp)
1408 {
1409         if(IS_REAL_CLIENT(self))
1410                 if(floor(finished - time - frametime) != floor(finished - time))
1411                         if(finished - time < 6)
1412                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1413 }
1414
1415 void player_powerups (void)
1416 {
1417         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1418         olditems = self.items;
1419
1420         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1421                 self.modelflags |= MF_ROCKET;
1422         else
1423                 self.modelflags &= ~MF_ROCKET;
1424
1425         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1426
1427         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1428                 return;
1429
1430         Fire_ApplyDamage(self);
1431         Fire_ApplyEffect(self);
1432
1433         if not(g_minstagib)
1434         {
1435                 if (self.items & IT_STRENGTH)
1436                 {
1437                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1438                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1439                         if (time > self.strength_finished)
1440                         {
1441                                 self.items = self.items - (self.items & IT_STRENGTH);
1442                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1443                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1444                         }
1445                 }
1446                 else
1447                 {
1448                         if (time < self.strength_finished)
1449                         {
1450                                 self.items = self.items | IT_STRENGTH;
1451                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1452                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1453                         }
1454                 }
1455                 if (self.items & IT_INVINCIBLE)
1456                 {
1457                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1458                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1459                         if (time > self.invincible_finished)
1460                         {
1461                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1462                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1463                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1464                         }
1465                 }
1466                 else
1467                 {
1468                         if (time < self.invincible_finished)
1469                         {
1470                                 self.items = self.items | IT_INVINCIBLE;
1471                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1472                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1473                         }
1474                 }
1475                 if (self.items & IT_SUPERWEAPON)
1476                 {
1477                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1478                         {
1479                                 self.superweapons_finished = 0;
1480                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1481                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1482                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1483                         }
1484                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1485                         {
1486                                 // don't let them run out
1487                         }
1488                         else
1489                         {
1490                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1491                                 if (time > self.superweapons_finished)
1492                                 {
1493                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1494                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1495                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1496                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1497                                 }
1498                         }
1499                 }
1500                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1501                 {
1502                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1503                         {
1504                                 self.items = self.items | IT_SUPERWEAPON;
1505                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1506                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1507                         }
1508                         else
1509                         {
1510                                 self.superweapons_finished = 0;
1511                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1512                         }
1513                 }
1514                 else
1515                 {
1516                         self.superweapons_finished = 0;
1517                 }
1518         }
1519
1520         if(autocvar_g_nodepthtestplayers)
1521                 self.effects = self.effects | EF_NODEPTHTEST;
1522
1523         if(autocvar_g_fullbrightplayers)
1524                 self.effects = self.effects | EF_FULLBRIGHT;
1525
1526         if (time >= game_starttime)
1527         if (time < self.spawnshieldtime)
1528                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1529
1530         MUTATOR_CALLHOOK(PlayerPowerups);
1531 }
1532
1533 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1534 {
1535         if(current > stable)
1536                 return current;
1537         else if(current > stable - 0.25) // when close enough, "snap"
1538                 return stable;
1539         else
1540                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1541 }
1542
1543 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1544 {
1545         if(current < stable)
1546                 return current;
1547         else if(current < stable + 0.25) // when close enough, "snap"
1548                 return stable;
1549         else
1550                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1551 }
1552
1553 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1554 {
1555         if(current > rotstable)
1556         {
1557                 if(rotframetime > 0)
1558                 {
1559                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1560                         current = max(rotstable, current - rotlinear * rotframetime);
1561                 }
1562         }
1563         else if(current < regenstable)
1564         {
1565                 if(regenframetime > 0)
1566                 {
1567                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1568                         current = min(regenstable, current + regenlinear * regenframetime);
1569                 }
1570         }
1571
1572         if(current > limit)
1573                 current = limit;
1574
1575         return current;
1576 }
1577
1578 void player_regen (void)
1579 {
1580         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1581         maxh = autocvar_g_balance_health_rotstable;
1582         maxa = autocvar_g_balance_armor_rotstable;
1583         maxf = autocvar_g_balance_fuel_rotstable;
1584         minh = autocvar_g_balance_health_regenstable;
1585         mina = autocvar_g_balance_armor_regenstable;
1586         minf = autocvar_g_balance_fuel_regenstable;
1587         limith = autocvar_g_balance_health_limit;
1588         limita = autocvar_g_balance_armor_limit;
1589         limitf = autocvar_g_balance_fuel_limit;
1590
1591         max_mod = regen_mod = rot_mod = limit_mod = 1;
1592
1593         maxh = maxh * max_mod;
1594         //maxa = maxa * max_mod;
1595         //maxf = maxf * max_mod;
1596         minh = minh * max_mod;
1597         //mina = mina * max_mod;
1598         //minf = minf * max_mod;
1599         limith = limith * limit_mod;
1600         limita = limita * limit_mod;
1601         //limitf = limitf * limit_mod;
1602
1603         if(g_ca)
1604                 rot_mod = 0;
1605
1606         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1607         {
1608                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1609                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1610
1611                 // if player rotted to death...  die!
1612                 if(self.health < 1)
1613                 {
1614                         if(self.vehicle)
1615                                 vehicles_exit(VHEF_RELESE);
1616                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1617                 }
1618         }
1619
1620         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1621                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1622 }
1623
1624 float zoomstate_set;
1625 void SetZoomState(float z)
1626 {
1627         if(z != self.zoomstate)
1628         {
1629                 self.zoomstate = z;
1630                 ClientData_Touch(self);
1631         }
1632         zoomstate_set = 1;
1633 }
1634
1635 void GetPressedKeys(void) {
1636         MUTATOR_CALLHOOK(GetPressedKeys);
1637         if (self.movement_x > 0) // get if movement keys are pressed
1638         {       // forward key pressed
1639                 self.pressedkeys |= KEY_FORWARD;
1640                 self.pressedkeys &= ~KEY_BACKWARD;
1641         }
1642         else if (self.movement_x < 0)
1643         {       // backward key pressed
1644                 self.pressedkeys |= KEY_BACKWARD;
1645                 self.pressedkeys &= ~KEY_FORWARD;
1646         }
1647         else
1648         {       // no x input
1649                 self.pressedkeys &= ~KEY_FORWARD;
1650                 self.pressedkeys &= ~KEY_BACKWARD;
1651         }
1652
1653         if (self.movement_y > 0)
1654         {       // right key pressed
1655                 self.pressedkeys |= KEY_RIGHT;
1656                 self.pressedkeys &= ~KEY_LEFT;
1657         }
1658         else if (self.movement_y < 0)
1659         {       // left key pressed
1660                 self.pressedkeys |= KEY_LEFT;
1661                 self.pressedkeys &= ~KEY_RIGHT;
1662         }
1663         else
1664         {       // no y input
1665                 self.pressedkeys &= ~KEY_RIGHT;
1666                 self.pressedkeys &= ~KEY_LEFT;
1667         }
1668
1669         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1670                 self.pressedkeys |= KEY_JUMP;
1671         else
1672                 self.pressedkeys &= ~KEY_JUMP;
1673         if (self.BUTTON_CROUCH)
1674                 self.pressedkeys |= KEY_CROUCH;
1675         else
1676                 self.pressedkeys &= ~KEY_CROUCH;
1677
1678         if (self.BUTTON_ATCK)
1679                 self.pressedkeys |= KEY_ATCK;
1680         else
1681                 self.pressedkeys &= ~KEY_ATCK;
1682         if (self.BUTTON_ATCK2)
1683                 self.pressedkeys |= KEY_ATCK2;
1684         else
1685                 self.pressedkeys &= ~KEY_ATCK2;
1686 }
1687
1688 /*
1689 ======================
1690 spectate mode routines
1691 ======================
1692 */
1693
1694 void SpectateCopy(entity spectatee) {
1695         other = spectatee;
1696         MUTATOR_CALLHOOK(SpectateCopy);
1697         self.armortype = spectatee.armortype;
1698         self.armorvalue = spectatee.armorvalue;
1699         self.ammo_cells = spectatee.ammo_cells;
1700         self.ammo_shells = spectatee.ammo_shells;
1701         self.ammo_nails = spectatee.ammo_nails;
1702         self.ammo_rockets = spectatee.ammo_rockets;
1703         self.ammo_fuel = spectatee.ammo_fuel;
1704         self.clip_load = spectatee.clip_load;
1705         self.clip_size = spectatee.clip_size;
1706         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1707         self.health = spectatee.health;
1708         self.impulse = 0;
1709         self.items = spectatee.items;
1710         self.last_pickup = spectatee.last_pickup;
1711         self.hit_time = spectatee.hit_time;
1712         self.metertime = spectatee.metertime;
1713         self.strength_finished = spectatee.strength_finished;
1714         self.invincible_finished = spectatee.invincible_finished;
1715         self.pressedkeys = spectatee.pressedkeys;
1716         self.weapons = spectatee.weapons;
1717         self.switchweapon = spectatee.switchweapon;
1718         self.switchingweapon = spectatee.switchingweapon;
1719         self.weapon = spectatee.weapon;
1720         self.nex_charge = spectatee.nex_charge;
1721         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1722         self.hagar_load = spectatee.hagar_load;
1723         self.minelayer_mines = spectatee.minelayer_mines;
1724         self.punchangle = spectatee.punchangle;
1725         self.view_ofs = spectatee.view_ofs;
1726         self.velocity = spectatee.velocity;
1727         self.dmg_take = spectatee.dmg_take;
1728         self.dmg_save = spectatee.dmg_save;
1729         self.dmg_inflictor = spectatee.dmg_inflictor;
1730         self.v_angle = spectatee.v_angle;
1731         self.angles = spectatee.v_angle;
1732         if(!self.BUTTON_USE)
1733                 self.fixangle = TRUE;
1734         setorigin(self, spectatee.origin);
1735         setsize(self, spectatee.mins, spectatee.maxs);
1736         SetZoomState(spectatee.zoomstate);
1737
1738     anticheat_spectatecopy(spectatee);
1739         self.hud = spectatee.hud;
1740         if(spectatee.vehicle)
1741     {
1742         self.fixangle = FALSE;
1743         //self.velocity = spectatee.vehicle.velocity;
1744         self.vehicle_health = spectatee.vehicle_health;
1745         self.vehicle_shield = spectatee.vehicle_shield;
1746         self.vehicle_energy = spectatee.vehicle_energy;
1747         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1748         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1749         self.vehicle_reload1 = spectatee.vehicle_reload1;
1750         self.vehicle_reload2 = spectatee.vehicle_reload2;
1751
1752         msg_entity = self;
1753
1754         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1755             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1756             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1757             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1758
1759         //WriteByte (MSG_ONE, SVC_SETVIEW);
1760         //    WriteEntity(MSG_ONE, self);
1761         //makevectors(spectatee.v_angle);
1762         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1763     }
1764 }
1765
1766 float SpectateUpdate() {
1767         if(!self.enemy)
1768             return 0;
1769
1770         if (self == self.enemy)
1771                 return 0;
1772
1773         if not(IS_PLAYER(self.enemy))
1774                 return 0;
1775
1776         SpectateCopy(self.enemy);
1777
1778         return 1;
1779 }
1780
1781
1782 float SpectateSet()
1783 {
1784         if(self.enemy.classname != "player")
1785                 return FALSE;
1786         /*if(self.enemy.vehicle)
1787         {
1788
1789                 msg_entity = self;
1790                 WriteByte(MSG_ONE, SVC_SETVIEW);
1791                 WriteEntity(MSG_ONE, self.enemy);
1792                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1793
1794                 self.movetype = MOVETYPE_NONE;
1795                 accuracy_resend(self);
1796         }
1797         else
1798         {*/
1799                 msg_entity = self;
1800                 WriteByte(MSG_ONE, SVC_SETVIEW);
1801                 WriteEntity(MSG_ONE, self.enemy);
1802                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1803                 self.movetype = MOVETYPE_NONE;
1804                 accuracy_resend(self);
1805
1806                 if(!SpectateUpdate())
1807                         PutObserverInServer();
1808         //}
1809         return TRUE;
1810 }
1811
1812 float Spectate(entity pl)
1813 {
1814         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1815         if(pl.team != self.team)
1816                 return 0;
1817
1818         self.enemy = pl;
1819         return SpectateSet();
1820 }
1821
1822 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1823 entity CA_SpectateNext(entity start) {
1824         if (start.team == self.team) {
1825                 return start;
1826         }
1827
1828         other = start;
1829         // continue from current player
1830         while(other && other.team != self.team) {
1831                 other = find(other, classname, "player");
1832         }
1833
1834         if (!other) {
1835                 // restart from begining
1836                 other = find(other, classname, "player");
1837                 while(other && other.team != self.team) {
1838                         other = find(other, classname, "player");
1839                 }
1840         }
1841
1842         return other;
1843 }
1844
1845 float SpectateNext()
1846 {
1847         other = find(self.enemy, classname, "player");
1848
1849         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1850                 // CA and ca players when spectating enemies is forbidden
1851                 other = CA_SpectateNext(other);
1852         } else {
1853                 // other modes and ca spectators or spectating enemies is allowed
1854                 if (!other)
1855                         other = find(other, classname, "player");
1856         }
1857
1858         if (other)
1859                 self.enemy = other;
1860
1861         return SpectateSet();
1862 }
1863
1864 float SpectatePrev()
1865 {
1866         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1867         other = findchain(classname, "player");
1868         if not(other) // no player
1869                 return FALSE;
1870
1871         entity first = other;
1872         // skip players until current spectated player
1873         if(self.enemy)
1874         while(other && other != self.enemy)
1875                 other = other.chain;
1876
1877         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1878         {
1879                 do { other = other.chain; }
1880                 while(other && other.team != self.team);
1881
1882                 if not(other)
1883                 {
1884                         other = first;
1885                         while(other.team != self.team)
1886                                 other = other.chain;
1887                         if(other == self.enemy)
1888                                 return TRUE;
1889                 }
1890         }
1891         else
1892         {
1893                 if(other.chain)
1894                         other = other.chain;
1895                 else
1896                         other = first;
1897         }
1898         self.enemy = other;
1899         return SpectateSet();
1900 }
1901
1902 /*
1903 =============
1904 ShowRespawnCountdown()
1905
1906 Update a respawn countdown display.
1907 =============
1908 */
1909 void ShowRespawnCountdown()
1910 {
1911         float number;
1912         if(self.deadflag == DEAD_NO) // just respawned?
1913                 return;
1914         else
1915         {
1916                 number = ceil(self.respawn_time - time);
1917                 if(number <= 0)
1918                         return;
1919                 if(number <= self.respawn_countdown)
1920                 {
1921                         self.respawn_countdown = number - 1;
1922                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1923                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1924                 }
1925         }
1926 }
1927
1928 void LeaveSpectatorMode()
1929 {
1930         if(self.caplayer)
1931                 return;
1932         if(nJoinAllowed(self))
1933         {
1934                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1935                 {
1936                         self.classname = "player";
1937
1938                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1939                                 { JoinBestTeam(self, FALSE, TRUE); }
1940
1941                         if(autocvar_g_campaign)
1942                                 { campaign_bots_may_start = 1; }
1943
1944                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1945
1946                         PutClientInServer();
1947
1948                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1949                 }
1950                 else
1951                         stuffcmd(self, "menu_showteamselect\n");
1952         }
1953         else
1954         {
1955                 // Player may not join because g_maxplayers is set
1956                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1957         }
1958 }
1959
1960 /**
1961  * Determines whether the player is allowed to join. This depends on cvar
1962  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1963  * it checks whether the number of currently playing players exceeds g_maxplayers.
1964  * @return int number of free slots for players, 0 if none
1965  */
1966 float nJoinAllowed(entity ignore) {
1967         if(!ignore)
1968         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1969         // so report 0 free slots if restricted
1970         {
1971                 if(autocvar_g_forced_team_otherwise == "spectate")
1972                         return 0;
1973                 if(autocvar_g_forced_team_otherwise == "spectator")
1974                         return 0;
1975         }
1976
1977         if(self.team_forced < 0)
1978                 return 0; // forced spectators can never join
1979
1980         // TODO simplify this
1981         entity e;
1982         float totalClients = 0;
1983         FOR_EACH_CLIENT(e)
1984                 if(e != ignore)
1985                         totalClients += 1;
1986
1987         if (!autocvar_g_maxplayers)
1988                 return maxclients - totalClients;
1989
1990         float currentlyPlaying = 0;
1991         FOR_EACH_REALCLIENT(e)
1992                 if(IS_PLAYER(e) || e.caplayer == 1)
1993                         currentlyPlaying += 1;
1994
1995         if(currentlyPlaying < autocvar_g_maxplayers)
1996                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1997
1998         return 0;
1999 }
2000
2001 /**
2002  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2003  * g_maxplayers_spectator_blocktime seconds
2004  */
2005 void checkSpectatorBlock() {
2006         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2007                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2008                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2009                         dropclient(self);
2010                 }
2011         }
2012 }
2013
2014 void PrintWelcomeMessage()
2015 {
2016         if(self.motd_actived_time == 0)
2017         {
2018                 if (autocvar_g_campaign) {
2019                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2020                                 self.motd_actived_time = time;
2021                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2022                         }
2023                 } else {
2024                         if (self.BUTTON_INFO) {
2025                                 self.motd_actived_time = time;
2026                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2027                         }
2028                 }
2029         }
2030         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2031         {
2032                 if (autocvar_g_campaign) {
2033                         if (self.BUTTON_INFO)
2034                                 self.motd_actived_time = time;
2035                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2036                                 self.motd_actived_time = 0;
2037                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2038                         }
2039                 } else {
2040                         if (self.BUTTON_INFO)
2041                                 self.motd_actived_time = time;
2042                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2043                                 self.motd_actived_time = 0;
2044                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2045                         }
2046                 }
2047         }
2048         else //if(self.motd_actived_time < 0) // just connected, motd is active
2049         {
2050                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2051                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2052                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2053                 {
2054                         // instanctly hide MOTD
2055                         self.motd_actived_time = 0;
2056                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2057                 }
2058         }
2059 }
2060
2061 void ObserverThink()
2062 {
2063         float prefered_movetype;
2064         if (self.flags & FL_JUMPRELEASED) {
2065                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2066                         self.flags &= ~FL_JUMPRELEASED;
2067                         self.flags |= FL_SPAWNING;
2068                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2069                         self.flags &= ~FL_JUMPRELEASED;
2070                         if(SpectateNext()) {
2071                                 self.classname = "spectator";
2072                         }
2073                 } else {
2074                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2075                         if (self.movetype != prefered_movetype)
2076                                 self.movetype = prefered_movetype;
2077                 }
2078         } else {
2079                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2080                         self.flags |= FL_JUMPRELEASED;
2081                         if(self.flags & FL_SPAWNING)
2082                         {
2083                                 self.flags &= ~FL_SPAWNING;
2084                                 LeaveSpectatorMode();
2085                                 return;
2086                         }
2087                 }
2088         }
2089 }
2090
2091 void SpectatorThink()
2092 {
2093         if (self.flags & FL_JUMPRELEASED) {
2094                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2095                         self.flags &= ~FL_JUMPRELEASED;
2096                         self.flags |= FL_SPAWNING;
2097                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2098                         self.flags &= ~FL_JUMPRELEASED;
2099                         if(SpectateNext()) {
2100                                 self.classname = "spectator";
2101                         } else {
2102                                 self.classname = "observer";
2103                                 PutClientInServer();
2104                         }
2105                         self.impulse = 0;
2106                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2107                         self.flags &= ~FL_JUMPRELEASED;
2108                         if(SpectatePrev()) {
2109                                 self.classname = "spectator";
2110                         } else {
2111                                 self.classname = "observer";
2112                                 PutClientInServer();
2113                         }
2114                         self.impulse = 0;
2115                 } else if (self.BUTTON_ATCK2) {
2116                         self.flags &= ~FL_JUMPRELEASED;
2117                         self.classname = "observer";
2118                         PutClientInServer();
2119                 } else {
2120                         if(!SpectateUpdate())
2121                                 PutObserverInServer();
2122                 }
2123         } else {
2124                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2125                         self.flags |= FL_JUMPRELEASED;
2126                         if(self.flags & FL_SPAWNING)
2127                         {
2128                                 self.flags &= ~FL_SPAWNING;
2129                                 LeaveSpectatorMode();
2130                                 return;
2131                         }
2132                 }
2133                 if(!SpectateUpdate())
2134                         PutObserverInServer();
2135         }
2136
2137         self.flags |= FL_CLIENT | FL_NOTARGET;
2138 }
2139
2140 void vehicles_enter (entity pl, entity veh);
2141 void PlayerUseKey()
2142 {
2143         if not(IS_PLAYER(self))
2144                 return;
2145
2146         if(self.vehicle)
2147         {
2148         vehicles_exit(VHEF_NORMAL);
2149         return;
2150         }
2151         else if(autocvar_g_vehicles_enter)
2152         {
2153                 if not(self.freezetag_frozen)
2154                 if(self.deadflag == DEAD_NO)
2155                 {
2156                         entity head, closest_target = world;
2157                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2158
2159                         while(head) // find the closest acceptable target to enter
2160                         {
2161                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2162                                 if(head.deadflag == DEAD_NO)
2163                                 if not(head.owner)
2164                                 {
2165                                         if(closest_target)
2166                                         {
2167                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2168                                                 { closest_target = head; }
2169                                         }
2170                                         else { closest_target = head; }
2171                                 }
2172
2173                                 head = head.chain;
2174                         }
2175
2176                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2177                 }
2178         }
2179
2180         // a use key was pressed; call handlers
2181         MUTATOR_CALLHOOK(PlayerUseKey);
2182 }
2183
2184 /*
2185 =============
2186 PlayerPreThink
2187
2188 Called every frame for each client before the physics are run
2189 =============
2190 */
2191 .float usekeypressed;
2192 void() nexball_setstatus;
2193 .float items_added;
2194 .float last_vehiclecheck;
2195 void PlayerPreThink (void)
2196 {
2197         WarpZone_PlayerPhysics_FixVAngle();
2198
2199         self.stat_game_starttime = game_starttime;
2200         self.stat_round_starttime = round_starttime;
2201         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2202         self.stat_leadlimit = autocvar_leadlimit;
2203
2204         if(frametime)
2205         {
2206                 // physics frames: update anticheat stuff
2207                 anticheat_prethink();
2208         }
2209
2210         if(blockSpectators && frametime)
2211                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2212                 checkSpectatorBlock();
2213
2214         zoomstate_set = 0;
2215
2216         if(self.netname_previous != self.netname)
2217         {
2218                 if(autocvar_sv_eventlog)
2219                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2220                 if(self.netname_previous)
2221                         strunzone(self.netname_previous);
2222                 self.netname_previous = strzone(self.netname);
2223         }
2224
2225         // version nagging
2226         if(self.version_nagtime)
2227                 if(self.cvar_g_xonoticversion)
2228                         if(time > self.version_nagtime)
2229                         {
2230                                 // don't notify git users
2231                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2232                                 {
2233                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2234                                         {
2235                                                 // notify release users if connecting to git
2236                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2237                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2238                                         }
2239                                         else
2240                                         {
2241                                                 float r;
2242                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2243                                                 if(r < 0)
2244                                                 {
2245                                                         // give users new version
2246                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2247                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2248                                                 }
2249                                                 else if(r > 0)
2250                                                 {
2251                                                         // notify users about old server version
2252                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2253                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2254                                                 }
2255                                         }
2256                                 }
2257                                 self.version_nagtime = 0;
2258                         }
2259
2260         // GOD MODE info
2261         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2262         {
2263                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2264                 self.max_armorvalue = 0;
2265         }
2266
2267 #ifdef TETRIS
2268         if (TetrisPreFrame())
2269                 return;
2270 #endif
2271
2272         MUTATOR_CALLHOOK(PlayerPreThink);
2273
2274         if(autocvar_g_vehicles_enter)
2275         if(time > self.last_vehiclecheck)
2276         if(IS_PLAYER(self))
2277         if not(self.freezetag_frozen)
2278         if not(self.vehicle)
2279         if(self.deadflag == DEAD_NO)
2280         {
2281                 entity veh;
2282                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2283                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2284                 if(veh.deadflag == DEAD_NO)
2285                 if not(veh.owner)
2286                 if(!veh.team || SAME_TEAM(self, veh))
2287                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2288                 else if(autocvar_g_vehicles_steal)
2289                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2290
2291                 self.last_vehiclecheck = time + 1;
2292         }
2293
2294         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2295         {
2296                 if(self.BUTTON_USE && !self.usekeypressed)
2297                         PlayerUseKey();
2298                 self.usekeypressed = self.BUTTON_USE;
2299         }
2300
2301         if(IS_REAL_CLIENT(self))
2302                 PrintWelcomeMessage();
2303
2304         if(IS_PLAYER(self))
2305         {
2306
2307                 CheckRules_Player();
2308
2309                 if (intermission_running)
2310                 {
2311                         IntermissionThink ();   // otherwise a button could be missed between
2312                         return;                                 // the think tics
2313                 }
2314
2315                 //don't allow the player to turn around while game is paused!
2316                 if(timeout_status == TIMEOUT_ACTIVE) {
2317                         // FIXME turn this into CSQC stuff
2318                         self.v_angle = self.lastV_angle;
2319                         self.angles = self.lastV_angle;
2320                         self.fixangle = TRUE;
2321                 }
2322
2323                 if(frametime)
2324                 {
2325                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2326                         {
2327                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2328                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2329                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2330
2331                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2332                                 {
2333                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2334                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2335                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2336                                 }
2337                         }
2338                         else
2339                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2340
2341                         player_powerups();
2342                 }
2343
2344                 if (self.deadflag != DEAD_NO)
2345                 {
2346                         if(self.personal && g_race_qualifying)
2347                         {
2348                                 if(time > self.respawn_time)
2349                                 {
2350                                         self.respawn_time = time + 1; // only retry once a second
2351                                         self.stat_respawn_time = self.respawn_time;
2352                                         respawn();
2353                                         self.impulse = 141;
2354                                 }
2355                         }
2356                         else
2357                         {
2358                                 float button_pressed;
2359                                 if(frametime)
2360                                         player_anim();
2361                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2362
2363                                 if (self.deadflag == DEAD_DYING)
2364                                 {
2365                                         if(self.respawn_flags & RESPAWN_FORCE)
2366                                                 self.deadflag = DEAD_RESPAWNING;
2367                                         else if(!button_pressed)
2368                                                 self.deadflag = DEAD_DEAD;
2369                                 }
2370                                 else if (self.deadflag == DEAD_DEAD)
2371                                 {
2372                                         if(button_pressed)
2373                                                 self.deadflag = DEAD_RESPAWNABLE;
2374                                 }
2375                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2376                                 {
2377                                         if(!button_pressed)
2378                                                 self.deadflag = DEAD_RESPAWNING;
2379                                 }
2380                                 else if (self.deadflag == DEAD_RESPAWNING)
2381                                 {
2382                                         if(time > self.respawn_time)
2383                                         {
2384                                                 self.respawn_time = time + 1; // only retry once a second
2385                                                 respawn();
2386                                         }
2387                                 }
2388
2389                                 ShowRespawnCountdown();
2390
2391                                 if(self.respawn_flags & RESPAWN_SILENT)
2392                                         self.stat_respawn_time = 0;
2393                                 else
2394                                         self.stat_respawn_time = self.respawn_time;
2395                         }
2396
2397                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2398                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2399                                 self.stat_respawn_time *= -1;
2400
2401                         return;
2402                 }
2403
2404                 self.prevorigin = self.origin;
2405
2406                 float do_crouch = self.BUTTON_CROUCH;
2407                 if(self.hook.state)
2408                         do_crouch = 0;
2409                 if(self.vehicle)
2410                         do_crouch = 0;
2411                 if(self.freezetag_frozen)
2412                         do_crouch = 0;
2413                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2414                         do_crouch = 0;
2415
2416                 if (do_crouch)
2417                 {
2418                         if (!self.crouch)
2419                         {
2420                                 self.crouch = TRUE;
2421                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2422                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2423                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2424                         }
2425                 }
2426                 else
2427                 {
2428                         if (self.crouch)
2429                         {
2430                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2431                                 if (!trace_startsolid)
2432                                 {
2433                                         self.crouch = FALSE;
2434                                         self.view_ofs = PL_VIEW_OFS;
2435                                         setsize (self, PL_MIN, PL_MAX);
2436                                 }
2437                         }
2438                 }
2439
2440                 FixPlayermodel();
2441
2442                 GrapplingHookFrame();
2443
2444                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2445                 //if(frametime)
2446                 {
2447                         self.items &= ~self.items_added;
2448
2449                         W_WeaponFrame();
2450
2451                         self.items_added = 0;
2452                         if(self.items & IT_JETPACK)
2453                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2454                                         self.items_added |= IT_FUEL;
2455
2456                         self.items |= self.items_added;
2457                 }
2458
2459                 player_regen();
2460
2461                 // rot nex charge to the charge limit
2462                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2463                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2464
2465                 if(frametime)
2466                         player_anim();
2467
2468                 // secret status
2469                 secrets_setstatus();
2470
2471                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2472
2473                 //self.angles_y=self.v_angle_y + 90;   // temp
2474         } else if(gameover) {
2475                 if (intermission_running)
2476                         IntermissionThink ();   // otherwise a button could be missed between
2477                 return;
2478         } else if(IS_OBSERVER(self)) {
2479                 ObserverThink();
2480         } else if(IS_SPEC(self)) {
2481                 SpectatorThink();
2482         }
2483
2484         if(!zoomstate_set)
2485                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2486
2487         float oldspectatee_status;
2488         oldspectatee_status = self.spectatee_status;
2489         if(IS_SPEC(self))
2490                 self.spectatee_status = num_for_edict(self.enemy);
2491         else if(IS_OBSERVER(self))
2492                 self.spectatee_status = num_for_edict(self);
2493         else
2494                 self.spectatee_status = 0;
2495         if(self.spectatee_status != oldspectatee_status)
2496         {
2497                 ClientData_Touch(self);
2498                 if(g_race || g_cts)
2499                         race_InitSpectator();
2500         }
2501
2502         if(self.teamkill_soundtime)
2503         if(time > self.teamkill_soundtime)
2504         {
2505                 self.teamkill_soundtime = 0;
2506
2507                 entity oldpusher, oldself;
2508
2509                 oldself = self; self = self.teamkill_soundsource;
2510                 oldpusher = self.pusher; self.pusher = oldself;
2511
2512                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2513
2514                 self.pusher = oldpusher;
2515                 self = oldself;
2516         }
2517
2518         if(self.taunt_soundtime)
2519         if(time > self.taunt_soundtime)
2520         {
2521                 self.taunt_soundtime = 0;
2522                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2523         }
2524
2525         target_voicescript_next(self);
2526
2527         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2528         if(!self.weapon)
2529                 self.clip_load = self.clip_size = 0;
2530 }
2531
2532 float isInvisibleString(string s)
2533 {
2534         float i, n, c;
2535         s = strdecolorize(s);
2536         for((i = 0), (n = strlen(s)); i < n; ++i)
2537         {
2538                 c = str2chr(s, i);
2539                 switch(c)
2540                 {
2541                         case 0:
2542                         case 32: // space
2543                                 break;
2544                         case 192: // charmap space
2545                                 if (!autocvar_utf8_enable)
2546                                         break;
2547                                 return FALSE;
2548                         case 160: // space in unicode fonts
2549                         case 0xE000 + 192: // utf8 charmap space
2550                                 if (autocvar_utf8_enable)
2551                                         break;
2552                         default:
2553                                 return FALSE;
2554                 }
2555         }
2556         return TRUE;
2557 }
2558
2559 /*
2560 =============
2561 PlayerPostThink
2562
2563 Called every frame for each client after the physics are run
2564 =============
2565 */
2566 .float idlekick_lasttimeleft;
2567 void PlayerPostThink (void)
2568 {
2569         // Savage: Check for nameless players
2570         if (isInvisibleString(self.netname)) {
2571                 self.netname = "Player";
2572                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2573         }
2574
2575         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2576         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2577         {
2578                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2579                 {
2580                         if(self.idlekick_lasttimeleft)
2581                         {
2582                                 self.idlekick_lasttimeleft = 0;
2583                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2584                         }
2585                 }
2586                 else
2587                 {
2588                         float timeleft;
2589                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2590                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2591                         {
2592                                 if(!self.idlekick_lasttimeleft)
2593                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2594                         }
2595                         if(timeleft <= 0)
2596                         {
2597                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2598                                 dropclient(self);
2599                                 return;
2600                         }
2601                         else if(timeleft <= 10)
2602                         {
2603                                 if(timeleft != self.idlekick_lasttimeleft)
2604                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2605                                 self.idlekick_lasttimeleft = timeleft;
2606                         }
2607                 }
2608         }
2609
2610 #ifdef TETRIS
2611         if(self.impulse == 100)
2612                 ImpulseCommands();
2613         if (!TetrisPostFrame())
2614         {
2615 #endif
2616
2617         CheatFrame();
2618
2619         //CheckPlayerJump();
2620
2621         if(IS_PLAYER(self)) {
2622                 CheckRules_Player();
2623                 UpdateChatBubble();
2624                 if (self.impulse)
2625                         ImpulseCommands();
2626                 if (intermission_running)
2627                         return;         // intermission or finale
2628                 GetPressedKeys();
2629         }
2630
2631 #ifdef TETRIS
2632         }
2633 #endif
2634
2635         /*
2636         float i;
2637         for(i = 0; i < 1000; ++i)
2638         {
2639                 vector end;
2640                 end = self.origin + '0 0 1024' + 512 * randomvec();
2641                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2642                 if(trace_fraction < 1)
2643                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2644                 {
2645                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2646                         break;
2647                 }
2648         }
2649         */
2650
2651         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2652
2653         if(self.waypointsprite_attachedforcarrier)
2654                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2655
2656         playerdemo_write();
2657
2658         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2659         {
2660                 if not(self.stored_netname)
2661                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2662                 if(self.stored_netname != self.netname)
2663                 {
2664                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2665                         strunzone(self.stored_netname);
2666                         self.stored_netname = strzone(self.netname);
2667                 }
2668         }
2669
2670         /*
2671         if(g_race)
2672                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2673         */
2674
2675         CSQCMODEL_AUTOUPDATE();
2676 }