qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!warmup_stage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         self.weapons = '0 0 0';
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                 {
 301                         defaultmodel = argv(floor(n * self.model_randomizer));
 302                         // However, do NOT randomize if the player-selected model is in the list.
 303                         for (i = 0; i < n; ++i)
 304                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 305                                         defaultmodel = argv(i);
 306                 }
 307
 308                 i = strstrofs(defaultmodel, ":", 0);
 309                 if(i >= 0)
 310                 {
 311                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 312                         defaultmodel = substring(defaultmodel, 0, i);
 313                 }
 314         }
 315
 316         if(defaultmodel != "")
 317         {
 318                 if (defaultmodel != self.model)
 319                 {
 320                         m1 = self.mins;
 321                         m2 = self.maxs;
 322                         setplayermodel (self, defaultmodel);
 323                         setsize (self, m1, m2);
 324                         chmdl = TRUE;
 325                 }
 326
 327                 oldskin = self.skin;
 328                 self.skin = defaultskin;
 329         } else {
 330                 if (self.playermodel != self.model || self.playermodel == "")
 331                 {
 332                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 333                         m1 = self.mins;
 334                         m2 = self.maxs;
 335                         setplayermodel (self, self.playermodel);
 336                         setsize (self, m1, m2);
 337                         chmdl = TRUE;
 338                 }
 339
 340                 oldskin = self.skin;
 341                 self.skin = stof(self.playerskin);
 342         }
 343
 344         if(chmdl || oldskin != self.skin) // model or skin has changed
 345         {
 346                 self.species = player_getspecies(); // update species
 347                 UpdatePlayerSounds(); // update skin sounds
 348         }
 349
 350         if(!teamplay)
 351                 if(strlen(autocvar_sv_defaultplayercolors))
 352                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 353                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 354 }
 355
 356 /*
 357 =============
 358 PutClientInServer
 359
 360 Called when a client spawns in the server
 361 =============
 362 */
 363 void PutClientInServer (void)
 364 {
 365         if(IS_BOT_CLIENT(self))
 366                 self.classname = "player";
 367         else if(IS_REAL_CLIENT(self))
 368         {
 369                 msg_entity = self;
 370                 WriteByte(MSG_ONE, SVC_SETVIEW);
 371                 WriteEntity(MSG_ONE, self);
 372         }
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 race_PreSpawn();
 393
 394                 spot = SelectSpawnPoint (FALSE);
 395                 if(!spot)
 396                 {
 397                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 398                         return; // spawn failed
 399                 }
 400
 401                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 402
 403                 self.classname = "player";
 404                 self.wasplayer = TRUE;
 405                 self.iscreature = TRUE;
 406                 self.teleportable = TELEPORT_NORMAL;
 407                 self.damagedbycontents = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 411                 if(autocvar_g_playerclip_collisions)
 412                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 413                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 414                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 415                 self.frags = FRAGS_PLAYER;
 416                 if(INDEPENDENT_PLAYERS)
 417                         MAKE_INDEPENDENT_PLAYER(self);
 418                 self.flags = FL_CLIENT;
 419                 if(autocvar__notarget)
 420                         self.flags |= FL_NOTARGET;
 421                 self.takedamage = DAMAGE_AIM;
 422                 self.effects = 0;
 423                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 424                 self.air_finished = time + 12;
 425                 self.dmg = 2;
 426                 if(autocvar_g_balance_nex_charge)
 427                 {
 428                         if(autocvar_g_balance_nex_secondary_chargepool)
 429                                 self.nex_chargepool_ammo = 1;
 430                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 431                 }
 432
 433                 if(warmup_stage)
 434                 {
 435                         self.ammo_shells = warmup_start_ammo_shells;
 436                         self.ammo_nails = warmup_start_ammo_nails;
 437                         self.ammo_rockets = warmup_start_ammo_rockets;
 438                         self.ammo_cells = warmup_start_ammo_cells;
 439                         self.ammo_fuel = warmup_start_ammo_fuel;
 440                         self.health = warmup_start_health;
 441                         self.armorvalue = warmup_start_armorvalue;
 442                         self.weapons = WARMUP_START_WEAPONS;
 443                 }
 444                 else
 445                 {
 446                         self.ammo_shells = start_ammo_shells;
 447                         self.ammo_nails = start_ammo_nails;
 448                         self.ammo_rockets = start_ammo_rockets;
 449                         self.ammo_cells = start_ammo_cells;
 450                         self.ammo_fuel = start_ammo_fuel;
 451                         self.health = start_health;
 452                         self.armorvalue = start_armorvalue;
 453                         self.weapons = start_weapons;
 454                 }
 455
 456                 if(self.weapons & WEPSET_SUPERWEAPONS)
 457                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 458                 else
 459                         self.superweapons_finished = 0;
 460
 461                 if(g_weaponarena_random)
 462                 {
 463                         if(g_weaponarena_random_with_laser)
 464                                 self.weapons &= ~WEPSET_LASER;
 465                         W_RandomWeapons(self, g_weaponarena_random);
 466                         if(g_weaponarena_random_with_laser)
 467                                 self.weapons |= WEPSET_LASER;
 468                 }
 469
 470                 self.items = start_items;
 471
 472                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 473                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 474                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 475                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 476                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 477                 //extend the pause of rotting if client was reset at the beginning of the countdown
 478                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 479                         self.spawnshieldtime += game_starttime - time;
 480                         self.pauserotarmor_finished += game_starttime - time;
 481                         self.pauserothealth_finished += game_starttime - time;
 482                         self.pauseregen_finished += game_starttime - time;
 483                 }
 484                 self.damageforcescale = 2;
 485                 self.death_time = 0;
 486                 self.respawn_flags = 0;
 487                 self.respawn_time = 0;
 488                 self.stat_respawn_time = 0;
 489                 self.scale = 0;
 490                 self.fade_time = 0;
 491                 self.pain_frame = 0;
 492                 self.pain_finished = 0;
 493                 self.strength_finished = 0;
 494                 self.invincible_finished = 0;
 495                 self.pushltime = 0;
 496                 // players have no think function
 497                 self.think = func_null;
 498                 self.nextthink = 0;
 499                 self.hook_time = 0;
 500                 self.dmg_team = 0;
 501                 self.ballistics_density = autocvar_g_ballistics_density_player;
 502
 503                 self.metertime = 0;
 504
 505                 self.deadflag = DEAD_NO;
 506
 507                 self.angles = spot.angles;
 508
 509                 self.angles_z = 0; // never spawn tilted even if the spot says to
 510                 self.fixangle = TRUE; // turn this way immediately
 511                 self.velocity = '0 0 0';
 512                 self.avelocity = '0 0 0';
 513                 self.punchangle = '0 0 0';
 514                 self.punchvector = '0 0 0';
 515                 self.oldvelocity = self.velocity;
 516                 self.fire_endtime = -1;
 517
 518                 entity spawnevent = spawn();
 519                 spawnevent.owner = self;
 520                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 521
 522                 self.model = "";
 523                 FixPlayermodel();
 524                 self.drawonlytoclient = world;
 525
 526                 self.crouch = FALSE;
 527                 self.view_ofs = PL_VIEW_OFS;
 528                 setsize (self, PL_MIN, PL_MAX);
 529                 self.spawnorigin = spot.origin;
 530                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 531                 // don't reset back to last position, even if new position is stuck in solid
 532                 self.oldorigin = self.origin;
 533                 self.prevorigin = self.origin;
 534                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 535                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 536         self.hud = HUD_NORMAL;
 537
 538                 self.event_damage = PlayerDamage;
 539
 540                 self.bot_attack = TRUE;
 541
 542                 self.statdraintime = time + 5;
 543                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 544
 545                 if(self.killcount == -666) {
 546                         PlayerScore_Clear(self);
 547                         self.killcount = 0;
 548                 }
 549
 550                 CL_SpawnWeaponentity();
 551                 self.alpha = default_player_alpha;
 552                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 553                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 554
 555                 self.speedrunning = FALSE;
 556
 557                 race_PostSpawn(spot);
 558
 559                 //stuffcmd(self, "chase_active 0");
 560                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 561
 562                 target_voicescript_clear(self);
 563
 564                 // reset fields the weapons may use
 565                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 566                 {
 567                         weapon_action(j, WR_RESETPLAYER);
 568
 569                         // all weapons must be fully loaded when we spawn
 570                         entity e;
 571                         e = get_weaponinfo(j);
 572                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 573                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 574                 }
 575
 576                 oldself = self;
 577                 self = spot;
 578                         activator = oldself;
 579                                 string s;
 580                                 s = self.target;
 581                                 self.target = string_null;
 582                                 SUB_UseTargets();
 583                                 self.target = s;
 584                         activator = world;
 585                 self = oldself;
 586
 587                 spawn_spot = spot;
 588                 MUTATOR_CALLHOOK(PlayerSpawn);
 589
 590                 if(autocvar_spawn_debug)
 591                 {
 592                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 593                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 594                 }
 595
 596                 self.switchweapon = w_getbestweapon(self);
 597                 self.cnt = -1; // W_LastWeapon will not complain
 598                 self.weapon = 0;
 599                 self.weaponname = "";
 600                 self.switchingweapon = 0;
 601
 602                 if(!warmup_stage)
 603                         if(!self.alivetime)
 604                                 self.alivetime = time;
 605
 606                 antilag_clear(self);
 607         }
 608         else if(IS_OBSERVER(self))
 609         {
 610                 PutObserverInServer ();
 611         }
 612 }
 613
 614 .float ebouncefactor, ebouncestop; // electro's values
 615 // TODO do we need all these fields, or should we stop autodetecting runtime
 616 // changes and just have a console command to update this?
 617 float ClientInit_SendEntity(entity to, float sf)
 618 {
 619         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 620         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 633         if(sv_foginterval && world.fog != "")
 634                 WriteString(MSG_ENTITY, world.fog);
 635         else
 636                 WriteString(MSG_ENTITY, "");
 637         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 638         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 639         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 640         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 641         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 642         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 644         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 645         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 647         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 649         return TRUE;
 650 }
 651
 652 void ClientInit_CheckUpdate()
 653 {
 654         self.nextthink = time;
 655         if(self.count != autocvar_g_balance_armor_blockpercent)
 656         {
 657                 self.count = autocvar_g_balance_armor_blockpercent;
 658                 self.SendFlags |= 1;
 659         }
 660         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 661         {
 662                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 666         {
 667                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 671         {
 672                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 673                 self.SendFlags |= 1;
 674         }
 675         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 676         {
 677                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 678                 self.SendFlags |= 1;
 679         }
 680 }
 681
 682 void ClientInit_Spawn()
 683 {
 684         entity o;
 685         entity e;
 686         e = spawn();
 687         e.classname = "clientinit";
 688         e.think = ClientInit_CheckUpdate;
 689         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 690
 691         o = self;
 692         self = e;
 693         ClientInit_CheckUpdate();
 694         self = o;
 695 }
 696
 697 /*
 698 =============
 699 SetNewParms
 700 =============
 701 */
 702 void SetNewParms (void)
 703 {
 704         // initialize parms for a new player
 705         parm1 = -(86400 * 366);
 706 }
 707
 708 /*
 709 =============
 710 SetChangeParms
 711 =============
 712 */
 713 void SetChangeParms (void)
 714 {
 715         // save parms for level change
 716         parm1 = self.parm_idlesince - time;
 717 }
 718
 719 /*
 720 =============
 721 DecodeLevelParms
 722 =============
 723 */
 724 void DecodeLevelParms (void)
 725 {
 726         // load parms
 727         self.parm_idlesince = parm1;
 728         if(self.parm_idlesince == -(86400 * 366))
 729                 self.parm_idlesince = time;
 730
 731         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 732         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 733 }
 734
 735 /*
 736 =============
 737 ClientKill
 738
 739 Called when a client types 'kill' in the console
 740 =============
 741 */
 742
 743 .float clientkill_nexttime;
 744 void ClientKill_Now_TeamChange()
 745 {
 746         if(self.killindicator_teamchange == -1)
 747         {
 748                 JoinBestTeam( self, FALSE, TRUE );
 749         }
 750         else if(self.killindicator_teamchange == -2)
 751         {
 752                 if(blockSpectators)
 753                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 754                 PutObserverInServer();
 755         }
 756         else
 757                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 758         self.killindicator_teamchange = 0;
 759 }
 760
 761 void ClientKill_Now()
 762 {
 763         if(self.vehicle)
 764         {
 765             vehicles_exit(VHEF_RELESE);
 766             if(!self.killindicator_teamchange)
 767             {
 768             self.vehicle_health = -1;
 769             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 770             }
 771         }
 772
 773         if(self.killindicator && !wasfreed(self.killindicator))
 774                 remove(self.killindicator);
 775
 776         self.killindicator = world;
 777
 778         if(self.killindicator_teamchange)
 779                 ClientKill_Now_TeamChange();
 780
 781         // in any case:
 782         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 783
 784         // now I am sure the player IS dead
 785 }
 786 void KillIndicator_Think()
 787 {
 788         if (gameover)
 789         {
 790                 self.owner.killindicator = world;
 791                 remove(self);
 792                 return;
 793         }
 794
 795         if (self.owner.alpha < 0 && !self.owner.vehicle)
 796         {
 797                 self.owner.killindicator = world;
 798                 remove(self);
 799                 return;
 800         }
 801
 802         if(self.cnt <= 0)
 803         {
 804                 self = self.owner;
 805                 ClientKill_Now(); // no oldself needed
 806                 return;
 807         }
 808     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 809     {
 810         self.nextthink = time + 1;
 811         self.cnt -= 1;
 812     }
 813         else
 814         {
 815                 if(self.cnt <= 10)
 816                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 817                 if(IS_REAL_CLIENT(self.owner))
 818                 {
 819                         if(self.cnt <= 10)
 820                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 821                 }
 822                 self.nextthink = time + 1;
 823                 self.cnt -= 1;
 824         }
 825 }
 826
 827 float clientkilltime;
 828 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 829 {
 830         float killtime;
 831         float starttime;
 832         entity e;
 833
 834         if (gameover)
 835                 return;
 836
 837         killtime = autocvar_g_balance_kill_delay;
 838
 839         if(g_race_qualifying || g_cts)
 840                 killtime = 0;
 841
 842     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 843     {
 844                 remove(self.killindicator);
 845                 self.killindicator = world;
 846
 847         ClientKill_Now(); // allow instant kill in this case
 848         return;
 849     }
 850
 851         self.killindicator_teamchange = targetteam;
 852
 853     if(!self.killindicator)
 854         {
 855                 if(self.deadflag == DEAD_NO)
 856                 {
 857                         killtime = max(killtime, self.clientkill_nexttime - time);
 858                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 859                 }
 860
 861                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 862                 {
 863                         ClientKill_Now();
 864                 }
 865                 else
 866                 {
 867                         starttime = max(time, clientkilltime);
 868
 869                         self.killindicator = spawn();
 870                         self.killindicator.owner = self;
 871                         self.killindicator.scale = 0.5;
 872                         setattachment(self.killindicator, self, "");
 873                         setorigin(self.killindicator, '0 0 52');
 874                         self.killindicator.think = KillIndicator_Think;
 875                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 876                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 877                         self.killindicator.cnt = ceil(killtime);
 878                         self.killindicator.count = bound(0, ceil(killtime), 10);
 879                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 880
 881                         for(e = world; (e = find(e, classname, "body")) != world; )
 882                         {
 883                                 if(e.enemy != self)
 884                                         continue;
 885                                 e.killindicator = spawn();
 886                                 e.killindicator.owner = e;
 887                                 e.killindicator.scale = 0.5;
 888                                 setattachment(e.killindicator, e, "");
 889                                 setorigin(e.killindicator, '0 0 52');
 890                                 e.killindicator.think = KillIndicator_Think;
 891                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 892                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 893                                 e.killindicator.cnt = ceil(killtime);
 894                         }
 895                         self.lip = 0;
 896                 }
 897         }
 898         if(self.killindicator)
 899         {
 900                 if(targetteam == 0) // just die
 901                 {
 902                         self.killindicator.colormod = '0 0 0';
 903                         if(IS_REAL_CLIENT(self))
 904                         if(self.killindicator.cnt > 0)
 905                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 906                 }
 907                 else if(targetteam == -1) // auto
 908                 {
 909                         self.killindicator.colormod = '0 1 0';
 910                         if(IS_REAL_CLIENT(self))
 911                         if(self.killindicator.cnt > 0)
 912                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 913                 }
 914                 else if(targetteam == -2) // spectate
 915                 {
 916                         self.killindicator.colormod = '0.5 0.5 0.5';
 917                         if(IS_REAL_CLIENT(self))
 918                         if(self.killindicator.cnt > 0)
 919                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 920                 }
 921                 else
 922                 {
 923                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 924                         if(IS_REAL_CLIENT(self))
 925                         if(self.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 927                 }
 928         }
 929
 930 }
 931
 932 void ClientKill (void)
 933 {
 934         if(gameover) return;
 935         if(self.player_blocked) return;
 936         if(self.freezetag_frozen) return;
 937
 938         ClientKill_TeamChange(0);
 939 }
 940
 941 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 942 {
 943     e.killindicator = spawn();
 944     e.killindicator.owner = e;
 945     e.killindicator.think = KillIndicator_Think;
 946     e.killindicator.nextthink = time + (e.lip) * 0.05;
 947     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 948     e.killindicator.health = 1; // this is used to indicate that it should be silent
 949     e.lip = 0;
 950 }
 951
 952 void FixClientCvars(entity e)
 953 {
 954         // send prediction settings to the client
 955         stuffcmd(e, "\nin_bindmap 0 0\n");
 956         if(g_race || g_cts)
 957                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 958         if(autocvar_g_antilag == 3) // client side hitscan
 959                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 960         if(autocvar_sv_gentle)
 961                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 962         /*
 963          * we no longer need to stuff this. Remove this comment block if you feel
 964          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 965         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 966         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 967         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 968         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 969         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 970         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 971         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 972         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 973         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 975         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 976         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 977         stuffcmd(e, "cl_movement_edgefriction 1\n");
 978          */
 979 }
 980
 981 float PlayerInIDList(entity p, string idlist)
 982 {
 983         float n, i;
 984         string s;
 985
 986         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 987         if not(p.crypto_idfp)
 988                 return 0;
 989
 990         // this function allows abbreviated player IDs too!
 991         n = tokenize_console(idlist);
 992         for(i = 0; i < n; ++i)
 993         {
 994                 s = argv(i);
 995                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 996                         return 1;
 997         }
 998
 999         return 0;
1000 }
1001
1002 /*
1003 =============
1004 ClientConnect
1005
1006 Called when a client connects to the server
1007 =============
1008 */
1009 void DecodeLevelParms (void);
1010 //void dom_player_join_team(entity pl);
1011 void set_dom_state(entity e);
1012 void ClientConnect (void)
1013 {
1014         float t;
1015
1016         if(IS_CLIENT(self))
1017         {
1018                 print("Warning: ClientConnect, but already connected!\n");
1019                 return;
1020         }
1021
1022         if(Ban_MaybeEnforceBanOnce(self))
1023                 return;
1024
1025         DecodeLevelParms();
1026
1027 #ifdef WATERMARK
1028         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1029 #endif
1030
1031         self.classname = "player_joining";
1032
1033         self.flags = FL_CLIENT;
1034         self.version_nagtime = time + 10 + random() * 10;
1035
1036         if(player_count<0)
1037         {
1038                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1039                 player_count = 0;
1040         }
1041
1042         PlayerInfo_Basic(self);
1043         PlayerScore_Attach(self);
1044         ClientData_Attach();
1045         accuracy_init(self);
1046
1047         bot_clientconnect();
1048
1049         playerdemo_init();
1050
1051         anticheat_init();
1052
1053         race_PreSpawnObserver();
1054
1055         // identify the right forced team
1056         if(autocvar_g_campaign)
1057         {
1058                 if(IS_REAL_CLIENT(self)) // only players, not bots
1059                 {
1060                         switch(autocvar_g_campaign_forceteam)
1061                         {
1062                                 case 1: self.team_forced = NUM_TEAM_1; break;
1063                                 case 2: self.team_forced = NUM_TEAM_2; break;
1064                                 case 3: self.team_forced = NUM_TEAM_3; break;
1065                                 case 4: self.team_forced = NUM_TEAM_4; break;
1066                                 default: self.team_forced = 0;
1067                         }
1068                 }
1069         }
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1071                 self.team_forced = NUM_TEAM_1;
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1073                 self.team_forced = NUM_TEAM_2;
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1075                 self.team_forced = NUM_TEAM_3;
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1077                 self.team_forced = NUM_TEAM_4;
1078         else if(autocvar_g_forced_team_otherwise == "red")
1079                 self.team_forced = NUM_TEAM_1;
1080         else if(autocvar_g_forced_team_otherwise == "blue")
1081                 self.team_forced = NUM_TEAM_2;
1082         else if(autocvar_g_forced_team_otherwise == "yellow")
1083                 self.team_forced = NUM_TEAM_3;
1084         else if(autocvar_g_forced_team_otherwise == "pink")
1085                 self.team_forced = NUM_TEAM_4;
1086         else if(autocvar_g_forced_team_otherwise == "spectate")
1087                 self.team_forced = -1;
1088         else if(autocvar_g_forced_team_otherwise == "spectator")
1089                 self.team_forced = -1;
1090         else
1091                 self.team_forced = 0;
1092
1093         if(!teamplay)
1094                 if(self.team_forced > 0)
1095                         self.team_forced = 0;
1096
1097         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1098
1099         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1100                 self.classname = "observer";
1101         } else {
1102                 if(teamplay)
1103                 {
1104                         if(autocvar_g_balance_teams)
1105                         {
1106                                 self.classname = "player";
1107                                 campaign_bots_may_start = 1;
1108                         }
1109                         else
1110                         {
1111                                 self.classname = "observer"; // do it anyway
1112                         }
1113                 }
1114                 else
1115                 {
1116                         self.classname = "player";
1117                         campaign_bots_may_start = 1;
1118                 }
1119         }
1120
1121         self.playerid = (playerid_last = playerid_last + 1);
1122
1123         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1124
1125     if(IS_BOT_CLIENT(self))
1126         PlayerStats_AddPlayer(self);
1127
1128         if(autocvar_sv_eventlog)
1129                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1130
1131         LogTeamchange(self.playerid, self.team, 1);
1132
1133         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1134
1135         self.netname_previous = strzone(self.netname);
1136
1137         if(IS_PLAYER(self) && teamplay)
1138                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1139         else
1140                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1141
1142         stuffcmd(self, strcat(clientstuff, "\n"));
1143         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1144
1145         FixClientCvars(self);
1146
1147         // spawnfunc_waypoint sprites
1148         WaypointSprite_InitClient(self);
1149
1150         // Wazat's grappling hook
1151         SetGrappleHookBindings();
1152
1153         // get version info from player
1154         stuffcmd(self, "cmd clientversion $gameversion\n");
1155
1156         // get other cvars from player
1157         GetCvars(0);
1158
1159         // notify about available teams
1160         if(teamplay)
1161         {
1162                 CheckAllowedTeams(self);
1163                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1164                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1165         }
1166         else
1167                 stuffcmd(self, "set _teams_available 0\n");
1168
1169         attach_entcs();
1170
1171         bot_relinkplayerlist();
1172
1173         self.spectatortime = time;
1174         if(blockSpectators)
1175         {
1176                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1177         }
1178
1179         self.jointime = time;
1180         self.allowed_timeouts = autocvar_sv_timeout_number;
1181
1182         if(IS_REAL_CLIENT(self))
1183         {
1184                 if(!autocvar_g_campaign)
1185                 {
1186                         self.motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1188                 }
1189
1190                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1191                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1192         }
1193
1194         if(!sv_foginterval && world.fog != "")
1195                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1196
1197         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1198         {
1199                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1200                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1201         }
1202         else
1203                 self.hitplotfh = -1;
1204
1205         if(g_race || g_cts) {
1206                 string rr;
1207                 if(g_cts)
1208                         rr = CTS_RECORD;
1209                 else
1210                         rr = RACE_RECORD;
1211
1212                 msg_entity = self;
1213                 race_send_recordtime(MSG_ONE);
1214                 race_send_speedaward(MSG_ONE);
1215
1216                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1217                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1218                 race_send_speedaward_alltimebest(MSG_ONE);
1219
1220                 float i;
1221                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1222                         race_SendRankings(i, 0, 0, MSG_ONE);
1223                 }
1224         }
1225         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1226                 send_CSQC_teamnagger();
1227
1228         CheatInitClient();
1229
1230         CSQCMODEL_AUTOINIT();
1231
1232         self.model_randomizer = random();
1233
1234         if(IS_REAL_CLIENT(self))
1235                 sv_notice_join();
1236
1237         MUTATOR_CALLHOOK(ClientConnect);
1238 }
1239 /*
1240 =============
1241 ClientDisconnect
1242
1243 Called when a client disconnects from the server
1244 =============
1245 */
1246 .entity chatbubbleentity;
1247 void ReadyCount();
1248 void ClientDisconnect (void)
1249 {
1250         if(self.vehicle)
1251             vehicles_exit(VHEF_RELESE);
1252
1253         if not(IS_CLIENT(self))
1254         {
1255                 print("Warning: ClientDisconnect without ClientConnect\n");
1256                 return;
1257         }
1258
1259         PlayerStats_AddGlobalInfo(self);
1260
1261         CheatShutdownClient();
1262
1263         if(self.hitplotfh >= 0)
1264         {
1265                 fclose(self.hitplotfh);
1266                 self.hitplotfh = -1;
1267         }
1268
1269         anticheat_report();
1270         anticheat_shutdown();
1271
1272         playerdemo_shutdown();
1273
1274         bot_clientdisconnect();
1275
1276         if(self.entcs)
1277                 detach_entcs();
1278
1279         if(autocvar_sv_eventlog)
1280                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1281
1282         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1283
1284         MUTATOR_CALLHOOK(ClientDisconnect);
1285
1286         Portal_ClearAll(self);
1287
1288         RemoveGrapplingHook(self);
1289
1290         // Here, everything has been done that requires this player to be a client.
1291
1292         self.flags &= ~FL_CLIENT;
1293
1294         if (self.chatbubbleentity)
1295                 remove (self.chatbubbleentity);
1296
1297         if (self.killindicator)
1298                 remove (self.killindicator);
1299
1300         WaypointSprite_PlayerGone();
1301
1302         bot_relinkplayerlist();
1303
1304         accuracy_free(self);
1305         ClientData_Detach();
1306         PlayerScore_Detach(self);
1307
1308         if(self.netname_previous)
1309                 strunzone(self.netname_previous);
1310         if(self.clientstatus)
1311                 strunzone(self.clientstatus);
1312         if(self.weaponorder_byimpulse)
1313                 strunzone(self.weaponorder_byimpulse);
1314
1315         ClearPlayerSounds();
1316
1317         if(self.personal)
1318                 remove(self.personal);
1319
1320         self.playerid = 0;
1321         ReadyCount();
1322
1323         // free cvars
1324         GetCvars(-1);
1325 }
1326
1327 .float BUTTON_CHAT;
1328 void ChatBubbleThink()
1329 {
1330         self.nextthink = time;
1331         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1332         {
1333                 if(self.owner) // but why can that ever be world?
1334                         self.owner.chatbubbleentity = world;
1335                 remove(self);
1336                 return;
1337         }
1338         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1339 #ifdef TETRIS
1340                 || self.owner.tetris_on
1341 #endif
1342         )
1343                 self.model = self.mdl;
1344         else
1345                 self.model = "";
1346 }
1347
1348 void UpdateChatBubble()
1349 {
1350         if (self.alpha < 0)
1351                 return;
1352         // spawn a chatbubble entity if needed
1353         if (!self.chatbubbleentity)
1354         {
1355                 self.chatbubbleentity = spawn();
1356                 self.chatbubbleentity.owner = self;
1357                 self.chatbubbleentity.exteriormodeltoclient = self;
1358                 self.chatbubbleentity.think = ChatBubbleThink;
1359                 self.chatbubbleentity.nextthink = time;
1360                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1361                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1362                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1363                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1364                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1365                 self.chatbubbleentity.model = "";
1366                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1367         }
1368 }
1369
1370
1371 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1372 // added to the model skins
1373 /*void UpdateColorModHack()
1374 {
1375         float c;
1376         c = self.clientcolors & 15;
1377         // LordHavoc: only bothering to support white, green, red, yellow, blue
1378              if (!teamplay) self.colormod = '0 0 0';
1379         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1380         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1381         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1382         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1383         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1384         else self.colormod = '1 1 1';
1385 }*/
1386
1387 void respawn(void)
1388 {
1389         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1390         {
1391                 self.solid = SOLID_NOT;
1392                 self.takedamage = DAMAGE_NO;
1393                 self.movetype = MOVETYPE_FLY;
1394                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1395                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1396                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1397                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1398                 if(autocvar_g_respawn_ghosts_maxtime)
1399                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1400         }
1401
1402         CopyBody(1);
1403
1404         self.effects |= EF_NODRAW; // prevent another CopyBody
1405         PutClientInServer();
1406 }
1407
1408 void play_countdown(float finished, string samp)
1409 {
1410         if(IS_REAL_CLIENT(self))
1411                 if(floor(finished - time - frametime) != floor(finished - time))
1412                         if(finished - time < 6)
1413                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1414 }
1415
1416 void player_powerups (void)
1417 {
1418         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1419         olditems = self.items;
1420
1421         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1422                 self.modelflags |= MF_ROCKET;
1423         else
1424                 self.modelflags &= ~MF_ROCKET;
1425
1426         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1427
1428         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1429                 return;
1430
1431         Fire_ApplyDamage(self);
1432         Fire_ApplyEffect(self);
1433
1434         if not(g_minstagib)
1435         {
1436                 if (self.items & IT_STRENGTH)
1437                 {
1438                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1439                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1440                         if (time > self.strength_finished)
1441                         {
1442                                 self.items = self.items - (self.items & IT_STRENGTH);
1443                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1444                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (time < self.strength_finished)
1450                         {
1451                                 self.items = self.items | IT_STRENGTH;
1452                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1453                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1454                         }
1455                 }
1456                 if (self.items & IT_INVINCIBLE)
1457                 {
1458                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1459                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1460                         if (time > self.invincible_finished)
1461                         {
1462                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1463                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1464                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1465                         }
1466                 }
1467                 else
1468                 {
1469                         if (time < self.invincible_finished)
1470                         {
1471                                 self.items = self.items | IT_INVINCIBLE;
1472                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1473                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1474                         }
1475                 }
1476                 if (self.items & IT_SUPERWEAPON)
1477                 {
1478                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1479                         {
1480                                 self.superweapons_finished = 0;
1481                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1482                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1483                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1484                         }
1485                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1486                         {
1487                                 // don't let them run out
1488                         }
1489                         else
1490                         {
1491                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1492                                 if (time > self.superweapons_finished)
1493                                 {
1494                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1495                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1496                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1497                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1498                                 }
1499                         }
1500                 }
1501                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1502                 {
1503                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1504                         {
1505                                 self.items = self.items | IT_SUPERWEAPON;
1506                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1507                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1508                         }
1509                         else
1510                         {
1511                                 self.superweapons_finished = 0;
1512                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1513                         }
1514                 }
1515                 else
1516                 {
1517                         self.superweapons_finished = 0;
1518                 }
1519         }
1520
1521         if(autocvar_g_nodepthtestplayers)
1522                 self.effects = self.effects | EF_NODEPTHTEST;
1523
1524         if(autocvar_g_fullbrightplayers)
1525                 self.effects = self.effects | EF_FULLBRIGHT;
1526
1527         if (time >= game_starttime)
1528         if (time < self.spawnshieldtime)
1529                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1530
1531         MUTATOR_CALLHOOK(PlayerPowerups);
1532 }
1533
1534 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1535 {
1536         if(current > stable)
1537                 return current;
1538         else if(current > stable - 0.25) // when close enough, "snap"
1539                 return stable;
1540         else
1541                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1542 }
1543
1544 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1545 {
1546         if(current < stable)
1547                 return current;
1548         else if(current < stable + 0.25) // when close enough, "snap"
1549                 return stable;
1550         else
1551                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1552 }
1553
1554 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1555 {
1556         if(current > rotstable)
1557         {
1558                 if(rotframetime > 0)
1559                 {
1560                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1561                         current = max(rotstable, current - rotlinear * rotframetime);
1562                 }
1563         }
1564         else if(current < regenstable)
1565         {
1566                 if(regenframetime > 0)
1567                 {
1568                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1569                         current = min(regenstable, current + regenlinear * regenframetime);
1570                 }
1571         }
1572
1573         if(current > limit)
1574                 current = limit;
1575
1576         return current;
1577 }
1578
1579 void player_regen (void)
1580 {
1581         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1582         maxh = autocvar_g_balance_health_rotstable;
1583         maxa = autocvar_g_balance_armor_rotstable;
1584         maxf = autocvar_g_balance_fuel_rotstable;
1585         minh = autocvar_g_balance_health_regenstable;
1586         mina = autocvar_g_balance_armor_regenstable;
1587         minf = autocvar_g_balance_fuel_regenstable;
1588         limith = autocvar_g_balance_health_limit;
1589         limita = autocvar_g_balance_armor_limit;
1590         limitf = autocvar_g_balance_fuel_limit;
1591
1592         max_mod = regen_mod = rot_mod = limit_mod = 1;
1593
1594         maxh = maxh * max_mod;
1595         //maxa = maxa * max_mod;
1596         //maxf = maxf * max_mod;
1597         minh = minh * max_mod;
1598         //mina = mina * max_mod;
1599         //minf = minf * max_mod;
1600         limith = limith * limit_mod;
1601         limita = limita * limit_mod;
1602         //limitf = limitf * limit_mod;
1603
1604         if(g_ca)
1605                 rot_mod = 0;
1606
1607         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1608         {
1609                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1610                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1611
1612                 // if player rotted to death...  die!
1613                 if(self.health < 1)
1614                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1615         }
1616
1617         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1618                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1619 }
1620
1621 float zoomstate_set;
1622 void SetZoomState(float z)
1623 {
1624         if(z != self.zoomstate)
1625         {
1626                 self.zoomstate = z;
1627                 ClientData_Touch(self);
1628         }
1629         zoomstate_set = 1;
1630 }
1631
1632 void GetPressedKeys(void) {
1633         MUTATOR_CALLHOOK(GetPressedKeys);
1634         if (self.movement_x > 0) // get if movement keys are pressed
1635         {       // forward key pressed
1636                 self.pressedkeys |= KEY_FORWARD;
1637                 self.pressedkeys &= ~KEY_BACKWARD;
1638         }
1639         else if (self.movement_x < 0)
1640         {       // backward key pressed
1641                 self.pressedkeys |= KEY_BACKWARD;
1642                 self.pressedkeys &= ~KEY_FORWARD;
1643         }
1644         else
1645         {       // no x input
1646                 self.pressedkeys &= ~KEY_FORWARD;
1647                 self.pressedkeys &= ~KEY_BACKWARD;
1648         }
1649
1650         if (self.movement_y > 0)
1651         {       // right key pressed
1652                 self.pressedkeys |= KEY_RIGHT;
1653                 self.pressedkeys &= ~KEY_LEFT;
1654         }
1655         else if (self.movement_y < 0)
1656         {       // left key pressed
1657                 self.pressedkeys |= KEY_LEFT;
1658                 self.pressedkeys &= ~KEY_RIGHT;
1659         }
1660         else
1661         {       // no y input
1662                 self.pressedkeys &= ~KEY_RIGHT;
1663                 self.pressedkeys &= ~KEY_LEFT;
1664         }
1665
1666         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1667                 self.pressedkeys |= KEY_JUMP;
1668         else
1669                 self.pressedkeys &= ~KEY_JUMP;
1670         if (self.BUTTON_CROUCH)
1671                 self.pressedkeys |= KEY_CROUCH;
1672         else
1673                 self.pressedkeys &= ~KEY_CROUCH;
1674
1675         if (self.BUTTON_ATCK)
1676                 self.pressedkeys |= KEY_ATCK;
1677         else
1678                 self.pressedkeys &= ~KEY_ATCK;
1679         if (self.BUTTON_ATCK2)
1680                 self.pressedkeys |= KEY_ATCK2;
1681         else
1682                 self.pressedkeys &= ~KEY_ATCK2;
1683 }
1684
1685 /*
1686 ======================
1687 spectate mode routines
1688 ======================
1689 */
1690
1691 void SpectateCopy(entity spectatee) {
1692         other = spectatee;
1693         MUTATOR_CALLHOOK(SpectateCopy);
1694         self.armortype = spectatee.armortype;
1695         self.armorvalue = spectatee.armorvalue;
1696         self.ammo_cells = spectatee.ammo_cells;
1697         self.ammo_shells = spectatee.ammo_shells;
1698         self.ammo_nails = spectatee.ammo_nails;
1699         self.ammo_rockets = spectatee.ammo_rockets;
1700         self.ammo_fuel = spectatee.ammo_fuel;
1701         self.clip_load = spectatee.clip_load;
1702         self.clip_size = spectatee.clip_size;
1703         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1704         self.health = spectatee.health;
1705         self.impulse = 0;
1706         self.items = spectatee.items;
1707         self.last_pickup = spectatee.last_pickup;
1708         self.hit_time = spectatee.hit_time;
1709         self.metertime = spectatee.metertime;
1710         self.strength_finished = spectatee.strength_finished;
1711         self.invincible_finished = spectatee.invincible_finished;
1712         self.pressedkeys = spectatee.pressedkeys;
1713         self.weapons = spectatee.weapons;
1714         self.switchweapon = spectatee.switchweapon;
1715         self.switchingweapon = spectatee.switchingweapon;
1716         self.weapon = spectatee.weapon;
1717         self.nex_charge = spectatee.nex_charge;
1718         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1719         self.hagar_load = spectatee.hagar_load;
1720         self.minelayer_mines = spectatee.minelayer_mines;
1721         self.punchangle = spectatee.punchangle;
1722         self.view_ofs = spectatee.view_ofs;
1723         self.velocity = spectatee.velocity;
1724         self.dmg_take = spectatee.dmg_take;
1725         self.dmg_save = spectatee.dmg_save;
1726         self.dmg_inflictor = spectatee.dmg_inflictor;
1727         self.v_angle = spectatee.v_angle;
1728         self.angles = spectatee.v_angle;
1729         if(!self.BUTTON_USE)
1730                 self.fixangle = TRUE;
1731         setorigin(self, spectatee.origin);
1732         setsize(self, spectatee.mins, spectatee.maxs);
1733         SetZoomState(spectatee.zoomstate);
1734
1735     anticheat_spectatecopy(spectatee);
1736         self.hud = spectatee.hud;
1737         if(spectatee.vehicle)
1738     {
1739         self.fixangle = FALSE;
1740         //self.velocity = spectatee.vehicle.velocity;
1741         self.vehicle_health = spectatee.vehicle_health;
1742         self.vehicle_shield = spectatee.vehicle_shield;
1743         self.vehicle_energy = spectatee.vehicle_energy;
1744         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1745         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1746         self.vehicle_reload1 = spectatee.vehicle_reload1;
1747         self.vehicle_reload2 = spectatee.vehicle_reload2;
1748
1749         msg_entity = self;
1750
1751         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1752             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1753             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1754             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1755
1756         //WriteByte (MSG_ONE, SVC_SETVIEW);
1757         //    WriteEntity(MSG_ONE, self);
1758         //makevectors(spectatee.v_angle);
1759         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1760     }
1761 }
1762
1763 float SpectateUpdate() {
1764         if(!self.enemy)
1765             return 0;
1766
1767         if (self == self.enemy)
1768                 return 0;
1769
1770         if not(IS_PLAYER(self.enemy))
1771                 return 0;
1772
1773         SpectateCopy(self.enemy);
1774
1775         return 1;
1776 }
1777
1778
1779 float SpectateSet()
1780 {
1781         if(self.enemy.classname != "player")
1782                 return FALSE;
1783         /*if(self.enemy.vehicle)
1784         {
1785
1786                 msg_entity = self;
1787                 WriteByte(MSG_ONE, SVC_SETVIEW);
1788                 WriteEntity(MSG_ONE, self.enemy);
1789                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1790
1791                 self.movetype = MOVETYPE_NONE;
1792                 accuracy_resend(self);
1793         }
1794         else
1795         {*/
1796                 msg_entity = self;
1797                 WriteByte(MSG_ONE, SVC_SETVIEW);
1798                 WriteEntity(MSG_ONE, self.enemy);
1799                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1800                 self.movetype = MOVETYPE_NONE;
1801                 accuracy_resend(self);
1802
1803                 if(!SpectateUpdate())
1804                         PutObserverInServer();
1805         //}
1806         return TRUE;
1807 }
1808
1809 float Spectate(entity pl)
1810 {
1811         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1812         if(pl.team != self.team)
1813                 return 0;
1814
1815         self.enemy = pl;
1816         return SpectateSet();
1817 }
1818
1819 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1820 entity CA_SpectateNext(entity start) {
1821         if (start.team == self.team) {
1822                 return start;
1823         }
1824
1825         other = start;
1826         // continue from current player
1827         while(other && other.team != self.team) {
1828                 other = find(other, classname, "player");
1829         }
1830
1831         if (!other) {
1832                 // restart from begining
1833                 other = find(other, classname, "player");
1834                 while(other && other.team != self.team) {
1835                         other = find(other, classname, "player");
1836                 }
1837         }
1838
1839         return other;
1840 }
1841
1842 float SpectateNext()
1843 {
1844         other = find(self.enemy, classname, "player");
1845
1846         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1847                 // CA and ca players when spectating enemies is forbidden
1848                 other = CA_SpectateNext(other);
1849         } else {
1850                 // other modes and ca spectators or spectating enemies is allowed
1851                 if (!other)
1852                         other = find(other, classname, "player");
1853         }
1854
1855         if (other)
1856                 self.enemy = other;
1857
1858         return SpectateSet();
1859 }
1860
1861 float SpectatePrev()
1862 {
1863         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1864         other = findchain(classname, "player");
1865         if not(other) // no player
1866                 return FALSE;
1867
1868         entity first = other;
1869         // skip players until current spectated player
1870         if(self.enemy)
1871         while(other && other != self.enemy)
1872                 other = other.chain;
1873
1874         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1875         {
1876                 do { other = other.chain; }
1877                 while(other && other.team != self.team);
1878
1879                 if not(other)
1880                 {
1881                         other = first;
1882                         while(other.team != self.team)
1883                                 other = other.chain;
1884                         if(other == self.enemy)
1885                                 return TRUE;
1886                 }
1887         }
1888         else
1889         {
1890                 if(other.chain)
1891                         other = other.chain;
1892                 else
1893                         other = first;
1894         }
1895         self.enemy = other;
1896         return SpectateSet();
1897 }
1898
1899 /*
1900 =============
1901 ShowRespawnCountdown()
1902
1903 Update a respawn countdown display.
1904 =============
1905 */
1906 void ShowRespawnCountdown()
1907 {
1908         float number;
1909         if(self.deadflag == DEAD_NO) // just respawned?
1910                 return;
1911         else
1912         {
1913                 number = ceil(self.respawn_time - time);
1914                 if(number <= 0)
1915                         return;
1916                 if(number <= self.respawn_countdown)
1917                 {
1918                         self.respawn_countdown = number - 1;
1919                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1920                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1921                 }
1922         }
1923 }
1924
1925 void LeaveSpectatorMode()
1926 {
1927         if(self.caplayer)
1928                 return;
1929         if(nJoinAllowed(self))
1930         {
1931                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1932                 {
1933                         self.classname = "player";
1934
1935                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1936                                 { JoinBestTeam(self, FALSE, TRUE); }
1937
1938                         if(autocvar_g_campaign)
1939                                 { campaign_bots_may_start = 1; }
1940
1941                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1942
1943                         PutClientInServer();
1944
1945                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1946                 }
1947                 else
1948                         stuffcmd(self, "menu_showteamselect\n");
1949         }
1950         else
1951         {
1952                 // Player may not join because g_maxplayers is set
1953                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1954         }
1955 }
1956
1957 /**
1958  * Determines whether the player is allowed to join. This depends on cvar
1959  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1960  * it checks whether the number of currently playing players exceeds g_maxplayers.
1961  * @return int number of free slots for players, 0 if none
1962  */
1963 float nJoinAllowed(entity ignore) {
1964         if(!ignore)
1965         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1966         // so report 0 free slots if restricted
1967         {
1968                 if(autocvar_g_forced_team_otherwise == "spectate")
1969                         return 0;
1970                 if(autocvar_g_forced_team_otherwise == "spectator")
1971                         return 0;
1972         }
1973
1974         if(self.team_forced < 0)
1975                 return 0; // forced spectators can never join
1976
1977         // TODO simplify this
1978         entity e;
1979         float totalClients = 0;
1980         FOR_EACH_CLIENT(e)
1981                 if(e != ignore)
1982                         totalClients += 1;
1983
1984         if (!autocvar_g_maxplayers)
1985                 return maxclients - totalClients;
1986
1987         float currentlyPlaying = 0;
1988         FOR_EACH_REALCLIENT(e)
1989                 if(IS_PLAYER(e) || e.caplayer == 1)
1990                         currentlyPlaying += 1;
1991
1992         if(currentlyPlaying < autocvar_g_maxplayers)
1993                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1994
1995         return 0;
1996 }
1997
1998 /**
1999  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2000  * g_maxplayers_spectator_blocktime seconds
2001  */
2002 void checkSpectatorBlock() {
2003         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2004                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2005                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2006                         dropclient(self);
2007                 }
2008         }
2009 }
2010
2011 void PrintWelcomeMessage()
2012 {
2013         if(self.motd_actived_time == 0)
2014         {
2015                 if (autocvar_g_campaign) {
2016                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2017                                 self.motd_actived_time = time;
2018                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2019                         }
2020                 } else {
2021                         if (self.BUTTON_INFO) {
2022                                 self.motd_actived_time = time;
2023                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2024                         }
2025                 }
2026         }
2027         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2028         {
2029                 if (autocvar_g_campaign) {
2030                         if (self.BUTTON_INFO)
2031                                 self.motd_actived_time = time;
2032                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2033                                 self.motd_actived_time = 0;
2034                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2035                         }
2036                 } else {
2037                         if (self.BUTTON_INFO)
2038                                 self.motd_actived_time = time;
2039                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2040                                 self.motd_actived_time = 0;
2041                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2042                         }
2043                 }
2044         }
2045         else //if(self.motd_actived_time < 0) // just connected, motd is active
2046         {
2047                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2048                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2049                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2050                 {
2051                         // instanctly hide MOTD
2052                         self.motd_actived_time = 0;
2053                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2054                 }
2055         }
2056 }
2057
2058 void ObserverThink()
2059 {
2060         float prefered_movetype;
2061         if (self.flags & FL_JUMPRELEASED) {
2062                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2063                         self.flags &= ~FL_JUMPRELEASED;
2064                         self.flags |= FL_SPAWNING;
2065                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2066                         self.flags &= ~FL_JUMPRELEASED;
2067                         if(SpectateNext()) {
2068                                 self.classname = "spectator";
2069                         }
2070                 } else {
2071                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2072                         if (self.movetype != prefered_movetype)
2073                                 self.movetype = prefered_movetype;
2074                 }
2075         } else {
2076                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2077                         self.flags |= FL_JUMPRELEASED;
2078                         if(self.flags & FL_SPAWNING)
2079                         {
2080                                 self.flags &= ~FL_SPAWNING;
2081                                 LeaveSpectatorMode();
2082                                 return;
2083                         }
2084                 }
2085         }
2086 }
2087
2088 void SpectatorThink()
2089 {
2090         if (self.flags & FL_JUMPRELEASED) {
2091                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2092                         self.flags &= ~FL_JUMPRELEASED;
2093                         self.flags |= FL_SPAWNING;
2094                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2095                         self.flags &= ~FL_JUMPRELEASED;
2096                         if(SpectateNext()) {
2097                                 self.classname = "spectator";
2098                         } else {
2099                                 self.classname = "observer";
2100                                 PutClientInServer();
2101                         }
2102                         self.impulse = 0;
2103                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2104                         self.flags &= ~FL_JUMPRELEASED;
2105                         if(SpectatePrev()) {
2106                                 self.classname = "spectator";
2107                         } else {
2108                                 self.classname = "observer";
2109                                 PutClientInServer();
2110                         }
2111                         self.impulse = 0;
2112                 } else if (self.BUTTON_ATCK2) {
2113                         self.flags &= ~FL_JUMPRELEASED;
2114                         self.classname = "observer";
2115                         PutClientInServer();
2116                 } else {
2117                         if(!SpectateUpdate())
2118                                 PutObserverInServer();
2119                 }
2120         } else {
2121                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2122                         self.flags |= FL_JUMPRELEASED;
2123                         if(self.flags & FL_SPAWNING)
2124                         {
2125                                 self.flags &= ~FL_SPAWNING;
2126                                 LeaveSpectatorMode();
2127                                 return;
2128                         }
2129                 }
2130                 if(!SpectateUpdate())
2131                         PutObserverInServer();
2132         }
2133
2134         self.flags |= FL_CLIENT | FL_NOTARGET;
2135 }
2136
2137 void PlayerUseKey()
2138 {
2139         if not(IS_PLAYER(self))
2140                 return;
2141
2142         if(self.vehicle)
2143         {
2144         vehicles_exit(VHEF_NORMAL);
2145         return;
2146         }
2147
2148         // a use key was pressed; call handlers
2149         MUTATOR_CALLHOOK(PlayerUseKey);
2150 }
2151
2152 /*
2153 =============
2154 PlayerPreThink
2155
2156 Called every frame for each client before the physics are run
2157 =============
2158 */
2159 .float usekeypressed;
2160 void() nexball_setstatus;
2161 .float items_added;
2162 void PlayerPreThink (void)
2163 {
2164         WarpZone_PlayerPhysics_FixVAngle();
2165
2166         self.stat_game_starttime = game_starttime;
2167         self.stat_round_starttime = round_starttime;
2168         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2169         self.stat_leadlimit = autocvar_leadlimit;
2170
2171         if(frametime)
2172         {
2173                 // physics frames: update anticheat stuff
2174                 anticheat_prethink();
2175         }
2176
2177         if(blockSpectators && frametime)
2178                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2179                 checkSpectatorBlock();
2180
2181         zoomstate_set = 0;
2182
2183         if(self.netname_previous != self.netname)
2184         {
2185                 if(autocvar_sv_eventlog)
2186                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2187                 if(self.netname_previous)
2188                         strunzone(self.netname_previous);
2189                 self.netname_previous = strzone(self.netname);
2190         }
2191
2192         // version nagging
2193         if(self.version_nagtime)
2194                 if(self.cvar_g_xonoticversion)
2195                         if(time > self.version_nagtime)
2196                         {
2197                                 // don't notify git users
2198                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2199                                 {
2200                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2201                                         {
2202                                                 // notify release users if connecting to git
2203                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2204                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2205                                         }
2206                                         else
2207                                         {
2208                                                 float r;
2209                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2210                                                 if(r < 0)
2211                                                 {
2212                                                         // give users new version
2213                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2214                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2215                                                 }
2216                                                 else if(r > 0)
2217                                                 {
2218                                                         // notify users about old server version
2219                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2220                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2221                                                 }
2222                                         }
2223                                 }
2224                                 self.version_nagtime = 0;
2225                         }
2226
2227         // GOD MODE info
2228         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2229         {
2230                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2231                 self.max_armorvalue = 0;
2232         }
2233
2234 #ifdef TETRIS
2235         if (TetrisPreFrame())
2236                 return;
2237 #endif
2238
2239         MUTATOR_CALLHOOK(PlayerPreThink);
2240
2241         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2242         {
2243                 if(self.BUTTON_USE && !self.usekeypressed)
2244                         PlayerUseKey();
2245                 self.usekeypressed = self.BUTTON_USE;
2246         }
2247
2248         if(IS_REAL_CLIENT(self))
2249                 PrintWelcomeMessage();
2250
2251         if(IS_PLAYER(self))
2252         {
2253
2254                 CheckRules_Player();
2255
2256                 if (intermission_running)
2257                 {
2258                         IntermissionThink ();   // otherwise a button could be missed between
2259                         return;                                 // the think tics
2260                 }
2261
2262                 //don't allow the player to turn around while game is paused!
2263                 if(timeout_status == TIMEOUT_ACTIVE) {
2264                         // FIXME turn this into CSQC stuff
2265                         self.v_angle = self.lastV_angle;
2266                         self.angles = self.lastV_angle;
2267                         self.fixangle = TRUE;
2268                 }
2269
2270                 if(frametime)
2271                 {
2272                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2273                         {
2274                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2275                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2276                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2277
2278                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2279                                 {
2280                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2281                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2282                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2283                                 }
2284                         }
2285                         else
2286                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2287
2288                         player_powerups();
2289                 }
2290
2291                 if (self.deadflag != DEAD_NO)
2292                 {
2293                         if(self.personal && g_race_qualifying)
2294                         {
2295                                 if(time > self.respawn_time)
2296                                 {
2297                                         self.respawn_time = time + 1; // only retry once a second
2298                                         self.stat_respawn_time = self.respawn_time;
2299                                         respawn();
2300                                         self.impulse = 141;
2301                                 }
2302                         }
2303                         else
2304                         {
2305                                 float button_pressed;
2306                                 if(frametime)
2307                                         player_anim();
2308                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2309
2310                                 if (self.deadflag == DEAD_DYING)
2311                                 {
2312                                         if(self.respawn_flags & RESPAWN_FORCE)
2313                                                 self.deadflag = DEAD_RESPAWNING;
2314                                         else if(!button_pressed)
2315                                                 self.deadflag = DEAD_DEAD;
2316                                 }
2317                                 else if (self.deadflag == DEAD_DEAD)
2318                                 {
2319                                         if(button_pressed)
2320                                                 self.deadflag = DEAD_RESPAWNABLE;
2321                                 }
2322                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2323                                 {
2324                                         if(!button_pressed)
2325                                                 self.deadflag = DEAD_RESPAWNING;
2326                                 }
2327                                 else if (self.deadflag == DEAD_RESPAWNING)
2328                                 {
2329                                         if(time > self.respawn_time)
2330                                         {
2331                                                 self.respawn_time = time + 1; // only retry once a second
2332                                                 respawn();
2333                                         }
2334                                 }
2335
2336                                 ShowRespawnCountdown();
2337
2338                                 if(self.respawn_flags & RESPAWN_SILENT)
2339                                         self.stat_respawn_time = 0;
2340                                 else
2341                                         self.stat_respawn_time = self.respawn_time;
2342                         }
2343
2344                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2345                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2346                                 self.stat_respawn_time *= -1;
2347
2348                         return;
2349                 }
2350
2351                 self.prevorigin = self.origin;
2352
2353                 float do_crouch = self.BUTTON_CROUCH;
2354                 if(self.hook.state)
2355                         do_crouch = 0;
2356                 if(self.vehicle)
2357                         do_crouch = 0;
2358                 if(self.freezetag_frozen)
2359                         do_crouch = 0;
2360                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2361                         do_crouch = 0;
2362
2363                 if (do_crouch)
2364                 {
2365                         if (!self.crouch)
2366                         {
2367                                 self.crouch = TRUE;
2368                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2369                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2370                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2371                         }
2372                 }
2373                 else
2374                 {
2375                         if (self.crouch)
2376                         {
2377                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2378                                 if (!trace_startsolid)
2379                                 {
2380                                         self.crouch = FALSE;
2381                                         self.view_ofs = PL_VIEW_OFS;
2382                                         setsize (self, PL_MIN, PL_MAX);
2383                                 }
2384                         }
2385                 }
2386
2387                 FixPlayermodel();
2388
2389                 GrapplingHookFrame();
2390
2391                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2392                 //if(frametime)
2393                 {
2394                         self.items &= ~self.items_added;
2395
2396                         W_WeaponFrame();
2397
2398                         self.items_added = 0;
2399                         if(self.items & IT_JETPACK)
2400                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2401                                         self.items_added |= IT_FUEL;
2402
2403                         self.items |= self.items_added;
2404                 }
2405
2406                 player_regen();
2407
2408                 // rot nex charge to the charge limit
2409                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2410                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2411
2412                 if(frametime)
2413                         player_anim();
2414
2415                 // secret status
2416                 secrets_setstatus();
2417
2418                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2419
2420                 //self.angles_y=self.v_angle_y + 90;   // temp
2421         } else if(gameover) {
2422                 if (intermission_running)
2423                         IntermissionThink ();   // otherwise a button could be missed between
2424                 return;
2425         } else if(IS_OBSERVER(self)) {
2426                 ObserverThink();
2427         } else if(IS_SPEC(self)) {
2428                 SpectatorThink();
2429         }
2430
2431         if(!zoomstate_set)
2432                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2433
2434         float oldspectatee_status;
2435         oldspectatee_status = self.spectatee_status;
2436         if(IS_SPEC(self))
2437                 self.spectatee_status = num_for_edict(self.enemy);
2438         else if(IS_OBSERVER(self))
2439                 self.spectatee_status = num_for_edict(self);
2440         else
2441                 self.spectatee_status = 0;
2442         if(self.spectatee_status != oldspectatee_status)
2443         {
2444                 ClientData_Touch(self);
2445                 if(g_race || g_cts)
2446                         race_InitSpectator();
2447         }
2448
2449         if(self.teamkill_soundtime)
2450         if(time > self.teamkill_soundtime)
2451         {
2452                 self.teamkill_soundtime = 0;
2453
2454                 entity oldpusher, oldself;
2455
2456                 oldself = self; self = self.teamkill_soundsource;
2457                 oldpusher = self.pusher; self.pusher = oldself;
2458
2459                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2460
2461                 self.pusher = oldpusher;
2462                 self = oldself;
2463         }
2464
2465         if(self.taunt_soundtime)
2466         if(time > self.taunt_soundtime)
2467         {
2468                 self.taunt_soundtime = 0;
2469                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2470         }
2471
2472         target_voicescript_next(self);
2473
2474         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2475         if(!self.weapon)
2476                 self.clip_load = self.clip_size = 0;
2477 }
2478
2479 float isInvisibleString(string s)
2480 {
2481         float i, n, c;
2482         s = strdecolorize(s);
2483         for((i = 0), (n = strlen(s)); i < n; ++i)
2484         {
2485                 c = str2chr(s, i);
2486                 switch(c)
2487                 {
2488                         case 0:
2489                         case 32: // space
2490                                 break;
2491                         case 192: // charmap space
2492                                 if (!autocvar_utf8_enable)
2493                                         break;
2494                                 return FALSE;
2495                         case 160: // space in unicode fonts
2496                         case 0xE000 + 192: // utf8 charmap space
2497                                 if (autocvar_utf8_enable)
2498                                         break;
2499                         default:
2500                                 return FALSE;
2501                 }
2502         }
2503         return TRUE;
2504 }
2505
2506 /*
2507 =============
2508 PlayerPostThink
2509
2510 Called every frame for each client after the physics are run
2511 =============
2512 */
2513 .float idlekick_lasttimeleft;
2514 void PlayerPostThink (void)
2515 {
2516         // Savage: Check for nameless players
2517         if (isInvisibleString(self.netname)) {
2518                 self.netname = "Player";
2519                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2520         }
2521
2522         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2523         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2524         {
2525                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2526                 {
2527                         if(self.idlekick_lasttimeleft)
2528                         {
2529                                 self.idlekick_lasttimeleft = 0;
2530                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2531                         }
2532                 }
2533                 else
2534                 {
2535                         float timeleft;
2536                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2537                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2538                         {
2539                                 if(!self.idlekick_lasttimeleft)
2540                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2541                         }
2542                         if(timeleft <= 0)
2543                         {
2544                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2545                                 dropclient(self);
2546                                 return;
2547                         }
2548                         else if(timeleft <= 10)
2549                         {
2550                                 if(timeleft != self.idlekick_lasttimeleft)
2551                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2552                                 self.idlekick_lasttimeleft = timeleft;
2553                         }
2554                 }
2555         }
2556
2557 #ifdef TETRIS
2558         if(self.impulse == 100)
2559                 ImpulseCommands();
2560         if (!TetrisPostFrame())
2561         {
2562 #endif
2563
2564         CheatFrame();
2565
2566         //CheckPlayerJump();
2567
2568         if(IS_PLAYER(self)) {
2569                 CheckRules_Player();
2570                 UpdateChatBubble();
2571                 if (self.impulse)
2572                         ImpulseCommands();
2573                 if (intermission_running)
2574                         return;         // intermission or finale
2575                 GetPressedKeys();
2576         }
2577
2578 #ifdef TETRIS
2579         }
2580 #endif
2581
2582         /*
2583         float i;
2584         for(i = 0; i < 1000; ++i)
2585         {
2586                 vector end;
2587                 end = self.origin + '0 0 1024' + 512 * randomvec();
2588                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2589                 if(trace_fraction < 1)
2590                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2591                 {
2592                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2593                         break;
2594                 }
2595         }
2596         */
2597
2598         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2599
2600         if(self.waypointsprite_attachedforcarrier)
2601                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2602
2603         playerdemo_write();
2604
2605         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2606         {
2607                 if not(self.stored_netname)
2608                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2609                 if(self.stored_netname != self.netname)
2610                 {
2611                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2612                         strunzone(self.stored_netname);
2613                         self.stored_netname = strzone(self.netname);
2614                 }
2615         }
2616
2617         /*
2618         if(g_race)
2619                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2620         */
2621
2622         CSQCMODEL_AUTOUPDATE();
2623 }