qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 if(!inWarmupStage)
 414                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419                 vehicles_exit(VHEF_RELESE);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 424                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 425
 426         if(self.killcount != -666) {
 427                 if(g_lms) {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
 429                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
 430                         else
 431                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
 432                 } else { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname); }
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.alpha = 0;
 465         self.scale = 0;
 466         self.fade_time = 0;
 467         self.pain_frame = 0;
 468         self.pain_finished = 0;
 469         self.strength_finished = 0;
 470         self.invincible_finished = 0;
 471         self.superweapons_finished = 0;
 472         self.pushltime = 0;
 473         self.istypefrag = 0;
 474         self.think = func_null;
 475         self.nextthink = 0;
 476         self.hook_time = 0;
 477         self.runes = 0;
 478         self.deadflag = DEAD_NO;
 479         self.angles = spot.angles;
 480         self.angles_z = 0;
 481         self.fixangle = TRUE;
 482         self.crouch = FALSE;
 483
 484         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 485         self.prevorigin = self.origin;
 486         self.items = 0;
 487         WEPSET_CLEAR_E(self);
 488         self.model = "";
 489         FixPlayermodel();
 490         setmodel(self, "null");
 491         self.drawonlytoclient = self;
 492
 493         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 494         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 495
 496         self.weapon = 0;
 497         self.weaponname = "";
 498         self.switchingweapon = 0;
 499         self.weaponmodel = "";
 500         self.weaponentity = world;
 501         self.exteriorweaponentity = world;
 502         self.killcount = -666;
 503         self.velocity = '0 0 0';
 504         self.avelocity = '0 0 0';
 505         self.punchangle = '0 0 0';
 506         self.punchvector = '0 0 0';
 507         self.oldvelocity = self.velocity;
 508         self.fire_endtime = -1;
 509
 510         if(g_arena)
 511         {
 512                 if(self.version_mismatch)
 513                 {
 514                         self.frags = FRAGS_SPECTATOR;
 515                         Spawnqueue_Unmark(self);
 516                         Spawnqueue_Remove(self);
 517                 }
 518                 else
 519                 {
 520                         self.frags = FRAGS_LMS_LOSER;
 521                         Spawnqueue_Insert(self);
 522                 }
 523         }
 524         else if(g_lms)
 525         {
 526                 // Only if the player cannot play at all
 527                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 528                         self.frags = FRAGS_SPECTATOR;
 529                 else
 530                         self.frags = FRAGS_LMS_LOSER;
 531         }
 532         else if(g_ca)
 533         {
 534                 if(self.caplayer)
 535                         self.frags = FRAGS_LMS_LOSER;
 536                 else
 537                         self.frags = FRAGS_SPECTATOR;
 538         }
 539         else if((g_race && g_race_qualifying) || g_cts)
 540         {
 541                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 542                         self.frags = FRAGS_LMS_LOSER;
 543                 else
 544                         self.frags = FRAGS_SPECTATOR;
 545         }
 546         else
 547                 self.frags = FRAGS_SPECTATOR;
 548 }
 549
 550 .float model_randomizer;
 551 void FixPlayermodel()
 552 {
 553         string defaultmodel;
 554         float defaultskin, chmdl, oldskin, n, i;
 555         vector m1, m2;
 556
 557         defaultmodel = "";
 558         defaultskin = 0;
 559         chmdl = FALSE;
 560
 561         if(autocvar_sv_defaultcharacter == 1)
 562         {
 563                 if(teamplay)
 564                 {
 565                         string s;
 566                         s = Team_ColorName_Lower(self.team);
 567                         if(s != "neutral")
 568                         {
 569                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 570                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 571                         }
 572                 }
 573
 574                 if(defaultmodel == "")
 575                 {
 576                         defaultmodel = autocvar_sv_defaultplayermodel;
 577                         defaultskin = autocvar_sv_defaultplayerskin;
 578                 }
 579
 580                 n = tokenize_console(defaultmodel);
 581                 if(n > 0)
 582                         defaultmodel = argv(floor(n * self.model_randomizer));
 583
 584                 i = strstrofs(defaultmodel, ":", 0);
 585                 if(i >= 0)
 586                 {
 587                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 588                         defaultmodel = substring(defaultmodel, 0, i);
 589                 }
 590         }
 591
 592         if(defaultmodel != "")
 593         {
 594                 if (defaultmodel != self.model)
 595                 {
 596                         m1 = self.mins;
 597                         m2 = self.maxs;
 598                         setplayermodel (self, defaultmodel);
 599                         setsize (self, m1, m2);
 600                         chmdl = TRUE;
 601                 }
 602
 603                 oldskin = self.skin;
 604                 self.skin = defaultskin;
 605         } else {
 606                 if (self.playermodel != self.model || self.playermodel == "")
 607                 {
 608                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 609                         m1 = self.mins;
 610                         m2 = self.maxs;
 611                         setplayermodel (self, self.playermodel);
 612                         setsize (self, m1, m2);
 613                         chmdl = TRUE;
 614                 }
 615
 616                 oldskin = self.skin;
 617                 self.skin = stof(self.playerskin);
 618         }
 619
 620         if(chmdl || oldskin != self.skin) // model or skin has changed
 621         {
 622                 self.species = player_getspecies(); // update species
 623                 UpdatePlayerSounds(); // update skin sounds
 624         }
 625
 626         if(!teamplay)
 627                 if(strlen(autocvar_sv_defaultplayercolors))
 628                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 629                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 630 }
 631
 632 void PlayerTouchExplode(entity p1, entity p2)
 633 {
 634         vector org;
 635         org = (p1.origin + p2.origin) * 0.5;
 636         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 637
 638         te_explosion(org);
 639
 640         entity e;
 641         e = spawn();
 642         setorigin(e, org);
 643         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 644         remove(e);
 645 }
 646
 647 /*
 648 =============
 649 PutClientInServer
 650
 651 Called when a client spawns in the server
 652 =============
 653 */
 654
 655 void PutClientInServer (void)
 656 {
 657         if(clienttype(self) == CLIENTTYPE_BOT)
 658         {
 659                 self.classname = "player";
 660                 if(g_ca)
 661                         self.caplayer = 1;
 662         }
 663         else if(clienttype(self) == CLIENTTYPE_REAL)
 664         {
 665                 msg_entity = self;
 666                 WriteByte(MSG_ONE, SVC_SETVIEW);
 667                 WriteEntity(MSG_ONE, self);
 668         }
 669
 670         // reset player keys
 671         self.itemkeys = 0;
 672
 673         // player is dead and becomes observer
 674         // FIXME fix LMS scoring for new system
 675         if(g_lms)
 676         {
 677                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 678                         self.classname = "observer";
 679         }
 680
 681         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 682                 self.classname = "observer";
 683
 684         if(gameover)
 685                 self.classname = "observer";
 686
 687         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 688                 entity spot, oldself;
 689                 float j;
 690
 691                 accuracy_resend(self);
 692
 693                 if(self.team < 0)
 694                         JoinBestTeam(self, FALSE, TRUE);
 695
 696                 race_PreSpawn();
 697
 698                 spot = SelectSpawnPoint (FALSE);
 699                 if(!spot)
 700                 {
 701                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 702                         return; // spawn failed
 703                 }
 704
 705                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 706
 707                 self.classname = "player";
 708                 self.wasplayer = TRUE;
 709                 self.iscreature = TRUE;
 710                 self.teleportable = TELEPORT_NORMAL;
 711                 self.damagedbycontents = TRUE;
 712                 self.movetype = MOVETYPE_WALK;
 713                 self.solid = SOLID_SLIDEBOX;
 714                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 715                 if(autocvar_g_playerclip_collisions)
 716                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 717                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 718                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 719                 self.frags = FRAGS_PLAYER;
 720                 if(INDEPENDENT_PLAYERS)
 721                         MAKE_INDEPENDENT_PLAYER(self);
 722                 self.flags = FL_CLIENT;
 723                 if(autocvar__notarget)
 724                         self.flags |= FL_NOTARGET;
 725                 self.takedamage = DAMAGE_AIM;
 726                 if(g_minstagib)
 727                         self.effects = EF_FULLBRIGHT;
 728                 else
 729                         self.effects = 0;
 730                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 731                 self.air_finished = time + 12;
 732                 self.dmg = 2;
 733                 if(autocvar_g_balance_nex_charge)
 734                 {
 735                         if(autocvar_g_balance_nex_secondary_chargepool)
 736                                 self.nex_chargepool_ammo = 1;
 737                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 738                 }
 739
 740                 if(inWarmupStage)
 741                 {
 742                         self.ammo_shells = warmup_start_ammo_shells;
 743                         self.ammo_nails = warmup_start_ammo_nails;
 744                         self.ammo_rockets = warmup_start_ammo_rockets;
 745                         self.ammo_cells = warmup_start_ammo_cells;
 746                         self.ammo_fuel = warmup_start_ammo_fuel;
 747                         self.health = warmup_start_health;
 748                         self.armorvalue = warmup_start_armorvalue;
 749                         WEPSET_COPY_EA(self, warmup_start_weapons);
 750                 }
 751                 else
 752                 {
 753                         self.ammo_shells = start_ammo_shells;
 754                         self.ammo_nails = start_ammo_nails;
 755                         self.ammo_rockets = start_ammo_rockets;
 756                         self.ammo_cells = start_ammo_cells;
 757                         self.ammo_fuel = start_ammo_fuel;
 758                         self.health = start_health;
 759                         self.armorvalue = start_armorvalue;
 760                         WEPSET_COPY_EA(self, start_weapons);
 761                 }
 762
 763                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 764                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 765                 else
 766                         self.superweapons_finished = 0;
 767
 768                 if(g_weaponarena_random)
 769                 {
 770                         if(g_weaponarena_random_with_laser)
 771                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 772                         W_RandomWeapons(self, g_weaponarena_random);
 773                         if(g_weaponarena_random_with_laser)
 774                                 WEPSET_OR_EW(self, WEP_LASER);
 775                 }
 776
 777                 self.items = start_items;
 778
 779                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 780                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 781                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 782                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 783                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 784                 //extend the pause of rotting if client was reset at the beginning of the countdown
 785                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 786                         self.spawnshieldtime += game_starttime - time;
 787                         self.pauserotarmor_finished += game_starttime - time;
 788                         self.pauserothealth_finished += game_starttime - time;
 789                         self.pauseregen_finished += game_starttime - time;
 790                 }
 791                 self.damageforcescale = 2;
 792                 self.death_time = 0;
 793                 self.respawn_time = 0;
 794                 self.scale = 0;
 795                 self.fade_time = 0;
 796                 self.pain_frame = 0;
 797                 self.pain_finished = 0;
 798                 self.strength_finished = 0;
 799                 self.invincible_finished = 0;
 800                 self.pushltime = 0;
 801                 // players have no think function
 802                 self.think = func_null;
 803                 self.nextthink = 0;
 804                 self.hook_time = 0;
 805                 self.dmg_team = 0;
 806                 self.ballistics_density = autocvar_g_ballistics_density_player;
 807
 808                 self.metertime = 0;
 809
 810                 self.runes = 0;
 811
 812                 self.deadflag = DEAD_NO;
 813
 814                 self.angles = spot.angles;
 815
 816                 self.angles_z = 0; // never spawn tilted even if the spot says to
 817                 self.fixangle = TRUE; // turn this way immediately
 818                 self.velocity = '0 0 0';
 819                 self.avelocity = '0 0 0';
 820                 self.punchangle = '0 0 0';
 821                 self.punchvector = '0 0 0';
 822                 self.oldvelocity = self.velocity;
 823                 self.fire_endtime = -1;
 824
 825                 msg_entity = self;
 826                 WRITESPECTATABLE_MSG_ONE({
 827                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 828                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 829                 });
 830
 831                 self.model = "";
 832                 FixPlayermodel();
 833                 self.drawonlytoclient = world;
 834
 835                 self.crouch = FALSE;
 836                 self.view_ofs = PL_VIEW_OFS;
 837                 setsize (self, PL_MIN, PL_MAX);
 838                 self.spawnorigin = spot.origin;
 839                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 840                 // don't reset back to last position, even if new position is stuck in solid
 841                 self.oldorigin = self.origin;
 842                 self.prevorigin = self.origin;
 843                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 844                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 845         self.hud = HUD_NORMAL;
 846
 847                 if(g_arena)
 848                 {
 849                         Spawnqueue_Remove(self);
 850                         Spawnqueue_Mark(self);
 851                 }
 852                 else if(g_ca)
 853                         self.caplayer = 1;
 854
 855                 self.event_damage = PlayerDamage;
 856
 857                 self.bot_attack = TRUE;
 858
 859                 self.statdraintime = time + 5;
 860                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 861
 862                 if(self.killcount == -666) {
 863                         PlayerScore_Clear(self);
 864                         self.killcount = 0;
 865                 }
 866
 867                 CL_SpawnWeaponentity();
 868                 self.alpha = default_player_alpha;
 869                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 870                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 871
 872                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 873                 self.lms_traveled_distance = 0;
 874                 self.speedrunning = FALSE;
 875
 876                 race_PostSpawn(spot);
 877
 878                 //stuffcmd(self, "chase_active 0");
 879                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 880
 881                 if(g_assault) {
 882                         if(self.team == assault_attacker_team)
 883                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 884                         else
 885                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 886                 }
 887
 888                 target_voicescript_clear(self);
 889
 890                 // reset fields the weapons may use
 891                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 892                 {
 893                         weapon_action(j, WR_RESETPLAYER);
 894
 895                         // all weapons must be fully loaded when we spawn
 896                         entity e;
 897                         e = get_weaponinfo(j);
 898                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 899                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 900                 }
 901
 902                 oldself = self;
 903                 self = spot;
 904                         activator = oldself;
 905                                 string s;
 906                                 s = self.target;
 907                                 self.target = string_null;
 908                                 SUB_UseTargets();
 909                                 self.target = s;
 910                         activator = world;
 911                 self = oldself;
 912
 913                 spawn_spot = spot;
 914                 MUTATOR_CALLHOOK(PlayerSpawn);
 915
 916                 if(autocvar_spawn_debug)
 917                 {
 918                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 919                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 920                 }
 921
 922                 self.switchweapon = w_getbestweapon(self);
 923                 self.cnt = -1; // W_LastWeapon will not complain
 924                 self.weapon = 0;
 925                 self.weaponname = "";
 926                 self.switchingweapon = 0;
 927
 928                 if(!inWarmupStage)
 929                         if(!self.alivetime)
 930                                 self.alivetime = time;
 931
 932                 antilag_clear(self);
 933
 934                 if (autocvar_g_spawnsound)
 935                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 936         } else if(self.classname == "observer") {
 937                 PutObserverInServer ();
 938         }
 939 }
 940
 941 .float ebouncefactor, ebouncestop; // electro's values
 942 // TODO do we need all these fields, or should we stop autodetecting runtime
 943 // changes and just have a console command to update this?
 944 float ClientInit_SendEntity(entity to, float sf)
 945 {
 946         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 947         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 954         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 955         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 956         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 957         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 958         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 959         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 960         if(sv_foginterval && world.fog != "")
 961                 WriteString(MSG_ENTITY, world.fog);
 962         else
 963                 WriteString(MSG_ENTITY, "");
 964         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 965         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 966         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 967         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 968         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 969         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 970         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 971         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 972         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 973         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 974         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 975         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 976         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 977         return TRUE;
 978 }
 979
 980 void ClientInit_CheckUpdate()
 981 {
 982         self.nextthink = time;
 983         if(self.count != autocvar_g_balance_armor_blockpercent)
 984         {
 985                 self.count = autocvar_g_balance_armor_blockpercent;
 986                 self.SendFlags |= 1;
 987         }
 988         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 989         {
 990                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 991                 self.SendFlags |= 1;
 992         }
 993         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 994         {
 995                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 996                 self.SendFlags |= 1;
 997         }
 998         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 999         {
1000                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1001                 self.SendFlags |= 1;
1002         }
1003         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1004         {
1005                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1006                 self.SendFlags |= 1;
1007         }
1008         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1009         {
1010                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1011                 self.SendFlags |= 1;
1012         }
1013 }
1014
1015 void ClientInit_Spawn()
1016 {
1017         entity o;
1018         entity e;
1019         e = spawn();
1020         e.classname = "clientinit";
1021         e.think = ClientInit_CheckUpdate;
1022         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1023
1024         o = self;
1025         self = e;
1026         ClientInit_CheckUpdate();
1027         self = o;
1028 }
1029
1030 /*
1031 =============
1032 SetNewParms
1033 =============
1034 */
1035 void SetNewParms (void)
1036 {
1037         // initialize parms for a new player
1038         parm1 = -(86400 * 366);
1039 }
1040
1041 /*
1042 =============
1043 SetChangeParms
1044 =============
1045 */
1046 void SetChangeParms (void)
1047 {
1048         // save parms for level change
1049         parm1 = self.parm_idlesince - time;
1050 }
1051
1052 /*
1053 =============
1054 DecodeLevelParms
1055 =============
1056 */
1057 void DecodeLevelParms (void)
1058 {
1059         // load parms
1060         self.parm_idlesince = parm1;
1061         if(self.parm_idlesince == -(86400 * 366))
1062                 self.parm_idlesince = time;
1063
1064         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1065         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1066 }
1067
1068 /*
1069 =============
1070 ClientKill
1071
1072 Called when a client types 'kill' in the console
1073 =============
1074 */
1075
1076 .float clientkill_nexttime;
1077 void ClientKill_Now_TeamChange()
1078 {
1079         if(self.killindicator_teamchange == -1)
1080         {
1081                 JoinBestTeam( self, FALSE, TRUE );
1082         }
1083         else if(self.killindicator_teamchange == -2)
1084         {
1085                 if(g_ca)
1086                         self.caplayer = 0;
1087                 if(blockSpectators)
1088                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1089                 PutObserverInServer();
1090         }
1091         else
1092                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1093 }
1094
1095 void ClientKill_Now()
1096 {
1097         if(self.vehicle)
1098         {
1099             vehicles_exit(VHEF_RELESE);
1100             if(!self.killindicator_teamchange)
1101             {
1102             self.vehicle_health = -1;
1103             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1104             }
1105         }
1106
1107         if(self.killindicator && !wasfreed(self.killindicator))
1108                 remove(self.killindicator);
1109
1110         self.killindicator = world;
1111
1112         if(self.killindicator_teamchange)
1113                 ClientKill_Now_TeamChange();
1114
1115         // in any case:
1116         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1117
1118         // now I am sure the player IS dead
1119 }
1120 void KillIndicator_Think()
1121 {
1122         if (gameover)
1123         {
1124                 self.owner.killindicator = world;
1125                 remove(self);
1126                 return;
1127         }
1128
1129         if (self.owner.alpha < 0 && !self.owner.vehicle)
1130         {
1131                 self.owner.killindicator = world;
1132                 remove(self);
1133                 return;
1134         }
1135
1136         if(self.cnt <= 0)
1137         {
1138                 self = self.owner;
1139                 ClientKill_Now(); // no oldself needed
1140                 return;
1141         }
1142     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1143     {
1144         self.nextthink = time + 1;
1145         self.cnt -= 1;
1146     }
1147         else
1148         {
1149                 if(self.cnt <= 10)
1150                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1151                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1152                 {
1153                         if(self.cnt <= 10)
1154                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1155                 }
1156                 self.nextthink = time + 1;
1157                 self.cnt -= 1;
1158         }
1159 }
1160
1161 float clientkilltime;
1162 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1163 {
1164         float killtime;
1165         float starttime;
1166         entity e;
1167
1168         if (gameover)
1169                 return;
1170
1171         killtime = autocvar_g_balance_kill_delay;
1172
1173         if(g_race_qualifying || g_cts)
1174                 killtime = 0;
1175
1176     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1177     {
1178                 remove(self.killindicator);
1179                 self.killindicator = world;
1180
1181         ClientKill_Now(); // allow instant kill in this case
1182         return;
1183     }
1184
1185         self.killindicator_teamchange = targetteam;
1186
1187     if(!self.killindicator)
1188         {
1189                 if(self.deadflag == DEAD_NO)
1190                 {
1191                         killtime = max(killtime, self.clientkill_nexttime - time);
1192                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1193                 }
1194
1195                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1196                 {
1197                         ClientKill_Now();
1198                 }
1199                 else
1200                 {
1201                         starttime = max(time, clientkilltime);
1202
1203                         self.killindicator = spawn();
1204                         self.killindicator.owner = self;
1205                         self.killindicator.scale = 0.5;
1206                         setattachment(self.killindicator, self, "");
1207                         setorigin(self.killindicator, '0 0 52');
1208                         self.killindicator.think = KillIndicator_Think;
1209                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1210                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1211                         self.killindicator.cnt = ceil(killtime);
1212                         self.killindicator.count = bound(0, ceil(killtime), 10);
1213                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1214
1215                         for(e = world; (e = find(e, classname, "body")) != world; )
1216                         {
1217                                 if(e.enemy != self)
1218                                         continue;
1219                                 e.killindicator = spawn();
1220                                 e.killindicator.owner = e;
1221                                 e.killindicator.scale = 0.5;
1222                                 setattachment(e.killindicator, e, "");
1223                                 setorigin(e.killindicator, '0 0 52');
1224                                 e.killindicator.think = KillIndicator_Think;
1225                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1226                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1227                                 e.killindicator.cnt = ceil(killtime);
1228                         }
1229                         self.lip = 0;
1230                 }
1231         }
1232         if(self.killindicator)
1233         {
1234                 if(targetteam == 0) // just die
1235                 {
1236                         self.killindicator.colormod = '0 0 0';
1237                         if(clienttype(self) == CLIENTTYPE_REAL)
1238                         if(self.killindicator.cnt > 0)
1239                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1240                 }
1241                 else if(targetteam == -1) // auto
1242                 {
1243                         self.killindicator.colormod = '0 1 0';
1244                         if(clienttype(self) == CLIENTTYPE_REAL)
1245                         if(self.killindicator.cnt > 0)
1246                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1247                 }
1248                 else if(targetteam == -2) // spectate
1249                 {
1250                         self.killindicator.colormod = '0.5 0.5 0.5';
1251                         if(clienttype(self) == CLIENTTYPE_REAL)
1252                         if(self.killindicator.cnt > 0)
1253                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1254                 }
1255                 else
1256                 {
1257                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1258                         if(clienttype(self) == CLIENTTYPE_REAL)
1259                         if(self.killindicator.cnt > 0)
1260                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1261                 }
1262         }
1263
1264 }
1265
1266 void ClientKill (void)
1267 {
1268         if (gameover)
1269                 return;
1270
1271         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1272         {
1273                 // do nothing
1274         }
1275     else if(self.freezetag_frozen)
1276     {
1277         // do nothing
1278     }
1279         else
1280                 ClientKill_TeamChange(0);
1281 }
1282
1283 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1284 {
1285     e.killindicator = spawn();
1286     e.killindicator.owner = e;
1287     e.killindicator.think = KillIndicator_Think;
1288     e.killindicator.nextthink = time + (e.lip) * 0.05;
1289     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1290     e.killindicator.health = 1; // this is used to indicate that it should be silent
1291     e.lip = 0;
1292 }
1293
1294 void FixClientCvars(entity e)
1295 {
1296         // send prediction settings to the client
1297         stuffcmd(e, "\nin_bindmap 0 0\n");
1298         if(g_race || g_cts)
1299                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1300         if(autocvar_g_antilag == 3) // client side hitscan
1301                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1302         if(autocvar_sv_gentle)
1303                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1304         /*
1305          * we no longer need to stuff this. Remove this comment block if you feel
1306          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1307         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1308         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1309         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1310         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1311         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1312         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1313         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1314         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1315         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1316         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1317         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1318         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1319         stuffcmd(e, "cl_movement_edgefriction 1\n");
1320          */
1321 }
1322
1323 float PlayerInIDList(entity p, string idlist)
1324 {
1325         float n, i;
1326         string s;
1327
1328         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1329         if not(p.crypto_idfp)
1330                 return 0;
1331
1332         // this function allows abbreviated player IDs too!
1333         n = tokenize_console(idlist);
1334         for(i = 0; i < n; ++i)
1335         {
1336                 s = argv(i);
1337                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1338                         return 1;
1339         }
1340
1341         return 0;
1342 }
1343
1344 /*
1345 =============
1346 ClientConnect
1347
1348 Called when a client connects to the server
1349 =============
1350 */
1351 void DecodeLevelParms (void);
1352 //void dom_player_join_team(entity pl);
1353 void set_dom_state(entity e);
1354 void ClientConnect (void)
1355 {
1356         float t;
1357
1358         if(self.flags & FL_CLIENT)
1359         {
1360                 print("Warning: ClientConnect, but already connected!\n");
1361                 return;
1362         }
1363
1364         if(Ban_MaybeEnforceBanOnce(self))
1365                 return;
1366
1367         DecodeLevelParms();
1368
1369 #ifdef WATERMARK
1370         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1371 #endif
1372
1373         self.classname = "player_joining";
1374
1375         self.flags = FL_CLIENT;
1376         self.version_nagtime = time + 10 + random() * 10;
1377
1378         if(player_count<0)
1379         {
1380                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1381                 player_count = 0;
1382         }
1383
1384         PlayerScore_Attach(self);
1385         ClientData_Attach();
1386         accuracy_init(self);
1387
1388         bot_clientconnect();
1389
1390         playerdemo_init();
1391
1392         anticheat_init();
1393
1394         race_PreSpawnObserver();
1395
1396         // identify the right forced team
1397         if(autocvar_g_campaign)
1398         {
1399                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1400                 {
1401                         switch(autocvar_g_campaign_forceteam)
1402                         {
1403                                 case 1: self.team_forced = NUM_TEAM_1; break;
1404                                 case 2: self.team_forced = NUM_TEAM_2; break;
1405                                 case 3: self.team_forced = NUM_TEAM_3; break;
1406                                 case 4: self.team_forced = NUM_TEAM_4; break;
1407                                 default: self.team_forced = 0;
1408                         }
1409                 }
1410         }
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1412                 self.team_forced = NUM_TEAM_1;
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1414                 self.team_forced = NUM_TEAM_2;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1416                 self.team_forced = NUM_TEAM_3;
1417         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1418                 self.team_forced = NUM_TEAM_4;
1419         else if(autocvar_g_forced_team_otherwise == "red")
1420                 self.team_forced = NUM_TEAM_1;
1421         else if(autocvar_g_forced_team_otherwise == "blue")
1422                 self.team_forced = NUM_TEAM_2;
1423         else if(autocvar_g_forced_team_otherwise == "yellow")
1424                 self.team_forced = NUM_TEAM_3;
1425         else if(autocvar_g_forced_team_otherwise == "pink")
1426                 self.team_forced = NUM_TEAM_4;
1427         else if(autocvar_g_forced_team_otherwise == "spectate")
1428                 self.team_forced = -1;
1429         else if(autocvar_g_forced_team_otherwise == "spectator")
1430                 self.team_forced = -1;
1431         else
1432                 self.team_forced = 0;
1433
1434         if(!teamplay)
1435                 if(self.team_forced > 0)
1436                         self.team_forced = 0;
1437
1438         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1439
1440         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1441                 self.classname = "observer";
1442         } else {
1443                 if(teamplay)
1444                 {
1445                         if(autocvar_g_balance_teams)
1446                         {
1447                                 self.classname = "player";
1448                                 campaign_bots_may_start = 1;
1449                         }
1450                         else
1451                         {
1452                                 self.classname = "observer"; // do it anyway
1453                         }
1454                 }
1455                 else
1456                 {
1457                         self.classname = "player";
1458                         campaign_bots_may_start = 1;
1459                 }
1460         }
1461
1462         self.playerid = (playerid_last = playerid_last + 1);
1463
1464         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1465
1466     if(clienttype(self) == CLIENTTYPE_BOT)
1467         PlayerStats_AddPlayer(self);
1468
1469         if(autocvar_sv_eventlog)
1470                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1471
1472         LogTeamchange(self.playerid, self.team, 1);
1473
1474         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1475
1476         self.netname_previous = strzone(self.netname);
1477
1478         if((self.classname == STR_PLAYER && teamplay))
1479                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1480         else
1481                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1482
1483         stuffcmd(self, strcat(clientstuff, "\n"));
1484         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1485
1486         FixClientCvars(self);
1487
1488         // spawnfunc_waypoint sprites
1489         WaypointSprite_InitClient(self);
1490
1491         // Wazat's grappling hook
1492         SetGrappleHookBindings();
1493
1494         // get version info from player
1495         stuffcmd(self, "cmd clientversion $gameversion\n");
1496
1497         // get other cvars from player
1498         GetCvars(0);
1499
1500         // notify about available teams
1501         if(teamplay)
1502         {
1503                 CheckAllowedTeams(self);
1504                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1505                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1506         }
1507         else
1508                 stuffcmd(self, "set _teams_available 0\n");
1509
1510         if(g_arena || g_ca)
1511         {
1512                 self.classname = "observer";
1513                 if(g_arena)
1514                         Spawnqueue_Insert(self);
1515         }
1516
1517         attach_entcs();
1518
1519         bot_relinkplayerlist();
1520
1521         self.spectatortime = time;
1522         if(blockSpectators)
1523         {
1524                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1525         }
1526
1527         self.jointime = time;
1528         self.allowed_timeouts = autocvar_sv_timeout_number;
1529
1530         if(clienttype(self) == CLIENTTYPE_REAL)
1531         {
1532                 if(!autocvar_g_campaign)
1533                 {
1534                         self.motd_actived_time = -1;
1535                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1536                 }
1537
1538                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1539                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1540         }
1541
1542         if(g_lms)
1543         {
1544                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1545                 {
1546                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1547                         self.frags = FRAGS_SPECTATOR;
1548                 }
1549         }
1550
1551         if(!sv_foginterval && world.fog != "")
1552                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1553
1554         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1555         {
1556                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1557                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1558         }
1559         else
1560                 self.hitplotfh = -1;
1561
1562         if(g_race || g_cts) {
1563                 string rr;
1564                 if(g_cts)
1565                         rr = CTS_RECORD;
1566                 else
1567                         rr = RACE_RECORD;
1568
1569                 msg_entity = self;
1570                 race_send_recordtime(MSG_ONE);
1571                 race_send_speedaward(MSG_ONE);
1572
1573                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1574                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1575                 race_send_speedaward_alltimebest(MSG_ONE);
1576
1577                 float i;
1578                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1579                         race_SendRankings(i, 0, 0, MSG_ONE);
1580                 }
1581         }
1582         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1583                 send_CSQC_teamnagger();
1584
1585         CheatInitClient();
1586
1587         CSQCMODEL_AUTOINIT();
1588
1589         self.model_randomizer = random();
1590
1591     if(clienttype(self) != CLIENTTYPE_REAL)
1592         return;
1593
1594     sv_notice_join();
1595
1596     MUTATOR_CALLHOOK(ClientConnect);
1597 }
1598 /*
1599 =============
1600 ClientDisconnect
1601
1602 Called when a client disconnects from the server
1603 =============
1604 */
1605 .entity chatbubbleentity;
1606 void ReadyCount();
1607 void ClientDisconnect (void)
1608 {
1609         if(self.vehicle)
1610             vehicles_exit(VHEF_RELESE);
1611
1612         if not(self.flags & FL_CLIENT)
1613         {
1614                 print("Warning: ClientDisconnect without ClientConnect\n");
1615                 return;
1616         }
1617
1618         PlayerStats_AddGlobalInfo(self);
1619
1620         CheatShutdownClient();
1621
1622         if(self.hitplotfh >= 0)
1623         {
1624                 fclose(self.hitplotfh);
1625                 self.hitplotfh = -1;
1626         }
1627
1628         anticheat_report();
1629         anticheat_shutdown();
1630
1631         playerdemo_shutdown();
1632
1633         bot_clientdisconnect();
1634
1635         if(self.entcs)
1636                 detach_entcs();
1637
1638         if(autocvar_sv_eventlog)
1639                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1640
1641         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1642
1643         DropAllRunes(self);
1644         MUTATOR_CALLHOOK(ClientDisconnect);
1645
1646         Portal_ClearAll(self);
1647
1648         RemoveGrapplingHook(self);
1649
1650         // Here, everything has been done that requires this player to be a client.
1651
1652         self.flags &~= FL_CLIENT;
1653
1654         if (self.chatbubbleentity)
1655                 remove (self.chatbubbleentity);
1656
1657         if (self.killindicator)
1658                 remove (self.killindicator);
1659
1660         WaypointSprite_PlayerGone();
1661
1662         bot_relinkplayerlist();
1663
1664         if(g_arena)
1665         {
1666                 Spawnqueue_Unmark(self);
1667                 Spawnqueue_Remove(self);
1668         }
1669
1670         accuracy_free(self);
1671         ClientData_Detach();
1672         PlayerScore_Detach(self);
1673
1674         if(self.netname_previous)
1675                 strunzone(self.netname_previous);
1676         if(self.clientstatus)
1677                 strunzone(self.clientstatus);
1678         if(self.weaponorder_byimpulse)
1679                 strunzone(self.weaponorder_byimpulse);
1680
1681         ClearPlayerSounds();
1682
1683         if(self.personal)
1684                 remove(self.personal);
1685
1686         self.playerid = 0;
1687         ReadyCount();
1688
1689         // free cvars
1690         GetCvars(-1);
1691 }
1692
1693 .float BUTTON_CHAT;
1694 void ChatBubbleThink()
1695 {
1696         self.nextthink = time;
1697         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1698         {
1699                 if(self.owner) // but why can that ever be world?
1700                         self.owner.chatbubbleentity = world;
1701                 remove(self);
1702                 return;
1703         }
1704         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1705 #ifdef TETRIS
1706                 || self.owner.tetris_on
1707 #endif
1708         )
1709                 self.model = self.mdl;
1710         else
1711                 self.model = "";
1712 }
1713
1714 void UpdateChatBubble()
1715 {
1716         if (self.alpha < 0)
1717                 return;
1718         // spawn a chatbubble entity if needed
1719         if (!self.chatbubbleentity)
1720         {
1721                 self.chatbubbleentity = spawn();
1722                 self.chatbubbleentity.owner = self;
1723                 self.chatbubbleentity.exteriormodeltoclient = self;
1724                 self.chatbubbleentity.think = ChatBubbleThink;
1725                 self.chatbubbleentity.nextthink = time;
1726                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1727                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1728                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1729                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1730                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1731                 self.chatbubbleentity.model = "";
1732                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1733         }
1734 }
1735
1736
1737 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1738 // added to the model skins
1739 /*void UpdateColorModHack()
1740 {
1741         float c;
1742         c = self.clientcolors & 15;
1743         // LordHavoc: only bothering to support white, green, red, yellow, blue
1744              if (!teamplay) self.colormod = '0 0 0';
1745         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1746         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1747         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1748         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1749         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1750         else self.colormod = '1 1 1';
1751 }*/
1752
1753 void respawn(void)
1754 {
1755         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1756         {
1757                 self.solid = SOLID_NOT;
1758                 self.takedamage = DAMAGE_NO;
1759                 self.movetype = MOVETYPE_FLY;
1760                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1761                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1762                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1763                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1764                 if(autocvar_g_respawn_ghosts_maxtime)
1765                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1766         }
1767
1768         CopyBody(1);
1769
1770         self.effects |= EF_NODRAW; // prevent another CopyBody
1771         PutClientInServer();
1772 }
1773
1774 void play_countdown(float finished, string samp)
1775 {
1776         if(clienttype(self) == CLIENTTYPE_REAL)
1777                 if(floor(finished - time - frametime) != floor(finished - time))
1778                         if(finished - time < 6)
1779                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1780 }
1781
1782 void player_powerups (void)
1783 {
1784         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1785         olditems = self.items;
1786
1787         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1788                 self.modelflags |= MF_ROCKET;
1789         else
1790                 self.modelflags &~= MF_ROCKET;
1791
1792         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1793
1794         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1795                 return;
1796
1797         Fire_ApplyDamage(self);
1798         Fire_ApplyEffect(self);
1799
1800         if (g_minstagib)
1801         {
1802                 self.effects |= EF_FULLBRIGHT;
1803
1804                 if (self.items & IT_STRENGTH)
1805                 {
1806                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1807                         if (time > self.strength_finished)
1808                         {
1809                                 self.alpha = default_player_alpha;
1810                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1811                                 self.items &~= IT_STRENGTH;
1812                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1813                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1814                         }
1815                 }
1816                 else
1817                 {
1818                         if (time < self.strength_finished)
1819                         {
1820                                 self.alpha = g_minstagib_invis_alpha;
1821                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1822                                 self.items |= IT_STRENGTH;
1823                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1824                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1825                         }
1826                 }
1827
1828                 if (self.items & IT_INVINCIBLE)
1829                 {
1830                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1831                         if (time > self.invincible_finished)
1832                         {
1833                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1834                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1835                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1836                         }
1837                 }
1838                 else
1839                 {
1840                         if (time < self.invincible_finished)
1841                         {
1842                                 self.items = self.items | IT_INVINCIBLE;
1843                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1844                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1845                         }
1846                 }
1847         }
1848         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1849         {
1850                 if (self.items & IT_STRENGTH)
1851                 {
1852                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1853                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1854                         if (time > self.strength_finished)
1855                         {
1856                                 self.items = self.items - (self.items & IT_STRENGTH);
1857                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1858                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1859                         }
1860                 }
1861                 else
1862                 {
1863                         if (time < self.strength_finished)
1864                         {
1865                                 self.items = self.items | IT_STRENGTH;
1866                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1867                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1868                         }
1869                 }
1870                 if (self.items & IT_INVINCIBLE)
1871                 {
1872                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1873                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1874                         if (time > self.invincible_finished)
1875                         {
1876                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1877                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1878                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1879                         }
1880                 }
1881                 else
1882                 {
1883                         if (time < self.invincible_finished)
1884                         {
1885                                 self.items = self.items | IT_INVINCIBLE;
1886                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1887                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1888                         }
1889                 }
1890                 if (self.items & IT_SUPERWEAPON)
1891                 {
1892                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1893                         {
1894                                 self.superweapons_finished = 0;
1895                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1896                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1897                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1898                         }
1899                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1900                         {
1901                                 // don't let them run out
1902                         }
1903                         else
1904                         {
1905                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1906                                 if (time > self.superweapons_finished)
1907                                 {
1908                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1909                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1910                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1911                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1912                                 }
1913                         }
1914                 }
1915                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1916                 {
1917                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1918                         {
1919                                 self.items = self.items | IT_SUPERWEAPON;
1920                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1921                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1922                         }
1923                         else
1924                         {
1925                                 self.superweapons_finished = 0;
1926                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1927                         }
1928                 }
1929                 else
1930                 {
1931                         self.superweapons_finished = 0;
1932                 }
1933         }
1934
1935         if(autocvar_g_nodepthtestplayers)
1936                 self.effects = self.effects | EF_NODEPTHTEST;
1937
1938         if(autocvar_g_fullbrightplayers)
1939                 self.effects = self.effects | EF_FULLBRIGHT;
1940
1941         // midair gamemode: damage only while in the air
1942         // if in midair mode, being on ground grants temporary invulnerability
1943         // (this is so that multishot weapon don't clear the ground flag on the
1944         // first damage in the frame, leaving the player vulnerable to the
1945         // remaining hits in the same frame)
1946         if (self.flags & FL_ONGROUND)
1947         if (g_midair)
1948                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1949
1950         if (time >= game_starttime)
1951         if (time < self.spawnshieldtime)
1952                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1953
1954         MUTATOR_CALLHOOK(PlayerPowerups);
1955 }
1956
1957 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1958 {
1959         if(current > stable)
1960                 return current;
1961         else if(current > stable - 0.25) // when close enough, "snap"
1962                 return stable;
1963         else
1964                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1965 }
1966
1967 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1968 {
1969         if(current < stable)
1970                 return current;
1971         else if(current < stable + 0.25) // when close enough, "snap"
1972                 return stable;
1973         else
1974                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1975 }
1976
1977 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1978 {
1979         if(current > rotstable)
1980         {
1981                 if(rotframetime > 0)
1982                 {
1983                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1984                         current = max(rotstable, current - rotlinear * rotframetime);
1985                 }
1986         }
1987         else if(current < regenstable)
1988         {
1989                 if(regenframetime > 0)
1990                 {
1991                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1992                         current = min(regenstable, current + regenlinear * regenframetime);
1993                 }
1994         }
1995
1996         if(current > limit)
1997                 current = limit;
1998
1999         return current;
2000 }
2001
2002 void player_regen (void)
2003 {
2004         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2005         maxh = autocvar_g_balance_health_rotstable;
2006         maxa = autocvar_g_balance_armor_rotstable;
2007         maxf = autocvar_g_balance_fuel_rotstable;
2008         minh = autocvar_g_balance_health_regenstable;
2009         mina = autocvar_g_balance_armor_regenstable;
2010         minf = autocvar_g_balance_fuel_regenstable;
2011         limith = autocvar_g_balance_health_limit;
2012         limita = autocvar_g_balance_armor_limit;
2013         limitf = autocvar_g_balance_fuel_limit;
2014
2015         max_mod = regen_mod = rot_mod = limit_mod = 1;
2016
2017         if (self.runes & RUNE_REGEN)
2018         {
2019                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2020                 {
2021                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2022                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2023                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2024                 }
2025                 else
2026                 {
2027                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2028                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2029                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2030                 }
2031         }
2032         else if (self.runes & CURSE_VENOM)
2033         {
2034                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2035                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2036                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2037                 else
2038                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2039                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2040                 //if (!self.runes & RUNE_REGEN)
2041                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2042         }
2043         maxh = maxh * max_mod;
2044         //maxa = maxa * max_mod;
2045         //maxf = maxf * max_mod;
2046         minh = minh * max_mod;
2047         //mina = mina * max_mod;
2048         //minf = minf * max_mod;
2049         limith = limith * limit_mod;
2050         limita = limita * limit_mod;
2051         //limitf = limitf * limit_mod;
2052
2053         if(g_lms && g_ca)
2054                 rot_mod = 0;
2055
2056         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2057         {
2058                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2059                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2060
2061                 // if player rotted to death...  die!
2062                 if(self.health < 1)
2063                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2064         }
2065
2066         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2067                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2068 }
2069
2070 float zoomstate_set;
2071 void SetZoomState(float z)
2072 {
2073         if(z != self.zoomstate)
2074         {
2075                 self.zoomstate = z;
2076                 ClientData_Touch(self);
2077         }
2078         zoomstate_set = 1;
2079 }
2080
2081 void GetPressedKeys(void) {
2082         MUTATOR_CALLHOOK(GetPressedKeys);
2083         if (self.movement_x > 0) // get if movement keys are pressed
2084         {       // forward key pressed
2085                 self.pressedkeys |= KEY_FORWARD;
2086                 self.pressedkeys &~= KEY_BACKWARD;
2087         }
2088         else if (self.movement_x < 0)
2089         {       // backward key pressed
2090                 self.pressedkeys |= KEY_BACKWARD;
2091                 self.pressedkeys &~= KEY_FORWARD;
2092         }
2093         else
2094         {       // no x input
2095                 self.pressedkeys &~= KEY_FORWARD;
2096                 self.pressedkeys &~= KEY_BACKWARD;
2097         }
2098
2099         if (self.movement_y > 0)
2100         {       // right key pressed
2101                 self.pressedkeys |= KEY_RIGHT;
2102                 self.pressedkeys &~= KEY_LEFT;
2103         }
2104         else if (self.movement_y < 0)
2105         {       // left key pressed
2106                 self.pressedkeys |= KEY_LEFT;
2107                 self.pressedkeys &~= KEY_RIGHT;
2108         }
2109         else
2110         {       // no y input
2111                 self.pressedkeys &~= KEY_RIGHT;
2112                 self.pressedkeys &~= KEY_LEFT;
2113         }
2114
2115         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2116                 self.pressedkeys |= KEY_JUMP;
2117         else
2118                 self.pressedkeys &~= KEY_JUMP;
2119         if (self.BUTTON_CROUCH)
2120                 self.pressedkeys |= KEY_CROUCH;
2121         else
2122                 self.pressedkeys &~= KEY_CROUCH;
2123
2124         if (self.BUTTON_ATCK)
2125                 self.pressedkeys |= KEY_ATCK;
2126         else
2127                 self.pressedkeys &~= KEY_ATCK;
2128         if (self.BUTTON_ATCK2)
2129                 self.pressedkeys |= KEY_ATCK2;
2130         else
2131                 self.pressedkeys &~= KEY_ATCK2;
2132 }
2133
2134 /*
2135 ======================
2136 spectate mode routines
2137 ======================
2138 */
2139
2140 void SpectateCopy(entity spectatee) {
2141         other = spectatee;
2142         MUTATOR_CALLHOOK(SpectateCopy);
2143         self.armortype = spectatee.armortype;
2144         self.armorvalue = spectatee.armorvalue;
2145         self.ammo_cells = spectatee.ammo_cells;
2146         self.ammo_shells = spectatee.ammo_shells;
2147         self.ammo_nails = spectatee.ammo_nails;
2148         self.ammo_rockets = spectatee.ammo_rockets;
2149         self.ammo_fuel = spectatee.ammo_fuel;
2150         self.clip_load = spectatee.clip_load;
2151         self.clip_size = spectatee.clip_size;
2152         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2153         self.health = spectatee.health;
2154         self.impulse = 0;
2155         self.items = spectatee.items;
2156         self.last_pickup = spectatee.last_pickup;
2157         self.hit_time = spectatee.hit_time;
2158         self.metertime = spectatee.metertime;
2159         self.strength_finished = spectatee.strength_finished;
2160         self.invincible_finished = spectatee.invincible_finished;
2161         self.pressedkeys = spectatee.pressedkeys;
2162         WEPSET_COPY_EE(self, spectatee);
2163         self.switchweapon = spectatee.switchweapon;
2164         self.switchingweapon = spectatee.switchingweapon;
2165         self.weapon = spectatee.weapon;
2166         self.nex_charge = spectatee.nex_charge;
2167         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2168         self.hagar_load = spectatee.hagar_load;
2169         self.minelayer_mines = spectatee.minelayer_mines;
2170         self.punchangle = spectatee.punchangle;
2171         self.view_ofs = spectatee.view_ofs;
2172         self.velocity = spectatee.velocity;
2173         self.dmg_take = spectatee.dmg_take;
2174         self.dmg_save = spectatee.dmg_save;
2175         self.dmg_inflictor = spectatee.dmg_inflictor;
2176         self.v_angle = spectatee.v_angle;
2177         self.angles = spectatee.v_angle;
2178         self.stat_respawn_time = spectatee.stat_respawn_time;
2179         if(!self.BUTTON_USE)
2180                 self.fixangle = TRUE;
2181         setorigin(self, spectatee.origin);
2182         setsize(self, spectatee.mins, spectatee.maxs);
2183         SetZoomState(spectatee.zoomstate);
2184
2185     anticheat_spectatecopy(spectatee);
2186         self.hud = spectatee.hud;
2187         if(spectatee.vehicle)
2188     {
2189         self.fixangle = FALSE;
2190         //self.velocity = spectatee.vehicle.velocity;
2191         self.vehicle_health = spectatee.vehicle_health;
2192         self.vehicle_shield = spectatee.vehicle_shield;
2193         self.vehicle_energy = spectatee.vehicle_energy;
2194         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2195         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2196         self.vehicle_reload1 = spectatee.vehicle_reload1;
2197         self.vehicle_reload2 = spectatee.vehicle_reload2;
2198
2199         msg_entity = self;
2200
2201         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2202             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2203             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2204             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2205
2206         //WriteByte (MSG_ONE, SVC_SETVIEW);
2207         //    WriteEntity(MSG_ONE, self);
2208         //makevectors(spectatee.v_angle);
2209         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2210     }
2211 }
2212
2213 float SpectateUpdate() {
2214         if(!self.enemy)
2215             return 0;
2216
2217         if (self == self.enemy)
2218                 return 0;
2219
2220         if(self.enemy.classname != "player")
2221                 return 0;
2222
2223         SpectateCopy(self.enemy);
2224
2225         return 1;
2226 }
2227
2228
2229 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2230 entity CA_SpectateNext(entity start) {
2231         if (start.team == self.team) {
2232                 return start;
2233         }
2234
2235         other = start;
2236         // continue from current player
2237         while(other && other.team != self.team) {
2238                 other = find(other, classname, "player");
2239         }
2240
2241         if (!other) {
2242                 // restart from begining
2243                 other = find(other, classname, "player");
2244                 while(other && other.team != self.team) {
2245                         other = find(other, classname, "player");
2246                 }
2247         }
2248
2249         return other;
2250 }
2251
2252 float SpectateNext(entity _prefer) {
2253
2254         if(_prefer)
2255                 other = _prefer;
2256         else
2257                 other = find(self.enemy, classname, "player");
2258
2259         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2260                 // CA and ca players when spectating enemies is forbidden
2261                 other = CA_SpectateNext(other);
2262         } else {
2263                 // other modes and ca spectators or spectating enemies is allowed
2264                 if (!other)
2265                         other = find(other, classname, "player");
2266         }
2267
2268         if (other)
2269                 self.enemy = other;
2270
2271         if(self.enemy.classname == "player") {
2272             /*if(self.enemy.vehicle)
2273             {
2274
2275             msg_entity = self;
2276             WriteByte(MSG_ONE, SVC_SETVIEW);
2277             WriteEntity(MSG_ONE, self.enemy);
2278             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2279
2280             self.movetype = MOVETYPE_NONE;
2281             accuracy_resend(self);
2282             }
2283             else
2284             {*/
2285             msg_entity = self;
2286             WriteByte(MSG_ONE, SVC_SETVIEW);
2287             WriteEntity(MSG_ONE, self.enemy);
2288             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2289             self.movetype = MOVETYPE_NONE;
2290             accuracy_resend(self);
2291
2292             if(!SpectateUpdate())
2293                 PutObserverInServer();
2294         //}
2295         return 1;
2296         } else {
2297                 return 0;
2298         }
2299 }
2300
2301 /*
2302 =============
2303 ShowRespawnCountdown()
2304
2305 Update a respawn countdown display.
2306 =============
2307 */
2308 void ShowRespawnCountdown()
2309 {
2310         float number;
2311         if(self.deadflag == DEAD_NO) // just respawned?
2312                 return;
2313         else
2314         {
2315                 number = ceil(self.respawn_time - time);
2316                 if(number <= 0)
2317                         return;
2318                 if(number <= self.respawn_countdown)
2319                 {
2320                         self.respawn_countdown = number - 1;
2321                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2322                                 AnnounceTo(self, strcat(ftos(number), ""));
2323                 }
2324         }
2325 }
2326
2327 void LeaveSpectatorMode()
2328 {
2329         if(nJoinAllowed(self))
2330         {
2331                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2332                 {
2333                         self.classname = "player";
2334
2335                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2336                                 { JoinBestTeam(self, FALSE, TRUE); }
2337
2338                         if(autocvar_g_campaign)
2339                                 { campaign_bots_may_start = 1; }
2340
2341                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2342
2343                         PutClientInServer();
2344
2345                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2346                 }
2347                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2348         }
2349         else
2350         {
2351                 // Player may not join because g_maxplayers is set
2352                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2353         }
2354 }
2355
2356 /**
2357  * Determines whether the player is allowed to join. This depends on cvar
2358  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2359  * it checks whether the number of currently playing players exceeds g_maxplayers.
2360  * @return int number of free slots for players, 0 if none
2361  */
2362 float nJoinAllowed(entity ignore) {
2363         if(!ignore)
2364         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2365         // so report 0 free slots if restricted
2366         {
2367                 if(autocvar_g_forced_team_otherwise == "spectate")
2368                         return 0;
2369                 if(autocvar_g_forced_team_otherwise == "spectator")
2370                         return 0;
2371         }
2372
2373         if(self.team_forced < 0)
2374                 return 0; // forced spectators can never join
2375
2376         // TODO simplify this
2377         entity e;
2378         float totalClients = 0;
2379         FOR_EACH_CLIENT(e)
2380                 if(e != ignore)
2381                         totalClients += 1;
2382
2383         if (!autocvar_g_maxplayers)
2384                 return maxclients - totalClients;
2385
2386         float currentlyPlaying = 0;
2387         FOR_EACH_REALPLAYER(e)
2388                 currentlyPlaying += 1;
2389
2390         if(currentlyPlaying < autocvar_g_maxplayers)
2391                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2392
2393         return 0;
2394 }
2395
2396 /**
2397  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2398  * g_maxplayers_spectator_blocktime seconds
2399  */
2400 void checkSpectatorBlock() {
2401         if(self.classname == "spectator" || self.classname == "observer") {
2402                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2403                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2404                         dropclient(self);
2405                 }
2406         }
2407 }
2408
2409 void PrintWelcomeMessage()
2410 {
2411         if(self.motd_actived_time == 0)
2412         {
2413                 if (autocvar_g_campaign) {
2414                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2415                                 self.motd_actived_time = time;
2416                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2417                         }
2418                 } else {
2419                         if (self.BUTTON_INFO) {
2420                                 self.motd_actived_time = time;
2421                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2422                         }
2423                 }
2424         }
2425         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2426         {
2427                 if (autocvar_g_campaign) {
2428                         if (self.BUTTON_INFO)
2429                                 self.motd_actived_time = time;
2430                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2431                                 self.motd_actived_time = 0;
2432                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2433                         }
2434                 } else {
2435                         if (self.BUTTON_INFO)
2436                                 self.motd_actived_time = time;
2437                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2438                                 self.motd_actived_time = 0;
2439                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2440                         }
2441                 }
2442         }
2443         else //if(self.motd_actived_time < 0) // just connected, motd is active
2444         {
2445                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2446                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2447                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2448                 {
2449                         // instanctly hide MOTD
2450                         self.motd_actived_time = 0;
2451                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2452                 }
2453         }
2454 }
2455
2456 void ObserverThink()
2457 {
2458         float prefered_movetype;
2459         if (self.flags & FL_JUMPRELEASED) {
2460                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2461                         self.flags &~= FL_JUMPRELEASED;
2462                         self.flags |= FL_SPAWNING;
2463                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         if(SpectateNext(world) == 1) {
2466                                 self.classname = "spectator";
2467                         }
2468                 } else {
2469                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2470                         if (self.movetype != prefered_movetype)
2471                                 self.movetype = prefered_movetype;
2472                 }
2473         } else {
2474                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2475                         self.flags |= FL_JUMPRELEASED;
2476                         if(self.flags & FL_SPAWNING)
2477                         {
2478                                 self.flags &~= FL_SPAWNING;
2479                                 LeaveSpectatorMode();
2480                                 return;
2481                         }
2482                 }
2483         }
2484 }
2485
2486 void SpectatorThink()
2487 {
2488         if (self.flags & FL_JUMPRELEASED) {
2489                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2490                         self.flags &~= FL_JUMPRELEASED;
2491                         self.flags |= FL_SPAWNING;
2492                 } else if(self.BUTTON_ATCK) {
2493                         self.flags &~= FL_JUMPRELEASED;
2494                         if(SpectateNext(world) == 1) {
2495                                 self.classname = "spectator";
2496                         } else {
2497                                 self.classname = "observer";
2498                                 PutClientInServer();
2499                         }
2500                 } else if (self.BUTTON_ATCK2) {
2501                         self.flags &~= FL_JUMPRELEASED;
2502                         self.classname = "observer";
2503                         PutClientInServer();
2504                 } else {
2505                         if(!SpectateUpdate())
2506                                 PutObserverInServer();
2507                 }
2508         } else {
2509                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2510                         self.flags |= FL_JUMPRELEASED;
2511                         if(self.flags & FL_SPAWNING)
2512                         {
2513                                 self.flags &~= FL_SPAWNING;
2514                                 LeaveSpectatorMode();
2515                                 return;
2516                         }
2517                 }
2518                 if(!SpectateUpdate())
2519                         PutObserverInServer();
2520         }
2521
2522         self.flags |= FL_CLIENT | FL_NOTARGET;
2523 }
2524
2525 void PlayerUseKey()
2526 {
2527         if(self.classname != "player")
2528                 return;
2529
2530         if(self.vehicle)
2531         {
2532         vehicles_exit(VHEF_NORMAL);
2533         return;
2534         }
2535
2536         // a use key was pressed; call handlers
2537         MUTATOR_CALLHOOK(PlayerUseKey);
2538 }
2539
2540 .float touchexplode_time;
2541
2542 /*
2543 =============
2544 PlayerPreThink
2545
2546 Called every frame for each client before the physics are run
2547 =============
2548 */
2549 .float usekeypressed;
2550 void() nexball_setstatus;
2551 .float items_added;
2552 void PlayerPreThink (void)
2553 {
2554         WarpZone_PlayerPhysics_FixVAngle();
2555
2556         self.stat_game_starttime = game_starttime;
2557         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2558         self.stat_leadlimit = autocvar_leadlimit;
2559
2560         if(g_arena || (g_ca && !allowed_to_spawn))
2561                 self.stat_respawn_time = 0;
2562         else
2563                 self.stat_respawn_time = self.respawn_time;
2564
2565         if(frametime)
2566         {
2567                 // physics frames: update anticheat stuff
2568                 anticheat_prethink();
2569         }
2570
2571         if(blockSpectators && frametime)
2572                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2573                 checkSpectatorBlock();
2574
2575         zoomstate_set = 0;
2576
2577         if(self.netname_previous != self.netname)
2578         {
2579                 if(autocvar_sv_eventlog)
2580                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2581                 if(self.netname_previous)
2582                         strunzone(self.netname_previous);
2583                 self.netname_previous = strzone(self.netname);
2584         }
2585
2586         // version nagging
2587         if(self.version_nagtime)
2588                 if(self.cvar_g_xonoticversion)
2589                         if(time > self.version_nagtime)
2590                         {
2591                                 // don't notify git users
2592                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2593                                 {
2594                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2595                                         {
2596                                                 // notify release users if connecting to git
2597                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2598                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2599                                         }
2600                                         else
2601                                         {
2602                                                 float r;
2603                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2604                                                 if(r < 0)
2605                                                 {
2606                                                         // give users new version
2607                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2608                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2609                                                 }
2610                                                 else if(r > 0)
2611                                                 {
2612                                                         // notify users about old server version
2613                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2614                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2615                                                 }
2616                                         }
2617                                 }
2618                                 self.version_nagtime = 0;
2619                         }
2620
2621         // GOD MODE info
2622         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2623         {
2624                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2625                 self.max_armorvalue = 0;
2626         }
2627
2628 #ifdef TETRIS
2629         if (TetrisPreFrame())
2630                 return;
2631 #endif
2632
2633         MUTATOR_CALLHOOK(PlayerPreThink);
2634
2635         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2636         {
2637                 if(self.BUTTON_USE && !self.usekeypressed)
2638                         PlayerUseKey();
2639                 self.usekeypressed = self.BUTTON_USE;
2640         }
2641
2642         if(clienttype(self) == CLIENTTYPE_REAL)
2643                 PrintWelcomeMessage();
2644
2645         if(self.classname == "player") {
2646
2647                 CheckRules_Player();
2648
2649                 if (intermission_running)
2650                 {
2651                         IntermissionThink ();   // otherwise a button could be missed between
2652                         return;                                 // the think tics
2653                 }
2654
2655                 //don't allow the player to turn around while game is paused!
2656                 if(timeout_status == TIMEOUT_ACTIVE) {
2657                         // FIXME turn this into CSQC stuff
2658                         self.v_angle = self.lastV_angle;
2659                         self.angles = self.lastV_angle;
2660                         self.fixangle = TRUE;
2661                 }
2662
2663                 if(frametime)
2664                 {
2665                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2666                         {
2667                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2668                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2669                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2670
2671                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2672                                 {
2673                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2674                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2675                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2676                                 }
2677                         }
2678                         else
2679                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2680
2681                         player_powerups();
2682                 }
2683
2684                 if (g_minstagib)
2685                         minstagib_ammocheck();
2686
2687                 if (self.deadflag != DEAD_NO)
2688                 {
2689                         float button_pressed, force_respawn;
2690                         if(self.personal && g_race_qualifying)
2691                         {
2692                                 if(time > self.respawn_time)
2693                                 {
2694                                         self.respawn_time = time + 1; // only retry once a second
2695                                         respawn();
2696                                         self.impulse = 141;
2697                                 }
2698                         }
2699                         else
2700                         {
2701                                 if(frametime)
2702                                         player_anim();
2703                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2704                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2705                                 if (self.deadflag == DEAD_DYING)
2706                                 {
2707                                         if(force_respawn)
2708                                                 self.deadflag = DEAD_RESPAWNING;
2709                                         else if(!button_pressed)
2710                                                 self.deadflag = DEAD_DEAD;
2711                                 }
2712                                 else if (self.deadflag == DEAD_DEAD)
2713                                 {
2714                                         if(button_pressed)
2715                                                 self.deadflag = DEAD_RESPAWNABLE;
2716                                 }
2717                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2718                                 {
2719                                         if(!button_pressed)
2720                                                 self.deadflag = DEAD_RESPAWNING;
2721                                 }
2722                                 else if (self.deadflag == DEAD_RESPAWNING)
2723                                 {
2724                                         if(time > self.respawn_time)
2725                                         {
2726                                                 self.respawn_time = time + 1; // only retry once a second
2727                                                 respawn();
2728                                         }
2729                                 }
2730                                 ShowRespawnCountdown();
2731                         }
2732
2733                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2734                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2735                                 self.stat_respawn_time *= -1;
2736
2737                         return;
2738                 }
2739                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2740                 // so (self.deadflag == DEAD_NO) is always true in the code below
2741
2742                 if(g_touchexplode)
2743                 if(time > self.touchexplode_time)
2744                 if(self.classname == "player")
2745                 if(self.deadflag == DEAD_NO)
2746                 if not(IS_INDEPENDENT_PLAYER(self))
2747                 FOR_EACH_PLAYER(other) if(self != other)
2748                 {
2749                         if(time > other.touchexplode_time)
2750                         if(other.deadflag == DEAD_NO)
2751                         if not(IS_INDEPENDENT_PLAYER(other))
2752                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2753                         {
2754                                 PlayerTouchExplode(self, other);
2755                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2756                         }
2757                 }
2758
2759                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2760                 {
2761                         vector dist;
2762
2763                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2764                         dist = self.prevorigin - self.origin;
2765                         dist_z = 0;
2766                         self.lms_traveled_distance += fabs(vlen(dist));
2767
2768                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2769                         {
2770                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2771                                 self.lms_traveled_distance = 0;
2772                         }
2773
2774                         if(time > self.lms_nextcheck)
2775                         {
2776                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2777                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2778                                 {
2779                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
2780                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2781                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2782                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2783                                 }
2784                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2785                                 self.lms_traveled_distance = 0;
2786                         }
2787                 }
2788
2789                 self.prevorigin = self.origin;
2790
2791                 float do_crouch = self.BUTTON_CROUCH;
2792                 if(self.hook.state)
2793                         do_crouch = 0;
2794                 if(self.health <= g_bloodloss)
2795                         do_crouch = 1;
2796                 if(self.vehicle)
2797                         do_crouch = 0;
2798                 if(self.freezetag_frozen)
2799                         do_crouch = 0;
2800                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2801                         do_crouch = 0;
2802
2803                 if (do_crouch)
2804                 {
2805                         if (!self.crouch)
2806                         {
2807                                 self.crouch = TRUE;
2808                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2809                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2810                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2811                         }
2812                 }
2813                 else
2814                 {
2815                         if (self.crouch)
2816                         {
2817                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2818                                 if (!trace_startsolid)
2819                                 {
2820                                         self.crouch = FALSE;
2821                                         self.view_ofs = PL_VIEW_OFS;
2822                                         setsize (self, PL_MIN, PL_MAX);
2823                                 }
2824                         }
2825                 }
2826
2827                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2828                 {
2829                         if(self.bloodloss_timer < time)
2830                         {
2831                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2832                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2833                         }
2834                 }
2835
2836                 FixPlayermodel();
2837
2838                 GrapplingHookFrame();
2839
2840                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2841                 //if(frametime)
2842                 {
2843                         self.items &~= self.items_added;
2844
2845                         W_WeaponFrame();
2846
2847                         self.items_added = 0;
2848                         if(self.items & IT_JETPACK)
2849                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2850                                         self.items_added |= IT_FUEL;
2851
2852                         self.items |= self.items_added;
2853                 }
2854
2855                 player_regen();
2856
2857                 // rot nex charge to the charge limit
2858                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2859                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2860
2861                 if(frametime)
2862                         player_anim();
2863
2864                 if(g_nexball)
2865                         nexball_setstatus();
2866
2867                 // secret status
2868                 secrets_setstatus();
2869
2870                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2871
2872                 //self.angles_y=self.v_angle_y + 90;   // temp
2873         } else if(gameover) {
2874                 if (intermission_running)
2875                         IntermissionThink ();   // otherwise a button could be missed between
2876                 return;
2877         } else if(self.classname == "observer") {
2878                 ObserverThink();
2879         } else if(self.classname == "spectator") {
2880                 SpectatorThink();
2881         }
2882
2883         if(!zoomstate_set)
2884                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2885
2886         float oldspectatee_status;
2887         oldspectatee_status = self.spectatee_status;
2888         if(self.classname == "spectator")
2889                 self.spectatee_status = num_for_edict(self.enemy);
2890         else if(self.classname == "observer")
2891                 self.spectatee_status = num_for_edict(self);
2892         else
2893                 self.spectatee_status = 0;
2894         if(self.spectatee_status != oldspectatee_status)
2895         {
2896                 ClientData_Touch(self);
2897                 if(g_race || g_cts)
2898                         race_InitSpectator();
2899         }
2900
2901         if(self.teamkill_soundtime)
2902         if(time > self.teamkill_soundtime)
2903         {
2904                 self.teamkill_soundtime = 0;
2905
2906                 entity oldpusher, oldself;
2907
2908                 oldself = self; self = self.teamkill_soundsource;
2909                 oldpusher = self.pusher; self.pusher = oldself;
2910
2911                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2912
2913                 self.pusher = oldpusher;
2914                 self = oldself;
2915         }
2916
2917         if(self.taunt_soundtime)
2918         if(time > self.taunt_soundtime)
2919         {
2920                 self.taunt_soundtime = 0;
2921                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2922         }
2923
2924         target_voicescript_next(self);
2925
2926         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2927         if(!self.weapon)
2928                 self.clip_load = self.clip_size = 0;
2929 }
2930
2931 float isInvisibleString(string s)
2932 {
2933         float i, n, c;
2934         s = strdecolorize(s);
2935         for((i = 0), (n = strlen(s)); i < n; ++i)
2936         {
2937                 c = str2chr(s, i);
2938                 switch(c)
2939                 {
2940                         case 0:
2941                         case 32: // space
2942                                 break;
2943                         case 192: // charmap space
2944                                 if (!autocvar_utf8_enable)
2945                                         break;
2946                                 return FALSE;
2947                         case 160: // space in unicode fonts
2948                         case 0xE000 + 192: // utf8 charmap space
2949                                 if (autocvar_utf8_enable)
2950                                         break;
2951                         default:
2952                                 return FALSE;
2953                 }
2954         }
2955         return TRUE;
2956 }
2957
2958 /*
2959 =============
2960 PlayerPostThink
2961
2962 Called every frame for each client after the physics are run
2963 =============
2964 */
2965 .float idlekick_lasttimeleft;
2966 void PlayerPostThink (void)
2967 {
2968         // Savage: Check for nameless players
2969         if (isInvisibleString(self.netname)) {
2970                 self.netname = "Player";
2971                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2972         }
2973
2974         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2975         {
2976                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2977                 {
2978                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2979                 }
2980                 else
2981                 {
2982                         float timeleft;
2983                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2984                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2985                         {
2986                                 if(!self.idlekick_lasttimeleft)
2987                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2988                         }
2989                         if(timeleft <= 0)
2990                         {
2991                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2992                                 dropclient(self);
2993                                 return;
2994                         }
2995                         else if(timeleft <= 10)
2996                         {
2997                                 if(timeleft != self.idlekick_lasttimeleft)
2998                                         AnnounceTo(self, ftos(timeleft));
2999                                 self.idlekick_lasttimeleft = timeleft;
3000                         }
3001                 }
3002         }
3003
3004 #ifdef TETRIS
3005         if(self.impulse == 100)
3006                 ImpulseCommands();
3007         if (!TetrisPostFrame())
3008         {
3009 #endif
3010
3011         CheatFrame();
3012
3013         //CheckPlayerJump();
3014
3015         if(self.classname == "player") {
3016                 CheckRules_Player();
3017                 UpdateChatBubble();
3018                 if (self.impulse)
3019                         ImpulseCommands();
3020                 if (intermission_running)
3021                         return;         // intermission or finale
3022                 GetPressedKeys();
3023         }
3024
3025 #ifdef TETRIS
3026         }
3027 #endif
3028
3029         /*
3030         float i;
3031         for(i = 0; i < 1000; ++i)
3032         {
3033                 vector end;
3034                 end = self.origin + '0 0 1024' + 512 * randomvec();
3035                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3036                 if(trace_fraction < 1)
3037                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3038                 {
3039                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3040                         break;
3041                 }
3042         }
3043         */
3044
3045         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3046
3047         if(self.waypointsprite_attachedforcarrier)
3048                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3049
3050         playerdemo_write();
3051
3052         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3053         {
3054                 if not(self.stored_netname)
3055                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3056                 if(self.stored_netname != self.netname)
3057                 {
3058                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3059                         strunzone(self.stored_netname);
3060                         self.stored_netname = strzone(self.netname);
3061                 }
3062         }
3063
3064         /*
3065         if(g_race)
3066                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3067         */
3068
3069         CSQCMODEL_AUTOUPDATE();
3070 }