qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602
 603         Portal_ClearAll(self);
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         MUTATOR_CALLHOOK(MakePlayerObserver);
 612
 613         WaypointSprite_PlayerDead();
 614
 615         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 616                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 617
 618         if(self.killcount != -666) {
 619                 if(g_lms) {
 620                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 621                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 622                         else
 623                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 624                 } else
 625                         bprint ("^4", self.netname, "^4 is spectating now\n");
 626
 627                 if(self.just_joined == FALSE) {
 628                         LogTeamchange(self.playerid, -1, 4);
 629                 } else
 630                         self.just_joined = FALSE;
 631         }
 632
 633         PlayerScore_Clear(self); // clear scores when needed
 634
 635         self.spectatortime = time;
 636
 637         self.classname = "observer";
 638         self.iscreature = FALSE;
 639         self.health = -666;
 640         self.takedamage = DAMAGE_NO;
 641         self.solid = SOLID_NOT;
 642         self.movetype = MOVETYPE_NOCLIP;
 643         self.flags = FL_CLIENT | FL_NOTARGET;
 644         self.armorvalue = 666;
 645         self.effects = 0;
 646         self.armorvalue = cvar("g_balance_armor_start");
 647         self.pauserotarmor_finished = 0;
 648         self.pauserothealth_finished = 0;
 649         self.pauseregen_finished = 0;
 650         self.damageforcescale = 0;
 651         self.death_time = 0;
 652         self.dead_frame = 0;
 653         self.alpha = 0;
 654         self.scale = 0;
 655         self.fade_time = 0;
 656         self.pain_frame = 0;
 657         self.pain_finished = 0;
 658         self.strength_finished = 0;
 659         self.invincible_finished = 0;
 660         self.pushltime = 0;
 661         self.think = SUB_Null;
 662         self.nextthink = 0;
 663         self.hook_time = 0;
 664         self.runes = 0;
 665         self.deadflag = DEAD_NO;
 666         self.angles = spot.angles;
 667         self.angles_z = 0;
 668         self.fixangle = TRUE;
 669         self.crouch = FALSE;
 670
 671         self.view_ofs = PL_VIEW_OFS;
 672         setorigin (self, spot.origin);
 673         setsize (self, '0 0 0', '0 0 0');
 674         self.prevorigin = self.origin;
 675         self.items = 0;
 676         self.weapons = 0;
 677         self.model = "";
 678         FixPlayermodel();
 679         self.model = "";
 680         self.modelindex = 0;
 681         self.weapon = 0;
 682         self.weaponmodel = "";
 683         self.weaponentity = world;
 684         self.exteriorweaponentity = world;
 685         self.killcount = -666;
 686         self.velocity = '0 0 0';
 687         self.avelocity = '0 0 0';
 688         self.punchangle = '0 0 0';
 689         self.punchvector = '0 0 0';
 690         self.oldvelocity = self.velocity;
 691         self.fire_endtime = -1;
 692
 693         if(sv_loddistance1)
 694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 695
 696         if(g_arena)
 697         {
 698                 if(self.version_mismatch)
 699                 {
 700                         Spawnqueue_Unmark(self);
 701                         Spawnqueue_Remove(self);
 702                 }
 703                 else
 704                 {
 705                         Spawnqueue_Insert(self);
 706                 }
 707         }
 708         else if(g_lms)
 709         {
 710                 // Only if the player cannot play at all
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 712                         self.frags = FRAGS_SPECTATOR;
 713                 else
 714                         self.frags = FRAGS_LMS_LOSER;
 715         }
 716         else
 717                 self.frags = FRAGS_SPECTATOR;
 718
 719         //MUTATOR_CALLHOOK(MakePlayerObserver);
 720 }
 721
 722 float RestrictSkin(float s)
 723 {
 724         if(!teams_matter)
 725                 return s;
 726         if(s == 6)
 727                 return 6;
 728         return mod(s, 3);
 729 }
 730
 731 void FixPlayermodel()
 732 {
 733         local string defaultmodel;
 734         local float defaultskin, chmdl, oldskin;
 735         local vector m1, m2;
 736
 737         defaultmodel = "";
 738
 739         if(cvar("sv_defaultcharacter") == 1) {
 740                 defaultskin = 0;
 741
 742                 if(teams_matter)
 743                 {
 744                         string s;
 745                         s = Team_ColorNameLowerCase(self.team);
 746                         if(s != "neutral")
 747                         {
 748                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 749                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 750                         }
 751                 }
 752
 753                 if(defaultmodel == "")
 754                 {
 755                         defaultmodel = cvar_string("sv_defaultplayermodel");
 756                         defaultskin = cvar("sv_defaultplayerskin");
 757                 }
 758         }
 759
 760         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 761         {
 762                 if(self.model != "")
 763                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 764                 self.model = ""; // force the != checks to return true
 765         }
 766
 767         if(defaultmodel != "")
 768         {
 769                 if (defaultmodel != self.model)
 770                 {
 771                         m1 = self.mins;
 772                         m2 = self.maxs;
 773                         setmodel_lod (self, defaultmodel);
 774                         setsize (self, m1, m2);
 775                         chmdl = TRUE;
 776                 }
 777
 778                 oldskin = self.skinindex;
 779                 self.skinindex = defaultskin;
 780         } else {
 781                 if (self.playermodel != self.model || self.playermodel == "")
 782                 {
 783                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 784                         m1 = self.mins;
 785                         m2 = self.maxs;
 786                         setmodel_lod (self, self.playermodel);
 787                         setsize (self, m1, m2);
 788                         chmdl = TRUE;
 789                 }
 790
 791                 oldskin = self.skinindex;
 792                 self.skinindex = RestrictSkin(stof(self.playerskin));
 793         }
 794
 795         if(chmdl || oldskin != self.skinindex)
 796                 self.species = player_getspecies(); // model or skin has changed
 797
 798         if(!teams_matter)
 799                 if(strlen(cvar_string("sv_defaultplayercolors")))
 800                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 801                                 setcolor(self, cvar("sv_defaultplayercolors"));
 802 }
 803
 804 void PlayerTouchExplode(entity p1, entity p2)
 805 {
 806         vector org;
 807         org = (p1.origin + p2.origin) * 0.5;
 808         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 809
 810         te_explosion(org);
 811
 812         entity e;
 813         e = spawn();
 814         setorigin(e, org);
 815         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 816         remove(e);
 817 }
 818
 819 /*
 820 =============
 821 PutClientInServer
 822
 823 Called when a client spawns in the server
 824 =============
 825 */
 826 //void() ctf_playerchanged;
 827 void PutClientInServer (void)
 828 {
 829         if(clienttype(self) == CLIENTTYPE_BOT)
 830         {
 831                 self.classname = "player";
 832         }
 833         else if(clienttype(self) == CLIENTTYPE_REAL)
 834         {
 835                 msg_entity = self;
 836                 WriteByte(MSG_ONE, SVC_SETVIEW);
 837                 WriteEntity(MSG_ONE, self);
 838         }
 839
 840         // player is dead and becomes observer
 841         // FIXME fix LMS scoring for new system
 842         if(g_lms)
 843         {
 844                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 845                         self.classname = "observer";
 846         }
 847
 848         if(g_arena || (g_ca && !allowed_to_spawn))
 849         if(!self.spawned)
 850                 self.classname = "observer";
 851
 852         if(gameover)
 853                 self.classname = "observer";
 854
 855         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 856                 entity spot, oldself;
 857                 float j;
 858
 859                 if(self.team < 0)
 860                         JoinBestTeam(self, FALSE, TRUE);
 861
 862                 race_PreSpawn();
 863
 864                 spot = SelectSpawnPoint (FALSE);
 865                 if(!spot)
 866                 {
 867                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 868                         return; // spawn failed
 869                 }
 870
 871                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 872
 873                 self.classname = "player";
 874                 self.wasplayer = TRUE;
 875                 self.iscreature = TRUE;
 876                 self.movetype = MOVETYPE_WALK;
 877                 self.solid = SOLID_SLIDEBOX;
 878                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 879                 if(cvar("g_playerclip_collisions"))
 880                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 881                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 882                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 883                 self.frags = FRAGS_PLAYER;
 884                 if(independent_players)
 885                         MAKE_INDEPENDENT_PLAYER(self);
 886                 self.flags = FL_CLIENT;
 887                 self.takedamage = DAMAGE_AIM;
 888                 if(g_minstagib)
 889                         self.effects = EF_FULLBRIGHT;
 890                 else
 891                         self.effects = 0;
 892                 self.air_finished = time + 12;
 893                 self.dmg = 2;
 894                 if(cvar("g_balance_nex_charge"))
 895                         self.nex_charge = cvar("g_balance_nex_charge_start");
 896
 897                 if(inWarmupStage)
 898                 {
 899                         self.ammo_shells = warmup_start_ammo_shells;
 900                         self.ammo_nails = warmup_start_ammo_nails;
 901                         self.ammo_rockets = warmup_start_ammo_rockets;
 902                         self.ammo_cells = warmup_start_ammo_cells;
 903                         self.ammo_fuel = warmup_start_ammo_fuel;
 904                         self.health = warmup_start_health;
 905                         self.armorvalue = warmup_start_armorvalue;
 906                         self.weapons = warmup_start_weapons;
 907                 }
 908                 else
 909                 {
 910                         self.ammo_shells = start_ammo_shells;
 911                         self.ammo_nails = start_ammo_nails;
 912                         self.ammo_rockets = start_ammo_rockets;
 913                         self.ammo_cells = start_ammo_cells;
 914                         self.ammo_fuel = start_ammo_fuel;
 915                         self.health = start_health;
 916                         self.armorvalue = start_armorvalue;
 917                         self.weapons = start_weapons;
 918                 }
 919
 920                 if(g_weaponarena_random)
 921                 {
 922                         if(g_weaponarena_random_with_laser)
 923                                 self.weapons &~= WEPBIT_LASER;
 924                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 925                         if(g_weaponarena_random_with_laser)
 926                                 self.weapons |= WEPBIT_LASER;
 927                 }
 928
 929                 self.items = start_items;
 930                 self.jump_interval = time;
 931
 932                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 933                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 934                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 935                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 936                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 937                 //extend the pause of rotting if client was reset at the beginning of the countdown
 938                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 939                         self.spawnshieldtime += game_starttime - time;
 940                         self.pauserotarmor_finished += game_starttime - time;
 941                         self.pauserothealth_finished += game_starttime - time;
 942                         self.pauseregen_finished += game_starttime - time;
 943                 }
 944                 self.damageforcescale = 2;
 945                 self.death_time = 0;
 946                 self.dead_frame = 0;
 947                 self.alpha = 0;
 948                 self.scale = 0;
 949                 self.fade_time = 0;
 950                 self.pain_frame = 0;
 951                 self.pain_finished = 0;
 952                 self.strength_finished = 0;
 953                 self.invincible_finished = 0;
 954                 self.pushltime = 0;
 955                 // players have no think function
 956                 self.think = SUB_Null;
 957                 self.nextthink = 0;
 958                 self.hook_time = 0;
 959                 self.dmg_team = 0;
 960                 self.ballistics_density = cvar("g_ballistics_density_player");
 961
 962                 self.metertime = 0;
 963
 964                 self.runes = 0;
 965
 966                 self.deadflag = DEAD_NO;
 967
 968                 self.angles = spot.angles;
 969
 970                 self.angles_z = 0; // never spawn tilted even if the spot says to
 971                 self.fixangle = TRUE; // turn this way immediately
 972                 self.velocity = '0 0 0';
 973                 self.avelocity = '0 0 0';
 974                 self.punchangle = '0 0 0';
 975                 self.punchvector = '0 0 0';
 976                 self.oldvelocity = self.velocity;
 977                 self.fire_endtime = -1;
 978
 979                 msg_entity = self;
 980                 WRITESPECTATABLE_MSG_ONE({
 981                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 982                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 983                 });
 984
 985                 if(sv_loddistance1)
 986                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 987
 988                 self.model = "";
 989                 FixPlayermodel();
 990
 991                 self.crouch = FALSE;
 992                 self.view_ofs = PL_VIEW_OFS;
 993                 setsize (self, PL_MIN, PL_MAX);
 994                 self.spawnorigin = spot.origin;
 995                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 996                 // don't reset back to last position, even if new position is stuck in solid
 997                 self.oldorigin = self.origin;
 998                 self.prevorigin = self.origin;
 999                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1000
1001                 if(g_arena)
1002                 {
1003                         Spawnqueue_Remove(self);
1004                         Spawnqueue_Mark(self);
1005                 }
1006
1007                 else if(g_ca)
1008                         self.caplayer = 1;
1009
1010                 self.event_damage = PlayerDamage;
1011
1012                 self.bot_attack = TRUE;
1013
1014                 self.statdraintime = time + 5;
1015                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1016
1017                 if(self.killcount == -666) {
1018                         PlayerScore_Clear(self);
1019                         self.killcount = 0;
1020                 }
1021
1022                 self.cnt = WEP_LASER;
1023
1024                 CL_SpawnWeaponentity();
1025                 self.alpha = default_player_alpha;
1026                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1027                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1028
1029                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1030                 self.lms_traveled_distance = 0;
1031                 self.speedrunning = FALSE;
1032
1033                 race_PostSpawn(spot);
1034
1035                 if(cvar("spawn_debug"))
1036                 {
1037                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1038                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1039                 }
1040
1041                 //stuffcmd(self, "chase_active 0");
1042                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1043
1044                 if (cvar("g_spawnsound"))
1045                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1046
1047                 if(g_assault) {
1048                         if(self.team == assault_attacker_team)
1049                                 centerprint(self, "You are attacking!");
1050                         else
1051                                 centerprint(self, "You are defending!");
1052                 }
1053
1054                 target_voicescript_clear(self);
1055
1056                 // reset fields the weapons may use
1057                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1058                         weapon_action(j, WR_RESETPLAYER);
1059
1060                 oldself = self;
1061                 self = spot;
1062                         activator = oldself;
1063                                 SUB_UseTargets();
1064                         activator = world;
1065                 self = oldself;
1066
1067                 MUTATOR_CALLHOOK(PlayerSpawn);
1068
1069                 self.switchweapon = w_getbestweapon(self);
1070                 self.cnt = self.switchweapon;
1071                 self.weapon = 0;
1072         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1073                 PutObserverInServer ();
1074         }
1075
1076         //if(g_ctf)
1077         //      ctf_playerchanged();
1078 }
1079
1080 .float ebouncefactor, ebouncestop; // electro's values
1081 // TODO do we need all these fields, or should we stop autodetecting runtime
1082 // changes and just have a console command to update this?
1083 float ClientInit_SendEntity(entity to, float sf)
1084 {
1085         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1086         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1099         if(sv_foginterval && world.fog != "")
1100                 WriteString(MSG_ENTITY, world.fog);
1101         else
1102                 WriteString(MSG_ENTITY, "");
1103         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1104         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1105         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1106         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1107         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1108         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1109         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1110         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1111         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1112         return TRUE;
1113 }
1114
1115 void ClientInit_CheckUpdate()
1116 {
1117         self.nextthink = time;
1118         if(self.count != cvar("g_balance_armor_blockpercent"))
1119         {
1120                 self.count = cvar("g_balance_armor_blockpercent");
1121                 self.SendFlags |= 1;
1122         }
1123         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1124         {
1125                 self.cnt = cvar("g_balance_weaponswitchdelay");
1126                 self.SendFlags |= 1;
1127         }
1128         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1129         {
1130                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1131                 self.SendFlags |= 1;
1132         }
1133         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1134         {
1135                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1136                 self.SendFlags |= 1;
1137         }
1138         if(self.ebouncefactor != cvar("g_balance_electro_secondary_bouncefactor"))
1139         {
1140                 self.ebouncefactor = cvar("g_balance_electro_secondary_bouncefactor");
1141                 self.SendFlags |= 1;
1142         }
1143         if(self.ebouncestop != cvar("g_balance_electro_secondary_bouncestop"))
1144         {
1145                 self.ebouncestop = cvar("g_balance_electro_secondary_bouncestop");
1146                 self.SendFlags |= 1;
1147         }
1148 }
1149
1150 void ClientInit_Spawn()
1151 {
1152         entity o;
1153         entity e;
1154         e = spawn();
1155         e.classname = "clientinit";
1156         e.think = ClientInit_CheckUpdate;
1157         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1158
1159         o = self;
1160         self = e;
1161         ClientInit_CheckUpdate();
1162         self = o;
1163 }
1164
1165 /*
1166 =============
1167 SetNewParms
1168 =============
1169 */
1170 void SetNewParms (void)
1171 {
1172         // initialize parms for a new player
1173         parm1 = -(86400 * 366);
1174 }
1175
1176 /*
1177 =============
1178 SetChangeParms
1179 =============
1180 */
1181 void SetChangeParms (void)
1182 {
1183         // save parms for level change
1184         parm1 = self.parm_idlesince - time;
1185 }
1186
1187 /*
1188 =============
1189 DecodeLevelParms
1190 =============
1191 */
1192 void DecodeLevelParms (void)
1193 {
1194         // load parms
1195         self.parm_idlesince = parm1;
1196         if(self.parm_idlesince == -(86400 * 366))
1197                 self.parm_idlesince = time;
1198
1199         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1200         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1201 }
1202
1203 /*
1204 =============
1205 ClientKill
1206
1207 Called when a client types 'kill' in the console
1208 =============
1209 */
1210
1211 void ClientKill_Now_TeamChange()
1212 {
1213         if(self.killindicator_teamchange == -1)
1214         {
1215                 self.team = -1;
1216                 JoinBestTeam( self, FALSE, FALSE );
1217         }
1218         else
1219                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1220 }
1221
1222 void ClientKill_Now()
1223 {
1224         if(self.killindicator_teamchange)
1225                 ClientKill_Now_TeamChange();
1226
1227         // in any case:
1228         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1229
1230         if(self.killindicator)
1231         {
1232                 dprint("Cleaned up after a leaked kill indicator.\n");
1233                 remove(self.killindicator);
1234                 self.killindicator = world;
1235         }
1236 }
1237 void KillIndicator_Think()
1238 {
1239         if (!self.owner.modelindex)
1240         {
1241                 self.owner.killindicator = world;
1242                 remove(self);
1243                 return;
1244         }
1245
1246         if(self.cnt <= 0)
1247         {
1248                 self = self.owner;
1249                 ClientKill_Now(); // no oldself needed
1250                 return;
1251         }
1252         else
1253         {
1254                 if(self.cnt <= 10)
1255                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1256                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1257                 {
1258                         if(self.cnt <= 10)
1259                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1260                         if(self.owner.killindicator_teamchange)
1261                         {
1262                                 if(self.owner.killindicator_teamchange == -1)
1263                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1264                                 else
1265                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1266                         }
1267                         else
1268                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1269                 }
1270                 self.nextthink = time + 1;
1271                 self.cnt -= 1;
1272         }
1273 }
1274
1275 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1276 {
1277         float killtime;
1278         entity e;
1279         killtime = cvar("g_balance_kill_delay");
1280
1281         if(g_race_qualifying)
1282                 killtime = 0;
1283
1284         self.killindicator_teamchange = targetteam;
1285
1286         if(!self.killindicator)
1287         {
1288                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1289                 {
1290                         ClientKill_Now();
1291                 }
1292                 else
1293                 {
1294                         self.killindicator = spawn();
1295                         self.killindicator.owner = self;
1296                         self.killindicator.scale = 0.5;
1297                         setattachment(self.killindicator, self, "");
1298                         setorigin(self.killindicator, '0 0 52');
1299                         self.killindicator.think = KillIndicator_Think;
1300                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1301                         self.killindicator.cnt = ceil(killtime);
1302                         self.killindicator.count = bound(0, ceil(killtime), 10);
1303                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1304
1305                         for(e = world; (e = find(e, classname, "body")) != world; )
1306                         {
1307                                 if(e.enemy != self)
1308                                         continue;
1309                                 e.killindicator = spawn();
1310                                 e.killindicator.owner = e;
1311                                 e.killindicator.scale = 0.5;
1312                                 setattachment(e.killindicator, e, "");
1313                                 setorigin(e.killindicator, '0 0 52');
1314                                 e.killindicator.think = KillIndicator_Think;
1315                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1316                                 e.killindicator.cnt = ceil(killtime);
1317                         }
1318                         self.lip = 0;
1319                 }
1320         }
1321         if(self.killindicator)
1322         {
1323                 if(targetteam)
1324                         self.killindicator.colormod = TeamColor(targetteam);
1325                 else
1326                         self.killindicator.colormod = '0 0 0';
1327         }
1328 }
1329
1330 void ClientKill (void)
1331 {
1332         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1333         {
1334                 // do nothing
1335         }
1336         else
1337                 ClientKill_TeamChange(0);
1338 }
1339
1340 void CTS_ClientKill_Think (void)
1341 {
1342         self = self.owner; // set self to the player to be killed
1343         sprint(self, "^1You were killed in order to prevent cheating!");
1344         ClientKill_Now();
1345 }
1346
1347 void CTS_ClientKill (float t) // silent version of ClientKill
1348 {
1349         entity e;
1350         e = spawn();
1351         e.owner = self;
1352         e.think = CTS_ClientKill_Think;
1353         e.nextthink = t;
1354 }
1355
1356 void DoTeamChange(float destteam)
1357 {
1358         float t, c0;
1359         if(!teams_matter)
1360         {
1361                 if(destteam >= 0)
1362                         SetPlayerColors(self, destteam);
1363                 return;
1364         }
1365         if(self.classname == "player")
1366         if(destteam == -1)
1367         {
1368                 CheckAllowedTeams(self);
1369                 t = FindSmallestTeam(self, TRUE);
1370                 switch(self.team)
1371                 {
1372                         case COLOR_TEAM1: c0 = c1; break;
1373                         case COLOR_TEAM2: c0 = c2; break;
1374                         case COLOR_TEAM3: c0 = c3; break;
1375                         case COLOR_TEAM4: c0 = c4; break;
1376                         default:          c0 = 999;
1377                 }
1378                 switch(t)
1379                 {
1380                         case 1:
1381                                 if(c0 > c1)
1382                                         destteam = COLOR_TEAM1;
1383                                 break;
1384                         case 2:
1385                                 if(c0 > c2)
1386                                         destteam = COLOR_TEAM2;
1387                                 break;
1388                         case 3:
1389                                 if(c0 > c3)
1390                                         destteam = COLOR_TEAM3;
1391                                 break;
1392                         case 4:
1393                                 if(c0 > c4)
1394                                         destteam = COLOR_TEAM4;
1395                                 break;
1396                 }
1397                 if(destteam == -1)
1398                         return;
1399         }
1400         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1401                 return;
1402         ClientKill_TeamChange(destteam);
1403 }
1404
1405 void FixClientCvars(entity e)
1406 {
1407         // send prediction settings to the client
1408         stuffcmd(e, "\nin_bindmap 0 0\n");
1409         if(g_race || g_cts)
1410                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1411         if(cvar("g_antilag") == 3) // client side hitscan
1412                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1413         if(sv_gentle)
1414                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1415         /*
1416          * we no longer need to stuff this. Remove this comment block if you feel
1417          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1418         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1419         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1420         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1421         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1422         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1423         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1424         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1425         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1426         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1427         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1428         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1429         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1430         stuffcmd(e, "cl_movement_edgefriction 1\n");
1431          */
1432 }
1433
1434 float PlayerInIDList(entity p, string idlist)
1435 {
1436         float n, i;
1437         string s;
1438
1439         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1440         if not(p.crypto_idfp)
1441                 return 0;
1442
1443         // this function allows abbreviated player IDs too!
1444         n = tokenize_console(idlist);
1445         for(i = 0; i < n; ++i)
1446         {
1447                 s = argv(i);
1448                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1449                         return 1;
1450         }
1451
1452         return 0;
1453 }
1454
1455 /*
1456 =============
1457 ClientConnect
1458
1459 Called when a client connects to the server
1460 =============
1461 */
1462 //void ctf_clientconnect();
1463 string ColoredTeamName(float t);
1464 void DecodeLevelParms (void);
1465 //void dom_player_join_team(entity pl);
1466 void ClientConnect (void)
1467 {
1468         float t;
1469
1470         if(self.flags & FL_CLIENT)
1471         {
1472                 print("Warning: ClientConnect, but already connected!\n");
1473                 return;
1474         }
1475
1476         if(Ban_MaybeEnforceBan(self))
1477                 return;
1478
1479         DecodeLevelParms();
1480
1481 #ifdef WATERMARK
1482         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1483 #endif
1484
1485         self.classname = "player_joining";
1486
1487         self.flags = FL_CLIENT;
1488         self.version_nagtime = time + 10 + random() * 10;
1489
1490         if(player_count<0)
1491         {
1492                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1493                 player_count = 0;
1494         }
1495
1496         PlayerScore_Attach(self);
1497         ClientData_Attach();
1498
1499         bot_clientconnect();
1500
1501         playerdemo_init();
1502
1503         anticheat_init();
1504
1505         race_PreSpawnObserver();
1506
1507         //if(g_domination)
1508         //      dom_player_join_team(self);
1509
1510         // identify the right forced team
1511         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1512                 self.team_forced = COLOR_TEAM1;
1513         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1514                 self.team_forced = COLOR_TEAM2;
1515         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1516                 self.team_forced = COLOR_TEAM3;
1517         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1518                 self.team_forced = COLOR_TEAM4;
1519         else if(cvar_string("g_forced_team_otherwise") == "red")
1520                 self.team_forced = COLOR_TEAM1;
1521         else if(cvar_string("g_forced_team_otherwise") == "blue")
1522                 self.team_forced = COLOR_TEAM2;
1523         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1524                 self.team_forced = COLOR_TEAM3;
1525         else if(cvar_string("g_forced_team_otherwise") == "pink")
1526                 self.team_forced = COLOR_TEAM4;
1527         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1528                 self.team_forced = -1;
1529         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1530                 self.team_forced = -1;
1531         else
1532                 self.team_forced = 0;
1533
1534         if(!teams_matter)
1535                 if(self.team_forced > 0)
1536                         self.team_forced = 0;
1537
1538         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1539
1540         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1541                 self.classname = "observer";
1542         } else {
1543                 if(teams_matter)
1544                 {
1545                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1546                         {
1547                                 self.classname = "player";
1548                                 campaign_bots_may_start = 1;
1549                         }
1550                         else
1551                         {
1552                                 self.classname = "observer"; // do it anyway
1553                         }
1554                 }
1555                 else
1556                 {
1557                         self.classname = "player";
1558                         campaign_bots_may_start = 1;
1559                 }
1560         }
1561
1562         self.playerid = (playerid_last = playerid_last + 1);
1563
1564         if(cvar("sv_eventlog"))
1565                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1566
1567         LogTeamchange(self.playerid, self.team, 1);
1568
1569         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1570
1571         self.netname_previous = strzone(self.netname);
1572
1573         bprint("^4", self.netname, "^4 connected");
1574
1575         if(self.classname != "observer" && (g_domination || g_ctf))
1576                 bprint(" and joined the ", ColoredTeamName(self.team));
1577
1578         bprint("\n");
1579
1580         self.welcomemessage_time = 0;
1581
1582         stuffcmd(self, strcat(clientstuff, "\n"));
1583         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1584         stuffcmd(self, "cl_particles_reloadeffects\n");
1585
1586         FixClientCvars(self);
1587
1588         // spawnfunc_waypoint sprites
1589         WaypointSprite_InitClient(self);
1590
1591         // Wazat's grappling hook
1592         SetGrappleHookBindings();
1593
1594         // get autoswitch state from player when he toggles it
1595         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1596
1597         // get version info from player
1598         stuffcmd(self, "cmd clientversion $gameversion\n");
1599
1600         // get other cvars from player
1601         GetCvars(0);
1602
1603         // set cvar for team scoreboard
1604         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1605
1606         // notify about available teams
1607         if(teams_matter)
1608         {
1609                 CheckAllowedTeams(self);
1610                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1611                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1612         }
1613         else
1614                 stuffcmd(self, "set _teams_available 0\n");
1615
1616         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1617
1618         if(g_arena || g_ca)
1619         {
1620                 self.classname = "observer";
1621                 if(g_arena)
1622                         Spawnqueue_Insert(self);
1623         }
1624         /*else if(g_ctf)
1625         {
1626                 ctf_clientconnect();
1627         }*/
1628
1629         if(teams_matter || radar_showennemies)
1630                 attach_entcs();
1631
1632         bot_relinkplayerlist();
1633
1634         self.spectatortime = time;
1635         if(blockSpectators)
1636         {
1637                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1638         }
1639
1640         self.jointime = time;
1641         self.allowedTimeouts = cvar("sv_timeout_number");
1642
1643         if(clienttype(self) == CLIENTTYPE_REAL)
1644         {
1645                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1646                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1647         }
1648
1649         if(g_lms)
1650         {
1651                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1652                 {
1653                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1654                         self.frags = FRAGS_SPECTATOR;
1655                 }
1656         }
1657
1658         if(!sv_foginterval && world.fog != "")
1659                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1660
1661         SoundEntity_Attach(self);
1662
1663         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1664         {
1665                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1666                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1667         }
1668         else
1669                 self.hitplotfh = -1;
1670
1671         if(g_race || g_cts) {
1672                 string rr;
1673                 if(g_cts)
1674                         rr = CTS_RECORD;
1675                 else
1676                         rr = RACE_RECORD;
1677                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1678
1679                 msg_entity = self;
1680                 race_send_recordtime(MSG_ONE);
1681                 race_send_speedaward(MSG_ONE);
1682
1683                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1684                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1685                 race_send_speedaward_alltimebest(MSG_ONE);
1686
1687                 float i;
1688                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1689                         race_SendRankings(i, 0, 0, MSG_ONE);
1690                 }
1691         }
1692         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1693                 send_CSQC_teamnagger();
1694
1695         send_CSQC_cr_maxbullets(self);
1696
1697         CheatInitClient();
1698 }
1699
1700 /*
1701 =============
1702 ClientDisconnect
1703
1704 Called when a client disconnects from the server
1705 =============
1706 */
1707 .entity chatbubbleentity;
1708 .entity teambubbleentity;
1709 void ReadyCount();
1710 void ClientDisconnect (void)
1711 {
1712         if not(self.flags & FL_CLIENT)
1713         {
1714                 print("Warning: ClientDisconnect without ClientConnect\n");
1715                 return;
1716         }
1717
1718         CheatShutdownClient();
1719
1720         if(self.hitplotfh >= 0)
1721         {
1722                 fclose(self.hitplotfh);
1723                 self.hitplotfh = -1;
1724         }
1725
1726         anticheat_report();
1727         anticheat_shutdown();
1728
1729         playerdemo_shutdown();
1730
1731         bot_clientdisconnect();
1732
1733         if(self.entcs)
1734                 detach_entcs();
1735
1736         if(cvar("sv_eventlog"))
1737                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1738         bprint ("^4",self.netname);
1739         bprint ("^4 disconnected\n");
1740
1741         SoundEntity_Detach(self);
1742
1743         DropAllRunes(self);
1744         MUTATOR_CALLHOOK(ClientDisconnect);
1745
1746         Portal_ClearAll(self);
1747
1748         if(self.flagcarried)
1749                 DropFlag(self.flagcarried, world, world);
1750         if(self.ballcarried)
1751                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1752
1753         // Here, everything has been done that requires this player to be a client.
1754
1755         self.flags &~= FL_CLIENT;
1756
1757         if (self.chatbubbleentity)
1758                 remove (self.chatbubbleentity);
1759
1760         if (self.teambubbleentity)
1761                 remove (self.teambubbleentity);
1762
1763         if (self.killindicator)
1764                 remove (self.killindicator);
1765
1766         WaypointSprite_PlayerGone();
1767
1768         bot_relinkplayerlist();
1769
1770         if(g_arena)
1771         {
1772                 Spawnqueue_Unmark(self);
1773                 Spawnqueue_Remove(self);
1774         }
1775
1776         ClientData_Detach();
1777         PlayerScore_Detach(self);
1778
1779         if(self.netname_previous)
1780                 strunzone(self.netname_previous);
1781         if(self.clientstatus)
1782                 strunzone(self.clientstatus);
1783         if(self.weaponorder_byimpulse)
1784                 strunzone(self.weaponorder_byimpulse);
1785
1786         ClearPlayerSounds();
1787
1788         if(self.personal)
1789                 remove(self.personal);
1790
1791         self.playerid = 0;
1792         ReadyCount();
1793
1794         // free cvars
1795         GetCvars(-1);
1796 }
1797
1798 .float BUTTON_CHAT;
1799 void ChatBubbleThink()
1800 {
1801         self.nextthink = time;
1802         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1803         {
1804                 if(self.owner) // but why can that ever be world?
1805                         self.owner.chatbubbleentity = world;
1806                 remove(self);
1807                 return;
1808         }
1809         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1810 #ifdef TETRIS
1811                 || self.owner.tetris_on
1812 #endif
1813         )
1814                 self.model = self.mdl;
1815         else
1816                 self.model = "";
1817 };
1818
1819 void UpdateChatBubble()
1820 {
1821         if (!self.modelindex)
1822                 return;
1823         // spawn a chatbubble entity if needed
1824         if (!self.chatbubbleentity)
1825         {
1826                 self.chatbubbleentity = spawn();
1827                 self.chatbubbleentity.owner = self;
1828                 self.chatbubbleentity.exteriormodeltoclient = self;
1829                 self.chatbubbleentity.think = ChatBubbleThink;
1830                 self.chatbubbleentity.nextthink = time;
1831                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1832                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1833                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1834                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1835                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1836                 self.chatbubbleentity.model = "";
1837                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1838         }
1839 }
1840
1841
1842 void TeamBubbleThink()
1843 {
1844         self.nextthink = time;
1845         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1846         {
1847                 if(self.owner) // but why can that ever be world?
1848                         self.owner.teambubbleentity = world;
1849                 remove(self);
1850                 return;
1851         }
1852 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1853         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1854                 self.model = "";
1855         else
1856                 self.model = self.mdl;
1857
1858 };
1859
1860 float TeamBubble_customizeentityforclient()
1861 {
1862         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1863 }
1864
1865 void UpdateTeamBubble()
1866 {
1867         if (!self.modelindex || !teams_matter)
1868                 return;
1869         // spawn a teambubble entity if needed
1870         if (!self.teambubbleentity && teams_matter)
1871         {
1872                 self.teambubbleentity = spawn();
1873                 self.teambubbleentity.owner = self;
1874                 self.teambubbleentity.exteriormodeltoclient = self;
1875                 self.teambubbleentity.think = TeamBubbleThink;
1876                 self.teambubbleentity.nextthink = time;
1877                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1878 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1879                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1880                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1881                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1882                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1883                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1884                 self.teambubbleentity.effects = EF_LOWPRECISION;
1885         }
1886 }
1887
1888 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1889 // added to the model skins
1890 /*void UpdateColorModHack()
1891 {
1892         local float c;
1893         c = self.clientcolors & 15;
1894         // LordHavoc: only bothering to support white, green, red, yellow, blue
1895              if (!teams_matter) self.colormod = '0 0 0';
1896         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1897         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1898         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1899         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1900         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1901         else self.colormod = '1 1 1';
1902 };*/
1903
1904 .float oldcolormap;
1905 void respawn(void)
1906 {
1907         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1908         {
1909                 self.solid = SOLID_NOT;
1910                 self.takedamage = DAMAGE_NO;
1911                 self.movetype = MOVETYPE_FLY;
1912                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1913                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1914                 self.effects |= EF_ADDITIVE;
1915                 self.oldcolormap = self.colormap;
1916                 self.colormap = 512;
1917                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1918                 if(cvar("g_respawn_ghosts_maxtime"))
1919                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1920         }
1921
1922         CopyBody(1);
1923         self.effects |= EF_NODRAW; // prevent another CopyBody
1924         if(self.oldcolormap)
1925         {
1926                 self.colormap = self.oldcolormap;
1927                 self.oldcolormap = 0;
1928         }
1929         PutClientInServer();
1930 }
1931
1932 void play_countdown(float finished, string samp)
1933 {
1934         if(clienttype(self) == CLIENTTYPE_REAL)
1935                 if(floor(finished - time - frametime) != floor(finished - time))
1936                         if(finished - time < 6)
1937                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1938 }
1939
1940 /**
1941  * When sv_timeout is used this function returs strings like
1942  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1943  * Called by centerprint functions
1944  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1945  */
1946 string getTimeoutText(float addOneSecond) {
1947         if (!cvar("sv_timeout") || !timeoutStatus)
1948                 return "";
1949
1950         local string retStr;
1951         if (timeoutStatus == 1) {
1952                 if (addOneSecond == 1) {
1953                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1954                 }
1955                 else {
1956                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1957                 }
1958                 return retStr;
1959         }
1960         else if (timeoutStatus == 2) {
1961                 if (addOneSecond) {
1962                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1963                         //don't show messages like "Timeout ends in 0 seconds"...
1964                         if ((remainingTimeoutTime + 1) > 0)
1965                                 return retStr;
1966                         else
1967                                 return "";
1968                 }
1969                 else {
1970                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1971                         //don't show messages like "Timeout ends in 0 seconds"...
1972                         if (remainingTimeoutTime > 0)
1973                                 return retStr;
1974                         else
1975                                 return "";
1976                 }
1977         }
1978         else return "";
1979 }
1980
1981 void player_powerups (void)
1982 {
1983         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1984         {
1985                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1986                 self.modelflags |= MF_ROCKET;
1987         }
1988         else
1989         {
1990                 SoundEntity_StopSound(self, CHAN_PLAYER);
1991                 self.modelflags &~= MF_ROCKET;
1992         }
1993
1994         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1995
1996         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1997                 return;
1998
1999         Fire_ApplyDamage(self);
2000         Fire_ApplyEffect(self);
2001
2002         if (g_minstagib)
2003         {
2004                 self.effects |= EF_FULLBRIGHT;
2005
2006                 if (self.items & IT_STRENGTH)
2007                 {
2008                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2009                         if (time > self.strength_finished)
2010                         {
2011                                 self.alpha = default_player_alpha;
2012                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2013                                 self.items &~= IT_STRENGTH;
2014                                 sprint(self, "^3Invisibility has worn off\n");
2015                         }
2016                 }
2017                 else
2018                 {
2019                         if (time < self.strength_finished)
2020                         {
2021                                 self.alpha = g_minstagib_invis_alpha;
2022                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2023                                 self.items |= IT_STRENGTH;
2024                                 sprint(self, "^3You are invisible\n");
2025                         }
2026                 }
2027
2028                 if (self.items & IT_INVINCIBLE)
2029                 {
2030                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2031                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2032                         {
2033                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2034                                 sprint(self, "^3Speed has worn off\n");
2035                         }
2036                 }
2037                 else
2038                 {
2039                         if (time < self.invincible_finished)
2040                         {
2041                                 self.items = self.items | IT_INVINCIBLE;
2042                                 sprint(self, "^3You are on speed\n");
2043                         }
2044                 }
2045                 return;
2046         }
2047
2048         if (self.items & IT_STRENGTH)
2049         {
2050                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2051                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2052                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2053                 {
2054                         self.items = self.items - (self.items & IT_STRENGTH);
2055                         sprint(self, "^3Strength has worn off\n");
2056                 }
2057         }
2058         else
2059         {
2060                 if (time < self.strength_finished)
2061                 {
2062                         self.items = self.items | IT_STRENGTH;
2063                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2064                 }
2065         }
2066         if (self.items & IT_INVINCIBLE)
2067         {
2068                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2069                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2070                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2071                 {
2072                         self.items = self.items - (self.items & IT_INVINCIBLE);
2073                         sprint(self, "^3Shield has worn off\n");
2074                 }
2075         }
2076         else
2077         {
2078                 if (time < self.invincible_finished)
2079                 {
2080                         self.items = self.items | IT_INVINCIBLE;
2081                         sprint(self, "^3Shield surrounds you\n");
2082                 }
2083         }
2084
2085         if(cvar("g_nodepthtestplayers"))
2086                 self.effects = self.effects | EF_NODEPTHTEST;
2087
2088         if(cvar("g_fullbrightplayers"))
2089                 self.effects = self.effects | EF_FULLBRIGHT;
2090
2091         // midair gamemode: damage only while in the air
2092         // if in midair mode, being on ground grants temporary invulnerability
2093         // (this is so that multishot weapon don't clear the ground flag on the
2094         // first damage in the frame, leaving the player vulnerable to the
2095         // remaining hits in the same frame)
2096         if (self.flags & FL_ONGROUND)
2097         if (g_midair)
2098                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2099
2100         if (time >= game_starttime)
2101         if (time < self.spawnshieldtime)
2102                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2103 }
2104
2105 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2106 {
2107         if(current > stable)
2108                 return current;
2109         else if(current > stable - 0.25) // when close enough, "snap"
2110                 return stable;
2111         else
2112                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2113 }
2114
2115 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2116 {
2117         if(current < stable)
2118                 return current;
2119         else if(current < stable + 0.25) // when close enough, "snap"
2120                 return stable;
2121         else
2122                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2123 }
2124
2125 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2126 {
2127         if(current > rotstable)
2128         {
2129                 if(rotframetime > 0)
2130                 {
2131                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2132                         current = max(rotstable, current - rotlinear * rotframetime);
2133                 }
2134         }
2135         else if(current < regenstable)
2136         {
2137                 if(regenframetime > 0)
2138                 {
2139                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2140                         current = min(regenstable, current + regenlinear * regenframetime);
2141                 }
2142         }
2143
2144         if(current > limit)
2145                 current = limit;
2146
2147         return current;
2148 }
2149
2150 void player_regen (void)
2151 {
2152         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2153         maxh = cvar("g_balance_health_rotstable");
2154         maxa = cvar("g_balance_armor_rotstable");
2155         maxf = cvar("g_balance_fuel_rotstable");
2156         minh = cvar("g_balance_health_regenstable");
2157         mina = cvar("g_balance_armor_regenstable");
2158         minf = cvar("g_balance_fuel_regenstable");
2159         limith = cvar("g_balance_health_limit");
2160         limita = cvar("g_balance_armor_limit");
2161         limitf = cvar("g_balance_fuel_limit");
2162
2163         max_mod = regen_mod = rot_mod = limit_mod = 1;
2164
2165         if (self.runes & RUNE_REGEN)
2166         {
2167                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2168                 {
2169                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2170                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2171                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2172                 }
2173                 else
2174                 {
2175                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2176                         max_mod = cvar("g_balance_rune_regen_hpmod");
2177                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2178                 }
2179         }
2180         else if (self.runes & CURSE_VENOM)
2181         {
2182                 max_mod = cvar("g_balance_curse_venom_hpmod");
2183                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2184                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2185                 else
2186                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2187                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2188                 //if (!self.runes & RUNE_REGEN)
2189                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2190         }
2191         maxh = maxh * max_mod;
2192         //maxa = maxa * max_mod;
2193         //maxf = maxf * max_mod;
2194         minh = minh * max_mod;
2195         //mina = mina * max_mod;
2196         //minf = minf * max_mod;
2197         limith = limith * limit_mod;
2198         limita = limita * limit_mod;
2199         //limitf = limitf * limit_mod;
2200
2201         if(g_lms && g_ca)
2202                 rot_mod = 0;
2203
2204         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2205         {
2206                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2207                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2208
2209                 // if player rotted to death...  die!
2210                 if(self.health < 1)
2211                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2212         }
2213
2214         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2215                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2216 }
2217
2218 float zoomstate_set;
2219 void SetZoomState(float z)
2220 {
2221         if(z != self.zoomstate)
2222         {
2223                 self.zoomstate = z;
2224                 ClientData_Touch(self);
2225         }
2226         zoomstate_set = 1;
2227 }
2228
2229 void GetPressedKeys(void) {
2230         MUTATOR_CALLHOOK(GetPressedKeys);
2231         if (self.movement_x > 0) // get if movement keys are pressed
2232         {       // forward key pressed
2233                 self.pressedkeys |= KEY_FORWARD;
2234                 self.pressedkeys &~= KEY_BACKWARD;
2235         }
2236         else if (self.movement_x < 0)
2237         {       // backward key pressed
2238                 self.pressedkeys |= KEY_BACKWARD;
2239                 self.pressedkeys &~= KEY_FORWARD;
2240         }
2241         else
2242         {       // no x input
2243                 self.pressedkeys &~= KEY_FORWARD;
2244                 self.pressedkeys &~= KEY_BACKWARD;
2245         }
2246
2247         if (self.movement_y > 0)
2248         {       // right key pressed
2249                 self.pressedkeys |= KEY_RIGHT;
2250                 self.pressedkeys &~= KEY_LEFT;
2251         }
2252         else if (self.movement_y < 0)
2253         {       // left key pressed
2254                 self.pressedkeys |= KEY_LEFT;
2255                 self.pressedkeys &~= KEY_RIGHT;
2256         }
2257         else
2258         {       // no y input
2259                 self.pressedkeys &~= KEY_RIGHT;
2260                 self.pressedkeys &~= KEY_LEFT;
2261         }
2262
2263         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2264                 self.pressedkeys |= KEY_JUMP;
2265         else
2266                 self.pressedkeys &~= KEY_JUMP;
2267         if (self.BUTTON_CROUCH)
2268                 self.pressedkeys |= KEY_CROUCH;
2269         else
2270                 self.pressedkeys &~= KEY_CROUCH;
2271 }
2272
2273 void update_stats (float number, float hit, float fired) {
2274 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2275 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2276
2277         if(number) {
2278                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2279                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2280         } else {
2281                 self.stat_hit = hit * sv_accuracy_data_share;
2282                 self.stat_fired = fired * sv_accuracy_data_share;
2283         }
2284 }
2285
2286 /*
2287 ======================
2288 spectate mode routines
2289 ======================
2290 */
2291
2292 .float weapon_count;
2293 void SpectateCopy(entity spectatee) {
2294         if(spectatee.weapon_count < WEP_LAST) {
2295                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2296                 spectatee.weapon_count ++;
2297         } else
2298                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2299
2300         other = spectatee;
2301         MUTATOR_CALLHOOK(SpectateCopy);
2302         self.armortype = spectatee.armortype;
2303         self.armorvalue = spectatee.armorvalue;
2304         self.ammo_cells = spectatee.ammo_cells;
2305         self.ammo_shells = spectatee.ammo_shells;
2306         self.ammo_nails = spectatee.ammo_nails;
2307         self.ammo_rockets = spectatee.ammo_rockets;
2308         self.ammo_fuel = spectatee.ammo_fuel;
2309         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2310         self.health = spectatee.health;
2311         self.impulse = 0;
2312         self.items = spectatee.items;
2313         self.last_pickup = spectatee.last_pickup;
2314         self.metertime = spectatee.metertime;
2315         self.strength_finished = spectatee.strength_finished;
2316         self.invincible_finished = spectatee.invincible_finished;
2317         self.pressedkeys = spectatee.pressedkeys;
2318         self.weapons = spectatee.weapons;
2319         self.switchweapon = spectatee.switchweapon;
2320         self.weapon = spectatee.weapon;
2321         self.punchangle = spectatee.punchangle;
2322         self.view_ofs = spectatee.view_ofs;
2323         self.v_angle = spectatee.v_angle;
2324         self.velocity = spectatee.velocity;
2325         self.dmg_take = spectatee.dmg_take;
2326         self.dmg_save = spectatee.dmg_save;
2327         self.dmg_inflictor = spectatee.dmg_inflictor;
2328         self.angles = spectatee.v_angle;
2329         self.fixangle = TRUE;
2330         setorigin(self, spectatee.origin);
2331         setsize(self, spectatee.mins, spectatee.maxs);
2332         SetZoomState(spectatee.zoomstate);
2333
2334         anticheat_spectatecopy(spectatee);
2335 }
2336
2337 float SpectateUpdate() {
2338         if(!self.enemy)
2339                 return 0;
2340
2341         if (self == self.enemy)
2342                 return 0;
2343
2344         if(self.enemy.classname != "player")
2345                 return 0;
2346
2347         SpectateCopy(self.enemy);
2348
2349         return 1;
2350 }
2351
2352 float SpectateNext() {
2353         other = find(self.enemy, classname, "player");
2354
2355         if (!other)
2356                 other = find(other, classname, "player");
2357
2358         if (other)
2359                 self.enemy = other;
2360
2361         if(self.enemy.classname == "player") {
2362                 msg_entity = self;
2363                 WriteByte(MSG_ONE, SVC_SETVIEW);
2364                 WriteEntity(MSG_ONE, self.enemy);
2365                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2366                 self.movetype = MOVETYPE_NONE;
2367
2368                 self.enemy.weapon_count = 0;
2369
2370                 if(!SpectateUpdate())
2371                         PutObserverInServer();
2372
2373                 return 1;
2374         } else {
2375                 return 0;
2376         }
2377 }
2378
2379 /*
2380 =============
2381 ShowRespawnCountdown()
2382
2383 Update a respawn countdown display.
2384 =============
2385 */
2386 void ShowRespawnCountdown()
2387 {
2388         float number;
2389         if(self.deadflag == DEAD_NO) // just respawned?
2390                 return;
2391         else
2392         {
2393                 number = ceil(self.death_time - time);
2394                 if(number <= 0)
2395                         return;
2396                 if(number <= self.respawn_countdown)
2397                 {
2398                         self.respawn_countdown = number - 1;
2399                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2400                                 AnnounceTo(self, strcat(ftos(number), ""));
2401                 }
2402         }
2403 }
2404
2405 void LeaveSpectatorMode()
2406 {
2407         if(isJoinAllowed()) {
2408                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2409                         self.classname = "player";
2410
2411                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2412                                 JoinBestTeam(self, FALSE, TRUE);
2413
2414                         if(cvar("g_campaign"))
2415                                 campaign_bots_may_start = 1;
2416
2417                         self.stat_count = WEP_LAST;
2418
2419                         PutClientInServer();
2420
2421                         if(self.classname == "player")
2422                                 bprint ("^4", self.netname, "^4 is playing now\n");
2423
2424                         if(!cvar("g_campaign"))
2425                                 centerprint(self,""); // clear MOTD
2426
2427                         return;
2428                 } else {
2429                         if (g_ca && self.caplayer) {
2430                         }       // do nothing
2431                         else
2432                                 stuffcmd(self,"menu_showteamselect\n");
2433                         return;
2434                 }
2435         }
2436         else {
2437                 //player may not join because of g_maxplayers is set
2438                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2439         }
2440 }
2441
2442 /**
2443  * Determines whether the player is allowed to join. This depends on cvar
2444  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2445  * it checks whether the number of currently playing players exceeds g_maxplayers.
2446  * @return bool TRUE if the player is allowed to join, false otherwise
2447  */
2448 float isJoinAllowed() {
2449         if(self.team_forced < 0)
2450                 return FALSE; // forced spectators can never join
2451
2452         if (!cvar("g_maxplayers"))
2453                 return TRUE;
2454
2455         local entity e;
2456         local float currentlyPlaying;
2457         FOR_EACH_REALPLAYER(e) {
2458                 if(e.classname == "player")
2459                         currentlyPlaying += 1;
2460         }
2461         if(currentlyPlaying < cvar("g_maxplayers"))
2462                 return TRUE;
2463
2464         return FALSE;
2465 }
2466
2467 /**
2468  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2469  * g_maxplayers_spectator_blocktime seconds
2470  */
2471 void checkSpectatorBlock() {
2472         if(self.classname == "spectator" || self.classname == "observer") {
2473                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2474                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2475                         dropclient(self);
2476                 }
2477         }
2478 }
2479
2480 void ObserverThink()
2481 {
2482         if (self.flags & FL_JUMPRELEASED) {
2483                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2484                         self.welcomemessage_time = 0;
2485                         self.flags &~= FL_JUMPRELEASED;
2486                         self.flags |= FL_SPAWNING;
2487                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2488                         self.welcomemessage_time = 0;
2489                         self.flags &~= FL_JUMPRELEASED;
2490                         if(SpectateNext() == 1) {
2491                                 self.classname = "spectator";
2492                         }
2493                 }
2494         } else {
2495                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2496                         self.flags |= FL_JUMPRELEASED;
2497                         if(self.flags & FL_SPAWNING)
2498                         {
2499                                 self.flags &~= FL_SPAWNING;
2500                                 LeaveSpectatorMode();
2501                                 return;
2502                         }
2503                 }
2504         }
2505         PrintWelcomeMessage(self);
2506 }
2507
2508 void SpectatorThink()
2509 {
2510         if (self.flags & FL_JUMPRELEASED) {
2511                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2512                         self.welcomemessage_time = 0;
2513                         self.flags &~= FL_JUMPRELEASED;
2514                         self.flags |= FL_SPAWNING;
2515                 } else if(self.BUTTON_ATCK) {
2516                         self.welcomemessage_time = 0;
2517                         self.flags &~= FL_JUMPRELEASED;
2518                         if(SpectateNext() == 1) {
2519                                 self.classname = "spectator";
2520                         } else {
2521                                 self.classname = "observer";
2522                                 self.stat_count = WEP_LAST;
2523                                 PutClientInServer();
2524                         }
2525                 } else if (self.BUTTON_ATCK2) {
2526                         self.welcomemessage_time = 0;
2527                         self.flags &~= FL_JUMPRELEASED;
2528                         self.classname = "observer";
2529                         self.stat_count = WEP_LAST;
2530                         PutClientInServer();
2531                 } else {
2532                         if(!SpectateUpdate())
2533                                 PutObserverInServer();
2534                 }
2535         } else {
2536                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2537                         self.flags |= FL_JUMPRELEASED;
2538                         if(self.flags & FL_SPAWNING)
2539                         {
2540                                 self.flags &~= FL_SPAWNING;
2541                                 LeaveSpectatorMode();
2542                                 return;
2543                         }
2544                 }
2545         }
2546
2547         PrintWelcomeMessage(self);
2548         self.flags |= FL_CLIENT | FL_NOTARGET;
2549 }
2550
2551 .float touchexplode_time;
2552
2553 /*
2554 =============
2555 PlayerPreThink
2556
2557 Called every frame for each client before the physics are run
2558 =============
2559 */
2560 void() ctf_setstatus;
2561 void() nexball_setstatus;
2562 .float items_added;
2563 void PlayerPreThink (void)
2564 {
2565         self.stat_game_starttime = game_starttime;
2566         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2567         self.stat_leadlimit = cvar("leadlimit");
2568
2569         if(frametime)
2570         {
2571                 // physics frames: update anticheat stuff
2572                 anticheat_prethink();
2573         }
2574
2575         if(blockSpectators && frametime)
2576                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2577                 checkSpectatorBlock();
2578
2579         zoomstate_set = 0;
2580
2581         if(self.netname_previous != self.netname)
2582         {
2583                 if(cvar("sv_eventlog"))
2584                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2585                 if(self.netname_previous)
2586                         strunzone(self.netname_previous);
2587                 self.netname_previous = strzone(self.netname);
2588         }
2589
2590         // version nagging
2591         if(self.version_nagtime)
2592                 if(self.cvar_g_xonoticversion)
2593                         if(time > self.version_nagtime)
2594                         {
2595                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2596                                 {
2597                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2598                                         {
2599                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2600                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2601                                         }
2602                                         else
2603                                         {
2604                                                 float r;
2605                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2606                                                 if(r < 0)
2607                                                 {
2608                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2609                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2610                                                 }
2611                                                 else if(r > 0)
2612                                                 {
2613                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2614                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2615                                                 }
2616                                         }
2617                                 }
2618                                 self.version_nagtime = 0;
2619                         }
2620
2621         // GOD MODE info
2622         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2623         {
2624                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2625                 self.max_armorvalue = 0;
2626         }
2627
2628 #ifdef TETRIS
2629         if (TetrisPreFrame())
2630                 return;
2631 #endif
2632
2633         MUTATOR_CALLHOOK(PlayerPreThink);
2634
2635         if(self.classname == "player") {
2636 //              if(self.netname == "Wazat")
2637 //                      bprint(self.classname, "\n");
2638
2639                 CheckRules_Player();
2640
2641                 PrintWelcomeMessage(self);
2642
2643                 if (intermission_running)
2644                 {
2645                         IntermissionThink ();   // otherwise a button could be missed between
2646                         return;                                 // the think tics
2647                 }
2648
2649                 if(self.teleport_time)
2650                 if(time > self.teleport_time)
2651                 {
2652                         self.teleport_time = 0;
2653                         self.effects = self.effects - (self.effects & EF_NODRAW);
2654                 }
2655
2656                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2657                         UpdateSelectedPlayer();
2658
2659                 //don't allow the player to turn around while game is paused!
2660                 if(timeoutStatus == 2) {
2661                         self.v_angle = self.lastV_angle;
2662                         self.angles = self.lastV_angle;
2663                         self.fixangle = TRUE;
2664                 }
2665
2666                 if(frametime)
2667                 {
2668                         if(self.health <= 0 && cvar("g_deathglow"))
2669                         {
2670                                 if(self.glowmod_x > 0)
2671                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2672                                 else
2673                                         self.glowmod_x = -1;
2674                                 if(self.glowmod_y > 0)
2675                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2676                                 else
2677                                         self.glowmod_y = -1;
2678                                 if(self.glowmod_z > 0)
2679                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2680                                 else
2681                                         self.glowmod_z = -1;
2682                         }
2683                         else
2684                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2685                         player_powerups();
2686                 }
2687
2688                 if (self.deadflag != DEAD_NO)
2689                 {
2690                         float button_pressed, force_respawn;
2691                         if(self.personal && g_race_qualifying)
2692                         {
2693                                 if(time > self.death_time)
2694                                 {
2695                                         self.death_time = time + 1; // only retry once a second
2696                                         respawn();
2697                                         self.impulse = 141;
2698                                 }
2699                         }
2700                         else
2701                         {
2702                                 if(frametime)
2703                                         player_anim();
2704                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2705                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2706                                 if (self.deadflag == DEAD_DYING)
2707                                 {
2708                                         if(force_respawn)
2709                                                 self.deadflag = DEAD_RESPAWNING;
2710                                         else if(!button_pressed)
2711                                                 self.deadflag = DEAD_DEAD;
2712                                 }
2713                                 else if (self.deadflag == DEAD_DEAD)
2714                                 {
2715                                         if(button_pressed)
2716                                                 self.deadflag = DEAD_RESPAWNABLE;
2717                                 }
2718                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2719                                 {
2720                                         if(!button_pressed)
2721                                                 self.deadflag = DEAD_RESPAWNING;
2722                                 }
2723                                 else if (self.deadflag == DEAD_RESPAWNING)
2724                                 {
2725                                         if(time > self.death_time)
2726                                         {
2727                                                 self.death_time = time + 1; // only retry once a second
2728                                                 respawn();
2729                                         }
2730                                 }
2731                                 ShowRespawnCountdown();
2732                         }
2733                         return;
2734                 }
2735
2736                 if(g_touchexplode)
2737                 if(time > self.touchexplode_time)
2738                 if(self.classname == "player")
2739                 if(self.deadflag == DEAD_NO)
2740                 if not(IS_INDEPENDENT_PLAYER(self))
2741                 FOR_EACH_PLAYER(other) if(self != other)
2742                 {
2743                         if(time > other.touchexplode_time)
2744                         if(other.deadflag == DEAD_NO)
2745                         if not(IS_INDEPENDENT_PLAYER(other))
2746                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2747                         {
2748                                 PlayerTouchExplode(self, other);
2749                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2750                         }
2751                 }
2752
2753                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2754                 {
2755                         vector dist;
2756
2757                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2758                         dist = self.prevorigin - self.origin;
2759                         dist_z = 0;
2760                         self.lms_traveled_distance += fabs(vlen(dist));
2761
2762                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2763                         {
2764                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2765                                 self.lms_traveled_distance = 0;
2766                         }
2767
2768                         if(time > self.lms_nextcheck)
2769                         {
2770                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2771                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2772                                 {
2773                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2774                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2775                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2776                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2777                                 }
2778                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2779                                 self.lms_traveled_distance = 0;
2780                         }
2781                 }
2782
2783                 self.prevorigin = self.origin;
2784
2785                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2786                 {
2787                         if (!self.crouch)
2788                         {
2789                                 self.crouch = TRUE;
2790                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2791                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2792                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2793                         }
2794                 }
2795                 else
2796                 {
2797                         if (self.crouch)
2798                         {
2799                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2800                                 if (!trace_startsolid)
2801                                 {
2802                                         self.crouch = FALSE;
2803                                         self.view_ofs = PL_VIEW_OFS;
2804                                         setsize (self, PL_MIN, PL_MAX);
2805                                 }
2806                         }
2807                 }
2808
2809                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2810                 {
2811                         if(self.bloodloss_timer < time)
2812                         {
2813                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2814                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2815                         }
2816                 }
2817
2818                 FixPlayermodel();
2819
2820                 GrapplingHookFrame();
2821
2822                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2823                 //if(frametime)
2824                 {
2825                         self.items &~= self.items_added;
2826
2827                         W_WeaponFrame();
2828
2829                         self.items_added = 0;
2830                         if(self.items & IT_JETPACK)
2831                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2832                                         self.items_added |= IT_FUEL;
2833
2834                         self.items |= self.items_added;
2835                 }
2836
2837                 player_regen();
2838
2839                 // rot nex charge to the charge limit
2840                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2841                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2842
2843                 if(frametime)
2844                         player_anim();
2845
2846                 if (g_minstagib)
2847                         minstagib_ammocheck();
2848
2849                 ctf_setstatus();
2850                 nexball_setstatus();
2851
2852                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2853
2854                 //self.angles_y=self.v_angle_y + 90;   // temp
2855         } else if(gameover) {
2856                 if (intermission_running)
2857                         IntermissionThink ();   // otherwise a button could be missed between
2858                 return;
2859         } else if(self.classname == "observer") {
2860                 ObserverThink();
2861         } else if(self.classname == "spectator") {
2862                 SpectatorThink();
2863         }
2864
2865         if(!zoomstate_set)
2866                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2867
2868         float oldspectatee_status;
2869         oldspectatee_status = self.spectatee_status;
2870         if(self.classname == "spectator")
2871                 self.spectatee_status = num_for_edict(self.enemy);
2872         else if(self.classname == "observer")
2873                 self.spectatee_status = num_for_edict(self);
2874         else
2875                 self.spectatee_status = 0;
2876         if(self.spectatee_status != oldspectatee_status)
2877         {
2878                 ClientData_Touch(self);
2879                 if(g_race || g_cts)
2880                         race_InitSpectator();
2881         }
2882
2883         if(self.teamkill_soundtime)
2884         if(time > self.teamkill_soundtime)
2885         {
2886                 self.teamkill_soundtime = 0;
2887
2888                 entity oldpusher, oldself;
2889
2890                 oldself = self; self = self.teamkill_soundsource;
2891                 oldpusher = self.pusher; self.pusher = oldself;
2892
2893                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2894
2895                 self.pusher = oldpusher;
2896                 self = oldself;
2897         }
2898
2899         if(self.taunt_soundtime)
2900         if(time > self.taunt_soundtime)
2901         {
2902                 self.taunt_soundtime = 0;
2903                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2904         }
2905
2906         target_voicescript_next(self);
2907 }
2908
2909 float isInvisibleString(string s)
2910 {
2911         float i, n, c;
2912         s = strdecolorize(s);
2913         for((i = 0), (n = strlen(s)); i < n; ++i)
2914         {
2915                 c = str2chr(s, i);
2916                 switch(c)
2917                 {
2918                         case 0:
2919                         case 32: // space
2920                                 break;
2921                         case 192: // charmap space
2922                                 if (!cvar("utf8_enable"))
2923                                         break;
2924                                 return FALSE;
2925                         case 160: // space in unicode fonts
2926                         case 0xE000 + 192: // utf8 charmap space
2927                                 if (cvar("utf8_enable"))
2928                                         break;
2929                         default:
2930                                 return FALSE;
2931                 }
2932         }
2933         return TRUE;
2934 }
2935
2936 /*
2937 =============
2938 PlayerPostThink
2939
2940 Called every frame for each client after the physics are run
2941 =============
2942 */
2943 .float idlekick_lasttimeleft;
2944 .entity showheadshotbbox;
2945 void showheadshotbbox_think()
2946 {
2947         if(self.owner.showheadshotbbox != self)
2948         {
2949                 remove(self);
2950                 return;
2951         }
2952         self.nextthink = time;
2953         setorigin(self, self.owner.origin);
2954         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2955 }
2956 void PlayerPostThink (void)
2957 {
2958         // Savage: Check for nameless players
2959         if (isInvisibleString(self.netname)) {
2960                 self.netname = "Player";
2961                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2962         }
2963
2964         // send the clients accuracy stats to the client
2965         if(self.stat_count > 0)
2966         if(frametime)
2967         {
2968                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2969                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2970                 self.stat_count -= 1;
2971         }
2972
2973         if(sv_maxidle && frametime)
2974         {
2975                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2976                 float timeleft;
2977                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2978                 if(timeleft <= 0)
2979                 {
2980                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2981                         AnnounceTo(self, "terminated");
2982                         dropclient(self);
2983                         return;
2984                 }
2985                 else if(timeleft <= 10)
2986                 {
2987                         if(timeleft != self.idlekick_lasttimeleft)
2988                         {
2989                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2990                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2991                         }
2992                 }
2993                 else
2994                 {
2995                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2996                 }
2997                 self.idlekick_lasttimeleft = timeleft;
2998         }
2999
3000 #ifdef TETRIS
3001         if(self.impulse == 100)
3002                 ImpulseCommands();
3003         if (TetrisPostFrame())
3004                 return;
3005 #endif
3006
3007         CheatFrame();
3008
3009         if(self.classname == "player") {
3010                 CheckRules_Player();
3011                 UpdateChatBubble();
3012                 UpdateTeamBubble();
3013                 if (self.impulse)
3014                         ImpulseCommands();
3015                 if (intermission_running)
3016                         return;         // intermission or finale
3017                 GetPressedKeys();
3018         } else if (self.classname == "observer") {
3019                 //do nothing
3020         } else if (self.classname == "spectator") {
3021                 //do nothing
3022         }
3023
3024         /*
3025         float i;
3026         for(i = 0; i < 1000; ++i)
3027         {
3028                 vector end;
3029                 end = self.origin + '0 0 1024' + 512 * randomvec();
3030                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3031                 if(trace_fraction < 1)
3032                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3033                 {
3034                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3035                         break;
3036                 }
3037         }
3038         */
3039
3040         Arena_Warmup();
3041
3042         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3043
3044         if(self.waypointsprite_attachedforcarrier)
3045                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3046
3047         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3048         {
3049                 if(!self.showheadshotbbox)
3050                 {
3051                         self.showheadshotbbox = spawn();
3052                         self.showheadshotbbox.classname = "headshotbbox";
3053                         self.showheadshotbbox.owner = self;
3054                         self.showheadshotbbox.think = showheadshotbbox_think;
3055                         self.showheadshotbbox.nextthink = time;
3056                         self = self.showheadshotbbox;
3057                         self.think();
3058                         self = self.owner;
3059                 }
3060         }
3061         else
3062         {
3063                 if(self.showheadshotbbox)
3064                         remove(self.showheadshotbbox);
3065         }
3066
3067         playerdemo_write();
3068
3069         if((g_cts || g_race) && self.cvar_cl_allow_uid2name)
3070         {
3071                 if(!self.stored_netname)
3072                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3073                 if(self.stored_netname != self.netname)
3074                 {
3075                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3076                         strunzone(self.stored_netname);
3077                         self.stored_netname = strzone(self.netname);
3078                 }
3079         }
3080
3081         /*
3082         if(g_race)
3083                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3084         */
3085 }