qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.health = -666;
 666         self.takedamage = DAMAGE_NO;
 667         self.solid = SOLID_NOT;
 668         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 669         self.flags = FL_CLIENT | FL_NOTARGET;
 670         self.armorvalue = 666;
 671         self.effects = 0;
 672         self.armorvalue = autocvar_g_balance_armor_start;
 673         self.pauserotarmor_finished = 0;
 674         self.pauserothealth_finished = 0;
 675         self.pauseregen_finished = 0;
 676         self.damageforcescale = 0;
 677         self.death_time = 0;
 678         self.dead_frame = 0;
 679         self.alpha = 0;
 680         self.scale = 0;
 681         self.fade_time = 0;
 682         self.pain_frame = 0;
 683         self.pain_finished = 0;
 684         self.strength_finished = 0;
 685         self.invincible_finished = 0;
 686         self.pushltime = 0;
 687         self.think = SUB_Null;
 688         self.nextthink = 0;
 689         self.hook_time = 0;
 690         self.runes = 0;
 691         self.deadflag = DEAD_NO;
 692         self.angles = spot.angles;
 693         self.angles_z = 0;
 694         self.fixangle = TRUE;
 695         self.crouch = FALSE;
 696
 697         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 698         setorigin (self, spot.origin);
 699         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 700         self.prevorigin = self.origin;
 701         self.items = 0;
 702         self.weapons = 0;
 703         self.model = "";
 704         FixPlayermodel();
 705         self.model = "";
 706         self.modelindex = 0;
 707         self.weapon = 0;
 708         self.switchingweapon = 0;
 709         self.weaponmodel = "";
 710         self.weaponentity = world;
 711         self.exteriorweaponentity = world;
 712         self.killcount = -666;
 713         self.velocity = '0 0 0';
 714         self.avelocity = '0 0 0';
 715         self.punchangle = '0 0 0';
 716         self.punchvector = '0 0 0';
 717         self.oldvelocity = self.velocity;
 718         self.fire_endtime = -1;
 719
 720         if(sv_loddistance1)
 721                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 722
 723         if(g_arena)
 724         {
 725                 if(self.version_mismatch)
 726                 {
 727                         Spawnqueue_Unmark(self);
 728                         Spawnqueue_Remove(self);
 729                 }
 730                 else
 731                 {
 732                         Spawnqueue_Insert(self);
 733                 }
 734         }
 735         else if(g_lms)
 736         {
 737                 // Only if the player cannot play at all
 738                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 739                         self.frags = FRAGS_SPECTATOR;
 740                 else
 741                         self.frags = FRAGS_LMS_LOSER;
 742         }
 743         else if(g_ca)
 744         {
 745                 if(self.caplayer)
 746                         self.frags = FRAGS_LMS_LOSER;
 747                 else
 748                         self.frags = FRAGS_SPECTATOR;
 749         }
 750         else
 751                 self.frags = FRAGS_SPECTATOR;
 752 }
 753
 754 void FixPlayermodel()
 755 {
 756         local string defaultmodel;
 757         local float defaultskin, chmdl, oldskin;
 758         local vector m1, m2;
 759
 760         defaultmodel = "";
 761
 762         if(autocvar_sv_defaultcharacter == 1) {
 763                 defaultskin = 0;
 764
 765                 if(teamplay)
 766                 {
 767                         string s;
 768                         s = Team_ColorNameLowerCase(self.team);
 769                         if(s != "neutral")
 770                         {
 771                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 772                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 773                         }
 774                 }
 775
 776                 if(defaultmodel == "")
 777                 {
 778                         defaultmodel = autocvar_sv_defaultplayermodel;
 779                         defaultskin = autocvar_sv_defaultplayerskin;
 780                 }
 781         }
 782
 783         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 784         {
 785                 if(self.model != "")
 786                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 787                 self.model = ""; // force the != checks to return true
 788         }
 789
 790         if(defaultmodel != "")
 791         {
 792                 if (defaultmodel != self.model)
 793                 {
 794                         m1 = self.mins;
 795                         m2 = self.maxs;
 796                         setmodel_lod (self, defaultmodel);
 797                         setsize (self, m1, m2);
 798                         chmdl = TRUE;
 799                 }
 800
 801                 oldskin = self.skinindex;
 802                 self.skinindex = defaultskin;
 803         } else {
 804                 if (self.playermodel != self.model || self.playermodel == "")
 805                 {
 806                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 807                         m1 = self.mins;
 808                         m2 = self.maxs;
 809                         setmodel_lod (self, self.playermodel);
 810                         setsize (self, m1, m2);
 811                         chmdl = TRUE;
 812                 }
 813
 814                 oldskin = self.skinindex;
 815                 self.skinindex = stof(self.playerskin);
 816         }
 817
 818         if(chmdl || oldskin != self.skinindex)
 819                 self.species = player_getspecies(); // model or skin has changed
 820
 821         if(!teamplay)
 822                 if(strlen(autocvar_sv_defaultplayercolors))
 823                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 824                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 825 }
 826
 827 void PlayerTouchExplode(entity p1, entity p2)
 828 {
 829         vector org;
 830         org = (p1.origin + p2.origin) * 0.5;
 831         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 832
 833         te_explosion(org);
 834
 835         entity e;
 836         e = spawn();
 837         setorigin(e, org);
 838         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 839         remove(e);
 840 }
 841
 842 /*
 843 =============
 844 PutClientInServer
 845
 846 Called when a client spawns in the server
 847 =============
 848 */
 849 //void() ctf_playerchanged;
 850 void PutClientInServer (void)
 851 {
 852         if(clienttype(self) == CLIENTTYPE_BOT)
 853         {
 854                 self.classname = "player";
 855         }
 856         else if(clienttype(self) == CLIENTTYPE_REAL)
 857         {
 858                 msg_entity = self;
 859                 WriteByte(MSG_ONE, SVC_SETVIEW);
 860                 WriteEntity(MSG_ONE, self);
 861         }
 862
 863         // player is dead and becomes observer
 864         // FIXME fix LMS scoring for new system
 865         if(g_lms)
 866         {
 867                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 868                         self.classname = "observer";
 869         }
 870
 871         if(g_arena || (g_ca && !allowed_to_spawn))
 872         if(!self.spawned)
 873                 self.classname = "observer";
 874
 875         if(gameover)
 876                 self.classname = "observer";
 877
 878         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 879                 entity spot, oldself;
 880                 float j;
 881
 882                 accuracy_resend(self);
 883
 884                 if(self.team < 0)
 885                         JoinBestTeam(self, FALSE, TRUE);
 886
 887                 race_PreSpawn();
 888
 889                 spot = SelectSpawnPoint (FALSE);
 890                 if(!spot)
 891                 {
 892                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 893                         return; // spawn failed
 894                 }
 895
 896                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 897
 898                 self.classname = "player";
 899                 self.wasplayer = TRUE;
 900                 self.iscreature = TRUE;
 901                 self.movetype = MOVETYPE_WALK;
 902                 self.solid = SOLID_SLIDEBOX;
 903                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 904                 if(autocvar_g_playerclip_collisions)
 905                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 906                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 907                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 908                 self.frags = FRAGS_PLAYER;
 909                 if(independent_players)
 910                         MAKE_INDEPENDENT_PLAYER(self);
 911                 self.flags = FL_CLIENT;
 912                 self.takedamage = DAMAGE_AIM;
 913                 if(g_minstagib)
 914                         self.effects = EF_FULLBRIGHT;
 915                 else
 916                         self.effects = 0;
 917                 self.air_finished = time + 12;
 918                 self.dmg = 2;
 919                 if(autocvar_g_balance_nex_charge)
 920                 {
 921                         if(autocvar_g_balance_nex_secondary_chargepool)
 922                                 self.nex_chargepool_ammo = 1;
 923                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 924                 }
 925
 926                 if(inWarmupStage)
 927                 {
 928                         self.ammo_shells = warmup_start_ammo_shells;
 929                         self.ammo_nails = warmup_start_ammo_nails;
 930                         self.ammo_rockets = warmup_start_ammo_rockets;
 931                         self.ammo_cells = warmup_start_ammo_cells;
 932                         self.ammo_fuel = warmup_start_ammo_fuel;
 933                         self.health = warmup_start_health;
 934                         self.armorvalue = warmup_start_armorvalue;
 935                         self.weapons = warmup_start_weapons;
 936                 }
 937                 else
 938                 {
 939                         self.ammo_shells = start_ammo_shells;
 940                         self.ammo_nails = start_ammo_nails;
 941                         self.ammo_rockets = start_ammo_rockets;
 942                         self.ammo_cells = start_ammo_cells;
 943                         self.ammo_fuel = start_ammo_fuel;
 944                         self.health = start_health;
 945                         self.armorvalue = start_armorvalue;
 946                         self.weapons = start_weapons;
 947                 }
 948
 949                 if(g_weaponarena_random)
 950                 {
 951                         if(g_weaponarena_random_with_laser)
 952                                 self.weapons &~= WEPBIT_LASER;
 953                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 954                         if(g_weaponarena_random_with_laser)
 955                                 self.weapons |= WEPBIT_LASER;
 956                 }
 957
 958                 self.items = start_items;
 959                 self.jump_interval = time;
 960
 961                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 962                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 963                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 964                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 965                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 966                 //extend the pause of rotting if client was reset at the beginning of the countdown
 967                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 968                         self.spawnshieldtime += game_starttime - time;
 969                         self.pauserotarmor_finished += game_starttime - time;
 970                         self.pauserothealth_finished += game_starttime - time;
 971                         self.pauseregen_finished += game_starttime - time;
 972                 }
 973                 self.damageforcescale = 2;
 974                 self.death_time = 0;
 975                 self.dead_frame = 0;
 976                 self.alpha = 0;
 977                 self.scale = 0;
 978                 self.fade_time = 0;
 979                 self.pain_frame = 0;
 980                 self.pain_finished = 0;
 981                 self.strength_finished = 0;
 982                 self.invincible_finished = 0;
 983                 self.pushltime = 0;
 984                 // players have no think function
 985                 self.think = SUB_Null;
 986                 self.nextthink = 0;
 987                 self.hook_time = 0;
 988                 self.dmg_team = 0;
 989                 self.ballistics_density = autocvar_g_ballistics_density_player;
 990
 991                 self.metertime = 0;
 992
 993                 self.runes = 0;
 994
 995                 self.deadflag = DEAD_NO;
 996
 997                 self.angles = spot.angles;
 998
 999                 self.angles_z = 0; // never spawn tilted even if the spot says to
1000                 self.fixangle = TRUE; // turn this way immediately
1001                 self.velocity = '0 0 0';
1002                 self.avelocity = '0 0 0';
1003                 self.punchangle = '0 0 0';
1004                 self.punchvector = '0 0 0';
1005                 self.oldvelocity = self.velocity;
1006                 self.fire_endtime = -1;
1007
1008                 msg_entity = self;
1009                 WRITESPECTATABLE_MSG_ONE({
1010                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1011                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1012                 });
1013
1014                 if(sv_loddistance1)
1015                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1016
1017                 self.model = "";
1018                 FixPlayermodel();
1019
1020                 self.crouch = FALSE;
1021                 self.view_ofs = PL_VIEW_OFS;
1022                 setsize (self, PL_MIN, PL_MAX);
1023                 self.spawnorigin = spot.origin;
1024                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1025                 // don't reset back to last position, even if new position is stuck in solid
1026                 self.oldorigin = self.origin;
1027                 self.prevorigin = self.origin;
1028                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1029                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1030
1031                 if(g_arena)
1032                 {
1033                         Spawnqueue_Remove(self);
1034                         Spawnqueue_Mark(self);
1035                 }
1036
1037                 else if(g_ca)
1038                         self.caplayer = 1;
1039
1040                 self.event_damage = PlayerDamage;
1041
1042                 self.bot_attack = TRUE;
1043
1044                 self.statdraintime = time + 5;
1045                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1046
1047                 if(self.killcount == -666) {
1048                         PlayerScore_Clear(self);
1049                         self.killcount = 0;
1050                 }
1051
1052                 self.cnt = WEP_LASER;
1053
1054                 CL_SpawnWeaponentity();
1055                 self.alpha = default_player_alpha;
1056                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1057                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1058
1059                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1060                 self.lms_traveled_distance = 0;
1061                 self.speedrunning = FALSE;
1062
1063                 race_PostSpawn(spot);
1064
1065                 if(autocvar_spawn_debug)
1066                 {
1067                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1068                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1069                 }
1070
1071                 //stuffcmd(self, "chase_active 0");
1072                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1073
1074                 if (autocvar_g_spawnsound)
1075                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1076
1077                 if(g_assault) {
1078                         if(self.team == assault_attacker_team)
1079                                 centerprint(self, "You are attacking!");
1080                         else
1081                                 centerprint(self, "You are defending!");
1082                 }
1083
1084                 target_voicescript_clear(self);
1085
1086                 // reset fields the weapons may use
1087                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1088                 {
1089                         weapon_action(j, WR_RESETPLAYER);
1090
1091                         // all weapons must be fully loaded when we spawn
1092                         entity e;
1093                         e = get_weaponinfo(j);
1094                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1095                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1096                 }
1097
1098                 oldself = self;
1099                 self = spot;
1100                         activator = oldself;
1101                                 string s;
1102                                 s = self.target;
1103                                 self.target = string_null;
1104                                 SUB_UseTargets();
1105                                 self.target = s;
1106                         activator = world;
1107                 self = oldself;
1108
1109                 MUTATOR_CALLHOOK(PlayerSpawn);
1110
1111                 self.switchweapon = w_getbestweapon(self);
1112                 self.cnt = self.switchweapon;
1113                 self.weapon = 0;
1114                 self.switchingweapon = 0;
1115
1116                 if(!self.alivetime)
1117                         self.alivetime = time;
1118         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1119                 PutObserverInServer ();
1120         }
1121
1122         //if(g_ctf)
1123         //      ctf_playerchanged();
1124 }
1125
1126 .float ebouncefactor, ebouncestop; // electro's values
1127 // TODO do we need all these fields, or should we stop autodetecting runtime
1128 // changes and just have a console command to update this?
1129 float ClientInit_SendEntity(entity to, float sf)
1130 {
1131         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1132         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1137         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1138         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1139         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1140         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1141         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1145         if(sv_foginterval && world.fog != "")
1146                 WriteString(MSG_ENTITY, world.fog);
1147         else
1148                 WriteString(MSG_ENTITY, "");
1149         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1150         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1151         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1152         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1153         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1154         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1155         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1156         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1157         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1158         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1159         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1160         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1161         return TRUE;
1162 }
1163
1164 void ClientInit_CheckUpdate()
1165 {
1166         self.nextthink = time;
1167         if(self.count != autocvar_g_balance_armor_blockpercent)
1168         {
1169                 self.count = autocvar_g_balance_armor_blockpercent;
1170                 self.SendFlags |= 1;
1171         }
1172         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1173         {
1174                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1175                 self.SendFlags |= 1;
1176         }
1177         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1178         {
1179                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1180                 self.SendFlags |= 1;
1181         }
1182         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1183         {
1184                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1185                 self.SendFlags |= 1;
1186         }
1187         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1188         {
1189                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1190                 self.SendFlags |= 1;
1191         }
1192         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1193         {
1194                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1195                 self.SendFlags |= 1;
1196         }
1197 }
1198
1199 void ClientInit_Spawn()
1200 {
1201         entity o;
1202         entity e;
1203         e = spawn();
1204         e.classname = "clientinit";
1205         e.think = ClientInit_CheckUpdate;
1206         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1207
1208         o = self;
1209         self = e;
1210         ClientInit_CheckUpdate();
1211         self = o;
1212 }
1213
1214 /*
1215 =============
1216 SetNewParms
1217 =============
1218 */
1219 void SetNewParms (void)
1220 {
1221         // initialize parms for a new player
1222         parm1 = -(86400 * 366);
1223 }
1224
1225 /*
1226 =============
1227 SetChangeParms
1228 =============
1229 */
1230 void SetChangeParms (void)
1231 {
1232         // save parms for level change
1233         parm1 = self.parm_idlesince - time;
1234 }
1235
1236 /*
1237 =============
1238 DecodeLevelParms
1239 =============
1240 */
1241 void DecodeLevelParms (void)
1242 {
1243         // load parms
1244         self.parm_idlesince = parm1;
1245         if(self.parm_idlesince == -(86400 * 366))
1246                 self.parm_idlesince = time;
1247
1248         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1249         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1250 }
1251
1252 /*
1253 =============
1254 ClientKill
1255
1256 Called when a client types 'kill' in the console
1257 =============
1258 */
1259
1260 .float clientkill_nexttime;
1261 void ClientKill_Now_TeamChange()
1262 {
1263         if(self.killindicator_teamchange == -1)
1264         {
1265                 self.team = -1;
1266                 JoinBestTeam( self, FALSE, FALSE );
1267         }
1268         else if(self.killindicator_teamchange == -2)
1269         {
1270                 if(g_ca)
1271                         self.caplayer = 0;
1272                 if(blockSpectators)
1273                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1274                 PutObserverInServer();
1275         }
1276         else
1277                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1278 }
1279
1280 void ClientKill_Now()
1281 {
1282         if(self.vehicle)
1283         {
1284             vehicles_exit(VHEF_RELESE);
1285             if(!self.killindicator_teamchange)
1286             {
1287             self.vehicle_health = -1;
1288             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1289             }
1290         }
1291
1292         if(self.killindicator && !wasfreed(self.killindicator))
1293                 remove(self.killindicator);
1294
1295         self.killindicator = world;
1296
1297         if(self.killindicator_teamchange)
1298                 ClientKill_Now_TeamChange();
1299
1300         // in any case:
1301         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1302
1303         // now I am sure the player IS dead
1304 }
1305 void KillIndicator_Think()
1306 {
1307         if (gameover)
1308         {
1309                 self.owner.killindicator = world;
1310                 remove(self);
1311                 return;
1312         }
1313
1314         if (!self.owner.modelindex)
1315         {
1316                 self.owner.killindicator = world;
1317                 remove(self);
1318                 return;
1319         }
1320
1321         if(self.cnt <= 0)
1322         {
1323                 self = self.owner;
1324                 ClientKill_Now(); // no oldself needed
1325                 return;
1326         }
1327     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1328     {
1329         self.nextthink = time + 1;
1330         self.cnt -= 1;
1331     }
1332         else
1333         {
1334                 if(self.cnt <= 10)
1335                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1336                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1337                 {
1338                         if(self.cnt <= 10)
1339                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1340                 }
1341                 self.nextthink = time + 1;
1342                 self.cnt -= 1;
1343         }
1344 }
1345
1346 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1347 {
1348         float killtime;
1349         entity e;
1350
1351         if (gameover)
1352                 return;
1353
1354         killtime = autocvar_g_balance_kill_delay;
1355
1356         if(g_race_qualifying || g_cts)
1357                 killtime = 0;
1358
1359     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1360     {
1361                 remove(self.killindicator);
1362                 self.killindicator = world;
1363
1364         ClientKill_Now(); // allow instant kill in this case
1365         return;
1366     }
1367
1368         self.killindicator_teamchange = targetteam;
1369
1370     if(!self.killindicator)
1371         {
1372                 if(self.modelindex && self.deadflag == DEAD_NO)
1373                 {
1374                         killtime = max(killtime, self.clientkill_nexttime - time);
1375                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1376                 }
1377
1378                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1379                 {
1380                         ClientKill_Now();
1381                 }
1382                 else
1383                 {
1384                         self.killindicator = spawn();
1385                         self.killindicator.owner = self;
1386                         self.killindicator.scale = 0.5;
1387                         setattachment(self.killindicator, self, "");
1388                         setorigin(self.killindicator, '0 0 52');
1389                         self.killindicator.think = KillIndicator_Think;
1390                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1391                         self.killindicator.cnt = ceil(killtime);
1392                         self.killindicator.count = bound(0, ceil(killtime), 10);
1393                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1394
1395                         for(e = world; (e = find(e, classname, "body")) != world; )
1396                         {
1397                                 if(e.enemy != self)
1398                                         continue;
1399                                 e.killindicator = spawn();
1400                                 e.killindicator.owner = e;
1401                                 e.killindicator.scale = 0.5;
1402                                 setattachment(e.killindicator, e, "");
1403                                 setorigin(e.killindicator, '0 0 52');
1404                                 e.killindicator.think = KillIndicator_Think;
1405                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1406                                 e.killindicator.cnt = ceil(killtime);
1407                         }
1408                         self.lip = 0;
1409                 }
1410         }
1411         if(self.killindicator)
1412         {
1413                 if(targetteam == 0) // just die
1414                 {
1415                         self.killindicator.colormod = '0 0 0';
1416                         if(clienttype(self) == CLIENTTYPE_REAL)
1417                         if(self.killindicator.cnt > 0)
1418                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1419                 }
1420                 else if(targetteam == -1) // auto
1421                 {
1422                         self.killindicator.colormod = '0 1 0';
1423                         if(clienttype(self) == CLIENTTYPE_REAL)
1424                         if(self.killindicator.cnt > 0)
1425                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1426                 }
1427                 else if(targetteam == -2) // spectate
1428                 {
1429                         self.killindicator.colormod = '0.5 0.5 0.5';
1430                         if(clienttype(self) == CLIENTTYPE_REAL)
1431                         if(self.killindicator.cnt > 0)
1432                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1433                 }
1434                 else
1435                 {
1436                         self.killindicator.colormod = TeamColor(targetteam);
1437                         if(clienttype(self) == CLIENTTYPE_REAL)
1438                         if(self.killindicator.cnt > 0)
1439                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1440                 }
1441         }
1442
1443 }
1444
1445 void ClientKill (void)
1446 {
1447         if (gameover)
1448                 return;
1449
1450         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1451         {
1452                 // do nothing
1453         }
1454     else if(self.freezetag_frozen)
1455     {
1456         // do nothing
1457     }
1458         else
1459                 ClientKill_TeamChange(0);
1460 }
1461
1462 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1463 {
1464     e.killindicator = spawn();
1465     e.killindicator.owner = e;
1466     e.killindicator.think = KillIndicator_Think;
1467     e.killindicator.nextthink = time + (e.lip) * 0.05;
1468     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1469     e.killindicator.health = 1; // this is used to indicate that it should be silent
1470     e.lip = 0;
1471 }
1472
1473 void FixClientCvars(entity e)
1474 {
1475         // send prediction settings to the client
1476         stuffcmd(e, "\nin_bindmap 0 0\n");
1477         if(g_race || g_cts)
1478                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1479         if(autocvar_g_antilag == 3) // client side hitscan
1480                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1481         if(sv_gentle)
1482                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1483         /*
1484          * we no longer need to stuff this. Remove this comment block if you feel
1485          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1486         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1487         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1488         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1489         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1490         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1491         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1492         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1493         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1494         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1495         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1496         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1497         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1498         stuffcmd(e, "cl_movement_edgefriction 1\n");
1499          */
1500 }
1501
1502 float PlayerInIDList(entity p, string idlist)
1503 {
1504         float n, i;
1505         string s;
1506
1507         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1508         if not(p.crypto_idfp)
1509                 return 0;
1510
1511         // this function allows abbreviated player IDs too!
1512         n = tokenize_console(idlist);
1513         for(i = 0; i < n; ++i)
1514         {
1515                 s = argv(i);
1516                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1517                         return 1;
1518         }
1519
1520         return 0;
1521 }
1522
1523 /*
1524 =============
1525 ClientConnect
1526
1527 Called when a client connects to the server
1528 =============
1529 */
1530 //void ctf_clientconnect();
1531 string ColoredTeamName(float t);
1532 void DecodeLevelParms (void);
1533 //void dom_player_join_team(entity pl);
1534 void set_dom_state(entity e);
1535 void ClientConnect (void)
1536 {
1537         float t;
1538
1539         if(self.flags & FL_CLIENT)
1540         {
1541                 print("Warning: ClientConnect, but already connected!\n");
1542                 return;
1543         }
1544
1545         if(Ban_MaybeEnforceBan(self))
1546                 return;
1547
1548         DecodeLevelParms();
1549
1550 #ifdef WATERMARK
1551         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1552 #endif
1553
1554         self.classname = "player_joining";
1555
1556         self.flags = FL_CLIENT;
1557         self.version_nagtime = time + 10 + random() * 10;
1558
1559         if(player_count<0)
1560         {
1561                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1562                 player_count = 0;
1563         }
1564
1565         PlayerScore_Attach(self);
1566         ClientData_Attach();
1567         accuracy_init(self);
1568
1569         bot_clientconnect();
1570
1571         playerdemo_init();
1572
1573         anticheat_init();
1574
1575         race_PreSpawnObserver();
1576
1577         //if(g_domination)
1578         //      dom_player_join_team(self);
1579
1580         // identify the right forced team
1581         if(autocvar_g_campaign)
1582         {
1583                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1584                 {
1585                         switch(autocvar_g_campaign_forceteam)
1586                         {
1587                                 case 1: self.team_forced = COLOR_TEAM1; break;
1588                                 case 2: self.team_forced = COLOR_TEAM2; break;
1589                                 case 3: self.team_forced = COLOR_TEAM3; break;
1590                                 case 4: self.team_forced = COLOR_TEAM4; break;
1591                                 default: self.team_forced = 0;
1592                         }
1593                 }
1594         }
1595         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1596                 self.team_forced = COLOR_TEAM1;
1597         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1598                 self.team_forced = COLOR_TEAM2;
1599         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1600                 self.team_forced = COLOR_TEAM3;
1601         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1602                 self.team_forced = COLOR_TEAM4;
1603         else if(autocvar_g_forced_team_otherwise == "red")
1604                 self.team_forced = COLOR_TEAM1;
1605         else if(autocvar_g_forced_team_otherwise == "blue")
1606                 self.team_forced = COLOR_TEAM2;
1607         else if(autocvar_g_forced_team_otherwise == "yellow")
1608                 self.team_forced = COLOR_TEAM3;
1609         else if(autocvar_g_forced_team_otherwise == "pink")
1610                 self.team_forced = COLOR_TEAM4;
1611         else if(autocvar_g_forced_team_otherwise == "spectate")
1612                 self.team_forced = -1;
1613         else if(autocvar_g_forced_team_otherwise == "spectator")
1614                 self.team_forced = -1;
1615         else
1616                 self.team_forced = 0;
1617
1618         if(!teamplay)
1619                 if(self.team_forced > 0)
1620                         self.team_forced = 0;
1621
1622         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1623
1624         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1625                 self.classname = "observer";
1626         } else {
1627                 if(teamplay)
1628                 {
1629                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1630                         {
1631                                 self.classname = "player";
1632                                 campaign_bots_may_start = 1;
1633                         }
1634                         else
1635                         {
1636                                 self.classname = "observer"; // do it anyway
1637                         }
1638                 }
1639                 else
1640                 {
1641                         self.classname = "player";
1642                         campaign_bots_may_start = 1;
1643                 }
1644         }
1645
1646         self.playerid = (playerid_last = playerid_last + 1);
1647
1648         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1649
1650     if(clienttype(self) == CLIENTTYPE_BOT)
1651         PlayerStats_AddPlayer(self);
1652
1653         if(autocvar_sv_eventlog)
1654                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1655
1656         LogTeamchange(self.playerid, self.team, 1);
1657
1658         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1659
1660         self.netname_previous = strzone(self.netname);
1661
1662         bprint("^4", self.netname, "^4 connected");
1663
1664         if(self.classname != "observer" && (g_domination || g_ctf))
1665                 bprint(" and joined the ", ColoredTeamName(self.team));
1666
1667         bprint("\n");
1668
1669         stuffcmd(self, strcat(clientstuff, "\n"));
1670         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1671         stuffcmd(self, "cl_particles_reloadeffects\n");
1672
1673         FixClientCvars(self);
1674
1675         // spawnfunc_waypoint sprites
1676         WaypointSprite_InitClient(self);
1677
1678         // Wazat's grappling hook
1679         SetGrappleHookBindings();
1680
1681         // get autoswitch state from player when he toggles it
1682         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1683
1684         // get version info from player
1685         stuffcmd(self, "cmd clientversion $gameversion\n");
1686
1687         // get other cvars from player
1688         GetCvars(0);
1689
1690         // notify about available teams
1691         if(teamplay)
1692         {
1693                 CheckAllowedTeams(self);
1694                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1695                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1696         }
1697         else
1698                 stuffcmd(self, "set _teams_available 0\n");
1699
1700         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1701
1702         if(g_arena || g_ca)
1703         {
1704                 self.classname = "observer";
1705                 if(g_arena)
1706                         Spawnqueue_Insert(self);
1707         }
1708         /*else if(g_ctf)
1709         {
1710                 ctf_clientconnect();
1711         }*/
1712
1713         attach_entcs();
1714
1715         bot_relinkplayerlist();
1716
1717         self.spectatortime = time;
1718         if(blockSpectators)
1719         {
1720                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1721         }
1722
1723         self.jointime = time;
1724         self.allowedTimeouts = autocvar_sv_timeout_number;
1725
1726         if(clienttype(self) == CLIENTTYPE_REAL)
1727         {
1728                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1729                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1730         }
1731
1732         if(g_lms)
1733         {
1734                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1735                 {
1736                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1737                         self.frags = FRAGS_SPECTATOR;
1738                 }
1739         }
1740
1741         if(!sv_foginterval && world.fog != "")
1742                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1743
1744         SoundEntity_Attach(self);
1745
1746         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1747         {
1748                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1749                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1750         }
1751         else
1752                 self.hitplotfh = -1;
1753
1754         if(g_race || g_cts) {
1755                 string rr;
1756                 if(g_cts)
1757                         rr = CTS_RECORD;
1758                 else
1759                         rr = RACE_RECORD;
1760                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1761
1762                 msg_entity = self;
1763                 race_send_recordtime(MSG_ONE);
1764                 race_send_speedaward(MSG_ONE);
1765
1766                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1767                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1768                 race_send_speedaward_alltimebest(MSG_ONE);
1769
1770                 float i;
1771                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1772                         race_SendRankings(i, 0, 0, MSG_ONE);
1773                 }
1774         }
1775         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1776                 send_CSQC_teamnagger();
1777
1778         if (g_domination)
1779                 set_dom_state(self);
1780
1781         CheatInitClient();
1782
1783         if(!autocvar_g_campaign)
1784                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1785 }
1786
1787 /*
1788 =============
1789 ClientDisconnect
1790
1791 Called when a client disconnects from the server
1792 =============
1793 */
1794 .entity chatbubbleentity;
1795 void ReadyCount();
1796 void ClientDisconnect (void)
1797 {
1798         if(self.vehicle)
1799             vehicles_exit(VHEF_RELESE);
1800
1801         if not(self.flags & FL_CLIENT)
1802         {
1803                 print("Warning: ClientDisconnect without ClientConnect\n");
1804                 return;
1805         }
1806
1807         PlayerStats_AddGlobalInfo(self);
1808
1809         CheatShutdownClient();
1810
1811         if(self.hitplotfh >= 0)
1812         {
1813                 fclose(self.hitplotfh);
1814                 self.hitplotfh = -1;
1815         }
1816
1817         anticheat_report();
1818         anticheat_shutdown();
1819
1820         playerdemo_shutdown();
1821
1822         bot_clientdisconnect();
1823
1824         if(self.entcs)
1825                 detach_entcs();
1826
1827         if(autocvar_sv_eventlog)
1828                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1829         bprint ("^4",self.netname);
1830         bprint ("^4 disconnected\n");
1831
1832         SoundEntity_Detach(self);
1833
1834         DropAllRunes(self);
1835         MUTATOR_CALLHOOK(ClientDisconnect);
1836
1837         Portal_ClearAll(self);
1838
1839         if(self.flagcarried)
1840                 DropFlag(self.flagcarried, world, world);
1841         if(self.ballcarried && g_nexball)
1842                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1843
1844         // Here, everything has been done that requires this player to be a client.
1845
1846         self.flags &~= FL_CLIENT;
1847
1848         if (self.chatbubbleentity)
1849                 remove (self.chatbubbleentity);
1850
1851         if (self.killindicator)
1852                 remove (self.killindicator);
1853
1854         WaypointSprite_PlayerGone();
1855
1856         bot_relinkplayerlist();
1857
1858         if(g_arena)
1859         {
1860                 Spawnqueue_Unmark(self);
1861                 Spawnqueue_Remove(self);
1862         }
1863
1864         accuracy_free(self);
1865         ClientData_Detach();
1866         PlayerScore_Detach(self);
1867
1868         if(self.netname_previous)
1869                 strunzone(self.netname_previous);
1870         if(self.clientstatus)
1871                 strunzone(self.clientstatus);
1872         if(self.weaponorder_byimpulse)
1873                 strunzone(self.weaponorder_byimpulse);
1874
1875         ClearPlayerSounds();
1876
1877         if(self.personal)
1878                 remove(self.personal);
1879
1880         self.playerid = 0;
1881         ReadyCount();
1882
1883         // free cvars
1884         GetCvars(-1);
1885 }
1886
1887 .float BUTTON_CHAT;
1888 void ChatBubbleThink()
1889 {
1890         self.nextthink = time;
1891         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1892         {
1893                 if(self.owner) // but why can that ever be world?
1894                         self.owner.chatbubbleentity = world;
1895                 remove(self);
1896                 return;
1897         }
1898         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1899 #ifdef TETRIS
1900                 || self.owner.tetris_on
1901 #endif
1902         )
1903                 self.model = self.mdl;
1904         else
1905                 self.model = "";
1906 };
1907
1908 void UpdateChatBubble()
1909 {
1910         if (!self.modelindex)
1911                 return;
1912         // spawn a chatbubble entity if needed
1913         if (!self.chatbubbleentity)
1914         {
1915                 self.chatbubbleentity = spawn();
1916                 self.chatbubbleentity.owner = self;
1917                 self.chatbubbleentity.exteriormodeltoclient = self;
1918                 self.chatbubbleentity.think = ChatBubbleThink;
1919                 self.chatbubbleentity.nextthink = time;
1920                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1921                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1922                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1923                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1924                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1925                 self.chatbubbleentity.model = "";
1926                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1927         }
1928 }
1929
1930
1931 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1932 // added to the model skins
1933 /*void UpdateColorModHack()
1934 {
1935         local float c;
1936         c = self.clientcolors & 15;
1937         // LordHavoc: only bothering to support white, green, red, yellow, blue
1938              if (!teamplay) self.colormod = '0 0 0';
1939         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1940         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1941         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1942         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1943         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1944         else self.colormod = '1 1 1';
1945 };*/
1946
1947 .float oldcolormap;
1948 void respawn(void)
1949 {
1950         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1951         {
1952                 self.solid = SOLID_NOT;
1953                 self.takedamage = DAMAGE_NO;
1954                 self.movetype = MOVETYPE_FLY;
1955                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1956                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1957                 self.effects |= EF_ADDITIVE;
1958                 self.oldcolormap = self.colormap;
1959                 self.colormap = 512;
1960                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1961                 if(autocvar_g_respawn_ghosts_maxtime)
1962                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1963         }
1964
1965         CopyBody(1);
1966         self.effects |= EF_NODRAW; // prevent another CopyBody
1967         if(self.oldcolormap)
1968         {
1969                 self.colormap = self.oldcolormap;
1970                 self.oldcolormap = 0;
1971         }
1972         PutClientInServer();
1973 }
1974
1975 void play_countdown(float finished, string samp)
1976 {
1977         if(clienttype(self) == CLIENTTYPE_REAL)
1978                 if(floor(finished - time - frametime) != floor(finished - time))
1979                         if(finished - time < 6)
1980                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1981 }
1982
1983 void player_powerups (void)
1984 {
1985         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1986         olditems = self.items;
1987
1988         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1989         {
1990                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1991                 self.modelflags |= MF_ROCKET;
1992         }
1993         else
1994         {
1995                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1996                 self.modelflags &~= MF_ROCKET;
1997         }
1998
1999         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2000
2001         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2002                 return;
2003
2004         Fire_ApplyDamage(self);
2005         Fire_ApplyEffect(self);
2006
2007         if (g_minstagib)
2008         {
2009                 self.effects |= EF_FULLBRIGHT;
2010
2011                 if (self.items & IT_STRENGTH)
2012                 {
2013                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2014                         if (time > self.strength_finished)
2015                         {
2016                                 self.alpha = default_player_alpha;
2017                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2018                                 self.items &~= IT_STRENGTH;
2019                                 sprint(self, "^3Invisibility has worn off\n");
2020                         }
2021                 }
2022                 else
2023                 {
2024                         if (time < self.strength_finished)
2025                         {
2026                                 self.alpha = g_minstagib_invis_alpha;
2027                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2028                                 self.items |= IT_STRENGTH;
2029                                 sprint(self, "^3You are invisible\n");
2030                         }
2031                 }
2032
2033                 if (self.items & IT_INVINCIBLE)
2034                 {
2035                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2036                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2037                         {
2038                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2039                                 sprint(self, "^3Speed has worn off\n");
2040                         }
2041                 }
2042                 else
2043                 {
2044                         if (time < self.invincible_finished)
2045                         {
2046                                 self.items = self.items | IT_INVINCIBLE;
2047                                 sprint(self, "^3You are on speed\n");
2048                         }
2049                 }
2050         }
2051         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2052         {
2053                 if (self.items & IT_STRENGTH)
2054                 {
2055                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2056                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2057                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2058                         {
2059                                 self.items = self.items - (self.items & IT_STRENGTH);
2060                                 sprint(self, "^3Strength has worn off\n");
2061                         }
2062                 }
2063                 else
2064                 {
2065                         if (time < self.strength_finished)
2066                         {
2067                                 self.items = self.items | IT_STRENGTH;
2068                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2069                         }
2070                 }
2071                 if (self.items & IT_INVINCIBLE)
2072                 {
2073                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2074                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2075                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2076                         {
2077                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2078                                 sprint(self, "^3Shield has worn off\n");
2079                         }
2080                 }
2081                 else
2082                 {
2083                         if (time < self.invincible_finished)
2084                         {
2085                                 self.items = self.items | IT_INVINCIBLE;
2086                                 sprint(self, "^3Shield surrounds you\n");
2087                         }
2088                 }
2089
2090                 if(autocvar_g_nodepthtestplayers)
2091                         self.effects = self.effects | EF_NODEPTHTEST;
2092
2093                 if(autocvar_g_fullbrightplayers)
2094                         self.effects = self.effects | EF_FULLBRIGHT;
2095
2096                 // midair gamemode: damage only while in the air
2097                 // if in midair mode, being on ground grants temporary invulnerability
2098                 // (this is so that multishot weapon don't clear the ground flag on the
2099                 // first damage in the frame, leaving the player vulnerable to the
2100                 // remaining hits in the same frame)
2101                 if (self.flags & FL_ONGROUND)
2102                 if (g_midair)
2103                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2104
2105                 if (time >= game_starttime)
2106                 if (time < self.spawnshieldtime)
2107                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2108         }
2109
2110         MUTATOR_CALLHOOK(PlayerPowerups);
2111 }
2112
2113 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2114 {
2115         if(current > stable)
2116                 return current;
2117         else if(current > stable - 0.25) // when close enough, "snap"
2118                 return stable;
2119         else
2120                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2121 }
2122
2123 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2124 {
2125         if(current < stable)
2126                 return current;
2127         else if(current < stable + 0.25) // when close enough, "snap"
2128                 return stable;
2129         else
2130                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2131 }
2132
2133 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2134 {
2135         if(current > rotstable)
2136         {
2137                 if(rotframetime > 0)
2138                 {
2139                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2140                         current = max(rotstable, current - rotlinear * rotframetime);
2141                 }
2142         }
2143         else if(current < regenstable)
2144         {
2145                 if(regenframetime > 0)
2146                 {
2147                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2148                         current = min(regenstable, current + regenlinear * regenframetime);
2149                 }
2150         }
2151
2152         if(current > limit)
2153                 current = limit;
2154
2155         return current;
2156 }
2157
2158 void player_regen (void)
2159 {
2160         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2161         maxh = autocvar_g_balance_health_rotstable;
2162         maxa = autocvar_g_balance_armor_rotstable;
2163         maxf = autocvar_g_balance_fuel_rotstable;
2164         minh = autocvar_g_balance_health_regenstable;
2165         mina = autocvar_g_balance_armor_regenstable;
2166         minf = autocvar_g_balance_fuel_regenstable;
2167         limith = autocvar_g_balance_health_limit;
2168         limita = autocvar_g_balance_armor_limit;
2169         limitf = autocvar_g_balance_fuel_limit;
2170
2171         max_mod = regen_mod = rot_mod = limit_mod = 1;
2172
2173         if (self.runes & RUNE_REGEN)
2174         {
2175                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2176                 {
2177                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2178                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2179                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2180                 }
2181                 else
2182                 {
2183                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2184                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2185                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2186                 }
2187         }
2188         else if (self.runes & CURSE_VENOM)
2189         {
2190                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2191                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2192                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2193                 else
2194                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2195                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2196                 //if (!self.runes & RUNE_REGEN)
2197                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2198         }
2199         maxh = maxh * max_mod;
2200         //maxa = maxa * max_mod;
2201         //maxf = maxf * max_mod;
2202         minh = minh * max_mod;
2203         //mina = mina * max_mod;
2204         //minf = minf * max_mod;
2205         limith = limith * limit_mod;
2206         limita = limita * limit_mod;
2207         //limitf = limitf * limit_mod;
2208
2209         if(g_lms && g_ca)
2210                 rot_mod = 0;
2211
2212         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2213         {
2214                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2215                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2216
2217                 // if player rotted to death...  die!
2218                 if(self.health < 1)
2219                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2220         }
2221
2222         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2223                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2224 }
2225
2226 float zoomstate_set;
2227 void SetZoomState(float z)
2228 {
2229         if(z != self.zoomstate)
2230         {
2231                 self.zoomstate = z;
2232                 ClientData_Touch(self);
2233         }
2234         zoomstate_set = 1;
2235 }
2236
2237 void GetPressedKeys(void) {
2238         MUTATOR_CALLHOOK(GetPressedKeys);
2239         if (self.movement_x > 0) // get if movement keys are pressed
2240         {       // forward key pressed
2241                 self.pressedkeys |= KEY_FORWARD;
2242                 self.pressedkeys &~= KEY_BACKWARD;
2243         }
2244         else if (self.movement_x < 0)
2245         {       // backward key pressed
2246                 self.pressedkeys |= KEY_BACKWARD;
2247                 self.pressedkeys &~= KEY_FORWARD;
2248         }
2249         else
2250         {       // no x input
2251                 self.pressedkeys &~= KEY_FORWARD;
2252                 self.pressedkeys &~= KEY_BACKWARD;
2253         }
2254
2255         if (self.movement_y > 0)
2256         {       // right key pressed
2257                 self.pressedkeys |= KEY_RIGHT;
2258                 self.pressedkeys &~= KEY_LEFT;
2259         }
2260         else if (self.movement_y < 0)
2261         {       // left key pressed
2262                 self.pressedkeys |= KEY_LEFT;
2263                 self.pressedkeys &~= KEY_RIGHT;
2264         }
2265         else
2266         {       // no y input
2267                 self.pressedkeys &~= KEY_RIGHT;
2268                 self.pressedkeys &~= KEY_LEFT;
2269         }
2270
2271         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2272                 self.pressedkeys |= KEY_JUMP;
2273         else
2274                 self.pressedkeys &~= KEY_JUMP;
2275         if (self.BUTTON_CROUCH)
2276                 self.pressedkeys |= KEY_CROUCH;
2277         else
2278                 self.pressedkeys &~= KEY_CROUCH;
2279 }
2280
2281 /*
2282 ======================
2283 spectate mode routines
2284 ======================
2285 */
2286
2287 void SpectateCopy(entity spectatee) {
2288         other = spectatee;
2289         MUTATOR_CALLHOOK(SpectateCopy);
2290         self.armortype = spectatee.armortype;
2291         self.armorvalue = spectatee.armorvalue;
2292         self.ammo_cells = spectatee.ammo_cells;
2293         self.ammo_shells = spectatee.ammo_shells;
2294         self.ammo_nails = spectatee.ammo_nails;
2295         self.ammo_rockets = spectatee.ammo_rockets;
2296         self.ammo_fuel = spectatee.ammo_fuel;
2297         self.clip_load = spectatee.clip_load;
2298         self.clip_size = spectatee.clip_size;
2299         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2300         self.health = spectatee.health;
2301         self.impulse = 0;
2302         self.items = spectatee.items;
2303         self.last_pickup = spectatee.last_pickup;
2304         self.hit_time = spectatee.hit_time;
2305         self.metertime = spectatee.metertime;
2306         self.strength_finished = spectatee.strength_finished;
2307         self.invincible_finished = spectatee.invincible_finished;
2308         self.pressedkeys = spectatee.pressedkeys;
2309         self.weapons = spectatee.weapons;
2310         self.switchweapon = spectatee.switchweapon;
2311         self.switchingweapon = spectatee.switchingweapon;
2312         self.weapon = spectatee.weapon;
2313         self.nex_charge = spectatee.nex_charge;
2314         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2315         self.hagar_load = spectatee.hagar_load;
2316         self.minelayer_mines = spectatee.minelayer_mines;
2317         self.punchangle = spectatee.punchangle;
2318         self.view_ofs = spectatee.view_ofs;
2319         self.v_angle = spectatee.v_angle;
2320         self.velocity = spectatee.velocity;
2321         self.dmg_take = spectatee.dmg_take;
2322         self.dmg_save = spectatee.dmg_save;
2323         self.dmg_inflictor = spectatee.dmg_inflictor;
2324         self.angles = spectatee.v_angle;
2325         if(!self.BUTTON_USE)
2326                 self.fixangle = TRUE;
2327         setorigin(self, spectatee.origin);
2328         setsize(self, spectatee.mins, spectatee.maxs);
2329         SetZoomState(spectatee.zoomstate);
2330
2331         anticheat_spectatecopy(spectatee);
2332
2333         //self.vehicle = spectatee.vehicle;
2334
2335         self.hud = spectatee.hud;
2336         if(spectatee.vehicle)
2337     {
2338         setorigin(self, spectatee.origin);
2339         self.velocity = spectatee.vehicle.velocity;
2340         self.v_angle += spectatee.vehicle.angles;
2341         //self.v_angle_x *= -1;
2342         self.vehicle_health = spectatee.vehicle_health;
2343         self.vehicle_shield = spectatee.vehicle_shield;
2344         self.vehicle_energy = spectatee.vehicle_energy;
2345         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2346         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2347         self.vehicle_reload1 = spectatee.vehicle_reload1;
2348         self.vehicle_reload2 = spectatee.vehicle_reload2;
2349
2350         msg_entity = self;
2351         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2352         WriteEntity(MSG_ONE, spectatee);
2353         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2354     }
2355 }
2356
2357 float SpectateUpdate() {
2358         if(!self.enemy)
2359             return 0;
2360
2361         if (self == self.enemy)
2362                 return 0;
2363
2364         if(self.enemy.classname != "player")
2365                 return 0;
2366
2367         SpectateCopy(self.enemy);
2368
2369         return 1;
2370 }
2371
2372
2373 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2374 entity CA_SpectateNext(entity start) {
2375         if (start.team == self.team) {
2376                 return start;
2377         }
2378
2379         other = start;
2380         // continue from current player
2381         while(other && other.team != self.team) {
2382                 other = find(other, classname, "player");
2383         }
2384
2385         if (!other) {
2386                 // restart from begining
2387                 other = find(other, classname, "player");
2388                 while(other && other.team != self.team) {
2389                         other = find(other, classname, "player");
2390                 }
2391         }
2392
2393         return other;
2394 }
2395
2396 float SpectateNext() {
2397         other = find(self.enemy, classname, "player");
2398         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2399                 // CA and ca players when spectating enemies is forbidden
2400                 other = CA_SpectateNext(other);
2401         } else {
2402                 // other modes and ca spectators or spectating enemies is allowed
2403                 if (!other)
2404                         other = find(other, classname, "player");
2405         }
2406
2407         if (other)
2408                 self.enemy = other;
2409
2410         if(self.enemy.classname == "player") {
2411             if(self.enemy.vehicle)
2412             {
2413             msg_entity = self;
2414             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2415             WriteEntity(MSG_ONE, self.enemy);
2416             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2417             self.movetype = MOVETYPE_NONE;
2418             accuracy_resend(self);
2419             }
2420             else
2421             {
2422             msg_entity = self;
2423             WriteByte(MSG_ONE, SVC_SETVIEW);
2424             WriteEntity(MSG_ONE, self.enemy);
2425             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2426             self.movetype = MOVETYPE_NONE;
2427             accuracy_resend(self);
2428
2429             if(!SpectateUpdate())
2430                 PutObserverInServer();
2431         }
2432         return 1;
2433         } else {
2434                 return 0;
2435         }
2436 }
2437
2438 /*
2439 =============
2440 ShowRespawnCountdown()
2441
2442 Update a respawn countdown display.
2443 =============
2444 */
2445 void ShowRespawnCountdown()
2446 {
2447         float number;
2448         if(self.deadflag == DEAD_NO) // just respawned?
2449                 return;
2450         else
2451         {
2452                 number = ceil(self.death_time - time);
2453                 if(number <= 0)
2454                         return;
2455                 if(number <= self.respawn_countdown)
2456                 {
2457                         self.respawn_countdown = number - 1;
2458                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2459                                 AnnounceTo(self, strcat(ftos(number), ""));
2460                 }
2461         }
2462 }
2463
2464 .float prevent_join_msgtime;
2465 void LeaveSpectatorMode()
2466 {
2467         if(nJoinAllowed(1)) {
2468                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2469                         self.classname = "player";
2470
2471                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2472                                 JoinBestTeam(self, FALSE, TRUE);
2473
2474                         if(autocvar_g_campaign)
2475                                 campaign_bots_may_start = 1;
2476
2477                         PutClientInServer();
2478
2479                         if(self.classname == "player")
2480                                 bprint ("^4", self.netname, "^4 is playing now\n");
2481
2482                         if(!autocvar_g_campaign)
2483                         if (time < self.jointime + autocvar_welcome_message_time)
2484                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2485
2486                         if (self.prevent_join_msgtime)
2487                         {
2488                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2489                                 self.prevent_join_msgtime = 0;
2490                         }
2491
2492                         return;
2493                 } else {
2494                         if (g_ca && self.caplayer) {
2495                         }       // do nothing
2496                         else
2497                                 stuffcmd(self,"menu_showteamselect\n");
2498                         return;
2499                 }
2500         }
2501         else {
2502                 //player may not join because of g_maxplayers is set
2503                 if (time - self.prevent_join_msgtime > 2)
2504                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2505                 self.prevent_join_msgtime = time;
2506         }
2507 }
2508
2509 /**
2510  * Determines whether the player is allowed to join. This depends on cvar
2511  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2512  * it checks whether the number of currently playing players exceeds g_maxplayers.
2513  * @return int number of free slots for players, 0 if none
2514  */
2515 float nJoinAllowed(float includeMe) {
2516         if(self.team_forced < 0)
2517                 return FALSE; // forced spectators can never join
2518
2519         // TODO simplify this
2520         local entity e;
2521
2522         local float totalClients;
2523         FOR_EACH_CLIENT(e)
2524                 totalClients += 1;
2525
2526         if (!autocvar_g_maxplayers)
2527                 return maxclients - totalClients + includeMe;
2528
2529         local float currentlyPlaying;
2530         FOR_EACH_REALPLAYER(e)
2531                 currentlyPlaying += 1;
2532
2533         if(currentlyPlaying < autocvar_g_maxplayers)
2534                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2535
2536         return 0;
2537 }
2538
2539 /**
2540  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2541  * g_maxplayers_spectator_blocktime seconds
2542  */
2543 void checkSpectatorBlock() {
2544         if(self.classname == "spectator" || self.classname == "observer") {
2545                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2546                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2547                         dropclient(self);
2548                 }
2549         }
2550 }
2551
2552 .float motd_actived_time; // used for both motd and campaign_message
2553 void PrintWelcomeMessage()
2554 {
2555         if (self.motd_actived_time == 0) { // is there already a message showing?
2556                 if (autocvar_g_campaign) {
2557                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2558                                 self.motd_actived_time = time;
2559                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2560                         }
2561                 } else {
2562                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2563                                 self.motd_actived_time = time;
2564                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2565                         }
2566                 }
2567         } else { // showing MOTD or campaign message
2568                 if (autocvar_g_campaign) {
2569                         if (self.BUTTON_INFO)
2570                                 self.motd_actived_time = time;
2571                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2572                                 self.motd_actived_time = 0;
2573                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2574                         }
2575                 } else {
2576                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2577                                 if (self.BUTTON_INFO)
2578                                         self.motd_actived_time = time;
2579                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2580                                         self.motd_actived_time = 0;
2581                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2582                                 }
2583                         }
2584                 }
2585         }
2586 }
2587
2588 void ObserverThink()
2589 {
2590         float prefered_movetype;
2591         if (self.flags & FL_JUMPRELEASED) {
2592                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2593                         self.flags &~= FL_JUMPRELEASED;
2594                         self.flags |= FL_SPAWNING;
2595                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2596                         self.flags &~= FL_JUMPRELEASED;
2597                         if(SpectateNext() == 1) {
2598                                 self.classname = "spectator";
2599                         }
2600                 } else {
2601                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2602                         if (self.movetype != prefered_movetype)
2603                                 self.movetype = prefered_movetype;
2604                 }
2605         } else {
2606                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2607                         self.flags |= FL_JUMPRELEASED;
2608                         if(self.flags & FL_SPAWNING)
2609                         {
2610                                 self.flags &~= FL_SPAWNING;
2611                                 LeaveSpectatorMode();
2612                                 return;
2613                         }
2614                 }
2615         }
2616
2617         PrintWelcomeMessage();
2618 }
2619
2620 void SpectatorThink()
2621 {
2622         if (self.flags & FL_JUMPRELEASED) {
2623                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2624                         self.flags &~= FL_JUMPRELEASED;
2625                         self.flags |= FL_SPAWNING;
2626                 } else if(self.BUTTON_ATCK) {
2627                         self.flags &~= FL_JUMPRELEASED;
2628                         if(SpectateNext() == 1) {
2629                                 self.classname = "spectator";
2630                         } else {
2631                                 self.classname = "observer";
2632                                 PutClientInServer();
2633                         }
2634                 } else if (self.BUTTON_ATCK2) {
2635                         self.flags &~= FL_JUMPRELEASED;
2636                         self.classname = "observer";
2637                         PutClientInServer();
2638                 } else {
2639                         if(!SpectateUpdate())
2640                                 PutObserverInServer();
2641                 }
2642         } else {
2643                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2644                         self.flags |= FL_JUMPRELEASED;
2645                         if(self.flags & FL_SPAWNING)
2646                         {
2647                                 self.flags &~= FL_SPAWNING;
2648                                 LeaveSpectatorMode();
2649                                 return;
2650                         }
2651                 }
2652                 if(!SpectateUpdate())
2653                         PutObserverInServer();
2654         }
2655
2656         PrintWelcomeMessage();
2657         self.flags |= FL_CLIENT | FL_NOTARGET;
2658 }
2659
2660 float ctf_usekey();
2661 void PlayerUseKey()
2662 {
2663         if(self.classname != "player")
2664                 return;
2665
2666         if(self.vehicle)
2667         {
2668         vehicles_exit(VHEF_NORMAL);
2669         return;
2670         }
2671
2672         // a use key was pressed; call handlers
2673         if(ctf_usekey())
2674                 return;
2675
2676         MUTATOR_CALLHOOK(PlayerUseKey);
2677 }
2678
2679 .float touchexplode_time;
2680
2681 /*
2682 =============
2683 PlayerPreThink
2684
2685 Called every frame for each client before the physics are run
2686 =============
2687 */
2688 .float usekeypressed;
2689 void() ctf_setstatus;
2690 void() nexball_setstatus;
2691 .float items_added;
2692 void PlayerPreThink (void)
2693 {
2694         WarpZone_PlayerPhysics_FixVAngle();
2695
2696         self.stat_game_starttime = game_starttime;
2697         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2698         self.stat_leadlimit = autocvar_leadlimit;
2699
2700         if(frametime)
2701         {
2702                 // physics frames: update anticheat stuff
2703                 anticheat_prethink();
2704         }
2705
2706         if(blockSpectators && frametime)
2707                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2708                 checkSpectatorBlock();
2709
2710         zoomstate_set = 0;
2711
2712         if(self.netname_previous != self.netname)
2713         {
2714                 if(autocvar_sv_eventlog)
2715                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2716                 if(self.netname_previous)
2717                         strunzone(self.netname_previous);
2718                 self.netname_previous = strzone(self.netname);
2719         }
2720
2721         // version nagging
2722         if(self.version_nagtime)
2723                 if(self.cvar_g_xonoticversion)
2724                         if(time > self.version_nagtime)
2725                         {
2726                                 // don't notify git users
2727                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2728                                 {
2729                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2730                                         {
2731                                                 // notify release users if connecting to git
2732                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2733                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2734                                         }
2735                                         else
2736                                         {
2737                                                 float r;
2738                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2739                                                 if(r < 0)
2740                                                 {
2741                                                         // give users new version
2742                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2743                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2744                                                 }
2745                                                 else if(r > 0)
2746                                                 {
2747                                                         // notify users about old server version
2748                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2749                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2750                                                 }
2751                                         }
2752                                 }
2753                                 self.version_nagtime = 0;
2754                         }
2755
2756         // GOD MODE info
2757         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2758         {
2759                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2760                 self.max_armorvalue = 0;
2761         }
2762
2763 #ifdef TETRIS
2764         if (TetrisPreFrame())
2765                 return;
2766 #endif
2767
2768         MUTATOR_CALLHOOK(PlayerPreThink);
2769
2770         if(self.BUTTON_USE && !self.usekeypressed)
2771                 PlayerUseKey();
2772         self.usekeypressed = self.BUTTON_USE;
2773
2774         PrintWelcomeMessage();
2775
2776         if(self.classname == "player") {
2777 //              if(self.netname == "Wazat")
2778 //                      bprint(self.classname, "\n");
2779
2780                 CheckRules_Player();
2781
2782                 if (intermission_running)
2783                 {
2784                         IntermissionThink ();   // otherwise a button could be missed between
2785                         return;                                 // the think tics
2786                 }
2787
2788                 //don't allow the player to turn around while game is paused!
2789                 if(timeoutStatus == 2) {
2790                         // FIXME turn this into CSQC stuff
2791                         self.v_angle = self.lastV_angle;
2792                         self.angles = self.lastV_angle;
2793                         self.fixangle = TRUE;
2794                 }
2795
2796                 if(frametime)
2797                 {
2798                         if(self.health <= 0 && autocvar_g_deathglow)
2799                         {
2800                                 if(self.glowmod_x > 0)
2801                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2802                                 else
2803                                         self.glowmod_x = -1;
2804                                 if(self.glowmod_y > 0)
2805                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2806                                 else
2807                                         self.glowmod_y = -1;
2808                                 if(self.glowmod_z > 0)
2809                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2810                                 else
2811                                         self.glowmod_z = -1;
2812                         }
2813                         else
2814                         {
2815                                 // set weapon and player glowmod
2816                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2817
2818                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2819                                 {
2820                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2821                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2822                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2823
2824                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2825                                         {
2826                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2827                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2828                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2829                                         }
2830                                 }
2831                                 else
2832                                         self.weaponentity_glowmod = self.glowmod;
2833                         }
2834                         player_powerups();
2835                 }
2836
2837                 if (g_minstagib)
2838                         minstagib_ammocheck();
2839
2840                 if (self.deadflag != DEAD_NO)
2841                 {
2842                         float button_pressed, force_respawn;
2843                         if(self.personal && g_race_qualifying)
2844                         {
2845                                 if(time > self.death_time)
2846                                 {
2847                                         self.death_time = time + 1; // only retry once a second
2848                                         respawn();
2849                                         self.impulse = 141;
2850                                 }
2851                         }
2852                         else
2853                         {
2854                                 if(frametime)
2855                                         player_anim();
2856                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2857                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2858                                 if (self.deadflag == DEAD_DYING)
2859                                 {
2860                                         if(force_respawn)
2861                                                 self.deadflag = DEAD_RESPAWNING;
2862                                         else if(!button_pressed)
2863                                                 self.deadflag = DEAD_DEAD;
2864                                 }
2865                                 else if (self.deadflag == DEAD_DEAD)
2866                                 {
2867                                         if(button_pressed)
2868                                                 self.deadflag = DEAD_RESPAWNABLE;
2869                                 }
2870                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2871                                 {
2872                                         if(!button_pressed)
2873                                                 self.deadflag = DEAD_RESPAWNING;
2874                                 }
2875                                 else if (self.deadflag == DEAD_RESPAWNING)
2876                                 {
2877                                         if(time > self.death_time)
2878                                         {
2879                                                 self.death_time = time + 1; // only retry once a second
2880                                                 respawn();
2881                                         }
2882                                 }
2883                                 ShowRespawnCountdown();
2884                         }
2885                         return;
2886                 }
2887                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2888                 // so (self.deadflag == DEAD_NO) is always true in the code below
2889
2890                 if(g_touchexplode)
2891                 if(time > self.touchexplode_time)
2892                 if(self.classname == "player")
2893                 if(self.deadflag == DEAD_NO)
2894                 if not(IS_INDEPENDENT_PLAYER(self))
2895                 FOR_EACH_PLAYER(other) if(self != other)
2896                 {
2897                         if(time > other.touchexplode_time)
2898                         if(other.deadflag == DEAD_NO)
2899                         if not(IS_INDEPENDENT_PLAYER(other))
2900                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2901                         {
2902                                 PlayerTouchExplode(self, other);
2903                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2904                         }
2905                 }
2906
2907                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2908                 {
2909                         vector dist;
2910
2911                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2912                         dist = self.prevorigin - self.origin;
2913                         dist_z = 0;
2914                         self.lms_traveled_distance += fabs(vlen(dist));
2915
2916                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2917                         {
2918                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2919                                 self.lms_traveled_distance = 0;
2920                         }
2921
2922                         if(time > self.lms_nextcheck)
2923                         {
2924                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2925                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2926                                 {
2927                                         centerprint(self, autocvar_g_lms_campcheck_message);
2928                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2929                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2930                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2931                                 }
2932                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2933                                 self.lms_traveled_distance = 0;
2934                         }
2935                 }
2936
2937                 self.prevorigin = self.origin;
2938
2939                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2940                 {
2941                         if (!self.crouch)
2942                         {
2943                                 self.crouch = TRUE;
2944                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2945                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2946                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2947                         }
2948                 }
2949                 else
2950                 {
2951                         if (self.crouch)
2952                         {
2953                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2954                                 if (!trace_startsolid)
2955                                 {
2956                                         self.crouch = FALSE;
2957                                         self.view_ofs = PL_VIEW_OFS;
2958                                         setsize (self, PL_MIN, PL_MAX);
2959                                 }
2960                         }
2961                 }
2962
2963                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2964                 {
2965                         if(self.bloodloss_timer < time)
2966                         {
2967                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2968                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2969                         }
2970                 }
2971
2972                 FixPlayermodel();
2973
2974                 GrapplingHookFrame();
2975
2976                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2977                 //if(frametime)
2978                 {
2979                         self.items &~= self.items_added;
2980
2981                         W_WeaponFrame();
2982
2983                         self.items_added = 0;
2984                         if(self.items & IT_JETPACK)
2985                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2986                                         self.items_added |= IT_FUEL;
2987
2988                         self.items |= self.items_added;
2989                 }
2990
2991                 player_regen();
2992
2993                 // rot nex charge to the charge limit
2994                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2995                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2996
2997                 if(frametime)
2998                         player_anim();
2999
3000                 if(g_ctf)
3001                         ctf_setstatus();
3002
3003                 if(g_nexball)
3004                         nexball_setstatus();
3005
3006                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3007
3008                 //self.angles_y=self.v_angle_y + 90;   // temp
3009         } else if(gameover) {
3010                 if (intermission_running)
3011                         IntermissionThink ();   // otherwise a button could be missed between
3012                 return;
3013         } else if(self.classname == "observer") {
3014                 ObserverThink();
3015         } else if(self.classname == "spectator") {
3016                 SpectatorThink();
3017         }
3018
3019         if(!zoomstate_set)
3020                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3021
3022         float oldspectatee_status;
3023         oldspectatee_status = self.spectatee_status;
3024         if(self.classname == "spectator")
3025                 self.spectatee_status = num_for_edict(self.enemy);
3026         else if(self.classname == "observer")
3027                 self.spectatee_status = num_for_edict(self);
3028         else
3029                 self.spectatee_status = 0;
3030         if(self.spectatee_status != oldspectatee_status)
3031         {
3032                 ClientData_Touch(self);
3033                 if(g_race || g_cts)
3034                         race_InitSpectator();
3035         }
3036
3037         if(self.teamkill_soundtime)
3038         if(time > self.teamkill_soundtime)
3039         {
3040                 self.teamkill_soundtime = 0;
3041
3042                 entity oldpusher, oldself;
3043
3044                 oldself = self; self = self.teamkill_soundsource;
3045                 oldpusher = self.pusher; self.pusher = oldself;
3046
3047                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3048
3049                 self.pusher = oldpusher;
3050                 self = oldself;
3051         }
3052
3053         if(self.taunt_soundtime)
3054         if(time > self.taunt_soundtime)
3055         {
3056                 self.taunt_soundtime = 0;
3057                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3058         }
3059
3060         target_voicescript_next(self);
3061
3062         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3063         if(!self.weapon)
3064                 self.clip_load = self.clip_size = 0;
3065 }
3066
3067 float isInvisibleString(string s)
3068 {
3069         float i, n, c;
3070         s = strdecolorize(s);
3071         for((i = 0), (n = strlen(s)); i < n; ++i)
3072         {
3073                 c = str2chr(s, i);
3074                 switch(c)
3075                 {
3076                         case 0:
3077                         case 32: // space
3078                                 break;
3079                         case 192: // charmap space
3080                                 if (!autocvar_utf8_enable)
3081                                         break;
3082                                 return FALSE;
3083                         case 160: // space in unicode fonts
3084                         case 0xE000 + 192: // utf8 charmap space
3085                                 if (autocvar_utf8_enable)
3086                                         break;
3087                         default:
3088                                 return FALSE;
3089                 }
3090         }
3091         return TRUE;
3092 }
3093
3094 /*
3095 =============
3096 PlayerPostThink
3097
3098 Called every frame for each client after the physics are run
3099 =============
3100 */
3101 .float idlekick_lasttimeleft;
3102 .entity showheadshotbbox;
3103 void showheadshotbbox_think()
3104 {
3105         if(self.owner.showheadshotbbox != self)
3106         {
3107                 remove(self);
3108                 return;
3109         }
3110         self.nextthink = time;
3111         setorigin(self, self.owner.origin);
3112         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3113 }
3114 void PlayerPostThink (void)
3115 {
3116         // Savage: Check for nameless players
3117         if (isInvisibleString(self.netname)) {
3118                 self.netname = "Player";
3119                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3120         }
3121
3122         if(sv_maxidle && frametime)
3123         {
3124                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3125                 float timeleft;
3126                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3127                 {
3128                         if(self.idlekick_lasttimeleft)
3129                         {
3130                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3131                                 self.idlekick_lasttimeleft = 0;
3132                         }
3133                         return;
3134                 }
3135                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3136                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3137                 {
3138                         if(!self.idlekick_lasttimeleft)
3139                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3140                 }
3141                 if(timeleft <= 0)
3142                 {
3143                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3144                         AnnounceTo(self, "terminated");
3145                         dropclient(self);
3146                         return;
3147                 }
3148                 else if(timeleft <= 10)
3149                 {
3150                         if(timeleft != self.idlekick_lasttimeleft)
3151                                 AnnounceTo(self, ftos(timeleft));
3152                         self.idlekick_lasttimeleft = timeleft;
3153                 }
3154         }
3155
3156 #ifdef TETRIS
3157         if(self.impulse == 100)
3158                 ImpulseCommands();
3159         if (TetrisPostFrame())
3160                 return;
3161 #endif
3162
3163         CheatFrame();
3164
3165         if(self.classname == "player") {
3166                 CheckRules_Player();
3167                 UpdateChatBubble();
3168                 if (self.impulse)
3169                         ImpulseCommands();
3170                 if (intermission_running)
3171                         return;         // intermission or finale
3172                 GetPressedKeys();
3173         } else if (self.classname == "observer") {
3174                 //do nothing
3175         } else if (self.classname == "spectator") {
3176                 //do nothing
3177         }
3178
3179         /*
3180         float i;
3181         for(i = 0; i < 1000; ++i)
3182         {
3183                 vector end;
3184                 end = self.origin + '0 0 1024' + 512 * randomvec();
3185                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3186                 if(trace_fraction < 1)
3187                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3188                 {
3189                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3190                         break;
3191                 }
3192         }
3193         */
3194
3195         Arena_Warmup();
3196
3197         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3198
3199         if(self.waypointsprite_attachedforcarrier)
3200                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3201
3202         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3203         {
3204                 if(!self.showheadshotbbox)
3205                 {
3206                         self.showheadshotbbox = spawn();
3207                         self.showheadshotbbox.classname = "headshotbbox";
3208                         self.showheadshotbbox.owner = self;
3209                         self.showheadshotbbox.think = showheadshotbbox_think;
3210                         self.showheadshotbbox.nextthink = time;
3211                         self = self.showheadshotbbox;
3212                         self.think();
3213                         self = self.owner;
3214                 }
3215         }
3216         else
3217         {
3218                 if(self.showheadshotbbox)
3219                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3220                 remove(self.showheadshotbbox);
3221         }
3222
3223         playerdemo_write();
3224
3225         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3226         {
3227                 if(!self.stored_netname)
3228                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3229                 if(self.stored_netname != self.netname)
3230                 {
3231                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3232                         strunzone(self.stored_netname);
3233                         self.stored_netname = strzone(self.netname);
3234                 }
3235         }
3236
3237         /*
3238         if(g_race)
3239                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3240         */
3241 }