qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.flagcarried)
 626                 DropFlag(self.flagcarried, world, world);
 627
 628         if(self.ballcarried && g_nexball)
 629                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 630
 631         WaypointSprite_PlayerDead();
 632
 633         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 634                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 635
 636         if(self.killcount != -666) {
 637                 if(g_lms) {
 638                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 639                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 640                         else
 641                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 642                 } else
 643                         bprint ("^4", self.netname, "^4 is spectating now\n");
 644
 645                 if(self.just_joined == FALSE) {
 646                         LogTeamchange(self.playerid, -1, 4);
 647                 } else
 648                         self.just_joined = FALSE;
 649         }
 650
 651         PlayerScore_Clear(self); // clear scores when needed
 652
 653         accuracy_resend(self);
 654
 655         self.spectatortime = time;
 656
 657         self.classname = "observer";
 658         self.iscreature = FALSE;
 659         self.health = -666;
 660         self.takedamage = DAMAGE_NO;
 661         self.solid = SOLID_NOT;
 662         self.movetype = MOVETYPE_NOCLIP;
 663         self.flags = FL_CLIENT | FL_NOTARGET;
 664         self.armorvalue = 666;
 665         self.effects = 0;
 666         self.armorvalue = autocvar_g_balance_armor_start;
 667         self.pauserotarmor_finished = 0;
 668         self.pauserothealth_finished = 0;
 669         self.pauseregen_finished = 0;
 670         self.damageforcescale = 0;
 671         self.death_time = 0;
 672         self.dead_frame = 0;
 673         self.alpha = 0;
 674         self.scale = 0;
 675         self.fade_time = 0;
 676         self.pain_frame = 0;
 677         self.pain_finished = 0;
 678         self.strength_finished = 0;
 679         self.invincible_finished = 0;
 680         self.pushltime = 0;
 681         self.think = SUB_Null;
 682         self.nextthink = 0;
 683         self.hook_time = 0;
 684         self.runes = 0;
 685         self.deadflag = DEAD_NO;
 686         self.angles = spot.angles;
 687         self.angles_z = 0;
 688         self.fixangle = TRUE;
 689         self.crouch = FALSE;
 690
 691         self.view_ofs = PL_VIEW_OFS;
 692         setorigin (self, spot.origin);
 693         setsize (self, '0 0 0', '0 0 0');
 694         self.prevorigin = self.origin;
 695         self.items = 0;
 696         self.weapons = 0;
 697         self.model = "";
 698         FixPlayermodel();
 699         self.model = "";
 700         self.modelindex = 0;
 701         self.weapon = 0;
 702         self.weaponmodel = "";
 703         self.weaponentity = world;
 704         self.exteriorweaponentity = world;
 705         self.killcount = -666;
 706         self.velocity = '0 0 0';
 707         self.avelocity = '0 0 0';
 708         self.punchangle = '0 0 0';
 709         self.punchvector = '0 0 0';
 710         self.oldvelocity = self.velocity;
 711         self.fire_endtime = -1;
 712
 713         if(sv_loddistance1)
 714                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 715
 716         if(g_arena)
 717         {
 718                 if(self.version_mismatch)
 719                 {
 720                         Spawnqueue_Unmark(self);
 721                         Spawnqueue_Remove(self);
 722                 }
 723                 else
 724                 {
 725                         Spawnqueue_Insert(self);
 726                 }
 727         }
 728         else if(g_lms)
 729         {
 730                 // Only if the player cannot play at all
 731                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 732                         self.frags = FRAGS_SPECTATOR;
 733                 else
 734                         self.frags = FRAGS_LMS_LOSER;
 735         }
 736         else
 737                 self.frags = FRAGS_SPECTATOR;
 738
 739     if(self.shownames)
 740         remove(self.shownames);
 741 }
 742
 743 void FixPlayermodel()
 744 {
 745         local string defaultmodel;
 746         local float defaultskin, chmdl, oldskin;
 747         local vector m1, m2;
 748
 749         defaultmodel = "";
 750
 751         if(autocvar_sv_defaultcharacter == 1) {
 752                 defaultskin = 0;
 753
 754                 if(teams_matter)
 755                 {
 756                         string s;
 757                         s = Team_ColorNameLowerCase(self.team);
 758                         if(s != "neutral")
 759                         {
 760                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 761                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 762                         }
 763                 }
 764
 765                 if(defaultmodel == "")
 766                 {
 767                         defaultmodel = autocvar_sv_defaultplayermodel;
 768                         defaultskin = autocvar_sv_defaultplayerskin;
 769                 }
 770         }
 771
 772         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 773         {
 774                 if(self.model != "")
 775                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 776                 self.model = ""; // force the != checks to return true
 777         }
 778
 779         if(defaultmodel != "")
 780         {
 781                 if (defaultmodel != self.model)
 782                 {
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, defaultmodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = defaultskin;
 792         } else {
 793                 if (self.playermodel != self.model || self.playermodel == "")
 794                 {
 795                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, self.playermodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = stof(self.playerskin);
 805         }
 806
 807         if(chmdl || oldskin != self.skinindex)
 808                 self.species = player_getspecies(); // model or skin has changed
 809
 810         if(!teams_matter)
 811                 if(strlen(autocvar_sv_defaultplayercolors))
 812                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 813                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 814 }
 815
 816 void PlayerTouchExplode(entity p1, entity p2)
 817 {
 818         vector org;
 819         org = (p1.origin + p2.origin) * 0.5;
 820         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 821
 822         te_explosion(org);
 823
 824         entity e;
 825         e = spawn();
 826         setorigin(e, org);
 827         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 828         remove(e);
 829 }
 830
 831 /*
 832 =============
 833 PutClientInServer
 834
 835 Called when a client spawns in the server
 836 =============
 837 */
 838 //void() ctf_playerchanged;
 839 void PutClientInServer (void)
 840 {
 841         if(clienttype(self) == CLIENTTYPE_BOT)
 842         {
 843                 self.classname = "player";
 844         }
 845         else if(clienttype(self) == CLIENTTYPE_REAL)
 846         {
 847                 msg_entity = self;
 848                 WriteByte(MSG_ONE, SVC_SETVIEW);
 849                 WriteEntity(MSG_ONE, self);
 850         }
 851
 852         // player is dead and becomes observer
 853         // FIXME fix LMS scoring for new system
 854         if(g_lms)
 855         {
 856                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 857                         self.classname = "observer";
 858         }
 859
 860         if(g_arena || (g_ca && !allowed_to_spawn))
 861         if(!self.spawned)
 862                 self.classname = "observer";
 863
 864         if(gameover)
 865                 self.classname = "observer";
 866
 867         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 868                 entity spot, oldself;
 869                 float j;
 870
 871                 accuracy_resend(self);
 872
 873                 if(self.team < 0)
 874                         JoinBestTeam(self, FALSE, TRUE);
 875
 876                 race_PreSpawn();
 877
 878                 spot = SelectSpawnPoint (FALSE);
 879                 if(!spot)
 880                 {
 881                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 882                         return; // spawn failed
 883                 }
 884
 885                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 886
 887                 self.classname = "player";
 888                 self.wasplayer = TRUE;
 889                 self.iscreature = TRUE;
 890                 self.movetype = MOVETYPE_WALK;
 891                 self.solid = SOLID_SLIDEBOX;
 892                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 893                 if(autocvar_g_playerclip_collisions)
 894                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 895                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 896                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 897                 self.frags = FRAGS_PLAYER;
 898                 if(independent_players)
 899                         MAKE_INDEPENDENT_PLAYER(self);
 900                 self.flags = FL_CLIENT;
 901                 self.takedamage = DAMAGE_AIM;
 902                 if(g_minstagib)
 903                         self.effects = EF_FULLBRIGHT;
 904                 else
 905                         self.effects = 0;
 906                 self.air_finished = time + 12;
 907                 self.dmg = 2;
 908                 if(autocvar_g_balance_nex_charge)
 909                 {
 910                         if(autocvar_g_balance_nex_secondary_chargepool)
 911                                 self.nex_chargepool_ammo = 1;
 912                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 913                 }
 914
 915                 if(inWarmupStage)
 916                 {
 917                         self.ammo_shells = warmup_start_ammo_shells;
 918                         self.ammo_nails = warmup_start_ammo_nails;
 919                         self.ammo_rockets = warmup_start_ammo_rockets;
 920                         self.ammo_cells = warmup_start_ammo_cells;
 921                         self.ammo_fuel = warmup_start_ammo_fuel;
 922                         self.health = warmup_start_health;
 923                         self.armorvalue = warmup_start_armorvalue;
 924                         self.weapons = warmup_start_weapons;
 925                 }
 926                 else
 927                 {
 928                         self.ammo_shells = start_ammo_shells;
 929                         self.ammo_nails = start_ammo_nails;
 930                         self.ammo_rockets = start_ammo_rockets;
 931                         self.ammo_cells = start_ammo_cells;
 932                         self.ammo_fuel = start_ammo_fuel;
 933                         self.health = start_health;
 934                         self.armorvalue = start_armorvalue;
 935                         self.weapons = start_weapons;
 936                 }
 937
 938                 if(g_weaponarena_random)
 939                 {
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons &~= WEPBIT_LASER;
 942                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons |= WEPBIT_LASER;
 945                 }
 946
 947                 self.items = start_items;
 948                 self.jump_interval = time;
 949
 950                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 951                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 952                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 953                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 954                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 955                 //extend the pause of rotting if client was reset at the beginning of the countdown
 956                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 957                         self.spawnshieldtime += game_starttime - time;
 958                         self.pauserotarmor_finished += game_starttime - time;
 959                         self.pauserothealth_finished += game_starttime - time;
 960                         self.pauseregen_finished += game_starttime - time;
 961                 }
 962                 self.damageforcescale = 2;
 963                 self.death_time = 0;
 964                 self.dead_frame = 0;
 965                 self.alpha = 0;
 966                 self.scale = 0;
 967                 self.fade_time = 0;
 968                 self.pain_frame = 0;
 969                 self.pain_finished = 0;
 970                 self.strength_finished = 0;
 971                 self.invincible_finished = 0;
 972                 self.pushltime = 0;
 973                 // players have no think function
 974                 self.think = SUB_Null;
 975                 self.nextthink = 0;
 976                 self.hook_time = 0;
 977                 self.dmg_team = 0;
 978                 self.ballistics_density = autocvar_g_ballistics_density_player;
 979
 980                 self.metertime = 0;
 981
 982                 self.runes = 0;
 983
 984                 self.deadflag = DEAD_NO;
 985
 986                 self.angles = spot.angles;
 987
 988                 self.angles_z = 0; // never spawn tilted even if the spot says to
 989                 self.fixangle = TRUE; // turn this way immediately
 990                 self.velocity = '0 0 0';
 991                 self.avelocity = '0 0 0';
 992                 self.punchangle = '0 0 0';
 993                 self.punchvector = '0 0 0';
 994                 self.oldvelocity = self.velocity;
 995                 self.fire_endtime = -1;
 996
 997                 msg_entity = self;
 998                 WRITESPECTATABLE_MSG_ONE({
 999                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1000                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1001                 });
1002
1003                 if(sv_loddistance1)
1004                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1005
1006                 self.model = "";
1007                 FixPlayermodel();
1008
1009                 self.crouch = FALSE;
1010                 self.view_ofs = PL_VIEW_OFS;
1011                 setsize (self, PL_MIN, PL_MAX);
1012                 self.spawnorigin = spot.origin;
1013                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1014                 // don't reset back to last position, even if new position is stuck in solid
1015                 self.oldorigin = self.origin;
1016                 self.prevorigin = self.origin;
1017                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1018
1019                 if(g_arena)
1020                 {
1021                         Spawnqueue_Remove(self);
1022                         Spawnqueue_Mark(self);
1023                 }
1024
1025                 else if(g_ca)
1026                         self.caplayer = 1;
1027
1028                 self.event_damage = PlayerDamage;
1029
1030                 self.bot_attack = TRUE;
1031
1032                 self.statdraintime = time + 5;
1033                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1034
1035                 if(self.killcount == -666) {
1036                         PlayerScore_Clear(self);
1037                         self.killcount = 0;
1038                 }
1039
1040                 self.cnt = WEP_LASER;
1041
1042                 CL_SpawnWeaponentity();
1043                 self.alpha = default_player_alpha;
1044                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1045                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1046
1047                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1048                 self.lms_traveled_distance = 0;
1049                 self.speedrunning = FALSE;
1050
1051                 race_PostSpawn(spot);
1052
1053                 if(autocvar_spawn_debug)
1054                 {
1055                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1056                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1057                 }
1058
1059                 //stuffcmd(self, "chase_active 0");
1060                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1061
1062                 if (autocvar_g_spawnsound)
1063                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1064
1065                 if(g_assault) {
1066                         if(self.team == assault_attacker_team)
1067                                 centerprint(self, "You are attacking!");
1068                         else
1069                                 centerprint(self, "You are defending!");
1070                 }
1071
1072                 target_voicescript_clear(self);
1073
1074                 // reset fields the weapons may use
1075                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1076                 {
1077                         weapon_action(j, WR_RESETPLAYER);
1078
1079                         // all weapons must be fully loaded when we spawn
1080                         entity e;
1081                         e = get_weaponinfo(j);
1082                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1083                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1084                 }
1085                 self.weapon_forbidchange = FALSE;
1086
1087                 oldself = self;
1088                 self = spot;
1089                         activator = oldself;
1090                                 SUB_UseTargets();
1091                         activator = world;
1092                 self = oldself;
1093
1094                 MUTATOR_CALLHOOK(PlayerSpawn);
1095
1096                 self.switchweapon = w_getbestweapon(self);
1097                 self.cnt = self.switchweapon;
1098                 self.weapon = 0;
1099
1100                 if(!self.alivetime)
1101                         self.alivetime = time;
1102         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1103                 PutObserverInServer ();
1104         }
1105
1106     if(!self.shownames)
1107     {
1108         self.shownames = spawn();
1109         self.shownames.owner = self;
1110         self.shownames.think = shownames_think;
1111         self.shownames.nextthink = time;
1112         Net_LinkEntity(self.shownames, FALSE, 0, SendEntity_ShowNames);
1113     }
1114
1115         //if(g_ctf)
1116         //      ctf_playerchanged();
1117 }
1118
1119 .float ebouncefactor, ebouncestop; // electro's values
1120 // TODO do we need all these fields, or should we stop autodetecting runtime
1121 // changes and just have a console command to update this?
1122 float ClientInit_SendEntity(entity to, float sf)
1123 {
1124         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1125         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1137         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1138         if(sv_foginterval && world.fog != "")
1139                 WriteString(MSG_ENTITY, world.fog);
1140         else
1141                 WriteString(MSG_ENTITY, "");
1142         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1143         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1144         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1145         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1146         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1147         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1148         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1149         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1150         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1151         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1152         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1153         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1154         return TRUE;
1155 }
1156
1157 void ClientInit_CheckUpdate()
1158 {
1159         self.nextthink = time;
1160         if(self.count != autocvar_g_balance_armor_blockpercent)
1161         {
1162                 self.count = autocvar_g_balance_armor_blockpercent;
1163                 self.SendFlags |= 1;
1164         }
1165         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1166         {
1167                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1168                 self.SendFlags |= 1;
1169         }
1170         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1171         {
1172                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1173                 self.SendFlags |= 1;
1174         }
1175         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1176         {
1177                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1178                 self.SendFlags |= 1;
1179         }
1180         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1181         {
1182                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1183                 self.SendFlags |= 1;
1184         }
1185         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1186         {
1187                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1188                 self.SendFlags |= 1;
1189         }
1190 }
1191
1192 void ClientInit_Spawn()
1193 {
1194         entity o;
1195         entity e;
1196         e = spawn();
1197         e.classname = "clientinit";
1198         e.think = ClientInit_CheckUpdate;
1199         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1200
1201         o = self;
1202         self = e;
1203         ClientInit_CheckUpdate();
1204         self = o;
1205 }
1206
1207 /*
1208 =============
1209 SetNewParms
1210 =============
1211 */
1212 void SetNewParms (void)
1213 {
1214         // initialize parms for a new player
1215         parm1 = -(86400 * 366);
1216 }
1217
1218 /*
1219 =============
1220 SetChangeParms
1221 =============
1222 */
1223 void SetChangeParms (void)
1224 {
1225         // save parms for level change
1226         parm1 = self.parm_idlesince - time;
1227 }
1228
1229 /*
1230 =============
1231 DecodeLevelParms
1232 =============
1233 */
1234 void DecodeLevelParms (void)
1235 {
1236         // load parms
1237         self.parm_idlesince = parm1;
1238         if(self.parm_idlesince == -(86400 * 366))
1239                 self.parm_idlesince = time;
1240
1241         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1242         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1243 }
1244
1245 /*
1246 =============
1247 ClientKill
1248
1249 Called when a client types 'kill' in the console
1250 =============
1251 */
1252
1253 .float clientkill_nexttime;
1254 void ClientKill_Now_TeamChange()
1255 {
1256         if(self.killindicator_teamchange == -1)
1257         {
1258                 self.team = -1;
1259                 JoinBestTeam( self, FALSE, FALSE );
1260         }
1261         else if(self.killindicator_teamchange == -2)
1262         {
1263                 if(g_ca)
1264                         self.caplayer = 0;
1265                 if(blockSpectators)
1266                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1267                 PutObserverInServer();
1268         }
1269         else
1270                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1271 }
1272
1273 void ClientKill_Now()
1274 {
1275         remove(self.killindicator);
1276         self.killindicator = world;
1277
1278         if(self.killindicator_teamchange)
1279                 ClientKill_Now_TeamChange();
1280
1281         // in any case:
1282         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1283
1284         // now I am sure the player IS dead
1285 }
1286 void KillIndicator_Think()
1287 {
1288         if (!self.owner.modelindex)
1289         {
1290                 self.owner.killindicator = world;
1291                 remove(self);
1292                 return;
1293         }
1294
1295         if(self.cnt <= 0)
1296         {
1297                 self = self.owner;
1298                 ClientKill_Now(); // no oldself needed
1299                 return;
1300         }
1301     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1302     {
1303         self.nextthink = time + 1;
1304         self.cnt -= 1;
1305     }
1306         else
1307         {
1308                 if(self.cnt <= 10)
1309                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1310                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1311                 {
1312                         if(self.cnt <= 10)
1313                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1314                         if(self.owner.killindicator_teamchange)
1315                         {
1316                                 if(self.owner.killindicator_teamchange == -1)
1317                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1318                                 else if(self.owner.killindicator_teamchange == -2)
1319                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1320                                 else
1321                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1322                         }
1323                         else
1324                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1325                 }
1326                 self.nextthink = time + 1;
1327                 self.cnt -= 1;
1328         }
1329 }
1330
1331 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1332 {
1333         float killtime;
1334         entity e;
1335         killtime = autocvar_g_balance_kill_delay;
1336
1337         if(g_race_qualifying || g_cts)
1338                 killtime = 0;
1339
1340     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1341     {
1342                 remove(self.killindicator);
1343                 self.killindicator = world;
1344
1345         ClientKill_Now(); // allow instant kill in this case
1346         return;
1347     }
1348
1349         self.killindicator_teamchange = targetteam;
1350
1351     if(!self.killindicator)
1352         {
1353                 if(self.modelindex && self.deadflag == DEAD_NO)
1354                 {
1355                         killtime = max(killtime, self.clientkill_nexttime - time);
1356                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1357                 }
1358
1359                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1360                 {
1361                         ClientKill_Now();
1362                 }
1363                 else
1364                 {
1365                         self.killindicator = spawn();
1366                         self.killindicator.owner = self;
1367                         self.killindicator.scale = 0.5;
1368                         setattachment(self.killindicator, self, "");
1369                         setorigin(self.killindicator, '0 0 52');
1370                         self.killindicator.think = KillIndicator_Think;
1371                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1372                         self.killindicator.cnt = ceil(killtime);
1373                         self.killindicator.count = bound(0, ceil(killtime), 10);
1374                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1375
1376                         for(e = world; (e = find(e, classname, "body")) != world; )
1377                         {
1378                                 if(e.enemy != self)
1379                                         continue;
1380                                 e.killindicator = spawn();
1381                                 e.killindicator.owner = e;
1382                                 e.killindicator.scale = 0.5;
1383                                 setattachment(e.killindicator, e, "");
1384                                 setorigin(e.killindicator, '0 0 52');
1385                                 e.killindicator.think = KillIndicator_Think;
1386                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1387                                 e.killindicator.cnt = ceil(killtime);
1388                         }
1389                         self.lip = 0;
1390                 }
1391         }
1392         if(self.killindicator)
1393         {
1394                 if(targetteam == 0) // just die
1395                         self.killindicator.colormod = '0 0 0';
1396                 else if(targetteam == -1) // auto
1397                         self.killindicator.colormod = '0 1 0';
1398                 else if(targetteam == -2) // spectate
1399                         self.killindicator.colormod = '0.5 0.5 0.5';
1400                 else
1401                         self.killindicator.colormod = TeamColor(targetteam);
1402         }
1403 }
1404
1405 void ClientKill (void)
1406 {
1407         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1408         {
1409                 // do nothing
1410         }
1411     else if(self.freezetag_frozen)
1412     {
1413         // do nothing
1414     }
1415         else
1416                 ClientKill_TeamChange(0);
1417 }
1418
1419 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1420 {
1421     e.killindicator = spawn();
1422     e.killindicator.owner = e;
1423     e.killindicator.think = KillIndicator_Think;
1424     e.killindicator.nextthink = time + (e.lip) * 0.05;
1425     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1426     e.killindicator.health = 1; // this is used to indicate that it should be silent
1427     e.lip = 0;
1428 }
1429
1430 void DoTeamChange(float destteam)
1431 {
1432         float t, c0;
1433         if(!teams_matter)
1434         {
1435                 if(destteam >= 0)
1436                         SetPlayerColors(self, destteam);
1437                 return;
1438         }
1439         if(self.classname == "player")
1440         if(destteam == -1)
1441         {
1442                 CheckAllowedTeams(self);
1443                 t = FindSmallestTeam(self, TRUE);
1444                 switch(self.team)
1445                 {
1446                         case COLOR_TEAM1: c0 = c1; break;
1447                         case COLOR_TEAM2: c0 = c2; break;
1448                         case COLOR_TEAM3: c0 = c3; break;
1449                         case COLOR_TEAM4: c0 = c4; break;
1450                         default:          c0 = 999;
1451                 }
1452                 switch(t)
1453                 {
1454                         case 1:
1455                                 if(c0 > c1)
1456                                         destteam = COLOR_TEAM1;
1457                                 break;
1458                         case 2:
1459                                 if(c0 > c2)
1460                                         destteam = COLOR_TEAM2;
1461                                 break;
1462                         case 3:
1463                                 if(c0 > c3)
1464                                         destteam = COLOR_TEAM3;
1465                                 break;
1466                         case 4:
1467                                 if(c0 > c4)
1468                                         destteam = COLOR_TEAM4;
1469                                 break;
1470                 }
1471                 if(destteam == -1)
1472                         return;
1473         }
1474         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1475                 return;
1476         ClientKill_TeamChange(destteam);
1477 }
1478
1479 void FixClientCvars(entity e)
1480 {
1481         // send prediction settings to the client
1482         stuffcmd(e, "\nin_bindmap 0 0\n");
1483         if(g_race || g_cts)
1484                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1485         if(autocvar_g_antilag == 3) // client side hitscan
1486                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1487         if(sv_gentle)
1488                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1489         /*
1490          * we no longer need to stuff this. Remove this comment block if you feel
1491          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1492         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1493         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1494         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1495         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1496         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1497         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1498         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1499         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1500         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1501         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1502         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1503         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1504         stuffcmd(e, "cl_movement_edgefriction 1\n");
1505          */
1506 }
1507
1508 float PlayerInIDList(entity p, string idlist)
1509 {
1510         float n, i;
1511         string s;
1512
1513         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1514         if not(p.crypto_idfp)
1515                 return 0;
1516
1517         // this function allows abbreviated player IDs too!
1518         n = tokenize_console(idlist);
1519         for(i = 0; i < n; ++i)
1520         {
1521                 s = argv(i);
1522                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1523                         return 1;
1524         }
1525
1526         return 0;
1527 }
1528
1529 /*
1530 =============
1531 ClientConnect
1532
1533 Called when a client connects to the server
1534 =============
1535 */
1536 //void ctf_clientconnect();
1537 string ColoredTeamName(float t);
1538 void DecodeLevelParms (void);
1539 //void dom_player_join_team(entity pl);
1540 void set_dom_state(entity e);
1541 void ClientConnect (void)
1542 {
1543         float t;
1544
1545         if(self.flags & FL_CLIENT)
1546         {
1547                 print("Warning: ClientConnect, but already connected!\n");
1548                 return;
1549         }
1550
1551         if(Ban_MaybeEnforceBan(self))
1552                 return;
1553
1554         DecodeLevelParms();
1555
1556 #ifdef WATERMARK
1557         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1558 #endif
1559
1560         self.classname = "player_joining";
1561
1562         self.flags = FL_CLIENT;
1563         self.version_nagtime = time + 10 + random() * 10;
1564
1565         if(player_count<0)
1566         {
1567                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1568                 player_count = 0;
1569         }
1570
1571         PlayerScore_Attach(self);
1572         ClientData_Attach();
1573         accuracy_init(self);
1574
1575         bot_clientconnect();
1576
1577         playerdemo_init();
1578
1579         anticheat_init();
1580
1581         race_PreSpawnObserver();
1582
1583         //if(g_domination)
1584         //      dom_player_join_team(self);
1585
1586         // identify the right forced team
1587         if(autocvar_g_campaign)
1588         {
1589                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1590                 {
1591                         switch(autocvar_g_campaign_forceteam)
1592                         {
1593                                 case 1: self.team_forced = COLOR_TEAM1; break;
1594                                 case 2: self.team_forced = COLOR_TEAM2; break;
1595                                 case 3: self.team_forced = COLOR_TEAM3; break;
1596                                 case 4: self.team_forced = COLOR_TEAM4; break;
1597                                 default: self.team_forced = 0;
1598                         }
1599                 }
1600         }
1601         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1602                 self.team_forced = COLOR_TEAM1;
1603         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1604                 self.team_forced = COLOR_TEAM2;
1605         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1606                 self.team_forced = COLOR_TEAM3;
1607         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1608                 self.team_forced = COLOR_TEAM4;
1609         else if(autocvar_g_forced_team_otherwise == "red")
1610                 self.team_forced = COLOR_TEAM1;
1611         else if(autocvar_g_forced_team_otherwise == "blue")
1612                 self.team_forced = COLOR_TEAM2;
1613         else if(autocvar_g_forced_team_otherwise == "yellow")
1614                 self.team_forced = COLOR_TEAM3;
1615         else if(autocvar_g_forced_team_otherwise == "pink")
1616                 self.team_forced = COLOR_TEAM4;
1617         else if(autocvar_g_forced_team_otherwise == "spectate")
1618                 self.team_forced = -1;
1619         else if(autocvar_g_forced_team_otherwise == "spectator")
1620                 self.team_forced = -1;
1621         else
1622                 self.team_forced = 0;
1623
1624         if(!teams_matter)
1625                 if(self.team_forced > 0)
1626                         self.team_forced = 0;
1627
1628         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1629
1630         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1631                 self.classname = "observer";
1632         } else {
1633                 if(teams_matter)
1634                 {
1635                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1636                         {
1637                                 self.classname = "player";
1638                                 campaign_bots_may_start = 1;
1639                         }
1640                         else
1641                         {
1642                                 self.classname = "observer"; // do it anyway
1643                         }
1644                 }
1645                 else
1646                 {
1647                         self.classname = "player";
1648                         campaign_bots_may_start = 1;
1649                 }
1650         }
1651
1652         self.playerid = (playerid_last = playerid_last + 1);
1653
1654         if(autocvar_sv_eventlog)
1655                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1656
1657         LogTeamchange(self.playerid, self.team, 1);
1658
1659         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1660
1661         self.netname_previous = strzone(self.netname);
1662
1663         bprint("^4", self.netname, "^4 connected");
1664
1665         if(self.classname != "observer" && (g_domination || g_ctf))
1666                 bprint(" and joined the ", ColoredTeamName(self.team));
1667
1668         bprint("\n");
1669
1670         self.welcomemessage_time = 0;
1671
1672         stuffcmd(self, strcat(clientstuff, "\n"));
1673         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1674         stuffcmd(self, "cl_particles_reloadeffects\n");
1675
1676         FixClientCvars(self);
1677
1678         // spawnfunc_waypoint sprites
1679         WaypointSprite_InitClient(self);
1680
1681         // Wazat's grappling hook
1682         SetGrappleHookBindings();
1683
1684         // get autoswitch state from player when he toggles it
1685         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1686
1687         // get version info from player
1688         stuffcmd(self, "cmd clientversion $gameversion\n");
1689
1690         // get other cvars from player
1691         GetCvars(0);
1692
1693         // notify about available teams
1694         if(teams_matter)
1695         {
1696                 CheckAllowedTeams(self);
1697                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1698                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1699         }
1700         else
1701                 stuffcmd(self, "set _teams_available 0\n");
1702
1703         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1704
1705         if(g_arena || g_ca)
1706         {
1707                 self.classname = "observer";
1708                 if(g_arena)
1709                         Spawnqueue_Insert(self);
1710         }
1711         /*else if(g_ctf)
1712         {
1713                 ctf_clientconnect();
1714         }*/
1715
1716         if(teams_matter || radar_showennemies)
1717                 attach_entcs();
1718
1719         bot_relinkplayerlist();
1720
1721         self.spectatortime = time;
1722         if(blockSpectators)
1723         {
1724                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1725         }
1726
1727         self.jointime = time;
1728         self.allowedTimeouts = autocvar_sv_timeout_number;
1729
1730         if(clienttype(self) == CLIENTTYPE_REAL)
1731         {
1732                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1733                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1734         }
1735
1736         if(g_lms)
1737         {
1738                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1739                 {
1740                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1741                         self.frags = FRAGS_SPECTATOR;
1742                 }
1743         }
1744
1745         if(!sv_foginterval && world.fog != "")
1746                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1747
1748         SoundEntity_Attach(self);
1749
1750         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1751         {
1752                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1753                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1754         }
1755         else
1756                 self.hitplotfh = -1;
1757
1758         if(g_race || g_cts) {
1759                 string rr;
1760                 if(g_cts)
1761                         rr = CTS_RECORD;
1762                 else
1763                         rr = RACE_RECORD;
1764                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1765
1766                 msg_entity = self;
1767                 race_send_recordtime(MSG_ONE);
1768                 race_send_speedaward(MSG_ONE);
1769
1770                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1771                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1772                 race_send_speedaward_alltimebest(MSG_ONE);
1773
1774                 float i;
1775                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1776                         race_SendRankings(i, 0, 0, MSG_ONE);
1777                 }
1778         }
1779         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1780                 send_CSQC_teamnagger();
1781
1782         if (g_domination)
1783                 set_dom_state(self);
1784
1785         CheatInitClient();
1786
1787         PlayerStats_AddPlayer(self);
1788 }
1789
1790 /*
1791 =============
1792 ClientDisconnect
1793
1794 Called when a client disconnects from the server
1795 =============
1796 */
1797 .entity chatbubbleentity;
1798 void ReadyCount();
1799 void ClientDisconnect (void)
1800 {
1801         if not(self.flags & FL_CLIENT)
1802         {
1803                 print("Warning: ClientDisconnect without ClientConnect\n");
1804                 return;
1805         }
1806
1807         PlayerStats_AddGlobalInfo(self);
1808
1809         CheatShutdownClient();
1810
1811         if(self.hitplotfh >= 0)
1812         {
1813                 fclose(self.hitplotfh);
1814                 self.hitplotfh = -1;
1815         }
1816
1817         anticheat_report();
1818         anticheat_shutdown();
1819
1820         playerdemo_shutdown();
1821
1822         bot_clientdisconnect();
1823
1824         if(self.entcs)
1825                 detach_entcs();
1826
1827         if(autocvar_sv_eventlog)
1828                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1829         bprint ("^4",self.netname);
1830         bprint ("^4 disconnected\n");
1831
1832         SoundEntity_Detach(self);
1833
1834         DropAllRunes(self);
1835         MUTATOR_CALLHOOK(ClientDisconnect);
1836
1837         Portal_ClearAll(self);
1838
1839         if(self.flagcarried)
1840                 DropFlag(self.flagcarried, world, world);
1841         if(self.ballcarried && g_nexball)
1842                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1843
1844         // Here, everything has been done that requires this player to be a client.
1845
1846         self.flags &~= FL_CLIENT;
1847
1848         if (self.chatbubbleentity)
1849                 remove (self.chatbubbleentity);
1850
1851         if (self.killindicator)
1852                 remove (self.killindicator);
1853
1854         WaypointSprite_PlayerGone();
1855
1856         bot_relinkplayerlist();
1857
1858         if(g_arena)
1859         {
1860                 Spawnqueue_Unmark(self);
1861                 Spawnqueue_Remove(self);
1862         }
1863
1864         accuracy_free(self);
1865         ClientData_Detach();
1866         PlayerScore_Detach(self);
1867
1868         if(self.netname_previous)
1869                 strunzone(self.netname_previous);
1870         if(self.clientstatus)
1871                 strunzone(self.clientstatus);
1872         if(self.weaponorder_byimpulse)
1873                 strunzone(self.weaponorder_byimpulse);
1874
1875         ClearPlayerSounds();
1876
1877         if(self.personal)
1878                 remove(self.personal);
1879
1880         self.playerid = 0;
1881         ReadyCount();
1882
1883     remove(self.shownames);
1884
1885         // free cvars
1886         GetCvars(-1);
1887 }
1888
1889 .float BUTTON_CHAT;
1890 void ChatBubbleThink()
1891 {
1892         self.nextthink = time;
1893         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1894         {
1895                 if(self.owner) // but why can that ever be world?
1896                         self.owner.chatbubbleentity = world;
1897                 remove(self);
1898                 return;
1899         }
1900         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1901 #ifdef TETRIS
1902                 || self.owner.tetris_on
1903 #endif
1904         )
1905                 self.model = self.mdl;
1906         else
1907                 self.model = "";
1908 };
1909
1910 void UpdateChatBubble()
1911 {
1912         if (!self.modelindex)
1913                 return;
1914         // spawn a chatbubble entity if needed
1915         if (!self.chatbubbleentity)
1916         {
1917                 self.chatbubbleentity = spawn();
1918                 self.chatbubbleentity.owner = self;
1919                 self.chatbubbleentity.exteriormodeltoclient = self;
1920                 self.chatbubbleentity.think = ChatBubbleThink;
1921                 self.chatbubbleentity.nextthink = time;
1922                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1923                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1924                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1925                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1926                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1927                 self.chatbubbleentity.model = "";
1928                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1929         }
1930 }
1931
1932
1933 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1934 // added to the model skins
1935 /*void UpdateColorModHack()
1936 {
1937         local float c;
1938         c = self.clientcolors & 15;
1939         // LordHavoc: only bothering to support white, green, red, yellow, blue
1940              if (!teams_matter) self.colormod = '0 0 0';
1941         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1942         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1943         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1944         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1945         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1946         else self.colormod = '1 1 1';
1947 };*/
1948
1949 .float oldcolormap;
1950 void respawn(void)
1951 {
1952         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1953         {
1954                 self.solid = SOLID_NOT;
1955                 self.takedamage = DAMAGE_NO;
1956                 self.movetype = MOVETYPE_FLY;
1957                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1958                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1959                 self.effects |= EF_ADDITIVE;
1960                 self.oldcolormap = self.colormap;
1961                 self.colormap = 512;
1962                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1963                 if(autocvar_g_respawn_ghosts_maxtime)
1964                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1965         }
1966
1967         CopyBody(1);
1968         self.effects |= EF_NODRAW; // prevent another CopyBody
1969         if(self.oldcolormap)
1970         {
1971                 self.colormap = self.oldcolormap;
1972                 self.oldcolormap = 0;
1973         }
1974         PutClientInServer();
1975 }
1976
1977 void play_countdown(float finished, string samp)
1978 {
1979         if(clienttype(self) == CLIENTTYPE_REAL)
1980                 if(floor(finished - time - frametime) != floor(finished - time))
1981                         if(finished - time < 6)
1982                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1983 }
1984
1985 /**
1986  * When sv_timeout is used this function returs strings like
1987  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1988  * Called by centerprint functions
1989  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1990  */
1991 string getTimeoutText(float addOneSecond) {
1992         if (!autocvar_sv_timeout || !timeoutStatus)
1993                 return "";
1994
1995         local string retStr;
1996         if (timeoutStatus == 1) {
1997                 if (addOneSecond == 1) {
1998                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1999                 }
2000                 else {
2001                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2002                 }
2003                 return retStr;
2004         }
2005         else if (timeoutStatus == 2) {
2006                 if (addOneSecond) {
2007                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2008                         //don't show messages like "Timeout ends in 0 seconds"...
2009                         if ((remainingTimeoutTime + 1) > 0)
2010                                 return retStr;
2011                         else
2012                                 return "";
2013                 }
2014                 else {
2015                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2016                         //don't show messages like "Timeout ends in 0 seconds"...
2017                         if (remainingTimeoutTime > 0)
2018                                 return retStr;
2019                         else
2020                                 return "";
2021                 }
2022         }
2023         else return "";
2024 }
2025
2026 void player_powerups (void)
2027 {
2028         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2029         olditems = self.items;
2030
2031         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2032         {
2033                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2034                 self.modelflags |= MF_ROCKET;
2035         }
2036         else
2037         {
2038                 SoundEntity_StopSound(self, CHAN_PLAYER);
2039                 self.modelflags &~= MF_ROCKET;
2040         }
2041
2042         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2043
2044         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2045                 return;
2046
2047         Fire_ApplyDamage(self);
2048         Fire_ApplyEffect(self);
2049
2050         if (g_minstagib)
2051         {
2052                 self.effects |= EF_FULLBRIGHT;
2053
2054                 if (self.items & IT_STRENGTH)
2055                 {
2056                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2057                         if (time > self.strength_finished)
2058                         {
2059                                 self.alpha = default_player_alpha;
2060                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2061                                 self.items &~= IT_STRENGTH;
2062                                 sprint(self, "^3Invisibility has worn off\n");
2063                         }
2064                 }
2065                 else
2066                 {
2067                         if (time < self.strength_finished)
2068                         {
2069                                 self.alpha = g_minstagib_invis_alpha;
2070                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2071                                 self.items |= IT_STRENGTH;
2072                                 sprint(self, "^3You are invisible\n");
2073                         }
2074                 }
2075
2076                 if (self.items & IT_INVINCIBLE)
2077                 {
2078                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2079                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2080                         {
2081                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2082                                 sprint(self, "^3Speed has worn off\n");
2083                         }
2084                 }
2085                 else
2086                 {
2087                         if (time < self.invincible_finished)
2088                         {
2089                                 self.items = self.items | IT_INVINCIBLE;
2090                                 sprint(self, "^3You are on speed\n");
2091                         }
2092                 }
2093         }
2094         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2095         {
2096                 if (self.items & IT_STRENGTH)
2097                 {
2098                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2099                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2100                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2101                         {
2102                                 self.items = self.items - (self.items & IT_STRENGTH);
2103                                 sprint(self, "^3Strength has worn off\n");
2104                         }
2105                 }
2106                 else
2107                 {
2108                         if (time < self.strength_finished)
2109                         {
2110                                 self.items = self.items | IT_STRENGTH;
2111                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2112                         }
2113                 }
2114                 if (self.items & IT_INVINCIBLE)
2115                 {
2116                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2117                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2118                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2119                         {
2120                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2121                                 sprint(self, "^3Shield has worn off\n");
2122                         }
2123                 }
2124                 else
2125                 {
2126                         if (time < self.invincible_finished)
2127                         {
2128                                 self.items = self.items | IT_INVINCIBLE;
2129                                 sprint(self, "^3Shield surrounds you\n");
2130                         }
2131                 }
2132
2133                 if(autocvar_g_nodepthtestplayers)
2134                         self.effects = self.effects | EF_NODEPTHTEST;
2135
2136                 if(autocvar_g_fullbrightplayers)
2137                         self.effects = self.effects | EF_FULLBRIGHT;
2138
2139                 // midair gamemode: damage only while in the air
2140                 // if in midair mode, being on ground grants temporary invulnerability
2141                 // (this is so that multishot weapon don't clear the ground flag on the
2142                 // first damage in the frame, leaving the player vulnerable to the
2143                 // remaining hits in the same frame)
2144                 if (self.flags & FL_ONGROUND)
2145                 if (g_midair)
2146                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2147
2148                 if (time >= game_starttime)
2149                 if (time < self.spawnshieldtime)
2150                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2151         }
2152
2153         MUTATOR_CALLHOOK(PlayerPowerups);
2154 }
2155
2156 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2157 {
2158         if(current > stable)
2159                 return current;
2160         else if(current > stable - 0.25) // when close enough, "snap"
2161                 return stable;
2162         else
2163                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2164 }
2165
2166 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2167 {
2168         if(current < stable)
2169                 return current;
2170         else if(current < stable + 0.25) // when close enough, "snap"
2171                 return stable;
2172         else
2173                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2174 }
2175
2176 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2177 {
2178         if(current > rotstable)
2179         {
2180                 if(rotframetime > 0)
2181                 {
2182                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2183                         current = max(rotstable, current - rotlinear * rotframetime);
2184                 }
2185         }
2186         else if(current < regenstable)
2187         {
2188                 if(regenframetime > 0)
2189                 {
2190                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2191                         current = min(regenstable, current + regenlinear * regenframetime);
2192                 }
2193         }
2194
2195         if(current > limit)
2196                 current = limit;
2197
2198         return current;
2199 }
2200
2201 void player_regen (void)
2202 {
2203         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2204         maxh = autocvar_g_balance_health_rotstable;
2205         maxa = autocvar_g_balance_armor_rotstable;
2206         maxf = autocvar_g_balance_fuel_rotstable;
2207         minh = autocvar_g_balance_health_regenstable;
2208         mina = autocvar_g_balance_armor_regenstable;
2209         minf = autocvar_g_balance_fuel_regenstable;
2210         limith = autocvar_g_balance_health_limit;
2211         limita = autocvar_g_balance_armor_limit;
2212         limitf = autocvar_g_balance_fuel_limit;
2213
2214         max_mod = regen_mod = rot_mod = limit_mod = 1;
2215
2216         if (self.runes & RUNE_REGEN)
2217         {
2218                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2219                 {
2220                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2221                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2222                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2223                 }
2224                 else
2225                 {
2226                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2227                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2228                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2229                 }
2230         }
2231         else if (self.runes & CURSE_VENOM)
2232         {
2233                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2234                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2235                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2236                 else
2237                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2238                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2239                 //if (!self.runes & RUNE_REGEN)
2240                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2241         }
2242         maxh = maxh * max_mod;
2243         //maxa = maxa * max_mod;
2244         //maxf = maxf * max_mod;
2245         minh = minh * max_mod;
2246         //mina = mina * max_mod;
2247         //minf = minf * max_mod;
2248         limith = limith * limit_mod;
2249         limita = limita * limit_mod;
2250         //limitf = limitf * limit_mod;
2251
2252         if(g_lms && g_ca)
2253                 rot_mod = 0;
2254
2255         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2256         {
2257                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2258                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2259
2260                 // if player rotted to death...  die!
2261                 if(self.health < 1)
2262                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2263         }
2264
2265         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2266                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2267 }
2268
2269 float zoomstate_set;
2270 void SetZoomState(float z)
2271 {
2272         if(z != self.zoomstate)
2273         {
2274                 self.zoomstate = z;
2275                 ClientData_Touch(self);
2276         }
2277         zoomstate_set = 1;
2278 }
2279
2280 void GetPressedKeys(void) {
2281         MUTATOR_CALLHOOK(GetPressedKeys);
2282         if (self.movement_x > 0) // get if movement keys are pressed
2283         {       // forward key pressed
2284                 self.pressedkeys |= KEY_FORWARD;
2285                 self.pressedkeys &~= KEY_BACKWARD;
2286         }
2287         else if (self.movement_x < 0)
2288         {       // backward key pressed
2289                 self.pressedkeys |= KEY_BACKWARD;
2290                 self.pressedkeys &~= KEY_FORWARD;
2291         }
2292         else
2293         {       // no x input
2294                 self.pressedkeys &~= KEY_FORWARD;
2295                 self.pressedkeys &~= KEY_BACKWARD;
2296         }
2297
2298         if (self.movement_y > 0)
2299         {       // right key pressed
2300                 self.pressedkeys |= KEY_RIGHT;
2301                 self.pressedkeys &~= KEY_LEFT;
2302         }
2303         else if (self.movement_y < 0)
2304         {       // left key pressed
2305                 self.pressedkeys |= KEY_LEFT;
2306                 self.pressedkeys &~= KEY_RIGHT;
2307         }
2308         else
2309         {       // no y input
2310                 self.pressedkeys &~= KEY_RIGHT;
2311                 self.pressedkeys &~= KEY_LEFT;
2312         }
2313
2314         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2315                 self.pressedkeys |= KEY_JUMP;
2316         else
2317                 self.pressedkeys &~= KEY_JUMP;
2318         if (self.BUTTON_CROUCH)
2319                 self.pressedkeys |= KEY_CROUCH;
2320         else
2321                 self.pressedkeys &~= KEY_CROUCH;
2322 }
2323
2324 /*
2325 ======================
2326 spectate mode routines
2327 ======================
2328 */
2329
2330 void SpectateCopy(entity spectatee) {
2331         other = spectatee;
2332         MUTATOR_CALLHOOK(SpectateCopy);
2333         self.armortype = spectatee.armortype;
2334         self.armorvalue = spectatee.armorvalue;
2335         self.ammo_cells = spectatee.ammo_cells;
2336         self.ammo_shells = spectatee.ammo_shells;
2337         self.ammo_nails = spectatee.ammo_nails;
2338         self.ammo_rockets = spectatee.ammo_rockets;
2339         self.ammo_fuel = spectatee.ammo_fuel;
2340         self.clip_load = spectatee.clip_load;
2341         self.clip_size = spectatee.clip_size;
2342         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2343         self.health = spectatee.health;
2344         self.impulse = 0;
2345         self.items = spectatee.items;
2346         self.last_pickup = spectatee.last_pickup;
2347         self.hit_time = spectatee.hit_time;
2348         self.metertime = spectatee.metertime;
2349         self.strength_finished = spectatee.strength_finished;
2350         self.invincible_finished = spectatee.invincible_finished;
2351         self.pressedkeys = spectatee.pressedkeys;
2352         self.weapons = spectatee.weapons;
2353         self.switchweapon = spectatee.switchweapon;
2354         self.weapon = spectatee.weapon;
2355         self.nex_charge = spectatee.nex_charge;
2356         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2357         self.hagar_load = spectatee.hagar_load;
2358         self.minelayer_mines = spectatee.minelayer_mines;
2359         self.punchangle = spectatee.punchangle;
2360         self.view_ofs = spectatee.view_ofs;
2361         self.v_angle = spectatee.v_angle;
2362         self.velocity = spectatee.velocity;
2363         self.dmg_take = spectatee.dmg_take;
2364         self.dmg_save = spectatee.dmg_save;
2365         self.dmg_inflictor = spectatee.dmg_inflictor;
2366         self.angles = spectatee.v_angle;
2367         self.fixangle = TRUE;
2368         setorigin(self, spectatee.origin);
2369         setsize(self, spectatee.mins, spectatee.maxs);
2370         SetZoomState(spectatee.zoomstate);
2371
2372         anticheat_spectatecopy(spectatee);
2373 }
2374
2375 float SpectateUpdate() {
2376         if(!self.enemy)
2377                 return 0;
2378
2379         if (self == self.enemy)
2380                 return 0;
2381
2382         if(self.enemy.classname != "player")
2383                 return 0;
2384
2385         SpectateCopy(self.enemy);
2386
2387         return 1;
2388 }
2389
2390 float SpectateNext() {
2391         other = find(self.enemy, classname, "player");
2392
2393         if (!other)
2394                 other = find(other, classname, "player");
2395
2396         if (other)
2397                 self.enemy = other;
2398
2399         if(self.enemy.classname == "player") {
2400                 msg_entity = self;
2401                 WriteByte(MSG_ONE, SVC_SETVIEW);
2402                 WriteEntity(MSG_ONE, self.enemy);
2403                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2404                 self.movetype = MOVETYPE_NONE;
2405                 accuracy_resend(self);
2406
2407                 if(!SpectateUpdate())
2408                         PutObserverInServer();
2409
2410                 return 1;
2411         } else {
2412                 return 0;
2413         }
2414 }
2415
2416 /*
2417 =============
2418 ShowRespawnCountdown()
2419
2420 Update a respawn countdown display.
2421 =============
2422 */
2423 void ShowRespawnCountdown()
2424 {
2425         float number;
2426         if(self.deadflag == DEAD_NO) // just respawned?
2427                 return;
2428         else
2429         {
2430                 number = ceil(self.death_time - time);
2431                 if(number <= 0)
2432                         return;
2433                 if(number <= self.respawn_countdown)
2434                 {
2435                         self.respawn_countdown = number - 1;
2436                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2437                                 AnnounceTo(self, strcat(ftos(number), ""));
2438                 }
2439         }
2440 }
2441
2442 void LeaveSpectatorMode()
2443 {
2444         if(nJoinAllowed(1)) {
2445                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2446                         self.classname = "player";
2447
2448                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2449                                 JoinBestTeam(self, FALSE, TRUE);
2450
2451                         if(autocvar_g_campaign)
2452                                 campaign_bots_may_start = 1;
2453
2454                         PutClientInServer();
2455
2456                         if(self.classname == "player")
2457                                 bprint ("^4", self.netname, "^4 is playing now\n");
2458
2459                         if(!autocvar_g_campaign)
2460                                 centerprint(self,""); // clear MOTD
2461
2462                         return;
2463                 } else {
2464                         if (g_ca && self.caplayer) {
2465                         }       // do nothing
2466                         else
2467                                 stuffcmd(self,"menu_showteamselect\n");
2468                         return;
2469                 }
2470         }
2471         else {
2472                 //player may not join because of g_maxplayers is set
2473                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2474         }
2475 }
2476
2477 /**
2478  * Determines whether the player is allowed to join. This depends on cvar
2479  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2480  * it checks whether the number of currently playing players exceeds g_maxplayers.
2481  * @return int number of free slots for players, 0 if none
2482  */
2483 float nJoinAllowed(float includeMe) {
2484         if(self.team_forced < 0)
2485                 return FALSE; // forced spectators can never join
2486
2487         // TODO simplify this
2488         local entity e;
2489
2490         local float totalClients;
2491         FOR_EACH_CLIENT(e)
2492                 totalClients += 1;
2493
2494         if (!autocvar_g_maxplayers)
2495                 return maxclients - totalClients + includeMe;
2496
2497         local float currentlyPlaying;
2498         FOR_EACH_REALPLAYER(e)
2499                 currentlyPlaying += 1;
2500
2501         if(currentlyPlaying < autocvar_g_maxplayers)
2502                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2503
2504         return 0;
2505 }
2506
2507 /**
2508  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2509  * g_maxplayers_spectator_blocktime seconds
2510  */
2511 void checkSpectatorBlock() {
2512         if(self.classname == "spectator" || self.classname == "observer") {
2513                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2514                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2515                         dropclient(self);
2516                 }
2517         }
2518 }
2519
2520 void ObserverThink()
2521 {
2522         if (self.flags & FL_JUMPRELEASED) {
2523                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2524                         self.welcomemessage_time = 0;
2525                         self.flags &~= FL_JUMPRELEASED;
2526                         self.flags |= FL_SPAWNING;
2527                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2528                         self.welcomemessage_time = 0;
2529                         self.flags &~= FL_JUMPRELEASED;
2530                         if(SpectateNext() == 1) {
2531                                 self.classname = "spectator";
2532                         }
2533                 }
2534         } else {
2535                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2536                         self.flags |= FL_JUMPRELEASED;
2537                         if(self.flags & FL_SPAWNING)
2538                         {
2539                                 self.flags &~= FL_SPAWNING;
2540                                 LeaveSpectatorMode();
2541                                 return;
2542                         }
2543                 }
2544         }
2545         PrintWelcomeMessage(self);
2546 }
2547
2548 void SpectatorThink()
2549 {
2550         if (self.flags & FL_JUMPRELEASED) {
2551                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2552                         self.welcomemessage_time = 0;
2553                         self.flags &~= FL_JUMPRELEASED;
2554                         self.flags |= FL_SPAWNING;
2555                 } else if(self.BUTTON_ATCK) {
2556                         self.welcomemessage_time = 0;
2557                         self.flags &~= FL_JUMPRELEASED;
2558                         if(SpectateNext() == 1) {
2559                                 self.classname = "spectator";
2560                         } else {
2561                                 self.classname = "observer";
2562                                 PutClientInServer();
2563                         }
2564                 } else if (self.BUTTON_ATCK2) {
2565                         self.welcomemessage_time = 0;
2566                         self.flags &~= FL_JUMPRELEASED;
2567                         self.classname = "observer";
2568                         PutClientInServer();
2569                 } else {
2570                         if(!SpectateUpdate())
2571                                 PutObserverInServer();
2572                 }
2573         } else {
2574                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2575                         self.flags |= FL_JUMPRELEASED;
2576                         if(self.flags & FL_SPAWNING)
2577                         {
2578                                 self.flags &~= FL_SPAWNING;
2579                                 LeaveSpectatorMode();
2580                                 return;
2581                         }
2582                 }
2583         }
2584
2585         PrintWelcomeMessage(self);
2586         self.flags |= FL_CLIENT | FL_NOTARGET;
2587 }
2588
2589 .float touchexplode_time;
2590
2591 /*
2592 =============
2593 PlayerPreThink
2594
2595 Called every frame for each client before the physics are run
2596 =============
2597 */
2598 void() ctf_setstatus;
2599 void() nexball_setstatus;
2600 .float items_added;
2601 void PlayerPreThink (void)
2602 {
2603         WarpZone_PlayerPhysics_FixVAngle();
2604
2605         self.stat_game_starttime = game_starttime;
2606         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2607         self.stat_leadlimit = autocvar_leadlimit;
2608
2609         if(frametime)
2610         {
2611                 // physics frames: update anticheat stuff
2612                 anticheat_prethink();
2613         }
2614
2615         if(blockSpectators && frametime)
2616                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2617                 checkSpectatorBlock();
2618
2619         zoomstate_set = 0;
2620
2621         if(self.netname_previous != self.netname)
2622         {
2623                 if(autocvar_sv_eventlog)
2624                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2625                 if(self.netname_previous)
2626                         strunzone(self.netname_previous);
2627                 self.netname_previous = strzone(self.netname);
2628         }
2629
2630         // version nagging
2631         if(self.version_nagtime)
2632                 if(self.cvar_g_xonoticversion)
2633                         if(time > self.version_nagtime)
2634                         {
2635                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2636                                 {
2637                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2638                                         {
2639                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2640                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2641                                         }
2642                                         else
2643                                         {
2644                                                 float r;
2645                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2646                                                 if(r < 0)
2647                                                 {
2648                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2649                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2650                                                 }
2651                                                 else if(r > 0)
2652                                                 {
2653                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2654                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2655                                                 }
2656                                         }
2657                                 }
2658                                 self.version_nagtime = 0;
2659                         }
2660
2661         // GOD MODE info
2662         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2663         {
2664                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2665                 self.max_armorvalue = 0;
2666         }
2667
2668 #ifdef TETRIS
2669         if (TetrisPreFrame())
2670                 return;
2671 #endif
2672
2673         MUTATOR_CALLHOOK(PlayerPreThink);
2674
2675         if(self.classname == "player") {
2676 //              if(self.netname == "Wazat")
2677 //                      bprint(self.classname, "\n");
2678
2679                 CheckRules_Player();
2680
2681                 PrintWelcomeMessage(self);
2682
2683                 if (intermission_running)
2684                 {
2685                         IntermissionThink ();   // otherwise a button could be missed between
2686                         return;                                 // the think tics
2687                 }
2688
2689                 //don't allow the player to turn around while game is paused!
2690                 if(timeoutStatus == 2) {
2691                         self.v_angle = self.lastV_angle;
2692                         self.angles = self.lastV_angle;
2693                         self.fixangle = TRUE;
2694                 }
2695
2696                 if(frametime)
2697                 {
2698                         if(self.health <= 0 && autocvar_g_deathglow)
2699                         {
2700                                 if(self.glowmod_x > 0)
2701                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2702                                 else
2703                                         self.glowmod_x = -1;
2704                                 if(self.glowmod_y > 0)
2705                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2706                                 else
2707                                         self.glowmod_y = -1;
2708                                 if(self.glowmod_z > 0)
2709                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2710                                 else
2711                                         self.glowmod_z = -1;
2712                         }
2713                         else
2714                         {
2715                                 // set weapon and player glowmod
2716                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2717
2718                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2719                                 {
2720                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2721                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2722                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2723
2724                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2725                                         {
2726                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2727                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2728                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2729                                         }
2730                                 }
2731                                 else
2732                                         self.weaponentity_glowmod = self.glowmod;
2733                         }
2734                         player_powerups();
2735                 }
2736
2737                 if (self.deadflag != DEAD_NO)
2738                 {
2739                         float button_pressed, force_respawn;
2740                         if(self.personal && g_race_qualifying)
2741                         {
2742                                 if(time > self.death_time)
2743                                 {
2744                                         self.death_time = time + 1; // only retry once a second
2745                                         respawn();
2746                                         self.impulse = 141;
2747                                 }
2748                         }
2749                         else
2750                         {
2751                                 if(frametime)
2752                                         player_anim();
2753                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2754                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2755                                 if (self.deadflag == DEAD_DYING)
2756                                 {
2757                                         if(force_respawn)
2758                                                 self.deadflag = DEAD_RESPAWNING;
2759                                         else if(!button_pressed)
2760                                                 self.deadflag = DEAD_DEAD;
2761                                 }
2762                                 else if (self.deadflag == DEAD_DEAD)
2763                                 {
2764                                         if(button_pressed)
2765                                                 self.deadflag = DEAD_RESPAWNABLE;
2766                                 }
2767                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2768                                 {
2769                                         if(!button_pressed)
2770                                                 self.deadflag = DEAD_RESPAWNING;
2771                                 }
2772                                 else if (self.deadflag == DEAD_RESPAWNING)
2773                                 {
2774                                         if(time > self.death_time)
2775                                         {
2776                                                 self.death_time = time + 1; // only retry once a second
2777                                                 respawn();
2778                                         }
2779                                 }
2780                                 ShowRespawnCountdown();
2781                         }
2782                         return;
2783                 }
2784
2785                 if(g_touchexplode)
2786                 if(time > self.touchexplode_time)
2787                 if(self.classname == "player")
2788                 if(self.deadflag == DEAD_NO)
2789                 if not(IS_INDEPENDENT_PLAYER(self))
2790                 FOR_EACH_PLAYER(other) if(self != other)
2791                 {
2792                         if(time > other.touchexplode_time)
2793                         if(other.deadflag == DEAD_NO)
2794                         if not(IS_INDEPENDENT_PLAYER(other))
2795                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2796                         {
2797                                 PlayerTouchExplode(self, other);
2798                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2799                         }
2800                 }
2801
2802                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2803                 {
2804                         vector dist;
2805
2806                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2807                         dist = self.prevorigin - self.origin;
2808                         dist_z = 0;
2809                         self.lms_traveled_distance += fabs(vlen(dist));
2810
2811                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2812                         {
2813                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2814                                 self.lms_traveled_distance = 0;
2815                         }
2816
2817                         if(time > self.lms_nextcheck)
2818                         {
2819                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2820                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2821                                 {
2822                                         centerprint(self, autocvar_g_lms_campcheck_message);
2823                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2824                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2825                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2826                                 }
2827                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2828                                 self.lms_traveled_distance = 0;
2829                         }
2830                 }
2831
2832                 self.prevorigin = self.origin;
2833
2834                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2835                 {
2836                         if (!self.crouch)
2837                         {
2838                                 self.crouch = TRUE;
2839                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2840                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2841                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2842                         }
2843                 }
2844                 else
2845                 {
2846                         if (self.crouch)
2847                         {
2848                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2849                                 if (!trace_startsolid)
2850                                 {
2851                                         self.crouch = FALSE;
2852                                         self.view_ofs = PL_VIEW_OFS;
2853                                         setsize (self, PL_MIN, PL_MAX);
2854                                 }
2855                         }
2856                 }
2857
2858                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2859                 {
2860                         if(self.bloodloss_timer < time)
2861                         {
2862                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2863                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2864                         }
2865                 }
2866
2867                 FixPlayermodel();
2868
2869                 GrapplingHookFrame();
2870
2871                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2872                 //if(frametime)
2873                 {
2874                         self.items &~= self.items_added;
2875
2876                         W_WeaponFrame();
2877
2878                         self.items_added = 0;
2879                         if(self.items & IT_JETPACK)
2880                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2881                                         self.items_added |= IT_FUEL;
2882
2883                         self.items |= self.items_added;
2884                 }
2885
2886                 player_regen();
2887
2888                 // rot nex charge to the charge limit
2889                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2890                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2891
2892                 if(frametime)
2893                         player_anim();
2894
2895                 if (g_minstagib)
2896                         minstagib_ammocheck();
2897
2898                 if(g_ctf)
2899                         ctf_setstatus();
2900
2901                 if(g_nexball)
2902                         nexball_setstatus();
2903
2904                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2905
2906                 //self.angles_y=self.v_angle_y + 90;   // temp
2907         } else if(gameover) {
2908                 if (intermission_running)
2909                         IntermissionThink ();   // otherwise a button could be missed between
2910                 return;
2911         } else if(self.classname == "observer") {
2912                 ObserverThink();
2913         } else if(self.classname == "spectator") {
2914                 SpectatorThink();
2915         }
2916
2917         if(!zoomstate_set)
2918                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2919
2920         float oldspectatee_status;
2921         oldspectatee_status = self.spectatee_status;
2922         if(self.classname == "spectator")
2923                 self.spectatee_status = num_for_edict(self.enemy);
2924         else if(self.classname == "observer")
2925                 self.spectatee_status = num_for_edict(self);
2926         else
2927                 self.spectatee_status = 0;
2928         if(self.spectatee_status != oldspectatee_status)
2929         {
2930                 ClientData_Touch(self);
2931                 if(g_race || g_cts)
2932                         race_InitSpectator();
2933         }
2934
2935         if(self.teamkill_soundtime)
2936         if(time > self.teamkill_soundtime)
2937         {
2938                 self.teamkill_soundtime = 0;
2939
2940                 entity oldpusher, oldself;
2941
2942                 oldself = self; self = self.teamkill_soundsource;
2943                 oldpusher = self.pusher; self.pusher = oldself;
2944
2945                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2946
2947                 self.pusher = oldpusher;
2948                 self = oldself;
2949         }
2950
2951         if(self.taunt_soundtime)
2952         if(time > self.taunt_soundtime)
2953         {
2954                 self.taunt_soundtime = 0;
2955                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2956         }
2957
2958         target_voicescript_next(self);
2959
2960         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2961         if(!self.weapon)
2962                 self.clip_load = self.clip_size = 0;
2963 }
2964
2965 float isInvisibleString(string s)
2966 {
2967         float i, n, c;
2968         s = strdecolorize(s);
2969         for((i = 0), (n = strlen(s)); i < n; ++i)
2970         {
2971                 c = str2chr(s, i);
2972                 switch(c)
2973                 {
2974                         case 0:
2975                         case 32: // space
2976                                 break;
2977                         case 192: // charmap space
2978                                 if (!autocvar_utf8_enable)
2979                                         break;
2980                                 return FALSE;
2981                         case 160: // space in unicode fonts
2982                         case 0xE000 + 192: // utf8 charmap space
2983                                 if (autocvar_utf8_enable)
2984                                         break;
2985                         default:
2986                                 return FALSE;
2987                 }
2988         }
2989         return TRUE;
2990 }
2991
2992 /*
2993 =============
2994 PlayerPostThink
2995
2996 Called every frame for each client after the physics are run
2997 =============
2998 */
2999 .float idlekick_lasttimeleft;
3000 .entity showheadshotbbox;
3001 void showheadshotbbox_think()
3002 {
3003         if(self.owner.showheadshotbbox != self)
3004         {
3005                 remove(self);
3006                 return;
3007         }
3008         self.nextthink = time;
3009         setorigin(self, self.owner.origin);
3010         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3011 }
3012 void PlayerPostThink (void)
3013 {
3014         // Savage: Check for nameless players
3015         if (isInvisibleString(self.netname)) {
3016                 self.netname = "Player";
3017                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3018         }
3019
3020         if(sv_maxidle && frametime)
3021         {
3022                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3023                 float timeleft;
3024                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3025                 if(timeleft <= 0)
3026                 {
3027                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3028                         AnnounceTo(self, "terminated");
3029                         dropclient(self);
3030                         return;
3031                 }
3032                 else if(timeleft <= 10)
3033                 {
3034                         if(timeleft != self.idlekick_lasttimeleft)
3035                         {
3036                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3037                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3038                         }
3039                 }
3040                 else
3041                 {
3042                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3043                 }
3044                 self.idlekick_lasttimeleft = timeleft;
3045         }
3046
3047 #ifdef TETRIS
3048         if(self.impulse == 100)
3049                 ImpulseCommands();
3050         if (TetrisPostFrame())
3051                 return;
3052 #endif
3053
3054         CheatFrame();
3055
3056         if(self.classname == "player") {
3057                 CheckRules_Player();
3058                 UpdateChatBubble();
3059                 if (self.impulse)
3060                         ImpulseCommands();
3061                 if (intermission_running)
3062                         return;         // intermission or finale
3063                 GetPressedKeys();
3064         } else if (self.classname == "observer") {
3065                 //do nothing
3066         } else if (self.classname == "spectator") {
3067                 //do nothing
3068         }
3069
3070         /*
3071         float i;
3072         for(i = 0; i < 1000; ++i)
3073         {
3074                 vector end;
3075                 end = self.origin + '0 0 1024' + 512 * randomvec();
3076                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3077                 if(trace_fraction < 1)
3078                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3079                 {
3080                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3081                         break;
3082                 }
3083         }
3084         */
3085
3086         Arena_Warmup();
3087
3088         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3089
3090         if(self.waypointsprite_attachedforcarrier)
3091                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3092
3093         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3094         {
3095                 if(!self.showheadshotbbox)
3096                 {
3097                         self.showheadshotbbox = spawn();
3098                         self.showheadshotbbox.classname = "headshotbbox";
3099                         self.showheadshotbbox.owner = self;
3100                         self.showheadshotbbox.think = showheadshotbbox_think;
3101                         self.showheadshotbbox.nextthink = time;
3102                         self = self.showheadshotbbox;
3103                         self.think();
3104                         self = self.owner;
3105                 }
3106         }
3107         else
3108         {
3109                 if(self.showheadshotbbox)
3110                         remove(self.showheadshotbbox);
3111         }
3112
3113         playerdemo_write();
3114
3115         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3116         {
3117                 if(!self.stored_netname)
3118                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3119                 if(self.stored_netname != self.netname)
3120                 {
3121                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3122                         strunzone(self.stored_netname);
3123                         self.stored_netname = strzone(self.netname);
3124                 }
3125         }
3126
3127         /*
3128         if(g_race)
3129                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3130         */
3131 }