qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teamplay)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 }
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck >= 0)
 120                 if(spot.team != teamcheck)
 121                         return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(clienttype(self) == CLIENTTYPE_REAL)
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         shortest = vlen(world.maxs - world.mins);
 139         FOR_EACH_PLAYER(player) if (player != self)
 140         {
 141                 thisdist = vlen(player.origin - spot.origin);
 142                 if (thisdist < shortest)
 143                         shortest = thisdist;
 144         }
 145         if(shortest > mindist)
 146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 147
 148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 149         spawn_spot = spot;
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 entity ent;
 154                 float found;
 155
 156                 found = 0;
 157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 158                 {
 159                         ++found;
 160                         if(ent.spawn_evalfunc)
 161                         {
 162                                 entity oldself = self;
 163                                 self = ent;
 164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 165                                 self = oldself;
 166                                 if(spawn_score_x < 0)
 167                                         return spawn_score;
 168                         }
 169                 }
 170
 171                 if(!found)
 172                 {
 173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 174                         return '-1 0 0';
 175                 }
 176         }
 177
 178         MUTATOR_CALLHOOK(Spawn_Score);
 179         return spawn_score;
 180 }
 181
 182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 183 {
 184         entity spot;
 185         for(spot = firstspot; spot; spot = spot.chain)
 186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 187 }
 188
 189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 190 {
 191         entity spot, spotlist, spotlistend;
 192
 193         spotlist = world;
 194         spotlistend = world;
 195
 196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 201                 {
 202                         if(spotlistend)
 203                                 spotlistend.chain = spot;
 204                         spotlistend = spot;
 205                         if(!spotlist)
 206                                 spotlist = spot;
 207                 }
 208         }
 209         if(spotlistend)
 210                 spotlistend.chain = world;
 211
 212         return spotlist;
 213 }
 214
 215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 216 {
 217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 219         entity spot;
 220
 221         RandomSelection_Init();
 222         for(spot = firstspot; spot; spot = spot.chain)
 223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 224
 225         return RandomSelection_chosen_ent;
 226 }
 227
 228 /*
 229 =============
 230 SelectSpawnPoint
 231
 232 Finds a point to respawn
 233 =============
 234 */
 235 entity SelectSpawnPoint (float anypoint)
 236 {
 237         float teamcheck;
 238         entity spot, firstspot;
 239
 240         spot = find (world, classname, "testplayerstart");
 241         if (spot)
 242                 return spot;
 243
 244         if(anypoint || autocvar_g_spawn_useallspawns)
 245                 teamcheck = -1;
 246         else if(have_team_spawns > 0)
 247         {
 248                 if(have_team_spawns_forteam[self.team] == 0)
 249                 {
 250                         // we request a spawn for a team, and we have team
 251                         // spawns, but that team has no spawns?
 252                         if(have_team_spawns_forteam[0])
 253                                 // try noteam spawns
 254                                 teamcheck = 0;
 255                         else
 256                                 // if not, any spawn has to do
 257                                 teamcheck = -1;
 258                 }
 259                 else
 260                         teamcheck = self.team; // MUST be team
 261         }
 262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 263                 teamcheck = 0; // MUST be noteam
 264         else
 265                 teamcheck = -1;
 266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 267
 268
 269         // get the entire list of spots
 270         firstspot = findchain(classname, "info_player_deathmatch");
 271         // filter out the bad ones
 272         // (note this returns the original list if none survived)
 273         if(anypoint)
 274         {
 275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 276         }
 277         else
 278         {
 279                 float mindist;
 280                 if (g_arena && arena_roundbased)
 281                         mindist = 800;
 282                 else
 283                         mindist = 100;
 284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 285
 286                 // there is 50/50 chance of choosing a random spot or the furthest spot
 287                 // (this means that roughly every other spawn will be furthest, so you
 288                 // usually won't get fragged at spawn twice in a row)
 289                 if (random() > autocvar_g_spawn_furthest)
 290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 291                 else
 292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 293         }
 294
 295         if (!spot)
 296         {
 297                 if(autocvar_spawn_debug)
 298                         GotoNextMap(0);
 299                 else
 300                 {
 301                         if(some_spawn_has_been_used)
 302                                 return world; // team can't spawn any more, because of actions of other team
 303                         else
 304                                 error("Cannot find a spawn point - please fix the map!");
 305                 }
 306         }
 307
 308         return spot;
 309 }
 310
 311 /*
 312 =============
 313 CheckPlayerModel
 314
 315 Checks if the argument string can be a valid playermodel.
 316 Returns a valid one in doubt.
 317 =============
 318 */
 319 string FallbackPlayerModel;
 320 string CheckPlayerModel(string plyermodel) {
 321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 322         {
 323                 // note: we cannot summon Don Strunzone here, some player may
 324                 // still have the model string set. In case anyone manages how
 325                 // to change a cvar default, we'll have a small leak here.
 326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 327         }
 328         // only in right path
 329         if( substring(plyermodel,0,14) != "models/player/")
 330                 return FallbackPlayerModel;
 331         // only good file extensions
 332         if(substring(plyermodel,-4,4) != ".zym")
 333         if(substring(plyermodel,-4,4) != ".dpm")
 334         if(substring(plyermodel,-4,4) != ".iqm")
 335         if(substring(plyermodel,-4,4) != ".md3")
 336         if(substring(plyermodel,-4,4) != ".psk")
 337                 return FallbackPlayerModel;
 338         // forbid the LOD models
 339         if(substring(plyermodel, -9,5) == "_lod1")
 340                 return FallbackPlayerModel;
 341         if(substring(plyermodel, -9,5) == "_lod2")
 342                 return FallbackPlayerModel;
 343         if(plyermodel != strtolower(plyermodel))
 344                 return FallbackPlayerModel;
 345         // also, restrict to server models
 346         if(autocvar_sv_servermodelsonly)
 347         {
 348                 if(!fexists(plyermodel))
 349                         return FallbackPlayerModel;
 350         }
 351         return plyermodel;
 352 }
 353
 354 void setplayermodel(entity e, string modelname)
 355 {
 356         precache_model(modelname);
 357         setmodel(e, modelname);
 358         player_setupanimsformodel();
 359         UpdatePlayerSounds();
 360 }
 361
 362 /*
 363 =============
 364 PutObserverInServer
 365
 366 putting a client as observer in the server
 367 =============
 368 */
 369 void FixPlayermodel();
 370 void PutObserverInServer (void)
 371 {
 372         entity  spot;
 373     self.hud = HUD_NORMAL;
 374         race_PreSpawnObserver();
 375
 376         spot = SelectSpawnPoint (TRUE);
 377         if(!spot)
 378                 error("No spawnpoints for observers?!?\n");
 379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 380
 381         if(clienttype(self) == CLIENTTYPE_REAL)
 382         {
 383                 msg_entity = self;
 384                 WriteByte(MSG_ONE, SVC_SETVIEW);
 385                 WriteEntity(MSG_ONE, self);
 386         }
 387
 388         if(g_lms)
 389         {
 390                 // Only if the player cannot play at all
 391                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 392                         self.frags = FRAGS_SPECTATOR;
 393                 else
 394                         self.frags = FRAGS_LMS_LOSER;
 395         }
 396         else if((g_race && g_race_qualifying) || g_cts)
 397         {
 398                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 399                         self.frags = FRAGS_LMS_LOSER;
 400                 else
 401                         self.frags = FRAGS_SPECTATOR;
 402         }
 403         else
 404                 self.frags = FRAGS_SPECTATOR;
 405
 406         MUTATOR_CALLHOOK(MakePlayerObserver);
 407
 408         minstagib_stop_countdown(self);
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 if(!inWarmupStage)
 415                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 416                 self.alivetime = 0;
 417         }
 418
 419         if(self.vehicle)
 420                 vehicles_exit(VHEF_RELESE);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 425                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 426
 427         if(self.killcount != -666) {
 428                 if(g_lms) {
 429                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
 430                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
 431                         else
 432                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
 433                 } else { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname); }
 434
 435                 if(self.just_joined == FALSE) {
 436                         LogTeamchange(self.playerid, -1, 4);
 437                 } else
 438                         self.just_joined = FALSE;
 439         }
 440
 441         PlayerScore_Clear(self); // clear scores when needed
 442
 443         accuracy_resend(self);
 444
 445         self.spectatortime = time;
 446
 447         self.classname = "observer";
 448         self.iscreature = FALSE;
 449         self.teleportable = TELEPORT_SIMPLE;
 450         self.damagedbycontents = FALSE;
 451         self.health = -666;
 452         self.takedamage = DAMAGE_NO;
 453         self.solid = SOLID_NOT;
 454         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 455         self.flags = FL_CLIENT | FL_NOTARGET;
 456         self.armorvalue = 666;
 457         self.effects = 0;
 458         self.armorvalue = autocvar_g_balance_armor_start;
 459         self.pauserotarmor_finished = 0;
 460         self.pauserothealth_finished = 0;
 461         self.pauseregen_finished = 0;
 462         self.damageforcescale = 0;
 463         self.death_time = 0;
 464         self.respawn_flags = 0;
 465         self.respawn_time = 0;
 466         self.stat_respawn_time = 0;
 467         self.alpha = 0;
 468         self.scale = 0;
 469         self.fade_time = 0;
 470         self.pain_frame = 0;
 471         self.pain_finished = 0;
 472         self.strength_finished = 0;
 473         self.invincible_finished = 0;
 474         self.superweapons_finished = 0;
 475         self.pushltime = 0;
 476         self.istypefrag = 0;
 477         self.think = func_null;
 478         self.nextthink = 0;
 479         self.hook_time = 0;
 480         self.deadflag = DEAD_NO;
 481         self.angles = spot.angles;
 482         self.angles_z = 0;
 483         self.fixangle = TRUE;
 484         self.crouch = FALSE;
 485
 486         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 487         self.prevorigin = self.origin;
 488         self.items = 0;
 489         WEPSET_CLEAR_E(self);
 490         self.model = "";
 491         FixPlayermodel();
 492         setmodel(self, "null");
 493         self.drawonlytoclient = self;
 494
 495         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 496         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 497
 498         self.weapon = 0;
 499         self.weaponname = "";
 500         self.switchingweapon = 0;
 501         self.weaponmodel = "";
 502         self.weaponentity = world;
 503         self.exteriorweaponentity = world;
 504         self.killcount = -666;
 505         self.velocity = '0 0 0';
 506         self.avelocity = '0 0 0';
 507         self.punchangle = '0 0 0';
 508         self.punchvector = '0 0 0';
 509         self.oldvelocity = self.velocity;
 510         self.fire_endtime = -1;
 511 }
 512
 513 .float model_randomizer;
 514 void FixPlayermodel()
 515 {
 516         string defaultmodel;
 517         float defaultskin, chmdl, oldskin, n, i;
 518         vector m1, m2;
 519
 520         defaultmodel = "";
 521         defaultskin = 0;
 522         chmdl = FALSE;
 523
 524         if(autocvar_sv_defaultcharacter == 1)
 525         {
 526                 if(teamplay)
 527                 {
 528                         string s;
 529                         s = Team_ColorName_Lower(self.team);
 530                         if(s != "neutral")
 531                         {
 532                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 533                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 534                         }
 535                 }
 536
 537                 if(defaultmodel == "")
 538                 {
 539                         defaultmodel = autocvar_sv_defaultplayermodel;
 540                         defaultskin = autocvar_sv_defaultplayerskin;
 541                 }
 542
 543                 n = tokenize_console(defaultmodel);
 544                 if(n > 0)
 545                         defaultmodel = argv(floor(n * self.model_randomizer));
 546
 547                 i = strstrofs(defaultmodel, ":", 0);
 548                 if(i >= 0)
 549                 {
 550                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 551                         defaultmodel = substring(defaultmodel, 0, i);
 552                 }
 553         }
 554
 555         if(defaultmodel != "")
 556         {
 557                 if (defaultmodel != self.model)
 558                 {
 559                         m1 = self.mins;
 560                         m2 = self.maxs;
 561                         setplayermodel (self, defaultmodel);
 562                         setsize (self, m1, m2);
 563                         chmdl = TRUE;
 564                 }
 565
 566                 oldskin = self.skin;
 567                 self.skin = defaultskin;
 568         } else {
 569                 if (self.playermodel != self.model || self.playermodel == "")
 570                 {
 571                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 572                         m1 = self.mins;
 573                         m2 = self.maxs;
 574                         setplayermodel (self, self.playermodel);
 575                         setsize (self, m1, m2);
 576                         chmdl = TRUE;
 577                 }
 578
 579                 oldskin = self.skin;
 580                 self.skin = stof(self.playerskin);
 581         }
 582
 583         if(chmdl || oldskin != self.skin) // model or skin has changed
 584         {
 585                 self.species = player_getspecies(); // update species
 586                 UpdatePlayerSounds(); // update skin sounds
 587         }
 588
 589         if(!teamplay)
 590                 if(strlen(autocvar_sv_defaultplayercolors))
 591                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 592                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 593 }
 594
 595 void PlayerTouchExplode(entity p1, entity p2)
 596 {
 597         vector org;
 598         org = (p1.origin + p2.origin) * 0.5;
 599         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 600
 601         te_explosion(org);
 602
 603         entity e;
 604         e = spawn();
 605         setorigin(e, org);
 606         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 607         remove(e);
 608 }
 609
 610 /*
 611 =============
 612 PutClientInServer
 613
 614 Called when a client spawns in the server
 615 =============
 616 */
 617
 618 void PutClientInServer (void)
 619 {
 620         if(clienttype(self) == CLIENTTYPE_BOT)
 621                 self.classname = "player";
 622         else if(clienttype(self) == CLIENTTYPE_REAL)
 623         {
 624                 msg_entity = self;
 625                 WriteByte(MSG_ONE, SVC_SETVIEW);
 626                 WriteEntity(MSG_ONE, self);
 627         }
 628
 629         // reset player keys
 630         self.itemkeys = 0;
 631
 632         // player is dead and becomes observer
 633         // FIXME fix LMS scoring for new system
 634         if(g_lms)
 635         {
 636                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 637                         self.classname = "observer";
 638         }
 639
 640         MUTATOR_CALLHOOK(PutClientInServer);
 641
 642         if(gameover)
 643                 self.classname = "observer";
 644
 645         if(self.classname == "player") {
 646                 entity spot, oldself;
 647                 float j;
 648
 649                 accuracy_resend(self);
 650
 651                 if(self.team < 0)
 652                         JoinBestTeam(self, FALSE, TRUE);
 653
 654                 race_PreSpawn();
 655
 656                 spot = SelectSpawnPoint (FALSE);
 657                 if(!spot)
 658                 {
 659                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 660                         return; // spawn failed
 661                 }
 662
 663                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 664
 665                 self.classname = "player";
 666                 self.wasplayer = TRUE;
 667                 self.iscreature = TRUE;
 668                 self.teleportable = TELEPORT_NORMAL;
 669                 self.damagedbycontents = TRUE;
 670                 self.movetype = MOVETYPE_WALK;
 671                 self.solid = SOLID_SLIDEBOX;
 672                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 673                 if(autocvar_g_playerclip_collisions)
 674                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 675                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 676                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 677                 self.frags = FRAGS_PLAYER;
 678                 if(INDEPENDENT_PLAYERS)
 679                         MAKE_INDEPENDENT_PLAYER(self);
 680                 self.flags = FL_CLIENT;
 681                 if(autocvar__notarget)
 682                         self.flags |= FL_NOTARGET;
 683                 self.takedamage = DAMAGE_AIM;
 684                 if(g_minstagib)
 685                         self.effects = EF_FULLBRIGHT;
 686                 else
 687                         self.effects = 0;
 688                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 689                 self.air_finished = time + 12;
 690                 self.dmg = 2;
 691                 if(autocvar_g_balance_nex_charge)
 692                 {
 693                         if(autocvar_g_balance_nex_secondary_chargepool)
 694                                 self.nex_chargepool_ammo = 1;
 695                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 696                 }
 697
 698                 if(inWarmupStage)
 699                 {
 700                         self.ammo_shells = warmup_start_ammo_shells;
 701                         self.ammo_nails = warmup_start_ammo_nails;
 702                         self.ammo_rockets = warmup_start_ammo_rockets;
 703                         self.ammo_cells = warmup_start_ammo_cells;
 704                         self.ammo_fuel = warmup_start_ammo_fuel;
 705                         self.health = warmup_start_health;
 706                         self.armorvalue = warmup_start_armorvalue;
 707                         WEPSET_COPY_EA(self, warmup_start_weapons);
 708                 }
 709                 else
 710                 {
 711                         self.ammo_shells = start_ammo_shells;
 712                         self.ammo_nails = start_ammo_nails;
 713                         self.ammo_rockets = start_ammo_rockets;
 714                         self.ammo_cells = start_ammo_cells;
 715                         self.ammo_fuel = start_ammo_fuel;
 716                         self.health = start_health;
 717                         self.armorvalue = start_armorvalue;
 718                         WEPSET_COPY_EA(self, start_weapons);
 719                 }
 720
 721                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 722                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 723                 else
 724                         self.superweapons_finished = 0;
 725
 726                 if(g_weaponarena_random)
 727                 {
 728                         if(g_weaponarena_random_with_laser)
 729                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 730                         W_RandomWeapons(self, g_weaponarena_random);
 731                         if(g_weaponarena_random_with_laser)
 732                                 WEPSET_OR_EW(self, WEP_LASER);
 733                 }
 734
 735                 self.items = start_items;
 736
 737                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 738                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 739                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 740                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 741                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 742                 //extend the pause of rotting if client was reset at the beginning of the countdown
 743                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 744                         self.spawnshieldtime += game_starttime - time;
 745                         self.pauserotarmor_finished += game_starttime - time;
 746                         self.pauserothealth_finished += game_starttime - time;
 747                         self.pauseregen_finished += game_starttime - time;
 748                 }
 749                 self.damageforcescale = 2;
 750                 self.death_time = 0;
 751                 self.respawn_flags = 0;
 752                 self.respawn_time = 0;
 753                 self.stat_respawn_time = 0;
 754                 self.scale = 0;
 755                 self.fade_time = 0;
 756                 self.pain_frame = 0;
 757                 self.pain_finished = 0;
 758                 self.strength_finished = 0;
 759                 self.invincible_finished = 0;
 760                 self.pushltime = 0;
 761                 // players have no think function
 762                 self.think = func_null;
 763                 self.nextthink = 0;
 764                 self.hook_time = 0;
 765                 self.dmg_team = 0;
 766                 self.ballistics_density = autocvar_g_ballistics_density_player;
 767
 768                 self.metertime = 0;
 769
 770                 self.deadflag = DEAD_NO;
 771
 772                 self.angles = spot.angles;
 773
 774                 self.angles_z = 0; // never spawn tilted even if the spot says to
 775                 self.fixangle = TRUE; // turn this way immediately
 776                 self.velocity = '0 0 0';
 777                 self.avelocity = '0 0 0';
 778                 self.punchangle = '0 0 0';
 779                 self.punchvector = '0 0 0';
 780                 self.oldvelocity = self.velocity;
 781                 self.fire_endtime = -1;
 782
 783                 msg_entity = self;
 784                 WRITESPECTATABLE_MSG_ONE({
 785                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 786                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 787                 });
 788
 789                 self.model = "";
 790                 FixPlayermodel();
 791                 self.drawonlytoclient = world;
 792
 793                 self.crouch = FALSE;
 794                 self.view_ofs = PL_VIEW_OFS;
 795                 setsize (self, PL_MIN, PL_MAX);
 796                 self.spawnorigin = spot.origin;
 797                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 798                 // don't reset back to last position, even if new position is stuck in solid
 799                 self.oldorigin = self.origin;
 800                 self.prevorigin = self.origin;
 801                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 802                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 803         self.hud = HUD_NORMAL;
 804
 805                 self.event_damage = PlayerDamage;
 806
 807                 self.bot_attack = TRUE;
 808
 809                 self.statdraintime = time + 5;
 810                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 811
 812                 if(self.killcount == -666) {
 813                         PlayerScore_Clear(self);
 814                         self.killcount = 0;
 815                 }
 816
 817                 CL_SpawnWeaponentity();
 818                 self.alpha = default_player_alpha;
 819                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 820                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 821
 822                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 823                 self.lms_traveled_distance = 0;
 824                 self.speedrunning = FALSE;
 825
 826                 race_PostSpawn(spot);
 827
 828                 //stuffcmd(self, "chase_active 0");
 829                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 830
 831                 if(g_assault) {
 832                         if(self.team == assault_attacker_team)
 833                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 834                         else
 835                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 836                 }
 837
 838                 target_voicescript_clear(self);
 839
 840                 // reset fields the weapons may use
 841                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 842                 {
 843                         weapon_action(j, WR_RESETPLAYER);
 844
 845                         // all weapons must be fully loaded when we spawn
 846                         entity e;
 847                         e = get_weaponinfo(j);
 848                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 849                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 850                 }
 851
 852                 oldself = self;
 853                 self = spot;
 854                         activator = oldself;
 855                                 string s;
 856                                 s = self.target;
 857                                 self.target = string_null;
 858                                 SUB_UseTargets();
 859                                 self.target = s;
 860                         activator = world;
 861                 self = oldself;
 862
 863                 spawn_spot = spot;
 864                 MUTATOR_CALLHOOK(PlayerSpawn);
 865
 866                 if(autocvar_spawn_debug)
 867                 {
 868                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 869                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 870                 }
 871
 872                 self.switchweapon = w_getbestweapon(self);
 873                 self.cnt = -1; // W_LastWeapon will not complain
 874                 self.weapon = 0;
 875                 self.weaponname = "";
 876                 self.switchingweapon = 0;
 877
 878                 if(!inWarmupStage)
 879                         if(!self.alivetime)
 880                                 self.alivetime = time;
 881
 882                 antilag_clear(self);
 883
 884                 if (autocvar_g_spawnsound)
 885                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 886         } else if(self.classname == "observer") {
 887                 PutObserverInServer ();
 888         }
 889 }
 890
 891 .float ebouncefactor, ebouncestop; // electro's values
 892 // TODO do we need all these fields, or should we stop autodetecting runtime
 893 // changes and just have a console command to update this?
 894 float ClientInit_SendEntity(entity to, float sf)
 895 {
 896         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 897         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 898         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 899         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 900         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 901         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 902         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 903         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 904         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 905         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 906         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 907         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 908         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 909         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 910         if(sv_foginterval && world.fog != "")
 911                 WriteString(MSG_ENTITY, world.fog);
 912         else
 913                 WriteString(MSG_ENTITY, "");
 914         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 915         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 916         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 917         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 918         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 919         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 920         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 921         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 922         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 923         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 924         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 925         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 926         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 927         return TRUE;
 928 }
 929
 930 void ClientInit_CheckUpdate()
 931 {
 932         self.nextthink = time;
 933         if(self.count != autocvar_g_balance_armor_blockpercent)
 934         {
 935                 self.count = autocvar_g_balance_armor_blockpercent;
 936                 self.SendFlags |= 1;
 937         }
 938         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 939         {
 940                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 941                 self.SendFlags |= 1;
 942         }
 943         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 944         {
 945                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 946                 self.SendFlags |= 1;
 947         }
 948         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 949         {
 950                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 951                 self.SendFlags |= 1;
 952         }
 953         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 954         {
 955                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 956                 self.SendFlags |= 1;
 957         }
 958         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 959         {
 960                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 961                 self.SendFlags |= 1;
 962         }
 963 }
 964
 965 void ClientInit_Spawn()
 966 {
 967         entity o;
 968         entity e;
 969         e = spawn();
 970         e.classname = "clientinit";
 971         e.think = ClientInit_CheckUpdate;
 972         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 973
 974         o = self;
 975         self = e;
 976         ClientInit_CheckUpdate();
 977         self = o;
 978 }
 979
 980 /*
 981 =============
 982 SetNewParms
 983 =============
 984 */
 985 void SetNewParms (void)
 986 {
 987         // initialize parms for a new player
 988         parm1 = -(86400 * 366);
 989 }
 990
 991 /*
 992 =============
 993 SetChangeParms
 994 =============
 995 */
 996 void SetChangeParms (void)
 997 {
 998         // save parms for level change
 999         parm1 = self.parm_idlesince - time;
1000 }
1001
1002 /*
1003 =============
1004 DecodeLevelParms
1005 =============
1006 */
1007 void DecodeLevelParms (void)
1008 {
1009         // load parms
1010         self.parm_idlesince = parm1;
1011         if(self.parm_idlesince == -(86400 * 366))
1012                 self.parm_idlesince = time;
1013
1014         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1015         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1016 }
1017
1018 /*
1019 =============
1020 ClientKill
1021
1022 Called when a client types 'kill' in the console
1023 =============
1024 */
1025
1026 .float clientkill_nexttime;
1027 void ClientKill_Now_TeamChange()
1028 {
1029         if(self.killindicator_teamchange == -1)
1030         {
1031                 JoinBestTeam( self, FALSE, TRUE );
1032         }
1033         else if(self.killindicator_teamchange == -2)
1034         {
1035                 if(blockSpectators)
1036                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1037                 PutObserverInServer();
1038         }
1039         else
1040                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1041         self.killindicator_teamchange = 0;
1042 }
1043
1044 void ClientKill_Now()
1045 {
1046         if(self.vehicle)
1047         {
1048             vehicles_exit(VHEF_RELESE);
1049             if(!self.killindicator_teamchange)
1050             {
1051             self.vehicle_health = -1;
1052             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1053             }
1054         }
1055
1056         if(self.killindicator && !wasfreed(self.killindicator))
1057                 remove(self.killindicator);
1058
1059         self.killindicator = world;
1060
1061         if(self.killindicator_teamchange)
1062                 ClientKill_Now_TeamChange();
1063
1064         // in any case:
1065         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1066
1067         // now I am sure the player IS dead
1068 }
1069 void KillIndicator_Think()
1070 {
1071         if (gameover)
1072         {
1073                 self.owner.killindicator = world;
1074                 remove(self);
1075                 return;
1076         }
1077
1078         if (self.owner.alpha < 0 && !self.owner.vehicle)
1079         {
1080                 self.owner.killindicator = world;
1081                 remove(self);
1082                 return;
1083         }
1084
1085         if(self.cnt <= 0)
1086         {
1087                 self = self.owner;
1088                 ClientKill_Now(); // no oldself needed
1089                 return;
1090         }
1091     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1092     {
1093         self.nextthink = time + 1;
1094         self.cnt -= 1;
1095     }
1096         else
1097         {
1098                 if(self.cnt <= 10)
1099                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1100                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1101                 {
1102                         if(self.cnt <= 10)
1103                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1104                 }
1105                 self.nextthink = time + 1;
1106                 self.cnt -= 1;
1107         }
1108 }
1109
1110 float clientkilltime;
1111 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1112 {
1113         float killtime;
1114         float starttime;
1115         entity e;
1116
1117         if (gameover)
1118                 return;
1119
1120         killtime = autocvar_g_balance_kill_delay;
1121
1122         if(g_race_qualifying || g_cts)
1123                 killtime = 0;
1124
1125     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1126     {
1127                 remove(self.killindicator);
1128                 self.killindicator = world;
1129
1130         ClientKill_Now(); // allow instant kill in this case
1131         return;
1132     }
1133
1134         self.killindicator_teamchange = targetteam;
1135
1136     if(!self.killindicator)
1137         {
1138                 if(self.deadflag == DEAD_NO)
1139                 {
1140                         killtime = max(killtime, self.clientkill_nexttime - time);
1141                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1142                 }
1143
1144                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1145                 {
1146                         ClientKill_Now();
1147                 }
1148                 else
1149                 {
1150                         starttime = max(time, clientkilltime);
1151
1152                         self.killindicator = spawn();
1153                         self.killindicator.owner = self;
1154                         self.killindicator.scale = 0.5;
1155                         setattachment(self.killindicator, self, "");
1156                         setorigin(self.killindicator, '0 0 52');
1157                         self.killindicator.think = KillIndicator_Think;
1158                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1159                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1160                         self.killindicator.cnt = ceil(killtime);
1161                         self.killindicator.count = bound(0, ceil(killtime), 10);
1162                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1163
1164                         for(e = world; (e = find(e, classname, "body")) != world; )
1165                         {
1166                                 if(e.enemy != self)
1167                                         continue;
1168                                 e.killindicator = spawn();
1169                                 e.killindicator.owner = e;
1170                                 e.killindicator.scale = 0.5;
1171                                 setattachment(e.killindicator, e, "");
1172                                 setorigin(e.killindicator, '0 0 52');
1173                                 e.killindicator.think = KillIndicator_Think;
1174                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1175                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1176                                 e.killindicator.cnt = ceil(killtime);
1177                         }
1178                         self.lip = 0;
1179                 }
1180         }
1181         if(self.killindicator)
1182         {
1183                 if(targetteam == 0) // just die
1184                 {
1185                         self.killindicator.colormod = '0 0 0';
1186                         if(clienttype(self) == CLIENTTYPE_REAL)
1187                         if(self.killindicator.cnt > 0)
1188                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1189                 }
1190                 else if(targetteam == -1) // auto
1191                 {
1192                         self.killindicator.colormod = '0 1 0';
1193                         if(clienttype(self) == CLIENTTYPE_REAL)
1194                         if(self.killindicator.cnt > 0)
1195                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1196                 }
1197                 else if(targetteam == -2) // spectate
1198                 {
1199                         self.killindicator.colormod = '0.5 0.5 0.5';
1200                         if(clienttype(self) == CLIENTTYPE_REAL)
1201                         if(self.killindicator.cnt > 0)
1202                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1203                 }
1204                 else
1205                 {
1206                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1207                         if(clienttype(self) == CLIENTTYPE_REAL)
1208                         if(self.killindicator.cnt > 0)
1209                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1210                 }
1211         }
1212
1213 }
1214
1215 void ClientKill (void)
1216 {
1217         if(gameover) return;
1218         if(self.player_blocked) return;
1219         if(self.freezetag_frozen) return;
1220
1221         ClientKill_TeamChange(0);
1222 }
1223
1224 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1225 {
1226     e.killindicator = spawn();
1227     e.killindicator.owner = e;
1228     e.killindicator.think = KillIndicator_Think;
1229     e.killindicator.nextthink = time + (e.lip) * 0.05;
1230     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1231     e.killindicator.health = 1; // this is used to indicate that it should be silent
1232     e.lip = 0;
1233 }
1234
1235 void FixClientCvars(entity e)
1236 {
1237         // send prediction settings to the client
1238         stuffcmd(e, "\nin_bindmap 0 0\n");
1239         if(g_race || g_cts)
1240                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1241         if(autocvar_g_antilag == 3) // client side hitscan
1242                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1243         if(autocvar_sv_gentle)
1244                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1245         /*
1246          * we no longer need to stuff this. Remove this comment block if you feel
1247          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1248         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1249         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1250         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1251         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1252         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1253         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1254         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1255         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1256         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1257         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1258         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1259         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1260         stuffcmd(e, "cl_movement_edgefriction 1\n");
1261          */
1262 }
1263
1264 float PlayerInIDList(entity p, string idlist)
1265 {
1266         float n, i;
1267         string s;
1268
1269         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1270         if not(p.crypto_idfp)
1271                 return 0;
1272
1273         // this function allows abbreviated player IDs too!
1274         n = tokenize_console(idlist);
1275         for(i = 0; i < n; ++i)
1276         {
1277                 s = argv(i);
1278                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1279                         return 1;
1280         }
1281
1282         return 0;
1283 }
1284
1285 /*
1286 =============
1287 ClientConnect
1288
1289 Called when a client connects to the server
1290 =============
1291 */
1292 void DecodeLevelParms (void);
1293 //void dom_player_join_team(entity pl);
1294 void set_dom_state(entity e);
1295 void ClientConnect (void)
1296 {
1297         float t;
1298
1299         if(self.flags & FL_CLIENT)
1300         {
1301                 print("Warning: ClientConnect, but already connected!\n");
1302                 return;
1303         }
1304
1305         if(Ban_MaybeEnforceBanOnce(self))
1306                 return;
1307
1308         DecodeLevelParms();
1309
1310 #ifdef WATERMARK
1311         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1312 #endif
1313
1314         self.classname = "player_joining";
1315
1316         self.flags = FL_CLIENT;
1317         self.version_nagtime = time + 10 + random() * 10;
1318
1319         if(player_count<0)
1320         {
1321                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1322                 player_count = 0;
1323         }
1324
1325         PlayerScore_Attach(self);
1326         ClientData_Attach();
1327         accuracy_init(self);
1328
1329         bot_clientconnect();
1330
1331         playerdemo_init();
1332
1333         anticheat_init();
1334
1335         race_PreSpawnObserver();
1336
1337         // identify the right forced team
1338         if(autocvar_g_campaign)
1339         {
1340                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1341                 {
1342                         switch(autocvar_g_campaign_forceteam)
1343                         {
1344                                 case 1: self.team_forced = NUM_TEAM_1; break;
1345                                 case 2: self.team_forced = NUM_TEAM_2; break;
1346                                 case 3: self.team_forced = NUM_TEAM_3; break;
1347                                 case 4: self.team_forced = NUM_TEAM_4; break;
1348                                 default: self.team_forced = 0;
1349                         }
1350                 }
1351         }
1352         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1353                 self.team_forced = NUM_TEAM_1;
1354         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1355                 self.team_forced = NUM_TEAM_2;
1356         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1357                 self.team_forced = NUM_TEAM_3;
1358         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1359                 self.team_forced = NUM_TEAM_4;
1360         else if(autocvar_g_forced_team_otherwise == "red")
1361                 self.team_forced = NUM_TEAM_1;
1362         else if(autocvar_g_forced_team_otherwise == "blue")
1363                 self.team_forced = NUM_TEAM_2;
1364         else if(autocvar_g_forced_team_otherwise == "yellow")
1365                 self.team_forced = NUM_TEAM_3;
1366         else if(autocvar_g_forced_team_otherwise == "pink")
1367                 self.team_forced = NUM_TEAM_4;
1368         else if(autocvar_g_forced_team_otherwise == "spectate")
1369                 self.team_forced = -1;
1370         else if(autocvar_g_forced_team_otherwise == "spectator")
1371                 self.team_forced = -1;
1372         else
1373                 self.team_forced = 0;
1374
1375         if(!teamplay)
1376                 if(self.team_forced > 0)
1377                         self.team_forced = 0;
1378
1379         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1380
1381         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1382                 self.classname = "observer";
1383         } else {
1384                 if(teamplay)
1385                 {
1386                         if(autocvar_g_balance_teams)
1387                         {
1388                                 self.classname = "player";
1389                                 campaign_bots_may_start = 1;
1390                         }
1391                         else
1392                         {
1393                                 self.classname = "observer"; // do it anyway
1394                         }
1395                 }
1396                 else
1397                 {
1398                         self.classname = "player";
1399                         campaign_bots_may_start = 1;
1400                 }
1401         }
1402
1403         self.playerid = (playerid_last = playerid_last + 1);
1404
1405         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1406
1407     if(clienttype(self) == CLIENTTYPE_BOT)
1408         PlayerStats_AddPlayer(self);
1409
1410         if(autocvar_sv_eventlog)
1411                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1412
1413         LogTeamchange(self.playerid, self.team, 1);
1414
1415         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1416
1417         self.netname_previous = strzone(self.netname);
1418
1419         if((self.classname == STR_PLAYER && teamplay))
1420                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1421         else
1422                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1423
1424         stuffcmd(self, strcat(clientstuff, "\n"));
1425         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1426
1427         FixClientCvars(self);
1428
1429         // spawnfunc_waypoint sprites
1430         WaypointSprite_InitClient(self);
1431
1432         // Wazat's grappling hook
1433         SetGrappleHookBindings();
1434
1435         // get version info from player
1436         stuffcmd(self, "cmd clientversion $gameversion\n");
1437
1438         // get other cvars from player
1439         GetCvars(0);
1440
1441         // notify about available teams
1442         if(teamplay)
1443         {
1444                 CheckAllowedTeams(self);
1445                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1446                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1447         }
1448         else
1449                 stuffcmd(self, "set _teams_available 0\n");
1450
1451         attach_entcs();
1452
1453         bot_relinkplayerlist();
1454
1455         self.spectatortime = time;
1456         if(blockSpectators)
1457         {
1458                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1459         }
1460
1461         self.jointime = time;
1462         self.allowed_timeouts = autocvar_sv_timeout_number;
1463
1464         if(clienttype(self) == CLIENTTYPE_REAL)
1465         {
1466                 if(!autocvar_g_campaign)
1467                 {
1468                         self.motd_actived_time = -1;
1469                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1470                 }
1471
1472                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1473                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1474         }
1475
1476         if(g_lms)
1477         {
1478                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1479                 {
1480                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1481                         self.frags = FRAGS_SPECTATOR;
1482                 }
1483         }
1484
1485         if(!sv_foginterval && world.fog != "")
1486                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1487
1488         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1489         {
1490                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1491                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1492         }
1493         else
1494                 self.hitplotfh = -1;
1495
1496         if(g_race || g_cts) {
1497                 string rr;
1498                 if(g_cts)
1499                         rr = CTS_RECORD;
1500                 else
1501                         rr = RACE_RECORD;
1502
1503                 msg_entity = self;
1504                 race_send_recordtime(MSG_ONE);
1505                 race_send_speedaward(MSG_ONE);
1506
1507                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1508                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1509                 race_send_speedaward_alltimebest(MSG_ONE);
1510
1511                 float i;
1512                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1513                         race_SendRankings(i, 0, 0, MSG_ONE);
1514                 }
1515         }
1516         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1517                 send_CSQC_teamnagger();
1518
1519         CheatInitClient();
1520
1521         CSQCMODEL_AUTOINIT();
1522
1523         self.model_randomizer = random();
1524
1525         if(clienttype(self) == CLIENTTYPE_REAL)
1526                 sv_notice_join();
1527
1528         MUTATOR_CALLHOOK(ClientConnect);
1529 }
1530 /*
1531 =============
1532 ClientDisconnect
1533
1534 Called when a client disconnects from the server
1535 =============
1536 */
1537 .entity chatbubbleentity;
1538 void ReadyCount();
1539 void ClientDisconnect (void)
1540 {
1541         if(self.vehicle)
1542             vehicles_exit(VHEF_RELESE);
1543
1544         if not(self.flags & FL_CLIENT)
1545         {
1546                 print("Warning: ClientDisconnect without ClientConnect\n");
1547                 return;
1548         }
1549
1550         PlayerStats_AddGlobalInfo(self);
1551
1552         CheatShutdownClient();
1553
1554         if(self.hitplotfh >= 0)
1555         {
1556                 fclose(self.hitplotfh);
1557                 self.hitplotfh = -1;
1558         }
1559
1560         anticheat_report();
1561         anticheat_shutdown();
1562
1563         playerdemo_shutdown();
1564
1565         bot_clientdisconnect();
1566
1567         if(self.entcs)
1568                 detach_entcs();
1569
1570         if(autocvar_sv_eventlog)
1571                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1572
1573         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1574
1575         MUTATOR_CALLHOOK(ClientDisconnect);
1576
1577         Portal_ClearAll(self);
1578
1579         RemoveGrapplingHook(self);
1580
1581         // Here, everything has been done that requires this player to be a client.
1582
1583         self.flags &~= FL_CLIENT;
1584
1585         if (self.chatbubbleentity)
1586                 remove (self.chatbubbleentity);
1587
1588         if (self.killindicator)
1589                 remove (self.killindicator);
1590
1591         WaypointSprite_PlayerGone();
1592
1593         bot_relinkplayerlist();
1594
1595         accuracy_free(self);
1596         ClientData_Detach();
1597         PlayerScore_Detach(self);
1598
1599         if(self.netname_previous)
1600                 strunzone(self.netname_previous);
1601         if(self.clientstatus)
1602                 strunzone(self.clientstatus);
1603         if(self.weaponorder_byimpulse)
1604                 strunzone(self.weaponorder_byimpulse);
1605
1606         ClearPlayerSounds();
1607
1608         if(self.personal)
1609                 remove(self.personal);
1610
1611         self.playerid = 0;
1612         ReadyCount();
1613
1614         // free cvars
1615         GetCvars(-1);
1616 }
1617
1618 .float BUTTON_CHAT;
1619 void ChatBubbleThink()
1620 {
1621         self.nextthink = time;
1622         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1623         {
1624                 if(self.owner) // but why can that ever be world?
1625                         self.owner.chatbubbleentity = world;
1626                 remove(self);
1627                 return;
1628         }
1629         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1630 #ifdef TETRIS
1631                 || self.owner.tetris_on
1632 #endif
1633         )
1634                 self.model = self.mdl;
1635         else
1636                 self.model = "";
1637 }
1638
1639 void UpdateChatBubble()
1640 {
1641         if (self.alpha < 0)
1642                 return;
1643         // spawn a chatbubble entity if needed
1644         if (!self.chatbubbleentity)
1645         {
1646                 self.chatbubbleentity = spawn();
1647                 self.chatbubbleentity.owner = self;
1648                 self.chatbubbleentity.exteriormodeltoclient = self;
1649                 self.chatbubbleentity.think = ChatBubbleThink;
1650                 self.chatbubbleentity.nextthink = time;
1651                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1652                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1653                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1654                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1655                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1656                 self.chatbubbleentity.model = "";
1657                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1658         }
1659 }
1660
1661
1662 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1663 // added to the model skins
1664 /*void UpdateColorModHack()
1665 {
1666         float c;
1667         c = self.clientcolors & 15;
1668         // LordHavoc: only bothering to support white, green, red, yellow, blue
1669              if (!teamplay) self.colormod = '0 0 0';
1670         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1671         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1672         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1673         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1674         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1675         else self.colormod = '1 1 1';
1676 }*/
1677
1678 void respawn(void)
1679 {
1680         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1681         {
1682                 self.solid = SOLID_NOT;
1683                 self.takedamage = DAMAGE_NO;
1684                 self.movetype = MOVETYPE_FLY;
1685                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1686                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1687                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1688                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1689                 if(autocvar_g_respawn_ghosts_maxtime)
1690                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1691         }
1692
1693         CopyBody(1);
1694
1695         self.effects |= EF_NODRAW; // prevent another CopyBody
1696         PutClientInServer();
1697 }
1698
1699 void play_countdown(float finished, string samp)
1700 {
1701         if(clienttype(self) == CLIENTTYPE_REAL)
1702                 if(floor(finished - time - frametime) != floor(finished - time))
1703                         if(finished - time < 6)
1704                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1705 }
1706
1707 void player_powerups (void)
1708 {
1709         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1710         olditems = self.items;
1711
1712         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1713                 self.modelflags |= MF_ROCKET;
1714         else
1715                 self.modelflags &~= MF_ROCKET;
1716
1717         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1718
1719         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1720                 return;
1721
1722         Fire_ApplyDamage(self);
1723         Fire_ApplyEffect(self);
1724
1725         if (g_minstagib)
1726         {
1727                 self.effects |= EF_FULLBRIGHT;
1728
1729                 if (self.items & IT_STRENGTH)
1730                 {
1731                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1732                         if (time > self.strength_finished)
1733                         {
1734                                 self.alpha = default_player_alpha;
1735                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1736                                 self.items &~= IT_STRENGTH;
1737                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1738                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1739                         }
1740                 }
1741                 else
1742                 {
1743                         if (time < self.strength_finished)
1744                         {
1745                                 self.alpha = g_minstagib_invis_alpha;
1746                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1747                                 self.items |= IT_STRENGTH;
1748                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1749                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1750                         }
1751                 }
1752
1753                 if (self.items & IT_INVINCIBLE)
1754                 {
1755                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1756                         if (time > self.invincible_finished)
1757                         {
1758                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1759                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1760                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1761                         }
1762                 }
1763                 else
1764                 {
1765                         if (time < self.invincible_finished)
1766                         {
1767                                 self.items = self.items | IT_INVINCIBLE;
1768                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1769                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1770                         }
1771                 }
1772         }
1773         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1774         {
1775                 if (self.items & IT_STRENGTH)
1776                 {
1777                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1778                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1779                         if (time > self.strength_finished)
1780                         {
1781                                 self.items = self.items - (self.items & IT_STRENGTH);
1782                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1783                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1784                         }
1785                 }
1786                 else
1787                 {
1788                         if (time < self.strength_finished)
1789                         {
1790                                 self.items = self.items | IT_STRENGTH;
1791                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1792                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1793                         }
1794                 }
1795                 if (self.items & IT_INVINCIBLE)
1796                 {
1797                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1798                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1799                         if (time > self.invincible_finished)
1800                         {
1801                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1802                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1803                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1804                         }
1805                 }
1806                 else
1807                 {
1808                         if (time < self.invincible_finished)
1809                         {
1810                                 self.items = self.items | IT_INVINCIBLE;
1811                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1812                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1813                         }
1814                 }
1815                 if (self.items & IT_SUPERWEAPON)
1816                 {
1817                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1818                         {
1819                                 self.superweapons_finished = 0;
1820                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1821                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1822                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1823                         }
1824                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1825                         {
1826                                 // don't let them run out
1827                         }
1828                         else
1829                         {
1830                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1831                                 if (time > self.superweapons_finished)
1832                                 {
1833                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1834                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1835                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1836                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1837                                 }
1838                         }
1839                 }
1840                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1841                 {
1842                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1843                         {
1844                                 self.items = self.items | IT_SUPERWEAPON;
1845                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1846                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1847                         }
1848                         else
1849                         {
1850                                 self.superweapons_finished = 0;
1851                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1852                         }
1853                 }
1854                 else
1855                 {
1856                         self.superweapons_finished = 0;
1857                 }
1858         }
1859
1860         if(autocvar_g_nodepthtestplayers)
1861                 self.effects = self.effects | EF_NODEPTHTEST;
1862
1863         if(autocvar_g_fullbrightplayers)
1864                 self.effects = self.effects | EF_FULLBRIGHT;
1865
1866         // midair gamemode: damage only while in the air
1867         // if in midair mode, being on ground grants temporary invulnerability
1868         // (this is so that multishot weapon don't clear the ground flag on the
1869         // first damage in the frame, leaving the player vulnerable to the
1870         // remaining hits in the same frame)
1871         if (self.flags & FL_ONGROUND)
1872         if (g_midair)
1873                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1874
1875         if (time >= game_starttime)
1876         if (time < self.spawnshieldtime)
1877                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1878
1879         MUTATOR_CALLHOOK(PlayerPowerups);
1880 }
1881
1882 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1883 {
1884         if(current > stable)
1885                 return current;
1886         else if(current > stable - 0.25) // when close enough, "snap"
1887                 return stable;
1888         else
1889                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1890 }
1891
1892 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1893 {
1894         if(current < stable)
1895                 return current;
1896         else if(current < stable + 0.25) // when close enough, "snap"
1897                 return stable;
1898         else
1899                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1900 }
1901
1902 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1903 {
1904         if(current > rotstable)
1905         {
1906                 if(rotframetime > 0)
1907                 {
1908                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1909                         current = max(rotstable, current - rotlinear * rotframetime);
1910                 }
1911         }
1912         else if(current < regenstable)
1913         {
1914                 if(regenframetime > 0)
1915                 {
1916                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1917                         current = min(regenstable, current + regenlinear * regenframetime);
1918                 }
1919         }
1920
1921         if(current > limit)
1922                 current = limit;
1923
1924         return current;
1925 }
1926
1927 void player_regen (void)
1928 {
1929         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1930         maxh = autocvar_g_balance_health_rotstable;
1931         maxa = autocvar_g_balance_armor_rotstable;
1932         maxf = autocvar_g_balance_fuel_rotstable;
1933         minh = autocvar_g_balance_health_regenstable;
1934         mina = autocvar_g_balance_armor_regenstable;
1935         minf = autocvar_g_balance_fuel_regenstable;
1936         limith = autocvar_g_balance_health_limit;
1937         limita = autocvar_g_balance_armor_limit;
1938         limitf = autocvar_g_balance_fuel_limit;
1939
1940         max_mod = regen_mod = rot_mod = limit_mod = 1;
1941
1942         maxh = maxh * max_mod;
1943         //maxa = maxa * max_mod;
1944         //maxf = maxf * max_mod;
1945         minh = minh * max_mod;
1946         //mina = mina * max_mod;
1947         //minf = minf * max_mod;
1948         limith = limith * limit_mod;
1949         limita = limita * limit_mod;
1950         //limitf = limitf * limit_mod;
1951
1952         if(g_ca)
1953                 rot_mod = 0;
1954
1955         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1956         {
1957                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1958                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1959
1960                 // if player rotted to death...  die!
1961                 if(self.health < 1)
1962                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1963         }
1964
1965         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1966                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1967 }
1968
1969 float zoomstate_set;
1970 void SetZoomState(float z)
1971 {
1972         if(z != self.zoomstate)
1973         {
1974                 self.zoomstate = z;
1975                 ClientData_Touch(self);
1976         }
1977         zoomstate_set = 1;
1978 }
1979
1980 void GetPressedKeys(void) {
1981         MUTATOR_CALLHOOK(GetPressedKeys);
1982         if (self.movement_x > 0) // get if movement keys are pressed
1983         {       // forward key pressed
1984                 self.pressedkeys |= KEY_FORWARD;
1985                 self.pressedkeys &~= KEY_BACKWARD;
1986         }
1987         else if (self.movement_x < 0)
1988         {       // backward key pressed
1989                 self.pressedkeys |= KEY_BACKWARD;
1990                 self.pressedkeys &~= KEY_FORWARD;
1991         }
1992         else
1993         {       // no x input
1994                 self.pressedkeys &~= KEY_FORWARD;
1995                 self.pressedkeys &~= KEY_BACKWARD;
1996         }
1997
1998         if (self.movement_y > 0)
1999         {       // right key pressed
2000                 self.pressedkeys |= KEY_RIGHT;
2001                 self.pressedkeys &~= KEY_LEFT;
2002         }
2003         else if (self.movement_y < 0)
2004         {       // left key pressed
2005                 self.pressedkeys |= KEY_LEFT;
2006                 self.pressedkeys &~= KEY_RIGHT;
2007         }
2008         else
2009         {       // no y input
2010                 self.pressedkeys &~= KEY_RIGHT;
2011                 self.pressedkeys &~= KEY_LEFT;
2012         }
2013
2014         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2015                 self.pressedkeys |= KEY_JUMP;
2016         else
2017                 self.pressedkeys &~= KEY_JUMP;
2018         if (self.BUTTON_CROUCH)
2019                 self.pressedkeys |= KEY_CROUCH;
2020         else
2021                 self.pressedkeys &~= KEY_CROUCH;
2022
2023         if (self.BUTTON_ATCK)
2024                 self.pressedkeys |= KEY_ATCK;
2025         else
2026                 self.pressedkeys &~= KEY_ATCK;
2027         if (self.BUTTON_ATCK2)
2028                 self.pressedkeys |= KEY_ATCK2;
2029         else
2030                 self.pressedkeys &~= KEY_ATCK2;
2031 }
2032
2033 /*
2034 ======================
2035 spectate mode routines
2036 ======================
2037 */
2038
2039 void SpectateCopy(entity spectatee) {
2040         other = spectatee;
2041         MUTATOR_CALLHOOK(SpectateCopy);
2042         self.armortype = spectatee.armortype;
2043         self.armorvalue = spectatee.armorvalue;
2044         self.ammo_cells = spectatee.ammo_cells;
2045         self.ammo_shells = spectatee.ammo_shells;
2046         self.ammo_nails = spectatee.ammo_nails;
2047         self.ammo_rockets = spectatee.ammo_rockets;
2048         self.ammo_fuel = spectatee.ammo_fuel;
2049         self.clip_load = spectatee.clip_load;
2050         self.clip_size = spectatee.clip_size;
2051         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2052         self.health = spectatee.health;
2053         self.impulse = 0;
2054         self.items = spectatee.items;
2055         self.last_pickup = spectatee.last_pickup;
2056         self.hit_time = spectatee.hit_time;
2057         self.metertime = spectatee.metertime;
2058         self.strength_finished = spectatee.strength_finished;
2059         self.invincible_finished = spectatee.invincible_finished;
2060         self.pressedkeys = spectatee.pressedkeys;
2061         WEPSET_COPY_EE(self, spectatee);
2062         self.switchweapon = spectatee.switchweapon;
2063         self.switchingweapon = spectatee.switchingweapon;
2064         self.weapon = spectatee.weapon;
2065         self.nex_charge = spectatee.nex_charge;
2066         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2067         self.hagar_load = spectatee.hagar_load;
2068         self.minelayer_mines = spectatee.minelayer_mines;
2069         self.punchangle = spectatee.punchangle;
2070         self.view_ofs = spectatee.view_ofs;
2071         self.velocity = spectatee.velocity;
2072         self.dmg_take = spectatee.dmg_take;
2073         self.dmg_save = spectatee.dmg_save;
2074         self.dmg_inflictor = spectatee.dmg_inflictor;
2075         self.v_angle = spectatee.v_angle;
2076         self.angles = spectatee.v_angle;
2077         if(!self.BUTTON_USE)
2078                 self.fixangle = TRUE;
2079         setorigin(self, spectatee.origin);
2080         setsize(self, spectatee.mins, spectatee.maxs);
2081         SetZoomState(spectatee.zoomstate);
2082
2083     anticheat_spectatecopy(spectatee);
2084         self.hud = spectatee.hud;
2085         if(spectatee.vehicle)
2086     {
2087         self.fixangle = FALSE;
2088         //self.velocity = spectatee.vehicle.velocity;
2089         self.vehicle_health = spectatee.vehicle_health;
2090         self.vehicle_shield = spectatee.vehicle_shield;
2091         self.vehicle_energy = spectatee.vehicle_energy;
2092         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2093         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2094         self.vehicle_reload1 = spectatee.vehicle_reload1;
2095         self.vehicle_reload2 = spectatee.vehicle_reload2;
2096
2097         msg_entity = self;
2098
2099         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2100             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2101             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2102             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2103
2104         //WriteByte (MSG_ONE, SVC_SETVIEW);
2105         //    WriteEntity(MSG_ONE, self);
2106         //makevectors(spectatee.v_angle);
2107         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2108     }
2109 }
2110
2111 float SpectateUpdate() {
2112         if(!self.enemy)
2113             return 0;
2114
2115         if (self == self.enemy)
2116                 return 0;
2117
2118         if(self.enemy.classname != "player")
2119                 return 0;
2120
2121         SpectateCopy(self.enemy);
2122
2123         return 1;
2124 }
2125
2126
2127 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2128 entity CA_SpectateNext(entity start) {
2129         if (start.team == self.team) {
2130                 return start;
2131         }
2132
2133         other = start;
2134         // continue from current player
2135         while(other && other.team != self.team) {
2136                 other = find(other, classname, "player");
2137         }
2138
2139         if (!other) {
2140                 // restart from begining
2141                 other = find(other, classname, "player");
2142                 while(other && other.team != self.team) {
2143                         other = find(other, classname, "player");
2144                 }
2145         }
2146
2147         return other;
2148 }
2149
2150 float SpectateNext(entity _prefer) {
2151
2152         if(_prefer)
2153                 other = _prefer;
2154         else
2155                 other = find(self.enemy, classname, "player");
2156
2157         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2158                 // CA and ca players when spectating enemies is forbidden
2159                 other = CA_SpectateNext(other);
2160         } else {
2161                 // other modes and ca spectators or spectating enemies is allowed
2162                 if (!other)
2163                         other = find(other, classname, "player");
2164         }
2165
2166         if (other)
2167                 self.enemy = other;
2168
2169         if(self.enemy.classname == "player") {
2170             /*if(self.enemy.vehicle)
2171             {
2172
2173             msg_entity = self;
2174             WriteByte(MSG_ONE, SVC_SETVIEW);
2175             WriteEntity(MSG_ONE, self.enemy);
2176             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2177
2178             self.movetype = MOVETYPE_NONE;
2179             accuracy_resend(self);
2180             }
2181             else
2182             {*/
2183             msg_entity = self;
2184             WriteByte(MSG_ONE, SVC_SETVIEW);
2185             WriteEntity(MSG_ONE, self.enemy);
2186             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2187             self.movetype = MOVETYPE_NONE;
2188             accuracy_resend(self);
2189
2190             if(!SpectateUpdate())
2191                 PutObserverInServer();
2192         //}
2193         return 1;
2194         } else {
2195                 return 0;
2196         }
2197 }
2198
2199 /*
2200 =============
2201 ShowRespawnCountdown()
2202
2203 Update a respawn countdown display.
2204 =============
2205 */
2206 void ShowRespawnCountdown()
2207 {
2208         float number;
2209         if(self.deadflag == DEAD_NO) // just respawned?
2210                 return;
2211         else
2212         {
2213                 number = ceil(self.respawn_time - time);
2214                 if(number <= 0)
2215                         return;
2216                 if(number <= self.respawn_countdown)
2217                 {
2218                         self.respawn_countdown = number - 1;
2219                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2220                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
2221                 }
2222         }
2223 }
2224
2225 void LeaveSpectatorMode()
2226 {
2227         if(self.caplayer)
2228                 return;
2229         if(nJoinAllowed(self))
2230         {
2231                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2232                 {
2233                         self.classname = "player";
2234
2235                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2236                                 { JoinBestTeam(self, FALSE, TRUE); }
2237
2238                         if(autocvar_g_campaign)
2239                                 { campaign_bots_may_start = 1; }
2240
2241                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2242
2243                         PutClientInServer();
2244
2245                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2246                 }
2247                 else
2248                         stuffcmd(self, "menu_showteamselect\n");
2249         }
2250         else
2251         {
2252                 // Player may not join because g_maxplayers is set
2253                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2254         }
2255 }
2256
2257 /**
2258  * Determines whether the player is allowed to join. This depends on cvar
2259  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2260  * it checks whether the number of currently playing players exceeds g_maxplayers.
2261  * @return int number of free slots for players, 0 if none
2262  */
2263 float nJoinAllowed(entity ignore) {
2264         if(!ignore)
2265         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2266         // so report 0 free slots if restricted
2267         {
2268                 if(autocvar_g_forced_team_otherwise == "spectate")
2269                         return 0;
2270                 if(autocvar_g_forced_team_otherwise == "spectator")
2271                         return 0;
2272         }
2273
2274         if(self.team_forced < 0)
2275                 return 0; // forced spectators can never join
2276
2277         // TODO simplify this
2278         entity e;
2279         float totalClients = 0;
2280         FOR_EACH_CLIENT(e)
2281                 if(e != ignore)
2282                         totalClients += 1;
2283
2284         if (!autocvar_g_maxplayers)
2285                 return maxclients - totalClients;
2286
2287         float currentlyPlaying = 0;
2288         FOR_EACH_REALCLIENT(e)
2289                 if(e.classname == "player" || e.caplayer == 1)
2290                         currentlyPlaying += 1;
2291
2292         if(currentlyPlaying < autocvar_g_maxplayers)
2293                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2294
2295         return 0;
2296 }
2297
2298 /**
2299  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2300  * g_maxplayers_spectator_blocktime seconds
2301  */
2302 void checkSpectatorBlock() {
2303         if(self.classname == "spectator" || self.classname == "observer") {
2304                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2305                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2306                         dropclient(self);
2307                 }
2308         }
2309 }
2310
2311 void PrintWelcomeMessage()
2312 {
2313         if(self.motd_actived_time == 0)
2314         {
2315                 if (autocvar_g_campaign) {
2316                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2317                                 self.motd_actived_time = time;
2318                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2319                         }
2320                 } else {
2321                         if (self.BUTTON_INFO) {
2322                                 self.motd_actived_time = time;
2323                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2324                         }
2325                 }
2326         }
2327         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2328         {
2329                 if (autocvar_g_campaign) {
2330                         if (self.BUTTON_INFO)
2331                                 self.motd_actived_time = time;
2332                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2333                                 self.motd_actived_time = 0;
2334                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2335                         }
2336                 } else {
2337                         if (self.BUTTON_INFO)
2338                                 self.motd_actived_time = time;
2339                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2340                                 self.motd_actived_time = 0;
2341                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2342                         }
2343                 }
2344         }
2345         else //if(self.motd_actived_time < 0) // just connected, motd is active
2346         {
2347                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2348                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2349                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2350                 {
2351                         // instanctly hide MOTD
2352                         self.motd_actived_time = 0;
2353                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2354                 }
2355         }
2356 }
2357
2358 void ObserverThink()
2359 {
2360         float prefered_movetype;
2361         if (self.flags & FL_JUMPRELEASED) {
2362                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2363                         self.flags &~= FL_JUMPRELEASED;
2364                         self.flags |= FL_SPAWNING;
2365                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2366                         self.flags &~= FL_JUMPRELEASED;
2367                         if(SpectateNext(world) == 1) {
2368                                 self.classname = "spectator";
2369                         }
2370                 } else {
2371                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2372                         if (self.movetype != prefered_movetype)
2373                                 self.movetype = prefered_movetype;
2374                 }
2375         } else {
2376                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2377                         self.flags |= FL_JUMPRELEASED;
2378                         if(self.flags & FL_SPAWNING)
2379                         {
2380                                 self.flags &~= FL_SPAWNING;
2381                                 LeaveSpectatorMode();
2382                                 return;
2383                         }
2384                 }
2385         }
2386 }
2387
2388 void SpectatorThink()
2389 {
2390         if (self.flags & FL_JUMPRELEASED) {
2391                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2392                         self.flags &~= FL_JUMPRELEASED;
2393                         self.flags |= FL_SPAWNING;
2394                 } else if(self.BUTTON_ATCK) {
2395                         self.flags &~= FL_JUMPRELEASED;
2396                         if(SpectateNext(world) == 1) {
2397                                 self.classname = "spectator";
2398                         } else {
2399                                 self.classname = "observer";
2400                                 PutClientInServer();
2401                         }
2402                 } else if (self.BUTTON_ATCK2) {
2403                         self.flags &~= FL_JUMPRELEASED;
2404                         self.classname = "observer";
2405                         PutClientInServer();
2406                 } else {
2407                         if(!SpectateUpdate())
2408                                 PutObserverInServer();
2409                 }
2410         } else {
2411                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2412                         self.flags |= FL_JUMPRELEASED;
2413                         if(self.flags & FL_SPAWNING)
2414                         {
2415                                 self.flags &~= FL_SPAWNING;
2416                                 LeaveSpectatorMode();
2417                                 return;
2418                         }
2419                 }
2420                 if(!SpectateUpdate())
2421                         PutObserverInServer();
2422         }
2423
2424         self.flags |= FL_CLIENT | FL_NOTARGET;
2425 }
2426
2427 void PlayerUseKey()
2428 {
2429         if(self.classname != "player")
2430                 return;
2431
2432         if(self.vehicle)
2433         {
2434         vehicles_exit(VHEF_NORMAL);
2435         return;
2436         }
2437
2438         // a use key was pressed; call handlers
2439         MUTATOR_CALLHOOK(PlayerUseKey);
2440 }
2441
2442 .float touchexplode_time;
2443
2444 /*
2445 =============
2446 PlayerPreThink
2447
2448 Called every frame for each client before the physics are run
2449 =============
2450 */
2451 .float usekeypressed;
2452 void() nexball_setstatus;
2453 .float items_added;
2454 void PlayerPreThink (void)
2455 {
2456         WarpZone_PlayerPhysics_FixVAngle();
2457
2458         self.stat_game_starttime = game_starttime;
2459         self.stat_round_starttime = round_starttime;
2460         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2461         self.stat_leadlimit = autocvar_leadlimit;
2462
2463         if(frametime)
2464         {
2465                 // physics frames: update anticheat stuff
2466                 anticheat_prethink();
2467         }
2468
2469         if(blockSpectators && frametime)
2470                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2471                 checkSpectatorBlock();
2472
2473         zoomstate_set = 0;
2474
2475         if(self.netname_previous != self.netname)
2476         {
2477                 if(autocvar_sv_eventlog)
2478                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2479                 if(self.netname_previous)
2480                         strunzone(self.netname_previous);
2481                 self.netname_previous = strzone(self.netname);
2482         }
2483
2484         // version nagging
2485         if(self.version_nagtime)
2486                 if(self.cvar_g_xonoticversion)
2487                         if(time > self.version_nagtime)
2488                         {
2489                                 // don't notify git users
2490                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2491                                 {
2492                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2493                                         {
2494                                                 // notify release users if connecting to git
2495                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2496                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2497                                         }
2498                                         else
2499                                         {
2500                                                 float r;
2501                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2502                                                 if(r < 0)
2503                                                 {
2504                                                         // give users new version
2505                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2506                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2507                                                 }
2508                                                 else if(r > 0)
2509                                                 {
2510                                                         // notify users about old server version
2511                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2512                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2513                                                 }
2514                                         }
2515                                 }
2516                                 self.version_nagtime = 0;
2517                         }
2518
2519         // GOD MODE info
2520         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2521         {
2522                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2523                 self.max_armorvalue = 0;
2524         }
2525
2526 #ifdef TETRIS
2527         if (TetrisPreFrame())
2528                 return;
2529 #endif
2530
2531         MUTATOR_CALLHOOK(PlayerPreThink);
2532
2533         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2534         {
2535                 if(self.BUTTON_USE && !self.usekeypressed)
2536                         PlayerUseKey();
2537                 self.usekeypressed = self.BUTTON_USE;
2538         }
2539
2540         if(clienttype(self) == CLIENTTYPE_REAL)
2541                 PrintWelcomeMessage();
2542
2543         if(self.classname == "player") {
2544
2545                 CheckRules_Player();
2546
2547                 if (intermission_running)
2548                 {
2549                         IntermissionThink ();   // otherwise a button could be missed between
2550                         return;                                 // the think tics
2551                 }
2552
2553                 //don't allow the player to turn around while game is paused!
2554                 if(timeout_status == TIMEOUT_ACTIVE) {
2555                         // FIXME turn this into CSQC stuff
2556                         self.v_angle = self.lastV_angle;
2557                         self.angles = self.lastV_angle;
2558                         self.fixangle = TRUE;
2559                 }
2560
2561                 if(frametime)
2562                 {
2563                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2564                         {
2565                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2566                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2567                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2568
2569                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2570                                 {
2571                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2572                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2573                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2574                                 }
2575                         }
2576                         else
2577                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2578
2579                         player_powerups();
2580                 }
2581
2582                 if (g_minstagib)
2583                         minstagib_ammocheck();
2584
2585                 if (self.deadflag != DEAD_NO)
2586                 {
2587                         if(self.personal && g_race_qualifying)
2588                         {
2589                                 if(time > self.respawn_time)
2590                                 {
2591                                         self.respawn_time = time + 1; // only retry once a second
2592                                         self.stat_respawn_time = self.respawn_time;
2593                                         respawn();
2594                                         self.impulse = 141;
2595                                 }
2596                         }
2597                         else
2598                         {
2599                                 float button_pressed;
2600                                 if(frametime)
2601                                         player_anim();
2602                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2603
2604                                 if (self.deadflag == DEAD_DYING)
2605                                 {
2606                                         if(self.respawn_flags & RESPAWN_FORCE)
2607                                                 self.deadflag = DEAD_RESPAWNING;
2608                                         else if(!button_pressed)
2609                                                 self.deadflag = DEAD_DEAD;
2610                                 }
2611                                 else if (self.deadflag == DEAD_DEAD)
2612                                 {
2613                                         if(button_pressed)
2614                                                 self.deadflag = DEAD_RESPAWNABLE;
2615                                 }
2616                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2617                                 {
2618                                         if(!button_pressed)
2619                                                 self.deadflag = DEAD_RESPAWNING;
2620                                 }
2621                                 else if (self.deadflag == DEAD_RESPAWNING)
2622                                 {
2623                                         if(time > self.respawn_time)
2624                                         {
2625                                                 self.respawn_time = time + 1; // only retry once a second
2626                                                 respawn();
2627                                         }
2628                                 }
2629
2630                                 ShowRespawnCountdown();
2631
2632                                 if(self.respawn_flags & RESPAWN_SILENT)
2633                                         self.stat_respawn_time = 0;
2634                                 else
2635                                         self.stat_respawn_time = self.respawn_time;
2636                         }
2637
2638                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2639                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2640                                 self.stat_respawn_time *= -1;
2641
2642                         return;
2643                 }
2644                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2645                 // so (self.deadflag == DEAD_NO) is always true in the code below
2646
2647                 if(g_touchexplode)
2648                 if(time > self.touchexplode_time)
2649                 if(self.classname == "player")
2650                 if(self.deadflag == DEAD_NO)
2651                 if not(IS_INDEPENDENT_PLAYER(self))
2652                 FOR_EACH_PLAYER(other) if(self != other)
2653                 {
2654                         if(time > other.touchexplode_time)
2655                         if(other.deadflag == DEAD_NO)
2656                         if not(IS_INDEPENDENT_PLAYER(other))
2657                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2658                         {
2659                                 PlayerTouchExplode(self, other);
2660                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2661                         }
2662                 }
2663
2664                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2665                 {
2666                         vector dist;
2667
2668                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2669                         dist = self.prevorigin - self.origin;
2670                         dist_z = 0;
2671                         self.lms_traveled_distance += fabs(vlen(dist));
2672
2673                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2674                         {
2675                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2676                                 self.lms_traveled_distance = 0;
2677                         }
2678
2679                         if(time > self.lms_nextcheck)
2680                         {
2681                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2682                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2683                                 {
2684                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
2685                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2686                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2687                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2688                                 }
2689                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2690                                 self.lms_traveled_distance = 0;
2691                         }
2692                 }
2693
2694                 self.prevorigin = self.origin;
2695
2696                 float do_crouch = self.BUTTON_CROUCH;
2697                 if(self.hook.state)
2698                         do_crouch = 0;
2699                 if(self.health <= g_bloodloss)
2700                         do_crouch = 1;
2701                 if(self.vehicle)
2702                         do_crouch = 0;
2703                 if(self.freezetag_frozen)
2704                         do_crouch = 0;
2705                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2706                         do_crouch = 0;
2707
2708                 if (do_crouch)
2709                 {
2710                         if (!self.crouch)
2711                         {
2712                                 self.crouch = TRUE;
2713                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2714                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2715                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2716                         }
2717                 }
2718                 else
2719                 {
2720                         if (self.crouch)
2721                         {
2722                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2723                                 if (!trace_startsolid)
2724                                 {
2725                                         self.crouch = FALSE;
2726                                         self.view_ofs = PL_VIEW_OFS;
2727                                         setsize (self, PL_MIN, PL_MAX);
2728                                 }
2729                         }
2730                 }
2731
2732                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2733                 {
2734                         if(self.bloodloss_timer < time)
2735                         {
2736                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2737                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2738                         }
2739                 }
2740
2741                 FixPlayermodel();
2742
2743                 GrapplingHookFrame();
2744
2745                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2746                 //if(frametime)
2747                 {
2748                         self.items &~= self.items_added;
2749
2750                         W_WeaponFrame();
2751
2752                         self.items_added = 0;
2753                         if(self.items & IT_JETPACK)
2754                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2755                                         self.items_added |= IT_FUEL;
2756
2757                         self.items |= self.items_added;
2758                 }
2759
2760                 player_regen();
2761
2762                 // rot nex charge to the charge limit
2763                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2764                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2765
2766                 if(frametime)
2767                         player_anim();
2768
2769                 if(g_nexball)
2770                         nexball_setstatus();
2771
2772                 // secret status
2773                 secrets_setstatus();
2774
2775                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2776
2777                 //self.angles_y=self.v_angle_y + 90;   // temp
2778         } else if(gameover) {
2779                 if (intermission_running)
2780                         IntermissionThink ();   // otherwise a button could be missed between
2781                 return;
2782         } else if(self.classname == "observer") {
2783                 ObserverThink();
2784         } else if(self.classname == "spectator") {
2785                 SpectatorThink();
2786         }
2787
2788         if(!zoomstate_set)
2789                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2790
2791         float oldspectatee_status;
2792         oldspectatee_status = self.spectatee_status;
2793         if(self.classname == "spectator")
2794                 self.spectatee_status = num_for_edict(self.enemy);
2795         else if(self.classname == "observer")
2796                 self.spectatee_status = num_for_edict(self);
2797         else
2798                 self.spectatee_status = 0;
2799         if(self.spectatee_status != oldspectatee_status)
2800         {
2801                 ClientData_Touch(self);
2802                 if(g_race || g_cts)
2803                         race_InitSpectator();
2804         }
2805
2806         if(self.teamkill_soundtime)
2807         if(time > self.teamkill_soundtime)
2808         {
2809                 self.teamkill_soundtime = 0;
2810
2811                 entity oldpusher, oldself;
2812
2813                 oldself = self; self = self.teamkill_soundsource;
2814                 oldpusher = self.pusher; self.pusher = oldself;
2815
2816                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2817
2818                 self.pusher = oldpusher;
2819                 self = oldself;
2820         }
2821
2822         if(self.taunt_soundtime)
2823         if(time > self.taunt_soundtime)
2824         {
2825                 self.taunt_soundtime = 0;
2826                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2827         }
2828
2829         target_voicescript_next(self);
2830
2831         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2832         if(!self.weapon)
2833                 self.clip_load = self.clip_size = 0;
2834 }
2835
2836 float isInvisibleString(string s)
2837 {
2838         float i, n, c;
2839         s = strdecolorize(s);
2840         for((i = 0), (n = strlen(s)); i < n; ++i)
2841         {
2842                 c = str2chr(s, i);
2843                 switch(c)
2844                 {
2845                         case 0:
2846                         case 32: // space
2847                                 break;
2848                         case 192: // charmap space
2849                                 if (!autocvar_utf8_enable)
2850                                         break;
2851                                 return FALSE;
2852                         case 160: // space in unicode fonts
2853                         case 0xE000 + 192: // utf8 charmap space
2854                                 if (autocvar_utf8_enable)
2855                                         break;
2856                         default:
2857                                 return FALSE;
2858                 }
2859         }
2860         return TRUE;
2861 }
2862
2863 /*
2864 =============
2865 PlayerPostThink
2866
2867 Called every frame for each client after the physics are run
2868 =============
2869 */
2870 .float idlekick_lasttimeleft;
2871 void PlayerPostThink (void)
2872 {
2873         // Savage: Check for nameless players
2874         if (isInvisibleString(self.netname)) {
2875                 self.netname = "Player";
2876                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2877         }
2878
2879         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2880         {
2881                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2882                 {
2883                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2884                 }
2885                 else
2886                 {
2887                         float timeleft;
2888                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2889                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2890                         {
2891                                 if(!self.idlekick_lasttimeleft)
2892                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2893                         }
2894                         if(timeleft <= 0)
2895                         {
2896                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2897                                 dropclient(self);
2898                                 return;
2899                         }
2900                         else if(timeleft <= 10)
2901                         {
2902                                 if(timeleft != self.idlekick_lasttimeleft)
2903                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2904                                 self.idlekick_lasttimeleft = timeleft;
2905                         }
2906                 }
2907         }
2908
2909 #ifdef TETRIS
2910         if(self.impulse == 100)
2911                 ImpulseCommands();
2912         if (!TetrisPostFrame())
2913         {
2914 #endif
2915
2916         CheatFrame();
2917
2918         //CheckPlayerJump();
2919
2920         if(self.classname == "player") {
2921                 CheckRules_Player();
2922                 UpdateChatBubble();
2923                 if (self.impulse)
2924                         ImpulseCommands();
2925                 if (intermission_running)
2926                         return;         // intermission or finale
2927                 GetPressedKeys();
2928         }
2929
2930 #ifdef TETRIS
2931         }
2932 #endif
2933
2934         /*
2935         float i;
2936         for(i = 0; i < 1000; ++i)
2937         {
2938                 vector end;
2939                 end = self.origin + '0 0 1024' + 512 * randomvec();
2940                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2941                 if(trace_fraction < 1)
2942                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2943                 {
2944                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2945                         break;
2946                 }
2947         }
2948         */
2949
2950         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2951
2952         if(self.waypointsprite_attachedforcarrier)
2953                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2954
2955         playerdemo_write();
2956
2957         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2958         {
2959                 if not(self.stored_netname)
2960                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2961                 if(self.stored_netname != self.netname)
2962                 {
2963                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2964                         strunzone(self.stored_netname);
2965                         self.stored_netname = strzone(self.netname);
2966                 }
2967         }
2968
2969         /*
2970         if(g_race)
2971                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2972         */
2973
2974         CSQCMODEL_AUTOUPDATE();
2975 }