qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.vehicle)
 626         {
 627             entity oldself;
 628             oldself = self;
 629             self = self.vehicle;
 630             vehicles_exit(VHEF_RELESE);
 631             self = oldself;
 632         }
 633
 634         if(self.flagcarried)
 635                 DropFlag(self.flagcarried, world, world);
 636
 637         if(self.ballcarried && g_nexball)
 638                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 639
 640         WaypointSprite_PlayerDead();
 641
 642         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 643                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 644
 645         if(self.killcount != -666) {
 646                 if(g_lms) {
 647                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 648                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 649                         else
 650                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 651                 } else
 652                         bprint ("^4", self.netname, "^4 is spectating now\n");
 653
 654                 if(self.just_joined == FALSE) {
 655                         LogTeamchange(self.playerid, -1, 4);
 656                 } else
 657                         self.just_joined = FALSE;
 658         }
 659
 660         PlayerScore_Clear(self); // clear scores when needed
 661
 662         accuracy_resend(self);
 663
 664         self.spectatortime = time;
 665
 666         self.classname = "observer";
 667         self.iscreature = FALSE;
 668         self.health = -666;
 669         self.takedamage = DAMAGE_NO;
 670         self.solid = SOLID_NOT;
 671         self.movetype = MOVETYPE_NOCLIP;
 672         self.flags = FL_CLIENT | FL_NOTARGET;
 673         self.armorvalue = 666;
 674         self.effects = 0;
 675         self.armorvalue = autocvar_g_balance_armor_start;
 676         self.pauserotarmor_finished = 0;
 677         self.pauserothealth_finished = 0;
 678         self.pauseregen_finished = 0;
 679         self.damageforcescale = 0;
 680         self.death_time = 0;
 681         self.dead_frame = 0;
 682         self.alpha = 0;
 683         self.scale = 0;
 684         self.fade_time = 0;
 685         self.pain_frame = 0;
 686         self.pain_finished = 0;
 687         self.strength_finished = 0;
 688         self.invincible_finished = 0;
 689         self.pushltime = 0;
 690         self.think = SUB_Null;
 691         self.nextthink = 0;
 692         self.hook_time = 0;
 693         self.runes = 0;
 694         self.deadflag = DEAD_NO;
 695         self.angles = spot.angles;
 696         self.angles_z = 0;
 697         self.fixangle = TRUE;
 698         self.crouch = FALSE;
 699
 700         self.view_ofs = PL_VIEW_OFS;
 701         setorigin (self, spot.origin);
 702         setsize (self, '0 0 0', '0 0 0');
 703         self.prevorigin = self.origin;
 704         self.items = 0;
 705         self.weapons = 0;
 706         self.model = "";
 707         FixPlayermodel();
 708         self.model = "";
 709         self.modelindex = 0;
 710         self.weapon = 0;
 711         self.weaponmodel = "";
 712         self.weaponentity = world;
 713         self.exteriorweaponentity = world;
 714         self.killcount = -666;
 715         self.velocity = '0 0 0';
 716         self.avelocity = '0 0 0';
 717         self.punchangle = '0 0 0';
 718         self.punchvector = '0 0 0';
 719         self.oldvelocity = self.velocity;
 720         self.fire_endtime = -1;
 721
 722         if(sv_loddistance1)
 723                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 724
 725         if(g_arena)
 726         {
 727                 if(self.version_mismatch)
 728                 {
 729                         Spawnqueue_Unmark(self);
 730                         Spawnqueue_Remove(self);
 731                 }
 732                 else
 733                 {
 734                         Spawnqueue_Insert(self);
 735                 }
 736         }
 737         else if(g_lms)
 738         {
 739                 // Only if the player cannot play at all
 740                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 741                         self.frags = FRAGS_SPECTATOR;
 742                 else
 743                         self.frags = FRAGS_LMS_LOSER;
 744         }
 745         else
 746                 self.frags = FRAGS_SPECTATOR;
 747 }
 748
 749 void FixPlayermodel()
 750 {
 751         local string defaultmodel;
 752         local float defaultskin, chmdl, oldskin;
 753         local vector m1, m2;
 754
 755         defaultmodel = "";
 756
 757         if(autocvar_sv_defaultcharacter == 1) {
 758                 defaultskin = 0;
 759
 760                 if(teams_matter)
 761                 {
 762                         string s;
 763                         s = Team_ColorNameLowerCase(self.team);
 764                         if(s != "neutral")
 765                         {
 766                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 767                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 768                         }
 769                 }
 770
 771                 if(defaultmodel == "")
 772                 {
 773                         defaultmodel = autocvar_sv_defaultplayermodel;
 774                         defaultskin = autocvar_sv_defaultplayerskin;
 775                 }
 776         }
 777
 778         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 779         {
 780                 if(self.model != "")
 781                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 782                 self.model = ""; // force the != checks to return true
 783         }
 784
 785         if(defaultmodel != "")
 786         {
 787                 if (defaultmodel != self.model)
 788                 {
 789                         m1 = self.mins;
 790                         m2 = self.maxs;
 791                         setmodel_lod (self, defaultmodel);
 792                         setsize (self, m1, m2);
 793                         chmdl = TRUE;
 794                 }
 795
 796                 oldskin = self.skinindex;
 797                 self.skinindex = defaultskin;
 798         } else {
 799                 if (self.playermodel != self.model || self.playermodel == "")
 800                 {
 801                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 802                         m1 = self.mins;
 803                         m2 = self.maxs;
 804                         setmodel_lod (self, self.playermodel);
 805                         setsize (self, m1, m2);
 806                         chmdl = TRUE;
 807                 }
 808
 809                 oldskin = self.skinindex;
 810                 self.skinindex = stof(self.playerskin);
 811         }
 812
 813         if(chmdl || oldskin != self.skinindex)
 814                 self.species = player_getspecies(); // model or skin has changed
 815
 816         if(!teams_matter)
 817                 if(strlen(autocvar_sv_defaultplayercolors))
 818                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 819                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 820 }
 821
 822 void PlayerTouchExplode(entity p1, entity p2)
 823 {
 824         vector org;
 825         org = (p1.origin + p2.origin) * 0.5;
 826         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 827
 828         te_explosion(org);
 829
 830         entity e;
 831         e = spawn();
 832         setorigin(e, org);
 833         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 834         remove(e);
 835 }
 836
 837 /*
 838 =============
 839 PutClientInServer
 840
 841 Called when a client spawns in the server
 842 =============
 843 */
 844 //void() ctf_playerchanged;
 845 void PutClientInServer (void)
 846 {
 847         if(clienttype(self) == CLIENTTYPE_BOT)
 848         {
 849                 self.classname = "player";
 850         }
 851         else if(clienttype(self) == CLIENTTYPE_REAL)
 852         {
 853                 msg_entity = self;
 854                 WriteByte(MSG_ONE, SVC_SETVIEW);
 855                 WriteEntity(MSG_ONE, self);
 856         }
 857
 858         // player is dead and becomes observer
 859         // FIXME fix LMS scoring for new system
 860         if(g_lms)
 861         {
 862                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 863                         self.classname = "observer";
 864         }
 865
 866         if(g_arena || (g_ca && !allowed_to_spawn))
 867         if(!self.spawned)
 868                 self.classname = "observer";
 869
 870         if(gameover)
 871                 self.classname = "observer";
 872
 873         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 874                 entity spot, oldself;
 875                 float j;
 876
 877                 accuracy_resend(self);
 878
 879                 if(self.team < 0)
 880                         JoinBestTeam(self, FALSE, TRUE);
 881
 882                 race_PreSpawn();
 883
 884                 spot = SelectSpawnPoint (FALSE);
 885                 if(!spot)
 886                 {
 887                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 888                         return; // spawn failed
 889                 }
 890
 891                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 892
 893                 self.classname = "player";
 894                 self.wasplayer = TRUE;
 895                 self.iscreature = TRUE;
 896                 self.movetype = MOVETYPE_WALK;
 897                 self.solid = SOLID_SLIDEBOX;
 898                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 899                 if(autocvar_g_playerclip_collisions)
 900                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 901                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 902                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 903                 self.frags = FRAGS_PLAYER;
 904                 if(independent_players)
 905                         MAKE_INDEPENDENT_PLAYER(self);
 906                 self.flags = FL_CLIENT;
 907                 self.takedamage = DAMAGE_AIM;
 908                 if(g_minstagib)
 909                         self.effects = EF_FULLBRIGHT;
 910                 else
 911                         self.effects = 0;
 912                 self.air_finished = time + 12;
 913                 self.dmg = 2;
 914                 if(autocvar_g_balance_nex_charge)
 915                 {
 916                         if(autocvar_g_balance_nex_secondary_chargepool)
 917                                 self.nex_chargepool_ammo = 1;
 918                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 919                 }
 920
 921                 if(inWarmupStage)
 922                 {
 923                         self.ammo_shells = warmup_start_ammo_shells;
 924                         self.ammo_nails = warmup_start_ammo_nails;
 925                         self.ammo_rockets = warmup_start_ammo_rockets;
 926                         self.ammo_cells = warmup_start_ammo_cells;
 927                         self.ammo_fuel = warmup_start_ammo_fuel;
 928                         self.health = warmup_start_health;
 929                         self.armorvalue = warmup_start_armorvalue;
 930                         self.weapons = warmup_start_weapons;
 931                 }
 932                 else
 933                 {
 934                         self.ammo_shells = start_ammo_shells;
 935                         self.ammo_nails = start_ammo_nails;
 936                         self.ammo_rockets = start_ammo_rockets;
 937                         self.ammo_cells = start_ammo_cells;
 938                         self.ammo_fuel = start_ammo_fuel;
 939                         self.health = start_health;
 940                         self.armorvalue = start_armorvalue;
 941                         self.weapons = start_weapons;
 942                 }
 943
 944                 if(g_weaponarena_random)
 945                 {
 946                         if(g_weaponarena_random_with_laser)
 947                                 self.weapons &~= WEPBIT_LASER;
 948                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 949                         if(g_weaponarena_random_with_laser)
 950                                 self.weapons |= WEPBIT_LASER;
 951                 }
 952
 953                 self.items = start_items;
 954                 self.jump_interval = time;
 955
 956                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 957                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 958                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 959                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 960                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 961                 //extend the pause of rotting if client was reset at the beginning of the countdown
 962                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 963                         self.spawnshieldtime += game_starttime - time;
 964                         self.pauserotarmor_finished += game_starttime - time;
 965                         self.pauserothealth_finished += game_starttime - time;
 966                         self.pauseregen_finished += game_starttime - time;
 967                 }
 968                 self.damageforcescale = 2;
 969                 self.death_time = 0;
 970                 self.dead_frame = 0;
 971                 self.alpha = 0;
 972                 self.scale = 0;
 973                 self.fade_time = 0;
 974                 self.pain_frame = 0;
 975                 self.pain_finished = 0;
 976                 self.strength_finished = 0;
 977                 self.invincible_finished = 0;
 978                 self.pushltime = 0;
 979                 // players have no think function
 980                 self.think = SUB_Null;
 981                 self.nextthink = 0;
 982                 self.hook_time = 0;
 983                 self.dmg_team = 0;
 984                 self.ballistics_density = autocvar_g_ballistics_density_player;
 985
 986                 self.metertime = 0;
 987
 988                 self.runes = 0;
 989
 990                 self.deadflag = DEAD_NO;
 991
 992                 self.angles = spot.angles;
 993
 994                 self.angles_z = 0; // never spawn tilted even if the spot says to
 995                 self.fixangle = TRUE; // turn this way immediately
 996                 self.velocity = '0 0 0';
 997                 self.avelocity = '0 0 0';
 998                 self.punchangle = '0 0 0';
 999                 self.punchvector = '0 0 0';
1000                 self.oldvelocity = self.velocity;
1001                 self.fire_endtime = -1;
1002
1003                 msg_entity = self;
1004                 WRITESPECTATABLE_MSG_ONE({
1005                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1006                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1007                 });
1008
1009                 if(sv_loddistance1)
1010                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1011
1012                 self.model = "";
1013                 FixPlayermodel();
1014
1015                 self.crouch = FALSE;
1016                 self.view_ofs = PL_VIEW_OFS;
1017                 setsize (self, PL_MIN, PL_MAX);
1018                 self.spawnorigin = spot.origin;
1019                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1020                 // don't reset back to last position, even if new position is stuck in solid
1021                 self.oldorigin = self.origin;
1022                 self.prevorigin = self.origin;
1023                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1024
1025                 if(g_arena)
1026                 {
1027                         Spawnqueue_Remove(self);
1028                         Spawnqueue_Mark(self);
1029                 }
1030
1031                 else if(g_ca)
1032                         self.caplayer = 1;
1033
1034                 self.event_damage = PlayerDamage;
1035
1036                 self.bot_attack = TRUE;
1037
1038                 self.statdraintime = time + 5;
1039                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1040
1041                 if(self.killcount == -666) {
1042                         PlayerScore_Clear(self);
1043                         self.killcount = 0;
1044                 }
1045
1046                 self.cnt = WEP_LASER;
1047
1048                 CL_SpawnWeaponentity();
1049                 self.alpha = default_player_alpha;
1050                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1051                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1052
1053                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1054                 self.lms_traveled_distance = 0;
1055                 self.speedrunning = FALSE;
1056
1057                 race_PostSpawn(spot);
1058
1059                 if(autocvar_spawn_debug)
1060                 {
1061                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1062                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1063                 }
1064
1065                 //stuffcmd(self, "chase_active 0");
1066                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1067
1068                 if (autocvar_g_spawnsound)
1069                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1070
1071                 if(g_assault) {
1072                         if(self.team == assault_attacker_team)
1073                                 centerprint(self, "You are attacking!");
1074                         else
1075                                 centerprint(self, "You are defending!");
1076                 }
1077
1078                 target_voicescript_clear(self);
1079
1080                 // reset fields the weapons may use
1081                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1082                 {
1083                         weapon_action(j, WR_RESETPLAYER);
1084
1085                         // all weapons must be fully loaded when we spawn
1086                         entity e;
1087                         e = get_weaponinfo(j);
1088                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1089                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1090                 }
1091                 self.weapon_forbidchange = FALSE;
1092
1093                 oldself = self;
1094                 self = spot;
1095                         activator = oldself;
1096                                 SUB_UseTargets();
1097                         activator = world;
1098                 self = oldself;
1099
1100                 MUTATOR_CALLHOOK(PlayerSpawn);
1101
1102                 self.switchweapon = w_getbestweapon(self);
1103                 self.cnt = self.switchweapon;
1104                 self.weapon = 0;
1105
1106                 if(!self.alivetime)
1107                         self.alivetime = time;
1108         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1109                 PutObserverInServer ();
1110         }
1111
1112         //if(g_ctf)
1113         //      ctf_playerchanged();
1114 }
1115
1116 .float ebouncefactor, ebouncestop; // electro's values
1117 // TODO do we need all these fields, or should we stop autodetecting runtime
1118 // changes and just have a console command to update this?
1119 float ClientInit_SendEntity(entity to, float sf)
1120 {
1121         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1122         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1135         if(sv_foginterval && world.fog != "")
1136                 WriteString(MSG_ENTITY, world.fog);
1137         else
1138                 WriteString(MSG_ENTITY, "");
1139         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1140         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1141         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1142         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1143         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1144         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1145         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1146         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1147         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1148         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1149         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1150         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1151         return TRUE;
1152 }
1153
1154 void ClientInit_CheckUpdate()
1155 {
1156         self.nextthink = time;
1157         if(self.count != autocvar_g_balance_armor_blockpercent)
1158         {
1159                 self.count = autocvar_g_balance_armor_blockpercent;
1160                 self.SendFlags |= 1;
1161         }
1162         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1163         {
1164                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1165                 self.SendFlags |= 1;
1166         }
1167         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1168         {
1169                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1170                 self.SendFlags |= 1;
1171         }
1172         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1173         {
1174                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1175                 self.SendFlags |= 1;
1176         }
1177         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1178         {
1179                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1180                 self.SendFlags |= 1;
1181         }
1182         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1183         {
1184                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1185                 self.SendFlags |= 1;
1186         }
1187 }
1188
1189 void ClientInit_Spawn()
1190 {
1191         entity o;
1192         entity e;
1193         e = spawn();
1194         e.classname = "clientinit";
1195         e.think = ClientInit_CheckUpdate;
1196         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1197
1198         o = self;
1199         self = e;
1200         ClientInit_CheckUpdate();
1201         self = o;
1202 }
1203
1204 /*
1205 =============
1206 SetNewParms
1207 =============
1208 */
1209 void SetNewParms (void)
1210 {
1211         // initialize parms for a new player
1212         parm1 = -(86400 * 366);
1213 }
1214
1215 /*
1216 =============
1217 SetChangeParms
1218 =============
1219 */
1220 void SetChangeParms (void)
1221 {
1222         // save parms for level change
1223         parm1 = self.parm_idlesince - time;
1224 }
1225
1226 /*
1227 =============
1228 DecodeLevelParms
1229 =============
1230 */
1231 void DecodeLevelParms (void)
1232 {
1233         // load parms
1234         self.parm_idlesince = parm1;
1235         if(self.parm_idlesince == -(86400 * 366))
1236                 self.parm_idlesince = time;
1237
1238         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1239         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1240 }
1241
1242 /*
1243 =============
1244 ClientKill
1245
1246 Called when a client types 'kill' in the console
1247 =============
1248 */
1249
1250 .float clientkill_nexttime;
1251 void ClientKill_Now_TeamChange()
1252 {
1253         if(self.killindicator_teamchange == -1)
1254         {
1255                 self.team = -1;
1256                 JoinBestTeam( self, FALSE, FALSE );
1257         }
1258         else if(self.killindicator_teamchange == -2)
1259         {
1260                 if(g_ca)
1261                         self.caplayer = 0;
1262                 if(blockSpectators)
1263                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1264                 PutObserverInServer();
1265         }
1266         else
1267                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1268 }
1269
1270 void ClientKill_Now()
1271 {
1272         if(self.vehicle)
1273         {
1274             entity oldself;
1275             oldself = self;
1276             self = self.vehicle;
1277             vehicles_exit(VHEF_RELESE);
1278             self.vehicle_health = -1;
1279             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1280             self = oldself;
1281         }
1282
1283         remove(self.killindicator);
1284         self.killindicator = world;
1285
1286         if(self.killindicator_teamchange)
1287                 ClientKill_Now_TeamChange();
1288
1289         // in any case:
1290         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1291
1292         // now I am sure the player IS dead
1293 }
1294 void KillIndicator_Think()
1295 {
1296         if (!self.owner.modelindex)
1297         {
1298                 self.owner.killindicator = world;
1299                 remove(self);
1300                 return;
1301         }
1302
1303         if(self.cnt <= 0)
1304         {
1305                 self = self.owner;
1306                 ClientKill_Now(); // no oldself needed
1307                 return;
1308         }
1309     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1310     {
1311         self.nextthink = time + 1;
1312         self.cnt -= 1;
1313     }
1314         else
1315         {
1316                 if(self.cnt <= 10)
1317                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1318                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1319                 {
1320                         if(self.cnt <= 10)
1321                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1322                         if(self.owner.killindicator_teamchange)
1323                         {
1324                                 if(self.owner.killindicator_teamchange == -1)
1325                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1326                                 else if(self.owner.killindicator_teamchange == -2)
1327                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1328                                 else
1329                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1330                         }
1331                         else
1332                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1333                 }
1334                 self.nextthink = time + 1;
1335                 self.cnt -= 1;
1336         }
1337 }
1338
1339 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1340 {
1341         float killtime;
1342         entity e;
1343         killtime = autocvar_g_balance_kill_delay;
1344
1345         if(g_race_qualifying || g_cts)
1346                 killtime = 0;
1347
1348     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1349     {
1350                 remove(self.killindicator);
1351                 self.killindicator = world;
1352
1353         ClientKill_Now(); // allow instant kill in this case
1354         return;
1355     }
1356
1357         self.killindicator_teamchange = targetteam;
1358
1359     if(!self.killindicator)
1360         {
1361                 if(self.modelindex && self.deadflag == DEAD_NO)
1362                 {
1363                         killtime = max(killtime, self.clientkill_nexttime - time);
1364                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1365                 }
1366
1367                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1368                 {
1369                         ClientKill_Now();
1370                 }
1371                 else
1372                 {
1373                         self.killindicator = spawn();
1374                         self.killindicator.owner = self;
1375                         self.killindicator.scale = 0.5;
1376                         setattachment(self.killindicator, self, "");
1377                         setorigin(self.killindicator, '0 0 52');
1378                         self.killindicator.think = KillIndicator_Think;
1379                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1380                         self.killindicator.cnt = ceil(killtime);
1381                         self.killindicator.count = bound(0, ceil(killtime), 10);
1382                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1383
1384                         for(e = world; (e = find(e, classname, "body")) != world; )
1385                         {
1386                                 if(e.enemy != self)
1387                                         continue;
1388                                 e.killindicator = spawn();
1389                                 e.killindicator.owner = e;
1390                                 e.killindicator.scale = 0.5;
1391                                 setattachment(e.killindicator, e, "");
1392                                 setorigin(e.killindicator, '0 0 52');
1393                                 e.killindicator.think = KillIndicator_Think;
1394                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1395                                 e.killindicator.cnt = ceil(killtime);
1396                         }
1397                         self.lip = 0;
1398                 }
1399         }
1400         if(self.killindicator)
1401         {
1402                 if(targetteam == 0) // just die
1403                         self.killindicator.colormod = '0 0 0';
1404                 else if(targetteam == -1) // auto
1405                         self.killindicator.colormod = '0 1 0';
1406                 else if(targetteam == -2) // spectate
1407                         self.killindicator.colormod = '0.5 0.5 0.5';
1408                 else
1409                         self.killindicator.colormod = TeamColor(targetteam);
1410         }
1411 }
1412
1413 void ClientKill (void)
1414 {
1415         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1416         {
1417                 // do nothing
1418         }
1419     else if(self.freezetag_frozen)
1420     {
1421         // do nothing
1422     }
1423         else
1424                 ClientKill_TeamChange(0);
1425 }
1426
1427 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1428 {
1429     e.killindicator = spawn();
1430     e.killindicator.owner = e;
1431     e.killindicator.think = KillIndicator_Think;
1432     e.killindicator.nextthink = time + (e.lip) * 0.05;
1433     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1434     e.killindicator.health = 1; // this is used to indicate that it should be silent
1435     e.lip = 0;
1436 }
1437
1438 void DoTeamChange(float destteam)
1439 {
1440         float t, c0;
1441         if(!teams_matter)
1442         {
1443                 if(destteam >= 0)
1444                         SetPlayerColors(self, destteam);
1445                 return;
1446         }
1447         if(self.classname == "player")
1448         if(destteam == -1)
1449         {
1450                 CheckAllowedTeams(self);
1451                 t = FindSmallestTeam(self, TRUE);
1452                 switch(self.team)
1453                 {
1454                         case COLOR_TEAM1: c0 = c1; break;
1455                         case COLOR_TEAM2: c0 = c2; break;
1456                         case COLOR_TEAM3: c0 = c3; break;
1457                         case COLOR_TEAM4: c0 = c4; break;
1458                         default:          c0 = 999;
1459                 }
1460                 switch(t)
1461                 {
1462                         case 1:
1463                                 if(c0 > c1)
1464                                         destteam = COLOR_TEAM1;
1465                                 break;
1466                         case 2:
1467                                 if(c0 > c2)
1468                                         destteam = COLOR_TEAM2;
1469                                 break;
1470                         case 3:
1471                                 if(c0 > c3)
1472                                         destteam = COLOR_TEAM3;
1473                                 break;
1474                         case 4:
1475                                 if(c0 > c4)
1476                                         destteam = COLOR_TEAM4;
1477                                 break;
1478                 }
1479                 if(destteam == -1)
1480                         return;
1481         }
1482         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1483                 return;
1484         ClientKill_TeamChange(destteam);
1485 }
1486
1487 void FixClientCvars(entity e)
1488 {
1489         // send prediction settings to the client
1490         stuffcmd(e, "\nin_bindmap 0 0\n");
1491         if(g_race || g_cts)
1492                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1493         if(autocvar_g_antilag == 3) // client side hitscan
1494                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1495         if(sv_gentle)
1496                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1497         /*
1498          * we no longer need to stuff this. Remove this comment block if you feel
1499          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1500         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1501         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1502         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1503         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1504         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1505         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1506         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1507         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1508         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1509         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1510         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1511         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1512         stuffcmd(e, "cl_movement_edgefriction 1\n");
1513          */
1514 }
1515
1516 float PlayerInIDList(entity p, string idlist)
1517 {
1518         float n, i;
1519         string s;
1520
1521         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1522         if not(p.crypto_idfp)
1523                 return 0;
1524
1525         // this function allows abbreviated player IDs too!
1526         n = tokenize_console(idlist);
1527         for(i = 0; i < n; ++i)
1528         {
1529                 s = argv(i);
1530                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1531                         return 1;
1532         }
1533
1534         return 0;
1535 }
1536
1537 /*
1538 =============
1539 ClientConnect
1540
1541 Called when a client connects to the server
1542 =============
1543 */
1544 //void ctf_clientconnect();
1545 string ColoredTeamName(float t);
1546 void DecodeLevelParms (void);
1547 //void dom_player_join_team(entity pl);
1548 void set_dom_state(entity e);
1549 void ClientConnect (void)
1550 {
1551         float t;
1552
1553         if(self.flags & FL_CLIENT)
1554         {
1555                 print("Warning: ClientConnect, but already connected!\n");
1556                 return;
1557         }
1558
1559         if(Ban_MaybeEnforceBan(self))
1560                 return;
1561
1562         DecodeLevelParms();
1563
1564 #ifdef WATERMARK
1565         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1566 #endif
1567
1568         self.classname = "player_joining";
1569
1570         self.flags = FL_CLIENT;
1571         self.version_nagtime = time + 10 + random() * 10;
1572
1573         if(player_count<0)
1574         {
1575                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1576                 player_count = 0;
1577         }
1578
1579         PlayerScore_Attach(self);
1580         ClientData_Attach();
1581         accuracy_init(self);
1582
1583         bot_clientconnect();
1584
1585         playerdemo_init();
1586
1587         anticheat_init();
1588
1589         race_PreSpawnObserver();
1590
1591         //if(g_domination)
1592         //      dom_player_join_team(self);
1593
1594         // identify the right forced team
1595         if(autocvar_g_campaign)
1596         {
1597                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1598                 {
1599                         switch(autocvar_g_campaign_forceteam)
1600                         {
1601                                 case 1: self.team_forced = COLOR_TEAM1; break;
1602                                 case 2: self.team_forced = COLOR_TEAM2; break;
1603                                 case 3: self.team_forced = COLOR_TEAM3; break;
1604                                 case 4: self.team_forced = COLOR_TEAM4; break;
1605                                 default: self.team_forced = 0;
1606                         }
1607                 }
1608         }
1609         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1610                 self.team_forced = COLOR_TEAM1;
1611         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1612                 self.team_forced = COLOR_TEAM2;
1613         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1614                 self.team_forced = COLOR_TEAM3;
1615         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1616                 self.team_forced = COLOR_TEAM4;
1617         else if(autocvar_g_forced_team_otherwise == "red")
1618                 self.team_forced = COLOR_TEAM1;
1619         else if(autocvar_g_forced_team_otherwise == "blue")
1620                 self.team_forced = COLOR_TEAM2;
1621         else if(autocvar_g_forced_team_otherwise == "yellow")
1622                 self.team_forced = COLOR_TEAM3;
1623         else if(autocvar_g_forced_team_otherwise == "pink")
1624                 self.team_forced = COLOR_TEAM4;
1625         else if(autocvar_g_forced_team_otherwise == "spectate")
1626                 self.team_forced = -1;
1627         else if(autocvar_g_forced_team_otherwise == "spectator")
1628                 self.team_forced = -1;
1629         else
1630                 self.team_forced = 0;
1631
1632         if(!teams_matter)
1633                 if(self.team_forced > 0)
1634                         self.team_forced = 0;
1635
1636         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1637
1638         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1639                 self.classname = "observer";
1640         } else {
1641                 if(teams_matter)
1642                 {
1643                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1644                         {
1645                                 self.classname = "player";
1646                                 campaign_bots_may_start = 1;
1647                         }
1648                         else
1649                         {
1650                                 self.classname = "observer"; // do it anyway
1651                         }
1652                 }
1653                 else
1654                 {
1655                         self.classname = "player";
1656                         campaign_bots_may_start = 1;
1657                 }
1658         }
1659
1660         self.playerid = (playerid_last = playerid_last + 1);
1661
1662     if(clienttype(self) == CLIENTTYPE_BOT)
1663         PlayerStats_AddPlayer(self);
1664
1665         if(autocvar_sv_eventlog)
1666                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1667
1668         LogTeamchange(self.playerid, self.team, 1);
1669
1670         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1671
1672         self.netname_previous = strzone(self.netname);
1673
1674         bprint("^4", self.netname, "^4 connected");
1675
1676         if(self.classname != "observer" && (g_domination || g_ctf))
1677                 bprint(" and joined the ", ColoredTeamName(self.team));
1678
1679         bprint("\n");
1680
1681         self.welcomemessage_time = 0;
1682
1683         stuffcmd(self, strcat(clientstuff, "\n"));
1684         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1685         stuffcmd(self, "cl_particles_reloadeffects\n");
1686
1687         FixClientCvars(self);
1688
1689         // spawnfunc_waypoint sprites
1690         WaypointSprite_InitClient(self);
1691
1692         // Wazat's grappling hook
1693         SetGrappleHookBindings();
1694
1695         // get autoswitch state from player when he toggles it
1696         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1697
1698         // get version info from player
1699         stuffcmd(self, "cmd clientversion $gameversion\n");
1700
1701         // get other cvars from player
1702         GetCvars(0);
1703
1704         // notify about available teams
1705         if(teams_matter)
1706         {
1707                 CheckAllowedTeams(self);
1708                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1709                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1710         }
1711         else
1712                 stuffcmd(self, "set _teams_available 0\n");
1713
1714         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1715
1716         if(g_arena || g_ca)
1717         {
1718                 self.classname = "observer";
1719                 if(g_arena)
1720                         Spawnqueue_Insert(self);
1721         }
1722         /*else if(g_ctf)
1723         {
1724                 ctf_clientconnect();
1725         }*/
1726
1727         attach_entcs();
1728
1729         bot_relinkplayerlist();
1730
1731         self.spectatortime = time;
1732         if(blockSpectators)
1733         {
1734                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1735         }
1736
1737         self.jointime = time;
1738         self.allowedTimeouts = autocvar_sv_timeout_number;
1739
1740         if(clienttype(self) == CLIENTTYPE_REAL)
1741         {
1742                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1743                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1744         }
1745
1746         if(g_lms)
1747         {
1748                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1749                 {
1750                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1751                         self.frags = FRAGS_SPECTATOR;
1752                 }
1753         }
1754
1755         if(!sv_foginterval && world.fog != "")
1756                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1757
1758         SoundEntity_Attach(self);
1759
1760         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1761         {
1762                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1763                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1764         }
1765         else
1766                 self.hitplotfh = -1;
1767
1768         if(g_race || g_cts) {
1769                 string rr;
1770                 if(g_cts)
1771                         rr = CTS_RECORD;
1772                 else
1773                         rr = RACE_RECORD;
1774                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1775
1776                 msg_entity = self;
1777                 race_send_recordtime(MSG_ONE);
1778                 race_send_speedaward(MSG_ONE);
1779
1780                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1781                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1782                 race_send_speedaward_alltimebest(MSG_ONE);
1783
1784                 float i;
1785                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1786                         race_SendRankings(i, 0, 0, MSG_ONE);
1787                 }
1788         }
1789         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1790                 send_CSQC_teamnagger();
1791
1792         if (g_domination)
1793                 set_dom_state(self);
1794
1795         CheatInitClient();
1796 }
1797
1798 /*
1799 =============
1800 ClientDisconnect
1801
1802 Called when a client disconnects from the server
1803 =============
1804 */
1805 .entity chatbubbleentity;
1806 void ReadyCount();
1807 void ClientDisconnect (void)
1808 {
1809         if(self.vehicle)
1810         {
1811             entity oldself;
1812             oldself = self;
1813             self = self.vehicle;
1814             vehicles_exit(VHEF_RELESE);
1815             self = oldself;
1816         }
1817
1818         if not(self.flags & FL_CLIENT)
1819         {
1820                 print("Warning: ClientDisconnect without ClientConnect\n");
1821                 return;
1822         }
1823
1824         PlayerStats_AddGlobalInfo(self);
1825
1826         CheatShutdownClient();
1827
1828         if(self.hitplotfh >= 0)
1829         {
1830                 fclose(self.hitplotfh);
1831                 self.hitplotfh = -1;
1832         }
1833
1834         anticheat_report();
1835         anticheat_shutdown();
1836
1837         playerdemo_shutdown();
1838
1839         bot_clientdisconnect();
1840
1841         if(self.entcs)
1842                 detach_entcs();
1843
1844         if(autocvar_sv_eventlog)
1845                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1846         bprint ("^4",self.netname);
1847         bprint ("^4 disconnected\n");
1848
1849         SoundEntity_Detach(self);
1850
1851         DropAllRunes(self);
1852         MUTATOR_CALLHOOK(ClientDisconnect);
1853
1854         Portal_ClearAll(self);
1855
1856         if(self.flagcarried)
1857                 DropFlag(self.flagcarried, world, world);
1858         if(self.ballcarried && g_nexball)
1859                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1860
1861         // Here, everything has been done that requires this player to be a client.
1862
1863         self.flags &~= FL_CLIENT;
1864
1865         if (self.chatbubbleentity)
1866                 remove (self.chatbubbleentity);
1867
1868         if (self.killindicator)
1869                 remove (self.killindicator);
1870
1871         WaypointSprite_PlayerGone();
1872
1873         bot_relinkplayerlist();
1874
1875         if(g_arena)
1876         {
1877                 Spawnqueue_Unmark(self);
1878                 Spawnqueue_Remove(self);
1879         }
1880
1881         accuracy_free(self);
1882         ClientData_Detach();
1883         PlayerScore_Detach(self);
1884
1885         if(self.netname_previous)
1886                 strunzone(self.netname_previous);
1887         if(self.clientstatus)
1888                 strunzone(self.clientstatus);
1889         if(self.weaponorder_byimpulse)
1890                 strunzone(self.weaponorder_byimpulse);
1891
1892         ClearPlayerSounds();
1893
1894         if(self.personal)
1895                 remove(self.personal);
1896
1897         self.playerid = 0;
1898         ReadyCount();
1899
1900         // free cvars
1901         GetCvars(-1);
1902 }
1903
1904 .float BUTTON_CHAT;
1905 void ChatBubbleThink()
1906 {
1907         self.nextthink = time;
1908         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1909         {
1910                 if(self.owner) // but why can that ever be world?
1911                         self.owner.chatbubbleentity = world;
1912                 remove(self);
1913                 return;
1914         }
1915         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1916 #ifdef TETRIS
1917                 || self.owner.tetris_on
1918 #endif
1919         )
1920                 self.model = self.mdl;
1921         else
1922                 self.model = "";
1923 };
1924
1925 void UpdateChatBubble()
1926 {
1927         if (!self.modelindex)
1928                 return;
1929         // spawn a chatbubble entity if needed
1930         if (!self.chatbubbleentity)
1931         {
1932                 self.chatbubbleentity = spawn();
1933                 self.chatbubbleentity.owner = self;
1934                 self.chatbubbleentity.exteriormodeltoclient = self;
1935                 self.chatbubbleentity.think = ChatBubbleThink;
1936                 self.chatbubbleentity.nextthink = time;
1937                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1938                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1939                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1940                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1941                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1942                 self.chatbubbleentity.model = "";
1943                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1944         }
1945 }
1946
1947
1948 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1949 // added to the model skins
1950 /*void UpdateColorModHack()
1951 {
1952         local float c;
1953         c = self.clientcolors & 15;
1954         // LordHavoc: only bothering to support white, green, red, yellow, blue
1955              if (!teams_matter) self.colormod = '0 0 0';
1956         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1957         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1958         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1959         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1960         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1961         else self.colormod = '1 1 1';
1962 };*/
1963
1964 .float oldcolormap;
1965 void respawn(void)
1966 {
1967         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1968         {
1969                 self.solid = SOLID_NOT;
1970                 self.takedamage = DAMAGE_NO;
1971                 self.movetype = MOVETYPE_FLY;
1972                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1973                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1974                 self.effects |= EF_ADDITIVE;
1975                 self.oldcolormap = self.colormap;
1976                 self.colormap = 512;
1977                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1978                 if(autocvar_g_respawn_ghosts_maxtime)
1979                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1980         }
1981
1982         CopyBody(1);
1983         self.effects |= EF_NODRAW; // prevent another CopyBody
1984         if(self.oldcolormap)
1985         {
1986                 self.colormap = self.oldcolormap;
1987                 self.oldcolormap = 0;
1988         }
1989         PutClientInServer();
1990 }
1991
1992 void play_countdown(float finished, string samp)
1993 {
1994         if(clienttype(self) == CLIENTTYPE_REAL)
1995                 if(floor(finished - time - frametime) != floor(finished - time))
1996                         if(finished - time < 6)
1997                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1998 }
1999
2000 /**
2001  * When sv_timeout is used this function returs strings like
2002  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2003  * Called by centerprint functions
2004  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2005  */
2006 string getTimeoutText(float addOneSecond) {
2007         if (!autocvar_sv_timeout || !timeoutStatus)
2008                 return "";
2009
2010         local string retStr;
2011         if (timeoutStatus == 1) {
2012                 if (addOneSecond == 1) {
2013                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2014                 }
2015                 else {
2016                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2017                 }
2018                 return retStr;
2019         }
2020         else if (timeoutStatus == 2) {
2021                 if (addOneSecond) {
2022                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2023                         //don't show messages like "Timeout ends in 0 seconds"...
2024                         if ((remainingTimeoutTime + 1) > 0)
2025                                 return retStr;
2026                         else
2027                                 return "";
2028                 }
2029                 else {
2030                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2031                         //don't show messages like "Timeout ends in 0 seconds"...
2032                         if (remainingTimeoutTime > 0)
2033                                 return retStr;
2034                         else
2035                                 return "";
2036                 }
2037         }
2038         else return "";
2039 }
2040
2041 void player_powerups (void)
2042 {
2043         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2044         olditems = self.items;
2045
2046         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2047         {
2048                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2049                 self.modelflags |= MF_ROCKET;
2050         }
2051         else
2052         {
2053                 SoundEntity_StopSound(self, CHAN_PLAYER);
2054                 self.modelflags &~= MF_ROCKET;
2055         }
2056
2057         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2058
2059         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2060                 return;
2061
2062         Fire_ApplyDamage(self);
2063         Fire_ApplyEffect(self);
2064
2065         if (g_minstagib)
2066         {
2067                 self.effects |= EF_FULLBRIGHT;
2068
2069                 if (self.items & IT_STRENGTH)
2070                 {
2071                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2072                         if (time > self.strength_finished)
2073                         {
2074                                 self.alpha = default_player_alpha;
2075                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2076                                 self.items &~= IT_STRENGTH;
2077                                 sprint(self, "^3Invisibility has worn off\n");
2078                         }
2079                 }
2080                 else
2081                 {
2082                         if (time < self.strength_finished)
2083                         {
2084                                 self.alpha = g_minstagib_invis_alpha;
2085                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2086                                 self.items |= IT_STRENGTH;
2087                                 sprint(self, "^3You are invisible\n");
2088                         }
2089                 }
2090
2091                 if (self.items & IT_INVINCIBLE)
2092                 {
2093                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2094                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2095                         {
2096                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2097                                 sprint(self, "^3Speed has worn off\n");
2098                         }
2099                 }
2100                 else
2101                 {
2102                         if (time < self.invincible_finished)
2103                         {
2104                                 self.items = self.items | IT_INVINCIBLE;
2105                                 sprint(self, "^3You are on speed\n");
2106                         }
2107                 }
2108         }
2109         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2110         {
2111                 if (self.items & IT_STRENGTH)
2112                 {
2113                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2114                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2115                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2116                         {
2117                                 self.items = self.items - (self.items & IT_STRENGTH);
2118                                 sprint(self, "^3Strength has worn off\n");
2119                         }
2120                 }
2121                 else
2122                 {
2123                         if (time < self.strength_finished)
2124                         {
2125                                 self.items = self.items | IT_STRENGTH;
2126                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2127                         }
2128                 }
2129                 if (self.items & IT_INVINCIBLE)
2130                 {
2131                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2132                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2133                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2134                         {
2135                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2136                                 sprint(self, "^3Shield has worn off\n");
2137                         }
2138                 }
2139                 else
2140                 {
2141                         if (time < self.invincible_finished)
2142                         {
2143                                 self.items = self.items | IT_INVINCIBLE;
2144                                 sprint(self, "^3Shield surrounds you\n");
2145                         }
2146                 }
2147
2148                 if(autocvar_g_nodepthtestplayers)
2149                         self.effects = self.effects | EF_NODEPTHTEST;
2150
2151                 if(autocvar_g_fullbrightplayers)
2152                         self.effects = self.effects | EF_FULLBRIGHT;
2153
2154                 // midair gamemode: damage only while in the air
2155                 // if in midair mode, being on ground grants temporary invulnerability
2156                 // (this is so that multishot weapon don't clear the ground flag on the
2157                 // first damage in the frame, leaving the player vulnerable to the
2158                 // remaining hits in the same frame)
2159                 if (self.flags & FL_ONGROUND)
2160                 if (g_midair)
2161                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2162
2163                 if (time >= game_starttime)
2164                 if (time < self.spawnshieldtime)
2165                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2166         }
2167
2168         MUTATOR_CALLHOOK(PlayerPowerups);
2169 }
2170
2171 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2172 {
2173         if(current > stable)
2174                 return current;
2175         else if(current > stable - 0.25) // when close enough, "snap"
2176                 return stable;
2177         else
2178                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2179 }
2180
2181 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2182 {
2183         if(current < stable)
2184                 return current;
2185         else if(current < stable + 0.25) // when close enough, "snap"
2186                 return stable;
2187         else
2188                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2189 }
2190
2191 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2192 {
2193         if(current > rotstable)
2194         {
2195                 if(rotframetime > 0)
2196                 {
2197                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2198                         current = max(rotstable, current - rotlinear * rotframetime);
2199                 }
2200         }
2201         else if(current < regenstable)
2202         {
2203                 if(regenframetime > 0)
2204                 {
2205                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2206                         current = min(regenstable, current + regenlinear * regenframetime);
2207                 }
2208         }
2209
2210         if(current > limit)
2211                 current = limit;
2212
2213         return current;
2214 }
2215
2216 void player_regen (void)
2217 {
2218         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2219         maxh = autocvar_g_balance_health_rotstable;
2220         maxa = autocvar_g_balance_armor_rotstable;
2221         maxf = autocvar_g_balance_fuel_rotstable;
2222         minh = autocvar_g_balance_health_regenstable;
2223         mina = autocvar_g_balance_armor_regenstable;
2224         minf = autocvar_g_balance_fuel_regenstable;
2225         limith = autocvar_g_balance_health_limit;
2226         limita = autocvar_g_balance_armor_limit;
2227         limitf = autocvar_g_balance_fuel_limit;
2228
2229         max_mod = regen_mod = rot_mod = limit_mod = 1;
2230
2231         if (self.runes & RUNE_REGEN)
2232         {
2233                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2234                 {
2235                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2236                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2237                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2238                 }
2239                 else
2240                 {
2241                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2242                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2243                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2244                 }
2245         }
2246         else if (self.runes & CURSE_VENOM)
2247         {
2248                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2249                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2250                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2251                 else
2252                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2253                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2254                 //if (!self.runes & RUNE_REGEN)
2255                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2256         }
2257         maxh = maxh * max_mod;
2258         //maxa = maxa * max_mod;
2259         //maxf = maxf * max_mod;
2260         minh = minh * max_mod;
2261         //mina = mina * max_mod;
2262         //minf = minf * max_mod;
2263         limith = limith * limit_mod;
2264         limita = limita * limit_mod;
2265         //limitf = limitf * limit_mod;
2266
2267         if(g_lms && g_ca)
2268                 rot_mod = 0;
2269
2270         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2271         {
2272                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2273                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2274
2275                 // if player rotted to death...  die!
2276                 if(self.health < 1)
2277                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2278         }
2279
2280         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2281                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2282 }
2283
2284 float zoomstate_set;
2285 void SetZoomState(float z)
2286 {
2287         if(z != self.zoomstate)
2288         {
2289                 self.zoomstate = z;
2290                 ClientData_Touch(self);
2291         }
2292         zoomstate_set = 1;
2293 }
2294
2295 void GetPressedKeys(void) {
2296         MUTATOR_CALLHOOK(GetPressedKeys);
2297         if (self.movement_x > 0) // get if movement keys are pressed
2298         {       // forward key pressed
2299                 self.pressedkeys |= KEY_FORWARD;
2300                 self.pressedkeys &~= KEY_BACKWARD;
2301         }
2302         else if (self.movement_x < 0)
2303         {       // backward key pressed
2304                 self.pressedkeys |= KEY_BACKWARD;
2305                 self.pressedkeys &~= KEY_FORWARD;
2306         }
2307         else
2308         {       // no x input
2309                 self.pressedkeys &~= KEY_FORWARD;
2310                 self.pressedkeys &~= KEY_BACKWARD;
2311         }
2312
2313         if (self.movement_y > 0)
2314         {       // right key pressed
2315                 self.pressedkeys |= KEY_RIGHT;
2316                 self.pressedkeys &~= KEY_LEFT;
2317         }
2318         else if (self.movement_y < 0)
2319         {       // left key pressed
2320                 self.pressedkeys |= KEY_LEFT;
2321                 self.pressedkeys &~= KEY_RIGHT;
2322         }
2323         else
2324         {       // no y input
2325                 self.pressedkeys &~= KEY_RIGHT;
2326                 self.pressedkeys &~= KEY_LEFT;
2327         }
2328
2329         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2330                 self.pressedkeys |= KEY_JUMP;
2331         else
2332                 self.pressedkeys &~= KEY_JUMP;
2333         if (self.BUTTON_CROUCH)
2334                 self.pressedkeys |= KEY_CROUCH;
2335         else
2336                 self.pressedkeys &~= KEY_CROUCH;
2337 }
2338
2339 /*
2340 ======================
2341 spectate mode routines
2342 ======================
2343 */
2344
2345 void SpectateCopy(entity spectatee) {
2346         other = spectatee;
2347         MUTATOR_CALLHOOK(SpectateCopy);
2348         self.armortype = spectatee.armortype;
2349         self.armorvalue = spectatee.armorvalue;
2350         self.ammo_cells = spectatee.ammo_cells;
2351         self.ammo_shells = spectatee.ammo_shells;
2352         self.ammo_nails = spectatee.ammo_nails;
2353         self.ammo_rockets = spectatee.ammo_rockets;
2354         self.ammo_fuel = spectatee.ammo_fuel;
2355         self.clip_load = spectatee.clip_load;
2356         self.clip_size = spectatee.clip_size;
2357         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2358         self.health = spectatee.health;
2359         self.impulse = 0;
2360         self.items = spectatee.items;
2361         self.last_pickup = spectatee.last_pickup;
2362         self.hit_time = spectatee.hit_time;
2363         self.metertime = spectatee.metertime;
2364         self.strength_finished = spectatee.strength_finished;
2365         self.invincible_finished = spectatee.invincible_finished;
2366         self.pressedkeys = spectatee.pressedkeys;
2367         self.weapons = spectatee.weapons;
2368         self.switchweapon = spectatee.switchweapon;
2369         self.weapon = spectatee.weapon;
2370         self.nex_charge = spectatee.nex_charge;
2371         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2372         self.hagar_load = spectatee.hagar_load;
2373         self.minelayer_mines = spectatee.minelayer_mines;
2374         self.punchangle = spectatee.punchangle;
2375         self.view_ofs = spectatee.view_ofs;
2376         self.v_angle = spectatee.v_angle;
2377         self.velocity = spectatee.velocity;
2378         self.dmg_take = spectatee.dmg_take;
2379         self.dmg_save = spectatee.dmg_save;
2380         self.dmg_inflictor = spectatee.dmg_inflictor;
2381         self.angles = spectatee.v_angle;
2382         //self.fixangle = TRUE;
2383         setorigin(self, spectatee.origin);
2384         setsize(self, spectatee.mins, spectatee.maxs);
2385         SetZoomState(spectatee.zoomstate);
2386
2387         anticheat_spectatecopy(spectatee);
2388
2389         //self.vehicle = spectatee.vehicle;
2390
2391         self.hud = spectatee.hud;
2392         if(spectatee.vehicle)
2393     {
2394         setorigin(self, spectatee.origin);
2395         self.velocity = spectatee.vehicle.velocity;
2396         //self.v_angle += spectatee.vehicle.angles;
2397         //self.v_angle_x *= -1;
2398         self.vehicle_health = spectatee.vehicle_health;
2399         self.vehicle_shield = spectatee.vehicle_shield;
2400         self.vehicle_energy = spectatee.vehicle_energy;
2401         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2402         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2403         self.vehicle_reload1 = spectatee.vehicle_reload1;
2404         self.vehicle_reload2 = spectatee.vehicle_reload2;
2405
2406         msg_entity = self;
2407         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2408         WriteEntity(MSG_ONE, spectatee);
2409         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2410     }
2411 }
2412
2413 float SpectateUpdate() {
2414         if(!self.enemy)
2415             return 0;
2416
2417         if (self == self.enemy)
2418                 return 0;
2419
2420         if(self.enemy.classname != "player")
2421                 return 0;
2422
2423         SpectateCopy(self.enemy);
2424
2425         return 1;
2426 }
2427
2428 float SpectateNext() {
2429         other = find(self.enemy, classname, "player");
2430
2431         if (!other)
2432                 other = find(other, classname, "player");
2433
2434         if (other)
2435                 self.enemy = other;
2436
2437         if(self.enemy.classname == "player") {
2438             if(self.enemy.vehicle)
2439             {
2440             msg_entity = self;
2441             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2442             WriteEntity(MSG_ONE, self.enemy);
2443             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2444             self.movetype = MOVETYPE_NONE;
2445             accuracy_resend(self);
2446             }
2447             else
2448             {
2449             msg_entity = self;
2450             WriteByte(MSG_ONE, SVC_SETVIEW);
2451             WriteEntity(MSG_ONE, self.enemy);
2452             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2453             self.movetype = MOVETYPE_NONE;
2454             accuracy_resend(self);
2455
2456             if(!SpectateUpdate())
2457                 PutObserverInServer();
2458         }
2459         return 1;
2460         } else {
2461                 return 0;
2462         }
2463 }
2464
2465 /*
2466 =============
2467 ShowRespawnCountdown()
2468
2469 Update a respawn countdown display.
2470 =============
2471 */
2472 void ShowRespawnCountdown()
2473 {
2474         float number;
2475         if(self.deadflag == DEAD_NO) // just respawned?
2476                 return;
2477         else
2478         {
2479                 number = ceil(self.death_time - time);
2480                 if(number <= 0)
2481                         return;
2482                 if(number <= self.respawn_countdown)
2483                 {
2484                         self.respawn_countdown = number - 1;
2485                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2486                                 AnnounceTo(self, strcat(ftos(number), ""));
2487                 }
2488         }
2489 }
2490
2491 void LeaveSpectatorMode()
2492 {
2493         if(nJoinAllowed(1)) {
2494                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2495                         self.classname = "player";
2496
2497                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2498                                 JoinBestTeam(self, FALSE, TRUE);
2499
2500                         if(autocvar_g_campaign)
2501                                 campaign_bots_may_start = 1;
2502
2503                         PutClientInServer();
2504
2505                         if(self.classname == "player")
2506                                 bprint ("^4", self.netname, "^4 is playing now\n");
2507
2508                         if(!autocvar_g_campaign)
2509                                 centerprint(self,""); // clear MOTD
2510
2511                         return;
2512                 } else {
2513                         if (g_ca && self.caplayer) {
2514                         }       // do nothing
2515                         else
2516                                 stuffcmd(self,"menu_showteamselect\n");
2517                         return;
2518                 }
2519         }
2520         else {
2521                 //player may not join because of g_maxplayers is set
2522                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2523         }
2524 }
2525
2526 /**
2527  * Determines whether the player is allowed to join. This depends on cvar
2528  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2529  * it checks whether the number of currently playing players exceeds g_maxplayers.
2530  * @return int number of free slots for players, 0 if none
2531  */
2532 float nJoinAllowed(float includeMe) {
2533         if(self.team_forced < 0)
2534                 return FALSE; // forced spectators can never join
2535
2536         // TODO simplify this
2537         local entity e;
2538
2539         local float totalClients;
2540         FOR_EACH_CLIENT(e)
2541                 totalClients += 1;
2542
2543         if (!autocvar_g_maxplayers)
2544                 return maxclients - totalClients + includeMe;
2545
2546         local float currentlyPlaying;
2547         FOR_EACH_REALPLAYER(e)
2548                 currentlyPlaying += 1;
2549
2550         if(currentlyPlaying < autocvar_g_maxplayers)
2551                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2552
2553         return 0;
2554 }
2555
2556 /**
2557  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2558  * g_maxplayers_spectator_blocktime seconds
2559  */
2560 void checkSpectatorBlock() {
2561         if(self.classname == "spectator" || self.classname == "observer") {
2562                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2563                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2564                         dropclient(self);
2565                 }
2566         }
2567 }
2568
2569 void ObserverThink()
2570 {
2571         if (self.flags & FL_JUMPRELEASED) {
2572                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2573                         self.welcomemessage_time = 0;
2574                         self.flags &~= FL_JUMPRELEASED;
2575                         self.flags |= FL_SPAWNING;
2576                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2577                         self.welcomemessage_time = 0;
2578                         self.flags &~= FL_JUMPRELEASED;
2579                         if(SpectateNext() == 1) {
2580                                 self.classname = "spectator";
2581                         }
2582                 }
2583         } else {
2584                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2585                         self.flags |= FL_JUMPRELEASED;
2586                         if(self.flags & FL_SPAWNING)
2587                         {
2588                                 self.flags &~= FL_SPAWNING;
2589                                 LeaveSpectatorMode();
2590                                 return;
2591                         }
2592                 }
2593         }
2594         PrintWelcomeMessage(self);
2595 }
2596
2597 void SpectatorThink()
2598 {
2599         if (self.flags & FL_JUMPRELEASED) {
2600                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2601                         self.welcomemessage_time = 0;
2602                         self.flags &~= FL_JUMPRELEASED;
2603                         self.flags |= FL_SPAWNING;
2604                 } else if(self.BUTTON_ATCK) {
2605                         self.welcomemessage_time = 0;
2606                         self.flags &~= FL_JUMPRELEASED;
2607                         if(SpectateNext() == 1) {
2608                                 self.classname = "spectator";
2609                         } else {
2610                                 self.classname = "observer";
2611                                 PutClientInServer();
2612                         }
2613                 } else if (self.BUTTON_ATCK2) {
2614                         self.welcomemessage_time = 0;
2615                         self.flags &~= FL_JUMPRELEASED;
2616                         self.classname = "observer";
2617                         PutClientInServer();
2618                 } else {
2619                         if(!SpectateUpdate())
2620                                 PutObserverInServer();
2621                 }
2622         } else {
2623                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2624                         self.flags |= FL_JUMPRELEASED;
2625                         if(self.flags & FL_SPAWNING)
2626                         {
2627                                 self.flags &~= FL_SPAWNING;
2628                                 LeaveSpectatorMode();
2629                                 return;
2630                         }
2631                 }
2632         }
2633
2634         PrintWelcomeMessage(self);
2635         self.flags |= FL_CLIENT | FL_NOTARGET;
2636 }
2637
2638 .float touchexplode_time;
2639
2640 /*
2641 =============
2642 PlayerPreThink
2643
2644 Called every frame for each client before the physics are run
2645 =============
2646 */
2647 void() ctf_setstatus;
2648 void() nexball_setstatus;
2649 .float items_added;
2650 void PlayerPreThink (void)
2651 {
2652         WarpZone_PlayerPhysics_FixVAngle();
2653
2654         self.stat_game_starttime = game_starttime;
2655         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2656         self.stat_leadlimit = autocvar_leadlimit;
2657
2658         if(frametime)
2659         {
2660                 // physics frames: update anticheat stuff
2661                 anticheat_prethink();
2662         }
2663
2664         if(blockSpectators && frametime)
2665                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2666                 checkSpectatorBlock();
2667
2668         zoomstate_set = 0;
2669
2670         if(self.netname_previous != self.netname)
2671         {
2672                 if(autocvar_sv_eventlog)
2673                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2674                 if(self.netname_previous)
2675                         strunzone(self.netname_previous);
2676                 self.netname_previous = strzone(self.netname);
2677         }
2678
2679         // version nagging
2680         if(self.version_nagtime)
2681                 if(self.cvar_g_xonoticversion)
2682                         if(time > self.version_nagtime)
2683                         {
2684                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2685                                 {
2686                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2687                                         {
2688                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2689                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2690                                         }
2691                                         else
2692                                         {
2693                                                 float r;
2694                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2695                                                 if(r < 0)
2696                                                 {
2697                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2698                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2699                                                 }
2700                                                 else if(r > 0)
2701                                                 {
2702                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2703                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2704                                                 }
2705                                         }
2706                                 }
2707                                 self.version_nagtime = 0;
2708                         }
2709
2710         // GOD MODE info
2711         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2712         {
2713                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2714                 self.max_armorvalue = 0;
2715         }
2716
2717 #ifdef TETRIS
2718         if (TetrisPreFrame())
2719                 return;
2720 #endif
2721
2722         MUTATOR_CALLHOOK(PlayerPreThink);
2723
2724         if(self.classname == "player") {
2725 //              if(self.netname == "Wazat")
2726 //                      bprint(self.classname, "\n");
2727
2728                 CheckRules_Player();
2729
2730                 PrintWelcomeMessage(self);
2731
2732                 if (intermission_running)
2733                 {
2734                         IntermissionThink ();   // otherwise a button could be missed between
2735                         return;                                 // the think tics
2736                 }
2737
2738                 //don't allow the player to turn around while game is paused!
2739                 if(timeoutStatus == 2) {
2740                         // FIXME turn this into CSQC stuff
2741                         self.v_angle = self.lastV_angle;
2742                         self.angles = self.lastV_angle;
2743                         self.fixangle = TRUE;
2744                 }
2745
2746                 if(frametime)
2747                 {
2748                         if(self.health <= 0 && autocvar_g_deathglow)
2749                         {
2750                                 if(self.glowmod_x > 0)
2751                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2752                                 else
2753                                         self.glowmod_x = -1;
2754                                 if(self.glowmod_y > 0)
2755                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2756                                 else
2757                                         self.glowmod_y = -1;
2758                                 if(self.glowmod_z > 0)
2759                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2760                                 else
2761                                         self.glowmod_z = -1;
2762                         }
2763                         else
2764                         {
2765                                 // set weapon and player glowmod
2766                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2767
2768                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2769                                 {
2770                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2771                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2772                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2773
2774                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2775                                         {
2776                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2777                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2778                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2779                                         }
2780                                 }
2781                                 else
2782                                         self.weaponentity_glowmod = self.glowmod;
2783                         }
2784                         player_powerups();
2785                 }
2786
2787                 if (self.deadflag != DEAD_NO)
2788                 {
2789                         float button_pressed, force_respawn;
2790                         if(self.personal && g_race_qualifying)
2791                         {
2792                                 if(time > self.death_time)
2793                                 {
2794                                         self.death_time = time + 1; // only retry once a second
2795                                         respawn();
2796                                         self.impulse = 141;
2797                                 }
2798                         }
2799                         else
2800                         {
2801                                 if(frametime)
2802                                         player_anim();
2803                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2804                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2805                                 if (self.deadflag == DEAD_DYING)
2806                                 {
2807                                         if(force_respawn)
2808                                                 self.deadflag = DEAD_RESPAWNING;
2809                                         else if(!button_pressed)
2810                                                 self.deadflag = DEAD_DEAD;
2811                                 }
2812                                 else if (self.deadflag == DEAD_DEAD)
2813                                 {
2814                                         if(button_pressed)
2815                                                 self.deadflag = DEAD_RESPAWNABLE;
2816                                 }
2817                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2818                                 {
2819                                         if(!button_pressed)
2820                                                 self.deadflag = DEAD_RESPAWNING;
2821                                 }
2822                                 else if (self.deadflag == DEAD_RESPAWNING)
2823                                 {
2824                                         if(time > self.death_time)
2825                                         {
2826                                                 self.death_time = time + 1; // only retry once a second
2827                                                 respawn();
2828                                         }
2829                                 }
2830                                 ShowRespawnCountdown();
2831                         }
2832                         return;
2833                 }
2834
2835                 if(g_touchexplode)
2836                 if(time > self.touchexplode_time)
2837                 if(self.classname == "player")
2838                 if(self.deadflag == DEAD_NO)
2839                 if not(IS_INDEPENDENT_PLAYER(self))
2840                 FOR_EACH_PLAYER(other) if(self != other)
2841                 {
2842                         if(time > other.touchexplode_time)
2843                         if(other.deadflag == DEAD_NO)
2844                         if not(IS_INDEPENDENT_PLAYER(other))
2845                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2846                         {
2847                                 PlayerTouchExplode(self, other);
2848                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2849                         }
2850                 }
2851
2852                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2853                 {
2854                         vector dist;
2855
2856                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2857                         dist = self.prevorigin - self.origin;
2858                         dist_z = 0;
2859                         self.lms_traveled_distance += fabs(vlen(dist));
2860
2861                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2862                         {
2863                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2864                                 self.lms_traveled_distance = 0;
2865                         }
2866
2867                         if(time > self.lms_nextcheck)
2868                         {
2869                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2870                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2871                                 {
2872                                         centerprint(self, autocvar_g_lms_campcheck_message);
2873                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2874                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2875                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2876                                 }
2877                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2878                                 self.lms_traveled_distance = 0;
2879                         }
2880                 }
2881
2882                 self.prevorigin = self.origin;
2883
2884                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2885                 {
2886                         if (!self.crouch)
2887                         {
2888                                 self.crouch = TRUE;
2889                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2890                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2891                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2892                         }
2893                 }
2894                 else
2895                 {
2896                         if (self.crouch)
2897                         {
2898                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2899                                 if (!trace_startsolid)
2900                                 {
2901                                         self.crouch = FALSE;
2902                                         self.view_ofs = PL_VIEW_OFS;
2903                                         setsize (self, PL_MIN, PL_MAX);
2904                                 }
2905                         }
2906                 }
2907
2908                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2909                 {
2910                         if(self.bloodloss_timer < time)
2911                         {
2912                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2913                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2914                         }
2915                 }
2916
2917                 FixPlayermodel();
2918
2919                 GrapplingHookFrame();
2920
2921                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2922                 //if(frametime)
2923                 {
2924                         self.items &~= self.items_added;
2925
2926                         W_WeaponFrame();
2927
2928                         self.items_added = 0;
2929                         if(self.items & IT_JETPACK)
2930                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2931                                         self.items_added |= IT_FUEL;
2932
2933                         self.items |= self.items_added;
2934                 }
2935
2936                 player_regen();
2937
2938                 // rot nex charge to the charge limit
2939                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2940                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2941
2942                 if(frametime)
2943                         player_anim();
2944
2945                 if (g_minstagib)
2946                         minstagib_ammocheck();
2947
2948                 if(g_ctf)
2949                         ctf_setstatus();
2950
2951                 if(g_nexball)
2952                         nexball_setstatus();
2953
2954                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2955
2956                 //self.angles_y=self.v_angle_y + 90;   // temp
2957         } else if(gameover) {
2958                 if (intermission_running)
2959                         IntermissionThink ();   // otherwise a button could be missed between
2960                 return;
2961         } else if(self.classname == "observer") {
2962                 ObserverThink();
2963         } else if(self.classname == "spectator") {
2964                 SpectatorThink();
2965         }
2966
2967         if(!zoomstate_set)
2968                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2969
2970         float oldspectatee_status;
2971         oldspectatee_status = self.spectatee_status;
2972         if(self.classname == "spectator")
2973                 self.spectatee_status = num_for_edict(self.enemy);
2974         else if(self.classname == "observer")
2975                 self.spectatee_status = num_for_edict(self);
2976         else
2977                 self.spectatee_status = 0;
2978         if(self.spectatee_status != oldspectatee_status)
2979         {
2980                 ClientData_Touch(self);
2981                 if(g_race || g_cts)
2982                         race_InitSpectator();
2983         }
2984
2985         if(self.teamkill_soundtime)
2986         if(time > self.teamkill_soundtime)
2987         {
2988                 self.teamkill_soundtime = 0;
2989
2990                 entity oldpusher, oldself;
2991
2992                 oldself = self; self = self.teamkill_soundsource;
2993                 oldpusher = self.pusher; self.pusher = oldself;
2994
2995                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2996
2997                 self.pusher = oldpusher;
2998                 self = oldself;
2999         }
3000
3001         if(self.taunt_soundtime)
3002         if(time > self.taunt_soundtime)
3003         {
3004                 self.taunt_soundtime = 0;
3005                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
3006         }
3007
3008         target_voicescript_next(self);
3009
3010         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3011         if(!self.weapon)
3012                 self.clip_load = self.clip_size = 0;
3013 }
3014
3015 float isInvisibleString(string s)
3016 {
3017         float i, n, c;
3018         s = strdecolorize(s);
3019         for((i = 0), (n = strlen(s)); i < n; ++i)
3020         {
3021                 c = str2chr(s, i);
3022                 switch(c)
3023                 {
3024                         case 0:
3025                         case 32: // space
3026                                 break;
3027                         case 192: // charmap space
3028                                 if (!autocvar_utf8_enable)
3029                                         break;
3030                                 return FALSE;
3031                         case 160: // space in unicode fonts
3032                         case 0xE000 + 192: // utf8 charmap space
3033                                 if (autocvar_utf8_enable)
3034                                         break;
3035                         default:
3036                                 return FALSE;
3037                 }
3038         }
3039         return TRUE;
3040 }
3041
3042 /*
3043 =============
3044 PlayerPostThink
3045
3046 Called every frame for each client after the physics are run
3047 =============
3048 */
3049 .float idlekick_lasttimeleft;
3050 .entity showheadshotbbox;
3051 void showheadshotbbox_think()
3052 {
3053         if(self.owner.showheadshotbbox != self)
3054         {
3055                 remove(self);
3056                 return;
3057         }
3058         self.nextthink = time;
3059         setorigin(self, self.owner.origin);
3060         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3061 }
3062 void PlayerPostThink (void)
3063 {
3064         // Savage: Check for nameless players
3065         if (isInvisibleString(self.netname)) {
3066                 self.netname = "Player";
3067                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3068         }
3069
3070         if(sv_maxidle && frametime)
3071         {
3072                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3073                 float timeleft;
3074                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3075                 if(timeleft <= 0)
3076                 {
3077                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3078                         AnnounceTo(self, "terminated");
3079                         dropclient(self);
3080                         return;
3081                 }
3082                 else if(timeleft <= 10)
3083                 {
3084                         if(timeleft != self.idlekick_lasttimeleft)
3085                         {
3086                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3087                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3088                         }
3089                 }
3090                 else
3091                 {
3092                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3093                 }
3094                 self.idlekick_lasttimeleft = timeleft;
3095         }
3096
3097 #ifdef TETRIS
3098         if(self.impulse == 100)
3099                 ImpulseCommands();
3100         if (TetrisPostFrame())
3101                 return;
3102 #endif
3103
3104         CheatFrame();
3105
3106         if(self.classname == "player") {
3107                 CheckRules_Player();
3108                 UpdateChatBubble();
3109                 if (self.impulse)
3110                         ImpulseCommands();
3111                 if (intermission_running)
3112                         return;         // intermission or finale
3113                 GetPressedKeys();
3114         } else if (self.classname == "observer") {
3115                 //do nothing
3116         } else if (self.classname == "spectator") {
3117                 //do nothing
3118         }
3119
3120         /*
3121         float i;
3122         for(i = 0; i < 1000; ++i)
3123         {
3124                 vector end;
3125                 end = self.origin + '0 0 1024' + 512 * randomvec();
3126                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3127                 if(trace_fraction < 1)
3128                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3129                 {
3130                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3131                         break;
3132                 }
3133         }
3134         */
3135
3136         Arena_Warmup();
3137
3138         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3139
3140         if(self.waypointsprite_attachedforcarrier)
3141                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3142
3143         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3144         {
3145                 if(!self.showheadshotbbox)
3146                 {
3147                         self.showheadshotbbox = spawn();
3148                         self.showheadshotbbox.classname = "headshotbbox";
3149                         self.showheadshotbbox.owner = self;
3150                         self.showheadshotbbox.think = showheadshotbbox_think;
3151                         self.showheadshotbbox.nextthink = time;
3152                         self = self.showheadshotbbox;
3153                         self.think();
3154                         self = self.owner;
3155                 }
3156         }
3157         else
3158         {
3159                 if(self.showheadshotbbox)
3160                         remove(self.showheadshotbbox);
3161         }
3162
3163         playerdemo_write();
3164
3165         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3166         {
3167                 if(!self.stored_netname)
3168                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3169                 if(self.stored_netname != self.netname)
3170                 {
3171                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3172                         strunzone(self.stored_netname);
3173                         self.stored_netname = strzone(self.netname);
3174                 }
3175         }
3176
3177         /*
3178         if(g_race)
3179                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3180         */
3181 }