qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!inWarmupStage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         WEPSET_CLEAR_E(self);
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                         defaultmodel = argv(floor(n * self.model_randomizer));
 301
 302                 i = strstrofs(defaultmodel, ":", 0);
 303                 if(i >= 0)
 304                 {
 305                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 306                         defaultmodel = substring(defaultmodel, 0, i);
 307                 }
 308         }
 309
 310         if(defaultmodel != "")
 311         {
 312                 if (defaultmodel != self.model)
 313                 {
 314                         m1 = self.mins;
 315                         m2 = self.maxs;
 316                         setplayermodel (self, defaultmodel);
 317                         setsize (self, m1, m2);
 318                         chmdl = TRUE;
 319                 }
 320
 321                 oldskin = self.skin;
 322                 self.skin = defaultskin;
 323         } else {
 324                 if (self.playermodel != self.model || self.playermodel == "")
 325                 {
 326                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 327                         m1 = self.mins;
 328                         m2 = self.maxs;
 329                         setplayermodel (self, self.playermodel);
 330                         setsize (self, m1, m2);
 331                         chmdl = TRUE;
 332                 }
 333
 334                 oldskin = self.skin;
 335                 self.skin = stof(self.playerskin);
 336         }
 337
 338         if(chmdl || oldskin != self.skin) // model or skin has changed
 339         {
 340                 self.species = player_getspecies(); // update species
 341                 UpdatePlayerSounds(); // update skin sounds
 342         }
 343
 344         if(!teamplay)
 345                 if(strlen(autocvar_sv_defaultplayercolors))
 346                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 347                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 348 }
 349
 350 /*
 351 =============
 352 PutClientInServer
 353
 354 Called when a client spawns in the server
 355 =============
 356 */
 357 void PutClientInServer (void)
 358 {
 359         if(IS_BOT_CLIENT(self))
 360                 self.classname = "player";
 361         else if(IS_REAL_CLIENT(self))
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         // reset player keys
 369         self.itemkeys = 0;
 370
 371         MUTATOR_CALLHOOK(PutClientInServer);
 372
 373         if(gameover)
 374                 self.classname = "observer";
 375
 376         if(IS_PLAYER(self))
 377         {
 378                 entity spot, oldself;
 379                 float j;
 380
 381                 accuracy_resend(self);
 382
 383                 if(self.team < 0)
 384                         JoinBestTeam(self, FALSE, TRUE);
 385
 386                 race_PreSpawn();
 387
 388                 spot = SelectSpawnPoint (FALSE);
 389                 if(!spot)
 390                 {
 391                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 392                         return; // spawn failed
 393                 }
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 self.classname = "player";
 398                 self.wasplayer = TRUE;
 399                 self.iscreature = TRUE;
 400                 self.teleportable = TELEPORT_NORMAL;
 401                 self.damagedbycontents = TRUE;
 402                 self.movetype = MOVETYPE_WALK;
 403                 self.solid = SOLID_SLIDEBOX;
 404                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 405                 if(autocvar_g_playerclip_collisions)
 406                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 407                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 409                 self.frags = FRAGS_PLAYER;
 410                 if(INDEPENDENT_PLAYERS)
 411                         MAKE_INDEPENDENT_PLAYER(self);
 412                 self.flags = FL_CLIENT;
 413                 if(autocvar__notarget)
 414                         self.flags |= FL_NOTARGET;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 if(autocvar_g_balance_nex_charge)
 421                 {
 422                         if(autocvar_g_balance_nex_secondary_chargepool)
 423                                 self.nex_chargepool_ammo = 1;
 424                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 425                 }
 426
 427                 if(inWarmupStage)
 428                 {
 429                         self.ammo_shells = warmup_start_ammo_shells;
 430                         self.ammo_nails = warmup_start_ammo_nails;
 431                         self.ammo_rockets = warmup_start_ammo_rockets;
 432                         self.ammo_cells = warmup_start_ammo_cells;
 433                         self.ammo_fuel = warmup_start_ammo_fuel;
 434                         self.health = warmup_start_health;
 435                         self.armorvalue = warmup_start_armorvalue;
 436                         WEPSET_COPY_EA(self, warmup_start_weapons);
 437                 }
 438                 else
 439                 {
 440                         self.ammo_shells = start_ammo_shells;
 441                         self.ammo_nails = start_ammo_nails;
 442                         self.ammo_rockets = start_ammo_rockets;
 443                         self.ammo_cells = start_ammo_cells;
 444                         self.ammo_fuel = start_ammo_fuel;
 445                         self.health = start_health;
 446                         self.armorvalue = start_armorvalue;
 447                         WEPSET_COPY_EA(self, start_weapons);
 448                 }
 449
 450                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 451                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 452                 else
 453                         self.superweapons_finished = 0;
 454
 455                 if(g_weaponarena_random)
 456                 {
 457                         if(g_weaponarena_random_with_laser)
 458                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 459                         W_RandomWeapons(self, g_weaponarena_random);
 460                         if(g_weaponarena_random_with_laser)
 461                                 WEPSET_OR_EW(self, WEP_LASER);
 462                 }
 463
 464                 self.items = start_items;
 465
 466                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 467                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 468                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 469                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 470                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 471                 //extend the pause of rotting if client was reset at the beginning of the countdown
 472                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 473                         self.spawnshieldtime += game_starttime - time;
 474                         self.pauserotarmor_finished += game_starttime - time;
 475                         self.pauserothealth_finished += game_starttime - time;
 476                         self.pauseregen_finished += game_starttime - time;
 477                 }
 478                 self.damageforcescale = 2;
 479                 self.death_time = 0;
 480                 self.respawn_flags = 0;
 481                 self.respawn_time = 0;
 482                 self.stat_respawn_time = 0;
 483                 self.scale = 0;
 484                 self.fade_time = 0;
 485                 self.pain_frame = 0;
 486                 self.pain_finished = 0;
 487                 self.strength_finished = 0;
 488                 self.invincible_finished = 0;
 489                 self.pushltime = 0;
 490                 // players have no think function
 491                 self.think = func_null;
 492                 self.nextthink = 0;
 493                 self.hook_time = 0;
 494                 self.dmg_team = 0;
 495                 self.ballistics_density = autocvar_g_ballistics_density_player;
 496
 497                 self.metertime = 0;
 498
 499                 self.deadflag = DEAD_NO;
 500
 501                 self.angles = spot.angles;
 502
 503                 self.angles_z = 0; // never spawn tilted even if the spot says to
 504                 self.fixangle = TRUE; // turn this way immediately
 505                 self.velocity = '0 0 0';
 506                 self.avelocity = '0 0 0';
 507                 self.punchangle = '0 0 0';
 508                 self.punchvector = '0 0 0';
 509                 self.oldvelocity = self.velocity;
 510                 self.fire_endtime = -1;
 511
 512                 entity spawnevent = spawn();
 513                 spawnevent.owner = self;
 514                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 515
 516                 self.model = "";
 517                 FixPlayermodel();
 518                 self.drawonlytoclient = world;
 519
 520                 self.crouch = FALSE;
 521                 self.view_ofs = PL_VIEW_OFS;
 522                 setsize (self, PL_MIN, PL_MAX);
 523                 self.spawnorigin = spot.origin;
 524                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 525                 // don't reset back to last position, even if new position is stuck in solid
 526                 self.oldorigin = self.origin;
 527                 self.prevorigin = self.origin;
 528                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 529                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 530         self.hud = HUD_NORMAL;
 531
 532                 self.event_damage = PlayerDamage;
 533
 534                 self.bot_attack = TRUE;
 535
 536                 self.statdraintime = time + 5;
 537                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 538
 539                 if(self.killcount == -666) {
 540                         PlayerScore_Clear(self);
 541                         self.killcount = 0;
 542                 }
 543
 544                 CL_SpawnWeaponentity();
 545                 self.alpha = default_player_alpha;
 546                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 547                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 548
 549                 self.speedrunning = FALSE;
 550
 551                 race_PostSpawn(spot);
 552
 553                 //stuffcmd(self, "chase_active 0");
 554                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 555
 556                 target_voicescript_clear(self);
 557
 558                 // reset fields the weapons may use
 559                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 560                 {
 561                         weapon_action(j, WR_RESETPLAYER);
 562
 563                         // all weapons must be fully loaded when we spawn
 564                         entity e;
 565                         e = get_weaponinfo(j);
 566                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 567                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 568                 }
 569
 570                 oldself = self;
 571                 self = spot;
 572                         activator = oldself;
 573                                 string s;
 574                                 s = self.target;
 575                                 self.target = string_null;
 576                                 SUB_UseTargets();
 577                                 self.target = s;
 578                         activator = world;
 579                 self = oldself;
 580
 581                 spawn_spot = spot;
 582                 MUTATOR_CALLHOOK(PlayerSpawn);
 583
 584                 if(autocvar_spawn_debug)
 585                 {
 586                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 587                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 588                 }
 589
 590                 self.switchweapon = w_getbestweapon(self);
 591                 self.cnt = -1; // W_LastWeapon will not complain
 592                 self.weapon = 0;
 593                 self.weaponname = "";
 594                 self.switchingweapon = 0;
 595
 596                 if(!inWarmupStage)
 597                         if(!self.alivetime)
 598                                 self.alivetime = time;
 599
 600                 antilag_clear(self);
 601         }
 602         else if(IS_OBSERVER(self))
 603         {
 604                 PutObserverInServer ();
 605         }
 606 }
 607
 608 .float ebouncefactor, ebouncestop; // electro's values
 609 // TODO do we need all these fields, or should we stop autodetecting runtime
 610 // changes and just have a console command to update this?
 611 float ClientInit_SendEntity(entity to, float sf)
 612 {
 613         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 614         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 615         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 627         if(sv_foginterval && world.fog != "")
 628                 WriteString(MSG_ENTITY, world.fog);
 629         else
 630                 WriteString(MSG_ENTITY, "");
 631         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 632         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 633         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 634         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 635         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 636         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 637         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 638         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 639         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 641         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 642         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 643         return TRUE;
 644 }
 645
 646 void ClientInit_CheckUpdate()
 647 {
 648         self.nextthink = time;
 649         if(self.count != autocvar_g_balance_armor_blockpercent)
 650         {
 651                 self.count = autocvar_g_balance_armor_blockpercent;
 652                 self.SendFlags |= 1;
 653         }
 654         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 655         {
 656                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 657                 self.SendFlags |= 1;
 658         }
 659         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 660         {
 661                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 662                 self.SendFlags |= 1;
 663         }
 664         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 665         {
 666                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 667                 self.SendFlags |= 1;
 668         }
 669         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 670         {
 671                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 672                 self.SendFlags |= 1;
 673         }
 674 }
 675
 676 void ClientInit_Spawn()
 677 {
 678         entity o;
 679         entity e;
 680         e = spawn();
 681         e.classname = "clientinit";
 682         e.think = ClientInit_CheckUpdate;
 683         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 684
 685         o = self;
 686         self = e;
 687         ClientInit_CheckUpdate();
 688         self = o;
 689 }
 690
 691 /*
 692 =============
 693 SetNewParms
 694 =============
 695 */
 696 void SetNewParms (void)
 697 {
 698         // initialize parms for a new player
 699         parm1 = -(86400 * 366);
 700 }
 701
 702 /*
 703 =============
 704 SetChangeParms
 705 =============
 706 */
 707 void SetChangeParms (void)
 708 {
 709         // save parms for level change
 710         parm1 = self.parm_idlesince - time;
 711 }
 712
 713 /*
 714 =============
 715 DecodeLevelParms
 716 =============
 717 */
 718 void DecodeLevelParms (void)
 719 {
 720         // load parms
 721         self.parm_idlesince = parm1;
 722         if(self.parm_idlesince == -(86400 * 366))
 723                 self.parm_idlesince = time;
 724
 725         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 726         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 727 }
 728
 729 /*
 730 =============
 731 ClientKill
 732
 733 Called when a client types 'kill' in the console
 734 =============
 735 */
 736
 737 .float clientkill_nexttime;
 738 void ClientKill_Now_TeamChange()
 739 {
 740         if(self.killindicator_teamchange == -1)
 741         {
 742                 JoinBestTeam( self, FALSE, TRUE );
 743         }
 744         else if(self.killindicator_teamchange == -2)
 745         {
 746                 if(blockSpectators)
 747                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 748                 PutObserverInServer();
 749         }
 750         else
 751                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 752         self.killindicator_teamchange = 0;
 753 }
 754
 755 void ClientKill_Now()
 756 {
 757         if(self.vehicle)
 758         {
 759             vehicles_exit(VHEF_RELESE);
 760             if(!self.killindicator_teamchange)
 761             {
 762             self.vehicle_health = -1;
 763             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 764             }
 765         }
 766
 767         if(self.killindicator && !wasfreed(self.killindicator))
 768                 remove(self.killindicator);
 769
 770         self.killindicator = world;
 771
 772         if(self.killindicator_teamchange)
 773                 ClientKill_Now_TeamChange();
 774
 775         // in any case:
 776         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 777
 778         // now I am sure the player IS dead
 779 }
 780 void KillIndicator_Think()
 781 {
 782         if (gameover)
 783         {
 784                 self.owner.killindicator = world;
 785                 remove(self);
 786                 return;
 787         }
 788
 789         if (self.owner.alpha < 0 && !self.owner.vehicle)
 790         {
 791                 self.owner.killindicator = world;
 792                 remove(self);
 793                 return;
 794         }
 795
 796         if(self.cnt <= 0)
 797         {
 798                 self = self.owner;
 799                 ClientKill_Now(); // no oldself needed
 800                 return;
 801         }
 802     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 803     {
 804         self.nextthink = time + 1;
 805         self.cnt -= 1;
 806     }
 807         else
 808         {
 809                 if(self.cnt <= 10)
 810                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 811                 if(IS_REAL_CLIENT(self.owner))
 812                 {
 813                         if(self.cnt <= 10)
 814                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
 815                 }
 816                 self.nextthink = time + 1;
 817                 self.cnt -= 1;
 818         }
 819 }
 820
 821 float clientkilltime;
 822 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 823 {
 824         float killtime;
 825         float starttime;
 826         entity e;
 827
 828         if (gameover)
 829                 return;
 830
 831         killtime = autocvar_g_balance_kill_delay;
 832
 833         if(g_race_qualifying || g_cts)
 834                 killtime = 0;
 835
 836     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 837     {
 838                 remove(self.killindicator);
 839                 self.killindicator = world;
 840
 841         ClientKill_Now(); // allow instant kill in this case
 842         return;
 843     }
 844
 845         self.killindicator_teamchange = targetteam;
 846
 847     if(!self.killindicator)
 848         {
 849                 if(self.deadflag == DEAD_NO)
 850                 {
 851                         killtime = max(killtime, self.clientkill_nexttime - time);
 852                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 853                 }
 854
 855                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 856                 {
 857                         ClientKill_Now();
 858                 }
 859                 else
 860                 {
 861                         starttime = max(time, clientkilltime);
 862
 863                         self.killindicator = spawn();
 864                         self.killindicator.owner = self;
 865                         self.killindicator.scale = 0.5;
 866                         setattachment(self.killindicator, self, "");
 867                         setorigin(self.killindicator, '0 0 52');
 868                         self.killindicator.think = KillIndicator_Think;
 869                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 870                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 871                         self.killindicator.cnt = ceil(killtime);
 872                         self.killindicator.count = bound(0, ceil(killtime), 10);
 873                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 874
 875                         for(e = world; (e = find(e, classname, "body")) != world; )
 876                         {
 877                                 if(e.enemy != self)
 878                                         continue;
 879                                 e.killindicator = spawn();
 880                                 e.killindicator.owner = e;
 881                                 e.killindicator.scale = 0.5;
 882                                 setattachment(e.killindicator, e, "");
 883                                 setorigin(e.killindicator, '0 0 52');
 884                                 e.killindicator.think = KillIndicator_Think;
 885                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 886                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 887                                 e.killindicator.cnt = ceil(killtime);
 888                         }
 889                         self.lip = 0;
 890                 }
 891         }
 892         if(self.killindicator)
 893         {
 894                 if(targetteam == 0) // just die
 895                 {
 896                         self.killindicator.colormod = '0 0 0';
 897                         if(IS_REAL_CLIENT(self))
 898                         if(self.killindicator.cnt > 0)
 899                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 900                 }
 901                 else if(targetteam == -1) // auto
 902                 {
 903                         self.killindicator.colormod = '0 1 0';
 904                         if(IS_REAL_CLIENT(self))
 905                         if(self.killindicator.cnt > 0)
 906                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 907                 }
 908                 else if(targetteam == -2) // spectate
 909                 {
 910                         self.killindicator.colormod = '0.5 0.5 0.5';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 914                 }
 915                 else
 916                 {
 917                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 921                 }
 922         }
 923
 924 }
 925
 926 void ClientKill (void)
 927 {
 928         if(gameover) return;
 929         if(self.player_blocked) return;
 930         if(self.freezetag_frozen) return;
 931
 932         ClientKill_TeamChange(0);
 933 }
 934
 935 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 936 {
 937     e.killindicator = spawn();
 938     e.killindicator.owner = e;
 939     e.killindicator.think = KillIndicator_Think;
 940     e.killindicator.nextthink = time + (e.lip) * 0.05;
 941     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 942     e.killindicator.health = 1; // this is used to indicate that it should be silent
 943     e.lip = 0;
 944 }
 945
 946 void FixClientCvars(entity e)
 947 {
 948         // send prediction settings to the client
 949         stuffcmd(e, "\nin_bindmap 0 0\n");
 950         if(g_race || g_cts)
 951                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 952         if(autocvar_g_antilag == 3) // client side hitscan
 953                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 954         if(autocvar_sv_gentle)
 955                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 956         /*
 957          * we no longer need to stuff this. Remove this comment block if you feel
 958          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 959         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 960         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 961         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 962         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 963         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 964         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 965         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 966         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 967         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 968         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 969         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 970         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 971         stuffcmd(e, "cl_movement_edgefriction 1\n");
 972          */
 973 }
 974
 975 float PlayerInIDList(entity p, string idlist)
 976 {
 977         float n, i;
 978         string s;
 979
 980         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 981         if not(p.crypto_idfp)
 982                 return 0;
 983
 984         // this function allows abbreviated player IDs too!
 985         n = tokenize_console(idlist);
 986         for(i = 0; i < n; ++i)
 987         {
 988                 s = argv(i);
 989                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 990                         return 1;
 991         }
 992
 993         return 0;
 994 }
 995
 996 /*
 997 =============
 998 ClientConnect
 999
1000 Called when a client connects to the server
1001 =============
1002 */
1003 void DecodeLevelParms (void);
1004 //void dom_player_join_team(entity pl);
1005 void set_dom_state(entity e);
1006 void ClientConnect (void)
1007 {
1008         float t;
1009
1010         if(IS_CLIENT(self))
1011         {
1012                 print("Warning: ClientConnect, but already connected!\n");
1013                 return;
1014         }
1015
1016         if(Ban_MaybeEnforceBanOnce(self))
1017                 return;
1018
1019         DecodeLevelParms();
1020
1021 #ifdef WATERMARK
1022         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1023 #endif
1024
1025         self.classname = "player_joining";
1026
1027         self.flags = FL_CLIENT;
1028         self.version_nagtime = time + 10 + random() * 10;
1029
1030         if(player_count<0)
1031         {
1032                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1033                 player_count = 0;
1034         }
1035
1036         PlayerInfo_Basic(self);
1037         PlayerScore_Attach(self);
1038         ClientData_Attach();
1039         accuracy_init(self);
1040
1041         bot_clientconnect();
1042
1043         playerdemo_init();
1044
1045         anticheat_init();
1046
1047         race_PreSpawnObserver();
1048
1049         // identify the right forced team
1050         if(autocvar_g_campaign)
1051         {
1052                 if(IS_REAL_CLIENT(self)) // only players, not bots
1053                 {
1054                         switch(autocvar_g_campaign_forceteam)
1055                         {
1056                                 case 1: self.team_forced = NUM_TEAM_1; break;
1057                                 case 2: self.team_forced = NUM_TEAM_2; break;
1058                                 case 3: self.team_forced = NUM_TEAM_3; break;
1059                                 case 4: self.team_forced = NUM_TEAM_4; break;
1060                                 default: self.team_forced = 0;
1061                         }
1062                 }
1063         }
1064         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1065                 self.team_forced = NUM_TEAM_1;
1066         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1067                 self.team_forced = NUM_TEAM_2;
1068         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1069                 self.team_forced = NUM_TEAM_3;
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1071                 self.team_forced = NUM_TEAM_4;
1072         else if(autocvar_g_forced_team_otherwise == "red")
1073                 self.team_forced = NUM_TEAM_1;
1074         else if(autocvar_g_forced_team_otherwise == "blue")
1075                 self.team_forced = NUM_TEAM_2;
1076         else if(autocvar_g_forced_team_otherwise == "yellow")
1077                 self.team_forced = NUM_TEAM_3;
1078         else if(autocvar_g_forced_team_otherwise == "pink")
1079                 self.team_forced = NUM_TEAM_4;
1080         else if(autocvar_g_forced_team_otherwise == "spectate")
1081                 self.team_forced = -1;
1082         else if(autocvar_g_forced_team_otherwise == "spectator")
1083                 self.team_forced = -1;
1084         else
1085                 self.team_forced = 0;
1086
1087         if(!teamplay)
1088                 if(self.team_forced > 0)
1089                         self.team_forced = 0;
1090
1091         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1092
1093         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1094                 self.classname = "observer";
1095         } else {
1096                 if(teamplay)
1097                 {
1098                         if(autocvar_g_balance_teams)
1099                         {
1100                                 self.classname = "player";
1101                                 campaign_bots_may_start = 1;
1102                         }
1103                         else
1104                         {
1105                                 self.classname = "observer"; // do it anyway
1106                         }
1107                 }
1108                 else
1109                 {
1110                         self.classname = "player";
1111                         campaign_bots_may_start = 1;
1112                 }
1113         }
1114
1115         self.playerid = (playerid_last = playerid_last + 1);
1116
1117         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1118
1119     if(IS_BOT_CLIENT(self))
1120         PlayerStats_AddPlayer(self);
1121
1122         if(autocvar_sv_eventlog)
1123                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1124
1125         LogTeamchange(self.playerid, self.team, 1);
1126
1127         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1128
1129         self.netname_previous = strzone(self.netname);
1130
1131         if(IS_PLAYER(self) && teamplay)
1132                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1133         else
1134                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1135
1136         stuffcmd(self, strcat(clientstuff, "\n"));
1137         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1138
1139         FixClientCvars(self);
1140
1141         // spawnfunc_waypoint sprites
1142         WaypointSprite_InitClient(self);
1143
1144         // Wazat's grappling hook
1145         SetGrappleHookBindings();
1146
1147         // get version info from player
1148         stuffcmd(self, "cmd clientversion $gameversion\n");
1149
1150         // get other cvars from player
1151         GetCvars(0);
1152
1153         // notify about available teams
1154         if(teamplay)
1155         {
1156                 CheckAllowedTeams(self);
1157                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1158                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1159         }
1160         else
1161                 stuffcmd(self, "set _teams_available 0\n");
1162
1163         attach_entcs();
1164
1165         bot_relinkplayerlist();
1166
1167         self.spectatortime = time;
1168         if(blockSpectators)
1169         {
1170                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1171         }
1172
1173         self.jointime = time;
1174         self.allowed_timeouts = autocvar_sv_timeout_number;
1175
1176         if(IS_REAL_CLIENT(self))
1177         {
1178                 if(!autocvar_g_campaign)
1179                 {
1180                         self.motd_actived_time = -1;
1181                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1182                 }
1183
1184                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1185                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1186         }
1187
1188         if(!sv_foginterval && world.fog != "")
1189                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1190
1191         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1192         {
1193                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1194                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1195         }
1196         else
1197                 self.hitplotfh = -1;
1198
1199         if(g_race || g_cts) {
1200                 string rr;
1201                 if(g_cts)
1202                         rr = CTS_RECORD;
1203                 else
1204                         rr = RACE_RECORD;
1205
1206                 msg_entity = self;
1207                 race_send_recordtime(MSG_ONE);
1208                 race_send_speedaward(MSG_ONE);
1209
1210                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1211                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1212                 race_send_speedaward_alltimebest(MSG_ONE);
1213
1214                 float i;
1215                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1216                         race_SendRankings(i, 0, 0, MSG_ONE);
1217                 }
1218         }
1219         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1220                 send_CSQC_teamnagger();
1221
1222         CheatInitClient();
1223
1224         CSQCMODEL_AUTOINIT();
1225
1226         self.model_randomizer = random();
1227
1228         if(IS_REAL_CLIENT(self))
1229                 sv_notice_join();
1230
1231         MUTATOR_CALLHOOK(ClientConnect);
1232 }
1233 /*
1234 =============
1235 ClientDisconnect
1236
1237 Called when a client disconnects from the server
1238 =============
1239 */
1240 .entity chatbubbleentity;
1241 void ReadyCount();
1242 void ClientDisconnect (void)
1243 {
1244         if(self.vehicle)
1245             vehicles_exit(VHEF_RELESE);
1246
1247         if not(IS_CLIENT(self))
1248         {
1249                 print("Warning: ClientDisconnect without ClientConnect\n");
1250                 return;
1251         }
1252
1253         PlayerStats_AddGlobalInfo(self);
1254
1255         CheatShutdownClient();
1256
1257         if(self.hitplotfh >= 0)
1258         {
1259                 fclose(self.hitplotfh);
1260                 self.hitplotfh = -1;
1261         }
1262
1263         anticheat_report();
1264         anticheat_shutdown();
1265
1266         playerdemo_shutdown();
1267
1268         bot_clientdisconnect();
1269
1270         if(self.entcs)
1271                 detach_entcs();
1272
1273         if(autocvar_sv_eventlog)
1274                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1275
1276         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1277
1278         MUTATOR_CALLHOOK(ClientDisconnect);
1279
1280         Portal_ClearAll(self);
1281
1282         RemoveGrapplingHook(self);
1283
1284         // Here, everything has been done that requires this player to be a client.
1285
1286         self.flags &~= FL_CLIENT;
1287
1288         if (self.chatbubbleentity)
1289                 remove (self.chatbubbleentity);
1290
1291         if (self.killindicator)
1292                 remove (self.killindicator);
1293
1294         WaypointSprite_PlayerGone();
1295
1296         bot_relinkplayerlist();
1297
1298         accuracy_free(self);
1299         ClientData_Detach();
1300         PlayerScore_Detach(self);
1301
1302         if(self.netname_previous)
1303                 strunzone(self.netname_previous);
1304         if(self.clientstatus)
1305                 strunzone(self.clientstatus);
1306         if(self.weaponorder_byimpulse)
1307                 strunzone(self.weaponorder_byimpulse);
1308
1309         ClearPlayerSounds();
1310
1311         if(self.personal)
1312                 remove(self.personal);
1313
1314         self.playerid = 0;
1315         ReadyCount();
1316
1317         // free cvars
1318         GetCvars(-1);
1319 }
1320
1321 .float BUTTON_CHAT;
1322 void ChatBubbleThink()
1323 {
1324         self.nextthink = time;
1325         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1326         {
1327                 if(self.owner) // but why can that ever be world?
1328                         self.owner.chatbubbleentity = world;
1329                 remove(self);
1330                 return;
1331         }
1332         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1333 #ifdef TETRIS
1334                 || self.owner.tetris_on
1335 #endif
1336         )
1337                 self.model = self.mdl;
1338         else
1339                 self.model = "";
1340 }
1341
1342 void UpdateChatBubble()
1343 {
1344         if (self.alpha < 0)
1345                 return;
1346         // spawn a chatbubble entity if needed
1347         if (!self.chatbubbleentity)
1348         {
1349                 self.chatbubbleentity = spawn();
1350                 self.chatbubbleentity.owner = self;
1351                 self.chatbubbleentity.exteriormodeltoclient = self;
1352                 self.chatbubbleentity.think = ChatBubbleThink;
1353                 self.chatbubbleentity.nextthink = time;
1354                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1355                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1356                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1357                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1358                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1359                 self.chatbubbleentity.model = "";
1360                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1361         }
1362 }
1363
1364
1365 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1366 // added to the model skins
1367 /*void UpdateColorModHack()
1368 {
1369         float c;
1370         c = self.clientcolors & 15;
1371         // LordHavoc: only bothering to support white, green, red, yellow, blue
1372              if (!teamplay) self.colormod = '0 0 0';
1373         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1374         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1375         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1376         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1377         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1378         else self.colormod = '1 1 1';
1379 }*/
1380
1381 void respawn(void)
1382 {
1383         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1384         {
1385                 self.solid = SOLID_NOT;
1386                 self.takedamage = DAMAGE_NO;
1387                 self.movetype = MOVETYPE_FLY;
1388                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1389                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1390                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1391                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1392                 if(autocvar_g_respawn_ghosts_maxtime)
1393                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1394         }
1395
1396         CopyBody(1);
1397
1398         self.effects |= EF_NODRAW; // prevent another CopyBody
1399         PutClientInServer();
1400 }
1401
1402 void play_countdown(float finished, string samp)
1403 {
1404         if(IS_REAL_CLIENT(self))
1405                 if(floor(finished - time - frametime) != floor(finished - time))
1406                         if(finished - time < 6)
1407                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1408 }
1409
1410 void player_powerups (void)
1411 {
1412         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1413         olditems = self.items;
1414
1415         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1416                 self.modelflags |= MF_ROCKET;
1417         else
1418                 self.modelflags &~= MF_ROCKET;
1419
1420         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1421
1422         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1423                 return;
1424
1425         Fire_ApplyDamage(self);
1426         Fire_ApplyEffect(self);
1427
1428         if not(g_minstagib)
1429         {
1430                 if (self.items & IT_STRENGTH)
1431                 {
1432                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1433                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1434                         if (time > self.strength_finished)
1435                         {
1436                                 self.items = self.items - (self.items & IT_STRENGTH);
1437                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1438                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1439                         }
1440                 }
1441                 else
1442                 {
1443                         if (time < self.strength_finished)
1444                         {
1445                                 self.items = self.items | IT_STRENGTH;
1446                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1447                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1448                         }
1449                 }
1450                 if (self.items & IT_INVINCIBLE)
1451                 {
1452                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1453                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1454                         if (time > self.invincible_finished)
1455                         {
1456                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1457                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1458                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1459                         }
1460                 }
1461                 else
1462                 {
1463                         if (time < self.invincible_finished)
1464                         {
1465                                 self.items = self.items | IT_INVINCIBLE;
1466                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1467                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1468                         }
1469                 }
1470                 if (self.items & IT_SUPERWEAPON)
1471                 {
1472                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1473                         {
1474                                 self.superweapons_finished = 0;
1475                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1476                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1477                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1478                         }
1479                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1480                         {
1481                                 // don't let them run out
1482                         }
1483                         else
1484                         {
1485                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1486                                 if (time > self.superweapons_finished)
1487                                 {
1488                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1489                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1490                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1491                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1492                                 }
1493                         }
1494                 }
1495                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1496                 {
1497                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1498                         {
1499                                 self.items = self.items | IT_SUPERWEAPON;
1500                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1501                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1502                         }
1503                         else
1504                         {
1505                                 self.superweapons_finished = 0;
1506                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1507                         }
1508                 }
1509                 else
1510                 {
1511                         self.superweapons_finished = 0;
1512                 }
1513         }
1514
1515         if(autocvar_g_nodepthtestplayers)
1516                 self.effects = self.effects | EF_NODEPTHTEST;
1517
1518         if(autocvar_g_fullbrightplayers)
1519                 self.effects = self.effects | EF_FULLBRIGHT;
1520
1521         if (time >= game_starttime)
1522         if (time < self.spawnshieldtime)
1523                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1524
1525         MUTATOR_CALLHOOK(PlayerPowerups);
1526 }
1527
1528 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1529 {
1530         if(current > stable)
1531                 return current;
1532         else if(current > stable - 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1536 }
1537
1538 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1539 {
1540         if(current < stable)
1541                 return current;
1542         else if(current < stable + 0.25) // when close enough, "snap"
1543                 return stable;
1544         else
1545                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1546 }
1547
1548 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1549 {
1550         if(current > rotstable)
1551         {
1552                 if(rotframetime > 0)
1553                 {
1554                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1555                         current = max(rotstable, current - rotlinear * rotframetime);
1556                 }
1557         }
1558         else if(current < regenstable)
1559         {
1560                 if(regenframetime > 0)
1561                 {
1562                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1563                         current = min(regenstable, current + regenlinear * regenframetime);
1564                 }
1565         }
1566
1567         if(current > limit)
1568                 current = limit;
1569
1570         return current;
1571 }
1572
1573 void player_regen (void)
1574 {
1575         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1576         maxh = autocvar_g_balance_health_rotstable;
1577         maxa = autocvar_g_balance_armor_rotstable;
1578         maxf = autocvar_g_balance_fuel_rotstable;
1579         minh = autocvar_g_balance_health_regenstable;
1580         mina = autocvar_g_balance_armor_regenstable;
1581         minf = autocvar_g_balance_fuel_regenstable;
1582         limith = autocvar_g_balance_health_limit;
1583         limita = autocvar_g_balance_armor_limit;
1584         limitf = autocvar_g_balance_fuel_limit;
1585
1586         max_mod = regen_mod = rot_mod = limit_mod = 1;
1587
1588         maxh = maxh * max_mod;
1589         //maxa = maxa * max_mod;
1590         //maxf = maxf * max_mod;
1591         minh = minh * max_mod;
1592         //mina = mina * max_mod;
1593         //minf = minf * max_mod;
1594         limith = limith * limit_mod;
1595         limita = limita * limit_mod;
1596         //limitf = limitf * limit_mod;
1597
1598         if(g_ca)
1599                 rot_mod = 0;
1600
1601         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1602         {
1603                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1604                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1605
1606                 // if player rotted to death...  die!
1607                 if(self.health < 1)
1608                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1609         }
1610
1611         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1612                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1613 }
1614
1615 float zoomstate_set;
1616 void SetZoomState(float z)
1617 {
1618         if(z != self.zoomstate)
1619         {
1620                 self.zoomstate = z;
1621                 ClientData_Touch(self);
1622         }
1623         zoomstate_set = 1;
1624 }
1625
1626 void GetPressedKeys(void) {
1627         MUTATOR_CALLHOOK(GetPressedKeys);
1628         if (self.movement_x > 0) // get if movement keys are pressed
1629         {       // forward key pressed
1630                 self.pressedkeys |= KEY_FORWARD;
1631                 self.pressedkeys &~= KEY_BACKWARD;
1632         }
1633         else if (self.movement_x < 0)
1634         {       // backward key pressed
1635                 self.pressedkeys |= KEY_BACKWARD;
1636                 self.pressedkeys &~= KEY_FORWARD;
1637         }
1638         else
1639         {       // no x input
1640                 self.pressedkeys &~= KEY_FORWARD;
1641                 self.pressedkeys &~= KEY_BACKWARD;
1642         }
1643
1644         if (self.movement_y > 0)
1645         {       // right key pressed
1646                 self.pressedkeys |= KEY_RIGHT;
1647                 self.pressedkeys &~= KEY_LEFT;
1648         }
1649         else if (self.movement_y < 0)
1650         {       // left key pressed
1651                 self.pressedkeys |= KEY_LEFT;
1652                 self.pressedkeys &~= KEY_RIGHT;
1653         }
1654         else
1655         {       // no y input
1656                 self.pressedkeys &~= KEY_RIGHT;
1657                 self.pressedkeys &~= KEY_LEFT;
1658         }
1659
1660         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1661                 self.pressedkeys |= KEY_JUMP;
1662         else
1663                 self.pressedkeys &~= KEY_JUMP;
1664         if (self.BUTTON_CROUCH)
1665                 self.pressedkeys |= KEY_CROUCH;
1666         else
1667                 self.pressedkeys &~= KEY_CROUCH;
1668
1669         if (self.BUTTON_ATCK)
1670                 self.pressedkeys |= KEY_ATCK;
1671         else
1672                 self.pressedkeys &~= KEY_ATCK;
1673         if (self.BUTTON_ATCK2)
1674                 self.pressedkeys |= KEY_ATCK2;
1675         else
1676                 self.pressedkeys &~= KEY_ATCK2;
1677 }
1678
1679 /*
1680 ======================
1681 spectate mode routines
1682 ======================
1683 */
1684
1685 void SpectateCopy(entity spectatee) {
1686         other = spectatee;
1687         MUTATOR_CALLHOOK(SpectateCopy);
1688         self.armortype = spectatee.armortype;
1689         self.armorvalue = spectatee.armorvalue;
1690         self.ammo_cells = spectatee.ammo_cells;
1691         self.ammo_shells = spectatee.ammo_shells;
1692         self.ammo_nails = spectatee.ammo_nails;
1693         self.ammo_rockets = spectatee.ammo_rockets;
1694         self.ammo_fuel = spectatee.ammo_fuel;
1695         self.clip_load = spectatee.clip_load;
1696         self.clip_size = spectatee.clip_size;
1697         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1698         self.health = spectatee.health;
1699         self.impulse = 0;
1700         self.items = spectatee.items;
1701         self.last_pickup = spectatee.last_pickup;
1702         self.hit_time = spectatee.hit_time;
1703         self.metertime = spectatee.metertime;
1704         self.strength_finished = spectatee.strength_finished;
1705         self.invincible_finished = spectatee.invincible_finished;
1706         self.pressedkeys = spectatee.pressedkeys;
1707         WEPSET_COPY_EE(self, spectatee);
1708         self.switchweapon = spectatee.switchweapon;
1709         self.switchingweapon = spectatee.switchingweapon;
1710         self.weapon = spectatee.weapon;
1711         self.nex_charge = spectatee.nex_charge;
1712         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1713         self.hagar_load = spectatee.hagar_load;
1714         self.minelayer_mines = spectatee.minelayer_mines;
1715         self.punchangle = spectatee.punchangle;
1716         self.view_ofs = spectatee.view_ofs;
1717         self.velocity = spectatee.velocity;
1718         self.dmg_take = spectatee.dmg_take;
1719         self.dmg_save = spectatee.dmg_save;
1720         self.dmg_inflictor = spectatee.dmg_inflictor;
1721         self.v_angle = spectatee.v_angle;
1722         self.angles = spectatee.v_angle;
1723         if(!self.BUTTON_USE)
1724                 self.fixangle = TRUE;
1725         setorigin(self, spectatee.origin);
1726         setsize(self, spectatee.mins, spectatee.maxs);
1727         SetZoomState(spectatee.zoomstate);
1728
1729     anticheat_spectatecopy(spectatee);
1730         self.hud = spectatee.hud;
1731         if(spectatee.vehicle)
1732     {
1733         self.fixangle = FALSE;
1734         //self.velocity = spectatee.vehicle.velocity;
1735         self.vehicle_health = spectatee.vehicle_health;
1736         self.vehicle_shield = spectatee.vehicle_shield;
1737         self.vehicle_energy = spectatee.vehicle_energy;
1738         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1739         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1740         self.vehicle_reload1 = spectatee.vehicle_reload1;
1741         self.vehicle_reload2 = spectatee.vehicle_reload2;
1742
1743         msg_entity = self;
1744
1745         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1746             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1747             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1748             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1749
1750         //WriteByte (MSG_ONE, SVC_SETVIEW);
1751         //    WriteEntity(MSG_ONE, self);
1752         //makevectors(spectatee.v_angle);
1753         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1754     }
1755 }
1756
1757 float SpectateUpdate() {
1758         if(!self.enemy)
1759             return 0;
1760
1761         if (self == self.enemy)
1762                 return 0;
1763
1764         if not(IS_PLAYER(self.enemy))
1765                 return 0;
1766
1767         SpectateCopy(self.enemy);
1768
1769         return 1;
1770 }
1771
1772
1773 float SpectateSet()
1774 {
1775         if(self.enemy.classname != "player")
1776                 return FALSE;
1777         /*if(self.enemy.vehicle)
1778         {
1779
1780                 msg_entity = self;
1781                 WriteByte(MSG_ONE, SVC_SETVIEW);
1782                 WriteEntity(MSG_ONE, self.enemy);
1783                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1784
1785                 self.movetype = MOVETYPE_NONE;
1786                 accuracy_resend(self);
1787         }
1788         else
1789         {*/
1790                 msg_entity = self;
1791                 WriteByte(MSG_ONE, SVC_SETVIEW);
1792                 WriteEntity(MSG_ONE, self.enemy);
1793                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1794                 self.movetype = MOVETYPE_NONE;
1795                 accuracy_resend(self);
1796
1797                 if(!SpectateUpdate())
1798                         PutObserverInServer();
1799         //}
1800         return TRUE;
1801 }
1802
1803 float Spectate(entity pl)
1804 {
1805         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1806         if(pl.team != self.team)
1807                 return 0;
1808
1809         self.enemy = pl;
1810         return SpectateSet();
1811 }
1812
1813 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1814 entity CA_SpectateNext(entity start) {
1815         if (start.team == self.team) {
1816                 return start;
1817         }
1818
1819         other = start;
1820         // continue from current player
1821         while(other && other.team != self.team) {
1822                 other = find(other, classname, "player");
1823         }
1824
1825         if (!other) {
1826                 // restart from begining
1827                 other = find(other, classname, "player");
1828                 while(other && other.team != self.team) {
1829                         other = find(other, classname, "player");
1830                 }
1831         }
1832
1833         return other;
1834 }
1835
1836 float SpectateNext()
1837 {
1838         other = find(self.enemy, classname, "player");
1839
1840         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1841                 // CA and ca players when spectating enemies is forbidden
1842                 other = CA_SpectateNext(other);
1843         } else {
1844                 // other modes and ca spectators or spectating enemies is allowed
1845                 if (!other)
1846                         other = find(other, classname, "player");
1847         }
1848
1849         if (other)
1850                 self.enemy = other;
1851
1852         return SpectateSet();
1853 }
1854
1855 float SpectatePrev()
1856 {
1857         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1858         other = findchain(classname, "player");
1859         if not(other) // no player
1860                 return FALSE;
1861
1862         entity first = other;
1863         // skip players until current spectated player
1864         if(self.enemy)
1865         while(other && other != self.enemy)
1866                 other = other.chain;
1867
1868         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1869         {
1870                 do { other = other.chain; }
1871                 while(other && other.team != self.team);
1872
1873                 if not(other)
1874                 {
1875                         other = first;
1876                         while(other.team != self.team)
1877                                 other = other.chain;
1878                         if(other == self.enemy)
1879                                 return TRUE;
1880                 }
1881         }
1882         else
1883         {
1884                 if(other.chain)
1885                         other = other.chain;
1886                 else
1887                         other = first;
1888         }
1889         self.enemy = other;
1890         return SpectateSet();
1891 }
1892
1893 /*
1894 =============
1895 ShowRespawnCountdown()
1896
1897 Update a respawn countdown display.
1898 =============
1899 */
1900 void ShowRespawnCountdown()
1901 {
1902         float number;
1903         if(self.deadflag == DEAD_NO) // just respawned?
1904                 return;
1905         else
1906         {
1907                 number = ceil(self.respawn_time - time);
1908                 if(number <= 0)
1909                         return;
1910                 if(number <= self.respawn_countdown)
1911                 {
1912                         self.respawn_countdown = number - 1;
1913                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1914                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
1915                 }
1916         }
1917 }
1918
1919 void LeaveSpectatorMode()
1920 {
1921         if(self.caplayer)
1922                 return;
1923         if(nJoinAllowed(self))
1924         {
1925                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1926                 {
1927                         self.classname = "player";
1928
1929                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1930                                 { JoinBestTeam(self, FALSE, TRUE); }
1931
1932                         if(autocvar_g_campaign)
1933                                 { campaign_bots_may_start = 1; }
1934
1935                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1936
1937                         PutClientInServer();
1938
1939                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1940                 }
1941                 else
1942                         stuffcmd(self, "menu_showteamselect\n");
1943         }
1944         else
1945         {
1946                 // Player may not join because g_maxplayers is set
1947                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1948         }
1949 }
1950
1951 /**
1952  * Determines whether the player is allowed to join. This depends on cvar
1953  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1954  * it checks whether the number of currently playing players exceeds g_maxplayers.
1955  * @return int number of free slots for players, 0 if none
1956  */
1957 float nJoinAllowed(entity ignore) {
1958         if(!ignore)
1959         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1960         // so report 0 free slots if restricted
1961         {
1962                 if(autocvar_g_forced_team_otherwise == "spectate")
1963                         return 0;
1964                 if(autocvar_g_forced_team_otherwise == "spectator")
1965                         return 0;
1966         }
1967
1968         if(self.team_forced < 0)
1969                 return 0; // forced spectators can never join
1970
1971         // TODO simplify this
1972         entity e;
1973         float totalClients = 0;
1974         FOR_EACH_CLIENT(e)
1975                 if(e != ignore)
1976                         totalClients += 1;
1977
1978         if (!autocvar_g_maxplayers)
1979                 return maxclients - totalClients;
1980
1981         float currentlyPlaying = 0;
1982         FOR_EACH_REALCLIENT(e)
1983                 if(IS_PLAYER(e) || e.caplayer == 1)
1984                         currentlyPlaying += 1;
1985
1986         if(currentlyPlaying < autocvar_g_maxplayers)
1987                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1988
1989         return 0;
1990 }
1991
1992 /**
1993  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1994  * g_maxplayers_spectator_blocktime seconds
1995  */
1996 void checkSpectatorBlock() {
1997         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1998                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1999                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2000                         dropclient(self);
2001                 }
2002         }
2003 }
2004
2005 void PrintWelcomeMessage()
2006 {
2007         if(self.motd_actived_time == 0)
2008         {
2009                 if (autocvar_g_campaign) {
2010                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2011                                 self.motd_actived_time = time;
2012                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2013                         }
2014                 } else {
2015                         if (self.BUTTON_INFO) {
2016                                 self.motd_actived_time = time;
2017                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2018                         }
2019                 }
2020         }
2021         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2022         {
2023                 if (autocvar_g_campaign) {
2024                         if (self.BUTTON_INFO)
2025                                 self.motd_actived_time = time;
2026                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2027                                 self.motd_actived_time = 0;
2028                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2029                         }
2030                 } else {
2031                         if (self.BUTTON_INFO)
2032                                 self.motd_actived_time = time;
2033                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2034                                 self.motd_actived_time = 0;
2035                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2036                         }
2037                 }
2038         }
2039         else //if(self.motd_actived_time < 0) // just connected, motd is active
2040         {
2041                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2042                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2043                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2044                 {
2045                         // instanctly hide MOTD
2046                         self.motd_actived_time = 0;
2047                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2048                 }
2049         }
2050 }
2051
2052 void ObserverThink()
2053 {
2054         float prefered_movetype;
2055         if (self.flags & FL_JUMPRELEASED) {
2056                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2057                         self.flags &~= FL_JUMPRELEASED;
2058                         self.flags |= FL_SPAWNING;
2059                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2060                         self.flags &~= FL_JUMPRELEASED;
2061                         if(SpectateNext()) {
2062                                 self.classname = "spectator";
2063                         }
2064                 } else {
2065                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2066                         if (self.movetype != prefered_movetype)
2067                                 self.movetype = prefered_movetype;
2068                 }
2069         } else {
2070                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2071                         self.flags |= FL_JUMPRELEASED;
2072                         if(self.flags & FL_SPAWNING)
2073                         {
2074                                 self.flags &~= FL_SPAWNING;
2075                                 LeaveSpectatorMode();
2076                                 return;
2077                         }
2078                 }
2079         }
2080 }
2081
2082 void SpectatorThink()
2083 {
2084         if (self.flags & FL_JUMPRELEASED) {
2085                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2086                         self.flags &~= FL_JUMPRELEASED;
2087                         self.flags |= FL_SPAWNING;
2088                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2089                         self.flags &~= FL_JUMPRELEASED;
2090                         if(SpectateNext()) {
2091                                 self.classname = "spectator";
2092                         } else {
2093                                 self.classname = "observer";
2094                                 PutClientInServer();
2095                         }
2096                         self.impulse = 0;
2097                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2098                         self.flags &~= FL_JUMPRELEASED;
2099                         if(SpectatePrev()) {
2100                                 self.classname = "spectator";
2101                         } else {
2102                                 self.classname = "observer";
2103                                 PutClientInServer();
2104                         }
2105                         self.impulse = 0;
2106                 } else if (self.BUTTON_ATCK2) {
2107                         self.flags &~= FL_JUMPRELEASED;
2108                         self.classname = "observer";
2109                         PutClientInServer();
2110                 } else {
2111                         if(!SpectateUpdate())
2112                                 PutObserverInServer();
2113                 }
2114         } else {
2115                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2116                         self.flags |= FL_JUMPRELEASED;
2117                         if(self.flags & FL_SPAWNING)
2118                         {
2119                                 self.flags &~= FL_SPAWNING;
2120                                 LeaveSpectatorMode();
2121                                 return;
2122                         }
2123                 }
2124                 if(!SpectateUpdate())
2125                         PutObserverInServer();
2126         }
2127
2128         self.flags |= FL_CLIENT | FL_NOTARGET;
2129 }
2130
2131 void PlayerUseKey()
2132 {
2133         if not(IS_PLAYER(self))
2134                 return;
2135
2136         if(self.vehicle)
2137         {
2138         vehicles_exit(VHEF_NORMAL);
2139         return;
2140         }
2141
2142         // a use key was pressed; call handlers
2143         MUTATOR_CALLHOOK(PlayerUseKey);
2144 }
2145
2146 /*
2147 =============
2148 PlayerPreThink
2149
2150 Called every frame for each client before the physics are run
2151 =============
2152 */
2153 .float usekeypressed;
2154 void() nexball_setstatus;
2155 .float items_added;
2156 void PlayerPreThink (void)
2157 {
2158         WarpZone_PlayerPhysics_FixVAngle();
2159
2160         self.stat_game_starttime = game_starttime;
2161         self.stat_round_starttime = round_starttime;
2162         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2163         self.stat_leadlimit = autocvar_leadlimit;
2164
2165         if(frametime)
2166         {
2167                 // physics frames: update anticheat stuff
2168                 anticheat_prethink();
2169         }
2170
2171         if(blockSpectators && frametime)
2172                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2173                 checkSpectatorBlock();
2174
2175         zoomstate_set = 0;
2176
2177         if(self.netname_previous != self.netname)
2178         {
2179                 if(autocvar_sv_eventlog)
2180                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2181                 if(self.netname_previous)
2182                         strunzone(self.netname_previous);
2183                 self.netname_previous = strzone(self.netname);
2184         }
2185
2186         // version nagging
2187         if(self.version_nagtime)
2188                 if(self.cvar_g_xonoticversion)
2189                         if(time > self.version_nagtime)
2190                         {
2191                                 // don't notify git users
2192                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2193                                 {
2194                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2195                                         {
2196                                                 // notify release users if connecting to git
2197                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2198                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2199                                         }
2200                                         else
2201                                         {
2202                                                 float r;
2203                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2204                                                 if(r < 0)
2205                                                 {
2206                                                         // give users new version
2207                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2208                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2209                                                 }
2210                                                 else if(r > 0)
2211                                                 {
2212                                                         // notify users about old server version
2213                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2214                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2215                                                 }
2216                                         }
2217                                 }
2218                                 self.version_nagtime = 0;
2219                         }
2220
2221         // GOD MODE info
2222         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2223         {
2224                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2225                 self.max_armorvalue = 0;
2226         }
2227
2228 #ifdef TETRIS
2229         if (TetrisPreFrame())
2230                 return;
2231 #endif
2232
2233         MUTATOR_CALLHOOK(PlayerPreThink);
2234
2235         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2236         {
2237                 if(self.BUTTON_USE && !self.usekeypressed)
2238                         PlayerUseKey();
2239                 self.usekeypressed = self.BUTTON_USE;
2240         }
2241
2242         if(IS_REAL_CLIENT(self))
2243                 PrintWelcomeMessage();
2244
2245         if(IS_PLAYER(self))
2246         {
2247
2248                 CheckRules_Player();
2249
2250                 if (intermission_running)
2251                 {
2252                         IntermissionThink ();   // otherwise a button could be missed between
2253                         return;                                 // the think tics
2254                 }
2255
2256                 //don't allow the player to turn around while game is paused!
2257                 if(timeout_status == TIMEOUT_ACTIVE) {
2258                         // FIXME turn this into CSQC stuff
2259                         self.v_angle = self.lastV_angle;
2260                         self.angles = self.lastV_angle;
2261                         self.fixangle = TRUE;
2262                 }
2263
2264                 if(frametime)
2265                 {
2266                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2267                         {
2268                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2269                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2270                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2271
2272                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2273                                 {
2274                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2275                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2276                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2277                                 }
2278                         }
2279                         else
2280                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2281
2282                         player_powerups();
2283                 }
2284
2285                 if (self.deadflag != DEAD_NO)
2286                 {
2287                         if(self.personal && g_race_qualifying)
2288                         {
2289                                 if(time > self.respawn_time)
2290                                 {
2291                                         self.respawn_time = time + 1; // only retry once a second
2292                                         self.stat_respawn_time = self.respawn_time;
2293                                         respawn();
2294                                         self.impulse = 141;
2295                                 }
2296                         }
2297                         else
2298                         {
2299                                 float button_pressed;
2300                                 if(frametime)
2301                                         player_anim();
2302                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2303
2304                                 if (self.deadflag == DEAD_DYING)
2305                                 {
2306                                         if(self.respawn_flags & RESPAWN_FORCE)
2307                                                 self.deadflag = DEAD_RESPAWNING;
2308                                         else if(!button_pressed)
2309                                                 self.deadflag = DEAD_DEAD;
2310                                 }
2311                                 else if (self.deadflag == DEAD_DEAD)
2312                                 {
2313                                         if(button_pressed)
2314                                                 self.deadflag = DEAD_RESPAWNABLE;
2315                                 }
2316                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2317                                 {
2318                                         if(!button_pressed)
2319                                                 self.deadflag = DEAD_RESPAWNING;
2320                                 }
2321                                 else if (self.deadflag == DEAD_RESPAWNING)
2322                                 {
2323                                         if(time > self.respawn_time)
2324                                         {
2325                                                 self.respawn_time = time + 1; // only retry once a second
2326                                                 respawn();
2327                                         }
2328                                 }
2329
2330                                 ShowRespawnCountdown();
2331
2332                                 if(self.respawn_flags & RESPAWN_SILENT)
2333                                         self.stat_respawn_time = 0;
2334                                 else
2335                                         self.stat_respawn_time = self.respawn_time;
2336                         }
2337
2338                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2339                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2340                                 self.stat_respawn_time *= -1;
2341
2342                         return;
2343                 }
2344
2345                 self.prevorigin = self.origin;
2346
2347                 float do_crouch = self.BUTTON_CROUCH;
2348                 if(self.hook.state)
2349                         do_crouch = 0;
2350                 if(self.vehicle)
2351                         do_crouch = 0;
2352                 if(self.freezetag_frozen)
2353                         do_crouch = 0;
2354                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2355                         do_crouch = 0;
2356
2357                 if (do_crouch)
2358                 {
2359                         if (!self.crouch)
2360                         {
2361                                 self.crouch = TRUE;
2362                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2363                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2364                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2365                         }
2366                 }
2367                 else
2368                 {
2369                         if (self.crouch)
2370                         {
2371                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2372                                 if (!trace_startsolid)
2373                                 {
2374                                         self.crouch = FALSE;
2375                                         self.view_ofs = PL_VIEW_OFS;
2376                                         setsize (self, PL_MIN, PL_MAX);
2377                                 }
2378                         }
2379                 }
2380
2381                 FixPlayermodel();
2382
2383                 GrapplingHookFrame();
2384
2385                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2386                 //if(frametime)
2387                 {
2388                         self.items &~= self.items_added;
2389
2390                         W_WeaponFrame();
2391
2392                         self.items_added = 0;
2393                         if(self.items & IT_JETPACK)
2394                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2395                                         self.items_added |= IT_FUEL;
2396
2397                         self.items |= self.items_added;
2398                 }
2399
2400                 player_regen();
2401
2402                 // rot nex charge to the charge limit
2403                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2404                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2405
2406                 if(frametime)
2407                         player_anim();
2408
2409                 // secret status
2410                 secrets_setstatus();
2411
2412                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2413
2414                 //self.angles_y=self.v_angle_y + 90;   // temp
2415         } else if(gameover) {
2416                 if (intermission_running)
2417                         IntermissionThink ();   // otherwise a button could be missed between
2418                 return;
2419         } else if(IS_OBSERVER(self)) {
2420                 ObserverThink();
2421         } else if(IS_SPEC(self)) {
2422                 SpectatorThink();
2423         }
2424
2425         if(!zoomstate_set)
2426                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2427
2428         float oldspectatee_status;
2429         oldspectatee_status = self.spectatee_status;
2430         if(IS_SPEC(self))
2431                 self.spectatee_status = num_for_edict(self.enemy);
2432         else if(IS_OBSERVER(self))
2433                 self.spectatee_status = num_for_edict(self);
2434         else
2435                 self.spectatee_status = 0;
2436         if(self.spectatee_status != oldspectatee_status)
2437         {
2438                 ClientData_Touch(self);
2439                 if(g_race || g_cts)
2440                         race_InitSpectator();
2441         }
2442
2443         if(self.teamkill_soundtime)
2444         if(time > self.teamkill_soundtime)
2445         {
2446                 self.teamkill_soundtime = 0;
2447
2448                 entity oldpusher, oldself;
2449
2450                 oldself = self; self = self.teamkill_soundsource;
2451                 oldpusher = self.pusher; self.pusher = oldself;
2452
2453                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2454
2455                 self.pusher = oldpusher;
2456                 self = oldself;
2457         }
2458
2459         if(self.taunt_soundtime)
2460         if(time > self.taunt_soundtime)
2461         {
2462                 self.taunt_soundtime = 0;
2463                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2464         }
2465
2466         target_voicescript_next(self);
2467
2468         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2469         if(!self.weapon)
2470                 self.clip_load = self.clip_size = 0;
2471 }
2472
2473 float isInvisibleString(string s)
2474 {
2475         float i, n, c;
2476         s = strdecolorize(s);
2477         for((i = 0), (n = strlen(s)); i < n; ++i)
2478         {
2479                 c = str2chr(s, i);
2480                 switch(c)
2481                 {
2482                         case 0:
2483                         case 32: // space
2484                                 break;
2485                         case 192: // charmap space
2486                                 if (!autocvar_utf8_enable)
2487                                         break;
2488                                 return FALSE;
2489                         case 160: // space in unicode fonts
2490                         case 0xE000 + 192: // utf8 charmap space
2491                                 if (autocvar_utf8_enable)
2492                                         break;
2493                         default:
2494                                 return FALSE;
2495                 }
2496         }
2497         return TRUE;
2498 }
2499
2500 /*
2501 =============
2502 PlayerPostThink
2503
2504 Called every frame for each client after the physics are run
2505 =============
2506 */
2507 .float idlekick_lasttimeleft;
2508 void PlayerPostThink (void)
2509 {
2510         // Savage: Check for nameless players
2511         if (isInvisibleString(self.netname)) {
2512                 self.netname = "Player";
2513                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2514         }
2515
2516         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2517         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2518         {
2519                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2520                 {
2521                         if(self.idlekick_lasttimeleft)
2522                         {
2523                                 self.idlekick_lasttimeleft = 0;
2524                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2525                         }
2526                 }
2527                 else
2528                 {
2529                         float timeleft;
2530                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2531                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2532                         {
2533                                 if(!self.idlekick_lasttimeleft)
2534                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2535                         }
2536                         if(timeleft <= 0)
2537                         {
2538                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2539                                 dropclient(self);
2540                                 return;
2541                         }
2542                         else if(timeleft <= 10)
2543                         {
2544                                 if(timeleft != self.idlekick_lasttimeleft)
2545                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2546                                 self.idlekick_lasttimeleft = timeleft;
2547                         }
2548                 }
2549         }
2550
2551 #ifdef TETRIS
2552         if(self.impulse == 100)
2553                 ImpulseCommands();
2554         if (!TetrisPostFrame())
2555         {
2556 #endif
2557
2558         CheatFrame();
2559
2560         //CheckPlayerJump();
2561
2562         if(IS_PLAYER(self)) {
2563                 CheckRules_Player();
2564                 UpdateChatBubble();
2565                 if (self.impulse)
2566                         ImpulseCommands();
2567                 if (intermission_running)
2568                         return;         // intermission or finale
2569                 GetPressedKeys();
2570         }
2571
2572 #ifdef TETRIS
2573         }
2574 #endif
2575
2576         /*
2577         float i;
2578         for(i = 0; i < 1000; ++i)
2579         {
2580                 vector end;
2581                 end = self.origin + '0 0 1024' + 512 * randomvec();
2582                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2583                 if(trace_fraction < 1)
2584                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2585                 {
2586                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2587                         break;
2588                 }
2589         }
2590         */
2591
2592         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2593
2594         if(self.waypointsprite_attachedforcarrier)
2595                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2596
2597         playerdemo_write();
2598
2599         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2600         {
2601                 if not(self.stored_netname)
2602                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2603                 if(self.stored_netname != self.netname)
2604                 {
2605                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2606                         strunzone(self.stored_netname);
2607                         self.stored_netname = strzone(self.netname);
2608                 }
2609         }
2610
2611         /*
2612         if(g_race)
2613                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2614         */
2615
2616         CSQCMODEL_AUTOUPDATE();
2617 }