qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teamplay)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 }
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck >= 0)
 120                 if(spot.team != teamcheck)
 121                         return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(clienttype(self) == CLIENTTYPE_REAL)
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         shortest = vlen(world.maxs - world.mins);
 139         FOR_EACH_PLAYER(player) if (player != self)
 140         {
 141                 thisdist = vlen(player.origin - spot.origin);
 142                 if (thisdist < shortest)
 143                         shortest = thisdist;
 144         }
 145         if(shortest > mindist)
 146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 147
 148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 149         spawn_spot = spot;
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 entity ent;
 154                 float found;
 155
 156                 found = 0;
 157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 158                 {
 159                         ++found;
 160                         if(ent.spawn_evalfunc)
 161                         {
 162                                 entity oldself = self;
 163                                 self = ent;
 164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 165                                 self = oldself;
 166                                 if(spawn_score_x < 0)
 167                                         return spawn_score;
 168                         }
 169                 }
 170
 171                 if(!found)
 172                 {
 173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 174                         return '-1 0 0';
 175                 }
 176         }
 177
 178         MUTATOR_CALLHOOK(Spawn_Score);
 179         return spawn_score;
 180 }
 181
 182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 183 {
 184         entity spot;
 185         for(spot = firstspot; spot; spot = spot.chain)
 186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 187 }
 188
 189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 190 {
 191         entity spot, spotlist, spotlistend;
 192
 193         spotlist = world;
 194         spotlistend = world;
 195
 196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 201                 {
 202                         if(spotlistend)
 203                                 spotlistend.chain = spot;
 204                         spotlistend = spot;
 205                         if(!spotlist)
 206                                 spotlist = spot;
 207                 }
 208         }
 209         if(spotlistend)
 210                 spotlistend.chain = world;
 211
 212         return spotlist;
 213 }
 214
 215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 216 {
 217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 219         entity spot;
 220
 221         RandomSelection_Init();
 222         for(spot = firstspot; spot; spot = spot.chain)
 223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 224
 225         return RandomSelection_chosen_ent;
 226 }
 227
 228 /*
 229 =============
 230 SelectSpawnPoint
 231
 232 Finds a point to respawn
 233 =============
 234 */
 235 entity SelectSpawnPoint (float anypoint)
 236 {
 237         float teamcheck;
 238         entity spot, firstspot;
 239
 240         spot = find (world, classname, "testplayerstart");
 241         if (spot)
 242                 return spot;
 243
 244         if(anypoint || autocvar_g_spawn_useallspawns)
 245                 teamcheck = -1;
 246         else if(have_team_spawns > 0)
 247         {
 248                 if(have_team_spawns_forteam[self.team] == 0)
 249                 {
 250                         // we request a spawn for a team, and we have team
 251                         // spawns, but that team has no spawns?
 252                         if(have_team_spawns_forteam[0])
 253                                 // try noteam spawns
 254                                 teamcheck = 0;
 255                         else
 256                                 // if not, any spawn has to do
 257                                 teamcheck = -1;
 258                 }
 259                 else
 260                         teamcheck = self.team; // MUST be team
 261         }
 262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 263                 teamcheck = 0; // MUST be noteam
 264         else
 265                 teamcheck = -1;
 266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 267
 268
 269         // get the entire list of spots
 270         firstspot = findchain(classname, "info_player_deathmatch");
 271         // filter out the bad ones
 272         // (note this returns the original list if none survived)
 273         if(anypoint)
 274         {
 275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 276         }
 277         else
 278         {
 279                 float mindist;
 280                 if (g_arena && arena_roundbased)
 281                         mindist = 800;
 282                 else
 283                         mindist = 100;
 284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 285
 286                 // there is 50/50 chance of choosing a random spot or the furthest spot
 287                 // (this means that roughly every other spawn will be furthest, so you
 288                 // usually won't get fragged at spawn twice in a row)
 289                 if (random() > autocvar_g_spawn_furthest)
 290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 291                 else
 292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 293         }
 294
 295         if (!spot)
 296         {
 297                 if(autocvar_spawn_debug)
 298                         GotoNextMap(0);
 299                 else
 300                 {
 301                         if(some_spawn_has_been_used)
 302                                 return world; // team can't spawn any more, because of actions of other team
 303                         else
 304                                 error("Cannot find a spawn point - please fix the map!");
 305                 }
 306         }
 307
 308         return spot;
 309 }
 310
 311 /*
 312 =============
 313 CheckPlayerModel
 314
 315 Checks if the argument string can be a valid playermodel.
 316 Returns a valid one in doubt.
 317 =============
 318 */
 319 string FallbackPlayerModel;
 320 string CheckPlayerModel(string plyermodel) {
 321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 322         {
 323                 // note: we cannot summon Don Strunzone here, some player may
 324                 // still have the model string set. In case anyone manages how
 325                 // to change a cvar default, we'll have a small leak here.
 326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 327         }
 328         // only in right path
 329         if( substring(plyermodel,0,14) != "models/player/")
 330                 return FallbackPlayerModel;
 331         // only good file extensions
 332         if(substring(plyermodel,-4,4) != ".zym")
 333         if(substring(plyermodel,-4,4) != ".dpm")
 334         if(substring(plyermodel,-4,4) != ".iqm")
 335         if(substring(plyermodel,-4,4) != ".md3")
 336         if(substring(plyermodel,-4,4) != ".psk")
 337                 return FallbackPlayerModel;
 338         // forbid the LOD models
 339         if(substring(plyermodel, -9,5) == "_lod1")
 340                 return FallbackPlayerModel;
 341         if(substring(plyermodel, -9,5) == "_lod2")
 342                 return FallbackPlayerModel;
 343         if(plyermodel != strtolower(plyermodel))
 344                 return FallbackPlayerModel;
 345         // also, restrict to server models
 346         if(autocvar_sv_servermodelsonly)
 347         {
 348                 if(!fexists(plyermodel))
 349                         return FallbackPlayerModel;
 350         }
 351         return plyermodel;
 352 }
 353
 354 void setplayermodel(entity e, string modelname)
 355 {
 356         precache_model(modelname);
 357         setmodel(e, modelname);
 358         player_setupanimsformodel();
 359         UpdatePlayerSounds();
 360 }
 361
 362 /*
 363 =============
 364 PutObserverInServer
 365
 366 putting a client as observer in the server
 367 =============
 368 */
 369 void FixPlayermodel();
 370 void PutObserverInServer (void)
 371 {
 372         entity  spot;
 373     self.hud = HUD_NORMAL;
 374         race_PreSpawnObserver();
 375
 376         spot = SelectSpawnPoint (TRUE);
 377         if(!spot)
 378                 error("No spawnpoints for observers?!?\n");
 379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 380
 381         if(clienttype(self) == CLIENTTYPE_REAL)
 382         {
 383                 msg_entity = self;
 384                 WriteByte(MSG_ONE, SVC_SETVIEW);
 385                 WriteEntity(MSG_ONE, self);
 386         }
 387
 388         if((g_race && g_race_qualifying) || g_cts)
 389         {
 390                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 391                         self.frags = FRAGS_LMS_LOSER;
 392                 else
 393                         self.frags = FRAGS_SPECTATOR;
 394         }
 395         else
 396                 self.frags = FRAGS_SPECTATOR;
 397
 398         MUTATOR_CALLHOOK(MakePlayerObserver);
 399
 400         minstagib_stop_countdown(self);
 401
 402         Portal_ClearAll(self);
 403
 404         if(self.alivetime)
 405         {
 406                 if(!inWarmupStage)
 407                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 408                 self.alivetime = 0;
 409         }
 410
 411         if(self.vehicle)
 412                 vehicles_exit(VHEF_RELESE);
 413
 414         WaypointSprite_PlayerDead();
 415
 416         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 417                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 418
 419         if(self.killcount != -666)
 420         {
 421                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 422
 423                 if(self.just_joined == FALSE) {
 424                         LogTeamchange(self.playerid, -1, 4);
 425                 } else
 426                         self.just_joined = FALSE;
 427         }
 428
 429         PlayerScore_Clear(self); // clear scores when needed
 430
 431         accuracy_resend(self);
 432
 433         self.spectatortime = time;
 434
 435         self.classname = "observer";
 436         self.iscreature = FALSE;
 437         self.teleportable = TELEPORT_SIMPLE;
 438         self.damagedbycontents = FALSE;
 439         self.health = -666;
 440         self.takedamage = DAMAGE_NO;
 441         self.solid = SOLID_NOT;
 442         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 443         self.flags = FL_CLIENT | FL_NOTARGET;
 444         self.armorvalue = 666;
 445         self.effects = 0;
 446         self.armorvalue = autocvar_g_balance_armor_start;
 447         self.pauserotarmor_finished = 0;
 448         self.pauserothealth_finished = 0;
 449         self.pauseregen_finished = 0;
 450         self.damageforcescale = 0;
 451         self.death_time = 0;
 452         self.respawn_flags = 0;
 453         self.respawn_time = 0;
 454         self.stat_respawn_time = 0;
 455         self.alpha = 0;
 456         self.scale = 0;
 457         self.fade_time = 0;
 458         self.pain_frame = 0;
 459         self.pain_finished = 0;
 460         self.strength_finished = 0;
 461         self.invincible_finished = 0;
 462         self.superweapons_finished = 0;
 463         self.pushltime = 0;
 464         self.istypefrag = 0;
 465         self.think = func_null;
 466         self.nextthink = 0;
 467         self.hook_time = 0;
 468         self.deadflag = DEAD_NO;
 469         self.angles = spot.angles;
 470         self.angles_z = 0;
 471         self.fixangle = TRUE;
 472         self.crouch = FALSE;
 473
 474         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 475         self.prevorigin = self.origin;
 476         self.items = 0;
 477         WEPSET_CLEAR_E(self);
 478         self.model = "";
 479         FixPlayermodel();
 480         setmodel(self, "null");
 481         self.drawonlytoclient = self;
 482
 483         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 484         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 485
 486         self.weapon = 0;
 487         self.weaponname = "";
 488         self.switchingweapon = 0;
 489         self.weaponmodel = "";
 490         self.weaponentity = world;
 491         self.exteriorweaponentity = world;
 492         self.killcount = -666;
 493         self.velocity = '0 0 0';
 494         self.avelocity = '0 0 0';
 495         self.punchangle = '0 0 0';
 496         self.punchvector = '0 0 0';
 497         self.oldvelocity = self.velocity;
 498         self.fire_endtime = -1;
 499 }
 500
 501 .float model_randomizer;
 502 void FixPlayermodel()
 503 {
 504         string defaultmodel;
 505         float defaultskin, chmdl, oldskin, n, i;
 506         vector m1, m2;
 507
 508         defaultmodel = "";
 509         defaultskin = 0;
 510         chmdl = FALSE;
 511
 512         if(autocvar_sv_defaultcharacter == 1)
 513         {
 514                 if(teamplay)
 515                 {
 516                         string s;
 517                         s = Team_ColorName_Lower(self.team);
 518                         if(s != "neutral")
 519                         {
 520                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 521                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 522                         }
 523                 }
 524
 525                 if(defaultmodel == "")
 526                 {
 527                         defaultmodel = autocvar_sv_defaultplayermodel;
 528                         defaultskin = autocvar_sv_defaultplayerskin;
 529                 }
 530
 531                 n = tokenize_console(defaultmodel);
 532                 if(n > 0)
 533                         defaultmodel = argv(floor(n * self.model_randomizer));
 534
 535                 i = strstrofs(defaultmodel, ":", 0);
 536                 if(i >= 0)
 537                 {
 538                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 539                         defaultmodel = substring(defaultmodel, 0, i);
 540                 }
 541         }
 542
 543         if(defaultmodel != "")
 544         {
 545                 if (defaultmodel != self.model)
 546                 {
 547                         m1 = self.mins;
 548                         m2 = self.maxs;
 549                         setplayermodel (self, defaultmodel);
 550                         setsize (self, m1, m2);
 551                         chmdl = TRUE;
 552                 }
 553
 554                 oldskin = self.skin;
 555                 self.skin = defaultskin;
 556         } else {
 557                 if (self.playermodel != self.model || self.playermodel == "")
 558                 {
 559                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 560                         m1 = self.mins;
 561                         m2 = self.maxs;
 562                         setplayermodel (self, self.playermodel);
 563                         setsize (self, m1, m2);
 564                         chmdl = TRUE;
 565                 }
 566
 567                 oldskin = self.skin;
 568                 self.skin = stof(self.playerskin);
 569         }
 570
 571         if(chmdl || oldskin != self.skin) // model or skin has changed
 572         {
 573                 self.species = player_getspecies(); // update species
 574                 UpdatePlayerSounds(); // update skin sounds
 575         }
 576
 577         if(!teamplay)
 578                 if(strlen(autocvar_sv_defaultplayercolors))
 579                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 580                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 581 }
 582
 583 /*
 584 =============
 585 PutClientInServer
 586
 587 Called when a client spawns in the server
 588 =============
 589 */
 590
 591 void PutClientInServer (void)
 592 {
 593         if(clienttype(self) == CLIENTTYPE_BOT)
 594                 self.classname = "player";
 595         else if(clienttype(self) == CLIENTTYPE_REAL)
 596         {
 597                 msg_entity = self;
 598                 WriteByte(MSG_ONE, SVC_SETVIEW);
 599                 WriteEntity(MSG_ONE, self);
 600         }
 601
 602         // reset player keys
 603         self.itemkeys = 0;
 604
 605         MUTATOR_CALLHOOK(PutClientInServer);
 606
 607         if(gameover)
 608                 self.classname = "observer";
 609
 610         if(self.classname == "player") {
 611                 entity spot, oldself;
 612                 float j;
 613
 614                 accuracy_resend(self);
 615
 616                 if(self.team < 0)
 617                         JoinBestTeam(self, FALSE, TRUE);
 618
 619                 race_PreSpawn();
 620
 621                 spot = SelectSpawnPoint (FALSE);
 622                 if(!spot)
 623                 {
 624                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 625                         return; // spawn failed
 626                 }
 627
 628                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 629
 630                 self.classname = "player";
 631                 self.wasplayer = TRUE;
 632                 self.iscreature = TRUE;
 633                 self.teleportable = TELEPORT_NORMAL;
 634                 self.damagedbycontents = TRUE;
 635                 self.movetype = MOVETYPE_WALK;
 636                 self.solid = SOLID_SLIDEBOX;
 637                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 638                 if(autocvar_g_playerclip_collisions)
 639                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 640                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 641                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 642                 self.frags = FRAGS_PLAYER;
 643                 if(INDEPENDENT_PLAYERS)
 644                         MAKE_INDEPENDENT_PLAYER(self);
 645                 self.flags = FL_CLIENT;
 646                 if(autocvar__notarget)
 647                         self.flags |= FL_NOTARGET;
 648                 self.takedamage = DAMAGE_AIM;
 649                 if(g_minstagib)
 650                         self.effects = EF_FULLBRIGHT;
 651                 else
 652                         self.effects = 0;
 653                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 654                 self.air_finished = time + 12;
 655                 self.dmg = 2;
 656                 if(autocvar_g_balance_nex_charge)
 657                 {
 658                         if(autocvar_g_balance_nex_secondary_chargepool)
 659                                 self.nex_chargepool_ammo = 1;
 660                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 661                 }
 662
 663                 if(inWarmupStage)
 664                 {
 665                         self.ammo_shells = warmup_start_ammo_shells;
 666                         self.ammo_nails = warmup_start_ammo_nails;
 667                         self.ammo_rockets = warmup_start_ammo_rockets;
 668                         self.ammo_cells = warmup_start_ammo_cells;
 669                         self.ammo_fuel = warmup_start_ammo_fuel;
 670                         self.health = warmup_start_health;
 671                         self.armorvalue = warmup_start_armorvalue;
 672                         WEPSET_COPY_EA(self, warmup_start_weapons);
 673                 }
 674                 else
 675                 {
 676                         self.ammo_shells = start_ammo_shells;
 677                         self.ammo_nails = start_ammo_nails;
 678                         self.ammo_rockets = start_ammo_rockets;
 679                         self.ammo_cells = start_ammo_cells;
 680                         self.ammo_fuel = start_ammo_fuel;
 681                         self.health = start_health;
 682                         self.armorvalue = start_armorvalue;
 683                         WEPSET_COPY_EA(self, start_weapons);
 684                 }
 685
 686                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 687                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 688                 else
 689                         self.superweapons_finished = 0;
 690
 691                 if(g_weaponarena_random)
 692                 {
 693                         if(g_weaponarena_random_with_laser)
 694                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 695                         W_RandomWeapons(self, g_weaponarena_random);
 696                         if(g_weaponarena_random_with_laser)
 697                                 WEPSET_OR_EW(self, WEP_LASER);
 698                 }
 699
 700                 self.items = start_items;
 701
 702                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 703                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 704                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 705                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 706                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 707                 //extend the pause of rotting if client was reset at the beginning of the countdown
 708                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 709                         self.spawnshieldtime += game_starttime - time;
 710                         self.pauserotarmor_finished += game_starttime - time;
 711                         self.pauserothealth_finished += game_starttime - time;
 712                         self.pauseregen_finished += game_starttime - time;
 713                 }
 714                 self.damageforcescale = 2;
 715                 self.death_time = 0;
 716                 self.respawn_flags = 0;
 717                 self.respawn_time = 0;
 718                 self.stat_respawn_time = 0;
 719                 self.scale = 0;
 720                 self.fade_time = 0;
 721                 self.pain_frame = 0;
 722                 self.pain_finished = 0;
 723                 self.strength_finished = 0;
 724                 self.invincible_finished = 0;
 725                 self.pushltime = 0;
 726                 // players have no think function
 727                 self.think = func_null;
 728                 self.nextthink = 0;
 729                 self.hook_time = 0;
 730                 self.dmg_team = 0;
 731                 self.ballistics_density = autocvar_g_ballistics_density_player;
 732
 733                 self.metertime = 0;
 734
 735                 self.deadflag = DEAD_NO;
 736
 737                 self.angles = spot.angles;
 738
 739                 self.angles_z = 0; // never spawn tilted even if the spot says to
 740                 self.fixangle = TRUE; // turn this way immediately
 741                 self.velocity = '0 0 0';
 742                 self.avelocity = '0 0 0';
 743                 self.punchangle = '0 0 0';
 744                 self.punchvector = '0 0 0';
 745                 self.oldvelocity = self.velocity;
 746                 self.fire_endtime = -1;
 747
 748                 msg_entity = self;
 749                 WRITESPECTATABLE_MSG_ONE({
 750                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 751                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 752                 });
 753
 754                 self.model = "";
 755                 FixPlayermodel();
 756                 self.drawonlytoclient = world;
 757
 758                 self.crouch = FALSE;
 759                 self.view_ofs = PL_VIEW_OFS;
 760                 setsize (self, PL_MIN, PL_MAX);
 761                 self.spawnorigin = spot.origin;
 762                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 763                 // don't reset back to last position, even if new position is stuck in solid
 764                 self.oldorigin = self.origin;
 765                 self.prevorigin = self.origin;
 766                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 767                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 768         self.hud = HUD_NORMAL;
 769
 770                 self.event_damage = PlayerDamage;
 771
 772                 self.bot_attack = TRUE;
 773
 774                 self.statdraintime = time + 5;
 775                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 776
 777                 if(self.killcount == -666) {
 778                         PlayerScore_Clear(self);
 779                         self.killcount = 0;
 780                 }
 781
 782                 CL_SpawnWeaponentity();
 783                 self.alpha = default_player_alpha;
 784                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 785                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 786
 787                 self.speedrunning = FALSE;
 788
 789                 race_PostSpawn(spot);
 790
 791                 //stuffcmd(self, "chase_active 0");
 792                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 793
 794                 target_voicescript_clear(self);
 795
 796                 // reset fields the weapons may use
 797                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 798                 {
 799                         weapon_action(j, WR_RESETPLAYER);
 800
 801                         // all weapons must be fully loaded when we spawn
 802                         entity e;
 803                         e = get_weaponinfo(j);
 804                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 805                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 806                 }
 807
 808                 oldself = self;
 809                 self = spot;
 810                         activator = oldself;
 811                                 string s;
 812                                 s = self.target;
 813                                 self.target = string_null;
 814                                 SUB_UseTargets();
 815                                 self.target = s;
 816                         activator = world;
 817                 self = oldself;
 818
 819                 spawn_spot = spot;
 820                 MUTATOR_CALLHOOK(PlayerSpawn);
 821
 822                 if(autocvar_spawn_debug)
 823                 {
 824                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 825                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 826                 }
 827
 828                 self.switchweapon = w_getbestweapon(self);
 829                 self.cnt = -1; // W_LastWeapon will not complain
 830                 self.weapon = 0;
 831                 self.weaponname = "";
 832                 self.switchingweapon = 0;
 833
 834                 if(!inWarmupStage)
 835                         if(!self.alivetime)
 836                                 self.alivetime = time;
 837
 838                 antilag_clear(self);
 839
 840                 if (autocvar_g_spawnsound)
 841                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 842         } else if(self.classname == "observer") {
 843                 PutObserverInServer ();
 844         }
 845 }
 846
 847 .float ebouncefactor, ebouncestop; // electro's values
 848 // TODO do we need all these fields, or should we stop autodetecting runtime
 849 // changes and just have a console command to update this?
 850 float ClientInit_SendEntity(entity to, float sf)
 851 {
 852         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 853         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 854         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 855         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 856         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 857         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 858         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 859         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 860         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 861         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 862         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 863         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 864         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 865         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 866         if(sv_foginterval && world.fog != "")
 867                 WriteString(MSG_ENTITY, world.fog);
 868         else
 869                 WriteString(MSG_ENTITY, "");
 870         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 871         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 872         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 873         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 874         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 875         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 876         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 877         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 878         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 879         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 880         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 881         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 882         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 883         return TRUE;
 884 }
 885
 886 void ClientInit_CheckUpdate()
 887 {
 888         self.nextthink = time;
 889         if(self.count != autocvar_g_balance_armor_blockpercent)
 890         {
 891                 self.count = autocvar_g_balance_armor_blockpercent;
 892                 self.SendFlags |= 1;
 893         }
 894         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 895         {
 896                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 897                 self.SendFlags |= 1;
 898         }
 899         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 900         {
 901                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 902                 self.SendFlags |= 1;
 903         }
 904         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 905         {
 906                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 907                 self.SendFlags |= 1;
 908         }
 909         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 910         {
 911                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 912                 self.SendFlags |= 1;
 913         }
 914         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 915         {
 916                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 917                 self.SendFlags |= 1;
 918         }
 919 }
 920
 921 void ClientInit_Spawn()
 922 {
 923         entity o;
 924         entity e;
 925         e = spawn();
 926         e.classname = "clientinit";
 927         e.think = ClientInit_CheckUpdate;
 928         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 929
 930         o = self;
 931         self = e;
 932         ClientInit_CheckUpdate();
 933         self = o;
 934 }
 935
 936 /*
 937 =============
 938 SetNewParms
 939 =============
 940 */
 941 void SetNewParms (void)
 942 {
 943         // initialize parms for a new player
 944         parm1 = -(86400 * 366);
 945 }
 946
 947 /*
 948 =============
 949 SetChangeParms
 950 =============
 951 */
 952 void SetChangeParms (void)
 953 {
 954         // save parms for level change
 955         parm1 = self.parm_idlesince - time;
 956 }
 957
 958 /*
 959 =============
 960 DecodeLevelParms
 961 =============
 962 */
 963 void DecodeLevelParms (void)
 964 {
 965         // load parms
 966         self.parm_idlesince = parm1;
 967         if(self.parm_idlesince == -(86400 * 366))
 968                 self.parm_idlesince = time;
 969
 970         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 971         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 972 }
 973
 974 /*
 975 =============
 976 ClientKill
 977
 978 Called when a client types 'kill' in the console
 979 =============
 980 */
 981
 982 .float clientkill_nexttime;
 983 void ClientKill_Now_TeamChange()
 984 {
 985         if(self.killindicator_teamchange == -1)
 986         {
 987                 JoinBestTeam( self, FALSE, TRUE );
 988         }
 989         else if(self.killindicator_teamchange == -2)
 990         {
 991                 if(blockSpectators)
 992                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 993                 PutObserverInServer();
 994         }
 995         else
 996                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 997         self.killindicator_teamchange = 0;
 998 }
 999
1000 void ClientKill_Now()
1001 {
1002         if(self.vehicle)
1003         {
1004             vehicles_exit(VHEF_RELESE);
1005             if(!self.killindicator_teamchange)
1006             {
1007             self.vehicle_health = -1;
1008             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1009             }
1010         }
1011
1012         if(self.killindicator && !wasfreed(self.killindicator))
1013                 remove(self.killindicator);
1014
1015         self.killindicator = world;
1016
1017         if(self.killindicator_teamchange)
1018                 ClientKill_Now_TeamChange();
1019
1020         // in any case:
1021         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1022
1023         // now I am sure the player IS dead
1024 }
1025 void KillIndicator_Think()
1026 {
1027         if (gameover)
1028         {
1029                 self.owner.killindicator = world;
1030                 remove(self);
1031                 return;
1032         }
1033
1034         if (self.owner.alpha < 0 && !self.owner.vehicle)
1035         {
1036                 self.owner.killindicator = world;
1037                 remove(self);
1038                 return;
1039         }
1040
1041         if(self.cnt <= 0)
1042         {
1043                 self = self.owner;
1044                 ClientKill_Now(); // no oldself needed
1045                 return;
1046         }
1047     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1048     {
1049         self.nextthink = time + 1;
1050         self.cnt -= 1;
1051     }
1052         else
1053         {
1054                 if(self.cnt <= 10)
1055                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1056                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1057                 {
1058                         if(self.cnt <= 10)
1059                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1060                 }
1061                 self.nextthink = time + 1;
1062                 self.cnt -= 1;
1063         }
1064 }
1065
1066 float clientkilltime;
1067 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1068 {
1069         float killtime;
1070         float starttime;
1071         entity e;
1072
1073         if (gameover)
1074                 return;
1075
1076         killtime = autocvar_g_balance_kill_delay;
1077
1078         if(g_race_qualifying || g_cts)
1079                 killtime = 0;
1080
1081     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1082     {
1083                 remove(self.killindicator);
1084                 self.killindicator = world;
1085
1086         ClientKill_Now(); // allow instant kill in this case
1087         return;
1088     }
1089
1090         self.killindicator_teamchange = targetteam;
1091
1092     if(!self.killindicator)
1093         {
1094                 if(self.deadflag == DEAD_NO)
1095                 {
1096                         killtime = max(killtime, self.clientkill_nexttime - time);
1097                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1098                 }
1099
1100                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1101                 {
1102                         ClientKill_Now();
1103                 }
1104                 else
1105                 {
1106                         starttime = max(time, clientkilltime);
1107
1108                         self.killindicator = spawn();
1109                         self.killindicator.owner = self;
1110                         self.killindicator.scale = 0.5;
1111                         setattachment(self.killindicator, self, "");
1112                         setorigin(self.killindicator, '0 0 52');
1113                         self.killindicator.think = KillIndicator_Think;
1114                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1115                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1116                         self.killindicator.cnt = ceil(killtime);
1117                         self.killindicator.count = bound(0, ceil(killtime), 10);
1118                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1119
1120                         for(e = world; (e = find(e, classname, "body")) != world; )
1121                         {
1122                                 if(e.enemy != self)
1123                                         continue;
1124                                 e.killindicator = spawn();
1125                                 e.killindicator.owner = e;
1126                                 e.killindicator.scale = 0.5;
1127                                 setattachment(e.killindicator, e, "");
1128                                 setorigin(e.killindicator, '0 0 52');
1129                                 e.killindicator.think = KillIndicator_Think;
1130                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1131                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1132                                 e.killindicator.cnt = ceil(killtime);
1133                         }
1134                         self.lip = 0;
1135                 }
1136         }
1137         if(self.killindicator)
1138         {
1139                 if(targetteam == 0) // just die
1140                 {
1141                         self.killindicator.colormod = '0 0 0';
1142                         if(clienttype(self) == CLIENTTYPE_REAL)
1143                         if(self.killindicator.cnt > 0)
1144                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1145                 }
1146                 else if(targetteam == -1) // auto
1147                 {
1148                         self.killindicator.colormod = '0 1 0';
1149                         if(clienttype(self) == CLIENTTYPE_REAL)
1150                         if(self.killindicator.cnt > 0)
1151                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1152                 }
1153                 else if(targetteam == -2) // spectate
1154                 {
1155                         self.killindicator.colormod = '0.5 0.5 0.5';
1156                         if(clienttype(self) == CLIENTTYPE_REAL)
1157                         if(self.killindicator.cnt > 0)
1158                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1159                 }
1160                 else
1161                 {
1162                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1163                         if(clienttype(self) == CLIENTTYPE_REAL)
1164                         if(self.killindicator.cnt > 0)
1165                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1166                 }
1167         }
1168
1169 }
1170
1171 void ClientKill (void)
1172 {
1173         if(gameover) return;
1174         if(self.player_blocked) return;
1175         if(self.freezetag_frozen) return;
1176
1177         ClientKill_TeamChange(0);
1178 }
1179
1180 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1181 {
1182     e.killindicator = spawn();
1183     e.killindicator.owner = e;
1184     e.killindicator.think = KillIndicator_Think;
1185     e.killindicator.nextthink = time + (e.lip) * 0.05;
1186     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1187     e.killindicator.health = 1; // this is used to indicate that it should be silent
1188     e.lip = 0;
1189 }
1190
1191 void FixClientCvars(entity e)
1192 {
1193         // send prediction settings to the client
1194         stuffcmd(e, "\nin_bindmap 0 0\n");
1195         if(g_race || g_cts)
1196                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1197         if(autocvar_g_antilag == 3) // client side hitscan
1198                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1199         if(autocvar_sv_gentle)
1200                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1201         /*
1202          * we no longer need to stuff this. Remove this comment block if you feel
1203          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1204         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1205         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1206         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1207         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1208         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1209         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1210         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1211         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1212         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1213         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1214         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1215         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1216         stuffcmd(e, "cl_movement_edgefriction 1\n");
1217          */
1218 }
1219
1220 float PlayerInIDList(entity p, string idlist)
1221 {
1222         float n, i;
1223         string s;
1224
1225         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1226         if not(p.crypto_idfp)
1227                 return 0;
1228
1229         // this function allows abbreviated player IDs too!
1230         n = tokenize_console(idlist);
1231         for(i = 0; i < n; ++i)
1232         {
1233                 s = argv(i);
1234                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1235                         return 1;
1236         }
1237
1238         return 0;
1239 }
1240
1241 /*
1242 =============
1243 ClientConnect
1244
1245 Called when a client connects to the server
1246 =============
1247 */
1248 void DecodeLevelParms (void);
1249 //void dom_player_join_team(entity pl);
1250 void set_dom_state(entity e);
1251 void ClientConnect (void)
1252 {
1253         float t;
1254
1255         if(self.flags & FL_CLIENT)
1256         {
1257                 print("Warning: ClientConnect, but already connected!\n");
1258                 return;
1259         }
1260
1261         if(Ban_MaybeEnforceBanOnce(self))
1262                 return;
1263
1264         DecodeLevelParms();
1265
1266 #ifdef WATERMARK
1267         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1268 #endif
1269
1270         self.classname = "player_joining";
1271
1272         self.flags = FL_CLIENT;
1273         self.version_nagtime = time + 10 + random() * 10;
1274
1275         if(player_count<0)
1276         {
1277                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1278                 player_count = 0;
1279         }
1280
1281         PlayerScore_Attach(self);
1282         ClientData_Attach();
1283         accuracy_init(self);
1284
1285         bot_clientconnect();
1286
1287         playerdemo_init();
1288
1289         anticheat_init();
1290
1291         race_PreSpawnObserver();
1292
1293         // identify the right forced team
1294         if(autocvar_g_campaign)
1295         {
1296                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1297                 {
1298                         switch(autocvar_g_campaign_forceteam)
1299                         {
1300                                 case 1: self.team_forced = NUM_TEAM_1; break;
1301                                 case 2: self.team_forced = NUM_TEAM_2; break;
1302                                 case 3: self.team_forced = NUM_TEAM_3; break;
1303                                 case 4: self.team_forced = NUM_TEAM_4; break;
1304                                 default: self.team_forced = 0;
1305                         }
1306                 }
1307         }
1308         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1309                 self.team_forced = NUM_TEAM_1;
1310         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1311                 self.team_forced = NUM_TEAM_2;
1312         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1313                 self.team_forced = NUM_TEAM_3;
1314         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1315                 self.team_forced = NUM_TEAM_4;
1316         else if(autocvar_g_forced_team_otherwise == "red")
1317                 self.team_forced = NUM_TEAM_1;
1318         else if(autocvar_g_forced_team_otherwise == "blue")
1319                 self.team_forced = NUM_TEAM_2;
1320         else if(autocvar_g_forced_team_otherwise == "yellow")
1321                 self.team_forced = NUM_TEAM_3;
1322         else if(autocvar_g_forced_team_otherwise == "pink")
1323                 self.team_forced = NUM_TEAM_4;
1324         else if(autocvar_g_forced_team_otherwise == "spectate")
1325                 self.team_forced = -1;
1326         else if(autocvar_g_forced_team_otherwise == "spectator")
1327                 self.team_forced = -1;
1328         else
1329                 self.team_forced = 0;
1330
1331         if(!teamplay)
1332                 if(self.team_forced > 0)
1333                         self.team_forced = 0;
1334
1335         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1336
1337         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1338                 self.classname = "observer";
1339         } else {
1340                 if(teamplay)
1341                 {
1342                         if(autocvar_g_balance_teams)
1343                         {
1344                                 self.classname = "player";
1345                                 campaign_bots_may_start = 1;
1346                         }
1347                         else
1348                         {
1349                                 self.classname = "observer"; // do it anyway
1350                         }
1351                 }
1352                 else
1353                 {
1354                         self.classname = "player";
1355                         campaign_bots_may_start = 1;
1356                 }
1357         }
1358
1359         self.playerid = (playerid_last = playerid_last + 1);
1360
1361         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1362
1363     if(clienttype(self) == CLIENTTYPE_BOT)
1364         PlayerStats_AddPlayer(self);
1365
1366         if(autocvar_sv_eventlog)
1367                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1368
1369         LogTeamchange(self.playerid, self.team, 1);
1370
1371         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1372
1373         self.netname_previous = strzone(self.netname);
1374
1375         if((self.classname == STR_PLAYER && teamplay))
1376                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1377         else
1378                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1379
1380         stuffcmd(self, strcat(clientstuff, "\n"));
1381         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1382
1383         FixClientCvars(self);
1384
1385         // spawnfunc_waypoint sprites
1386         WaypointSprite_InitClient(self);
1387
1388         // Wazat's grappling hook
1389         SetGrappleHookBindings();
1390
1391         // get version info from player
1392         stuffcmd(self, "cmd clientversion $gameversion\n");
1393
1394         // get other cvars from player
1395         GetCvars(0);
1396
1397         // notify about available teams
1398         if(teamplay)
1399         {
1400                 CheckAllowedTeams(self);
1401                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1402                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1403         }
1404         else
1405                 stuffcmd(self, "set _teams_available 0\n");
1406
1407         attach_entcs();
1408
1409         bot_relinkplayerlist();
1410
1411         self.spectatortime = time;
1412         if(blockSpectators)
1413         {
1414                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1415         }
1416
1417         self.jointime = time;
1418         self.allowed_timeouts = autocvar_sv_timeout_number;
1419
1420         if(clienttype(self) == CLIENTTYPE_REAL)
1421         {
1422                 if(!autocvar_g_campaign)
1423                 {
1424                         self.motd_actived_time = -1;
1425                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1426                 }
1427
1428                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1429                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1430         }
1431
1432         if(!sv_foginterval && world.fog != "")
1433                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1434
1435         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1436         {
1437                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1438                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1439         }
1440         else
1441                 self.hitplotfh = -1;
1442
1443         if(g_race || g_cts) {
1444                 string rr;
1445                 if(g_cts)
1446                         rr = CTS_RECORD;
1447                 else
1448                         rr = RACE_RECORD;
1449
1450                 msg_entity = self;
1451                 race_send_recordtime(MSG_ONE);
1452                 race_send_speedaward(MSG_ONE);
1453
1454                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1455                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1456                 race_send_speedaward_alltimebest(MSG_ONE);
1457
1458                 float i;
1459                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1460                         race_SendRankings(i, 0, 0, MSG_ONE);
1461                 }
1462         }
1463         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1464                 send_CSQC_teamnagger();
1465
1466         CheatInitClient();
1467
1468         CSQCMODEL_AUTOINIT();
1469
1470         self.model_randomizer = random();
1471
1472         if(clienttype(self) == CLIENTTYPE_REAL)
1473                 sv_notice_join();
1474
1475         MUTATOR_CALLHOOK(ClientConnect);
1476 }
1477 /*
1478 =============
1479 ClientDisconnect
1480
1481 Called when a client disconnects from the server
1482 =============
1483 */
1484 .entity chatbubbleentity;
1485 void ReadyCount();
1486 void ClientDisconnect (void)
1487 {
1488         if(self.vehicle)
1489             vehicles_exit(VHEF_RELESE);
1490
1491         if not(self.flags & FL_CLIENT)
1492         {
1493                 print("Warning: ClientDisconnect without ClientConnect\n");
1494                 return;
1495         }
1496
1497         PlayerStats_AddGlobalInfo(self);
1498
1499         CheatShutdownClient();
1500
1501         if(self.hitplotfh >= 0)
1502         {
1503                 fclose(self.hitplotfh);
1504                 self.hitplotfh = -1;
1505         }
1506
1507         anticheat_report();
1508         anticheat_shutdown();
1509
1510         playerdemo_shutdown();
1511
1512         bot_clientdisconnect();
1513
1514         if(self.entcs)
1515                 detach_entcs();
1516
1517         if(autocvar_sv_eventlog)
1518                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1519
1520         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1521
1522         MUTATOR_CALLHOOK(ClientDisconnect);
1523
1524         Portal_ClearAll(self);
1525
1526         RemoveGrapplingHook(self);
1527
1528         // Here, everything has been done that requires this player to be a client.
1529
1530         self.flags &~= FL_CLIENT;
1531
1532         if (self.chatbubbleentity)
1533                 remove (self.chatbubbleentity);
1534
1535         if (self.killindicator)
1536                 remove (self.killindicator);
1537
1538         WaypointSprite_PlayerGone();
1539
1540         bot_relinkplayerlist();
1541
1542         accuracy_free(self);
1543         ClientData_Detach();
1544         PlayerScore_Detach(self);
1545
1546         if(self.netname_previous)
1547                 strunzone(self.netname_previous);
1548         if(self.clientstatus)
1549                 strunzone(self.clientstatus);
1550         if(self.weaponorder_byimpulse)
1551                 strunzone(self.weaponorder_byimpulse);
1552
1553         ClearPlayerSounds();
1554
1555         if(self.personal)
1556                 remove(self.personal);
1557
1558         self.playerid = 0;
1559         ReadyCount();
1560
1561         // free cvars
1562         GetCvars(-1);
1563 }
1564
1565 .float BUTTON_CHAT;
1566 void ChatBubbleThink()
1567 {
1568         self.nextthink = time;
1569         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1570         {
1571                 if(self.owner) // but why can that ever be world?
1572                         self.owner.chatbubbleentity = world;
1573                 remove(self);
1574                 return;
1575         }
1576         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1577 #ifdef TETRIS
1578                 || self.owner.tetris_on
1579 #endif
1580         )
1581                 self.model = self.mdl;
1582         else
1583                 self.model = "";
1584 }
1585
1586 void UpdateChatBubble()
1587 {
1588         if (self.alpha < 0)
1589                 return;
1590         // spawn a chatbubble entity if needed
1591         if (!self.chatbubbleentity)
1592         {
1593                 self.chatbubbleentity = spawn();
1594                 self.chatbubbleentity.owner = self;
1595                 self.chatbubbleentity.exteriormodeltoclient = self;
1596                 self.chatbubbleentity.think = ChatBubbleThink;
1597                 self.chatbubbleentity.nextthink = time;
1598                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1599                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1600                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1601                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1602                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1603                 self.chatbubbleentity.model = "";
1604                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1605         }
1606 }
1607
1608
1609 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1610 // added to the model skins
1611 /*void UpdateColorModHack()
1612 {
1613         float c;
1614         c = self.clientcolors & 15;
1615         // LordHavoc: only bothering to support white, green, red, yellow, blue
1616              if (!teamplay) self.colormod = '0 0 0';
1617         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1618         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1619         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1620         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1621         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1622         else self.colormod = '1 1 1';
1623 }*/
1624
1625 void respawn(void)
1626 {
1627         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1628         {
1629                 self.solid = SOLID_NOT;
1630                 self.takedamage = DAMAGE_NO;
1631                 self.movetype = MOVETYPE_FLY;
1632                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1633                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1634                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1635                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1636                 if(autocvar_g_respawn_ghosts_maxtime)
1637                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1638         }
1639
1640         CopyBody(1);
1641
1642         self.effects |= EF_NODRAW; // prevent another CopyBody
1643         PutClientInServer();
1644 }
1645
1646 void play_countdown(float finished, string samp)
1647 {
1648         if(clienttype(self) == CLIENTTYPE_REAL)
1649                 if(floor(finished - time - frametime) != floor(finished - time))
1650                         if(finished - time < 6)
1651                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1652 }
1653
1654 void player_powerups (void)
1655 {
1656         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1657         olditems = self.items;
1658
1659         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1660                 self.modelflags |= MF_ROCKET;
1661         else
1662                 self.modelflags &~= MF_ROCKET;
1663
1664         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1665
1666         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1667                 return;
1668
1669         Fire_ApplyDamage(self);
1670         Fire_ApplyEffect(self);
1671
1672         if (g_minstagib)
1673         {
1674                 self.effects |= EF_FULLBRIGHT;
1675
1676                 if (self.items & IT_STRENGTH)
1677                 {
1678                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1679                         if (time > self.strength_finished)
1680                         {
1681                                 self.alpha = default_player_alpha;
1682                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1683                                 self.items &~= IT_STRENGTH;
1684                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1685                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1686                         }
1687                 }
1688                 else
1689                 {
1690                         if (time < self.strength_finished)
1691                         {
1692                                 self.alpha = g_minstagib_invis_alpha;
1693                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1694                                 self.items |= IT_STRENGTH;
1695                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1696                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1697                         }
1698                 }
1699
1700                 if (self.items & IT_INVINCIBLE)
1701                 {
1702                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1703                         if (time > self.invincible_finished)
1704                         {
1705                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1706                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1707                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1708                         }
1709                 }
1710                 else
1711                 {
1712                         if (time < self.invincible_finished)
1713                         {
1714                                 self.items = self.items | IT_INVINCIBLE;
1715                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1716                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1717                         }
1718                 }
1719         }
1720         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1721         {
1722                 if (self.items & IT_STRENGTH)
1723                 {
1724                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1725                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1726                         if (time > self.strength_finished)
1727                         {
1728                                 self.items = self.items - (self.items & IT_STRENGTH);
1729                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1730                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1731                         }
1732                 }
1733                 else
1734                 {
1735                         if (time < self.strength_finished)
1736                         {
1737                                 self.items = self.items | IT_STRENGTH;
1738                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1739                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1740                         }
1741                 }
1742                 if (self.items & IT_INVINCIBLE)
1743                 {
1744                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1745                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1746                         if (time > self.invincible_finished)
1747                         {
1748                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1749                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1750                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1751                         }
1752                 }
1753                 else
1754                 {
1755                         if (time < self.invincible_finished)
1756                         {
1757                                 self.items = self.items | IT_INVINCIBLE;
1758                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1759                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1760                         }
1761                 }
1762                 if (self.items & IT_SUPERWEAPON)
1763                 {
1764                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1765                         {
1766                                 self.superweapons_finished = 0;
1767                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1768                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1769                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1770                         }
1771                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1772                         {
1773                                 // don't let them run out
1774                         }
1775                         else
1776                         {
1777                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1778                                 if (time > self.superweapons_finished)
1779                                 {
1780                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1781                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1782                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1783                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1784                                 }
1785                         }
1786                 }
1787                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1788                 {
1789                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1790                         {
1791                                 self.items = self.items | IT_SUPERWEAPON;
1792                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1793                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1794                         }
1795                         else
1796                         {
1797                                 self.superweapons_finished = 0;
1798                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1799                         }
1800                 }
1801                 else
1802                 {
1803                         self.superweapons_finished = 0;
1804                 }
1805         }
1806
1807         if(autocvar_g_nodepthtestplayers)
1808                 self.effects = self.effects | EF_NODEPTHTEST;
1809
1810         if(autocvar_g_fullbrightplayers)
1811                 self.effects = self.effects | EF_FULLBRIGHT;
1812
1813         // midair gamemode: damage only while in the air
1814         // if in midair mode, being on ground grants temporary invulnerability
1815         // (this is so that multishot weapon don't clear the ground flag on the
1816         // first damage in the frame, leaving the player vulnerable to the
1817         // remaining hits in the same frame)
1818         if (self.flags & FL_ONGROUND)
1819         if (g_midair)
1820                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1821
1822         if (time >= game_starttime)
1823         if (time < self.spawnshieldtime)
1824                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1825
1826         MUTATOR_CALLHOOK(PlayerPowerups);
1827 }
1828
1829 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1830 {
1831         if(current > stable)
1832                 return current;
1833         else if(current > stable - 0.25) // when close enough, "snap"
1834                 return stable;
1835         else
1836                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1837 }
1838
1839 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1840 {
1841         if(current < stable)
1842                 return current;
1843         else if(current < stable + 0.25) // when close enough, "snap"
1844                 return stable;
1845         else
1846                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1847 }
1848
1849 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1850 {
1851         if(current > rotstable)
1852         {
1853                 if(rotframetime > 0)
1854                 {
1855                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1856                         current = max(rotstable, current - rotlinear * rotframetime);
1857                 }
1858         }
1859         else if(current < regenstable)
1860         {
1861                 if(regenframetime > 0)
1862                 {
1863                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1864                         current = min(regenstable, current + regenlinear * regenframetime);
1865                 }
1866         }
1867
1868         if(current > limit)
1869                 current = limit;
1870
1871         return current;
1872 }
1873
1874 void player_regen (void)
1875 {
1876         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1877         maxh = autocvar_g_balance_health_rotstable;
1878         maxa = autocvar_g_balance_armor_rotstable;
1879         maxf = autocvar_g_balance_fuel_rotstable;
1880         minh = autocvar_g_balance_health_regenstable;
1881         mina = autocvar_g_balance_armor_regenstable;
1882         minf = autocvar_g_balance_fuel_regenstable;
1883         limith = autocvar_g_balance_health_limit;
1884         limita = autocvar_g_balance_armor_limit;
1885         limitf = autocvar_g_balance_fuel_limit;
1886
1887         max_mod = regen_mod = rot_mod = limit_mod = 1;
1888
1889         maxh = maxh * max_mod;
1890         //maxa = maxa * max_mod;
1891         //maxf = maxf * max_mod;
1892         minh = minh * max_mod;
1893         //mina = mina * max_mod;
1894         //minf = minf * max_mod;
1895         limith = limith * limit_mod;
1896         limita = limita * limit_mod;
1897         //limitf = limitf * limit_mod;
1898
1899         if(g_ca)
1900                 rot_mod = 0;
1901
1902         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1903         {
1904                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1905                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1906
1907                 // if player rotted to death...  die!
1908                 if(self.health < 1)
1909                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1910         }
1911
1912         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1913                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1914 }
1915
1916 float zoomstate_set;
1917 void SetZoomState(float z)
1918 {
1919         if(z != self.zoomstate)
1920         {
1921                 self.zoomstate = z;
1922                 ClientData_Touch(self);
1923         }
1924         zoomstate_set = 1;
1925 }
1926
1927 void GetPressedKeys(void) {
1928         MUTATOR_CALLHOOK(GetPressedKeys);
1929         if (self.movement_x > 0) // get if movement keys are pressed
1930         {       // forward key pressed
1931                 self.pressedkeys |= KEY_FORWARD;
1932                 self.pressedkeys &~= KEY_BACKWARD;
1933         }
1934         else if (self.movement_x < 0)
1935         {       // backward key pressed
1936                 self.pressedkeys |= KEY_BACKWARD;
1937                 self.pressedkeys &~= KEY_FORWARD;
1938         }
1939         else
1940         {       // no x input
1941                 self.pressedkeys &~= KEY_FORWARD;
1942                 self.pressedkeys &~= KEY_BACKWARD;
1943         }
1944
1945         if (self.movement_y > 0)
1946         {       // right key pressed
1947                 self.pressedkeys |= KEY_RIGHT;
1948                 self.pressedkeys &~= KEY_LEFT;
1949         }
1950         else if (self.movement_y < 0)
1951         {       // left key pressed
1952                 self.pressedkeys |= KEY_LEFT;
1953                 self.pressedkeys &~= KEY_RIGHT;
1954         }
1955         else
1956         {       // no y input
1957                 self.pressedkeys &~= KEY_RIGHT;
1958                 self.pressedkeys &~= KEY_LEFT;
1959         }
1960
1961         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1962                 self.pressedkeys |= KEY_JUMP;
1963         else
1964                 self.pressedkeys &~= KEY_JUMP;
1965         if (self.BUTTON_CROUCH)
1966                 self.pressedkeys |= KEY_CROUCH;
1967         else
1968                 self.pressedkeys &~= KEY_CROUCH;
1969
1970         if (self.BUTTON_ATCK)
1971                 self.pressedkeys |= KEY_ATCK;
1972         else
1973                 self.pressedkeys &~= KEY_ATCK;
1974         if (self.BUTTON_ATCK2)
1975                 self.pressedkeys |= KEY_ATCK2;
1976         else
1977                 self.pressedkeys &~= KEY_ATCK2;
1978 }
1979
1980 /*
1981 ======================
1982 spectate mode routines
1983 ======================
1984 */
1985
1986 void SpectateCopy(entity spectatee) {
1987         other = spectatee;
1988         MUTATOR_CALLHOOK(SpectateCopy);
1989         self.armortype = spectatee.armortype;
1990         self.armorvalue = spectatee.armorvalue;
1991         self.ammo_cells = spectatee.ammo_cells;
1992         self.ammo_shells = spectatee.ammo_shells;
1993         self.ammo_nails = spectatee.ammo_nails;
1994         self.ammo_rockets = spectatee.ammo_rockets;
1995         self.ammo_fuel = spectatee.ammo_fuel;
1996         self.clip_load = spectatee.clip_load;
1997         self.clip_size = spectatee.clip_size;
1998         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1999         self.health = spectatee.health;
2000         self.impulse = 0;
2001         self.items = spectatee.items;
2002         self.last_pickup = spectatee.last_pickup;
2003         self.hit_time = spectatee.hit_time;
2004         self.metertime = spectatee.metertime;
2005         self.strength_finished = spectatee.strength_finished;
2006         self.invincible_finished = spectatee.invincible_finished;
2007         self.pressedkeys = spectatee.pressedkeys;
2008         WEPSET_COPY_EE(self, spectatee);
2009         self.switchweapon = spectatee.switchweapon;
2010         self.switchingweapon = spectatee.switchingweapon;
2011         self.weapon = spectatee.weapon;
2012         self.nex_charge = spectatee.nex_charge;
2013         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2014         self.hagar_load = spectatee.hagar_load;
2015         self.minelayer_mines = spectatee.minelayer_mines;
2016         self.punchangle = spectatee.punchangle;
2017         self.view_ofs = spectatee.view_ofs;
2018         self.velocity = spectatee.velocity;
2019         self.dmg_take = spectatee.dmg_take;
2020         self.dmg_save = spectatee.dmg_save;
2021         self.dmg_inflictor = spectatee.dmg_inflictor;
2022         self.v_angle = spectatee.v_angle;
2023         self.angles = spectatee.v_angle;
2024         if(!self.BUTTON_USE)
2025                 self.fixangle = TRUE;
2026         setorigin(self, spectatee.origin);
2027         setsize(self, spectatee.mins, spectatee.maxs);
2028         SetZoomState(spectatee.zoomstate);
2029
2030     anticheat_spectatecopy(spectatee);
2031         self.hud = spectatee.hud;
2032         if(spectatee.vehicle)
2033     {
2034         self.fixangle = FALSE;
2035         //self.velocity = spectatee.vehicle.velocity;
2036         self.vehicle_health = spectatee.vehicle_health;
2037         self.vehicle_shield = spectatee.vehicle_shield;
2038         self.vehicle_energy = spectatee.vehicle_energy;
2039         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2040         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2041         self.vehicle_reload1 = spectatee.vehicle_reload1;
2042         self.vehicle_reload2 = spectatee.vehicle_reload2;
2043
2044         msg_entity = self;
2045
2046         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2047             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2048             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2049             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2050
2051         //WriteByte (MSG_ONE, SVC_SETVIEW);
2052         //    WriteEntity(MSG_ONE, self);
2053         //makevectors(spectatee.v_angle);
2054         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2055     }
2056 }
2057
2058 float SpectateUpdate() {
2059         if(!self.enemy)
2060             return 0;
2061
2062         if (self == self.enemy)
2063                 return 0;
2064
2065         if(self.enemy.classname != "player")
2066                 return 0;
2067
2068         SpectateCopy(self.enemy);
2069
2070         return 1;
2071 }
2072
2073
2074 float SpectateSet()
2075 {
2076         if(self.enemy.classname != "player")
2077                 return FALSE;
2078         /*if(self.enemy.vehicle)
2079         {
2080
2081                 msg_entity = self;
2082                 WriteByte(MSG_ONE, SVC_SETVIEW);
2083                 WriteEntity(MSG_ONE, self.enemy);
2084                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2085
2086                 self.movetype = MOVETYPE_NONE;
2087                 accuracy_resend(self);
2088         }
2089         else
2090         {*/
2091                 msg_entity = self;
2092                 WriteByte(MSG_ONE, SVC_SETVIEW);
2093                 WriteEntity(MSG_ONE, self.enemy);
2094                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2095                 self.movetype = MOVETYPE_NONE;
2096                 accuracy_resend(self);
2097
2098                 if(!SpectateUpdate())
2099                         PutObserverInServer();
2100         //}
2101         return TRUE;
2102 }
2103
2104 float Spectate(entity pl)
2105 {
2106         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2107         if(pl.team != self.team)
2108                 return 0;
2109
2110         self.enemy = pl;
2111         return SpectateSet();
2112 }
2113
2114 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2115 entity CA_SpectateNext(entity start) {
2116         if (start.team == self.team) {
2117                 return start;
2118         }
2119
2120         other = start;
2121         // continue from current player
2122         while(other && other.team != self.team) {
2123                 other = find(other, classname, "player");
2124         }
2125
2126         if (!other) {
2127                 // restart from begining
2128                 other = find(other, classname, "player");
2129                 while(other && other.team != self.team) {
2130                         other = find(other, classname, "player");
2131                 }
2132         }
2133
2134         return other;
2135 }
2136
2137 float SpectateNext()
2138 {
2139         other = find(self.enemy, classname, "player");
2140
2141         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2142                 // CA and ca players when spectating enemies is forbidden
2143                 other = CA_SpectateNext(other);
2144         } else {
2145                 // other modes and ca spectators or spectating enemies is allowed
2146                 if (!other)
2147                         other = find(other, classname, "player");
2148         }
2149
2150         if (other)
2151                 self.enemy = other;
2152
2153         return SpectateSet();
2154 }
2155
2156 float SpectatePrev()
2157 {
2158         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2159         other = findchain(classname, "player");
2160         if not(other) // no player
2161                 return FALSE;
2162
2163         entity first = other;
2164         // skip players until current spectated player
2165         if(self.enemy)
2166         while(other && other != self.enemy)
2167                 other = other.chain;
2168
2169         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2170         {
2171                 do { other = other.chain; }
2172                 while(other && other.team != self.team);
2173
2174                 if not(other)
2175                 {
2176                         other = first;
2177                         while(other.team != self.team)
2178                                 other = other.chain;
2179                         if(other == self.enemy)
2180                                 return TRUE;
2181                 }
2182         }
2183         else
2184         {
2185                 if(other.chain)
2186                         other = other.chain;
2187                 else
2188                         other = first;
2189         }
2190         self.enemy = other;
2191         return SpectateSet();
2192 }
2193
2194 /*
2195 =============
2196 ShowRespawnCountdown()
2197
2198 Update a respawn countdown display.
2199 =============
2200 */
2201 void ShowRespawnCountdown()
2202 {
2203         float number;
2204         if(self.deadflag == DEAD_NO) // just respawned?
2205                 return;
2206         else
2207         {
2208                 number = ceil(self.respawn_time - time);
2209                 if(number <= 0)
2210                         return;
2211                 if(number <= self.respawn_countdown)
2212                 {
2213                         self.respawn_countdown = number - 1;
2214                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2215                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
2216                 }
2217         }
2218 }
2219
2220 void LeaveSpectatorMode()
2221 {
2222         if(self.caplayer)
2223                 return;
2224         if(nJoinAllowed(self))
2225         {
2226                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2227                 {
2228                         self.classname = "player";
2229
2230                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2231                                 { JoinBestTeam(self, FALSE, TRUE); }
2232
2233                         if(autocvar_g_campaign)
2234                                 { campaign_bots_may_start = 1; }
2235
2236                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2237
2238                         PutClientInServer();
2239
2240                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2241                 }
2242                 else
2243                         stuffcmd(self, "menu_showteamselect\n");
2244         }
2245         else
2246         {
2247                 // Player may not join because g_maxplayers is set
2248                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2249         }
2250 }
2251
2252 /**
2253  * Determines whether the player is allowed to join. This depends on cvar
2254  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2255  * it checks whether the number of currently playing players exceeds g_maxplayers.
2256  * @return int number of free slots for players, 0 if none
2257  */
2258 float nJoinAllowed(entity ignore) {
2259         if(!ignore)
2260         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2261         // so report 0 free slots if restricted
2262         {
2263                 if(autocvar_g_forced_team_otherwise == "spectate")
2264                         return 0;
2265                 if(autocvar_g_forced_team_otherwise == "spectator")
2266                         return 0;
2267         }
2268
2269         if(self.team_forced < 0)
2270                 return 0; // forced spectators can never join
2271
2272         // TODO simplify this
2273         entity e;
2274         float totalClients = 0;
2275         FOR_EACH_CLIENT(e)
2276                 if(e != ignore)
2277                         totalClients += 1;
2278
2279         if (!autocvar_g_maxplayers)
2280                 return maxclients - totalClients;
2281
2282         float currentlyPlaying = 0;
2283         FOR_EACH_REALCLIENT(e)
2284                 if(e.classname == "player" || e.caplayer == 1)
2285                         currentlyPlaying += 1;
2286
2287         if(currentlyPlaying < autocvar_g_maxplayers)
2288                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2289
2290         return 0;
2291 }
2292
2293 /**
2294  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2295  * g_maxplayers_spectator_blocktime seconds
2296  */
2297 void checkSpectatorBlock() {
2298         if(self.classname == "spectator" || self.classname == "observer") {
2299                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2300                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2301                         dropclient(self);
2302                 }
2303         }
2304 }
2305
2306 void PrintWelcomeMessage()
2307 {
2308         if(self.motd_actived_time == 0)
2309         {
2310                 if (autocvar_g_campaign) {
2311                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2312                                 self.motd_actived_time = time;
2313                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2314                         }
2315                 } else {
2316                         if (self.BUTTON_INFO) {
2317                                 self.motd_actived_time = time;
2318                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2319                         }
2320                 }
2321         }
2322         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2323         {
2324                 if (autocvar_g_campaign) {
2325                         if (self.BUTTON_INFO)
2326                                 self.motd_actived_time = time;
2327                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2328                                 self.motd_actived_time = 0;
2329                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2330                         }
2331                 } else {
2332                         if (self.BUTTON_INFO)
2333                                 self.motd_actived_time = time;
2334                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2335                                 self.motd_actived_time = 0;
2336                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2337                         }
2338                 }
2339         }
2340         else //if(self.motd_actived_time < 0) // just connected, motd is active
2341         {
2342                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2343                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2344                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2345                 {
2346                         // instanctly hide MOTD
2347                         self.motd_actived_time = 0;
2348                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2349                 }
2350         }
2351 }
2352
2353 void ObserverThink()
2354 {
2355         float prefered_movetype;
2356         if (self.flags & FL_JUMPRELEASED) {
2357                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2358                         self.flags &~= FL_JUMPRELEASED;
2359                         self.flags |= FL_SPAWNING;
2360                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2361                         self.flags &~= FL_JUMPRELEASED;
2362                         if(SpectateNext()) {
2363                                 self.classname = "spectator";
2364                         }
2365                 } else {
2366                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2367                         if (self.movetype != prefered_movetype)
2368                                 self.movetype = prefered_movetype;
2369                 }
2370         } else {
2371                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2372                         self.flags |= FL_JUMPRELEASED;
2373                         if(self.flags & FL_SPAWNING)
2374                         {
2375                                 self.flags &~= FL_SPAWNING;
2376                                 LeaveSpectatorMode();
2377                                 return;
2378                         }
2379                 }
2380         }
2381 }
2382
2383 void SpectatorThink()
2384 {
2385         if (self.flags & FL_JUMPRELEASED) {
2386                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2387                         self.flags &~= FL_JUMPRELEASED;
2388                         self.flags |= FL_SPAWNING;
2389                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2390                         self.flags &~= FL_JUMPRELEASED;
2391                         if(SpectateNext()) {
2392                                 self.classname = "spectator";
2393                         } else {
2394                                 self.classname = "observer";
2395                                 PutClientInServer();
2396                         }
2397                         self.impulse = 0;
2398                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2399                         self.flags &~= FL_JUMPRELEASED;
2400                         if(SpectatePrev()) {
2401                                 self.classname = "spectator";
2402                         } else {
2403                                 self.classname = "observer";
2404                                 PutClientInServer();
2405                         }
2406                         self.impulse = 0;
2407                 } else if (self.BUTTON_ATCK2) {
2408                         self.flags &~= FL_JUMPRELEASED;
2409                         self.classname = "observer";
2410                         PutClientInServer();
2411                 } else {
2412                         if(!SpectateUpdate())
2413                                 PutObserverInServer();
2414                 }
2415         } else {
2416                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2417                         self.flags |= FL_JUMPRELEASED;
2418                         if(self.flags & FL_SPAWNING)
2419                         {
2420                                 self.flags &~= FL_SPAWNING;
2421                                 LeaveSpectatorMode();
2422                                 return;
2423                         }
2424                 }
2425                 if(!SpectateUpdate())
2426                         PutObserverInServer();
2427         }
2428
2429         self.flags |= FL_CLIENT | FL_NOTARGET;
2430 }
2431
2432 void PlayerUseKey()
2433 {
2434         if(self.classname != "player")
2435                 return;
2436
2437         if(self.vehicle)
2438         {
2439         vehicles_exit(VHEF_NORMAL);
2440         return;
2441         }
2442
2443         // a use key was pressed; call handlers
2444         MUTATOR_CALLHOOK(PlayerUseKey);
2445 }
2446
2447 /*
2448 =============
2449 PlayerPreThink
2450
2451 Called every frame for each client before the physics are run
2452 =============
2453 */
2454 .float usekeypressed;
2455 void() nexball_setstatus;
2456 .float items_added;
2457 void PlayerPreThink (void)
2458 {
2459         WarpZone_PlayerPhysics_FixVAngle();
2460
2461         self.stat_game_starttime = game_starttime;
2462         self.stat_round_starttime = round_starttime;
2463         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2464         self.stat_leadlimit = autocvar_leadlimit;
2465
2466         if(frametime)
2467         {
2468                 // physics frames: update anticheat stuff
2469                 anticheat_prethink();
2470         }
2471
2472         if(blockSpectators && frametime)
2473                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2474                 checkSpectatorBlock();
2475
2476         zoomstate_set = 0;
2477
2478         if(self.netname_previous != self.netname)
2479         {
2480                 if(autocvar_sv_eventlog)
2481                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2482                 if(self.netname_previous)
2483                         strunzone(self.netname_previous);
2484                 self.netname_previous = strzone(self.netname);
2485         }
2486
2487         // version nagging
2488         if(self.version_nagtime)
2489                 if(self.cvar_g_xonoticversion)
2490                         if(time > self.version_nagtime)
2491                         {
2492                                 // don't notify git users
2493                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2494                                 {
2495                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2496                                         {
2497                                                 // notify release users if connecting to git
2498                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2499                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2500                                         }
2501                                         else
2502                                         {
2503                                                 float r;
2504                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2505                                                 if(r < 0)
2506                                                 {
2507                                                         // give users new version
2508                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2509                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2510                                                 }
2511                                                 else if(r > 0)
2512                                                 {
2513                                                         // notify users about old server version
2514                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2515                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2516                                                 }
2517                                         }
2518                                 }
2519                                 self.version_nagtime = 0;
2520                         }
2521
2522         // GOD MODE info
2523         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2524         {
2525                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2526                 self.max_armorvalue = 0;
2527         }
2528
2529 #ifdef TETRIS
2530         if (TetrisPreFrame())
2531                 return;
2532 #endif
2533
2534         MUTATOR_CALLHOOK(PlayerPreThink);
2535
2536         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2537         {
2538                 if(self.BUTTON_USE && !self.usekeypressed)
2539                         PlayerUseKey();
2540                 self.usekeypressed = self.BUTTON_USE;
2541         }
2542
2543         if(clienttype(self) == CLIENTTYPE_REAL)
2544                 PrintWelcomeMessage();
2545
2546         if(self.classname == "player") {
2547
2548                 CheckRules_Player();
2549
2550                 if (intermission_running)
2551                 {
2552                         IntermissionThink ();   // otherwise a button could be missed between
2553                         return;                                 // the think tics
2554                 }
2555
2556                 //don't allow the player to turn around while game is paused!
2557                 if(timeout_status == TIMEOUT_ACTIVE) {
2558                         // FIXME turn this into CSQC stuff
2559                         self.v_angle = self.lastV_angle;
2560                         self.angles = self.lastV_angle;
2561                         self.fixangle = TRUE;
2562                 }
2563
2564                 if(frametime)
2565                 {
2566                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2567                         {
2568                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2569                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2570                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2571
2572                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2573                                 {
2574                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2575                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2576                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2577                                 }
2578                         }
2579                         else
2580                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2581
2582                         player_powerups();
2583                 }
2584
2585                 if (g_minstagib)
2586                         minstagib_ammocheck();
2587
2588                 if (self.deadflag != DEAD_NO)
2589                 {
2590                         if(self.personal && g_race_qualifying)
2591                         {
2592                                 if(time > self.respawn_time)
2593                                 {
2594                                         self.respawn_time = time + 1; // only retry once a second
2595                                         self.stat_respawn_time = self.respawn_time;
2596                                         respawn();
2597                                         self.impulse = 141;
2598                                 }
2599                         }
2600                         else
2601                         {
2602                                 float button_pressed;
2603                                 if(frametime)
2604                                         player_anim();
2605                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2606
2607                                 if (self.deadflag == DEAD_DYING)
2608                                 {
2609                                         if(self.respawn_flags & RESPAWN_FORCE)
2610                                                 self.deadflag = DEAD_RESPAWNING;
2611                                         else if(!button_pressed)
2612                                                 self.deadflag = DEAD_DEAD;
2613                                 }
2614                                 else if (self.deadflag == DEAD_DEAD)
2615                                 {
2616                                         if(button_pressed)
2617                                                 self.deadflag = DEAD_RESPAWNABLE;
2618                                 }
2619                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2620                                 {
2621                                         if(!button_pressed)
2622                                                 self.deadflag = DEAD_RESPAWNING;
2623                                 }
2624                                 else if (self.deadflag == DEAD_RESPAWNING)
2625                                 {
2626                                         if(time > self.respawn_time)
2627                                         {
2628                                                 self.respawn_time = time + 1; // only retry once a second
2629                                                 respawn();
2630                                         }
2631                                 }
2632
2633                                 ShowRespawnCountdown();
2634
2635                                 if(self.respawn_flags & RESPAWN_SILENT)
2636                                         self.stat_respawn_time = 0;
2637                                 else
2638                                         self.stat_respawn_time = self.respawn_time;
2639                         }
2640
2641                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2642                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2643                                 self.stat_respawn_time *= -1;
2644
2645                         return;
2646                 }
2647
2648                 self.prevorigin = self.origin;
2649
2650                 float do_crouch = self.BUTTON_CROUCH;
2651                 if(self.hook.state)
2652                         do_crouch = 0;
2653                 if(self.health <= g_bloodloss)
2654                         do_crouch = 1;
2655                 if(self.vehicle)
2656                         do_crouch = 0;
2657                 if(self.freezetag_frozen)
2658                         do_crouch = 0;
2659                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2660                         do_crouch = 0;
2661
2662                 if (do_crouch)
2663                 {
2664                         if (!self.crouch)
2665                         {
2666                                 self.crouch = TRUE;
2667                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2668                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2669                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2670                         }
2671                 }
2672                 else
2673                 {
2674                         if (self.crouch)
2675                         {
2676                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2677                                 if (!trace_startsolid)
2678                                 {
2679                                         self.crouch = FALSE;
2680                                         self.view_ofs = PL_VIEW_OFS;
2681                                         setsize (self, PL_MIN, PL_MAX);
2682                                 }
2683                         }
2684                 }
2685
2686                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2687                 {
2688                         if(self.bloodloss_timer < time)
2689                         {
2690                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2691                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2692                         }
2693                 }
2694
2695                 FixPlayermodel();
2696
2697                 GrapplingHookFrame();
2698
2699                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2700                 //if(frametime)
2701                 {
2702                         self.items &~= self.items_added;
2703
2704                         W_WeaponFrame();
2705
2706                         self.items_added = 0;
2707                         if(self.items & IT_JETPACK)
2708                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2709                                         self.items_added |= IT_FUEL;
2710
2711                         self.items |= self.items_added;
2712                 }
2713
2714                 player_regen();
2715
2716                 // rot nex charge to the charge limit
2717                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2718                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2719
2720                 if(frametime)
2721                         player_anim();
2722
2723                 if(g_nexball)
2724                         nexball_setstatus();
2725
2726                 // secret status
2727                 secrets_setstatus();
2728
2729                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2730
2731                 //self.angles_y=self.v_angle_y + 90;   // temp
2732         } else if(gameover) {
2733                 if (intermission_running)
2734                         IntermissionThink ();   // otherwise a button could be missed between
2735                 return;
2736         } else if(self.classname == "observer") {
2737                 ObserverThink();
2738         } else if(self.classname == "spectator") {
2739                 SpectatorThink();
2740         }
2741
2742         if(!zoomstate_set)
2743                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2744
2745         float oldspectatee_status;
2746         oldspectatee_status = self.spectatee_status;
2747         if(self.classname == "spectator")
2748                 self.spectatee_status = num_for_edict(self.enemy);
2749         else if(self.classname == "observer")
2750                 self.spectatee_status = num_for_edict(self);
2751         else
2752                 self.spectatee_status = 0;
2753         if(self.spectatee_status != oldspectatee_status)
2754         {
2755                 ClientData_Touch(self);
2756                 if(g_race || g_cts)
2757                         race_InitSpectator();
2758         }
2759
2760         if(self.teamkill_soundtime)
2761         if(time > self.teamkill_soundtime)
2762         {
2763                 self.teamkill_soundtime = 0;
2764
2765                 entity oldpusher, oldself;
2766
2767                 oldself = self; self = self.teamkill_soundsource;
2768                 oldpusher = self.pusher; self.pusher = oldself;
2769
2770                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2771
2772                 self.pusher = oldpusher;
2773                 self = oldself;
2774         }
2775
2776         if(self.taunt_soundtime)
2777         if(time > self.taunt_soundtime)
2778         {
2779                 self.taunt_soundtime = 0;
2780                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2781         }
2782
2783         target_voicescript_next(self);
2784
2785         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2786         if(!self.weapon)
2787                 self.clip_load = self.clip_size = 0;
2788 }
2789
2790 float isInvisibleString(string s)
2791 {
2792         float i, n, c;
2793         s = strdecolorize(s);
2794         for((i = 0), (n = strlen(s)); i < n; ++i)
2795         {
2796                 c = str2chr(s, i);
2797                 switch(c)
2798                 {
2799                         case 0:
2800                         case 32: // space
2801                                 break;
2802                         case 192: // charmap space
2803                                 if (!autocvar_utf8_enable)
2804                                         break;
2805                                 return FALSE;
2806                         case 160: // space in unicode fonts
2807                         case 0xE000 + 192: // utf8 charmap space
2808                                 if (autocvar_utf8_enable)
2809                                         break;
2810                         default:
2811                                 return FALSE;
2812                 }
2813         }
2814         return TRUE;
2815 }
2816
2817 /*
2818 =============
2819 PlayerPostThink
2820
2821 Called every frame for each client after the physics are run
2822 =============
2823 */
2824 .float idlekick_lasttimeleft;
2825 void PlayerPostThink (void)
2826 {
2827         // Savage: Check for nameless players
2828         if (isInvisibleString(self.netname)) {
2829                 self.netname = "Player";
2830                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2831         }
2832
2833         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2834         {
2835                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2836                 {
2837                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2838                 }
2839                 else
2840                 {
2841                         float timeleft;
2842                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2843                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2844                         {
2845                                 if(!self.idlekick_lasttimeleft)
2846                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2847                         }
2848                         if(timeleft <= 0)
2849                         {
2850                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2851                                 dropclient(self);
2852                                 return;
2853                         }
2854                         else if(timeleft <= 10)
2855                         {
2856                                 if(timeleft != self.idlekick_lasttimeleft)
2857                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2858                                 self.idlekick_lasttimeleft = timeleft;
2859                         }
2860                 }
2861         }
2862
2863 #ifdef TETRIS
2864         if(self.impulse == 100)
2865                 ImpulseCommands();
2866         if (!TetrisPostFrame())
2867         {
2868 #endif
2869
2870         CheatFrame();
2871
2872         //CheckPlayerJump();
2873
2874         if(self.classname == "player") {
2875                 CheckRules_Player();
2876                 UpdateChatBubble();
2877                 if (self.impulse)
2878                         ImpulseCommands();
2879                 if (intermission_running)
2880                         return;         // intermission or finale
2881                 GetPressedKeys();
2882         }
2883
2884 #ifdef TETRIS
2885         }
2886 #endif
2887
2888         /*
2889         float i;
2890         for(i = 0; i < 1000; ++i)
2891         {
2892                 vector end;
2893                 end = self.origin + '0 0 1024' + 512 * randomvec();
2894                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2895                 if(trace_fraction < 1)
2896                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2897                 {
2898                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2899                         break;
2900                 }
2901         }
2902         */
2903
2904         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2905
2906         if(self.waypointsprite_attachedforcarrier)
2907                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2908
2909         playerdemo_write();
2910
2911         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2912         {
2913                 if not(self.stored_netname)
2914                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2915                 if(self.stored_netname != self.netname)
2916                 {
2917                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2918                         strunzone(self.stored_netname);
2919                         self.stored_netname = strzone(self.netname);
2920                 }
2921         }
2922
2923         /*
2924         if(g_race)
2925                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2926         */
2927
2928         CSQCMODEL_AUTOUPDATE();
2929 }