qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest < mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap();
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         if(strlen(plyermodel) < 4)
 345                 return FallbackPlayerModel;
 346         if( substring(plyermodel,0,14) != "models/player/")
 347                 return FallbackPlayerModel;
 348         else if(autocvar_sv_servermodelsonly)
 349         {
 350                 if(substring(plyermodel,-4,4) != ".zym")
 351                 if(substring(plyermodel,-4,4) != ".dpm")
 352                 if(substring(plyermodel,-4,4) != ".iqm")
 353                 if(substring(plyermodel,-4,4) != ".md3")
 354                 if(substring(plyermodel,-4,4) != ".psk")
 355                         return FallbackPlayerModel;
 356                 // forbid the LOD models
 357                 if(substring(plyermodel, -9,5) == "_lod1")
 358                         return FallbackPlayerModel;
 359                 if(substring(plyermodel, -9,5) == "_lod2")
 360                         return FallbackPlayerModel;
 361                 if(plyermodel != strtolower(plyermodel))
 362                         return FallbackPlayerModel;
 363                 if(!fexists(plyermodel))
 364                         return FallbackPlayerModel;
 365         }
 366         return plyermodel;
 367 }
 368
 369 /*
 370 =============
 371 Client_customizeentityforclient
 372
 373 LOD reduction
 374 =============
 375 */
 376 void Client_uncustomizeentityforclient()
 377 {
 378         if(self.modelindex == 0) // no need to uncustomize then
 379                 return;
 380         self.modelindex = self.modelindex_lod0;
 381         self.skin = self.skinindex;
 382 }
 383
 384 float Client_customizeentityforclient()
 385 {
 386         entity modelsource;
 387
 388         if(self.modelindex == 0)
 389                 return TRUE;
 390
 391         // forcemodel stuff
 392
 393 #ifdef PROFILING
 394         float t0;
 395         t0 = gettime(GETTIME_HIRES); // reference
 396 #endif
 397
 398         modelsource = self;
 399
 400 #ifdef ALLOW_FORCEMODELS
 401         if(other.cvar_cl_forceplayermodelsfromxonotic)
 402                 if not(self.modelindex_lod0_from_xonotic)
 403                         modelsource = other;
 404         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 405                 modelsource = other;
 406 #endif
 407
 408         self.skin = modelsource.skinindex;
 409
 410 #if 0
 411         if(modelsource == self)
 412                 self.skin = modelsource.skinindex;
 413         else
 414                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 415 #endif
 416
 417         // self: me
 418         // other: the player viewing me
 419         float distance;
 420         float f;
 421
 422         if(other.cvar_cl_playerdetailreduction <= 0)
 423         {
 424                 if(other.cvar_cl_playerdetailreduction <= -2)
 425                         self.modelindex = modelsource.modelindex_lod2;
 426                 else if(other.cvar_cl_playerdetailreduction <= -1)
 427                         self.modelindex = modelsource.modelindex_lod1;
 428                 else
 429                         self.modelindex = modelsource.modelindex_lod0;
 430         }
 431         else
 432         {
 433                 distance = vlen(self.origin - other.origin);
 434                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 435                 if(f > sv_loddistance2)
 436                         self.modelindex = modelsource.modelindex_lod2;
 437                 else if(f > sv_loddistance1)
 438                         self.modelindex = modelsource.modelindex_lod1;
 439                 else
 440                         self.modelindex = modelsource.modelindex_lod0;
 441         }
 442
 443 #ifdef PROFILING
 444         float t1;
 445         t1 = gettime(GETTIME_HIRES); // reference
 446         client_cefc_accumulator += (t1 - t0);
 447 #endif
 448
 449         return TRUE;
 450 }
 451
 452 void setmodel_lod(entity e, string modelname)
 453 {
 454         string s;
 455
 456         if(sv_loddistance1)
 457         {
 458                 // FIXME: this only supports 3-letter extensions
 459                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 460                 if(fexists(s))
 461                 {
 462                         setmodel(e, s); // players have high precision
 463                         self.modelindex_lod1 = self.modelindex;
 464                 }
 465                 else
 466                         self.modelindex_lod1 = -1;
 467
 468                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 469                 if(fexists(s))
 470                 {
 471                         setmodel(e, s); // players have high precision
 472                         self.modelindex_lod2 = self.modelindex;
 473                 }
 474                 else
 475                         self.modelindex_lod2 = -1;
 476
 477                 precache_model(modelname);
 478                 setmodel(e, modelname); // players have high precision
 479                 self.modelindex_lod0 = self.modelindex;
 480
 481                 if(self.modelindex_lod1 < 0)
 482                         self.modelindex_lod1 = self.modelindex;
 483
 484                 if(self.modelindex_lod2 < 0)
 485                         self.modelindex_lod2 = self.modelindex;
 486         }
 487         else
 488         {
 489                 precache_model(modelname);
 490                 setmodel(e, modelname); // players have high precision
 491                 self.modelindex_lod0 = self.modelindex;
 492                         // save it for possible player model forcing
 493         }
 494
 495         s = whichpack(self.model);
 496         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 497
 498         player_setupanimsformodel();
 499         UpdatePlayerSounds();
 500 }
 501
 502 /*
 503 =============
 504 PutObserverInServer
 505
 506 putting a client as observer in the server
 507 =============
 508 */
 509 void FixPlayermodel();
 510 void PutObserverInServer (void)
 511 {
 512         entity  spot;
 513     self.hud = HUD_NORMAL;
 514         race_PreSpawnObserver();
 515
 516         spot = SelectSpawnPoint (TRUE);
 517         if(!spot)
 518                 error("No spawnpoints for observers?!?\n");
 519         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 520
 521         if(clienttype(self) == CLIENTTYPE_REAL)
 522         {
 523                 msg_entity = self;
 524                 WriteByte(MSG_ONE, SVC_SETVIEW);
 525                 WriteEntity(MSG_ONE, self);
 526         }
 527
 528         DropAllRunes(self);
 529         MUTATOR_CALLHOOK(MakePlayerObserver);
 530
 531         if (g_minstagib)
 532                 minstagib_stop_countdown();
 533
 534         Portal_ClearAll(self);
 535
 536         if(self.alivetime)
 537         {
 538                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 539                 self.alivetime = 0;
 540         }
 541
 542         if(self.vehicle)
 543             vehicles_exit(VHEF_RELESE);
 544
 545         if(self.flagcarried)
 546                 DropFlag(self.flagcarried, world, world);
 547
 548         if(self.ballcarried && g_nexball)
 549                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 550
 551         WaypointSprite_PlayerDead();
 552
 553         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 554                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 555
 556         if(self.killcount != -666) {
 557                 if(g_lms) {
 558                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 559                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 560                         else
 561                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 562                 } else
 563                         bprint ("^4", self.netname, "^4 is spectating now\n");
 564
 565                 if(self.just_joined == FALSE) {
 566                         LogTeamchange(self.playerid, -1, 4);
 567                 } else
 568                         self.just_joined = FALSE;
 569         }
 570
 571         PlayerScore_Clear(self); // clear scores when needed
 572
 573         accuracy_resend(self);
 574
 575         self.spectatortime = time;
 576
 577         self.classname = "observer";
 578         self.iscreature = FALSE;
 579         self.damagedbycontents = FALSE;
 580         self.health = -666;
 581         self.takedamage = DAMAGE_NO;
 582         self.solid = SOLID_NOT;
 583         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 584         self.flags = FL_CLIENT | FL_NOTARGET;
 585         self.armorvalue = 666;
 586         self.effects = 0;
 587         self.armorvalue = autocvar_g_balance_armor_start;
 588         self.pauserotarmor_finished = 0;
 589         self.pauserothealth_finished = 0;
 590         self.pauseregen_finished = 0;
 591         self.damageforcescale = 0;
 592         self.death_time = 0;
 593         self.dead_frame = 0;
 594         self.alpha = 0;
 595         self.scale = 0;
 596         self.fade_time = 0;
 597         self.pain_frame = 0;
 598         self.pain_finished = 0;
 599         self.strength_finished = 0;
 600         self.invincible_finished = 0;
 601         self.pushltime = 0;
 602         self.think = SUB_Null;
 603         self.nextthink = 0;
 604         self.hook_time = 0;
 605         self.runes = 0;
 606         self.deadflag = DEAD_NO;
 607         self.angles = spot.angles;
 608         self.angles_z = 0;
 609         self.fixangle = TRUE;
 610         self.crouch = FALSE;
 611
 612         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 613         setorigin (self, spot.origin);
 614         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 615         self.prevorigin = self.origin;
 616         self.items = 0;
 617         self.weapons = 0;
 618         self.model = "";
 619         FixPlayermodel();
 620         self.model = "";
 621         self.modelindex = 0;
 622         self.weapon = 0;
 623         self.weaponname = "";
 624         self.switchingweapon = 0;
 625         self.weaponmodel = "";
 626         self.weaponentity = world;
 627         self.exteriorweaponentity = world;
 628         self.killcount = -666;
 629         self.velocity = '0 0 0';
 630         self.avelocity = '0 0 0';
 631         self.punchangle = '0 0 0';
 632         self.punchvector = '0 0 0';
 633         self.oldvelocity = self.velocity;
 634         self.fire_endtime = -1;
 635
 636         if(sv_loddistance1)
 637                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 638
 639         if(g_arena)
 640         {
 641                 if(self.version_mismatch)
 642                 {
 643                         Spawnqueue_Unmark(self);
 644                         Spawnqueue_Remove(self);
 645                 }
 646                 else
 647                 {
 648                         Spawnqueue_Insert(self);
 649                 }
 650         }
 651         else if(g_lms)
 652         {
 653                 // Only if the player cannot play at all
 654                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 655                         self.frags = FRAGS_SPECTATOR;
 656                 else
 657                         self.frags = FRAGS_LMS_LOSER;
 658         }
 659         else if(g_ca)
 660         {
 661                 if(self.caplayer)
 662                         self.frags = FRAGS_LMS_LOSER;
 663                 else
 664                         self.frags = FRAGS_SPECTATOR;
 665         }
 666         else
 667                 self.frags = FRAGS_SPECTATOR;
 668 }
 669
 670 .float model_randomizer;
 671 void FixPlayermodel()
 672 {
 673         string defaultmodel;
 674         float defaultskin, chmdl, oldskin, n, i;
 675         vector m1, m2;
 676
 677         defaultmodel = "";
 678
 679         if(autocvar_sv_defaultcharacter == 1)
 680         {
 681                 defaultskin = 0;
 682
 683                 if(teamplay)
 684                 {
 685                         string s;
 686                         s = Team_ColorNameLowerCase(self.team);
 687                         if(s != "neutral")
 688                         {
 689                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 690                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 691                         }
 692                 }
 693
 694                 if(defaultmodel == "")
 695                 {
 696                         defaultmodel = autocvar_sv_defaultplayermodel;
 697                         defaultskin = autocvar_sv_defaultplayerskin;
 698                 }
 699
 700                 n = tokenize_console(defaultmodel);
 701                 if(n > 0)
 702                         defaultmodel = argv(floor(n * self.model_randomizer));
 703
 704                 i = strstrofs(defaultmodel, ":", 0);
 705                 if(i >= 0)
 706                 {
 707                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 708                         defaultmodel = substring(defaultmodel, 0, i);
 709                 }
 710         }
 711
 712         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 713         {
 714                 if(self.model != "")
 715                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 716                 self.model = ""; // force the != checks to return true
 717         }
 718
 719         if(defaultmodel != "")
 720         {
 721                 if (defaultmodel != self.model)
 722                 {
 723                         m1 = self.mins;
 724                         m2 = self.maxs;
 725                         setmodel_lod (self, defaultmodel);
 726                         setsize (self, m1, m2);
 727                         chmdl = TRUE;
 728                 }
 729
 730                 oldskin = self.skinindex;
 731                 self.skinindex = defaultskin;
 732         } else {
 733                 if (self.playermodel != self.model || self.playermodel == "")
 734                 {
 735                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 736                         m1 = self.mins;
 737                         m2 = self.maxs;
 738                         setmodel_lod (self, self.playermodel);
 739                         setsize (self, m1, m2);
 740                         chmdl = TRUE;
 741                 }
 742
 743                 oldskin = self.skinindex;
 744                 self.skinindex = stof(self.playerskin);
 745         }
 746
 747         if(chmdl || oldskin != self.skinindex)
 748                 self.species = player_getspecies(); // model or skin has changed
 749
 750         if(!teamplay)
 751                 if(strlen(autocvar_sv_defaultplayercolors))
 752                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 753                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 754 }
 755
 756 void PlayerTouchExplode(entity p1, entity p2)
 757 {
 758         vector org;
 759         org = (p1.origin + p2.origin) * 0.5;
 760         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 761
 762         te_explosion(org);
 763
 764         entity e;
 765         e = spawn();
 766         setorigin(e, org);
 767         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 768         remove(e);
 769 }
 770
 771 /*
 772 =============
 773 PutClientInServer
 774
 775 Called when a client spawns in the server
 776 =============
 777 */
 778 //void() ctf_playerchanged;
 779 void PutClientInServer (void)
 780 {
 781         if(clienttype(self) == CLIENTTYPE_BOT)
 782         {
 783                 self.classname = "player";
 784         }
 785         else if(clienttype(self) == CLIENTTYPE_REAL)
 786         {
 787                 msg_entity = self;
 788                 WriteByte(MSG_ONE, SVC_SETVIEW);
 789                 WriteEntity(MSG_ONE, self);
 790         }
 791
 792         // reset player keys
 793         self.itemkeys = 0;
 794
 795         // player is dead and becomes observer
 796         // FIXME fix LMS scoring for new system
 797         if(g_lms)
 798         {
 799                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 800                         self.classname = "observer";
 801         }
 802
 803         if(g_arena || (g_ca && !allowed_to_spawn))
 804         if(!self.spawned)
 805                 self.classname = "observer";
 806
 807         if(gameover)
 808                 self.classname = "observer";
 809
 810         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 811                 entity spot, oldself;
 812                 float j;
 813
 814                 accuracy_resend(self);
 815
 816                 if(self.team < 0)
 817                         JoinBestTeam(self, FALSE, TRUE);
 818
 819                 race_PreSpawn();
 820
 821                 spot = SelectSpawnPoint (FALSE);
 822                 if(!spot)
 823                 {
 824                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 825                         return; // spawn failed
 826                 }
 827
 828                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 829
 830                 self.classname = "player";
 831                 self.wasplayer = TRUE;
 832                 self.iscreature = TRUE;
 833                 self.damagedbycontents = TRUE;
 834                 self.movetype = MOVETYPE_WALK;
 835                 self.solid = SOLID_SLIDEBOX;
 836                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 837                 if(autocvar_g_playerclip_collisions)
 838                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 839                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 840                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 841                 self.frags = FRAGS_PLAYER;
 842                 if(INDEPENDENT_PLAYERS)
 843                         MAKE_INDEPENDENT_PLAYER(self);
 844                 self.flags = FL_CLIENT;
 845                 if(autocvar__notarget)
 846                         self.flags |= FL_NOTARGET;
 847                 self.takedamage = DAMAGE_AIM;
 848                 if(g_minstagib)
 849                         self.effects = EF_FULLBRIGHT;
 850                 else
 851                         self.effects = 0;
 852                 self.air_finished = time + 12;
 853                 self.dmg = 2;
 854                 if(autocvar_g_balance_nex_charge)
 855                 {
 856                         if(autocvar_g_balance_nex_secondary_chargepool)
 857                                 self.nex_chargepool_ammo = 1;
 858                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 859                 }
 860
 861                 if(inWarmupStage)
 862                 {
 863                         self.ammo_shells = warmup_start_ammo_shells;
 864                         self.ammo_nails = warmup_start_ammo_nails;
 865                         self.ammo_rockets = warmup_start_ammo_rockets;
 866                         self.ammo_cells = warmup_start_ammo_cells;
 867                         self.ammo_fuel = warmup_start_ammo_fuel;
 868                         self.health = warmup_start_health;
 869                         self.armorvalue = warmup_start_armorvalue;
 870                         self.weapons = warmup_start_weapons;
 871                 }
 872                 else
 873                 {
 874                         self.ammo_shells = start_ammo_shells;
 875                         self.ammo_nails = start_ammo_nails;
 876                         self.ammo_rockets = start_ammo_rockets;
 877                         self.ammo_cells = start_ammo_cells;
 878                         self.ammo_fuel = start_ammo_fuel;
 879                         self.health = start_health;
 880                         self.armorvalue = start_armorvalue;
 881                         self.weapons = start_weapons;
 882                 }
 883
 884                 if(g_weaponarena_random)
 885                 {
 886                         if(g_weaponarena_random_with_laser)
 887                                 self.weapons &~= WEPBIT_LASER;
 888                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 889                         if(g_weaponarena_random_with_laser)
 890                                 self.weapons |= WEPBIT_LASER;
 891                 }
 892
 893                 self.items = start_items;
 894                 self.jump_interval = time;
 895
 896                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 897                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 898                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 899                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 900                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 901                 //extend the pause of rotting if client was reset at the beginning of the countdown
 902                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 903                         self.spawnshieldtime += game_starttime - time;
 904                         self.pauserotarmor_finished += game_starttime - time;
 905                         self.pauserothealth_finished += game_starttime - time;
 906                         self.pauseregen_finished += game_starttime - time;
 907                 }
 908                 self.damageforcescale = 2;
 909                 self.death_time = 0;
 910                 self.dead_frame = 0;
 911                 self.alpha = 0;
 912                 self.scale = 0;
 913                 self.fade_time = 0;
 914                 self.pain_frame = 0;
 915                 self.pain_finished = 0;
 916                 self.strength_finished = 0;
 917                 self.invincible_finished = 0;
 918                 self.pushltime = 0;
 919                 // players have no think function
 920                 self.think = SUB_Null;
 921                 self.nextthink = 0;
 922                 self.hook_time = 0;
 923                 self.dmg_team = 0;
 924                 self.ballistics_density = autocvar_g_ballistics_density_player;
 925
 926                 self.metertime = 0;
 927
 928                 self.runes = 0;
 929
 930                 self.deadflag = DEAD_NO;
 931
 932                 self.angles = spot.angles;
 933
 934                 self.angles_z = 0; // never spawn tilted even if the spot says to
 935                 self.fixangle = TRUE; // turn this way immediately
 936                 self.velocity = '0 0 0';
 937                 self.avelocity = '0 0 0';
 938                 self.punchangle = '0 0 0';
 939                 self.punchvector = '0 0 0';
 940                 self.oldvelocity = self.velocity;
 941                 self.fire_endtime = -1;
 942
 943                 msg_entity = self;
 944                 WRITESPECTATABLE_MSG_ONE({
 945                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 946                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 947                 });
 948
 949                 if(sv_loddistance1)
 950                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 951
 952                 self.model = "";
 953                 FixPlayermodel();
 954
 955                 self.crouch = FALSE;
 956                 self.view_ofs = PL_VIEW_OFS;
 957                 setsize (self, PL_MIN, PL_MAX);
 958                 self.spawnorigin = spot.origin;
 959                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 960                 // don't reset back to last position, even if new position is stuck in solid
 961                 self.oldorigin = self.origin;
 962                 self.prevorigin = self.origin;
 963                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 964                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 965         self.hud = HUD_NORMAL;
 966
 967                 if(g_arena)
 968                 {
 969                         Spawnqueue_Remove(self);
 970                         Spawnqueue_Mark(self);
 971                 }
 972
 973                 else if(g_ca)
 974                         self.caplayer = 1;
 975
 976                 self.event_damage = PlayerDamage;
 977
 978                 self.bot_attack = TRUE;
 979
 980                 self.statdraintime = time + 5;
 981                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 982
 983                 if(self.killcount == -666) {
 984                         PlayerScore_Clear(self);
 985                         self.killcount = 0;
 986                 }
 987
 988                 CL_SpawnWeaponentity();
 989                 self.alpha = default_player_alpha;
 990                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 991                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 992
 993                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 994                 self.lms_traveled_distance = 0;
 995                 self.speedrunning = FALSE;
 996
 997                 race_PostSpawn(spot);
 998
 999                 //stuffcmd(self, "chase_active 0");
1000                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1001
1002                 if (autocvar_g_spawnsound)
1003                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1004
1005                 if(g_assault) {
1006                         if(self.team == assault_attacker_team)
1007                                 centerprint(self, "You are attacking!");
1008                         else
1009                                 centerprint(self, "You are defending!");
1010                 }
1011
1012                 target_voicescript_clear(self);
1013
1014                 // reset fields the weapons may use
1015                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1016                 {
1017                         weapon_action(j, WR_RESETPLAYER);
1018
1019                         // all weapons must be fully loaded when we spawn
1020                         entity e;
1021                         e = get_weaponinfo(j);
1022                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1023                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1024                 }
1025
1026                 oldself = self;
1027                 self = spot;
1028                         activator = oldself;
1029                                 string s;
1030                                 s = self.target;
1031                                 self.target = string_null;
1032                                 SUB_UseTargets();
1033                                 self.target = s;
1034                         activator = world;
1035                 self = oldself;
1036
1037                 spawn_spot = spot;
1038                 MUTATOR_CALLHOOK(PlayerSpawn);
1039
1040                 if(autocvar_spawn_debug)
1041                 {
1042                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1043                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1044                 }
1045
1046                 self.switchweapon = w_getbestweapon(self);
1047                 self.cnt = -1; // W_LastWeapon will not complain
1048                 self.weapon = 0;
1049                 self.weaponname = "";
1050                 self.switchingweapon = 0;
1051
1052                 if(!self.alivetime)
1053                         self.alivetime = time;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 .float ebouncefactor, ebouncestop; // electro's values
1063 // TODO do we need all these fields, or should we stop autodetecting runtime
1064 // changes and just have a console command to update this?
1065 float ClientInit_SendEntity(entity to, float sf)
1066 {
1067         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1068         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1069         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1070         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1071         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1072         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1073         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1074         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1075         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1081         if(sv_foginterval && world.fog != "")
1082                 WriteString(MSG_ENTITY, world.fog);
1083         else
1084                 WriteString(MSG_ENTITY, "");
1085         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1086         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1087         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1088         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1089         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1090         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1091         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1092         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1093         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1094         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1095         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1096         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1097         return TRUE;
1098 }
1099
1100 void ClientInit_CheckUpdate()
1101 {
1102         self.nextthink = time;
1103         if(self.count != autocvar_g_balance_armor_blockpercent)
1104         {
1105                 self.count = autocvar_g_balance_armor_blockpercent;
1106                 self.SendFlags |= 1;
1107         }
1108         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1109         {
1110                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1111                 self.SendFlags |= 1;
1112         }
1113         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1114         {
1115                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1116                 self.SendFlags |= 1;
1117         }
1118         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1119         {
1120                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1121                 self.SendFlags |= 1;
1122         }
1123         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1124         {
1125                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1126                 self.SendFlags |= 1;
1127         }
1128         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1129         {
1130                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1131                 self.SendFlags |= 1;
1132         }
1133 }
1134
1135 void ClientInit_Spawn()
1136 {
1137         entity o;
1138         entity e;
1139         e = spawn();
1140         e.classname = "clientinit";
1141         e.think = ClientInit_CheckUpdate;
1142         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1143
1144         o = self;
1145         self = e;
1146         ClientInit_CheckUpdate();
1147         self = o;
1148 }
1149
1150 /*
1151 =============
1152 SetNewParms
1153 =============
1154 */
1155 void SetNewParms (void)
1156 {
1157         // initialize parms for a new player
1158         parm1 = -(86400 * 366);
1159 }
1160
1161 /*
1162 =============
1163 SetChangeParms
1164 =============
1165 */
1166 void SetChangeParms (void)
1167 {
1168         // save parms for level change
1169         parm1 = self.parm_idlesince - time;
1170 }
1171
1172 /*
1173 =============
1174 DecodeLevelParms
1175 =============
1176 */
1177 void DecodeLevelParms (void)
1178 {
1179         // load parms
1180         self.parm_idlesince = parm1;
1181         if(self.parm_idlesince == -(86400 * 366))
1182                 self.parm_idlesince = time;
1183
1184         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1185         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1186 }
1187
1188 /*
1189 =============
1190 ClientKill
1191
1192 Called when a client types 'kill' in the console
1193 =============
1194 */
1195
1196 .float clientkill_nexttime;
1197 void ClientKill_Now_TeamChange()
1198 {
1199         if(self.killindicator_teamchange == -1)
1200         {
1201                 self.team = -1;
1202                 JoinBestTeam( self, FALSE, FALSE );
1203         }
1204         else if(self.killindicator_teamchange == -2)
1205         {
1206                 if(g_ca)
1207                         self.caplayer = 0;
1208                 if(blockSpectators)
1209                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1210                 PutObserverInServer();
1211         }
1212         else
1213                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1214 }
1215
1216 void ClientKill_Now()
1217 {
1218         if(self.vehicle)
1219         {
1220             vehicles_exit(VHEF_RELESE);
1221             if(!self.killindicator_teamchange)
1222             {
1223             self.vehicle_health = -1;
1224             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1225             }
1226         }
1227
1228         if(self.killindicator && !wasfreed(self.killindicator))
1229                 remove(self.killindicator);
1230
1231         self.killindicator = world;
1232
1233         if(self.killindicator_teamchange)
1234                 ClientKill_Now_TeamChange();
1235
1236         // in any case:
1237         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1238
1239         // now I am sure the player IS dead
1240 }
1241 void KillIndicator_Think()
1242 {
1243         if (gameover)
1244         {
1245                 self.owner.killindicator = world;
1246                 remove(self);
1247                 return;
1248         }
1249
1250         if (!self.owner.modelindex)
1251         {
1252                 self.owner.killindicator = world;
1253                 remove(self);
1254                 return;
1255         }
1256
1257         if(self.cnt <= 0)
1258         {
1259                 self = self.owner;
1260                 ClientKill_Now(); // no oldself needed
1261                 return;
1262         }
1263     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1264     {
1265         self.nextthink = time + 1;
1266         self.cnt -= 1;
1267     }
1268         else
1269         {
1270                 if(self.cnt <= 10)
1271                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1272                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1273                 {
1274                         if(self.cnt <= 10)
1275                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1276                 }
1277                 self.nextthink = time + 1;
1278                 self.cnt -= 1;
1279         }
1280 }
1281
1282 float clientkilltime;
1283 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1284 {
1285         float killtime;
1286         float starttime;
1287         entity e;
1288
1289         if (gameover)
1290                 return;
1291
1292         killtime = autocvar_g_balance_kill_delay;
1293
1294         if(g_race_qualifying || g_cts)
1295                 killtime = 0;
1296
1297     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1298     {
1299                 remove(self.killindicator);
1300                 self.killindicator = world;
1301
1302         ClientKill_Now(); // allow instant kill in this case
1303         return;
1304     }
1305
1306         self.killindicator_teamchange = targetteam;
1307
1308     if(!self.killindicator)
1309         {
1310                 if(self.modelindex && self.deadflag == DEAD_NO)
1311                 {
1312                         killtime = max(killtime, self.clientkill_nexttime - time);
1313                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1314                 }
1315
1316                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1317                 {
1318                         ClientKill_Now();
1319                 }
1320                 else
1321                 {
1322                         starttime = max(time, clientkilltime);
1323
1324                         self.killindicator = spawn();
1325                         self.killindicator.owner = self;
1326                         self.killindicator.scale = 0.5;
1327                         setattachment(self.killindicator, self, "");
1328                         setorigin(self.killindicator, '0 0 52');
1329                         self.killindicator.think = KillIndicator_Think;
1330                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1331                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1332                         self.killindicator.cnt = ceil(killtime);
1333                         self.killindicator.count = bound(0, ceil(killtime), 10);
1334                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1335
1336                         for(e = world; (e = find(e, classname, "body")) != world; )
1337                         {
1338                                 if(e.enemy != self)
1339                                         continue;
1340                                 e.killindicator = spawn();
1341                                 e.killindicator.owner = e;
1342                                 e.killindicator.scale = 0.5;
1343                                 setattachment(e.killindicator, e, "");
1344                                 setorigin(e.killindicator, '0 0 52');
1345                                 e.killindicator.think = KillIndicator_Think;
1346                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1347                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1348                                 e.killindicator.cnt = ceil(killtime);
1349                         }
1350                         self.lip = 0;
1351                 }
1352         }
1353         if(self.killindicator)
1354         {
1355                 if(targetteam == 0) // just die
1356                 {
1357                         self.killindicator.colormod = '0 0 0';
1358                         if(clienttype(self) == CLIENTTYPE_REAL)
1359                         if(self.killindicator.cnt > 0)
1360                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1361                 }
1362                 else if(targetteam == -1) // auto
1363                 {
1364                         self.killindicator.colormod = '0 1 0';
1365                         if(clienttype(self) == CLIENTTYPE_REAL)
1366                         if(self.killindicator.cnt > 0)
1367                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1368                 }
1369                 else if(targetteam == -2) // spectate
1370                 {
1371                         self.killindicator.colormod = '0.5 0.5 0.5';
1372                         if(clienttype(self) == CLIENTTYPE_REAL)
1373                         if(self.killindicator.cnt > 0)
1374                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1375                 }
1376                 else
1377                 {
1378                         self.killindicator.colormod = TeamColor(targetteam);
1379                         if(clienttype(self) == CLIENTTYPE_REAL)
1380                         if(self.killindicator.cnt > 0)
1381                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1382                 }
1383         }
1384
1385 }
1386
1387 void ClientKill (void)
1388 {
1389         if (gameover)
1390                 return;
1391
1392         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1393         {
1394                 // do nothing
1395         }
1396     else if(self.freezetag_frozen)
1397     {
1398         // do nothing
1399     }
1400         else
1401                 ClientKill_TeamChange(0);
1402 }
1403
1404 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1405 {
1406     e.killindicator = spawn();
1407     e.killindicator.owner = e;
1408     e.killindicator.think = KillIndicator_Think;
1409     e.killindicator.nextthink = time + (e.lip) * 0.05;
1410     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1411     e.killindicator.health = 1; // this is used to indicate that it should be silent
1412     e.lip = 0;
1413 }
1414
1415 void FixClientCvars(entity e)
1416 {
1417         // send prediction settings to the client
1418         stuffcmd(e, "\nin_bindmap 0 0\n");
1419         if(g_race || g_cts)
1420                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1421         if(autocvar_g_antilag == 3) // client side hitscan
1422                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1423         if(sv_gentle)
1424                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1425         /*
1426          * we no longer need to stuff this. Remove this comment block if you feel
1427          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1428         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1429         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1430         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1431         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1432         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1433         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1434         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1435         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1436         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1437         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1438         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1439         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1440         stuffcmd(e, "cl_movement_edgefriction 1\n");
1441          */
1442 }
1443
1444 float PlayerInIDList(entity p, string idlist)
1445 {
1446         float n, i;
1447         string s;
1448
1449         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1450         if not(p.crypto_idfp)
1451                 return 0;
1452
1453         // this function allows abbreviated player IDs too!
1454         n = tokenize_console(idlist);
1455         for(i = 0; i < n; ++i)
1456         {
1457                 s = argv(i);
1458                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1459                         return 1;
1460         }
1461
1462         return 0;
1463 }
1464
1465 /*
1466 =============
1467 ClientConnect
1468
1469 Called when a client connects to the server
1470 =============
1471 */
1472 //void ctf_clientconnect();
1473 string ColoredTeamName(float t);
1474 void DecodeLevelParms (void);
1475 //void dom_player_join_team(entity pl);
1476 void set_dom_state(entity e);
1477 void ClientConnect (void)
1478 {
1479         float t;
1480
1481         if(self.flags & FL_CLIENT)
1482         {
1483                 print("Warning: ClientConnect, but already connected!\n");
1484                 return;
1485         }
1486
1487         if(Ban_MaybeEnforceBan(self))
1488                 return;
1489
1490         DecodeLevelParms();
1491
1492 #ifdef WATERMARK
1493         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1494 #endif
1495
1496         self.classname = "player_joining";
1497
1498         self.flags = FL_CLIENT;
1499         self.version_nagtime = time + 10 + random() * 10;
1500
1501         if(player_count<0)
1502         {
1503                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1504                 player_count = 0;
1505         }
1506
1507         PlayerScore_Attach(self);
1508         ClientData_Attach();
1509         accuracy_init(self);
1510
1511         bot_clientconnect();
1512
1513         playerdemo_init();
1514
1515         anticheat_init();
1516
1517         race_PreSpawnObserver();
1518
1519         //if(g_domination)
1520         //      dom_player_join_team(self);
1521
1522         // identify the right forced team
1523         if(autocvar_g_campaign)
1524         {
1525                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1526                 {
1527                         switch(autocvar_g_campaign_forceteam)
1528                         {
1529                                 case 1: self.team_forced = COLOR_TEAM1; break;
1530                                 case 2: self.team_forced = COLOR_TEAM2; break;
1531                                 case 3: self.team_forced = COLOR_TEAM3; break;
1532                                 case 4: self.team_forced = COLOR_TEAM4; break;
1533                                 default: self.team_forced = 0;
1534                         }
1535                 }
1536         }
1537         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1538                 self.team_forced = COLOR_TEAM1;
1539         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1540                 self.team_forced = COLOR_TEAM2;
1541         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1542                 self.team_forced = COLOR_TEAM3;
1543         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1544                 self.team_forced = COLOR_TEAM4;
1545         else if(autocvar_g_forced_team_otherwise == "red")
1546                 self.team_forced = COLOR_TEAM1;
1547         else if(autocvar_g_forced_team_otherwise == "blue")
1548                 self.team_forced = COLOR_TEAM2;
1549         else if(autocvar_g_forced_team_otherwise == "yellow")
1550                 self.team_forced = COLOR_TEAM3;
1551         else if(autocvar_g_forced_team_otherwise == "pink")
1552                 self.team_forced = COLOR_TEAM4;
1553         else if(autocvar_g_forced_team_otherwise == "spectate")
1554                 self.team_forced = -1;
1555         else if(autocvar_g_forced_team_otherwise == "spectator")
1556                 self.team_forced = -1;
1557         else
1558                 self.team_forced = 0;
1559
1560         if(!teamplay)
1561                 if(self.team_forced > 0)
1562                         self.team_forced = 0;
1563
1564         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1565
1566         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1567                 self.classname = "observer";
1568         } else {
1569                 if(teamplay)
1570                 {
1571                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1572                         {
1573                                 self.classname = "player";
1574                                 campaign_bots_may_start = 1;
1575                         }
1576                         else
1577                         {
1578                                 self.classname = "observer"; // do it anyway
1579                         }
1580                 }
1581                 else
1582                 {
1583                         self.classname = "player";
1584                         campaign_bots_may_start = 1;
1585                 }
1586         }
1587
1588         self.playerid = (playerid_last = playerid_last + 1);
1589
1590         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1591
1592     if(clienttype(self) == CLIENTTYPE_BOT)
1593         PlayerStats_AddPlayer(self);
1594
1595         if(autocvar_sv_eventlog)
1596                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1597
1598         LogTeamchange(self.playerid, self.team, 1);
1599
1600         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1601
1602         self.netname_previous = strzone(self.netname);
1603
1604         bprint("^4", self.netname, "^4 connected");
1605
1606         if(self.classname != "observer" && (g_domination || g_ctf))
1607                 bprint(" and joined the ", ColoredTeamName(self.team));
1608
1609         bprint("\n");
1610
1611         stuffcmd(self, strcat(clientstuff, "\n"));
1612         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1613
1614         FixClientCvars(self);
1615
1616         // spawnfunc_waypoint sprites
1617         WaypointSprite_InitClient(self);
1618
1619         // Wazat's grappling hook
1620         SetGrappleHookBindings();
1621
1622         // get version info from player
1623         stuffcmd(self, "cmd clientversion $gameversion\n");
1624
1625         // get other cvars from player
1626         GetCvars(0);
1627
1628         // notify about available teams
1629         if(teamplay)
1630         {
1631                 CheckAllowedTeams(self);
1632                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1633                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1634         }
1635         else
1636                 stuffcmd(self, "set _teams_available 0\n");
1637
1638         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1639
1640         if(g_arena || g_ca)
1641         {
1642                 self.classname = "observer";
1643                 if(g_arena)
1644                         Spawnqueue_Insert(self);
1645         }
1646         /*else if(g_ctf)
1647         {
1648                 ctf_clientconnect();
1649         }*/
1650
1651         attach_entcs();
1652
1653         bot_relinkplayerlist();
1654
1655         self.spectatortime = time;
1656         if(blockSpectators)
1657         {
1658                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1659         }
1660
1661         self.jointime = time;
1662         self.allowedTimeouts = autocvar_sv_timeout_number;
1663
1664         if(clienttype(self) == CLIENTTYPE_REAL)
1665         {
1666                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1667                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1668         }
1669
1670         if(g_lms)
1671         {
1672                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1673                 {
1674                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1675                         self.frags = FRAGS_SPECTATOR;
1676                 }
1677         }
1678
1679         if(!sv_foginterval && world.fog != "")
1680                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1681
1682         SoundEntity_Attach(self);
1683
1684         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1685         {
1686                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1687                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1688         }
1689         else
1690                 self.hitplotfh = -1;
1691
1692         if(g_race || g_cts) {
1693                 string rr;
1694                 if(g_cts)
1695                         rr = CTS_RECORD;
1696                 else
1697                         rr = RACE_RECORD;
1698                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1699
1700                 msg_entity = self;
1701                 race_send_recordtime(MSG_ONE);
1702                 race_send_speedaward(MSG_ONE);
1703
1704                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1705                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1706                 race_send_speedaward_alltimebest(MSG_ONE);
1707
1708                 float i;
1709                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1710                         race_SendRankings(i, 0, 0, MSG_ONE);
1711                 }
1712         }
1713         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1714                 send_CSQC_teamnagger();
1715
1716         if (g_domination)
1717                 set_dom_state(self);
1718
1719         CheatInitClient();
1720
1721         if(!autocvar_g_campaign)
1722                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1723
1724         self.model_randomizer = random();
1725 }
1726
1727 /*
1728 =============
1729 ClientDisconnect
1730
1731 Called when a client disconnects from the server
1732 =============
1733 */
1734 .entity chatbubbleentity;
1735 void ReadyCount();
1736 void ClientDisconnect (void)
1737 {
1738         if(self.vehicle)
1739             vehicles_exit(VHEF_RELESE);
1740
1741         if not(self.flags & FL_CLIENT)
1742         {
1743                 print("Warning: ClientDisconnect without ClientConnect\n");
1744                 return;
1745         }
1746
1747         PlayerStats_AddGlobalInfo(self);
1748
1749         CheatShutdownClient();
1750
1751         if(self.hitplotfh >= 0)
1752         {
1753                 fclose(self.hitplotfh);
1754                 self.hitplotfh = -1;
1755         }
1756
1757         anticheat_report();
1758         anticheat_shutdown();
1759
1760         playerdemo_shutdown();
1761
1762         bot_clientdisconnect();
1763
1764         if(self.entcs)
1765                 detach_entcs();
1766
1767         if(autocvar_sv_eventlog)
1768                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1769         bprint ("^4",self.netname);
1770         bprint ("^4 disconnected\n");
1771
1772         SoundEntity_Detach(self);
1773
1774         DropAllRunes(self);
1775         MUTATOR_CALLHOOK(ClientDisconnect);
1776
1777         Portal_ClearAll(self);
1778
1779         RemoveGrapplingHook(self);
1780         if(self.flagcarried)
1781                 DropFlag(self.flagcarried, world, world);
1782         if(self.ballcarried && g_nexball)
1783                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1784
1785         // Here, everything has been done that requires this player to be a client.
1786
1787         self.flags &~= FL_CLIENT;
1788
1789         if (self.chatbubbleentity)
1790                 remove (self.chatbubbleentity);
1791
1792         if (self.killindicator)
1793                 remove (self.killindicator);
1794
1795         WaypointSprite_PlayerGone();
1796
1797         bot_relinkplayerlist();
1798
1799         if(g_arena)
1800         {
1801                 Spawnqueue_Unmark(self);
1802                 Spawnqueue_Remove(self);
1803         }
1804
1805         accuracy_free(self);
1806         ClientData_Detach();
1807         PlayerScore_Detach(self);
1808
1809         if(self.netname_previous)
1810                 strunzone(self.netname_previous);
1811         if(self.clientstatus)
1812                 strunzone(self.clientstatus);
1813         if(self.weaponorder_byimpulse)
1814                 strunzone(self.weaponorder_byimpulse);
1815
1816         ClearPlayerSounds();
1817
1818         if(self.personal)
1819                 remove(self.personal);
1820
1821         self.playerid = 0;
1822         ReadyCount();
1823
1824         // free cvars
1825         GetCvars(-1);
1826 }
1827
1828 .float BUTTON_CHAT;
1829 void ChatBubbleThink()
1830 {
1831         self.nextthink = time;
1832         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1833         {
1834                 if(self.owner) // but why can that ever be world?
1835                         self.owner.chatbubbleentity = world;
1836                 remove(self);
1837                 return;
1838         }
1839         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1840 #ifdef TETRIS
1841                 || self.owner.tetris_on
1842 #endif
1843         )
1844                 self.model = self.mdl;
1845         else
1846                 self.model = "";
1847 }
1848
1849 void UpdateChatBubble()
1850 {
1851         if (!self.modelindex)
1852                 return;
1853         // spawn a chatbubble entity if needed
1854         if (!self.chatbubbleentity)
1855         {
1856                 self.chatbubbleentity = spawn();
1857                 self.chatbubbleentity.owner = self;
1858                 self.chatbubbleentity.exteriormodeltoclient = self;
1859                 self.chatbubbleentity.think = ChatBubbleThink;
1860                 self.chatbubbleentity.nextthink = time;
1861                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1862                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1863                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1864                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1865                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1866                 self.chatbubbleentity.model = "";
1867                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1868         }
1869 }
1870
1871
1872 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1873 // added to the model skins
1874 /*void UpdateColorModHack()
1875 {
1876         float c;
1877         c = self.clientcolors & 15;
1878         // LordHavoc: only bothering to support white, green, red, yellow, blue
1879              if (!teamplay) self.colormod = '0 0 0';
1880         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1881         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1882         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1883         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1884         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1885         else self.colormod = '1 1 1';
1886 }*/
1887
1888 .float oldcolormap;
1889 void respawn(void)
1890 {
1891         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1892         {
1893                 self.solid = SOLID_NOT;
1894                 self.takedamage = DAMAGE_NO;
1895                 self.movetype = MOVETYPE_FLY;
1896                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1897                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1898                 self.effects |= EF_ADDITIVE;
1899                 self.oldcolormap = self.colormap;
1900                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1901                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1902                 if(autocvar_g_respawn_ghosts_maxtime)
1903                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1904         }
1905
1906         CopyBody(1);
1907         self.effects |= EF_NODRAW; // prevent another CopyBody
1908         if(self.oldcolormap)
1909         {
1910                 self.colormap = self.oldcolormap;
1911                 self.oldcolormap = 0;
1912         }
1913         PutClientInServer();
1914 }
1915
1916 void play_countdown(float finished, string samp)
1917 {
1918         if(clienttype(self) == CLIENTTYPE_REAL)
1919                 if(floor(finished - time - frametime) != floor(finished - time))
1920                         if(finished - time < 6)
1921                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1922 }
1923
1924 void player_powerups (void)
1925 {
1926         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1927         olditems = self.items;
1928
1929         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1930         {
1931                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1932                 self.modelflags |= MF_ROCKET;
1933         }
1934         else
1935         {
1936                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1937                 self.modelflags &~= MF_ROCKET;
1938         }
1939
1940         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1941
1942         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1943                 return;
1944
1945         Fire_ApplyDamage(self);
1946         Fire_ApplyEffect(self);
1947
1948         if (g_minstagib)
1949         {
1950                 self.effects |= EF_FULLBRIGHT;
1951
1952                 if (self.items & IT_STRENGTH)
1953                 {
1954                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1955                         if (time > self.strength_finished)
1956                         {
1957                                 self.alpha = default_player_alpha;
1958                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1959                                 self.items &~= IT_STRENGTH;
1960                                 sprint(self, "^3Invisibility has worn off\n");
1961                         }
1962                 }
1963                 else
1964                 {
1965                         if (time < self.strength_finished)
1966                         {
1967                                 self.alpha = g_minstagib_invis_alpha;
1968                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1969                                 self.items |= IT_STRENGTH;
1970                                 sprint(self, "^3You are invisible\n");
1971                         }
1972                 }
1973
1974                 if (self.items & IT_INVINCIBLE)
1975                 {
1976                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1977                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
1978                         {
1979                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1980                                 sprint(self, "^3Speed has worn off\n");
1981                         }
1982                 }
1983                 else
1984                 {
1985                         if (time < self.invincible_finished)
1986                         {
1987                                 self.items = self.items | IT_INVINCIBLE;
1988                                 sprint(self, "^3You are on speed\n");
1989                         }
1990                 }
1991         }
1992         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1993         {
1994                 if (self.items & IT_STRENGTH)
1995                 {
1996                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1997                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1998                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
1999                         {
2000                                 self.items = self.items - (self.items & IT_STRENGTH);
2001                                 sprint(self, "^3Strength has worn off\n");
2002                         }
2003                 }
2004                 else
2005                 {
2006                         if (time < self.strength_finished)
2007                         {
2008                                 self.items = self.items | IT_STRENGTH;
2009                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2010                         }
2011                 }
2012                 if (self.items & IT_INVINCIBLE)
2013                 {
2014                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2015                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2016                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2017                         {
2018                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2019                                 sprint(self, "^3Shield has worn off\n");
2020                         }
2021                 }
2022                 else
2023                 {
2024                         if (time < self.invincible_finished)
2025                         {
2026                                 self.items = self.items | IT_INVINCIBLE;
2027                                 sprint(self, "^3Shield surrounds you\n");
2028                         }
2029                 }
2030
2031                 if(autocvar_g_nodepthtestplayers)
2032                         self.effects = self.effects | EF_NODEPTHTEST;
2033
2034                 if(autocvar_g_fullbrightplayers)
2035                         self.effects = self.effects | EF_FULLBRIGHT;
2036
2037                 // midair gamemode: damage only while in the air
2038                 // if in midair mode, being on ground grants temporary invulnerability
2039                 // (this is so that multishot weapon don't clear the ground flag on the
2040                 // first damage in the frame, leaving the player vulnerable to the
2041                 // remaining hits in the same frame)
2042                 if (self.flags & FL_ONGROUND)
2043                 if (g_midair)
2044                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2045
2046                 if (time >= game_starttime)
2047                 if (time < self.spawnshieldtime)
2048                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2049         }
2050
2051         MUTATOR_CALLHOOK(PlayerPowerups);
2052 }
2053
2054 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2055 {
2056         if(current > stable)
2057                 return current;
2058         else if(current > stable - 0.25) // when close enough, "snap"
2059                 return stable;
2060         else
2061                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2062 }
2063
2064 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2065 {
2066         if(current < stable)
2067                 return current;
2068         else if(current < stable + 0.25) // when close enough, "snap"
2069                 return stable;
2070         else
2071                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2072 }
2073
2074 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2075 {
2076         if(current > rotstable)
2077         {
2078                 if(rotframetime > 0)
2079                 {
2080                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2081                         current = max(rotstable, current - rotlinear * rotframetime);
2082                 }
2083         }
2084         else if(current < regenstable)
2085         {
2086                 if(regenframetime > 0)
2087                 {
2088                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2089                         current = min(regenstable, current + regenlinear * regenframetime);
2090                 }
2091         }
2092
2093         if(current > limit)
2094                 current = limit;
2095
2096         return current;
2097 }
2098
2099 void player_regen (void)
2100 {
2101         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2102         maxh = autocvar_g_balance_health_rotstable;
2103         maxa = autocvar_g_balance_armor_rotstable;
2104         maxf = autocvar_g_balance_fuel_rotstable;
2105         minh = autocvar_g_balance_health_regenstable;
2106         mina = autocvar_g_balance_armor_regenstable;
2107         minf = autocvar_g_balance_fuel_regenstable;
2108         limith = autocvar_g_balance_health_limit;
2109         limita = autocvar_g_balance_armor_limit;
2110         limitf = autocvar_g_balance_fuel_limit;
2111
2112         max_mod = regen_mod = rot_mod = limit_mod = 1;
2113
2114         if (self.runes & RUNE_REGEN)
2115         {
2116                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2117                 {
2118                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2119                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2120                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2121                 }
2122                 else
2123                 {
2124                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2125                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2126                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2127                 }
2128         }
2129         else if (self.runes & CURSE_VENOM)
2130         {
2131                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2132                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2133                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2134                 else
2135                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2136                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2137                 //if (!self.runes & RUNE_REGEN)
2138                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2139         }
2140         maxh = maxh * max_mod;
2141         //maxa = maxa * max_mod;
2142         //maxf = maxf * max_mod;
2143         minh = minh * max_mod;
2144         //mina = mina * max_mod;
2145         //minf = minf * max_mod;
2146         limith = limith * limit_mod;
2147         limita = limita * limit_mod;
2148         //limitf = limitf * limit_mod;
2149
2150         if(g_lms && g_ca)
2151                 rot_mod = 0;
2152
2153         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2154         {
2155                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2156                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2157
2158                 // if player rotted to death...  die!
2159                 if(self.health < 1)
2160                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2161         }
2162
2163         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2164                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2165 }
2166
2167 float zoomstate_set;
2168 void SetZoomState(float z)
2169 {
2170         if(z != self.zoomstate)
2171         {
2172                 self.zoomstate = z;
2173                 ClientData_Touch(self);
2174         }
2175         zoomstate_set = 1;
2176 }
2177
2178 void GetPressedKeys(void) {
2179         MUTATOR_CALLHOOK(GetPressedKeys);
2180         if (self.movement_x > 0) // get if movement keys are pressed
2181         {       // forward key pressed
2182                 self.pressedkeys |= KEY_FORWARD;
2183                 self.pressedkeys &~= KEY_BACKWARD;
2184         }
2185         else if (self.movement_x < 0)
2186         {       // backward key pressed
2187                 self.pressedkeys |= KEY_BACKWARD;
2188                 self.pressedkeys &~= KEY_FORWARD;
2189         }
2190         else
2191         {       // no x input
2192                 self.pressedkeys &~= KEY_FORWARD;
2193                 self.pressedkeys &~= KEY_BACKWARD;
2194         }
2195
2196         if (self.movement_y > 0)
2197         {       // right key pressed
2198                 self.pressedkeys |= KEY_RIGHT;
2199                 self.pressedkeys &~= KEY_LEFT;
2200         }
2201         else if (self.movement_y < 0)
2202         {       // left key pressed
2203                 self.pressedkeys |= KEY_LEFT;
2204                 self.pressedkeys &~= KEY_RIGHT;
2205         }
2206         else
2207         {       // no y input
2208                 self.pressedkeys &~= KEY_RIGHT;
2209                 self.pressedkeys &~= KEY_LEFT;
2210         }
2211
2212         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2213                 self.pressedkeys |= KEY_JUMP;
2214         else
2215                 self.pressedkeys &~= KEY_JUMP;
2216         if (self.BUTTON_CROUCH)
2217                 self.pressedkeys |= KEY_CROUCH;
2218         else
2219                 self.pressedkeys &~= KEY_CROUCH;
2220 }
2221
2222 /*
2223 ======================
2224 spectate mode routines
2225 ======================
2226 */
2227
2228 void SpectateCopy(entity spectatee) {
2229         other = spectatee;
2230         MUTATOR_CALLHOOK(SpectateCopy);
2231         self.armortype = spectatee.armortype;
2232         self.armorvalue = spectatee.armorvalue;
2233         self.ammo_cells = spectatee.ammo_cells;
2234         self.ammo_shells = spectatee.ammo_shells;
2235         self.ammo_nails = spectatee.ammo_nails;
2236         self.ammo_rockets = spectatee.ammo_rockets;
2237         self.ammo_fuel = spectatee.ammo_fuel;
2238         self.clip_load = spectatee.clip_load;
2239         self.clip_size = spectatee.clip_size;
2240         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2241         self.health = spectatee.health;
2242         self.impulse = 0;
2243         self.items = spectatee.items;
2244         self.last_pickup = spectatee.last_pickup;
2245         self.hit_time = spectatee.hit_time;
2246         self.metertime = spectatee.metertime;
2247         self.strength_finished = spectatee.strength_finished;
2248         self.invincible_finished = spectatee.invincible_finished;
2249         self.pressedkeys = spectatee.pressedkeys;
2250         self.weapons = spectatee.weapons;
2251         self.switchweapon = spectatee.switchweapon;
2252         self.switchingweapon = spectatee.switchingweapon;
2253         self.weapon = spectatee.weapon;
2254         self.nex_charge = spectatee.nex_charge;
2255         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2256         self.hagar_load = spectatee.hagar_load;
2257         self.minelayer_mines = spectatee.minelayer_mines;
2258         self.punchangle = spectatee.punchangle;
2259         self.view_ofs = spectatee.view_ofs;
2260         self.v_angle = spectatee.v_angle;
2261         self.velocity = spectatee.velocity;
2262         self.dmg_take = spectatee.dmg_take;
2263         self.dmg_save = spectatee.dmg_save;
2264         self.dmg_inflictor = spectatee.dmg_inflictor;
2265         self.angles = spectatee.v_angle;
2266         if(!self.BUTTON_USE)
2267                 self.fixangle = TRUE;
2268         setorigin(self, spectatee.origin);
2269         setsize(self, spectatee.mins, spectatee.maxs);
2270         SetZoomState(spectatee.zoomstate);
2271
2272         anticheat_spectatecopy(spectatee);
2273
2274         //self.vehicle = spectatee.vehicle;
2275
2276         self.hud = spectatee.hud;
2277         if(spectatee.vehicle)
2278     {
2279         setorigin(self, spectatee.origin);
2280         self.velocity = spectatee.vehicle.velocity;
2281         self.v_angle += spectatee.vehicle.angles;
2282         //self.v_angle_x *= -1;
2283         self.vehicle_health = spectatee.vehicle_health;
2284         self.vehicle_shield = spectatee.vehicle_shield;
2285         self.vehicle_energy = spectatee.vehicle_energy;
2286         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2287         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2288         self.vehicle_reload1 = spectatee.vehicle_reload1;
2289         self.vehicle_reload2 = spectatee.vehicle_reload2;
2290
2291         msg_entity = self;
2292         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2293         WriteEntity(MSG_ONE, spectatee);
2294         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2295     }
2296 }
2297
2298 float SpectateUpdate() {
2299         if(!self.enemy)
2300             return 0;
2301
2302         if (self == self.enemy)
2303                 return 0;
2304
2305         if(self.enemy.classname != "player")
2306                 return 0;
2307
2308         SpectateCopy(self.enemy);
2309
2310         return 1;
2311 }
2312
2313
2314 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2315 entity CA_SpectateNext(entity start) {
2316         if (start.team == self.team) {
2317                 return start;
2318         }
2319
2320         other = start;
2321         // continue from current player
2322         while(other && other.team != self.team) {
2323                 other = find(other, classname, "player");
2324         }
2325
2326         if (!other) {
2327                 // restart from begining
2328                 other = find(other, classname, "player");
2329                 while(other && other.team != self.team) {
2330                         other = find(other, classname, "player");
2331                 }
2332         }
2333
2334         return other;
2335 }
2336
2337 float SpectateNext() {
2338         other = find(self.enemy, classname, "player");
2339         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2340                 // CA and ca players when spectating enemies is forbidden
2341                 other = CA_SpectateNext(other);
2342         } else {
2343                 // other modes and ca spectators or spectating enemies is allowed
2344                 if (!other)
2345                         other = find(other, classname, "player");
2346         }
2347
2348         if (other)
2349                 self.enemy = other;
2350
2351         if(self.enemy.classname == "player") {
2352             if(self.enemy.vehicle)
2353             {
2354             msg_entity = self;
2355             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2356             WriteEntity(MSG_ONE, self.enemy);
2357             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2358             self.movetype = MOVETYPE_NONE;
2359             accuracy_resend(self);
2360             }
2361             else
2362             {
2363             msg_entity = self;
2364             WriteByte(MSG_ONE, SVC_SETVIEW);
2365             WriteEntity(MSG_ONE, self.enemy);
2366             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2367             self.movetype = MOVETYPE_NONE;
2368             accuracy_resend(self);
2369
2370             if(!SpectateUpdate())
2371                 PutObserverInServer();
2372         }
2373         return 1;
2374         } else {
2375                 return 0;
2376         }
2377 }
2378
2379 /*
2380 =============
2381 ShowRespawnCountdown()
2382
2383 Update a respawn countdown display.
2384 =============
2385 */
2386 void ShowRespawnCountdown()
2387 {
2388         float number;
2389         if(self.deadflag == DEAD_NO) // just respawned?
2390                 return;
2391         else
2392         {
2393                 number = ceil(self.death_time - time);
2394                 if(number <= 0)
2395                         return;
2396                 if(number <= self.respawn_countdown)
2397                 {
2398                         self.respawn_countdown = number - 1;
2399                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2400                                 AnnounceTo(self, strcat(ftos(number), ""));
2401                 }
2402         }
2403 }
2404
2405 .float prevent_join_msgtime;
2406 void LeaveSpectatorMode()
2407 {
2408         if(nJoinAllowed(1)) {
2409                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2410                         self.classname = "player";
2411
2412                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2413                                 JoinBestTeam(self, FALSE, TRUE);
2414
2415                         if(autocvar_g_campaign)
2416                                 campaign_bots_may_start = 1;
2417
2418                         PutClientInServer();
2419
2420                         if(self.classname == "player")
2421                                 bprint ("^4", self.netname, "^4 is playing now\n");
2422
2423                         if(!autocvar_g_campaign)
2424                         if (time < self.jointime + autocvar_welcome_message_time)
2425                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2426
2427                         if (self.prevent_join_msgtime)
2428                         {
2429                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2430                                 self.prevent_join_msgtime = 0;
2431                         }
2432
2433                         return;
2434                 } else {
2435                         if (g_ca && self.caplayer) {
2436                         }       // do nothing
2437                         else
2438                                 stuffcmd(self,"menu_showteamselect\n");
2439                         return;
2440                 }
2441         }
2442         else {
2443                 //player may not join because of g_maxplayers is set
2444                 if (time - self.prevent_join_msgtime > 2)
2445                 {
2446                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2447                         self.prevent_join_msgtime = time;
2448                 }
2449         }
2450 }
2451
2452 /**
2453  * Determines whether the player is allowed to join. This depends on cvar
2454  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2455  * it checks whether the number of currently playing players exceeds g_maxplayers.
2456  * @return int number of free slots for players, 0 if none
2457  */
2458 float nJoinAllowed(float includeMe) {
2459         if(self.team_forced < 0)
2460                 return FALSE; // forced spectators can never join
2461
2462         // TODO simplify this
2463         entity e;
2464
2465         float totalClients;
2466         FOR_EACH_CLIENT(e)
2467                 totalClients += 1;
2468
2469         if (!autocvar_g_maxplayers)
2470                 return maxclients - totalClients + includeMe;
2471
2472         float currentlyPlaying;
2473         FOR_EACH_REALPLAYER(e)
2474                 currentlyPlaying += 1;
2475
2476         if(currentlyPlaying < autocvar_g_maxplayers)
2477                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2478
2479         return 0;
2480 }
2481
2482 /**
2483  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2484  * g_maxplayers_spectator_blocktime seconds
2485  */
2486 void checkSpectatorBlock() {
2487         if(self.classname == "spectator" || self.classname == "observer") {
2488                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2489                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2490                         dropclient(self);
2491                 }
2492         }
2493 }
2494
2495 .float motd_actived_time; // used for both motd and campaign_message
2496 void PrintWelcomeMessage()
2497 {
2498         if (self.motd_actived_time == 0) { // is there already a message showing?
2499                 if (autocvar_g_campaign) {
2500                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2501                                 self.motd_actived_time = time;
2502                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2503                         }
2504                 } else {
2505                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2506                                 self.motd_actived_time = time;
2507                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2508                         }
2509                 }
2510         } else { // showing MOTD or campaign message
2511                 if (autocvar_g_campaign) {
2512                         if (self.BUTTON_INFO)
2513                                 self.motd_actived_time = time;
2514                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2515                                 self.motd_actived_time = 0;
2516                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2517                         }
2518                 } else {
2519                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2520                                 if (self.BUTTON_INFO)
2521                                         self.motd_actived_time = time;
2522                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2523                                         self.motd_actived_time = 0;
2524                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2525                                 }
2526                         }
2527                 }
2528         }
2529 }
2530
2531 void ObserverThink()
2532 {
2533         float prefered_movetype;
2534         if (self.flags & FL_JUMPRELEASED) {
2535                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2536                         self.flags &~= FL_JUMPRELEASED;
2537                         self.flags |= FL_SPAWNING;
2538                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2539                         self.flags &~= FL_JUMPRELEASED;
2540                         if(SpectateNext() == 1) {
2541                                 self.classname = "spectator";
2542                         }
2543                 } else {
2544                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2545                         if (self.movetype != prefered_movetype)
2546                                 self.movetype = prefered_movetype;
2547                 }
2548         } else {
2549                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2550                         self.flags |= FL_JUMPRELEASED;
2551                         if(self.flags & FL_SPAWNING)
2552                         {
2553                                 self.flags &~= FL_SPAWNING;
2554                                 LeaveSpectatorMode();
2555                                 return;
2556                         }
2557                 }
2558         }
2559
2560         PrintWelcomeMessage();
2561 }
2562
2563 void SpectatorThink()
2564 {
2565         if (self.flags & FL_JUMPRELEASED) {
2566                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2567                         self.flags &~= FL_JUMPRELEASED;
2568                         self.flags |= FL_SPAWNING;
2569                 } else if(self.BUTTON_ATCK) {
2570                         self.flags &~= FL_JUMPRELEASED;
2571                         if(SpectateNext() == 1) {
2572                                 self.classname = "spectator";
2573                         } else {
2574                                 self.classname = "observer";
2575                                 PutClientInServer();
2576                         }
2577                 } else if (self.BUTTON_ATCK2) {
2578                         self.flags &~= FL_JUMPRELEASED;
2579                         self.classname = "observer";
2580                         PutClientInServer();
2581                 } else {
2582                         if(!SpectateUpdate())
2583                                 PutObserverInServer();
2584                 }
2585         } else {
2586                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2587                         self.flags |= FL_JUMPRELEASED;
2588                         if(self.flags & FL_SPAWNING)
2589                         {
2590                                 self.flags &~= FL_SPAWNING;
2591                                 LeaveSpectatorMode();
2592                                 return;
2593                         }
2594                 }
2595                 if(!SpectateUpdate())
2596                         PutObserverInServer();
2597         }
2598
2599         PrintWelcomeMessage();
2600         self.flags |= FL_CLIENT | FL_NOTARGET;
2601 }
2602
2603 float ctf_usekey();
2604 void PlayerUseKey()
2605 {
2606         if(self.classname != "player")
2607                 return;
2608
2609         if(self.vehicle)
2610         {
2611         vehicles_exit(VHEF_NORMAL);
2612         return;
2613         }
2614
2615         // a use key was pressed; call handlers
2616         if(ctf_usekey())
2617                 return;
2618
2619         MUTATOR_CALLHOOK(PlayerUseKey);
2620 }
2621
2622 .float touchexplode_time;
2623
2624 /*
2625 =============
2626 PlayerPreThink
2627
2628 Called every frame for each client before the physics are run
2629 =============
2630 */
2631 .float usekeypressed;
2632 void() ctf_setstatus;
2633 void() nexball_setstatus;
2634 .float items_added;
2635 void PlayerPreThink (void)
2636 {
2637         WarpZone_PlayerPhysics_FixVAngle();
2638
2639         self.stat_game_starttime = game_starttime;
2640         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2641         self.stat_leadlimit = autocvar_leadlimit;
2642
2643         if(frametime)
2644         {
2645                 // physics frames: update anticheat stuff
2646                 anticheat_prethink();
2647         }
2648
2649         if(blockSpectators && frametime)
2650                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2651                 checkSpectatorBlock();
2652
2653         zoomstate_set = 0;
2654
2655         if(self.netname_previous != self.netname)
2656         {
2657                 if(autocvar_sv_eventlog)
2658                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2659                 if(self.netname_previous)
2660                         strunzone(self.netname_previous);
2661                 self.netname_previous = strzone(self.netname);
2662         }
2663
2664         // version nagging
2665         if(self.version_nagtime)
2666                 if(self.cvar_g_xonoticversion)
2667                         if(time > self.version_nagtime)
2668                         {
2669                                 // don't notify git users
2670                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2671                                 {
2672                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2673                                         {
2674                                                 // notify release users if connecting to git
2675                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2676                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2677                                         }
2678                                         else
2679                                         {
2680                                                 float r;
2681                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2682                                                 if(r < 0)
2683                                                 {
2684                                                         // give users new version
2685                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2686                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2687                                                 }
2688                                                 else if(r > 0)
2689                                                 {
2690                                                         // notify users about old server version
2691                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2692                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2693                                                 }
2694                                         }
2695                                 }
2696                                 self.version_nagtime = 0;
2697                         }
2698
2699         // GOD MODE info
2700         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2701         {
2702                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2703                 self.max_armorvalue = 0;
2704         }
2705
2706 #ifdef TETRIS
2707         if (TetrisPreFrame())
2708                 return;
2709 #endif
2710
2711         MUTATOR_CALLHOOK(PlayerPreThink);
2712
2713         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2714         {
2715                 if(self.BUTTON_USE && !self.usekeypressed)
2716                         PlayerUseKey();
2717                 self.usekeypressed = self.BUTTON_USE;
2718         }
2719
2720         PrintWelcomeMessage();
2721
2722         if(self.classname == "player") {
2723 //              if(self.netname == "Wazat")
2724 //                      bprint(self.classname, "\n");
2725
2726                 CheckRules_Player();
2727
2728                 if (intermission_running)
2729                 {
2730                         IntermissionThink ();   // otherwise a button could be missed between
2731                         return;                                 // the think tics
2732                 }
2733
2734                 //don't allow the player to turn around while game is paused!
2735                 if(timeoutStatus == 2) {
2736                         // FIXME turn this into CSQC stuff
2737                         self.v_angle = self.lastV_angle;
2738                         self.angles = self.lastV_angle;
2739                         self.fixangle = TRUE;
2740                 }
2741
2742                 if(frametime)
2743                 {
2744                         if(self.health <= 0 && autocvar_g_deathglow)
2745                         {
2746                                 if(self.glowmod_x > 0)
2747                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2748                                 else
2749                                         self.glowmod_x = -1;
2750                                 if(self.glowmod_y > 0)
2751                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2752                                 else
2753                                         self.glowmod_y = -1;
2754                                 if(self.glowmod_z > 0)
2755                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2756                                 else
2757                                         self.glowmod_z = -1;
2758                         }
2759                         else
2760                         {
2761                                 // set weapon and player glowmod
2762                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2763
2764                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2765                                 {
2766                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2767                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2768                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2769
2770                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2771                                         {
2772                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2773                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2774                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2775                                         }
2776                                 }
2777                                 else
2778                                         self.weaponentity_glowmod = self.glowmod;
2779                         }
2780                         player_powerups();
2781                 }
2782
2783                 if (g_minstagib)
2784                         minstagib_ammocheck();
2785
2786                 if (self.deadflag != DEAD_NO)
2787                 {
2788                         float button_pressed, force_respawn;
2789                         if(self.personal && g_race_qualifying)
2790                         {
2791                                 if(time > self.death_time)
2792                                 {
2793                                         self.death_time = time + 1; // only retry once a second
2794                                         respawn();
2795                                         self.impulse = 141;
2796                                 }
2797                         }
2798                         else
2799                         {
2800                                 if(frametime)
2801                                         player_anim();
2802                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2803                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2804                                 if (self.deadflag == DEAD_DYING)
2805                                 {
2806                                         if(force_respawn)
2807                                                 self.deadflag = DEAD_RESPAWNING;
2808                                         else if(!button_pressed)
2809                                                 self.deadflag = DEAD_DEAD;
2810                                 }
2811                                 else if (self.deadflag == DEAD_DEAD)
2812                                 {
2813                                         if(button_pressed)
2814                                                 self.deadflag = DEAD_RESPAWNABLE;
2815                                 }
2816                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2817                                 {
2818                                         if(!button_pressed)
2819                                                 self.deadflag = DEAD_RESPAWNING;
2820                                 }
2821                                 else if (self.deadflag == DEAD_RESPAWNING)
2822                                 {
2823                                         if(time > self.death_time)
2824                                         {
2825                                                 self.death_time = time + 1; // only retry once a second
2826                                                 respawn();
2827                                         }
2828                                 }
2829                                 ShowRespawnCountdown();
2830                         }
2831                         return;
2832                 }
2833                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2834                 // so (self.deadflag == DEAD_NO) is always true in the code below
2835
2836                 if(g_touchexplode)
2837                 if(time > self.touchexplode_time)
2838                 if(self.classname == "player")
2839                 if(self.deadflag == DEAD_NO)
2840                 if not(IS_INDEPENDENT_PLAYER(self))
2841                 FOR_EACH_PLAYER(other) if(self != other)
2842                 {
2843                         if(time > other.touchexplode_time)
2844                         if(other.deadflag == DEAD_NO)
2845                         if not(IS_INDEPENDENT_PLAYER(other))
2846                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2847                         {
2848                                 PlayerTouchExplode(self, other);
2849                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2850                         }
2851                 }
2852
2853                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2854                 {
2855                         vector dist;
2856
2857                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2858                         dist = self.prevorigin - self.origin;
2859                         dist_z = 0;
2860                         self.lms_traveled_distance += fabs(vlen(dist));
2861
2862                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2863                         {
2864                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2865                                 self.lms_traveled_distance = 0;
2866                         }
2867
2868                         if(time > self.lms_nextcheck)
2869                         {
2870                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2871                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2872                                 {
2873                                         centerprint(self, autocvar_g_lms_campcheck_message);
2874                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2875                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2876                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2877                                 }
2878                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2879                                 self.lms_traveled_distance = 0;
2880                         }
2881                 }
2882
2883                 self.prevorigin = self.origin;
2884
2885                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2886                 {
2887                         if (!self.crouch)
2888                         {
2889                                 self.crouch = TRUE;
2890                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2891                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2892                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2893                         }
2894                 }
2895                 else
2896                 {
2897                         if (self.crouch)
2898                         {
2899                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2900                                 if (!trace_startsolid)
2901                                 {
2902                                         self.crouch = FALSE;
2903                                         self.view_ofs = PL_VIEW_OFS;
2904                                         setsize (self, PL_MIN, PL_MAX);
2905                                 }
2906                         }
2907                 }
2908
2909                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2910                 {
2911                         if(self.bloodloss_timer < time)
2912                         {
2913                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2914                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2915                         }
2916                 }
2917
2918                 FixPlayermodel();
2919
2920                 GrapplingHookFrame();
2921
2922                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2923                 //if(frametime)
2924                 {
2925                         self.items &~= self.items_added;
2926
2927                         W_WeaponFrame();
2928
2929                         self.items_added = 0;
2930                         if(self.items & IT_JETPACK)
2931                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2932                                         self.items_added |= IT_FUEL;
2933
2934                         self.items |= self.items_added;
2935                 }
2936
2937                 player_regen();
2938
2939                 // rot nex charge to the charge limit
2940                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2941                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2942
2943                 if(frametime)
2944                         player_anim();
2945
2946                 if(g_ctf)
2947                         ctf_setstatus();
2948
2949                 if(g_nexball)
2950                         nexball_setstatus();
2951
2952                 // secret status
2953                 secrets_setstatus();
2954
2955                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2956
2957                 //self.angles_y=self.v_angle_y + 90;   // temp
2958         } else if(gameover) {
2959                 if (intermission_running)
2960                         IntermissionThink ();   // otherwise a button could be missed between
2961                 return;
2962         } else if(self.classname == "observer") {
2963                 ObserverThink();
2964         } else if(self.classname == "spectator") {
2965                 SpectatorThink();
2966         }
2967
2968         if(!zoomstate_set)
2969                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2970
2971         float oldspectatee_status;
2972         oldspectatee_status = self.spectatee_status;
2973         if(self.classname == "spectator")
2974                 self.spectatee_status = num_for_edict(self.enemy);
2975         else if(self.classname == "observer")
2976                 self.spectatee_status = num_for_edict(self);
2977         else
2978                 self.spectatee_status = 0;
2979         if(self.spectatee_status != oldspectatee_status)
2980         {
2981                 ClientData_Touch(self);
2982                 if(g_race || g_cts)
2983                         race_InitSpectator();
2984         }
2985
2986         if(self.teamkill_soundtime)
2987         if(time > self.teamkill_soundtime)
2988         {
2989                 self.teamkill_soundtime = 0;
2990
2991                 entity oldpusher, oldself;
2992
2993                 oldself = self; self = self.teamkill_soundsource;
2994                 oldpusher = self.pusher; self.pusher = oldself;
2995
2996                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2997
2998                 self.pusher = oldpusher;
2999                 self = oldself;
3000         }
3001
3002         if(self.taunt_soundtime)
3003         if(time > self.taunt_soundtime)
3004         {
3005                 self.taunt_soundtime = 0;
3006                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3007         }
3008
3009         target_voicescript_next(self);
3010
3011         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3012         if(!self.weapon)
3013                 self.clip_load = self.clip_size = 0;
3014 }
3015
3016 float isInvisibleString(string s)
3017 {
3018         float i, n, c;
3019         s = strdecolorize(s);
3020         for((i = 0), (n = strlen(s)); i < n; ++i)
3021         {
3022                 c = str2chr(s, i);
3023                 switch(c)
3024                 {
3025                         case 0:
3026                         case 32: // space
3027                                 break;
3028                         case 192: // charmap space
3029                                 if (!autocvar_utf8_enable)
3030                                         break;
3031                                 return FALSE;
3032                         case 160: // space in unicode fonts
3033                         case 0xE000 + 192: // utf8 charmap space
3034                                 if (autocvar_utf8_enable)
3035                                         break;
3036                         default:
3037                                 return FALSE;
3038                 }
3039         }
3040         return TRUE;
3041 }
3042
3043 /*
3044 =============
3045 PlayerPostThink
3046
3047 Called every frame for each client after the physics are run
3048 =============
3049 */
3050 .float idlekick_lasttimeleft;
3051 .entity showheadshotbbox;
3052 void showheadshotbbox_think()
3053 {
3054         if(self.owner.showheadshotbbox != self)
3055         {
3056                 remove(self);
3057                 return;
3058         }
3059         self.nextthink = time;
3060         setorigin(self, self.owner.origin);
3061         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3062 }
3063 void PlayerPostThink (void)
3064 {
3065         // Savage: Check for nameless players
3066         if (isInvisibleString(self.netname)) {
3067                 self.netname = "Player";
3068                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3069         }
3070
3071         if(sv_maxidle && frametime)
3072         {
3073                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3074                 float timeleft;
3075                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3076                 {
3077                         if(self.idlekick_lasttimeleft)
3078                         {
3079                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3080                                 self.idlekick_lasttimeleft = 0;
3081                         }
3082                         return;
3083                 }
3084                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3085                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3086                 {
3087                         if(!self.idlekick_lasttimeleft)
3088                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3089                 }
3090                 if(timeleft <= 0)
3091                 {
3092                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3093                         AnnounceTo(self, "terminated");
3094                         dropclient(self);
3095                         return;
3096                 }
3097                 else if(timeleft <= 10)
3098                 {
3099                         if(timeleft != self.idlekick_lasttimeleft)
3100                                 AnnounceTo(self, ftos(timeleft));
3101                         self.idlekick_lasttimeleft = timeleft;
3102                 }
3103         }
3104
3105 #ifdef TETRIS
3106         if(self.impulse == 100)
3107                 ImpulseCommands();
3108         if (TetrisPostFrame())
3109                 return;
3110 #endif
3111
3112         CheatFrame();
3113
3114         //CheckPlayerJump();
3115
3116         if(self.classname == "player") {
3117                 CheckRules_Player();
3118                 UpdateChatBubble();
3119                 if (self.impulse)
3120                         ImpulseCommands();
3121                 if (intermission_running)
3122                         return;         // intermission or finale
3123                 GetPressedKeys();
3124         } else if (self.classname == "observer") {
3125                 //do nothing
3126         } else if (self.classname == "spectator") {
3127                 //do nothing
3128         }
3129
3130         /*
3131         float i;
3132         for(i = 0; i < 1000; ++i)
3133         {
3134                 vector end;
3135                 end = self.origin + '0 0 1024' + 512 * randomvec();
3136                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3137                 if(trace_fraction < 1)
3138                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3139                 {
3140                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3141                         break;
3142                 }
3143         }
3144         */
3145
3146         Arena_Warmup();
3147
3148         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3149
3150         if(self.waypointsprite_attachedforcarrier)
3151                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3152
3153         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3154         {
3155                 if(!self.showheadshotbbox)
3156                 {
3157                         self.showheadshotbbox = spawn();
3158                         self.showheadshotbbox.classname = "headshotbbox";
3159                         self.showheadshotbbox.owner = self;
3160                         self.showheadshotbbox.think = showheadshotbbox_think;
3161                         self.showheadshotbbox.nextthink = time;
3162                         self = self.showheadshotbbox;
3163                         self.think();
3164                         self = self.owner;
3165                 }
3166         }
3167         else
3168         {
3169                 if(self.showheadshotbbox)
3170                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3171                 remove(self.showheadshotbbox);
3172         }
3173
3174         playerdemo_write();
3175
3176         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3177         {
3178                 if(!self.stored_netname)
3179                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3180                 if(self.stored_netname != self.netname)
3181                 {
3182                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3183                         strunzone(self.stored_netname);
3184                         self.stored_netname = strzone(self.netname);
3185                 }
3186         }
3187
3188         /*
3189         if(g_race)
3190                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3191         */
3192 }