qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > autocvar_g_spawn_furthest)
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(autocvar_spawn_debugview)
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(autocvar_spawn_debug)
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(autocvar_sv_servermodelsonly)
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595         MUTATOR_CALLHOOK(MakePlayerObserver);
 596
 597         Portal_ClearAll(self);
 598
 599         if(self.alivetime)
 600         {
 601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 602                 self.alivetime = 0;
 603         }
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried && g_nexball)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         accuracy_resend(self);
 634
 635         self.spectatortime = time;
 636
 637         self.classname = "observer";
 638         self.iscreature = FALSE;
 639         self.health = -666;
 640         self.takedamage = DAMAGE_NO;
 641         self.solid = SOLID_NOT;
 642         self.movetype = MOVETYPE_NOCLIP;
 643         self.flags = FL_CLIENT | FL_NOTARGET;
 644         self.armorvalue = 666;
 645         self.effects = 0;
 646         self.armorvalue = autocvar_g_balance_armor_start;
 647         self.pauserotarmor_finished = 0;
 648         self.pauserothealth_finished = 0;
 649         self.pauseregen_finished = 0;
 650         self.damageforcescale = 0;
 651         self.death_time = 0;
 652         self.dead_frame = 0;
 653         self.alpha = 0;
 654         self.scale = 0;
 655         self.fade_time = 0;
 656         self.pain_frame = 0;
 657         self.pain_finished = 0;
 658         self.strength_finished = 0;
 659         self.invincible_finished = 0;
 660         self.pushltime = 0;
 661         self.think = SUB_Null;
 662         self.nextthink = 0;
 663         self.hook_time = 0;
 664         self.runes = 0;
 665         self.deadflag = DEAD_NO;
 666         self.angles = spot.angles;
 667         self.angles_z = 0;
 668         self.fixangle = TRUE;
 669         self.crouch = FALSE;
 670
 671         self.view_ofs = PL_VIEW_OFS;
 672         setorigin (self, spot.origin);
 673         setsize (self, '0 0 0', '0 0 0');
 674         self.prevorigin = self.origin;
 675         self.items = 0;
 676         self.weapons = 0;
 677         self.model = "";
 678         FixPlayermodel();
 679         self.model = "";
 680         self.modelindex = 0;
 681         self.weapon = 0;
 682         self.weaponmodel = "";
 683         self.weaponentity = world;
 684         self.exteriorweaponentity = world;
 685         self.killcount = -666;
 686         self.velocity = '0 0 0';
 687         self.avelocity = '0 0 0';
 688         self.punchangle = '0 0 0';
 689         self.punchvector = '0 0 0';
 690         self.oldvelocity = self.velocity;
 691         self.fire_endtime = -1;
 692
 693         if(sv_loddistance1)
 694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 695
 696         if(g_arena)
 697         {
 698                 if(self.version_mismatch)
 699                 {
 700                         Spawnqueue_Unmark(self);
 701                         Spawnqueue_Remove(self);
 702                 }
 703                 else
 704                 {
 705                         Spawnqueue_Insert(self);
 706                 }
 707         }
 708         else if(g_lms)
 709         {
 710                 // Only if the player cannot play at all
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 712                         self.frags = FRAGS_SPECTATOR;
 713                 else
 714                         self.frags = FRAGS_LMS_LOSER;
 715         }
 716         else
 717                 self.frags = FRAGS_SPECTATOR;
 718 }
 719
 720 void FixPlayermodel()
 721 {
 722         local string defaultmodel;
 723         local float defaultskin, chmdl, oldskin;
 724         local vector m1, m2;
 725
 726         defaultmodel = "";
 727
 728         if(autocvar_sv_defaultcharacter == 1) {
 729                 defaultskin = 0;
 730
 731                 if(teams_matter)
 732                 {
 733                         string s;
 734                         s = Team_ColorNameLowerCase(self.team);
 735                         if(s != "neutral")
 736                         {
 737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 739                         }
 740                 }
 741
 742                 if(defaultmodel == "")
 743                 {
 744                         defaultmodel = autocvar_sv_defaultplayermodel;
 745                         defaultskin = autocvar_sv_defaultplayerskin;
 746                 }
 747         }
 748
 749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 750         {
 751                 if(self.model != "")
 752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 753                 self.model = ""; // force the != checks to return true
 754         }
 755
 756         if(defaultmodel != "")
 757         {
 758                 if (defaultmodel != self.model)
 759                 {
 760                         m1 = self.mins;
 761                         m2 = self.maxs;
 762                         setmodel_lod (self, defaultmodel);
 763                         setsize (self, m1, m2);
 764                         chmdl = TRUE;
 765                 }
 766
 767                 oldskin = self.skinindex;
 768                 self.skinindex = defaultskin;
 769         } else {
 770                 if (self.playermodel != self.model || self.playermodel == "")
 771                 {
 772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 773                         m1 = self.mins;
 774                         m2 = self.maxs;
 775                         setmodel_lod (self, self.playermodel);
 776                         setsize (self, m1, m2);
 777                         chmdl = TRUE;
 778                 }
 779
 780                 oldskin = self.skinindex;
 781                 self.skinindex = stof(self.playerskin);
 782         }
 783
 784         if(chmdl || oldskin != self.skinindex)
 785                 self.species = player_getspecies(); // model or skin has changed
 786
 787         if(!teams_matter)
 788                 if(strlen(autocvar_sv_defaultplayercolors))
 789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 791 }
 792
 793 void PlayerTouchExplode(entity p1, entity p2)
 794 {
 795         vector org;
 796         org = (p1.origin + p2.origin) * 0.5;
 797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 798
 799         te_explosion(org);
 800
 801         entity e;
 802         e = spawn();
 803         setorigin(e, org);
 804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 805         remove(e);
 806 }
 807
 808 /*
 809 =============
 810 PutClientInServer
 811
 812 Called when a client spawns in the server
 813 =============
 814 */
 815 //void() ctf_playerchanged;
 816 void PutClientInServer (void)
 817 {
 818         if(clienttype(self) == CLIENTTYPE_BOT)
 819         {
 820                 self.classname = "player";
 821         }
 822         else if(clienttype(self) == CLIENTTYPE_REAL)
 823         {
 824                 msg_entity = self;
 825                 WriteByte(MSG_ONE, SVC_SETVIEW);
 826                 WriteEntity(MSG_ONE, self);
 827         }
 828
 829         // player is dead and becomes observer
 830         // FIXME fix LMS scoring for new system
 831         if(g_lms)
 832         {
 833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 834                         self.classname = "observer";
 835         }
 836
 837         if(g_arena || (g_ca && !allowed_to_spawn))
 838         if(!self.spawned)
 839                 self.classname = "observer";
 840
 841         if(gameover)
 842                 self.classname = "observer";
 843
 844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 845                 entity spot, oldself;
 846                 float j;
 847
 848                 accuracy_resend(self);
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 870                 if(autocvar_g_playerclip_collisions)
 871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 874                 self.frags = FRAGS_PLAYER;
 875                 if(independent_players)
 876                         MAKE_INDEPENDENT_PLAYER(self);
 877                 self.flags = FL_CLIENT;
 878                 self.takedamage = DAMAGE_AIM;
 879                 if(g_minstagib)
 880                         self.effects = EF_FULLBRIGHT;
 881                 else
 882                         self.effects = 0;
 883                 self.air_finished = time + 12;
 884                 self.dmg = 2;
 885                 if(autocvar_g_balance_nex_charge)
 886                 {
 887                         if(autocvar_g_balance_nex_secondary_chargepool)
 888                                 self.nex_chargepool_ammo = 1;
 889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 890                 }
 891
 892                 // all weapons must be fully loaded the first time we pick them up, so set their load to maximum at respawn
 893                 self.shotgun_load = autocvar_g_balance_shotgun_reload_ammo;
 894                 self.sniperrifle_load = autocvar_g_balance_sniperrifle_reload_ammo;
 895                 self.uzi_load = autocvar_g_balance_uzi_reload_ammo;
 896                 self.grenadelauncher_load = autocvar_g_balance_grenadelauncher_reload_ammo;
 897                 self.minelayer_load = autocvar_g_balance_minelayer_reload_ammo;
 898                 self.electro_load = autocvar_g_balance_electro_reload_ammo;
 899                 self.crylink_load = autocvar_g_balance_crylink_reload_ammo;
 900                 self.hlac_load = autocvar_g_balance_hlac_reload_ammo;
 901
 902                 if(inWarmupStage)
 903                 {
 904                         self.ammo_shells = warmup_start_ammo_shells;
 905                         self.ammo_nails = warmup_start_ammo_nails;
 906                         self.ammo_rockets = warmup_start_ammo_rockets;
 907                         self.ammo_cells = warmup_start_ammo_cells;
 908                         self.ammo_fuel = warmup_start_ammo_fuel;
 909                         self.health = warmup_start_health;
 910                         self.armorvalue = warmup_start_armorvalue;
 911                         self.weapons = warmup_start_weapons;
 912                 }
 913                 else
 914                 {
 915                         self.ammo_shells = start_ammo_shells;
 916                         self.ammo_nails = start_ammo_nails;
 917                         self.ammo_rockets = start_ammo_rockets;
 918                         self.ammo_cells = start_ammo_cells;
 919                         self.ammo_fuel = start_ammo_fuel;
 920                         self.health = start_health;
 921                         self.armorvalue = start_armorvalue;
 922                         self.weapons = start_weapons;
 923                 }
 924
 925                 if(g_weaponarena_random)
 926                 {
 927                         if(g_weaponarena_random_with_laser)
 928                                 self.weapons &~= WEPBIT_LASER;
 929                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 930                         if(g_weaponarena_random_with_laser)
 931                                 self.weapons |= WEPBIT_LASER;
 932                 }
 933
 934                 self.items = start_items;
 935                 self.jump_interval = time;
 936
 937                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 938                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 939                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 940                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 941                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 942                 //extend the pause of rotting if client was reset at the beginning of the countdown
 943                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 944                         self.spawnshieldtime += game_starttime - time;
 945                         self.pauserotarmor_finished += game_starttime - time;
 946                         self.pauserothealth_finished += game_starttime - time;
 947                         self.pauseregen_finished += game_starttime - time;
 948                 }
 949                 self.damageforcescale = 2;
 950                 self.death_time = 0;
 951                 self.dead_frame = 0;
 952                 self.alpha = 0;
 953                 self.scale = 0;
 954                 self.fade_time = 0;
 955                 self.pain_frame = 0;
 956                 self.pain_finished = 0;
 957                 self.strength_finished = 0;
 958                 self.invincible_finished = 0;
 959                 self.pushltime = 0;
 960                 // players have no think function
 961                 self.think = SUB_Null;
 962                 self.nextthink = 0;
 963                 self.hook_time = 0;
 964                 self.dmg_team = 0;
 965                 self.ballistics_density = autocvar_g_ballistics_density_player;
 966
 967                 self.metertime = 0;
 968
 969                 self.runes = 0;
 970
 971                 self.deadflag = DEAD_NO;
 972
 973                 self.angles = spot.angles;
 974
 975                 self.angles_z = 0; // never spawn tilted even if the spot says to
 976                 self.fixangle = TRUE; // turn this way immediately
 977                 self.velocity = '0 0 0';
 978                 self.avelocity = '0 0 0';
 979                 self.punchangle = '0 0 0';
 980                 self.punchvector = '0 0 0';
 981                 self.oldvelocity = self.velocity;
 982                 self.fire_endtime = -1;
 983
 984                 msg_entity = self;
 985                 WRITESPECTATABLE_MSG_ONE({
 986                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 987                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 988                 });
 989
 990                 if(sv_loddistance1)
 991                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 992
 993                 self.model = "";
 994                 FixPlayermodel();
 995
 996                 self.crouch = FALSE;
 997                 self.view_ofs = PL_VIEW_OFS;
 998                 setsize (self, PL_MIN, PL_MAX);
 999                 self.spawnorigin = spot.origin;
1000                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1001                 // don't reset back to last position, even if new position is stuck in solid
1002                 self.oldorigin = self.origin;
1003                 self.prevorigin = self.origin;
1004                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1005
1006                 if(g_arena)
1007                 {
1008                         Spawnqueue_Remove(self);
1009                         Spawnqueue_Mark(self);
1010                 }
1011
1012                 else if(g_ca)
1013                         self.caplayer = 1;
1014
1015                 self.event_damage = PlayerDamage;
1016
1017                 self.bot_attack = TRUE;
1018
1019                 self.statdraintime = time + 5;
1020                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1021
1022                 if(self.killcount == -666) {
1023                         PlayerScore_Clear(self);
1024                         self.killcount = 0;
1025                 }
1026
1027                 self.cnt = WEP_LASER;
1028
1029                 CL_SpawnWeaponentity();
1030                 self.alpha = default_player_alpha;
1031                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1032                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1033
1034                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1035                 self.lms_traveled_distance = 0;
1036                 self.speedrunning = FALSE;
1037
1038                 race_PostSpawn(spot);
1039
1040                 if(autocvar_spawn_debug)
1041                 {
1042                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1043                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1044                 }
1045
1046                 //stuffcmd(self, "chase_active 0");
1047                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1048
1049                 if (autocvar_g_spawnsound)
1050                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1051
1052                 if(g_assault) {
1053                         if(self.team == assault_attacker_team)
1054                                 centerprint(self, "You are attacking!");
1055                         else
1056                                 centerprint(self, "You are defending!");
1057                 }
1058
1059                 target_voicescript_clear(self);
1060
1061                 // reset fields the weapons may use
1062                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1063                         weapon_action(j, WR_RESETPLAYER);
1064
1065                 oldself = self;
1066                 self = spot;
1067                         activator = oldself;
1068                                 SUB_UseTargets();
1069                         activator = world;
1070                 self = oldself;
1071
1072                 MUTATOR_CALLHOOK(PlayerSpawn);
1073
1074                 self.switchweapon = w_getbestweapon(self);
1075                 self.cnt = self.switchweapon;
1076                 self.weapon = 0;
1077
1078                 if(!self.alivetime)
1079                         self.alivetime = time;
1080         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1081                 PutObserverInServer ();
1082         }
1083
1084         //if(g_ctf)
1085         //      ctf_playerchanged();
1086 }
1087
1088 .float ebouncefactor, ebouncestop; // electro's values
1089 // TODO do we need all these fields, or should we stop autodetecting runtime
1090 // changes and just have a console command to update this?
1091 float ClientInit_SendEntity(entity to, float sf)
1092 {
1093         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1094         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1107         if(sv_foginterval && world.fog != "")
1108                 WriteString(MSG_ENTITY, world.fog);
1109         else
1110                 WriteString(MSG_ENTITY, "");
1111         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1112         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1113         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1114         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1115         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1116         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1117         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1118         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1119         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1120         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1121         return TRUE;
1122 }
1123
1124 void ClientInit_CheckUpdate()
1125 {
1126         self.nextthink = time;
1127         if(self.count != autocvar_g_balance_armor_blockpercent)
1128         {
1129                 self.count = autocvar_g_balance_armor_blockpercent;
1130                 self.SendFlags |= 1;
1131         }
1132         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1133         {
1134                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1138         {
1139                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1143         {
1144                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1148         {
1149                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1153         {
1154                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1155                 self.SendFlags |= 1;
1156         }
1157 }
1158
1159 void ClientInit_Spawn()
1160 {
1161         entity o;
1162         entity e;
1163         e = spawn();
1164         e.classname = "clientinit";
1165         e.think = ClientInit_CheckUpdate;
1166         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1167
1168         o = self;
1169         self = e;
1170         ClientInit_CheckUpdate();
1171         self = o;
1172 }
1173
1174 /*
1175 =============
1176 SetNewParms
1177 =============
1178 */
1179 void SetNewParms (void)
1180 {
1181         // initialize parms for a new player
1182         parm1 = -(86400 * 366);
1183 }
1184
1185 /*
1186 =============
1187 SetChangeParms
1188 =============
1189 */
1190 void SetChangeParms (void)
1191 {
1192         // save parms for level change
1193         parm1 = self.parm_idlesince - time;
1194 }
1195
1196 /*
1197 =============
1198 DecodeLevelParms
1199 =============
1200 */
1201 void DecodeLevelParms (void)
1202 {
1203         // load parms
1204         self.parm_idlesince = parm1;
1205         if(self.parm_idlesince == -(86400 * 366))
1206                 self.parm_idlesince = time;
1207
1208         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1209         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1210 }
1211
1212 /*
1213 =============
1214 ClientKill
1215
1216 Called when a client types 'kill' in the console
1217 =============
1218 */
1219
1220 .float clientkill_nexttime;
1221 void ClientKill_Now_TeamChange()
1222 {
1223         if(self.killindicator_teamchange == -1)
1224         {
1225                 self.team = -1;
1226                 JoinBestTeam( self, FALSE, FALSE );
1227         }
1228         else if(self.killindicator_teamchange == -2)
1229         {
1230                 if(g_ca)
1231                         self.caplayer = 0;
1232                 if(blockSpectators)
1233                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1234                 PutObserverInServer();
1235         }
1236         else
1237                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1238 }
1239
1240 void ClientKill_Now()
1241 {
1242         remove(self.killindicator);
1243         self.killindicator = world;
1244
1245         if(self.killindicator_teamchange)
1246                 ClientKill_Now_TeamChange();
1247
1248         // in any case:
1249         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1250
1251         // now I am sure the player IS dead
1252 }
1253 void KillIndicator_Think()
1254 {
1255         if (!self.owner.modelindex)
1256         {
1257                 self.owner.killindicator = world;
1258                 remove(self);
1259                 return;
1260         }
1261
1262         if(self.cnt <= 0)
1263         {
1264                 self = self.owner;
1265                 ClientKill_Now(); // no oldself needed
1266                 return;
1267         }
1268     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1269     {
1270         self.nextthink = time + 1;
1271         self.cnt -= 1;
1272     }
1273         else
1274         {
1275                 if(self.cnt <= 10)
1276                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1277                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1278                 {
1279                         if(self.cnt <= 10)
1280                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1281                         if(self.owner.killindicator_teamchange)
1282                         {
1283                                 if(self.owner.killindicator_teamchange == -1)
1284                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1285                                 else if(self.owner.killindicator_teamchange == -2)
1286                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1287                                 else
1288                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1289                         }
1290                         else
1291                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1292                 }
1293                 self.nextthink = time + 1;
1294                 self.cnt -= 1;
1295         }
1296 }
1297
1298 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1299 {
1300         float killtime;
1301         entity e;
1302         killtime = autocvar_g_balance_kill_delay;
1303
1304         if(g_race_qualifying || g_cts)
1305                 killtime = 0;
1306
1307     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1308     {
1309                 remove(self.killindicator);
1310                 self.killindicator = world;
1311
1312         ClientKill_Now(); // allow instant kill in this case
1313         return;
1314     }
1315
1316         self.killindicator_teamchange = targetteam;
1317
1318     if(!self.killindicator)
1319         {
1320                 if(self.modelindex && self.deadflag == DEAD_NO)
1321                 {
1322                         killtime = max(killtime, self.clientkill_nexttime - time);
1323                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1324                 }
1325
1326                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1327                 {
1328                         ClientKill_Now();
1329                 }
1330                 else
1331                 {
1332                         self.killindicator = spawn();
1333                         self.killindicator.owner = self;
1334                         self.killindicator.scale = 0.5;
1335                         setattachment(self.killindicator, self, "");
1336                         setorigin(self.killindicator, '0 0 52');
1337                         self.killindicator.think = KillIndicator_Think;
1338                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1339                         self.killindicator.cnt = ceil(killtime);
1340                         self.killindicator.count = bound(0, ceil(killtime), 10);
1341                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1342
1343                         for(e = world; (e = find(e, classname, "body")) != world; )
1344                         {
1345                                 if(e.enemy != self)
1346                                         continue;
1347                                 e.killindicator = spawn();
1348                                 e.killindicator.owner = e;
1349                                 e.killindicator.scale = 0.5;
1350                                 setattachment(e.killindicator, e, "");
1351                                 setorigin(e.killindicator, '0 0 52');
1352                                 e.killindicator.think = KillIndicator_Think;
1353                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1354                                 e.killindicator.cnt = ceil(killtime);
1355                         }
1356                         self.lip = 0;
1357                 }
1358         }
1359         if(self.killindicator)
1360         {
1361                 if(targetteam == 0) // just die
1362                         self.killindicator.colormod = '0 0 0';
1363                 else if(targetteam == -1) // auto
1364                         self.killindicator.colormod = '0 1 0';
1365                 else if(targetteam == -2) // spectate
1366                         self.killindicator.colormod = '0.5 0.5 0.5';
1367                 else
1368                         self.killindicator.colormod = TeamColor(targetteam);
1369         }
1370 }
1371
1372 void ClientKill (void)
1373 {
1374         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1375         {
1376                 // do nothing
1377         }
1378     else if(self.freezetag_frozen)
1379     {
1380         // do nothing
1381     }
1382         else
1383                 ClientKill_TeamChange(0);
1384 }
1385
1386 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1387 {
1388     e.killindicator = spawn();
1389     e.killindicator.owner = e;
1390     e.killindicator.think = KillIndicator_Think;
1391     e.killindicator.nextthink = time + (e.lip) * 0.05;
1392     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1393     e.killindicator.health = 1; // this is used to indicate that it should be silent
1394     e.lip = 0;
1395 }
1396
1397 void DoTeamChange(float destteam)
1398 {
1399         float t, c0;
1400         if(!teams_matter)
1401         {
1402                 if(destteam >= 0)
1403                         SetPlayerColors(self, destteam);
1404                 return;
1405         }
1406         if(self.classname == "player")
1407         if(destteam == -1)
1408         {
1409                 CheckAllowedTeams(self);
1410                 t = FindSmallestTeam(self, TRUE);
1411                 switch(self.team)
1412                 {
1413                         case COLOR_TEAM1: c0 = c1; break;
1414                         case COLOR_TEAM2: c0 = c2; break;
1415                         case COLOR_TEAM3: c0 = c3; break;
1416                         case COLOR_TEAM4: c0 = c4; break;
1417                         default:          c0 = 999;
1418                 }
1419                 switch(t)
1420                 {
1421                         case 1:
1422                                 if(c0 > c1)
1423                                         destteam = COLOR_TEAM1;
1424                                 break;
1425                         case 2:
1426                                 if(c0 > c2)
1427                                         destteam = COLOR_TEAM2;
1428                                 break;
1429                         case 3:
1430                                 if(c0 > c3)
1431                                         destteam = COLOR_TEAM3;
1432                                 break;
1433                         case 4:
1434                                 if(c0 > c4)
1435                                         destteam = COLOR_TEAM4;
1436                                 break;
1437                 }
1438                 if(destteam == -1)
1439                         return;
1440         }
1441         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1442                 return;
1443         ClientKill_TeamChange(destteam);
1444 }
1445
1446 void FixClientCvars(entity e)
1447 {
1448         // send prediction settings to the client
1449         stuffcmd(e, "\nin_bindmap 0 0\n");
1450         if(g_race || g_cts)
1451                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1452         if(autocvar_g_antilag == 3) // client side hitscan
1453                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1454         if(sv_gentle)
1455                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1456         /*
1457          * we no longer need to stuff this. Remove this comment block if you feel
1458          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1459         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1460         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1461         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1462         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1463         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1464         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1465         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1466         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1467         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1468         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1469         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1470         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1471         stuffcmd(e, "cl_movement_edgefriction 1\n");
1472          */
1473 }
1474
1475 float PlayerInIDList(entity p, string idlist)
1476 {
1477         float n, i;
1478         string s;
1479
1480         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1481         if not(p.crypto_idfp)
1482                 return 0;
1483
1484         // this function allows abbreviated player IDs too!
1485         n = tokenize_console(idlist);
1486         for(i = 0; i < n; ++i)
1487         {
1488                 s = argv(i);
1489                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1490                         return 1;
1491         }
1492
1493         return 0;
1494 }
1495
1496 /*
1497 =============
1498 ClientConnect
1499
1500 Called when a client connects to the server
1501 =============
1502 */
1503 //void ctf_clientconnect();
1504 string ColoredTeamName(float t);
1505 void DecodeLevelParms (void);
1506 //void dom_player_join_team(entity pl);
1507 void ClientConnect (void)
1508 {
1509         float t;
1510
1511         if(self.flags & FL_CLIENT)
1512         {
1513                 print("Warning: ClientConnect, but already connected!\n");
1514                 return;
1515         }
1516
1517         if(Ban_MaybeEnforceBan(self))
1518                 return;
1519
1520         DecodeLevelParms();
1521
1522 #ifdef WATERMARK
1523         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1524 #endif
1525
1526         self.classname = "player_joining";
1527
1528         self.flags = FL_CLIENT;
1529         self.version_nagtime = time + 10 + random() * 10;
1530
1531         if(player_count<0)
1532         {
1533                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1534                 player_count = 0;
1535         }
1536
1537         PlayerScore_Attach(self);
1538         ClientData_Attach();
1539         accuracy_init(self);
1540
1541         bot_clientconnect();
1542
1543         playerdemo_init();
1544
1545         anticheat_init();
1546
1547         race_PreSpawnObserver();
1548
1549         //if(g_domination)
1550         //      dom_player_join_team(self);
1551
1552         // identify the right forced team
1553         if(autocvar_g_campaign)
1554         {
1555                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1556                 {
1557                         switch(autocvar_g_campaign_forceteam)
1558                         {
1559                                 case 1: self.team_forced = COLOR_TEAM1; break;
1560                                 case 2: self.team_forced = COLOR_TEAM2; break;
1561                                 case 3: self.team_forced = COLOR_TEAM3; break;
1562                                 case 4: self.team_forced = COLOR_TEAM4; break;
1563                                 default: self.team_forced = 0;
1564                         }
1565                 }
1566         }
1567         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1568                 self.team_forced = COLOR_TEAM1;
1569         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1570                 self.team_forced = COLOR_TEAM2;
1571         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1572                 self.team_forced = COLOR_TEAM3;
1573         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1574                 self.team_forced = COLOR_TEAM4;
1575         else if(autocvar_g_forced_team_otherwise == "red")
1576                 self.team_forced = COLOR_TEAM1;
1577         else if(autocvar_g_forced_team_otherwise == "blue")
1578                 self.team_forced = COLOR_TEAM2;
1579         else if(autocvar_g_forced_team_otherwise == "yellow")
1580                 self.team_forced = COLOR_TEAM3;
1581         else if(autocvar_g_forced_team_otherwise == "pink")
1582                 self.team_forced = COLOR_TEAM4;
1583         else if(autocvar_g_forced_team_otherwise == "spectate")
1584                 self.team_forced = -1;
1585         else if(autocvar_g_forced_team_otherwise == "spectator")
1586                 self.team_forced = -1;
1587         else
1588                 self.team_forced = 0;
1589
1590         if(!teams_matter)
1591                 if(self.team_forced > 0)
1592                         self.team_forced = 0;
1593
1594         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1595
1596         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1597                 self.classname = "observer";
1598         } else {
1599                 if(teams_matter)
1600                 {
1601                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1602                         {
1603                                 self.classname = "player";
1604                                 campaign_bots_may_start = 1;
1605                         }
1606                         else
1607                         {
1608                                 self.classname = "observer"; // do it anyway
1609                         }
1610                 }
1611                 else
1612                 {
1613                         self.classname = "player";
1614                         campaign_bots_may_start = 1;
1615                 }
1616         }
1617
1618         self.playerid = (playerid_last = playerid_last + 1);
1619
1620         if(autocvar_sv_eventlog)
1621                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1622
1623         LogTeamchange(self.playerid, self.team, 1);
1624
1625         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1626
1627         self.netname_previous = strzone(self.netname);
1628
1629         bprint("^4", self.netname, "^4 connected");
1630
1631         if(self.classname != "observer" && (g_domination || g_ctf))
1632                 bprint(" and joined the ", ColoredTeamName(self.team));
1633
1634         bprint("\n");
1635
1636         self.welcomemessage_time = 0;
1637
1638         stuffcmd(self, strcat(clientstuff, "\n"));
1639         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1640         stuffcmd(self, "cl_particles_reloadeffects\n");
1641
1642         FixClientCvars(self);
1643
1644         // spawnfunc_waypoint sprites
1645         WaypointSprite_InitClient(self);
1646
1647         // Wazat's grappling hook
1648         SetGrappleHookBindings();
1649
1650         // get autoswitch state from player when he toggles it
1651         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1652
1653         // get version info from player
1654         stuffcmd(self, "cmd clientversion $gameversion\n");
1655
1656         // get other cvars from player
1657         GetCvars(0);
1658
1659         // notify about available teams
1660         if(teams_matter)
1661         {
1662                 CheckAllowedTeams(self);
1663                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1664                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1665         }
1666         else
1667                 stuffcmd(self, "set _teams_available 0\n");
1668
1669         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1670
1671         if(g_arena || g_ca)
1672         {
1673                 self.classname = "observer";
1674                 if(g_arena)
1675                         Spawnqueue_Insert(self);
1676         }
1677         /*else if(g_ctf)
1678         {
1679                 ctf_clientconnect();
1680         }*/
1681
1682         if(teams_matter || radar_showennemies)
1683                 attach_entcs();
1684
1685         bot_relinkplayerlist();
1686
1687         self.spectatortime = time;
1688         if(blockSpectators)
1689         {
1690                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1691         }
1692
1693         self.jointime = time;
1694         self.allowedTimeouts = autocvar_sv_timeout_number;
1695
1696         if(clienttype(self) == CLIENTTYPE_REAL)
1697         {
1698                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1699                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1700         }
1701
1702         if(g_lms)
1703         {
1704                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1705                 {
1706                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1707                         self.frags = FRAGS_SPECTATOR;
1708                 }
1709         }
1710
1711         if(!sv_foginterval && world.fog != "")
1712                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1713
1714         SoundEntity_Attach(self);
1715
1716         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1717         {
1718                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1719                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1720         }
1721         else
1722                 self.hitplotfh = -1;
1723
1724         if(g_race || g_cts) {
1725                 string rr;
1726                 if(g_cts)
1727                         rr = CTS_RECORD;
1728                 else
1729                         rr = RACE_RECORD;
1730                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1731
1732                 msg_entity = self;
1733                 race_send_recordtime(MSG_ONE);
1734                 race_send_speedaward(MSG_ONE);
1735
1736                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1737                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1738                 race_send_speedaward_alltimebest(MSG_ONE);
1739
1740                 float i;
1741                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1742                         race_SendRankings(i, 0, 0, MSG_ONE);
1743                 }
1744         }
1745         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1746                 send_CSQC_teamnagger();
1747
1748         CheatInitClient();
1749
1750         PlayerStats_AddPlayer(self);
1751 }
1752
1753 /*
1754 =============
1755 ClientDisconnect
1756
1757 Called when a client disconnects from the server
1758 =============
1759 */
1760 .entity chatbubbleentity;
1761 .entity teambubbleentity;
1762 void ReadyCount();
1763 void ClientDisconnect (void)
1764 {
1765         if not(self.flags & FL_CLIENT)
1766         {
1767                 print("Warning: ClientDisconnect without ClientConnect\n");
1768                 return;
1769         }
1770
1771         PlayerStats_AddGlobalInfo(self);
1772
1773         CheatShutdownClient();
1774
1775         if(self.hitplotfh >= 0)
1776         {
1777                 fclose(self.hitplotfh);
1778                 self.hitplotfh = -1;
1779         }
1780
1781         anticheat_report();
1782         anticheat_shutdown();
1783
1784         playerdemo_shutdown();
1785
1786         bot_clientdisconnect();
1787
1788         if(self.entcs)
1789                 detach_entcs();
1790
1791         if(autocvar_sv_eventlog)
1792                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1793         bprint ("^4",self.netname);
1794         bprint ("^4 disconnected\n");
1795
1796         SoundEntity_Detach(self);
1797
1798         DropAllRunes(self);
1799         MUTATOR_CALLHOOK(ClientDisconnect);
1800
1801         Portal_ClearAll(self);
1802
1803         if(self.flagcarried)
1804                 DropFlag(self.flagcarried, world, world);
1805         if(self.ballcarried && g_nexball)
1806                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1807
1808         // Here, everything has been done that requires this player to be a client.
1809
1810         self.flags &~= FL_CLIENT;
1811
1812         if (self.chatbubbleentity)
1813                 remove (self.chatbubbleentity);
1814
1815         if (self.teambubbleentity)
1816                 remove (self.teambubbleentity);
1817
1818         if (self.killindicator)
1819                 remove (self.killindicator);
1820
1821         WaypointSprite_PlayerGone();
1822
1823         bot_relinkplayerlist();
1824
1825         if(g_arena)
1826         {
1827                 Spawnqueue_Unmark(self);
1828                 Spawnqueue_Remove(self);
1829         }
1830
1831         accuracy_free(self);
1832         ClientData_Detach();
1833         PlayerScore_Detach(self);
1834
1835         if(self.netname_previous)
1836                 strunzone(self.netname_previous);
1837         if(self.clientstatus)
1838                 strunzone(self.clientstatus);
1839         if(self.weaponorder_byimpulse)
1840                 strunzone(self.weaponorder_byimpulse);
1841
1842         ClearPlayerSounds();
1843
1844         if(self.personal)
1845                 remove(self.personal);
1846
1847         self.playerid = 0;
1848         ReadyCount();
1849
1850         // free cvars
1851         GetCvars(-1);
1852 }
1853
1854 .float BUTTON_CHAT;
1855 void ChatBubbleThink()
1856 {
1857         self.nextthink = time;
1858         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1859         {
1860                 if(self.owner) // but why can that ever be world?
1861                         self.owner.chatbubbleentity = world;
1862                 remove(self);
1863                 return;
1864         }
1865         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1866 #ifdef TETRIS
1867                 || self.owner.tetris_on
1868 #endif
1869         )
1870                 self.model = self.mdl;
1871         else
1872                 self.model = "";
1873 };
1874
1875 void UpdateChatBubble()
1876 {
1877         if (!self.modelindex)
1878                 return;
1879         // spawn a chatbubble entity if needed
1880         if (!self.chatbubbleentity)
1881         {
1882                 self.chatbubbleentity = spawn();
1883                 self.chatbubbleentity.owner = self;
1884                 self.chatbubbleentity.exteriormodeltoclient = self;
1885                 self.chatbubbleentity.think = ChatBubbleThink;
1886                 self.chatbubbleentity.nextthink = time;
1887                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1888                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1889                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1890                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1891                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1892                 self.chatbubbleentity.model = "";
1893                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1894         }
1895 }
1896
1897
1898 void TeamBubbleThink()
1899 {
1900         self.nextthink = time;
1901         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1902         {
1903                 if(self.owner) // but why can that ever be world?
1904                         self.owner.teambubbleentity = world;
1905                 remove(self);
1906                 return;
1907         }
1908 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1909         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1910                 self.model = "";
1911         else
1912                 self.model = self.mdl;
1913
1914 };
1915
1916 float TeamBubble_customizeentityforclient()
1917 {
1918         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1919 }
1920
1921 void UpdateTeamBubble()
1922 {
1923         if (!self.modelindex || !teams_matter)
1924                 return;
1925         // spawn a teambubble entity if needed
1926         if (!self.teambubbleentity && teams_matter)
1927         {
1928                 self.teambubbleentity = spawn();
1929                 self.teambubbleentity.owner = self;
1930                 self.teambubbleentity.exteriormodeltoclient = self;
1931                 self.teambubbleentity.think = TeamBubbleThink;
1932                 self.teambubbleentity.nextthink = time;
1933                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1934 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1935                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1936                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1937                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1938                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1939                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1940                 self.teambubbleentity.effects = EF_LOWPRECISION;
1941         }
1942 }
1943
1944 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1945 // added to the model skins
1946 /*void UpdateColorModHack()
1947 {
1948         local float c;
1949         c = self.clientcolors & 15;
1950         // LordHavoc: only bothering to support white, green, red, yellow, blue
1951              if (!teams_matter) self.colormod = '0 0 0';
1952         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1953         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1954         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1955         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1956         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1957         else self.colormod = '1 1 1';
1958 };*/
1959
1960 .float oldcolormap;
1961 void respawn(void)
1962 {
1963         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1964         {
1965                 self.solid = SOLID_NOT;
1966                 self.takedamage = DAMAGE_NO;
1967                 self.movetype = MOVETYPE_FLY;
1968                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1969                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1970                 self.effects |= EF_ADDITIVE;
1971                 self.oldcolormap = self.colormap;
1972                 self.colormap = 512;
1973                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1974                 if(autocvar_g_respawn_ghosts_maxtime)
1975                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1976         }
1977
1978         CopyBody(1);
1979         self.effects |= EF_NODRAW; // prevent another CopyBody
1980         if(self.oldcolormap)
1981         {
1982                 self.colormap = self.oldcolormap;
1983                 self.oldcolormap = 0;
1984         }
1985         PutClientInServer();
1986 }
1987
1988 void play_countdown(float finished, string samp)
1989 {
1990         if(clienttype(self) == CLIENTTYPE_REAL)
1991                 if(floor(finished - time - frametime) != floor(finished - time))
1992                         if(finished - time < 6)
1993                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1994 }
1995
1996 /**
1997  * When sv_timeout is used this function returs strings like
1998  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1999  * Called by centerprint functions
2000  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2001  */
2002 string getTimeoutText(float addOneSecond) {
2003         if (!autocvar_sv_timeout || !timeoutStatus)
2004                 return "";
2005
2006         local string retStr;
2007         if (timeoutStatus == 1) {
2008                 if (addOneSecond == 1) {
2009                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2010                 }
2011                 else {
2012                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2013                 }
2014                 return retStr;
2015         }
2016         else if (timeoutStatus == 2) {
2017                 if (addOneSecond) {
2018                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2019                         //don't show messages like "Timeout ends in 0 seconds"...
2020                         if ((remainingTimeoutTime + 1) > 0)
2021                                 return retStr;
2022                         else
2023                                 return "";
2024                 }
2025                 else {
2026                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2027                         //don't show messages like "Timeout ends in 0 seconds"...
2028                         if (remainingTimeoutTime > 0)
2029                                 return retStr;
2030                         else
2031                                 return "";
2032                 }
2033         }
2034         else return "";
2035 }
2036
2037 void player_powerups (void)
2038 {
2039         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2040         olditems = self.items;
2041
2042         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2043         {
2044                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2045                 self.modelflags |= MF_ROCKET;
2046         }
2047         else
2048         {
2049                 SoundEntity_StopSound(self, CHAN_PLAYER);
2050                 self.modelflags &~= MF_ROCKET;
2051         }
2052
2053         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2054
2055         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2056                 return;
2057
2058         Fire_ApplyDamage(self);
2059         Fire_ApplyEffect(self);
2060
2061         if (g_minstagib)
2062         {
2063                 self.effects |= EF_FULLBRIGHT;
2064
2065                 if (self.items & IT_STRENGTH)
2066                 {
2067                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2068                         if (time > self.strength_finished)
2069                         {
2070                                 self.alpha = default_player_alpha;
2071                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2072                                 self.items &~= IT_STRENGTH;
2073                                 sprint(self, "^3Invisibility has worn off\n");
2074                         }
2075                 }
2076                 else
2077                 {
2078                         if (time < self.strength_finished)
2079                         {
2080                                 self.alpha = g_minstagib_invis_alpha;
2081                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2082                                 self.items |= IT_STRENGTH;
2083                                 sprint(self, "^3You are invisible\n");
2084                         }
2085                 }
2086
2087                 if (self.items & IT_INVINCIBLE)
2088                 {
2089                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2090                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2091                         {
2092                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2093                                 sprint(self, "^3Speed has worn off\n");
2094                         }
2095                 }
2096                 else
2097                 {
2098                         if (time < self.invincible_finished)
2099                         {
2100                                 self.items = self.items | IT_INVINCIBLE;
2101                                 sprint(self, "^3You are on speed\n");
2102                         }
2103                 }
2104         }
2105         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2106         {
2107                 if (self.items & IT_STRENGTH)
2108                 {
2109                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2110                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2111                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2112                         {
2113                                 self.items = self.items - (self.items & IT_STRENGTH);
2114                                 sprint(self, "^3Strength has worn off\n");
2115                         }
2116                 }
2117                 else
2118                 {
2119                         if (time < self.strength_finished)
2120                         {
2121                                 self.items = self.items | IT_STRENGTH;
2122                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2123                         }
2124                 }
2125                 if (self.items & IT_INVINCIBLE)
2126                 {
2127                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2128                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2129                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2130                         {
2131                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2132                                 sprint(self, "^3Shield has worn off\n");
2133                         }
2134                 }
2135                 else
2136                 {
2137                         if (time < self.invincible_finished)
2138                         {
2139                                 self.items = self.items | IT_INVINCIBLE;
2140                                 sprint(self, "^3Shield surrounds you\n");
2141                         }
2142                 }
2143
2144                 if(autocvar_g_nodepthtestplayers)
2145                         self.effects = self.effects | EF_NODEPTHTEST;
2146
2147                 if(autocvar_g_fullbrightplayers)
2148                         self.effects = self.effects | EF_FULLBRIGHT;
2149
2150                 // midair gamemode: damage only while in the air
2151                 // if in midair mode, being on ground grants temporary invulnerability
2152                 // (this is so that multishot weapon don't clear the ground flag on the
2153                 // first damage in the frame, leaving the player vulnerable to the
2154                 // remaining hits in the same frame)
2155                 if (self.flags & FL_ONGROUND)
2156                 if (g_midair)
2157                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2158
2159                 if (time >= game_starttime)
2160                 if (time < self.spawnshieldtime)
2161                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2162         }
2163
2164         MUTATOR_CALLHOOK(PlayerPowerups);
2165 }
2166
2167 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2168 {
2169         if(current > stable)
2170                 return current;
2171         else if(current > stable - 0.25) // when close enough, "snap"
2172                 return stable;
2173         else
2174                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2175 }
2176
2177 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2178 {
2179         if(current < stable)
2180                 return current;
2181         else if(current < stable + 0.25) // when close enough, "snap"
2182                 return stable;
2183         else
2184                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2185 }
2186
2187 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2188 {
2189         if(current > rotstable)
2190         {
2191                 if(rotframetime > 0)
2192                 {
2193                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2194                         current = max(rotstable, current - rotlinear * rotframetime);
2195                 }
2196         }
2197         else if(current < regenstable)
2198         {
2199                 if(regenframetime > 0)
2200                 {
2201                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2202                         current = min(regenstable, current + regenlinear * regenframetime);
2203                 }
2204         }
2205
2206         if(current > limit)
2207                 current = limit;
2208
2209         return current;
2210 }
2211
2212 void player_regen (void)
2213 {
2214         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2215         maxh = autocvar_g_balance_health_rotstable;
2216         maxa = autocvar_g_balance_armor_rotstable;
2217         maxf = autocvar_g_balance_fuel_rotstable;
2218         minh = autocvar_g_balance_health_regenstable;
2219         mina = autocvar_g_balance_armor_regenstable;
2220         minf = autocvar_g_balance_fuel_regenstable;
2221         limith = autocvar_g_balance_health_limit;
2222         limita = autocvar_g_balance_armor_limit;
2223         limitf = autocvar_g_balance_fuel_limit;
2224
2225         max_mod = regen_mod = rot_mod = limit_mod = 1;
2226
2227         if (self.runes & RUNE_REGEN)
2228         {
2229                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2230                 {
2231                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2232                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2233                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2234                 }
2235                 else
2236                 {
2237                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2238                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2239                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2240                 }
2241         }
2242         else if (self.runes & CURSE_VENOM)
2243         {
2244                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2245                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2246                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2247                 else
2248                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2249                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2250                 //if (!self.runes & RUNE_REGEN)
2251                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2252         }
2253         maxh = maxh * max_mod;
2254         //maxa = maxa * max_mod;
2255         //maxf = maxf * max_mod;
2256         minh = minh * max_mod;
2257         //mina = mina * max_mod;
2258         //minf = minf * max_mod;
2259         limith = limith * limit_mod;
2260         limita = limita * limit_mod;
2261         //limitf = limitf * limit_mod;
2262
2263         if(g_lms && g_ca)
2264                 rot_mod = 0;
2265
2266         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2267         {
2268                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2269                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2270
2271                 // if player rotted to death...  die!
2272                 if(self.health < 1)
2273                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2274         }
2275
2276         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2277                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2278 }
2279
2280 float zoomstate_set;
2281 void SetZoomState(float z)
2282 {
2283         if(z != self.zoomstate)
2284         {
2285                 self.zoomstate = z;
2286                 ClientData_Touch(self);
2287         }
2288         zoomstate_set = 1;
2289 }
2290
2291 void GetPressedKeys(void) {
2292         MUTATOR_CALLHOOK(GetPressedKeys);
2293         if (self.movement_x > 0) // get if movement keys are pressed
2294         {       // forward key pressed
2295                 self.pressedkeys |= KEY_FORWARD;
2296                 self.pressedkeys &~= KEY_BACKWARD;
2297         }
2298         else if (self.movement_x < 0)
2299         {       // backward key pressed
2300                 self.pressedkeys |= KEY_BACKWARD;
2301                 self.pressedkeys &~= KEY_FORWARD;
2302         }
2303         else
2304         {       // no x input
2305                 self.pressedkeys &~= KEY_FORWARD;
2306                 self.pressedkeys &~= KEY_BACKWARD;
2307         }
2308
2309         if (self.movement_y > 0)
2310         {       // right key pressed
2311                 self.pressedkeys |= KEY_RIGHT;
2312                 self.pressedkeys &~= KEY_LEFT;
2313         }
2314         else if (self.movement_y < 0)
2315         {       // left key pressed
2316                 self.pressedkeys |= KEY_LEFT;
2317                 self.pressedkeys &~= KEY_RIGHT;
2318         }
2319         else
2320         {       // no y input
2321                 self.pressedkeys &~= KEY_RIGHT;
2322                 self.pressedkeys &~= KEY_LEFT;
2323         }
2324
2325         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2326                 self.pressedkeys |= KEY_JUMP;
2327         else
2328                 self.pressedkeys &~= KEY_JUMP;
2329         if (self.BUTTON_CROUCH)
2330                 self.pressedkeys |= KEY_CROUCH;
2331         else
2332                 self.pressedkeys &~= KEY_CROUCH;
2333 }
2334
2335 /*
2336 ======================
2337 spectate mode routines
2338 ======================
2339 */
2340
2341 void SpectateCopy(entity spectatee) {
2342         other = spectatee;
2343         MUTATOR_CALLHOOK(SpectateCopy);
2344         self.armortype = spectatee.armortype;
2345         self.armorvalue = spectatee.armorvalue;
2346         self.ammo_cells = spectatee.ammo_cells;
2347         self.ammo_shells = spectatee.ammo_shells;
2348         self.ammo_nails = spectatee.ammo_nails;
2349         self.ammo_rockets = spectatee.ammo_rockets;
2350         self.ammo_fuel = spectatee.ammo_fuel;
2351         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2352         self.health = spectatee.health;
2353         self.impulse = 0;
2354         self.items = spectatee.items;
2355         self.last_pickup = spectatee.last_pickup;
2356         self.metertime = spectatee.metertime;
2357         self.strength_finished = spectatee.strength_finished;
2358         self.invincible_finished = spectatee.invincible_finished;
2359         self.pressedkeys = spectatee.pressedkeys;
2360         self.weapons = spectatee.weapons;
2361         self.switchweapon = spectatee.switchweapon;
2362         self.weapon = spectatee.weapon;
2363         self.punchangle = spectatee.punchangle;
2364         self.view_ofs = spectatee.view_ofs;
2365         self.v_angle = spectatee.v_angle;
2366         self.velocity = spectatee.velocity;
2367         self.dmg_take = spectatee.dmg_take;
2368         self.dmg_save = spectatee.dmg_save;
2369         self.dmg_inflictor = spectatee.dmg_inflictor;
2370         self.angles = spectatee.v_angle;
2371         self.fixangle = TRUE;
2372         setorigin(self, spectatee.origin);
2373         setsize(self, spectatee.mins, spectatee.maxs);
2374         SetZoomState(spectatee.zoomstate);
2375
2376         anticheat_spectatecopy(spectatee);
2377 }
2378
2379 float SpectateUpdate() {
2380         if(!self.enemy)
2381                 return 0;
2382
2383         if (self == self.enemy)
2384                 return 0;
2385
2386         if(self.enemy.classname != "player")
2387                 return 0;
2388
2389         SpectateCopy(self.enemy);
2390
2391         return 1;
2392 }
2393
2394 float SpectateNext() {
2395         other = find(self.enemy, classname, "player");
2396
2397         if (!other)
2398                 other = find(other, classname, "player");
2399
2400         if (other)
2401                 self.enemy = other;
2402
2403         if(self.enemy.classname == "player") {
2404                 msg_entity = self;
2405                 WriteByte(MSG_ONE, SVC_SETVIEW);
2406                 WriteEntity(MSG_ONE, self.enemy);
2407                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2408                 self.movetype = MOVETYPE_NONE;
2409                 accuracy_resend(self);
2410
2411                 if(!SpectateUpdate())
2412                         PutObserverInServer();
2413
2414                 return 1;
2415         } else {
2416                 return 0;
2417         }
2418 }
2419
2420 /*
2421 =============
2422 ShowRespawnCountdown()
2423
2424 Update a respawn countdown display.
2425 =============
2426 */
2427 void ShowRespawnCountdown()
2428 {
2429         float number;
2430         if(self.deadflag == DEAD_NO) // just respawned?
2431                 return;
2432         else
2433         {
2434                 number = ceil(self.death_time - time);
2435                 if(number <= 0)
2436                         return;
2437                 if(number <= self.respawn_countdown)
2438                 {
2439                         self.respawn_countdown = number - 1;
2440                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2441                                 AnnounceTo(self, strcat(ftos(number), ""));
2442                 }
2443         }
2444 }
2445
2446 void LeaveSpectatorMode()
2447 {
2448         if(isJoinAllowed()) {
2449                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2450                         self.classname = "player";
2451
2452                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2453                                 JoinBestTeam(self, FALSE, TRUE);
2454
2455                         if(autocvar_g_campaign)
2456                                 campaign_bots_may_start = 1;
2457
2458                         PutClientInServer();
2459
2460                         if(self.classname == "player")
2461                                 bprint ("^4", self.netname, "^4 is playing now\n");
2462
2463                         if(!autocvar_g_campaign)
2464                                 centerprint(self,""); // clear MOTD
2465
2466                         return;
2467                 } else {
2468                         if (g_ca && self.caplayer) {
2469                         }       // do nothing
2470                         else
2471                                 stuffcmd(self,"menu_showteamselect\n");
2472                         return;
2473                 }
2474         }
2475         else {
2476                 //player may not join because of g_maxplayers is set
2477                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2478         }
2479 }
2480
2481 /**
2482  * Determines whether the player is allowed to join. This depends on cvar
2483  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2484  * it checks whether the number of currently playing players exceeds g_maxplayers.
2485  * @return bool TRUE if the player is allowed to join, false otherwise
2486  */
2487 float isJoinAllowed() {
2488         if(self.team_forced < 0)
2489                 return FALSE; // forced spectators can never join
2490
2491         if (!autocvar_g_maxplayers)
2492                 return TRUE;
2493
2494         local entity e;
2495         local float currentlyPlaying;
2496         FOR_EACH_REALPLAYER(e) {
2497                 if(e.classname == "player")
2498                         currentlyPlaying += 1;
2499         }
2500         if(currentlyPlaying < autocvar_g_maxplayers)
2501                 return TRUE;
2502
2503         return FALSE;
2504 }
2505
2506 /**
2507  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2508  * g_maxplayers_spectator_blocktime seconds
2509  */
2510 void checkSpectatorBlock() {
2511         if(self.classname == "spectator" || self.classname == "observer") {
2512                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2513                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2514                         dropclient(self);
2515                 }
2516         }
2517 }
2518
2519 void ObserverThink()
2520 {
2521         if (self.flags & FL_JUMPRELEASED) {
2522                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2523                         self.welcomemessage_time = 0;
2524                         self.flags &~= FL_JUMPRELEASED;
2525                         self.flags |= FL_SPAWNING;
2526                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2527                         self.welcomemessage_time = 0;
2528                         self.flags &~= FL_JUMPRELEASED;
2529                         if(SpectateNext() == 1) {
2530                                 self.classname = "spectator";
2531                         }
2532                 }
2533         } else {
2534                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2535                         self.flags |= FL_JUMPRELEASED;
2536                         if(self.flags & FL_SPAWNING)
2537                         {
2538                                 self.flags &~= FL_SPAWNING;
2539                                 LeaveSpectatorMode();
2540                                 return;
2541                         }
2542                 }
2543         }
2544         PrintWelcomeMessage(self);
2545 }
2546
2547 void SpectatorThink()
2548 {
2549         if (self.flags & FL_JUMPRELEASED) {
2550                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2551                         self.welcomemessage_time = 0;
2552                         self.flags &~= FL_JUMPRELEASED;
2553                         self.flags |= FL_SPAWNING;
2554                 } else if(self.BUTTON_ATCK) {
2555                         self.welcomemessage_time = 0;
2556                         self.flags &~= FL_JUMPRELEASED;
2557                         if(SpectateNext() == 1) {
2558                                 self.classname = "spectator";
2559                         } else {
2560                                 self.classname = "observer";
2561                                 PutClientInServer();
2562                         }
2563                 } else if (self.BUTTON_ATCK2) {
2564                         self.welcomemessage_time = 0;
2565                         self.flags &~= FL_JUMPRELEASED;
2566                         self.classname = "observer";
2567                         PutClientInServer();
2568                 } else {
2569                         if(!SpectateUpdate())
2570                                 PutObserverInServer();
2571                 }
2572         } else {
2573                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2574                         self.flags |= FL_JUMPRELEASED;
2575                         if(self.flags & FL_SPAWNING)
2576                         {
2577                                 self.flags &~= FL_SPAWNING;
2578                                 LeaveSpectatorMode();
2579                                 return;
2580                         }
2581                 }
2582         }
2583
2584         PrintWelcomeMessage(self);
2585         self.flags |= FL_CLIENT | FL_NOTARGET;
2586 }
2587
2588 .float touchexplode_time;
2589
2590 /*
2591 =============
2592 PlayerPreThink
2593
2594 Called every frame for each client before the physics are run
2595 =============
2596 */
2597 void() ctf_setstatus;
2598 void() nexball_setstatus;
2599 .float items_added;
2600 void PlayerPreThink (void)
2601 {
2602         self.stat_game_starttime = game_starttime;
2603         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2604         self.stat_leadlimit = autocvar_leadlimit;
2605
2606         if(frametime)
2607         {
2608                 // physics frames: update anticheat stuff
2609                 anticheat_prethink();
2610         }
2611
2612         if(blockSpectators && frametime)
2613                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2614                 checkSpectatorBlock();
2615
2616         zoomstate_set = 0;
2617
2618         if(self.netname_previous != self.netname)
2619         {
2620                 if(autocvar_sv_eventlog)
2621                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2622                 if(self.netname_previous)
2623                         strunzone(self.netname_previous);
2624                 self.netname_previous = strzone(self.netname);
2625         }
2626
2627         // version nagging
2628         if(self.version_nagtime)
2629                 if(self.cvar_g_xonoticversion)
2630                         if(time > self.version_nagtime)
2631                         {
2632                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2633                                 {
2634                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2635                                         {
2636                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2637                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2638                                         }
2639                                         else
2640                                         {
2641                                                 float r;
2642                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2643                                                 if(r < 0)
2644                                                 {
2645                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2646                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2647                                                 }
2648                                                 else if(r > 0)
2649                                                 {
2650                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2651                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2652                                                 }
2653                                         }
2654                                 }
2655                                 self.version_nagtime = 0;
2656                         }
2657
2658         // GOD MODE info
2659         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2660         {
2661                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2662                 self.max_armorvalue = 0;
2663         }
2664
2665 #ifdef TETRIS
2666         if (TetrisPreFrame())
2667                 return;
2668 #endif
2669
2670         MUTATOR_CALLHOOK(PlayerPreThink);
2671
2672         if(self.classname == "player") {
2673 //              if(self.netname == "Wazat")
2674 //                      bprint(self.classname, "\n");
2675
2676                 CheckRules_Player();
2677
2678                 PrintWelcomeMessage(self);
2679
2680                 if (intermission_running)
2681                 {
2682                         IntermissionThink ();   // otherwise a button could be missed between
2683                         return;                                 // the think tics
2684                 }
2685
2686                 if(self.teleport_time)
2687                 if(time > self.teleport_time)
2688                 {
2689                         self.teleport_time = 0;
2690                         self.effects = self.effects - (self.effects & EF_NODRAW);
2691                 }
2692
2693                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2694                         UpdateSelectedPlayer();
2695
2696                 //don't allow the player to turn around while game is paused!
2697                 if(timeoutStatus == 2) {
2698                         self.v_angle = self.lastV_angle;
2699                         self.angles = self.lastV_angle;
2700                         self.fixangle = TRUE;
2701                 }
2702
2703                 if(frametime)
2704                 {
2705                         if(self.health <= 0 && autocvar_g_deathglow)
2706                         {
2707                                 if(self.glowmod_x > 0)
2708                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2709                                 else
2710                                         self.glowmod_x = -1;
2711                                 if(self.glowmod_y > 0)
2712                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2713                                 else
2714                                         self.glowmod_y = -1;
2715                                 if(self.glowmod_z > 0)
2716                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2717                                 else
2718                                         self.glowmod_z = -1;
2719                         }
2720                         else
2721                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2722                         player_powerups();
2723                 }
2724
2725                 if (self.deadflag != DEAD_NO)
2726                 {
2727                         float button_pressed, force_respawn;
2728                         if(self.personal && g_race_qualifying)
2729                         {
2730                                 if(time > self.death_time)
2731                                 {
2732                                         self.death_time = time + 1; // only retry once a second
2733                                         respawn();
2734                                         self.impulse = 141;
2735                                 }
2736                         }
2737                         else
2738                         {
2739                                 if(frametime)
2740                                         player_anim();
2741                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2742                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2743                                 if (self.deadflag == DEAD_DYING)
2744                                 {
2745                                         if(force_respawn)
2746                                                 self.deadflag = DEAD_RESPAWNING;
2747                                         else if(!button_pressed)
2748                                                 self.deadflag = DEAD_DEAD;
2749                                 }
2750                                 else if (self.deadflag == DEAD_DEAD)
2751                                 {
2752                                         if(button_pressed)
2753                                                 self.deadflag = DEAD_RESPAWNABLE;
2754                                 }
2755                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2756                                 {
2757                                         if(!button_pressed)
2758                                                 self.deadflag = DEAD_RESPAWNING;
2759                                 }
2760                                 else if (self.deadflag == DEAD_RESPAWNING)
2761                                 {
2762                                         if(time > self.death_time)
2763                                         {
2764                                                 self.death_time = time + 1; // only retry once a second
2765                                                 respawn();
2766                                         }
2767                                 }
2768                                 ShowRespawnCountdown();
2769                         }
2770                         return;
2771                 }
2772
2773                 if(g_touchexplode)
2774                 if(time > self.touchexplode_time)
2775                 if(self.classname == "player")
2776                 if(self.deadflag == DEAD_NO)
2777                 if not(IS_INDEPENDENT_PLAYER(self))
2778                 FOR_EACH_PLAYER(other) if(self != other)
2779                 {
2780                         if(time > other.touchexplode_time)
2781                         if(other.deadflag == DEAD_NO)
2782                         if not(IS_INDEPENDENT_PLAYER(other))
2783                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2784                         {
2785                                 PlayerTouchExplode(self, other);
2786                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2787                         }
2788                 }
2789
2790                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2791                 {
2792                         vector dist;
2793
2794                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2795                         dist = self.prevorigin - self.origin;
2796                         dist_z = 0;
2797                         self.lms_traveled_distance += fabs(vlen(dist));
2798
2799                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2800                         {
2801                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2802                                 self.lms_traveled_distance = 0;
2803                         }
2804
2805                         if(time > self.lms_nextcheck)
2806                         {
2807                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2808                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2809                                 {
2810                                         centerprint(self, autocvar_g_lms_campcheck_message);
2811                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2812                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2813                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2814                                 }
2815                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2816                                 self.lms_traveled_distance = 0;
2817                         }
2818                 }
2819
2820                 self.prevorigin = self.origin;
2821
2822                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2823                 {
2824                         if (!self.crouch)
2825                         {
2826                                 self.crouch = TRUE;
2827                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2828                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2829                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2830                         }
2831                 }
2832                 else
2833                 {
2834                         if (self.crouch)
2835                         {
2836                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2837                                 if (!trace_startsolid)
2838                                 {
2839                                         self.crouch = FALSE;
2840                                         self.view_ofs = PL_VIEW_OFS;
2841                                         setsize (self, PL_MIN, PL_MAX);
2842                                 }
2843                         }
2844                 }
2845
2846                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2847                 {
2848                         if(self.bloodloss_timer < time)
2849                         {
2850                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2851                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2852                         }
2853                 }
2854
2855                 FixPlayermodel();
2856
2857                 GrapplingHookFrame();
2858
2859                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2860                 //if(frametime)
2861                 {
2862                         self.items &~= self.items_added;
2863
2864                         W_WeaponFrame();
2865
2866                         self.items_added = 0;
2867                         if(self.items & IT_JETPACK)
2868                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2869                                         self.items_added |= IT_FUEL;
2870
2871                         self.items |= self.items_added;
2872                 }
2873
2874                 player_regen();
2875
2876                 // rot nex charge to the charge limit
2877                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2878                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2879
2880                 if(frametime)
2881                         player_anim();
2882
2883                 if (g_minstagib)
2884                         minstagib_ammocheck();
2885
2886                 if(g_ctf)
2887                         ctf_setstatus();
2888
2889                 if(g_nexball)
2890                         nexball_setstatus();
2891
2892                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2893
2894                 //self.angles_y=self.v_angle_y + 90;   // temp
2895         } else if(gameover) {
2896                 if (intermission_running)
2897                         IntermissionThink ();   // otherwise a button could be missed between
2898                 return;
2899         } else if(self.classname == "observer") {
2900                 ObserverThink();
2901         } else if(self.classname == "spectator") {
2902                 SpectatorThink();
2903         }
2904
2905         if(!zoomstate_set)
2906                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2907
2908         float oldspectatee_status;
2909         oldspectatee_status = self.spectatee_status;
2910         if(self.classname == "spectator")
2911                 self.spectatee_status = num_for_edict(self.enemy);
2912         else if(self.classname == "observer")
2913                 self.spectatee_status = num_for_edict(self);
2914         else
2915                 self.spectatee_status = 0;
2916         if(self.spectatee_status != oldspectatee_status)
2917         {
2918                 ClientData_Touch(self);
2919                 if(g_race || g_cts)
2920                         race_InitSpectator();
2921         }
2922
2923         if(self.teamkill_soundtime)
2924         if(time > self.teamkill_soundtime)
2925         {
2926                 self.teamkill_soundtime = 0;
2927
2928                 entity oldpusher, oldself;
2929
2930                 oldself = self; self = self.teamkill_soundsource;
2931                 oldpusher = self.pusher; self.pusher = oldself;
2932
2933                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2934
2935                 self.pusher = oldpusher;
2936                 self = oldself;
2937         }
2938
2939         if(self.taunt_soundtime)
2940         if(time > self.taunt_soundtime)
2941         {
2942                 self.taunt_soundtime = 0;
2943                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2944         }
2945
2946         target_voicescript_next(self);
2947 }
2948
2949 float isInvisibleString(string s)
2950 {
2951         float i, n, c;
2952         s = strdecolorize(s);
2953         for((i = 0), (n = strlen(s)); i < n; ++i)
2954         {
2955                 c = str2chr(s, i);
2956                 switch(c)
2957                 {
2958                         case 0:
2959                         case 32: // space
2960                                 break;
2961                         case 192: // charmap space
2962                                 if (!autocvar_utf8_enable)
2963                                         break;
2964                                 return FALSE;
2965                         case 160: // space in unicode fonts
2966                         case 0xE000 + 192: // utf8 charmap space
2967                                 if (autocvar_utf8_enable)
2968                                         break;
2969                         default:
2970                                 return FALSE;
2971                 }
2972         }
2973         return TRUE;
2974 }
2975
2976 /*
2977 =============
2978 PlayerPostThink
2979
2980 Called every frame for each client after the physics are run
2981 =============
2982 */
2983 .float idlekick_lasttimeleft;
2984 .entity showheadshotbbox;
2985 void showheadshotbbox_think()
2986 {
2987         if(self.owner.showheadshotbbox != self)
2988         {
2989                 remove(self);
2990                 return;
2991         }
2992         self.nextthink = time;
2993         setorigin(self, self.owner.origin);
2994         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2995 }
2996 void PlayerPostThink (void)
2997 {
2998         // Savage: Check for nameless players
2999         if (isInvisibleString(self.netname)) {
3000                 self.netname = "Player";
3001                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3002         }
3003
3004         if(sv_maxidle && frametime)
3005         {
3006                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3007                 float timeleft;
3008                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3009                 if(timeleft <= 0)
3010                 {
3011                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3012                         AnnounceTo(self, "terminated");
3013                         dropclient(self);
3014                         return;
3015                 }
3016                 else if(timeleft <= 10)
3017                 {
3018                         if(timeleft != self.idlekick_lasttimeleft)
3019                         {
3020                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3021                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3022                         }
3023                 }
3024                 else
3025                 {
3026                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3027                 }
3028                 self.idlekick_lasttimeleft = timeleft;
3029         }
3030
3031 #ifdef TETRIS
3032         if(self.impulse == 100)
3033                 ImpulseCommands();
3034         if (TetrisPostFrame())
3035                 return;
3036 #endif
3037
3038         CheatFrame();
3039
3040         if(self.classname == "player") {
3041                 CheckRules_Player();
3042                 UpdateChatBubble();
3043                 UpdateTeamBubble();
3044                 if (self.impulse)
3045                         ImpulseCommands();
3046                 if (intermission_running)
3047                         return;         // intermission or finale
3048                 GetPressedKeys();
3049         } else if (self.classname == "observer") {
3050                 //do nothing
3051         } else if (self.classname == "spectator") {
3052                 //do nothing
3053         }
3054
3055         /*
3056         float i;
3057         for(i = 0; i < 1000; ++i)
3058         {
3059                 vector end;
3060                 end = self.origin + '0 0 1024' + 512 * randomvec();
3061                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3062                 if(trace_fraction < 1)
3063                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3064                 {
3065                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3066                         break;
3067                 }
3068         }
3069         */
3070
3071         Arena_Warmup();
3072
3073         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3074
3075         if(self.waypointsprite_attachedforcarrier)
3076                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3077
3078         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3079         {
3080                 if(!self.showheadshotbbox)
3081                 {
3082                         self.showheadshotbbox = spawn();
3083                         self.showheadshotbbox.classname = "headshotbbox";
3084                         self.showheadshotbbox.owner = self;
3085                         self.showheadshotbbox.think = showheadshotbbox_think;
3086                         self.showheadshotbbox.nextthink = time;
3087                         self = self.showheadshotbbox;
3088                         self.think();
3089                         self = self.owner;
3090                 }
3091         }
3092         else
3093         {
3094                 if(self.showheadshotbbox)
3095                         remove(self.showheadshotbbox);
3096         }
3097
3098         playerdemo_write();
3099
3100         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3101         {
3102                 if(!self.stored_netname)
3103                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3104                 if(self.stored_netname != self.netname)
3105                 {
3106                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3107                         strunzone(self.stored_netname);
3108                         self.stored_netname = strzone(self.netname);
3109                 }
3110         }
3111
3112         /*
3113         if(g_race)
3114                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3115         */
3116 }