qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         Unfreeze(self);
 172
 173         if(self.alivetime)
 174         {
 175                 if(!warmup_stage)
 176                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 177                 self.alivetime = 0;
 178         }
 179
 180         if(self.vehicle)
 181                 vehicles_exit(VHEF_RELESE);
 182
 183         WaypointSprite_PlayerDead();
 184
 185         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 186                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 187
 188         if(self.killcount != -666)
 189         {
 190                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 191
 192                 if(self.just_joined == FALSE) {
 193                         LogTeamchange(self.playerid, -1, 4);
 194                 } else
 195                         self.just_joined = FALSE;
 196         }
 197
 198         PlayerScore_Clear(self); // clear scores when needed
 199
 200         accuracy_resend(self);
 201
 202         self.spectatortime = time;
 203
 204         self.classname = "observer";
 205         self.iscreature = FALSE;
 206         self.teleportable = TELEPORT_SIMPLE;
 207         self.damagedbycontents = FALSE;
 208         self.health = -666;
 209         self.takedamage = DAMAGE_NO;
 210         self.solid = SOLID_NOT;
 211         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 212         self.flags = FL_CLIENT | FL_NOTARGET;
 213         self.armorvalue = 666;
 214         self.effects = 0;
 215         self.armorvalue = autocvar_g_balance_armor_start;
 216         self.pauserotarmor_finished = 0;
 217         self.pauserothealth_finished = 0;
 218         self.pauseregen_finished = 0;
 219         self.damageforcescale = 0;
 220         self.death_time = 0;
 221         self.respawn_flags = 0;
 222         self.respawn_time = 0;
 223         self.stat_respawn_time = 0;
 224         self.alpha = 0;
 225         self.scale = 0;
 226         self.fade_time = 0;
 227         self.pain_frame = 0;
 228         self.pain_finished = 0;
 229         self.strength_finished = 0;
 230         self.invincible_finished = 0;
 231         self.superweapons_finished = 0;
 232         self.pushltime = 0;
 233         self.istypefrag = 0;
 234         self.think = func_null;
 235         self.nextthink = 0;
 236         self.hook_time = 0;
 237         self.deadflag = DEAD_NO;
 238         self.angles = spot.angles;
 239         self.angles_z = 0;
 240         self.fixangle = TRUE;
 241         self.crouch = FALSE;
 242
 243         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 244         self.prevorigin = self.origin;
 245         self.items = 0;
 246         self.weapons = '0 0 0';
 247         self.model = "";
 248         FixPlayermodel();
 249         setmodel(self, "null");
 250         self.drawonlytoclient = self;
 251
 252         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254
 255         self.weapon = 0;
 256         self.weaponname = "";
 257         self.switchingweapon = 0;
 258         self.weaponmodel = "";
 259         self.weaponentity = world;
 260         self.exteriorweaponentity = world;
 261         self.killcount = -666;
 262         self.velocity = '0 0 0';
 263         self.avelocity = '0 0 0';
 264         self.punchangle = '0 0 0';
 265         self.punchvector = '0 0 0';
 266         self.oldvelocity = self.velocity;
 267         self.fire_endtime = -1;
 268 }
 269
 270 .float model_randomizer;
 271 void FixPlayermodel()
 272 {
 273         string defaultmodel;
 274         float defaultskin, chmdl, oldskin, n, i;
 275         vector m1, m2;
 276
 277         defaultmodel = "";
 278         defaultskin = 0;
 279         chmdl = FALSE;
 280
 281         if(autocvar_sv_defaultcharacter == 1)
 282         {
 283                 if(teamplay)
 284                 {
 285                         string s;
 286                         s = Team_ColorName_Lower(self.team);
 287                         if(s != "neutral")
 288                         {
 289                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 290                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 291                         }
 292                 }
 293
 294                 if(defaultmodel == "")
 295                 {
 296                         defaultmodel = autocvar_sv_defaultplayermodel;
 297                         defaultskin = autocvar_sv_defaultplayerskin;
 298                 }
 299
 300                 n = tokenize_console(defaultmodel);
 301                 if(n > 0)
 302                 {
 303                         defaultmodel = argv(floor(n * self.model_randomizer));
 304                         // However, do NOT randomize if the player-selected model is in the list.
 305                         for (i = 0; i < n; ++i)
 306                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 307                                         defaultmodel = argv(i);
 308                 }
 309
 310                 i = strstrofs(defaultmodel, ":", 0);
 311                 if(i >= 0)
 312                 {
 313                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 314                         defaultmodel = substring(defaultmodel, 0, i);
 315                 }
 316         }
 317
 318         if(defaultmodel != "")
 319         {
 320                 if (defaultmodel != self.model)
 321                 {
 322                         m1 = self.mins;
 323                         m2 = self.maxs;
 324                         setplayermodel (self, defaultmodel);
 325                         setsize (self, m1, m2);
 326                         chmdl = TRUE;
 327                 }
 328
 329                 oldskin = self.skin;
 330                 self.skin = defaultskin;
 331         } else {
 332                 if (self.playermodel != self.model || self.playermodel == "")
 333                 {
 334                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 335                         m1 = self.mins;
 336                         m2 = self.maxs;
 337                         setplayermodel (self, self.playermodel);
 338                         setsize (self, m1, m2);
 339                         chmdl = TRUE;
 340                 }
 341
 342                 oldskin = self.skin;
 343                 self.skin = stof(self.playerskin);
 344         }
 345
 346         if(chmdl || oldskin != self.skin) // model or skin has changed
 347         {
 348                 self.species = player_getspecies(); // update species
 349                 UpdatePlayerSounds(); // update skin sounds
 350         }
 351
 352         if(!teamplay)
 353                 if(strlen(autocvar_sv_defaultplayercolors))
 354                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 355                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 356 }
 357
 358 /*
 359 =============
 360 PutClientInServer
 361
 362 Called when a client spawns in the server
 363 =============
 364 */
 365 void PutClientInServer (void)
 366 {
 367         if(IS_BOT_CLIENT(self))
 368                 self.classname = "player";
 369         else if(IS_REAL_CLIENT(self))
 370         {
 371                 msg_entity = self;
 372                 WriteByte(MSG_ONE, SVC_SETVIEW);
 373                 WriteEntity(MSG_ONE, self);
 374         }
 375
 376         // reset player keys
 377         self.itemkeys = 0;
 378
 379         MUTATOR_CALLHOOK(PutClientInServer);
 380
 381         if(gameover)
 382                 self.classname = "observer";
 383
 384         if(IS_PLAYER(self))
 385         {
 386                 entity spot, oldself;
 387                 float j;
 388
 389                 accuracy_resend(self);
 390
 391                 if(self.team < 0)
 392                         JoinBestTeam(self, FALSE, TRUE);
 393
 394                 race_PreSpawn();
 395
 396                 spot = SelectSpawnPoint (FALSE);
 397                 if(!spot)
 398                 {
 399                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 400                         return; // spawn failed
 401                 }
 402
 403                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 404
 405                 self.classname = "player";
 406                 self.wasplayer = TRUE;
 407                 self.iscreature = TRUE;
 408                 self.teleportable = TELEPORT_NORMAL;
 409                 self.damagedbycontents = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 413                 if(autocvar_g_playerclip_collisions)
 414                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 415                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 416                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 417                 self.frags = FRAGS_PLAYER;
 418                 if(INDEPENDENT_PLAYERS)
 419                         MAKE_INDEPENDENT_PLAYER(self);
 420                 self.flags = FL_CLIENT;
 421                 if(autocvar__notarget)
 422                         self.flags |= FL_NOTARGET;
 423                 self.takedamage = DAMAGE_AIM;
 424                 self.effects = 0;
 425                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 426                 self.air_finished = time + 12;
 427                 self.dmg = 2;
 428                 if(autocvar_g_balance_nex_charge)
 429                 {
 430                         if(autocvar_g_balance_nex_secondary_chargepool)
 431                                 self.nex_chargepool_ammo = 1;
 432                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 433                 }
 434
 435                 if(warmup_stage)
 436                 {
 437                         self.ammo_shells = warmup_start_ammo_shells;
 438                         self.ammo_nails = warmup_start_ammo_nails;
 439                         self.ammo_rockets = warmup_start_ammo_rockets;
 440                         self.ammo_cells = warmup_start_ammo_cells;
 441                         self.ammo_fuel = warmup_start_ammo_fuel;
 442                         self.health = warmup_start_health;
 443                         self.armorvalue = warmup_start_armorvalue;
 444                         self.weapons = warmup_start_weapons;
 445                 }
 446                 else
 447                 {
 448                         self.ammo_shells = start_ammo_shells;
 449                         self.ammo_nails = start_ammo_nails;
 450                         self.ammo_rockets = start_ammo_rockets;
 451                         self.ammo_cells = start_ammo_cells;
 452                         self.ammo_fuel = start_ammo_fuel;
 453                         self.health = start_health;
 454                         self.armorvalue = start_armorvalue;
 455                         self.weapons = start_weapons;
 456                 }
 457
 458                 if(self.weapons & WEPSET_SUPERWEAPONS)
 459                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 460                 else
 461                         self.superweapons_finished = 0;
 462
 463                 if(g_weaponarena_random)
 464                 {
 465                         if(g_weaponarena_random_with_laser)
 466                                 self.weapons &= ~WEPSET_LASER;
 467                         W_RandomWeapons(self, g_weaponarena_random);
 468                         if(g_weaponarena_random_with_laser)
 469                                 self.weapons |= WEPSET_LASER;
 470                 }
 471
 472                 self.items = start_items;
 473
 474                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 475                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 476                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 477                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 478                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 479                 //extend the pause of rotting if client was reset at the beginning of the countdown
 480                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 481                         self.spawnshieldtime += game_starttime - time;
 482                         self.pauserotarmor_finished += game_starttime - time;
 483                         self.pauserothealth_finished += game_starttime - time;
 484                         self.pauseregen_finished += game_starttime - time;
 485                 }
 486                 self.damageforcescale = 2;
 487                 self.death_time = 0;
 488                 self.respawn_flags = 0;
 489                 self.respawn_time = 0;
 490                 self.stat_respawn_time = 0;
 491                 self.scale = 0;
 492                 self.fade_time = 0;
 493                 self.pain_frame = 0;
 494                 self.pain_finished = 0;
 495                 self.strength_finished = 0;
 496                 self.invincible_finished = 0;
 497                 self.pushltime = 0;
 498                 // players have no think function
 499                 self.think = func_null;
 500                 self.nextthink = 0;
 501                 self.hook_time = 0;
 502                 self.dmg_team = 0;
 503                 self.ballistics_density = autocvar_g_ballistics_density_player;
 504
 505                 self.metertime = 0;
 506
 507                 self.deadflag = DEAD_NO;
 508
 509                 self.angles = spot.angles;
 510
 511                 self.angles_z = 0; // never spawn tilted even if the spot says to
 512                 self.fixangle = TRUE; // turn this way immediately
 513                 self.velocity = '0 0 0';
 514                 self.avelocity = '0 0 0';
 515                 self.punchangle = '0 0 0';
 516                 self.punchvector = '0 0 0';
 517                 self.oldvelocity = self.velocity;
 518                 self.fire_endtime = -1;
 519
 520                 entity spawnevent = spawn();
 521                 spawnevent.owner = self;
 522                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 523
 524                 self.model = "";
 525                 FixPlayermodel();
 526                 self.drawonlytoclient = world;
 527
 528                 self.crouch = FALSE;
 529                 self.view_ofs = PL_VIEW_OFS;
 530                 setsize (self, PL_MIN, PL_MAX);
 531                 self.spawnorigin = spot.origin;
 532                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 533                 // don't reset back to last position, even if new position is stuck in solid
 534                 self.oldorigin = self.origin;
 535                 self.prevorigin = self.origin;
 536                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 537                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 538         self.hud = HUD_NORMAL;
 539
 540                 self.event_damage = PlayerDamage;
 541
 542                 self.bot_attack = TRUE;
 543                 self.monster_attack = TRUE;
 544
 545                 self.statdraintime = time + 5;
 546                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 547
 548                 if(self.killcount == -666) {
 549                         PlayerScore_Clear(self);
 550                         self.killcount = 0;
 551                 }
 552
 553                 CL_SpawnWeaponentity();
 554                 self.alpha = default_player_alpha;
 555                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 556                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 557
 558                 self.speedrunning = FALSE;
 559
 560                 race_PostSpawn(spot);
 561
 562                 //stuffcmd(self, "chase_active 0");
 563                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 564
 565                 target_voicescript_clear(self);
 566
 567                 // reset fields the weapons may use
 568                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 569                 {
 570                         weapon_action(j, WR_RESETPLAYER);
 571
 572                         // all weapons must be fully loaded when we spawn
 573                         entity e;
 574                         e = get_weaponinfo(j);
 575                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 576                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 577                 }
 578
 579                 oldself = self;
 580                 self = spot;
 581                         activator = oldself;
 582                                 string s;
 583                                 s = self.target;
 584                                 self.target = string_null;
 585                                 SUB_UseTargets();
 586                                 self.target = s;
 587                         activator = world;
 588                 self = oldself;
 589
 590                 Unfreeze(self);
 591
 592                 spawn_spot = spot;
 593                 MUTATOR_CALLHOOK(PlayerSpawn);
 594
 595                 if(autocvar_spawn_debug)
 596                 {
 597                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 598                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 599                 }
 600
 601                 self.switchweapon = w_getbestweapon(self);
 602                 self.cnt = -1; // W_LastWeapon will not complain
 603                 self.weapon = 0;
 604                 self.weaponname = "";
 605                 self.switchingweapon = 0;
 606
 607                 if(!warmup_stage)
 608                         if(!self.alivetime)
 609                                 self.alivetime = time;
 610
 611                 antilag_clear(self);
 612         }
 613         else if(IS_OBSERVER(self))
 614         {
 615                 PutObserverInServer ();
 616         }
 617 }
 618
 619 .float ebouncefactor, ebouncestop; // electro's values
 620 // TODO do we need all these fields, or should we stop autodetecting runtime
 621 // changes and just have a console command to update this?
 622 float ClientInit_SendEntity(entity to, float sf)
 623 {
 624         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 625         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 638         if(sv_foginterval && world.fog != "")
 639                 WriteString(MSG_ENTITY, world.fog);
 640         else
 641                 WriteString(MSG_ENTITY, "");
 642         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 643         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 644         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 645         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 646         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 647         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 649         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 650         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 651         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 652         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 653         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 654         return TRUE;
 655 }
 656
 657 void ClientInit_CheckUpdate()
 658 {
 659         self.nextthink = time;
 660         if(self.count != autocvar_g_balance_armor_blockpercent)
 661         {
 662                 self.count = autocvar_g_balance_armor_blockpercent;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 666         {
 667                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 671         {
 672                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 673                 self.SendFlags |= 1;
 674         }
 675         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 676         {
 677                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 678                 self.SendFlags |= 1;
 679         }
 680         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 681         {
 682                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 683                 self.SendFlags |= 1;
 684         }
 685 }
 686
 687 void ClientInit_Spawn()
 688 {
 689         entity o;
 690         entity e;
 691         e = spawn();
 692         e.classname = "clientinit";
 693         e.think = ClientInit_CheckUpdate;
 694         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 695
 696         o = self;
 697         self = e;
 698         ClientInit_CheckUpdate();
 699         self = o;
 700 }
 701
 702 /*
 703 =============
 704 SetNewParms
 705 =============
 706 */
 707 void SetNewParms (void)
 708 {
 709         // initialize parms for a new player
 710         parm1 = -(86400 * 366);
 711 }
 712
 713 /*
 714 =============
 715 SetChangeParms
 716 =============
 717 */
 718 void SetChangeParms (void)
 719 {
 720         // save parms for level change
 721         parm1 = self.parm_idlesince - time;
 722 }
 723
 724 /*
 725 =============
 726 DecodeLevelParms
 727 =============
 728 */
 729 void DecodeLevelParms (void)
 730 {
 731         // load parms
 732         self.parm_idlesince = parm1;
 733         if(self.parm_idlesince == -(86400 * 366))
 734                 self.parm_idlesince = time;
 735
 736         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 737         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 738 }
 739
 740 /*
 741 =============
 742 ClientKill
 743
 744 Called when a client types 'kill' in the console
 745 =============
 746 */
 747
 748 .float clientkill_nexttime;
 749 void ClientKill_Now_TeamChange()
 750 {
 751         if(self.killindicator_teamchange == -1)
 752         {
 753                 JoinBestTeam( self, FALSE, TRUE );
 754         }
 755         else if(self.killindicator_teamchange == -2)
 756         {
 757                 if(blockSpectators)
 758                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 759                 PutObserverInServer();
 760         }
 761         else
 762                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 763         self.killindicator_teamchange = 0;
 764 }
 765
 766 void ClientKill_Now()
 767 {
 768         if(self.vehicle)
 769         {
 770             vehicles_exit(VHEF_RELESE);
 771             if(!self.killindicator_teamchange)
 772             {
 773             self.vehicle_health = -1;
 774             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 775             }
 776         }
 777
 778         if(self.killindicator && !wasfreed(self.killindicator))
 779                 remove(self.killindicator);
 780
 781         self.killindicator = world;
 782
 783         if(self.killindicator_teamchange)
 784                 ClientKill_Now_TeamChange();
 785
 786         // in any case:
 787         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 788
 789         // now I am sure the player IS dead
 790 }
 791 void KillIndicator_Think()
 792 {
 793         if (gameover)
 794         {
 795                 self.owner.killindicator = world;
 796                 remove(self);
 797                 return;
 798         }
 799
 800         if (self.owner.alpha < 0 && !self.owner.vehicle)
 801         {
 802                 self.owner.killindicator = world;
 803                 remove(self);
 804                 return;
 805         }
 806
 807         if(self.cnt <= 0)
 808         {
 809                 self = self.owner;
 810                 ClientKill_Now(); // no oldself needed
 811                 return;
 812         }
 813     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 814     {
 815         self.nextthink = time + 1;
 816         self.cnt -= 1;
 817     }
 818         else
 819         {
 820                 if(self.cnt <= 10)
 821                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 822                 if(IS_REAL_CLIENT(self.owner))
 823                 {
 824                         if(self.cnt <= 10)
 825                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 826                 }
 827                 self.nextthink = time + 1;
 828                 self.cnt -= 1;
 829         }
 830 }
 831
 832 float clientkilltime;
 833 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 834 {
 835         float killtime;
 836         float starttime;
 837         entity e;
 838
 839         if (gameover)
 840                 return;
 841
 842         killtime = autocvar_g_balance_kill_delay;
 843
 844         if(g_race_qualifying || g_cts)
 845                 killtime = 0;
 846
 847     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 848     {
 849                 remove(self.killindicator);
 850                 self.killindicator = world;
 851
 852         ClientKill_Now(); // allow instant kill in this case
 853         return;
 854     }
 855
 856         self.killindicator_teamchange = targetteam;
 857
 858     if(!self.killindicator)
 859         {
 860                 if(self.deadflag == DEAD_NO)
 861                 {
 862                         killtime = max(killtime, self.clientkill_nexttime - time);
 863                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 864                 }
 865
 866                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 867                 {
 868                         ClientKill_Now();
 869                 }
 870                 else
 871                 {
 872                         starttime = max(time, clientkilltime);
 873
 874                         self.killindicator = spawn();
 875                         self.killindicator.owner = self;
 876                         self.killindicator.scale = 0.5;
 877                         setattachment(self.killindicator, self, "");
 878                         setorigin(self.killindicator, '0 0 52');
 879                         self.killindicator.think = KillIndicator_Think;
 880                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 881                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 882                         self.killindicator.cnt = ceil(killtime);
 883                         self.killindicator.count = bound(0, ceil(killtime), 10);
 884                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 885
 886                         for(e = world; (e = find(e, classname, "body")) != world; )
 887                         {
 888                                 if(e.enemy != self)
 889                                         continue;
 890                                 e.killindicator = spawn();
 891                                 e.killindicator.owner = e;
 892                                 e.killindicator.scale = 0.5;
 893                                 setattachment(e.killindicator, e, "");
 894                                 setorigin(e.killindicator, '0 0 52');
 895                                 e.killindicator.think = KillIndicator_Think;
 896                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 897                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 898                                 e.killindicator.cnt = ceil(killtime);
 899                         }
 900                         self.lip = 0;
 901                 }
 902         }
 903         if(self.killindicator)
 904         {
 905                 if(targetteam == 0) // just die
 906                 {
 907                         self.killindicator.colormod = '0 0 0';
 908                         if(IS_REAL_CLIENT(self))
 909                         if(self.killindicator.cnt > 0)
 910                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 911                 }
 912                 else if(targetteam == -1) // auto
 913                 {
 914                         self.killindicator.colormod = '0 1 0';
 915                         if(IS_REAL_CLIENT(self))
 916                         if(self.killindicator.cnt > 0)
 917                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 918                 }
 919                 else if(targetteam == -2) // spectate
 920                 {
 921                         self.killindicator.colormod = '0.5 0.5 0.5';
 922                         if(IS_REAL_CLIENT(self))
 923                         if(self.killindicator.cnt > 0)
 924                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 925                 }
 926                 else
 927                 {
 928                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 929                         if(IS_REAL_CLIENT(self))
 930                         if(self.killindicator.cnt > 0)
 931                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 932                 }
 933         }
 934
 935 }
 936
 937 void ClientKill (void)
 938 {
 939         if(gameover) return;
 940         if(self.player_blocked) return;
 941         if(self.frozen) return;
 942
 943         ClientKill_TeamChange(0);
 944 }
 945
 946 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 947 {
 948     e.killindicator = spawn();
 949     e.killindicator.owner = e;
 950     e.killindicator.think = KillIndicator_Think;
 951     e.killindicator.nextthink = time + (e.lip) * 0.05;
 952     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 953     e.killindicator.health = 1; // this is used to indicate that it should be silent
 954     e.lip = 0;
 955 }
 956
 957 void FixClientCvars(entity e)
 958 {
 959         // send prediction settings to the client
 960         stuffcmd(e, "\nin_bindmap 0 0\n");
 961         if(g_race || g_cts)
 962                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 963         if(autocvar_g_antilag == 3) // client side hitscan
 964                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 965         if(autocvar_sv_gentle)
 966                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 967         /*
 968          * we no longer need to stuff this. Remove this comment block if you feel
 969          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 970         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 971         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 972         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 973         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 974         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 975         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 976         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 978         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 979         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 982         stuffcmd(e, "cl_movement_edgefriction 1\n");
 983          */
 984 }
 985
 986 float PlayerInIDList(entity p, string idlist)
 987 {
 988         float n, i;
 989         string s;
 990
 991         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 992         if not(p.crypto_idfp)
 993                 return 0;
 994
 995         // this function allows abbreviated player IDs too!
 996         n = tokenize_console(idlist);
 997         for(i = 0; i < n; ++i)
 998         {
 999                 s = argv(i);
1000                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1001                         return 1;
1002         }
1003
1004         return 0;
1005 }
1006
1007 /*
1008 =============
1009 ClientConnect
1010
1011 Called when a client connects to the server
1012 =============
1013 */
1014 void DecodeLevelParms (void);
1015 //void dom_player_join_team(entity pl);
1016 void set_dom_state(entity e);
1017 void ClientConnect (void)
1018 {
1019         float t;
1020
1021         if(IS_CLIENT(self))
1022         {
1023                 print("Warning: ClientConnect, but already connected!\n");
1024                 return;
1025         }
1026
1027         if(Ban_MaybeEnforceBanOnce(self))
1028                 return;
1029
1030         DecodeLevelParms();
1031
1032 #ifdef WATERMARK
1033         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1034 #endif
1035
1036         self.classname = "player_joining";
1037
1038         self.flags = FL_CLIENT;
1039         self.version_nagtime = time + 10 + random() * 10;
1040
1041         if(player_count<0)
1042         {
1043                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1044                 player_count = 0;
1045         }
1046
1047         PlayerScore_Attach(self);
1048         ClientData_Attach();
1049         accuracy_init(self);
1050
1051         bot_clientconnect();
1052
1053         playerdemo_init();
1054
1055         anticheat_init();
1056
1057         race_PreSpawnObserver();
1058
1059         // identify the right forced team
1060         if(autocvar_g_campaign)
1061         {
1062                 if(IS_REAL_CLIENT(self)) // only players, not bots
1063                 {
1064                         switch(autocvar_g_campaign_forceteam)
1065                         {
1066                                 case 1: self.team_forced = NUM_TEAM_1; break;
1067                                 case 2: self.team_forced = NUM_TEAM_2; break;
1068                                 case 3: self.team_forced = NUM_TEAM_3; break;
1069                                 case 4: self.team_forced = NUM_TEAM_4; break;
1070                                 default: self.team_forced = 0;
1071                         }
1072                 }
1073         }
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1075                 self.team_forced = NUM_TEAM_1;
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1077                 self.team_forced = NUM_TEAM_2;
1078         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1079                 self.team_forced = NUM_TEAM_3;
1080         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1081                 self.team_forced = NUM_TEAM_4;
1082         else if(autocvar_g_forced_team_otherwise == "red")
1083                 self.team_forced = NUM_TEAM_1;
1084         else if(autocvar_g_forced_team_otherwise == "blue")
1085                 self.team_forced = NUM_TEAM_2;
1086         else if(autocvar_g_forced_team_otherwise == "yellow")
1087                 self.team_forced = NUM_TEAM_3;
1088         else if(autocvar_g_forced_team_otherwise == "pink")
1089                 self.team_forced = NUM_TEAM_4;
1090         else if(autocvar_g_forced_team_otherwise == "spectate")
1091                 self.team_forced = -1;
1092         else if(autocvar_g_forced_team_otherwise == "spectator")
1093                 self.team_forced = -1;
1094         else
1095                 self.team_forced = 0;
1096
1097         if(!teamplay)
1098                 if(self.team_forced > 0)
1099                         self.team_forced = 0;
1100
1101         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1102
1103         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1104                 self.classname = "observer";
1105         } else {
1106                 if(teamplay)
1107                 {
1108                         if(autocvar_g_balance_teams)
1109                         {
1110                                 self.classname = "player";
1111                                 campaign_bots_may_start = 1;
1112                         }
1113                         else
1114                         {
1115                                 self.classname = "observer"; // do it anyway
1116                         }
1117                 }
1118                 else
1119                 {
1120                         self.classname = "player";
1121                         campaign_bots_may_start = 1;
1122                 }
1123         }
1124
1125         self.playerid = (playerid_last = playerid_last + 1);
1126
1127         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1128
1129     if(IS_BOT_CLIENT(self))
1130         PlayerStats_AddPlayer(self);
1131
1132         if(autocvar_sv_eventlog)
1133                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1134
1135         LogTeamchange(self.playerid, self.team, 1);
1136
1137         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1138
1139         self.netname_previous = strzone(self.netname);
1140
1141         if(IS_PLAYER(self) && teamplay)
1142                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1143         else
1144                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1145
1146         stuffcmd(self, strcat(clientstuff, "\n"));
1147         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1148
1149         FixClientCvars(self);
1150
1151         // spawnfunc_waypoint sprites
1152         WaypointSprite_InitClient(self);
1153
1154         // Wazat's grappling hook
1155         SetGrappleHookBindings();
1156
1157         // get version info from player
1158         stuffcmd(self, "cmd clientversion $gameversion\n");
1159
1160         // get other cvars from player
1161         GetCvars(0);
1162
1163         // notify about available teams
1164         if(teamplay)
1165         {
1166                 CheckAllowedTeams(self);
1167                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1168                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1169         }
1170         else
1171                 stuffcmd(self, "set _teams_available 0\n");
1172
1173         attach_entcs();
1174
1175         bot_relinkplayerlist();
1176
1177         self.spectatortime = time;
1178         if(blockSpectators)
1179         {
1180                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1181         }
1182
1183         self.jointime = time;
1184         self.allowed_timeouts = autocvar_sv_timeout_number;
1185
1186         if(IS_REAL_CLIENT(self))
1187         {
1188                 if(!autocvar_g_campaign)
1189                 {
1190                         self.motd_actived_time = -1;
1191                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1192                 }
1193
1194                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1195                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1196         }
1197
1198         if(!sv_foginterval && world.fog != "")
1199                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1200
1201         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1202         {
1203                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1204                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1205         }
1206         else
1207                 self.hitplotfh = -1;
1208
1209         if(g_race || g_cts) {
1210                 string rr;
1211                 if(g_cts)
1212                         rr = CTS_RECORD;
1213                 else
1214                         rr = RACE_RECORD;
1215
1216                 msg_entity = self;
1217                 race_send_recordtime(MSG_ONE);
1218                 race_send_speedaward(MSG_ONE);
1219
1220                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1221                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1222                 race_send_speedaward_alltimebest(MSG_ONE);
1223
1224                 float i;
1225                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1226                         race_SendRankings(i, 0, 0, MSG_ONE);
1227                 }
1228         }
1229         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1230                 send_CSQC_teamnagger();
1231
1232         CheatInitClient();
1233
1234         CSQCMODEL_AUTOINIT();
1235
1236         self.model_randomizer = random();
1237
1238         if(IS_REAL_CLIENT(self))
1239                 sv_notice_join();
1240
1241         MUTATOR_CALLHOOK(ClientConnect);
1242 }
1243 /*
1244 =============
1245 ClientDisconnect
1246
1247 Called when a client disconnects from the server
1248 =============
1249 */
1250 .entity chatbubbleentity;
1251 void ReadyCount();
1252 void ClientDisconnect (void)
1253 {
1254         if(self.vehicle)
1255             vehicles_exit(VHEF_RELESE);
1256
1257         if not(IS_CLIENT(self))
1258         {
1259                 print("Warning: ClientDisconnect without ClientConnect\n");
1260                 return;
1261         }
1262
1263         PlayerStats_AddGlobalInfo(self);
1264
1265         CheatShutdownClient();
1266
1267         if(self.hitplotfh >= 0)
1268         {
1269                 fclose(self.hitplotfh);
1270                 self.hitplotfh = -1;
1271         }
1272
1273         anticheat_report();
1274         anticheat_shutdown();
1275
1276         playerdemo_shutdown();
1277
1278         bot_clientdisconnect();
1279
1280         if(self.entcs)
1281                 detach_entcs();
1282
1283         if(autocvar_sv_eventlog)
1284                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1285
1286         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1287
1288         MUTATOR_CALLHOOK(ClientDisconnect);
1289
1290         Portal_ClearAll(self);
1291
1292         Unfreeze(self);
1293
1294         RemoveGrapplingHook(self);
1295
1296         // Here, everything has been done that requires this player to be a client.
1297
1298         self.flags &= ~FL_CLIENT;
1299
1300         if (self.chatbubbleentity)
1301                 remove (self.chatbubbleentity);
1302
1303         if (self.killindicator)
1304                 remove (self.killindicator);
1305
1306         WaypointSprite_PlayerGone();
1307
1308         bot_relinkplayerlist();
1309
1310         accuracy_free(self);
1311         ClientData_Detach();
1312         PlayerScore_Detach(self);
1313
1314         if(self.netname_previous)
1315                 strunzone(self.netname_previous);
1316         if(self.clientstatus)
1317                 strunzone(self.clientstatus);
1318         if(self.weaponorder_byimpulse)
1319                 strunzone(self.weaponorder_byimpulse);
1320
1321         ClearPlayerSounds();
1322
1323         if(self.personal)
1324                 remove(self.personal);
1325
1326         self.playerid = 0;
1327         ReadyCount();
1328
1329         // free cvars
1330         GetCvars(-1);
1331 }
1332
1333 .float BUTTON_CHAT;
1334 void ChatBubbleThink()
1335 {
1336         self.nextthink = time;
1337         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1338         {
1339                 if(self.owner) // but why can that ever be world?
1340                         self.owner.chatbubbleentity = world;
1341                 remove(self);
1342                 return;
1343         }
1344         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1345 #ifdef TETRIS
1346                 || self.owner.tetris_on
1347 #endif
1348         )
1349                 self.model = self.mdl;
1350         else
1351                 self.model = "";
1352 }
1353
1354 void UpdateChatBubble()
1355 {
1356         if (self.alpha < 0)
1357                 return;
1358         // spawn a chatbubble entity if needed
1359         if (!self.chatbubbleentity)
1360         {
1361                 self.chatbubbleentity = spawn();
1362                 self.chatbubbleentity.owner = self;
1363                 self.chatbubbleentity.exteriormodeltoclient = self;
1364                 self.chatbubbleentity.think = ChatBubbleThink;
1365                 self.chatbubbleentity.nextthink = time;
1366                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1367                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1368                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1369                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1370                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1371                 self.chatbubbleentity.model = "";
1372                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1373         }
1374 }
1375
1376
1377 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1378 // added to the model skins
1379 /*void UpdateColorModHack()
1380 {
1381         float c;
1382         c = self.clientcolors & 15;
1383         // LordHavoc: only bothering to support white, green, red, yellow, blue
1384              if (!teamplay) self.colormod = '0 0 0';
1385         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1386         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1387         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1388         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1389         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1390         else self.colormod = '1 1 1';
1391 }*/
1392
1393 void respawn(void)
1394 {
1395         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1396         {
1397                 self.solid = SOLID_NOT;
1398                 self.takedamage = DAMAGE_NO;
1399                 self.movetype = MOVETYPE_FLY;
1400                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1401                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1402                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1403                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1404                 if(autocvar_g_respawn_ghosts_maxtime)
1405                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1406         }
1407
1408         CopyBody(1);
1409
1410         self.effects |= EF_NODRAW; // prevent another CopyBody
1411         PutClientInServer();
1412 }
1413
1414 void play_countdown(float finished, string samp)
1415 {
1416         if(IS_REAL_CLIENT(self))
1417                 if(floor(finished - time - frametime) != floor(finished - time))
1418                         if(finished - time < 6)
1419                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1420 }
1421
1422 void player_powerups (void)
1423 {
1424         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1425         olditems = self.items;
1426
1427         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1428                 self.modelflags |= MF_ROCKET;
1429         else
1430                 self.modelflags &= ~MF_ROCKET;
1431
1432         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1433
1434         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1435                 return;
1436
1437         Fire_ApplyDamage(self);
1438         Fire_ApplyEffect(self);
1439
1440         if not(g_minstagib)
1441         {
1442                 if (self.items & IT_STRENGTH)
1443                 {
1444                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1445                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1446                         if (time > self.strength_finished)
1447                         {
1448                                 self.items = self.items - (self.items & IT_STRENGTH);
1449                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1450                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1451                         }
1452                 }
1453                 else
1454                 {
1455                         if (time < self.strength_finished)
1456                         {
1457                                 self.items = self.items | IT_STRENGTH;
1458                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1459                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1460                         }
1461                 }
1462                 if (self.items & IT_INVINCIBLE)
1463                 {
1464                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1465                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1466                         if (time > self.invincible_finished)
1467                         {
1468                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1469                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1470                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1471                         }
1472                 }
1473                 else
1474                 {
1475                         if (time < self.invincible_finished)
1476                         {
1477                                 self.items = self.items | IT_INVINCIBLE;
1478                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1479                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1480                         }
1481                 }
1482                 if (self.items & IT_SUPERWEAPON)
1483                 {
1484                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1485                         {
1486                                 self.superweapons_finished = 0;
1487                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1488                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1489                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1490                         }
1491                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1492                         {
1493                                 // don't let them run out
1494                         }
1495                         else
1496                         {
1497                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1498                                 if (time > self.superweapons_finished)
1499                                 {
1500                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1501                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1502                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1503                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1504                                 }
1505                         }
1506                 }
1507                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1508                 {
1509                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1510                         {
1511                                 self.items = self.items | IT_SUPERWEAPON;
1512                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1513                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1514                         }
1515                         else
1516                         {
1517                                 self.superweapons_finished = 0;
1518                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1519                         }
1520                 }
1521                 else
1522                 {
1523                         self.superweapons_finished = 0;
1524                 }
1525         }
1526
1527         if(autocvar_g_nodepthtestplayers)
1528                 self.effects = self.effects | EF_NODEPTHTEST;
1529
1530         if(autocvar_g_fullbrightplayers)
1531                 self.effects = self.effects | EF_FULLBRIGHT;
1532
1533         if (time >= game_starttime)
1534         if (time < self.spawnshieldtime)
1535                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1536
1537         MUTATOR_CALLHOOK(PlayerPowerups);
1538 }
1539
1540 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1541 {
1542         if(current > stable)
1543                 return current;
1544         else if(current > stable - 0.25) // when close enough, "snap"
1545                 return stable;
1546         else
1547                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1548 }
1549
1550 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1551 {
1552         if(current < stable)
1553                 return current;
1554         else if(current < stable + 0.25) // when close enough, "snap"
1555                 return stable;
1556         else
1557                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1558 }
1559
1560 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1561 {
1562         if(current > rotstable)
1563         {
1564                 if(rotframetime > 0)
1565                 {
1566                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1567                         current = max(rotstable, current - rotlinear * rotframetime);
1568                 }
1569         }
1570         else if(current < regenstable)
1571         {
1572                 if(regenframetime > 0)
1573                 {
1574                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1575                         current = min(regenstable, current + regenlinear * regenframetime);
1576                 }
1577         }
1578
1579         if(current > limit)
1580                 current = limit;
1581
1582         return current;
1583 }
1584
1585 void player_regen (void)
1586 {
1587         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1588         maxh = autocvar_g_balance_health_rotstable;
1589         maxa = autocvar_g_balance_armor_rotstable;
1590         maxf = autocvar_g_balance_fuel_rotstable;
1591         minh = autocvar_g_balance_health_regenstable;
1592         mina = autocvar_g_balance_armor_regenstable;
1593         minf = autocvar_g_balance_fuel_regenstable;
1594         limith = autocvar_g_balance_health_limit;
1595         limita = autocvar_g_balance_armor_limit;
1596         limitf = autocvar_g_balance_fuel_limit;
1597
1598         max_mod = regen_mod = rot_mod = limit_mod = 1;
1599
1600         maxh = maxh * max_mod;
1601         //maxa = maxa * max_mod;
1602         //maxf = maxf * max_mod;
1603         minh = minh * max_mod;
1604         //mina = mina * max_mod;
1605         //minf = minf * max_mod;
1606         limith = limith * limit_mod;
1607         limita = limita * limit_mod;
1608         //limitf = limitf * limit_mod;
1609
1610         if(g_ca)
1611                 rot_mod = 0;
1612
1613         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1614         {
1615                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1616                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1617
1618                 // if player rotted to death...  die!
1619                 if(self.health < 1)
1620                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1621         }
1622
1623         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1624                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1625 }
1626
1627 float zoomstate_set;
1628 void SetZoomState(float z)
1629 {
1630         if(z != self.zoomstate)
1631         {
1632                 self.zoomstate = z;
1633                 ClientData_Touch(self);
1634         }
1635         zoomstate_set = 1;
1636 }
1637
1638 void GetPressedKeys(void) {
1639         MUTATOR_CALLHOOK(GetPressedKeys);
1640         if (self.movement_x > 0) // get if movement keys are pressed
1641         {       // forward key pressed
1642                 self.pressedkeys |= KEY_FORWARD;
1643                 self.pressedkeys &= ~KEY_BACKWARD;
1644         }
1645         else if (self.movement_x < 0)
1646         {       // backward key pressed
1647                 self.pressedkeys |= KEY_BACKWARD;
1648                 self.pressedkeys &= ~KEY_FORWARD;
1649         }
1650         else
1651         {       // no x input
1652                 self.pressedkeys &= ~KEY_FORWARD;
1653                 self.pressedkeys &= ~KEY_BACKWARD;
1654         }
1655
1656         if (self.movement_y > 0)
1657         {       // right key pressed
1658                 self.pressedkeys |= KEY_RIGHT;
1659                 self.pressedkeys &= ~KEY_LEFT;
1660         }
1661         else if (self.movement_y < 0)
1662         {       // left key pressed
1663                 self.pressedkeys |= KEY_LEFT;
1664                 self.pressedkeys &= ~KEY_RIGHT;
1665         }
1666         else
1667         {       // no y input
1668                 self.pressedkeys &= ~KEY_RIGHT;
1669                 self.pressedkeys &= ~KEY_LEFT;
1670         }
1671
1672         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1673                 self.pressedkeys |= KEY_JUMP;
1674         else
1675                 self.pressedkeys &= ~KEY_JUMP;
1676         if (self.BUTTON_CROUCH)
1677                 self.pressedkeys |= KEY_CROUCH;
1678         else
1679                 self.pressedkeys &= ~KEY_CROUCH;
1680
1681         if (self.BUTTON_ATCK)
1682                 self.pressedkeys |= KEY_ATCK;
1683         else
1684                 self.pressedkeys &= ~KEY_ATCK;
1685         if (self.BUTTON_ATCK2)
1686                 self.pressedkeys |= KEY_ATCK2;
1687         else
1688                 self.pressedkeys &= ~KEY_ATCK2;
1689 }
1690
1691 /*
1692 ======================
1693 spectate mode routines
1694 ======================
1695 */
1696
1697 void SpectateCopy(entity spectatee) {
1698         other = spectatee;
1699         MUTATOR_CALLHOOK(SpectateCopy);
1700         self.armortype = spectatee.armortype;
1701         self.armorvalue = spectatee.armorvalue;
1702         self.ammo_cells = spectatee.ammo_cells;
1703         self.ammo_shells = spectatee.ammo_shells;
1704         self.ammo_nails = spectatee.ammo_nails;
1705         self.ammo_rockets = spectatee.ammo_rockets;
1706         self.ammo_fuel = spectatee.ammo_fuel;
1707         self.clip_load = spectatee.clip_load;
1708         self.clip_size = spectatee.clip_size;
1709         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1710         self.health = spectatee.health;
1711         self.impulse = 0;
1712         self.items = spectatee.items;
1713         self.last_pickup = spectatee.last_pickup;
1714         self.hit_time = spectatee.hit_time;
1715         self.metertime = spectatee.metertime;
1716         self.strength_finished = spectatee.strength_finished;
1717         self.invincible_finished = spectatee.invincible_finished;
1718         self.pressedkeys = spectatee.pressedkeys;
1719         self.weapons = spectatee.weapons;
1720         self.switchweapon = spectatee.switchweapon;
1721         self.switchingweapon = spectatee.switchingweapon;
1722         self.weapon = spectatee.weapon;
1723         self.nex_charge = spectatee.nex_charge;
1724         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1725         self.hagar_load = spectatee.hagar_load;
1726         self.minelayer_mines = spectatee.minelayer_mines;
1727         self.punchangle = spectatee.punchangle;
1728         self.view_ofs = spectatee.view_ofs;
1729         self.velocity = spectatee.velocity;
1730         self.dmg_take = spectatee.dmg_take;
1731         self.dmg_save = spectatee.dmg_save;
1732         self.dmg_inflictor = spectatee.dmg_inflictor;
1733         self.v_angle = spectatee.v_angle;
1734         self.angles = spectatee.v_angle;
1735         self.frozen = spectatee.frozen;
1736         self.revive_progress = spectatee.revive_progress;
1737         if(!self.BUTTON_USE)
1738                 self.fixangle = TRUE;
1739         setorigin(self, spectatee.origin);
1740         setsize(self, spectatee.mins, spectatee.maxs);
1741         SetZoomState(spectatee.zoomstate);
1742
1743     anticheat_spectatecopy(spectatee);
1744         self.hud = spectatee.hud;
1745         if(spectatee.vehicle)
1746     {
1747         self.fixangle = FALSE;
1748         //self.velocity = spectatee.vehicle.velocity;
1749         self.vehicle_health = spectatee.vehicle_health;
1750         self.vehicle_shield = spectatee.vehicle_shield;
1751         self.vehicle_energy = spectatee.vehicle_energy;
1752         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1753         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1754         self.vehicle_reload1 = spectatee.vehicle_reload1;
1755         self.vehicle_reload2 = spectatee.vehicle_reload2;
1756
1757         msg_entity = self;
1758
1759         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1760             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1761             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1762             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1763
1764         //WriteByte (MSG_ONE, SVC_SETVIEW);
1765         //    WriteEntity(MSG_ONE, self);
1766         //makevectors(spectatee.v_angle);
1767         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1768     }
1769 }
1770
1771 float SpectateUpdate() {
1772         if(!self.enemy)
1773             return 0;
1774
1775         if (self == self.enemy)
1776                 return 0;
1777
1778         if not(IS_PLAYER(self.enemy))
1779                 return 0;
1780
1781         SpectateCopy(self.enemy);
1782
1783         return 1;
1784 }
1785
1786
1787 float SpectateSet()
1788 {
1789         if(self.enemy.classname != "player")
1790                 return FALSE;
1791         /*if(self.enemy.vehicle)
1792         {
1793
1794                 msg_entity = self;
1795                 WriteByte(MSG_ONE, SVC_SETVIEW);
1796                 WriteEntity(MSG_ONE, self.enemy);
1797                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1798
1799                 self.movetype = MOVETYPE_NONE;
1800                 accuracy_resend(self);
1801         }
1802         else
1803         {*/
1804                 msg_entity = self;
1805                 WriteByte(MSG_ONE, SVC_SETVIEW);
1806                 WriteEntity(MSG_ONE, self.enemy);
1807                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1808                 self.movetype = MOVETYPE_NONE;
1809                 accuracy_resend(self);
1810
1811                 if(!SpectateUpdate())
1812                         PutObserverInServer();
1813         //}
1814         return TRUE;
1815 }
1816
1817 float Spectate(entity pl)
1818 {
1819         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1820         if(pl.team != self.team)
1821                 return 0;
1822
1823         self.enemy = pl;
1824         return SpectateSet();
1825 }
1826
1827 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1828 entity CA_SpectateNext(entity start) {
1829         if (start.team == self.team) {
1830                 return start;
1831         }
1832
1833         other = start;
1834         // continue from current player
1835         while(other && other.team != self.team) {
1836                 other = find(other, classname, "player");
1837         }
1838
1839         if (!other) {
1840                 // restart from begining
1841                 other = find(other, classname, "player");
1842                 while(other && other.team != self.team) {
1843                         other = find(other, classname, "player");
1844                 }
1845         }
1846
1847         return other;
1848 }
1849
1850 float SpectateNext()
1851 {
1852         other = find(self.enemy, classname, "player");
1853
1854         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1855                 // CA and ca players when spectating enemies is forbidden
1856                 other = CA_SpectateNext(other);
1857         } else {
1858                 // other modes and ca spectators or spectating enemies is allowed
1859                 if (!other)
1860                         other = find(other, classname, "player");
1861         }
1862
1863         if (other)
1864                 self.enemy = other;
1865
1866         return SpectateSet();
1867 }
1868
1869 float SpectatePrev()
1870 {
1871         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1872         other = findchain(classname, "player");
1873         if not(other) // no player
1874                 return FALSE;
1875
1876         entity first = other;
1877         // skip players until current spectated player
1878         if(self.enemy)
1879         while(other && other != self.enemy)
1880                 other = other.chain;
1881
1882         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1883         {
1884                 do { other = other.chain; }
1885                 while(other && other.team != self.team);
1886
1887                 if not(other)
1888                 {
1889                         other = first;
1890                         while(other.team != self.team)
1891                                 other = other.chain;
1892                         if(other == self.enemy)
1893                                 return TRUE;
1894                 }
1895         }
1896         else
1897         {
1898                 if(other.chain)
1899                         other = other.chain;
1900                 else
1901                         other = first;
1902         }
1903         self.enemy = other;
1904         return SpectateSet();
1905 }
1906
1907 /*
1908 =============
1909 ShowRespawnCountdown()
1910
1911 Update a respawn countdown display.
1912 =============
1913 */
1914 void ShowRespawnCountdown()
1915 {
1916         float number;
1917         if(self.deadflag == DEAD_NO) // just respawned?
1918                 return;
1919         else
1920         {
1921                 number = ceil(self.respawn_time - time);
1922                 if(number <= 0)
1923                         return;
1924                 if(number <= self.respawn_countdown)
1925                 {
1926                         self.respawn_countdown = number - 1;
1927                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1928                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1929                 }
1930         }
1931 }
1932
1933 void LeaveSpectatorMode()
1934 {
1935         if(self.caplayer)
1936                 return;
1937         if(nJoinAllowed(self))
1938         {
1939                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1940                 {
1941                         self.classname = "player";
1942
1943                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1944                                 { JoinBestTeam(self, FALSE, TRUE); }
1945
1946                         if(autocvar_g_campaign)
1947                                 { campaign_bots_may_start = 1; }
1948
1949                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1950
1951                         PutClientInServer();
1952
1953                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1954                 }
1955                 else
1956                         stuffcmd(self, "menu_showteamselect\n");
1957         }
1958         else
1959         {
1960                 // Player may not join because g_maxplayers is set
1961                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1962         }
1963 }
1964
1965 /**
1966  * Determines whether the player is allowed to join. This depends on cvar
1967  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1968  * it checks whether the number of currently playing players exceeds g_maxplayers.
1969  * @return int number of free slots for players, 0 if none
1970  */
1971 float nJoinAllowed(entity ignore) {
1972         if(!ignore)
1973         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1974         // so report 0 free slots if restricted
1975         {
1976                 if(autocvar_g_forced_team_otherwise == "spectate")
1977                         return 0;
1978                 if(autocvar_g_forced_team_otherwise == "spectator")
1979                         return 0;
1980         }
1981
1982         if(self.team_forced < 0)
1983                 return 0; // forced spectators can never join
1984
1985         // TODO simplify this
1986         entity e;
1987         float totalClients = 0;
1988         FOR_EACH_CLIENT(e)
1989                 if(e != ignore)
1990                         totalClients += 1;
1991
1992         if (!autocvar_g_maxplayers)
1993                 return maxclients - totalClients;
1994
1995         float currentlyPlaying = 0;
1996         FOR_EACH_REALCLIENT(e)
1997                 if(IS_PLAYER(e) || e.caplayer == 1)
1998                         currentlyPlaying += 1;
1999
2000         if(currentlyPlaying < autocvar_g_maxplayers)
2001                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2002
2003         return 0;
2004 }
2005
2006 /**
2007  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2008  * g_maxplayers_spectator_blocktime seconds
2009  */
2010 void checkSpectatorBlock() {
2011         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2012                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2013                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2014                         dropclient(self);
2015                 }
2016         }
2017 }
2018
2019 void PrintWelcomeMessage()
2020 {
2021         if(self.motd_actived_time == 0)
2022         {
2023                 if (autocvar_g_campaign) {
2024                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2025                                 self.motd_actived_time = time;
2026                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2027                         }
2028                 } else {
2029                         if (self.BUTTON_INFO) {
2030                                 self.motd_actived_time = time;
2031                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2032                         }
2033                 }
2034         }
2035         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2036         {
2037                 if (autocvar_g_campaign) {
2038                         if (self.BUTTON_INFO)
2039                                 self.motd_actived_time = time;
2040                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2041                                 self.motd_actived_time = 0;
2042                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2043                         }
2044                 } else {
2045                         if (self.BUTTON_INFO)
2046                                 self.motd_actived_time = time;
2047                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2048                                 self.motd_actived_time = 0;
2049                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2050                         }
2051                 }
2052         }
2053         else //if(self.motd_actived_time < 0) // just connected, motd is active
2054         {
2055                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2056                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2057                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2058                 {
2059                         // instanctly hide MOTD
2060                         self.motd_actived_time = 0;
2061                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2062                 }
2063         }
2064 }
2065
2066 void ObserverThink()
2067 {
2068         float prefered_movetype;
2069         if (self.flags & FL_JUMPRELEASED) {
2070                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2071                         self.flags &= ~FL_JUMPRELEASED;
2072                         self.flags |= FL_SPAWNING;
2073                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2074                         self.flags &= ~FL_JUMPRELEASED;
2075                         if(SpectateNext()) {
2076                                 self.classname = "spectator";
2077                         }
2078                 } else {
2079                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2080                         if (self.movetype != prefered_movetype)
2081                                 self.movetype = prefered_movetype;
2082                 }
2083         } else {
2084                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2085                         self.flags |= FL_JUMPRELEASED;
2086                         if(self.flags & FL_SPAWNING)
2087                         {
2088                                 self.flags &= ~FL_SPAWNING;
2089                                 LeaveSpectatorMode();
2090                                 return;
2091                         }
2092                 }
2093         }
2094 }
2095
2096 void SpectatorThink()
2097 {
2098         if (self.flags & FL_JUMPRELEASED) {
2099                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2100                         self.flags &= ~FL_JUMPRELEASED;
2101                         self.flags |= FL_SPAWNING;
2102                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2103                         self.flags &= ~FL_JUMPRELEASED;
2104                         if(SpectateNext()) {
2105                                 self.classname = "spectator";
2106                         } else {
2107                                 self.classname = "observer";
2108                                 PutClientInServer();
2109                         }
2110                         self.impulse = 0;
2111                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2112                         self.flags &= ~FL_JUMPRELEASED;
2113                         if(SpectatePrev()) {
2114                                 self.classname = "spectator";
2115                         } else {
2116                                 self.classname = "observer";
2117                                 PutClientInServer();
2118                         }
2119                         self.impulse = 0;
2120                 } else if (self.BUTTON_ATCK2) {
2121                         self.flags &= ~FL_JUMPRELEASED;
2122                         self.classname = "observer";
2123                         PutClientInServer();
2124                 } else {
2125                         if(!SpectateUpdate())
2126                                 PutObserverInServer();
2127                 }
2128         } else {
2129                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2130                         self.flags |= FL_JUMPRELEASED;
2131                         if(self.flags & FL_SPAWNING)
2132                         {
2133                                 self.flags &= ~FL_SPAWNING;
2134                                 LeaveSpectatorMode();
2135                                 return;
2136                         }
2137                 }
2138                 if(!SpectateUpdate())
2139                         PutObserverInServer();
2140         }
2141
2142         self.flags |= FL_CLIENT | FL_NOTARGET;
2143 }
2144
2145 void PlayerUseKey()
2146 {
2147         if not(IS_PLAYER(self))
2148                 return;
2149
2150         if(self.vehicle)
2151         {
2152         vehicles_exit(VHEF_NORMAL);
2153         return;
2154         }
2155
2156         // a use key was pressed; call handlers
2157         MUTATOR_CALLHOOK(PlayerUseKey);
2158 }
2159
2160 /*
2161 =============
2162 PlayerPreThink
2163
2164 Called every frame for each client before the physics are run
2165 =============
2166 */
2167 .float usekeypressed;
2168 void() nexball_setstatus;
2169 .float items_added;
2170 void PlayerPreThink (void)
2171 {
2172         WarpZone_PlayerPhysics_FixVAngle();
2173
2174         self.stat_game_starttime = game_starttime;
2175         self.stat_round_starttime = round_starttime;
2176         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2177         self.stat_leadlimit = autocvar_leadlimit;
2178
2179         if(frametime)
2180         {
2181                 // physics frames: update anticheat stuff
2182                 anticheat_prethink();
2183         }
2184
2185         if(blockSpectators && frametime)
2186                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2187                 checkSpectatorBlock();
2188
2189         zoomstate_set = 0;
2190
2191         if(self.netname_previous != self.netname)
2192         {
2193                 if(autocvar_sv_eventlog)
2194                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2195                 if(self.netname_previous)
2196                         strunzone(self.netname_previous);
2197                 self.netname_previous = strzone(self.netname);
2198         }
2199
2200         // version nagging
2201         if(self.version_nagtime)
2202                 if(self.cvar_g_xonoticversion)
2203                         if(time > self.version_nagtime)
2204                         {
2205                                 // don't notify git users
2206                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2207                                 {
2208                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2209                                         {
2210                                                 // notify release users if connecting to git
2211                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2212                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2213                                         }
2214                                         else
2215                                         {
2216                                                 float r;
2217                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2218                                                 if(r < 0)
2219                                                 {
2220                                                         // give users new version
2221                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2222                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2223                                                 }
2224                                                 else if(r > 0)
2225                                                 {
2226                                                         // notify users about old server version
2227                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2228                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2229                                                 }
2230                                         }
2231                                 }
2232                                 self.version_nagtime = 0;
2233                         }
2234
2235         // GOD MODE info
2236         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2237         {
2238                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2239                 self.max_armorvalue = 0;
2240         }
2241
2242 #ifdef TETRIS
2243         if (TetrisPreFrame())
2244                 return;
2245 #endif
2246
2247         if(self.frozen == 2)
2248         {
2249                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2250                 self.health = max(1, self.revive_progress * autocvar_g_balance_health_start);
2251                 self.iceblock.alpha = 1 - self.revive_progress;
2252
2253                 if(self.revive_progress >= 1)
2254                         Unfreeze(self);
2255         }
2256
2257         MUTATOR_CALLHOOK(PlayerPreThink);
2258
2259         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2260         {
2261                 if(self.BUTTON_USE && !self.usekeypressed)
2262                         PlayerUseKey();
2263                 self.usekeypressed = self.BUTTON_USE;
2264         }
2265
2266         if(IS_REAL_CLIENT(self))
2267                 PrintWelcomeMessage();
2268
2269         if(IS_PLAYER(self))
2270         {
2271
2272                 CheckRules_Player();
2273
2274                 if (intermission_running)
2275                 {
2276                         IntermissionThink ();   // otherwise a button could be missed between
2277                         return;                                 // the think tics
2278                 }
2279
2280                 //don't allow the player to turn around while game is paused!
2281                 if(timeout_status == TIMEOUT_ACTIVE) {
2282                         // FIXME turn this into CSQC stuff
2283                         self.v_angle = self.lastV_angle;
2284                         self.angles = self.lastV_angle;
2285                         self.fixangle = TRUE;
2286                 }
2287
2288                 if(frametime)
2289                 {
2290                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2291                         {
2292                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2293                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2294                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2295
2296                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2297                                 {
2298                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2299                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2300                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2301                                 }
2302                         }
2303                         else
2304                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2305
2306                         player_powerups();
2307                 }
2308
2309                 if (self.deadflag != DEAD_NO)
2310                 {
2311                         if(self.personal && g_race_qualifying)
2312                         {
2313                                 if(time > self.respawn_time)
2314                                 {
2315                                         self.respawn_time = time + 1; // only retry once a second
2316                                         self.stat_respawn_time = self.respawn_time;
2317                                         respawn();
2318                                         self.impulse = 141;
2319                                 }
2320                         }
2321                         else
2322                         {
2323                                 float button_pressed;
2324                                 if(frametime)
2325                                         player_anim();
2326                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2327
2328                                 if (self.deadflag == DEAD_DYING)
2329                                 {
2330                                         if(self.respawn_flags & RESPAWN_FORCE)
2331                                                 self.deadflag = DEAD_RESPAWNING;
2332                                         else if(!button_pressed)
2333                                                 self.deadflag = DEAD_DEAD;
2334                                 }
2335                                 else if (self.deadflag == DEAD_DEAD)
2336                                 {
2337                                         if(button_pressed)
2338                                                 self.deadflag = DEAD_RESPAWNABLE;
2339                                 }
2340                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2341                                 {
2342                                         if(!button_pressed)
2343                                                 self.deadflag = DEAD_RESPAWNING;
2344                                 }
2345                                 else if (self.deadflag == DEAD_RESPAWNING)
2346                                 {
2347                                         if(time > self.respawn_time)
2348                                         {
2349                                                 self.respawn_time = time + 1; // only retry once a second
2350                                                 respawn();
2351                                         }
2352                                 }
2353
2354                                 ShowRespawnCountdown();
2355
2356                                 if(self.respawn_flags & RESPAWN_SILENT)
2357                                         self.stat_respawn_time = 0;
2358                                 else
2359                                         self.stat_respawn_time = self.respawn_time;
2360                         }
2361
2362                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2363                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2364                                 self.stat_respawn_time *= -1;
2365
2366                         return;
2367                 }
2368
2369                 self.prevorigin = self.origin;
2370
2371                 float do_crouch = self.BUTTON_CROUCH;
2372                 if(self.hook.state)
2373                         do_crouch = 0;
2374                 if(self.vehicle)
2375                         do_crouch = 0;
2376                 if(self.frozen)
2377                         do_crouch = 0;
2378                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2379                         do_crouch = 0;
2380
2381                 if (do_crouch)
2382                 {
2383                         if (!self.crouch)
2384                         {
2385                                 self.crouch = TRUE;
2386                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2387                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2388                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2389                         }
2390                 }
2391                 else
2392                 {
2393                         if (self.crouch)
2394                         {
2395                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2396                                 if (!trace_startsolid)
2397                                 {
2398                                         self.crouch = FALSE;
2399                                         self.view_ofs = PL_VIEW_OFS;
2400                                         setsize (self, PL_MIN, PL_MAX);
2401                                 }
2402                         }
2403                 }
2404
2405                 FixPlayermodel();
2406
2407                 GrapplingHookFrame();
2408
2409                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2410                 //if(frametime)
2411                 {
2412                         self.items &= ~self.items_added;
2413
2414                         W_WeaponFrame();
2415
2416                         self.items_added = 0;
2417                         if(self.items & IT_JETPACK)
2418                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2419                                         self.items_added |= IT_FUEL;
2420
2421                         self.items |= self.items_added;
2422                 }
2423
2424                 player_regen();
2425
2426                 // rot nex charge to the charge limit
2427                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2428                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2429
2430                 if(frametime)
2431                         player_anim();
2432
2433                 // secret status
2434                 secrets_setstatus();
2435
2436                 // monsters status
2437                 monsters_setstatus();
2438
2439                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2440
2441                 //self.angles_y=self.v_angle_y + 90;   // temp
2442         } else if(gameover) {
2443                 if (intermission_running)
2444                         IntermissionThink ();   // otherwise a button could be missed between
2445                 return;
2446         } else if(IS_OBSERVER(self)) {
2447                 ObserverThink();
2448         } else if(IS_SPEC(self)) {
2449                 SpectatorThink();
2450         }
2451
2452         if(!zoomstate_set)
2453                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2454
2455         float oldspectatee_status;
2456         oldspectatee_status = self.spectatee_status;
2457         if(IS_SPEC(self))
2458                 self.spectatee_status = num_for_edict(self.enemy);
2459         else if(IS_OBSERVER(self))
2460                 self.spectatee_status = num_for_edict(self);
2461         else
2462                 self.spectatee_status = 0;
2463         if(self.spectatee_status != oldspectatee_status)
2464         {
2465                 ClientData_Touch(self);
2466                 if(g_race || g_cts)
2467                         race_InitSpectator();
2468         }
2469
2470         if(self.teamkill_soundtime)
2471         if(time > self.teamkill_soundtime)
2472         {
2473                 self.teamkill_soundtime = 0;
2474
2475                 entity oldpusher, oldself;
2476
2477                 oldself = self; self = self.teamkill_soundsource;
2478                 oldpusher = self.pusher; self.pusher = oldself;
2479
2480                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2481
2482                 self.pusher = oldpusher;
2483                 self = oldself;
2484         }
2485
2486         if(self.taunt_soundtime)
2487         if(time > self.taunt_soundtime)
2488         {
2489                 self.taunt_soundtime = 0;
2490                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2491         }
2492
2493         target_voicescript_next(self);
2494
2495         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2496         if(!self.weapon)
2497                 self.clip_load = self.clip_size = 0;
2498 }
2499
2500 float isInvisibleString(string s)
2501 {
2502         float i, n, c;
2503         s = strdecolorize(s);
2504         for((i = 0), (n = strlen(s)); i < n; ++i)
2505         {
2506                 c = str2chr(s, i);
2507                 switch(c)
2508                 {
2509                         case 0:
2510                         case 32: // space
2511                                 break;
2512                         case 192: // charmap space
2513                                 if (!autocvar_utf8_enable)
2514                                         break;
2515                                 return FALSE;
2516                         case 160: // space in unicode fonts
2517                         case 0xE000 + 192: // utf8 charmap space
2518                                 if (autocvar_utf8_enable)
2519                                         break;
2520                         default:
2521                                 return FALSE;
2522                 }
2523         }
2524         return TRUE;
2525 }
2526
2527 /*
2528 =============
2529 PlayerPostThink
2530
2531 Called every frame for each client after the physics are run
2532 =============
2533 */
2534 .float idlekick_lasttimeleft;
2535 void PlayerPostThink (void)
2536 {
2537         // Savage: Check for nameless players
2538         if (isInvisibleString(self.netname)) {
2539                 self.netname = "Player";
2540                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2541         }
2542
2543         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2544         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2545         {
2546                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2547                 {
2548                         if(self.idlekick_lasttimeleft)
2549                         {
2550                                 self.idlekick_lasttimeleft = 0;
2551                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2552                         }
2553                 }
2554                 else
2555                 {
2556                         float timeleft;
2557                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2558                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2559                         {
2560                                 if(!self.idlekick_lasttimeleft)
2561                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2562                         }
2563                         if(timeleft <= 0)
2564                         {
2565                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2566                                 dropclient(self);
2567                                 return;
2568                         }
2569                         else if(timeleft <= 10)
2570                         {
2571                                 if(timeleft != self.idlekick_lasttimeleft)
2572                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2573                                 self.idlekick_lasttimeleft = timeleft;
2574                         }
2575                 }
2576         }
2577
2578 #ifdef TETRIS
2579         if(self.impulse == 100)
2580                 ImpulseCommands();
2581         if (!TetrisPostFrame())
2582         {
2583 #endif
2584
2585         CheatFrame();
2586
2587         //CheckPlayerJump();
2588
2589         if(IS_PLAYER(self)) {
2590                 CheckRules_Player();
2591                 UpdateChatBubble();
2592                 if (self.impulse)
2593                         ImpulseCommands();
2594                 if (intermission_running)
2595                         return;         // intermission or finale
2596                 GetPressedKeys();
2597         }
2598
2599 #ifdef TETRIS
2600         }
2601 #endif
2602
2603         /*
2604         float i;
2605         for(i = 0; i < 1000; ++i)
2606         {
2607                 vector end;
2608                 end = self.origin + '0 0 1024' + 512 * randomvec();
2609                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2610                 if(trace_fraction < 1)
2611                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2612                 {
2613                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2614                         break;
2615                 }
2616         }
2617         */
2618
2619         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2620
2621         if(self.waypointsprite_attachedforcarrier)
2622                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2623
2624         playerdemo_write();
2625
2626         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2627         {
2628                 if not(self.stored_netname)
2629                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2630                 if(self.stored_netname != self.netname)
2631                 {
2632                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2633                         strunzone(self.stored_netname);
2634                         self.stored_netname = strzone(self.netname);
2635                 }
2636         }
2637
2638         /*
2639         if(g_race)
2640                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2641         */
2642
2643         CSQCMODEL_AUTOUPDATE();
2644 }