qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, autocvar_g_balance_campingrifle_magazinecapacity);
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(autocvar_spawn_debugview)
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > autocvar_g_spawn_furthest)
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(autocvar_spawn_debugview)
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(autocvar_spawn_debug)
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(autocvar_sv_servermodelsonly)
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602         MUTATOR_CALLHOOK(MakePlayerObserver);
 603
 604         Portal_ClearAll(self);
 605
 606         if(self.alivetime)
 607         {
 608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 609                 self.alivetime = 0;
 610         }
 611
 612         if(self.flagcarried)
 613                 DropFlag(self.flagcarried, world, world);
 614
 615         if(self.ballcarried && g_nexball)
 616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 617
 618         WaypointSprite_PlayerDead();
 619
 620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 622
 623         if(self.killcount != -666) {
 624                 if(g_lms) {
 625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 627                         else
 628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 629                 } else
 630                         bprint ("^4", self.netname, "^4 is spectating now\n");
 631
 632                 if(self.just_joined == FALSE) {
 633                         LogTeamchange(self.playerid, -1, 4);
 634                 } else
 635                         self.just_joined = FALSE;
 636         }
 637
 638         PlayerScore_Clear(self); // clear scores when needed
 639
 640         accuracy_resend(self);
 641
 642         self.spectatortime = time;
 643
 644         self.classname = "observer";
 645         self.iscreature = FALSE;
 646         self.health = -666;
 647         self.takedamage = DAMAGE_NO;
 648         self.solid = SOLID_NOT;
 649         self.movetype = MOVETYPE_NOCLIP;
 650         self.flags = FL_CLIENT | FL_NOTARGET;
 651         self.armorvalue = 666;
 652         self.effects = 0;
 653         self.armorvalue = autocvar_g_balance_armor_start;
 654         self.pauserotarmor_finished = 0;
 655         self.pauserothealth_finished = 0;
 656         self.pauseregen_finished = 0;
 657         self.damageforcescale = 0;
 658         self.death_time = 0;
 659         self.dead_frame = 0;
 660         self.alpha = 0;
 661         self.scale = 0;
 662         self.fade_time = 0;
 663         self.pain_frame = 0;
 664         self.pain_finished = 0;
 665         self.strength_finished = 0;
 666         self.invincible_finished = 0;
 667         self.pushltime = 0;
 668         self.think = SUB_Null;
 669         self.nextthink = 0;
 670         self.hook_time = 0;
 671         self.runes = 0;
 672         self.deadflag = DEAD_NO;
 673         self.angles = spot.angles;
 674         self.angles_z = 0;
 675         self.fixangle = TRUE;
 676         self.crouch = FALSE;
 677
 678         self.view_ofs = PL_VIEW_OFS;
 679         setorigin (self, spot.origin);
 680         setsize (self, '0 0 0', '0 0 0');
 681         self.prevorigin = self.origin;
 682         self.items = 0;
 683         self.weapons = 0;
 684         self.model = "";
 685         FixPlayermodel();
 686         self.model = "";
 687         self.modelindex = 0;
 688         self.weapon = 0;
 689         self.weaponmodel = "";
 690         self.weaponentity = world;
 691         self.exteriorweaponentity = world;
 692         self.killcount = -666;
 693         self.velocity = '0 0 0';
 694         self.avelocity = '0 0 0';
 695         self.punchangle = '0 0 0';
 696         self.punchvector = '0 0 0';
 697         self.oldvelocity = self.velocity;
 698         self.fire_endtime = -1;
 699
 700         if(sv_loddistance1)
 701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 702
 703         if(g_arena)
 704         {
 705                 if(self.version_mismatch)
 706                 {
 707                         Spawnqueue_Unmark(self);
 708                         Spawnqueue_Remove(self);
 709                 }
 710                 else
 711                 {
 712                         Spawnqueue_Insert(self);
 713                 }
 714         }
 715         else if(g_lms)
 716         {
 717                 // Only if the player cannot play at all
 718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 719                         self.frags = FRAGS_SPECTATOR;
 720                 else
 721                         self.frags = FRAGS_LMS_LOSER;
 722         }
 723         else
 724                 self.frags = FRAGS_SPECTATOR;
 725 }
 726
 727 float RestrictSkin(float s)
 728 {
 729         if(!teams_matter)
 730                 return s;
 731         if(s == 6)
 732                 return 6;
 733         return mod(s, 3);
 734 }
 735
 736 void FixPlayermodel()
 737 {
 738         local string defaultmodel;
 739         local float defaultskin, chmdl, oldskin;
 740         local vector m1, m2;
 741
 742         defaultmodel = "";
 743
 744         if(autocvar_sv_defaultcharacter == 1) {
 745                 defaultskin = 0;
 746
 747                 if(teams_matter)
 748                 {
 749                         string s;
 750                         s = Team_ColorNameLowerCase(self.team);
 751                         if(s != "neutral")
 752                         {
 753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 755                         }
 756                 }
 757
 758                 if(defaultmodel == "")
 759                 {
 760                         defaultmodel = autocvar_sv_defaultplayermodel;
 761                         defaultskin = autocvar_sv_defaultplayerskin;
 762                 }
 763         }
 764
 765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 766         {
 767                 if(self.model != "")
 768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 769                 self.model = ""; // force the != checks to return true
 770         }
 771
 772         if(defaultmodel != "")
 773         {
 774                 if (defaultmodel != self.model)
 775                 {
 776                         m1 = self.mins;
 777                         m2 = self.maxs;
 778                         setmodel_lod (self, defaultmodel);
 779                         setsize (self, m1, m2);
 780                         chmdl = TRUE;
 781                 }
 782
 783                 oldskin = self.skinindex;
 784                 self.skinindex = defaultskin;
 785         } else {
 786                 if (self.playermodel != self.model || self.playermodel == "")
 787                 {
 788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 789                         m1 = self.mins;
 790                         m2 = self.maxs;
 791                         setmodel_lod (self, self.playermodel);
 792                         setsize (self, m1, m2);
 793                         chmdl = TRUE;
 794                 }
 795
 796                 oldskin = self.skinindex;
 797                 self.skinindex = RestrictSkin(stof(self.playerskin));
 798         }
 799
 800         if(chmdl || oldskin != self.skinindex)
 801                 self.species = player_getspecies(); // model or skin has changed
 802
 803         if(!teams_matter)
 804                 if(strlen(autocvar_sv_defaultplayercolors))
 805                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 806                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 807 }
 808
 809 void PlayerTouchExplode(entity p1, entity p2)
 810 {
 811         vector org;
 812         org = (p1.origin + p2.origin) * 0.5;
 813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 814
 815         te_explosion(org);
 816
 817         entity e;
 818         e = spawn();
 819         setorigin(e, org);
 820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 821         remove(e);
 822 }
 823
 824 /*
 825 =============
 826 PutClientInServer
 827
 828 Called when a client spawns in the server
 829 =============
 830 */
 831 //void() ctf_playerchanged;
 832 void PutClientInServer (void)
 833 {
 834         if(clienttype(self) == CLIENTTYPE_BOT)
 835         {
 836                 self.classname = "player";
 837         }
 838         else if(clienttype(self) == CLIENTTYPE_REAL)
 839         {
 840                 msg_entity = self;
 841                 WriteByte(MSG_ONE, SVC_SETVIEW);
 842                 WriteEntity(MSG_ONE, self);
 843         }
 844
 845         // player is dead and becomes observer
 846         // FIXME fix LMS scoring for new system
 847         if(g_lms)
 848         {
 849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 850                         self.classname = "observer";
 851         }
 852
 853         if(g_arena || (g_ca && !allowed_to_spawn))
 854         if(!self.spawned)
 855                 self.classname = "observer";
 856
 857         if(gameover)
 858                 self.classname = "observer";
 859
 860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 861                 entity spot, oldself;
 862                 float j;
 863
 864                 accuracy_resend(self);
 865
 866                 if(self.team < 0)
 867                         JoinBestTeam(self, FALSE, TRUE);
 868
 869                 race_PreSpawn();
 870
 871                 spot = SelectSpawnPoint (FALSE);
 872                 if(!spot)
 873                 {
 874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 875                         return; // spawn failed
 876                 }
 877
 878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 879
 880                 self.classname = "player";
 881                 self.wasplayer = TRUE;
 882                 self.iscreature = TRUE;
 883                 self.movetype = MOVETYPE_WALK;
 884                 self.solid = SOLID_SLIDEBOX;
 885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 886                 if(autocvar_g_playerclip_collisions)
 887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 888                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 890                 self.frags = FRAGS_PLAYER;
 891                 if(independent_players)
 892                         MAKE_INDEPENDENT_PLAYER(self);
 893                 self.flags = FL_CLIENT;
 894                 self.takedamage = DAMAGE_AIM;
 895                 if(g_minstagib)
 896                         self.effects = EF_FULLBRIGHT;
 897                 else
 898                         self.effects = 0;
 899                 self.air_finished = time + 12;
 900                 self.dmg = 2;
 901                 if(autocvar_g_balance_nex_charge)
 902                 {
 903                         if(autocvar_g_balance_nex_secondary_chargepool)
 904                                 self.nex_chargepool_ammo = 1;
 905                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 906                 }
 907
 908                 if(inWarmupStage)
 909                 {
 910                         self.ammo_shells = warmup_start_ammo_shells;
 911                         self.ammo_nails = warmup_start_ammo_nails;
 912                         self.ammo_rockets = warmup_start_ammo_rockets;
 913                         self.ammo_cells = warmup_start_ammo_cells;
 914                         self.ammo_fuel = warmup_start_ammo_fuel;
 915                         self.health = warmup_start_health;
 916                         self.armorvalue = warmup_start_armorvalue;
 917                         self.weapons = warmup_start_weapons;
 918                 }
 919                 else
 920                 {
 921                         self.ammo_shells = start_ammo_shells;
 922                         self.ammo_nails = start_ammo_nails;
 923                         self.ammo_rockets = start_ammo_rockets;
 924                         self.ammo_cells = start_ammo_cells;
 925                         self.ammo_fuel = start_ammo_fuel;
 926                         self.health = start_health;
 927                         self.armorvalue = start_armorvalue;
 928                         self.weapons = start_weapons;
 929                 }
 930
 931                 if(g_weaponarena_random)
 932                 {
 933                         if(g_weaponarena_random_with_laser)
 934                                 self.weapons &~= WEPBIT_LASER;
 935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 936                         if(g_weaponarena_random_with_laser)
 937                                 self.weapons |= WEPBIT_LASER;
 938                 }
 939
 940                 self.items = start_items;
 941                 self.jump_interval = time;
 942
 943                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 944                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 945                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 946                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 947                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 948                 //extend the pause of rotting if client was reset at the beginning of the countdown
 949                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 950                         self.spawnshieldtime += game_starttime - time;
 951                         self.pauserotarmor_finished += game_starttime - time;
 952                         self.pauserothealth_finished += game_starttime - time;
 953                         self.pauseregen_finished += game_starttime - time;
 954                 }
 955                 self.damageforcescale = 2;
 956                 self.death_time = 0;
 957                 self.dead_frame = 0;
 958                 self.alpha = 0;
 959                 self.scale = 0;
 960                 self.fade_time = 0;
 961                 self.pain_frame = 0;
 962                 self.pain_finished = 0;
 963                 self.strength_finished = 0;
 964                 self.invincible_finished = 0;
 965                 self.pushltime = 0;
 966                 // players have no think function
 967                 self.think = SUB_Null;
 968                 self.nextthink = 0;
 969                 self.hook_time = 0;
 970                 self.dmg_team = 0;
 971                 self.ballistics_density = autocvar_g_ballistics_density_player;
 972
 973                 self.metertime = 0;
 974
 975                 self.runes = 0;
 976
 977                 self.deadflag = DEAD_NO;
 978
 979                 self.angles = spot.angles;
 980
 981                 self.angles_z = 0; // never spawn tilted even if the spot says to
 982                 self.fixangle = TRUE; // turn this way immediately
 983                 self.velocity = '0 0 0';
 984                 self.avelocity = '0 0 0';
 985                 self.punchangle = '0 0 0';
 986                 self.punchvector = '0 0 0';
 987                 self.oldvelocity = self.velocity;
 988                 self.fire_endtime = -1;
 989
 990                 msg_entity = self;
 991                 WRITESPECTATABLE_MSG_ONE({
 992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 994                 });
 995
 996                 if(sv_loddistance1)
 997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 998
 999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(autocvar_spawn_debug)
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (autocvar_g_spawnsound)
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_campingrifle_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != autocvar_g_balance_armor_blockpercent)
1133         {
1134                 self.count = autocvar_g_balance_armor_blockpercent;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1138         {
1139                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1143         {
1144                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1148         {
1149                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1153         {
1154                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1158         {
1159                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else
1233                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1234 }
1235
1236 void ClientKill_Now()
1237 {
1238         if(self.killindicator_teamchange)
1239                 ClientKill_Now_TeamChange();
1240
1241         // in any case:
1242         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1243
1244         if(self.killindicator)
1245         {
1246                 dprint("Cleaned up after a leaked kill indicator.\n");
1247                 remove(self.killindicator);
1248                 self.killindicator = world;
1249         }
1250 }
1251 void KillIndicator_Think()
1252 {
1253         if (!self.owner.modelindex)
1254         {
1255                 self.owner.killindicator = world;
1256                 remove(self);
1257                 return;
1258         }
1259
1260         if(self.cnt <= 0)
1261         {
1262                 self = self.owner;
1263                 ClientKill_Now(); // no oldself needed
1264                 return;
1265         }
1266     else if(g_cts)
1267     {
1268         self.nextthink = time + 1;
1269         self.cnt -= 1;
1270     }
1271         else
1272         {
1273                 if(self.cnt <= 10)
1274                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1275                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1276                 {
1277                         if(self.cnt <= 10)
1278                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1279                         if(self.owner.killindicator_teamchange)
1280                         {
1281                                 if(self.owner.killindicator_teamchange == -1)
1282                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1283                                 else
1284                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1285                         }
1286                         else
1287                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1288                 }
1289                 self.nextthink = time + 1;
1290                 self.cnt -= 1;
1291         }
1292 }
1293
1294 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1295 {
1296         float killtime;
1297         entity e;
1298         killtime = autocvar_g_balance_kill_delay;
1299
1300         if(g_race_qualifying)
1301                 killtime = 0;
1302
1303         self.killindicator_teamchange = targetteam;
1304
1305     if(g_cts) // allow an instant kill in CTS
1306     {
1307         if(self.selfkilltime < time + 3) // prevent spam
1308         {
1309             self.selfkilltime = max(time, self.selfkilltime) + 2;
1310             ClientKill_Now();
1311         }
1312         return;
1313     }
1314     if(!self.killindicator)
1315         {
1316                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1317                 {
1318                         ClientKill_Now();
1319                 }
1320                 else
1321                 {
1322                         self.killindicator = spawn();
1323                         self.killindicator.owner = self;
1324                         self.killindicator.scale = 0.5;
1325                         setattachment(self.killindicator, self, "");
1326                         setorigin(self.killindicator, '0 0 52');
1327                         self.killindicator.think = KillIndicator_Think;
1328                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1329                         self.killindicator.cnt = ceil(killtime);
1330                         self.killindicator.count = bound(0, ceil(killtime), 10);
1331                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1332
1333                         for(e = world; (e = find(e, classname, "body")) != world; )
1334                         {
1335                                 if(e.enemy != self)
1336                                         continue;
1337                                 e.killindicator = spawn();
1338                                 e.killindicator.owner = e;
1339                                 e.killindicator.scale = 0.5;
1340                                 setattachment(e.killindicator, e, "");
1341                                 setorigin(e.killindicator, '0 0 52');
1342                                 e.killindicator.think = KillIndicator_Think;
1343                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1344                                 e.killindicator.cnt = ceil(killtime);
1345                         }
1346                         self.lip = 0;
1347                 }
1348         }
1349         if(self.killindicator)
1350         {
1351                 if(targetteam)
1352                         self.killindicator.colormod = TeamColor(targetteam);
1353                 else
1354                         self.killindicator.colormod = '0 0 0';
1355         }
1356 }
1357
1358 void ClientKill (void)
1359 {
1360         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1361         {
1362                 // do nothing
1363         }
1364     else if(g_freezetag && self.freezetag_frozen == 1)
1365     {
1366         // do nothing
1367     }
1368         else
1369                 ClientKill_TeamChange(0);
1370 }
1371
1372 void CTS_ClientKill (entity e) // silent version of ClientKill
1373 {
1374     e.killindicator = spawn();
1375     e.killindicator.owner = e;
1376     e.killindicator.think = KillIndicator_Think;
1377     e.killindicator.nextthink = time + (e.lip) * 0.05;
1378     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1379     e.lip = 0;
1380 }
1381
1382 void DoTeamChange(float destteam)
1383 {
1384         float t, c0;
1385         if(!teams_matter)
1386         {
1387                 if(destteam >= 0)
1388                         SetPlayerColors(self, destteam);
1389                 return;
1390         }
1391         if(self.classname == "player")
1392         if(destteam == -1)
1393         {
1394                 CheckAllowedTeams(self);
1395                 t = FindSmallestTeam(self, TRUE);
1396                 switch(self.team)
1397                 {
1398                         case COLOR_TEAM1: c0 = c1; break;
1399                         case COLOR_TEAM2: c0 = c2; break;
1400                         case COLOR_TEAM3: c0 = c3; break;
1401                         case COLOR_TEAM4: c0 = c4; break;
1402                         default:          c0 = 999;
1403                 }
1404                 switch(t)
1405                 {
1406                         case 1:
1407                                 if(c0 > c1)
1408                                         destteam = COLOR_TEAM1;
1409                                 break;
1410                         case 2:
1411                                 if(c0 > c2)
1412                                         destteam = COLOR_TEAM2;
1413                                 break;
1414                         case 3:
1415                                 if(c0 > c3)
1416                                         destteam = COLOR_TEAM3;
1417                                 break;
1418                         case 4:
1419                                 if(c0 > c4)
1420                                         destteam = COLOR_TEAM4;
1421                                 break;
1422                 }
1423                 if(destteam == -1)
1424                         return;
1425         }
1426         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1427                 return;
1428         ClientKill_TeamChange(destteam);
1429 }
1430
1431 void FixClientCvars(entity e)
1432 {
1433         // send prediction settings to the client
1434         stuffcmd(e, "\nin_bindmap 0 0\n");
1435         if(g_race || g_cts)
1436                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1437         if(autocvar_g_antilag == 3) // client side hitscan
1438                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1439         if(sv_gentle)
1440                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1441         /*
1442          * we no longer need to stuff this. Remove this comment block if you feel
1443          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1444         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1445         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1446         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1447         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1448         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1449         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1450         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1451         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1452         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1453         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1454         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1455         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1456         stuffcmd(e, "cl_movement_edgefriction 1\n");
1457          */
1458 }
1459
1460 float PlayerInIDList(entity p, string idlist)
1461 {
1462         float n, i;
1463         string s;
1464
1465         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1466         if not(p.crypto_idfp)
1467                 return 0;
1468
1469         // this function allows abbreviated player IDs too!
1470         n = tokenize_console(idlist);
1471         for(i = 0; i < n; ++i)
1472         {
1473                 s = argv(i);
1474                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1475                         return 1;
1476         }
1477
1478         return 0;
1479 }
1480
1481 /*
1482 =============
1483 ClientConnect
1484
1485 Called when a client connects to the server
1486 =============
1487 */
1488 //void ctf_clientconnect();
1489 string ColoredTeamName(float t);
1490 void DecodeLevelParms (void);
1491 //void dom_player_join_team(entity pl);
1492 void ClientConnect (void)
1493 {
1494         float t;
1495
1496         if(self.flags & FL_CLIENT)
1497         {
1498                 print("Warning: ClientConnect, but already connected!\n");
1499                 return;
1500         }
1501
1502         if(Ban_MaybeEnforceBan(self))
1503                 return;
1504
1505         DecodeLevelParms();
1506
1507 #ifdef WATERMARK
1508         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1509 #endif
1510
1511         self.classname = "player_joining";
1512
1513         self.flags = FL_CLIENT;
1514         self.version_nagtime = time + 10 + random() * 10;
1515
1516         if(player_count<0)
1517         {
1518                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1519                 player_count = 0;
1520         }
1521
1522         PlayerScore_Attach(self);
1523         ClientData_Attach();
1524         accuracy_init(self);
1525
1526         bot_clientconnect();
1527
1528         playerdemo_init();
1529
1530         anticheat_init();
1531
1532         race_PreSpawnObserver();
1533
1534         //if(g_domination)
1535         //      dom_player_join_team(self);
1536
1537         // identify the right forced team
1538         if(autocvar_g_campaign)
1539         {
1540                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1541                 {
1542                         switch(autocvar_g_campaign_forceteam)
1543                         {
1544                                 case 1: self.team_forced = COLOR_TEAM1; break;
1545                                 case 2: self.team_forced = COLOR_TEAM2; break;
1546                                 case 3: self.team_forced = COLOR_TEAM3; break;
1547                                 case 4: self.team_forced = COLOR_TEAM4; break;
1548                                 default: self.team_forced = 0;
1549                         }
1550                 }
1551         }
1552         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1553                 self.team_forced = COLOR_TEAM1;
1554         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1555                 self.team_forced = COLOR_TEAM2;
1556         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1557                 self.team_forced = COLOR_TEAM3;
1558         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1559                 self.team_forced = COLOR_TEAM4;
1560         else if(autocvar_g_forced_team_otherwise == "red")
1561                 self.team_forced = COLOR_TEAM1;
1562         else if(autocvar_g_forced_team_otherwise == "blue")
1563                 self.team_forced = COLOR_TEAM2;
1564         else if(autocvar_g_forced_team_otherwise == "yellow")
1565                 self.team_forced = COLOR_TEAM3;
1566         else if(autocvar_g_forced_team_otherwise == "pink")
1567                 self.team_forced = COLOR_TEAM4;
1568         else if(autocvar_g_forced_team_otherwise == "spectate")
1569                 self.team_forced = -1;
1570         else if(autocvar_g_forced_team_otherwise == "spectator")
1571                 self.team_forced = -1;
1572         else
1573                 self.team_forced = 0;
1574
1575         if(!teams_matter)
1576                 if(self.team_forced > 0)
1577                         self.team_forced = 0;
1578
1579         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1580
1581         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1582                 self.classname = "observer";
1583         } else {
1584                 if(teams_matter)
1585                 {
1586                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1587                         {
1588                                 self.classname = "player";
1589                                 campaign_bots_may_start = 1;
1590                         }
1591                         else
1592                         {
1593                                 self.classname = "observer"; // do it anyway
1594                         }
1595                 }
1596                 else
1597                 {
1598                         self.classname = "player";
1599                         campaign_bots_may_start = 1;
1600                 }
1601         }
1602
1603         self.playerid = (playerid_last = playerid_last + 1);
1604
1605         if(autocvar_sv_eventlog)
1606                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1607
1608         LogTeamchange(self.playerid, self.team, 1);
1609
1610         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1611
1612         self.netname_previous = strzone(self.netname);
1613
1614         bprint("^4", self.netname, "^4 connected");
1615
1616         if(self.classname != "observer" && (g_domination || g_ctf))
1617                 bprint(" and joined the ", ColoredTeamName(self.team));
1618
1619         bprint("\n");
1620
1621         self.welcomemessage_time = 0;
1622
1623         stuffcmd(self, strcat(clientstuff, "\n"));
1624         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1625         stuffcmd(self, "cl_particles_reloadeffects\n");
1626
1627         FixClientCvars(self);
1628
1629         // spawnfunc_waypoint sprites
1630         WaypointSprite_InitClient(self);
1631
1632         // Wazat's grappling hook
1633         SetGrappleHookBindings();
1634
1635         // get autoswitch state from player when he toggles it
1636         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1637
1638         // get version info from player
1639         stuffcmd(self, "cmd clientversion $gameversion\n");
1640
1641         // get other cvars from player
1642         GetCvars(0);
1643
1644         // notify about available teams
1645         if(teams_matter)
1646         {
1647                 CheckAllowedTeams(self);
1648                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1649                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1650         }
1651         else
1652                 stuffcmd(self, "set _teams_available 0\n");
1653
1654         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1655
1656         if(g_arena || g_ca)
1657         {
1658                 self.classname = "observer";
1659                 if(g_arena)
1660                         Spawnqueue_Insert(self);
1661         }
1662         /*else if(g_ctf)
1663         {
1664                 ctf_clientconnect();
1665         }*/
1666
1667         if(teams_matter || radar_showennemies)
1668                 attach_entcs();
1669
1670         bot_relinkplayerlist();
1671
1672         self.spectatortime = time;
1673         if(blockSpectators)
1674         {
1675                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1676         }
1677
1678         self.jointime = time;
1679         self.allowedTimeouts = autocvar_sv_timeout_number;
1680
1681         if(clienttype(self) == CLIENTTYPE_REAL)
1682         {
1683                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1684                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1685         }
1686
1687         if(g_lms)
1688         {
1689                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1690                 {
1691                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1692                         self.frags = FRAGS_SPECTATOR;
1693                 }
1694         }
1695
1696         if(!sv_foginterval && world.fog != "")
1697                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1698
1699         SoundEntity_Attach(self);
1700
1701         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1702         {
1703                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1704                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1705         }
1706         else
1707                 self.hitplotfh = -1;
1708
1709         if(g_race || g_cts) {
1710                 string rr;
1711                 if(g_cts)
1712                         rr = CTS_RECORD;
1713                 else
1714                         rr = RACE_RECORD;
1715                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1716
1717                 msg_entity = self;
1718                 race_send_recordtime(MSG_ONE);
1719                 race_send_speedaward(MSG_ONE);
1720
1721                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1722                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1723                 race_send_speedaward_alltimebest(MSG_ONE);
1724
1725                 float i;
1726                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1727                         race_SendRankings(i, 0, 0, MSG_ONE);
1728                 }
1729         }
1730         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1731                 send_CSQC_teamnagger();
1732
1733         send_CSQC_cr_maxbullets(self);
1734
1735         CheatInitClient();
1736
1737         PlayerStats_AddPlayer(self);
1738 }
1739
1740 /*
1741 =============
1742 ClientDisconnect
1743
1744 Called when a client disconnects from the server
1745 =============
1746 */
1747 .entity chatbubbleentity;
1748 .entity teambubbleentity;
1749 void ReadyCount();
1750 void ClientDisconnect (void)
1751 {
1752         if not(self.flags & FL_CLIENT)
1753         {
1754                 print("Warning: ClientDisconnect without ClientConnect\n");
1755                 return;
1756         }
1757
1758         PlayerStats_AddGlobalInfo(self);
1759
1760         CheatShutdownClient();
1761
1762         if(self.hitplotfh >= 0)
1763         {
1764                 fclose(self.hitplotfh);
1765                 self.hitplotfh = -1;
1766         }
1767
1768         anticheat_report();
1769         anticheat_shutdown();
1770
1771         playerdemo_shutdown();
1772
1773         bot_clientdisconnect();
1774
1775         if(self.entcs)
1776                 detach_entcs();
1777
1778         if(autocvar_sv_eventlog)
1779                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1780         bprint ("^4",self.netname);
1781         bprint ("^4 disconnected\n");
1782
1783         SoundEntity_Detach(self);
1784
1785         DropAllRunes(self);
1786         MUTATOR_CALLHOOK(ClientDisconnect);
1787
1788         Portal_ClearAll(self);
1789
1790         if(self.flagcarried)
1791                 DropFlag(self.flagcarried, world, world);
1792         if(self.ballcarried && g_nexball)
1793                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1794
1795         // Here, everything has been done that requires this player to be a client.
1796
1797         self.flags &~= FL_CLIENT;
1798
1799         if (self.chatbubbleentity)
1800                 remove (self.chatbubbleentity);
1801
1802         if (self.teambubbleentity)
1803                 remove (self.teambubbleentity);
1804
1805         if (self.killindicator)
1806                 remove (self.killindicator);
1807
1808         WaypointSprite_PlayerGone();
1809
1810         bot_relinkplayerlist();
1811
1812         if(g_arena)
1813         {
1814                 Spawnqueue_Unmark(self);
1815                 Spawnqueue_Remove(self);
1816         }
1817
1818         accuracy_free(self);
1819         ClientData_Detach();
1820         PlayerScore_Detach(self);
1821
1822         if(self.netname_previous)
1823                 strunzone(self.netname_previous);
1824         if(self.clientstatus)
1825                 strunzone(self.clientstatus);
1826         if(self.weaponorder_byimpulse)
1827                 strunzone(self.weaponorder_byimpulse);
1828
1829         ClearPlayerSounds();
1830
1831         if(self.personal)
1832                 remove(self.personal);
1833
1834         self.playerid = 0;
1835         ReadyCount();
1836
1837         // free cvars
1838         GetCvars(-1);
1839 }
1840
1841 .float BUTTON_CHAT;
1842 void ChatBubbleThink()
1843 {
1844         self.nextthink = time;
1845         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1846         {
1847                 if(self.owner) // but why can that ever be world?
1848                         self.owner.chatbubbleentity = world;
1849                 remove(self);
1850                 return;
1851         }
1852         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1853 #ifdef TETRIS
1854                 || self.owner.tetris_on
1855 #endif
1856         )
1857                 self.model = self.mdl;
1858         else
1859                 self.model = "";
1860 };
1861
1862 void UpdateChatBubble()
1863 {
1864         if (!self.modelindex)
1865                 return;
1866         // spawn a chatbubble entity if needed
1867         if (!self.chatbubbleentity)
1868         {
1869                 self.chatbubbleentity = spawn();
1870                 self.chatbubbleentity.owner = self;
1871                 self.chatbubbleentity.exteriormodeltoclient = self;
1872                 self.chatbubbleentity.think = ChatBubbleThink;
1873                 self.chatbubbleentity.nextthink = time;
1874                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1875                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1876                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1877                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1878                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1879                 self.chatbubbleentity.model = "";
1880                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1881         }
1882 }
1883
1884
1885 void TeamBubbleThink()
1886 {
1887         self.nextthink = time;
1888         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1889         {
1890                 if(self.owner) // but why can that ever be world?
1891                         self.owner.teambubbleentity = world;
1892                 remove(self);
1893                 return;
1894         }
1895 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1896         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1897                 self.model = "";
1898         else
1899                 self.model = self.mdl;
1900
1901 };
1902
1903 float TeamBubble_customizeentityforclient()
1904 {
1905         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1906 }
1907
1908 void UpdateTeamBubble()
1909 {
1910         if (!self.modelindex || !teams_matter)
1911                 return;
1912         // spawn a teambubble entity if needed
1913         if (!self.teambubbleentity && teams_matter)
1914         {
1915                 self.teambubbleentity = spawn();
1916                 self.teambubbleentity.owner = self;
1917                 self.teambubbleentity.exteriormodeltoclient = self;
1918                 self.teambubbleentity.think = TeamBubbleThink;
1919                 self.teambubbleentity.nextthink = time;
1920                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1921 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1922                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1923                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1924                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1925                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1926                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1927                 self.teambubbleentity.effects = EF_LOWPRECISION;
1928         }
1929 }
1930
1931 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1932 // added to the model skins
1933 /*void UpdateColorModHack()
1934 {
1935         local float c;
1936         c = self.clientcolors & 15;
1937         // LordHavoc: only bothering to support white, green, red, yellow, blue
1938              if (!teams_matter) self.colormod = '0 0 0';
1939         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1940         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1941         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1942         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1943         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1944         else self.colormod = '1 1 1';
1945 };*/
1946
1947 .float oldcolormap;
1948 void respawn(void)
1949 {
1950         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1951         {
1952                 self.solid = SOLID_NOT;
1953                 self.takedamage = DAMAGE_NO;
1954                 self.movetype = MOVETYPE_FLY;
1955                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1956                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1957                 self.effects |= EF_ADDITIVE;
1958                 self.oldcolormap = self.colormap;
1959                 self.colormap = 512;
1960                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1961                 if(autocvar_g_respawn_ghosts_maxtime)
1962                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1963         }
1964
1965         CopyBody(1);
1966         self.effects |= EF_NODRAW; // prevent another CopyBody
1967         if(self.oldcolormap)
1968         {
1969                 self.colormap = self.oldcolormap;
1970                 self.oldcolormap = 0;
1971         }
1972         PutClientInServer();
1973 }
1974
1975 void play_countdown(float finished, string samp)
1976 {
1977         if(clienttype(self) == CLIENTTYPE_REAL)
1978                 if(floor(finished - time - frametime) != floor(finished - time))
1979                         if(finished - time < 6)
1980                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1981 }
1982
1983 /**
1984  * When sv_timeout is used this function returs strings like
1985  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1986  * Called by centerprint functions
1987  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1988  */
1989 string getTimeoutText(float addOneSecond) {
1990         if (!autocvar_sv_timeout || !timeoutStatus)
1991                 return "";
1992
1993         local string retStr;
1994         if (timeoutStatus == 1) {
1995                 if (addOneSecond == 1) {
1996                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1997                 }
1998                 else {
1999                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2000                 }
2001                 return retStr;
2002         }
2003         else if (timeoutStatus == 2) {
2004                 if (addOneSecond) {
2005                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2006                         //don't show messages like "Timeout ends in 0 seconds"...
2007                         if ((remainingTimeoutTime + 1) > 0)
2008                                 return retStr;
2009                         else
2010                                 return "";
2011                 }
2012                 else {
2013                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2014                         //don't show messages like "Timeout ends in 0 seconds"...
2015                         if (remainingTimeoutTime > 0)
2016                                 return retStr;
2017                         else
2018                                 return "";
2019                 }
2020         }
2021         else return "";
2022 }
2023
2024 void player_powerups (void)
2025 {
2026         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2027         olditems = self.items;
2028
2029         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2030         {
2031                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2032                 self.modelflags |= MF_ROCKET;
2033         }
2034         else
2035         {
2036                 SoundEntity_StopSound(self, CHAN_PLAYER);
2037                 self.modelflags &~= MF_ROCKET;
2038         }
2039
2040         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2041
2042         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2043                 return;
2044
2045         Fire_ApplyDamage(self);
2046         Fire_ApplyEffect(self);
2047
2048         if (g_minstagib)
2049         {
2050                 self.effects |= EF_FULLBRIGHT;
2051
2052                 if (self.items & IT_STRENGTH)
2053                 {
2054                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2055                         if (time > self.strength_finished)
2056                         {
2057                                 self.alpha = default_player_alpha;
2058                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2059                                 self.items &~= IT_STRENGTH;
2060                                 sprint(self, "^3Invisibility has worn off\n");
2061                         }
2062                 }
2063                 else
2064                 {
2065                         if (time < self.strength_finished)
2066                         {
2067                                 self.alpha = g_minstagib_invis_alpha;
2068                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2069                                 self.items |= IT_STRENGTH;
2070                                 sprint(self, "^3You are invisible\n");
2071                         }
2072                 }
2073
2074                 if (self.items & IT_INVINCIBLE)
2075                 {
2076                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2077                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2078                         {
2079                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2080                                 sprint(self, "^3Speed has worn off\n");
2081                         }
2082                 }
2083                 else
2084                 {
2085                         if (time < self.invincible_finished)
2086                         {
2087                                 self.items = self.items | IT_INVINCIBLE;
2088                                 sprint(self, "^3You are on speed\n");
2089                         }
2090                 }
2091         }
2092         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2093         {
2094                 if (self.items & IT_STRENGTH)
2095                 {
2096                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2097                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2098                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2099                         {
2100                                 self.items = self.items - (self.items & IT_STRENGTH);
2101                                 sprint(self, "^3Strength has worn off\n");
2102                         }
2103                 }
2104                 else
2105                 {
2106                         if (time < self.strength_finished)
2107                         {
2108                                 self.items = self.items | IT_STRENGTH;
2109                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2110                         }
2111                 }
2112                 if (self.items & IT_INVINCIBLE)
2113                 {
2114                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2115                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2116                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2117                         {
2118                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2119                                 sprint(self, "^3Shield has worn off\n");
2120                         }
2121                 }
2122                 else
2123                 {
2124                         if (time < self.invincible_finished)
2125                         {
2126                                 self.items = self.items | IT_INVINCIBLE;
2127                                 sprint(self, "^3Shield surrounds you\n");
2128                         }
2129                 }
2130
2131                 if(autocvar_g_nodepthtestplayers)
2132                         self.effects = self.effects | EF_NODEPTHTEST;
2133
2134                 if(autocvar_g_fullbrightplayers)
2135                         self.effects = self.effects | EF_FULLBRIGHT;
2136
2137                 // midair gamemode: damage only while in the air
2138                 // if in midair mode, being on ground grants temporary invulnerability
2139                 // (this is so that multishot weapon don't clear the ground flag on the
2140                 // first damage in the frame, leaving the player vulnerable to the
2141                 // remaining hits in the same frame)
2142                 if (self.flags & FL_ONGROUND)
2143                 if (g_midair)
2144                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2145
2146                 if (time >= game_starttime)
2147                 if (time < self.spawnshieldtime)
2148                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2149         }
2150
2151         MUTATOR_CALLHOOK(PlayerPowerups);
2152 }
2153
2154 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2155 {
2156         if(current > stable)
2157                 return current;
2158         else if(current > stable - 0.25) // when close enough, "snap"
2159                 return stable;
2160         else
2161                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2162 }
2163
2164 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2165 {
2166         if(current < stable)
2167                 return current;
2168         else if(current < stable + 0.25) // when close enough, "snap"
2169                 return stable;
2170         else
2171                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2172 }
2173
2174 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2175 {
2176         if(current > rotstable)
2177         {
2178                 if(rotframetime > 0)
2179                 {
2180                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2181                         current = max(rotstable, current - rotlinear * rotframetime);
2182                 }
2183         }
2184         else if(current < regenstable)
2185         {
2186                 if(regenframetime > 0)
2187                 {
2188                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2189                         current = min(regenstable, current + regenlinear * regenframetime);
2190                 }
2191         }
2192
2193         if(current > limit)
2194                 current = limit;
2195
2196         return current;
2197 }
2198
2199 void player_regen (void)
2200 {
2201         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2202         maxh = autocvar_g_balance_health_rotstable;
2203         maxa = autocvar_g_balance_armor_rotstable;
2204         maxf = autocvar_g_balance_fuel_rotstable;
2205         minh = autocvar_g_balance_health_regenstable;
2206         mina = autocvar_g_balance_armor_regenstable;
2207         minf = autocvar_g_balance_fuel_regenstable;
2208         limith = autocvar_g_balance_health_limit;
2209         limita = autocvar_g_balance_armor_limit;
2210         limitf = autocvar_g_balance_fuel_limit;
2211
2212         max_mod = regen_mod = rot_mod = limit_mod = 1;
2213
2214         if (self.runes & RUNE_REGEN)
2215         {
2216                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2217                 {
2218                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2219                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2220                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2221                 }
2222                 else
2223                 {
2224                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2225                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2226                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2227                 }
2228         }
2229         else if (self.runes & CURSE_VENOM)
2230         {
2231                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2232                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2233                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2234                 else
2235                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2236                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2237                 //if (!self.runes & RUNE_REGEN)
2238                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2239         }
2240         maxh = maxh * max_mod;
2241         //maxa = maxa * max_mod;
2242         //maxf = maxf * max_mod;
2243         minh = minh * max_mod;
2244         //mina = mina * max_mod;
2245         //minf = minf * max_mod;
2246         limith = limith * limit_mod;
2247         limita = limita * limit_mod;
2248         //limitf = limitf * limit_mod;
2249
2250         if(g_lms && g_ca)
2251                 rot_mod = 0;
2252
2253         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2254         {
2255                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2256                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2257
2258                 // if player rotted to death...  die!
2259                 if(self.health < 1)
2260                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2261         }
2262
2263         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2264                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2265 }
2266
2267 float zoomstate_set;
2268 void SetZoomState(float z)
2269 {
2270         if(z != self.zoomstate)
2271         {
2272                 self.zoomstate = z;
2273                 ClientData_Touch(self);
2274         }
2275         zoomstate_set = 1;
2276 }
2277
2278 void GetPressedKeys(void) {
2279         MUTATOR_CALLHOOK(GetPressedKeys);
2280         if (self.movement_x > 0) // get if movement keys are pressed
2281         {       // forward key pressed
2282                 self.pressedkeys |= KEY_FORWARD;
2283                 self.pressedkeys &~= KEY_BACKWARD;
2284         }
2285         else if (self.movement_x < 0)
2286         {       // backward key pressed
2287                 self.pressedkeys |= KEY_BACKWARD;
2288                 self.pressedkeys &~= KEY_FORWARD;
2289         }
2290         else
2291         {       // no x input
2292                 self.pressedkeys &~= KEY_FORWARD;
2293                 self.pressedkeys &~= KEY_BACKWARD;
2294         }
2295
2296         if (self.movement_y > 0)
2297         {       // right key pressed
2298                 self.pressedkeys |= KEY_RIGHT;
2299                 self.pressedkeys &~= KEY_LEFT;
2300         }
2301         else if (self.movement_y < 0)
2302         {       // left key pressed
2303                 self.pressedkeys |= KEY_LEFT;
2304                 self.pressedkeys &~= KEY_RIGHT;
2305         }
2306         else
2307         {       // no y input
2308                 self.pressedkeys &~= KEY_RIGHT;
2309                 self.pressedkeys &~= KEY_LEFT;
2310         }
2311
2312         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2313                 self.pressedkeys |= KEY_JUMP;
2314         else
2315                 self.pressedkeys &~= KEY_JUMP;
2316         if (self.BUTTON_CROUCH)
2317                 self.pressedkeys |= KEY_CROUCH;
2318         else
2319                 self.pressedkeys &~= KEY_CROUCH;
2320 }
2321
2322 /*
2323 ======================
2324 spectate mode routines
2325 ======================
2326 */
2327
2328 void SpectateCopy(entity spectatee) {
2329         other = spectatee;
2330         MUTATOR_CALLHOOK(SpectateCopy);
2331         self.armortype = spectatee.armortype;
2332         self.armorvalue = spectatee.armorvalue;
2333         self.ammo_cells = spectatee.ammo_cells;
2334         self.ammo_shells = spectatee.ammo_shells;
2335         self.ammo_nails = spectatee.ammo_nails;
2336         self.ammo_rockets = spectatee.ammo_rockets;
2337         self.ammo_fuel = spectatee.ammo_fuel;
2338         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2339         self.health = spectatee.health;
2340         self.impulse = 0;
2341         self.items = spectatee.items;
2342         self.last_pickup = spectatee.last_pickup;
2343         self.metertime = spectatee.metertime;
2344         self.strength_finished = spectatee.strength_finished;
2345         self.invincible_finished = spectatee.invincible_finished;
2346         self.pressedkeys = spectatee.pressedkeys;
2347         self.weapons = spectatee.weapons;
2348         self.switchweapon = spectatee.switchweapon;
2349         self.weapon = spectatee.weapon;
2350         self.punchangle = spectatee.punchangle;
2351         self.view_ofs = spectatee.view_ofs;
2352         self.v_angle = spectatee.v_angle;
2353         self.velocity = spectatee.velocity;
2354         self.dmg_take = spectatee.dmg_take;
2355         self.dmg_save = spectatee.dmg_save;
2356         self.dmg_inflictor = spectatee.dmg_inflictor;
2357         self.angles = spectatee.v_angle;
2358         self.fixangle = TRUE;
2359         setorigin(self, spectatee.origin);
2360         setsize(self, spectatee.mins, spectatee.maxs);
2361         SetZoomState(spectatee.zoomstate);
2362
2363         anticheat_spectatecopy(spectatee);
2364 }
2365
2366 float SpectateUpdate() {
2367         if(!self.enemy)
2368                 return 0;
2369
2370         if (self == self.enemy)
2371                 return 0;
2372
2373         if(self.enemy.classname != "player")
2374                 return 0;
2375
2376         SpectateCopy(self.enemy);
2377
2378         return 1;
2379 }
2380
2381 float SpectateNext() {
2382         other = find(self.enemy, classname, "player");
2383
2384         if (!other)
2385                 other = find(other, classname, "player");
2386
2387         if (other)
2388                 self.enemy = other;
2389
2390         if(self.enemy.classname == "player") {
2391                 msg_entity = self;
2392                 WriteByte(MSG_ONE, SVC_SETVIEW);
2393                 WriteEntity(MSG_ONE, self.enemy);
2394                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2395                 self.movetype = MOVETYPE_NONE;
2396                 accuracy_resend(self);
2397
2398                 if(!SpectateUpdate())
2399                         PutObserverInServer();
2400
2401                 return 1;
2402         } else {
2403                 return 0;
2404         }
2405 }
2406
2407 /*
2408 =============
2409 ShowRespawnCountdown()
2410
2411 Update a respawn countdown display.
2412 =============
2413 */
2414 void ShowRespawnCountdown()
2415 {
2416         float number;
2417         if(self.deadflag == DEAD_NO) // just respawned?
2418                 return;
2419         else
2420         {
2421                 number = ceil(self.death_time - time);
2422                 if(number <= 0)
2423                         return;
2424                 if(number <= self.respawn_countdown)
2425                 {
2426                         self.respawn_countdown = number - 1;
2427                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2428                                 AnnounceTo(self, strcat(ftos(number), ""));
2429                 }
2430         }
2431 }
2432
2433 void LeaveSpectatorMode()
2434 {
2435         if(isJoinAllowed()) {
2436                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2437                         self.classname = "player";
2438
2439                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2440                                 JoinBestTeam(self, FALSE, TRUE);
2441
2442                         if(autocvar_g_campaign)
2443                                 campaign_bots_may_start = 1;
2444
2445                         PutClientInServer();
2446
2447                         if(self.classname == "player")
2448                                 bprint ("^4", self.netname, "^4 is playing now\n");
2449
2450                         if(!autocvar_g_campaign)
2451                                 centerprint(self,""); // clear MOTD
2452
2453                         return;
2454                 } else {
2455                         if (g_ca && self.caplayer) {
2456                         }       // do nothing
2457                         else
2458                                 stuffcmd(self,"menu_showteamselect\n");
2459                         return;
2460                 }
2461         }
2462         else {
2463                 //player may not join because of g_maxplayers is set
2464                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2465         }
2466 }
2467
2468 /**
2469  * Determines whether the player is allowed to join. This depends on cvar
2470  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2471  * it checks whether the number of currently playing players exceeds g_maxplayers.
2472  * @return bool TRUE if the player is allowed to join, false otherwise
2473  */
2474 float isJoinAllowed() {
2475         if(self.team_forced < 0)
2476                 return FALSE; // forced spectators can never join
2477
2478         if (!autocvar_g_maxplayers)
2479                 return TRUE;
2480
2481         local entity e;
2482         local float currentlyPlaying;
2483         FOR_EACH_REALPLAYER(e) {
2484                 if(e.classname == "player")
2485                         currentlyPlaying += 1;
2486         }
2487         if(currentlyPlaying < autocvar_g_maxplayers)
2488                 return TRUE;
2489
2490         return FALSE;
2491 }
2492
2493 /**
2494  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2495  * g_maxplayers_spectator_blocktime seconds
2496  */
2497 void checkSpectatorBlock() {
2498         if(self.classname == "spectator" || self.classname == "observer") {
2499                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2500                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2501                         dropclient(self);
2502                 }
2503         }
2504 }
2505
2506 void ObserverThink()
2507 {
2508         if (self.flags & FL_JUMPRELEASED) {
2509                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2510                         self.welcomemessage_time = 0;
2511                         self.flags &~= FL_JUMPRELEASED;
2512                         self.flags |= FL_SPAWNING;
2513                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2514                         self.welcomemessage_time = 0;
2515                         self.flags &~= FL_JUMPRELEASED;
2516                         if(SpectateNext() == 1) {
2517                                 self.classname = "spectator";
2518                         }
2519                 }
2520         } else {
2521                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2522                         self.flags |= FL_JUMPRELEASED;
2523                         if(self.flags & FL_SPAWNING)
2524                         {
2525                                 self.flags &~= FL_SPAWNING;
2526                                 LeaveSpectatorMode();
2527                                 return;
2528                         }
2529                 }
2530         }
2531         PrintWelcomeMessage(self);
2532 }
2533
2534 void SpectatorThink()
2535 {
2536         if (self.flags & FL_JUMPRELEASED) {
2537                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2538                         self.welcomemessage_time = 0;
2539                         self.flags &~= FL_JUMPRELEASED;
2540                         self.flags |= FL_SPAWNING;
2541                 } else if(self.BUTTON_ATCK) {
2542                         self.welcomemessage_time = 0;
2543                         self.flags &~= FL_JUMPRELEASED;
2544                         if(SpectateNext() == 1) {
2545                                 self.classname = "spectator";
2546                         } else {
2547                                 self.classname = "observer";
2548                                 PutClientInServer();
2549                         }
2550                 } else if (self.BUTTON_ATCK2) {
2551                         self.welcomemessage_time = 0;
2552                         self.flags &~= FL_JUMPRELEASED;
2553                         self.classname = "observer";
2554                         PutClientInServer();
2555                 } else {
2556                         if(!SpectateUpdate())
2557                                 PutObserverInServer();
2558                 }
2559         } else {
2560                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2561                         self.flags |= FL_JUMPRELEASED;
2562                         if(self.flags & FL_SPAWNING)
2563                         {
2564                                 self.flags &~= FL_SPAWNING;
2565                                 LeaveSpectatorMode();
2566                                 return;
2567                         }
2568                 }
2569         }
2570
2571         PrintWelcomeMessage(self);
2572         self.flags |= FL_CLIENT | FL_NOTARGET;
2573 }
2574
2575 .float touchexplode_time;
2576
2577 /*
2578 =============
2579 PlayerPreThink
2580
2581 Called every frame for each client before the physics are run
2582 =============
2583 */
2584 void() ctf_setstatus;
2585 void() nexball_setstatus;
2586 .float items_added;
2587 void PlayerPreThink (void)
2588 {
2589         self.stat_game_starttime = game_starttime;
2590         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2591         self.stat_leadlimit = autocvar_leadlimit;
2592
2593         if(frametime)
2594         {
2595                 // physics frames: update anticheat stuff
2596                 anticheat_prethink();
2597         }
2598
2599         if(blockSpectators && frametime)
2600                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2601                 checkSpectatorBlock();
2602
2603         zoomstate_set = 0;
2604
2605         if(self.netname_previous != self.netname)
2606         {
2607                 if(autocvar_sv_eventlog)
2608                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2609                 if(self.netname_previous)
2610                         strunzone(self.netname_previous);
2611                 self.netname_previous = strzone(self.netname);
2612         }
2613
2614         // version nagging
2615         if(self.version_nagtime)
2616                 if(self.cvar_g_xonoticversion)
2617                         if(time > self.version_nagtime)
2618                         {
2619                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2620                                 {
2621                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2622                                         {
2623                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2624                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2625                                         }
2626                                         else
2627                                         {
2628                                                 float r;
2629                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2630                                                 if(r < 0)
2631                                                 {
2632                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2633                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2634                                                 }
2635                                                 else if(r > 0)
2636                                                 {
2637                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2638                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2639                                                 }
2640                                         }
2641                                 }
2642                                 self.version_nagtime = 0;
2643                         }
2644
2645         // GOD MODE info
2646         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2647         {
2648                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2649                 self.max_armorvalue = 0;
2650         }
2651
2652 #ifdef TETRIS
2653         if (TetrisPreFrame())
2654                 return;
2655 #endif
2656
2657         MUTATOR_CALLHOOK(PlayerPreThink);
2658
2659         if(self.classname == "player") {
2660 //              if(self.netname == "Wazat")
2661 //                      bprint(self.classname, "\n");
2662
2663                 CheckRules_Player();
2664
2665                 PrintWelcomeMessage(self);
2666
2667                 if (intermission_running)
2668                 {
2669                         IntermissionThink ();   // otherwise a button could be missed between
2670                         return;                                 // the think tics
2671                 }
2672
2673                 if(self.teleport_time)
2674                 if(time > self.teleport_time)
2675                 {
2676                         self.teleport_time = 0;
2677                         self.effects = self.effects - (self.effects & EF_NODRAW);
2678                 }
2679
2680                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2681                         UpdateSelectedPlayer();
2682
2683                 //don't allow the player to turn around while game is paused!
2684                 if(timeoutStatus == 2) {
2685                         self.v_angle = self.lastV_angle;
2686                         self.angles = self.lastV_angle;
2687                         self.fixangle = TRUE;
2688                 }
2689
2690                 if(frametime)
2691                 {
2692                         if(self.health <= 0 && autocvar_g_deathglow)
2693                         {
2694                                 if(self.glowmod_x > 0)
2695                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2696                                 else
2697                                         self.glowmod_x = -1;
2698                                 if(self.glowmod_y > 0)
2699                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2700                                 else
2701                                         self.glowmod_y = -1;
2702                                 if(self.glowmod_z > 0)
2703                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2704                                 else
2705                                         self.glowmod_z = -1;
2706                         }
2707                         else
2708                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2709                         player_powerups();
2710                 }
2711
2712                 if (self.deadflag != DEAD_NO)
2713                 {
2714                         float button_pressed, force_respawn;
2715                         if(self.personal && g_race_qualifying)
2716                         {
2717                                 if(time > self.death_time)
2718                                 {
2719                                         self.death_time = time + 1; // only retry once a second
2720                                         respawn();
2721                                         self.impulse = 141;
2722                                 }
2723                         }
2724                         else
2725                         {
2726                                 if(frametime)
2727                                         player_anim();
2728                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2729                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2730                                 if (self.deadflag == DEAD_DYING)
2731                                 {
2732                                         if(force_respawn)
2733                                                 self.deadflag = DEAD_RESPAWNING;
2734                                         else if(!button_pressed)
2735                                                 self.deadflag = DEAD_DEAD;
2736                                 }
2737                                 else if (self.deadflag == DEAD_DEAD)
2738                                 {
2739                                         if(button_pressed)
2740                                                 self.deadflag = DEAD_RESPAWNABLE;
2741                                 }
2742                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2743                                 {
2744                                         if(!button_pressed)
2745                                                 self.deadflag = DEAD_RESPAWNING;
2746                                 }
2747                                 else if (self.deadflag == DEAD_RESPAWNING)
2748                                 {
2749                                         if(time > self.death_time)
2750                                         {
2751                                                 self.death_time = time + 1; // only retry once a second
2752                                                 respawn();
2753                                         }
2754                                 }
2755                                 ShowRespawnCountdown();
2756                         }
2757                         return;
2758                 }
2759
2760                 if(g_touchexplode)
2761                 if(time > self.touchexplode_time)
2762                 if(self.classname == "player")
2763                 if(self.deadflag == DEAD_NO)
2764                 if not(IS_INDEPENDENT_PLAYER(self))
2765                 FOR_EACH_PLAYER(other) if(self != other)
2766                 {
2767                         if(time > other.touchexplode_time)
2768                         if(other.deadflag == DEAD_NO)
2769                         if not(IS_INDEPENDENT_PLAYER(other))
2770                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2771                         {
2772                                 PlayerTouchExplode(self, other);
2773                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2774                         }
2775                 }
2776
2777                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2778                 {
2779                         vector dist;
2780
2781                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2782                         dist = self.prevorigin - self.origin;
2783                         dist_z = 0;
2784                         self.lms_traveled_distance += fabs(vlen(dist));
2785
2786                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2787                         {
2788                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2789                                 self.lms_traveled_distance = 0;
2790                         }
2791
2792                         if(time > self.lms_nextcheck)
2793                         {
2794                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2795                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2796                                 {
2797                                         centerprint(self, autocvar_g_lms_campcheck_message);
2798                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2799                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2800                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2801                                 }
2802                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2803                                 self.lms_traveled_distance = 0;
2804                         }
2805                 }
2806
2807                 self.prevorigin = self.origin;
2808
2809                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2810                 {
2811                         if (!self.crouch)
2812                         {
2813                                 self.crouch = TRUE;
2814                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2815                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2816                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2817                         }
2818                 }
2819                 else
2820                 {
2821                         if (self.crouch)
2822                         {
2823                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2824                                 if (!trace_startsolid)
2825                                 {
2826                                         self.crouch = FALSE;
2827                                         self.view_ofs = PL_VIEW_OFS;
2828                                         setsize (self, PL_MIN, PL_MAX);
2829                                 }
2830                         }
2831                 }
2832
2833                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2834                 {
2835                         if(self.bloodloss_timer < time)
2836                         {
2837                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2838                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2839                         }
2840                 }
2841
2842                 FixPlayermodel();
2843
2844                 GrapplingHookFrame();
2845
2846                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2847                 //if(frametime)
2848                 {
2849                         self.items &~= self.items_added;
2850
2851                         W_WeaponFrame();
2852
2853                         self.items_added = 0;
2854                         if(self.items & IT_JETPACK)
2855                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2856                                         self.items_added |= IT_FUEL;
2857
2858                         self.items |= self.items_added;
2859                 }
2860
2861                 player_regen();
2862
2863                 // rot nex charge to the charge limit
2864                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2865                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2866
2867                 if(frametime)
2868                         player_anim();
2869
2870                 if (g_minstagib)
2871                         minstagib_ammocheck();
2872
2873                 if(g_ctf)
2874                         ctf_setstatus();
2875
2876                 if(g_nexball)
2877                         nexball_setstatus();
2878
2879                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2880
2881                 //self.angles_y=self.v_angle_y + 90;   // temp
2882         } else if(gameover) {
2883                 if (intermission_running)
2884                         IntermissionThink ();   // otherwise a button could be missed between
2885                 return;
2886         } else if(self.classname == "observer") {
2887                 ObserverThink();
2888         } else if(self.classname == "spectator") {
2889                 SpectatorThink();
2890         }
2891
2892         if(!zoomstate_set)
2893                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && autocvar_g_balance_campingrifle_secondary == 0));
2894
2895         float oldspectatee_status;
2896         oldspectatee_status = self.spectatee_status;
2897         if(self.classname == "spectator")
2898                 self.spectatee_status = num_for_edict(self.enemy);
2899         else if(self.classname == "observer")
2900                 self.spectatee_status = num_for_edict(self);
2901         else
2902                 self.spectatee_status = 0;
2903         if(self.spectatee_status != oldspectatee_status)
2904         {
2905                 ClientData_Touch(self);
2906                 if(g_race || g_cts)
2907                         race_InitSpectator();
2908         }
2909
2910         if(self.teamkill_soundtime)
2911         if(time > self.teamkill_soundtime)
2912         {
2913                 self.teamkill_soundtime = 0;
2914
2915                 entity oldpusher, oldself;
2916
2917                 oldself = self; self = self.teamkill_soundsource;
2918                 oldpusher = self.pusher; self.pusher = oldself;
2919
2920                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2921
2922                 self.pusher = oldpusher;
2923                 self = oldself;
2924         }
2925
2926         if(self.taunt_soundtime)
2927         if(time > self.taunt_soundtime)
2928         {
2929                 self.taunt_soundtime = 0;
2930                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2931         }
2932
2933         target_voicescript_next(self);
2934 }
2935
2936 float isInvisibleString(string s)
2937 {
2938         float i, n, c;
2939         s = strdecolorize(s);
2940         for((i = 0), (n = strlen(s)); i < n; ++i)
2941         {
2942                 c = str2chr(s, i);
2943                 switch(c)
2944                 {
2945                         case 0:
2946                         case 32: // space
2947                                 break;
2948                         case 192: // charmap space
2949                                 if (!autocvar_utf8_enable)
2950                                         break;
2951                                 return FALSE;
2952                         case 160: // space in unicode fonts
2953                         case 0xE000 + 192: // utf8 charmap space
2954                                 if (autocvar_utf8_enable)
2955                                         break;
2956                         default:
2957                                 return FALSE;
2958                 }
2959         }
2960         return TRUE;
2961 }
2962
2963 /*
2964 =============
2965 PlayerPostThink
2966
2967 Called every frame for each client after the physics are run
2968 =============
2969 */
2970 .float idlekick_lasttimeleft;
2971 .entity showheadshotbbox;
2972 void showheadshotbbox_think()
2973 {
2974         if(self.owner.showheadshotbbox != self)
2975         {
2976                 remove(self);
2977                 return;
2978         }
2979         self.nextthink = time;
2980         setorigin(self, self.owner.origin);
2981         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2982 }
2983 void PlayerPostThink (void)
2984 {
2985         // Savage: Check for nameless players
2986         if (isInvisibleString(self.netname)) {
2987                 self.netname = "Player";
2988                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2989         }
2990
2991         if(sv_maxidle && frametime)
2992         {
2993                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2994                 float timeleft;
2995                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2996                 if(timeleft <= 0)
2997                 {
2998                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2999                         AnnounceTo(self, "terminated");
3000                         dropclient(self);
3001                         return;
3002                 }
3003                 else if(timeleft <= 10)
3004                 {
3005                         if(timeleft != self.idlekick_lasttimeleft)
3006                         {
3007                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3008                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3009                         }
3010                 }
3011                 else
3012                 {
3013                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3014                 }
3015                 self.idlekick_lasttimeleft = timeleft;
3016         }
3017
3018 #ifdef TETRIS
3019         if(self.impulse == 100)
3020                 ImpulseCommands();
3021         if (TetrisPostFrame())
3022                 return;
3023 #endif
3024
3025         CheatFrame();
3026
3027         if(self.classname == "player") {
3028                 CheckRules_Player();
3029                 UpdateChatBubble();
3030                 UpdateTeamBubble();
3031                 if (self.impulse)
3032                         ImpulseCommands();
3033                 if (intermission_running)
3034                         return;         // intermission or finale
3035                 GetPressedKeys();
3036         } else if (self.classname == "observer") {
3037                 //do nothing
3038         } else if (self.classname == "spectator") {
3039                 //do nothing
3040         }
3041
3042         /*
3043         float i;
3044         for(i = 0; i < 1000; ++i)
3045         {
3046                 vector end;
3047                 end = self.origin + '0 0 1024' + 512 * randomvec();
3048                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3049                 if(trace_fraction < 1)
3050                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3051                 {
3052                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3053                         break;
3054                 }
3055         }
3056         */
3057
3058         Arena_Warmup();
3059
3060         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3061
3062         if(self.waypointsprite_attachedforcarrier)
3063                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3064
3065         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3066         {
3067                 if(!self.showheadshotbbox)
3068                 {
3069                         self.showheadshotbbox = spawn();
3070                         self.showheadshotbbox.classname = "headshotbbox";
3071                         self.showheadshotbbox.owner = self;
3072                         self.showheadshotbbox.think = showheadshotbbox_think;
3073                         self.showheadshotbbox.nextthink = time;
3074                         self = self.showheadshotbbox;
3075                         self.think();
3076                         self = self.owner;
3077                 }
3078         }
3079         else
3080         {
3081                 if(self.showheadshotbbox)
3082                         remove(self.showheadshotbbox);
3083         }
3084
3085         playerdemo_write();
3086
3087         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3088         {
3089                 if(!self.stored_netname)
3090                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3091                 if(self.stored_netname != self.netname)
3092                 {
3093                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3094                         strunzone(self.stored_netname);
3095                         self.stored_netname = strzone(self.netname);
3096                 }
3097         }
3098
3099         /*
3100         if(g_race)
3101                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3102         */
3103 }