qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(cvar("sv_servermodelsonly"))
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595
 596         Portal_ClearAll(self);
 597
 598         if(self.flagcarried)
 599                 DropFlag(self.flagcarried, world, world);
 600
 601         if(self.ballcarried)
 602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 603
 604         WaypointSprite_PlayerDead();
 605
 606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 608
 609         if(self.killcount != -666) {
 610                 if(g_lms) {
 611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 613                         else
 614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 615                 } else
 616                         bprint ("^4", self.netname, "^4 is spectating now\n");
 617
 618                 if(self.just_joined == FALSE) {
 619                         LogTeamchange(self.playerid, -1, 4);
 620                 } else
 621                         self.just_joined = FALSE;
 622         }
 623
 624         PlayerScore_Clear(self); // clear scores when needed
 625
 626         self.spectatortime = time;
 627
 628         self.classname = "observer";
 629         self.iscreature = FALSE;
 630         self.health = -666;
 631         self.takedamage = DAMAGE_NO;
 632         self.solid = SOLID_NOT;
 633         self.movetype = MOVETYPE_NOCLIP;
 634         self.flags = FL_CLIENT | FL_NOTARGET;
 635         self.armorvalue = 666;
 636         self.effects = 0;
 637         self.armorvalue = cvar("g_balance_armor_start");
 638         self.pauserotarmor_finished = 0;
 639         self.pauserothealth_finished = 0;
 640         self.pauseregen_finished = 0;
 641         self.damageforcescale = 0;
 642         self.death_time = 0;
 643         self.dead_frame = 0;
 644         self.alpha = 0;
 645         self.scale = 0;
 646         self.fade_time = 0;
 647         self.pain_frame = 0;
 648         self.pain_finished = 0;
 649         self.strength_finished = 0;
 650         self.invincible_finished = 0;
 651         self.pushltime = 0;
 652         self.think = SUB_Null;
 653         self.nextthink = 0;
 654         self.hook_time = 0;
 655         self.runes = 0;
 656         self.deadflag = DEAD_NO;
 657         self.angles = spot.angles;
 658         self.angles_z = 0;
 659         self.fixangle = TRUE;
 660         self.crouch = FALSE;
 661
 662         self.view_ofs = PL_VIEW_OFS;
 663         setorigin (self, spot.origin);
 664         setsize (self, '0 0 0', '0 0 0');
 665         self.prevorigin = self.origin;
 666         self.items = 0;
 667         self.weapons = 0;
 668         self.model = "";
 669         FixPlayermodel();
 670         self.model = "";
 671         self.modelindex = 0;
 672         self.weapon = 0;
 673         self.weaponmodel = "";
 674         self.weaponentity = world;
 675         self.exteriorweaponentity = world;
 676         self.killcount = -666;
 677         self.velocity = '0 0 0';
 678         self.avelocity = '0 0 0';
 679         self.punchangle = '0 0 0';
 680         self.punchvector = '0 0 0';
 681         self.oldvelocity = self.velocity;
 682         self.fire_endtime = -1;
 683
 684         if(sv_loddistance1)
 685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 686
 687         if(g_arena)
 688         {
 689                 if(self.version_mismatch)
 690                 {
 691                         Spawnqueue_Unmark(self);
 692                         Spawnqueue_Remove(self);
 693                 }
 694                 else
 695                 {
 696                         Spawnqueue_Insert(self);
 697                 }
 698         }
 699         else if(g_lms)
 700         {
 701                 // Only if the player cannot play at all
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 703                         self.frags = FRAGS_SPECTATOR;
 704                 else
 705                         self.frags = FRAGS_LMS_LOSER;
 706         }
 707         else
 708                 self.frags = FRAGS_SPECTATOR;
 709
 710         MUTATOR_CALLHOOK(MakePlayerObserver);
 711 }
 712
 713 float RestrictSkin(float s)
 714 {
 715         if(!teams_matter)
 716                 return s;
 717         if(s == 6)
 718                 return 6;
 719         return mod(s, 3);
 720 }
 721
 722 void FixPlayermodel()
 723 {
 724         local string defaultmodel;
 725         local float defaultskin, chmdl, oldskin;
 726         local vector m1, m2;
 727
 728         defaultmodel = "";
 729
 730         if(cvar("sv_defaultcharacter") == 1) {
 731                 defaultskin = 0;
 732
 733                 if(teams_matter)
 734                 {
 735                         string s;
 736                         s = Team_ColorNameLowerCase(self.team);
 737                         if(s != "neutral")
 738                         {
 739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 741                         }
 742                 }
 743
 744                 if(defaultmodel == "")
 745                 {
 746                         defaultmodel = cvar_string("sv_defaultplayermodel");
 747                         defaultskin = cvar("sv_defaultplayerskin");
 748                 }
 749         }
 750
 751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 752         {
 753                 if(self.model != "")
 754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 755                 self.model = ""; // force the != checks to return true
 756         }
 757
 758         if(defaultmodel != "")
 759         {
 760                 if (defaultmodel != self.model)
 761                 {
 762                         m1 = self.mins;
 763                         m2 = self.maxs;
 764                         setmodel_lod (self, defaultmodel);
 765                         setsize (self, m1, m2);
 766                         chmdl = TRUE;
 767                 }
 768
 769                 oldskin = self.skinindex;
 770                 self.skinindex = defaultskin;
 771         } else {
 772                 if (self.playermodel != self.model || self.playermodel == "")
 773                 {
 774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 775                         m1 = self.mins;
 776                         m2 = self.maxs;
 777                         setmodel_lod (self, self.playermodel);
 778                         setsize (self, m1, m2);
 779                         chmdl = TRUE;
 780                 }
 781
 782                 oldskin = self.skinindex;
 783                 self.skinindex = RestrictSkin(stof(self.playerskin));
 784         }
 785
 786         if(chmdl || oldskin != self.skinindex)
 787                 self.species = player_getspecies(); // model or skin has changed
 788
 789         if(!teams_matter)
 790                 if(strlen(cvar_string("sv_defaultplayercolors")))
 791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 792                                 setcolor(self, cvar("sv_defaultplayercolors"));
 793 }
 794
 795 void PlayerTouchExplode(entity p1, entity p2)
 796 {
 797         vector org;
 798         org = (p1.origin + p2.origin) * 0.5;
 799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 800
 801         te_explosion(org);
 802
 803         entity e;
 804         e = spawn();
 805         setorigin(e, org);
 806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 807         remove(e);
 808 }
 809
 810 /*
 811 =============
 812 PutClientInServer
 813
 814 Called when a client spawns in the server
 815 =============
 816 */
 817 //void() ctf_playerchanged;
 818 void PutClientInServer (void)
 819 {
 820         if(clienttype(self) == CLIENTTYPE_BOT)
 821         {
 822                 self.classname = "player";
 823         }
 824         else if(clienttype(self) == CLIENTTYPE_REAL)
 825         {
 826                 msg_entity = self;
 827                 WriteByte(MSG_ONE, SVC_SETVIEW);
 828                 WriteEntity(MSG_ONE, self);
 829         }
 830
 831         // player is dead and becomes observer
 832         // FIXME fix LMS scoring for new system
 833         if(g_lms)
 834         {
 835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 836                         self.classname = "observer";
 837         }
 838
 839         if(g_arena || (g_ca && !allowed_to_spawn))
 840         if(!self.spawned)
 841                 self.classname = "observer";
 842
 843         if(gameover)
 844                 self.classname = "observer";
 845
 846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 847                 entity spot, oldself;
 848                 float j;
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 if(cvar("g_playerclip_collisions"))
 870                 {
 871                         if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 872                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 873                         else
 874                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 875                 }
 876                 else
 877                 {
 878                         if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 879                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP;
 880                         else
 881                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 882                 }
 883                 self.frags = FRAGS_PLAYER;
 884                 if(independent_players)
 885                         MAKE_INDEPENDENT_PLAYER(self);
 886                 self.flags = FL_CLIENT;
 887                 self.takedamage = DAMAGE_AIM;
 888                 if(g_minstagib)
 889                         self.effects = EF_FULLBRIGHT;
 890                 else
 891                         self.effects = 0;
 892                 self.air_finished = time + 12;
 893                 self.dmg = 2;
 894
 895                 if(inWarmupStage)
 896                 {
 897                         self.ammo_shells = warmup_start_ammo_shells;
 898                         self.ammo_nails = warmup_start_ammo_nails;
 899                         self.ammo_rockets = warmup_start_ammo_rockets;
 900                         self.ammo_cells = warmup_start_ammo_cells;
 901                         self.ammo_fuel = warmup_start_ammo_fuel;
 902                         self.health = warmup_start_health;
 903                         self.armorvalue = warmup_start_armorvalue;
 904                         self.weapons = warmup_start_weapons;
 905                 }
 906                 else
 907                 {
 908                         self.ammo_shells = start_ammo_shells;
 909                         self.ammo_nails = start_ammo_nails;
 910                         self.ammo_rockets = start_ammo_rockets;
 911                         self.ammo_cells = start_ammo_cells;
 912                         self.ammo_fuel = start_ammo_fuel;
 913                         self.health = start_health;
 914                         self.armorvalue = start_armorvalue;
 915                         self.weapons = start_weapons;
 916                 }
 917
 918                 if(g_weaponarena_random)
 919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 920
 921                 self.items = start_items;
 922                 self.jump_interval = time;
 923
 924                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 925                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 926                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 927                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 928                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 929                 //extend the pause of rotting if client was reset at the beginning of the countdown
 930                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 931                         self.spawnshieldtime += game_starttime - time;
 932                         self.pauserotarmor_finished += game_starttime - time;
 933                         self.pauserothealth_finished += game_starttime - time;
 934                         self.pauseregen_finished += game_starttime - time;
 935                 }
 936                 self.damageforcescale = 2;
 937                 self.death_time = 0;
 938                 self.dead_frame = 0;
 939                 self.alpha = 0;
 940                 self.scale = 0;
 941                 self.fade_time = 0;
 942                 self.pain_frame = 0;
 943                 self.pain_finished = 0;
 944                 self.strength_finished = 0;
 945                 self.invincible_finished = 0;
 946                 self.pushltime = 0;
 947                 // players have no think function
 948                 self.think = SUB_Null;
 949                 self.nextthink = 0;
 950                 self.hook_time = 0;
 951                 self.dmg_team = 0;
 952                 self.ballistics_density = cvar("g_ballistics_density_player");
 953
 954                 self.metertime = 0;
 955
 956                 self.runes = 0;
 957
 958                 self.deadflag = DEAD_NO;
 959
 960                 self.angles = spot.angles;
 961
 962                 self.angles_z = 0; // never spawn tilted even if the spot says to
 963                 self.fixangle = TRUE; // turn this way immediately
 964                 self.velocity = '0 0 0';
 965                 self.avelocity = '0 0 0';
 966                 self.punchangle = '0 0 0';
 967                 self.punchvector = '0 0 0';
 968                 self.oldvelocity = self.velocity;
 969                 self.fire_endtime = -1;
 970
 971                 msg_entity = self;
 972                 WRITESPECTATABLE_MSG_ONE({
 973                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 974                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 975                 });
 976
 977                 if(sv_loddistance1)
 978                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 979
 980                 self.model = "";
 981                 FixPlayermodel();
 982
 983                 self.crouch = FALSE;
 984                 self.view_ofs = PL_VIEW_OFS;
 985                 setsize (self, PL_MIN, PL_MAX);
 986                 self.spawnorigin = spot.origin;
 987                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 988                 // don't reset back to last position, even if new position is stuck in solid
 989                 self.oldorigin = self.origin;
 990                 self.prevorigin = self.origin;
 991                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 992
 993                 if(g_arena)
 994                 {
 995                         Spawnqueue_Remove(self);
 996                         Spawnqueue_Mark(self);
 997                 }
 998
 999                 else if(g_ca)
1000                         self.caplayer = 1;
1001
1002                 self.event_damage = PlayerDamage;
1003
1004                 self.bot_attack = TRUE;
1005
1006                 self.statdraintime = time + 5;
1007                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1008
1009                 if(self.killcount == -666) {
1010                         PlayerScore_Clear(self);
1011                         self.killcount = 0;
1012                 }
1013
1014                 self.cnt = WEP_LASER;
1015
1016                 CL_SpawnWeaponentity();
1017                 self.alpha = default_player_alpha;
1018                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1019                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1020
1021                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1022                 self.lms_traveled_distance = 0;
1023                 self.speedrunning = FALSE;
1024
1025                 race_PostSpawn(spot);
1026
1027                 if(cvar("spawn_debug"))
1028                 {
1029                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1030                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1031                 }
1032
1033                 //stuffcmd(self, "chase_active 0");
1034                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1035
1036                 if (cvar("g_spawnsound"))
1037                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1038
1039                 if(g_assault) {
1040                         if(self.team == assault_attacker_team)
1041                                 centerprint(self, "You are attacking!");
1042                         else
1043                                 centerprint(self, "You are defending!");
1044                 }
1045
1046                 target_voicescript_clear(self);
1047
1048                 // reset fields the weapons may use
1049                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1050                         weapon_action(j, WR_RESETPLAYER);
1051
1052                 oldself = self;
1053                 self = spot;
1054                         activator = oldself;
1055                                 SUB_UseTargets();
1056                         activator = world;
1057                 self = oldself;
1058
1059                 MUTATOR_CALLHOOK(PlayerSpawn);
1060
1061                 self.switchweapon = w_getbestweapon(self);
1062                 self.cnt = self.switchweapon;
1063                 self.weapon = 0;
1064         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1065                 PutObserverInServer ();
1066         }
1067
1068         //if(g_ctf)
1069         //      ctf_playerchanged();
1070 }
1071
1072 float ClientInit_SendEntity(entity to, float sf)
1073 {
1074         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1075         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1081         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1088         if(sv_foginterval && world.fog != "")
1089                 WriteString(MSG_ENTITY, world.fog);
1090         else
1091                 WriteString(MSG_ENTITY, "");
1092         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1093         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1094         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1095         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1096         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1097         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1098         return TRUE;
1099 }
1100
1101 void ClientInit_CheckUpdate()
1102 {
1103         self.nextthink = time;
1104         if(self.count != cvar("g_balance_armor_blockpercent"))
1105         {
1106                 self.count = cvar("g_balance_armor_blockpercent");
1107                 self.SendFlags |= 1;
1108         }
1109         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1110         {
1111                 self.cnt = cvar("g_balance_weaponswitchdelay");
1112                 self.SendFlags |= 1;
1113         }
1114         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1115         {
1116                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1117                 self.SendFlags |= 1;
1118         }
1119         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1120         {
1121                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1122                 self.SendFlags |= 1;
1123         }
1124 }
1125
1126 void ClientInit_Spawn()
1127 {
1128         entity o;
1129         entity e;
1130         e = spawn();
1131         e.classname = "clientinit";
1132         e.think = ClientInit_CheckUpdate;
1133         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1134
1135         o = self;
1136         self = e;
1137         ClientInit_CheckUpdate();
1138         self = o;
1139 }
1140
1141 /*
1142 =============
1143 SetNewParms
1144 =============
1145 */
1146 void SetNewParms (void)
1147 {
1148         // initialize parms for a new player
1149         parm1 = -(86400 * 366);
1150 }
1151
1152 /*
1153 =============
1154 SetChangeParms
1155 =============
1156 */
1157 void SetChangeParms (void)
1158 {
1159         // save parms for level change
1160         parm1 = self.parm_idlesince - time;
1161 }
1162
1163 /*
1164 =============
1165 DecodeLevelParms
1166 =============
1167 */
1168 void DecodeLevelParms (void)
1169 {
1170         // load parms
1171         self.parm_idlesince = parm1;
1172         if(self.parm_idlesince == -(86400 * 366))
1173                 self.parm_idlesince = time;
1174
1175         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1176         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1177 }
1178
1179 /*
1180 =============
1181 ClientKill
1182
1183 Called when a client types 'kill' in the console
1184 =============
1185 */
1186
1187 void ClientKill_Now_TeamChange()
1188 {
1189         if(self.killindicator_teamchange == -1)
1190         {
1191                 self.team = -1;
1192                 JoinBestTeam( self, FALSE, FALSE );
1193         }
1194         else
1195                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1196 }
1197
1198 void ClientKill_Now()
1199 {
1200         if(self.killindicator_teamchange)
1201                 ClientKill_Now_TeamChange();
1202
1203         // in any case:
1204         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1205
1206         if(self.killindicator)
1207         {
1208                 dprint("Cleaned up after a leaked kill indicator.\n");
1209                 remove(self.killindicator);
1210                 self.killindicator = world;
1211         }
1212 }
1213 void KillIndicator_Think()
1214 {
1215         if (!self.owner.modelindex)
1216         {
1217                 self.owner.killindicator = world;
1218                 remove(self);
1219                 return;
1220         }
1221
1222         if(self.cnt <= 0)
1223         {
1224                 self = self.owner;
1225                 ClientKill_Now(); // no oldself needed
1226                 return;
1227         }
1228         else
1229         {
1230                 if(self.cnt <= 10)
1231                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1232                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1233                 {
1234                         if(self.cnt <= 10)
1235                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1236                         if(self.owner.killindicator_teamchange)
1237                         {
1238                                 if(self.owner.killindicator_teamchange == -1)
1239                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1240                                 else
1241                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1242                         }
1243                         else
1244                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1245                 }
1246                 self.nextthink = time + 1;
1247                 self.cnt -= 1;
1248         }
1249 }
1250
1251 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1252 {
1253         float killtime;
1254         entity e;
1255         killtime = cvar("g_balance_kill_delay");
1256
1257         if(g_race_qualifying)
1258                 killtime = 0;
1259
1260         self.killindicator_teamchange = targetteam;
1261
1262         if(!self.killindicator)
1263         {
1264                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1265                 {
1266                         ClientKill_Now();
1267                 }
1268                 else
1269                 {
1270                         self.killindicator = spawn();
1271                         self.killindicator.owner = self;
1272                         self.killindicator.scale = 0.5;
1273                         setattachment(self.killindicator, self, "");
1274                         setorigin(self.killindicator, '0 0 52');
1275                         self.killindicator.think = KillIndicator_Think;
1276                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1277                         self.killindicator.cnt = ceil(killtime);
1278                         self.killindicator.count = bound(0, ceil(killtime), 10);
1279                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1280
1281                         for(e = world; (e = find(e, classname, "body")) != world; )
1282                         {
1283                                 if(e.enemy != self)
1284                                         continue;
1285                                 e.killindicator = spawn();
1286                                 e.killindicator.owner = e;
1287                                 e.killindicator.scale = 0.5;
1288                                 setattachment(e.killindicator, e, "");
1289                                 setorigin(e.killindicator, '0 0 52');
1290                                 e.killindicator.think = KillIndicator_Think;
1291                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1292                                 e.killindicator.cnt = ceil(killtime);
1293                         }
1294                         self.lip = 0;
1295                 }
1296         }
1297         if(self.killindicator)
1298         {
1299                 if(targetteam)
1300                         self.killindicator.colormod = TeamColor(targetteam);
1301                 else
1302                         self.killindicator.colormod = '0 0 0';
1303         }
1304 }
1305
1306 void ClientKill (void)
1307 {
1308         ClientKill_TeamChange(0);
1309 }
1310
1311 void DoTeamChange(float destteam)
1312 {
1313         float t, c0;
1314         if(!teams_matter)
1315         {
1316                 if(destteam >= 0)
1317                         SetPlayerColors(self, destteam);
1318                 return;
1319         }
1320         if(self.classname == "player")
1321         if(destteam == -1)
1322         {
1323                 CheckAllowedTeams(self);
1324                 t = FindSmallestTeam(self, TRUE);
1325                 switch(self.team)
1326                 {
1327                         case COLOR_TEAM1: c0 = c1; break;
1328                         case COLOR_TEAM2: c0 = c2; break;
1329                         case COLOR_TEAM3: c0 = c3; break;
1330                         case COLOR_TEAM4: c0 = c4; break;
1331                         default:          c0 = 999;
1332                 }
1333                 switch(t)
1334                 {
1335                         case 1:
1336                                 if(c0 > c1)
1337                                         destteam = COLOR_TEAM1;
1338                                 break;
1339                         case 2:
1340                                 if(c0 > c2)
1341                                         destteam = COLOR_TEAM2;
1342                                 break;
1343                         case 3:
1344                                 if(c0 > c3)
1345                                         destteam = COLOR_TEAM3;
1346                                 break;
1347                         case 4:
1348                                 if(c0 > c4)
1349                                         destteam = COLOR_TEAM4;
1350                                 break;
1351                 }
1352                 if(destteam == -1)
1353                         return;
1354         }
1355         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1356                 return;
1357         ClientKill_TeamChange(destteam);
1358 }
1359
1360 void FixClientCvars(entity e)
1361 {
1362         // send prediction settings to the client
1363         stuffcmd(e, "\nin_bindmap 0 0\n");
1364         if(g_race || g_cts)
1365                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1366         if(cvar("g_antilag") == 3) // client side hitscan
1367                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1368         if(sv_gentle)
1369                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1370         /*
1371          * we no longer need to stuff this. Remove this comment block if you feel
1372          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1373         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1374         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1375         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1376         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1377         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1378         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1379         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1380         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1381         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1382         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1383         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1384         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1385         stuffcmd(e, "cl_movement_edgefriction 1\n");
1386          */
1387 }
1388
1389 /*
1390 =============
1391 ClientConnect
1392
1393 Called when a client connects to the server
1394 =============
1395 */
1396 //void ctf_clientconnect();
1397 string ColoredTeamName(float t);
1398 void DecodeLevelParms (void);
1399 //void dom_player_join_team(entity pl);
1400 #ifdef UID
1401 .float uid_kicktime;
1402 .string uid;
1403 #endif
1404 void ClientConnect (void)
1405 {
1406         float t;
1407
1408         if(self.flags & FL_CLIENT)
1409         {
1410                 print("Warning: ClientConnect, but already connected!\n");
1411                 return;
1412         }
1413
1414         if(Ban_MaybeEnforceBan(self))
1415                 return;
1416
1417         DecodeLevelParms();
1418
1419 #ifdef WATERMARK
1420         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1421 #endif
1422
1423         self.classname = "player_joining";
1424
1425         self.flags = FL_CLIENT;
1426         self.version_nagtime = time + 10 + random() * 10;
1427
1428         if(player_count<0)
1429         {
1430                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1431                 player_count = 0;
1432         }
1433
1434         PlayerScore_Attach(self);
1435         ClientData_Attach();
1436
1437         bot_clientconnect();
1438
1439         playerdemo_init();
1440
1441         anticheat_init();
1442
1443         race_PreSpawnObserver();
1444
1445         //if(g_domination)
1446         //      dom_player_join_team(self);
1447
1448         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1449
1450         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1451                 self.classname = "observer";
1452         } else {
1453                 if(teams_matter)
1454                 {
1455                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1456                         {
1457                                 self.classname = "player";
1458                                 campaign_bots_may_start = 1;
1459                         }
1460                         else
1461                         {
1462                                 self.classname = "observer"; // do it anyway
1463                         }
1464                 }
1465                 else
1466                 {
1467                         self.classname = "player";
1468                         campaign_bots_may_start = 1;
1469                 }
1470         }
1471
1472         self.playerid = (playerid_last = playerid_last + 1);
1473
1474         if(cvar("sv_eventlog"))
1475                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1476
1477         LogTeamchange(self.playerid, self.team, 1);
1478
1479         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1480
1481         self.netname_previous = strzone(self.netname);
1482
1483         bprint("^4", self.netname, "^4 connected");
1484
1485         if(self.classname != "observer" && (g_domination || g_ctf))
1486                 bprint(" and joined the ", ColoredTeamName(self.team));
1487
1488         bprint("\n");
1489
1490         self.welcomemessage_time = 0;
1491
1492         stuffcmd(self, strcat(clientstuff, "\n"));
1493         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1494         stuffcmd(self, "cl_particles_reloadeffects\n");
1495
1496         FixClientCvars(self);
1497
1498         // spawnfunc_waypoint sprites
1499         WaypointSprite_InitClient(self);
1500
1501         // Wazat's grappling hook
1502         SetGrappleHookBindings();
1503
1504         // get autoswitch state from player when he toggles it
1505         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1506
1507         // get version info from player
1508         stuffcmd(self, "cmd clientversion $gameversion\n");
1509
1510         // get other cvars from player
1511         GetCvars(0);
1512
1513         // set cvar for team scoreboard
1514         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1515
1516         // notify about available teams
1517         if(teams_matter)
1518         {
1519                 CheckAllowedTeams(self);
1520                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1521                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1522         }
1523         else
1524                 stuffcmd(self, "set _teams_available 0\n");
1525
1526         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1527
1528         if(g_arena || g_ca)
1529         {
1530                 self.classname = "observer";
1531                 if(g_arena)
1532                         Spawnqueue_Insert(self);
1533         }
1534         /*else if(g_ctf)
1535         {
1536                 ctf_clientconnect();
1537         }*/
1538
1539         if(teams_matter || radar_showennemies)
1540                 attach_entcs();
1541
1542         bot_relinkplayerlist();
1543
1544         self.spectatortime = time;
1545         if(blockSpectators)
1546         {
1547                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1548         }
1549
1550         self.jointime = time;
1551         self.allowedTimeouts = cvar("sv_timeout_number");
1552
1553         if(clienttype(self) == CLIENTTYPE_REAL)
1554         {
1555                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1556                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1557         }
1558
1559         if(g_lms)
1560         {
1561                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1562                 {
1563                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1564                         self.frags = FRAGS_SPECTATOR;
1565                 }
1566         }
1567
1568         if(!sv_foginterval && world.fog != "")
1569                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1570
1571         SoundEntity_Attach(self);
1572
1573         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1574         {
1575                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1576                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1577         }
1578         else
1579                 self.hitplotfh = -1;
1580
1581 #ifdef UID
1582         if(clienttype(self) == CLIENTTYPE_REAL)
1583         if not(self.uid)
1584                 self.uid_kicktime = time + 60;
1585 #endif
1586
1587         if(g_race || g_cts) {
1588                 string rr;
1589                 if(g_cts)
1590                         rr = CTS_RECORD;
1591                 else
1592                         rr = RACE_RECORD;
1593                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1594
1595                 race_send_recordtime(MSG_ONE);
1596                 race_send_speedaward(MSG_ONE);
1597
1598                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1599                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1600                 race_send_speedaward_alltimebest(MSG_ONE);
1601
1602                 float i;
1603                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1604                         race_SendRankings(i, 0, 0, MSG_ONE);
1605                 }
1606         }
1607         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1608                 send_CSQC_teamnagger();
1609
1610         CheatInitClient();
1611 }
1612
1613 /*
1614 =============
1615 ClientDisconnect
1616
1617 Called when a client disconnects from the server
1618 =============
1619 */
1620 .entity chatbubbleentity;
1621 .entity teambubbleentity;
1622 void ReadyCount();
1623 void ClientDisconnect (void)
1624 {
1625         if not(self.flags & FL_CLIENT)
1626         {
1627                 print("Warning: ClientDisconnect without ClientConnect\n");
1628                 return;
1629         }
1630
1631         CheatShutdownClient();
1632
1633         if(self.hitplotfh >= 0)
1634         {
1635                 fclose(self.hitplotfh);
1636                 self.hitplotfh = -1;
1637         }
1638
1639         anticheat_report();
1640         anticheat_shutdown();
1641
1642         playerdemo_shutdown();
1643
1644         bot_clientdisconnect();
1645
1646         if(self.entcs)
1647                 detach_entcs();
1648
1649         if(cvar("sv_eventlog"))
1650                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1651         bprint ("^4",self.netname);
1652         bprint ("^4 disconnected\n");
1653
1654         SoundEntity_Detach(self);
1655
1656         DropAllRunes(self);
1657         MUTATOR_CALLHOOK(ClientDisconnect);
1658
1659         Portal_ClearAll(self);
1660
1661         if(self.flagcarried)
1662                 DropFlag(self.flagcarried, world, world);
1663         if(self.ballcarried)
1664                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1665
1666         // Here, everything has been done that requires this player to be a client.
1667
1668         self.flags &~= FL_CLIENT;
1669
1670         if (self.chatbubbleentity)
1671                 remove (self.chatbubbleentity);
1672
1673         if (self.teambubbleentity)
1674                 remove (self.teambubbleentity);
1675
1676         if (self.killindicator)
1677                 remove (self.killindicator);
1678
1679         WaypointSprite_PlayerGone();
1680
1681         bot_relinkplayerlist();
1682
1683         // remove laserdot
1684         if(self.weaponentity)
1685                 if(self.weaponentity.lasertarget)
1686                         remove(self.weaponentity.lasertarget);
1687
1688         if(g_arena)
1689         {
1690                 Spawnqueue_Unmark(self);
1691                 Spawnqueue_Remove(self);
1692         }
1693
1694         ClientData_Detach();
1695         PlayerScore_Detach(self);
1696
1697         if(self.netname_previous)
1698                 strunzone(self.netname_previous);
1699         if(self.clientstatus)
1700                 strunzone(self.clientstatus);
1701
1702         ClearPlayerSounds();
1703
1704         if(self.personal)
1705                 remove(self.personal);
1706
1707         self.playerid = 0;
1708         ReadyCount();
1709
1710         // free cvars
1711         GetCvars(-1);
1712 }
1713
1714 .float BUTTON_CHAT;
1715 void ChatBubbleThink()
1716 {
1717         self.nextthink = time;
1718         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1719         {
1720                 if(self.owner) // but why can that ever be world?
1721                         self.owner.chatbubbleentity = world;
1722                 remove(self);
1723                 return;
1724         }
1725         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1726 #ifdef TETRIS
1727                 || self.owner.tetris_on
1728 #endif
1729         )
1730                 self.model = self.mdl;
1731         else
1732                 self.model = "";
1733 };
1734
1735 void UpdateChatBubble()
1736 {
1737         if (!self.modelindex)
1738                 return;
1739         // spawn a chatbubble entity if needed
1740         if (!self.chatbubbleentity)
1741         {
1742                 self.chatbubbleentity = spawn();
1743                 self.chatbubbleentity.owner = self;
1744                 self.chatbubbleentity.exteriormodeltoclient = self;
1745                 self.chatbubbleentity.think = ChatBubbleThink;
1746                 self.chatbubbleentity.nextthink = time;
1747                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1748                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1749                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1750                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1751                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1752                 self.chatbubbleentity.model = "";
1753                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1754         }
1755 }
1756
1757
1758 void TeamBubbleThink()
1759 {
1760         self.nextthink = time;
1761         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1762         {
1763                 if(self.owner) // but why can that ever be world?
1764                         self.owner.teambubbleentity = world;
1765                 remove(self);
1766                 return;
1767         }
1768 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1769         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1770                 self.model = "";
1771         else
1772                 self.model = self.mdl;
1773
1774 };
1775
1776 float TeamBubble_customizeentityforclient()
1777 {
1778         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1779 }
1780
1781 void UpdateTeamBubble()
1782 {
1783         if (!self.modelindex || !teams_matter)
1784                 return;
1785         // spawn a teambubble entity if needed
1786         if (!self.teambubbleentity && teams_matter)
1787         {
1788                 self.teambubbleentity = spawn();
1789                 self.teambubbleentity.owner = self;
1790                 self.teambubbleentity.exteriormodeltoclient = self;
1791                 self.teambubbleentity.think = TeamBubbleThink;
1792                 self.teambubbleentity.nextthink = time;
1793                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1794 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1795                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1796                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1797                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1798                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1799                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1800                 self.teambubbleentity.effects = EF_LOWPRECISION;
1801         }
1802 }
1803
1804 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1805 // added to the model skins
1806 /*void UpdateColorModHack()
1807 {
1808         local float c;
1809         c = self.clientcolors & 15;
1810         // LordHavoc: only bothering to support white, green, red, yellow, blue
1811              if (!teams_matter) self.colormod = '0 0 0';
1812         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1813         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1814         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1815         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1816         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1817         else self.colormod = '1 1 1';
1818 };*/
1819
1820 .float oldcolormap;
1821 void respawn(void)
1822 {
1823         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1824         {
1825                 self.solid = SOLID_NOT;
1826                 self.takedamage = DAMAGE_NO;
1827                 self.movetype = MOVETYPE_FLY;
1828                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1829                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1830                 self.effects |= EF_ADDITIVE;
1831                 self.oldcolormap = self.colormap;
1832                 self.colormap = 512;
1833                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1834                 if(cvar("g_respawn_ghosts_maxtime"))
1835                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1836         }
1837
1838         CopyBody(1);
1839         self.effects |= EF_NODRAW; // prevent another CopyBody
1840         if(self.oldcolormap)
1841         {
1842                 self.colormap = self.oldcolormap;
1843                 self.oldcolormap = 0;
1844         }
1845         PutClientInServer();
1846 }
1847
1848 void play_countdown(float finished, string samp)
1849 {
1850         if(clienttype(self) == CLIENTTYPE_REAL)
1851                 if(floor(finished - time - frametime) != floor(finished - time))
1852                         if(finished - time < 6)
1853                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1854 }
1855
1856 /**
1857  * When sv_timeout is used this function returs strings like
1858  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1859  * Called by centerprint functions
1860  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1861  */
1862 string getTimeoutText(float addOneSecond) {
1863         if (!cvar("sv_timeout") || !timeoutStatus)
1864                 return "";
1865
1866         local string retStr;
1867         if (timeoutStatus == 1) {
1868                 if (addOneSecond == 1) {
1869                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1870                 }
1871                 else {
1872                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1873                 }
1874                 return retStr;
1875         }
1876         else if (timeoutStatus == 2) {
1877                 if (addOneSecond) {
1878                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1879                         //don't show messages like "Timeout ends in 0 seconds"...
1880                         if ((remainingTimeoutTime + 1) > 0)
1881                                 return retStr;
1882                         else
1883                                 return "";
1884                 }
1885                 else {
1886                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1887                         //don't show messages like "Timeout ends in 0 seconds"...
1888                         if (remainingTimeoutTime > 0)
1889                                 return retStr;
1890                         else
1891                                 return "";
1892                 }
1893         }
1894         else return "";
1895 }
1896
1897 void player_powerups (void)
1898 {
1899         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1900         {
1901                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1902                 self.modelflags |= MF_ROCKET;
1903         }
1904         else
1905         {
1906                 SoundEntity_StopSound(self, CHAN_PLAYER);
1907                 self.modelflags &~= MF_ROCKET;
1908         }
1909
1910         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1911
1912         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1913                 return;
1914
1915         Fire_ApplyDamage(self);
1916         Fire_ApplyEffect(self);
1917
1918         if (g_minstagib)
1919         {
1920                 self.effects |= EF_FULLBRIGHT;
1921
1922                 if (self.items & IT_STRENGTH)
1923                 {
1924                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1925                         if (time > self.strength_finished)
1926                         {
1927                                 self.alpha = default_player_alpha;
1928                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1929                                 self.items &~= IT_STRENGTH;
1930                                 sprint(self, "^3Invisibility has worn off\n");
1931                         }
1932                 }
1933                 else
1934                 {
1935                         if (time < self.strength_finished)
1936                         {
1937                                 self.alpha = g_minstagib_invis_alpha;
1938                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1939                                 self.items |= IT_STRENGTH;
1940                                 sprint(self, "^3You are invisible\n");
1941                         }
1942                 }
1943
1944                 if (self.items & IT_INVINCIBLE)
1945                 {
1946                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1947                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1948                         {
1949                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1950                                 sprint(self, "^3Speed has worn off\n");
1951                         }
1952                 }
1953                 else
1954                 {
1955                         if (time < self.invincible_finished)
1956                         {
1957                                 self.items = self.items | IT_INVINCIBLE;
1958                                 sprint(self, "^3You are on speed\n");
1959                         }
1960                 }
1961                 return;
1962         }
1963
1964         if (self.items & IT_STRENGTH)
1965         {
1966                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1967                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1968                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1969                 {
1970                         self.items = self.items - (self.items & IT_STRENGTH);
1971                         sprint(self, "^3Strength has worn off\n");
1972                 }
1973         }
1974         else
1975         {
1976                 if (time < self.strength_finished)
1977                 {
1978                         self.items = self.items | IT_STRENGTH;
1979                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1980                 }
1981         }
1982         if (self.items & IT_INVINCIBLE)
1983         {
1984                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1985                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1986                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1987                 {
1988                         self.items = self.items - (self.items & IT_INVINCIBLE);
1989                         sprint(self, "^3Shield has worn off\n");
1990                 }
1991         }
1992         else
1993         {
1994                 if (time < self.invincible_finished)
1995                 {
1996                         self.items = self.items | IT_INVINCIBLE;
1997                         sprint(self, "^3Shield surrounds you\n");
1998                 }
1999         }
2000
2001         if(cvar("g_nodepthtestplayers"))
2002                 self.effects = self.effects | EF_NODEPTHTEST;
2003
2004         if(cvar("g_fullbrightplayers"))
2005                 self.effects = self.effects | EF_FULLBRIGHT;
2006
2007         // midair gamemode: damage only while in the air
2008         // if in midair mode, being on ground grants temporary invulnerability
2009         // (this is so that multishot weapon don't clear the ground flag on the
2010         // first damage in the frame, leaving the player vulnerable to the
2011         // remaining hits in the same frame)
2012         if (self.flags & FL_ONGROUND)
2013         if (g_midair)
2014                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2015
2016         if (time >= game_starttime)
2017         if (time < self.spawnshieldtime)
2018                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2019 }
2020
2021 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2022 {
2023         if(current > stable)
2024                 return current;
2025         else if(current > stable - 0.25) // when close enough, "snap"
2026                 return stable;
2027         else
2028                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2029 }
2030
2031 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2032 {
2033         if(current < stable)
2034                 return current;
2035         else if(current < stable + 0.25) // when close enough, "snap"
2036                 return stable;
2037         else
2038                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2039 }
2040
2041 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2042 {
2043         if(current > rotstable)
2044         {
2045                 if(rotframetime > 0)
2046                 {
2047                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2048                         current = max(rotstable, current - rotlinear * rotframetime);
2049                 }
2050         }
2051         else if(current < regenstable)
2052         {
2053                 if(regenframetime > 0)
2054                 {
2055                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2056                         current = min(regenstable, current + regenlinear * regenframetime);
2057                 }
2058         }
2059
2060         if(current > limit)
2061                 current = limit;
2062
2063         return current;
2064 }
2065
2066 void player_regen (void)
2067 {
2068         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2069         maxh = cvar("g_balance_health_rotstable");
2070         maxa = cvar("g_balance_armor_rotstable");
2071         maxf = cvar("g_balance_fuel_rotstable");
2072         minh = cvar("g_balance_health_regenstable");
2073         mina = cvar("g_balance_armor_regenstable");
2074         minf = cvar("g_balance_fuel_regenstable");
2075         limith = cvar("g_balance_health_limit");
2076         limita = cvar("g_balance_armor_limit");
2077         limitf = cvar("g_balance_fuel_limit");
2078
2079         max_mod = regen_mod = rot_mod = limit_mod = 1;
2080
2081         if (self.runes & RUNE_REGEN)
2082         {
2083                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2084                 {
2085                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2086                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2087                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2088                 }
2089                 else
2090                 {
2091                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2092                         max_mod = cvar("g_balance_rune_regen_hpmod");
2093                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2094                 }
2095         }
2096         else if (self.runes & CURSE_VENOM)
2097         {
2098                 max_mod = cvar("g_balance_curse_venom_hpmod");
2099                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2100                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2101                 else
2102                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2103                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2104                 //if (!self.runes & RUNE_REGEN)
2105                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2106         }
2107         maxh = maxh * max_mod;
2108         //maxa = maxa * max_mod;
2109         //maxf = maxf * max_mod;
2110         minh = minh * max_mod;
2111         //mina = mina * max_mod;
2112         //minf = minf * max_mod;
2113         limith = limith * limit_mod;
2114         limita = limita * limit_mod;
2115         //limitf = limitf * limit_mod;
2116
2117         if(g_lms && g_ca)
2118                 rot_mod = 0;
2119
2120         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2121         {
2122                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2123                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2124
2125                 // if player rotted to death...  die!
2126                 if(self.health < 1)
2127                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2128         }
2129
2130         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2131                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2132 }
2133
2134 float zoomstate_set;
2135 void SetZoomState(float z)
2136 {
2137         if(z != self.zoomstate)
2138         {
2139                 self.zoomstate = z;
2140                 ClientData_Touch(self);
2141         }
2142         zoomstate_set = 1;
2143 }
2144
2145 void GetPressedKeys(void) {
2146         MUTATOR_CALLHOOK(GetPressedKeys);
2147         if (self.movement_x > 0) // get if movement keys are pressed
2148         {       // forward key pressed
2149                 self.pressedkeys |= KEY_FORWARD;
2150                 self.pressedkeys &~= KEY_BACKWARD;
2151         }
2152         else if (self.movement_x < 0)
2153         {       // backward key pressed
2154                 self.pressedkeys |= KEY_BACKWARD;
2155                 self.pressedkeys &~= KEY_FORWARD;
2156         }
2157         else
2158         {       // no x input
2159                 self.pressedkeys &~= KEY_FORWARD;
2160                 self.pressedkeys &~= KEY_BACKWARD;
2161         }
2162
2163         if (self.movement_y > 0)
2164         {       // right key pressed
2165                 self.pressedkeys |= KEY_RIGHT;
2166                 self.pressedkeys &~= KEY_LEFT;
2167         }
2168         else if (self.movement_y < 0)
2169         {       // left key pressed
2170                 self.pressedkeys |= KEY_LEFT;
2171                 self.pressedkeys &~= KEY_RIGHT;
2172         }
2173         else
2174         {       // no y input
2175                 self.pressedkeys &~= KEY_RIGHT;
2176                 self.pressedkeys &~= KEY_LEFT;
2177         }
2178
2179         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2180                 self.pressedkeys |= KEY_JUMP;
2181         else
2182                 self.pressedkeys &~= KEY_JUMP;
2183         if (self.BUTTON_CROUCH)
2184                 self.pressedkeys |= KEY_CROUCH;
2185         else
2186                 self.pressedkeys &~= KEY_CROUCH;
2187 }
2188
2189 void update_stats (float number, float hit, float fired) {
2190 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2191 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2192
2193         if(number) {
2194                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2195                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2196         } else {
2197                 self.stat_hit = hit * sv_accuracy_data_share;
2198                 self.stat_fired = fired * sv_accuracy_data_share;
2199         }
2200 }
2201
2202 /*
2203 ======================
2204 spectate mode routines
2205 ======================
2206 */
2207
2208 .float weapon_count;
2209 void SpectateCopy(entity spectatee) {
2210         if(spectatee.weapon_count < WEP_LAST) {
2211                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2212                 spectatee.weapon_count ++;
2213         } else
2214                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2215
2216         other = spectatee;
2217         MUTATOR_CALLHOOK(SpectateCopy);
2218         self.armortype = spectatee.armortype;
2219         self.armorvalue = spectatee.armorvalue;
2220         self.ammo_cells = spectatee.ammo_cells;
2221         self.ammo_shells = spectatee.ammo_shells;
2222         self.ammo_nails = spectatee.ammo_nails;
2223         self.ammo_rockets = spectatee.ammo_rockets;
2224         self.ammo_fuel = spectatee.ammo_fuel;
2225         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2226         self.health = spectatee.health;
2227         self.impulse = 0;
2228         self.items = spectatee.items;
2229         self.metertime = spectatee.metertime;
2230         self.strength_finished = spectatee.strength_finished;
2231         self.invincible_finished = spectatee.invincible_finished;
2232         self.pressedkeys = spectatee.pressedkeys;
2233         self.weapons = spectatee.weapons;
2234         self.switchweapon = spectatee.switchweapon;
2235         self.weapon = spectatee.weapon;
2236         self.punchangle = spectatee.punchangle;
2237         self.view_ofs = spectatee.view_ofs;
2238         self.v_angle = spectatee.v_angle;
2239         self.velocity = spectatee.velocity;
2240         self.dmg_take = spectatee.dmg_take;
2241         self.dmg_save = spectatee.dmg_save;
2242         self.dmg_inflictor = spectatee.dmg_inflictor;
2243         self.angles = spectatee.v_angle;
2244         self.fixangle = TRUE;
2245         setorigin(self, spectatee.origin);
2246         setsize(self, spectatee.mins, spectatee.maxs);
2247         SetZoomState(spectatee.zoomstate);
2248
2249         anticheat_spectatecopy(spectatee);
2250 }
2251
2252 float SpectateUpdate() {
2253         if(!self.enemy)
2254                 return 0;
2255
2256         if (self == self.enemy)
2257                 return 0;
2258
2259         if(self.enemy.classname != "player")
2260                 return 0;
2261
2262         SpectateCopy(self.enemy);
2263
2264         return 1;
2265 }
2266
2267 float SpectateNext() {
2268         other = find(self.enemy, classname, "player");
2269
2270         if (!other)
2271                 other = find(other, classname, "player");
2272
2273         if (other)
2274                 self.enemy = other;
2275
2276         if(self.enemy.classname == "player") {
2277                 msg_entity = self;
2278                 WriteByte(MSG_ONE, SVC_SETVIEW);
2279                 WriteEntity(MSG_ONE, self.enemy);
2280                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2281                 self.movetype = MOVETYPE_NONE;
2282
2283                 self.enemy.weapon_count = 0;
2284
2285                 if(!SpectateUpdate())
2286                         PutObserverInServer();
2287
2288                 return 1;
2289         } else {
2290                 return 0;
2291         }
2292 }
2293
2294 /*
2295 =============
2296 ShowRespawnCountdown()
2297
2298 Update a respawn countdown display.
2299 =============
2300 */
2301 void ShowRespawnCountdown()
2302 {
2303         float number;
2304         if(self.deadflag == DEAD_NO) // just respawned?
2305                 return;
2306         else
2307         {
2308                 number = ceil(self.death_time - time);
2309                 if(number <= 0)
2310                         return;
2311                 if(number <= self.respawn_countdown)
2312                 {
2313                         self.respawn_countdown = number - 1;
2314                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2315                                 AnnounceTo(self, strcat(ftos(number), ""));
2316                 }
2317         }
2318 }
2319
2320 void LeaveSpectatorMode()
2321 {
2322         if(isJoinAllowed()) {
2323                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2324                         self.classname = "player";
2325
2326                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2327                                 JoinBestTeam(self, FALSE, TRUE);
2328
2329                         if(cvar("g_campaign"))
2330                                 campaign_bots_may_start = 1;
2331
2332                         self.stat_count = WEP_LAST;
2333
2334                         PutClientInServer();
2335
2336                         if(self.classname == "player")
2337                                 bprint ("^4", self.netname, "^4 is playing now\n");
2338
2339                         if(!cvar("g_campaign"))
2340                                 centerprint(self,""); // clear MOTD
2341
2342                         return;
2343                 } else {
2344                         if (g_ca && self.caplayer) {
2345                         }       // do nothing
2346                         else
2347                                 stuffcmd(self,"menu_showteamselect\n");
2348                         return;
2349                 }
2350         }
2351         else {
2352                 //player may not join because of g_maxplayers is set
2353                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2354         }
2355 }
2356
2357 /**
2358  * Determines whether the player is allowed to join. This depends on cvar
2359  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2360  * it checks whether the number of currently playing players exceeds g_maxplayers.
2361  * @return bool TRUE if the player is allowed to join, false otherwise
2362  */
2363 float isJoinAllowed() {
2364         if (!cvar("g_maxplayers"))
2365                 return TRUE;
2366
2367         local entity e;
2368         local float currentlyPlaying;
2369         FOR_EACH_REALPLAYER(e) {
2370                 if(e.classname == "player")
2371                         currentlyPlaying += 1;
2372         }
2373         if(currentlyPlaying < cvar("g_maxplayers"))
2374                 return TRUE;
2375
2376         return FALSE;
2377 }
2378
2379 /**
2380  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2381  * g_maxplayers_spectator_blocktime seconds
2382  */
2383 void checkSpectatorBlock() {
2384         if(self.classname == "spectator" || self.classname == "observer") {
2385                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2386                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2387                         dropclient(self);
2388                 }
2389         }
2390 }
2391
2392 float vercmp_recursive(string v1, string v2)
2393 {
2394         float dot1, dot2;
2395         string s1, s2;
2396         float r;
2397
2398         dot1 = strstrofs(v1, ".", 0);
2399         dot2 = strstrofs(v2, ".", 0);
2400         if(dot1 == -1)
2401                 s1 = v1;
2402         else
2403                 s1 = substring(v1, 0, dot1);
2404         if(dot2 == -1)
2405                 s2 = v2;
2406         else
2407                 s2 = substring(v2, 0, dot2);
2408
2409         r = stof(s1) - stof(s2);
2410         if(r != 0)
2411                 return r;
2412
2413         r = strcasecmp(s1, s2);
2414         if(r != 0)
2415                 return r;
2416
2417         if(dot1 == -1)
2418                 if(dot2 == -1)
2419                         return 0;
2420                 else
2421                         return -1;
2422         else
2423                 if(dot2 == -1)
2424                         return 1;
2425                 else
2426                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2427 }
2428
2429 float vercmp(string v1, string v2)
2430 {
2431         if(strcasecmp(v1, v2) == 0) // early out check
2432                 return 0;
2433         return vercmp_recursive(v1, v2);
2434 }
2435
2436 void ObserverThink()
2437 {
2438         if (self.flags & FL_JUMPRELEASED) {
2439                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2440                         self.welcomemessage_time = 0;
2441                         self.flags &~= FL_JUMPRELEASED;
2442                         self.flags |= FL_SPAWNING;
2443                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2444                         self.welcomemessage_time = 0;
2445                         self.flags &~= FL_JUMPRELEASED;
2446                         if(SpectateNext() == 1) {
2447                                 self.classname = "spectator";
2448                         }
2449                 }
2450         } else {
2451                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2452                         self.flags |= FL_JUMPRELEASED;
2453                         if(self.flags & FL_SPAWNING)
2454                         {
2455                                 self.flags &~= FL_SPAWNING;
2456                                 LeaveSpectatorMode();
2457                                 return;
2458                         }
2459                 }
2460         }
2461         PrintWelcomeMessage(self);
2462 }
2463
2464 void SpectatorThink()
2465 {
2466         if (self.flags & FL_JUMPRELEASED) {
2467                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2468                         self.welcomemessage_time = 0;
2469                         self.flags &~= FL_JUMPRELEASED;
2470                         self.flags |= FL_SPAWNING;
2471                 } else if(self.BUTTON_ATCK) {
2472                         self.welcomemessage_time = 0;
2473                         self.flags &~= FL_JUMPRELEASED;
2474                         if(SpectateNext() == 1) {
2475                                 self.classname = "spectator";
2476                         } else {
2477                                 self.classname = "observer";
2478                                 self.stat_count = WEP_LAST;
2479                                 PutClientInServer();
2480                         }
2481                 } else if (self.BUTTON_ATCK2) {
2482                         self.welcomemessage_time = 0;
2483                         self.flags &~= FL_JUMPRELEASED;
2484                         self.classname = "observer";
2485                         self.stat_count = WEP_LAST;
2486                         PutClientInServer();
2487                 } else {
2488                         if(!SpectateUpdate())
2489                                 PutObserverInServer();
2490                 }
2491         } else {
2492                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2493                         self.flags |= FL_JUMPRELEASED;
2494                         if(self.flags & FL_SPAWNING)
2495                         {
2496                                 self.flags &~= FL_SPAWNING;
2497                                 LeaveSpectatorMode();
2498                                 return;
2499                         }
2500                 }
2501         }
2502
2503         PrintWelcomeMessage(self);
2504         self.flags |= FL_CLIENT | FL_NOTARGET;
2505 }
2506
2507 .float touchexplode_time;
2508
2509 /*
2510 =============
2511 PlayerPreThink
2512
2513 Called every frame for each client before the physics are run
2514 =============
2515 */
2516 void() ctf_setstatus;
2517 void() nexball_setstatus;
2518 .float items_added;
2519 void PlayerPreThink (void)
2520 {
2521         self.stat_game_starttime = game_starttime;
2522         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2523         self.stat_leadlimit = cvar("leadlimit");
2524
2525         if(frametime)
2526         {
2527                 // physics frames: update anticheat stuff
2528                 anticheat_prethink();
2529         }
2530
2531         if(blockSpectators && frametime)
2532                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2533                 checkSpectatorBlock();
2534
2535         zoomstate_set = 0;
2536
2537         if(self.netname_previous != self.netname)
2538         {
2539                 if(cvar("sv_eventlog"))
2540                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2541                 if(self.netname_previous)
2542                         strunzone(self.netname_previous);
2543                 self.netname_previous = strzone(self.netname);
2544         }
2545
2546         // version nagging
2547         if(self.version_nagtime)
2548                 if(self.cvar_g_xonoticversion)
2549                         if(time > self.version_nagtime)
2550                         {
2551                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2552                                 {
2553                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2554                                         {
2555                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2556                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2557                                         }
2558                                         else
2559                                         {
2560                                                 float r;
2561                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2562                                                 if(r < 0)
2563                                                 {
2564                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2565                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2566                                                 }
2567                                                 else if(r > 0)
2568                                                 {
2569                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2570                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2571                                                 }
2572                                         }
2573                                 }
2574                                 self.version_nagtime = 0;
2575                         }
2576
2577         // GOD MODE info
2578         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2579         {
2580                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2581                 self.max_armorvalue = 0;
2582         }
2583
2584 #ifdef TETRIS
2585         if (TetrisPreFrame())
2586                 return;
2587 #endif
2588
2589         MUTATOR_CALLHOOK(PlayerPreThink);
2590
2591         if(self.classname == "player") {
2592 //              if(self.netname == "Wazat")
2593 //                      bprint(self.classname, "\n");
2594
2595                 CheckRules_Player();
2596
2597                 PrintWelcomeMessage(self);
2598
2599                 if (intermission_running)
2600                 {
2601                         IntermissionThink ();   // otherwise a button could be missed between
2602                         return;                                 // the think tics
2603                 }
2604
2605                 if(self.teleport_time)
2606                 if(time > self.teleport_time)
2607                 {
2608                         self.teleport_time = 0;
2609                         self.effects = self.effects - (self.effects & EF_NODRAW);
2610                 }
2611
2612                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2613                         UpdateSelectedPlayer();
2614
2615                 //don't allow the player to turn around while game is paused!
2616                 if(timeoutStatus == 2) {
2617                         self.v_angle = self.lastV_angle;
2618                         self.angles = self.lastV_angle;
2619                         self.fixangle = TRUE;
2620                 }
2621
2622                 if(frametime)
2623                 {
2624                         if(self.health <= 0 && cvar("g_deathglow"))
2625                         {
2626                                 if(self.glowmod_x > 0)
2627                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2628                                 else
2629                                         self.glowmod_x = -1;
2630                                 if(self.glowmod_y > 0)
2631                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2632                                 else
2633                                         self.glowmod_y = -1;
2634                                 if(self.glowmod_z > 0)
2635                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2636                                 else
2637                                         self.glowmod_z = -1;
2638                         }
2639                         else
2640                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2641                         player_powerups();
2642                 }
2643
2644                 if (self.deadflag != DEAD_NO)
2645                 {
2646                         float button_pressed, force_respawn;
2647                         if(self.personal && g_race_qualifying)
2648                         {
2649                                 if(time > self.death_time)
2650                                 {
2651                                         self.death_time = time + 1; // only retry once a second
2652                                         respawn();
2653                                         self.impulse = 141;
2654                                 }
2655                         }
2656                         else
2657                         {
2658                                 if(frametime)
2659                                         player_anim();
2660                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2661                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2662                                 if (self.deadflag == DEAD_DYING)
2663                                 {
2664                                         if(force_respawn)
2665                                                 self.deadflag = DEAD_RESPAWNING;
2666                                         else if(!button_pressed)
2667                                                 self.deadflag = DEAD_DEAD;
2668                                 }
2669                                 else if (self.deadflag == DEAD_DEAD)
2670                                 {
2671                                         if(button_pressed)
2672                                                 self.deadflag = DEAD_RESPAWNABLE;
2673                                 }
2674                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2675                                 {
2676                                         if(!button_pressed)
2677                                                 self.deadflag = DEAD_RESPAWNING;
2678                                 }
2679                                 else if (self.deadflag == DEAD_RESPAWNING)
2680                                 {
2681                                         if(time > self.death_time)
2682                                         {
2683                                                 self.death_time = time + 1; // only retry once a second
2684                                                 respawn();
2685                                         }
2686                                 }
2687                                 ShowRespawnCountdown();
2688                         }
2689                         return;
2690                 }
2691
2692                 if(g_touchexplode)
2693                 if(time > self.touchexplode_time)
2694                 if(self.classname == "player")
2695                 if(self.deadflag == DEAD_NO)
2696                 if not(IS_INDEPENDENT_PLAYER(self))
2697                 FOR_EACH_PLAYER(other) if(self != other)
2698                 {
2699                         if(time > other.touchexplode_time)
2700                         if(other.deadflag == DEAD_NO)
2701                         if not(IS_INDEPENDENT_PLAYER(other))
2702                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2703                         {
2704                                 PlayerTouchExplode(self, other);
2705                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2706                         }
2707                 }
2708
2709                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2710                 {
2711                         vector dist;
2712
2713                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2714                         dist = self.prevorigin - self.origin;
2715                         dist_z = 0;
2716                         self.lms_traveled_distance += fabs(vlen(dist));
2717
2718                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2719                         {
2720                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2721                                 self.lms_traveled_distance = 0;
2722                         }
2723
2724                         if(time > self.lms_nextcheck)
2725                         {
2726                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2727                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2728                                 {
2729                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2730                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2731                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2732                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2733                                 }
2734                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2735                                 self.lms_traveled_distance = 0;
2736                         }
2737                 }
2738
2739                 self.prevorigin = self.origin;
2740
2741                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2742                 {
2743                         if (!self.crouch)
2744                         {
2745                                 self.crouch = TRUE;
2746                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2747                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2748                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2749                         }
2750                 }
2751                 else
2752                 {
2753                         if (self.crouch)
2754                         {
2755                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2756                                 if (!trace_startsolid)
2757                                 {
2758                                         self.crouch = FALSE;
2759                                         self.view_ofs = PL_VIEW_OFS;
2760                                         setsize (self, PL_MIN, PL_MAX);
2761                                 }
2762                         }
2763                 }
2764
2765                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2766                 {
2767                         if(self.bloodloss_timer < time)
2768                         {
2769                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2770                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2771                         }
2772                 }
2773
2774                 FixPlayermodel();
2775
2776                 GrapplingHookFrame();
2777
2778                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2779                 //if(frametime)
2780                 {
2781                         self.items &~= self.items_added;
2782
2783                         W_WeaponFrame();
2784
2785                         self.items_added = 0;
2786                         if(self.items & IT_JETPACK)
2787                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2788                                         self.items_added |= IT_FUEL;
2789
2790                         self.items |= self.items_added;
2791                 }
2792
2793                 player_regen();
2794                 if(frametime)
2795                         player_anim();
2796
2797                 if (g_minstagib)
2798                         minstagib_ammocheck();
2799
2800                 ctf_setstatus();
2801                 nexball_setstatus();
2802
2803                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2804
2805                 //self.angles_y=self.v_angle_y + 90;   // temp
2806         } else if(gameover) {
2807                 if (intermission_running)
2808                         IntermissionThink ();   // otherwise a button could be missed between
2809                 return;
2810         } else if(self.classname == "observer") {
2811                 ObserverThink();
2812         } else if(self.classname == "spectator") {
2813                 SpectatorThink();
2814         }
2815
2816         if(!zoomstate_set)
2817                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2818
2819         float oldspectatee_status;
2820         oldspectatee_status = self.spectatee_status;
2821         if(self.classname == "spectator")
2822                 self.spectatee_status = num_for_edict(self.enemy);
2823         else if(self.classname == "observer")
2824                 self.spectatee_status = num_for_edict(self);
2825         else
2826                 self.spectatee_status = 0;
2827         if(self.spectatee_status != oldspectatee_status)
2828         {
2829                 ClientData_Touch(self);
2830                 if(g_race || g_cts)
2831                         race_InitSpectator();
2832         }
2833
2834         if(self.teamkill_soundtime)
2835         if(time > self.teamkill_soundtime)
2836         {
2837                 self.teamkill_soundtime = 0;
2838
2839                 entity oldpusher, oldself;
2840
2841                 oldself = self; self = self.teamkill_soundsource;
2842                 oldpusher = self.pusher; self.pusher = oldself;
2843
2844                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2845
2846                 self.pusher = oldpusher;
2847                 self = oldself;
2848         }
2849
2850         if(self.taunt_soundtime)
2851         if(time > self.taunt_soundtime)
2852         {
2853                 self.taunt_soundtime = 0;
2854                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2855         }
2856
2857         target_voicescript_next(self);
2858 }
2859
2860 float isInvisibleString(string s)
2861 {
2862         float i, n, c;
2863         s = strdecolorize(s);
2864         for((i = 0), (n = strlen(s)); i < n; ++i)
2865         {
2866                 c = str2chr(s, i);
2867                 switch(c)
2868                 {
2869                         case 0:
2870                         case 32: // space
2871                                 break;
2872                         case 192: // charmap space
2873                                 if (!cvar("utf8_enable"))
2874                                         break;
2875                                 return FALSE;
2876                         case 160: // space in unicode fonts
2877                         case 0xE000 + 192: // utf8 charmap space
2878                                 if (cvar("utf8_enable"))
2879                                         break;
2880                         default:
2881                                 return FALSE;
2882                 }
2883         }
2884         return TRUE;
2885 }
2886
2887 /*
2888 =============
2889 PlayerPostThink
2890
2891 Called every frame for each client after the physics are run
2892 =============
2893 */
2894 .float idlekick_lasttimeleft;
2895 .entity showheadshotbbox;
2896 void showheadshotbbox_think()
2897 {
2898         if(self.owner.showheadshotbbox != self)
2899         {
2900                 remove(self);
2901                 return;
2902         }
2903         self.nextthink = time;
2904         setorigin(self, self.owner.origin);
2905         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2906 }
2907 void PlayerPostThink (void)
2908 {
2909         // Savage: Check for nameless players
2910         if (isInvisibleString(self.netname)) {
2911                 self.netname = "Player";
2912                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2913         }
2914
2915         // send the clients accuracy stats to the client
2916         if(self.stat_count > 0)
2917         if(frametime)
2918         {
2919                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2920                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2921                 self.stat_count -= 1;
2922         }
2923
2924 #ifdef UID
2925         if(self.uid_kicktime)
2926         if(time > self.uid_kicktime)
2927         {
2928                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2929                 dropclient(self);
2930                 return;
2931         }
2932 #endif
2933
2934         if(sv_maxidle && frametime)
2935         {
2936                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2937                 float timeleft;
2938                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2939                 if(timeleft <= 0)
2940                 {
2941                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2942                         AnnounceTo(self, "terminated");
2943                         dropclient(self);
2944                         return;
2945                 }
2946                 else if(timeleft <= 10)
2947                 {
2948                         if(timeleft != self.idlekick_lasttimeleft)
2949                         {
2950                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2951                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2952                         }
2953                 }
2954                 else
2955                 {
2956                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2957                 }
2958                 self.idlekick_lasttimeleft = timeleft;
2959         }
2960
2961 #ifdef TETRIS
2962         if(self.impulse == 100)
2963                 ImpulseCommands();
2964         if (TetrisPostFrame())
2965                 return;
2966 #endif
2967
2968         CheatFrame();
2969
2970         if(self.classname == "player") {
2971                 CheckRules_Player();
2972                 UpdateChatBubble();
2973                 UpdateTeamBubble();
2974                 if (self.impulse)
2975                         ImpulseCommands();
2976                 if (intermission_running)
2977                         return;         // intermission or finale
2978                 GetPressedKeys();
2979         } else if (self.classname == "observer") {
2980                 //do nothing
2981         } else if (self.classname == "spectator") {
2982                 //do nothing
2983         }
2984
2985         /*
2986         float i;
2987         for(i = 0; i < 1000; ++i)
2988         {
2989                 vector end;
2990                 end = self.origin + '0 0 1024' + 512 * randomvec();
2991                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2992                 if(trace_fraction < 1)
2993                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2994                 {
2995                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2996                         break;
2997                 }
2998         }
2999         */
3000
3001         Arena_Warmup();
3002
3003         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3004
3005         if(self.waypointsprite_attachedforcarrier)
3006                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3007
3008         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3009         {
3010                 if(!self.showheadshotbbox)
3011                 {
3012                         self.showheadshotbbox = spawn();
3013                         self.showheadshotbbox.classname = "headshotbbox";
3014                         self.showheadshotbbox.owner = self;
3015                         self.showheadshotbbox.think = showheadshotbbox_think;
3016                         self.showheadshotbbox.nextthink = time;
3017                         self = self.showheadshotbbox;
3018                         self.think();
3019                         self = self.owner;
3020                 }
3021         }
3022         else
3023         {
3024                 if(self.showheadshotbbox)
3025                         remove(self.showheadshotbbox);
3026         }
3027
3028         playerdemo_write();
3029
3030         /*
3031         if(g_race)
3032                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3033         */
3034 }