qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  54         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  55 }
  56
  57 bool ClientData_Send(entity this, entity to, int sf)
  58 {
  59         if(to != self.owner)
  60         {
  61                 error("wtf");
  62                 return false;
  63         }
  64
  65         entity e;
  66
  67         e = to;
  68         if(IS_SPEC(to))
  69                 e = to.enemy;
  70
  71         sf = 0;
  72
  73         if(e.race_completed)
  74                 sf |= 1; // forced scoreboard
  75         if(to.spectatee_status)
  76                 sf |= 2; // spectator ent number follows
  77         if(e.zoomstate)
  78                 sf |= 4; // zoomed
  79         if(e.porto_v_angle_held)
  80                 sf |= 8; // angles held
  81
  82         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  83         WriteByte(MSG_ENTITY, sf);
  84
  85         if(sf & 2)
  86                 WriteByte(MSG_ENTITY, to.spectatee_status);
  87
  88         if(sf & 8)
  89         {
  90                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  91                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  92         }
  93
  94         return true;
  95 }
  96
  97 void ClientData_Attach()
  98 {SELFPARAM();
  99         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
 100         self.clientdata.drawonlytoclient = self;
 101         self.clientdata.owner = self;
 102 }
 103
 104 void ClientData_Detach()
 105 {SELFPARAM();
 106         remove(self.clientdata);
 107         self.clientdata = world;
 108 }
 109
 110 void ClientData_Touch(entity e)
 111 {
 112         e.clientdata.SendFlags = 1;
 113
 114         // make it spectatable
 115         entity e2;
 116         FOR_EACH_REALCLIENT(e2)
 117         {
 118                 if(e2 != e)
 119                         if(IS_SPEC(e2))
 120                                 if(e2.enemy == e)
 121                                         e2.clientdata.SendFlags = 1;
 122         }
 123 }
 124
 125 .string netname_previous;
 126
 127 void SetSpectatee(entity player, entity spectatee);
 128
 129
 130 /*
 131 =============
 132 CheckPlayerModel
 133
 134 Checks if the argument string can be a valid playermodel.
 135 Returns a valid one in doubt.
 136 =============
 137 */
 138 string FallbackPlayerModel;
 139 string CheckPlayerModel(string plyermodel) {
 140         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 141         {
 142                 // note: we cannot summon Don Strunzone here, some player may
 143                 // still have the model string set. In case anyone manages how
 144                 // to change a cvar default, we'll have a small leak here.
 145                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 146         }
 147         // only in right path
 148         if( substring(plyermodel,0,14) != "models/player/")
 149                 return FallbackPlayerModel;
 150         // only good file extensions
 151         if(substring(plyermodel,-4,4) != ".zym")
 152         if(substring(plyermodel,-4,4) != ".dpm")
 153         if(substring(plyermodel,-4,4) != ".iqm")
 154         if(substring(plyermodel,-4,4) != ".md3")
 155         if(substring(plyermodel,-4,4) != ".psk")
 156                 return FallbackPlayerModel;
 157         // forbid the LOD models
 158         if(substring(plyermodel, -9,5) == "_lod1")
 159                 return FallbackPlayerModel;
 160         if(substring(plyermodel, -9,5) == "_lod2")
 161                 return FallbackPlayerModel;
 162         if(plyermodel != strtolower(plyermodel))
 163                 return FallbackPlayerModel;
 164         // also, restrict to server models
 165         if(autocvar_sv_servermodelsonly)
 166         {
 167                 if(!fexists(plyermodel))
 168                         return FallbackPlayerModel;
 169         }
 170         return plyermodel;
 171 }
 172
 173 void setplayermodel(entity e, string modelname)
 174 {
 175         precache_model(modelname);
 176         _setmodel(e, modelname);
 177         player_setupanimsformodel();
 178         UpdatePlayerSounds();
 179 }
 180
 181 /*
 182 =============
 183 PutObserverInServer
 184
 185 putting a client as observer in the server
 186 =============
 187 */
 188 void FixPlayermodel(entity player);
 189 void PutObserverInServer()
 190 {SELFPARAM();
 191         entity  spot;
 192     self.hud = HUD_NORMAL;
 193
 194         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 195
 196         spot = SelectSpawnPoint (true);
 197         if(!spot)
 198                 error("No spawnpoints for observers?!?\n");
 199         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 200
 201         if(IS_REAL_CLIENT(self))
 202         {
 203                 msg_entity = self;
 204                 WriteByte(MSG_ONE, SVC_SETVIEW);
 205                 WriteEntity(MSG_ONE, self);
 206         }
 207
 208         self.frags = FRAGS_SPECTATOR;
 209         self.bot_attack = false;
 210
 211         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 212
 213         Portal_ClearAll(self);
 214
 215         Unfreeze(self);
 216
 217         if(self.alivetime)
 218         {
 219                 if(!warmup_stage)
 220                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 221                 self.alivetime = 0;
 222         }
 223
 224         if(self.vehicle)
 225                 vehicles_exit(VHEF_RELEASE);
 226
 227         WaypointSprite_PlayerDead();
 228
 229         if(!mutator_returnvalue)  // mutator prevents resetting teams
 230                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 231
 232         if(self.killcount != FRAGS_SPECTATOR)
 233         {
 234                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 235                 if(!intermission_running)
 236                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 237                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 238
 239                 if(self.just_joined == false) {
 240                         LogTeamchange(self.playerid, -1, 4);
 241                 } else
 242                         self.just_joined = false;
 243         }
 244
 245         PlayerScore_Clear(self); // clear scores when needed
 246
 247         accuracy_resend(self);
 248
 249         self.spectatortime = time;
 250
 251         self.classname = STR_OBSERVER;
 252         self.iscreature = false;
 253         self.teleportable = TELEPORT_SIMPLE;
 254         self.damagedbycontents = false;
 255         self.health = FRAGS_SPECTATOR;
 256         self.takedamage = DAMAGE_NO;
 257         self.solid = SOLID_NOT;
 258         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 259         self.flags = FL_CLIENT | FL_NOTARGET;
 260         self.armorvalue = 666;
 261         self.effects = 0;
 262         self.armorvalue = autocvar_g_balance_armor_start;
 263         self.pauserotarmor_finished = 0;
 264         self.pauserothealth_finished = 0;
 265         self.pauseregen_finished = 0;
 266         self.damageforcescale = 0;
 267         self.death_time = 0;
 268         self.respawn_flags = 0;
 269         self.respawn_time = 0;
 270         self.stat_respawn_time = 0;
 271         self.alpha = 0;
 272         self.scale = 0;
 273         self.fade_time = 0;
 274         self.pain_frame = 0;
 275         self.pain_finished = 0;
 276         self.strength_finished = 0;
 277         self.invincible_finished = 0;
 278         self.superweapons_finished = 0;
 279         self.pushltime = 0;
 280         self.istypefrag = 0;
 281         self.think = func_null;
 282         self.nextthink = 0;
 283         self.hook_time = 0;
 284         self.deadflag = DEAD_NO;
 285         self.angles = spot.angles;
 286         self.angles_z = 0;
 287         self.fixangle = true;
 288         self.crouch = false;
 289         self.revival_time = 0;
 290
 291         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 292         self.prevorigin = self.origin;
 293         self.items = 0;
 294         self.weapons = '0 0 0';
 295         self.model = "";
 296         FixPlayermodel(self);
 297         setmodel(self, MDL_Null);
 298         self.drawonlytoclient = self;
 299
 300         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 301         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 302
 303         self.weapon = 0;
 304         self.weaponname = "";
 305         self.switchingweapon = 0;
 306         self.weaponmodel = "";
 307         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 308         {
 309                 self.weaponentity[slot] = NULL;
 310         }
 311         self.exteriorweaponentity = world;
 312         self.killcount = FRAGS_SPECTATOR;
 313         self.velocity = '0 0 0';
 314         self.avelocity = '0 0 0';
 315         self.punchangle = '0 0 0';
 316         self.punchvector = '0 0 0';
 317         self.oldvelocity = self.velocity;
 318         self.fire_endtime = -1;
 319         self.event_damage = func_null;
 320 }
 321
 322 .float model_randomizer;
 323 void FixPlayermodel(entity player)
 324 {
 325         string defaultmodel = "";
 326         int defaultskin = 0;
 327         if(autocvar_sv_defaultcharacter)
 328         {
 329                 if(teamplay)
 330                 {
 331                         string s = Static_Team_ColorName_Lower(player.team);
 332                         if (s != "neutral")
 333                         {
 334                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 335                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 336                         }
 337                 }
 338
 339                 if(defaultmodel == "")
 340                 {
 341                         defaultmodel = autocvar_sv_defaultplayermodel;
 342                         defaultskin = autocvar_sv_defaultplayerskin;
 343                 }
 344
 345                 int n = tokenize_console(defaultmodel);
 346                 if(n > 0)
 347                 {
 348                         defaultmodel = argv(floor(n * player.model_randomizer));
 349                         // However, do NOT randomize if the player-selected model is in the list.
 350                         for (int i = 0; i < n; ++i)
 351                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 352                                         defaultmodel = argv(i);
 353                 }
 354
 355                 int i = strstrofs(defaultmodel, ":", 0);
 356                 if(i >= 0)
 357                 {
 358                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 359                         defaultmodel = substring(defaultmodel, 0, i);
 360                 }
 361         }
 362         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 363         defaultmodel = ret_string;
 364         defaultskin = ret_int;
 365
 366         bool chmdl = false;
 367         int oldskin;
 368         if(defaultmodel != "")
 369         {
 370                 if (defaultmodel != player.model)
 371                 {
 372                         vector m1 = player.mins;
 373                         vector m2 = player.maxs;
 374                         setplayermodel (player, defaultmodel);
 375                         setsize (player, m1, m2);
 376                         chmdl = true;
 377                 }
 378
 379                 oldskin = player.skin;
 380                 player.skin = defaultskin;
 381         } else {
 382                 if (player.playermodel != player.model || player.playermodel == "")
 383                 {
 384                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 385                         vector m1 = player.mins;
 386                         vector m2 = player.maxs;
 387                         setplayermodel (player, player.playermodel);
 388                         setsize (player, m1, m2);
 389                         chmdl = true;
 390                 }
 391
 392                 oldskin = player.skin;
 393                 player.skin = stof(player.playerskin);
 394         }
 395
 396         if(chmdl || oldskin != player.skin) // model or skin has changed
 397         {
 398                 player.species = player_getspecies(); // update species
 399                 UpdatePlayerSounds(); // update skin sounds
 400         }
 401
 402         if(!teamplay)
 403                 if(strlen(autocvar_sv_defaultplayercolors))
 404                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 405                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 406 }
 407
 408
 409 /** Called when a client spawns in the server */
 410 void PutClientInServer()
 411 {
 412         SELFPARAM();
 413         if (IS_BOT_CLIENT(this)) {
 414                 this.classname = STR_PLAYER;
 415         } else if (IS_REAL_CLIENT(this)) {
 416                 msg_entity = this;
 417                 WriteByte(MSG_ONE, SVC_SETVIEW);
 418                 WriteEntity(MSG_ONE, this);
 419         }
 420         if (gameover) {
 421                 this.classname = STR_OBSERVER;
 422         }
 423
 424         SetSpectatee(this, NULL);
 425
 426         // reset player keys
 427         this.itemkeys = 0;
 428
 429         MUTATOR_CALLHOOK(PutClientInServer, this);
 430
 431         if (IS_OBSERVER(this)) {
 432                 PutObserverInServer();
 433         } else if (IS_PLAYER(this)) {
 434                 accuracy_resend(this);
 435
 436                 if (this.team < 0)
 437                         JoinBestTeam(this, false, true);
 438
 439                 entity spot = SelectSpawnPoint(false);
 440                 if (!spot) {
 441                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 442                         return; // spawn failed
 443                 }
 444
 445                 this.classname = STR_PLAYER;
 446                 this.wasplayer = true;
 447                 this.iscreature = true;
 448                 this.teleportable = TELEPORT_NORMAL;
 449                 this.damagedbycontents = true;
 450                 this.movetype = MOVETYPE_WALK;
 451                 this.solid = SOLID_SLIDEBOX;
 452                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 453                 if (autocvar_g_playerclip_collisions)
 454                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 455                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 456                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 457                 this.frags = FRAGS_PLAYER;
 458                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 459                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 460                 if (autocvar__notarget)
 461                         this.flags |= FL_NOTARGET;
 462                 this.takedamage = DAMAGE_AIM;
 463                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 464                 this.dmg = 2; // WTF
 465
 466                 if (warmup_stage) {
 467                         this.ammo_shells = warmup_start_ammo_shells;
 468                         this.ammo_nails = warmup_start_ammo_nails;
 469                         this.ammo_rockets = warmup_start_ammo_rockets;
 470                         this.ammo_cells = warmup_start_ammo_cells;
 471                         this.ammo_plasma = warmup_start_ammo_plasma;
 472                         this.ammo_fuel = warmup_start_ammo_fuel;
 473                         this.health = warmup_start_health;
 474                         this.armorvalue = warmup_start_armorvalue;
 475                         this.weapons = WARMUP_START_WEAPONS;
 476                 } else {
 477                         this.ammo_shells = start_ammo_shells;
 478                         this.ammo_nails = start_ammo_nails;
 479                         this.ammo_rockets = start_ammo_rockets;
 480                         this.ammo_cells = start_ammo_cells;
 481                         this.ammo_plasma = start_ammo_plasma;
 482                         this.ammo_fuel = start_ammo_fuel;
 483                         this.health = start_health;
 484                         this.armorvalue = start_armorvalue;
 485                         this.weapons = start_weapons;
 486                 }
 487
 488                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 489
 490                 this.items = start_items;
 491
 492                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 493                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 494                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 495                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 496                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 497                 // extend the pause of rotting if client was reset at the beginning of the countdown
 498                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 499                         float f = game_starttime - time;
 500                         this.spawnshieldtime += f;
 501                         this.pauserotarmor_finished += f;
 502                         this.pauserothealth_finished += f;
 503                         this.pauseregen_finished += f;
 504                 }
 505                 this.damageforcescale = 2;
 506                 this.death_time = 0;
 507                 this.respawn_flags = 0;
 508                 this.respawn_time = 0;
 509                 this.stat_respawn_time = 0;
 510                 this.scale = autocvar_sv_player_scale;
 511                 this.fade_time = 0;
 512                 this.pain_frame = 0;
 513                 this.pain_finished = 0;
 514                 this.pushltime = 0;
 515                 this.think = func_null; // players have no think function
 516                 this.nextthink = 0;
 517                 this.dmg_team = 0;
 518                 this.ballistics_density = autocvar_g_ballistics_density_player;
 519
 520                 this.deadflag = DEAD_NO;
 521
 522                 this.angles = spot.angles;
 523                 this.angles_z = 0; // never spawn tilted even if the spot says to
 524                 if (IS_BOT_CLIENT(this))
 525                         this.v_angle = this.angles;
 526                 this.fixangle = true; // turn this way immediately
 527                 this.oldvelocity = this.velocity = '0 0 0';
 528                 this.avelocity = '0 0 0';
 529                 this.punchangle = '0 0 0';
 530                 this.punchvector = '0 0 0';
 531
 532                 this.strength_finished = 0;
 533                 this.invincible_finished = 0;
 534                 this.fire_endtime = -1;
 535                 this.revival_time = 0;
 536                 this.air_finished = time + 12;
 537
 538                 entity spawnevent = spawn();
 539                 spawnevent.owner = this;
 540                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 541
 542                 // Cut off any still running player sounds.
 543                 stopsound(this, CH_PLAYER_SINGLE);
 544
 545                 this.model = "";
 546                 FixPlayermodel(this);
 547                 this.drawonlytoclient = NULL;
 548
 549                 this.crouch = false;
 550                 this.view_ofs = PL_VIEW_OFS;
 551                 setsize(this, PL_MIN, PL_MAX);
 552                 this.spawnorigin = spot.origin;
 553                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 554                 // don't reset back to last position, even if new position is stuck in solid
 555                 this.oldorigin = this.origin;
 556                 this.prevorigin = this.origin;
 557                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 558         this.hud = HUD_NORMAL;
 559
 560                 this.event_damage = PlayerDamage;
 561
 562                 this.bot_attack = true;
 563                 this.monster_attack = true;
 564
 565                 this.spider_slowness = 0;
 566
 567                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = false;
 568
 569                 if (this.killcount == FRAGS_SPECTATOR) {
 570                         PlayerScore_Clear(this);
 571                         this.killcount = 0;
 572                 }
 573
 574                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 575                 {
 576                         CL_SpawnWeaponentity(this, slot);
 577                 }
 578                 this.alpha = default_player_alpha;
 579                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 580                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 581
 582                 this.speedrunning = false;
 583
 584                 target_voicescript_clear(this);
 585
 586                 // reset fields the weapons may use
 587                 FOREACH(Weapons, true, LAMBDA(
 588                         it.wr_resetplayer(it);
 589                         // reload all reloadable weapons
 590                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 591                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 592                         }
 593                 ));
 594
 595                 {
 596                         string s = spot.target;
 597                         spot.target = string_null;
 598                         WITH(entity, activator, this, LAMBDA(
 599                                 WITH(entity, self, spot, SUB_UseTargets())
 600                         ));
 601                         spot.target = s;
 602                 }
 603
 604                 Unfreeze(this);
 605
 606                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 607
 608                 if (autocvar_spawn_debug)
 609                 {
 610                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 611                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 612                 }
 613
 614                 this.switchweapon = w_getbestweapon(this);
 615                 this.cnt = -1; // W_LastWeapon will not complain
 616                 this.weapon = 0;
 617                 this.weaponname = "";
 618                 this.switchingweapon = 0;
 619
 620                 if (!warmup_stage && !this.alivetime)
 621                         this.alivetime = time;
 622
 623                 antilag_clear(this);
 624         }
 625 }
 626
 627 .float ebouncefactor, ebouncestop; // electro's values
 628 // TODO do we need all these fields, or should we stop autodetecting runtime
 629 // changes and just have a console command to update this?
 630 bool ClientInit_SendEntity(entity this, entity to, int sf)
 631 {
 632         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 633         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 640         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 641         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 642
 643         if(sv_foginterval && world.fog != "")
 644                 WriteString(MSG_ENTITY, world.fog);
 645         else
 646                 WriteString(MSG_ENTITY, "");
 647         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 648         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 649         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 650         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 651         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 652         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 653         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 654         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 655         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 656         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 657         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 658         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 659         return true;
 660 }
 661
 662 void ClientInit_CheckUpdate()
 663 {SELFPARAM();
 664         self.nextthink = time;
 665         if(self.count != autocvar_g_balance_armor_blockpercent)
 666         {
 667                 self.count = autocvar_g_balance_armor_blockpercent;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 671         {
 672                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 673                 self.SendFlags |= 1;
 674         }
 675         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 676         {
 677                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 678                 self.SendFlags |= 1;
 679         }
 680         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 681         {
 682                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 683                 self.SendFlags |= 1;
 684         }
 685         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 686         {
 687                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 688                 self.SendFlags |= 1;
 689         }
 690 }
 691
 692 void ClientInit_Spawn()
 693 {SELFPARAM();
 694         entity e = spawn();
 695         e.classname = "clientinit";
 696         e.think = ClientInit_CheckUpdate;
 697         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 698
 699         WITH(entity, self, e, ClientInit_CheckUpdate());
 700 }
 701
 702 /*
 703 =============
 704 SetNewParms
 705 =============
 706 */
 707 void SetNewParms (void)
 708 {
 709         // initialize parms for a new player
 710         parm1 = -(86400 * 366);
 711
 712         MUTATOR_CALLHOOK(SetNewParms);
 713 }
 714
 715 /*
 716 =============
 717 SetChangeParms
 718 =============
 719 */
 720 void SetChangeParms (void)
 721 {SELFPARAM();
 722         // save parms for level change
 723         parm1 = self.parm_idlesince - time;
 724
 725         MUTATOR_CALLHOOK(SetChangeParms);
 726 }
 727
 728 /*
 729 =============
 730 DecodeLevelParms
 731 =============
 732 */
 733 void DecodeLevelParms (void)
 734 {SELFPARAM();
 735         // load parms
 736         self.parm_idlesince = parm1;
 737         if(self.parm_idlesince == -(86400 * 366))
 738                 self.parm_idlesince = time;
 739
 740         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 741         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 742
 743         MUTATOR_CALLHOOK(DecodeLevelParms);
 744 }
 745
 746 /*
 747 =============
 748 ClientKill
 749
 750 Called when a client types 'kill' in the console
 751 =============
 752 */
 753
 754 .float clientkill_nexttime;
 755 void ClientKill_Now_TeamChange()
 756 {SELFPARAM();
 757         if(self.killindicator_teamchange == -1)
 758         {
 759                 JoinBestTeam( self, false, true );
 760         }
 761         else if(self.killindicator_teamchange == -2)
 762         {
 763                 if(blockSpectators)
 764                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 765                 PutObserverInServer();
 766         }
 767         else
 768                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 769         self.killindicator_teamchange = 0;
 770 }
 771
 772 void ClientKill_Now()
 773 {SELFPARAM();
 774         if(self.vehicle)
 775         {
 776             vehicles_exit(VHEF_RELEASE);
 777             if(!self.killindicator_teamchange)
 778             {
 779             self.vehicle_health = -1;
 780             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 781             }
 782         }
 783
 784         if(self.killindicator && !wasfreed(self.killindicator))
 785                 remove(self.killindicator);
 786
 787         self.killindicator = world;
 788
 789         if(self.killindicator_teamchange)
 790                 ClientKill_Now_TeamChange();
 791
 792         if(IS_PLAYER(self))
 793                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 794
 795         // now I am sure the player IS dead
 796 }
 797 void KillIndicator_Think()
 798 {SELFPARAM();
 799         if (gameover)
 800         {
 801                 self.owner.killindicator = world;
 802                 remove(self);
 803                 return;
 804         }
 805
 806         if (self.owner.alpha < 0 && !self.owner.vehicle)
 807         {
 808                 self.owner.killindicator = world;
 809                 remove(self);
 810                 return;
 811         }
 812
 813         if(self.cnt <= 0)
 814         {
 815                 WITH(entity, self, self.owner, ClientKill_Now());
 816                 return;
 817         }
 818     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 819     {
 820         self.nextthink = time + 1;
 821         self.cnt -= 1;
 822     }
 823         else
 824         {
 825                 if(self.cnt <= 10)
 826                         setmodel(self, MDL_NUM(self.cnt));
 827                 if(IS_REAL_CLIENT(self.owner))
 828                 {
 829                         if(self.cnt <= 10)
 830                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 831                 }
 832                 self.nextthink = time + 1;
 833                 self.cnt -= 1;
 834         }
 835 }
 836
 837 float clientkilltime;
 838 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 839 {SELFPARAM();
 840         float killtime;
 841         float starttime;
 842         entity e;
 843
 844         if (gameover)
 845                 return;
 846
 847         killtime = autocvar_g_balance_kill_delay;
 848
 849         if(g_race_qualifying || g_cts)
 850                 killtime = 0;
 851
 852     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 853         return;
 854
 855         self.killindicator_teamchange = targetteam;
 856
 857     if(!self.killindicator)
 858         {
 859                 if(self.deadflag == DEAD_NO)
 860                 {
 861                         killtime = max(killtime, self.clientkill_nexttime - time);
 862                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 863                 }
 864
 865                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 866                 {
 867                         ClientKill_Now();
 868                 }
 869                 else
 870                 {
 871                         starttime = max(time, clientkilltime);
 872
 873                         self.killindicator = spawn();
 874                         self.killindicator.owner = self;
 875                         self.killindicator.scale = 0.5;
 876                         setattachment(self.killindicator, self, "");
 877                         setorigin(self.killindicator, '0 0 52');
 878                         self.killindicator.think = KillIndicator_Think;
 879                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 880                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 881                         self.killindicator.cnt = ceil(killtime);
 882                         self.killindicator.count = bound(0, ceil(killtime), 10);
 883                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 884
 885                         for(e = world; (e = find(e, classname, "body")) != world; )
 886                         {
 887                                 if(e.enemy != self)
 888                                         continue;
 889                                 e.killindicator = spawn();
 890                                 e.killindicator.owner = e;
 891                                 e.killindicator.scale = 0.5;
 892                                 setattachment(e.killindicator, e, "");
 893                                 setorigin(e.killindicator, '0 0 52');
 894                                 e.killindicator.think = KillIndicator_Think;
 895                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 896                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 897                                 e.killindicator.cnt = ceil(killtime);
 898                         }
 899                         self.lip = 0;
 900                 }
 901         }
 902         if(self.killindicator)
 903         {
 904                 if(targetteam == 0) // just die
 905                 {
 906                         self.killindicator.colormod = '0 0 0';
 907                         if(IS_REAL_CLIENT(self))
 908                         if(self.killindicator.cnt > 0)
 909                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 910                 }
 911                 else if(targetteam == -1) // auto
 912                 {
 913                         self.killindicator.colormod = '0 1 0';
 914                         if(IS_REAL_CLIENT(self))
 915                         if(self.killindicator.cnt > 0)
 916                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 917                 }
 918                 else if(targetteam == -2) // spectate
 919                 {
 920                         self.killindicator.colormod = '0.5 0.5 0.5';
 921                         if(IS_REAL_CLIENT(self))
 922                         if(self.killindicator.cnt > 0)
 923                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 924                 }
 925                 else
 926                 {
 927                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 928                         if(IS_REAL_CLIENT(self))
 929                         if(self.killindicator.cnt > 0)
 930                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 931                 }
 932         }
 933
 934 }
 935
 936 void ClientKill (void)
 937 {SELFPARAM();
 938         if(gameover) return;
 939         if(self.player_blocked) return;
 940         if(self.frozen) return;
 941
 942         ClientKill_TeamChange(0);
 943 }
 944
 945 void FixClientCvars(entity e)
 946 {
 947         // send prediction settings to the client
 948         stuffcmd(e, "\nin_bindmap 0 0\n");
 949         if(autocvar_g_antilag == 3) // client side hitscan
 950                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 951         if(autocvar_sv_gentle)
 952                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 953 }
 954
 955 float PlayerInIDList(entity p, string idlist)
 956 {
 957         float n, i;
 958         string s;
 959
 960         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 961         if (!p.crypto_idfp)
 962                 return 0;
 963
 964         // this function allows abbreviated player IDs too!
 965         n = tokenize_console(idlist);
 966         for(i = 0; i < n; ++i)
 967         {
 968                 s = argv(i);
 969                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 970                         return 1;
 971         }
 972
 973         return 0;
 974 }
 975
 976 #ifdef DP_EXT_PRECONNECT
 977 /*
 978 =============
 979 ClientPreConnect
 980
 981 Called once (not at each match start) when a client begins a connection to the server
 982 =============
 983 */
 984 void ClientPreConnect (void)
 985 {SELFPARAM();
 986         if(autocvar_sv_eventlog)
 987         {
 988                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 989                         self.playerid,
 990                         num_for_edict(self),
 991                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
 992                 ));
 993         }
 994 }
 995 #endif
 996
 997 /*
 998 =============
 999 ClientConnect
1000
1001 Called when a client connects to the server
1002 =============
1003 */
1004 void DecodeLevelParms (void);
1005 void ClientConnect (void)
1006 {SELFPARAM();
1007         float t;
1008
1009         if(IS_CLIENT(self))
1010         {
1011                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1012                 return;
1013         }
1014
1015         if(Ban_MaybeEnforceBanOnce(self))
1016                 return;
1017
1018         DecodeLevelParms();
1019
1020 #ifdef WATERMARK
1021         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1022 #endif
1023
1024         self.classname = "player_joining";
1025
1026         self.flags = FL_CLIENT;
1027         self.version_nagtime = time + 10 + random() * 10;
1028
1029         if(player_count<0)
1030         {
1031                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1032                 player_count = 0;
1033         }
1034
1035         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1036
1037         PlayerScore_Attach(self);
1038         ClientData_Attach();
1039         accuracy_init(self);
1040         Inventory_new(self);
1041
1042         bot_clientconnect();
1043
1044         playerdemo_init();
1045
1046         anticheat_init();
1047
1048         // identify the right forced team
1049         if(autocvar_g_campaign)
1050         {
1051                 if(IS_REAL_CLIENT(self)) // only players, not bots
1052                 {
1053                         switch(autocvar_g_campaign_forceteam)
1054                         {
1055                                 case 1: self.team_forced = NUM_TEAM_1; break;
1056                                 case 2: self.team_forced = NUM_TEAM_2; break;
1057                                 case 3: self.team_forced = NUM_TEAM_3; break;
1058                                 case 4: self.team_forced = NUM_TEAM_4; break;
1059                                 default: self.team_forced = 0;
1060                         }
1061                 }
1062         }
1063         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1064                 self.team_forced = NUM_TEAM_1;
1065         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1066                 self.team_forced = NUM_TEAM_2;
1067         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1068                 self.team_forced = NUM_TEAM_3;
1069         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1070                 self.team_forced = NUM_TEAM_4;
1071         else if(autocvar_g_forced_team_otherwise == "red")
1072                 self.team_forced = NUM_TEAM_1;
1073         else if(autocvar_g_forced_team_otherwise == "blue")
1074                 self.team_forced = NUM_TEAM_2;
1075         else if(autocvar_g_forced_team_otherwise == "yellow")
1076                 self.team_forced = NUM_TEAM_3;
1077         else if(autocvar_g_forced_team_otherwise == "pink")
1078                 self.team_forced = NUM_TEAM_4;
1079         else if(autocvar_g_forced_team_otherwise == "spectate")
1080                 self.team_forced = -1;
1081         else if(autocvar_g_forced_team_otherwise == "spectator")
1082                 self.team_forced = -1;
1083         else
1084                 self.team_forced = 0;
1085
1086         if(!teamplay)
1087                 if(self.team_forced > 0)
1088                         self.team_forced = 0;
1089
1090         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1091
1092         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1093                 self.classname = STR_OBSERVER;
1094         } else {
1095                 if(teamplay)
1096                 {
1097                         if(autocvar_g_balance_teams)
1098                         {
1099                                 self.classname = STR_PLAYER;
1100                                 campaign_bots_may_start = 1;
1101                         }
1102                         else
1103                         {
1104                                 self.classname = STR_OBSERVER; // do it anyway
1105                         }
1106                 }
1107                 else
1108                 {
1109                         self.classname = STR_PLAYER;
1110                         campaign_bots_may_start = 1;
1111                 }
1112         }
1113
1114         self.playerid = (playerid_last = playerid_last + 1);
1115
1116         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1117
1118     if(IS_BOT_CLIENT(self))
1119         PlayerStats_GameReport_AddPlayer(self);
1120
1121         if(autocvar_sv_eventlog)
1122                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1123
1124         LogTeamchange(self.playerid, self.team, 1);
1125
1126         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1127
1128         self.netname_previous = strzone(self.netname);
1129
1130         if(IS_PLAYER(self) && teamplay)
1131                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1132         else
1133                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1134
1135         stuffcmd(self, strcat(clientstuff, "\n"));
1136         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1137
1138         FixClientCvars(self);
1139
1140         // spawnfunc_waypoint sprites
1141         WaypointSprite_InitClient(self);
1142
1143         // Wazat's grappling hook
1144         SetGrappleHookBindings();
1145
1146         // Jetpack binds
1147         stuffcmd(self, "alias +jetpack +button10\n");
1148         stuffcmd(self, "alias -jetpack -button10\n");
1149
1150         // get version info from player
1151         stuffcmd(self, "cmd clientversion $gameversion\n");
1152
1153         // get other cvars from player
1154         GetCvars(0);
1155
1156         // notify about available teams
1157         if(teamplay)
1158         {
1159                 CheckAllowedTeams(self);
1160                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1161                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1162         }
1163         else
1164                 stuffcmd(self, "set _teams_available 0\n");
1165
1166         attach_entcs(self);
1167
1168         bot_relinkplayerlist();
1169
1170         self.spectatortime = time;
1171         if(blockSpectators)
1172         {
1173                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1174         }
1175
1176         self.jointime = time;
1177         self.allowed_timeouts = autocvar_sv_timeout_number;
1178
1179         if(IS_REAL_CLIENT(self))
1180         {
1181                 if(!autocvar_g_campaign)
1182                 {
1183                         self.motd_actived_time = -1;
1184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1185                 }
1186
1187                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET(TUBA)))
1188                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1189         }
1190
1191         if(!sv_foginterval && world.fog != "")
1192                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1193
1194         W_HitPlotOpen(self);
1195
1196         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1197                 send_CSQC_teamnagger();
1198
1199         CheatInitClient();
1200
1201         CSQCMODEL_AUTOINIT(self);
1202
1203         self.model_randomizer = random();
1204
1205         if(IS_REAL_CLIENT(self))
1206                 sv_notice_join();
1207
1208         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1209                 WITH(entity, self, e, e.init_for_player(this));
1210         }
1211
1212         MUTATOR_CALLHOOK(ClientConnect, self);
1213 }
1214 /*
1215 =============
1216 ClientDisconnect
1217
1218 Called when a client disconnects from the server
1219 =============
1220 */
1221 .entity chatbubbleentity;
1222 void ReadyCount();
1223 void ClientDisconnect (void)
1224 {SELFPARAM();
1225         if(self.vehicle)
1226             vehicles_exit(VHEF_RELEASE);
1227
1228         if (!IS_CLIENT(self))
1229         {
1230                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1231                 return;
1232         }
1233
1234         PlayerStats_GameReport_FinalizePlayer(self);
1235
1236         if ( self.active_minigame )
1237                 part_minigame(self);
1238
1239         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1240
1241         CheatShutdownClient();
1242
1243         W_HitPlotClose(self);
1244
1245         anticheat_report();
1246         anticheat_shutdown();
1247
1248         playerdemo_shutdown();
1249
1250         bot_clientdisconnect();
1251
1252         detach_entcs(self);
1253
1254         if(autocvar_sv_eventlog)
1255                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1256
1257         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1258
1259         MUTATOR_CALLHOOK(ClientDisconnect);
1260
1261         Portal_ClearAll(self);
1262
1263         Unfreeze(self);
1264
1265         RemoveGrapplingHook(self);
1266
1267         // Here, everything has been done that requires this player to be a client.
1268
1269         self.flags &= ~FL_CLIENT;
1270
1271         if (self.chatbubbleentity)
1272                 remove (self.chatbubbleentity);
1273
1274         if (self.killindicator)
1275                 remove (self.killindicator);
1276
1277         WaypointSprite_PlayerGone();
1278
1279         bot_relinkplayerlist();
1280
1281         accuracy_free(self);
1282         Inventory_delete(self);
1283         ClientData_Detach();
1284         PlayerScore_Detach(self);
1285
1286         if(self.netname_previous)
1287                 strunzone(self.netname_previous);
1288         if(self.clientstatus)
1289                 strunzone(self.clientstatus);
1290         if(self.weaponorder_byimpulse)
1291                 strunzone(self.weaponorder_byimpulse);
1292
1293         ClearPlayerSounds();
1294
1295         if(self.personal)
1296                 remove(self.personal);
1297
1298         self.playerid = 0;
1299         ReadyCount();
1300
1301         // free cvars
1302         GetCvars(-1);
1303 }
1304
1305 .float BUTTON_CHAT;
1306 void ChatBubbleThink()
1307 {SELFPARAM();
1308         self.nextthink = time;
1309         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1310         {
1311                 if(self.owner) // but why can that ever be world?
1312                         self.owner.chatbubbleentity = world;
1313                 remove(self);
1314                 return;
1315         }
1316
1317         self.mdl = "";
1318
1319         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1320         {
1321                 if ( self.owner.active_minigame )
1322                         self.mdl = "models/sprites/minigame_busy.iqm";
1323                 else if ( self.owner.BUTTON_CHAT )
1324                         self.mdl = "models/misc/chatbubble.spr";
1325         }
1326
1327         if ( self.model != self.mdl )
1328                 _setmodel(self, self.mdl);
1329
1330 }
1331
1332 void UpdateChatBubble()
1333 {SELFPARAM();
1334         if (self.alpha < 0)
1335                 return;
1336         // spawn a chatbubble entity if needed
1337         if (!self.chatbubbleentity)
1338         {
1339                 self.chatbubbleentity = spawn();
1340                 self.chatbubbleentity.owner = self;
1341                 self.chatbubbleentity.exteriormodeltoclient = self;
1342                 self.chatbubbleentity.think = ChatBubbleThink;
1343                 self.chatbubbleentity.nextthink = time;
1344                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1345                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1346                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1347                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1348                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1349                 //self.chatbubbleentity.model = "";
1350                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1351         }
1352 }
1353
1354
1355 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1356 // added to the model skins
1357 /*void UpdateColorModHack()
1358 {
1359         float c;
1360         c = self.clientcolors & 15;
1361         // LordHavoc: only bothering to support white, green, red, yellow, blue
1362              if (!teamplay) self.colormod = '0 0 0';
1363         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1364         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1365         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1366         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1367         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1368         else self.colormod = '1 1 1';
1369 }*/
1370
1371 void respawn(void)
1372 {SELFPARAM();
1373         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1374         {
1375                 self.solid = SOLID_NOT;
1376                 self.takedamage = DAMAGE_NO;
1377                 self.movetype = MOVETYPE_FLY;
1378                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1379                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1380                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1381                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1382                 if(autocvar_g_respawn_ghosts_maxtime)
1383                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1384         }
1385
1386         CopyBody(1);
1387
1388         self.effects |= EF_NODRAW; // prevent another CopyBody
1389         PutClientInServer();
1390 }
1391
1392 void play_countdown(float finished, string samp)
1393 {SELFPARAM();
1394         if(IS_REAL_CLIENT(self))
1395                 if(floor(finished - time - frametime) != floor(finished - time))
1396                         if(finished - time < 6)
1397                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1398 }
1399
1400 void player_powerups (void)
1401 {SELFPARAM();
1402         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1403         int items_prev = self.items;
1404
1405         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1406                 self.modelflags |= MF_ROCKET;
1407         else
1408                 self.modelflags &= ~MF_ROCKET;
1409
1410         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1411
1412         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1413                 return;
1414
1415         Fire_ApplyDamage(self);
1416         Fire_ApplyEffect(self);
1417
1418         if (!g_instagib)
1419         {
1420                 if (self.items & ITEM_Strength.m_itemid)
1421                 {
1422                         play_countdown(self.strength_finished, SND(POWEROFF));
1423                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1424                         if (time > self.strength_finished)
1425                         {
1426                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1427                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1428                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1429                         }
1430                 }
1431                 else
1432                 {
1433                         if (time < self.strength_finished)
1434                         {
1435                                 self.items = self.items | ITEM_Strength.m_itemid;
1436                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1437                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1438                         }
1439                 }
1440                 if (self.items & ITEM_Shield.m_itemid)
1441                 {
1442                         play_countdown(self.invincible_finished, SND(POWEROFF));
1443                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1444                         if (time > self.invincible_finished)
1445                         {
1446                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1447                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1448                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1449                         }
1450                 }
1451                 else
1452                 {
1453                         if (time < self.invincible_finished)
1454                         {
1455                                 self.items = self.items | ITEM_Shield.m_itemid;
1456                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1457                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1458                         }
1459                 }
1460                 if (self.items & IT_SUPERWEAPON)
1461                 {
1462                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1463                         {
1464                                 self.superweapons_finished = 0;
1465                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1466                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1467                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1468                         }
1469                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1470                         {
1471                                 // don't let them run out
1472                         }
1473                         else
1474                         {
1475                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1476                                 if (time > self.superweapons_finished)
1477                                 {
1478                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1479                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1480                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1481                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1482                                 }
1483                         }
1484                 }
1485                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1486                 {
1487                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1488                         {
1489                                 self.items = self.items | IT_SUPERWEAPON;
1490                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1491                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1492                         }
1493                         else
1494                         {
1495                                 self.superweapons_finished = 0;
1496                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1497                         }
1498                 }
1499                 else
1500                 {
1501                         self.superweapons_finished = 0;
1502                 }
1503         }
1504
1505         if(autocvar_g_nodepthtestplayers)
1506                 self.effects = self.effects | EF_NODEPTHTEST;
1507
1508         if(autocvar_g_fullbrightplayers)
1509                 self.effects = self.effects | EF_FULLBRIGHT;
1510
1511         if (time >= game_starttime)
1512         if (time < self.spawnshieldtime)
1513                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1514
1515         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1516 }
1517
1518 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1519 {
1520         if(current > stable)
1521                 return current;
1522         else if(current > stable - 0.25) // when close enough, "snap"
1523                 return stable;
1524         else
1525                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1526 }
1527
1528 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1529 {
1530         if(current < stable)
1531                 return current;
1532         else if(current < stable + 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1536 }
1537
1538 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1539 {
1540         if(current > rotstable)
1541         {
1542                 if(rotframetime > 0)
1543                 {
1544                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1545                         current = max(rotstable, current - rotlinear * rotframetime);
1546                 }
1547         }
1548         else if(current < regenstable)
1549         {
1550                 if(regenframetime > 0)
1551                 {
1552                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1553                         current = min(regenstable, current + regenlinear * regenframetime);
1554                 }
1555         }
1556
1557         if(current > limit)
1558                 current = limit;
1559
1560         return current;
1561 }
1562
1563 void player_regen (void)
1564 {SELFPARAM();
1565         float max_mod, regen_mod, rot_mod, limit_mod;
1566         max_mod = regen_mod = rot_mod = limit_mod = 1;
1567         regen_mod_max = max_mod;
1568         regen_mod_regen = regen_mod;
1569         regen_mod_rot = rot_mod;
1570         regen_mod_limit = limit_mod;
1571
1572         regen_health = autocvar_g_balance_health_regen;
1573         regen_health_linear = autocvar_g_balance_health_regenlinear;
1574         regen_health_rot = autocvar_g_balance_health_rot;
1575         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1576         regen_health_stable = autocvar_g_balance_health_regenstable;
1577         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1578         if(!MUTATOR_CALLHOOK(PlayerRegen))
1579         if(!self.frozen)
1580         {
1581                 float mina, maxa, limith, limita;
1582                 maxa = autocvar_g_balance_armor_rotstable;
1583                 mina = autocvar_g_balance_armor_regenstable;
1584                 limith = autocvar_g_balance_health_limit;
1585                 limita = autocvar_g_balance_armor_limit;
1586
1587                 max_mod = regen_mod_max;
1588                 regen_mod = regen_mod_regen;
1589                 rot_mod = regen_mod_rot;
1590                 limit_mod = regen_mod_limit;
1591
1592                 regen_health_rotstable = regen_health_rotstable * max_mod;
1593                 regen_health_stable = regen_health_stable * max_mod;
1594                 limith = limith * limit_mod;
1595                 limita = limita * limit_mod;
1596
1597                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1598                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1599         }
1600
1601         // if player rotted to death...  die!
1602         // check this outside above checks, as player may still be able to rot to death
1603         if(self.health < 1)
1604         {
1605                 if(self.vehicle)
1606                         vehicles_exit(VHEF_RELEASE);
1607                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1608         }
1609
1610         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1611         {
1612                 float minf, maxf, limitf;
1613
1614                 maxf = autocvar_g_balance_fuel_rotstable;
1615                 minf = autocvar_g_balance_fuel_regenstable;
1616                 limitf = autocvar_g_balance_fuel_limit;
1617
1618                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1619         }
1620 }
1621
1622 float zoomstate_set;
1623 void SetZoomState(float z)
1624 {SELFPARAM();
1625         if(z != self.zoomstate)
1626         {
1627                 self.zoomstate = z;
1628                 ClientData_Touch(self);
1629         }
1630         zoomstate_set = 1;
1631 }
1632
1633 void GetPressedKeys()
1634 {SELFPARAM();
1635         MUTATOR_CALLHOOK(GetPressedKeys);
1636         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1637         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1638         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1639         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1640         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1641
1642         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1643         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1644         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1645         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1646         #undef X
1647 }
1648
1649 /*
1650 ======================
1651 spectate mode routines
1652 ======================
1653 */
1654
1655 void SpectateCopy(entity spectatee)
1656 {SELFPARAM();
1657         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1658         self.armortype = spectatee.armortype;
1659         self.armorvalue = spectatee.armorvalue;
1660         self.ammo_cells = spectatee.ammo_cells;
1661         self.ammo_plasma = spectatee.ammo_plasma;
1662         self.ammo_shells = spectatee.ammo_shells;
1663         self.ammo_nails = spectatee.ammo_nails;
1664         self.ammo_rockets = spectatee.ammo_rockets;
1665         self.ammo_fuel = spectatee.ammo_fuel;
1666         self.clip_load = spectatee.clip_load;
1667         self.clip_size = spectatee.clip_size;
1668         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1669         self.health = spectatee.health;
1670         self.impulse = 0;
1671         self.items = spectatee.items;
1672         self.last_pickup = spectatee.last_pickup;
1673         self.hit_time = spectatee.hit_time;
1674         self.strength_finished = spectatee.strength_finished;
1675         self.invincible_finished = spectatee.invincible_finished;
1676         self.pressedkeys = spectatee.pressedkeys;
1677         self.weapons = spectatee.weapons;
1678         self.switchweapon = spectatee.switchweapon;
1679         self.switchingweapon = spectatee.switchingweapon;
1680         self.weapon = spectatee.weapon;
1681         self.vortex_charge = spectatee.vortex_charge;
1682         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1683         self.hagar_load = spectatee.hagar_load;
1684         self.arc_heat_percent = spectatee.arc_heat_percent;
1685         self.minelayer_mines = spectatee.minelayer_mines;
1686         self.punchangle = spectatee.punchangle;
1687         self.view_ofs = spectatee.view_ofs;
1688         self.velocity = spectatee.velocity;
1689         self.dmg_take = spectatee.dmg_take;
1690         self.dmg_save = spectatee.dmg_save;
1691         self.dmg_inflictor = spectatee.dmg_inflictor;
1692         self.v_angle = spectatee.v_angle;
1693         self.angles = spectatee.v_angle;
1694         self.frozen = spectatee.frozen;
1695         self.revive_progress = spectatee.revive_progress;
1696         if(!self.BUTTON_USE)
1697                 self.fixangle = true;
1698         setorigin(self, spectatee.origin);
1699         setsize(self, spectatee.mins, spectatee.maxs);
1700         SetZoomState(spectatee.zoomstate);
1701
1702     anticheat_spectatecopy(spectatee);
1703         self.hud = spectatee.hud;
1704         if(spectatee.vehicle)
1705     {
1706         self.fixangle = false;
1707         //self.velocity = spectatee.vehicle.velocity;
1708         self.vehicle_health = spectatee.vehicle_health;
1709         self.vehicle_shield = spectatee.vehicle_shield;
1710         self.vehicle_energy = spectatee.vehicle_energy;
1711         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1712         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1713         self.vehicle_reload1 = spectatee.vehicle_reload1;
1714         self.vehicle_reload2 = spectatee.vehicle_reload2;
1715
1716         msg_entity = self;
1717
1718         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1719             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1720             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1721             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1722
1723         //WriteByte (MSG_ONE, SVC_SETVIEW);
1724         //    WriteEntity(MSG_ONE, self);
1725         //makevectors(spectatee.v_angle);
1726         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1727     }
1728 }
1729
1730 bool SpectateUpdate()
1731 {SELFPARAM();
1732         if(!self.enemy)
1733             return false;
1734
1735         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1736         {
1737                 SetSpectatee(self, NULL);
1738                 return false;
1739         }
1740
1741         SpectateCopy(self.enemy);
1742
1743         return true;
1744 }
1745
1746 bool SpectateSet()
1747 {SELFPARAM();
1748         if(!IS_PLAYER(self.enemy))
1749                 return false;
1750
1751         msg_entity = self;
1752         WriteByte(MSG_ONE, SVC_SETVIEW);
1753         WriteEntity(MSG_ONE, self.enemy);
1754         self.movetype = MOVETYPE_NONE;
1755         accuracy_resend(self);
1756
1757         if(!SpectateUpdate())
1758                 PutObserverInServer();
1759
1760         return true;
1761 }
1762
1763 void SetSpectatee(entity player, entity spectatee)
1764 {
1765         entity old_spectatee = player.enemy;
1766
1767         player.enemy = spectatee;
1768
1769         // WEAPONTODO
1770         // these are required to fix the spectator bug with arc
1771         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1772         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1773 }
1774
1775 bool Spectate(entity pl)
1776 {SELFPARAM();
1777         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1778                 return false;
1779         pl = spec_player;
1780
1781         SetSpectatee(self, pl);
1782         return SpectateSet();
1783 }
1784
1785 bool SpectateNext()
1786 {SELFPARAM();
1787         other = find(self.enemy, classname, "player");
1788
1789         if (MUTATOR_CALLHOOK(SpectateNext, self, other))
1790                 other = spec_player;
1791         else if (!other)
1792                 other = find(other, classname, "player");
1793
1794         if(other) { SetSpectatee(self, other); }
1795
1796         return SpectateSet();
1797 }
1798
1799 bool SpectatePrev()
1800 {SELFPARAM();
1801         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1802         other = findchain(classname, "player");
1803         if (!other) // no player
1804                 return false;
1805
1806         entity first = other;
1807         // skip players until current spectated player
1808         if(self.enemy)
1809         while(other && other != self.enemy)
1810                 other = other.chain;
1811
1812         switch (MUTATOR_CALLHOOK(SpectatePrev, self, other, first))
1813         {
1814                 case MUT_SPECPREV_FOUND:
1815                     other = spec_player;
1816                     break;
1817                 case MUT_SPECPREV_RETURN:
1818                     other = spec_player;
1819                     return true;
1820                 case MUT_SPECPREV_CONTINUE:
1821                 default:
1822                 {
1823                         if(other.chain)
1824                                 other = other.chain;
1825                         else
1826                                 other = first;
1827                         break;
1828                 }
1829         }
1830
1831         SetSpectatee(self, other);
1832         return SpectateSet();
1833 }
1834
1835 /*
1836 =============
1837 ShowRespawnCountdown()
1838
1839 Update a respawn countdown display.
1840 =============
1841 */
1842 void ShowRespawnCountdown()
1843 {SELFPARAM();
1844         float number;
1845         if(self.deadflag == DEAD_NO) // just respawned?
1846                 return;
1847         else
1848         {
1849                 number = ceil(self.respawn_time - time);
1850                 if(number <= 0)
1851                         return;
1852                 if(number <= self.respawn_countdown)
1853                 {
1854                         self.respawn_countdown = number - 1;
1855                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1856                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1857                 }
1858         }
1859 }
1860
1861 void LeaveSpectatorMode()
1862 {SELFPARAM();
1863         if(self.caplayer)
1864                 return;
1865         if(nJoinAllowed(self))
1866         {
1867                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1868                 {
1869                         self.classname = STR_PLAYER;
1870                         nades_RemoveBonus(self);
1871
1872                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1873                                 { JoinBestTeam(self, false, true); }
1874
1875                         if(autocvar_g_campaign)
1876                                 { campaign_bots_may_start = 1; }
1877
1878                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1879
1880                         PutClientInServer();
1881
1882                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1883                 }
1884                 else
1885                         stuffcmd(self, "menu_showteamselect\n");
1886         }
1887         else
1888         {
1889                 // Player may not join because g_maxplayers is set
1890                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1891         }
1892 }
1893
1894 /**
1895  * Determines whether the player is allowed to join. This depends on cvar
1896  * g_maxplayers, if it isn't used this function always return true, otherwise
1897  * it checks whether the number of currently playing players exceeds g_maxplayers.
1898  * @return int number of free slots for players, 0 if none
1899  */
1900 float nJoinAllowed(entity ignore)
1901 {SELFPARAM();
1902         if(!ignore)
1903         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1904         // so report 0 free slots if restricted
1905         {
1906                 if(autocvar_g_forced_team_otherwise == "spectate")
1907                         return 0;
1908                 if(autocvar_g_forced_team_otherwise == "spectator")
1909                         return 0;
1910         }
1911
1912         if(self.team_forced < 0)
1913                 return 0; // forced spectators can never join
1914
1915         // TODO simplify this
1916         entity e;
1917         float totalClients = 0;
1918         FOR_EACH_CLIENT(e)
1919                 if(e != ignore)
1920                         totalClients += 1;
1921
1922         if (!autocvar_g_maxplayers)
1923                 return maxclients - totalClients;
1924
1925         float currentlyPlaying = 0;
1926         FOR_EACH_REALCLIENT(e)
1927                 if(IS_PLAYER(e) || e.caplayer)
1928                         currentlyPlaying += 1;
1929
1930         if(currentlyPlaying < autocvar_g_maxplayers)
1931                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1932
1933         return 0;
1934 }
1935
1936 /**
1937  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1938  * g_maxplayers_spectator_blocktime seconds
1939  */
1940 void checkSpectatorBlock()
1941 {SELFPARAM();
1942         if(IS_SPEC(self) || IS_OBSERVER(self))
1943         if(!self.caplayer)
1944         if(IS_REAL_CLIENT(self))
1945         {
1946                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1947                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1948                         dropclient(self);
1949                 }
1950         }
1951 }
1952
1953 void PrintWelcomeMessage()
1954 {SELFPARAM();
1955         if(self.motd_actived_time == 0)
1956         {
1957                 if (autocvar_g_campaign) {
1958                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1959                                 self.motd_actived_time = time;
1960                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1961                         }
1962                 } else {
1963                         if (self.BUTTON_INFO) {
1964                                 self.motd_actived_time = time;
1965                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1966                         }
1967                 }
1968         }
1969         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1970         {
1971                 if (autocvar_g_campaign) {
1972                         if (self.BUTTON_INFO)
1973                                 self.motd_actived_time = time;
1974                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
1975                                 self.motd_actived_time = 0;
1976                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1977                         }
1978                 } else {
1979                         if (self.BUTTON_INFO)
1980                                 self.motd_actived_time = time;
1981                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1982                                 self.motd_actived_time = 0;
1983                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1984                         }
1985                 }
1986         }
1987         else //if(self.motd_actived_time < 0) // just connected, motd is active
1988         {
1989                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
1990                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1991                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
1992                 {
1993                         // instanctly hide MOTD
1994                         self.motd_actived_time = 0;
1995                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1996                 }
1997         }
1998 }
1999
2000 void ObserverThink()
2001 {SELFPARAM();
2002         if ( self.impulse )
2003         {
2004                 MinigameImpulse(self.impulse);
2005                 self.impulse = 0;
2006         }
2007         float prefered_movetype;
2008         if (self.flags & FL_JUMPRELEASED) {
2009                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2010                         self.flags &= ~FL_JUMPRELEASED;
2011                         self.flags |= FL_SPAWNING;
2012                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2013                         self.flags &= ~FL_JUMPRELEASED;
2014                         if(SpectateNext()) {
2015                                 self.classname = STR_SPECTATOR;
2016                         }
2017                 } else {
2018                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2019                         if (self.movetype != prefered_movetype)
2020                                 self.movetype = prefered_movetype;
2021                 }
2022         } else {
2023                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2024                         self.flags |= FL_JUMPRELEASED;
2025                         if(self.flags & FL_SPAWNING)
2026                         {
2027                                 self.flags &= ~FL_SPAWNING;
2028                                 LeaveSpectatorMode();
2029                                 return;
2030                         }
2031                 }
2032         }
2033 }
2034
2035 void SpectatorThink()
2036 {SELFPARAM();
2037         if ( self.impulse )
2038         {
2039                 if(MinigameImpulse(self.impulse))
2040                         self.impulse = 0;
2041         }
2042         if (self.flags & FL_JUMPRELEASED) {
2043                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2044                         self.flags &= ~FL_JUMPRELEASED;
2045                         self.flags |= FL_SPAWNING;
2046                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2047                         self.flags &= ~FL_JUMPRELEASED;
2048                         if(SpectateNext()) {
2049                                 self.classname = STR_SPECTATOR;
2050                         } else {
2051                                 self.classname = STR_OBSERVER;
2052                                 PutClientInServer();
2053                         }
2054                         self.impulse = 0;
2055                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2056                         self.flags &= ~FL_JUMPRELEASED;
2057                         if(SpectatePrev()) {
2058                                 self.classname = STR_SPECTATOR;
2059                         } else {
2060                                 self.classname = STR_OBSERVER;
2061                                 PutClientInServer();
2062                         }
2063                         self.impulse = 0;
2064                 } else if (self.BUTTON_ATCK2) {
2065                         self.flags &= ~FL_JUMPRELEASED;
2066                         self.classname = STR_OBSERVER;
2067                         PutClientInServer();
2068                 } else {
2069                         if(!SpectateUpdate())
2070                                 PutObserverInServer();
2071                 }
2072         } else {
2073                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2074                         self.flags |= FL_JUMPRELEASED;
2075                         if(self.flags & FL_SPAWNING)
2076                         {
2077                                 self.flags &= ~FL_SPAWNING;
2078                                 LeaveSpectatorMode();
2079                                 return;
2080                         }
2081                 }
2082                 if(!SpectateUpdate())
2083                         PutObserverInServer();
2084         }
2085
2086         self.flags |= FL_CLIENT | FL_NOTARGET;
2087 }
2088
2089 void vehicles_enter (entity pl, entity veh);
2090 void PlayerUseKey()
2091 {SELFPARAM();
2092         if (!IS_PLAYER(self))
2093                 return;
2094
2095         if(self.vehicle)
2096         {
2097                 if(!gameover)
2098                 {
2099                         vehicles_exit(VHEF_NORMAL);
2100                         return;
2101                 }
2102         }
2103         else if(autocvar_g_vehicles_enter)
2104         {
2105                 if(!self.frozen)
2106                 if(self.deadflag == DEAD_NO)
2107                 if(!gameover)
2108                 {
2109                         entity head, closest_target = world;
2110                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2111
2112                         while(head) // find the closest acceptable target to enter
2113                         {
2114                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2115                                 if(head.deadflag == DEAD_NO)
2116                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2117                                 if(head.takedamage != DAMAGE_NO)
2118                                 {
2119                                         if(closest_target)
2120                                         {
2121                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2122                                                 { closest_target = head; }
2123                                         }
2124                                         else { closest_target = head; }
2125                                 }
2126
2127                                 head = head.chain;
2128                         }
2129
2130                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2131                 }
2132         }
2133
2134         // a use key was pressed; call handlers
2135         MUTATOR_CALLHOOK(PlayerUseKey);
2136 }
2137
2138 float isInvisibleString(string s)
2139 {
2140         float i, n, c;
2141         s = strdecolorize(s);
2142         for((i = 0), (n = strlen(s)); i < n; ++i)
2143         {
2144                 c = str2chr(s, i);
2145                 switch(c)
2146                 {
2147                         case 0:
2148                         case 32: // space
2149                                 break;
2150                         case 192: // charmap space
2151                                 if (!autocvar_utf8_enable)
2152                                         break;
2153                                 return false;
2154                         case 160: // space in unicode fonts
2155                         case 0xE000 + 192: // utf8 charmap space
2156                                 if (autocvar_utf8_enable)
2157                                         break;
2158                         default:
2159                                 return false;
2160                 }
2161         }
2162         return true;
2163 }
2164
2165 /*
2166 =============
2167 PlayerPreThink
2168
2169 Called every frame for each client before the physics are run
2170 =============
2171 */
2172 .float usekeypressed;
2173 void() nexball_setstatus;
2174 .float last_vehiclecheck;
2175 .int items_added;
2176 void PlayerPreThink (void)
2177 {SELFPARAM();
2178         WarpZone_PlayerPhysics_FixVAngle();
2179
2180         self.stat_game_starttime = game_starttime;
2181         self.stat_round_starttime = round_starttime;
2182         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2183         self.stat_leadlimit = autocvar_leadlimit;
2184
2185         self.weaponsinmap = weaponsInMap;
2186
2187         if(frametime)
2188         {
2189                 // physics frames: update anticheat stuff
2190                 anticheat_prethink();
2191         }
2192
2193         if(blockSpectators && frametime)
2194                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2195                 checkSpectatorBlock();
2196
2197         zoomstate_set = 0;
2198
2199         // Savage: Check for nameless players
2200         if (isInvisibleString(self.netname)) {
2201                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2202                 if(autocvar_sv_eventlog)
2203                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2204                 if(self.netname_previous)
2205                         strunzone(self.netname_previous);
2206                 self.netname_previous = strzone(new_name);
2207                 self.netname = self.netname_previous;
2208                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2209         } else if(self.netname_previous != self.netname) {
2210                 if(autocvar_sv_eventlog)
2211                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2212                 if(self.netname_previous)
2213                         strunzone(self.netname_previous);
2214                 self.netname_previous = strzone(self.netname);
2215         }
2216
2217         // version nagging
2218         if(self.version_nagtime)
2219                 if(self.cvar_g_xonoticversion)
2220                         if(time > self.version_nagtime)
2221                         {
2222                                 // don't notify git users
2223                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2224                                 {
2225                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2226                                         {
2227                                                 // notify release users if connecting to git
2228                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2229                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2230                                         }
2231                                         else
2232                                         {
2233                                                 float r;
2234                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2235                                                 if(r < 0)
2236                                                 {
2237                                                         // give users new version
2238                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2239                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2240                                                 }
2241                                                 else if(r > 0)
2242                                                 {
2243                                                         // notify users about old server version
2244                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2245                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2246                                                 }
2247                                         }
2248                                 }
2249                                 self.version_nagtime = 0;
2250                         }
2251
2252         // GOD MODE info
2253         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2254         {
2255                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2256                 self.max_armorvalue = 0;
2257         }
2258
2259         if(self.frozen == 2)
2260         {
2261                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2262                 self.health = max(1, self.revive_progress * start_health);
2263                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2264
2265                 if(self.revive_progress >= 1)
2266                         Unfreeze(self);
2267         }
2268         else if(self.frozen == 3)
2269         {
2270                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2271                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2272
2273                 if(self.health < 1)
2274                 {
2275                         if(self.vehicle)
2276                                 vehicles_exit(VHEF_RELEASE);
2277                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2278                 }
2279                 else if ( self.revive_progress <= 0 )
2280                         Unfreeze(self);
2281         }
2282
2283         MUTATOR_CALLHOOK(PlayerPreThink);
2284
2285         if(autocvar_g_vehicles_enter)
2286         if(time > self.last_vehiclecheck)
2287         if(IS_PLAYER(self))
2288         if(!gameover)
2289         if(!self.frozen)
2290         if(!self.vehicle)
2291         if(self.deadflag == DEAD_NO)
2292         {
2293                 entity veh;
2294                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2295                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2296                 if(veh.deadflag == DEAD_NO)
2297                 if(veh.takedamage != DAMAGE_NO)
2298                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2299                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2300                 else if(!veh.owner)
2301                 if(!veh.team || SAME_TEAM(self, veh))
2302                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2303                 else if(autocvar_g_vehicles_steal)
2304                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2305
2306                 self.last_vehiclecheck = time + 1;
2307         }
2308
2309         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2310         {
2311                 if(self.BUTTON_USE && !self.usekeypressed)
2312                         PlayerUseKey();
2313                 self.usekeypressed = self.BUTTON_USE;
2314         }
2315
2316         if(IS_REAL_CLIENT(self))
2317                 PrintWelcomeMessage();
2318
2319         if(IS_PLAYER(self))
2320         {
2321
2322                 CheckRules_Player();
2323
2324                 if (intermission_running)
2325                 {
2326                         IntermissionThink ();   // otherwise a button could be missed between
2327                         return;                                 // the think tics
2328                 }
2329
2330                 //don't allow the player to turn around while game is paused!
2331                 if(timeout_status == TIMEOUT_ACTIVE) {
2332                         // FIXME turn this into CSQC stuff
2333                         self.v_angle = self.lastV_angle;
2334                         self.angles = self.lastV_angle;
2335                         self.fixangle = true;
2336                 }
2337
2338                 if(frametime)
2339                 {
2340                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2341                         {
2342                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2343                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2344                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2345
2346                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2347                                 {
2348                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2349                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2350                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2351                                 }
2352                         }
2353                         else
2354                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2355
2356                         player_powerups();
2357                 }
2358
2359                 if (self.deadflag != DEAD_NO)
2360                 {
2361                         if(self.personal && g_race_qualifying)
2362                         {
2363                                 if(time > self.respawn_time)
2364                                 {
2365                                         self.respawn_time = time + 1; // only retry once a second
2366                                         self.stat_respawn_time = self.respawn_time;
2367                                         respawn();
2368                                         self.impulse = 141;
2369                                 }
2370                         }
2371                         else
2372                         {
2373                                 float button_pressed;
2374                                 if(frametime)
2375                                         player_anim();
2376                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2377
2378                                 if (self.deadflag == DEAD_DYING)
2379                                 {
2380                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2381                                                 self.deadflag = DEAD_RESPAWNING;
2382                                         else if(!button_pressed)
2383                                                 self.deadflag = DEAD_DEAD;
2384                                 }
2385                                 else if (self.deadflag == DEAD_DEAD)
2386                                 {
2387                                         if(button_pressed)
2388                                                 self.deadflag = DEAD_RESPAWNABLE;
2389                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2390                                                 self.deadflag = DEAD_RESPAWNING;
2391                                 }
2392                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2393                                 {
2394                                         if(!button_pressed)
2395                                                 self.deadflag = DEAD_RESPAWNING;
2396                                 }
2397                                 else if (self.deadflag == DEAD_RESPAWNING)
2398                                 {
2399                                         if(time > self.respawn_time)
2400                                         {
2401                                                 self.respawn_time = time + 1; // only retry once a second
2402                                                 self.respawn_time_max = self.respawn_time;
2403                                                 respawn();
2404                                         }
2405                                 }
2406
2407                                 ShowRespawnCountdown();
2408
2409                                 if(self.respawn_flags & RESPAWN_SILENT)
2410                                         self.stat_respawn_time = 0;
2411                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2412                                         self.stat_respawn_time = self.respawn_time_max;
2413                                 else
2414                                         self.stat_respawn_time = self.respawn_time;
2415                         }
2416
2417                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2418                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2419                                 self.stat_respawn_time *= -1;
2420
2421                         return;
2422                 }
2423
2424                 self.prevorigin = self.origin;
2425
2426                 float do_crouch = self.BUTTON_CROUCH;
2427                 if(self.hook.state)
2428                         do_crouch = 0;
2429                 if(self.vehicle)
2430                         do_crouch = 0;
2431                 if(self.frozen)
2432                         do_crouch = 0;
2433
2434                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2435                 // It cannot be predicted by the engine!
2436                 int slot = 0; // TODO: unhardcode
2437                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity[slot].wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2438                         do_crouch = 0;
2439
2440                 if (do_crouch)
2441                 {
2442                         if (!self.crouch)
2443                         {
2444                                 self.crouch = true;
2445                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2446                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2447                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2448                         }
2449                 }
2450                 else
2451                 {
2452                         if (self.crouch)
2453                         {
2454                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2455                                 if (!trace_startsolid)
2456                                 {
2457                                         self.crouch = false;
2458                                         self.view_ofs = self.stat_pl_view_ofs;
2459                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2460                                 }
2461                         }
2462                 }
2463
2464                 FixPlayermodel(self);
2465
2466                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2467                 //if(frametime)
2468                 {
2469                         self.items &= ~self.items_added;
2470
2471                         W_WeaponFrame(self);
2472
2473                         self.items_added = 0;
2474                         if(self.items & ITEM_Jetpack.m_itemid)
2475                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2476                                         self.items_added |= IT_FUEL;
2477
2478                         self.items |= self.items_added;
2479                 }
2480
2481                 player_regen();
2482
2483                 // WEAPONTODO: Add a weapon request for this
2484                 // rot vortex charge to the charge limit
2485                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2486                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2487
2488                 if(frametime)
2489                         player_anim();
2490
2491                 // secret status
2492                 secrets_setstatus();
2493
2494                 // monsters status
2495                 monsters_setstatus();
2496
2497                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2498
2499                 //self.angles_y=self.v_angle_y + 90;   // temp
2500         } else if(gameover) {
2501                 if (intermission_running)
2502                         IntermissionThink ();   // otherwise a button could be missed between
2503                 return;
2504         } else if(IS_OBSERVER(self)) {
2505                 ObserverThink();
2506         } else if(IS_SPEC(self)) {
2507                 SpectatorThink();
2508         }
2509
2510         // WEAPONTODO: Add weapon request for this
2511         if(!zoomstate_set)
2512                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2513
2514         float oldspectatee_status;
2515         oldspectatee_status = self.spectatee_status;
2516         if(IS_SPEC(self))
2517                 self.spectatee_status = num_for_edict(self.enemy);
2518         else if(IS_OBSERVER(self))
2519                 self.spectatee_status = num_for_edict(self);
2520         else
2521                 self.spectatee_status = 0;
2522         if(self.spectatee_status != oldspectatee_status)
2523         {
2524                 ClientData_Touch(self);
2525         }
2526
2527         if(self.teamkill_soundtime)
2528         if(time > self.teamkill_soundtime)
2529         {
2530                 self.teamkill_soundtime = 0;
2531
2532                 setself(self.teamkill_soundsource);
2533                 entity oldpusher = self.pusher;
2534                 self.pusher = this;
2535
2536                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2537
2538                 self.pusher = oldpusher;
2539                 setself(this);
2540         }
2541
2542         if(self.taunt_soundtime)
2543         if(time > self.taunt_soundtime)
2544         {
2545                 self.taunt_soundtime = 0;
2546                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2547         }
2548
2549         target_voicescript_next(self);
2550
2551         // WEAPONTODO: Move into weaponsystem somehow
2552         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2553         if(!self.weapon)
2554                 self.clip_load = self.clip_size = 0;
2555 }
2556
2557 /*
2558 =============
2559 PlayerPostThink
2560
2561 Called every frame for each client after the physics are run
2562 =============
2563 */
2564 .float idlekick_lasttimeleft;
2565 void PlayerPostThink (void)
2566 {SELFPARAM();
2567         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2568         if(IS_REAL_CLIENT(self))
2569         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2570         {
2571                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2572                 {
2573                         if(self.idlekick_lasttimeleft)
2574                         {
2575                                 self.idlekick_lasttimeleft = 0;
2576                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2577                         }
2578                 }
2579                 else
2580                 {
2581                         float timeleft;
2582                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2583                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2584                         {
2585                                 if(!self.idlekick_lasttimeleft)
2586                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2587                         }
2588                         if(timeleft <= 0)
2589                         {
2590                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2591                                 dropclient(self);
2592                                 return;
2593                         }
2594                         else if(timeleft <= 10)
2595                         {
2596                                 if(timeleft != self.idlekick_lasttimeleft)
2597                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2598                                 self.idlekick_lasttimeleft = timeleft;
2599                         }
2600                 }
2601         }
2602
2603         CheatFrame();
2604
2605         //CheckPlayerJump();
2606
2607         if(IS_PLAYER(self)) {
2608                 CheckRules_Player();
2609                 UpdateChatBubble();
2610                 if (self.impulse)
2611                         ImpulseCommands();
2612                 if (intermission_running)
2613                         return;         // intermission or finale
2614                 GetPressedKeys();
2615         }
2616
2617         /*
2618         float i;
2619         for(i = 0; i < 1000; ++i)
2620         {
2621                 vector end;
2622                 end = self.origin + '0 0 1024' + 512 * randomvec();
2623                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2624                 if(trace_fraction < 1)
2625                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2626                 {
2627                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2628                         break;
2629                 }
2630         }
2631         */
2632
2633         if(self.waypointsprite_attachedforcarrier)
2634                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2635
2636         playerdemo_write();
2637
2638         CSQCMODEL_AUTOUPDATE(self);
2639 }