qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "waypointsprites.qh"
   4
   5 #include "anticheat.qh"
   6 #include "cl_impulse.qh"
   7 #include "cl_player.qh"
   8 #include "ent_cs.qh"
   9 #include "g_subs.qh"
  10 #include "ipban.qh"
  11 #include "miscfunctions.qh"
  12 #include "portals.qh"
  13 #include "teamplay.qh"
  14 #include "playerdemo.qh"
  15 #include "secret.qh"
  16 #include "spawnpoints.qh"
  17 #include "g_damage.qh"
  18 #include "g_hook.qh"
  19 #include "t_teleporters.qh"
  20 #include "command/common.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27
  28 #include "bot/bot.qh"
  29 #include "bot/navigation.qh"
  30
  31 #include "../common/vehicles/sv_vehicles.qh"
  32
  33 #include "weapons/hitplot.qh"
  34 #include "weapons/weaponsystem.qh"
  35
  36 #include "../common/net_notice.qh"
  37
  38 #include "../common/items/inventory.qh"
  39
  40 #include "../common/monsters/sv_monsters.qh"
  41
  42 #include "../warpzonelib/server.qh"
  43
  44
  45 void send_CSQC_teamnagger() {
  46         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  47         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  48 }
  49
  50 float ClientData_Send(entity to, int sf)
  51 {
  52         if(to != self.owner)
  53         {
  54                 error("wtf");
  55                 return false;
  56         }
  57
  58         entity e;
  59
  60         e = to;
  61         if(IS_SPEC(to))
  62                 e = to.enemy;
  63
  64         sf = 0;
  65
  66         if(e.race_completed)
  67                 sf |= 1; // forced scoreboard
  68         if(to.spectatee_status)
  69                 sf |= 2; // spectator ent number follows
  70         if(e.zoomstate)
  71                 sf |= 4; // zoomed
  72         if(e.porto_v_angle_held)
  73                 sf |= 8; // angles held
  74
  75         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  76         WriteByte(MSG_ENTITY, sf);
  77
  78         if(sf & 2)
  79                 WriteByte(MSG_ENTITY, to.spectatee_status);
  80
  81         if(sf & 8)
  82         {
  83                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  84                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  85         }
  86
  87         return true;
  88 }
  89
  90 void ClientData_Attach()
  91 {
  92         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  93         self.clientdata.drawonlytoclient = self;
  94         self.clientdata.owner = self;
  95 }
  96
  97 void ClientData_Detach()
  98 {
  99         remove(self.clientdata);
 100         self.clientdata = world;
 101 }
 102
 103 void ClientData_Touch(entity e)
 104 {
 105         e.clientdata.SendFlags = 1;
 106
 107         // make it spectatable
 108         entity e2;
 109         FOR_EACH_REALCLIENT(e2)
 110         {
 111                 if(e2 != e)
 112                         if(IS_SPEC(e2))
 113                                 if(e2.enemy == e)
 114                                         e2.clientdata.SendFlags = 1;
 115         }
 116 }
 117
 118 .string netname_previous;
 119
 120 void SetSpectator(entity player, entity spectatee);
 121
 122
 123 /*
 124 =============
 125 CheckPlayerModel
 126
 127 Checks if the argument string can be a valid playermodel.
 128 Returns a valid one in doubt.
 129 =============
 130 */
 131 string FallbackPlayerModel;
 132 string CheckPlayerModel(string plyermodel) {
 133         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 134         {
 135                 // note: we cannot summon Don Strunzone here, some player may
 136                 // still have the model string set. In case anyone manages how
 137                 // to change a cvar default, we'll have a small leak here.
 138                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 139         }
 140         // only in right path
 141         if( substring(plyermodel,0,14) != "models/player/")
 142                 return FallbackPlayerModel;
 143         // only good file extensions
 144         if(substring(plyermodel,-4,4) != ".zym")
 145         if(substring(plyermodel,-4,4) != ".dpm")
 146         if(substring(plyermodel,-4,4) != ".iqm")
 147         if(substring(plyermodel,-4,4) != ".md3")
 148         if(substring(plyermodel,-4,4) != ".psk")
 149                 return FallbackPlayerModel;
 150         // forbid the LOD models
 151         if(substring(plyermodel, -9,5) == "_lod1")
 152                 return FallbackPlayerModel;
 153         if(substring(plyermodel, -9,5) == "_lod2")
 154                 return FallbackPlayerModel;
 155         if(plyermodel != strtolower(plyermodel))
 156                 return FallbackPlayerModel;
 157         // also, restrict to server models
 158         if(autocvar_sv_servermodelsonly)
 159         {
 160                 if(!fexists(plyermodel))
 161                         return FallbackPlayerModel;
 162         }
 163         return plyermodel;
 164 }
 165
 166 void setplayermodel(entity e, string modelname)
 167 {
 168         precache_model(modelname);
 169         setmodel(e, modelname);
 170         player_setupanimsformodel();
 171         UpdatePlayerSounds();
 172 }
 173
 174 /*
 175 =============
 176 PutObserverInServer
 177
 178 putting a client as observer in the server
 179 =============
 180 */
 181 void FixPlayermodel();
 182 void PutObserverInServer (void)
 183 {
 184         entity  spot;
 185     self.hud = HUD_NORMAL;
 186
 187         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 188
 189         spot = SelectSpawnPoint (true);
 190         if(!spot)
 191                 error("No spawnpoints for observers?!?\n");
 192         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 193
 194         if(IS_REAL_CLIENT(self))
 195         {
 196                 msg_entity = self;
 197                 WriteByte(MSG_ONE, SVC_SETVIEW);
 198                 WriteEntity(MSG_ONE, self);
 199         }
 200
 201         self.frags = FRAGS_SPECTATOR;
 202
 203         MUTATOR_CALLHOOK(MakePlayerObserver);
 204
 205         Portal_ClearAll(self);
 206
 207         Unfreeze(self);
 208
 209         if(self.alivetime)
 210         {
 211                 if(!warmup_stage)
 212                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 213                 self.alivetime = 0;
 214         }
 215
 216         if(self.vehicle)
 217                 vehicles_exit(VHEF_RELEASE);
 218
 219         WaypointSprite_PlayerDead();
 220
 221         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 222                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 223
 224         if(self.killcount != -666)
 225         {
 226                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 227                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 228                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 229
 230                 if(self.just_joined == false) {
 231                         LogTeamchange(self.playerid, -1, 4);
 232                 } else
 233                         self.just_joined = false;
 234         }
 235
 236         PlayerScore_Clear(self); // clear scores when needed
 237
 238         accuracy_resend(self);
 239
 240         self.spectatortime = time;
 241
 242         self.classname = "observer";
 243         self.iscreature = false;
 244         self.teleportable = TELEPORT_SIMPLE;
 245         self.damagedbycontents = false;
 246         self.health = -666;
 247         self.takedamage = DAMAGE_NO;
 248         self.solid = SOLID_NOT;
 249         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 250         self.flags = FL_CLIENT | FL_NOTARGET;
 251         self.armorvalue = 666;
 252         self.effects = 0;
 253         self.armorvalue = autocvar_g_balance_armor_start;
 254         self.pauserotarmor_finished = 0;
 255         self.pauserothealth_finished = 0;
 256         self.pauseregen_finished = 0;
 257         self.damageforcescale = 0;
 258         self.death_time = 0;
 259         self.respawn_flags = 0;
 260         self.respawn_time = 0;
 261         self.stat_respawn_time = 0;
 262         self.alpha = 0;
 263         self.scale = 0;
 264         self.fade_time = 0;
 265         self.pain_frame = 0;
 266         self.pain_finished = 0;
 267         self.strength_finished = 0;
 268         self.invincible_finished = 0;
 269         self.superweapons_finished = 0;
 270         self.pushltime = 0;
 271         self.istypefrag = 0;
 272         self.think = func_null;
 273         self.nextthink = 0;
 274         self.hook_time = 0;
 275         self.deadflag = DEAD_NO;
 276         self.angles = spot.angles;
 277         self.angles_z = 0;
 278         self.fixangle = true;
 279         self.crouch = false;
 280         self.revival_time = 0;
 281
 282         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 283         self.prevorigin = self.origin;
 284         self.items = 0;
 285         self.weapons = '0 0 0';
 286         self.model = "";
 287         FixPlayermodel();
 288         setmodel(self, "null");
 289         self.drawonlytoclient = self;
 290
 291         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 292         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 293
 294         self.weapon = 0;
 295         self.weaponname = "";
 296         self.switchingweapon = 0;
 297         self.weaponmodel = "";
 298         self.weaponentity = world;
 299         self.exteriorweaponentity = world;
 300         self.killcount = -666;
 301         self.velocity = '0 0 0';
 302         self.avelocity = '0 0 0';
 303         self.punchangle = '0 0 0';
 304         self.punchvector = '0 0 0';
 305         self.oldvelocity = self.velocity;
 306         self.fire_endtime = -1;
 307         self.event_damage = func_null;
 308 }
 309
 310 .float model_randomizer;
 311 void FixPlayermodel()
 312 {
 313         string defaultmodel;
 314         float defaultskin, chmdl, oldskin, n, i;
 315         vector m1, m2;
 316
 317         defaultmodel = "";
 318         defaultskin = 0;
 319         chmdl = false;
 320
 321         if(autocvar_sv_defaultcharacter)
 322         {
 323                 if(teamplay)
 324                 {
 325                         string s;
 326                         s = Static_Team_ColorName_Lower(self.team);
 327                         if(s != "neutral")
 328                         {
 329                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 330                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 331                         }
 332                 }
 333
 334                 if(defaultmodel == "")
 335                 {
 336                         defaultmodel = autocvar_sv_defaultplayermodel;
 337                         defaultskin = autocvar_sv_defaultplayerskin;
 338                 }
 339
 340                 n = tokenize_console(defaultmodel);
 341                 if(n > 0)
 342                 {
 343                         defaultmodel = argv(floor(n * self.model_randomizer));
 344                         // However, do NOT randomize if the player-selected model is in the list.
 345                         for (i = 0; i < n; ++i)
 346                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 347                                         defaultmodel = argv(i);
 348                 }
 349
 350                 i = strstrofs(defaultmodel, ":", 0);
 351                 if(i >= 0)
 352                 {
 353                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 354                         defaultmodel = substring(defaultmodel, 0, i);
 355                 }
 356         }
 357
 358         if(defaultmodel != "")
 359         {
 360                 if (defaultmodel != self.model)
 361                 {
 362                         m1 = self.mins;
 363                         m2 = self.maxs;
 364                         setplayermodel (self, defaultmodel);
 365                         setsize (self, m1, m2);
 366                         chmdl = true;
 367                 }
 368
 369                 oldskin = self.skin;
 370                 self.skin = defaultskin;
 371         } else {
 372                 if (self.playermodel != self.model || self.playermodel == "")
 373                 {
 374                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 375                         m1 = self.mins;
 376                         m2 = self.maxs;
 377                         setplayermodel (self, self.playermodel);
 378                         setsize (self, m1, m2);
 379                         chmdl = true;
 380                 }
 381
 382                 oldskin = self.skin;
 383                 self.skin = stof(self.playerskin);
 384         }
 385
 386         if(chmdl || oldskin != self.skin) // model or skin has changed
 387         {
 388                 self.species = player_getspecies(); // update species
 389                 UpdatePlayerSounds(); // update skin sounds
 390         }
 391
 392         if(!teamplay)
 393                 if(strlen(autocvar_sv_defaultplayercolors))
 394                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 395                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 396 }
 397
 398 /*
 399 =============
 400 PutClientInServer
 401
 402 Called when a client spawns in the server
 403 =============
 404 */
 405 void PutClientInServer (void)
 406 {
 407         if(IS_BOT_CLIENT(self))
 408                 self.classname = "player";
 409         else if(IS_REAL_CLIENT(self))
 410         {
 411                 msg_entity = self;
 412                 WriteByte(MSG_ONE, SVC_SETVIEW);
 413                 WriteEntity(MSG_ONE, self);
 414         }
 415
 416         SetSpectator(self, world);
 417
 418         // reset player keys
 419         self.itemkeys = 0;
 420
 421         MUTATOR_CALLHOOK(PutClientInServer);
 422
 423         if(gameover)
 424                 self.classname = "observer";
 425
 426         if(IS_PLAYER(self))
 427         {
 428                 entity spot, oldself;
 429
 430                 accuracy_resend(self);
 431
 432                 if(self.team < 0)
 433                         JoinBestTeam(self, false, true);
 434
 435                 spot = SelectSpawnPoint (false);
 436                 if(!spot)
 437                 {
 438                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 439                         return; // spawn failed
 440                 }
 441
 442                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 443
 444                 self.classname = "player";
 445                 self.wasplayer = true;
 446                 self.iscreature = true;
 447                 self.teleportable = TELEPORT_NORMAL;
 448                 self.damagedbycontents = true;
 449                 self.movetype = MOVETYPE_WALK;
 450                 self.solid = SOLID_SLIDEBOX;
 451                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 452                 if(autocvar_g_playerclip_collisions)
 453                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 454                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 455                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 456                 self.frags = FRAGS_PLAYER;
 457                 if(INDEPENDENT_PLAYERS)
 458                         MAKE_INDEPENDENT_PLAYER(self);
 459                 self.flags = FL_CLIENT;
 460                 if(autocvar__notarget)
 461                         self.flags |= FL_NOTARGET;
 462                 self.takedamage = DAMAGE_AIM;
 463                 self.effects = 0;
 464                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 465                 self.air_finished = time + 12;
 466                 self.dmg = 2;
 467                 if(WEP_CVAR(vortex, charge))
 468                 {
 469                         if(WEP_CVAR_SEC(vortex, chargepool))
 470                                 self.vortex_chargepool_ammo = 1;
 471                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 472                 }
 473
 474                 if(warmup_stage)
 475                 {
 476                         self.ammo_shells = warmup_start_ammo_shells;
 477                         self.ammo_nails = warmup_start_ammo_nails;
 478                         self.ammo_rockets = warmup_start_ammo_rockets;
 479                         self.ammo_cells = warmup_start_ammo_cells;
 480                         self.ammo_plasma = warmup_start_ammo_plasma;
 481                         self.ammo_fuel = warmup_start_ammo_fuel;
 482                         self.health = warmup_start_health;
 483                         self.armorvalue = warmup_start_armorvalue;
 484                         self.weapons = WARMUP_START_WEAPONS;
 485                 }
 486                 else
 487                 {
 488                         self.ammo_shells = start_ammo_shells;
 489                         self.ammo_nails = start_ammo_nails;
 490                         self.ammo_rockets = start_ammo_rockets;
 491                         self.ammo_cells = start_ammo_cells;
 492                         self.ammo_plasma = start_ammo_plasma;
 493                         self.ammo_fuel = start_ammo_fuel;
 494                         self.health = start_health;
 495                         self.armorvalue = start_armorvalue;
 496                         self.weapons = start_weapons;
 497                 }
 498
 499                 if(self.weapons & WEPSET_SUPERWEAPONS)
 500                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 501                 else
 502                         self.superweapons_finished = 0;
 503
 504                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 505                 {
 506                         if(g_weaponarena_random_with_blaster)
 507                                 self.weapons &= ~WEPSET_BLASTER;
 508                         W_RandomWeapons(self, g_weaponarena_random);
 509                         if(g_weaponarena_random_with_blaster)
 510                                 self.weapons |= WEPSET_BLASTER;
 511                 }
 512
 513                 self.items = start_items;
 514
 515                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 516                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 517                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 518                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 519                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 520                 //extend the pause of rotting if client was reset at the beginning of the countdown
 521                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 522                         self.spawnshieldtime += game_starttime - time;
 523                         self.pauserotarmor_finished += game_starttime - time;
 524                         self.pauserothealth_finished += game_starttime - time;
 525                         self.pauseregen_finished += game_starttime - time;
 526                 }
 527                 self.damageforcescale = 2;
 528                 self.death_time = 0;
 529                 self.respawn_flags = 0;
 530                 self.respawn_time = 0;
 531                 self.stat_respawn_time = 0;
 532                 self.scale = 0;
 533                 self.fade_time = 0;
 534                 self.pain_frame = 0;
 535                 self.pain_finished = 0;
 536                 self.strength_finished = 0;
 537                 self.invincible_finished = 0;
 538                 self.pushltime = 0;
 539                 // players have no think function
 540                 self.think = func_null;
 541                 self.nextthink = 0;
 542                 self.hook_time = 0;
 543                 self.dmg_team = 0;
 544                 self.ballistics_density = autocvar_g_ballistics_density_player;
 545
 546                 self.metertime = 0;
 547
 548                 self.deadflag = DEAD_NO;
 549
 550                 self.angles = spot.angles;
 551
 552                 self.angles_z = 0; // never spawn tilted even if the spot says to
 553                 if(IS_BOT_CLIENT(self))
 554                         self.v_angle = self.angles;
 555                 self.fixangle = true; // turn this way immediately
 556                 self.velocity = '0 0 0';
 557                 self.avelocity = '0 0 0';
 558                 self.punchangle = '0 0 0';
 559                 self.punchvector = '0 0 0';
 560                 self.oldvelocity = self.velocity;
 561                 self.fire_endtime = -1;
 562                 self.revival_time = 0;
 563
 564                 entity spawnevent = spawn();
 565                 spawnevent.owner = self;
 566                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 567
 568                 // Cut off any still running player sounds.
 569                 stopsound(self, CH_PLAYER_SINGLE);
 570
 571                 self.model = "";
 572                 FixPlayermodel();
 573                 self.drawonlytoclient = world;
 574
 575                 self.crouch = false;
 576                 self.view_ofs = PL_VIEW_OFS;
 577                 setsize (self, PL_MIN, PL_MAX);
 578                 self.spawnorigin = spot.origin;
 579                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 580                 // don't reset back to last position, even if new position is stuck in solid
 581                 self.oldorigin = self.origin;
 582                 self.prevorigin = self.origin;
 583                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 584                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 585         self.hud = HUD_NORMAL;
 586
 587                 self.event_damage = PlayerDamage;
 588
 589                 self.bot_attack = true;
 590                 self.monster_attack = true;
 591
 592                 self.spider_slowness = 0;
 593
 594                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 595
 596                 if(self.killcount == -666) {
 597                         PlayerScore_Clear(self);
 598                         self.killcount = 0;
 599                 }
 600
 601                 CL_SpawnWeaponentity();
 602                 self.alpha = default_player_alpha;
 603                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 604                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 605
 606                 self.speedrunning = false;
 607
 608                 //stuffcmd(self, "chase_active 0");
 609                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 610
 611                 target_voicescript_clear(self);
 612
 613                 // reset fields the weapons may use
 614                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 615                 {
 616                         WEP_ACTION(j, WR_RESETPLAYER);
 617
 618                         // all weapons must be fully loaded when we spawn
 619                         entity e = get_weaponinfo(j);
 620                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 621                                 self.(weapon_load[j]) = e.reloading_ammo;
 622                 }
 623
 624                 oldself = self;
 625                 self = spot;
 626                         activator = oldself;
 627                                 string s;
 628                                 s = self.target;
 629                                 self.target = string_null;
 630                                 SUB_UseTargets();
 631                                 self.target = s;
 632                         activator = world;
 633                 self = oldself;
 634
 635                 Unfreeze(self);
 636
 637                 spawn_spot = spot;
 638                 MUTATOR_CALLHOOK(PlayerSpawn);
 639
 640                 if(autocvar_spawn_debug)
 641                 {
 642                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 643                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 644                 }
 645
 646                 self.switchweapon = w_getbestweapon(self);
 647                 self.cnt = -1; // W_LastWeapon will not complain
 648                 self.weapon = 0;
 649                 self.weaponname = "";
 650                 self.switchingweapon = 0;
 651
 652                 if(!warmup_stage)
 653                         if(!self.alivetime)
 654                                 self.alivetime = time;
 655
 656                 antilag_clear(self);
 657         }
 658         else if(IS_OBSERVER(self))
 659         {
 660                 PutObserverInServer ();
 661         }
 662 }
 663
 664 .float ebouncefactor, ebouncestop; // electro's values
 665 // TODO do we need all these fields, or should we stop autodetecting runtime
 666 // changes and just have a console command to update this?
 667 float ClientInit_SendEntity(entity to, int sf)
 668 {
 669         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 670         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 671         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 672         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 673         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 674         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 675         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 679
 680         if(sv_foginterval && world.fog != "")
 681                 WriteString(MSG_ENTITY, world.fog);
 682         else
 683                 WriteString(MSG_ENTITY, "");
 684         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 685         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 686         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 687         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 688         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 689         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 690         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 691         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 692         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 693         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 694         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 695         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 696         return true;
 697 }
 698
 699 void ClientInit_CheckUpdate()
 700 {
 701         self.nextthink = time;
 702         if(self.count != autocvar_g_balance_armor_blockpercent)
 703         {
 704                 self.count = autocvar_g_balance_armor_blockpercent;
 705                 self.SendFlags |= 1;
 706         }
 707         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 708         {
 709                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 710                 self.SendFlags |= 1;
 711         }
 712         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 713         {
 714                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 715                 self.SendFlags |= 1;
 716         }
 717         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 718         {
 719                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 720                 self.SendFlags |= 1;
 721         }
 722         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 723         {
 724                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 725                 self.SendFlags |= 1;
 726         }
 727 }
 728
 729 void ClientInit_Spawn()
 730 {
 731         entity o;
 732         entity e;
 733         e = spawn();
 734         e.classname = "clientinit";
 735         e.think = ClientInit_CheckUpdate;
 736         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 737
 738         o = self;
 739         self = e;
 740         ClientInit_CheckUpdate();
 741         self = o;
 742 }
 743
 744 /*
 745 =============
 746 SetNewParms
 747 =============
 748 */
 749 void SetNewParms (void)
 750 {
 751         // initialize parms for a new player
 752         parm1 = -(86400 * 366);
 753 }
 754
 755 /*
 756 =============
 757 SetChangeParms
 758 =============
 759 */
 760 void SetChangeParms (void)
 761 {
 762         // save parms for level change
 763         parm1 = self.parm_idlesince - time;
 764 }
 765
 766 /*
 767 =============
 768 DecodeLevelParms
 769 =============
 770 */
 771 void DecodeLevelParms (void)
 772 {
 773         // load parms
 774         self.parm_idlesince = parm1;
 775         if(self.parm_idlesince == -(86400 * 366))
 776                 self.parm_idlesince = time;
 777
 778         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 779         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 780 }
 781
 782 /*
 783 =============
 784 ClientKill
 785
 786 Called when a client types 'kill' in the console
 787 =============
 788 */
 789
 790 .float clientkill_nexttime;
 791 void ClientKill_Now_TeamChange()
 792 {
 793         if(self.killindicator_teamchange == -1)
 794         {
 795                 JoinBestTeam( self, false, true );
 796         }
 797         else if(self.killindicator_teamchange == -2)
 798         {
 799                 if(blockSpectators)
 800                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 801                 PutObserverInServer();
 802         }
 803         else
 804                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 805         self.killindicator_teamchange = 0;
 806 }
 807
 808 void ClientKill_Now()
 809 {
 810         if(self.vehicle)
 811         {
 812             vehicles_exit(VHEF_RELEASE);
 813             if(!self.killindicator_teamchange)
 814             {
 815             self.vehicle_health = -1;
 816             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 817             }
 818         }
 819
 820         if(self.killindicator && !wasfreed(self.killindicator))
 821                 remove(self.killindicator);
 822
 823         self.killindicator = world;
 824
 825         if(self.killindicator_teamchange)
 826                 ClientKill_Now_TeamChange();
 827
 828         if(IS_PLAYER(self))
 829                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 830
 831         // now I am sure the player IS dead
 832 }
 833 void KillIndicator_Think()
 834 {
 835         if (gameover)
 836         {
 837                 self.owner.killindicator = world;
 838                 remove(self);
 839                 return;
 840         }
 841
 842         if (self.owner.alpha < 0 && !self.owner.vehicle)
 843         {
 844                 self.owner.killindicator = world;
 845                 remove(self);
 846                 return;
 847         }
 848
 849         if(self.cnt <= 0)
 850         {
 851                 self = self.owner;
 852                 ClientKill_Now(); // no oldself needed
 853                 return;
 854         }
 855     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 856     {
 857         self.nextthink = time + 1;
 858         self.cnt -= 1;
 859     }
 860         else
 861         {
 862                 if(self.cnt <= 10)
 863                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 864                 if(IS_REAL_CLIENT(self.owner))
 865                 {
 866                         if(self.cnt <= 10)
 867                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 868                 }
 869                 self.nextthink = time + 1;
 870                 self.cnt -= 1;
 871         }
 872 }
 873
 874 float clientkilltime;
 875 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 876 {
 877         float killtime;
 878         float starttime;
 879         entity e;
 880
 881         if (gameover)
 882                 return;
 883
 884         killtime = autocvar_g_balance_kill_delay;
 885
 886         if(g_race_qualifying || g_cts)
 887                 killtime = 0;
 888
 889     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 890     {
 891                 remove(self.killindicator);
 892                 self.killindicator = world;
 893
 894         ClientKill_Now(); // allow instant kill in this case
 895         return;
 896     }
 897
 898         self.killindicator_teamchange = targetteam;
 899
 900     if(!self.killindicator)
 901         {
 902                 if(self.deadflag == DEAD_NO)
 903                 {
 904                         killtime = max(killtime, self.clientkill_nexttime - time);
 905                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 906                 }
 907
 908                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 909                 {
 910                         ClientKill_Now();
 911                 }
 912                 else
 913                 {
 914                         starttime = max(time, clientkilltime);
 915
 916                         self.killindicator = spawn();
 917                         self.killindicator.owner = self;
 918                         self.killindicator.scale = 0.5;
 919                         setattachment(self.killindicator, self, "");
 920                         setorigin(self.killindicator, '0 0 52');
 921                         self.killindicator.think = KillIndicator_Think;
 922                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 923                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 924                         self.killindicator.cnt = ceil(killtime);
 925                         self.killindicator.count = bound(0, ceil(killtime), 10);
 926                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 927
 928                         for(e = world; (e = find(e, classname, "body")) != world; )
 929                         {
 930                                 if(e.enemy != self)
 931                                         continue;
 932                                 e.killindicator = spawn();
 933                                 e.killindicator.owner = e;
 934                                 e.killindicator.scale = 0.5;
 935                                 setattachment(e.killindicator, e, "");
 936                                 setorigin(e.killindicator, '0 0 52');
 937                                 e.killindicator.think = KillIndicator_Think;
 938                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 939                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 940                                 e.killindicator.cnt = ceil(killtime);
 941                         }
 942                         self.lip = 0;
 943                 }
 944         }
 945         if(self.killindicator)
 946         {
 947                 if(targetteam == 0) // just die
 948                 {
 949                         self.killindicator.colormod = '0 0 0';
 950                         if(IS_REAL_CLIENT(self))
 951                         if(self.killindicator.cnt > 0)
 952                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 953                 }
 954                 else if(targetteam == -1) // auto
 955                 {
 956                         self.killindicator.colormod = '0 1 0';
 957                         if(IS_REAL_CLIENT(self))
 958                         if(self.killindicator.cnt > 0)
 959                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 960                 }
 961                 else if(targetteam == -2) // spectate
 962                 {
 963                         self.killindicator.colormod = '0.5 0.5 0.5';
 964                         if(IS_REAL_CLIENT(self))
 965                         if(self.killindicator.cnt > 0)
 966                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 967                 }
 968                 else
 969                 {
 970                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 971                         if(IS_REAL_CLIENT(self))
 972                         if(self.killindicator.cnt > 0)
 973                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 974                 }
 975         }
 976
 977 }
 978
 979 void ClientKill (void)
 980 {
 981         if(gameover) return;
 982         if(self.player_blocked) return;
 983         if(self.frozen) return;
 984
 985         ClientKill_TeamChange(0);
 986 }
 987
 988 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 989 {
 990     e.killindicator = spawn();
 991     e.killindicator.owner = e;
 992     e.killindicator.think = KillIndicator_Think;
 993     e.killindicator.nextthink = time + (e.lip) * 0.05;
 994     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 995     e.killindicator.health = 1; // this is used to indicate that it should be silent
 996     e.lip = 0;
 997 }
 998
 999 void FixClientCvars(entity e)
1000 {
1001         // send prediction settings to the client
1002         stuffcmd(e, "\nin_bindmap 0 0\n");
1003         if(g_race || g_cts)
1004                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1005         if(autocvar_g_antilag == 3) // client side hitscan
1006                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1007         if(autocvar_sv_gentle)
1008                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1009 }
1010
1011 float PlayerInIDList(entity p, string idlist)
1012 {
1013         float n, i;
1014         string s;
1015
1016         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1017         if (!p.crypto_idfp)
1018                 return 0;
1019
1020         // this function allows abbreviated player IDs too!
1021         n = tokenize_console(idlist);
1022         for(i = 0; i < n; ++i)
1023         {
1024                 s = argv(i);
1025                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1026                         return 1;
1027         }
1028
1029         return 0;
1030 }
1031
1032 #ifdef DP_EXT_PRECONNECT
1033 /*
1034 =============
1035 ClientPreConnect
1036
1037 Called once (not at each match start) when a client begins a connection to the server
1038 =============
1039 */
1040 void ClientPreConnect (void)
1041 {
1042         if(autocvar_sv_eventlog)
1043         {
1044                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1045                         self.playerid,
1046                         num_for_edict(self),
1047                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1048                 ));
1049         }
1050 }
1051 #endif
1052
1053 /*
1054 =============
1055 ClientConnect
1056
1057 Called when a client connects to the server
1058 =============
1059 */
1060 void DecodeLevelParms (void);
1061 //void dom_player_join_team(entity pl);
1062 void set_dom_state(entity e);
1063 void ClientConnect (void)
1064 {
1065         float t;
1066
1067         if(IS_CLIENT(self))
1068         {
1069                 print("Warning: ClientConnect, but already connected!\n");
1070                 return;
1071         }
1072
1073         if(Ban_MaybeEnforceBanOnce(self))
1074                 return;
1075
1076         DecodeLevelParms();
1077
1078 #ifdef WATERMARK
1079         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1080 #endif
1081
1082         self.classname = "player_joining";
1083
1084         self.flags = FL_CLIENT;
1085         self.version_nagtime = time + 10 + random() * 10;
1086
1087         if(player_count<0)
1088         {
1089                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1090                 player_count = 0;
1091         }
1092
1093         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1094
1095         PlayerScore_Attach(self);
1096         ClientData_Attach();
1097         accuracy_init(self);
1098         Inventory_new(self);
1099
1100         bot_clientconnect();
1101
1102         playerdemo_init();
1103
1104         anticheat_init();
1105
1106         // identify the right forced team
1107         if(autocvar_g_campaign)
1108         {
1109                 if(IS_REAL_CLIENT(self)) // only players, not bots
1110                 {
1111                         switch(autocvar_g_campaign_forceteam)
1112                         {
1113                                 case 1: self.team_forced = NUM_TEAM_1; break;
1114                                 case 2: self.team_forced = NUM_TEAM_2; break;
1115                                 case 3: self.team_forced = NUM_TEAM_3; break;
1116                                 case 4: self.team_forced = NUM_TEAM_4; break;
1117                                 default: self.team_forced = 0;
1118                         }
1119                 }
1120         }
1121         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1122                 self.team_forced = NUM_TEAM_1;
1123         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1124                 self.team_forced = NUM_TEAM_2;
1125         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1126                 self.team_forced = NUM_TEAM_3;
1127         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1128                 self.team_forced = NUM_TEAM_4;
1129         else if(autocvar_g_forced_team_otherwise == "red")
1130                 self.team_forced = NUM_TEAM_1;
1131         else if(autocvar_g_forced_team_otherwise == "blue")
1132                 self.team_forced = NUM_TEAM_2;
1133         else if(autocvar_g_forced_team_otherwise == "yellow")
1134                 self.team_forced = NUM_TEAM_3;
1135         else if(autocvar_g_forced_team_otherwise == "pink")
1136                 self.team_forced = NUM_TEAM_4;
1137         else if(autocvar_g_forced_team_otherwise == "spectate")
1138                 self.team_forced = -1;
1139         else if(autocvar_g_forced_team_otherwise == "spectator")
1140                 self.team_forced = -1;
1141         else
1142                 self.team_forced = 0;
1143
1144         if(!teamplay)
1145                 if(self.team_forced > 0)
1146                         self.team_forced = 0;
1147
1148         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1149
1150         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1151                 self.classname = "observer";
1152         } else {
1153                 if(teamplay)
1154                 {
1155                         if(autocvar_g_balance_teams)
1156                         {
1157                                 self.classname = "player";
1158                                 campaign_bots_may_start = 1;
1159                         }
1160                         else
1161                         {
1162                                 self.classname = "observer"; // do it anyway
1163                         }
1164                 }
1165                 else
1166                 {
1167                         self.classname = "player";
1168                         campaign_bots_may_start = 1;
1169                 }
1170         }
1171
1172         self.playerid = (playerid_last = playerid_last + 1);
1173
1174         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1175
1176     if(IS_BOT_CLIENT(self))
1177         PlayerStats_GameReport_AddPlayer(self);
1178
1179         if(autocvar_sv_eventlog)
1180                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1181
1182         LogTeamchange(self.playerid, self.team, 1);
1183
1184         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1185
1186         self.netname_previous = strzone(self.netname);
1187
1188         if(IS_PLAYER(self) && teamplay)
1189                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1190         else
1191                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1192
1193         stuffcmd(self, strcat(clientstuff, "\n"));
1194         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1195
1196         FixClientCvars(self);
1197
1198         // spawnfunc_waypoint sprites
1199         WaypointSprite_InitClient(self);
1200
1201         // Wazat's grappling hook
1202         SetGrappleHookBindings();
1203
1204         // Jetpack binds
1205         stuffcmd(self, "alias +jetpack +button10\n");
1206         stuffcmd(self, "alias -jetpack -button10\n");
1207
1208         // get version info from player
1209         stuffcmd(self, "cmd clientversion $gameversion\n");
1210
1211         // get other cvars from player
1212         GetCvars(0);
1213
1214         // notify about available teams
1215         if(teamplay)
1216         {
1217                 CheckAllowedTeams(self);
1218                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1219                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1220         }
1221         else
1222                 stuffcmd(self, "set _teams_available 0\n");
1223
1224         attach_entcs();
1225
1226         bot_relinkplayerlist();
1227
1228         self.spectatortime = time;
1229         if(blockSpectators)
1230         {
1231                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1232         }
1233
1234         self.jointime = time;
1235         self.allowed_timeouts = autocvar_sv_timeout_number;
1236
1237         if(IS_REAL_CLIENT(self))
1238         {
1239                 if(!autocvar_g_campaign)
1240                 {
1241                         self.motd_actived_time = -1;
1242                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1243                 }
1244
1245                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1246                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1247         }
1248
1249         if(!sv_foginterval && world.fog != "")
1250                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1251
1252         W_HitPlotOpen(self);
1253
1254         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1255                 send_CSQC_teamnagger();
1256
1257         CheatInitClient();
1258
1259         CSQCMODEL_AUTOINIT();
1260
1261         self.model_randomizer = random();
1262
1263         if(IS_REAL_CLIENT(self))
1264                 sv_notice_join();
1265
1266         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1267                 entity oldself = self;
1268                 self = e;
1269                 e.init_for_player(oldself);
1270                 self = oldself;
1271         }
1272
1273         MUTATOR_CALLHOOK(ClientConnect);
1274 }
1275 /*
1276 =============
1277 ClientDisconnect
1278
1279 Called when a client disconnects from the server
1280 =============
1281 */
1282 .entity chatbubbleentity;
1283 void ReadyCount();
1284 void ClientDisconnect (void)
1285 {
1286         if(self.vehicle)
1287             vehicles_exit(VHEF_RELEASE);
1288
1289         if (!IS_CLIENT(self))
1290         {
1291                 print("Warning: ClientDisconnect without ClientConnect\n");
1292                 return;
1293         }
1294
1295         PlayerStats_GameReport_FinalizePlayer(self);
1296
1297         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1298
1299         CheatShutdownClient();
1300
1301         W_HitPlotClose(self);
1302
1303         anticheat_report();
1304         anticheat_shutdown();
1305
1306         playerdemo_shutdown();
1307
1308         bot_clientdisconnect();
1309
1310         if(self.entcs)
1311                 detach_entcs();
1312
1313         if(autocvar_sv_eventlog)
1314                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1315
1316         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1317
1318         MUTATOR_CALLHOOK(ClientDisconnect);
1319
1320         Portal_ClearAll(self);
1321
1322         Unfreeze(self);
1323
1324         RemoveGrapplingHook(self);
1325
1326         // Here, everything has been done that requires this player to be a client.
1327
1328         self.flags &= ~FL_CLIENT;
1329
1330         if (self.chatbubbleentity)
1331                 remove (self.chatbubbleentity);
1332
1333         if (self.killindicator)
1334                 remove (self.killindicator);
1335
1336         WaypointSprite_PlayerGone();
1337
1338         bot_relinkplayerlist();
1339
1340         accuracy_free(self);
1341         Inventory_delete(self);
1342         ClientData_Detach();
1343         PlayerScore_Detach(self);
1344
1345         if(self.netname_previous)
1346                 strunzone(self.netname_previous);
1347         if(self.clientstatus)
1348                 strunzone(self.clientstatus);
1349         if(self.weaponorder_byimpulse)
1350                 strunzone(self.weaponorder_byimpulse);
1351
1352         ClearPlayerSounds();
1353
1354         if(self.personal)
1355                 remove(self.personal);
1356
1357         self.playerid = 0;
1358         ReadyCount();
1359
1360         // free cvars
1361         GetCvars(-1);
1362 }
1363
1364 .float BUTTON_CHAT;
1365 void ChatBubbleThink()
1366 {
1367         self.nextthink = time;
1368         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1369         {
1370                 if(self.owner) // but why can that ever be world?
1371                         self.owner.chatbubbleentity = world;
1372                 remove(self);
1373                 return;
1374         }
1375         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1376 #ifdef TETRIS
1377                 || self.owner.tetris_on
1378 #endif
1379         )
1380                 self.model = self.mdl;
1381         else
1382                 self.model = "";
1383 }
1384
1385 void UpdateChatBubble()
1386 {
1387         if (self.alpha < 0)
1388                 return;
1389         // spawn a chatbubble entity if needed
1390         if (!self.chatbubbleentity)
1391         {
1392                 self.chatbubbleentity = spawn();
1393                 self.chatbubbleentity.owner = self;
1394                 self.chatbubbleentity.exteriormodeltoclient = self;
1395                 self.chatbubbleentity.think = ChatBubbleThink;
1396                 self.chatbubbleentity.nextthink = time;
1397                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1398                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1399                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1400                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1401                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1402                 self.chatbubbleentity.model = "";
1403                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1404         }
1405 }
1406
1407
1408 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1409 // added to the model skins
1410 /*void UpdateColorModHack()
1411 {
1412         float c;
1413         c = self.clientcolors & 15;
1414         // LordHavoc: only bothering to support white, green, red, yellow, blue
1415              if (!teamplay) self.colormod = '0 0 0';
1416         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1417         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1418         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1419         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1420         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1421         else self.colormod = '1 1 1';
1422 }*/
1423
1424 void respawn(void)
1425 {
1426         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1427         {
1428                 self.solid = SOLID_NOT;
1429                 self.takedamage = DAMAGE_NO;
1430                 self.movetype = MOVETYPE_FLY;
1431                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1432                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1433                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1434                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1435                 if(autocvar_g_respawn_ghosts_maxtime)
1436                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1437         }
1438
1439         CopyBody(1);
1440
1441         self.effects |= EF_NODRAW; // prevent another CopyBody
1442         PutClientInServer();
1443 }
1444
1445 void play_countdown(float finished, string samp)
1446 {
1447         if(IS_REAL_CLIENT(self))
1448                 if(floor(finished - time - frametime) != floor(finished - time))
1449                         if(finished - time < 6)
1450                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1451 }
1452
1453 void player_powerups (void)
1454 {
1455         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1456         olditems = self.items;
1457
1458         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1459                 self.modelflags |= MF_ROCKET;
1460         else
1461                 self.modelflags &= ~MF_ROCKET;
1462
1463         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1464
1465         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1466                 return;
1467
1468         Fire_ApplyDamage(self);
1469         Fire_ApplyEffect(self);
1470
1471         if (!g_instagib)
1472         {
1473                 if (self.items & IT_STRENGTH)
1474                 {
1475                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1476                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1477                         if (time > self.strength_finished)
1478                         {
1479                                 self.items = self.items - (self.items & IT_STRENGTH);
1480                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1481                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1482                         }
1483                 }
1484                 else
1485                 {
1486                         if (time < self.strength_finished)
1487                         {
1488                                 self.items = self.items | IT_STRENGTH;
1489                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1490                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1491                         }
1492                 }
1493                 if (self.items & IT_INVINCIBLE)
1494                 {
1495                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1496                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1497                         if (time > self.invincible_finished)
1498                         {
1499                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1500                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1501                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1502                         }
1503                 }
1504                 else
1505                 {
1506                         if (time < self.invincible_finished)
1507                         {
1508                                 self.items = self.items | IT_INVINCIBLE;
1509                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1510                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1511                         }
1512                 }
1513                 if (self.items & IT_SUPERWEAPON)
1514                 {
1515                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1516                         {
1517                                 self.superweapons_finished = 0;
1518                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1519                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1520                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1521                         }
1522                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1523                         {
1524                                 // don't let them run out
1525                         }
1526                         else
1527                         {
1528                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1529                                 if (time > self.superweapons_finished)
1530                                 {
1531                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1532                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1533                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1534                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1535                                 }
1536                         }
1537                 }
1538                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1539                 {
1540                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1541                         {
1542                                 self.items = self.items | IT_SUPERWEAPON;
1543                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1544                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1545                         }
1546                         else
1547                         {
1548                                 self.superweapons_finished = 0;
1549                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1550                         }
1551                 }
1552                 else
1553                 {
1554                         self.superweapons_finished = 0;
1555                 }
1556         }
1557
1558         if(autocvar_g_nodepthtestplayers)
1559                 self.effects = self.effects | EF_NODEPTHTEST;
1560
1561         if(autocvar_g_fullbrightplayers)
1562                 self.effects = self.effects | EF_FULLBRIGHT;
1563
1564         if (time >= game_starttime)
1565         if (time < self.spawnshieldtime)
1566                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1567
1568         MUTATOR_CALLHOOK(PlayerPowerups);
1569 }
1570
1571 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1572 {
1573         if(current > stable)
1574                 return current;
1575         else if(current > stable - 0.25) // when close enough, "snap"
1576                 return stable;
1577         else
1578                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1579 }
1580
1581 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1582 {
1583         if(current < stable)
1584                 return current;
1585         else if(current < stable + 0.25) // when close enough, "snap"
1586                 return stable;
1587         else
1588                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1589 }
1590
1591 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1592 {
1593         if(current > rotstable)
1594         {
1595                 if(rotframetime > 0)
1596                 {
1597                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1598                         current = max(rotstable, current - rotlinear * rotframetime);
1599                 }
1600         }
1601         else if(current < regenstable)
1602         {
1603                 if(regenframetime > 0)
1604                 {
1605                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1606                         current = min(regenstable, current + regenlinear * regenframetime);
1607                 }
1608         }
1609
1610         if(current > limit)
1611                 current = limit;
1612
1613         return current;
1614 }
1615
1616 void player_regen (void)
1617 {
1618         float max_mod, regen_mod, rot_mod, limit_mod;
1619         max_mod = regen_mod = rot_mod = limit_mod = 1;
1620         regen_mod_max = max_mod;
1621         regen_mod_regen = regen_mod;
1622         regen_mod_rot = rot_mod;
1623         regen_mod_limit = limit_mod;
1624         if(!MUTATOR_CALLHOOK(PlayerRegen))
1625         if(!self.frozen)
1626         {
1627                 float minh, mina, maxh, maxa, limith, limita;
1628                 maxh = autocvar_g_balance_health_rotstable;
1629                 maxa = autocvar_g_balance_armor_rotstable;
1630                 minh = autocvar_g_balance_health_regenstable;
1631                 mina = autocvar_g_balance_armor_regenstable;
1632                 limith = autocvar_g_balance_health_limit;
1633                 limita = autocvar_g_balance_armor_limit;
1634
1635                 max_mod = regen_mod_max;
1636                 regen_mod = regen_mod_regen;
1637                 rot_mod = regen_mod_rot;
1638                 limit_mod = regen_mod_limit;
1639
1640                 maxh = maxh * max_mod;
1641                 minh = minh * max_mod;
1642                 limith = limith * limit_mod;
1643                 limita = limita * limit_mod;
1644
1645                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1646                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1647         }
1648
1649         // if player rotted to death...  die!
1650         // check this outside above checks, as player may still be able to rot to death
1651         if(self.health < 1)
1652         {
1653                 if(self.vehicle)
1654                         vehicles_exit(VHEF_RELEASE);
1655                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1656         }
1657
1658         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1659         {
1660                 float minf, maxf, limitf;
1661
1662                 maxf = autocvar_g_balance_fuel_rotstable;
1663                 minf = autocvar_g_balance_fuel_regenstable;
1664                 limitf = autocvar_g_balance_fuel_limit;
1665
1666                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1667         }
1668 }
1669
1670 float zoomstate_set;
1671 void SetZoomState(float z)
1672 {
1673         if(z != self.zoomstate)
1674         {
1675                 self.zoomstate = z;
1676                 ClientData_Touch(self);
1677         }
1678         zoomstate_set = 1;
1679 }
1680
1681 void GetPressedKeys(void) {
1682         MUTATOR_CALLHOOK(GetPressedKeys);
1683         if (self.movement.x > 0) // get if movement keys are pressed
1684         {       // forward key pressed
1685                 self.pressedkeys |= KEY_FORWARD;
1686                 self.pressedkeys &= ~KEY_BACKWARD;
1687         }
1688         else if (self.movement.x < 0)
1689         {       // backward key pressed
1690                 self.pressedkeys |= KEY_BACKWARD;
1691                 self.pressedkeys &= ~KEY_FORWARD;
1692         }
1693         else
1694         {       // no x input
1695                 self.pressedkeys &= ~KEY_FORWARD;
1696                 self.pressedkeys &= ~KEY_BACKWARD;
1697         }
1698
1699         if (self.movement.y > 0)
1700         {       // right key pressed
1701                 self.pressedkeys |= KEY_RIGHT;
1702                 self.pressedkeys &= ~KEY_LEFT;
1703         }
1704         else if (self.movement.y < 0)
1705         {       // left key pressed
1706                 self.pressedkeys |= KEY_LEFT;
1707                 self.pressedkeys &= ~KEY_RIGHT;
1708         }
1709         else
1710         {       // no y input
1711                 self.pressedkeys &= ~KEY_RIGHT;
1712                 self.pressedkeys &= ~KEY_LEFT;
1713         }
1714
1715         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1716                 self.pressedkeys |= KEY_JUMP;
1717         else
1718                 self.pressedkeys &= ~KEY_JUMP;
1719         if (self.BUTTON_CROUCH)
1720                 self.pressedkeys |= KEY_CROUCH;
1721         else
1722                 self.pressedkeys &= ~KEY_CROUCH;
1723
1724         if (self.BUTTON_ATCK)
1725                 self.pressedkeys |= KEY_ATCK;
1726         else
1727                 self.pressedkeys &= ~KEY_ATCK;
1728         if (self.BUTTON_ATCK2)
1729                 self.pressedkeys |= KEY_ATCK2;
1730         else
1731                 self.pressedkeys &= ~KEY_ATCK2;
1732 }
1733
1734 /*
1735 ======================
1736 spectate mode routines
1737 ======================
1738 */
1739
1740 void SpectateCopy(entity spectatee) {
1741         other = spectatee;
1742         MUTATOR_CALLHOOK(SpectateCopy);
1743         self.armortype = spectatee.armortype;
1744         self.armorvalue = spectatee.armorvalue;
1745         self.ammo_cells = spectatee.ammo_cells;
1746         self.ammo_plasma = spectatee.ammo_plasma;
1747         self.ammo_shells = spectatee.ammo_shells;
1748         self.ammo_nails = spectatee.ammo_nails;
1749         self.ammo_rockets = spectatee.ammo_rockets;
1750         self.ammo_fuel = spectatee.ammo_fuel;
1751         self.clip_load = spectatee.clip_load;
1752         self.clip_size = spectatee.clip_size;
1753         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1754         self.health = spectatee.health;
1755         self.impulse = 0;
1756         self.items = spectatee.items;
1757         self.last_pickup = spectatee.last_pickup;
1758         self.hit_time = spectatee.hit_time;
1759         self.metertime = spectatee.metertime;
1760         self.strength_finished = spectatee.strength_finished;
1761         self.invincible_finished = spectatee.invincible_finished;
1762         self.pressedkeys = spectatee.pressedkeys;
1763         self.weapons = spectatee.weapons;
1764         self.switchweapon = spectatee.switchweapon;
1765         self.switchingweapon = spectatee.switchingweapon;
1766         self.weapon = spectatee.weapon;
1767         self.vortex_charge = spectatee.vortex_charge;
1768         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1769         self.hagar_load = spectatee.hagar_load;
1770         self.arc_heat_percent = spectatee.arc_heat_percent;
1771         self.minelayer_mines = spectatee.minelayer_mines;
1772         self.punchangle = spectatee.punchangle;
1773         self.view_ofs = spectatee.view_ofs;
1774         self.velocity = spectatee.velocity;
1775         self.dmg_take = spectatee.dmg_take;
1776         self.dmg_save = spectatee.dmg_save;
1777         self.dmg_inflictor = spectatee.dmg_inflictor;
1778         self.v_angle = spectatee.v_angle;
1779         self.angles = spectatee.v_angle;
1780         self.frozen = spectatee.frozen;
1781         self.revive_progress = spectatee.revive_progress;
1782         if(!self.BUTTON_USE)
1783                 self.fixangle = true;
1784         setorigin(self, spectatee.origin);
1785         setsize(self, spectatee.mins, spectatee.maxs);
1786         SetZoomState(spectatee.zoomstate);
1787
1788     anticheat_spectatecopy(spectatee);
1789         self.hud = spectatee.hud;
1790         if(spectatee.vehicle)
1791     {
1792         self.fixangle = false;
1793         //self.velocity = spectatee.vehicle.velocity;
1794         self.vehicle_health = spectatee.vehicle_health;
1795         self.vehicle_shield = spectatee.vehicle_shield;
1796         self.vehicle_energy = spectatee.vehicle_energy;
1797         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1798         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1799         self.vehicle_reload1 = spectatee.vehicle_reload1;
1800         self.vehicle_reload2 = spectatee.vehicle_reload2;
1801
1802         msg_entity = self;
1803
1804         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1805             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1806             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1807             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1808
1809         //WriteByte (MSG_ONE, SVC_SETVIEW);
1810         //    WriteEntity(MSG_ONE, self);
1811         //makevectors(spectatee.v_angle);
1812         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1813     }
1814 }
1815
1816 float SpectateUpdate()
1817 {
1818         if(!self.enemy)
1819             return 0;
1820
1821         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1822         {
1823                 SetSpectator(self, world);
1824                 return 0;
1825         }
1826
1827         SpectateCopy(self.enemy);
1828
1829         return 1;
1830 }
1831
1832 float SpectateSet()
1833 {
1834         if(self.enemy.classname != "player")
1835                 return false;
1836         /*if(self.enemy.vehicle)
1837         {
1838
1839                 msg_entity = self;
1840                 WriteByte(MSG_ONE, SVC_SETVIEW);
1841                 WriteEntity(MSG_ONE, self.enemy);
1842                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1843
1844                 self.movetype = MOVETYPE_NONE;
1845                 accuracy_resend(self);
1846         }
1847         else
1848         {*/
1849                 msg_entity = self;
1850                 WriteByte(MSG_ONE, SVC_SETVIEW);
1851                 WriteEntity(MSG_ONE, self.enemy);
1852                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1853                 self.movetype = MOVETYPE_NONE;
1854                 accuracy_resend(self);
1855
1856                 if(!SpectateUpdate())
1857                         PutObserverInServer();
1858         //}
1859         return true;
1860 }
1861
1862 void SetSpectator(entity player, entity spectatee)
1863 {
1864         entity old_spectatee = player.enemy;
1865
1866         player.enemy = spectatee;
1867
1868         // WEAPONTODO
1869         // these are required to fix the spectator bug with arc
1870         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1871         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1872 }
1873
1874 float Spectate(entity pl)
1875 {
1876         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1877         if(pl.team != self.team)
1878                 return 0;
1879
1880         SetSpectator(self, pl);
1881         return SpectateSet();
1882 }
1883
1884 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1885 entity CA_SpectateNext(entity start) {
1886         if (start.team == self.team) {
1887                 return start;
1888         }
1889
1890         other = start;
1891         // continue from current player
1892         while(other && other.team != self.team) {
1893                 other = find(other, classname, "player");
1894         }
1895
1896         if (!other) {
1897                 // restart from begining
1898                 other = find(other, classname, "player");
1899                 while(other && other.team != self.team) {
1900                         other = find(other, classname, "player");
1901                 }
1902         }
1903
1904         return other;
1905 }
1906
1907 float SpectateNext()
1908 {
1909         other = find(self.enemy, classname, "player");
1910
1911         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1912                 // CA and ca players when spectating enemies is forbidden
1913                 other = CA_SpectateNext(other);
1914         } else {
1915                 // other modes and ca spectators or spectating enemies is allowed
1916                 if (!other)
1917                         other = find(other, classname, "player");
1918         }
1919
1920         if(other) { SetSpectator(self, other); }
1921
1922         return SpectateSet();
1923 }
1924
1925 float SpectatePrev()
1926 {
1927         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1928         other = findchain(classname, "player");
1929         if (!other) // no player
1930                 return false;
1931
1932         entity first = other;
1933         // skip players until current spectated player
1934         if(self.enemy)
1935         while(other && other != self.enemy)
1936                 other = other.chain;
1937
1938         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1939         {
1940                 do { other = other.chain; }
1941                 while(other && other.team != self.team);
1942
1943                 if (!other)
1944                 {
1945                         other = first;
1946                         while(other.team != self.team)
1947                                 other = other.chain;
1948                         if(other == self.enemy)
1949                                 return true;
1950                 }
1951         }
1952         else
1953         {
1954                 if(other.chain)
1955                         other = other.chain;
1956                 else
1957                         other = first;
1958         }
1959         SetSpectator(self, other);
1960         return SpectateSet();
1961 }
1962
1963 /*
1964 =============
1965 ShowRespawnCountdown()
1966
1967 Update a respawn countdown display.
1968 =============
1969 */
1970 void ShowRespawnCountdown()
1971 {
1972         float number;
1973         if(self.deadflag == DEAD_NO) // just respawned?
1974                 return;
1975         else
1976         {
1977                 number = ceil(self.respawn_time - time);
1978                 if(number <= 0)
1979                         return;
1980                 if(number <= self.respawn_countdown)
1981                 {
1982                         self.respawn_countdown = number - 1;
1983                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1984                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1985                 }
1986         }
1987 }
1988
1989 void LeaveSpectatorMode()
1990 {
1991         if(self.caplayer)
1992                 return;
1993         if(nJoinAllowed(self))
1994         {
1995                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1996                 {
1997                         self.classname = "player";
1998                         nades_RemoveBonus(self);
1999
2000                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2001                                 { JoinBestTeam(self, false, true); }
2002
2003                         if(autocvar_g_campaign)
2004                                 { campaign_bots_may_start = 1; }
2005
2006                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2007
2008                         PutClientInServer();
2009
2010                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2011                 }
2012                 else
2013                         stuffcmd(self, "menu_showteamselect\n");
2014         }
2015         else
2016         {
2017                 // Player may not join because g_maxplayers is set
2018                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2019         }
2020 }
2021
2022 /**
2023  * Determines whether the player is allowed to join. This depends on cvar
2024  * g_maxplayers, if it isn't used this function always return true, otherwise
2025  * it checks whether the number of currently playing players exceeds g_maxplayers.
2026  * @return int number of free slots for players, 0 if none
2027  */
2028 float nJoinAllowed(entity ignore) {
2029         if(!ignore)
2030         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2031         // so report 0 free slots if restricted
2032         {
2033                 if(autocvar_g_forced_team_otherwise == "spectate")
2034                         return 0;
2035                 if(autocvar_g_forced_team_otherwise == "spectator")
2036                         return 0;
2037         }
2038
2039         if(self.team_forced < 0)
2040                 return 0; // forced spectators can never join
2041
2042         // TODO simplify this
2043         entity e;
2044         float totalClients = 0;
2045         FOR_EACH_CLIENT(e)
2046                 if(e != ignore)
2047                         totalClients += 1;
2048
2049         if (!autocvar_g_maxplayers)
2050                 return maxclients - totalClients;
2051
2052         float currentlyPlaying = 0;
2053         FOR_EACH_REALCLIENT(e)
2054                 if(IS_PLAYER(e) || e.caplayer)
2055                         currentlyPlaying += 1;
2056
2057         if(currentlyPlaying < autocvar_g_maxplayers)
2058                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2059
2060         return 0;
2061 }
2062
2063 /**
2064  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2065  * g_maxplayers_spectator_blocktime seconds
2066  */
2067 void checkSpectatorBlock() {
2068         if(IS_SPEC(self) || IS_OBSERVER(self))
2069         if(!self.caplayer)
2070         if(IS_REAL_CLIENT(self))
2071         {
2072                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2073                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2074                         dropclient(self);
2075                 }
2076         }
2077 }
2078
2079 void PrintWelcomeMessage()
2080 {
2081         if(self.motd_actived_time == 0)
2082         {
2083                 if (autocvar_g_campaign) {
2084                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2085                                 self.motd_actived_time = time;
2086                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2087                         }
2088                 } else {
2089                         if (self.BUTTON_INFO) {
2090                                 self.motd_actived_time = time;
2091                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2092                         }
2093                 }
2094         }
2095         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2096         {
2097                 if (autocvar_g_campaign) {
2098                         if (self.BUTTON_INFO)
2099                                 self.motd_actived_time = time;
2100                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2101                                 self.motd_actived_time = 0;
2102                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2103                         }
2104                 } else {
2105                         if (self.BUTTON_INFO)
2106                                 self.motd_actived_time = time;
2107                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2108                                 self.motd_actived_time = 0;
2109                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2110                         }
2111                 }
2112         }
2113         else //if(self.motd_actived_time < 0) // just connected, motd is active
2114         {
2115                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2116                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2117                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2118                 {
2119                         // instanctly hide MOTD
2120                         self.motd_actived_time = 0;
2121                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2122                 }
2123         }
2124 }
2125
2126 void ObserverThink()
2127 {
2128         float prefered_movetype;
2129         if (self.flags & FL_JUMPRELEASED) {
2130                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2131                         self.flags &= ~FL_JUMPRELEASED;
2132                         self.flags |= FL_SPAWNING;
2133                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2134                         self.flags &= ~FL_JUMPRELEASED;
2135                         if(SpectateNext()) {
2136                                 self.classname = "spectator";
2137                         }
2138                 } else {
2139                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2140                         if (self.movetype != prefered_movetype)
2141                                 self.movetype = prefered_movetype;
2142                 }
2143         } else {
2144                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2145                         self.flags |= FL_JUMPRELEASED;
2146                         if(self.flags & FL_SPAWNING)
2147                         {
2148                                 self.flags &= ~FL_SPAWNING;
2149                                 LeaveSpectatorMode();
2150                                 return;
2151                         }
2152                 }
2153         }
2154 }
2155
2156 void SpectatorThink()
2157 {
2158         if (self.flags & FL_JUMPRELEASED) {
2159                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2160                         self.flags &= ~FL_JUMPRELEASED;
2161                         self.flags |= FL_SPAWNING;
2162                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2163                         self.flags &= ~FL_JUMPRELEASED;
2164                         if(SpectateNext()) {
2165                                 self.classname = "spectator";
2166                         } else {
2167                                 self.classname = "observer";
2168                                 PutClientInServer();
2169                         }
2170                         self.impulse = 0;
2171                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2172                         self.flags &= ~FL_JUMPRELEASED;
2173                         if(SpectatePrev()) {
2174                                 self.classname = "spectator";
2175                         } else {
2176                                 self.classname = "observer";
2177                                 PutClientInServer();
2178                         }
2179                         self.impulse = 0;
2180                 } else if (self.BUTTON_ATCK2) {
2181                         self.flags &= ~FL_JUMPRELEASED;
2182                         self.classname = "observer";
2183                         PutClientInServer();
2184                 } else {
2185                         if(!SpectateUpdate())
2186                                 PutObserverInServer();
2187                 }
2188         } else {
2189                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2190                         self.flags |= FL_JUMPRELEASED;
2191                         if(self.flags & FL_SPAWNING)
2192                         {
2193                                 self.flags &= ~FL_SPAWNING;
2194                                 LeaveSpectatorMode();
2195                                 return;
2196                         }
2197                 }
2198                 if(!SpectateUpdate())
2199                         PutObserverInServer();
2200         }
2201
2202         self.flags |= FL_CLIENT | FL_NOTARGET;
2203 }
2204
2205 void vehicles_enter (entity pl, entity veh);
2206 void PlayerUseKey()
2207 {
2208         if (!IS_PLAYER(self))
2209                 return;
2210
2211         if(self.vehicle)
2212         {
2213                 if(!gameover)
2214                 {
2215                         vehicles_exit(VHEF_NORMAL);
2216                         return;
2217                 }
2218         }
2219         else if(autocvar_g_vehicles_enter)
2220         {
2221                 if(!self.frozen)
2222                 if(self.deadflag == DEAD_NO)
2223                 if(!gameover)
2224                 {
2225                         entity head, closest_target = world;
2226                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2227
2228                         while(head) // find the closest acceptable target to enter
2229                         {
2230                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2231                                 if(head.deadflag == DEAD_NO)
2232                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2233                                 if(head.takedamage != DAMAGE_NO)
2234                                 {
2235                                         if(closest_target)
2236                                         {
2237                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2238                                                 { closest_target = head; }
2239                                         }
2240                                         else { closest_target = head; }
2241                                 }
2242
2243                                 head = head.chain;
2244                         }
2245
2246                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2247                 }
2248         }
2249
2250         // a use key was pressed; call handlers
2251         MUTATOR_CALLHOOK(PlayerUseKey);
2252 }
2253
2254 float isInvisibleString(string s)
2255 {
2256         float i, n, c;
2257         s = strdecolorize(s);
2258         for((i = 0), (n = strlen(s)); i < n; ++i)
2259         {
2260                 c = str2chr(s, i);
2261                 switch(c)
2262                 {
2263                         case 0:
2264                         case 32: // space
2265                                 break;
2266                         case 192: // charmap space
2267                                 if (!autocvar_utf8_enable)
2268                                         break;
2269                                 return false;
2270                         case 160: // space in unicode fonts
2271                         case 0xE000 + 192: // utf8 charmap space
2272                                 if (autocvar_utf8_enable)
2273                                         break;
2274                         default:
2275                                 return false;
2276                 }
2277         }
2278         return true;
2279 }
2280
2281 /*
2282 =============
2283 PlayerPreThink
2284
2285 Called every frame for each client before the physics are run
2286 =============
2287 */
2288 .float usekeypressed;
2289 void() nexball_setstatus;
2290 .float last_vehiclecheck;
2291 .int items_added;
2292 void PlayerPreThink (void)
2293 {
2294         WarpZone_PlayerPhysics_FixVAngle();
2295
2296         self.stat_game_starttime = game_starttime;
2297         self.stat_round_starttime = round_starttime;
2298         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2299         self.stat_leadlimit = autocvar_leadlimit;
2300
2301         if(frametime)
2302         {
2303                 // physics frames: update anticheat stuff
2304                 anticheat_prethink();
2305         }
2306
2307         if(blockSpectators && frametime)
2308                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2309                 checkSpectatorBlock();
2310
2311         zoomstate_set = 0;
2312
2313         // Savage: Check for nameless players
2314         if (isInvisibleString(self.netname)) {
2315                 string new_name = strzone(strcat("Player@", self.netaddress));
2316                 if(autocvar_sv_eventlog)
2317                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2318                 if(self.netname_previous)
2319                         strunzone(self.netname_previous);
2320                 self.netname_previous = strzone(new_name);
2321                 self.netname = self.netname_previous;
2322                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2323         } else if(self.netname_previous != self.netname) {
2324                 if(autocvar_sv_eventlog)
2325                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2326                 if(self.netname_previous)
2327                         strunzone(self.netname_previous);
2328                 self.netname_previous = strzone(self.netname);
2329         }
2330
2331         // version nagging
2332         if(self.version_nagtime)
2333                 if(self.cvar_g_xonoticversion)
2334                         if(time > self.version_nagtime)
2335                         {
2336                                 // don't notify git users
2337                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2338                                 {
2339                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2340                                         {
2341                                                 // notify release users if connecting to git
2342                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2343                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2344                                         }
2345                                         else
2346                                         {
2347                                                 float r;
2348                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2349                                                 if(r < 0)
2350                                                 {
2351                                                         // give users new version
2352                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2353                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2354                                                 }
2355                                                 else if(r > 0)
2356                                                 {
2357                                                         // notify users about old server version
2358                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2359                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2360                                                 }
2361                                         }
2362                                 }
2363                                 self.version_nagtime = 0;
2364                         }
2365
2366         // GOD MODE info
2367         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2368         {
2369                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2370                 self.max_armorvalue = 0;
2371         }
2372
2373 #ifdef TETRIS
2374         if (TetrisPreFrame())
2375                 return;
2376 #endif
2377
2378         if(self.frozen == 2)
2379         {
2380                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2381                 self.health = max(1, self.revive_progress * start_health);
2382                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2383
2384                 if(self.revive_progress >= 1)
2385                         Unfreeze(self);
2386         }
2387         else if(self.frozen == 3)
2388         {
2389                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2390                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2391
2392                 if(self.health < 1)
2393                 {
2394                         if(self.vehicle)
2395                                 vehicles_exit(VHEF_RELEASE);
2396                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2397                 }
2398                 else if ( self.revive_progress <= 0 )
2399                         Unfreeze(self);
2400         }
2401
2402         MUTATOR_CALLHOOK(PlayerPreThink);
2403
2404         if(autocvar_g_vehicles_enter)
2405         if(time > self.last_vehiclecheck)
2406         if(IS_PLAYER(self))
2407         if(!gameover)
2408         if(!self.frozen)
2409         if(!self.vehicle)
2410         if(self.deadflag == DEAD_NO)
2411         {
2412                 entity veh;
2413                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2414                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2415                 if(veh.deadflag == DEAD_NO)
2416                 if(veh.takedamage != DAMAGE_NO)
2417                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2418                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2419                 else if(!veh.owner)
2420                 if(!veh.team || SAME_TEAM(self, veh))
2421                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2422                 else if(autocvar_g_vehicles_steal)
2423                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2424
2425                 self.last_vehiclecheck = time + 1;
2426         }
2427
2428         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2429         {
2430                 if(self.BUTTON_USE && !self.usekeypressed)
2431                         PlayerUseKey();
2432                 self.usekeypressed = self.BUTTON_USE;
2433         }
2434
2435         if(IS_REAL_CLIENT(self))
2436                 PrintWelcomeMessage();
2437
2438         if(IS_PLAYER(self))
2439         {
2440
2441                 CheckRules_Player();
2442
2443                 if (intermission_running)
2444                 {
2445                         IntermissionThink ();   // otherwise a button could be missed between
2446                         return;                                 // the think tics
2447                 }
2448
2449                 //don't allow the player to turn around while game is paused!
2450                 if(timeout_status == TIMEOUT_ACTIVE) {
2451                         // FIXME turn this into CSQC stuff
2452                         self.v_angle = self.lastV_angle;
2453                         self.angles = self.lastV_angle;
2454                         self.fixangle = true;
2455                 }
2456
2457                 if(frametime)
2458                 {
2459                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2460                         {
2461                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2462                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2463                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2464
2465                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2466                                 {
2467                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2468                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2469                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2470                                 }
2471                         }
2472                         else
2473                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2474
2475                         player_powerups();
2476                 }
2477
2478                 if (self.deadflag != DEAD_NO)
2479                 {
2480                         if(self.personal && g_race_qualifying)
2481                         {
2482                                 if(time > self.respawn_time)
2483                                 {
2484                                         self.respawn_time = time + 1; // only retry once a second
2485                                         self.stat_respawn_time = self.respawn_time;
2486                                         respawn();
2487                                         self.impulse = 141;
2488                                 }
2489                         }
2490                         else
2491                         {
2492                                 float button_pressed;
2493                                 if(frametime)
2494                                         player_anim();
2495                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2496
2497                                 if (self.deadflag == DEAD_DYING)
2498                                 {
2499                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2500                                                 self.deadflag = DEAD_RESPAWNING;
2501                                         else if(!button_pressed)
2502                                                 self.deadflag = DEAD_DEAD;
2503                                 }
2504                                 else if (self.deadflag == DEAD_DEAD)
2505                                 {
2506                                         if(button_pressed)
2507                                                 self.deadflag = DEAD_RESPAWNABLE;
2508                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2509                                                 self.deadflag = DEAD_RESPAWNING;
2510                                 }
2511                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2512                                 {
2513                                         if(!button_pressed)
2514                                                 self.deadflag = DEAD_RESPAWNING;
2515                                 }
2516                                 else if (self.deadflag == DEAD_RESPAWNING)
2517                                 {
2518                                         if(time > self.respawn_time)
2519                                         {
2520                                                 self.respawn_time = time + 1; // only retry once a second
2521                                                 self.respawn_time_max = self.respawn_time;
2522                                                 respawn();
2523                                         }
2524                                 }
2525
2526                                 ShowRespawnCountdown();
2527
2528                                 if(self.respawn_flags & RESPAWN_SILENT)
2529                                         self.stat_respawn_time = 0;
2530                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2531                                         self.stat_respawn_time = self.respawn_time_max;
2532                                 else
2533                                         self.stat_respawn_time = self.respawn_time;
2534                         }
2535
2536                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2537                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2538                                 self.stat_respawn_time *= -1;
2539
2540                         return;
2541                 }
2542
2543                 self.prevorigin = self.origin;
2544
2545                 float do_crouch = self.BUTTON_CROUCH;
2546                 if(self.hook.state)
2547                         do_crouch = 0;
2548                 if(self.vehicle)
2549                         do_crouch = 0;
2550                 if(self.frozen)
2551                         do_crouch = 0;
2552
2553                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2554                 // It cannot be predicted by the engine!
2555                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2556                         do_crouch = 0;
2557
2558                 if (do_crouch)
2559                 {
2560                         if (!self.crouch)
2561                         {
2562                                 self.crouch = true;
2563                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2564                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2565                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2566                         }
2567                 }
2568                 else
2569                 {
2570                         if (self.crouch)
2571                         {
2572                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2573                                 if (!trace_startsolid)
2574                                 {
2575                                         self.crouch = false;
2576                                         self.view_ofs = PL_VIEW_OFS;
2577                                         setsize (self, PL_MIN, PL_MAX);
2578                                 }
2579                         }
2580                 }
2581
2582                 FixPlayermodel();
2583
2584                 GrapplingHookFrame();
2585
2586                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2587                 //if(frametime)
2588                 {
2589                         self.items &= ~self.items_added;
2590
2591                         W_WeaponFrame();
2592
2593                         self.items_added = 0;
2594                         if(self.items & IT_JETPACK)
2595                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2596                                         self.items_added |= IT_FUEL;
2597
2598                         self.items |= self.items_added;
2599                 }
2600
2601                 player_regen();
2602
2603                 // WEAPONTODO: Add a weapon request for this
2604                 // rot vortex charge to the charge limit
2605                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2606                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2607
2608                 if(frametime)
2609                         player_anim();
2610
2611                 // secret status
2612                 secrets_setstatus();
2613
2614                 // monsters status
2615                 monsters_setstatus();
2616
2617                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2618
2619                 //self.angles_y=self.v_angle_y + 90;   // temp
2620         } else if(gameover) {
2621                 if (intermission_running)
2622                         IntermissionThink ();   // otherwise a button could be missed between
2623                 return;
2624         } else if(IS_OBSERVER(self)) {
2625                 ObserverThink();
2626         } else if(IS_SPEC(self)) {
2627                 SpectatorThink();
2628         }
2629
2630         // WEAPONTODO: Add weapon request for this
2631         if(!zoomstate_set)
2632                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2633
2634         float oldspectatee_status;
2635         oldspectatee_status = self.spectatee_status;
2636         if(IS_SPEC(self))
2637                 self.spectatee_status = num_for_edict(self.enemy);
2638         else if(IS_OBSERVER(self))
2639                 self.spectatee_status = num_for_edict(self);
2640         else
2641                 self.spectatee_status = 0;
2642         if(self.spectatee_status != oldspectatee_status)
2643         {
2644                 ClientData_Touch(self);
2645         }
2646
2647         if(self.teamkill_soundtime)
2648         if(time > self.teamkill_soundtime)
2649         {
2650                 self.teamkill_soundtime = 0;
2651
2652                 entity oldpusher, oldself;
2653
2654                 oldself = self; self = self.teamkill_soundsource;
2655                 oldpusher = self.pusher; self.pusher = oldself;
2656
2657                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2658
2659                 self.pusher = oldpusher;
2660                 self = oldself;
2661         }
2662
2663         if(self.taunt_soundtime)
2664         if(time > self.taunt_soundtime)
2665         {
2666                 self.taunt_soundtime = 0;
2667                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2668         }
2669
2670         target_voicescript_next(self);
2671
2672         // WEAPONTODO: Move into weaponsystem somehow
2673         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2674         if(!self.weapon)
2675                 self.clip_load = self.clip_size = 0;
2676 }
2677
2678 /*
2679 =============
2680 PlayerPostThink
2681
2682 Called every frame for each client after the physics are run
2683 =============
2684 */
2685 .float idlekick_lasttimeleft;
2686 void PlayerPostThink (void)
2687 {
2688         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2689         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2690         {
2691                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2692                 {
2693                         if(self.idlekick_lasttimeleft)
2694                         {
2695                                 self.idlekick_lasttimeleft = 0;
2696                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2697                         }
2698                 }
2699                 else
2700                 {
2701                         float timeleft;
2702                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2703                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2704                         {
2705                                 if(!self.idlekick_lasttimeleft)
2706                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2707                         }
2708                         if(timeleft <= 0)
2709                         {
2710                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2711                                 dropclient(self);
2712                                 return;
2713                         }
2714                         else if(timeleft <= 10)
2715                         {
2716                                 if(timeleft != self.idlekick_lasttimeleft)
2717                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2718                                 self.idlekick_lasttimeleft = timeleft;
2719                         }
2720                 }
2721         }
2722
2723 #ifdef TETRIS
2724         if(self.impulse == 100)
2725                 ImpulseCommands();
2726         if (!TetrisPostFrame())
2727         {
2728 #endif
2729
2730         CheatFrame();
2731
2732         //CheckPlayerJump();
2733
2734         if(IS_PLAYER(self)) {
2735                 CheckRules_Player();
2736                 UpdateChatBubble();
2737                 if (self.impulse)
2738                         ImpulseCommands();
2739                 if (intermission_running)
2740                         return;         // intermission or finale
2741                 GetPressedKeys();
2742         }
2743
2744 #ifdef TETRIS
2745         }
2746 #endif
2747
2748         /*
2749         float i;
2750         for(i = 0; i < 1000; ++i)
2751         {
2752                 vector end;
2753                 end = self.origin + '0 0 1024' + 512 * randomvec();
2754                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2755                 if(trace_fraction < 1)
2756                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2757                 {
2758                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2759                         break;
2760                 }
2761         }
2762         */
2763
2764         if(self.waypointsprite_attachedforcarrier)
2765                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2766
2767         playerdemo_write();
2768
2769         CSQCMODEL_AUTOUPDATE();
2770 }