qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         spot = SelectSpawnPoint (TRUE);
 142         if(!spot)
 143                 error("No spawnpoints for observers?!?\n");
 144         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 145
 146         if(IS_REAL_CLIENT(self))
 147         {
 148                 msg_entity = self;
 149                 WriteByte(MSG_ONE, SVC_SETVIEW);
 150                 WriteEntity(MSG_ONE, self);
 151         }
 152
 153         self.frags = FRAGS_SPECTATOR;
 154
 155         MUTATOR_CALLHOOK(MakePlayerObserver);
 156
 157         Portal_ClearAll(self);
 158
 159         if(self.alivetime)
 160         {
 161                 if(!warmup_stage)
 162                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 163                 self.alivetime = 0;
 164         }
 165
 166         if(self.vehicle)
 167                 vehicles_exit(VHEF_RELESE);
 168
 169         WaypointSprite_PlayerDead();
 170
 171         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 172                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 173
 174         if(self.killcount != -666)
 175         {
 176                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 177                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 178                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 179
 180                 if(self.just_joined == FALSE) {
 181                         LogTeamchange(self.playerid, -1, 4);
 182                 } else
 183                         self.just_joined = FALSE;
 184         }
 185
 186         PlayerScore_Clear(self); // clear scores when needed
 187
 188         accuracy_resend(self);
 189
 190         self.spectatortime = time;
 191
 192         self.classname = "observer";
 193         self.iscreature = FALSE;
 194         self.teleportable = TELEPORT_SIMPLE;
 195         self.damagedbycontents = FALSE;
 196         self.health = -666;
 197         self.takedamage = DAMAGE_NO;
 198         self.solid = SOLID_NOT;
 199         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 200         self.flags = FL_CLIENT | FL_NOTARGET;
 201         self.armorvalue = 666;
 202         self.effects = 0;
 203         self.armorvalue = autocvar_g_balance_armor_start;
 204         self.pauserotarmor_finished = 0;
 205         self.pauserothealth_finished = 0;
 206         self.pauseregen_finished = 0;
 207         self.damageforcescale = 0;
 208         self.death_time = 0;
 209         self.respawn_flags = 0;
 210         self.respawn_time = 0;
 211         self.stat_respawn_time = 0;
 212         self.alpha = 0;
 213         self.scale = 0;
 214         self.fade_time = 0;
 215         self.pain_frame = 0;
 216         self.pain_finished = 0;
 217         self.strength_finished = 0;
 218         self.invincible_finished = 0;
 219         self.superweapons_finished = 0;
 220         self.pushltime = 0;
 221         self.istypefrag = 0;
 222         self.think = func_null;
 223         self.nextthink = 0;
 224         self.hook_time = 0;
 225         self.deadflag = DEAD_NO;
 226         self.angles = spot.angles;
 227         self.angles_z = 0;
 228         self.fixangle = TRUE;
 229         self.crouch = FALSE;
 230
 231         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 232         self.prevorigin = self.origin;
 233         self.items = 0;
 234         self.weapons = '0 0 0';
 235         self.model = "";
 236         FixPlayermodel();
 237         setmodel(self, "null");
 238         self.drawonlytoclient = self;
 239
 240         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 241         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 242
 243         self.weapon = 0;
 244         self.weaponname = "";
 245         self.switchingweapon = 0;
 246         self.weaponmodel = "";
 247         self.weaponentity = world;
 248         self.exteriorweaponentity = world;
 249         self.killcount = -666;
 250         self.velocity = '0 0 0';
 251         self.avelocity = '0 0 0';
 252         self.punchangle = '0 0 0';
 253         self.punchvector = '0 0 0';
 254         self.oldvelocity = self.velocity;
 255         self.fire_endtime = -1;
 256 }
 257
 258 .float model_randomizer;
 259 void FixPlayermodel()
 260 {
 261         string defaultmodel;
 262         float defaultskin, chmdl, oldskin, n, i;
 263         vector m1, m2;
 264
 265         defaultmodel = "";
 266         defaultskin = 0;
 267         chmdl = FALSE;
 268
 269         if(autocvar_sv_defaultcharacter == 1)
 270         {
 271                 if(teamplay)
 272                 {
 273                         string s;
 274                         s = Team_ColorName_Lower(self.team);
 275                         if(s != "neutral")
 276                         {
 277                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 278                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 279                         }
 280                 }
 281
 282                 if(defaultmodel == "")
 283                 {
 284                         defaultmodel = autocvar_sv_defaultplayermodel;
 285                         defaultskin = autocvar_sv_defaultplayerskin;
 286                 }
 287
 288                 n = tokenize_console(defaultmodel);
 289                 if(n > 0)
 290                 {
 291                         defaultmodel = argv(floor(n * self.model_randomizer));
 292                         // However, do NOT randomize if the player-selected model is in the list.
 293                         for (i = 0; i < n; ++i)
 294                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 295                                         defaultmodel = argv(i);
 296                 }
 297
 298                 i = strstrofs(defaultmodel, ":", 0);
 299                 if(i >= 0)
 300                 {
 301                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 302                         defaultmodel = substring(defaultmodel, 0, i);
 303                 }
 304         }
 305
 306         if(defaultmodel != "")
 307         {
 308                 if (defaultmodel != self.model)
 309                 {
 310                         m1 = self.mins;
 311                         m2 = self.maxs;
 312                         setplayermodel (self, defaultmodel);
 313                         setsize (self, m1, m2);
 314                         chmdl = TRUE;
 315                 }
 316
 317                 oldskin = self.skin;
 318                 self.skin = defaultskin;
 319         } else {
 320                 if (self.playermodel != self.model || self.playermodel == "")
 321                 {
 322                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 323                         m1 = self.mins;
 324                         m2 = self.maxs;
 325                         setplayermodel (self, self.playermodel);
 326                         setsize (self, m1, m2);
 327                         chmdl = TRUE;
 328                 }
 329
 330                 oldskin = self.skin;
 331                 self.skin = stof(self.playerskin);
 332         }
 333
 334         if(chmdl || oldskin != self.skin) // model or skin has changed
 335         {
 336                 self.species = player_getspecies(); // update species
 337                 UpdatePlayerSounds(); // update skin sounds
 338         }
 339
 340         if(!teamplay)
 341                 if(strlen(autocvar_sv_defaultplayercolors))
 342                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 343                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 344 }
 345
 346 /*
 347 =============
 348 PutClientInServer
 349
 350 Called when a client spawns in the server
 351 =============
 352 */
 353 void PutClientInServer (void)
 354 {
 355         if(IS_BOT_CLIENT(self))
 356                 self.classname = "player";
 357         else if(IS_REAL_CLIENT(self))
 358         {
 359                 msg_entity = self;
 360                 WriteByte(MSG_ONE, SVC_SETVIEW);
 361                 WriteEntity(MSG_ONE, self);
 362         }
 363
 364         // reset player keys
 365         self.itemkeys = 0;
 366
 367         MUTATOR_CALLHOOK(PutClientInServer);
 368
 369         if(gameover)
 370                 self.classname = "observer";
 371
 372         if(IS_PLAYER(self))
 373         {
 374                 entity spot, oldself;
 375                 float j;
 376
 377                 accuracy_resend(self);
 378
 379                 if(self.team < 0)
 380                         JoinBestTeam(self, FALSE, TRUE);
 381
 382                 spot = SelectSpawnPoint (FALSE);
 383                 if(!spot)
 384                 {
 385                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 386                         return; // spawn failed
 387                 }
 388
 389                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 390
 391                 if(self.vehicle)
 392                         vehicles_exit(VHEF_RELESE);
 393
 394                 self.classname = "player";
 395                 self.wasplayer = TRUE;
 396                 self.iscreature = TRUE;
 397                 self.teleportable = TELEPORT_NORMAL;
 398                 self.damagedbycontents = TRUE;
 399                 self.movetype = MOVETYPE_WALK;
 400                 self.solid = SOLID_SLIDEBOX;
 401                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 402                 if(autocvar_g_playerclip_collisions)
 403                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 404                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 405                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 406                 self.frags = FRAGS_PLAYER;
 407                 if(INDEPENDENT_PLAYERS)
 408                         MAKE_INDEPENDENT_PLAYER(self);
 409                 self.flags = FL_CLIENT;
 410                 if(autocvar__notarget)
 411                         self.flags |= FL_NOTARGET;
 412                 self.takedamage = DAMAGE_AIM;
 413                 self.effects = 0;
 414                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 415                 self.air_finished = time + 12;
 416                 self.dmg = 2;
 417                 if(autocvar_g_balance_nex_charge)
 418                 {
 419                         if(autocvar_g_balance_nex_secondary_chargepool)
 420                                 self.nex_chargepool_ammo = 1;
 421                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 422                 }
 423
 424                 if(warmup_stage)
 425                 {
 426                         self.ammo_shells = warmup_start_ammo_shells;
 427                         self.ammo_nails = warmup_start_ammo_nails;
 428                         self.ammo_rockets = warmup_start_ammo_rockets;
 429                         self.ammo_cells = warmup_start_ammo_cells;
 430                         self.ammo_fuel = warmup_start_ammo_fuel;
 431                         self.health = warmup_start_health;
 432                         self.armorvalue = warmup_start_armorvalue;
 433                         self.weapons = WARMUP_START_WEAPONS;
 434                 }
 435                 else
 436                 {
 437                         self.ammo_shells = start_ammo_shells;
 438                         self.ammo_nails = start_ammo_nails;
 439                         self.ammo_rockets = start_ammo_rockets;
 440                         self.ammo_cells = start_ammo_cells;
 441                         self.ammo_fuel = start_ammo_fuel;
 442                         self.health = start_health;
 443                         self.armorvalue = start_armorvalue;
 444                         self.weapons = start_weapons;
 445                 }
 446
 447                 if(self.weapons & WEPSET_SUPERWEAPONS)
 448                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 449                 else
 450                         self.superweapons_finished = 0;
 451
 452                 if(g_weaponarena_random)
 453                 {
 454                         if(g_weaponarena_random_with_laser)
 455                                 self.weapons &= ~WEPSET_LASER;
 456                         W_RandomWeapons(self, g_weaponarena_random);
 457                         if(g_weaponarena_random_with_laser)
 458                                 self.weapons |= WEPSET_LASER;
 459                 }
 460
 461                 self.items = start_items;
 462
 463                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 464                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 465                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 466                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 467                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 468                 //extend the pause of rotting if client was reset at the beginning of the countdown
 469                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 470                         self.spawnshieldtime += game_starttime - time;
 471                         self.pauserotarmor_finished += game_starttime - time;
 472                         self.pauserothealth_finished += game_starttime - time;
 473                         self.pauseregen_finished += game_starttime - time;
 474                 }
 475                 self.damageforcescale = 2;
 476                 self.death_time = 0;
 477                 self.respawn_flags = 0;
 478                 self.respawn_time = 0;
 479                 self.stat_respawn_time = 0;
 480                 self.scale = 0;
 481                 self.fade_time = 0;
 482                 self.pain_frame = 0;
 483                 self.pain_finished = 0;
 484                 self.strength_finished = 0;
 485                 self.invincible_finished = 0;
 486                 self.pushltime = 0;
 487                 // players have no think function
 488                 self.think = func_null;
 489                 self.nextthink = 0;
 490                 self.hook_time = 0;
 491                 self.dmg_team = 0;
 492                 self.ballistics_density = autocvar_g_ballistics_density_player;
 493
 494                 self.metertime = 0;
 495
 496                 self.deadflag = DEAD_NO;
 497
 498                 self.angles = spot.angles;
 499
 500                 self.angles_z = 0; // never spawn tilted even if the spot says to
 501                 self.fixangle = TRUE; // turn this way immediately
 502                 self.velocity = '0 0 0';
 503                 self.avelocity = '0 0 0';
 504                 self.punchangle = '0 0 0';
 505                 self.punchvector = '0 0 0';
 506                 self.oldvelocity = self.velocity;
 507                 self.fire_endtime = -1;
 508
 509                 entity spawnevent = spawn();
 510                 spawnevent.owner = self;
 511                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 512
 513                 self.model = "";
 514                 FixPlayermodel();
 515                 self.drawonlytoclient = world;
 516
 517                 self.crouch = FALSE;
 518                 self.view_ofs = PL_VIEW_OFS;
 519                 setsize (self, PL_MIN, PL_MAX);
 520                 self.spawnorigin = spot.origin;
 521                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 522                 // don't reset back to last position, even if new position is stuck in solid
 523                 self.oldorigin = self.origin;
 524                 self.prevorigin = self.origin;
 525                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 526                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 527         self.hud = HUD_NORMAL;
 528
 529                 self.event_damage = PlayerDamage;
 530
 531                 self.bot_attack = TRUE;
 532                 self.monster_attack = TRUE;
 533
 534                 self.spider_slowness = 0;
 535
 536                 self.statdraintime = time + 5;
 537                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 538
 539                 if(self.killcount == -666) {
 540                         PlayerScore_Clear(self);
 541                         self.killcount = 0;
 542                 }
 543
 544                 CL_SpawnWeaponentity();
 545                 self.alpha = default_player_alpha;
 546                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 547                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 548
 549                 self.speedrunning = FALSE;
 550
 551                 //stuffcmd(self, "chase_active 0");
 552                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 553
 554                 target_voicescript_clear(self);
 555
 556                 // reset fields the weapons may use
 557                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 558                 {
 559                         weapon_action(j, WR_RESETPLAYER);
 560
 561                         // all weapons must be fully loaded when we spawn
 562                         entity e;
 563                         e = get_weaponinfo(j);
 564                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 565                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 566                 }
 567
 568                 oldself = self;
 569                 self = spot;
 570                         activator = oldself;
 571                                 string s;
 572                                 s = self.target;
 573                                 self.target = string_null;
 574                                 SUB_UseTargets();
 575                                 self.target = s;
 576                         activator = world;
 577                 self = oldself;
 578
 579                 spawn_spot = spot;
 580                 MUTATOR_CALLHOOK(PlayerSpawn);
 581
 582                 if(autocvar_spawn_debug)
 583                 {
 584                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 585                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 586                 }
 587
 588                 self.switchweapon = w_getbestweapon(self);
 589                 self.cnt = -1; // W_LastWeapon will not complain
 590                 self.weapon = 0;
 591                 self.weaponname = "";
 592                 self.switchingweapon = 0;
 593
 594                 if(!warmup_stage)
 595                         if(!self.alivetime)
 596                                 self.alivetime = time;
 597
 598                 antilag_clear(self);
 599         }
 600         else if(IS_OBSERVER(self))
 601         {
 602                 PutObserverInServer ();
 603         }
 604 }
 605
 606 .float ebouncefactor, ebouncestop; // electro's values
 607 // TODO do we need all these fields, or should we stop autodetecting runtime
 608 // changes and just have a console command to update this?
 609 float ClientInit_SendEntity(entity to, float sf)
 610 {
 611         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 612         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 613         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 614         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 615         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 625         if(sv_foginterval && world.fog != "")
 626                 WriteString(MSG_ENTITY, world.fog);
 627         else
 628                 WriteString(MSG_ENTITY, "");
 629         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 630         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 631         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 632         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 633         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 634         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 635         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 636         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 637         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 638         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 639         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 641         return TRUE;
 642 }
 643
 644 void ClientInit_CheckUpdate()
 645 {
 646         self.nextthink = time;
 647         if(self.count != autocvar_g_balance_armor_blockpercent)
 648         {
 649                 self.count = autocvar_g_balance_armor_blockpercent;
 650                 self.SendFlags |= 1;
 651         }
 652         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 653         {
 654                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 655                 self.SendFlags |= 1;
 656         }
 657         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 658         {
 659                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 660                 self.SendFlags |= 1;
 661         }
 662         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 663         {
 664                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 665                 self.SendFlags |= 1;
 666         }
 667         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 668         {
 669                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 670                 self.SendFlags |= 1;
 671         }
 672 }
 673
 674 void ClientInit_Spawn()
 675 {
 676         entity o;
 677         entity e;
 678         e = spawn();
 679         e.classname = "clientinit";
 680         e.think = ClientInit_CheckUpdate;
 681         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 682
 683         o = self;
 684         self = e;
 685         ClientInit_CheckUpdate();
 686         self = o;
 687 }
 688
 689 /*
 690 =============
 691 SetNewParms
 692 =============
 693 */
 694 void SetNewParms (void)
 695 {
 696         // initialize parms for a new player
 697         parm1 = -(86400 * 366);
 698 }
 699
 700 /*
 701 =============
 702 SetChangeParms
 703 =============
 704 */
 705 void SetChangeParms (void)
 706 {
 707         // save parms for level change
 708         parm1 = self.parm_idlesince - time;
 709 }
 710
 711 /*
 712 =============
 713 DecodeLevelParms
 714 =============
 715 */
 716 void DecodeLevelParms (void)
 717 {
 718         // load parms
 719         self.parm_idlesince = parm1;
 720         if(self.parm_idlesince == -(86400 * 366))
 721                 self.parm_idlesince = time;
 722
 723         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 724         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 725 }
 726
 727 /*
 728 =============
 729 ClientKill
 730
 731 Called when a client types 'kill' in the console
 732 =============
 733 */
 734
 735 .float clientkill_nexttime;
 736 void ClientKill_Now_TeamChange()
 737 {
 738         if(self.killindicator_teamchange == -1)
 739         {
 740                 JoinBestTeam( self, FALSE, TRUE );
 741         }
 742         else if(self.killindicator_teamchange == -2)
 743         {
 744                 if(blockSpectators)
 745                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 746                 PutObserverInServer();
 747         }
 748         else
 749                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 750         self.killindicator_teamchange = 0;
 751 }
 752
 753 void ClientKill_Now()
 754 {
 755         if(self.vehicle)
 756         {
 757             vehicles_exit(VHEF_RELESE);
 758             if(!self.killindicator_teamchange)
 759             {
 760             self.vehicle_health = -1;
 761             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 762             }
 763         }
 764
 765         if(self.killindicator && !wasfreed(self.killindicator))
 766                 remove(self.killindicator);
 767
 768         self.killindicator = world;
 769
 770         if(self.killindicator_teamchange)
 771                 ClientKill_Now_TeamChange();
 772
 773         // in any case:
 774         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 775
 776         // now I am sure the player IS dead
 777 }
 778 void KillIndicator_Think()
 779 {
 780         if (gameover)
 781         {
 782                 self.owner.killindicator = world;
 783                 remove(self);
 784                 return;
 785         }
 786
 787         if (self.owner.alpha < 0 && !self.owner.vehicle)
 788         {
 789                 self.owner.killindicator = world;
 790                 remove(self);
 791                 return;
 792         }
 793
 794         if(self.cnt <= 0)
 795         {
 796                 self = self.owner;
 797                 ClientKill_Now(); // no oldself needed
 798                 return;
 799         }
 800     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 801     {
 802         self.nextthink = time + 1;
 803         self.cnt -= 1;
 804     }
 805         else
 806         {
 807                 if(self.cnt <= 10)
 808                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 809                 if(IS_REAL_CLIENT(self.owner))
 810                 {
 811                         if(self.cnt <= 10)
 812                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 813                 }
 814                 self.nextthink = time + 1;
 815                 self.cnt -= 1;
 816         }
 817 }
 818
 819 float clientkilltime;
 820 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 821 {
 822         float killtime;
 823         float starttime;
 824         entity e;
 825
 826         if (gameover)
 827                 return;
 828
 829         killtime = autocvar_g_balance_kill_delay;
 830
 831         if(g_race_qualifying || g_cts)
 832                 killtime = 0;
 833
 834     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 835     {
 836                 remove(self.killindicator);
 837                 self.killindicator = world;
 838
 839         ClientKill_Now(); // allow instant kill in this case
 840         return;
 841     }
 842
 843         self.killindicator_teamchange = targetteam;
 844
 845     if(!self.killindicator)
 846         {
 847                 if(self.deadflag == DEAD_NO)
 848                 {
 849                         killtime = max(killtime, self.clientkill_nexttime - time);
 850                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 851                 }
 852
 853                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 854                 {
 855                         ClientKill_Now();
 856                 }
 857                 else
 858                 {
 859                         starttime = max(time, clientkilltime);
 860
 861                         self.killindicator = spawn();
 862                         self.killindicator.owner = self;
 863                         self.killindicator.scale = 0.5;
 864                         setattachment(self.killindicator, self, "");
 865                         setorigin(self.killindicator, '0 0 52');
 866                         self.killindicator.think = KillIndicator_Think;
 867                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 868                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 869                         self.killindicator.cnt = ceil(killtime);
 870                         self.killindicator.count = bound(0, ceil(killtime), 10);
 871                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 872
 873                         for(e = world; (e = find(e, classname, "body")) != world; )
 874                         {
 875                                 if(e.enemy != self)
 876                                         continue;
 877                                 e.killindicator = spawn();
 878                                 e.killindicator.owner = e;
 879                                 e.killindicator.scale = 0.5;
 880                                 setattachment(e.killindicator, e, "");
 881                                 setorigin(e.killindicator, '0 0 52');
 882                                 e.killindicator.think = KillIndicator_Think;
 883                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 884                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 885                                 e.killindicator.cnt = ceil(killtime);
 886                         }
 887                         self.lip = 0;
 888                 }
 889         }
 890         if(self.killindicator)
 891         {
 892                 if(targetteam == 0) // just die
 893                 {
 894                         self.killindicator.colormod = '0 0 0';
 895                         if(IS_REAL_CLIENT(self))
 896                         if(self.killindicator.cnt > 0)
 897                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 898                 }
 899                 else if(targetteam == -1) // auto
 900                 {
 901                         self.killindicator.colormod = '0 1 0';
 902                         if(IS_REAL_CLIENT(self))
 903                         if(self.killindicator.cnt > 0)
 904                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 905                 }
 906                 else if(targetteam == -2) // spectate
 907                 {
 908                         self.killindicator.colormod = '0.5 0.5 0.5';
 909                         if(IS_REAL_CLIENT(self))
 910                         if(self.killindicator.cnt > 0)
 911                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 912                 }
 913                 else
 914                 {
 915                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 916                         if(IS_REAL_CLIENT(self))
 917                         if(self.killindicator.cnt > 0)
 918                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 919                 }
 920         }
 921
 922 }
 923
 924 void ClientKill (void)
 925 {
 926         if(gameover) return;
 927         if(self.player_blocked) return;
 928         if(self.freezetag_frozen) return;
 929
 930         ClientKill_TeamChange(0);
 931 }
 932
 933 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 934 {
 935     e.killindicator = spawn();
 936     e.killindicator.owner = e;
 937     e.killindicator.think = KillIndicator_Think;
 938     e.killindicator.nextthink = time + (e.lip) * 0.05;
 939     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 940     e.killindicator.health = 1; // this is used to indicate that it should be silent
 941     e.lip = 0;
 942 }
 943
 944 void FixClientCvars(entity e)
 945 {
 946         // send prediction settings to the client
 947         stuffcmd(e, "\nin_bindmap 0 0\n");
 948         if(g_race || g_cts)
 949                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954         /*
 955          * we no longer need to stuff this. Remove this comment block if you feel
 956          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 957         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 958         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 959         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 960         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 961         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 962         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 963         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 964         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 965         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 966         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 967         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 968         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 969         stuffcmd(e, "cl_movement_edgefriction 1\n");
 970          */
 971 }
 972
 973 float PlayerInIDList(entity p, string idlist)
 974 {
 975         float n, i;
 976         string s;
 977
 978         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 979         if (!p.crypto_idfp)
 980                 return 0;
 981
 982         // this function allows abbreviated player IDs too!
 983         n = tokenize_console(idlist);
 984         for(i = 0; i < n; ++i)
 985         {
 986                 s = argv(i);
 987                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 988                         return 1;
 989         }
 990
 991         return 0;
 992 }
 993
 994 /*
 995 =============
 996 ClientConnect
 997
 998 Called when a client connects to the server
 999 =============
1000 */
1001 void DecodeLevelParms (void);
1002 //void dom_player_join_team(entity pl);
1003 void set_dom_state(entity e);
1004 void ClientConnect (void)
1005 {
1006         float t;
1007
1008         if(IS_CLIENT(self))
1009         {
1010                 print("Warning: ClientConnect, but already connected!\n");
1011                 return;
1012         }
1013
1014         if(Ban_MaybeEnforceBanOnce(self))
1015                 return;
1016
1017         DecodeLevelParms();
1018
1019 #ifdef WATERMARK
1020         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1021 #endif
1022
1023         self.classname = "player_joining";
1024
1025         self.flags = FL_CLIENT;
1026         self.version_nagtime = time + 10 + random() * 10;
1027
1028         if(player_count<0)
1029         {
1030                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1031                 player_count = 0;
1032         }
1033
1034         PlayerScore_Attach(self);
1035         ClientData_Attach();
1036         accuracy_init(self);
1037
1038         bot_clientconnect();
1039
1040         playerdemo_init();
1041
1042         anticheat_init();
1043
1044         // identify the right forced team
1045         if(autocvar_g_campaign)
1046         {
1047                 if(IS_REAL_CLIENT(self)) // only players, not bots
1048                 {
1049                         switch(autocvar_g_campaign_forceteam)
1050                         {
1051                                 case 1: self.team_forced = NUM_TEAM_1; break;
1052                                 case 2: self.team_forced = NUM_TEAM_2; break;
1053                                 case 3: self.team_forced = NUM_TEAM_3; break;
1054                                 case 4: self.team_forced = NUM_TEAM_4; break;
1055                                 default: self.team_forced = 0;
1056                         }
1057                 }
1058         }
1059         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1060                 self.team_forced = NUM_TEAM_1;
1061         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1062                 self.team_forced = NUM_TEAM_2;
1063         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1064                 self.team_forced = NUM_TEAM_3;
1065         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1066                 self.team_forced = NUM_TEAM_4;
1067         else if(autocvar_g_forced_team_otherwise == "red")
1068                 self.team_forced = NUM_TEAM_1;
1069         else if(autocvar_g_forced_team_otherwise == "blue")
1070                 self.team_forced = NUM_TEAM_2;
1071         else if(autocvar_g_forced_team_otherwise == "yellow")
1072                 self.team_forced = NUM_TEAM_3;
1073         else if(autocvar_g_forced_team_otherwise == "pink")
1074                 self.team_forced = NUM_TEAM_4;
1075         else if(autocvar_g_forced_team_otherwise == "spectate")
1076                 self.team_forced = -1;
1077         else if(autocvar_g_forced_team_otherwise == "spectator")
1078                 self.team_forced = -1;
1079         else
1080                 self.team_forced = 0;
1081
1082         if(!teamplay)
1083                 if(self.team_forced > 0)
1084                         self.team_forced = 0;
1085
1086         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1087
1088         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1089                 self.classname = "observer";
1090         } else {
1091                 if(teamplay)
1092                 {
1093                         if(autocvar_g_balance_teams)
1094                         {
1095                                 self.classname = "player";
1096                                 campaign_bots_may_start = 1;
1097                         }
1098                         else
1099                         {
1100                                 self.classname = "observer"; // do it anyway
1101                         }
1102                 }
1103                 else
1104                 {
1105                         self.classname = "player";
1106                         campaign_bots_may_start = 1;
1107                 }
1108         }
1109
1110         self.playerid = (playerid_last = playerid_last + 1);
1111
1112         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1113
1114     if(IS_BOT_CLIENT(self))
1115         PlayerStats_AddPlayer(self);
1116
1117         if(autocvar_sv_eventlog)
1118                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1119
1120         LogTeamchange(self.playerid, self.team, 1);
1121
1122         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1123
1124         self.netname_previous = strzone(self.netname);
1125
1126         if(IS_PLAYER(self) && teamplay)
1127                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1128         else
1129                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1130
1131         stuffcmd(self, strcat(clientstuff, "\n"));
1132         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1133
1134         FixClientCvars(self);
1135
1136         // spawnfunc_waypoint sprites
1137         WaypointSprite_InitClient(self);
1138
1139         // Wazat's grappling hook
1140         SetGrappleHookBindings();
1141
1142         // get version info from player
1143         stuffcmd(self, "cmd clientversion $gameversion\n");
1144
1145         // get other cvars from player
1146         GetCvars(0);
1147
1148         // notify about available teams
1149         if(teamplay)
1150         {
1151                 CheckAllowedTeams(self);
1152                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1153                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1154         }
1155         else
1156                 stuffcmd(self, "set _teams_available 0\n");
1157
1158         attach_entcs();
1159
1160         bot_relinkplayerlist();
1161
1162         self.spectatortime = time;
1163         if(blockSpectators)
1164         {
1165                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1166         }
1167
1168         self.jointime = time;
1169         self.allowed_timeouts = autocvar_sv_timeout_number;
1170
1171         if(IS_REAL_CLIENT(self))
1172         {
1173                 if(!autocvar_g_campaign)
1174                 {
1175                         self.motd_actived_time = -1;
1176                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1177                 }
1178
1179                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1180                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1181         }
1182
1183         if(!sv_foginterval && world.fog != "")
1184                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1185
1186         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1187         {
1188                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1189                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1190         }
1191         else
1192                 self.hitplotfh = -1;
1193
1194         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1195                 send_CSQC_teamnagger();
1196
1197         CheatInitClient();
1198
1199         CSQCMODEL_AUTOINIT();
1200
1201         self.model_randomizer = random();
1202
1203         if(IS_REAL_CLIENT(self))
1204                 sv_notice_join();
1205
1206         MUTATOR_CALLHOOK(ClientConnect);
1207 }
1208 /*
1209 =============
1210 ClientDisconnect
1211
1212 Called when a client disconnects from the server
1213 =============
1214 */
1215 .entity chatbubbleentity;
1216 void ReadyCount();
1217 void ClientDisconnect (void)
1218 {
1219         if(self.vehicle)
1220             vehicles_exit(VHEF_RELESE);
1221
1222         if (!IS_CLIENT(self))
1223         {
1224                 print("Warning: ClientDisconnect without ClientConnect\n");
1225                 return;
1226         }
1227
1228         PlayerStats_AddGlobalInfo(self);
1229
1230         CheatShutdownClient();
1231
1232         if(self.hitplotfh >= 0)
1233         {
1234                 fclose(self.hitplotfh);
1235                 self.hitplotfh = -1;
1236         }
1237
1238         anticheat_report();
1239         anticheat_shutdown();
1240
1241         playerdemo_shutdown();
1242
1243         bot_clientdisconnect();
1244
1245         if(self.entcs)
1246                 detach_entcs();
1247
1248         if(autocvar_sv_eventlog)
1249                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1250
1251         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1252
1253         MUTATOR_CALLHOOK(ClientDisconnect);
1254
1255         Portal_ClearAll(self);
1256
1257         RemoveGrapplingHook(self);
1258
1259         // Here, everything has been done that requires this player to be a client.
1260
1261         self.flags &= ~FL_CLIENT;
1262
1263         if (self.chatbubbleentity)
1264                 remove (self.chatbubbleentity);
1265
1266         if (self.killindicator)
1267                 remove (self.killindicator);
1268
1269         WaypointSprite_PlayerGone();
1270
1271         bot_relinkplayerlist();
1272
1273         accuracy_free(self);
1274         ClientData_Detach();
1275         PlayerScore_Detach(self);
1276
1277         if(self.netname_previous)
1278                 strunzone(self.netname_previous);
1279         if(self.clientstatus)
1280                 strunzone(self.clientstatus);
1281         if(self.weaponorder_byimpulse)
1282                 strunzone(self.weaponorder_byimpulse);
1283
1284         ClearPlayerSounds();
1285
1286         if(self.personal)
1287                 remove(self.personal);
1288
1289         self.playerid = 0;
1290         ReadyCount();
1291
1292         // free cvars
1293         GetCvars(-1);
1294 }
1295
1296 .float BUTTON_CHAT;
1297 void ChatBubbleThink()
1298 {
1299         self.nextthink = time;
1300         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1301         {
1302                 if(self.owner) // but why can that ever be world?
1303                         self.owner.chatbubbleentity = world;
1304                 remove(self);
1305                 return;
1306         }
1307         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1308 #ifdef TETRIS
1309                 || self.owner.tetris_on
1310 #endif
1311         )
1312                 self.model = self.mdl;
1313         else
1314                 self.model = "";
1315 }
1316
1317 void UpdateChatBubble()
1318 {
1319         if (self.alpha < 0)
1320                 return;
1321         // spawn a chatbubble entity if needed
1322         if (!self.chatbubbleentity)
1323         {
1324                 self.chatbubbleentity = spawn();
1325                 self.chatbubbleentity.owner = self;
1326                 self.chatbubbleentity.exteriormodeltoclient = self;
1327                 self.chatbubbleentity.think = ChatBubbleThink;
1328                 self.chatbubbleentity.nextthink = time;
1329                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1330                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1331                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1332                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1333                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1334                 self.chatbubbleentity.model = "";
1335                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1336         }
1337 }
1338
1339
1340 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1341 // added to the model skins
1342 /*void UpdateColorModHack()
1343 {
1344         float c;
1345         c = self.clientcolors & 15;
1346         // LordHavoc: only bothering to support white, green, red, yellow, blue
1347              if (!teamplay) self.colormod = '0 0 0';
1348         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1349         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1350         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1351         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1352         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1353         else self.colormod = '1 1 1';
1354 }*/
1355
1356 void respawn(void)
1357 {
1358         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1359         {
1360                 self.solid = SOLID_NOT;
1361                 self.takedamage = DAMAGE_NO;
1362                 self.movetype = MOVETYPE_FLY;
1363                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1364                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1365                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1366                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1367                 if(autocvar_g_respawn_ghosts_maxtime)
1368                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1369         }
1370
1371         CopyBody(1);
1372
1373         self.effects |= EF_NODRAW; // prevent another CopyBody
1374         PutClientInServer();
1375 }
1376
1377 void play_countdown(float finished, string samp)
1378 {
1379         if(IS_REAL_CLIENT(self))
1380                 if(floor(finished - time - frametime) != floor(finished - time))
1381                         if(finished - time < 6)
1382                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1383 }
1384
1385 void player_powerups (void)
1386 {
1387         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1388         olditems = self.items;
1389
1390         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1391                 self.modelflags |= MF_ROCKET;
1392         else
1393                 self.modelflags &= ~MF_ROCKET;
1394
1395         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1396
1397         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1398                 return;
1399
1400         Fire_ApplyDamage(self);
1401         Fire_ApplyEffect(self);
1402
1403         if (!g_minstagib)
1404         {
1405                 if (self.items & IT_STRENGTH)
1406                 {
1407                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1408                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1409                         if (time > self.strength_finished)
1410                         {
1411                                 self.items = self.items - (self.items & IT_STRENGTH);
1412                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1413                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1414                         }
1415                 }
1416                 else
1417                 {
1418                         if (time < self.strength_finished)
1419                         {
1420                                 self.items = self.items | IT_STRENGTH;
1421                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1422                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1423                         }
1424                 }
1425                 if (self.items & IT_INVINCIBLE)
1426                 {
1427                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1428                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1429                         if (time > self.invincible_finished)
1430                         {
1431                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1432                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1433                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1434                         }
1435                 }
1436                 else
1437                 {
1438                         if (time < self.invincible_finished)
1439                         {
1440                                 self.items = self.items | IT_INVINCIBLE;
1441                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1442                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1443                         }
1444                 }
1445                 if (self.items & IT_SUPERWEAPON)
1446                 {
1447                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1448                         {
1449                                 self.superweapons_finished = 0;
1450                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1451                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1452                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1453                         }
1454                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1455                         {
1456                                 // don't let them run out
1457                         }
1458                         else
1459                         {
1460                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1461                                 if (time > self.superweapons_finished)
1462                                 {
1463                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1464                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1465                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1466                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1467                                 }
1468                         }
1469                 }
1470                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1471                 {
1472                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1473                         {
1474                                 self.items = self.items | IT_SUPERWEAPON;
1475                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1476                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1477                         }
1478                         else
1479                         {
1480                                 self.superweapons_finished = 0;
1481                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1482                         }
1483                 }
1484                 else
1485                 {
1486                         self.superweapons_finished = 0;
1487                 }
1488         }
1489
1490         if(autocvar_g_nodepthtestplayers)
1491                 self.effects = self.effects | EF_NODEPTHTEST;
1492
1493         if(autocvar_g_fullbrightplayers)
1494                 self.effects = self.effects | EF_FULLBRIGHT;
1495
1496         if (time >= game_starttime)
1497         if (time < self.spawnshieldtime)
1498                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1499
1500         MUTATOR_CALLHOOK(PlayerPowerups);
1501 }
1502
1503 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1504 {
1505         if(current > stable)
1506                 return current;
1507         else if(current > stable - 0.25) // when close enough, "snap"
1508                 return stable;
1509         else
1510                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1511 }
1512
1513 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1514 {
1515         if(current < stable)
1516                 return current;
1517         else if(current < stable + 0.25) // when close enough, "snap"
1518                 return stable;
1519         else
1520                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1521 }
1522
1523 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1524 {
1525         if(current > rotstable)
1526         {
1527                 if(rotframetime > 0)
1528                 {
1529                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1530                         current = max(rotstable, current - rotlinear * rotframetime);
1531                 }
1532         }
1533         else if(current < regenstable)
1534         {
1535                 if(regenframetime > 0)
1536                 {
1537                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1538                         current = min(regenstable, current + regenlinear * regenframetime);
1539                 }
1540         }
1541
1542         if(current > limit)
1543                 current = limit;
1544
1545         return current;
1546 }
1547
1548 void player_regen (void)
1549 {
1550         if(!MUTATOR_CALLHOOK(PlayerRegen))
1551         {
1552                 float minh, mina, maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1553                 maxh = autocvar_g_balance_health_rotstable;
1554                 maxa = autocvar_g_balance_armor_rotstable;
1555                 minh = autocvar_g_balance_health_regenstable;
1556                 mina = autocvar_g_balance_armor_regenstable;
1557                 limith = autocvar_g_balance_health_limit;
1558                 limita = autocvar_g_balance_armor_limit;
1559
1560                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1561
1562                 maxh = maxh * max_mod;
1563                 minh = minh * max_mod;
1564                 limith = limith * limit_mod;
1565                 limita = limita * limit_mod;
1566
1567                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1568                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1569         }
1570
1571         // if player rotted to death...  die!
1572         // check this outside above checks, as player may still be able to rot to death
1573         if(self.health < 1)
1574                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1575
1576         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1577         {
1578                 float minf, maxf, limitf;
1579
1580                 maxf = autocvar_g_balance_fuel_rotstable;
1581                 minf = autocvar_g_balance_fuel_regenstable;
1582                 limitf = autocvar_g_balance_fuel_limit;
1583
1584                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1585         }
1586 }
1587
1588 float zoomstate_set;
1589 void SetZoomState(float z)
1590 {
1591         if(z != self.zoomstate)
1592         {
1593                 self.zoomstate = z;
1594                 ClientData_Touch(self);
1595         }
1596         zoomstate_set = 1;
1597 }
1598
1599 void GetPressedKeys(void) {
1600         MUTATOR_CALLHOOK(GetPressedKeys);
1601         if (self.movement_x > 0) // get if movement keys are pressed
1602         {       // forward key pressed
1603                 self.pressedkeys |= KEY_FORWARD;
1604                 self.pressedkeys &= ~KEY_BACKWARD;
1605         }
1606         else if (self.movement_x < 0)
1607         {       // backward key pressed
1608                 self.pressedkeys |= KEY_BACKWARD;
1609                 self.pressedkeys &= ~KEY_FORWARD;
1610         }
1611         else
1612         {       // no x input
1613                 self.pressedkeys &= ~KEY_FORWARD;
1614                 self.pressedkeys &= ~KEY_BACKWARD;
1615         }
1616
1617         if (self.movement_y > 0)
1618         {       // right key pressed
1619                 self.pressedkeys |= KEY_RIGHT;
1620                 self.pressedkeys &= ~KEY_LEFT;
1621         }
1622         else if (self.movement_y < 0)
1623         {       // left key pressed
1624                 self.pressedkeys |= KEY_LEFT;
1625                 self.pressedkeys &= ~KEY_RIGHT;
1626         }
1627         else
1628         {       // no y input
1629                 self.pressedkeys &= ~KEY_RIGHT;
1630                 self.pressedkeys &= ~KEY_LEFT;
1631         }
1632
1633         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1634                 self.pressedkeys |= KEY_JUMP;
1635         else
1636                 self.pressedkeys &= ~KEY_JUMP;
1637         if (self.BUTTON_CROUCH)
1638                 self.pressedkeys |= KEY_CROUCH;
1639         else
1640                 self.pressedkeys &= ~KEY_CROUCH;
1641
1642         if (self.BUTTON_ATCK)
1643                 self.pressedkeys |= KEY_ATCK;
1644         else
1645                 self.pressedkeys &= ~KEY_ATCK;
1646         if (self.BUTTON_ATCK2)
1647                 self.pressedkeys |= KEY_ATCK2;
1648         else
1649                 self.pressedkeys &= ~KEY_ATCK2;
1650 }
1651
1652 /*
1653 ======================
1654 spectate mode routines
1655 ======================
1656 */
1657
1658 void SpectateCopy(entity spectatee) {
1659         other = spectatee;
1660         MUTATOR_CALLHOOK(SpectateCopy);
1661         self.armortype = spectatee.armortype;
1662         self.armorvalue = spectatee.armorvalue;
1663         self.ammo_cells = spectatee.ammo_cells;
1664         self.ammo_shells = spectatee.ammo_shells;
1665         self.ammo_nails = spectatee.ammo_nails;
1666         self.ammo_rockets = spectatee.ammo_rockets;
1667         self.ammo_fuel = spectatee.ammo_fuel;
1668         self.clip_load = spectatee.clip_load;
1669         self.clip_size = spectatee.clip_size;
1670         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1671         self.health = spectatee.health;
1672         self.impulse = 0;
1673         self.items = spectatee.items;
1674         self.last_pickup = spectatee.last_pickup;
1675         self.hit_time = spectatee.hit_time;
1676         self.metertime = spectatee.metertime;
1677         self.strength_finished = spectatee.strength_finished;
1678         self.invincible_finished = spectatee.invincible_finished;
1679         self.pressedkeys = spectatee.pressedkeys;
1680         self.weapons = spectatee.weapons;
1681         self.switchweapon = spectatee.switchweapon;
1682         self.switchingweapon = spectatee.switchingweapon;
1683         self.weapon = spectatee.weapon;
1684         self.nex_charge = spectatee.nex_charge;
1685         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1686         self.hagar_load = spectatee.hagar_load;
1687         self.minelayer_mines = spectatee.minelayer_mines;
1688         self.punchangle = spectatee.punchangle;
1689         self.view_ofs = spectatee.view_ofs;
1690         self.velocity = spectatee.velocity;
1691         self.dmg_take = spectatee.dmg_take;
1692         self.dmg_save = spectatee.dmg_save;
1693         self.dmg_inflictor = spectatee.dmg_inflictor;
1694         self.v_angle = spectatee.v_angle;
1695         self.angles = spectatee.v_angle;
1696         if(!self.BUTTON_USE)
1697                 self.fixangle = TRUE;
1698         setorigin(self, spectatee.origin);
1699         setsize(self, spectatee.mins, spectatee.maxs);
1700         SetZoomState(spectatee.zoomstate);
1701
1702     anticheat_spectatecopy(spectatee);
1703         self.hud = spectatee.hud;
1704         if(spectatee.vehicle)
1705     {
1706         self.fixangle = FALSE;
1707         //self.velocity = spectatee.vehicle.velocity;
1708         self.vehicle_health = spectatee.vehicle_health;
1709         self.vehicle_shield = spectatee.vehicle_shield;
1710         self.vehicle_energy = spectatee.vehicle_energy;
1711         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1712         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1713         self.vehicle_reload1 = spectatee.vehicle_reload1;
1714         self.vehicle_reload2 = spectatee.vehicle_reload2;
1715
1716         msg_entity = self;
1717
1718         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1719             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1720             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1721             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1722
1723         //WriteByte (MSG_ONE, SVC_SETVIEW);
1724         //    WriteEntity(MSG_ONE, self);
1725         //makevectors(spectatee.v_angle);
1726         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1727     }
1728 }
1729
1730 float SpectateUpdate() {
1731         if(!self.enemy)
1732             return 0;
1733
1734         if (self == self.enemy)
1735                 return 0;
1736
1737         if (!IS_PLAYER(self.enemy))
1738                 return 0;
1739
1740         SpectateCopy(self.enemy);
1741
1742         return 1;
1743 }
1744
1745
1746 float SpectateSet()
1747 {
1748         if(self.enemy.classname != "player")
1749                 return FALSE;
1750         /*if(self.enemy.vehicle)
1751         {
1752
1753                 msg_entity = self;
1754                 WriteByte(MSG_ONE, SVC_SETVIEW);
1755                 WriteEntity(MSG_ONE, self.enemy);
1756                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1757
1758                 self.movetype = MOVETYPE_NONE;
1759                 accuracy_resend(self);
1760         }
1761         else
1762         {*/
1763                 msg_entity = self;
1764                 WriteByte(MSG_ONE, SVC_SETVIEW);
1765                 WriteEntity(MSG_ONE, self.enemy);
1766                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1767                 self.movetype = MOVETYPE_NONE;
1768                 accuracy_resend(self);
1769
1770                 if(!SpectateUpdate())
1771                         PutObserverInServer();
1772         //}
1773         return TRUE;
1774 }
1775
1776 float Spectate(entity pl)
1777 {
1778         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1779         if(pl.team != self.team)
1780                 return 0;
1781
1782         self.enemy = pl;
1783         return SpectateSet();
1784 }
1785
1786 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1787 entity CA_SpectateNext(entity start) {
1788         if (start.team == self.team) {
1789                 return start;
1790         }
1791
1792         other = start;
1793         // continue from current player
1794         while(other && other.team != self.team) {
1795                 other = find(other, classname, "player");
1796         }
1797
1798         if (!other) {
1799                 // restart from begining
1800                 other = find(other, classname, "player");
1801                 while(other && other.team != self.team) {
1802                         other = find(other, classname, "player");
1803                 }
1804         }
1805
1806         return other;
1807 }
1808
1809 float SpectateNext()
1810 {
1811         other = find(self.enemy, classname, "player");
1812
1813         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1814                 // CA and ca players when spectating enemies is forbidden
1815                 other = CA_SpectateNext(other);
1816         } else {
1817                 // other modes and ca spectators or spectating enemies is allowed
1818                 if (!other)
1819                         other = find(other, classname, "player");
1820         }
1821
1822         if (other)
1823                 self.enemy = other;
1824
1825         return SpectateSet();
1826 }
1827
1828 float SpectatePrev()
1829 {
1830         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1831         other = findchain(classname, "player");
1832         if (!other) // no player
1833                 return FALSE;
1834
1835         entity first = other;
1836         // skip players until current spectated player
1837         if(self.enemy)
1838         while(other && other != self.enemy)
1839                 other = other.chain;
1840
1841         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1842         {
1843                 do { other = other.chain; }
1844                 while(other && other.team != self.team);
1845
1846                 if (!other)
1847                 {
1848                         other = first;
1849                         while(other.team != self.team)
1850                                 other = other.chain;
1851                         if(other == self.enemy)
1852                                 return TRUE;
1853                 }
1854         }
1855         else
1856         {
1857                 if(other.chain)
1858                         other = other.chain;
1859                 else
1860                         other = first;
1861         }
1862         self.enemy = other;
1863         return SpectateSet();
1864 }
1865
1866 /*
1867 =============
1868 ShowRespawnCountdown()
1869
1870 Update a respawn countdown display.
1871 =============
1872 */
1873 void ShowRespawnCountdown()
1874 {
1875         float number;
1876         if(self.deadflag == DEAD_NO) // just respawned?
1877                 return;
1878         else
1879         {
1880                 number = ceil(self.respawn_time - time);
1881                 if(number <= 0)
1882                         return;
1883                 if(number <= self.respawn_countdown)
1884                 {
1885                         self.respawn_countdown = number - 1;
1886                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1887                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1888                 }
1889         }
1890 }
1891
1892 void LeaveSpectatorMode()
1893 {
1894         if(self.caplayer)
1895                 return;
1896         if(nJoinAllowed(self))
1897         {
1898                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1899                 {
1900                         self.classname = "player";
1901
1902                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1903                                 { JoinBestTeam(self, FALSE, TRUE); }
1904
1905                         if(autocvar_g_campaign)
1906                                 { campaign_bots_may_start = 1; }
1907
1908                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1909
1910                         PutClientInServer();
1911
1912                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1913                 }
1914                 else
1915                         stuffcmd(self, "menu_showteamselect\n");
1916         }
1917         else
1918         {
1919                 // Player may not join because g_maxplayers is set
1920                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1921         }
1922 }
1923
1924 /**
1925  * Determines whether the player is allowed to join. This depends on cvar
1926  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1927  * it checks whether the number of currently playing players exceeds g_maxplayers.
1928  * @return int number of free slots for players, 0 if none
1929  */
1930 float nJoinAllowed(entity ignore) {
1931         if(!ignore)
1932         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1933         // so report 0 free slots if restricted
1934         {
1935                 if(autocvar_g_forced_team_otherwise == "spectate")
1936                         return 0;
1937                 if(autocvar_g_forced_team_otherwise == "spectator")
1938                         return 0;
1939         }
1940
1941         if(self.team_forced < 0)
1942                 return 0; // forced spectators can never join
1943
1944         // TODO simplify this
1945         entity e;
1946         float totalClients = 0;
1947         FOR_EACH_CLIENT(e)
1948                 if(e != ignore)
1949                         totalClients += 1;
1950
1951         if (!autocvar_g_maxplayers)
1952                 return maxclients - totalClients;
1953
1954         float currentlyPlaying = 0;
1955         FOR_EACH_REALCLIENT(e)
1956                 if(IS_PLAYER(e) || e.caplayer == 1)
1957                         currentlyPlaying += 1;
1958
1959         if(currentlyPlaying < autocvar_g_maxplayers)
1960                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1961
1962         return 0;
1963 }
1964
1965 /**
1966  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1967  * g_maxplayers_spectator_blocktime seconds
1968  */
1969 void checkSpectatorBlock() {
1970         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1971                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1972                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1973                         dropclient(self);
1974                 }
1975         }
1976 }
1977
1978 void PrintWelcomeMessage()
1979 {
1980         if(self.motd_actived_time == 0)
1981         {
1982                 if (autocvar_g_campaign) {
1983                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1984                                 self.motd_actived_time = time;
1985                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1986                         }
1987                 } else {
1988                         if (self.BUTTON_INFO) {
1989                                 self.motd_actived_time = time;
1990                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1991                         }
1992                 }
1993         }
1994         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1995         {
1996                 if (autocvar_g_campaign) {
1997                         if (self.BUTTON_INFO)
1998                                 self.motd_actived_time = time;
1999                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2000                                 self.motd_actived_time = 0;
2001                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2002                         }
2003                 } else {
2004                         if (self.BUTTON_INFO)
2005                                 self.motd_actived_time = time;
2006                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2007                                 self.motd_actived_time = 0;
2008                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2009                         }
2010                 }
2011         }
2012         else //if(self.motd_actived_time < 0) // just connected, motd is active
2013         {
2014                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2015                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2016                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2017                 {
2018                         // instanctly hide MOTD
2019                         self.motd_actived_time = 0;
2020                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2021                 }
2022         }
2023 }
2024
2025 void ObserverThink()
2026 {
2027         float prefered_movetype;
2028         if (self.flags & FL_JUMPRELEASED) {
2029                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2030                         self.flags &= ~FL_JUMPRELEASED;
2031                         self.flags |= FL_SPAWNING;
2032                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2033                         self.flags &= ~FL_JUMPRELEASED;
2034                         if(SpectateNext()) {
2035                                 self.classname = "spectator";
2036                         }
2037                 } else {
2038                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2039                         if (self.movetype != prefered_movetype)
2040                                 self.movetype = prefered_movetype;
2041                 }
2042         } else {
2043                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2044                         self.flags |= FL_JUMPRELEASED;
2045                         if(self.flags & FL_SPAWNING)
2046                         {
2047                                 self.flags &= ~FL_SPAWNING;
2048                                 LeaveSpectatorMode();
2049                                 return;
2050                         }
2051                 }
2052         }
2053 }
2054
2055 void SpectatorThink()
2056 {
2057         if (self.flags & FL_JUMPRELEASED) {
2058                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2059                         self.flags &= ~FL_JUMPRELEASED;
2060                         self.flags |= FL_SPAWNING;
2061                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2062                         self.flags &= ~FL_JUMPRELEASED;
2063                         if(SpectateNext()) {
2064                                 self.classname = "spectator";
2065                         } else {
2066                                 self.classname = "observer";
2067                                 PutClientInServer();
2068                         }
2069                         self.impulse = 0;
2070                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2071                         self.flags &= ~FL_JUMPRELEASED;
2072                         if(SpectatePrev()) {
2073                                 self.classname = "spectator";
2074                         } else {
2075                                 self.classname = "observer";
2076                                 PutClientInServer();
2077                         }
2078                         self.impulse = 0;
2079                 } else if (self.BUTTON_ATCK2) {
2080                         self.flags &= ~FL_JUMPRELEASED;
2081                         self.classname = "observer";
2082                         PutClientInServer();
2083                 } else {
2084                         if(!SpectateUpdate())
2085                                 PutObserverInServer();
2086                 }
2087         } else {
2088                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2089                         self.flags |= FL_JUMPRELEASED;
2090                         if(self.flags & FL_SPAWNING)
2091                         {
2092                                 self.flags &= ~FL_SPAWNING;
2093                                 LeaveSpectatorMode();
2094                                 return;
2095                         }
2096                 }
2097                 if(!SpectateUpdate())
2098                         PutObserverInServer();
2099         }
2100
2101         self.flags |= FL_CLIENT | FL_NOTARGET;
2102 }
2103
2104 void PlayerUseKey()
2105 {
2106         if (!IS_PLAYER(self))
2107                 return;
2108
2109         if(self.vehicle)
2110         {
2111         vehicles_exit(VHEF_NORMAL);
2112         return;
2113         }
2114
2115         // a use key was pressed; call handlers
2116         MUTATOR_CALLHOOK(PlayerUseKey);
2117 }
2118
2119 /*
2120 =============
2121 PlayerPreThink
2122
2123 Called every frame for each client before the physics are run
2124 =============
2125 */
2126 .float usekeypressed;
2127 void() nexball_setstatus;
2128 .float items_added;
2129 void PlayerPreThink (void)
2130 {
2131         WarpZone_PlayerPhysics_FixVAngle();
2132
2133         self.stat_game_starttime = game_starttime;
2134         self.stat_round_starttime = round_starttime;
2135         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2136         self.stat_leadlimit = autocvar_leadlimit;
2137
2138         if(frametime)
2139         {
2140                 // physics frames: update anticheat stuff
2141                 anticheat_prethink();
2142         }
2143
2144         if(blockSpectators && frametime)
2145                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2146                 checkSpectatorBlock();
2147
2148         zoomstate_set = 0;
2149
2150         if(self.netname_previous != self.netname)
2151         {
2152                 if(autocvar_sv_eventlog)
2153                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2154                 if(self.netname_previous)
2155                         strunzone(self.netname_previous);
2156                 self.netname_previous = strzone(self.netname);
2157         }
2158
2159         // version nagging
2160         if(self.version_nagtime)
2161                 if(self.cvar_g_xonoticversion)
2162                         if(time > self.version_nagtime)
2163                         {
2164                                 // don't notify git users
2165                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2166                                 {
2167                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2168                                         {
2169                                                 // notify release users if connecting to git
2170                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2171                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2172                                         }
2173                                         else
2174                                         {
2175                                                 float r;
2176                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2177                                                 if(r < 0)
2178                                                 {
2179                                                         // give users new version
2180                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2181                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2182                                                 }
2183                                                 else if(r > 0)
2184                                                 {
2185                                                         // notify users about old server version
2186                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2187                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2188                                                 }
2189                                         }
2190                                 }
2191                                 self.version_nagtime = 0;
2192                         }
2193
2194         // GOD MODE info
2195         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2196         {
2197                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2198                 self.max_armorvalue = 0;
2199         }
2200
2201 #ifdef TETRIS
2202         if (TetrisPreFrame())
2203                 return;
2204 #endif
2205
2206         MUTATOR_CALLHOOK(PlayerPreThink);
2207
2208         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2209         {
2210                 if(self.BUTTON_USE && !self.usekeypressed)
2211                         PlayerUseKey();
2212                 self.usekeypressed = self.BUTTON_USE;
2213         }
2214
2215         if(IS_REAL_CLIENT(self))
2216                 PrintWelcomeMessage();
2217
2218         if(IS_PLAYER(self))
2219         {
2220
2221                 CheckRules_Player();
2222
2223                 if (intermission_running)
2224                 {
2225                         IntermissionThink ();   // otherwise a button could be missed between
2226                         return;                                 // the think tics
2227                 }
2228
2229                 //don't allow the player to turn around while game is paused!
2230                 if(timeout_status == TIMEOUT_ACTIVE) {
2231                         // FIXME turn this into CSQC stuff
2232                         self.v_angle = self.lastV_angle;
2233                         self.angles = self.lastV_angle;
2234                         self.fixangle = TRUE;
2235                 }
2236
2237                 if(frametime)
2238                 {
2239                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2240                         {
2241                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2242                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2243                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2244
2245                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2246                                 {
2247                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2248                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2249                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2250                                 }
2251                         }
2252                         else
2253                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2254
2255                         player_powerups();
2256                 }
2257
2258                 if (self.deadflag != DEAD_NO)
2259                 {
2260                         if(self.personal && g_race_qualifying)
2261                         {
2262                                 if(time > self.respawn_time)
2263                                 {
2264                                         self.respawn_time = time + 1; // only retry once a second
2265                                         self.stat_respawn_time = self.respawn_time;
2266                                         respawn();
2267                                         self.impulse = 141;
2268                                 }
2269                         }
2270                         else
2271                         {
2272                                 float button_pressed;
2273                                 if(frametime)
2274                                         player_anim();
2275                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2276
2277                                 if (self.deadflag == DEAD_DYING)
2278                                 {
2279                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2280                                                 self.deadflag = DEAD_RESPAWNING;
2281                                         else if(!button_pressed)
2282                                                 self.deadflag = DEAD_DEAD;
2283                                 }
2284                                 else if (self.deadflag == DEAD_DEAD)
2285                                 {
2286                                         if(button_pressed)
2287                                                 self.deadflag = DEAD_RESPAWNABLE;
2288                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2289                                                 self.deadflag = DEAD_RESPAWNING;
2290                                 }
2291                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2292                                 {
2293                                         if(!button_pressed)
2294                                                 self.deadflag = DEAD_RESPAWNING;
2295                                 }
2296                                 else if (self.deadflag == DEAD_RESPAWNING)
2297                                 {
2298                                         if(time > self.respawn_time)
2299                                         {
2300                                                 self.respawn_time = time + 1; // only retry once a second
2301                                                 self.respawn_time_max = self.respawn_time;
2302                                                 respawn();
2303                                         }
2304                                 }
2305
2306                                 ShowRespawnCountdown();
2307
2308                                 if(self.respawn_flags & RESPAWN_SILENT)
2309                                         self.stat_respawn_time = 0;
2310                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2311                                         self.stat_respawn_time = self.respawn_time_max;
2312                                 else
2313                                         self.stat_respawn_time = self.respawn_time;
2314                         }
2315
2316                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2317                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2318                                 self.stat_respawn_time *= -1;
2319
2320                         return;
2321                 }
2322
2323                 self.prevorigin = self.origin;
2324
2325                 float do_crouch = self.BUTTON_CROUCH;
2326                 if(self.hook.state)
2327                         do_crouch = 0;
2328                 if(self.vehicle)
2329                         do_crouch = 0;
2330                 if(self.freezetag_frozen)
2331                         do_crouch = 0;
2332                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2333                         do_crouch = 0;
2334
2335                 if (do_crouch)
2336                 {
2337                         if (!self.crouch)
2338                         {
2339                                 self.crouch = TRUE;
2340                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2341                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2342                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2343                         }
2344                 }
2345                 else
2346                 {
2347                         if (self.crouch)
2348                         {
2349                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2350                                 if (!trace_startsolid)
2351                                 {
2352                                         self.crouch = FALSE;
2353                                         self.view_ofs = PL_VIEW_OFS;
2354                                         setsize (self, PL_MIN, PL_MAX);
2355                                 }
2356                         }
2357                 }
2358
2359                 FixPlayermodel();
2360
2361                 GrapplingHookFrame();
2362
2363                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2364                 //if(frametime)
2365                 {
2366                         self.items &= ~self.items_added;
2367
2368                         W_WeaponFrame();
2369
2370                         self.items_added = 0;
2371                         if(self.items & IT_JETPACK)
2372                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2373                                         self.items_added |= IT_FUEL;
2374
2375                         self.items |= self.items_added;
2376                 }
2377
2378                 player_regen();
2379
2380                 // rot nex charge to the charge limit
2381                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2382                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2383
2384                 if(frametime)
2385                         player_anim();
2386
2387                 // secret status
2388                 secrets_setstatus();
2389
2390                 // monsters status
2391                 monsters_setstatus();
2392
2393                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2394
2395                 //self.angles_y=self.v_angle_y + 90;   // temp
2396         } else if(gameover) {
2397                 if (intermission_running)
2398                         IntermissionThink ();   // otherwise a button could be missed between
2399                 return;
2400         } else if(IS_OBSERVER(self)) {
2401                 ObserverThink();
2402         } else if(IS_SPEC(self)) {
2403                 SpectatorThink();
2404         }
2405
2406         if(!zoomstate_set)
2407                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2408
2409         float oldspectatee_status;
2410         oldspectatee_status = self.spectatee_status;
2411         if(IS_SPEC(self))
2412                 self.spectatee_status = num_for_edict(self.enemy);
2413         else if(IS_OBSERVER(self))
2414                 self.spectatee_status = num_for_edict(self);
2415         else
2416                 self.spectatee_status = 0;
2417         if(self.spectatee_status != oldspectatee_status)
2418         {
2419                 ClientData_Touch(self);
2420         }
2421
2422         if(self.teamkill_soundtime)
2423         if(time > self.teamkill_soundtime)
2424         {
2425                 self.teamkill_soundtime = 0;
2426
2427                 entity oldpusher, oldself;
2428
2429                 oldself = self; self = self.teamkill_soundsource;
2430                 oldpusher = self.pusher; self.pusher = oldself;
2431
2432                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2433
2434                 self.pusher = oldpusher;
2435                 self = oldself;
2436         }
2437
2438         if(self.taunt_soundtime)
2439         if(time > self.taunt_soundtime)
2440         {
2441                 self.taunt_soundtime = 0;
2442                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2443         }
2444
2445         target_voicescript_next(self);
2446
2447         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2448         if(!self.weapon)
2449                 self.clip_load = self.clip_size = 0;
2450 }
2451
2452 float isInvisibleString(string s)
2453 {
2454         float i, n, c;
2455         s = strdecolorize(s);
2456         for((i = 0), (n = strlen(s)); i < n; ++i)
2457         {
2458                 c = str2chr(s, i);
2459                 switch(c)
2460                 {
2461                         case 0:
2462                         case 32: // space
2463                                 break;
2464                         case 192: // charmap space
2465                                 if (!autocvar_utf8_enable)
2466                                         break;
2467                                 return FALSE;
2468                         case 160: // space in unicode fonts
2469                         case 0xE000 + 192: // utf8 charmap space
2470                                 if (autocvar_utf8_enable)
2471                                         break;
2472                         default:
2473                                 return FALSE;
2474                 }
2475         }
2476         return TRUE;
2477 }
2478
2479 /*
2480 =============
2481 PlayerPostThink
2482
2483 Called every frame for each client after the physics are run
2484 =============
2485 */
2486 .float idlekick_lasttimeleft;
2487 void PlayerPostThink (void)
2488 {
2489         // Savage: Check for nameless players
2490         if (isInvisibleString(self.netname)) {
2491                 self.netname = "Player";
2492                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2493         }
2494
2495         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2496         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2497         {
2498                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2499                 {
2500                         if(self.idlekick_lasttimeleft)
2501                         {
2502                                 self.idlekick_lasttimeleft = 0;
2503                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2504                         }
2505                 }
2506                 else
2507                 {
2508                         float timeleft;
2509                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2510                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2511                         {
2512                                 if(!self.idlekick_lasttimeleft)
2513                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2514                         }
2515                         if(timeleft <= 0)
2516                         {
2517                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2518                                 dropclient(self);
2519                                 return;
2520                         }
2521                         else if(timeleft <= 10)
2522                         {
2523                                 if(timeleft != self.idlekick_lasttimeleft)
2524                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2525                                 self.idlekick_lasttimeleft = timeleft;
2526                         }
2527                 }
2528         }
2529
2530 #ifdef TETRIS
2531         if(self.impulse == 100)
2532                 ImpulseCommands();
2533         if (!TetrisPostFrame())
2534         {
2535 #endif
2536
2537         CheatFrame();
2538
2539         //CheckPlayerJump();
2540
2541         if(IS_PLAYER(self)) {
2542                 CheckRules_Player();
2543                 UpdateChatBubble();
2544                 if (self.impulse)
2545                         ImpulseCommands();
2546                 if (intermission_running)
2547                         return;         // intermission or finale
2548                 GetPressedKeys();
2549         }
2550
2551 #ifdef TETRIS
2552         }
2553 #endif
2554
2555         /*
2556         float i;
2557         for(i = 0; i < 1000; ++i)
2558         {
2559                 vector end;
2560                 end = self.origin + '0 0 1024' + 512 * randomvec();
2561                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2562                 if(trace_fraction < 1)
2563                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2564                 {
2565                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2566                         break;
2567                 }
2568         }
2569         */
2570
2571         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2572
2573         if(self.waypointsprite_attachedforcarrier)
2574                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2575
2576         playerdemo_write();
2577
2578         CSQCMODEL_AUTOUPDATE();
2579 }