qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602
 603         Portal_ClearAll(self);
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         self.spectatortime = time;
 634
 635         self.classname = "observer";
 636         self.iscreature = FALSE;
 637         self.health = -666;
 638         self.takedamage = DAMAGE_NO;
 639         self.solid = SOLID_NOT;
 640         self.movetype = MOVETYPE_NOCLIP;
 641         self.flags = FL_CLIENT | FL_NOTARGET;
 642         self.armorvalue = 666;
 643         self.effects = 0;
 644         self.armorvalue = cvar("g_balance_armor_start");
 645         self.pauserotarmor_finished = 0;
 646         self.pauserothealth_finished = 0;
 647         self.pauseregen_finished = 0;
 648         self.damageforcescale = 0;
 649         self.death_time = 0;
 650         self.dead_frame = 0;
 651         self.alpha = 0;
 652         self.scale = 0;
 653         self.fade_time = 0;
 654         self.pain_frame = 0;
 655         self.pain_finished = 0;
 656         self.strength_finished = 0;
 657         self.invincible_finished = 0;
 658         self.pushltime = 0;
 659         self.think = SUB_Null;
 660         self.nextthink = 0;
 661         self.hook_time = 0;
 662         self.runes = 0;
 663         self.deadflag = DEAD_NO;
 664         self.angles = spot.angles;
 665         self.angles_z = 0;
 666         self.fixangle = TRUE;
 667         self.crouch = FALSE;
 668
 669         self.view_ofs = PL_VIEW_OFS;
 670         setorigin (self, spot.origin);
 671         setsize (self, '0 0 0', '0 0 0');
 672         self.prevorigin = self.origin;
 673         self.items = 0;
 674         self.weapons = 0;
 675         self.model = "";
 676         FixPlayermodel();
 677         self.model = "";
 678         self.modelindex = 0;
 679         self.weapon = 0;
 680         self.weaponmodel = "";
 681         self.weaponentity = world;
 682         self.exteriorweaponentity = world;
 683         self.killcount = -666;
 684         self.velocity = '0 0 0';
 685         self.avelocity = '0 0 0';
 686         self.punchangle = '0 0 0';
 687         self.punchvector = '0 0 0';
 688         self.oldvelocity = self.velocity;
 689         self.fire_endtime = -1;
 690
 691         if(sv_loddistance1)
 692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 693
 694         if(g_arena)
 695         {
 696                 if(self.version_mismatch)
 697                 {
 698                         Spawnqueue_Unmark(self);
 699                         Spawnqueue_Remove(self);
 700                 }
 701                 else
 702                 {
 703                         Spawnqueue_Insert(self);
 704                 }
 705         }
 706         else if(g_lms)
 707         {
 708                 // Only if the player cannot play at all
 709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 710                         self.frags = FRAGS_SPECTATOR;
 711                 else
 712                         self.frags = FRAGS_LMS_LOSER;
 713         }
 714         else
 715                 self.frags = FRAGS_SPECTATOR;
 716
 717         MUTATOR_CALLHOOK(MakePlayerObserver);
 718 }
 719
 720 float RestrictSkin(float s)
 721 {
 722         if(!teams_matter)
 723                 return s;
 724         if(s == 6)
 725                 return 6;
 726         return mod(s, 3);
 727 }
 728
 729 void FixPlayermodel()
 730 {
 731         local string defaultmodel;
 732         local float defaultskin, chmdl, oldskin;
 733         local vector m1, m2;
 734
 735         defaultmodel = "";
 736
 737         if(cvar("sv_defaultcharacter") == 1) {
 738                 defaultskin = 0;
 739
 740                 if(teams_matter)
 741                 {
 742                         string s;
 743                         s = Team_ColorNameLowerCase(self.team);
 744                         if(s != "neutral")
 745                         {
 746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 748                         }
 749                 }
 750
 751                 if(defaultmodel == "")
 752                 {
 753                         defaultmodel = cvar_string("sv_defaultplayermodel");
 754                         defaultskin = cvar("sv_defaultplayerskin");
 755                 }
 756         }
 757
 758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 759         {
 760                 if(self.model != "")
 761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 762                 self.model = ""; // force the != checks to return true
 763         }
 764
 765         if(defaultmodel != "")
 766         {
 767                 if (defaultmodel != self.model)
 768                 {
 769                         m1 = self.mins;
 770                         m2 = self.maxs;
 771                         setmodel_lod (self, defaultmodel);
 772                         setsize (self, m1, m2);
 773                         chmdl = TRUE;
 774                 }
 775
 776                 oldskin = self.skinindex;
 777                 self.skinindex = defaultskin;
 778         } else {
 779                 if (self.playermodel != self.model || self.playermodel == "")
 780                 {
 781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 782                         m1 = self.mins;
 783                         m2 = self.maxs;
 784                         setmodel_lod (self, self.playermodel);
 785                         setsize (self, m1, m2);
 786                         chmdl = TRUE;
 787                 }
 788
 789                 oldskin = self.skinindex;
 790                 self.skinindex = RestrictSkin(stof(self.playerskin));
 791         }
 792
 793         if(chmdl || oldskin != self.skinindex)
 794                 self.species = player_getspecies(); // model or skin has changed
 795
 796         if(!teams_matter)
 797                 if(strlen(cvar_string("sv_defaultplayercolors")))
 798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 799                                 setcolor(self, cvar("sv_defaultplayercolors"));
 800 }
 801
 802 void PlayerTouchExplode(entity p1, entity p2)
 803 {
 804         vector org;
 805         org = (p1.origin + p2.origin) * 0.5;
 806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 807
 808         te_explosion(org);
 809
 810         entity e;
 811         e = spawn();
 812         setorigin(e, org);
 813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 814         remove(e);
 815 }
 816
 817 /*
 818 =============
 819 PutClientInServer
 820
 821 Called when a client spawns in the server
 822 =============
 823 */
 824 //void() ctf_playerchanged;
 825 void PutClientInServer (void)
 826 {
 827         if(clienttype(self) == CLIENTTYPE_BOT)
 828         {
 829                 self.classname = "player";
 830         }
 831         else if(clienttype(self) == CLIENTTYPE_REAL)
 832         {
 833                 msg_entity = self;
 834                 WriteByte(MSG_ONE, SVC_SETVIEW);
 835                 WriteEntity(MSG_ONE, self);
 836         }
 837
 838         // player is dead and becomes observer
 839         // FIXME fix LMS scoring for new system
 840         if(g_lms)
 841         {
 842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 843                         self.classname = "observer";
 844         }
 845
 846         if(g_arena || (g_ca && !allowed_to_spawn))
 847         if(!self.spawned)
 848                 self.classname = "observer";
 849
 850         if(gameover)
 851                 self.classname = "observer";
 852
 853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 854                 entity spot, oldself;
 855                 float j;
 856
 857                 if(self.team < 0)
 858                         JoinBestTeam(self, FALSE, TRUE);
 859
 860                 race_PreSpawn();
 861
 862                 spot = SelectSpawnPoint (FALSE);
 863                 if(!spot)
 864                 {
 865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 866                         return; // spawn failed
 867                 }
 868
 869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 870
 871                 self.classname = "player";
 872                 self.wasplayer = TRUE;
 873                 self.iscreature = TRUE;
 874                 self.movetype = MOVETYPE_WALK;
 875                 self.solid = SOLID_SLIDEBOX;
 876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 877                 if(cvar("g_playerclip_collisions"))
 878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 881                 self.frags = FRAGS_PLAYER;
 882                 if(independent_players)
 883                         MAKE_INDEPENDENT_PLAYER(self);
 884                 self.flags = FL_CLIENT;
 885                 self.takedamage = DAMAGE_AIM;
 886                 if(g_minstagib)
 887                         self.effects = EF_FULLBRIGHT;
 888                 else
 889                         self.effects = 0;
 890                 self.air_finished = time + 12;
 891                 self.dmg = 2;
 892                 if(cvar("g_balance_nex_charge"))
 893                         self.nex_charge = cvar("g_balance_nex_charge_start");
 894
 895                 if(inWarmupStage)
 896                 {
 897                         self.ammo_shells = warmup_start_ammo_shells;
 898                         self.ammo_nails = warmup_start_ammo_nails;
 899                         self.ammo_rockets = warmup_start_ammo_rockets;
 900                         self.ammo_cells = warmup_start_ammo_cells;
 901                         self.ammo_fuel = warmup_start_ammo_fuel;
 902                         self.health = warmup_start_health;
 903                         self.armorvalue = warmup_start_armorvalue;
 904                         self.weapons = warmup_start_weapons;
 905                 }
 906                 else
 907                 {
 908                         self.ammo_shells = start_ammo_shells;
 909                         self.ammo_nails = start_ammo_nails;
 910                         self.ammo_rockets = start_ammo_rockets;
 911                         self.ammo_cells = start_ammo_cells;
 912                         self.ammo_fuel = start_ammo_fuel;
 913                         self.health = start_health;
 914                         self.armorvalue = start_armorvalue;
 915                         self.weapons = start_weapons;
 916                 }
 917
 918                 if(g_weaponarena_random)
 919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 920
 921                 self.items = start_items;
 922                 self.jump_interval = time;
 923
 924                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 925                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 926                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 927                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 928                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 929                 //extend the pause of rotting if client was reset at the beginning of the countdown
 930                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 931                         self.spawnshieldtime += game_starttime - time;
 932                         self.pauserotarmor_finished += game_starttime - time;
 933                         self.pauserothealth_finished += game_starttime - time;
 934                         self.pauseregen_finished += game_starttime - time;
 935                 }
 936                 self.damageforcescale = 2;
 937                 self.death_time = 0;
 938                 self.dead_frame = 0;
 939                 self.alpha = 0;
 940                 self.scale = 0;
 941                 self.fade_time = 0;
 942                 self.pain_frame = 0;
 943                 self.pain_finished = 0;
 944                 self.strength_finished = 0;
 945                 self.invincible_finished = 0;
 946                 self.pushltime = 0;
 947                 // players have no think function
 948                 self.think = SUB_Null;
 949                 self.nextthink = 0;
 950                 self.hook_time = 0;
 951                 self.dmg_team = 0;
 952                 self.ballistics_density = cvar("g_ballistics_density_player");
 953
 954                 self.metertime = 0;
 955
 956                 self.runes = 0;
 957
 958                 self.deadflag = DEAD_NO;
 959
 960                 self.angles = spot.angles;
 961
 962                 self.angles_z = 0; // never spawn tilted even if the spot says to
 963                 self.fixangle = TRUE; // turn this way immediately
 964                 self.velocity = '0 0 0';
 965                 self.avelocity = '0 0 0';
 966                 self.punchangle = '0 0 0';
 967                 self.punchvector = '0 0 0';
 968                 self.oldvelocity = self.velocity;
 969                 self.fire_endtime = -1;
 970
 971                 msg_entity = self;
 972                 WRITESPECTATABLE_MSG_ONE({
 973                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 974                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 975                 });
 976
 977                 if(sv_loddistance1)
 978                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 979
 980                 self.model = "";
 981                 FixPlayermodel();
 982
 983                 self.crouch = FALSE;
 984                 self.view_ofs = PL_VIEW_OFS;
 985                 setsize (self, PL_MIN, PL_MAX);
 986                 self.spawnorigin = spot.origin;
 987                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 988                 // don't reset back to last position, even if new position is stuck in solid
 989                 self.oldorigin = self.origin;
 990                 self.prevorigin = self.origin;
 991                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 992
 993                 if(g_arena)
 994                 {
 995                         Spawnqueue_Remove(self);
 996                         Spawnqueue_Mark(self);
 997                 }
 998
 999                 else if(g_ca)
1000                         self.caplayer = 1;
1001
1002                 self.event_damage = PlayerDamage;
1003
1004                 self.bot_attack = TRUE;
1005
1006                 self.statdraintime = time + 5;
1007                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1008
1009                 if(self.killcount == -666) {
1010                         PlayerScore_Clear(self);
1011                         self.killcount = 0;
1012                 }
1013
1014                 self.cnt = WEP_LASER;
1015
1016                 CL_SpawnWeaponentity();
1017                 self.alpha = default_player_alpha;
1018                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1019                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1020
1021                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1022                 self.lms_traveled_distance = 0;
1023                 self.speedrunning = FALSE;
1024
1025                 race_PostSpawn(spot);
1026
1027                 if(cvar("spawn_debug"))
1028                 {
1029                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1030                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1031                 }
1032
1033                 //stuffcmd(self, "chase_active 0");
1034                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1035
1036                 if (cvar("g_spawnsound"))
1037                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1038
1039                 if(g_assault) {
1040                         if(self.team == assault_attacker_team)
1041                                 centerprint(self, "You are attacking!");
1042                         else
1043                                 centerprint(self, "You are defending!");
1044                 }
1045
1046                 target_voicescript_clear(self);
1047
1048                 // reset fields the weapons may use
1049                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1050                         weapon_action(j, WR_RESETPLAYER);
1051
1052                 oldself = self;
1053                 self = spot;
1054                         activator = oldself;
1055                                 SUB_UseTargets();
1056                         activator = world;
1057                 self = oldself;
1058
1059                 MUTATOR_CALLHOOK(PlayerSpawn);
1060
1061                 self.switchweapon = w_getbestweapon(self);
1062                 self.cnt = self.switchweapon;
1063                 self.weapon = 0;
1064         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1065                 PutObserverInServer ();
1066         }
1067
1068         //if(g_ctf)
1069         //      ctf_playerchanged();
1070 }
1071
1072 float ClientInit_SendEntity(entity to, float sf)
1073 {
1074         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1075         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1081         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1088         if(sv_foginterval && world.fog != "")
1089                 WriteString(MSG_ENTITY, world.fog);
1090         else
1091                 WriteString(MSG_ENTITY, "");
1092         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1093         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1094         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1095         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1096         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1097         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1098         return TRUE;
1099 }
1100
1101 void ClientInit_CheckUpdate()
1102 {
1103         self.nextthink = time;
1104         if(self.count != cvar("g_balance_armor_blockpercent"))
1105         {
1106                 self.count = cvar("g_balance_armor_blockpercent");
1107                 self.SendFlags |= 1;
1108         }
1109         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1110         {
1111                 self.cnt = cvar("g_balance_weaponswitchdelay");
1112                 self.SendFlags |= 1;
1113         }
1114         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1115         {
1116                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1117                 self.SendFlags |= 1;
1118         }
1119         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1120         {
1121                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1122                 self.SendFlags |= 1;
1123         }
1124 }
1125
1126 void ClientInit_Spawn()
1127 {
1128         entity o;
1129         entity e;
1130         e = spawn();
1131         e.classname = "clientinit";
1132         e.think = ClientInit_CheckUpdate;
1133         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1134
1135         o = self;
1136         self = e;
1137         ClientInit_CheckUpdate();
1138         self = o;
1139 }
1140
1141 /*
1142 =============
1143 SetNewParms
1144 =============
1145 */
1146 void SetNewParms (void)
1147 {
1148         // initialize parms for a new player
1149         parm1 = -(86400 * 366);
1150 }
1151
1152 /*
1153 =============
1154 SetChangeParms
1155 =============
1156 */
1157 void SetChangeParms (void)
1158 {
1159         // save parms for level change
1160         parm1 = self.parm_idlesince - time;
1161 }
1162
1163 /*
1164 =============
1165 DecodeLevelParms
1166 =============
1167 */
1168 void DecodeLevelParms (void)
1169 {
1170         // load parms
1171         self.parm_idlesince = parm1;
1172         if(self.parm_idlesince == -(86400 * 366))
1173                 self.parm_idlesince = time;
1174
1175         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1176         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1177 }
1178
1179 /*
1180 =============
1181 ClientKill
1182
1183 Called when a client types 'kill' in the console
1184 =============
1185 */
1186
1187 void ClientKill_Now_TeamChange()
1188 {
1189         if(self.killindicator_teamchange == -1)
1190         {
1191                 self.team = -1;
1192                 JoinBestTeam( self, FALSE, FALSE );
1193         }
1194         else
1195                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1196 }
1197
1198 void ClientKill_Now()
1199 {
1200         if(self.killindicator_teamchange)
1201                 ClientKill_Now_TeamChange();
1202
1203         // in any case:
1204         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1205
1206         if(self.killindicator)
1207         {
1208                 dprint("Cleaned up after a leaked kill indicator.\n");
1209                 remove(self.killindicator);
1210                 self.killindicator = world;
1211         }
1212 }
1213 void KillIndicator_Think()
1214 {
1215         if (!self.owner.modelindex)
1216         {
1217                 self.owner.killindicator = world;
1218                 remove(self);
1219                 return;
1220         }
1221
1222         if(self.cnt <= 0)
1223         {
1224                 self = self.owner;
1225                 ClientKill_Now(); // no oldself needed
1226                 return;
1227         }
1228         else
1229         {
1230                 if(self.cnt <= 10)
1231                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1232                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1233                 {
1234                         if(self.cnt <= 10)
1235                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1236                         if(self.owner.killindicator_teamchange)
1237                         {
1238                                 if(self.owner.killindicator_teamchange == -1)
1239                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1240                                 else
1241                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1242                         }
1243                         else
1244                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1245                 }
1246                 self.nextthink = time + 1;
1247                 self.cnt -= 1;
1248         }
1249 }
1250
1251 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1252 {
1253         float killtime;
1254         entity e;
1255         killtime = cvar("g_balance_kill_delay");
1256
1257         if(g_race_qualifying)
1258                 killtime = 0;
1259
1260         self.killindicator_teamchange = targetteam;
1261
1262         if(!self.killindicator)
1263         {
1264                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1265                 {
1266                         ClientKill_Now();
1267                 }
1268                 else
1269                 {
1270                         self.killindicator = spawn();
1271                         self.killindicator.owner = self;
1272                         self.killindicator.scale = 0.5;
1273                         setattachment(self.killindicator, self, "");
1274                         setorigin(self.killindicator, '0 0 52');
1275                         self.killindicator.think = KillIndicator_Think;
1276                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1277                         self.killindicator.cnt = ceil(killtime);
1278                         self.killindicator.count = bound(0, ceil(killtime), 10);
1279                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1280
1281                         for(e = world; (e = find(e, classname, "body")) != world; )
1282                         {
1283                                 if(e.enemy != self)
1284                                         continue;
1285                                 e.killindicator = spawn();
1286                                 e.killindicator.owner = e;
1287                                 e.killindicator.scale = 0.5;
1288                                 setattachment(e.killindicator, e, "");
1289                                 setorigin(e.killindicator, '0 0 52');
1290                                 e.killindicator.think = KillIndicator_Think;
1291                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1292                                 e.killindicator.cnt = ceil(killtime);
1293                         }
1294                         self.lip = 0;
1295                 }
1296         }
1297         if(self.killindicator)
1298         {
1299                 if(targetteam)
1300                         self.killindicator.colormod = TeamColor(targetteam);
1301                 else
1302                         self.killindicator.colormod = '0 0 0';
1303         }
1304 }
1305
1306 void ClientKill (void)
1307 {
1308         ClientKill_TeamChange(0);
1309 }
1310
1311 void CTS_ClientKill_Think (void)
1312 {
1313         self = self.owner; // set self to the player to be killed
1314         sprint(self, "^1You were killed in order to prevent cheating!");
1315         ClientKill_Now();
1316 }
1317
1318 void CTS_ClientKill (float t) // silent version of ClientKill
1319 {
1320         entity e;
1321         e = spawn();
1322         e.owner = self;
1323         e.think = CTS_ClientKill_Think;
1324         e.nextthink = t;
1325 }
1326
1327 void DoTeamChange(float destteam)
1328 {
1329         float t, c0;
1330         if(!teams_matter)
1331         {
1332                 if(destteam >= 0)
1333                         SetPlayerColors(self, destteam);
1334                 return;
1335         }
1336         if(self.classname == "player")
1337         if(destteam == -1)
1338         {
1339                 CheckAllowedTeams(self);
1340                 t = FindSmallestTeam(self, TRUE);
1341                 switch(self.team)
1342                 {
1343                         case COLOR_TEAM1: c0 = c1; break;
1344                         case COLOR_TEAM2: c0 = c2; break;
1345                         case COLOR_TEAM3: c0 = c3; break;
1346                         case COLOR_TEAM4: c0 = c4; break;
1347                         default:          c0 = 999;
1348                 }
1349                 switch(t)
1350                 {
1351                         case 1:
1352                                 if(c0 > c1)
1353                                         destteam = COLOR_TEAM1;
1354                                 break;
1355                         case 2:
1356                                 if(c0 > c2)
1357                                         destteam = COLOR_TEAM2;
1358                                 break;
1359                         case 3:
1360                                 if(c0 > c3)
1361                                         destteam = COLOR_TEAM3;
1362                                 break;
1363                         case 4:
1364                                 if(c0 > c4)
1365                                         destteam = COLOR_TEAM4;
1366                                 break;
1367                 }
1368                 if(destteam == -1)
1369                         return;
1370         }
1371         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1372                 return;
1373         ClientKill_TeamChange(destteam);
1374 }
1375
1376 void FixClientCvars(entity e)
1377 {
1378         // send prediction settings to the client
1379         stuffcmd(e, "\nin_bindmap 0 0\n");
1380         if(g_race || g_cts)
1381                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1382         if(cvar("g_antilag") == 3) // client side hitscan
1383                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1384         if(sv_gentle)
1385                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1386         /*
1387          * we no longer need to stuff this. Remove this comment block if you feel
1388          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1389         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1390         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1391         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1392         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1393         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1394         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1395         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1396         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1397         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1398         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1399         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1400         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1401         stuffcmd(e, "cl_movement_edgefriction 1\n");
1402          */
1403 }
1404
1405 /*
1406 =============
1407 ClientConnect
1408
1409 Called when a client connects to the server
1410 =============
1411 */
1412 //void ctf_clientconnect();
1413 string ColoredTeamName(float t);
1414 void DecodeLevelParms (void);
1415 //void dom_player_join_team(entity pl);
1416 void ClientConnect (void)
1417 {
1418         float t;
1419
1420         if(self.flags & FL_CLIENT)
1421         {
1422                 print("Warning: ClientConnect, but already connected!\n");
1423                 return;
1424         }
1425
1426         if(Ban_MaybeEnforceBan(self))
1427                 return;
1428
1429         DecodeLevelParms();
1430
1431 #ifdef WATERMARK
1432         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1433 #endif
1434
1435         self.classname = "player_joining";
1436
1437         self.flags = FL_CLIENT;
1438         self.version_nagtime = time + 10 + random() * 10;
1439
1440         if(player_count<0)
1441         {
1442                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1443                 player_count = 0;
1444         }
1445
1446         PlayerScore_Attach(self);
1447         ClientData_Attach();
1448
1449         bot_clientconnect();
1450
1451         playerdemo_init();
1452
1453         anticheat_init();
1454
1455         race_PreSpawnObserver();
1456
1457         //if(g_domination)
1458         //      dom_player_join_team(self);
1459
1460         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1461
1462         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1463                 self.classname = "observer";
1464         } else {
1465                 if(teams_matter)
1466                 {
1467                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1468                         {
1469                                 self.classname = "player";
1470                                 campaign_bots_may_start = 1;
1471                         }
1472                         else
1473                         {
1474                                 self.classname = "observer"; // do it anyway
1475                         }
1476                 }
1477                 else
1478                 {
1479                         self.classname = "player";
1480                         campaign_bots_may_start = 1;
1481                 }
1482         }
1483
1484         self.playerid = (playerid_last = playerid_last + 1);
1485
1486         if(cvar("sv_eventlog"))
1487                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1488
1489         LogTeamchange(self.playerid, self.team, 1);
1490
1491         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1492
1493         self.netname_previous = strzone(self.netname);
1494
1495         bprint("^4", self.netname, "^4 connected");
1496
1497         if(self.classname != "observer" && (g_domination || g_ctf))
1498                 bprint(" and joined the ", ColoredTeamName(self.team));
1499
1500         bprint("\n");
1501
1502         self.welcomemessage_time = 0;
1503
1504         stuffcmd(self, strcat(clientstuff, "\n"));
1505         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1506         stuffcmd(self, "cl_particles_reloadeffects\n");
1507
1508         FixClientCvars(self);
1509
1510         // spawnfunc_waypoint sprites
1511         WaypointSprite_InitClient(self);
1512
1513         // Wazat's grappling hook
1514         SetGrappleHookBindings();
1515
1516         // get autoswitch state from player when he toggles it
1517         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1518
1519         // get version info from player
1520         stuffcmd(self, "cmd clientversion $gameversion\n");
1521
1522         // get other cvars from player
1523         GetCvars(0);
1524
1525         // set cvar for team scoreboard
1526         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1527
1528         // notify about available teams
1529         if(teams_matter)
1530         {
1531                 CheckAllowedTeams(self);
1532                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1533                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1534         }
1535         else
1536                 stuffcmd(self, "set _teams_available 0\n");
1537
1538         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1539
1540         if(g_arena || g_ca)
1541         {
1542                 self.classname = "observer";
1543                 if(g_arena)
1544                         Spawnqueue_Insert(self);
1545         }
1546         /*else if(g_ctf)
1547         {
1548                 ctf_clientconnect();
1549         }*/
1550
1551         if(teams_matter || radar_showennemies)
1552                 attach_entcs();
1553
1554         bot_relinkplayerlist();
1555
1556         self.spectatortime = time;
1557         if(blockSpectators)
1558         {
1559                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1560         }
1561
1562         self.jointime = time;
1563         self.allowedTimeouts = cvar("sv_timeout_number");
1564
1565         if(clienttype(self) == CLIENTTYPE_REAL)
1566         {
1567                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1568                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1569         }
1570
1571         if(g_lms)
1572         {
1573                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1574                 {
1575                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1576                         self.frags = FRAGS_SPECTATOR;
1577                 }
1578         }
1579
1580         if(!sv_foginterval && world.fog != "")
1581                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1582
1583         SoundEntity_Attach(self);
1584
1585         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1586         {
1587                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1588                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1589         }
1590         else
1591                 self.hitplotfh = -1;
1592
1593         if(g_race || g_cts) {
1594                 string rr;
1595                 if(g_cts)
1596                         rr = CTS_RECORD;
1597                 else
1598                         rr = RACE_RECORD;
1599                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1600
1601                 race_send_recordtime(MSG_ONE);
1602                 race_send_speedaward(MSG_ONE);
1603
1604                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1605                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1606                 race_send_speedaward_alltimebest(MSG_ONE);
1607
1608                 float i;
1609                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1610                         race_SendRankings(i, 0, 0, MSG_ONE);
1611                 }
1612         }
1613         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1614                 send_CSQC_teamnagger();
1615
1616         send_CSQC_cr_maxbullets(self);
1617
1618         CheatInitClient();
1619 }
1620
1621 /*
1622 =============
1623 ClientDisconnect
1624
1625 Called when a client disconnects from the server
1626 =============
1627 */
1628 .entity chatbubbleentity;
1629 .entity teambubbleentity;
1630 void ReadyCount();
1631 void ClientDisconnect (void)
1632 {
1633         if not(self.flags & FL_CLIENT)
1634         {
1635                 print("Warning: ClientDisconnect without ClientConnect\n");
1636                 return;
1637         }
1638
1639         CheatShutdownClient();
1640
1641         if(self.hitplotfh >= 0)
1642         {
1643                 fclose(self.hitplotfh);
1644                 self.hitplotfh = -1;
1645         }
1646
1647         anticheat_report();
1648         anticheat_shutdown();
1649
1650         playerdemo_shutdown();
1651
1652         bot_clientdisconnect();
1653
1654         if(self.entcs)
1655                 detach_entcs();
1656
1657         if(cvar("sv_eventlog"))
1658                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1659         bprint ("^4",self.netname);
1660         bprint ("^4 disconnected\n");
1661
1662         SoundEntity_Detach(self);
1663
1664         DropAllRunes(self);
1665         MUTATOR_CALLHOOK(ClientDisconnect);
1666
1667         Portal_ClearAll(self);
1668
1669         if(self.flagcarried)
1670                 DropFlag(self.flagcarried, world, world);
1671         if(self.ballcarried)
1672                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1673
1674         // Here, everything has been done that requires this player to be a client.
1675
1676         self.flags &~= FL_CLIENT;
1677
1678         if (self.chatbubbleentity)
1679                 remove (self.chatbubbleentity);
1680
1681         if (self.teambubbleentity)
1682                 remove (self.teambubbleentity);
1683
1684         if (self.killindicator)
1685                 remove (self.killindicator);
1686
1687         WaypointSprite_PlayerGone();
1688
1689         bot_relinkplayerlist();
1690
1691         // remove laserdot
1692         if(self.weaponentity)
1693                 if(self.weaponentity.lasertarget)
1694                         remove(self.weaponentity.lasertarget);
1695
1696         if(g_arena)
1697         {
1698                 Spawnqueue_Unmark(self);
1699                 Spawnqueue_Remove(self);
1700         }
1701
1702         ClientData_Detach();
1703         PlayerScore_Detach(self);
1704
1705         if(self.netname_previous)
1706                 strunzone(self.netname_previous);
1707         if(self.clientstatus)
1708                 strunzone(self.clientstatus);
1709
1710         ClearPlayerSounds();
1711
1712         if(self.personal)
1713                 remove(self.personal);
1714
1715         self.playerid = 0;
1716         ReadyCount();
1717
1718         // free cvars
1719         GetCvars(-1);
1720 }
1721
1722 .float BUTTON_CHAT;
1723 void ChatBubbleThink()
1724 {
1725         self.nextthink = time;
1726         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1727         {
1728                 if(self.owner) // but why can that ever be world?
1729                         self.owner.chatbubbleentity = world;
1730                 remove(self);
1731                 return;
1732         }
1733         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1734 #ifdef TETRIS
1735                 || self.owner.tetris_on
1736 #endif
1737         )
1738                 self.model = self.mdl;
1739         else
1740                 self.model = "";
1741 };
1742
1743 void UpdateChatBubble()
1744 {
1745         if (!self.modelindex)
1746                 return;
1747         // spawn a chatbubble entity if needed
1748         if (!self.chatbubbleentity)
1749         {
1750                 self.chatbubbleentity = spawn();
1751                 self.chatbubbleentity.owner = self;
1752                 self.chatbubbleentity.exteriormodeltoclient = self;
1753                 self.chatbubbleentity.think = ChatBubbleThink;
1754                 self.chatbubbleentity.nextthink = time;
1755                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1756                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1757                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1758                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1759                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1760                 self.chatbubbleentity.model = "";
1761                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1762         }
1763 }
1764
1765
1766 void TeamBubbleThink()
1767 {
1768         self.nextthink = time;
1769         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1770         {
1771                 if(self.owner) // but why can that ever be world?
1772                         self.owner.teambubbleentity = world;
1773                 remove(self);
1774                 return;
1775         }
1776 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1777         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1778                 self.model = "";
1779         else
1780                 self.model = self.mdl;
1781
1782 };
1783
1784 float TeamBubble_customizeentityforclient()
1785 {
1786         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1787 }
1788
1789 void UpdateTeamBubble()
1790 {
1791         if (!self.modelindex || !teams_matter)
1792                 return;
1793         // spawn a teambubble entity if needed
1794         if (!self.teambubbleentity && teams_matter)
1795         {
1796                 self.teambubbleentity = spawn();
1797                 self.teambubbleentity.owner = self;
1798                 self.teambubbleentity.exteriormodeltoclient = self;
1799                 self.teambubbleentity.think = TeamBubbleThink;
1800                 self.teambubbleentity.nextthink = time;
1801                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1802 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1803                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1804                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1805                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1806                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1807                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1808                 self.teambubbleentity.effects = EF_LOWPRECISION;
1809         }
1810 }
1811
1812 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1813 // added to the model skins
1814 /*void UpdateColorModHack()
1815 {
1816         local float c;
1817         c = self.clientcolors & 15;
1818         // LordHavoc: only bothering to support white, green, red, yellow, blue
1819              if (!teams_matter) self.colormod = '0 0 0';
1820         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1821         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1822         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1823         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1824         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1825         else self.colormod = '1 1 1';
1826 };*/
1827
1828 .float oldcolormap;
1829 void respawn(void)
1830 {
1831         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1832         {
1833                 self.solid = SOLID_NOT;
1834                 self.takedamage = DAMAGE_NO;
1835                 self.movetype = MOVETYPE_FLY;
1836                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1837                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1838                 self.effects |= EF_ADDITIVE;
1839                 self.oldcolormap = self.colormap;
1840                 self.colormap = 512;
1841                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1842                 if(cvar("g_respawn_ghosts_maxtime"))
1843                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1844         }
1845
1846         CopyBody(1);
1847         self.effects |= EF_NODRAW; // prevent another CopyBody
1848         if(self.oldcolormap)
1849         {
1850                 self.colormap = self.oldcolormap;
1851                 self.oldcolormap = 0;
1852         }
1853         PutClientInServer();
1854 }
1855
1856 void play_countdown(float finished, string samp)
1857 {
1858         if(clienttype(self) == CLIENTTYPE_REAL)
1859                 if(floor(finished - time - frametime) != floor(finished - time))
1860                         if(finished - time < 6)
1861                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1862 }
1863
1864 /**
1865  * When sv_timeout is used this function returs strings like
1866  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1867  * Called by centerprint functions
1868  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1869  */
1870 string getTimeoutText(float addOneSecond) {
1871         if (!cvar("sv_timeout") || !timeoutStatus)
1872                 return "";
1873
1874         local string retStr;
1875         if (timeoutStatus == 1) {
1876                 if (addOneSecond == 1) {
1877                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1878                 }
1879                 else {
1880                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1881                 }
1882                 return retStr;
1883         }
1884         else if (timeoutStatus == 2) {
1885                 if (addOneSecond) {
1886                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1887                         //don't show messages like "Timeout ends in 0 seconds"...
1888                         if ((remainingTimeoutTime + 1) > 0)
1889                                 return retStr;
1890                         else
1891                                 return "";
1892                 }
1893                 else {
1894                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1895                         //don't show messages like "Timeout ends in 0 seconds"...
1896                         if (remainingTimeoutTime > 0)
1897                                 return retStr;
1898                         else
1899                                 return "";
1900                 }
1901         }
1902         else return "";
1903 }
1904
1905 void player_powerups (void)
1906 {
1907         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1908         {
1909                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1910                 self.modelflags |= MF_ROCKET;
1911         }
1912         else
1913         {
1914                 SoundEntity_StopSound(self, CHAN_PLAYER);
1915                 self.modelflags &~= MF_ROCKET;
1916         }
1917
1918         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1919
1920         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1921                 return;
1922
1923         Fire_ApplyDamage(self);
1924         Fire_ApplyEffect(self);
1925
1926         if (g_minstagib)
1927         {
1928                 self.effects |= EF_FULLBRIGHT;
1929
1930                 if (self.items & IT_STRENGTH)
1931                 {
1932                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1933                         if (time > self.strength_finished)
1934                         {
1935                                 self.alpha = default_player_alpha;
1936                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1937                                 self.items &~= IT_STRENGTH;
1938                                 sprint(self, "^3Invisibility has worn off\n");
1939                         }
1940                 }
1941                 else
1942                 {
1943                         if (time < self.strength_finished)
1944                         {
1945                                 self.alpha = g_minstagib_invis_alpha;
1946                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1947                                 self.items |= IT_STRENGTH;
1948                                 sprint(self, "^3You are invisible\n");
1949                         }
1950                 }
1951
1952                 if (self.items & IT_INVINCIBLE)
1953                 {
1954                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1955                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1956                         {
1957                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1958                                 sprint(self, "^3Speed has worn off\n");
1959                         }
1960                 }
1961                 else
1962                 {
1963                         if (time < self.invincible_finished)
1964                         {
1965                                 self.items = self.items | IT_INVINCIBLE;
1966                                 sprint(self, "^3You are on speed\n");
1967                         }
1968                 }
1969                 return;
1970         }
1971
1972         if (self.items & IT_STRENGTH)
1973         {
1974                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1975                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1976                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1977                 {
1978                         self.items = self.items - (self.items & IT_STRENGTH);
1979                         sprint(self, "^3Strength has worn off\n");
1980                 }
1981         }
1982         else
1983         {
1984                 if (time < self.strength_finished)
1985                 {
1986                         self.items = self.items | IT_STRENGTH;
1987                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1988                 }
1989         }
1990         if (self.items & IT_INVINCIBLE)
1991         {
1992                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1993                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1994                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1995                 {
1996                         self.items = self.items - (self.items & IT_INVINCIBLE);
1997                         sprint(self, "^3Shield has worn off\n");
1998                 }
1999         }
2000         else
2001         {
2002                 if (time < self.invincible_finished)
2003                 {
2004                         self.items = self.items | IT_INVINCIBLE;
2005                         sprint(self, "^3Shield surrounds you\n");
2006                 }
2007         }
2008
2009         if(cvar("g_nodepthtestplayers"))
2010                 self.effects = self.effects | EF_NODEPTHTEST;
2011
2012         if(cvar("g_fullbrightplayers"))
2013                 self.effects = self.effects | EF_FULLBRIGHT;
2014
2015         // midair gamemode: damage only while in the air
2016         // if in midair mode, being on ground grants temporary invulnerability
2017         // (this is so that multishot weapon don't clear the ground flag on the
2018         // first damage in the frame, leaving the player vulnerable to the
2019         // remaining hits in the same frame)
2020         if (self.flags & FL_ONGROUND)
2021         if (g_midair)
2022                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2023
2024         if (time >= game_starttime)
2025         if (time < self.spawnshieldtime)
2026                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2027 }
2028
2029 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2030 {
2031         if(current > stable)
2032                 return current;
2033         else if(current > stable - 0.25) // when close enough, "snap"
2034                 return stable;
2035         else
2036                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2037 }
2038
2039 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2040 {
2041         if(current < stable)
2042                 return current;
2043         else if(current < stable + 0.25) // when close enough, "snap"
2044                 return stable;
2045         else
2046                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2047 }
2048
2049 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2050 {
2051         if(current > rotstable)
2052         {
2053                 if(rotframetime > 0)
2054                 {
2055                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2056                         current = max(rotstable, current - rotlinear * rotframetime);
2057                 }
2058         }
2059         else if(current < regenstable)
2060         {
2061                 if(regenframetime > 0)
2062                 {
2063                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2064                         current = min(regenstable, current + regenlinear * regenframetime);
2065                 }
2066         }
2067
2068         if(current > limit)
2069                 current = limit;
2070
2071         return current;
2072 }
2073
2074 void player_regen (void)
2075 {
2076         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2077         maxh = cvar("g_balance_health_rotstable");
2078         maxa = cvar("g_balance_armor_rotstable");
2079         maxf = cvar("g_balance_fuel_rotstable");
2080         minh = cvar("g_balance_health_regenstable");
2081         mina = cvar("g_balance_armor_regenstable");
2082         minf = cvar("g_balance_fuel_regenstable");
2083         limith = cvar("g_balance_health_limit");
2084         limita = cvar("g_balance_armor_limit");
2085         limitf = cvar("g_balance_fuel_limit");
2086
2087         max_mod = regen_mod = rot_mod = limit_mod = 1;
2088
2089         if (self.runes & RUNE_REGEN)
2090         {
2091                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2092                 {
2093                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2094                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2095                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2096                 }
2097                 else
2098                 {
2099                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2100                         max_mod = cvar("g_balance_rune_regen_hpmod");
2101                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2102                 }
2103         }
2104         else if (self.runes & CURSE_VENOM)
2105         {
2106                 max_mod = cvar("g_balance_curse_venom_hpmod");
2107                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2108                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2109                 else
2110                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2111                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2112                 //if (!self.runes & RUNE_REGEN)
2113                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2114         }
2115         maxh = maxh * max_mod;
2116         //maxa = maxa * max_mod;
2117         //maxf = maxf * max_mod;
2118         minh = minh * max_mod;
2119         //mina = mina * max_mod;
2120         //minf = minf * max_mod;
2121         limith = limith * limit_mod;
2122         limita = limita * limit_mod;
2123         //limitf = limitf * limit_mod;
2124
2125         if(g_lms && g_ca)
2126                 rot_mod = 0;
2127
2128         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2129         {
2130                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2131                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2132
2133                 // if player rotted to death...  die!
2134                 if(self.health < 1)
2135                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2136         }
2137
2138         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2139                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2140 }
2141
2142 float zoomstate_set;
2143 void SetZoomState(float z)
2144 {
2145         if(z != self.zoomstate)
2146         {
2147                 self.zoomstate = z;
2148                 ClientData_Touch(self);
2149         }
2150         zoomstate_set = 1;
2151 }
2152
2153 void GetPressedKeys(void) {
2154         MUTATOR_CALLHOOK(GetPressedKeys);
2155         if (self.movement_x > 0) // get if movement keys are pressed
2156         {       // forward key pressed
2157                 self.pressedkeys |= KEY_FORWARD;
2158                 self.pressedkeys &~= KEY_BACKWARD;
2159         }
2160         else if (self.movement_x < 0)
2161         {       // backward key pressed
2162                 self.pressedkeys |= KEY_BACKWARD;
2163                 self.pressedkeys &~= KEY_FORWARD;
2164         }
2165         else
2166         {       // no x input
2167                 self.pressedkeys &~= KEY_FORWARD;
2168                 self.pressedkeys &~= KEY_BACKWARD;
2169         }
2170
2171         if (self.movement_y > 0)
2172         {       // right key pressed
2173                 self.pressedkeys |= KEY_RIGHT;
2174                 self.pressedkeys &~= KEY_LEFT;
2175         }
2176         else if (self.movement_y < 0)
2177         {       // left key pressed
2178                 self.pressedkeys |= KEY_LEFT;
2179                 self.pressedkeys &~= KEY_RIGHT;
2180         }
2181         else
2182         {       // no y input
2183                 self.pressedkeys &~= KEY_RIGHT;
2184                 self.pressedkeys &~= KEY_LEFT;
2185         }
2186
2187         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2188                 self.pressedkeys |= KEY_JUMP;
2189         else
2190                 self.pressedkeys &~= KEY_JUMP;
2191         if (self.BUTTON_CROUCH)
2192                 self.pressedkeys |= KEY_CROUCH;
2193         else
2194                 self.pressedkeys &~= KEY_CROUCH;
2195 }
2196
2197 void update_stats (float number, float hit, float fired) {
2198 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2199 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2200
2201         if(number) {
2202                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2203                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2204         } else {
2205                 self.stat_hit = hit * sv_accuracy_data_share;
2206                 self.stat_fired = fired * sv_accuracy_data_share;
2207         }
2208 }
2209
2210 /*
2211 ======================
2212 spectate mode routines
2213 ======================
2214 */
2215
2216 .float weapon_count;
2217 void SpectateCopy(entity spectatee) {
2218         if(spectatee.weapon_count < WEP_LAST) {
2219                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2220                 spectatee.weapon_count ++;
2221         } else
2222                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2223
2224         other = spectatee;
2225         MUTATOR_CALLHOOK(SpectateCopy);
2226         self.armortype = spectatee.armortype;
2227         self.armorvalue = spectatee.armorvalue;
2228         self.ammo_cells = spectatee.ammo_cells;
2229         self.ammo_shells = spectatee.ammo_shells;
2230         self.ammo_nails = spectatee.ammo_nails;
2231         self.ammo_rockets = spectatee.ammo_rockets;
2232         self.ammo_fuel = spectatee.ammo_fuel;
2233         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2234         self.health = spectatee.health;
2235         self.impulse = 0;
2236         self.items = spectatee.items;
2237         self.metertime = spectatee.metertime;
2238         self.strength_finished = spectatee.strength_finished;
2239         self.invincible_finished = spectatee.invincible_finished;
2240         self.pressedkeys = spectatee.pressedkeys;
2241         self.weapons = spectatee.weapons;
2242         self.switchweapon = spectatee.switchweapon;
2243         self.weapon = spectatee.weapon;
2244         self.punchangle = spectatee.punchangle;
2245         self.view_ofs = spectatee.view_ofs;
2246         self.v_angle = spectatee.v_angle;
2247         self.velocity = spectatee.velocity;
2248         self.dmg_take = spectatee.dmg_take;
2249         self.dmg_save = spectatee.dmg_save;
2250         self.dmg_inflictor = spectatee.dmg_inflictor;
2251         self.angles = spectatee.v_angle;
2252         self.fixangle = TRUE;
2253         setorigin(self, spectatee.origin);
2254         setsize(self, spectatee.mins, spectatee.maxs);
2255         SetZoomState(spectatee.zoomstate);
2256
2257         anticheat_spectatecopy(spectatee);
2258 }
2259
2260 float SpectateUpdate() {
2261         if(!self.enemy)
2262                 return 0;
2263
2264         if (self == self.enemy)
2265                 return 0;
2266
2267         if(self.enemy.classname != "player")
2268                 return 0;
2269
2270         SpectateCopy(self.enemy);
2271
2272         return 1;
2273 }
2274
2275 float SpectateNext() {
2276         other = find(self.enemy, classname, "player");
2277
2278         if (!other)
2279                 other = find(other, classname, "player");
2280
2281         if (other)
2282                 self.enemy = other;
2283
2284         if(self.enemy.classname == "player") {
2285                 msg_entity = self;
2286                 WriteByte(MSG_ONE, SVC_SETVIEW);
2287                 WriteEntity(MSG_ONE, self.enemy);
2288                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2289                 self.movetype = MOVETYPE_NONE;
2290
2291                 self.enemy.weapon_count = 0;
2292
2293                 if(!SpectateUpdate())
2294                         PutObserverInServer();
2295
2296                 return 1;
2297         } else {
2298                 return 0;
2299         }
2300 }
2301
2302 /*
2303 =============
2304 ShowRespawnCountdown()
2305
2306 Update a respawn countdown display.
2307 =============
2308 */
2309 void ShowRespawnCountdown()
2310 {
2311         float number;
2312         if(self.deadflag == DEAD_NO) // just respawned?
2313                 return;
2314         else
2315         {
2316                 number = ceil(self.death_time - time);
2317                 if(number <= 0)
2318                         return;
2319                 if(number <= self.respawn_countdown)
2320                 {
2321                         self.respawn_countdown = number - 1;
2322                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2323                                 AnnounceTo(self, strcat(ftos(number), ""));
2324                 }
2325         }
2326 }
2327
2328 void LeaveSpectatorMode()
2329 {
2330         if(isJoinAllowed()) {
2331                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2332                         self.classname = "player";
2333
2334                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2335                                 JoinBestTeam(self, FALSE, TRUE);
2336
2337                         if(cvar("g_campaign"))
2338                                 campaign_bots_may_start = 1;
2339
2340                         self.stat_count = WEP_LAST;
2341
2342                         PutClientInServer();
2343
2344                         if(self.classname == "player")
2345                                 bprint ("^4", self.netname, "^4 is playing now\n");
2346
2347                         if(!cvar("g_campaign"))
2348                                 centerprint(self,""); // clear MOTD
2349
2350                         return;
2351                 } else {
2352                         if (g_ca && self.caplayer) {
2353                         }       // do nothing
2354                         else
2355                                 stuffcmd(self,"menu_showteamselect\n");
2356                         return;
2357                 }
2358         }
2359         else {
2360                 //player may not join because of g_maxplayers is set
2361                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2362         }
2363 }
2364
2365 /**
2366  * Determines whether the player is allowed to join. This depends on cvar
2367  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2368  * it checks whether the number of currently playing players exceeds g_maxplayers.
2369  * @return bool TRUE if the player is allowed to join, false otherwise
2370  */
2371 float isJoinAllowed() {
2372         if (!cvar("g_maxplayers"))
2373                 return TRUE;
2374
2375         local entity e;
2376         local float currentlyPlaying;
2377         FOR_EACH_REALPLAYER(e) {
2378                 if(e.classname == "player")
2379                         currentlyPlaying += 1;
2380         }
2381         if(currentlyPlaying < cvar("g_maxplayers"))
2382                 return TRUE;
2383
2384         return FALSE;
2385 }
2386
2387 /**
2388  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2389  * g_maxplayers_spectator_blocktime seconds
2390  */
2391 void checkSpectatorBlock() {
2392         if(self.classname == "spectator" || self.classname == "observer") {
2393                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2394                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2395                         dropclient(self);
2396                 }
2397         }
2398 }
2399
2400 float vercmp_recursive(string v1, string v2)
2401 {
2402         float dot1, dot2;
2403         string s1, s2;
2404         float r;
2405
2406         dot1 = strstrofs(v1, ".", 0);
2407         dot2 = strstrofs(v2, ".", 0);
2408         if(dot1 == -1)
2409                 s1 = v1;
2410         else
2411                 s1 = substring(v1, 0, dot1);
2412         if(dot2 == -1)
2413                 s2 = v2;
2414         else
2415                 s2 = substring(v2, 0, dot2);
2416
2417         r = stof(s1) - stof(s2);
2418         if(r != 0)
2419                 return r;
2420
2421         r = strcasecmp(s1, s2);
2422         if(r != 0)
2423                 return r;
2424
2425         if(dot1 == -1)
2426                 if(dot2 == -1)
2427                         return 0;
2428                 else
2429                         return -1;
2430         else
2431                 if(dot2 == -1)
2432                         return 1;
2433                 else
2434                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2435 }
2436
2437 float vercmp(string v1, string v2)
2438 {
2439         if(strcasecmp(v1, v2) == 0) // early out check
2440                 return 0;
2441         return vercmp_recursive(v1, v2);
2442 }
2443
2444 void ObserverThink()
2445 {
2446         if (self.flags & FL_JUMPRELEASED) {
2447                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2448                         self.welcomemessage_time = 0;
2449                         self.flags &~= FL_JUMPRELEASED;
2450                         self.flags |= FL_SPAWNING;
2451                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2452                         self.welcomemessage_time = 0;
2453                         self.flags &~= FL_JUMPRELEASED;
2454                         if(SpectateNext() == 1) {
2455                                 self.classname = "spectator";
2456                         }
2457                 }
2458         } else {
2459                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2460                         self.flags |= FL_JUMPRELEASED;
2461                         if(self.flags & FL_SPAWNING)
2462                         {
2463                                 self.flags &~= FL_SPAWNING;
2464                                 LeaveSpectatorMode();
2465                                 return;
2466                         }
2467                 }
2468         }
2469         PrintWelcomeMessage(self);
2470 }
2471
2472 void SpectatorThink()
2473 {
2474         if (self.flags & FL_JUMPRELEASED) {
2475                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2476                         self.welcomemessage_time = 0;
2477                         self.flags &~= FL_JUMPRELEASED;
2478                         self.flags |= FL_SPAWNING;
2479                 } else if(self.BUTTON_ATCK) {
2480                         self.welcomemessage_time = 0;
2481                         self.flags &~= FL_JUMPRELEASED;
2482                         if(SpectateNext() == 1) {
2483                                 self.classname = "spectator";
2484                         } else {
2485                                 self.classname = "observer";
2486                                 self.stat_count = WEP_LAST;
2487                                 PutClientInServer();
2488                         }
2489                 } else if (self.BUTTON_ATCK2) {
2490                         self.welcomemessage_time = 0;
2491                         self.flags &~= FL_JUMPRELEASED;
2492                         self.classname = "observer";
2493                         self.stat_count = WEP_LAST;
2494                         PutClientInServer();
2495                 } else {
2496                         if(!SpectateUpdate())
2497                                 PutObserverInServer();
2498                 }
2499         } else {
2500                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2501                         self.flags |= FL_JUMPRELEASED;
2502                         if(self.flags & FL_SPAWNING)
2503                         {
2504                                 self.flags &~= FL_SPAWNING;
2505                                 LeaveSpectatorMode();
2506                                 return;
2507                         }
2508                 }
2509         }
2510
2511         PrintWelcomeMessage(self);
2512         self.flags |= FL_CLIENT | FL_NOTARGET;
2513 }
2514
2515 .float touchexplode_time;
2516
2517 /*
2518 =============
2519 PlayerPreThink
2520
2521 Called every frame for each client before the physics are run
2522 =============
2523 */
2524 void() ctf_setstatus;
2525 void() nexball_setstatus;
2526 .float items_added;
2527 void PlayerPreThink (void)
2528 {
2529         self.stat_game_starttime = game_starttime;
2530         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2531         self.stat_leadlimit = cvar("leadlimit");
2532
2533         if(frametime)
2534         {
2535                 // physics frames: update anticheat stuff
2536                 anticheat_prethink();
2537         }
2538
2539         if(blockSpectators && frametime)
2540                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2541                 checkSpectatorBlock();
2542
2543         zoomstate_set = 0;
2544
2545         if(self.netname_previous != self.netname)
2546         {
2547                 if(cvar("sv_eventlog"))
2548                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2549                 if(self.netname_previous)
2550                         strunzone(self.netname_previous);
2551                 self.netname_previous = strzone(self.netname);
2552         }
2553
2554         // version nagging
2555         if(self.version_nagtime)
2556                 if(self.cvar_g_xonoticversion)
2557                         if(time > self.version_nagtime)
2558                         {
2559                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2560                                 {
2561                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2562                                         {
2563                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2564                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2565                                         }
2566                                         else
2567                                         {
2568                                                 float r;
2569                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2570                                                 if(r < 0)
2571                                                 {
2572                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2573                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2574                                                 }
2575                                                 else if(r > 0)
2576                                                 {
2577                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2578                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2579                                                 }
2580                                         }
2581                                 }
2582                                 self.version_nagtime = 0;
2583                         }
2584
2585         // GOD MODE info
2586         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2587         {
2588                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2589                 self.max_armorvalue = 0;
2590         }
2591
2592 #ifdef TETRIS
2593         if (TetrisPreFrame())
2594                 return;
2595 #endif
2596
2597         MUTATOR_CALLHOOK(PlayerPreThink);
2598
2599         if(self.classname == "player") {
2600 //              if(self.netname == "Wazat")
2601 //                      bprint(self.classname, "\n");
2602
2603                 CheckRules_Player();
2604
2605                 PrintWelcomeMessage(self);
2606
2607                 if (intermission_running)
2608                 {
2609                         IntermissionThink ();   // otherwise a button could be missed between
2610                         return;                                 // the think tics
2611                 }
2612
2613                 if(self.teleport_time)
2614                 if(time > self.teleport_time)
2615                 {
2616                         self.teleport_time = 0;
2617                         self.effects = self.effects - (self.effects & EF_NODRAW);
2618                 }
2619
2620                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2621                         UpdateSelectedPlayer();
2622
2623                 //don't allow the player to turn around while game is paused!
2624                 if(timeoutStatus == 2) {
2625                         self.v_angle = self.lastV_angle;
2626                         self.angles = self.lastV_angle;
2627                         self.fixangle = TRUE;
2628                 }
2629
2630                 if(frametime)
2631                 {
2632                         if(self.health <= 0 && cvar("g_deathglow"))
2633                         {
2634                                 if(self.glowmod_x > 0)
2635                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2636                                 else
2637                                         self.glowmod_x = -1;
2638                                 if(self.glowmod_y > 0)
2639                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2640                                 else
2641                                         self.glowmod_y = -1;
2642                                 if(self.glowmod_z > 0)
2643                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2644                                 else
2645                                         self.glowmod_z = -1;
2646                         }
2647                         else
2648                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2649                         player_powerups();
2650                 }
2651
2652                 if (self.deadflag != DEAD_NO)
2653                 {
2654                         float button_pressed, force_respawn;
2655                         if(self.personal && g_race_qualifying)
2656                         {
2657                                 if(time > self.death_time)
2658                                 {
2659                                         self.death_time = time + 1; // only retry once a second
2660                                         respawn();
2661                                         self.impulse = 141;
2662                                 }
2663                         }
2664                         else
2665                         {
2666                                 if(frametime)
2667                                         player_anim();
2668                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2669                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2670                                 if (self.deadflag == DEAD_DYING)
2671                                 {
2672                                         if(force_respawn)
2673                                                 self.deadflag = DEAD_RESPAWNING;
2674                                         else if(!button_pressed)
2675                                                 self.deadflag = DEAD_DEAD;
2676                                 }
2677                                 else if (self.deadflag == DEAD_DEAD)
2678                                 {
2679                                         if(button_pressed)
2680                                                 self.deadflag = DEAD_RESPAWNABLE;
2681                                 }
2682                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2683                                 {
2684                                         if(!button_pressed)
2685                                                 self.deadflag = DEAD_RESPAWNING;
2686                                 }
2687                                 else if (self.deadflag == DEAD_RESPAWNING)
2688                                 {
2689                                         if(time > self.death_time)
2690                                         {
2691                                                 self.death_time = time + 1; // only retry once a second
2692                                                 respawn();
2693                                         }
2694                                 }
2695                                 ShowRespawnCountdown();
2696                         }
2697                         return;
2698                 }
2699
2700                 if(g_touchexplode)
2701                 if(time > self.touchexplode_time)
2702                 if(self.classname == "player")
2703                 if(self.deadflag == DEAD_NO)
2704                 if not(IS_INDEPENDENT_PLAYER(self))
2705                 FOR_EACH_PLAYER(other) if(self != other)
2706                 {
2707                         if(time > other.touchexplode_time)
2708                         if(other.deadflag == DEAD_NO)
2709                         if not(IS_INDEPENDENT_PLAYER(other))
2710                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2711                         {
2712                                 PlayerTouchExplode(self, other);
2713                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2714                         }
2715                 }
2716
2717                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2718                 {
2719                         vector dist;
2720
2721                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2722                         dist = self.prevorigin - self.origin;
2723                         dist_z = 0;
2724                         self.lms_traveled_distance += fabs(vlen(dist));
2725
2726                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2727                         {
2728                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2729                                 self.lms_traveled_distance = 0;
2730                         }
2731
2732                         if(time > self.lms_nextcheck)
2733                         {
2734                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2735                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2736                                 {
2737                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2738                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2739                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2740                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2741                                 }
2742                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2743                                 self.lms_traveled_distance = 0;
2744                         }
2745                 }
2746
2747                 self.prevorigin = self.origin;
2748
2749                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2750                 {
2751                         if (!self.crouch)
2752                         {
2753                                 self.crouch = TRUE;
2754                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2755                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2756                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2757                         }
2758                 }
2759                 else
2760                 {
2761                         if (self.crouch)
2762                         {
2763                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2764                                 if (!trace_startsolid)
2765                                 {
2766                                         self.crouch = FALSE;
2767                                         self.view_ofs = PL_VIEW_OFS;
2768                                         setsize (self, PL_MIN, PL_MAX);
2769                                 }
2770                         }
2771                 }
2772
2773                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2774                 {
2775                         if(self.bloodloss_timer < time)
2776                         {
2777                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2778                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2779                         }
2780                 }
2781
2782                 FixPlayermodel();
2783
2784                 GrapplingHookFrame();
2785
2786                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2787                 //if(frametime)
2788                 {
2789                         self.items &~= self.items_added;
2790
2791                         W_WeaponFrame();
2792
2793                         self.items_added = 0;
2794                         if(self.items & IT_JETPACK)
2795                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2796                                         self.items_added |= IT_FUEL;
2797
2798                         self.items |= self.items_added;
2799                 }
2800
2801                 player_regen();
2802                 if(frametime)
2803                         player_anim();
2804
2805                 if (g_minstagib)
2806                         minstagib_ammocheck();
2807
2808                 ctf_setstatus();
2809                 nexball_setstatus();
2810
2811                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2812
2813                 //self.angles_y=self.v_angle_y + 90;   // temp
2814         } else if(gameover) {
2815                 if (intermission_running)
2816                         IntermissionThink ();   // otherwise a button could be missed between
2817                 return;
2818         } else if(self.classname == "observer") {
2819                 ObserverThink();
2820         } else if(self.classname == "spectator") {
2821                 SpectatorThink();
2822         }
2823
2824         if(!zoomstate_set)
2825                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2826
2827         float oldspectatee_status;
2828         oldspectatee_status = self.spectatee_status;
2829         if(self.classname == "spectator")
2830                 self.spectatee_status = num_for_edict(self.enemy);
2831         else if(self.classname == "observer")
2832                 self.spectatee_status = num_for_edict(self);
2833         else
2834                 self.spectatee_status = 0;
2835         if(self.spectatee_status != oldspectatee_status)
2836         {
2837                 ClientData_Touch(self);
2838                 if(g_race || g_cts)
2839                         race_InitSpectator();
2840         }
2841
2842         if(self.teamkill_soundtime)
2843         if(time > self.teamkill_soundtime)
2844         {
2845                 self.teamkill_soundtime = 0;
2846
2847                 entity oldpusher, oldself;
2848
2849                 oldself = self; self = self.teamkill_soundsource;
2850                 oldpusher = self.pusher; self.pusher = oldself;
2851
2852                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2853
2854                 self.pusher = oldpusher;
2855                 self = oldself;
2856         }
2857
2858         if(self.taunt_soundtime)
2859         if(time > self.taunt_soundtime)
2860         {
2861                 self.taunt_soundtime = 0;
2862                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2863         }
2864
2865         target_voicescript_next(self);
2866 }
2867
2868 float isInvisibleString(string s)
2869 {
2870         float i, n, c;
2871         s = strdecolorize(s);
2872         for((i = 0), (n = strlen(s)); i < n; ++i)
2873         {
2874                 c = str2chr(s, i);
2875                 switch(c)
2876                 {
2877                         case 0:
2878                         case 32: // space
2879                                 break;
2880                         case 192: // charmap space
2881                                 if (!cvar("utf8_enable"))
2882                                         break;
2883                                 return FALSE;
2884                         case 160: // space in unicode fonts
2885                         case 0xE000 + 192: // utf8 charmap space
2886                                 if (cvar("utf8_enable"))
2887                                         break;
2888                         default:
2889                                 return FALSE;
2890                 }
2891         }
2892         return TRUE;
2893 }
2894
2895 /*
2896 =============
2897 PlayerPostThink
2898
2899 Called every frame for each client after the physics are run
2900 =============
2901 */
2902 .float idlekick_lasttimeleft;
2903 .entity showheadshotbbox;
2904 void showheadshotbbox_think()
2905 {
2906         if(self.owner.showheadshotbbox != self)
2907         {
2908                 remove(self);
2909                 return;
2910         }
2911         self.nextthink = time;
2912         setorigin(self, self.owner.origin);
2913         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2914 }
2915 void PlayerPostThink (void)
2916 {
2917         // Savage: Check for nameless players
2918         if (isInvisibleString(self.netname)) {
2919                 self.netname = "Player";
2920                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2921         }
2922
2923         // send the clients accuracy stats to the client
2924         if(self.stat_count > 0)
2925         if(frametime)
2926         {
2927                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2928                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2929                 self.stat_count -= 1;
2930         }
2931
2932         if(sv_maxidle && frametime)
2933         {
2934                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2935                 float timeleft;
2936                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2937                 if(timeleft <= 0)
2938                 {
2939                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2940                         AnnounceTo(self, "terminated");
2941                         dropclient(self);
2942                         return;
2943                 }
2944                 else if(timeleft <= 10)
2945                 {
2946                         if(timeleft != self.idlekick_lasttimeleft)
2947                         {
2948                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2949                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2950                         }
2951                 }
2952                 else
2953                 {
2954                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2955                 }
2956                 self.idlekick_lasttimeleft = timeleft;
2957         }
2958
2959 #ifdef TETRIS
2960         if(self.impulse == 100)
2961                 ImpulseCommands();
2962         if (TetrisPostFrame())
2963                 return;
2964 #endif
2965
2966         CheatFrame();
2967
2968         if(self.classname == "player") {
2969                 CheckRules_Player();
2970                 UpdateChatBubble();
2971                 UpdateTeamBubble();
2972                 if (self.impulse)
2973                         ImpulseCommands();
2974                 if (intermission_running)
2975                         return;         // intermission or finale
2976                 GetPressedKeys();
2977         } else if (self.classname == "observer") {
2978                 //do nothing
2979         } else if (self.classname == "spectator") {
2980                 //do nothing
2981         }
2982
2983         /*
2984         float i;
2985         for(i = 0; i < 1000; ++i)
2986         {
2987                 vector end;
2988                 end = self.origin + '0 0 1024' + 512 * randomvec();
2989                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2990                 if(trace_fraction < 1)
2991                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2992                 {
2993                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2994                         break;
2995                 }
2996         }
2997         */
2998
2999         Arena_Warmup();
3000
3001         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3002
3003         if(self.waypointsprite_attachedforcarrier)
3004                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3005
3006         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3007         {
3008                 if(!self.showheadshotbbox)
3009                 {
3010                         self.showheadshotbbox = spawn();
3011                         self.showheadshotbbox.classname = "headshotbbox";
3012                         self.showheadshotbbox.owner = self;
3013                         self.showheadshotbbox.think = showheadshotbbox_think;
3014                         self.showheadshotbbox.nextthink = time;
3015                         self = self.showheadshotbbox;
3016                         self.think();
3017                         self = self.owner;
3018                 }
3019         }
3020         else
3021         {
3022                 if(self.showheadshotbbox)
3023                         remove(self.showheadshotbbox);
3024         }
3025
3026         playerdemo_write();
3027
3028         /*
3029         if(g_race)
3030                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3031         */
3032 }