qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.respawn_time = 0;
 470         self.alpha = 0;
 471         self.scale = 0;
 472         self.fade_time = 0;
 473         self.pain_frame = 0;
 474         self.pain_finished = 0;
 475         self.strength_finished = 0;
 476         self.invincible_finished = 0;
 477         self.superweapons_finished = 0;
 478         self.pushltime = 0;
 479         self.think = SUB_Null;
 480         self.nextthink = 0;
 481         self.hook_time = 0;
 482         self.runes = 0;
 483         self.deadflag = DEAD_NO;
 484         self.angles = spot.angles;
 485         self.angles_z = 0;
 486         self.fixangle = TRUE;
 487         self.crouch = FALSE;
 488
 489         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 490         self.prevorigin = self.origin;
 491         self.items = 0;
 492         self.weapons = 0;
 493         self.model = "";
 494         FixPlayermodel();
 495         setmodel(self, "null");
 496         self.drawonlytoclient = self;
 497
 498         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 499         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 500
 501         self.weapon = 0;
 502         self.weaponname = "";
 503         self.switchingweapon = 0;
 504         self.weaponmodel = "";
 505         self.weaponentity = world;
 506         self.exteriorweaponentity = world;
 507         self.killcount = -666;
 508         self.velocity = '0 0 0';
 509         self.avelocity = '0 0 0';
 510         self.punchangle = '0 0 0';
 511         self.punchvector = '0 0 0';
 512         self.oldvelocity = self.velocity;
 513         self.fire_endtime = -1;
 514
 515         if(g_arena)
 516         {
 517                 if(self.version_mismatch)
 518                 {
 519                         Spawnqueue_Unmark(self);
 520                         Spawnqueue_Remove(self);
 521                 }
 522                 else
 523                 {
 524                         Spawnqueue_Insert(self);
 525                 }
 526         }
 527         else if(g_lms)
 528         {
 529                 // Only if the player cannot play at all
 530                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 531                         self.frags = FRAGS_SPECTATOR;
 532                 else
 533                         self.frags = FRAGS_LMS_LOSER;
 534         }
 535         else if(g_ca)
 536         {
 537                 if(self.caplayer)
 538                         self.frags = FRAGS_LMS_LOSER;
 539                 else
 540                         self.frags = FRAGS_SPECTATOR;
 541         }
 542         else
 543                 self.frags = FRAGS_SPECTATOR;
 544 }
 545
 546 .float model_randomizer;
 547 void FixPlayermodel()
 548 {
 549         string defaultmodel;
 550         float defaultskin, chmdl, oldskin, n, i;
 551         vector m1, m2;
 552
 553         defaultmodel = "";
 554
 555         if(autocvar_sv_defaultcharacter == 1)
 556         {
 557                 defaultskin = 0;
 558
 559                 if(teamplay)
 560                 {
 561                         string s;
 562                         s = Team_ColorNameLowerCase(self.team);
 563                         if(s != "neutral")
 564                         {
 565                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 566                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 567                         }
 568                 }
 569
 570                 if(defaultmodel == "")
 571                 {
 572                         defaultmodel = autocvar_sv_defaultplayermodel;
 573                         defaultskin = autocvar_sv_defaultplayerskin;
 574                 }
 575
 576                 n = tokenize_console(defaultmodel);
 577                 if(n > 0)
 578                         defaultmodel = argv(floor(n * self.model_randomizer));
 579
 580                 i = strstrofs(defaultmodel, ":", 0);
 581                 if(i >= 0)
 582                 {
 583                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 584                         defaultmodel = substring(defaultmodel, 0, i);
 585                 }
 586         }
 587
 588         if(defaultmodel != "")
 589         {
 590                 if (defaultmodel != self.model)
 591                 {
 592                         m1 = self.mins;
 593                         m2 = self.maxs;
 594                         setplayermodel (self, defaultmodel);
 595                         setsize (self, m1, m2);
 596                         chmdl = TRUE;
 597                 }
 598
 599                 oldskin = self.skin;
 600                 self.skin = defaultskin;
 601         } else {
 602                 if (self.playermodel != self.model || self.playermodel == "")
 603                 {
 604                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 605                         m1 = self.mins;
 606                         m2 = self.maxs;
 607                         setplayermodel (self, self.playermodel);
 608                         setsize (self, m1, m2);
 609                         chmdl = TRUE;
 610                 }
 611
 612                 oldskin = self.skin;
 613                 self.skin = stof(self.playerskin);
 614         }
 615
 616         if(chmdl || oldskin != self.skin)
 617                 self.species = player_getspecies(); // model or skin has changed
 618
 619         if(!teamplay)
 620                 if(strlen(autocvar_sv_defaultplayercolors))
 621                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 622                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 623 }
 624
 625 void PlayerTouchExplode(entity p1, entity p2)
 626 {
 627         vector org;
 628         org = (p1.origin + p2.origin) * 0.5;
 629         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 630
 631         te_explosion(org);
 632
 633         entity e;
 634         e = spawn();
 635         setorigin(e, org);
 636         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 637         remove(e);
 638 }
 639
 640 /*
 641 =============
 642 PutClientInServer
 643
 644 Called when a client spawns in the server
 645 =============
 646 */
 647 //void() ctf_playerchanged;
 648
 649 void PutClientInServer (void)
 650 {
 651         if(clienttype(self) == CLIENTTYPE_BOT)
 652         {
 653                 self.classname = "player";
 654         }
 655         else if(clienttype(self) == CLIENTTYPE_REAL)
 656         {
 657                 msg_entity = self;
 658                 WriteByte(MSG_ONE, SVC_SETVIEW);
 659                 WriteEntity(MSG_ONE, self);
 660         }
 661
 662         // reset player keys
 663         self.itemkeys = 0;
 664
 665         // player is dead and becomes observer
 666         // FIXME fix LMS scoring for new system
 667         if(g_lms)
 668         {
 669                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 670                         self.classname = "observer";
 671         }
 672
 673         if(g_arena || (g_ca && !allowed_to_spawn))
 674         if(!self.spawned)
 675                 self.classname = "observer";
 676
 677         if(gameover)
 678                 self.classname = "observer";
 679
 680         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 681                 entity spot, oldself;
 682                 float j;
 683
 684                 accuracy_resend(self);
 685
 686                 if(self.team < 0)
 687                         JoinBestTeam(self, FALSE, TRUE);
 688
 689                 race_PreSpawn();
 690
 691                 spot = SelectSpawnPoint (FALSE);
 692                 if(!spot)
 693                 {
 694                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 695                         return; // spawn failed
 696                 }
 697
 698                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 699
 700                 self.classname = "player";
 701                 self.wasplayer = TRUE;
 702                 self.iscreature = TRUE;
 703                 self.damagedbycontents = TRUE;
 704                 self.movetype = MOVETYPE_WALK;
 705                 self.solid = SOLID_SLIDEBOX;
 706                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 707                 if(autocvar_g_playerclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 709                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 710                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 711                 self.frags = FRAGS_PLAYER;
 712                 if(INDEPENDENT_PLAYERS)
 713                         MAKE_INDEPENDENT_PLAYER(self);
 714                 self.flags = FL_CLIENT;
 715                 if(autocvar__notarget)
 716                         self.flags |= FL_NOTARGET;
 717                 self.takedamage = DAMAGE_AIM;
 718                 if(g_minstagib)
 719                         self.effects = EF_FULLBRIGHT;
 720                 else
 721                         self.effects = 0;
 722                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 723                 self.air_finished = time + 12;
 724                 self.dmg = 2;
 725                 if(autocvar_g_balance_nex_charge)
 726                 {
 727                         if(autocvar_g_balance_nex_secondary_chargepool)
 728                                 self.nex_chargepool_ammo = 1;
 729                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 730                 }
 731
 732                 if(inWarmupStage)
 733                 {
 734                         self.ammo_shells = warmup_start_ammo_shells;
 735                         self.ammo_nails = warmup_start_ammo_nails;
 736                         self.ammo_rockets = warmup_start_ammo_rockets;
 737                         self.ammo_cells = warmup_start_ammo_cells;
 738                         self.ammo_fuel = warmup_start_ammo_fuel;
 739                         self.health = warmup_start_health;
 740                         self.armorvalue = warmup_start_armorvalue;
 741                         self.weapons = warmup_start_weapons;
 742                 }
 743                 else
 744                 {
 745                         self.ammo_shells = start_ammo_shells;
 746                         self.ammo_nails = start_ammo_nails;
 747                         self.ammo_rockets = start_ammo_rockets;
 748                         self.ammo_cells = start_ammo_cells;
 749                         self.ammo_fuel = start_ammo_fuel;
 750                         self.health = start_health;
 751                         self.armorvalue = start_armorvalue;
 752                         self.weapons = start_weapons;
 753                 }
 754
 755                 if(self.weapons & WEPBIT_SUPERWEAPONS) // exception for minstagib, as minstanex is a superweapon
 756                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 757                 else
 758                         self.superweapons_finished = 0;
 759
 760                 if(g_weaponarena_random)
 761                 {
 762                         if(g_weaponarena_random_with_laser)
 763                                 self.weapons &~= WEPBIT_LASER;
 764                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 765                         if(g_weaponarena_random_with_laser)
 766                                 self.weapons |= WEPBIT_LASER;
 767                 }
 768
 769                 self.items = start_items;
 770
 771                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 772                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 773                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 774                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 775                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 776                 //extend the pause of rotting if client was reset at the beginning of the countdown
 777                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 778                         self.spawnshieldtime += game_starttime - time;
 779                         self.pauserotarmor_finished += game_starttime - time;
 780                         self.pauserothealth_finished += game_starttime - time;
 781                         self.pauseregen_finished += game_starttime - time;
 782                 }
 783                 self.damageforcescale = 2;
 784                 self.death_time = 0;
 785                 self.respawn_time = 0;
 786                 self.scale = 0;
 787                 self.fade_time = 0;
 788                 self.pain_frame = 0;
 789                 self.pain_finished = 0;
 790                 self.strength_finished = 0;
 791                 self.invincible_finished = 0;
 792                 self.pushltime = 0;
 793                 // players have no think function
 794                 self.think = SUB_Null;
 795                 self.nextthink = 0;
 796                 self.hook_time = 0;
 797                 self.dmg_team = 0;
 798                 self.ballistics_density = autocvar_g_ballistics_density_player;
 799
 800                 self.metertime = 0;
 801
 802                 self.runes = 0;
 803
 804                 self.deadflag = DEAD_NO;
 805
 806                 self.angles = spot.angles;
 807
 808                 self.angles_z = 0; // never spawn tilted even if the spot says to
 809                 self.fixangle = TRUE; // turn this way immediately
 810                 self.velocity = '0 0 0';
 811                 self.avelocity = '0 0 0';
 812                 self.punchangle = '0 0 0';
 813                 self.punchvector = '0 0 0';
 814                 self.oldvelocity = self.velocity;
 815                 self.fire_endtime = -1;
 816
 817                 msg_entity = self;
 818                 WRITESPECTATABLE_MSG_ONE({
 819                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 820                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 821                 });
 822
 823                 self.model = "";
 824                 FixPlayermodel();
 825                 self.drawonlytoclient = world;
 826
 827                 self.crouch = FALSE;
 828                 self.view_ofs = PL_VIEW_OFS;
 829                 setsize (self, PL_MIN, PL_MAX);
 830                 self.spawnorigin = spot.origin;
 831                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 832                 // don't reset back to last position, even if new position is stuck in solid
 833                 self.oldorigin = self.origin;
 834                 self.prevorigin = self.origin;
 835                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 836                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 837         self.hud = HUD_NORMAL;
 838
 839                 if(g_arena)
 840                 {
 841                         Spawnqueue_Remove(self);
 842                         Spawnqueue_Mark(self);
 843                 }
 844
 845                 else if(g_ca)
 846                         self.caplayer = 1;
 847
 848                 self.event_damage = PlayerDamage;
 849
 850                 self.bot_attack = TRUE;
 851
 852                 self.statdraintime = time + 5;
 853                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 854
 855                 if(self.killcount == -666) {
 856                         PlayerScore_Clear(self);
 857                         self.killcount = 0;
 858                 }
 859
 860                 CL_SpawnWeaponentity();
 861                 self.alpha = default_player_alpha;
 862                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 863                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 864
 865                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 866                 self.lms_traveled_distance = 0;
 867                 self.speedrunning = FALSE;
 868
 869                 race_PostSpawn(spot);
 870
 871                 //stuffcmd(self, "chase_active 0");
 872                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 873
 874                 if (autocvar_g_spawnsound)
 875                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 876
 877                 if(g_assault) {
 878                         if(self.team == assault_attacker_team)
 879                                 centerprint(self, "You are attacking!");
 880                         else
 881                                 centerprint(self, "You are defending!");
 882                 }
 883
 884                 target_voicescript_clear(self);
 885
 886                 // reset fields the weapons may use
 887                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 888                 {
 889                         weapon_action(j, WR_RESETPLAYER);
 890
 891                         // all weapons must be fully loaded when we spawn
 892                         entity e;
 893                         e = get_weaponinfo(j);
 894                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 895                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 896                 }
 897
 898                 oldself = self;
 899                 self = spot;
 900                         activator = oldself;
 901                                 string s;
 902                                 s = self.target;
 903                                 self.target = string_null;
 904                                 SUB_UseTargets();
 905                                 self.target = s;
 906                         activator = world;
 907                 self = oldself;
 908
 909                 spawn_spot = spot;
 910                 MUTATOR_CALLHOOK(PlayerSpawn);
 911
 912                 if(autocvar_spawn_debug)
 913                 {
 914                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 915                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 916                 }
 917
 918                 self.switchweapon = w_getbestweapon(self);
 919                 self.cnt = -1; // W_LastWeapon will not complain
 920                 self.weapon = 0;
 921                 self.weaponname = "";
 922                 self.switchingweapon = 0;
 923
 924                 if(!self.alivetime)
 925                         self.alivetime = time;
 926
 927                 antilag_clear(self);
 928         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 929                 PutObserverInServer ();
 930         }
 931
 932     // to-do: make sv_join_notices support per-entry times
 933     if(!autocvar_sv_join_notices || autocvar_sv_join_notices == "")
 934         return;
 935
 936     float argc = tokenizebyseparator(autocvar_sv_join_notices, "|");
 937     if(argc > 0)
 938     {
 939         float i;
 940         for(i = argc - 1; i >= 0; --i)
 941             sv_notice_to(self, argv(i), autocvar_sv_join_notices_time, FALSE);
 942     }
 943
 944         //if(g_ctf)
 945         //      ctf_playerchanged();
 946 }
 947
 948 .float ebouncefactor, ebouncestop; // electro's values
 949 // TODO do we need all these fields, or should we stop autodetecting runtime
 950 // changes and just have a console command to update this?
 951 float ClientInit_SendEntity(entity to, float sf)
 952 {
 953         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 954         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 955         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 956         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 957         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 958         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 959         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 960         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 961         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 962         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 963         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 964         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 965         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 966         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 967         if(sv_foginterval && world.fog != "")
 968                 WriteString(MSG_ENTITY, world.fog);
 969         else
 970                 WriteString(MSG_ENTITY, "");
 971         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 972         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 973         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 974         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 975         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 976         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 977         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 978         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 979         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 980         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 981         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 982         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 983         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 984         return TRUE;
 985 }
 986
 987 void ClientInit_CheckUpdate()
 988 {
 989         self.nextthink = time;
 990         if(self.count != autocvar_g_balance_armor_blockpercent)
 991         {
 992                 self.count = autocvar_g_balance_armor_blockpercent;
 993                 self.SendFlags |= 1;
 994         }
 995         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 996         {
 997                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 998                 self.SendFlags |= 1;
 999         }
1000         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1001         {
1002                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1003                 self.SendFlags |= 1;
1004         }
1005         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1006         {
1007                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1008                 self.SendFlags |= 1;
1009         }
1010         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1011         {
1012                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1013                 self.SendFlags |= 1;
1014         }
1015         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1016         {
1017                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1018                 self.SendFlags |= 1;
1019         }
1020 }
1021
1022 void ClientInit_Spawn()
1023 {
1024         entity o;
1025         entity e;
1026         e = spawn();
1027         e.classname = "clientinit";
1028         e.think = ClientInit_CheckUpdate;
1029         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1030
1031         o = self;
1032         self = e;
1033         ClientInit_CheckUpdate();
1034         self = o;
1035 }
1036
1037 /*
1038 =============
1039 SetNewParms
1040 =============
1041 */
1042 void SetNewParms (void)
1043 {
1044         // initialize parms for a new player
1045         parm1 = -(86400 * 366);
1046 }
1047
1048 /*
1049 =============
1050 SetChangeParms
1051 =============
1052 */
1053 void SetChangeParms (void)
1054 {
1055         // save parms for level change
1056         parm1 = self.parm_idlesince - time;
1057 }
1058
1059 /*
1060 =============
1061 DecodeLevelParms
1062 =============
1063 */
1064 void DecodeLevelParms (void)
1065 {
1066         // load parms
1067         self.parm_idlesince = parm1;
1068         if(self.parm_idlesince == -(86400 * 366))
1069                 self.parm_idlesince = time;
1070
1071         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1072         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1073 }
1074
1075 /*
1076 =============
1077 ClientKill
1078
1079 Called when a client types 'kill' in the console
1080 =============
1081 */
1082
1083 .float clientkill_nexttime;
1084 void ClientKill_Now_TeamChange()
1085 {
1086         if(self.killindicator_teamchange == -1)
1087         {
1088                 self.team = -1;
1089                 JoinBestTeam( self, FALSE, FALSE );
1090         }
1091         else if(self.killindicator_teamchange == -2)
1092         {
1093                 if(g_ca)
1094                         self.caplayer = 0;
1095                 if(blockSpectators)
1096                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1097                 PutObserverInServer();
1098         }
1099         else
1100                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1101 }
1102
1103 void ClientKill_Now()
1104 {
1105         if(self.vehicle)
1106         {
1107             vehicles_exit(VHEF_RELESE);
1108             if(!self.killindicator_teamchange)
1109             {
1110             self.vehicle_health = -1;
1111             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1112             }
1113         }
1114
1115         if(self.killindicator && !wasfreed(self.killindicator))
1116                 remove(self.killindicator);
1117
1118         self.killindicator = world;
1119
1120         if(self.killindicator_teamchange)
1121                 ClientKill_Now_TeamChange();
1122
1123         // in any case:
1124         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1125
1126         // now I am sure the player IS dead
1127 }
1128 void KillIndicator_Think()
1129 {
1130         if (gameover)
1131         {
1132                 self.owner.killindicator = world;
1133                 remove(self);
1134                 return;
1135         }
1136
1137         if (self.owner.alpha < 0)
1138         {
1139                 self.owner.killindicator = world;
1140                 remove(self);
1141                 return;
1142         }
1143
1144         if(self.cnt <= 0)
1145         {
1146                 self = self.owner;
1147                 ClientKill_Now(); // no oldself needed
1148                 return;
1149         }
1150     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1151     {
1152         self.nextthink = time + 1;
1153         self.cnt -= 1;
1154     }
1155         else
1156         {
1157                 if(self.cnt <= 10)
1158                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1159                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1160                 {
1161                         if(self.cnt <= 10)
1162                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1163                 }
1164                 self.nextthink = time + 1;
1165                 self.cnt -= 1;
1166         }
1167 }
1168
1169 float clientkilltime;
1170 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1171 {
1172         float killtime;
1173         float starttime;
1174         entity e;
1175
1176         if (gameover)
1177                 return;
1178
1179         killtime = autocvar_g_balance_kill_delay;
1180
1181         if(g_race_qualifying || g_cts)
1182                 killtime = 0;
1183
1184     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1185     {
1186                 remove(self.killindicator);
1187                 self.killindicator = world;
1188
1189         ClientKill_Now(); // allow instant kill in this case
1190         return;
1191     }
1192
1193         self.killindicator_teamchange = targetteam;
1194
1195     if(!self.killindicator)
1196         {
1197                 if(self.deadflag == DEAD_NO)
1198                 {
1199                         killtime = max(killtime, self.clientkill_nexttime - time);
1200                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1201                 }
1202
1203                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1204                 {
1205                         ClientKill_Now();
1206                 }
1207                 else
1208                 {
1209                         starttime = max(time, clientkilltime);
1210
1211                         self.killindicator = spawn();
1212                         self.killindicator.owner = self;
1213                         self.killindicator.scale = 0.5;
1214                         setattachment(self.killindicator, self, "");
1215                         setorigin(self.killindicator, '0 0 52');
1216                         self.killindicator.think = KillIndicator_Think;
1217                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1218                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1219                         self.killindicator.cnt = ceil(killtime);
1220                         self.killindicator.count = bound(0, ceil(killtime), 10);
1221                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1222
1223                         for(e = world; (e = find(e, classname, "body")) != world; )
1224                         {
1225                                 if(e.enemy != self)
1226                                         continue;
1227                                 e.killindicator = spawn();
1228                                 e.killindicator.owner = e;
1229                                 e.killindicator.scale = 0.5;
1230                                 setattachment(e.killindicator, e, "");
1231                                 setorigin(e.killindicator, '0 0 52');
1232                                 e.killindicator.think = KillIndicator_Think;
1233                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1234                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1235                                 e.killindicator.cnt = ceil(killtime);
1236                         }
1237                         self.lip = 0;
1238                 }
1239         }
1240         if(self.killindicator)
1241         {
1242                 if(targetteam == 0) // just die
1243                 {
1244                         self.killindicator.colormod = '0 0 0';
1245                         if(clienttype(self) == CLIENTTYPE_REAL)
1246                         if(self.killindicator.cnt > 0)
1247                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1248                 }
1249                 else if(targetteam == -1) // auto
1250                 {
1251                         self.killindicator.colormod = '0 1 0';
1252                         if(clienttype(self) == CLIENTTYPE_REAL)
1253                         if(self.killindicator.cnt > 0)
1254                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1255                 }
1256                 else if(targetteam == -2) // spectate
1257                 {
1258                         self.killindicator.colormod = '0.5 0.5 0.5';
1259                         if(clienttype(self) == CLIENTTYPE_REAL)
1260                         if(self.killindicator.cnt > 0)
1261                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1262                 }
1263                 else
1264                 {
1265                         self.killindicator.colormod = TeamColor(targetteam);
1266                         if(clienttype(self) == CLIENTTYPE_REAL)
1267                         if(self.killindicator.cnt > 0)
1268                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1269                 }
1270         }
1271
1272 }
1273
1274 void ClientKill (void)
1275 {
1276         if (gameover)
1277                 return;
1278
1279         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1280         {
1281                 // do nothing
1282         }
1283     else if(self.freezetag_frozen)
1284     {
1285         // do nothing
1286     }
1287         else
1288                 ClientKill_TeamChange(0);
1289 }
1290
1291 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1292 {
1293     e.killindicator = spawn();
1294     e.killindicator.owner = e;
1295     e.killindicator.think = KillIndicator_Think;
1296     e.killindicator.nextthink = time + (e.lip) * 0.05;
1297     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1298     e.killindicator.health = 1; // this is used to indicate that it should be silent
1299     e.lip = 0;
1300 }
1301
1302 void FixClientCvars(entity e)
1303 {
1304         // send prediction settings to the client
1305         stuffcmd(e, "\nin_bindmap 0 0\n");
1306         if(g_race || g_cts)
1307                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1308         if(autocvar_g_antilag == 3) // client side hitscan
1309                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1310         if(sv_gentle)
1311                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1312         /*
1313          * we no longer need to stuff this. Remove this comment block if you feel
1314          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1315         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1316         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1317         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1318         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1319         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1320         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1321         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1322         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1323         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1324         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1325         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1326         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1327         stuffcmd(e, "cl_movement_edgefriction 1\n");
1328          */
1329 }
1330
1331 float PlayerInIDList(entity p, string idlist)
1332 {
1333         float n, i;
1334         string s;
1335
1336         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1337         if not(p.crypto_idfp)
1338                 return 0;
1339
1340         // this function allows abbreviated player IDs too!
1341         n = tokenize_console(idlist);
1342         for(i = 0; i < n; ++i)
1343         {
1344                 s = argv(i);
1345                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1346                         return 1;
1347         }
1348
1349         return 0;
1350 }
1351
1352 /*
1353 =============
1354 ClientConnect
1355
1356 Called when a client connects to the server
1357 =============
1358 */
1359 //void ctf_clientconnect();
1360 string ColoredTeamName(float t);
1361 void DecodeLevelParms (void);
1362 //void dom_player_join_team(entity pl);
1363 void set_dom_state(entity e);
1364 void ClientConnect (void)
1365 {
1366         float t;
1367
1368         if(self.flags & FL_CLIENT)
1369         {
1370                 print("Warning: ClientConnect, but already connected!\n");
1371                 return;
1372         }
1373
1374         if(Ban_MaybeEnforceBan(self))
1375                 return;
1376
1377         DecodeLevelParms();
1378
1379 #ifdef WATERMARK
1380         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1381 #endif
1382
1383         self.classname = "player_joining";
1384
1385         self.flags = FL_CLIENT;
1386         self.version_nagtime = time + 10 + random() * 10;
1387
1388         if(player_count<0)
1389         {
1390                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1391                 player_count = 0;
1392         }
1393
1394         PlayerScore_Attach(self);
1395         ClientData_Attach();
1396         accuracy_init(self);
1397
1398         bot_clientconnect();
1399
1400         playerdemo_init();
1401
1402         anticheat_init();
1403
1404         race_PreSpawnObserver();
1405
1406         //if(g_domination)
1407         //      dom_player_join_team(self);
1408
1409         // identify the right forced team
1410         if(autocvar_g_campaign)
1411         {
1412                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1413                 {
1414                         switch(autocvar_g_campaign_forceteam)
1415                         {
1416                                 case 1: self.team_forced = COLOR_TEAM1; break;
1417                                 case 2: self.team_forced = COLOR_TEAM2; break;
1418                                 case 3: self.team_forced = COLOR_TEAM3; break;
1419                                 case 4: self.team_forced = COLOR_TEAM4; break;
1420                                 default: self.team_forced = 0;
1421                         }
1422                 }
1423         }
1424         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1425                 self.team_forced = COLOR_TEAM1;
1426         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1427                 self.team_forced = COLOR_TEAM2;
1428         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1429                 self.team_forced = COLOR_TEAM3;
1430         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1431                 self.team_forced = COLOR_TEAM4;
1432         else if(autocvar_g_forced_team_otherwise == "red")
1433                 self.team_forced = COLOR_TEAM1;
1434         else if(autocvar_g_forced_team_otherwise == "blue")
1435                 self.team_forced = COLOR_TEAM2;
1436         else if(autocvar_g_forced_team_otherwise == "yellow")
1437                 self.team_forced = COLOR_TEAM3;
1438         else if(autocvar_g_forced_team_otherwise == "pink")
1439                 self.team_forced = COLOR_TEAM4;
1440         else if(autocvar_g_forced_team_otherwise == "spectate")
1441                 self.team_forced = -1;
1442         else if(autocvar_g_forced_team_otherwise == "spectator")
1443                 self.team_forced = -1;
1444         else
1445                 self.team_forced = 0;
1446
1447         if(!teamplay)
1448                 if(self.team_forced > 0)
1449                         self.team_forced = 0;
1450
1451         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1452
1453         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1454                 self.classname = "observer";
1455         } else {
1456                 if(teamplay)
1457                 {
1458                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1459                         {
1460                                 self.classname = "player";
1461                                 campaign_bots_may_start = 1;
1462                         }
1463                         else
1464                         {
1465                                 self.classname = "observer"; // do it anyway
1466                         }
1467                 }
1468                 else
1469                 {
1470                         self.classname = "player";
1471                         campaign_bots_may_start = 1;
1472                 }
1473         }
1474
1475         self.playerid = (playerid_last = playerid_last + 1);
1476
1477         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1478
1479     if(clienttype(self) == CLIENTTYPE_BOT)
1480         PlayerStats_AddPlayer(self);
1481
1482         if(autocvar_sv_eventlog)
1483                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1484
1485         LogTeamchange(self.playerid, self.team, 1);
1486
1487         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1488
1489         self.netname_previous = strzone(self.netname);
1490
1491         bprint("^4", self.netname, "^4 connected");
1492
1493         if(self.classname != "observer" && (g_domination || g_ctf))
1494                 bprint(" and joined the ", ColoredTeamName(self.team));
1495
1496         bprint("\n");
1497
1498         stuffcmd(self, strcat(clientstuff, "\n"));
1499         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1500
1501         FixClientCvars(self);
1502
1503         // spawnfunc_waypoint sprites
1504         WaypointSprite_InitClient(self);
1505
1506         // Wazat's grappling hook
1507         SetGrappleHookBindings();
1508
1509         // get version info from player
1510         stuffcmd(self, "cmd clientversion $gameversion\n");
1511
1512         // get other cvars from player
1513         GetCvars(0);
1514
1515         // notify about available teams
1516         if(teamplay)
1517         {
1518                 CheckAllowedTeams(self);
1519                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1520                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1521         }
1522         else
1523                 stuffcmd(self, "set _teams_available 0\n");
1524
1525         if(g_arena || g_ca)
1526         {
1527                 self.classname = "observer";
1528                 if(g_arena)
1529                         Spawnqueue_Insert(self);
1530         }
1531         /*else if(g_ctf)
1532         {
1533                 ctf_clientconnect();
1534         }*/
1535
1536         attach_entcs();
1537
1538         bot_relinkplayerlist();
1539
1540         self.spectatortime = time;
1541         if(blockSpectators)
1542         {
1543                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1544         }
1545
1546         self.jointime = time;
1547         self.allowed_timeouts = autocvar_sv_timeout_number;
1548
1549         if(clienttype(self) == CLIENTTYPE_REAL)
1550         {
1551                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1552                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1553         }
1554
1555         if(g_lms)
1556         {
1557                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1558                 {
1559                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1560                         self.frags = FRAGS_SPECTATOR;
1561                 }
1562         }
1563
1564         if(!sv_foginterval && world.fog != "")
1565                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1566
1567         SoundEntity_Attach(self);
1568
1569         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1570         {
1571                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1572                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1573         }
1574         else
1575                 self.hitplotfh = -1;
1576
1577         if(g_race || g_cts) {
1578                 string rr;
1579                 if(g_cts)
1580                         rr = CTS_RECORD;
1581                 else
1582                         rr = RACE_RECORD;
1583                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1584
1585                 msg_entity = self;
1586                 race_send_recordtime(MSG_ONE);
1587                 race_send_speedaward(MSG_ONE);
1588
1589                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1590                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1591                 race_send_speedaward_alltimebest(MSG_ONE);
1592
1593                 float i;
1594                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1595                         race_SendRankings(i, 0, 0, MSG_ONE);
1596                 }
1597         }
1598         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1599                 send_CSQC_teamnagger();
1600
1601         if (g_domination)
1602                 set_dom_state(self);
1603
1604         CheatInitClient();
1605
1606         if(!autocvar_g_campaign)
1607                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1608
1609         CSQCMODEL_AUTOINIT();
1610
1611         self.model_randomizer = random();
1612 }
1613
1614 /*
1615 =============
1616 ClientDisconnect
1617
1618 Called when a client disconnects from the server
1619 =============
1620 */
1621 .entity chatbubbleentity;
1622 void ReadyCount();
1623 void ClientDisconnect (void)
1624 {
1625         if(self.vehicle)
1626             vehicles_exit(VHEF_RELESE);
1627
1628         if not(self.flags & FL_CLIENT)
1629         {
1630                 print("Warning: ClientDisconnect without ClientConnect\n");
1631                 return;
1632         }
1633
1634         PlayerStats_AddGlobalInfo(self);
1635
1636         CheatShutdownClient();
1637
1638         if(self.hitplotfh >= 0)
1639         {
1640                 fclose(self.hitplotfh);
1641                 self.hitplotfh = -1;
1642         }
1643
1644         anticheat_report();
1645         anticheat_shutdown();
1646
1647         playerdemo_shutdown();
1648
1649         bot_clientdisconnect();
1650
1651         if(self.entcs)
1652                 detach_entcs();
1653
1654         if(autocvar_sv_eventlog)
1655                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1656         bprint ("^4",self.netname);
1657         bprint ("^4 disconnected\n");
1658
1659         SoundEntity_Detach(self);
1660
1661         DropAllRunes(self);
1662         MUTATOR_CALLHOOK(ClientDisconnect);
1663
1664         Portal_ClearAll(self);
1665
1666         RemoveGrapplingHook(self);
1667         if(self.flagcarried)
1668                 DropFlag(self.flagcarried, world, world);
1669         if(self.ballcarried && g_nexball)
1670                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1671
1672         // Here, everything has been done that requires this player to be a client.
1673
1674         self.flags &~= FL_CLIENT;
1675
1676         if (self.chatbubbleentity)
1677                 remove (self.chatbubbleentity);
1678
1679         if (self.killindicator)
1680                 remove (self.killindicator);
1681
1682         WaypointSprite_PlayerGone();
1683
1684         bot_relinkplayerlist();
1685
1686         if(g_arena)
1687         {
1688                 Spawnqueue_Unmark(self);
1689                 Spawnqueue_Remove(self);
1690         }
1691
1692         accuracy_free(self);
1693         ClientData_Detach();
1694         PlayerScore_Detach(self);
1695
1696         if(self.netname_previous)
1697                 strunzone(self.netname_previous);
1698         if(self.clientstatus)
1699                 strunzone(self.clientstatus);
1700         if(self.weaponorder_byimpulse)
1701                 strunzone(self.weaponorder_byimpulse);
1702
1703         ClearPlayerSounds();
1704
1705         if(self.personal)
1706                 remove(self.personal);
1707
1708         self.playerid = 0;
1709         ReadyCount();
1710
1711         // free cvars
1712         GetCvars(-1);
1713 }
1714
1715 .float BUTTON_CHAT;
1716 void ChatBubbleThink()
1717 {
1718         self.nextthink = time;
1719         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1720         {
1721                 if(self.owner) // but why can that ever be world?
1722                         self.owner.chatbubbleentity = world;
1723                 remove(self);
1724                 return;
1725         }
1726         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1727 #ifdef TETRIS
1728                 || self.owner.tetris_on
1729 #endif
1730         )
1731                 self.model = self.mdl;
1732         else
1733                 self.model = "";
1734 }
1735
1736 void UpdateChatBubble()
1737 {
1738         if (self.alpha < 0)
1739                 return;
1740         // spawn a chatbubble entity if needed
1741         if (!self.chatbubbleentity)
1742         {
1743                 self.chatbubbleentity = spawn();
1744                 self.chatbubbleentity.owner = self;
1745                 self.chatbubbleentity.exteriormodeltoclient = self;
1746                 self.chatbubbleentity.think = ChatBubbleThink;
1747                 self.chatbubbleentity.nextthink = time;
1748                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1749                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1750                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1751                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1752                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1753                 self.chatbubbleentity.model = "";
1754                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1755         }
1756 }
1757
1758
1759 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1760 // added to the model skins
1761 /*void UpdateColorModHack()
1762 {
1763         float c;
1764         c = self.clientcolors & 15;
1765         // LordHavoc: only bothering to support white, green, red, yellow, blue
1766              if (!teamplay) self.colormod = '0 0 0';
1767         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1768         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1769         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1770         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1771         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1772         else self.colormod = '1 1 1';
1773 }*/
1774
1775 void respawn(void)
1776 {
1777         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1778         {
1779                 self.solid = SOLID_NOT;
1780                 self.takedamage = DAMAGE_NO;
1781                 self.movetype = MOVETYPE_FLY;
1782                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1783                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1784                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1785                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1786                 if(autocvar_g_respawn_ghosts_maxtime)
1787                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1788         }
1789
1790         CopyBody(1);
1791
1792         self.effects |= EF_NODRAW; // prevent another CopyBody
1793         PutClientInServer();
1794 }
1795
1796 void play_countdown(float finished, string samp)
1797 {
1798         if(clienttype(self) == CLIENTTYPE_REAL)
1799                 if(floor(finished - time - frametime) != floor(finished - time))
1800                         if(finished - time < 6)
1801                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1802 }
1803
1804 void player_powerups (void)
1805 {
1806         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1807         olditems = self.items;
1808
1809         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1810         {
1811                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1812                 self.modelflags |= MF_ROCKET;
1813         }
1814         else
1815         {
1816                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1817                 self.modelflags &~= MF_ROCKET;
1818         }
1819
1820         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1821
1822         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1823                 return;
1824
1825         Fire_ApplyDamage(self);
1826         Fire_ApplyEffect(self);
1827
1828         if (g_minstagib)
1829         {
1830                 self.effects |= EF_FULLBRIGHT;
1831
1832                 if (self.items & IT_STRENGTH)
1833                 {
1834                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1835                         if (time > self.strength_finished)
1836                         {
1837                                 self.alpha = default_player_alpha;
1838                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1839                                 self.items &~= IT_STRENGTH;
1840                                 sprint(self, "^3Invisibility has worn off\n");
1841                         }
1842                 }
1843                 else
1844                 {
1845                         if (time < self.strength_finished)
1846                         {
1847                                 self.alpha = g_minstagib_invis_alpha;
1848                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1849                                 self.items |= IT_STRENGTH;
1850                                 sprint(self, "^3You are invisible\n");
1851                         }
1852                 }
1853
1854                 if (self.items & IT_INVINCIBLE)
1855                 {
1856                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1857                         if (time > self.invincible_finished)
1858                         {
1859                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1860                                 sprint(self, "^3Speed has worn off\n");
1861                         }
1862                 }
1863                 else
1864                 {
1865                         if (time < self.invincible_finished)
1866                         {
1867                                 self.items = self.items | IT_INVINCIBLE;
1868                                 sprint(self, "^3You are on speed\n");
1869                         }
1870                 }
1871         }
1872         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1873         {
1874                 if (self.items & IT_STRENGTH)
1875                 {
1876                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1877                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1878                         if (time > self.strength_finished)
1879                         {
1880                                 self.items = self.items - (self.items & IT_STRENGTH);
1881                                 sprint(self, "^3Strength has worn off\n");
1882                         }
1883                 }
1884                 else
1885                 {
1886                         if (time < self.strength_finished)
1887                         {
1888                                 self.items = self.items | IT_STRENGTH;
1889                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1890                         }
1891                 }
1892                 if (self.items & IT_INVINCIBLE)
1893                 {
1894                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1895                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1896                         if (time > self.invincible_finished)
1897                         {
1898                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1899                                 sprint(self, "^3Shield has worn off\n");
1900                         }
1901                 }
1902                 else
1903                 {
1904                         if (time < self.invincible_finished)
1905                         {
1906                                 self.items = self.items | IT_INVINCIBLE;
1907                                 sprint(self, "^3Shield surrounds you\n");
1908                         }
1909                 }
1910                 if (self.items & IT_SUPERWEAPON)
1911                 {
1912                         //if(W_WeaponBit(self.weapon) & WEPBIT_SUPERWEAPONS)
1913                         //      self.effects = self.effects | EF_RED;
1914                         if (!(self.weapons & WEPBIT_SUPERWEAPONS))
1915                         {
1916                                 self.superweapons_finished = 0;
1917                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1918                                 sprint(self, "^3Superweapons have been lost\n");
1919                         }
1920                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1921                         {
1922                                 // don't let them run out
1923                         }
1924                         else
1925                         {
1926                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1927                                 if (time > self.superweapons_finished)
1928                                 {
1929                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1930                                         self.weapons &~= WEPBIT_SUPERWEAPONS;
1931                                         sprint(self, "^3Superweapons have broken down\n");
1932                                 }
1933                         }
1934                 }
1935                 else if(self.weapons & WEPBIT_SUPERWEAPONS)
1936                 {
1937                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1938                         {
1939                                 self.items = self.items | IT_SUPERWEAPON;
1940                                 sprint(self, "^3You now have a superweapon\n");
1941                         }
1942                         else
1943                         {
1944                                 self.superweapons_finished = 0;
1945                                 self.weapons &~= WEPBIT_SUPERWEAPONS; // just in case
1946                         }
1947                 }
1948                 else
1949                 {
1950                         self.superweapons_finished = 0;
1951                 }
1952         }
1953
1954         if(autocvar_g_nodepthtestplayers)
1955                 self.effects = self.effects | EF_NODEPTHTEST;
1956
1957         if(autocvar_g_fullbrightplayers)
1958                 self.effects = self.effects | EF_FULLBRIGHT;
1959
1960         // midair gamemode: damage only while in the air
1961         // if in midair mode, being on ground grants temporary invulnerability
1962         // (this is so that multishot weapon don't clear the ground flag on the
1963         // first damage in the frame, leaving the player vulnerable to the
1964         // remaining hits in the same frame)
1965         if (self.flags & FL_ONGROUND)
1966         if (g_midair)
1967                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1968
1969         if (time >= game_starttime)
1970         if (time < self.spawnshieldtime)
1971                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1972
1973         MUTATOR_CALLHOOK(PlayerPowerups);
1974 }
1975
1976 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1977 {
1978         if(current > stable)
1979                 return current;
1980         else if(current > stable - 0.25) // when close enough, "snap"
1981                 return stable;
1982         else
1983                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1984 }
1985
1986 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1987 {
1988         if(current < stable)
1989                 return current;
1990         else if(current < stable + 0.25) // when close enough, "snap"
1991                 return stable;
1992         else
1993                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1994 }
1995
1996 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1997 {
1998         if(current > rotstable)
1999         {
2000                 if(rotframetime > 0)
2001                 {
2002                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2003                         current = max(rotstable, current - rotlinear * rotframetime);
2004                 }
2005         }
2006         else if(current < regenstable)
2007         {
2008                 if(regenframetime > 0)
2009                 {
2010                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2011                         current = min(regenstable, current + regenlinear * regenframetime);
2012                 }
2013         }
2014
2015         if(current > limit)
2016                 current = limit;
2017
2018         return current;
2019 }
2020
2021 void player_regen (void)
2022 {
2023         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2024         maxh = autocvar_g_balance_health_rotstable;
2025         maxa = autocvar_g_balance_armor_rotstable;
2026         maxf = autocvar_g_balance_fuel_rotstable;
2027         minh = autocvar_g_balance_health_regenstable;
2028         mina = autocvar_g_balance_armor_regenstable;
2029         minf = autocvar_g_balance_fuel_regenstable;
2030         limith = autocvar_g_balance_health_limit;
2031         limita = autocvar_g_balance_armor_limit;
2032         limitf = autocvar_g_balance_fuel_limit;
2033
2034         max_mod = regen_mod = rot_mod = limit_mod = 1;
2035
2036         if (self.runes & RUNE_REGEN)
2037         {
2038                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2039                 {
2040                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2041                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2042                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2043                 }
2044                 else
2045                 {
2046                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2047                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2048                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2049                 }
2050         }
2051         else if (self.runes & CURSE_VENOM)
2052         {
2053                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2054                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2055                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2056                 else
2057                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2058                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2059                 //if (!self.runes & RUNE_REGEN)
2060                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2061         }
2062         maxh = maxh * max_mod;
2063         //maxa = maxa * max_mod;
2064         //maxf = maxf * max_mod;
2065         minh = minh * max_mod;
2066         //mina = mina * max_mod;
2067         //minf = minf * max_mod;
2068         limith = limith * limit_mod;
2069         limita = limita * limit_mod;
2070         //limitf = limitf * limit_mod;
2071
2072         if(g_lms && g_ca)
2073                 rot_mod = 0;
2074
2075         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2076         {
2077                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2078                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2079
2080                 // if player rotted to death...  die!
2081                 if(self.health < 1)
2082                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2083         }
2084
2085         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2086                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2087 }
2088
2089 float zoomstate_set;
2090 void SetZoomState(float z)
2091 {
2092         if(z != self.zoomstate)
2093         {
2094                 self.zoomstate = z;
2095                 ClientData_Touch(self);
2096         }
2097         zoomstate_set = 1;
2098 }
2099
2100 void GetPressedKeys(void) {
2101         MUTATOR_CALLHOOK(GetPressedKeys);
2102         if (self.movement_x > 0) // get if movement keys are pressed
2103         {       // forward key pressed
2104                 self.pressedkeys |= KEY_FORWARD;
2105                 self.pressedkeys &~= KEY_BACKWARD;
2106         }
2107         else if (self.movement_x < 0)
2108         {       // backward key pressed
2109                 self.pressedkeys |= KEY_BACKWARD;
2110                 self.pressedkeys &~= KEY_FORWARD;
2111         }
2112         else
2113         {       // no x input
2114                 self.pressedkeys &~= KEY_FORWARD;
2115                 self.pressedkeys &~= KEY_BACKWARD;
2116         }
2117
2118         if (self.movement_y > 0)
2119         {       // right key pressed
2120                 self.pressedkeys |= KEY_RIGHT;
2121                 self.pressedkeys &~= KEY_LEFT;
2122         }
2123         else if (self.movement_y < 0)
2124         {       // left key pressed
2125                 self.pressedkeys |= KEY_LEFT;
2126                 self.pressedkeys &~= KEY_RIGHT;
2127         }
2128         else
2129         {       // no y input
2130                 self.pressedkeys &~= KEY_RIGHT;
2131                 self.pressedkeys &~= KEY_LEFT;
2132         }
2133
2134         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2135                 self.pressedkeys |= KEY_JUMP;
2136         else
2137                 self.pressedkeys &~= KEY_JUMP;
2138         if (self.BUTTON_CROUCH)
2139                 self.pressedkeys |= KEY_CROUCH;
2140         else
2141                 self.pressedkeys &~= KEY_CROUCH;
2142 }
2143
2144 /*
2145 ======================
2146 spectate mode routines
2147 ======================
2148 */
2149
2150 void SpectateCopy(entity spectatee) {
2151         other = spectatee;
2152         MUTATOR_CALLHOOK(SpectateCopy);
2153         self.armortype = spectatee.armortype;
2154         self.armorvalue = spectatee.armorvalue;
2155         self.ammo_cells = spectatee.ammo_cells;
2156         self.ammo_shells = spectatee.ammo_shells;
2157         self.ammo_nails = spectatee.ammo_nails;
2158         self.ammo_rockets = spectatee.ammo_rockets;
2159         self.ammo_fuel = spectatee.ammo_fuel;
2160         self.clip_load = spectatee.clip_load;
2161         self.clip_size = spectatee.clip_size;
2162         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2163         self.health = spectatee.health;
2164         self.impulse = 0;
2165         self.items = spectatee.items;
2166         self.last_pickup = spectatee.last_pickup;
2167         self.hit_time = spectatee.hit_time;
2168         self.metertime = spectatee.metertime;
2169         self.strength_finished = spectatee.strength_finished;
2170         self.invincible_finished = spectatee.invincible_finished;
2171         self.pressedkeys = spectatee.pressedkeys;
2172         self.weapons = spectatee.weapons;
2173         self.switchweapon = spectatee.switchweapon;
2174         self.switchingweapon = spectatee.switchingweapon;
2175         self.weapon = spectatee.weapon;
2176         self.nex_charge = spectatee.nex_charge;
2177         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2178         self.hagar_load = spectatee.hagar_load;
2179         self.minelayer_mines = spectatee.minelayer_mines;
2180         self.punchangle = spectatee.punchangle;
2181         self.view_ofs = spectatee.view_ofs;
2182         self.v_angle = spectatee.v_angle;
2183         self.velocity = spectatee.velocity;
2184         self.dmg_take = spectatee.dmg_take;
2185         self.dmg_save = spectatee.dmg_save;
2186         self.dmg_inflictor = spectatee.dmg_inflictor;
2187         self.angles = spectatee.v_angle;
2188         if(!self.BUTTON_USE)
2189                 self.fixangle = TRUE;
2190         setorigin(self, spectatee.origin);
2191         setsize(self, spectatee.mins, spectatee.maxs);
2192         SetZoomState(spectatee.zoomstate);
2193
2194         anticheat_spectatecopy(spectatee);
2195
2196         //self.vehicle = spectatee.vehicle;
2197
2198         self.hud = spectatee.hud;
2199         if(spectatee.vehicle)
2200     {
2201         setorigin(self, spectatee.origin);
2202         self.velocity = spectatee.vehicle.velocity;
2203         self.v_angle += spectatee.vehicle.angles;
2204         //self.v_angle_x *= -1;
2205         self.vehicle_health = spectatee.vehicle_health;
2206         self.vehicle_shield = spectatee.vehicle_shield;
2207         self.vehicle_energy = spectatee.vehicle_energy;
2208         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2209         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2210         self.vehicle_reload1 = spectatee.vehicle_reload1;
2211         self.vehicle_reload2 = spectatee.vehicle_reload2;
2212
2213         msg_entity = self;
2214         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2215         WriteEntity(MSG_ONE, spectatee);
2216         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2217     }
2218 }
2219
2220 float SpectateUpdate() {
2221         if(!self.enemy)
2222             return 0;
2223
2224         if (self == self.enemy)
2225                 return 0;
2226
2227         if(self.enemy.classname != "player")
2228                 return 0;
2229
2230         SpectateCopy(self.enemy);
2231
2232         return 1;
2233 }
2234
2235
2236 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2237 entity CA_SpectateNext(entity start) {
2238         if (start.team == self.team) {
2239                 return start;
2240         }
2241
2242         other = start;
2243         // continue from current player
2244         while(other && other.team != self.team) {
2245                 other = find(other, classname, "player");
2246         }
2247
2248         if (!other) {
2249                 // restart from begining
2250                 other = find(other, classname, "player");
2251                 while(other && other.team != self.team) {
2252                         other = find(other, classname, "player");
2253                 }
2254         }
2255
2256         return other;
2257 }
2258
2259 float SpectateNext() {
2260         other = find(self.enemy, classname, "player");
2261         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2262                 // CA and ca players when spectating enemies is forbidden
2263                 other = CA_SpectateNext(other);
2264         } else {
2265                 // other modes and ca spectators or spectating enemies is allowed
2266                 if (!other)
2267                         other = find(other, classname, "player");
2268         }
2269
2270         if (other)
2271                 self.enemy = other;
2272
2273         if(self.enemy.classname == "player") {
2274             if(self.enemy.vehicle)
2275             {
2276             msg_entity = self;
2277             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2278             WriteEntity(MSG_ONE, self.enemy);
2279             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2280             self.movetype = MOVETYPE_NONE;
2281             accuracy_resend(self);
2282             }
2283             else
2284             {
2285             msg_entity = self;
2286             WriteByte(MSG_ONE, SVC_SETVIEW);
2287             WriteEntity(MSG_ONE, self.enemy);
2288             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2289             self.movetype = MOVETYPE_NONE;
2290             accuracy_resend(self);
2291
2292             if(!SpectateUpdate())
2293                 PutObserverInServer();
2294         }
2295         return 1;
2296         } else {
2297                 return 0;
2298         }
2299 }
2300
2301 /*
2302 =============
2303 ShowRespawnCountdown()
2304
2305 Update a respawn countdown display.
2306 =============
2307 */
2308 void ShowRespawnCountdown()
2309 {
2310         float number;
2311         if(self.deadflag == DEAD_NO) // just respawned?
2312                 return;
2313         else
2314         {
2315                 number = ceil(self.respawn_time - time);
2316                 if(number <= 0)
2317                         return;
2318                 if(number <= self.respawn_countdown)
2319                 {
2320                         self.respawn_countdown = number - 1;
2321                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2322                                 AnnounceTo(self, strcat(ftos(number), ""));
2323                 }
2324         }
2325 }
2326
2327 .float prevent_join_msgtime;
2328 void LeaveSpectatorMode()
2329 {
2330         if(nJoinAllowed(self)) {
2331                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2332                         self.classname = "player";
2333
2334                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2335                                 JoinBestTeam(self, FALSE, TRUE);
2336
2337                         if(autocvar_g_campaign)
2338                                 campaign_bots_may_start = 1;
2339
2340                         PutClientInServer();
2341
2342                         if(self.classname == "player")
2343                                 bprint ("^4", self.netname, "^4 is playing now\n");
2344
2345                         if(!autocvar_g_campaign)
2346                         if (time < self.jointime + autocvar_welcome_message_time)
2347                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2348
2349                         if (self.prevent_join_msgtime)
2350                         {
2351                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2352                                 self.prevent_join_msgtime = 0;
2353                         }
2354
2355                         return;
2356                 } else {
2357                         if (g_ca && self.caplayer) {
2358                         }       // do nothing
2359                         else
2360                                 stuffcmd(self,"menu_showteamselect\n");
2361                         return;
2362                 }
2363         }
2364         else {
2365                 //player may not join because of g_maxplayers is set
2366                 if (time - self.prevent_join_msgtime > 2)
2367                 {
2368                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2369                         self.prevent_join_msgtime = time;
2370                 }
2371         }
2372 }
2373
2374 /**
2375  * Determines whether the player is allowed to join. This depends on cvar
2376  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2377  * it checks whether the number of currently playing players exceeds g_maxplayers.
2378  * @return int number of free slots for players, 0 if none
2379  */
2380 float nJoinAllowed(entity ignore) {
2381         if(!ignore)
2382         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2383         // so report 0 free slots if restricted
2384         {
2385                 if(autocvar_g_forced_team_otherwise == "spectate")
2386                         return 0;
2387                 if(autocvar_g_forced_team_otherwise == "spectator")
2388                         return 0;
2389         }
2390
2391         if(self.team_forced < 0)
2392                 return 0; // forced spectators can never join
2393
2394         // TODO simplify this
2395         entity e;
2396         float totalClients;
2397         FOR_EACH_CLIENT(e)
2398                 if(e != ignore)
2399                         totalClients += 1;
2400
2401         if (!autocvar_g_maxplayers)
2402                 return maxclients - totalClients;
2403
2404         float currentlyPlaying;
2405         FOR_EACH_REALPLAYER(e)
2406                 currentlyPlaying += 1;
2407
2408         if(currentlyPlaying < autocvar_g_maxplayers)
2409                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2410
2411         return 0;
2412 }
2413
2414 /**
2415  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2416  * g_maxplayers_spectator_blocktime seconds
2417  */
2418 void checkSpectatorBlock() {
2419         if(self.classname == "spectator" || self.classname == "observer") {
2420                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2421                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2422                         dropclient(self);
2423                 }
2424         }
2425 }
2426
2427 .float motd_actived_time; // used for both motd and campaign_message
2428 void PrintWelcomeMessage()
2429 {
2430         if (self.motd_actived_time == 0) { // is there already a message showing?
2431                 if (autocvar_g_campaign) {
2432                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2433                                 self.motd_actived_time = time;
2434                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2435                         }
2436                 } else {
2437                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2438                                 self.motd_actived_time = time;
2439                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2440                         }
2441                 }
2442         } else { // showing MOTD or campaign message
2443                 if (autocvar_g_campaign) {
2444                         if (self.BUTTON_INFO)
2445                                 self.motd_actived_time = time;
2446                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2447                                 self.motd_actived_time = 0;
2448                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2449                         }
2450                 } else {
2451                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2452                                 if (self.BUTTON_INFO)
2453                                         self.motd_actived_time = time;
2454                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2455                                         self.motd_actived_time = 0;
2456                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2457                                 }
2458                         }
2459                 }
2460         }
2461 }
2462
2463 void ObserverThink()
2464 {
2465         float prefered_movetype;
2466         if (self.flags & FL_JUMPRELEASED) {
2467                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2468                         self.flags &~= FL_JUMPRELEASED;
2469                         self.flags |= FL_SPAWNING;
2470                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2471                         self.flags &~= FL_JUMPRELEASED;
2472                         if(SpectateNext() == 1) {
2473                                 self.classname = "spectator";
2474                         }
2475                 } else {
2476                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2477                         if (self.movetype != prefered_movetype)
2478                                 self.movetype = prefered_movetype;
2479                 }
2480         } else {
2481                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2482                         self.flags |= FL_JUMPRELEASED;
2483                         if(self.flags & FL_SPAWNING)
2484                         {
2485                                 self.flags &~= FL_SPAWNING;
2486                                 LeaveSpectatorMode();
2487                                 return;
2488                         }
2489                 }
2490         }
2491
2492         PrintWelcomeMessage();
2493 }
2494
2495 void SpectatorThink()
2496 {
2497         if (self.flags & FL_JUMPRELEASED) {
2498                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2499                         self.flags &~= FL_JUMPRELEASED;
2500                         self.flags |= FL_SPAWNING;
2501                 } else if(self.BUTTON_ATCK) {
2502                         self.flags &~= FL_JUMPRELEASED;
2503                         if(SpectateNext() == 1) {
2504                                 self.classname = "spectator";
2505                         } else {
2506                                 self.classname = "observer";
2507                                 PutClientInServer();
2508                         }
2509                 } else if (self.BUTTON_ATCK2) {
2510                         self.flags &~= FL_JUMPRELEASED;
2511                         self.classname = "observer";
2512                         PutClientInServer();
2513                 } else {
2514                         if(!SpectateUpdate())
2515                                 PutObserverInServer();
2516                 }
2517         } else {
2518                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2519                         self.flags |= FL_JUMPRELEASED;
2520                         if(self.flags & FL_SPAWNING)
2521                         {
2522                                 self.flags &~= FL_SPAWNING;
2523                                 LeaveSpectatorMode();
2524                                 return;
2525                         }
2526                 }
2527                 if(!SpectateUpdate())
2528                         PutObserverInServer();
2529         }
2530
2531         PrintWelcomeMessage();
2532         self.flags |= FL_CLIENT | FL_NOTARGET;
2533 }
2534
2535 float ctf_usekey();
2536 void PlayerUseKey()
2537 {
2538         if(self.classname != "player")
2539                 return;
2540
2541         if(self.vehicle)
2542         {
2543         vehicles_exit(VHEF_NORMAL);
2544         return;
2545         }
2546
2547         // a use key was pressed; call handlers
2548         if(ctf_usekey())
2549                 return;
2550
2551         MUTATOR_CALLHOOK(PlayerUseKey);
2552 }
2553
2554 .float touchexplode_time;
2555
2556 /*
2557 =============
2558 PlayerPreThink
2559
2560 Called every frame for each client before the physics are run
2561 =============
2562 */
2563 .float usekeypressed;
2564 void() ctf_setstatus;
2565 void() nexball_setstatus;
2566 .float items_added;
2567 void PlayerPreThink (void)
2568 {
2569         WarpZone_PlayerPhysics_FixVAngle();
2570
2571         self.stat_game_starttime = game_starttime;
2572         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2573         self.stat_leadlimit = autocvar_leadlimit;
2574
2575         if(frametime)
2576         {
2577                 // physics frames: update anticheat stuff
2578                 anticheat_prethink();
2579         }
2580
2581         if(blockSpectators && frametime)
2582                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2583                 checkSpectatorBlock();
2584
2585         zoomstate_set = 0;
2586
2587         if(self.netname_previous != self.netname)
2588         {
2589                 if(autocvar_sv_eventlog)
2590                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2591                 if(self.netname_previous)
2592                         strunzone(self.netname_previous);
2593                 self.netname_previous = strzone(self.netname);
2594         }
2595
2596         // version nagging
2597         if(self.version_nagtime)
2598                 if(self.cvar_g_xonoticversion)
2599                         if(time > self.version_nagtime)
2600                         {
2601                                 // don't notify git users
2602                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2603                                 {
2604                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2605                                         {
2606                                                 // notify release users if connecting to git
2607                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2608                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2609                                         }
2610                                         else
2611                                         {
2612                                                 float r;
2613                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2614                                                 if(r < 0)
2615                                                 {
2616                                                         // give users new version
2617                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2618                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2619                                                 }
2620                                                 else if(r > 0)
2621                                                 {
2622                                                         // notify users about old server version
2623                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2624                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2625                                                 }
2626                                         }
2627                                 }
2628                                 self.version_nagtime = 0;
2629                         }
2630
2631         // GOD MODE info
2632         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2633         {
2634                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2635                 self.max_armorvalue = 0;
2636         }
2637
2638 #ifdef TETRIS
2639         if (TetrisPreFrame())
2640                 return;
2641 #endif
2642
2643         MUTATOR_CALLHOOK(PlayerPreThink);
2644
2645         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2646         {
2647                 if(self.BUTTON_USE && !self.usekeypressed)
2648                         PlayerUseKey();
2649                 self.usekeypressed = self.BUTTON_USE;
2650         }
2651
2652         PrintWelcomeMessage();
2653
2654         if(self.classname == "player") {
2655 //              if(self.netname == "Wazat")
2656 //                      bprint(self.classname, "\n");
2657
2658                 CheckRules_Player();
2659
2660                 if (intermission_running)
2661                 {
2662                         IntermissionThink ();   // otherwise a button could be missed between
2663                         return;                                 // the think tics
2664                 }
2665
2666                 //don't allow the player to turn around while game is paused!
2667                 if(timeout_status == TIMEOUT_ACTIVE) {
2668                         // FIXME turn this into CSQC stuff
2669                         self.v_angle = self.lastV_angle;
2670                         self.angles = self.lastV_angle;
2671                         self.fixangle = TRUE;
2672                 }
2673
2674                 if(frametime)
2675                 {
2676 #ifndef NO_LEGACY_NETWORKING
2677                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2678 #endif
2679
2680                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2681                         {
2682                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2683                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2684                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2685
2686                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2687                                 {
2688                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2689                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2690                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2691                                 }
2692                         }
2693                         else
2694                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2695
2696                         player_powerups();
2697                 }
2698
2699                 if (g_minstagib)
2700                         minstagib_ammocheck();
2701
2702                 if (self.deadflag != DEAD_NO)
2703                 {
2704                         float button_pressed, force_respawn;
2705                         if(self.personal && g_race_qualifying)
2706                         {
2707                                 if(time > self.respawn_time)
2708                                 {
2709                                         self.respawn_time = time + 1; // only retry once a second
2710                                         respawn();
2711                                         self.impulse = 141;
2712                                 }
2713                         }
2714                         else
2715                         {
2716                                 if(frametime)
2717                                         player_anim();
2718                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2719                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2720                                 if (self.deadflag == DEAD_DYING)
2721                                 {
2722                                         if(force_respawn)
2723                                                 self.deadflag = DEAD_RESPAWNING;
2724                                         else if(!button_pressed)
2725                                                 self.deadflag = DEAD_DEAD;
2726                                 }
2727                                 else if (self.deadflag == DEAD_DEAD)
2728                                 {
2729                                         if(button_pressed)
2730                                                 self.deadflag = DEAD_RESPAWNABLE;
2731                                 }
2732                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2733                                 {
2734                                         if(!button_pressed)
2735                                                 self.deadflag = DEAD_RESPAWNING;
2736                                 }
2737                                 else if (self.deadflag == DEAD_RESPAWNING)
2738                                 {
2739                                         if(time > self.respawn_time)
2740                                         {
2741                                                 self.respawn_time = time + 1; // only retry once a second
2742                                                 respawn();
2743                                         }
2744                                 }
2745                                 ShowRespawnCountdown();
2746                         }
2747                         return;
2748                 }
2749                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2750                 // so (self.deadflag == DEAD_NO) is always true in the code below
2751
2752                 if(g_touchexplode)
2753                 if(time > self.touchexplode_time)
2754                 if(self.classname == "player")
2755                 if(self.deadflag == DEAD_NO)
2756                 if not(IS_INDEPENDENT_PLAYER(self))
2757                 FOR_EACH_PLAYER(other) if(self != other)
2758                 {
2759                         if(time > other.touchexplode_time)
2760                         if(other.deadflag == DEAD_NO)
2761                         if not(IS_INDEPENDENT_PLAYER(other))
2762                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2763                         {
2764                                 PlayerTouchExplode(self, other);
2765                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2766                         }
2767                 }
2768
2769                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2770                 {
2771                         vector dist;
2772
2773                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2774                         dist = self.prevorigin - self.origin;
2775                         dist_z = 0;
2776                         self.lms_traveled_distance += fabs(vlen(dist));
2777
2778                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2779                         {
2780                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2781                                 self.lms_traveled_distance = 0;
2782                         }
2783
2784                         if(time > self.lms_nextcheck)
2785                         {
2786                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2787                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2788                                 {
2789                                         centerprint(self, autocvar_g_lms_campcheck_message);
2790                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2791                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2792                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2793                                 }
2794                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2795                                 self.lms_traveled_distance = 0;
2796                         }
2797                 }
2798
2799                 self.prevorigin = self.origin;
2800
2801                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2802                 {
2803                         if (!self.crouch)
2804                         {
2805                                 self.crouch = TRUE;
2806                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2807                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2808                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2809                         }
2810                 }
2811                 else
2812                 {
2813                         if (self.crouch)
2814                         {
2815                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2816                                 if (!trace_startsolid)
2817                                 {
2818                                         self.crouch = FALSE;
2819                                         self.view_ofs = PL_VIEW_OFS;
2820                                         setsize (self, PL_MIN, PL_MAX);
2821                                 }
2822                         }
2823                 }
2824
2825                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2826                 {
2827                         if(self.bloodloss_timer < time)
2828                         {
2829                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2830                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2831                         }
2832                 }
2833
2834                 FixPlayermodel();
2835
2836                 GrapplingHookFrame();
2837
2838                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2839                 //if(frametime)
2840                 {
2841                         self.items &~= self.items_added;
2842
2843                         W_WeaponFrame();
2844
2845                         self.items_added = 0;
2846                         if(self.items & IT_JETPACK)
2847                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2848                                         self.items_added |= IT_FUEL;
2849
2850                         self.items |= self.items_added;
2851                 }
2852
2853                 player_regen();
2854
2855                 // rot nex charge to the charge limit
2856                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2857                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2858
2859                 if(frametime)
2860                         player_anim();
2861
2862                 if(g_ctf)
2863                         ctf_setstatus();
2864
2865                 if(g_nexball)
2866                         nexball_setstatus();
2867
2868                 // secret status
2869                 secrets_setstatus();
2870
2871                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2872
2873                 //self.angles_y=self.v_angle_y + 90;   // temp
2874         } else if(gameover) {
2875                 if (intermission_running)
2876                         IntermissionThink ();   // otherwise a button could be missed between
2877                 return;
2878         } else if(self.classname == "observer") {
2879                 ObserverThink();
2880         } else if(self.classname == "spectator") {
2881                 SpectatorThink();
2882         }
2883
2884         if(!zoomstate_set)
2885                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2886
2887         float oldspectatee_status;
2888         oldspectatee_status = self.spectatee_status;
2889         if(self.classname == "spectator")
2890                 self.spectatee_status = num_for_edict(self.enemy);
2891         else if(self.classname == "observer")
2892                 self.spectatee_status = num_for_edict(self);
2893         else
2894                 self.spectatee_status = 0;
2895         if(self.spectatee_status != oldspectatee_status)
2896         {
2897                 ClientData_Touch(self);
2898                 if(g_race || g_cts)
2899                         race_InitSpectator();
2900         }
2901
2902         if(self.teamkill_soundtime)
2903         if(time > self.teamkill_soundtime)
2904         {
2905                 self.teamkill_soundtime = 0;
2906
2907                 entity oldpusher, oldself;
2908
2909                 oldself = self; self = self.teamkill_soundsource;
2910                 oldpusher = self.pusher; self.pusher = oldself;
2911
2912                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2913
2914                 self.pusher = oldpusher;
2915                 self = oldself;
2916         }
2917
2918         if(self.taunt_soundtime)
2919         if(time > self.taunt_soundtime)
2920         {
2921                 self.taunt_soundtime = 0;
2922                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2923         }
2924
2925         target_voicescript_next(self);
2926
2927         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2928         if(!self.weapon)
2929                 self.clip_load = self.clip_size = 0;
2930 }
2931
2932 float isInvisibleString(string s)
2933 {
2934         float i, n, c;
2935         s = strdecolorize(s);
2936         for((i = 0), (n = strlen(s)); i < n; ++i)
2937         {
2938                 c = str2chr(s, i);
2939                 switch(c)
2940                 {
2941                         case 0:
2942                         case 32: // space
2943                                 break;
2944                         case 192: // charmap space
2945                                 if (!autocvar_utf8_enable)
2946                                         break;
2947                                 return FALSE;
2948                         case 160: // space in unicode fonts
2949                         case 0xE000 + 192: // utf8 charmap space
2950                                 if (autocvar_utf8_enable)
2951                                         break;
2952                         default:
2953                                 return FALSE;
2954                 }
2955         }
2956         return TRUE;
2957 }
2958
2959 /*
2960 =============
2961 PlayerPostThink
2962
2963 Called every frame for each client after the physics are run
2964 =============
2965 */
2966 .float idlekick_lasttimeleft;
2967 .entity showheadshotbbox;
2968 void showheadshotbbox_think()
2969 {
2970         if(self.owner.showheadshotbbox != self)
2971         {
2972                 remove(self);
2973                 return;
2974         }
2975         self.nextthink = time;
2976         setorigin(self, self.owner.origin);
2977         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2978 }
2979 void PlayerPostThink (void)
2980 {
2981         // Savage: Check for nameless players
2982         if (isInvisibleString(self.netname)) {
2983                 self.netname = "Player";
2984                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2985         }
2986
2987         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2988         {
2989                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2990                 {
2991                         if(self.idlekick_lasttimeleft)
2992                         {
2993                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2994                                 self.idlekick_lasttimeleft = 0;
2995                         }
2996                 }
2997                 else
2998                 {
2999                         float timeleft;
3000                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3001                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3002                         {
3003                                 if(!self.idlekick_lasttimeleft)
3004                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3005                         }
3006                         if(timeleft <= 0)
3007                         {
3008                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3009                                 AnnounceTo(self, "terminated");
3010                                 dropclient(self);
3011                                 return;
3012                         }
3013                         else if(timeleft <= 10)
3014                         {
3015                                 if(timeleft != self.idlekick_lasttimeleft)
3016                                         AnnounceTo(self, ftos(timeleft));
3017                                 self.idlekick_lasttimeleft = timeleft;
3018                         }
3019                 }
3020         }
3021
3022 #ifdef TETRIS
3023         if(self.impulse == 100)
3024                 ImpulseCommands();
3025         if (!TetrisPostFrame())
3026         {
3027 #endif
3028
3029         CheatFrame();
3030
3031         //CheckPlayerJump();
3032
3033         if(self.classname == "player") {
3034                 CheckRules_Player();
3035                 UpdateChatBubble();
3036                 if (self.impulse)
3037                         ImpulseCommands();
3038                 if (intermission_running)
3039                         return;         // intermission or finale
3040                 GetPressedKeys();
3041         } else if (self.classname == "observer") {
3042                 //do nothing
3043         } else if (self.classname == "spectator") {
3044                 //do nothing
3045         }
3046
3047 #ifdef TETRIS
3048         }
3049 #endif
3050
3051         /*
3052         float i;
3053         for(i = 0; i < 1000; ++i)
3054         {
3055                 vector end;
3056                 end = self.origin + '0 0 1024' + 512 * randomvec();
3057                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3058                 if(trace_fraction < 1)
3059                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3060                 {
3061                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3062                         break;
3063                 }
3064         }
3065         */
3066
3067         Arena_Warmup();
3068
3069         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3070
3071         if(self.waypointsprite_attachedforcarrier)
3072                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3073
3074         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3075         {
3076                 if(!self.showheadshotbbox)
3077                 {
3078                         self.showheadshotbbox = spawn();
3079                         self.showheadshotbbox.classname = "headshotbbox";
3080                         self.showheadshotbbox.owner = self;
3081                         self.showheadshotbbox.think = showheadshotbbox_think;
3082                         self.showheadshotbbox.nextthink = time;
3083                         self = self.showheadshotbbox;
3084                         self.think();
3085                         self = self.owner;
3086                 }
3087         }
3088         else
3089         {
3090                 if(self.showheadshotbbox)
3091                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3092                 remove(self.showheadshotbbox);
3093         }
3094
3095         playerdemo_write();
3096
3097         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3098         {
3099                 if(!self.stored_netname)
3100                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3101                 if(self.stored_netname != self.netname)
3102                 {
3103                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3104                         strunzone(self.stored_netname);
3105                         self.stored_netname = strzone(self.netname);
3106                 }
3107         }
3108
3109         /*
3110         if(g_race)
3111                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3112         */
3113
3114         CSQCMODEL_AUTOUPDATE();
3115 }