qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602
 603         Portal_ClearAll(self);
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         self.spectatortime = time;
 634
 635         self.classname = "observer";
 636         self.iscreature = FALSE;
 637         self.health = -666;
 638         self.takedamage = DAMAGE_NO;
 639         self.solid = SOLID_NOT;
 640         self.movetype = MOVETYPE_NOCLIP;
 641         self.flags = FL_CLIENT | FL_NOTARGET;
 642         self.armorvalue = 666;
 643         self.effects = 0;
 644         self.armorvalue = cvar("g_balance_armor_start");
 645         self.pauserotarmor_finished = 0;
 646         self.pauserothealth_finished = 0;
 647         self.pauseregen_finished = 0;
 648         self.damageforcescale = 0;
 649         self.death_time = 0;
 650         self.dead_frame = 0;
 651         self.alpha = 0;
 652         self.scale = 0;
 653         self.fade_time = 0;
 654         self.pain_frame = 0;
 655         self.pain_finished = 0;
 656         self.strength_finished = 0;
 657         self.invincible_finished = 0;
 658         self.pushltime = 0;
 659         self.think = SUB_Null;
 660         self.nextthink = 0;
 661         self.hook_time = 0;
 662         self.runes = 0;
 663         self.deadflag = DEAD_NO;
 664         self.angles = spot.angles;
 665         self.angles_z = 0;
 666         self.fixangle = TRUE;
 667         self.crouch = FALSE;
 668
 669         self.view_ofs = PL_VIEW_OFS;
 670         setorigin (self, spot.origin);
 671         setsize (self, '0 0 0', '0 0 0');
 672         self.prevorigin = self.origin;
 673         self.items = 0;
 674         self.weapons = 0;
 675         self.model = "";
 676         FixPlayermodel();
 677         self.model = "";
 678         self.modelindex = 0;
 679         self.weapon = 0;
 680         self.weaponmodel = "";
 681         self.weaponentity = world;
 682         self.exteriorweaponentity = world;
 683         self.killcount = -666;
 684         self.velocity = '0 0 0';
 685         self.avelocity = '0 0 0';
 686         self.punchangle = '0 0 0';
 687         self.punchvector = '0 0 0';
 688         self.oldvelocity = self.velocity;
 689         self.fire_endtime = -1;
 690
 691         if(sv_loddistance1)
 692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 693
 694         if(g_arena)
 695         {
 696                 if(self.version_mismatch)
 697                 {
 698                         Spawnqueue_Unmark(self);
 699                         Spawnqueue_Remove(self);
 700                 }
 701                 else
 702                 {
 703                         Spawnqueue_Insert(self);
 704                 }
 705         }
 706         else if(g_lms)
 707         {
 708                 // Only if the player cannot play at all
 709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 710                         self.frags = FRAGS_SPECTATOR;
 711                 else
 712                         self.frags = FRAGS_LMS_LOSER;
 713         }
 714         else
 715                 self.frags = FRAGS_SPECTATOR;
 716
 717         MUTATOR_CALLHOOK(MakePlayerObserver);
 718 }
 719
 720 float RestrictSkin(float s)
 721 {
 722         if(!teams_matter)
 723                 return s;
 724         if(s == 6)
 725                 return 6;
 726         return mod(s, 3);
 727 }
 728
 729 void FixPlayermodel()
 730 {
 731         local string defaultmodel;
 732         local float defaultskin, chmdl, oldskin;
 733         local vector m1, m2;
 734
 735         defaultmodel = "";
 736
 737         if(cvar("sv_defaultcharacter") == 1) {
 738                 defaultskin = 0;
 739
 740                 if(teams_matter)
 741                 {
 742                         string s;
 743                         s = Team_ColorNameLowerCase(self.team);
 744                         if(s != "neutral")
 745                         {
 746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 748                         }
 749                 }
 750
 751                 if(defaultmodel == "")
 752                 {
 753                         defaultmodel = cvar_string("sv_defaultplayermodel");
 754                         defaultskin = cvar("sv_defaultplayerskin");
 755                 }
 756         }
 757
 758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 759         {
 760                 if(self.model != "")
 761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 762                 self.model = ""; // force the != checks to return true
 763         }
 764
 765         if(defaultmodel != "")
 766         {
 767                 if (defaultmodel != self.model)
 768                 {
 769                         m1 = self.mins;
 770                         m2 = self.maxs;
 771                         setmodel_lod (self, defaultmodel);
 772                         setsize (self, m1, m2);
 773                         chmdl = TRUE;
 774                 }
 775
 776                 oldskin = self.skinindex;
 777                 self.skinindex = defaultskin;
 778         } else {
 779                 if (self.playermodel != self.model || self.playermodel == "")
 780                 {
 781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 782                         m1 = self.mins;
 783                         m2 = self.maxs;
 784                         setmodel_lod (self, self.playermodel);
 785                         setsize (self, m1, m2);
 786                         chmdl = TRUE;
 787                 }
 788
 789                 oldskin = self.skinindex;
 790                 self.skinindex = RestrictSkin(stof(self.playerskin));
 791         }
 792
 793         if(chmdl || oldskin != self.skinindex)
 794                 self.species = player_getspecies(); // model or skin has changed
 795
 796         if(!teams_matter)
 797                 if(strlen(cvar_string("sv_defaultplayercolors")))
 798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 799                                 setcolor(self, cvar("sv_defaultplayercolors"));
 800 }
 801
 802 void PlayerTouchExplode(entity p1, entity p2)
 803 {
 804         vector org;
 805         org = (p1.origin + p2.origin) * 0.5;
 806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 807
 808         te_explosion(org);
 809
 810         entity e;
 811         e = spawn();
 812         setorigin(e, org);
 813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 814         remove(e);
 815 }
 816
 817 /*
 818 =============
 819 PutClientInServer
 820
 821 Called when a client spawns in the server
 822 =============
 823 */
 824 //void() ctf_playerchanged;
 825 void PutClientInServer (void)
 826 {
 827         if(clienttype(self) == CLIENTTYPE_BOT)
 828         {
 829                 self.classname = "player";
 830         }
 831         else if(clienttype(self) == CLIENTTYPE_REAL)
 832         {
 833                 msg_entity = self;
 834                 WriteByte(MSG_ONE, SVC_SETVIEW);
 835                 WriteEntity(MSG_ONE, self);
 836         }
 837
 838         // player is dead and becomes observer
 839         // FIXME fix LMS scoring for new system
 840         if(g_lms)
 841         {
 842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 843                         self.classname = "observer";
 844         }
 845
 846         if(g_arena || (g_ca && !allowed_to_spawn))
 847         if(!self.spawned)
 848                 self.classname = "observer";
 849
 850         if(gameover)
 851                 self.classname = "observer";
 852
 853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 854                 entity spot, oldself;
 855                 float j;
 856
 857                 if(self.team < 0)
 858                         JoinBestTeam(self, FALSE, TRUE);
 859
 860                 race_PreSpawn();
 861
 862                 spot = SelectSpawnPoint (FALSE);
 863                 if(!spot)
 864                 {
 865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 866                         return; // spawn failed
 867                 }
 868
 869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 870
 871                 self.classname = "player";
 872                 self.wasplayer = TRUE;
 873                 self.iscreature = TRUE;
 874                 self.movetype = MOVETYPE_WALK;
 875                 self.solid = SOLID_SLIDEBOX;
 876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 877                 if(cvar("g_playerclip_collisions"))
 878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 881                 self.frags = FRAGS_PLAYER;
 882                 if(independent_players)
 883                         MAKE_INDEPENDENT_PLAYER(self);
 884                 self.flags = FL_CLIENT;
 885                 self.takedamage = DAMAGE_AIM;
 886                 if(g_minstagib)
 887                         self.effects = EF_FULLBRIGHT;
 888                 else
 889                         self.effects = 0;
 890                 self.air_finished = time + 12;
 891                 self.dmg = 2;
 892                 if(cvar("g_balance_nex_charge"))
 893                 {
 894                         if(cvar("g_balance_nex_secondary_charge_pool"))
 895                                 self.nex_charge_pool_ammo = 1;
 896                         self.nex_charge = cvar("g_balance_nex_charge_start");
 897                 }
 898
 899                 if(inWarmupStage)
 900                 {
 901                         self.ammo_shells = warmup_start_ammo_shells;
 902                         self.ammo_nails = warmup_start_ammo_nails;
 903                         self.ammo_rockets = warmup_start_ammo_rockets;
 904                         self.ammo_cells = warmup_start_ammo_cells;
 905                         self.ammo_fuel = warmup_start_ammo_fuel;
 906                         self.health = warmup_start_health;
 907                         self.armorvalue = warmup_start_armorvalue;
 908                         self.weapons = warmup_start_weapons;
 909                 }
 910                 else
 911                 {
 912                         self.ammo_shells = start_ammo_shells;
 913                         self.ammo_nails = start_ammo_nails;
 914                         self.ammo_rockets = start_ammo_rockets;
 915                         self.ammo_cells = start_ammo_cells;
 916                         self.ammo_fuel = start_ammo_fuel;
 917                         self.health = start_health;
 918                         self.armorvalue = start_armorvalue;
 919                         self.weapons = start_weapons;
 920                 }
 921
 922                 if(g_weaponarena_random)
 923                 {
 924                         if(g_weaponarena_random_with_laser)
 925                                 self.weapons &~= WEPBIT_LASER;
 926                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 927                         if(g_weaponarena_random_with_laser)
 928                                 self.weapons |= WEPBIT_LASER;
 929                 }
 930
 931                 self.items = start_items;
 932                 self.jump_interval = time;
 933
 934                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 935                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 936                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 937                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 938                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 939                 //extend the pause of rotting if client was reset at the beginning of the countdown
 940                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 941                         self.spawnshieldtime += game_starttime - time;
 942                         self.pauserotarmor_finished += game_starttime - time;
 943                         self.pauserothealth_finished += game_starttime - time;
 944                         self.pauseregen_finished += game_starttime - time;
 945                 }
 946                 self.damageforcescale = 2;
 947                 self.death_time = 0;
 948                 self.dead_frame = 0;
 949                 self.alpha = 0;
 950                 self.scale = 0;
 951                 self.fade_time = 0;
 952                 self.pain_frame = 0;
 953                 self.pain_finished = 0;
 954                 self.strength_finished = 0;
 955                 self.invincible_finished = 0;
 956                 self.pushltime = 0;
 957                 // players have no think function
 958                 self.think = SUB_Null;
 959                 self.nextthink = 0;
 960                 self.hook_time = 0;
 961                 self.dmg_team = 0;
 962                 self.ballistics_density = cvar("g_ballistics_density_player");
 963
 964                 self.metertime = 0;
 965
 966                 self.runes = 0;
 967
 968                 self.deadflag = DEAD_NO;
 969
 970                 self.angles = spot.angles;
 971
 972                 self.angles_z = 0; // never spawn tilted even if the spot says to
 973                 self.fixangle = TRUE; // turn this way immediately
 974                 self.velocity = '0 0 0';
 975                 self.avelocity = '0 0 0';
 976                 self.punchangle = '0 0 0';
 977                 self.punchvector = '0 0 0';
 978                 self.oldvelocity = self.velocity;
 979                 self.fire_endtime = -1;
 980
 981                 msg_entity = self;
 982                 WRITESPECTATABLE_MSG_ONE({
 983                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 984                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 985                 });
 986
 987                 if(sv_loddistance1)
 988                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 989
 990                 self.model = "";
 991                 FixPlayermodel();
 992
 993                 self.crouch = FALSE;
 994                 self.view_ofs = PL_VIEW_OFS;
 995                 setsize (self, PL_MIN, PL_MAX);
 996                 self.spawnorigin = spot.origin;
 997                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 998                 // don't reset back to last position, even if new position is stuck in solid
 999                 self.oldorigin = self.origin;
1000                 self.prevorigin = self.origin;
1001                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1002
1003                 if(g_arena)
1004                 {
1005                         Spawnqueue_Remove(self);
1006                         Spawnqueue_Mark(self);
1007                 }
1008
1009                 else if(g_ca)
1010                         self.caplayer = 1;
1011
1012                 self.event_damage = PlayerDamage;
1013
1014                 self.bot_attack = TRUE;
1015
1016                 self.statdraintime = time + 5;
1017                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1018
1019                 if(self.killcount == -666) {
1020                         PlayerScore_Clear(self);
1021                         self.killcount = 0;
1022                 }
1023
1024                 self.cnt = WEP_LASER;
1025
1026                 CL_SpawnWeaponentity();
1027                 self.alpha = default_player_alpha;
1028                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1029                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1030
1031                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1032                 self.lms_traveled_distance = 0;
1033                 self.speedrunning = FALSE;
1034
1035                 race_PostSpawn(spot);
1036
1037                 if(cvar("spawn_debug"))
1038                 {
1039                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1040                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1041                 }
1042
1043                 //stuffcmd(self, "chase_active 0");
1044                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1045
1046                 if (cvar("g_spawnsound"))
1047                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1048
1049                 if(g_assault) {
1050                         if(self.team == assault_attacker_team)
1051                                 centerprint(self, "You are attacking!");
1052                         else
1053                                 centerprint(self, "You are defending!");
1054                 }
1055
1056                 target_voicescript_clear(self);
1057
1058                 // reset fields the weapons may use
1059                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1060                         weapon_action(j, WR_RESETPLAYER);
1061
1062                 oldself = self;
1063                 self = spot;
1064                         activator = oldself;
1065                                 SUB_UseTargets();
1066                         activator = world;
1067                 self = oldself;
1068
1069                 MUTATOR_CALLHOOK(PlayerSpawn);
1070
1071                 self.switchweapon = w_getbestweapon(self);
1072                 self.cnt = self.switchweapon;
1073                 self.weapon = 0;
1074         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1075                 PutObserverInServer ();
1076         }
1077
1078         //if(g_ctf)
1079         //      ctf_playerchanged();
1080 }
1081
1082 .float ebouncefactor, ebouncestop; // electro's values
1083 // TODO do we need all these fields, or should we stop autodetecting runtime
1084 // changes and just have a console command to update this?
1085 float ClientInit_SendEntity(entity to, float sf)
1086 {
1087         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1088         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1101         if(sv_foginterval && world.fog != "")
1102                 WriteString(MSG_ENTITY, world.fog);
1103         else
1104                 WriteString(MSG_ENTITY, "");
1105         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1106         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1107         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1108         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1109         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1110         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1111         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1112         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1113         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1114         return TRUE;
1115 }
1116
1117 void ClientInit_CheckUpdate()
1118 {
1119         self.nextthink = time;
1120         if(self.count != cvar("g_balance_armor_blockpercent"))
1121         {
1122                 self.count = cvar("g_balance_armor_blockpercent");
1123                 self.SendFlags |= 1;
1124         }
1125         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1126         {
1127                 self.cnt = cvar("g_balance_weaponswitchdelay");
1128                 self.SendFlags |= 1;
1129         }
1130         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1131         {
1132                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1133                 self.SendFlags |= 1;
1134         }
1135         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1136         {
1137                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1138                 self.SendFlags |= 1;
1139         }
1140         if(self.ebouncefactor != cvar("g_balance_electro_secondary_bouncefactor"))
1141         {
1142                 self.ebouncefactor = cvar("g_balance_electro_secondary_bouncefactor");
1143                 self.SendFlags |= 1;
1144         }
1145         if(self.ebouncestop != cvar("g_balance_electro_secondary_bouncestop"))
1146         {
1147                 self.ebouncestop = cvar("g_balance_electro_secondary_bouncestop");
1148                 self.SendFlags |= 1;
1149         }
1150 }
1151
1152 void ClientInit_Spawn()
1153 {
1154         entity o;
1155         entity e;
1156         e = spawn();
1157         e.classname = "clientinit";
1158         e.think = ClientInit_CheckUpdate;
1159         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1160
1161         o = self;
1162         self = e;
1163         ClientInit_CheckUpdate();
1164         self = o;
1165 }
1166
1167 /*
1168 =============
1169 SetNewParms
1170 =============
1171 */
1172 void SetNewParms (void)
1173 {
1174         // initialize parms for a new player
1175         parm1 = -(86400 * 366);
1176 }
1177
1178 /*
1179 =============
1180 SetChangeParms
1181 =============
1182 */
1183 void SetChangeParms (void)
1184 {
1185         // save parms for level change
1186         parm1 = self.parm_idlesince - time;
1187 }
1188
1189 /*
1190 =============
1191 DecodeLevelParms
1192 =============
1193 */
1194 void DecodeLevelParms (void)
1195 {
1196         // load parms
1197         self.parm_idlesince = parm1;
1198         if(self.parm_idlesince == -(86400 * 366))
1199                 self.parm_idlesince = time;
1200
1201         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1202         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1203 }
1204
1205 /*
1206 =============
1207 ClientKill
1208
1209 Called when a client types 'kill' in the console
1210 =============
1211 */
1212
1213 void ClientKill_Now_TeamChange()
1214 {
1215         if(self.killindicator_teamchange == -1)
1216         {
1217                 self.team = -1;
1218                 JoinBestTeam( self, FALSE, FALSE );
1219         }
1220         else
1221                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1222 }
1223
1224 void ClientKill_Now()
1225 {
1226         if(self.killindicator_teamchange)
1227                 ClientKill_Now_TeamChange();
1228
1229         // in any case:
1230         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1231
1232         if(self.killindicator)
1233         {
1234                 dprint("Cleaned up after a leaked kill indicator.\n");
1235                 remove(self.killindicator);
1236                 self.killindicator = world;
1237         }
1238 }
1239 void KillIndicator_Think()
1240 {
1241         if (!self.owner.modelindex)
1242         {
1243                 self.owner.killindicator = world;
1244                 remove(self);
1245                 return;
1246         }
1247
1248         if(self.cnt <= 0)
1249         {
1250                 self = self.owner;
1251                 ClientKill_Now(); // no oldself needed
1252                 return;
1253         }
1254         else
1255         {
1256                 if(self.cnt <= 10)
1257                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1258                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1259                 {
1260                         if(self.cnt <= 10)
1261                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1262                         if(self.owner.killindicator_teamchange)
1263                         {
1264                                 if(self.owner.killindicator_teamchange == -1)
1265                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1266                                 else
1267                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1268                         }
1269                         else
1270                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1271                 }
1272                 self.nextthink = time + 1;
1273                 self.cnt -= 1;
1274         }
1275 }
1276
1277 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1278 {
1279         float killtime;
1280         entity e;
1281         killtime = cvar("g_balance_kill_delay");
1282
1283         if(g_race_qualifying)
1284                 killtime = 0;
1285
1286         self.killindicator_teamchange = targetteam;
1287
1288         if(!self.killindicator)
1289         {
1290                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1291                 {
1292                         ClientKill_Now();
1293                 }
1294                 else
1295                 {
1296                         self.killindicator = spawn();
1297                         self.killindicator.owner = self;
1298                         self.killindicator.scale = 0.5;
1299                         setattachment(self.killindicator, self, "");
1300                         setorigin(self.killindicator, '0 0 52');
1301                         self.killindicator.think = KillIndicator_Think;
1302                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1303                         self.killindicator.cnt = ceil(killtime);
1304                         self.killindicator.count = bound(0, ceil(killtime), 10);
1305                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1306
1307                         for(e = world; (e = find(e, classname, "body")) != world; )
1308                         {
1309                                 if(e.enemy != self)
1310                                         continue;
1311                                 e.killindicator = spawn();
1312                                 e.killindicator.owner = e;
1313                                 e.killindicator.scale = 0.5;
1314                                 setattachment(e.killindicator, e, "");
1315                                 setorigin(e.killindicator, '0 0 52');
1316                                 e.killindicator.think = KillIndicator_Think;
1317                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1318                                 e.killindicator.cnt = ceil(killtime);
1319                         }
1320                         self.lip = 0;
1321                 }
1322         }
1323         if(self.killindicator)
1324         {
1325                 if(targetteam)
1326                         self.killindicator.colormod = TeamColor(targetteam);
1327                 else
1328                         self.killindicator.colormod = '0 0 0';
1329         }
1330 }
1331
1332 void ClientKill (void)
1333 {
1334         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1335         {
1336                 // do nothing
1337         }
1338         else
1339                 ClientKill_TeamChange(0);
1340 }
1341
1342 void CTS_ClientKill_Think (void)
1343 {
1344         self = self.owner; // set self to the player to be killed
1345         sprint(self, "^1You were killed in order to prevent cheating!");
1346         ClientKill_Now();
1347 }
1348
1349 void CTS_ClientKill (float t) // silent version of ClientKill
1350 {
1351         entity e;
1352         e = spawn();
1353         e.owner = self;
1354         e.think = CTS_ClientKill_Think;
1355         e.nextthink = t;
1356 }
1357
1358 void DoTeamChange(float destteam)
1359 {
1360         float t, c0;
1361         if(!teams_matter)
1362         {
1363                 if(destteam >= 0)
1364                         SetPlayerColors(self, destteam);
1365                 return;
1366         }
1367         if(self.classname == "player")
1368         if(destteam == -1)
1369         {
1370                 CheckAllowedTeams(self);
1371                 t = FindSmallestTeam(self, TRUE);
1372                 switch(self.team)
1373                 {
1374                         case COLOR_TEAM1: c0 = c1; break;
1375                         case COLOR_TEAM2: c0 = c2; break;
1376                         case COLOR_TEAM3: c0 = c3; break;
1377                         case COLOR_TEAM4: c0 = c4; break;
1378                         default:          c0 = 999;
1379                 }
1380                 switch(t)
1381                 {
1382                         case 1:
1383                                 if(c0 > c1)
1384                                         destteam = COLOR_TEAM1;
1385                                 break;
1386                         case 2:
1387                                 if(c0 > c2)
1388                                         destteam = COLOR_TEAM2;
1389                                 break;
1390                         case 3:
1391                                 if(c0 > c3)
1392                                         destteam = COLOR_TEAM3;
1393                                 break;
1394                         case 4:
1395                                 if(c0 > c4)
1396                                         destteam = COLOR_TEAM4;
1397                                 break;
1398                 }
1399                 if(destteam == -1)
1400                         return;
1401         }
1402         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1403                 return;
1404         ClientKill_TeamChange(destteam);
1405 }
1406
1407 void FixClientCvars(entity e)
1408 {
1409         // send prediction settings to the client
1410         stuffcmd(e, "\nin_bindmap 0 0\n");
1411         if(g_race || g_cts)
1412                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1413         if(cvar("g_antilag") == 3) // client side hitscan
1414                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1415         if(sv_gentle)
1416                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1417         /*
1418          * we no longer need to stuff this. Remove this comment block if you feel
1419          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1420         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1421         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1422         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1423         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1424         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1425         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1426         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1427         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1428         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1429         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1430         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1431         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1432         stuffcmd(e, "cl_movement_edgefriction 1\n");
1433          */
1434 }
1435
1436 float PlayerInIDList(entity p, string idlist)
1437 {
1438         float n, i;
1439         string s;
1440
1441         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1442         if not(p.crypto_idfp)
1443                 return 0;
1444
1445         // this function allows abbreviated player IDs too!
1446         n = tokenize_console(idlist);
1447         for(i = 0; i < n; ++i)
1448         {
1449                 s = argv(i);
1450                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1451                         return 1;
1452         }
1453
1454         return 0;
1455 }
1456
1457 /*
1458 =============
1459 ClientConnect
1460
1461 Called when a client connects to the server
1462 =============
1463 */
1464 //void ctf_clientconnect();
1465 string ColoredTeamName(float t);
1466 void DecodeLevelParms (void);
1467 //void dom_player_join_team(entity pl);
1468 void ClientConnect (void)
1469 {
1470         float t;
1471
1472         if(self.flags & FL_CLIENT)
1473         {
1474                 print("Warning: ClientConnect, but already connected!\n");
1475                 return;
1476         }
1477
1478         if(Ban_MaybeEnforceBan(self))
1479                 return;
1480
1481         DecodeLevelParms();
1482
1483 #ifdef WATERMARK
1484         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1485 #endif
1486
1487         self.classname = "player_joining";
1488
1489         self.flags = FL_CLIENT;
1490         self.version_nagtime = time + 10 + random() * 10;
1491
1492         if(player_count<0)
1493         {
1494                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1495                 player_count = 0;
1496         }
1497
1498         PlayerScore_Attach(self);
1499         ClientData_Attach();
1500
1501         bot_clientconnect();
1502
1503         playerdemo_init();
1504
1505         anticheat_init();
1506
1507         race_PreSpawnObserver();
1508
1509         //if(g_domination)
1510         //      dom_player_join_team(self);
1511
1512         // identify the right forced team
1513         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1514                 self.team_forced = COLOR_TEAM1;
1515         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1516                 self.team_forced = COLOR_TEAM2;
1517         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1518                 self.team_forced = COLOR_TEAM3;
1519         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1520                 self.team_forced = COLOR_TEAM4;
1521         else if(cvar_string("g_forced_team_otherwise") == "red")
1522                 self.team_forced = COLOR_TEAM1;
1523         else if(cvar_string("g_forced_team_otherwise") == "blue")
1524                 self.team_forced = COLOR_TEAM2;
1525         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1526                 self.team_forced = COLOR_TEAM3;
1527         else if(cvar_string("g_forced_team_otherwise") == "pink")
1528                 self.team_forced = COLOR_TEAM4;
1529         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1530                 self.team_forced = -1;
1531         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1532                 self.team_forced = -1;
1533         else
1534                 self.team_forced = 0;
1535
1536         if(!teams_matter)
1537                 if(self.team_forced > 0)
1538                         self.team_forced = 0;
1539
1540         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1541
1542         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1543                 self.classname = "observer";
1544         } else {
1545                 if(teams_matter)
1546                 {
1547                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1548                         {
1549                                 self.classname = "player";
1550                                 campaign_bots_may_start = 1;
1551                         }
1552                         else
1553                         {
1554                                 self.classname = "observer"; // do it anyway
1555                         }
1556                 }
1557                 else
1558                 {
1559                         self.classname = "player";
1560                         campaign_bots_may_start = 1;
1561                 }
1562         }
1563
1564         self.playerid = (playerid_last = playerid_last + 1);
1565
1566         if(cvar("sv_eventlog"))
1567                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1568
1569         LogTeamchange(self.playerid, self.team, 1);
1570
1571         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1572
1573         self.netname_previous = strzone(self.netname);
1574
1575         bprint("^4", self.netname, "^4 connected");
1576
1577         if(self.classname != "observer" && (g_domination || g_ctf))
1578                 bprint(" and joined the ", ColoredTeamName(self.team));
1579
1580         bprint("\n");
1581
1582         self.welcomemessage_time = 0;
1583
1584         stuffcmd(self, strcat(clientstuff, "\n"));
1585         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1586         stuffcmd(self, "cl_particles_reloadeffects\n");
1587
1588         FixClientCvars(self);
1589
1590         // spawnfunc_waypoint sprites
1591         WaypointSprite_InitClient(self);
1592
1593         // Wazat's grappling hook
1594         SetGrappleHookBindings();
1595
1596         // get autoswitch state from player when he toggles it
1597         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1598
1599         // get version info from player
1600         stuffcmd(self, "cmd clientversion $gameversion\n");
1601
1602         // get other cvars from player
1603         GetCvars(0);
1604
1605         // set cvar for team scoreboard
1606         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1607
1608         // notify about available teams
1609         if(teams_matter)
1610         {
1611                 CheckAllowedTeams(self);
1612                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1613                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1614         }
1615         else
1616                 stuffcmd(self, "set _teams_available 0\n");
1617
1618         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1619
1620         if(g_arena || g_ca)
1621         {
1622                 self.classname = "observer";
1623                 if(g_arena)
1624                         Spawnqueue_Insert(self);
1625         }
1626         /*else if(g_ctf)
1627         {
1628                 ctf_clientconnect();
1629         }*/
1630
1631         if(teams_matter || radar_showennemies)
1632                 attach_entcs();
1633
1634         bot_relinkplayerlist();
1635
1636         self.spectatortime = time;
1637         if(blockSpectators)
1638         {
1639                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1640         }
1641
1642         self.jointime = time;
1643         self.allowedTimeouts = cvar("sv_timeout_number");
1644
1645         if(clienttype(self) == CLIENTTYPE_REAL)
1646         {
1647                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1648                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1649         }
1650
1651         if(g_lms)
1652         {
1653                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1654                 {
1655                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1656                         self.frags = FRAGS_SPECTATOR;
1657                 }
1658         }
1659
1660         if(!sv_foginterval && world.fog != "")
1661                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1662
1663         SoundEntity_Attach(self);
1664
1665         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1666         {
1667                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1668                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1669         }
1670         else
1671                 self.hitplotfh = -1;
1672
1673         if(g_race || g_cts) {
1674                 string rr;
1675                 if(g_cts)
1676                         rr = CTS_RECORD;
1677                 else
1678                         rr = RACE_RECORD;
1679                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1680
1681                 msg_entity = self;
1682                 race_send_recordtime(MSG_ONE);
1683                 race_send_speedaward(MSG_ONE);
1684
1685                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1686                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1687                 race_send_speedaward_alltimebest(MSG_ONE);
1688
1689                 float i;
1690                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1691                         race_SendRankings(i, 0, 0, MSG_ONE);
1692                 }
1693         }
1694         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1695                 send_CSQC_teamnagger();
1696
1697         send_CSQC_cr_maxbullets(self);
1698
1699         CheatInitClient();
1700 }
1701
1702 /*
1703 =============
1704 ClientDisconnect
1705
1706 Called when a client disconnects from the server
1707 =============
1708 */
1709 .entity chatbubbleentity;
1710 .entity teambubbleentity;
1711 void ReadyCount();
1712 void ClientDisconnect (void)
1713 {
1714         if not(self.flags & FL_CLIENT)
1715         {
1716                 print("Warning: ClientDisconnect without ClientConnect\n");
1717                 return;
1718         }
1719
1720         CheatShutdownClient();
1721
1722         if(self.hitplotfh >= 0)
1723         {
1724                 fclose(self.hitplotfh);
1725                 self.hitplotfh = -1;
1726         }
1727
1728         anticheat_report();
1729         anticheat_shutdown();
1730
1731         playerdemo_shutdown();
1732
1733         bot_clientdisconnect();
1734
1735         if(self.entcs)
1736                 detach_entcs();
1737
1738         if(cvar("sv_eventlog"))
1739                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1740         bprint ("^4",self.netname);
1741         bprint ("^4 disconnected\n");
1742
1743         SoundEntity_Detach(self);
1744
1745         DropAllRunes(self);
1746         MUTATOR_CALLHOOK(ClientDisconnect);
1747
1748         Portal_ClearAll(self);
1749
1750         if(self.flagcarried)
1751                 DropFlag(self.flagcarried, world, world);
1752         if(self.ballcarried)
1753                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1754
1755         // Here, everything has been done that requires this player to be a client.
1756
1757         self.flags &~= FL_CLIENT;
1758
1759         if (self.chatbubbleentity)
1760                 remove (self.chatbubbleentity);
1761
1762         if (self.teambubbleentity)
1763                 remove (self.teambubbleentity);
1764
1765         if (self.killindicator)
1766                 remove (self.killindicator);
1767
1768         WaypointSprite_PlayerGone();
1769
1770         bot_relinkplayerlist();
1771
1772         if(g_arena)
1773         {
1774                 Spawnqueue_Unmark(self);
1775                 Spawnqueue_Remove(self);
1776         }
1777
1778         ClientData_Detach();
1779         PlayerScore_Detach(self);
1780
1781         if(self.netname_previous)
1782                 strunzone(self.netname_previous);
1783         if(self.clientstatus)
1784                 strunzone(self.clientstatus);
1785         if(self.weaponorder_byimpulse)
1786                 strunzone(self.weaponorder_byimpulse);
1787
1788         ClearPlayerSounds();
1789
1790         if(self.personal)
1791                 remove(self.personal);
1792
1793         self.playerid = 0;
1794         ReadyCount();
1795
1796         // free cvars
1797         GetCvars(-1);
1798 }
1799
1800 .float BUTTON_CHAT;
1801 void ChatBubbleThink()
1802 {
1803         self.nextthink = time;
1804         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1805         {
1806                 if(self.owner) // but why can that ever be world?
1807                         self.owner.chatbubbleentity = world;
1808                 remove(self);
1809                 return;
1810         }
1811         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1812 #ifdef TETRIS
1813                 || self.owner.tetris_on
1814 #endif
1815         )
1816                 self.model = self.mdl;
1817         else
1818                 self.model = "";
1819 };
1820
1821 void UpdateChatBubble()
1822 {
1823         if (!self.modelindex)
1824                 return;
1825         // spawn a chatbubble entity if needed
1826         if (!self.chatbubbleentity)
1827         {
1828                 self.chatbubbleentity = spawn();
1829                 self.chatbubbleentity.owner = self;
1830                 self.chatbubbleentity.exteriormodeltoclient = self;
1831                 self.chatbubbleentity.think = ChatBubbleThink;
1832                 self.chatbubbleentity.nextthink = time;
1833                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1834                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1835                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1836                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1837                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1838                 self.chatbubbleentity.model = "";
1839                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1840         }
1841 }
1842
1843
1844 void TeamBubbleThink()
1845 {
1846         self.nextthink = time;
1847         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1848         {
1849                 if(self.owner) // but why can that ever be world?
1850                         self.owner.teambubbleentity = world;
1851                 remove(self);
1852                 return;
1853         }
1854 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1855         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1856                 self.model = "";
1857         else
1858                 self.model = self.mdl;
1859
1860 };
1861
1862 float TeamBubble_customizeentityforclient()
1863 {
1864         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1865 }
1866
1867 void UpdateTeamBubble()
1868 {
1869         if (!self.modelindex || !teams_matter)
1870                 return;
1871         // spawn a teambubble entity if needed
1872         if (!self.teambubbleentity && teams_matter)
1873         {
1874                 self.teambubbleentity = spawn();
1875                 self.teambubbleentity.owner = self;
1876                 self.teambubbleentity.exteriormodeltoclient = self;
1877                 self.teambubbleentity.think = TeamBubbleThink;
1878                 self.teambubbleentity.nextthink = time;
1879                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1880 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1881                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1882                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1883                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1884                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1885                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1886                 self.teambubbleentity.effects = EF_LOWPRECISION;
1887         }
1888 }
1889
1890 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1891 // added to the model skins
1892 /*void UpdateColorModHack()
1893 {
1894         local float c;
1895         c = self.clientcolors & 15;
1896         // LordHavoc: only bothering to support white, green, red, yellow, blue
1897              if (!teams_matter) self.colormod = '0 0 0';
1898         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1899         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1900         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1901         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1902         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1903         else self.colormod = '1 1 1';
1904 };*/
1905
1906 .float oldcolormap;
1907 void respawn(void)
1908 {
1909         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1910         {
1911                 self.solid = SOLID_NOT;
1912                 self.takedamage = DAMAGE_NO;
1913                 self.movetype = MOVETYPE_FLY;
1914                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1915                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1916                 self.effects |= EF_ADDITIVE;
1917                 self.oldcolormap = self.colormap;
1918                 self.colormap = 512;
1919                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1920                 if(cvar("g_respawn_ghosts_maxtime"))
1921                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1922         }
1923
1924         CopyBody(1);
1925         self.effects |= EF_NODRAW; // prevent another CopyBody
1926         if(self.oldcolormap)
1927         {
1928                 self.colormap = self.oldcolormap;
1929                 self.oldcolormap = 0;
1930         }
1931         PutClientInServer();
1932 }
1933
1934 void play_countdown(float finished, string samp)
1935 {
1936         if(clienttype(self) == CLIENTTYPE_REAL)
1937                 if(floor(finished - time - frametime) != floor(finished - time))
1938                         if(finished - time < 6)
1939                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1940 }
1941
1942 /**
1943  * When sv_timeout is used this function returs strings like
1944  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1945  * Called by centerprint functions
1946  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1947  */
1948 string getTimeoutText(float addOneSecond) {
1949         if (!cvar("sv_timeout") || !timeoutStatus)
1950                 return "";
1951
1952         local string retStr;
1953         if (timeoutStatus == 1) {
1954                 if (addOneSecond == 1) {
1955                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1956                 }
1957                 else {
1958                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1959                 }
1960                 return retStr;
1961         }
1962         else if (timeoutStatus == 2) {
1963                 if (addOneSecond) {
1964                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1965                         //don't show messages like "Timeout ends in 0 seconds"...
1966                         if ((remainingTimeoutTime + 1) > 0)
1967                                 return retStr;
1968                         else
1969                                 return "";
1970                 }
1971                 else {
1972                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1973                         //don't show messages like "Timeout ends in 0 seconds"...
1974                         if (remainingTimeoutTime > 0)
1975                                 return retStr;
1976                         else
1977                                 return "";
1978                 }
1979         }
1980         else return "";
1981 }
1982
1983 void player_powerups (void)
1984 {
1985         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1986         {
1987                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1988                 self.modelflags |= MF_ROCKET;
1989         }
1990         else
1991         {
1992                 SoundEntity_StopSound(self, CHAN_PLAYER);
1993                 self.modelflags &~= MF_ROCKET;
1994         }
1995
1996         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1997
1998         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1999                 return;
2000
2001         Fire_ApplyDamage(self);
2002         Fire_ApplyEffect(self);
2003
2004         if (g_minstagib)
2005         {
2006                 self.effects |= EF_FULLBRIGHT;
2007
2008                 if (self.items & IT_STRENGTH)
2009                 {
2010                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2011                         if (time > self.strength_finished)
2012                         {
2013                                 self.alpha = default_player_alpha;
2014                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2015                                 self.items &~= IT_STRENGTH;
2016                                 sprint(self, "^3Invisibility has worn off\n");
2017                         }
2018                 }
2019                 else
2020                 {
2021                         if (time < self.strength_finished)
2022                         {
2023                                 self.alpha = g_minstagib_invis_alpha;
2024                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2025                                 self.items |= IT_STRENGTH;
2026                                 sprint(self, "^3You are invisible\n");
2027                         }
2028                 }
2029
2030                 if (self.items & IT_INVINCIBLE)
2031                 {
2032                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2033                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2034                         {
2035                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2036                                 sprint(self, "^3Speed has worn off\n");
2037                         }
2038                 }
2039                 else
2040                 {
2041                         if (time < self.invincible_finished)
2042                         {
2043                                 self.items = self.items | IT_INVINCIBLE;
2044                                 sprint(self, "^3You are on speed\n");
2045                         }
2046                 }
2047                 return;
2048         }
2049
2050         if (self.items & IT_STRENGTH)
2051         {
2052                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2053                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2054                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2055                 {
2056                         self.items = self.items - (self.items & IT_STRENGTH);
2057                         sprint(self, "^3Strength has worn off\n");
2058                 }
2059         }
2060         else
2061         {
2062                 if (time < self.strength_finished)
2063                 {
2064                         self.items = self.items | IT_STRENGTH;
2065                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2066                 }
2067         }
2068         if (self.items & IT_INVINCIBLE)
2069         {
2070                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2071                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2072                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2073                 {
2074                         self.items = self.items - (self.items & IT_INVINCIBLE);
2075                         sprint(self, "^3Shield has worn off\n");
2076                 }
2077         }
2078         else
2079         {
2080                 if (time < self.invincible_finished)
2081                 {
2082                         self.items = self.items | IT_INVINCIBLE;
2083                         sprint(self, "^3Shield surrounds you\n");
2084                 }
2085         }
2086
2087         if(cvar("g_nodepthtestplayers"))
2088                 self.effects = self.effects | EF_NODEPTHTEST;
2089
2090         if(cvar("g_fullbrightplayers"))
2091                 self.effects = self.effects | EF_FULLBRIGHT;
2092
2093         // midair gamemode: damage only while in the air
2094         // if in midair mode, being on ground grants temporary invulnerability
2095         // (this is so that multishot weapon don't clear the ground flag on the
2096         // first damage in the frame, leaving the player vulnerable to the
2097         // remaining hits in the same frame)
2098         if (self.flags & FL_ONGROUND)
2099         if (g_midair)
2100                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2101
2102         if (time >= game_starttime)
2103         if (time < self.spawnshieldtime)
2104                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2105 }
2106
2107 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2108 {
2109         if(current > stable)
2110                 return current;
2111         else if(current > stable - 0.25) // when close enough, "snap"
2112                 return stable;
2113         else
2114                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2115 }
2116
2117 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2118 {
2119         if(current < stable)
2120                 return current;
2121         else if(current < stable + 0.25) // when close enough, "snap"
2122                 return stable;
2123         else
2124                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2125 }
2126
2127 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2128 {
2129         if(current > rotstable)
2130         {
2131                 if(rotframetime > 0)
2132                 {
2133                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2134                         current = max(rotstable, current - rotlinear * rotframetime);
2135                 }
2136         }
2137         else if(current < regenstable)
2138         {
2139                 if(regenframetime > 0)
2140                 {
2141                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2142                         current = min(regenstable, current + regenlinear * regenframetime);
2143                 }
2144         }
2145
2146         if(current > limit)
2147                 current = limit;
2148
2149         return current;
2150 }
2151
2152 void player_regen (void)
2153 {
2154         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2155         maxh = cvar("g_balance_health_rotstable");
2156         maxa = cvar("g_balance_armor_rotstable");
2157         maxf = cvar("g_balance_fuel_rotstable");
2158         minh = cvar("g_balance_health_regenstable");
2159         mina = cvar("g_balance_armor_regenstable");
2160         minf = cvar("g_balance_fuel_regenstable");
2161         limith = cvar("g_balance_health_limit");
2162         limita = cvar("g_balance_armor_limit");
2163         limitf = cvar("g_balance_fuel_limit");
2164
2165         max_mod = regen_mod = rot_mod = limit_mod = 1;
2166
2167         if (self.runes & RUNE_REGEN)
2168         {
2169                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2170                 {
2171                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2172                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2173                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2174                 }
2175                 else
2176                 {
2177                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2178                         max_mod = cvar("g_balance_rune_regen_hpmod");
2179                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2180                 }
2181         }
2182         else if (self.runes & CURSE_VENOM)
2183         {
2184                 max_mod = cvar("g_balance_curse_venom_hpmod");
2185                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2186                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2187                 else
2188                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2189                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2190                 //if (!self.runes & RUNE_REGEN)
2191                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2192         }
2193         maxh = maxh * max_mod;
2194         //maxa = maxa * max_mod;
2195         //maxf = maxf * max_mod;
2196         minh = minh * max_mod;
2197         //mina = mina * max_mod;
2198         //minf = minf * max_mod;
2199         limith = limith * limit_mod;
2200         limita = limita * limit_mod;
2201         //limitf = limitf * limit_mod;
2202
2203         if(g_lms && g_ca)
2204                 rot_mod = 0;
2205
2206         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2207         {
2208                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2209                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2210
2211                 // if player rotted to death...  die!
2212                 if(self.health < 1)
2213                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2214         }
2215
2216         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2217                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2218 }
2219
2220 float zoomstate_set;
2221 void SetZoomState(float z)
2222 {
2223         if(z != self.zoomstate)
2224         {
2225                 self.zoomstate = z;
2226                 ClientData_Touch(self);
2227         }
2228         zoomstate_set = 1;
2229 }
2230
2231 void GetPressedKeys(void) {
2232         MUTATOR_CALLHOOK(GetPressedKeys);
2233         if (self.movement_x > 0) // get if movement keys are pressed
2234         {       // forward key pressed
2235                 self.pressedkeys |= KEY_FORWARD;
2236                 self.pressedkeys &~= KEY_BACKWARD;
2237         }
2238         else if (self.movement_x < 0)
2239         {       // backward key pressed
2240                 self.pressedkeys |= KEY_BACKWARD;
2241                 self.pressedkeys &~= KEY_FORWARD;
2242         }
2243         else
2244         {       // no x input
2245                 self.pressedkeys &~= KEY_FORWARD;
2246                 self.pressedkeys &~= KEY_BACKWARD;
2247         }
2248
2249         if (self.movement_y > 0)
2250         {       // right key pressed
2251                 self.pressedkeys |= KEY_RIGHT;
2252                 self.pressedkeys &~= KEY_LEFT;
2253         }
2254         else if (self.movement_y < 0)
2255         {       // left key pressed
2256                 self.pressedkeys |= KEY_LEFT;
2257                 self.pressedkeys &~= KEY_RIGHT;
2258         }
2259         else
2260         {       // no y input
2261                 self.pressedkeys &~= KEY_RIGHT;
2262                 self.pressedkeys &~= KEY_LEFT;
2263         }
2264
2265         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2266                 self.pressedkeys |= KEY_JUMP;
2267         else
2268                 self.pressedkeys &~= KEY_JUMP;
2269         if (self.BUTTON_CROUCH)
2270                 self.pressedkeys |= KEY_CROUCH;
2271         else
2272                 self.pressedkeys &~= KEY_CROUCH;
2273 }
2274
2275 void update_stats (float number, float hit, float fired) {
2276 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2277 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2278
2279         if(number) {
2280                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2281                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2282         } else {
2283                 self.stat_hit = hit * sv_accuracy_data_share;
2284                 self.stat_fired = fired * sv_accuracy_data_share;
2285         }
2286 }
2287
2288 /*
2289 ======================
2290 spectate mode routines
2291 ======================
2292 */
2293
2294 .float weapon_count;
2295 void SpectateCopy(entity spectatee) {
2296         if(spectatee.weapon_count < WEP_LAST) {
2297                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2298                 spectatee.weapon_count ++;
2299         } else
2300                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2301
2302         other = spectatee;
2303         MUTATOR_CALLHOOK(SpectateCopy);
2304         self.armortype = spectatee.armortype;
2305         self.armorvalue = spectatee.armorvalue;
2306         self.ammo_cells = spectatee.ammo_cells;
2307         self.ammo_shells = spectatee.ammo_shells;
2308         self.ammo_nails = spectatee.ammo_nails;
2309         self.ammo_rockets = spectatee.ammo_rockets;
2310         self.ammo_fuel = spectatee.ammo_fuel;
2311         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2312         self.health = spectatee.health;
2313         self.impulse = 0;
2314         self.items = spectatee.items;
2315         self.last_pickup = spectatee.last_pickup;
2316         self.metertime = spectatee.metertime;
2317         self.strength_finished = spectatee.strength_finished;
2318         self.invincible_finished = spectatee.invincible_finished;
2319         self.pressedkeys = spectatee.pressedkeys;
2320         self.weapons = spectatee.weapons;
2321         self.switchweapon = spectatee.switchweapon;
2322         self.weapon = spectatee.weapon;
2323         self.punchangle = spectatee.punchangle;
2324         self.view_ofs = spectatee.view_ofs;
2325         self.v_angle = spectatee.v_angle;
2326         self.velocity = spectatee.velocity;
2327         self.dmg_take = spectatee.dmg_take;
2328         self.dmg_save = spectatee.dmg_save;
2329         self.dmg_inflictor = spectatee.dmg_inflictor;
2330         self.angles = spectatee.v_angle;
2331         self.fixangle = TRUE;
2332         setorigin(self, spectatee.origin);
2333         setsize(self, spectatee.mins, spectatee.maxs);
2334         SetZoomState(spectatee.zoomstate);
2335
2336         anticheat_spectatecopy(spectatee);
2337 }
2338
2339 float SpectateUpdate() {
2340         if(!self.enemy)
2341                 return 0;
2342
2343         if (self == self.enemy)
2344                 return 0;
2345
2346         if(self.enemy.classname != "player")
2347                 return 0;
2348
2349         SpectateCopy(self.enemy);
2350
2351         return 1;
2352 }
2353
2354 float SpectateNext() {
2355         other = find(self.enemy, classname, "player");
2356
2357         if (!other)
2358                 other = find(other, classname, "player");
2359
2360         if (other)
2361                 self.enemy = other;
2362
2363         if(self.enemy.classname == "player") {
2364                 msg_entity = self;
2365                 WriteByte(MSG_ONE, SVC_SETVIEW);
2366                 WriteEntity(MSG_ONE, self.enemy);
2367                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2368                 self.movetype = MOVETYPE_NONE;
2369
2370                 self.enemy.weapon_count = 0;
2371
2372                 if(!SpectateUpdate())
2373                         PutObserverInServer();
2374
2375                 return 1;
2376         } else {
2377                 return 0;
2378         }
2379 }
2380
2381 /*
2382 =============
2383 ShowRespawnCountdown()
2384
2385 Update a respawn countdown display.
2386 =============
2387 */
2388 void ShowRespawnCountdown()
2389 {
2390         float number;
2391         if(self.deadflag == DEAD_NO) // just respawned?
2392                 return;
2393         else
2394         {
2395                 number = ceil(self.death_time - time);
2396                 if(number <= 0)
2397                         return;
2398                 if(number <= self.respawn_countdown)
2399                 {
2400                         self.respawn_countdown = number - 1;
2401                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2402                                 AnnounceTo(self, strcat(ftos(number), ""));
2403                 }
2404         }
2405 }
2406
2407 void LeaveSpectatorMode()
2408 {
2409         if(isJoinAllowed()) {
2410                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2411                         self.classname = "player";
2412
2413                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2414                                 JoinBestTeam(self, FALSE, TRUE);
2415
2416                         if(cvar("g_campaign"))
2417                                 campaign_bots_may_start = 1;
2418
2419                         self.stat_count = WEP_LAST;
2420
2421                         PutClientInServer();
2422
2423                         if(self.classname == "player")
2424                                 bprint ("^4", self.netname, "^4 is playing now\n");
2425
2426                         if(!cvar("g_campaign"))
2427                                 centerprint(self,""); // clear MOTD
2428
2429                         return;
2430                 } else {
2431                         if (g_ca && self.caplayer) {
2432                         }       // do nothing
2433                         else
2434                                 stuffcmd(self,"menu_showteamselect\n");
2435                         return;
2436                 }
2437         }
2438         else {
2439                 //player may not join because of g_maxplayers is set
2440                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2441         }
2442 }
2443
2444 /**
2445  * Determines whether the player is allowed to join. This depends on cvar
2446  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2447  * it checks whether the number of currently playing players exceeds g_maxplayers.
2448  * @return bool TRUE if the player is allowed to join, false otherwise
2449  */
2450 float isJoinAllowed() {
2451         if(self.team_forced < 0)
2452                 return FALSE; // forced spectators can never join
2453
2454         if (!cvar("g_maxplayers"))
2455                 return TRUE;
2456
2457         local entity e;
2458         local float currentlyPlaying;
2459         FOR_EACH_REALPLAYER(e) {
2460                 if(e.classname == "player")
2461                         currentlyPlaying += 1;
2462         }
2463         if(currentlyPlaying < cvar("g_maxplayers"))
2464                 return TRUE;
2465
2466         return FALSE;
2467 }
2468
2469 /**
2470  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2471  * g_maxplayers_spectator_blocktime seconds
2472  */
2473 void checkSpectatorBlock() {
2474         if(self.classname == "spectator" || self.classname == "observer") {
2475                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2476                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2477                         dropclient(self);
2478                 }
2479         }
2480 }
2481
2482 void ObserverThink()
2483 {
2484         if (self.flags & FL_JUMPRELEASED) {
2485                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2486                         self.welcomemessage_time = 0;
2487                         self.flags &~= FL_JUMPRELEASED;
2488                         self.flags |= FL_SPAWNING;
2489                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2490                         self.welcomemessage_time = 0;
2491                         self.flags &~= FL_JUMPRELEASED;
2492                         if(SpectateNext() == 1) {
2493                                 self.classname = "spectator";
2494                         }
2495                 }
2496         } else {
2497                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2498                         self.flags |= FL_JUMPRELEASED;
2499                         if(self.flags & FL_SPAWNING)
2500                         {
2501                                 self.flags &~= FL_SPAWNING;
2502                                 LeaveSpectatorMode();
2503                                 return;
2504                         }
2505                 }
2506         }
2507         PrintWelcomeMessage(self);
2508 }
2509
2510 void SpectatorThink()
2511 {
2512         if (self.flags & FL_JUMPRELEASED) {
2513                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2514                         self.welcomemessage_time = 0;
2515                         self.flags &~= FL_JUMPRELEASED;
2516                         self.flags |= FL_SPAWNING;
2517                 } else if(self.BUTTON_ATCK) {
2518                         self.welcomemessage_time = 0;
2519                         self.flags &~= FL_JUMPRELEASED;
2520                         if(SpectateNext() == 1) {
2521                                 self.classname = "spectator";
2522                         } else {
2523                                 self.classname = "observer";
2524                                 self.stat_count = WEP_LAST;
2525                                 PutClientInServer();
2526                         }
2527                 } else if (self.BUTTON_ATCK2) {
2528                         self.welcomemessage_time = 0;
2529                         self.flags &~= FL_JUMPRELEASED;
2530                         self.classname = "observer";
2531                         self.stat_count = WEP_LAST;
2532                         PutClientInServer();
2533                 } else {
2534                         if(!SpectateUpdate())
2535                                 PutObserverInServer();
2536                 }
2537         } else {
2538                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2539                         self.flags |= FL_JUMPRELEASED;
2540                         if(self.flags & FL_SPAWNING)
2541                         {
2542                                 self.flags &~= FL_SPAWNING;
2543                                 LeaveSpectatorMode();
2544                                 return;
2545                         }
2546                 }
2547         }
2548
2549         PrintWelcomeMessage(self);
2550         self.flags |= FL_CLIENT | FL_NOTARGET;
2551 }
2552
2553 .float touchexplode_time;
2554
2555 /*
2556 =============
2557 PlayerPreThink
2558
2559 Called every frame for each client before the physics are run
2560 =============
2561 */
2562 void() ctf_setstatus;
2563 void() nexball_setstatus;
2564 .float items_added;
2565 void PlayerPreThink (void)
2566 {
2567         self.stat_game_starttime = game_starttime;
2568         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2569         self.stat_leadlimit = cvar("leadlimit");
2570
2571         if(frametime)
2572         {
2573                 // physics frames: update anticheat stuff
2574                 anticheat_prethink();
2575         }
2576
2577         if(blockSpectators && frametime)
2578                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2579                 checkSpectatorBlock();
2580
2581         zoomstate_set = 0;
2582
2583         if(self.netname_previous != self.netname)
2584         {
2585                 if(cvar("sv_eventlog"))
2586                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2587                 if(self.netname_previous)
2588                         strunzone(self.netname_previous);
2589                 self.netname_previous = strzone(self.netname);
2590         }
2591
2592         // version nagging
2593         if(self.version_nagtime)
2594                 if(self.cvar_g_xonoticversion)
2595                         if(time > self.version_nagtime)
2596                         {
2597                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2598                                 {
2599                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2600                                         {
2601                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2602                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2603                                         }
2604                                         else
2605                                         {
2606                                                 float r;
2607                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2608                                                 if(r < 0)
2609                                                 {
2610                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2611                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2612                                                 }
2613                                                 else if(r > 0)
2614                                                 {
2615                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2616                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2617                                                 }
2618                                         }
2619                                 }
2620                                 self.version_nagtime = 0;
2621                         }
2622
2623         // GOD MODE info
2624         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2625         {
2626                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2627                 self.max_armorvalue = 0;
2628         }
2629
2630 #ifdef TETRIS
2631         if (TetrisPreFrame())
2632                 return;
2633 #endif
2634
2635         MUTATOR_CALLHOOK(PlayerPreThink);
2636
2637         if(self.classname == "player") {
2638 //              if(self.netname == "Wazat")
2639 //                      bprint(self.classname, "\n");
2640
2641                 CheckRules_Player();
2642
2643                 PrintWelcomeMessage(self);
2644
2645                 if (intermission_running)
2646                 {
2647                         IntermissionThink ();   // otherwise a button could be missed between
2648                         return;                                 // the think tics
2649                 }
2650
2651                 if(self.teleport_time)
2652                 if(time > self.teleport_time)
2653                 {
2654                         self.teleport_time = 0;
2655                         self.effects = self.effects - (self.effects & EF_NODRAW);
2656                 }
2657
2658                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2659                         UpdateSelectedPlayer();
2660
2661                 //don't allow the player to turn around while game is paused!
2662                 if(timeoutStatus == 2) {
2663                         self.v_angle = self.lastV_angle;
2664                         self.angles = self.lastV_angle;
2665                         self.fixangle = TRUE;
2666                 }
2667
2668                 if(frametime)
2669                 {
2670                         if(self.health <= 0 && cvar("g_deathglow"))
2671                         {
2672                                 if(self.glowmod_x > 0)
2673                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2674                                 else
2675                                         self.glowmod_x = -1;
2676                                 if(self.glowmod_y > 0)
2677                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2678                                 else
2679                                         self.glowmod_y = -1;
2680                                 if(self.glowmod_z > 0)
2681                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2682                                 else
2683                                         self.glowmod_z = -1;
2684                         }
2685                         else
2686                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2687                         player_powerups();
2688                 }
2689
2690                 if (self.deadflag != DEAD_NO)
2691                 {
2692                         float button_pressed, force_respawn;
2693                         if(self.personal && g_race_qualifying)
2694                         {
2695                                 if(time > self.death_time)
2696                                 {
2697                                         self.death_time = time + 1; // only retry once a second
2698                                         respawn();
2699                                         self.impulse = 141;
2700                                 }
2701                         }
2702                         else
2703                         {
2704                                 if(frametime)
2705                                         player_anim();
2706                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2707                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2708                                 if (self.deadflag == DEAD_DYING)
2709                                 {
2710                                         if(force_respawn)
2711                                                 self.deadflag = DEAD_RESPAWNING;
2712                                         else if(!button_pressed)
2713                                                 self.deadflag = DEAD_DEAD;
2714                                 }
2715                                 else if (self.deadflag == DEAD_DEAD)
2716                                 {
2717                                         if(button_pressed)
2718                                                 self.deadflag = DEAD_RESPAWNABLE;
2719                                 }
2720                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2721                                 {
2722                                         if(!button_pressed)
2723                                                 self.deadflag = DEAD_RESPAWNING;
2724                                 }
2725                                 else if (self.deadflag == DEAD_RESPAWNING)
2726                                 {
2727                                         if(time > self.death_time)
2728                                         {
2729                                                 self.death_time = time + 1; // only retry once a second
2730                                                 respawn();
2731                                         }
2732                                 }
2733                                 ShowRespawnCountdown();
2734                         }
2735                         return;
2736                 }
2737
2738                 if(g_touchexplode)
2739                 if(time > self.touchexplode_time)
2740                 if(self.classname == "player")
2741                 if(self.deadflag == DEAD_NO)
2742                 if not(IS_INDEPENDENT_PLAYER(self))
2743                 FOR_EACH_PLAYER(other) if(self != other)
2744                 {
2745                         if(time > other.touchexplode_time)
2746                         if(other.deadflag == DEAD_NO)
2747                         if not(IS_INDEPENDENT_PLAYER(other))
2748                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2749                         {
2750                                 PlayerTouchExplode(self, other);
2751                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2752                         }
2753                 }
2754
2755                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2756                 {
2757                         vector dist;
2758
2759                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2760                         dist = self.prevorigin - self.origin;
2761                         dist_z = 0;
2762                         self.lms_traveled_distance += fabs(vlen(dist));
2763
2764                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2765                         {
2766                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2767                                 self.lms_traveled_distance = 0;
2768                         }
2769
2770                         if(time > self.lms_nextcheck)
2771                         {
2772                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2773                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2774                                 {
2775                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2776                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2777                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2778                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2779                                 }
2780                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2781                                 self.lms_traveled_distance = 0;
2782                         }
2783                 }
2784
2785                 self.prevorigin = self.origin;
2786
2787                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2788                 {
2789                         if (!self.crouch)
2790                         {
2791                                 self.crouch = TRUE;
2792                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2793                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2794                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2795                         }
2796                 }
2797                 else
2798                 {
2799                         if (self.crouch)
2800                         {
2801                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2802                                 if (!trace_startsolid)
2803                                 {
2804                                         self.crouch = FALSE;
2805                                         self.view_ofs = PL_VIEW_OFS;
2806                                         setsize (self, PL_MIN, PL_MAX);
2807                                 }
2808                         }
2809                 }
2810
2811                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2812                 {
2813                         if(self.bloodloss_timer < time)
2814                         {
2815                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2816                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2817                         }
2818                 }
2819
2820                 FixPlayermodel();
2821
2822                 GrapplingHookFrame();
2823
2824                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2825                 //if(frametime)
2826                 {
2827                         self.items &~= self.items_added;
2828
2829                         W_WeaponFrame();
2830
2831                         self.items_added = 0;
2832                         if(self.items & IT_JETPACK)
2833                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2834                                         self.items_added |= IT_FUEL;
2835
2836                         self.items |= self.items_added;
2837                 }
2838
2839                 player_regen();
2840
2841                 // rot nex charge to the charge limit
2842                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2843                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2844
2845                 if(frametime)
2846                         player_anim();
2847
2848                 if (g_minstagib)
2849                         minstagib_ammocheck();
2850
2851                 ctf_setstatus();
2852                 nexball_setstatus();
2853
2854                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2855
2856                 //self.angles_y=self.v_angle_y + 90;   // temp
2857         } else if(gameover) {
2858                 if (intermission_running)
2859                         IntermissionThink ();   // otherwise a button could be missed between
2860                 return;
2861         } else if(self.classname == "observer") {
2862                 ObserverThink();
2863         } else if(self.classname == "spectator") {
2864                 SpectatorThink();
2865         }
2866
2867         if(!zoomstate_set)
2868                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2869
2870         float oldspectatee_status;
2871         oldspectatee_status = self.spectatee_status;
2872         if(self.classname == "spectator")
2873                 self.spectatee_status = num_for_edict(self.enemy);
2874         else if(self.classname == "observer")
2875                 self.spectatee_status = num_for_edict(self);
2876         else
2877                 self.spectatee_status = 0;
2878         if(self.spectatee_status != oldspectatee_status)
2879         {
2880                 ClientData_Touch(self);
2881                 if(g_race || g_cts)
2882                         race_InitSpectator();
2883         }
2884
2885         if(self.teamkill_soundtime)
2886         if(time > self.teamkill_soundtime)
2887         {
2888                 self.teamkill_soundtime = 0;
2889
2890                 entity oldpusher, oldself;
2891
2892                 oldself = self; self = self.teamkill_soundsource;
2893                 oldpusher = self.pusher; self.pusher = oldself;
2894
2895                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2896
2897                 self.pusher = oldpusher;
2898                 self = oldself;
2899         }
2900
2901         if(self.taunt_soundtime)
2902         if(time > self.taunt_soundtime)
2903         {
2904                 self.taunt_soundtime = 0;
2905                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2906         }
2907
2908         target_voicescript_next(self);
2909 }
2910
2911 float isInvisibleString(string s)
2912 {
2913         float i, n, c;
2914         s = strdecolorize(s);
2915         for((i = 0), (n = strlen(s)); i < n; ++i)
2916         {
2917                 c = str2chr(s, i);
2918                 switch(c)
2919                 {
2920                         case 0:
2921                         case 32: // space
2922                                 break;
2923                         case 192: // charmap space
2924                                 if (!cvar("utf8_enable"))
2925                                         break;
2926                                 return FALSE;
2927                         case 160: // space in unicode fonts
2928                         case 0xE000 + 192: // utf8 charmap space
2929                                 if (cvar("utf8_enable"))
2930                                         break;
2931                         default:
2932                                 return FALSE;
2933                 }
2934         }
2935         return TRUE;
2936 }
2937
2938 /*
2939 =============
2940 PlayerPostThink
2941
2942 Called every frame for each client after the physics are run
2943 =============
2944 */
2945 .float idlekick_lasttimeleft;
2946 .entity showheadshotbbox;
2947 void showheadshotbbox_think()
2948 {
2949         if(self.owner.showheadshotbbox != self)
2950         {
2951                 remove(self);
2952                 return;
2953         }
2954         self.nextthink = time;
2955         setorigin(self, self.owner.origin);
2956         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2957 }
2958 void PlayerPostThink (void)
2959 {
2960         // Savage: Check for nameless players
2961         if (isInvisibleString(self.netname)) {
2962                 self.netname = "Player";
2963                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2964         }
2965
2966         // send the clients accuracy stats to the client
2967         if(self.stat_count > 0)
2968         if(frametime)
2969         {
2970                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2971                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2972                 self.stat_count -= 1;
2973         }
2974
2975         if(sv_maxidle && frametime)
2976         {
2977                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2978                 float timeleft;
2979                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2980                 if(timeleft <= 0)
2981                 {
2982                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2983                         AnnounceTo(self, "terminated");
2984                         dropclient(self);
2985                         return;
2986                 }
2987                 else if(timeleft <= 10)
2988                 {
2989                         if(timeleft != self.idlekick_lasttimeleft)
2990                         {
2991                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2992                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2993                         }
2994                 }
2995                 else
2996                 {
2997                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2998                 }
2999                 self.idlekick_lasttimeleft = timeleft;
3000         }
3001
3002 #ifdef TETRIS
3003         if(self.impulse == 100)
3004                 ImpulseCommands();
3005         if (TetrisPostFrame())
3006                 return;
3007 #endif
3008
3009         CheatFrame();
3010
3011         if(self.classname == "player") {
3012                 CheckRules_Player();
3013                 UpdateChatBubble();
3014                 UpdateTeamBubble();
3015                 if (self.impulse)
3016                         ImpulseCommands();
3017                 if (intermission_running)
3018                         return;         // intermission or finale
3019                 GetPressedKeys();
3020         } else if (self.classname == "observer") {
3021                 //do nothing
3022         } else if (self.classname == "spectator") {
3023                 //do nothing
3024         }
3025
3026         /*
3027         float i;
3028         for(i = 0; i < 1000; ++i)
3029         {
3030                 vector end;
3031                 end = self.origin + '0 0 1024' + 512 * randomvec();
3032                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3033                 if(trace_fraction < 1)
3034                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3035                 {
3036                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3037                         break;
3038                 }
3039         }
3040         */
3041
3042         Arena_Warmup();
3043
3044         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3045
3046         if(self.waypointsprite_attachedforcarrier)
3047                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3048
3049         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3050         {
3051                 if(!self.showheadshotbbox)
3052                 {
3053                         self.showheadshotbbox = spawn();
3054                         self.showheadshotbbox.classname = "headshotbbox";
3055                         self.showheadshotbbox.owner = self;
3056                         self.showheadshotbbox.think = showheadshotbbox_think;
3057                         self.showheadshotbbox.nextthink = time;
3058                         self = self.showheadshotbbox;
3059                         self.think();
3060                         self = self.owner;
3061                 }
3062         }
3063         else
3064         {
3065                 if(self.showheadshotbbox)
3066                         remove(self.showheadshotbbox);
3067         }
3068
3069         playerdemo_write();
3070
3071         if((g_cts || g_race) && self.cvar_cl_allow_uid2name)
3072         {
3073                 if(!self.stored_netname)
3074                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3075                 if(self.stored_netname != self.netname)
3076                 {
3077                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3078                         strunzone(self.stored_netname);
3079                         self.stored_netname = strzone(self.netname);
3080                 }
3081         }
3082
3083         /*
3084         if(g_race)
3085                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3086         */
3087 }