qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         spot = SelectSpawnPoint (TRUE);
 142         if(!spot)
 143                 error("No spawnpoints for observers?!?\n");
 144         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 145
 146         if(IS_REAL_CLIENT(self))
 147         {
 148                 msg_entity = self;
 149                 WriteByte(MSG_ONE, SVC_SETVIEW);
 150                 WriteEntity(MSG_ONE, self);
 151         }
 152
 153         self.frags = FRAGS_SPECTATOR;
 154
 155         MUTATOR_CALLHOOK(MakePlayerObserver);
 156
 157         Portal_ClearAll(self);
 158
 159         Unfreeze(self);
 160
 161         if(self.alivetime)
 162         {
 163                 if(!warmup_stage)
 164                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 165                 self.alivetime = 0;
 166         }
 167
 168         if(self.vehicle)
 169                 vehicles_exit(VHEF_RELEASE);
 170
 171         WaypointSprite_PlayerDead();
 172
 173         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 174                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 175
 176         if(self.killcount != -666)
 177         {
 178                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 179                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 180                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 181
 182                 if(self.just_joined == FALSE) {
 183                         LogTeamchange(self.playerid, -1, 4);
 184                 } else
 185                         self.just_joined = FALSE;
 186         }
 187
 188         PlayerScore_Clear(self); // clear scores when needed
 189
 190         accuracy_resend(self);
 191
 192         self.spectatortime = time;
 193
 194         self.classname = "observer";
 195         self.iscreature = FALSE;
 196         self.teleportable = TELEPORT_SIMPLE;
 197         self.damagedbycontents = FALSE;
 198         self.health = -666;
 199         self.takedamage = DAMAGE_NO;
 200         self.solid = SOLID_NOT;
 201         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 202         self.flags = FL_CLIENT | FL_NOTARGET;
 203         self.armorvalue = 666;
 204         self.effects = 0;
 205         self.armorvalue = autocvar_g_balance_armor_start;
 206         self.pauserotarmor_finished = 0;
 207         self.pauserothealth_finished = 0;
 208         self.pauseregen_finished = 0;
 209         self.damageforcescale = 0;
 210         self.death_time = 0;
 211         self.respawn_flags = 0;
 212         self.respawn_time = 0;
 213         self.stat_respawn_time = 0;
 214         self.alpha = 0;
 215         self.scale = 0;
 216         self.fade_time = 0;
 217         self.pain_frame = 0;
 218         self.pain_finished = 0;
 219         self.strength_finished = 0;
 220         self.invincible_finished = 0;
 221         self.superweapons_finished = 0;
 222         self.pushltime = 0;
 223         self.istypefrag = 0;
 224         self.think = func_null;
 225         self.nextthink = 0;
 226         self.hook_time = 0;
 227         self.deadflag = DEAD_NO;
 228         self.angles = spot.angles;
 229         self.angles_z = 0;
 230         self.fixangle = TRUE;
 231         self.crouch = FALSE;
 232         self.revival_time = 0;
 233
 234         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 235         self.prevorigin = self.origin;
 236         self.items = 0;
 237         self.weapons = '0 0 0';
 238         self.model = "";
 239         FixPlayermodel();
 240         setmodel(self, "null");
 241         self.drawonlytoclient = self;
 242
 243         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 244         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 245
 246         self.weapon = 0;
 247         self.weaponname = "";
 248         self.switchingweapon = 0;
 249         self.weaponmodel = "";
 250         self.weaponentity = world;
 251         self.exteriorweaponentity = world;
 252         self.killcount = -666;
 253         self.velocity = '0 0 0';
 254         self.avelocity = '0 0 0';
 255         self.punchangle = '0 0 0';
 256         self.punchvector = '0 0 0';
 257         self.oldvelocity = self.velocity;
 258         self.fire_endtime = -1;
 259 }
 260
 261 .float model_randomizer;
 262 void FixPlayermodel()
 263 {
 264         string defaultmodel;
 265         float defaultskin, chmdl, oldskin, n, i;
 266         vector m1, m2;
 267
 268         defaultmodel = "";
 269         defaultskin = 0;
 270         chmdl = FALSE;
 271
 272         if(autocvar_sv_defaultcharacter == 1)
 273         {
 274                 if(teamplay)
 275                 {
 276                         string s;
 277                         s = Static_Team_ColorName_Lower(self.team);
 278                         if(s != "neutral")
 279                         {
 280                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 281                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 282                         }
 283                 }
 284
 285                 if(defaultmodel == "")
 286                 {
 287                         defaultmodel = autocvar_sv_defaultplayermodel;
 288                         defaultskin = autocvar_sv_defaultplayerskin;
 289                 }
 290
 291                 n = tokenize_console(defaultmodel);
 292                 if(n > 0)
 293                 {
 294                         defaultmodel = argv(floor(n * self.model_randomizer));
 295                         // However, do NOT randomize if the player-selected model is in the list.
 296                         for (i = 0; i < n; ++i)
 297                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 298                                         defaultmodel = argv(i);
 299                 }
 300
 301                 i = strstrofs(defaultmodel, ":", 0);
 302                 if(i >= 0)
 303                 {
 304                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 305                         defaultmodel = substring(defaultmodel, 0, i);
 306                 }
 307         }
 308
 309         if(defaultmodel != "")
 310         {
 311                 if (defaultmodel != self.model)
 312                 {
 313                         m1 = self.mins;
 314                         m2 = self.maxs;
 315                         setplayermodel (self, defaultmodel);
 316                         setsize (self, m1, m2);
 317                         chmdl = TRUE;
 318                 }
 319
 320                 oldskin = self.skin;
 321                 self.skin = defaultskin;
 322         } else {
 323                 if (self.playermodel != self.model || self.playermodel == "")
 324                 {
 325                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 326                         m1 = self.mins;
 327                         m2 = self.maxs;
 328                         setplayermodel (self, self.playermodel);
 329                         setsize (self, m1, m2);
 330                         chmdl = TRUE;
 331                 }
 332
 333                 oldskin = self.skin;
 334                 self.skin = stof(self.playerskin);
 335         }
 336
 337         if(chmdl || oldskin != self.skin) // model or skin has changed
 338         {
 339                 self.species = player_getspecies(); // update species
 340                 UpdatePlayerSounds(); // update skin sounds
 341         }
 342
 343         if(!teamplay)
 344                 if(strlen(autocvar_sv_defaultplayercolors))
 345                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 346                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 347 }
 348
 349 /*
 350 =============
 351 PutClientInServer
 352
 353 Called when a client spawns in the server
 354 =============
 355 */
 356 void PutClientInServer (void)
 357 {
 358         if(IS_BOT_CLIENT(self))
 359                 self.classname = "player";
 360         else if(IS_REAL_CLIENT(self))
 361         {
 362                 msg_entity = self;
 363                 WriteByte(MSG_ONE, SVC_SETVIEW);
 364                 WriteEntity(MSG_ONE, self);
 365         }
 366
 367         // reset player keys
 368         self.itemkeys = 0;
 369
 370         MUTATOR_CALLHOOK(PutClientInServer);
 371
 372         if(gameover)
 373                 self.classname = "observer";
 374
 375         if(IS_PLAYER(self))
 376         {
 377                 entity spot, oldself;
 378                 float j;
 379
 380                 accuracy_resend(self);
 381
 382                 if(self.team < 0)
 383                         JoinBestTeam(self, FALSE, TRUE);
 384
 385                 spot = SelectSpawnPoint (FALSE);
 386                 if(!spot)
 387                 {
 388                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 389                         return; // spawn failed
 390                 }
 391
 392                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394                 self.classname = "player";
 395                 self.wasplayer = TRUE;
 396                 self.iscreature = TRUE;
 397                 self.teleportable = TELEPORT_NORMAL;
 398                 self.damagedbycontents = TRUE;
 399                 self.movetype = MOVETYPE_WALK;
 400                 self.solid = SOLID_SLIDEBOX;
 401                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 402                 if(autocvar_g_playerclip_collisions)
 403                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 404                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 405                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 406                 self.frags = FRAGS_PLAYER;
 407                 if(INDEPENDENT_PLAYERS)
 408                         MAKE_INDEPENDENT_PLAYER(self);
 409                 self.flags = FL_CLIENT;
 410                 if(autocvar__notarget)
 411                         self.flags |= FL_NOTARGET;
 412                 self.takedamage = DAMAGE_AIM;
 413                 self.effects = 0;
 414                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 415                 self.air_finished = time + 12;
 416                 self.dmg = 2;
 417                 if(autocvar_g_balance_nex_charge)
 418                 {
 419                         if(autocvar_g_balance_nex_secondary_chargepool)
 420                                 self.nex_chargepool_ammo = 1;
 421                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 422                 }
 423
 424                 if(warmup_stage)
 425                 {
 426                         self.ammo_shells = warmup_start_ammo_shells;
 427                         self.ammo_nails = warmup_start_ammo_nails;
 428                         self.ammo_rockets = warmup_start_ammo_rockets;
 429                         self.ammo_cells = warmup_start_ammo_cells;
 430                         self.ammo_fuel = warmup_start_ammo_fuel;
 431                         self.health = warmup_start_health;
 432                         self.armorvalue = warmup_start_armorvalue;
 433                         self.weapons = WARMUP_START_WEAPONS;
 434                 }
 435                 else
 436                 {
 437                         self.ammo_shells = start_ammo_shells;
 438                         self.ammo_nails = start_ammo_nails;
 439                         self.ammo_rockets = start_ammo_rockets;
 440                         self.ammo_cells = start_ammo_cells;
 441                         self.ammo_fuel = start_ammo_fuel;
 442                         self.health = start_health;
 443                         self.armorvalue = start_armorvalue;
 444                         self.weapons = start_weapons;
 445                 }
 446
 447                 if(self.weapons & WEPSET_SUPERWEAPONS)
 448                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 449                 else
 450                         self.superweapons_finished = 0;
 451
 452                 if(g_weaponarena_random)
 453                 {
 454                         if(g_weaponarena_random_with_laser)
 455                                 self.weapons &= ~WEPSET_LASER;
 456                         W_RandomWeapons(self, g_weaponarena_random);
 457                         if(g_weaponarena_random_with_laser)
 458                                 self.weapons |= WEPSET_LASER;
 459                 }
 460
 461                 self.items = start_items;
 462
 463                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 464                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 465                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 466                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 467                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 468                 //extend the pause of rotting if client was reset at the beginning of the countdown
 469                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 470                         self.spawnshieldtime += game_starttime - time;
 471                         self.pauserotarmor_finished += game_starttime - time;
 472                         self.pauserothealth_finished += game_starttime - time;
 473                         self.pauseregen_finished += game_starttime - time;
 474                 }
 475                 self.damageforcescale = 2;
 476                 self.death_time = 0;
 477                 self.respawn_flags = 0;
 478                 self.respawn_time = 0;
 479                 self.stat_respawn_time = 0;
 480                 self.scale = 0;
 481                 self.fade_time = 0;
 482                 self.pain_frame = 0;
 483                 self.pain_finished = 0;
 484                 self.strength_finished = 0;
 485                 self.invincible_finished = 0;
 486                 self.pushltime = 0;
 487                 // players have no think function
 488                 self.think = func_null;
 489                 self.nextthink = 0;
 490                 self.hook_time = 0;
 491                 self.dmg_team = 0;
 492                 self.ballistics_density = autocvar_g_ballistics_density_player;
 493
 494                 self.metertime = 0;
 495
 496                 self.deadflag = DEAD_NO;
 497
 498                 self.angles = spot.angles;
 499
 500                 self.angles_z = 0; // never spawn tilted even if the spot says to
 501                 self.fixangle = TRUE; // turn this way immediately
 502                 self.velocity = '0 0 0';
 503                 self.avelocity = '0 0 0';
 504                 self.punchangle = '0 0 0';
 505                 self.punchvector = '0 0 0';
 506                 self.oldvelocity = self.velocity;
 507                 self.fire_endtime = -1;
 508                 self.revival_time = 0;
 509
 510                 entity spawnevent = spawn();
 511                 spawnevent.owner = self;
 512                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 513
 514                 // Cut off any still running player sounds.
 515                 stopsound(self, CH_PLAYER_SINGLE);
 516
 517                 self.model = "";
 518                 FixPlayermodel();
 519                 self.drawonlytoclient = world;
 520
 521                 self.crouch = FALSE;
 522                 self.view_ofs = PL_VIEW_OFS;
 523                 setsize (self, PL_MIN, PL_MAX);
 524                 self.spawnorigin = spot.origin;
 525                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 526                 // don't reset back to last position, even if new position is stuck in solid
 527                 self.oldorigin = self.origin;
 528                 self.prevorigin = self.origin;
 529                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 530                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 531         self.hud = HUD_NORMAL;
 532
 533                 self.event_damage = PlayerDamage;
 534
 535                 self.bot_attack = TRUE;
 536                 self.monster_attack = TRUE;
 537
 538                 self.spider_slowness = 0;
 539
 540                 self.statdraintime = time + 5;
 541                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 542
 543                 if(self.killcount == -666) {
 544                         PlayerScore_Clear(self);
 545                         self.killcount = 0;
 546                 }
 547
 548                 CL_SpawnWeaponentity();
 549                 self.alpha = default_player_alpha;
 550                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 551                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 552
 553                 self.speedrunning = FALSE;
 554
 555                 //stuffcmd(self, "chase_active 0");
 556                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 557
 558                 target_voicescript_clear(self);
 559
 560                 // reset fields the weapons may use
 561                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 562                 {
 563                         weapon_action(j, WR_RESETPLAYER);
 564
 565                         // all weapons must be fully loaded when we spawn
 566                         entity e;
 567                         e = get_weaponinfo(j);
 568                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 569                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 570                 }
 571
 572                 oldself = self;
 573                 self = spot;
 574                         activator = oldself;
 575                                 string s;
 576                                 s = self.target;
 577                                 self.target = string_null;
 578                                 SUB_UseTargets();
 579                                 self.target = s;
 580                         activator = world;
 581                 self = oldself;
 582
 583                 Unfreeze(self);
 584
 585                 spawn_spot = spot;
 586                 MUTATOR_CALLHOOK(PlayerSpawn);
 587
 588                 if(autocvar_spawn_debug)
 589                 {
 590                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 591                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 592                 }
 593
 594                 self.switchweapon = w_getbestweapon(self);
 595                 self.cnt = -1; // W_LastWeapon will not complain
 596                 self.weapon = 0;
 597                 self.weaponname = "";
 598                 self.switchingweapon = 0;
 599
 600                 if(!warmup_stage)
 601                         if(!self.alivetime)
 602                                 self.alivetime = time;
 603
 604                 antilag_clear(self);
 605         }
 606         else if(IS_OBSERVER(self))
 607         {
 608                 PutObserverInServer ();
 609         }
 610 }
 611
 612 .float ebouncefactor, ebouncestop; // electro's values
 613 // TODO do we need all these fields, or should we stop autodetecting runtime
 614 // changes and just have a console command to update this?
 615 float ClientInit_SendEntity(entity to, float sf)
 616 {
 617         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 618         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 631         if(sv_foginterval && world.fog != "")
 632                 WriteString(MSG_ENTITY, world.fog);
 633         else
 634                 WriteString(MSG_ENTITY, "");
 635         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 636         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 637         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 638         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 639         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 641         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 642         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 644         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 645         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 647         return TRUE;
 648 }
 649
 650 void ClientInit_CheckUpdate()
 651 {
 652         self.nextthink = time;
 653         if(self.count != autocvar_g_balance_armor_blockpercent)
 654         {
 655                 self.count = autocvar_g_balance_armor_blockpercent;
 656                 self.SendFlags |= 1;
 657         }
 658         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 659         {
 660                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 661                 self.SendFlags |= 1;
 662         }
 663         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 664         {
 665                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 669         {
 670                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 674         {
 675                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 676                 self.SendFlags |= 1;
 677         }
 678 }
 679
 680 void ClientInit_Spawn()
 681 {
 682         entity o;
 683         entity e;
 684         e = spawn();
 685         e.classname = "clientinit";
 686         e.think = ClientInit_CheckUpdate;
 687         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 688
 689         o = self;
 690         self = e;
 691         ClientInit_CheckUpdate();
 692         self = o;
 693 }
 694
 695 /*
 696 =============
 697 SetNewParms
 698 =============
 699 */
 700 void SetNewParms (void)
 701 {
 702         // initialize parms for a new player
 703         parm1 = -(86400 * 366);
 704 }
 705
 706 /*
 707 =============
 708 SetChangeParms
 709 =============
 710 */
 711 void SetChangeParms (void)
 712 {
 713         // save parms for level change
 714         parm1 = self.parm_idlesince - time;
 715 }
 716
 717 /*
 718 =============
 719 DecodeLevelParms
 720 =============
 721 */
 722 void DecodeLevelParms (void)
 723 {
 724         // load parms
 725         self.parm_idlesince = parm1;
 726         if(self.parm_idlesince == -(86400 * 366))
 727                 self.parm_idlesince = time;
 728
 729         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 730         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 731 }
 732
 733 /*
 734 =============
 735 ClientKill
 736
 737 Called when a client types 'kill' in the console
 738 =============
 739 */
 740
 741 .float clientkill_nexttime;
 742 void ClientKill_Now_TeamChange()
 743 {
 744         if(self.killindicator_teamchange == -1)
 745         {
 746                 JoinBestTeam( self, FALSE, TRUE );
 747         }
 748         else if(self.killindicator_teamchange == -2)
 749         {
 750                 if(blockSpectators)
 751                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 752                 PutObserverInServer();
 753         }
 754         else
 755                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 756         self.killindicator_teamchange = 0;
 757 }
 758
 759 void ClientKill_Now()
 760 {
 761         if(self.vehicle)
 762         {
 763             vehicles_exit(VHEF_RELEASE);
 764             if(!self.killindicator_teamchange)
 765             {
 766             self.vehicle_health = -1;
 767             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 768             }
 769         }
 770
 771         if(self.killindicator && !wasfreed(self.killindicator))
 772                 remove(self.killindicator);
 773
 774         self.killindicator = world;
 775
 776         if(self.killindicator_teamchange)
 777                 ClientKill_Now_TeamChange();
 778
 779         // in any case:
 780         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 781
 782         // now I am sure the player IS dead
 783 }
 784 void KillIndicator_Think()
 785 {
 786         if (gameover)
 787         {
 788                 self.owner.killindicator = world;
 789                 remove(self);
 790                 return;
 791         }
 792
 793         if (self.owner.alpha < 0 && !self.owner.vehicle)
 794         {
 795                 self.owner.killindicator = world;
 796                 remove(self);
 797                 return;
 798         }
 799
 800         if(self.cnt <= 0)
 801         {
 802                 self = self.owner;
 803                 ClientKill_Now(); // no oldself needed
 804                 return;
 805         }
 806     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 807     {
 808         self.nextthink = time + 1;
 809         self.cnt -= 1;
 810     }
 811         else
 812         {
 813                 if(self.cnt <= 10)
 814                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 815                 if(IS_REAL_CLIENT(self.owner))
 816                 {
 817                         if(self.cnt <= 10)
 818                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 819                 }
 820                 self.nextthink = time + 1;
 821                 self.cnt -= 1;
 822         }
 823 }
 824
 825 float clientkilltime;
 826 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 827 {
 828         float killtime;
 829         float starttime;
 830         entity e;
 831
 832         if (gameover)
 833                 return;
 834
 835         killtime = autocvar_g_balance_kill_delay;
 836
 837         if(g_race_qualifying || g_cts)
 838                 killtime = 0;
 839
 840     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 841     {
 842                 remove(self.killindicator);
 843                 self.killindicator = world;
 844
 845         ClientKill_Now(); // allow instant kill in this case
 846         return;
 847     }
 848
 849         self.killindicator_teamchange = targetteam;
 850
 851     if(!self.killindicator)
 852         {
 853                 if(self.deadflag == DEAD_NO)
 854                 {
 855                         killtime = max(killtime, self.clientkill_nexttime - time);
 856                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 857                 }
 858
 859                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 860                 {
 861                         ClientKill_Now();
 862                 }
 863                 else
 864                 {
 865                         starttime = max(time, clientkilltime);
 866
 867                         self.killindicator = spawn();
 868                         self.killindicator.owner = self;
 869                         self.killindicator.scale = 0.5;
 870                         setattachment(self.killindicator, self, "");
 871                         setorigin(self.killindicator, '0 0 52');
 872                         self.killindicator.think = KillIndicator_Think;
 873                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 874                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 875                         self.killindicator.cnt = ceil(killtime);
 876                         self.killindicator.count = bound(0, ceil(killtime), 10);
 877                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 878
 879                         for(e = world; (e = find(e, classname, "body")) != world; )
 880                         {
 881                                 if(e.enemy != self)
 882                                         continue;
 883                                 e.killindicator = spawn();
 884                                 e.killindicator.owner = e;
 885                                 e.killindicator.scale = 0.5;
 886                                 setattachment(e.killindicator, e, "");
 887                                 setorigin(e.killindicator, '0 0 52');
 888                                 e.killindicator.think = KillIndicator_Think;
 889                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 890                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 891                                 e.killindicator.cnt = ceil(killtime);
 892                         }
 893                         self.lip = 0;
 894                 }
 895         }
 896         if(self.killindicator)
 897         {
 898                 if(targetteam == 0) // just die
 899                 {
 900                         self.killindicator.colormod = '0 0 0';
 901                         if(IS_REAL_CLIENT(self))
 902                         if(self.killindicator.cnt > 0)
 903                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 904                 }
 905                 else if(targetteam == -1) // auto
 906                 {
 907                         self.killindicator.colormod = '0 1 0';
 908                         if(IS_REAL_CLIENT(self))
 909                         if(self.killindicator.cnt > 0)
 910                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 911                 }
 912                 else if(targetteam == -2) // spectate
 913                 {
 914                         self.killindicator.colormod = '0.5 0.5 0.5';
 915                         if(IS_REAL_CLIENT(self))
 916                         if(self.killindicator.cnt > 0)
 917                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 918                 }
 919                 else
 920                 {
 921                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 922                         if(IS_REAL_CLIENT(self))
 923                         if(self.killindicator.cnt > 0)
 924                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 925                 }
 926         }
 927
 928 }
 929
 930 void ClientKill (void)
 931 {
 932         if(gameover) return;
 933         if(self.player_blocked) return;
 934         if(self.frozen) return;
 935
 936         ClientKill_TeamChange(0);
 937 }
 938
 939 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 940 {
 941     e.killindicator = spawn();
 942     e.killindicator.owner = e;
 943     e.killindicator.think = KillIndicator_Think;
 944     e.killindicator.nextthink = time + (e.lip) * 0.05;
 945     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 946     e.killindicator.health = 1; // this is used to indicate that it should be silent
 947     e.lip = 0;
 948 }
 949
 950 void FixClientCvars(entity e)
 951 {
 952         // send prediction settings to the client
 953         stuffcmd(e, "\nin_bindmap 0 0\n");
 954         if(g_race || g_cts)
 955                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 956         if(autocvar_g_antilag == 3) // client side hitscan
 957                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 958         if(autocvar_sv_gentle)
 959                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 960         /*
 961          * we no longer need to stuff this. Remove this comment block if you feel
 962          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 963         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 964         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 965         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 966         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 967         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 968         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 969         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 970         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 971         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 972         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 973         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 975         stuffcmd(e, "cl_movement_edgefriction 1\n");
 976          */
 977 }
 978
 979 float PlayerInIDList(entity p, string idlist)
 980 {
 981         float n, i;
 982         string s;
 983
 984         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 985         if (!p.crypto_idfp)
 986                 return 0;
 987
 988         // this function allows abbreviated player IDs too!
 989         n = tokenize_console(idlist);
 990         for(i = 0; i < n; ++i)
 991         {
 992                 s = argv(i);
 993                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 994                         return 1;
 995         }
 996
 997         return 0;
 998 }
 999
1000 /*
1001 =============
1002 ClientConnect
1003
1004 Called when a client connects to the server
1005 =============
1006 */
1007 void DecodeLevelParms (void);
1008 //void dom_player_join_team(entity pl);
1009 void set_dom_state(entity e);
1010 void ClientConnect (void)
1011 {
1012         float t;
1013
1014         if(IS_CLIENT(self))
1015         {
1016                 print("Warning: ClientConnect, but already connected!\n");
1017                 return;
1018         }
1019
1020         if(Ban_MaybeEnforceBanOnce(self))
1021                 return;
1022
1023         DecodeLevelParms();
1024
1025 #ifdef WATERMARK
1026         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1027 #endif
1028
1029         self.classname = "player_joining";
1030
1031         self.flags = FL_CLIENT;
1032         self.version_nagtime = time + 10 + random() * 10;
1033
1034         if(player_count<0)
1035         {
1036                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1037                 player_count = 0;
1038         }
1039
1040         PlayerScore_Attach(self);
1041         ClientData_Attach();
1042         accuracy_init(self);
1043
1044         bot_clientconnect();
1045
1046         playerdemo_init();
1047
1048         anticheat_init();
1049
1050         // identify the right forced team
1051         if(autocvar_g_campaign)
1052         {
1053                 if(IS_REAL_CLIENT(self)) // only players, not bots
1054                 {
1055                         switch(autocvar_g_campaign_forceteam)
1056                         {
1057                                 case 1: self.team_forced = NUM_TEAM_1; break;
1058                                 case 2: self.team_forced = NUM_TEAM_2; break;
1059                                 case 3: self.team_forced = NUM_TEAM_3; break;
1060                                 case 4: self.team_forced = NUM_TEAM_4; break;
1061                                 default: self.team_forced = 0;
1062                         }
1063                 }
1064         }
1065         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1066                 self.team_forced = NUM_TEAM_1;
1067         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1068                 self.team_forced = NUM_TEAM_2;
1069         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1070                 self.team_forced = NUM_TEAM_3;
1071         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1072                 self.team_forced = NUM_TEAM_4;
1073         else if(autocvar_g_forced_team_otherwise == "red")
1074                 self.team_forced = NUM_TEAM_1;
1075         else if(autocvar_g_forced_team_otherwise == "blue")
1076                 self.team_forced = NUM_TEAM_2;
1077         else if(autocvar_g_forced_team_otherwise == "yellow")
1078                 self.team_forced = NUM_TEAM_3;
1079         else if(autocvar_g_forced_team_otherwise == "pink")
1080                 self.team_forced = NUM_TEAM_4;
1081         else if(autocvar_g_forced_team_otherwise == "spectate")
1082                 self.team_forced = -1;
1083         else if(autocvar_g_forced_team_otherwise == "spectator")
1084                 self.team_forced = -1;
1085         else
1086                 self.team_forced = 0;
1087
1088         if(!teamplay)
1089                 if(self.team_forced > 0)
1090                         self.team_forced = 0;
1091
1092         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1093
1094         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1095                 self.classname = "observer";
1096         } else {
1097                 if(teamplay)
1098                 {
1099                         if(autocvar_g_balance_teams)
1100                         {
1101                                 self.classname = "player";
1102                                 campaign_bots_may_start = 1;
1103                         }
1104                         else
1105                         {
1106                                 self.classname = "observer"; // do it anyway
1107                         }
1108                 }
1109                 else
1110                 {
1111                         self.classname = "player";
1112                         campaign_bots_may_start = 1;
1113                 }
1114         }
1115
1116         self.playerid = (playerid_last = playerid_last + 1);
1117
1118         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1119
1120     if(IS_BOT_CLIENT(self))
1121         PlayerStats_AddPlayer(self);
1122
1123         if(autocvar_sv_eventlog)
1124                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1125
1126         LogTeamchange(self.playerid, self.team, 1);
1127
1128         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1129
1130         self.netname_previous = strzone(self.netname);
1131
1132         if(IS_PLAYER(self) && teamplay)
1133                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1134         else
1135                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1136
1137         stuffcmd(self, strcat(clientstuff, "\n"));
1138         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1139
1140         FixClientCvars(self);
1141
1142         // spawnfunc_waypoint sprites
1143         WaypointSprite_InitClient(self);
1144
1145         // Wazat's grappling hook
1146         SetGrappleHookBindings();
1147
1148         // get version info from player
1149         stuffcmd(self, "cmd clientversion $gameversion\n");
1150
1151         // get other cvars from player
1152         GetCvars(0);
1153
1154         // notify about available teams
1155         if(teamplay)
1156         {
1157                 CheckAllowedTeams(self);
1158                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1159                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1160         }
1161         else
1162                 stuffcmd(self, "set _teams_available 0\n");
1163
1164         attach_entcs();
1165
1166         bot_relinkplayerlist();
1167
1168         self.spectatortime = time;
1169         if(blockSpectators)
1170         {
1171                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1172         }
1173
1174         self.jointime = time;
1175         self.allowed_timeouts = autocvar_sv_timeout_number;
1176
1177         if(IS_REAL_CLIENT(self))
1178         {
1179                 if(!autocvar_g_campaign)
1180                 {
1181                         self.motd_actived_time = -1;
1182                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1183                 }
1184
1185                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1186                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1187         }
1188
1189         if(!sv_foginterval && world.fog != "")
1190                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1191
1192         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1193         {
1194                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1195                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1196         }
1197         else
1198                 self.hitplotfh = -1;
1199
1200         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1201                 send_CSQC_teamnagger();
1202
1203         CheatInitClient();
1204
1205         CSQCMODEL_AUTOINIT();
1206
1207         self.model_randomizer = random();
1208
1209         if(IS_REAL_CLIENT(self))
1210                 sv_notice_join();
1211
1212         MUTATOR_CALLHOOK(ClientConnect);
1213 }
1214 /*
1215 =============
1216 ClientDisconnect
1217
1218 Called when a client disconnects from the server
1219 =============
1220 */
1221 .entity chatbubbleentity;
1222 void ReadyCount();
1223 void ClientDisconnect (void)
1224 {
1225         if(self.vehicle)
1226             vehicles_exit(VHEF_RELEASE);
1227
1228         if (!IS_CLIENT(self))
1229         {
1230                 print("Warning: ClientDisconnect without ClientConnect\n");
1231                 return;
1232         }
1233
1234         PlayerStats_AddGlobalInfo(self);
1235
1236         CheatShutdownClient();
1237
1238         if(self.hitplotfh >= 0)
1239         {
1240                 fclose(self.hitplotfh);
1241                 self.hitplotfh = -1;
1242         }
1243
1244         anticheat_report();
1245         anticheat_shutdown();
1246
1247         playerdemo_shutdown();
1248
1249         bot_clientdisconnect();
1250
1251         if(self.entcs)
1252                 detach_entcs();
1253
1254         if(autocvar_sv_eventlog)
1255                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1256
1257         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1258
1259         MUTATOR_CALLHOOK(ClientDisconnect);
1260
1261         Portal_ClearAll(self);
1262
1263         Unfreeze(self);
1264
1265         RemoveGrapplingHook(self);
1266
1267         // Here, everything has been done that requires this player to be a client.
1268
1269         self.flags &= ~FL_CLIENT;
1270
1271         if (self.chatbubbleentity)
1272                 remove (self.chatbubbleentity);
1273
1274         if (self.killindicator)
1275                 remove (self.killindicator);
1276
1277         WaypointSprite_PlayerGone();
1278
1279         bot_relinkplayerlist();
1280
1281         accuracy_free(self);
1282         ClientData_Detach();
1283         PlayerScore_Detach(self);
1284
1285         if(self.netname_previous)
1286                 strunzone(self.netname_previous);
1287         if(self.clientstatus)
1288                 strunzone(self.clientstatus);
1289         if(self.weaponorder_byimpulse)
1290                 strunzone(self.weaponorder_byimpulse);
1291
1292         ClearPlayerSounds();
1293
1294         if(self.personal)
1295                 remove(self.personal);
1296
1297         self.playerid = 0;
1298         ReadyCount();
1299
1300         // free cvars
1301         GetCvars(-1);
1302 }
1303
1304 .float BUTTON_CHAT;
1305 void ChatBubbleThink()
1306 {
1307         self.nextthink = time;
1308         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1309         {
1310                 if(self.owner) // but why can that ever be world?
1311                         self.owner.chatbubbleentity = world;
1312                 remove(self);
1313                 return;
1314         }
1315         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1316 #ifdef TETRIS
1317                 || self.owner.tetris_on
1318 #endif
1319         )
1320                 self.model = self.mdl;
1321         else
1322                 self.model = "";
1323 }
1324
1325 void UpdateChatBubble()
1326 {
1327         if (self.alpha < 0)
1328                 return;
1329         // spawn a chatbubble entity if needed
1330         if (!self.chatbubbleentity)
1331         {
1332                 self.chatbubbleentity = spawn();
1333                 self.chatbubbleentity.owner = self;
1334                 self.chatbubbleentity.exteriormodeltoclient = self;
1335                 self.chatbubbleentity.think = ChatBubbleThink;
1336                 self.chatbubbleentity.nextthink = time;
1337                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1338                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1339                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1340                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1341                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1342                 self.chatbubbleentity.model = "";
1343                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1344         }
1345 }
1346
1347
1348 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1349 // added to the model skins
1350 /*void UpdateColorModHack()
1351 {
1352         float c;
1353         c = self.clientcolors & 15;
1354         // LordHavoc: only bothering to support white, green, red, yellow, blue
1355              if (!teamplay) self.colormod = '0 0 0';
1356         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1357         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1358         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1359         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1360         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1361         else self.colormod = '1 1 1';
1362 }*/
1363
1364 void respawn(void)
1365 {
1366         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1367         {
1368                 self.solid = SOLID_NOT;
1369                 self.takedamage = DAMAGE_NO;
1370                 self.movetype = MOVETYPE_FLY;
1371                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1372                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1373                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1374                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1375                 if(autocvar_g_respawn_ghosts_maxtime)
1376                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1377         }
1378
1379         CopyBody(1);
1380
1381         self.effects |= EF_NODRAW; // prevent another CopyBody
1382         PutClientInServer();
1383 }
1384
1385 void play_countdown(float finished, string samp)
1386 {
1387         if(IS_REAL_CLIENT(self))
1388                 if(floor(finished - time - frametime) != floor(finished - time))
1389                         if(finished - time < 6)
1390                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1391 }
1392
1393 void player_powerups (void)
1394 {
1395         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1396         olditems = self.items;
1397
1398         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1399                 self.modelflags |= MF_ROCKET;
1400         else
1401                 self.modelflags &= ~MF_ROCKET;
1402
1403         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1404
1405         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1406                 return;
1407
1408         Fire_ApplyDamage(self);
1409         Fire_ApplyEffect(self);
1410
1411         if (!g_minstagib)
1412         {
1413                 if (self.items & IT_STRENGTH)
1414                 {
1415                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1416                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1417                         if (time > self.strength_finished)
1418                         {
1419                                 self.items = self.items - (self.items & IT_STRENGTH);
1420                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1421                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1422                         }
1423                 }
1424                 else
1425                 {
1426                         if (time < self.strength_finished)
1427                         {
1428                                 self.items = self.items | IT_STRENGTH;
1429                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1430                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1431                         }
1432                 }
1433                 if (self.items & IT_INVINCIBLE)
1434                 {
1435                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1436                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1437                         if (time > self.invincible_finished)
1438                         {
1439                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1440                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1441                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1442                         }
1443                 }
1444                 else
1445                 {
1446                         if (time < self.invincible_finished)
1447                         {
1448                                 self.items = self.items | IT_INVINCIBLE;
1449                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1450                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1451                         }
1452                 }
1453                 if (self.items & IT_SUPERWEAPON)
1454                 {
1455                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1456                         {
1457                                 self.superweapons_finished = 0;
1458                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1459                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1461                         }
1462                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1463                         {
1464                                 // don't let them run out
1465                         }
1466                         else
1467                         {
1468                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1469                                 if (time > self.superweapons_finished)
1470                                 {
1471                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1472                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1473                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1474                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1475                                 }
1476                         }
1477                 }
1478                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1479                 {
1480                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1481                         {
1482                                 self.items = self.items | IT_SUPERWEAPON;
1483                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1484                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1485                         }
1486                         else
1487                         {
1488                                 self.superweapons_finished = 0;
1489                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1490                         }
1491                 }
1492                 else
1493                 {
1494                         self.superweapons_finished = 0;
1495                 }
1496         }
1497
1498         if(autocvar_g_nodepthtestplayers)
1499                 self.effects = self.effects | EF_NODEPTHTEST;
1500
1501         if(autocvar_g_fullbrightplayers)
1502                 self.effects = self.effects | EF_FULLBRIGHT;
1503
1504         if (time >= game_starttime)
1505         if (time < self.spawnshieldtime)
1506                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1507
1508         MUTATOR_CALLHOOK(PlayerPowerups);
1509 }
1510
1511 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1512 {
1513         if(current > stable)
1514                 return current;
1515         else if(current > stable - 0.25) // when close enough, "snap"
1516                 return stable;
1517         else
1518                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1519 }
1520
1521 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1522 {
1523         if(current < stable)
1524                 return current;
1525         else if(current < stable + 0.25) // when close enough, "snap"
1526                 return stable;
1527         else
1528                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1529 }
1530
1531 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1532 {
1533         if(current > rotstable)
1534         {
1535                 if(rotframetime > 0)
1536                 {
1537                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1538                         current = max(rotstable, current - rotlinear * rotframetime);
1539                 }
1540         }
1541         else if(current < regenstable)
1542         {
1543                 if(regenframetime > 0)
1544                 {
1545                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1546                         current = min(regenstable, current + regenlinear * regenframetime);
1547                 }
1548         }
1549
1550         if(current > limit)
1551                 current = limit;
1552
1553         return current;
1554 }
1555
1556 void player_regen (void)
1557 {
1558         float max_mod, regen_mod, rot_mod, limit_mod;
1559         max_mod = regen_mod = rot_mod = limit_mod = 1;
1560         regen_mod_max = max_mod;
1561         regen_mod_regen = regen_mod;
1562         regen_mod_rot = rot_mod;
1563         regen_mod_limit = limit_mod;
1564         if(!MUTATOR_CALLHOOK(PlayerRegen))
1565         if(!self.frozen)
1566         {
1567                 float minh, mina, maxh, maxa, limith, limita;
1568                 maxh = autocvar_g_balance_health_rotstable;
1569                 maxa = autocvar_g_balance_armor_rotstable;
1570                 minh = autocvar_g_balance_health_regenstable;
1571                 mina = autocvar_g_balance_armor_regenstable;
1572                 limith = autocvar_g_balance_health_limit;
1573                 limita = autocvar_g_balance_armor_limit;
1574
1575                 max_mod = regen_mod_max;
1576                 regen_mod = regen_mod_regen;
1577                 rot_mod = regen_mod_rot;
1578                 limit_mod = regen_mod_limit;
1579
1580                 maxh = maxh * max_mod;
1581                 minh = minh * max_mod;
1582                 limith = limith * limit_mod;
1583                 limita = limita * limit_mod;
1584
1585                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1586                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1587         }
1588
1589         // if player rotted to death...  die!
1590         // check this outside above checks, as player may still be able to rot to death
1591         if(self.health < 1)
1592         {
1593                 if(self.vehicle)
1594                         vehicles_exit(VHEF_RELEASE);
1595                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1596         }
1597
1598         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1599         {
1600                 float minf, maxf, limitf;
1601
1602                 maxf = autocvar_g_balance_fuel_rotstable;
1603                 minf = autocvar_g_balance_fuel_regenstable;
1604                 limitf = autocvar_g_balance_fuel_limit;
1605
1606                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1607         }
1608 }
1609
1610 float zoomstate_set;
1611 void SetZoomState(float z)
1612 {
1613         if(z != self.zoomstate)
1614         {
1615                 self.zoomstate = z;
1616                 ClientData_Touch(self);
1617         }
1618         zoomstate_set = 1;
1619 }
1620
1621 void GetPressedKeys(void) {
1622         MUTATOR_CALLHOOK(GetPressedKeys);
1623         if (self.movement_x > 0) // get if movement keys are pressed
1624         {       // forward key pressed
1625                 self.pressedkeys |= KEY_FORWARD;
1626                 self.pressedkeys &= ~KEY_BACKWARD;
1627         }
1628         else if (self.movement_x < 0)
1629         {       // backward key pressed
1630                 self.pressedkeys |= KEY_BACKWARD;
1631                 self.pressedkeys &= ~KEY_FORWARD;
1632         }
1633         else
1634         {       // no x input
1635                 self.pressedkeys &= ~KEY_FORWARD;
1636                 self.pressedkeys &= ~KEY_BACKWARD;
1637         }
1638
1639         if (self.movement_y > 0)
1640         {       // right key pressed
1641                 self.pressedkeys |= KEY_RIGHT;
1642                 self.pressedkeys &= ~KEY_LEFT;
1643         }
1644         else if (self.movement_y < 0)
1645         {       // left key pressed
1646                 self.pressedkeys |= KEY_LEFT;
1647                 self.pressedkeys &= ~KEY_RIGHT;
1648         }
1649         else
1650         {       // no y input
1651                 self.pressedkeys &= ~KEY_RIGHT;
1652                 self.pressedkeys &= ~KEY_LEFT;
1653         }
1654
1655         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1656                 self.pressedkeys |= KEY_JUMP;
1657         else
1658                 self.pressedkeys &= ~KEY_JUMP;
1659         if (self.BUTTON_CROUCH)
1660                 self.pressedkeys |= KEY_CROUCH;
1661         else
1662                 self.pressedkeys &= ~KEY_CROUCH;
1663
1664         if (self.BUTTON_ATCK)
1665                 self.pressedkeys |= KEY_ATCK;
1666         else
1667                 self.pressedkeys &= ~KEY_ATCK;
1668         if (self.BUTTON_ATCK2)
1669                 self.pressedkeys |= KEY_ATCK2;
1670         else
1671                 self.pressedkeys &= ~KEY_ATCK2;
1672 }
1673
1674 /*
1675 ======================
1676 spectate mode routines
1677 ======================
1678 */
1679
1680 void SpectateCopy(entity spectatee) {
1681         other = spectatee;
1682         MUTATOR_CALLHOOK(SpectateCopy);
1683         self.armortype = spectatee.armortype;
1684         self.armorvalue = spectatee.armorvalue;
1685         self.ammo_cells = spectatee.ammo_cells;
1686         self.ammo_shells = spectatee.ammo_shells;
1687         self.ammo_nails = spectatee.ammo_nails;
1688         self.ammo_rockets = spectatee.ammo_rockets;
1689         self.ammo_fuel = spectatee.ammo_fuel;
1690         self.clip_load = spectatee.clip_load;
1691         self.clip_size = spectatee.clip_size;
1692         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1693         self.health = spectatee.health;
1694         self.impulse = 0;
1695         self.items = spectatee.items;
1696         self.last_pickup = spectatee.last_pickup;
1697         self.hit_time = spectatee.hit_time;
1698         self.metertime = spectatee.metertime;
1699         self.strength_finished = spectatee.strength_finished;
1700         self.invincible_finished = spectatee.invincible_finished;
1701         self.pressedkeys = spectatee.pressedkeys;
1702         self.weapons = spectatee.weapons;
1703         self.switchweapon = spectatee.switchweapon;
1704         self.switchingweapon = spectatee.switchingweapon;
1705         self.weapon = spectatee.weapon;
1706         self.nex_charge = spectatee.nex_charge;
1707         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1708         self.hagar_load = spectatee.hagar_load;
1709         self.minelayer_mines = spectatee.minelayer_mines;
1710         self.punchangle = spectatee.punchangle;
1711         self.view_ofs = spectatee.view_ofs;
1712         self.velocity = spectatee.velocity;
1713         self.dmg_take = spectatee.dmg_take;
1714         self.dmg_save = spectatee.dmg_save;
1715         self.dmg_inflictor = spectatee.dmg_inflictor;
1716         self.v_angle = spectatee.v_angle;
1717         self.angles = spectatee.v_angle;
1718         self.frozen = spectatee.frozen;
1719         self.revive_progress = spectatee.revive_progress;
1720         if(!self.BUTTON_USE)
1721                 self.fixangle = TRUE;
1722         setorigin(self, spectatee.origin);
1723         setsize(self, spectatee.mins, spectatee.maxs);
1724         SetZoomState(spectatee.zoomstate);
1725
1726     anticheat_spectatecopy(spectatee);
1727         self.hud = spectatee.hud;
1728         if(spectatee.vehicle)
1729     {
1730         self.fixangle = FALSE;
1731         //self.velocity = spectatee.vehicle.velocity;
1732         self.vehicle_health = spectatee.vehicle_health;
1733         self.vehicle_shield = spectatee.vehicle_shield;
1734         self.vehicle_energy = spectatee.vehicle_energy;
1735         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1736         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1737         self.vehicle_reload1 = spectatee.vehicle_reload1;
1738         self.vehicle_reload2 = spectatee.vehicle_reload2;
1739
1740         msg_entity = self;
1741
1742         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1743             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1744             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1745             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1746
1747         //WriteByte (MSG_ONE, SVC_SETVIEW);
1748         //    WriteEntity(MSG_ONE, self);
1749         //makevectors(spectatee.v_angle);
1750         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1751     }
1752 }
1753
1754 float SpectateUpdate() {
1755         if(!self.enemy)
1756             return 0;
1757
1758         if (self == self.enemy)
1759                 return 0;
1760
1761         if (!IS_PLAYER(self.enemy))
1762                 return 0;
1763
1764         SpectateCopy(self.enemy);
1765
1766         return 1;
1767 }
1768
1769
1770 float SpectateSet()
1771 {
1772         if(self.enemy.classname != "player")
1773                 return FALSE;
1774         /*if(self.enemy.vehicle)
1775         {
1776
1777                 msg_entity = self;
1778                 WriteByte(MSG_ONE, SVC_SETVIEW);
1779                 WriteEntity(MSG_ONE, self.enemy);
1780                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1781
1782                 self.movetype = MOVETYPE_NONE;
1783                 accuracy_resend(self);
1784         }
1785         else
1786         {*/
1787                 msg_entity = self;
1788                 WriteByte(MSG_ONE, SVC_SETVIEW);
1789                 WriteEntity(MSG_ONE, self.enemy);
1790                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1791                 self.movetype = MOVETYPE_NONE;
1792                 accuracy_resend(self);
1793
1794                 if(!SpectateUpdate())
1795                         PutObserverInServer();
1796         //}
1797         return TRUE;
1798 }
1799
1800 float Spectate(entity pl)
1801 {
1802         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1803         if(pl.team != self.team)
1804                 return 0;
1805
1806         self.enemy = pl;
1807         return SpectateSet();
1808 }
1809
1810 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1811 entity CA_SpectateNext(entity start) {
1812         if (start.team == self.team) {
1813                 return start;
1814         }
1815
1816         other = start;
1817         // continue from current player
1818         while(other && other.team != self.team) {
1819                 other = find(other, classname, "player");
1820         }
1821
1822         if (!other) {
1823                 // restart from begining
1824                 other = find(other, classname, "player");
1825                 while(other && other.team != self.team) {
1826                         other = find(other, classname, "player");
1827                 }
1828         }
1829
1830         return other;
1831 }
1832
1833 float SpectateNext()
1834 {
1835         other = find(self.enemy, classname, "player");
1836
1837         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1838                 // CA and ca players when spectating enemies is forbidden
1839                 other = CA_SpectateNext(other);
1840         } else {
1841                 // other modes and ca spectators or spectating enemies is allowed
1842                 if (!other)
1843                         other = find(other, classname, "player");
1844         }
1845
1846         if (other)
1847                 self.enemy = other;
1848
1849         return SpectateSet();
1850 }
1851
1852 float SpectatePrev()
1853 {
1854         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1855         other = findchain(classname, "player");
1856         if (!other) // no player
1857                 return FALSE;
1858
1859         entity first = other;
1860         // skip players until current spectated player
1861         if(self.enemy)
1862         while(other && other != self.enemy)
1863                 other = other.chain;
1864
1865         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1866         {
1867                 do { other = other.chain; }
1868                 while(other && other.team != self.team);
1869
1870                 if (!other)
1871                 {
1872                         other = first;
1873                         while(other.team != self.team)
1874                                 other = other.chain;
1875                         if(other == self.enemy)
1876                                 return TRUE;
1877                 }
1878         }
1879         else
1880         {
1881                 if(other.chain)
1882                         other = other.chain;
1883                 else
1884                         other = first;
1885         }
1886         self.enemy = other;
1887         return SpectateSet();
1888 }
1889
1890 /*
1891 =============
1892 ShowRespawnCountdown()
1893
1894 Update a respawn countdown display.
1895 =============
1896 */
1897 void ShowRespawnCountdown()
1898 {
1899         float number;
1900         if(self.deadflag == DEAD_NO) // just respawned?
1901                 return;
1902         else
1903         {
1904                 number = ceil(self.respawn_time - time);
1905                 if(number <= 0)
1906                         return;
1907                 if(number <= self.respawn_countdown)
1908                 {
1909                         self.respawn_countdown = number - 1;
1910                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1911                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1912                 }
1913         }
1914 }
1915
1916 void LeaveSpectatorMode()
1917 {
1918         if(self.caplayer)
1919                 return;
1920         if(nJoinAllowed(self))
1921         {
1922                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1923                 {
1924                         self.classname = "player";
1925                         nades_RemoveBonus(self);
1926
1927                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1928                                 { JoinBestTeam(self, FALSE, TRUE); }
1929
1930                         if(autocvar_g_campaign)
1931                                 { campaign_bots_may_start = 1; }
1932
1933                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1934
1935                         PutClientInServer();
1936
1937                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1938                 }
1939                 else
1940                         stuffcmd(self, "menu_showteamselect\n");
1941         }
1942         else
1943         {
1944                 // Player may not join because g_maxplayers is set
1945                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1946         }
1947 }
1948
1949 /**
1950  * Determines whether the player is allowed to join. This depends on cvar
1951  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1952  * it checks whether the number of currently playing players exceeds g_maxplayers.
1953  * @return int number of free slots for players, 0 if none
1954  */
1955 float nJoinAllowed(entity ignore) {
1956         if(!ignore)
1957         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1958         // so report 0 free slots if restricted
1959         {
1960                 if(autocvar_g_forced_team_otherwise == "spectate")
1961                         return 0;
1962                 if(autocvar_g_forced_team_otherwise == "spectator")
1963                         return 0;
1964         }
1965
1966         if(self.team_forced < 0)
1967                 return 0; // forced spectators can never join
1968
1969         // TODO simplify this
1970         entity e;
1971         float totalClients = 0;
1972         FOR_EACH_CLIENT(e)
1973                 if(e != ignore)
1974                         totalClients += 1;
1975
1976         if (!autocvar_g_maxplayers)
1977                 return maxclients - totalClients;
1978
1979         float currentlyPlaying = 0;
1980         FOR_EACH_REALCLIENT(e)
1981                 if(IS_PLAYER(e) || e.caplayer == 1)
1982                         currentlyPlaying += 1;
1983
1984         if(currentlyPlaying < autocvar_g_maxplayers)
1985                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1986
1987         return 0;
1988 }
1989
1990 /**
1991  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1992  * g_maxplayers_spectator_blocktime seconds
1993  */
1994 void checkSpectatorBlock() {
1995         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1996                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1997                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1998                         dropclient(self);
1999                 }
2000         }
2001 }
2002
2003 void PrintWelcomeMessage()
2004 {
2005         if(self.motd_actived_time == 0)
2006         {
2007                 if (autocvar_g_campaign) {
2008                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2009                                 self.motd_actived_time = time;
2010                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2011                         }
2012                 } else {
2013                         if (self.BUTTON_INFO) {
2014                                 self.motd_actived_time = time;
2015                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2016                         }
2017                 }
2018         }
2019         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2020         {
2021                 if (autocvar_g_campaign) {
2022                         if (self.BUTTON_INFO)
2023                                 self.motd_actived_time = time;
2024                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2025                                 self.motd_actived_time = 0;
2026                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2027                         }
2028                 } else {
2029                         if (self.BUTTON_INFO)
2030                                 self.motd_actived_time = time;
2031                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2032                                 self.motd_actived_time = 0;
2033                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2034                         }
2035                 }
2036         }
2037         else //if(self.motd_actived_time < 0) // just connected, motd is active
2038         {
2039                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2040                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2041                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2042                 {
2043                         // instanctly hide MOTD
2044                         self.motd_actived_time = 0;
2045                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2046                 }
2047         }
2048 }
2049
2050 void ObserverThink()
2051 {
2052         float prefered_movetype;
2053         if (self.flags & FL_JUMPRELEASED) {
2054                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2055                         self.flags &= ~FL_JUMPRELEASED;
2056                         self.flags |= FL_SPAWNING;
2057                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2058                         self.flags &= ~FL_JUMPRELEASED;
2059                         if(SpectateNext()) {
2060                                 self.classname = "spectator";
2061                         }
2062                 } else {
2063                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2064                         if (self.movetype != prefered_movetype)
2065                                 self.movetype = prefered_movetype;
2066                 }
2067         } else {
2068                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2069                         self.flags |= FL_JUMPRELEASED;
2070                         if(self.flags & FL_SPAWNING)
2071                         {
2072                                 self.flags &= ~FL_SPAWNING;
2073                                 LeaveSpectatorMode();
2074                                 return;
2075                         }
2076                 }
2077         }
2078 }
2079
2080 void SpectatorThink()
2081 {
2082         if (self.flags & FL_JUMPRELEASED) {
2083                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2084                         self.flags &= ~FL_JUMPRELEASED;
2085                         self.flags |= FL_SPAWNING;
2086                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2087                         self.flags &= ~FL_JUMPRELEASED;
2088                         if(SpectateNext()) {
2089                                 self.classname = "spectator";
2090                         } else {
2091                                 self.classname = "observer";
2092                                 PutClientInServer();
2093                         }
2094                         self.impulse = 0;
2095                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2096                         self.flags &= ~FL_JUMPRELEASED;
2097                         if(SpectatePrev()) {
2098                                 self.classname = "spectator";
2099                         } else {
2100                                 self.classname = "observer";
2101                                 PutClientInServer();
2102                         }
2103                         self.impulse = 0;
2104                 } else if (self.BUTTON_ATCK2) {
2105                         self.flags &= ~FL_JUMPRELEASED;
2106                         self.classname = "observer";
2107                         PutClientInServer();
2108                 } else {
2109                         if(!SpectateUpdate())
2110                                 PutObserverInServer();
2111                 }
2112         } else {
2113                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2114                         self.flags |= FL_JUMPRELEASED;
2115                         if(self.flags & FL_SPAWNING)
2116                         {
2117                                 self.flags &= ~FL_SPAWNING;
2118                                 LeaveSpectatorMode();
2119                                 return;
2120                         }
2121                 }
2122                 if(!SpectateUpdate())
2123                         PutObserverInServer();
2124         }
2125
2126         self.flags |= FL_CLIENT | FL_NOTARGET;
2127 }
2128
2129 void vehicles_enter (entity pl, entity veh);
2130 void PlayerUseKey()
2131 {
2132         if (!IS_PLAYER(self))
2133                 return;
2134
2135         if(self.vehicle)
2136         {
2137                 if(!gameover)
2138                 {
2139                         vehicles_exit(VHEF_NORMAL);
2140                         return;
2141                 }
2142         }
2143         else if(autocvar_g_vehicles_enter)
2144         {
2145                 if(!self.frozen)
2146                 if(self.deadflag == DEAD_NO)
2147                 if(!gameover)
2148                 {
2149                         entity head, closest_target = world;
2150                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2151
2152                         while(head) // find the closest acceptable target to enter
2153                         {
2154                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2155                                 if(head.deadflag == DEAD_NO)
2156                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2157                                 if(head.takedamage != DAMAGE_NO)
2158                                 {
2159                                         if(closest_target)
2160                                         {
2161                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2162                                                 { closest_target = head; }
2163                                         }
2164                                         else { closest_target = head; }
2165                                 }
2166
2167                                 head = head.chain;
2168                         }
2169
2170                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2171                 }
2172         }
2173
2174         // a use key was pressed; call handlers
2175         MUTATOR_CALLHOOK(PlayerUseKey);
2176 }
2177
2178 /*
2179 =============
2180 PlayerPreThink
2181
2182 Called every frame for each client before the physics are run
2183 =============
2184 */
2185 .float usekeypressed;
2186 void() nexball_setstatus;
2187 .float items_added;
2188 .float last_vehiclecheck;
2189 void PlayerPreThink (void)
2190 {
2191         WarpZone_PlayerPhysics_FixVAngle();
2192
2193         self.stat_game_starttime = game_starttime;
2194         self.stat_round_starttime = round_starttime;
2195         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2196         self.stat_leadlimit = autocvar_leadlimit;
2197
2198         if(frametime)
2199         {
2200                 // physics frames: update anticheat stuff
2201                 anticheat_prethink();
2202         }
2203
2204         if(blockSpectators && frametime)
2205                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2206                 checkSpectatorBlock();
2207
2208         zoomstate_set = 0;
2209
2210         if(self.netname_previous != self.netname)
2211         {
2212                 if(autocvar_sv_eventlog)
2213                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2214                 if(self.netname_previous)
2215                         strunzone(self.netname_previous);
2216                 self.netname_previous = strzone(self.netname);
2217         }
2218
2219         // version nagging
2220         if(self.version_nagtime)
2221                 if(self.cvar_g_xonoticversion)
2222                         if(time > self.version_nagtime)
2223                         {
2224                                 // don't notify git users
2225                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2226                                 {
2227                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2228                                         {
2229                                                 // notify release users if connecting to git
2230                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2231                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2232                                         }
2233                                         else
2234                                         {
2235                                                 float r;
2236                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2237                                                 if(r < 0)
2238                                                 {
2239                                                         // give users new version
2240                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2241                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2242                                                 }
2243                                                 else if(r > 0)
2244                                                 {
2245                                                         // notify users about old server version
2246                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2247                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2248                                                 }
2249                                         }
2250                                 }
2251                                 self.version_nagtime = 0;
2252                         }
2253
2254         // GOD MODE info
2255         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2256         {
2257                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2258                 self.max_armorvalue = 0;
2259         }
2260
2261 #ifdef TETRIS
2262         if (TetrisPreFrame())
2263                 return;
2264 #endif
2265
2266         if(self.frozen == 2)
2267         {
2268                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2269                 self.health = max(1, self.revive_progress * start_health);
2270                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2271
2272                 if(self.revive_progress >= 1)
2273                         Unfreeze(self);
2274         }
2275         else if(self.frozen == 3)
2276         {
2277                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2278                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2279
2280                 if(self.health < 1)
2281                 {
2282                         if(self.vehicle)
2283                                 vehicles_exit(VHEF_RELEASE);
2284                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2285                 }
2286                 else if ( self.revive_progress <= 0 )
2287                         Unfreeze(self);
2288         }
2289
2290         MUTATOR_CALLHOOK(PlayerPreThink);
2291
2292         if(autocvar_g_vehicles_enter)
2293         if(time > self.last_vehiclecheck)
2294         if(IS_PLAYER(self))
2295         if(!gameover)
2296         if(!self.frozen)
2297         if(!self.vehicle)
2298         if(self.deadflag == DEAD_NO)
2299         {
2300                 entity veh;
2301                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2302                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2303                 if(veh.deadflag == DEAD_NO)
2304                 if(veh.takedamage != DAMAGE_NO)
2305                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2306                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2307                 else if(!veh.owner)
2308                 if(!veh.team || SAME_TEAM(self, veh))
2309                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2310                 else if(autocvar_g_vehicles_steal)
2311                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2312
2313                 self.last_vehiclecheck = time + 1;
2314         }
2315
2316         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2317         {
2318                 if(self.BUTTON_USE && !self.usekeypressed)
2319                         PlayerUseKey();
2320                 self.usekeypressed = self.BUTTON_USE;
2321         }
2322
2323         if(IS_REAL_CLIENT(self))
2324                 PrintWelcomeMessage();
2325
2326         if(IS_PLAYER(self))
2327         {
2328
2329                 CheckRules_Player();
2330
2331                 if (intermission_running)
2332                 {
2333                         IntermissionThink ();   // otherwise a button could be missed between
2334                         return;                                 // the think tics
2335                 }
2336
2337                 //don't allow the player to turn around while game is paused!
2338                 if(timeout_status == TIMEOUT_ACTIVE) {
2339                         // FIXME turn this into CSQC stuff
2340                         self.v_angle = self.lastV_angle;
2341                         self.angles = self.lastV_angle;
2342                         self.fixangle = TRUE;
2343                 }
2344
2345                 if(frametime)
2346                 {
2347                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2348                         {
2349                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2350                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2351                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2352
2353                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2354                                 {
2355                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2356                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2357                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2358                                 }
2359                         }
2360                         else
2361                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2362
2363                         player_powerups();
2364                 }
2365
2366                 if (self.deadflag != DEAD_NO)
2367                 {
2368                         if(self.personal && g_race_qualifying)
2369                         {
2370                                 if(time > self.respawn_time)
2371                                 {
2372                                         self.respawn_time = time + 1; // only retry once a second
2373                                         self.stat_respawn_time = self.respawn_time;
2374                                         respawn();
2375                                         self.impulse = 141;
2376                                 }
2377                         }
2378                         else
2379                         {
2380                                 float button_pressed;
2381                                 if(frametime)
2382                                         player_anim();
2383                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2384
2385                                 if (self.deadflag == DEAD_DYING)
2386                                 {
2387                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2388                                                 self.deadflag = DEAD_RESPAWNING;
2389                                         else if(!button_pressed)
2390                                                 self.deadflag = DEAD_DEAD;
2391                                 }
2392                                 else if (self.deadflag == DEAD_DEAD)
2393                                 {
2394                                         if(button_pressed)
2395                                                 self.deadflag = DEAD_RESPAWNABLE;
2396                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2397                                                 self.deadflag = DEAD_RESPAWNING;
2398                                 }
2399                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2400                                 {
2401                                         if(!button_pressed)
2402                                                 self.deadflag = DEAD_RESPAWNING;
2403                                 }
2404                                 else if (self.deadflag == DEAD_RESPAWNING)
2405                                 {
2406                                         if(time > self.respawn_time)
2407                                         {
2408                                                 self.respawn_time = time + 1; // only retry once a second
2409                                                 self.respawn_time_max = self.respawn_time;
2410                                                 respawn();
2411                                         }
2412                                 }
2413
2414                                 ShowRespawnCountdown();
2415
2416                                 if(self.respawn_flags & RESPAWN_SILENT)
2417                                         self.stat_respawn_time = 0;
2418                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2419                                         self.stat_respawn_time = self.respawn_time_max;
2420                                 else
2421                                         self.stat_respawn_time = self.respawn_time;
2422                         }
2423
2424                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2425                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2426                                 self.stat_respawn_time *= -1;
2427
2428                         return;
2429                 }
2430
2431                 self.prevorigin = self.origin;
2432
2433                 float do_crouch = self.BUTTON_CROUCH;
2434                 if(self.hook.state)
2435                         do_crouch = 0;
2436                 if(self.vehicle)
2437                         do_crouch = 0;
2438                 if(self.frozen)
2439                         do_crouch = 0;
2440                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2441                         do_crouch = 0;
2442
2443                 if (do_crouch)
2444                 {
2445                         if (!self.crouch)
2446                         {
2447                                 self.crouch = TRUE;
2448                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2449                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2450                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2451                         }
2452                 }
2453                 else
2454                 {
2455                         if (self.crouch)
2456                         {
2457                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2458                                 if (!trace_startsolid)
2459                                 {
2460                                         self.crouch = FALSE;
2461                                         self.view_ofs = PL_VIEW_OFS;
2462                                         setsize (self, PL_MIN, PL_MAX);
2463                                 }
2464                         }
2465                 }
2466
2467                 FixPlayermodel();
2468
2469                 GrapplingHookFrame();
2470
2471                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2472                 //if(frametime)
2473                 {
2474                         self.items &= ~self.items_added;
2475
2476                         W_WeaponFrame();
2477
2478                         self.items_added = 0;
2479                         if(self.items & IT_JETPACK)
2480                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2481                                         self.items_added |= IT_FUEL;
2482
2483                         self.items |= self.items_added;
2484                 }
2485
2486                 player_regen();
2487
2488                 // rot nex charge to the charge limit
2489                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2490                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2491
2492                 if(frametime)
2493                         player_anim();
2494
2495                 // secret status
2496                 secrets_setstatus();
2497
2498                 // monsters status
2499                 monsters_setstatus();
2500
2501                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2502
2503                 //self.angles_y=self.v_angle_y + 90;   // temp
2504         } else if(gameover) {
2505                 if (intermission_running)
2506                         IntermissionThink ();   // otherwise a button could be missed between
2507                 return;
2508         } else if(IS_OBSERVER(self)) {
2509                 ObserverThink();
2510         } else if(IS_SPEC(self)) {
2511                 SpectatorThink();
2512         }
2513
2514         if(!zoomstate_set)
2515                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2516
2517         float oldspectatee_status;
2518         oldspectatee_status = self.spectatee_status;
2519         if(IS_SPEC(self))
2520                 self.spectatee_status = num_for_edict(self.enemy);
2521         else if(IS_OBSERVER(self))
2522                 self.spectatee_status = num_for_edict(self);
2523         else
2524                 self.spectatee_status = 0;
2525         if(self.spectatee_status != oldspectatee_status)
2526         {
2527                 ClientData_Touch(self);
2528         }
2529
2530         if(self.teamkill_soundtime)
2531         if(time > self.teamkill_soundtime)
2532         {
2533                 self.teamkill_soundtime = 0;
2534
2535                 entity oldpusher, oldself;
2536
2537                 oldself = self; self = self.teamkill_soundsource;
2538                 oldpusher = self.pusher; self.pusher = oldself;
2539
2540                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2541
2542                 self.pusher = oldpusher;
2543                 self = oldself;
2544         }
2545
2546         if(self.taunt_soundtime)
2547         if(time > self.taunt_soundtime)
2548         {
2549                 self.taunt_soundtime = 0;
2550                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2551         }
2552
2553         target_voicescript_next(self);
2554
2555         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2556         if(!self.weapon)
2557                 self.clip_load = self.clip_size = 0;
2558 }
2559
2560 float isInvisibleString(string s)
2561 {
2562         float i, n, c;
2563         s = strdecolorize(s);
2564         for((i = 0), (n = strlen(s)); i < n; ++i)
2565         {
2566                 c = str2chr(s, i);
2567                 switch(c)
2568                 {
2569                         case 0:
2570                         case 32: // space
2571                                 break;
2572                         case 192: // charmap space
2573                                 if (!autocvar_utf8_enable)
2574                                         break;
2575                                 return FALSE;
2576                         case 160: // space in unicode fonts
2577                         case 0xE000 + 192: // utf8 charmap space
2578                                 if (autocvar_utf8_enable)
2579                                         break;
2580                         default:
2581                                 return FALSE;
2582                 }
2583         }
2584         return TRUE;
2585 }
2586
2587 /*
2588 =============
2589 PlayerPostThink
2590
2591 Called every frame for each client after the physics are run
2592 =============
2593 */
2594 .float idlekick_lasttimeleft;
2595 void PlayerPostThink (void)
2596 {
2597         // Savage: Check for nameless players
2598         if (isInvisibleString(self.netname)) {
2599                 self.netname = "Player";
2600                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2601         }
2602
2603         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2604         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2605         {
2606                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2607                 {
2608                         if(self.idlekick_lasttimeleft)
2609                         {
2610                                 self.idlekick_lasttimeleft = 0;
2611                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2612                         }
2613                 }
2614                 else
2615                 {
2616                         float timeleft;
2617                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2618                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2619                         {
2620                                 if(!self.idlekick_lasttimeleft)
2621                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2622                         }
2623                         if(timeleft <= 0)
2624                         {
2625                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2626                                 dropclient(self);
2627                                 return;
2628                         }
2629                         else if(timeleft <= 10)
2630                         {
2631                                 if(timeleft != self.idlekick_lasttimeleft)
2632                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2633                                 self.idlekick_lasttimeleft = timeleft;
2634                         }
2635                 }
2636         }
2637
2638 #ifdef TETRIS
2639         if(self.impulse == 100)
2640                 ImpulseCommands();
2641         if (!TetrisPostFrame())
2642         {
2643 #endif
2644
2645         CheatFrame();
2646
2647         //CheckPlayerJump();
2648
2649         if(IS_PLAYER(self)) {
2650                 CheckRules_Player();
2651                 UpdateChatBubble();
2652                 if (self.impulse)
2653                         ImpulseCommands();
2654                 if (intermission_running)
2655                         return;         // intermission or finale
2656                 GetPressedKeys();
2657         }
2658
2659 #ifdef TETRIS
2660         }
2661 #endif
2662
2663         /*
2664         float i;
2665         for(i = 0; i < 1000; ++i)
2666         {
2667                 vector end;
2668                 end = self.origin + '0 0 1024' + 512 * randomvec();
2669                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2670                 if(trace_fraction < 1)
2671                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2672                 {
2673                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2674                         break;
2675                 }
2676         }
2677         */
2678
2679         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2680
2681         if(self.waypointsprite_attachedforcarrier)
2682                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2683
2684         playerdemo_write();
2685
2686         CSQCMODEL_AUTOUPDATE();
2687 }