qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         Unfreeze(self);
 172
 173         if(self.alivetime)
 174         {
 175                 if(!warmup_stage)
 176                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 177                 self.alivetime = 0;
 178         }
 179
 180         if(self.vehicle)
 181                 vehicles_exit(VHEF_RELESE);
 182
 183         WaypointSprite_PlayerDead();
 184
 185         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 186                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 187
 188         if(self.killcount != -666)
 189         {
 190                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 191
 192                 if(self.just_joined == FALSE) {
 193                         LogTeamchange(self.playerid, -1, 4);
 194                 } else
 195                         self.just_joined = FALSE;
 196         }
 197
 198         PlayerScore_Clear(self); // clear scores when needed
 199
 200         accuracy_resend(self);
 201
 202         self.spectatortime = time;
 203
 204         self.classname = "observer";
 205         self.iscreature = FALSE;
 206         self.teleportable = TELEPORT_SIMPLE;
 207         self.damagedbycontents = FALSE;
 208         self.health = -666;
 209         self.takedamage = DAMAGE_NO;
 210         self.solid = SOLID_NOT;
 211         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 212         self.flags = FL_CLIENT | FL_NOTARGET;
 213         self.armorvalue = 666;
 214         self.effects = 0;
 215         self.armorvalue = autocvar_g_balance_armor_start;
 216         self.pauserotarmor_finished = 0;
 217         self.pauserothealth_finished = 0;
 218         self.pauseregen_finished = 0;
 219         self.damageforcescale = 0;
 220         self.death_time = 0;
 221         self.respawn_flags = 0;
 222         self.respawn_time = 0;
 223         self.stat_respawn_time = 0;
 224         self.alpha = 0;
 225         self.scale = 0;
 226         self.fade_time = 0;
 227         self.pain_frame = 0;
 228         self.pain_finished = 0;
 229         self.strength_finished = 0;
 230         self.invincible_finished = 0;
 231         self.superweapons_finished = 0;
 232         self.pushltime = 0;
 233         self.istypefrag = 0;
 234         self.think = func_null;
 235         self.nextthink = 0;
 236         self.hook_time = 0;
 237         self.deadflag = DEAD_NO;
 238         self.angles = spot.angles;
 239         self.angles_z = 0;
 240         self.fixangle = TRUE;
 241         self.crouch = FALSE;
 242
 243         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 244         self.prevorigin = self.origin;
 245         self.items = 0;
 246         self.weapons = '0 0 0';
 247         self.model = "";
 248         FixPlayermodel();
 249         setmodel(self, "null");
 250         self.drawonlytoclient = self;
 251
 252         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254
 255         self.weapon = 0;
 256         self.weaponname = "";
 257         self.switchingweapon = 0;
 258         self.weaponmodel = "";
 259         self.weaponentity = world;
 260         self.exteriorweaponentity = world;
 261         self.killcount = -666;
 262         self.velocity = '0 0 0';
 263         self.avelocity = '0 0 0';
 264         self.punchangle = '0 0 0';
 265         self.punchvector = '0 0 0';
 266         self.oldvelocity = self.velocity;
 267         self.fire_endtime = -1;
 268 }
 269
 270 .float model_randomizer;
 271 void FixPlayermodel()
 272 {
 273         string defaultmodel;
 274         float defaultskin, chmdl, oldskin, n, i;
 275         vector m1, m2;
 276
 277         defaultmodel = "";
 278         defaultskin = 0;
 279         chmdl = FALSE;
 280
 281         if(autocvar_sv_defaultcharacter == 1)
 282         {
 283                 if(teamplay)
 284                 {
 285                         string s;
 286                         s = Team_ColorName_Lower(self.team);
 287                         if(s != "neutral")
 288                         {
 289                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 290                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 291                         }
 292                 }
 293
 294                 if(defaultmodel == "")
 295                 {
 296                         defaultmodel = autocvar_sv_defaultplayermodel;
 297                         defaultskin = autocvar_sv_defaultplayerskin;
 298                 }
 299
 300                 n = tokenize_console(defaultmodel);
 301                 if(n > 0)
 302                 {
 303                         defaultmodel = argv(floor(n * self.model_randomizer));
 304                         // However, do NOT randomize if the player-selected model is in the list.
 305                         for (i = 0; i < n; ++i)
 306                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 307                                         defaultmodel = argv(i);
 308                 }
 309
 310                 i = strstrofs(defaultmodel, ":", 0);
 311                 if(i >= 0)
 312                 {
 313                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 314                         defaultmodel = substring(defaultmodel, 0, i);
 315                 }
 316         }
 317
 318         if(defaultmodel != "")
 319         {
 320                 if (defaultmodel != self.model)
 321                 {
 322                         m1 = self.mins;
 323                         m2 = self.maxs;
 324                         setplayermodel (self, defaultmodel);
 325                         setsize (self, m1, m2);
 326                         chmdl = TRUE;
 327                 }
 328
 329                 oldskin = self.skin;
 330                 self.skin = defaultskin;
 331         } else {
 332                 if (self.playermodel != self.model || self.playermodel == "")
 333                 {
 334                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 335                         m1 = self.mins;
 336                         m2 = self.maxs;
 337                         setplayermodel (self, self.playermodel);
 338                         setsize (self, m1, m2);
 339                         chmdl = TRUE;
 340                 }
 341
 342                 oldskin = self.skin;
 343                 self.skin = stof(self.playerskin);
 344         }
 345
 346         if(chmdl || oldskin != self.skin) // model or skin has changed
 347         {
 348                 self.species = player_getspecies(); // update species
 349                 UpdatePlayerSounds(); // update skin sounds
 350         }
 351
 352         if(!teamplay)
 353                 if(strlen(autocvar_sv_defaultplayercolors))
 354                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 355                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 356 }
 357
 358 /*
 359 =============
 360 PutClientInServer
 361
 362 Called when a client spawns in the server
 363 =============
 364 */
 365 void PutClientInServer (void)
 366 {
 367         if(IS_BOT_CLIENT(self))
 368                 self.classname = "player";
 369         else if(IS_REAL_CLIENT(self))
 370         {
 371                 msg_entity = self;
 372                 WriteByte(MSG_ONE, SVC_SETVIEW);
 373                 WriteEntity(MSG_ONE, self);
 374         }
 375
 376         // reset player keys
 377         self.itemkeys = 0;
 378
 379         MUTATOR_CALLHOOK(PutClientInServer);
 380
 381         if(gameover)
 382                 self.classname = "observer";
 383
 384         if(IS_PLAYER(self))
 385         {
 386                 entity spot, oldself;
 387                 float j;
 388
 389                 accuracy_resend(self);
 390
 391                 if(self.team < 0)
 392                         JoinBestTeam(self, FALSE, TRUE);
 393
 394                 race_PreSpawn();
 395
 396                 spot = SelectSpawnPoint (FALSE);
 397                 if(!spot)
 398                 {
 399                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 400                         return; // spawn failed
 401                 }
 402
 403                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 404
 405                 self.classname = "player";
 406                 self.wasplayer = TRUE;
 407                 self.iscreature = TRUE;
 408                 self.teleportable = TELEPORT_NORMAL;
 409                 self.damagedbycontents = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 413                 if(autocvar_g_playerclip_collisions)
 414                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 415                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 416                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 417                 self.frags = FRAGS_PLAYER;
 418                 if(INDEPENDENT_PLAYERS)
 419                         MAKE_INDEPENDENT_PLAYER(self);
 420                 self.flags = FL_CLIENT;
 421                 if(autocvar__notarget)
 422                         self.flags |= FL_NOTARGET;
 423                 self.takedamage = DAMAGE_AIM;
 424                 self.effects = 0;
 425                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 426                 self.air_finished = time + 12;
 427                 self.dmg = 2;
 428                 if(autocvar_g_balance_nex_charge)
 429                 {
 430                         if(autocvar_g_balance_nex_secondary_chargepool)
 431                                 self.nex_chargepool_ammo = 1;
 432                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 433                 }
 434
 435                 if(warmup_stage)
 436                 {
 437                         self.ammo_shells = warmup_start_ammo_shells;
 438                         self.ammo_nails = warmup_start_ammo_nails;
 439                         self.ammo_rockets = warmup_start_ammo_rockets;
 440                         self.ammo_cells = warmup_start_ammo_cells;
 441                         self.ammo_fuel = warmup_start_ammo_fuel;
 442                         self.health = warmup_start_health;
 443                         self.armorvalue = warmup_start_armorvalue;
 444                         self.weapons = warmup_start_weapons;
 445                 }
 446                 else
 447                 {
 448                         self.ammo_shells = start_ammo_shells;
 449                         self.ammo_nails = start_ammo_nails;
 450                         self.ammo_rockets = start_ammo_rockets;
 451                         self.ammo_cells = start_ammo_cells;
 452                         self.ammo_fuel = start_ammo_fuel;
 453                         self.health = start_health;
 454                         self.armorvalue = start_armorvalue;
 455                         self.weapons = start_weapons;
 456                 }
 457
 458                 if(self.weapons & WEPSET_SUPERWEAPONS)
 459                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 460                 else
 461                         self.superweapons_finished = 0;
 462
 463                 if(g_weaponarena_random)
 464                 {
 465                         if(g_weaponarena_random_with_laser)
 466                                 self.weapons &= ~WEPSET_LASER;
 467                         W_RandomWeapons(self, g_weaponarena_random);
 468                         if(g_weaponarena_random_with_laser)
 469                                 self.weapons |= WEPSET_LASER;
 470                 }
 471
 472                 self.items = start_items;
 473
 474                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 475                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 476                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 477                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 478                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 479                 //extend the pause of rotting if client was reset at the beginning of the countdown
 480                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 481                         self.spawnshieldtime += game_starttime - time;
 482                         self.pauserotarmor_finished += game_starttime - time;
 483                         self.pauserothealth_finished += game_starttime - time;
 484                         self.pauseregen_finished += game_starttime - time;
 485                 }
 486                 self.damageforcescale = 2;
 487                 self.death_time = 0;
 488                 self.respawn_flags = 0;
 489                 self.respawn_time = 0;
 490                 self.stat_respawn_time = 0;
 491                 self.scale = 0;
 492                 self.fade_time = 0;
 493                 self.pain_frame = 0;
 494                 self.pain_finished = 0;
 495                 self.strength_finished = 0;
 496                 self.invincible_finished = 0;
 497                 self.pushltime = 0;
 498                 // players have no think function
 499                 self.think = func_null;
 500                 self.nextthink = 0;
 501                 self.hook_time = 0;
 502                 self.dmg_team = 0;
 503                 self.ballistics_density = autocvar_g_ballistics_density_player;
 504
 505                 self.metertime = 0;
 506
 507                 self.deadflag = DEAD_NO;
 508
 509                 self.angles = spot.angles;
 510
 511                 self.angles_z = 0; // never spawn tilted even if the spot says to
 512                 self.fixangle = TRUE; // turn this way immediately
 513                 self.velocity = '0 0 0';
 514                 self.avelocity = '0 0 0';
 515                 self.punchangle = '0 0 0';
 516                 self.punchvector = '0 0 0';
 517                 self.oldvelocity = self.velocity;
 518                 self.fire_endtime = -1;
 519
 520                 entity spawnevent = spawn();
 521                 spawnevent.owner = self;
 522                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 523
 524                 self.model = "";
 525                 FixPlayermodel();
 526                 self.drawonlytoclient = world;
 527
 528                 self.crouch = FALSE;
 529                 self.view_ofs = PL_VIEW_OFS;
 530                 setsize (self, PL_MIN, PL_MAX);
 531                 self.spawnorigin = spot.origin;
 532                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 533                 // don't reset back to last position, even if new position is stuck in solid
 534                 self.oldorigin = self.origin;
 535                 self.prevorigin = self.origin;
 536                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 537                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 538         self.hud = HUD_NORMAL;
 539
 540                 self.event_damage = PlayerDamage;
 541
 542                 self.bot_attack = TRUE;
 543                 self.monster_attack = TRUE;
 544
 545                 self.spider_slowness = 0;
 546
 547                 self.statdraintime = time + 5;
 548                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 549
 550                 if(self.killcount == -666) {
 551                         PlayerScore_Clear(self);
 552                         self.killcount = 0;
 553                 }
 554
 555                 CL_SpawnWeaponentity();
 556                 self.alpha = default_player_alpha;
 557                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 558                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 559
 560                 self.speedrunning = FALSE;
 561
 562                 race_PostSpawn(spot);
 563
 564                 //stuffcmd(self, "chase_active 0");
 565                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 566
 567                 target_voicescript_clear(self);
 568
 569                 // reset fields the weapons may use
 570                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 571                 {
 572                         weapon_action(j, WR_RESETPLAYER);
 573
 574                         // all weapons must be fully loaded when we spawn
 575                         entity e;
 576                         e = get_weaponinfo(j);
 577                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 578                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 579                 }
 580
 581                 oldself = self;
 582                 self = spot;
 583                         activator = oldself;
 584                                 string s;
 585                                 s = self.target;
 586                                 self.target = string_null;
 587                                 SUB_UseTargets();
 588                                 self.target = s;
 589                         activator = world;
 590                 self = oldself;
 591
 592                 Unfreeze(self);
 593
 594                 spawn_spot = spot;
 595                 MUTATOR_CALLHOOK(PlayerSpawn);
 596
 597                 if(autocvar_spawn_debug)
 598                 {
 599                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 600                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 601                 }
 602
 603                 self.switchweapon = w_getbestweapon(self);
 604                 self.cnt = -1; // W_LastWeapon will not complain
 605                 self.weapon = 0;
 606                 self.weaponname = "";
 607                 self.switchingweapon = 0;
 608
 609                 if(!warmup_stage)
 610                         if(!self.alivetime)
 611                                 self.alivetime = time;
 612
 613                 antilag_clear(self);
 614         }
 615         else if(IS_OBSERVER(self))
 616         {
 617                 PutObserverInServer ();
 618         }
 619 }
 620
 621 .float ebouncefactor, ebouncestop; // electro's values
 622 // TODO do we need all these fields, or should we stop autodetecting runtime
 623 // changes and just have a console command to update this?
 624 float ClientInit_SendEntity(entity to, float sf)
 625 {
 626         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 627         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 640         if(sv_foginterval && world.fog != "")
 641                 WriteString(MSG_ENTITY, world.fog);
 642         else
 643                 WriteString(MSG_ENTITY, "");
 644         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 645         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 646         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 647         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 648         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 650         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 651         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 652         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 653         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 654         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 655         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 656         return TRUE;
 657 }
 658
 659 void ClientInit_CheckUpdate()
 660 {
 661         self.nextthink = time;
 662         if(self.count != autocvar_g_balance_armor_blockpercent)
 663         {
 664                 self.count = autocvar_g_balance_armor_blockpercent;
 665                 self.SendFlags |= 1;
 666         }
 667         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 668         {
 669                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 670                 self.SendFlags |= 1;
 671         }
 672         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 673         {
 674                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 675                 self.SendFlags |= 1;
 676         }
 677         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 678         {
 679                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 680                 self.SendFlags |= 1;
 681         }
 682         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 683         {
 684                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 685                 self.SendFlags |= 1;
 686         }
 687 }
 688
 689 void ClientInit_Spawn()
 690 {
 691         entity o;
 692         entity e;
 693         e = spawn();
 694         e.classname = "clientinit";
 695         e.think = ClientInit_CheckUpdate;
 696         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 697
 698         o = self;
 699         self = e;
 700         ClientInit_CheckUpdate();
 701         self = o;
 702 }
 703
 704 /*
 705 =============
 706 SetNewParms
 707 =============
 708 */
 709 void SetNewParms (void)
 710 {
 711         // initialize parms for a new player
 712         parm1 = -(86400 * 366);
 713 }
 714
 715 /*
 716 =============
 717 SetChangeParms
 718 =============
 719 */
 720 void SetChangeParms (void)
 721 {
 722         // save parms for level change
 723         parm1 = self.parm_idlesince - time;
 724 }
 725
 726 /*
 727 =============
 728 DecodeLevelParms
 729 =============
 730 */
 731 void DecodeLevelParms (void)
 732 {
 733         // load parms
 734         self.parm_idlesince = parm1;
 735         if(self.parm_idlesince == -(86400 * 366))
 736                 self.parm_idlesince = time;
 737
 738         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 739         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 740 }
 741
 742 /*
 743 =============
 744 ClientKill
 745
 746 Called when a client types 'kill' in the console
 747 =============
 748 */
 749
 750 .float clientkill_nexttime;
 751 void ClientKill_Now_TeamChange()
 752 {
 753         if(self.killindicator_teamchange == -1)
 754         {
 755                 JoinBestTeam( self, FALSE, TRUE );
 756         }
 757         else if(self.killindicator_teamchange == -2)
 758         {
 759                 if(blockSpectators)
 760                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 761                 PutObserverInServer();
 762         }
 763         else
 764                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 765         self.killindicator_teamchange = 0;
 766 }
 767
 768 void ClientKill_Now()
 769 {
 770         if(self.vehicle)
 771         {
 772             vehicles_exit(VHEF_RELESE);
 773             if(!self.killindicator_teamchange)
 774             {
 775             self.vehicle_health = -1;
 776             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 777             }
 778         }
 779
 780         if(self.killindicator && !wasfreed(self.killindicator))
 781                 remove(self.killindicator);
 782
 783         self.killindicator = world;
 784
 785         if(self.killindicator_teamchange)
 786                 ClientKill_Now_TeamChange();
 787
 788         // in any case:
 789         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 790
 791         // now I am sure the player IS dead
 792 }
 793 void KillIndicator_Think()
 794 {
 795         if (gameover)
 796         {
 797                 self.owner.killindicator = world;
 798                 remove(self);
 799                 return;
 800         }
 801
 802         if (self.owner.alpha < 0 && !self.owner.vehicle)
 803         {
 804                 self.owner.killindicator = world;
 805                 remove(self);
 806                 return;
 807         }
 808
 809         if(self.cnt <= 0)
 810         {
 811                 self = self.owner;
 812                 ClientKill_Now(); // no oldself needed
 813                 return;
 814         }
 815     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 816     {
 817         self.nextthink = time + 1;
 818         self.cnt -= 1;
 819     }
 820         else
 821         {
 822                 if(self.cnt <= 10)
 823                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 824                 if(IS_REAL_CLIENT(self.owner))
 825                 {
 826                         if(self.cnt <= 10)
 827                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 828                 }
 829                 self.nextthink = time + 1;
 830                 self.cnt -= 1;
 831         }
 832 }
 833
 834 float clientkilltime;
 835 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 836 {
 837         float killtime;
 838         float starttime;
 839         entity e;
 840
 841         if (gameover)
 842                 return;
 843
 844         killtime = autocvar_g_balance_kill_delay;
 845
 846         if(g_race_qualifying || g_cts)
 847                 killtime = 0;
 848
 849     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 850     {
 851                 remove(self.killindicator);
 852                 self.killindicator = world;
 853
 854         ClientKill_Now(); // allow instant kill in this case
 855         return;
 856     }
 857
 858         self.killindicator_teamchange = targetteam;
 859
 860     if(!self.killindicator)
 861         {
 862                 if(self.deadflag == DEAD_NO)
 863                 {
 864                         killtime = max(killtime, self.clientkill_nexttime - time);
 865                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 866                 }
 867
 868                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 869                 {
 870                         ClientKill_Now();
 871                 }
 872                 else
 873                 {
 874                         starttime = max(time, clientkilltime);
 875
 876                         self.killindicator = spawn();
 877                         self.killindicator.owner = self;
 878                         self.killindicator.scale = 0.5;
 879                         setattachment(self.killindicator, self, "");
 880                         setorigin(self.killindicator, '0 0 52');
 881                         self.killindicator.think = KillIndicator_Think;
 882                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 883                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 884                         self.killindicator.cnt = ceil(killtime);
 885                         self.killindicator.count = bound(0, ceil(killtime), 10);
 886                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 887
 888                         for(e = world; (e = find(e, classname, "body")) != world; )
 889                         {
 890                                 if(e.enemy != self)
 891                                         continue;
 892                                 e.killindicator = spawn();
 893                                 e.killindicator.owner = e;
 894                                 e.killindicator.scale = 0.5;
 895                                 setattachment(e.killindicator, e, "");
 896                                 setorigin(e.killindicator, '0 0 52');
 897                                 e.killindicator.think = KillIndicator_Think;
 898                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 899                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 900                                 e.killindicator.cnt = ceil(killtime);
 901                         }
 902                         self.lip = 0;
 903                 }
 904         }
 905         if(self.killindicator)
 906         {
 907                 if(targetteam == 0) // just die
 908                 {
 909                         self.killindicator.colormod = '0 0 0';
 910                         if(IS_REAL_CLIENT(self))
 911                         if(self.killindicator.cnt > 0)
 912                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 913                 }
 914                 else if(targetteam == -1) // auto
 915                 {
 916                         self.killindicator.colormod = '0 1 0';
 917                         if(IS_REAL_CLIENT(self))
 918                         if(self.killindicator.cnt > 0)
 919                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 920                 }
 921                 else if(targetteam == -2) // spectate
 922                 {
 923                         self.killindicator.colormod = '0.5 0.5 0.5';
 924                         if(IS_REAL_CLIENT(self))
 925                         if(self.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 927                 }
 928                 else
 929                 {
 930                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 931                         if(IS_REAL_CLIENT(self))
 932                         if(self.killindicator.cnt > 0)
 933                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 934                 }
 935         }
 936
 937 }
 938
 939 void ClientKill (void)
 940 {
 941         if(gameover) return;
 942         if(self.player_blocked) return;
 943         if(self.frozen) return;
 944
 945         ClientKill_TeamChange(0);
 946 }
 947
 948 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 949 {
 950     e.killindicator = spawn();
 951     e.killindicator.owner = e;
 952     e.killindicator.think = KillIndicator_Think;
 953     e.killindicator.nextthink = time + (e.lip) * 0.05;
 954     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 955     e.killindicator.health = 1; // this is used to indicate that it should be silent
 956     e.lip = 0;
 957 }
 958
 959 void FixClientCvars(entity e)
 960 {
 961         // send prediction settings to the client
 962         stuffcmd(e, "\nin_bindmap 0 0\n");
 963         if(g_race || g_cts)
 964                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 965         if(autocvar_g_antilag == 3) // client side hitscan
 966                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 967         if(autocvar_sv_gentle)
 968                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 969         /*
 970          * we no longer need to stuff this. Remove this comment block if you feel
 971          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 972         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 973         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 974         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 975         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 976         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 977         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 978         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 979         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 980         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 983         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 984         stuffcmd(e, "cl_movement_edgefriction 1\n");
 985          */
 986 }
 987
 988 float PlayerInIDList(entity p, string idlist)
 989 {
 990         float n, i;
 991         string s;
 992
 993         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 994         if not(p.crypto_idfp)
 995                 return 0;
 996
 997         // this function allows abbreviated player IDs too!
 998         n = tokenize_console(idlist);
 999         for(i = 0; i < n; ++i)
1000         {
1001                 s = argv(i);
1002                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1003                         return 1;
1004         }
1005
1006         return 0;
1007 }
1008
1009 /*
1010 =============
1011 ClientConnect
1012
1013 Called when a client connects to the server
1014 =============
1015 */
1016 void DecodeLevelParms (void);
1017 //void dom_player_join_team(entity pl);
1018 void set_dom_state(entity e);
1019 void ClientConnect (void)
1020 {
1021         float t;
1022
1023         if(IS_CLIENT(self))
1024         {
1025                 print("Warning: ClientConnect, but already connected!\n");
1026                 return;
1027         }
1028
1029         if(Ban_MaybeEnforceBanOnce(self))
1030                 return;
1031
1032         DecodeLevelParms();
1033
1034 #ifdef WATERMARK
1035         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1036 #endif
1037
1038         self.classname = "player_joining";
1039
1040         self.flags = FL_CLIENT;
1041         self.version_nagtime = time + 10 + random() * 10;
1042
1043         if(player_count<0)
1044         {
1045                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1046                 player_count = 0;
1047         }
1048
1049         PlayerScore_Attach(self);
1050         ClientData_Attach();
1051         accuracy_init(self);
1052
1053         bot_clientconnect();
1054
1055         playerdemo_init();
1056
1057         anticheat_init();
1058
1059         race_PreSpawnObserver();
1060
1061         // identify the right forced team
1062         if(autocvar_g_campaign)
1063         {
1064                 if(IS_REAL_CLIENT(self)) // only players, not bots
1065                 {
1066                         switch(autocvar_g_campaign_forceteam)
1067                         {
1068                                 case 1: self.team_forced = NUM_TEAM_1; break;
1069                                 case 2: self.team_forced = NUM_TEAM_2; break;
1070                                 case 3: self.team_forced = NUM_TEAM_3; break;
1071                                 case 4: self.team_forced = NUM_TEAM_4; break;
1072                                 default: self.team_forced = 0;
1073                         }
1074                 }
1075         }
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1077                 self.team_forced = NUM_TEAM_1;
1078         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1079                 self.team_forced = NUM_TEAM_2;
1080         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1081                 self.team_forced = NUM_TEAM_3;
1082         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1083                 self.team_forced = NUM_TEAM_4;
1084         else if(autocvar_g_forced_team_otherwise == "red")
1085                 self.team_forced = NUM_TEAM_1;
1086         else if(autocvar_g_forced_team_otherwise == "blue")
1087                 self.team_forced = NUM_TEAM_2;
1088         else if(autocvar_g_forced_team_otherwise == "yellow")
1089                 self.team_forced = NUM_TEAM_3;
1090         else if(autocvar_g_forced_team_otherwise == "pink")
1091                 self.team_forced = NUM_TEAM_4;
1092         else if(autocvar_g_forced_team_otherwise == "spectate")
1093                 self.team_forced = -1;
1094         else if(autocvar_g_forced_team_otherwise == "spectator")
1095                 self.team_forced = -1;
1096         else
1097                 self.team_forced = 0;
1098
1099         if(!teamplay)
1100                 if(self.team_forced > 0)
1101                         self.team_forced = 0;
1102
1103         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1104
1105         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1106                 self.classname = "observer";
1107         } else {
1108                 if(teamplay)
1109                 {
1110                         if(autocvar_g_balance_teams)
1111                         {
1112                                 self.classname = "player";
1113                                 campaign_bots_may_start = 1;
1114                         }
1115                         else
1116                         {
1117                                 self.classname = "observer"; // do it anyway
1118                         }
1119                 }
1120                 else
1121                 {
1122                         self.classname = "player";
1123                         campaign_bots_may_start = 1;
1124                 }
1125         }
1126
1127         self.playerid = (playerid_last = playerid_last + 1);
1128
1129         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1130
1131     if(IS_BOT_CLIENT(self))
1132         PlayerStats_AddPlayer(self);
1133
1134         if(autocvar_sv_eventlog)
1135                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1136
1137         LogTeamchange(self.playerid, self.team, 1);
1138
1139         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1140
1141         self.netname_previous = strzone(self.netname);
1142
1143         if(IS_PLAYER(self) && teamplay)
1144                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1145         else
1146                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1147
1148         stuffcmd(self, strcat(clientstuff, "\n"));
1149         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1150
1151         FixClientCvars(self);
1152
1153         // spawnfunc_waypoint sprites
1154         WaypointSprite_InitClient(self);
1155
1156         // Wazat's grappling hook
1157         SetGrappleHookBindings();
1158
1159         // get version info from player
1160         stuffcmd(self, "cmd clientversion $gameversion\n");
1161
1162         // get other cvars from player
1163         GetCvars(0);
1164
1165         // notify about available teams
1166         if(teamplay)
1167         {
1168                 CheckAllowedTeams(self);
1169                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1170                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1171         }
1172         else
1173                 stuffcmd(self, "set _teams_available 0\n");
1174
1175         attach_entcs();
1176
1177         bot_relinkplayerlist();
1178
1179         self.spectatortime = time;
1180         if(blockSpectators)
1181         {
1182                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1183         }
1184
1185         self.jointime = time;
1186         self.allowed_timeouts = autocvar_sv_timeout_number;
1187
1188         if(IS_REAL_CLIENT(self))
1189         {
1190                 if(!autocvar_g_campaign)
1191                 {
1192                         self.motd_actived_time = -1;
1193                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1194                 }
1195
1196                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1197                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1198         }
1199
1200         if(!sv_foginterval && world.fog != "")
1201                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1202
1203         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1204         {
1205                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1206                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1207         }
1208         else
1209                 self.hitplotfh = -1;
1210
1211         if(g_race || g_cts) {
1212                 string rr;
1213                 if(g_cts)
1214                         rr = CTS_RECORD;
1215                 else
1216                         rr = RACE_RECORD;
1217
1218                 msg_entity = self;
1219                 race_send_recordtime(MSG_ONE);
1220                 race_send_speedaward(MSG_ONE);
1221
1222                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1223                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1224                 race_send_speedaward_alltimebest(MSG_ONE);
1225
1226                 float i;
1227                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1228                         race_SendRankings(i, 0, 0, MSG_ONE);
1229                 }
1230         }
1231         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1232                 send_CSQC_teamnagger();
1233
1234         CheatInitClient();
1235
1236         CSQCMODEL_AUTOINIT();
1237
1238         self.model_randomizer = random();
1239
1240         if(IS_REAL_CLIENT(self))
1241                 sv_notice_join();
1242
1243         MUTATOR_CALLHOOK(ClientConnect);
1244 }
1245 /*
1246 =============
1247 ClientDisconnect
1248
1249 Called when a client disconnects from the server
1250 =============
1251 */
1252 .entity chatbubbleentity;
1253 void ReadyCount();
1254 void ClientDisconnect (void)
1255 {
1256         if(self.vehicle)
1257             vehicles_exit(VHEF_RELESE);
1258
1259         if not(IS_CLIENT(self))
1260         {
1261                 print("Warning: ClientDisconnect without ClientConnect\n");
1262                 return;
1263         }
1264
1265         PlayerStats_AddGlobalInfo(self);
1266
1267         CheatShutdownClient();
1268
1269         if(self.hitplotfh >= 0)
1270         {
1271                 fclose(self.hitplotfh);
1272                 self.hitplotfh = -1;
1273         }
1274
1275         anticheat_report();
1276         anticheat_shutdown();
1277
1278         playerdemo_shutdown();
1279
1280         bot_clientdisconnect();
1281
1282         if(self.entcs)
1283                 detach_entcs();
1284
1285         if(autocvar_sv_eventlog)
1286                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1287
1288         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1289
1290         MUTATOR_CALLHOOK(ClientDisconnect);
1291
1292         Portal_ClearAll(self);
1293
1294         Unfreeze(self);
1295
1296         RemoveGrapplingHook(self);
1297
1298         // Here, everything has been done that requires this player to be a client.
1299
1300         self.flags &= ~FL_CLIENT;
1301
1302         if (self.chatbubbleentity)
1303                 remove (self.chatbubbleentity);
1304
1305         if (self.killindicator)
1306                 remove (self.killindicator);
1307
1308         WaypointSprite_PlayerGone();
1309
1310         bot_relinkplayerlist();
1311
1312         accuracy_free(self);
1313         ClientData_Detach();
1314         PlayerScore_Detach(self);
1315
1316         if(self.netname_previous)
1317                 strunzone(self.netname_previous);
1318         if(self.clientstatus)
1319                 strunzone(self.clientstatus);
1320         if(self.weaponorder_byimpulse)
1321                 strunzone(self.weaponorder_byimpulse);
1322
1323         ClearPlayerSounds();
1324
1325         if(self.personal)
1326                 remove(self.personal);
1327
1328         self.playerid = 0;
1329         ReadyCount();
1330
1331         // free cvars
1332         GetCvars(-1);
1333 }
1334
1335 .float BUTTON_CHAT;
1336 void ChatBubbleThink()
1337 {
1338         self.nextthink = time;
1339         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1340         {
1341                 if(self.owner) // but why can that ever be world?
1342                         self.owner.chatbubbleentity = world;
1343                 remove(self);
1344                 return;
1345         }
1346         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1347 #ifdef TETRIS
1348                 || self.owner.tetris_on
1349 #endif
1350         )
1351                 self.model = self.mdl;
1352         else
1353                 self.model = "";
1354 }
1355
1356 void UpdateChatBubble()
1357 {
1358         if (self.alpha < 0)
1359                 return;
1360         // spawn a chatbubble entity if needed
1361         if (!self.chatbubbleentity)
1362         {
1363                 self.chatbubbleentity = spawn();
1364                 self.chatbubbleentity.owner = self;
1365                 self.chatbubbleentity.exteriormodeltoclient = self;
1366                 self.chatbubbleentity.think = ChatBubbleThink;
1367                 self.chatbubbleentity.nextthink = time;
1368                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1369                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1370                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1371                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1372                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1373                 self.chatbubbleentity.model = "";
1374                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1375         }
1376 }
1377
1378
1379 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1380 // added to the model skins
1381 /*void UpdateColorModHack()
1382 {
1383         float c;
1384         c = self.clientcolors & 15;
1385         // LordHavoc: only bothering to support white, green, red, yellow, blue
1386              if (!teamplay) self.colormod = '0 0 0';
1387         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1388         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1389         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1390         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1391         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1392         else self.colormod = '1 1 1';
1393 }*/
1394
1395 void respawn(void)
1396 {
1397         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1398         {
1399                 self.solid = SOLID_NOT;
1400                 self.takedamage = DAMAGE_NO;
1401                 self.movetype = MOVETYPE_FLY;
1402                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1403                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1404                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1405                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1406                 if(autocvar_g_respawn_ghosts_maxtime)
1407                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1408         }
1409
1410         CopyBody(1);
1411
1412         self.effects |= EF_NODRAW; // prevent another CopyBody
1413         PutClientInServer();
1414 }
1415
1416 void play_countdown(float finished, string samp)
1417 {
1418         if(IS_REAL_CLIENT(self))
1419                 if(floor(finished - time - frametime) != floor(finished - time))
1420                         if(finished - time < 6)
1421                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1422 }
1423
1424 void player_powerups (void)
1425 {
1426         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1427         olditems = self.items;
1428
1429         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1430                 self.modelflags |= MF_ROCKET;
1431         else
1432                 self.modelflags &= ~MF_ROCKET;
1433
1434         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1435
1436         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1437                 return;
1438
1439         Fire_ApplyDamage(self);
1440         Fire_ApplyEffect(self);
1441
1442         if not(g_minstagib)
1443         {
1444                 if (self.items & IT_STRENGTH)
1445                 {
1446                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1447                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1448                         if (time > self.strength_finished)
1449                         {
1450                                 self.items = self.items - (self.items & IT_STRENGTH);
1451                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1452                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1453                         }
1454                 }
1455                 else
1456                 {
1457                         if (time < self.strength_finished)
1458                         {
1459                                 self.items = self.items | IT_STRENGTH;
1460                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1461                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1462                         }
1463                 }
1464                 if (self.items & IT_INVINCIBLE)
1465                 {
1466                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1467                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1468                         if (time > self.invincible_finished)
1469                         {
1470                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1471                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1472                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1473                         }
1474                 }
1475                 else
1476                 {
1477                         if (time < self.invincible_finished)
1478                         {
1479                                 self.items = self.items | IT_INVINCIBLE;
1480                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1481                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1482                         }
1483                 }
1484                 if (self.items & IT_SUPERWEAPON)
1485                 {
1486                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1487                         {
1488                                 self.superweapons_finished = 0;
1489                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1490                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1491                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1492                         }
1493                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1494                         {
1495                                 // don't let them run out
1496                         }
1497                         else
1498                         {
1499                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1500                                 if (time > self.superweapons_finished)
1501                                 {
1502                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1503                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1504                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1505                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1506                                 }
1507                         }
1508                 }
1509                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1510                 {
1511                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1512                         {
1513                                 self.items = self.items | IT_SUPERWEAPON;
1514                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1515                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1516                         }
1517                         else
1518                         {
1519                                 self.superweapons_finished = 0;
1520                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1521                         }
1522                 }
1523                 else
1524                 {
1525                         self.superweapons_finished = 0;
1526                 }
1527         }
1528
1529         if(autocvar_g_nodepthtestplayers)
1530                 self.effects = self.effects | EF_NODEPTHTEST;
1531
1532         if(autocvar_g_fullbrightplayers)
1533                 self.effects = self.effects | EF_FULLBRIGHT;
1534
1535         if (time >= game_starttime)
1536         if (time < self.spawnshieldtime)
1537                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1538
1539         MUTATOR_CALLHOOK(PlayerPowerups);
1540 }
1541
1542 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1543 {
1544         if(current > stable)
1545                 return current;
1546         else if(current > stable - 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1550 }
1551
1552 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1553 {
1554         if(current < stable)
1555                 return current;
1556         else if(current < stable + 0.25) // when close enough, "snap"
1557                 return stable;
1558         else
1559                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1560 }
1561
1562 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1563 {
1564         if(current > rotstable)
1565         {
1566                 if(rotframetime > 0)
1567                 {
1568                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1569                         current = max(rotstable, current - rotlinear * rotframetime);
1570                 }
1571         }
1572         else if(current < regenstable)
1573         {
1574                 if(regenframetime > 0)
1575                 {
1576                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1577                         current = min(regenstable, current + regenlinear * regenframetime);
1578                 }
1579         }
1580
1581         if(current > limit)
1582                 current = limit;
1583
1584         return current;
1585 }
1586
1587 void player_regen (void)
1588 {
1589         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1590         maxh = autocvar_g_balance_health_rotstable;
1591         maxa = autocvar_g_balance_armor_rotstable;
1592         maxf = autocvar_g_balance_fuel_rotstable;
1593         minh = autocvar_g_balance_health_regenstable;
1594         mina = autocvar_g_balance_armor_regenstable;
1595         minf = autocvar_g_balance_fuel_regenstable;
1596         limith = autocvar_g_balance_health_limit;
1597         limita = autocvar_g_balance_armor_limit;
1598         limitf = autocvar_g_balance_fuel_limit;
1599
1600         max_mod = regen_mod = rot_mod = limit_mod = 1;
1601
1602         maxh = maxh * max_mod;
1603         //maxa = maxa * max_mod;
1604         //maxf = maxf * max_mod;
1605         minh = minh * max_mod;
1606         //mina = mina * max_mod;
1607         //minf = minf * max_mod;
1608         limith = limith * limit_mod;
1609         limita = limita * limit_mod;
1610         //limitf = limitf * limit_mod;
1611
1612         if(g_ca || g_invasion)
1613                 rot_mod = 0;
1614
1615         if (!g_minstagib && !g_ca && !g_invasion && (!g_lms || autocvar_g_lms_regenerate))
1616         {
1617                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1618                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1619
1620                 // if player rotted to death...  die!
1621                 if(self.health < 1)
1622                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1623         }
1624
1625         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1626                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1627 }
1628
1629 float zoomstate_set;
1630 void SetZoomState(float z)
1631 {
1632         if(z != self.zoomstate)
1633         {
1634                 self.zoomstate = z;
1635                 ClientData_Touch(self);
1636         }
1637         zoomstate_set = 1;
1638 }
1639
1640 void GetPressedKeys(void) {
1641         MUTATOR_CALLHOOK(GetPressedKeys);
1642         if (self.movement_x > 0) // get if movement keys are pressed
1643         {       // forward key pressed
1644                 self.pressedkeys |= KEY_FORWARD;
1645                 self.pressedkeys &= ~KEY_BACKWARD;
1646         }
1647         else if (self.movement_x < 0)
1648         {       // backward key pressed
1649                 self.pressedkeys |= KEY_BACKWARD;
1650                 self.pressedkeys &= ~KEY_FORWARD;
1651         }
1652         else
1653         {       // no x input
1654                 self.pressedkeys &= ~KEY_FORWARD;
1655                 self.pressedkeys &= ~KEY_BACKWARD;
1656         }
1657
1658         if (self.movement_y > 0)
1659         {       // right key pressed
1660                 self.pressedkeys |= KEY_RIGHT;
1661                 self.pressedkeys &= ~KEY_LEFT;
1662         }
1663         else if (self.movement_y < 0)
1664         {       // left key pressed
1665                 self.pressedkeys |= KEY_LEFT;
1666                 self.pressedkeys &= ~KEY_RIGHT;
1667         }
1668         else
1669         {       // no y input
1670                 self.pressedkeys &= ~KEY_RIGHT;
1671                 self.pressedkeys &= ~KEY_LEFT;
1672         }
1673
1674         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1675                 self.pressedkeys |= KEY_JUMP;
1676         else
1677                 self.pressedkeys &= ~KEY_JUMP;
1678         if (self.BUTTON_CROUCH)
1679                 self.pressedkeys |= KEY_CROUCH;
1680         else
1681                 self.pressedkeys &= ~KEY_CROUCH;
1682
1683         if (self.BUTTON_ATCK)
1684                 self.pressedkeys |= KEY_ATCK;
1685         else
1686                 self.pressedkeys &= ~KEY_ATCK;
1687         if (self.BUTTON_ATCK2)
1688                 self.pressedkeys |= KEY_ATCK2;
1689         else
1690                 self.pressedkeys &= ~KEY_ATCK2;
1691 }
1692
1693 /*
1694 ======================
1695 spectate mode routines
1696 ======================
1697 */
1698
1699 void SpectateCopy(entity spectatee) {
1700         other = spectatee;
1701         MUTATOR_CALLHOOK(SpectateCopy);
1702         self.armortype = spectatee.armortype;
1703         self.armorvalue = spectatee.armorvalue;
1704         self.ammo_cells = spectatee.ammo_cells;
1705         self.ammo_shells = spectatee.ammo_shells;
1706         self.ammo_nails = spectatee.ammo_nails;
1707         self.ammo_rockets = spectatee.ammo_rockets;
1708         self.ammo_fuel = spectatee.ammo_fuel;
1709         self.clip_load = spectatee.clip_load;
1710         self.clip_size = spectatee.clip_size;
1711         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1712         self.health = spectatee.health;
1713         self.impulse = 0;
1714         self.items = spectatee.items;
1715         self.last_pickup = spectatee.last_pickup;
1716         self.hit_time = spectatee.hit_time;
1717         self.metertime = spectatee.metertime;
1718         self.strength_finished = spectatee.strength_finished;
1719         self.invincible_finished = spectatee.invincible_finished;
1720         self.pressedkeys = spectatee.pressedkeys;
1721         self.weapons = spectatee.weapons;
1722         self.switchweapon = spectatee.switchweapon;
1723         self.switchingweapon = spectatee.switchingweapon;
1724         self.weapon = spectatee.weapon;
1725         self.nex_charge = spectatee.nex_charge;
1726         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1727         self.hagar_load = spectatee.hagar_load;
1728         self.minelayer_mines = spectatee.minelayer_mines;
1729         self.punchangle = spectatee.punchangle;
1730         self.view_ofs = spectatee.view_ofs;
1731         self.velocity = spectatee.velocity;
1732         self.dmg_take = spectatee.dmg_take;
1733         self.dmg_save = spectatee.dmg_save;
1734         self.dmg_inflictor = spectatee.dmg_inflictor;
1735         self.v_angle = spectatee.v_angle;
1736         self.angles = spectatee.v_angle;
1737         self.frozen = spectatee.frozen;
1738         self.revive_progress = spectatee.revive_progress;
1739         if(!self.BUTTON_USE)
1740                 self.fixangle = TRUE;
1741         setorigin(self, spectatee.origin);
1742         setsize(self, spectatee.mins, spectatee.maxs);
1743         SetZoomState(spectatee.zoomstate);
1744
1745     anticheat_spectatecopy(spectatee);
1746         self.hud = spectatee.hud;
1747         if(spectatee.vehicle)
1748     {
1749         self.fixangle = FALSE;
1750         //self.velocity = spectatee.vehicle.velocity;
1751         self.vehicle_health = spectatee.vehicle_health;
1752         self.vehicle_shield = spectatee.vehicle_shield;
1753         self.vehicle_energy = spectatee.vehicle_energy;
1754         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1755         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1756         self.vehicle_reload1 = spectatee.vehicle_reload1;
1757         self.vehicle_reload2 = spectatee.vehicle_reload2;
1758
1759         msg_entity = self;
1760
1761         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1762             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1763             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1764             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1765
1766         //WriteByte (MSG_ONE, SVC_SETVIEW);
1767         //    WriteEntity(MSG_ONE, self);
1768         //makevectors(spectatee.v_angle);
1769         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1770     }
1771 }
1772
1773 float SpectateUpdate() {
1774         if(!self.enemy)
1775             return 0;
1776
1777         if (self == self.enemy)
1778                 return 0;
1779
1780         if not(IS_PLAYER(self.enemy))
1781                 return 0;
1782
1783         SpectateCopy(self.enemy);
1784
1785         return 1;
1786 }
1787
1788
1789 float SpectateSet()
1790 {
1791         if(self.enemy.classname != "player")
1792                 return FALSE;
1793         /*if(self.enemy.vehicle)
1794         {
1795
1796                 msg_entity = self;
1797                 WriteByte(MSG_ONE, SVC_SETVIEW);
1798                 WriteEntity(MSG_ONE, self.enemy);
1799                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1800
1801                 self.movetype = MOVETYPE_NONE;
1802                 accuracy_resend(self);
1803         }
1804         else
1805         {*/
1806                 msg_entity = self;
1807                 WriteByte(MSG_ONE, SVC_SETVIEW);
1808                 WriteEntity(MSG_ONE, self.enemy);
1809                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1810                 self.movetype = MOVETYPE_NONE;
1811                 accuracy_resend(self);
1812
1813                 if(!SpectateUpdate())
1814                         PutObserverInServer();
1815         //}
1816         return TRUE;
1817 }
1818
1819 float Spectate(entity pl)
1820 {
1821         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1822         if(pl.team != self.team)
1823                 return 0;
1824
1825         self.enemy = pl;
1826         return SpectateSet();
1827 }
1828
1829 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1830 entity CA_SpectateNext(entity start) {
1831         if (start.team == self.team) {
1832                 return start;
1833         }
1834
1835         other = start;
1836         // continue from current player
1837         while(other && other.team != self.team) {
1838                 other = find(other, classname, "player");
1839         }
1840
1841         if (!other) {
1842                 // restart from begining
1843                 other = find(other, classname, "player");
1844                 while(other && other.team != self.team) {
1845                         other = find(other, classname, "player");
1846                 }
1847         }
1848
1849         return other;
1850 }
1851
1852 float SpectateNext()
1853 {
1854         other = find(self.enemy, classname, "player");
1855
1856         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1857                 // CA and ca players when spectating enemies is forbidden
1858                 other = CA_SpectateNext(other);
1859         } else {
1860                 // other modes and ca spectators or spectating enemies is allowed
1861                 if (!other)
1862                         other = find(other, classname, "player");
1863         }
1864
1865         if (other)
1866                 self.enemy = other;
1867
1868         return SpectateSet();
1869 }
1870
1871 float SpectatePrev()
1872 {
1873         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1874         other = findchain(classname, "player");
1875         if not(other) // no player
1876                 return FALSE;
1877
1878         entity first = other;
1879         // skip players until current spectated player
1880         if(self.enemy)
1881         while(other && other != self.enemy)
1882                 other = other.chain;
1883
1884         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1885         {
1886                 do { other = other.chain; }
1887                 while(other && other.team != self.team);
1888
1889                 if not(other)
1890                 {
1891                         other = first;
1892                         while(other.team != self.team)
1893                                 other = other.chain;
1894                         if(other == self.enemy)
1895                                 return TRUE;
1896                 }
1897         }
1898         else
1899         {
1900                 if(other.chain)
1901                         other = other.chain;
1902                 else
1903                         other = first;
1904         }
1905         self.enemy = other;
1906         return SpectateSet();
1907 }
1908
1909 /*
1910 =============
1911 ShowRespawnCountdown()
1912
1913 Update a respawn countdown display.
1914 =============
1915 */
1916 void ShowRespawnCountdown()
1917 {
1918         float number;
1919         if(self.deadflag == DEAD_NO) // just respawned?
1920                 return;
1921         else
1922         {
1923                 number = ceil(self.respawn_time - time);
1924                 if(number <= 0)
1925                         return;
1926                 if(number <= self.respawn_countdown)
1927                 {
1928                         self.respawn_countdown = number - 1;
1929                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1930                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1931                 }
1932         }
1933 }
1934
1935 void LeaveSpectatorMode()
1936 {
1937         if(self.caplayer)
1938                 return;
1939         if(nJoinAllowed(self))
1940         {
1941                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1942                 {
1943                         self.classname = "player";
1944
1945                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1946                                 { JoinBestTeam(self, FALSE, TRUE); }
1947
1948                         if(autocvar_g_campaign)
1949                                 { campaign_bots_may_start = 1; }
1950
1951                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1952
1953                         PutClientInServer();
1954
1955                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1956                 }
1957                 else
1958                         stuffcmd(self, "menu_showteamselect\n");
1959         }
1960         else
1961         {
1962                 // Player may not join because g_maxplayers is set
1963                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1964         }
1965 }
1966
1967 /**
1968  * Determines whether the player is allowed to join. This depends on cvar
1969  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1970  * it checks whether the number of currently playing players exceeds g_maxplayers.
1971  * @return int number of free slots for players, 0 if none
1972  */
1973 float nJoinAllowed(entity ignore) {
1974         if(!ignore)
1975         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1976         // so report 0 free slots if restricted
1977         {
1978                 if(autocvar_g_forced_team_otherwise == "spectate")
1979                         return 0;
1980                 if(autocvar_g_forced_team_otherwise == "spectator")
1981                         return 0;
1982         }
1983
1984         if(self.team_forced < 0)
1985                 return 0; // forced spectators can never join
1986
1987         // TODO simplify this
1988         entity e;
1989         float totalClients = 0;
1990         FOR_EACH_CLIENT(e)
1991                 if(e != ignore)
1992                         totalClients += 1;
1993
1994         if (!autocvar_g_maxplayers)
1995                 return maxclients - totalClients;
1996
1997         float currentlyPlaying = 0;
1998         FOR_EACH_REALCLIENT(e)
1999                 if(IS_PLAYER(e) || e.caplayer == 1)
2000                         currentlyPlaying += 1;
2001
2002         if(currentlyPlaying < autocvar_g_maxplayers)
2003                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2004
2005         return 0;
2006 }
2007
2008 /**
2009  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2010  * g_maxplayers_spectator_blocktime seconds
2011  */
2012 void checkSpectatorBlock() {
2013         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2014                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2015                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2016                         dropclient(self);
2017                 }
2018         }
2019 }
2020
2021 void PrintWelcomeMessage()
2022 {
2023         if(self.motd_actived_time == 0)
2024         {
2025                 if (autocvar_g_campaign) {
2026                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2027                                 self.motd_actived_time = time;
2028                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2029                         }
2030                 } else {
2031                         if (self.BUTTON_INFO) {
2032                                 self.motd_actived_time = time;
2033                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2034                         }
2035                 }
2036         }
2037         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2038         {
2039                 if (autocvar_g_campaign) {
2040                         if (self.BUTTON_INFO)
2041                                 self.motd_actived_time = time;
2042                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2043                                 self.motd_actived_time = 0;
2044                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2045                         }
2046                 } else {
2047                         if (self.BUTTON_INFO)
2048                                 self.motd_actived_time = time;
2049                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2050                                 self.motd_actived_time = 0;
2051                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2052                         }
2053                 }
2054         }
2055         else //if(self.motd_actived_time < 0) // just connected, motd is active
2056         {
2057                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2058                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2059                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2060                 {
2061                         // instanctly hide MOTD
2062                         self.motd_actived_time = 0;
2063                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2064                 }
2065         }
2066 }
2067
2068 void ObserverThink()
2069 {
2070         float prefered_movetype;
2071         if (self.flags & FL_JUMPRELEASED) {
2072                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2073                         self.flags &= ~FL_JUMPRELEASED;
2074                         self.flags |= FL_SPAWNING;
2075                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2076                         self.flags &= ~FL_JUMPRELEASED;
2077                         if(SpectateNext()) {
2078                                 self.classname = "spectator";
2079                         }
2080                 } else {
2081                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2082                         if (self.movetype != prefered_movetype)
2083                                 self.movetype = prefered_movetype;
2084                 }
2085         } else {
2086                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2087                         self.flags |= FL_JUMPRELEASED;
2088                         if(self.flags & FL_SPAWNING)
2089                         {
2090                                 self.flags &= ~FL_SPAWNING;
2091                                 LeaveSpectatorMode();
2092                                 return;
2093                         }
2094                 }
2095         }
2096 }
2097
2098 void SpectatorThink()
2099 {
2100         if (self.flags & FL_JUMPRELEASED) {
2101                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2102                         self.flags &= ~FL_JUMPRELEASED;
2103                         self.flags |= FL_SPAWNING;
2104                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2105                         self.flags &= ~FL_JUMPRELEASED;
2106                         if(SpectateNext()) {
2107                                 self.classname = "spectator";
2108                         } else {
2109                                 self.classname = "observer";
2110                                 PutClientInServer();
2111                         }
2112                         self.impulse = 0;
2113                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2114                         self.flags &= ~FL_JUMPRELEASED;
2115                         if(SpectatePrev()) {
2116                                 self.classname = "spectator";
2117                         } else {
2118                                 self.classname = "observer";
2119                                 PutClientInServer();
2120                         }
2121                         self.impulse = 0;
2122                 } else if (self.BUTTON_ATCK2) {
2123                         self.flags &= ~FL_JUMPRELEASED;
2124                         self.classname = "observer";
2125                         PutClientInServer();
2126                 } else {
2127                         if(!SpectateUpdate())
2128                                 PutObserverInServer();
2129                 }
2130         } else {
2131                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2132                         self.flags |= FL_JUMPRELEASED;
2133                         if(self.flags & FL_SPAWNING)
2134                         {
2135                                 self.flags &= ~FL_SPAWNING;
2136                                 LeaveSpectatorMode();
2137                                 return;
2138                         }
2139                 }
2140                 if(!SpectateUpdate())
2141                         PutObserverInServer();
2142         }
2143
2144         self.flags |= FL_CLIENT | FL_NOTARGET;
2145 }
2146
2147 void PlayerUseKey()
2148 {
2149         if not(IS_PLAYER(self))
2150                 return;
2151
2152         if(self.vehicle)
2153         {
2154         vehicles_exit(VHEF_NORMAL);
2155         return;
2156         }
2157
2158         // a use key was pressed; call handlers
2159         MUTATOR_CALLHOOK(PlayerUseKey);
2160 }
2161
2162 /*
2163 =============
2164 PlayerPreThink
2165
2166 Called every frame for each client before the physics are run
2167 =============
2168 */
2169 .float usekeypressed;
2170 void() nexball_setstatus;
2171 .float items_added;
2172 void PlayerPreThink (void)
2173 {
2174         WarpZone_PlayerPhysics_FixVAngle();
2175
2176         self.stat_game_starttime = game_starttime;
2177         self.stat_round_starttime = round_starttime;
2178         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2179         self.stat_leadlimit = autocvar_leadlimit;
2180
2181         if(frametime)
2182         {
2183                 // physics frames: update anticheat stuff
2184                 anticheat_prethink();
2185         }
2186
2187         if(blockSpectators && frametime)
2188                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2189                 checkSpectatorBlock();
2190
2191         zoomstate_set = 0;
2192
2193         if(self.netname_previous != self.netname)
2194         {
2195                 if(autocvar_sv_eventlog)
2196                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2197                 if(self.netname_previous)
2198                         strunzone(self.netname_previous);
2199                 self.netname_previous = strzone(self.netname);
2200         }
2201
2202         // version nagging
2203         if(self.version_nagtime)
2204                 if(self.cvar_g_xonoticversion)
2205                         if(time > self.version_nagtime)
2206                         {
2207                                 // don't notify git users
2208                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2209                                 {
2210                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2211                                         {
2212                                                 // notify release users if connecting to git
2213                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2214                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2215                                         }
2216                                         else
2217                                         {
2218                                                 float r;
2219                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2220                                                 if(r < 0)
2221                                                 {
2222                                                         // give users new version
2223                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2224                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2225                                                 }
2226                                                 else if(r > 0)
2227                                                 {
2228                                                         // notify users about old server version
2229                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2230                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2231                                                 }
2232                                         }
2233                                 }
2234                                 self.version_nagtime = 0;
2235                         }
2236
2237         // GOD MODE info
2238         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2239         {
2240                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2241                 self.max_armorvalue = 0;
2242         }
2243
2244 #ifdef TETRIS
2245         if (TetrisPreFrame())
2246                 return;
2247 #endif
2248
2249         if(self.frozen == 2)
2250         {
2251                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2252                 self.health = max(1, self.revive_progress * autocvar_g_balance_health_start);
2253                 self.iceblock.alpha = 1 - self.revive_progress;
2254
2255                 if(self.revive_progress >= 1)
2256                         Unfreeze(self);
2257         }
2258
2259         MUTATOR_CALLHOOK(PlayerPreThink);
2260
2261         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2262         {
2263                 if(self.BUTTON_USE && !self.usekeypressed)
2264                         PlayerUseKey();
2265                 self.usekeypressed = self.BUTTON_USE;
2266         }
2267
2268         if(IS_REAL_CLIENT(self))
2269                 PrintWelcomeMessage();
2270
2271         if(IS_PLAYER(self))
2272         {
2273
2274                 CheckRules_Player();
2275
2276                 if (intermission_running)
2277                 {
2278                         IntermissionThink ();   // otherwise a button could be missed between
2279                         return;                                 // the think tics
2280                 }
2281
2282                 //don't allow the player to turn around while game is paused!
2283                 if(timeout_status == TIMEOUT_ACTIVE) {
2284                         // FIXME turn this into CSQC stuff
2285                         self.v_angle = self.lastV_angle;
2286                         self.angles = self.lastV_angle;
2287                         self.fixangle = TRUE;
2288                 }
2289
2290                 if(frametime)
2291                 {
2292                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2293                         {
2294                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2295                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2296                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2297
2298                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2299                                 {
2300                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2301                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2302                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2303                                 }
2304                         }
2305                         else
2306                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2307
2308                         player_powerups();
2309                 }
2310
2311                 if (self.deadflag != DEAD_NO)
2312                 {
2313                         if(self.personal && g_race_qualifying)
2314                         {
2315                                 if(time > self.respawn_time)
2316                                 {
2317                                         self.respawn_time = time + 1; // only retry once a second
2318                                         self.stat_respawn_time = self.respawn_time;
2319                                         respawn();
2320                                         self.impulse = 141;
2321                                 }
2322                         }
2323                         else
2324                         {
2325                                 float button_pressed;
2326                                 if(frametime)
2327                                         player_anim();
2328                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2329
2330                                 if (self.deadflag == DEAD_DYING)
2331                                 {
2332                                         if(self.respawn_flags & RESPAWN_FORCE)
2333                                                 self.deadflag = DEAD_RESPAWNING;
2334                                         else if(!button_pressed)
2335                                                 self.deadflag = DEAD_DEAD;
2336                                 }
2337                                 else if (self.deadflag == DEAD_DEAD)
2338                                 {
2339                                         if(button_pressed)
2340                                                 self.deadflag = DEAD_RESPAWNABLE;
2341                                 }
2342                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2343                                 {
2344                                         if(!button_pressed)
2345                                                 self.deadflag = DEAD_RESPAWNING;
2346                                 }
2347                                 else if (self.deadflag == DEAD_RESPAWNING)
2348                                 {
2349                                         if(time > self.respawn_time)
2350                                         {
2351                                                 self.respawn_time = time + 1; // only retry once a second
2352                                                 respawn();
2353                                         }
2354                                 }
2355
2356                                 ShowRespawnCountdown();
2357
2358                                 if(self.respawn_flags & RESPAWN_SILENT)
2359                                         self.stat_respawn_time = 0;
2360                                 else
2361                                         self.stat_respawn_time = self.respawn_time;
2362                         }
2363
2364                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2365                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2366                                 self.stat_respawn_time *= -1;
2367
2368                         return;
2369                 }
2370
2371                 self.prevorigin = self.origin;
2372
2373                 float do_crouch = self.BUTTON_CROUCH;
2374                 if(self.hook.state)
2375                         do_crouch = 0;
2376                 if(self.vehicle)
2377                         do_crouch = 0;
2378                 if(self.frozen)
2379                         do_crouch = 0;
2380                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2381                         do_crouch = 0;
2382
2383                 if (do_crouch)
2384                 {
2385                         if (!self.crouch)
2386                         {
2387                                 self.crouch = TRUE;
2388                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2389                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2390                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2391                         }
2392                 }
2393                 else
2394                 {
2395                         if (self.crouch)
2396                         {
2397                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2398                                 if (!trace_startsolid)
2399                                 {
2400                                         self.crouch = FALSE;
2401                                         self.view_ofs = PL_VIEW_OFS;
2402                                         setsize (self, PL_MIN, PL_MAX);
2403                                 }
2404                         }
2405                 }
2406
2407                 FixPlayermodel();
2408
2409                 GrapplingHookFrame();
2410
2411                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2412                 //if(frametime)
2413                 {
2414                         self.items &= ~self.items_added;
2415
2416                         W_WeaponFrame();
2417
2418                         self.items_added = 0;
2419                         if(self.items & IT_JETPACK)
2420                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2421                                         self.items_added |= IT_FUEL;
2422
2423                         self.items |= self.items_added;
2424                 }
2425
2426                 player_regen();
2427
2428                 // rot nex charge to the charge limit
2429                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2430                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2431
2432                 if(frametime)
2433                         player_anim();
2434
2435                 // secret status
2436                 secrets_setstatus();
2437
2438                 // monsters status
2439                 monsters_setstatus();
2440
2441                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2442
2443                 //self.angles_y=self.v_angle_y + 90;   // temp
2444         } else if(gameover) {
2445                 if (intermission_running)
2446                         IntermissionThink ();   // otherwise a button could be missed between
2447                 return;
2448         } else if(IS_OBSERVER(self)) {
2449                 ObserverThink();
2450         } else if(IS_SPEC(self)) {
2451                 SpectatorThink();
2452         }
2453
2454         if(!zoomstate_set)
2455                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2456
2457         float oldspectatee_status;
2458         oldspectatee_status = self.spectatee_status;
2459         if(IS_SPEC(self))
2460                 self.spectatee_status = num_for_edict(self.enemy);
2461         else if(IS_OBSERVER(self))
2462                 self.spectatee_status = num_for_edict(self);
2463         else
2464                 self.spectatee_status = 0;
2465         if(self.spectatee_status != oldspectatee_status)
2466         {
2467                 ClientData_Touch(self);
2468                 if(g_race || g_cts)
2469                         race_InitSpectator();
2470         }
2471
2472         if(self.teamkill_soundtime)
2473         if(time > self.teamkill_soundtime)
2474         {
2475                 self.teamkill_soundtime = 0;
2476
2477                 entity oldpusher, oldself;
2478
2479                 oldself = self; self = self.teamkill_soundsource;
2480                 oldpusher = self.pusher; self.pusher = oldself;
2481
2482                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2483
2484                 self.pusher = oldpusher;
2485                 self = oldself;
2486         }
2487
2488         if(self.taunt_soundtime)
2489         if(time > self.taunt_soundtime)
2490         {
2491                 self.taunt_soundtime = 0;
2492                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2493         }
2494
2495         target_voicescript_next(self);
2496
2497         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2498         if(!self.weapon)
2499                 self.clip_load = self.clip_size = 0;
2500 }
2501
2502 float isInvisibleString(string s)
2503 {
2504         float i, n, c;
2505         s = strdecolorize(s);
2506         for((i = 0), (n = strlen(s)); i < n; ++i)
2507         {
2508                 c = str2chr(s, i);
2509                 switch(c)
2510                 {
2511                         case 0:
2512                         case 32: // space
2513                                 break;
2514                         case 192: // charmap space
2515                                 if (!autocvar_utf8_enable)
2516                                         break;
2517                                 return FALSE;
2518                         case 160: // space in unicode fonts
2519                         case 0xE000 + 192: // utf8 charmap space
2520                                 if (autocvar_utf8_enable)
2521                                         break;
2522                         default:
2523                                 return FALSE;
2524                 }
2525         }
2526         return TRUE;
2527 }
2528
2529 /*
2530 =============
2531 PlayerPostThink
2532
2533 Called every frame for each client after the physics are run
2534 =============
2535 */
2536 .float idlekick_lasttimeleft;
2537 void PlayerPostThink (void)
2538 {
2539         // Savage: Check for nameless players
2540         if (isInvisibleString(self.netname)) {
2541                 self.netname = "Player";
2542                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2543         }
2544
2545         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2546         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2547         {
2548                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2549                 {
2550                         if(self.idlekick_lasttimeleft)
2551                         {
2552                                 self.idlekick_lasttimeleft = 0;
2553                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2554                         }
2555                 }
2556                 else
2557                 {
2558                         float timeleft;
2559                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2560                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2561                         {
2562                                 if(!self.idlekick_lasttimeleft)
2563                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2564                         }
2565                         if(timeleft <= 0)
2566                         {
2567                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2568                                 dropclient(self);
2569                                 return;
2570                         }
2571                         else if(timeleft <= 10)
2572                         {
2573                                 if(timeleft != self.idlekick_lasttimeleft)
2574                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2575                                 self.idlekick_lasttimeleft = timeleft;
2576                         }
2577                 }
2578         }
2579
2580 #ifdef TETRIS
2581         if(self.impulse == 100)
2582                 ImpulseCommands();
2583         if (!TetrisPostFrame())
2584         {
2585 #endif
2586
2587         CheatFrame();
2588
2589         //CheckPlayerJump();
2590
2591         if(IS_PLAYER(self)) {
2592                 CheckRules_Player();
2593                 UpdateChatBubble();
2594                 if (self.impulse)
2595                         ImpulseCommands();
2596                 if (intermission_running)
2597                         return;         // intermission or finale
2598                 GetPressedKeys();
2599         }
2600
2601 #ifdef TETRIS
2602         }
2603 #endif
2604
2605         /*
2606         float i;
2607         for(i = 0; i < 1000; ++i)
2608         {
2609                 vector end;
2610                 end = self.origin + '0 0 1024' + 512 * randomvec();
2611                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2612                 if(trace_fraction < 1)
2613                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2614                 {
2615                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2616                         break;
2617                 }
2618         }
2619         */
2620
2621         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2622
2623         if(self.waypointsprite_attachedforcarrier)
2624                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2625
2626         playerdemo_write();
2627
2628         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2629         {
2630                 if not(self.stored_netname)
2631                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2632                 if(self.stored_netname != self.netname)
2633                 {
2634                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2635                         strunzone(self.stored_netname);
2636                         self.stored_netname = strzone(self.netname);
2637                 }
2638         }
2639
2640         /*
2641         if(g_race)
2642                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2643         */
2644
2645         CSQCMODEL_AUTOUPDATE();
2646 }