qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 .float ladder_time;
   5 .entity ladder_entity;
   6 .float gravity;
   7 .float swamp_slowdown;
   8 .float lastflags;
   9 .float lastground;
  10 .float wasFlying;
  11 .float spectatorspeed;
  12
  13 .float multijump_count;
  14 .float multijump_ready;
  15 .float prevjumpbutton;
  16
  17 /*
  18 =============
  19 PlayerJump
  20
  21 When you press the jump key
  22 =============
  23 */
  24 void PlayerJump (void)
  25 {
  26         if(self.freezetag_frozen)
  27                 return; // no jumping in freezetag when frozen
  28
  29         float mjumpheight;
  30         float doublejump;
  31
  32         doublejump = FALSE;
  33         if (autocvar_sv_doublejump)
  34         {
  35                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  36                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  37                         doublejump = TRUE;
  38         }
  39
  40         mjumpheight = autocvar_sv_jumpvelocity;
  41         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  42         {
  43                 if (self.watertype == CONTENT_WATER)
  44                         self.velocity_z = 200;
  45                 else if (self.watertype == CONTENT_SLIME)
  46                         self.velocity_z = 80;
  47                 else
  48                         self.velocity_z = 50;
  49
  50                 return;
  51         }
  52
  53         if (autocvar_g_multijump)
  54         {
  55                 if (self.prevjumpbutton == FALSE && !(self.flags & FL_ONGROUND)) // jump button pressed this frame and we are in midair
  56                         self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  57                 else
  58                         self.multijump_ready = FALSE;
  59         }
  60
  61         if(!doublejump && self.multijump_ready && self.multijump_count < autocvar_g_multijump && self.velocity_z > autocvar_g_multijump_speed)
  62         {
  63                 // doublejump = FALSE; // checked above in the if
  64                 if (autocvar_g_multijump)
  65                 {
  66                         if (autocvar_g_multijump_add == 0) // in this case we make the z velocity == jumpvelocity
  67                         {
  68                                 if (self.velocity_z < mjumpheight)
  69                                 {
  70                                         doublejump = TRUE;
  71                                         self.velocity_z = 0;
  72                                 }
  73                         }
  74                         else
  75                                 doublejump = TRUE;
  76
  77                         if(doublejump)
  78                         {
  79                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
  80                                 {
  81                                         float curspeed;
  82                                         vector wishvel, wishdir;
  83
  84                                         curspeed = max(
  85                                                 vlen(vec2(self.velocity)), // current xy speed
  86                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
  87                                         );
  88                                         makevectors(self.v_angle_y * '0 1 0');
  89                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
  90                                         wishdir = normalize(wishvel);
  91
  92                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
  93                                         self.velocity_y = wishdir_y * curspeed;
  94                                         // keep velocity_z unchanged!
  95                                 }
  96                                 if (autocvar_g_multijump > 0)
  97                                         self.multijump_count += 1;
  98                         }
  99                 }
 100                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
 101         }
 102
 103         if (!doublejump)
 104                 if (!(self.flags & FL_ONGROUND))
 105                         return;
 106
 107         if(!sv_pogostick)
 108                 if (!(self.flags & FL_JUMPRELEASED))
 109                         return;
 110
 111         if(self.health <= g_bloodloss)
 112                 return;
 113
 114         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 115         // velocity bounds.  Final velocity is bound between (jumpheight *
 116         // min + jumpheight) and (jumpheight * max + jumpheight);
 117
 118         if(autocvar_sv_jumpspeedcap_min != "")
 119         {
 120                 float minjumpspeed;
 121
 122                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
 123
 124                 if (self.velocity_z < minjumpspeed)
 125                         mjumpheight += minjumpspeed - self.velocity_z;
 126         }
 127
 128         if(autocvar_sv_jumpspeedcap_max != "")
 129         {
 130                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 131                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 132
 133                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
 134                 {
 135                         float maxjumpspeed;
 136
 137                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
 138
 139                         if (self.velocity_z > maxjumpspeed)
 140                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 141                 }
 142         }
 143
 144         if(!(self.lastflags & FL_ONGROUND))
 145         {
 146                 if(autocvar_speedmeter)
 147                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 148                 if(self.lastground < time - 0.3)
 149                 {
 150                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
 151                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
 152                 }
 153                 if(self.jumppadcount > 1)
 154                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 155                 self.jumppadcount = 0;
 156         }
 157
 158         self.velocity_z = self.velocity_z + mjumpheight;
 159         self.oldvelocity_z = self.velocity_z;
 160
 161         self.flags &~= FL_ONGROUND;
 162         self.flags &~= FL_JUMPRELEASED;
 163
 164         if (self.crouch)
 165                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 166         else
 167                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 168
 169         if(g_jump_grunt)
 170                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 171
 172         self.restart_jump = -1; // restart jump anim next time
 173         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 174 }
 175
 176 void CheckWaterJump()
 177 {
 178         local vector start, end;
 179
 180 // check for a jump-out-of-water
 181         makevectors (self.angles);
 182         start = self.origin;
 183         start_z = start_z + 8;
 184         v_forward_z = 0;
 185         normalize(v_forward);
 186         end = start + v_forward*24;
 187         traceline (start, end, TRUE, self);
 188         if (trace_fraction < 1)
 189         {       // solid at waist
 190                 start_z = start_z + self.maxs_z - 8;
 191                 end = start + v_forward*24;
 192                 self.movedir = trace_plane_normal * -50;
 193                 traceline (start, end, TRUE, self);
 194                 if (trace_fraction == 1)
 195                 {       // open at eye level
 196                         self.flags |= FL_WATERJUMP;
 197                         self.velocity_z = 225;
 198                         self.flags &~= FL_JUMPRELEASED;
 199                         self.teleport_time = time + 2;  // safety net
 200                         return;
 201                 }
 202         }
 203 };
 204
 205 float racecar_angle(float forward, float down)
 206 {
 207         float ret, angle_mult;
 208
 209         if(forward < 0)
 210         {
 211                 forward = -forward;
 212                 down = -down;
 213         }
 214
 215         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 216
 217         angle_mult = forward / (800 + forward);
 218
 219         if(ret > 180)
 220                 return ret * angle_mult + 360 * (1 - angle_mult);
 221         else
 222                 return ret * angle_mult;
 223 }
 224
 225 void RaceCarPhysics()
 226 {
 227         // using this move type for "big rigs"
 228         // the engine does not push the entity!
 229
 230         float accel, steer, f, myspeed, steerfactor;
 231         vector angles_save, rigvel;
 232
 233         angles_save = self.angles;
 234         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 235         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 236
 237         if(g_bugrigs_reverse_speeding)
 238         {
 239                 if(accel < 0)
 240                 {
 241                         // back accel is DIGITAL
 242                         // to prevent speedhack
 243                         if(accel < -0.5)
 244                                 accel = -1;
 245                         else
 246                                 accel = 0;
 247                 }
 248         }
 249
 250         self.angles_x = 0;
 251         self.angles_z = 0;
 252         makevectors(self.angles); // new forward direction!
 253
 254         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 255         {
 256                 float upspeed, accelfactor;
 257
 258                 myspeed = self.velocity * v_forward;
 259                 upspeed = self.velocity * v_up;
 260
 261                 // responsiveness factor for steering and acceleration
 262                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 263                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 264
 265                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 266                         steerfactor = -myspeed * g_bugrigs_steer;
 267                 else
 268                         steerfactor = -myspeed * f * g_bugrigs_steer;
 269
 270                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 271                         accelfactor = g_bugrigs_accel;
 272                 else
 273                         accelfactor = f * g_bugrigs_accel;
 274                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 275
 276                 if(accel < 0)
 277                 {
 278                         if(myspeed > 0)
 279                         {
 280                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 281                         }
 282                         else
 283                         {
 284                                 if(!g_bugrigs_reverse_speeding)
 285                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 286                         }
 287                 }
 288                 else
 289                 {
 290                         if(myspeed >= 0)
 291                         {
 292                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 293                         }
 294                         else
 295                         {
 296                                 if(g_bugrigs_reverse_stopping)
 297                                         myspeed = 0;
 298                                 else
 299                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 300                         }
 301                 }
 302                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 303                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 304
 305                 self.angles_y += steer * frametime * steerfactor; // apply steering
 306                 makevectors(self.angles); // new forward direction!
 307
 308                 myspeed += accel * accelfactor * frametime;
 309
 310                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 311         }
 312         else
 313         {
 314                 myspeed = vlen(self.velocity);
 315
 316                 // responsiveness factor for steering and acceleration
 317                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 318                 steerfactor = -myspeed * f;
 319                 self.angles_y += steer * frametime * steerfactor; // apply steering
 320
 321                 rigvel = self.velocity;
 322                 makevectors(self.angles); // new forward direction!
 323         }
 324
 325         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 326         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 327         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 328         //MAXIMA: solve(total_acceleration(v) = 0, v);
 329
 330         if(g_bugrigs_planar_movement)
 331         {
 332                 vector rigvel_xy, neworigin, up;
 333                 float mt;
 334
 335                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 336                 rigvel_xy = vec2(rigvel);
 337
 338                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 339                         mt = MOVE_NORMAL;
 340                 else
 341                         mt = MOVE_NOMONSTERS;
 342
 343                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 344                 up = trace_endpos - self.origin;
 345
 346                 // BUG RIGS: align the move to the surface instead of doing collision testing
 347                 // can we move?
 348                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 349
 350                 // align to surface
 351                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 352
 353                 if(trace_fraction < 0.5)
 354                 {
 355                         trace_fraction = 1;
 356                         neworigin = self.origin;
 357                 }
 358                 else
 359                         neworigin = trace_endpos;
 360
 361                 if(trace_fraction < 1)
 362                 {
 363                         // now set angles_x so that the car points parallel to the surface
 364                         self.angles = vectoangles(
 365                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 366                                         +
 367                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 368                                         +
 369                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 370                                         );
 371                         self.flags |= FL_ONGROUND;
 372                 }
 373                 else
 374                 {
 375                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 376                         self.flags &~= FL_ONGROUND;
 377                 }
 378
 379                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 380                 self.movetype = MOVETYPE_NOCLIP;
 381         }
 382         else
 383         {
 384                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 385                 self.velocity = rigvel;
 386                 self.movetype = MOVETYPE_FLY;
 387         }
 388
 389         trace_fraction = 1;
 390         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 391         if(trace_fraction != 1)
 392         {
 393                 self.angles = vectoangles2(
 394                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 395                                 +
 396                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 397                                 +
 398                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 399                                 trace_plane_normal
 400                                 );
 401         }
 402         else
 403         {
 404                 vector vel_local;
 405
 406                 vel_local_x = v_forward * self.velocity;
 407                 vel_local_y = v_right * self.velocity;
 408                 vel_local_z = v_up * self.velocity;
 409
 410                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 411                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 412         }
 413
 414         // smooth the angles
 415         vector vf1, vu1, smoothangles;
 416         makevectors(self.angles);
 417         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 418         if(f == 0)
 419                 f = 1;
 420         vf1 = v_forward * f;
 421         vu1 = v_up * f;
 422         makevectors(angles_save);
 423         vf1 = vf1 + v_forward * (1 - f);
 424         vu1 = vu1 + v_up * (1 - f);
 425         smoothangles = vectoangles2(vf1, vu1);
 426         self.angles_x = -smoothangles_x;
 427         self.angles_z =  smoothangles_z;
 428 }
 429
 430 float IsMoveInDirection(vector mv, float angle) // key mix factor
 431 {
 432         if(mv_x == 0 && mv_y == 0)
 433                 return 0; // avoid division by zero
 434         angle -= RAD2DEG * atan2(mv_y, mv_x);
 435         angle = remainder(angle, 360) / 45;
 436         if(angle >  1)
 437                 return 0;
 438         if(angle < -1)
 439                 return 0;
 440         return 1 - fabs(angle);
 441 }
 442
 443 float GeomLerp(float a, float lerp, float b)
 444 {
 445         if(a == 0)
 446         {
 447                 if(lerp < 1)
 448                         return 0;
 449                 else
 450                         return b;
 451         }
 452         if(b == 0)
 453         {
 454                 if(lerp > 0)
 455                         return 0;
 456                 else
 457                         return a;
 458         }
 459         return a * pow(fabs(b / a), lerp);
 460 }
 461
 462 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 463 {
 464         float zspeed, xyspeed, dot, k;
 465
 466 #if 0
 467         // this doesn't play well with analog input
 468         if(self.movement_x == 0 || self.movement_y != 0)
 469                 return; // can't control movement if not moving forward or backward
 470         k = 32;
 471 #else
 472         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 473         if(k <= 0)
 474                 return;
 475 #endif
 476
 477         k *= bound(0, wishspeed / autocvar_sv_maxairspeed, 1);
 478
 479         zspeed = self.velocity_z;
 480         self.velocity_z = 0;
 481         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 482
 483         dot = self.velocity * wishdir;
 484
 485         if(dot > 0) // we can't change direction while slowing down
 486         {
 487                 k *= pow(dot, autocvar_sv_aircontrol_power)*frametime;
 488                 xyspeed = max(0, xyspeed - autocvar_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 489                 k *= autocvar_sv_aircontrol;
 490                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 491         }
 492
 493         self.velocity = self.velocity * xyspeed;
 494         self.velocity_z = zspeed;
 495 }
 496
 497 float AdjustAirAccelQW(float accelqw, float factor)
 498 {
 499         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 500 }
 501
 502 // example config for alternate speed clamping:
 503 //   sv_airaccel_qw 0.8
 504 //   sv_airaccel_sideways_friction 0
 505 //   prvm_globalset server speedclamp_mode 1
 506 //     (or 2)
 507 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric, float speedlimit)
 508 {
 509         float vel_straight;
 510         float vel_z;
 511         vector vel_perpend;
 512         float step;
 513
 514         vector vel_xy;
 515         float vel_xy_current;
 516         float vel_xy_backward, vel_xy_forward;
 517         float speedclamp;
 518
 519         if(accelqw < 0)
 520         {
 521 #ifdef SPEEDCLAMP
 522                 speedclamp = SPEEDCLAMP;
 523 #else
 524                 speedclamp = 0.000001; // no strafe accel
 525 #endif
 526                 accelqw = -accelqw;
 527         }
 528         else
 529                 speedclamp = 0;
 530         // speedclamp usage:
 531         // > 0: max acceleration in qu/s^2 in excess of regular (try 50, 100)
 532         // < 0: max acceleration factor in excess of regular (try -0.1)
 533
 534         if(autocvar_sv_gameplayfix_q2airaccelerate)
 535                 wishspeed0 = wishspeed;
 536
 537         vel_straight = self.velocity * wishdir;
 538         vel_z = self.velocity_z;
 539         vel_xy = vec2(self.velocity);
 540         vel_perpend = vel_xy - vel_straight * wishdir;
 541
 542         step = accel * frametime * wishspeed0;
 543
 544         vel_xy_current  = vlen(vel_xy);
 545         if(speedlimit)
 546                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 547         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 548         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 549         if(vel_xy_backward < 0)
 550                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 551
 552         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 553
 554         if(sidefric < 0 && (vel_perpend*vel_perpend))
 555                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 556         {
 557                 float f, fminimum;
 558                 f = max(0, 1 + frametime * wishspeed * sidefric);
 559                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 560                 // this cannot be > 1
 561                 if(fminimum <= 0)
 562                         vel_perpend = vel_perpend * max(0, f);
 563                 else
 564                 {
 565                         fminimum = sqrt(fminimum);
 566                         vel_perpend = vel_perpend * max(fminimum, f);
 567                 }
 568         }
 569         else
 570                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 571
 572         vel_xy = vel_straight * wishdir + vel_perpend;
 573
 574         if(speedclamp != 0)
 575         {
 576                 // ensure we don't get too fast or decelerate faster than we should
 577                 if(speedclamp > 0)
 578                         vel_xy_current = min(vlen(vel_xy), vel_xy_forward + frametime * speedclamp);
 579                 else
 580                         vel_xy_current = min(vlen(vel_xy), vel_xy_current + (vel_xy_forward - vel_xy_current) * (1 - frametime * speedclamp));
 581                 if(vel_xy_current > 0) // prevent division by zero
 582                         vel_xy = normalize(vel_xy) * vel_xy_current;
 583         }
 584
 585         self.velocity = vel_xy + vel_z * '0 0 1';
 586 }
 587
 588 void PM_AirAccelerate(vector wishdir, float wishspeed)
 589 {
 590         vector curvel, wishvel, acceldir, curdir;
 591         float addspeed, accelspeed, curspeed, f;
 592         float dot;
 593
 594         if(wishspeed == 0)
 595                 return;
 596
 597         curvel = self.velocity;
 598         curvel_z = 0;
 599         curspeed = vlen(curvel);
 600
 601         if(wishspeed > curspeed * 1.01)
 602         {
 603                 wishspeed = min(wishspeed, curspeed + autocvar_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 604         }
 605         else
 606         {
 607                 f = max(0, (autocvar_sv_warsowbunny_topspeed - curspeed) / (autocvar_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 608                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + autocvar_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 609         }
 610         wishvel = wishdir * wishspeed;
 611         acceldir = wishvel - curvel;
 612         addspeed = vlen(acceldir);
 613         acceldir = normalize(acceldir);
 614
 615         accelspeed = min(addspeed, autocvar_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 616
 617         if(autocvar_sv_warsowbunny_backtosideratio < 1)
 618         {
 619                 curdir = normalize(curvel);
 620                 dot = acceldir * curdir;
 621                 if(dot < 0)
 622                         acceldir = acceldir - (1 - autocvar_sv_warsowbunny_backtosideratio) * dot * curdir;
 623         }
 624
 625         self.velocity += accelspeed * acceldir;
 626 }
 627
 628 .vector movement_old;
 629 .float buttons_old;
 630 .vector v_angle_old;
 631 .string lastclassname;
 632
 633 .float() PlayerPhysplug;
 634
 635 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 636 .float specialcommand_pos;
 637 void SpecialCommand()
 638 {
 639 #ifdef TETRIS
 640         TetrisImpulse();
 641 #else
 642         if(!CheatImpulse(99))
 643                 print("A hollow voice says \"Plugh\".\n");
 644 #endif
 645 }
 646
 647 float speedaward_speed;
 648 string speedaward_holder;
 649 string speedaward_uid;
 650 void race_send_speedaward(float msg)
 651 {
 652         // send the best speed of the round
 653         WriteByte(msg, SVC_TEMPENTITY);
 654         WriteByte(msg, TE_CSQC_RACE);
 655         WriteByte(msg, RACE_NET_SPEED_AWARD);
 656         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 657         WriteString(msg, speedaward_holder);
 658 }
 659
 660 float speedaward_alltimebest;
 661 string speedaward_alltimebest_holder;
 662 string speedaward_alltimebest_uid;
 663 void race_send_speedaward_alltimebest(float msg)
 664 {
 665         // send the best speed
 666         WriteByte(msg, SVC_TEMPENTITY);
 667         WriteByte(msg, TE_CSQC_RACE);
 668         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 669         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 670         WriteString(msg, speedaward_alltimebest_holder);
 671 }
 672
 673 string GetMapname(void);
 674 float speedaward_lastupdate;
 675 float speedaward_lastsent;
 676 void SV_PlayerPhysics()
 677 {
 678         local vector wishvel, wishdir, v;
 679         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 680         string temps;
 681         float buttons_prev;
 682         float not_allowed_to_move;
 683         string c;
 684
 685         WarpZone_PlayerPhysics_FixVAngle();
 686
 687         maxspd_mod = 1;
 688         if(g_minstagib && (self.items & IT_INVINCIBLE))
 689                 maxspd_mod *= autocvar_g_minstagib_speed_highspeed;
 690         if(self.ballcarried)
 691                 if(g_nexball)
 692                         maxspd_mod *= autocvar_g_nexball_basketball_carrier_highspeed;
 693                 else if(g_keepaway)
 694                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
 695
 696         if(g_runematch)
 697         {
 698                 if(self.runes & RUNE_SPEED)
 699                 {
 700                         if(self.runes & CURSE_SLOW)
 701                                 maxspd_mod *= autocvar_g_balance_rune_speed_combo_highspeed;
 702                         else
 703                                 maxspd_mod *= autocvar_g_balance_rune_speed_highspeed;
 704                 }
 705                 else if(self.runes & CURSE_SLOW)
 706                 {
 707                         maxspd_mod *= autocvar_g_balance_curse_slow_highspeed;
 708                 }
 709         }
 710         maxspd_mod *= autocvar_g_movement_highspeed;
 711
 712         // fix physics stats for g_movement_highspeed
 713         self.stat_sv_airaccel_qw = AdjustAirAccelQW(autocvar_sv_airaccel_qw, maxspd_mod);
 714         if(autocvar_sv_airstrafeaccel_qw)
 715                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(autocvar_sv_airstrafeaccel_qw, maxspd_mod);
 716         else
 717                 self.stat_sv_airstrafeaccel_qw = 0;
 718         self.stat_sv_airspeedlimit_nonqw = autocvar_sv_airspeedlimit_nonqw * maxspd_mod;
 719         self.stat_sv_maxspeed = autocvar_sv_maxspeed * maxspd_mod; // also slow walking
 720
 721     if(self.PlayerPhysplug)
 722         if(self.PlayerPhysplug())
 723             return;
 724
 725         self.race_movetime_frac += frametime;
 726         f = floor(self.race_movetime_frac);
 727         self.race_movetime_frac -= f;
 728         self.race_movetime_count += f;
 729         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 730
 731         anticheat_physics();
 732
 733         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 734
 735         if(!buttons)
 736                 c = "x";
 737         else if(buttons == 1)
 738                 c = "1";
 739         else if(buttons == 2)
 740                 c = " ";
 741         else if(buttons == 128)
 742                 c = "s";
 743         else if(buttons == 256)
 744                 c = "w";
 745         else if(buttons == 512)
 746                 c = "a";
 747         else if(buttons == 1024)
 748                 c = "d";
 749         else
 750                 c = "?";
 751
 752         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 753         {
 754                 self.specialcommand_pos += 1;
 755                 if(self.specialcommand_pos >= strlen(specialcommand))
 756                 {
 757                         self.specialcommand_pos = 0;
 758                         SpecialCommand();
 759                         return;
 760                 }
 761         }
 762         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 763                 self.specialcommand_pos = 0;
 764
 765         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 766         {
 767                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 768                         self.parm_idlesince = time;
 769         }
 770         buttons_prev = self.buttons_old;
 771         self.buttons_old = buttons;
 772         self.movement_old = self.movement;
 773         self.v_angle_old = self.v_angle;
 774
 775         if(time < self.nickspamtime)
 776         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 777         {
 778                 // slight annoyance for nick change scripts
 779                 self.movement = -1 * self.movement;
 780                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 781
 782                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 783                 {
 784                         self.angles_x = random() * 360;
 785                         self.angles_y = random() * 360;
 786                         // at least I'm not forcing retardedview by also assigning to angles_z
 787                         self.fixangle = 1;
 788                 }
 789         }
 790
 791         if (self.punchangle != '0 0 0')
 792         {
 793                 f = vlen(self.punchangle) - 10 * frametime;
 794                 if (f > 0)
 795                         self.punchangle = normalize(self.punchangle) * f;
 796                 else
 797                         self.punchangle = '0 0 0';
 798         }
 799
 800         if (self.punchvector != '0 0 0')
 801         {
 802                 f = vlen(self.punchvector) - 30 * frametime;
 803                 if (f > 0)
 804                         self.punchvector = normalize(self.punchvector) * f;
 805                 else
 806                         self.punchvector = '0 0 0';
 807         }
 808
 809         if (clienttype(self) == CLIENTTYPE_BOT)
 810         {
 811                 if(playerdemo_read())
 812                         return;
 813                 bot_think();
 814         }
 815
 816         self.items &~= IT_USING_JETPACK;
 817
 818         if(self.classname == "player")
 819         {
 820                 if(self.race_penalty)
 821                         if(time > self.race_penalty)
 822                                 self.race_penalty = 0;
 823
 824                 not_allowed_to_move = 0;
 825                 if(self.race_penalty)
 826                         not_allowed_to_move = 1;
 827                 if(!autocvar_sv_ready_restart_after_countdown)
 828                 if(time < game_starttime)
 829                         not_allowed_to_move = 1;
 830
 831                 if(not_allowed_to_move)
 832                 {
 833                         self.velocity = '0 0 0';
 834                         self.movetype = MOVETYPE_NONE;
 835                         self.disableclientprediction = 2;
 836                 }
 837                 else if(self.disableclientprediction == 2)
 838                 {
 839                         if(self.movetype == MOVETYPE_NONE)
 840                                 self.movetype = MOVETYPE_WALK;
 841                         self.disableclientprediction = 0;
 842                 }
 843         }
 844
 845         if (self.movetype == MOVETYPE_NONE)
 846                 return;
 847
 848         // when we get here, disableclientprediction cannot be 2
 849         self.disableclientprediction = 0;
 850         if(time < self.ladder_time)
 851                 self.disableclientprediction = 1;
 852
 853         MUTATOR_CALLHOOK(PlayerPhysics);
 854
 855         maxspd_mod = 1;
 856
 857         swampspd_mod = 1;
 858         if(self.in_swamp) {
 859                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 860         }
 861
 862         if(self.classname != "player")
 863         {
 864                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
 865                 if(!self.spectatorspeed)
 866                         self.spectatorspeed = maxspd_mod;
 867                 if(self.impulse && self.impulse <= 19)
 868                 {
 869                         if(self.lastclassname != "player")
 870                         {
 871                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 872                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 873                                 else if(self.impulse == 11)
 874                                         self.spectatorspeed = maxspd_mod;
 875                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 876                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 877                                 else if(self.impulse >= 1 && self.impulse <= 9)
 878                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 879                         } // otherwise just clear
 880                         self.impulse = 0;
 881                 }
 882                 maxspd_mod = self.spectatorspeed;
 883         }
 884
 885         spd = max(self.stat_sv_maxspeed, autocvar_sv_maxairspeed) * maxspd_mod * swampspd_mod;
 886         if(self.speed != spd)
 887         {
 888                 self.speed = spd;
 889                 temps = ftos(spd);
 890                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 891                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 892                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 893                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 894         }
 895
 896         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 897         swampspd_mod = 1;
 898
 899         // if dead, behave differently
 900         if (self.deadflag)
 901                 goto end;
 902
 903         if (!self.fixangle && !g_bugrigs)
 904         {
 905                 self.angles_x = 0;
 906                 self.angles_y = self.v_angle_y;
 907                 self.angles_z = 0;
 908         }
 909
 910         if(self.flags & FL_ONGROUND)
 911         if(self.wasFlying)
 912         {
 913                 self.wasFlying = 0;
 914
 915                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 916                 if(time >= self.ladder_time)
 917                 if not(self.hook)
 918                 {
 919                         self.nextstep = time + 0.3 + random() * 0.1;
 920                         trace_dphitq3surfaceflags = 0;
 921                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 922                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 923                         {
 924                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 925                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 926                                 else
 927                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 928                         }
 929                 }
 930         }
 931
 932         if(IsFlying(self))
 933                 self.wasFlying = 1;
 934
 935         if(self.classname == "player")
 936         {
 937                 if(self.flags & FL_ONGROUND)
 938                 {
 939                         if (autocvar_g_multijump > 0)
 940                                 self.multijump_count = 0;
 941                         else
 942                                 self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
 943                 }
 944
 945                 if (self.BUTTON_JUMP)
 946                         PlayerJump ();
 947                 else
 948                         self.flags |= FL_JUMPRELEASED;
 949
 950                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 951                         CheckWaterJump ();
 952                 self.prevjumpbutton = self.BUTTON_JUMP;
 953         }
 954
 955         if (self.flags & FL_WATERJUMP )
 956         {
 957                 self.velocity_x = self.movedir_x;
 958                 self.velocity_y = self.movedir_y;
 959                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 960                 {
 961                         self.flags &~= FL_WATERJUMP;
 962                         self.teleport_time = 0;
 963                 }
 964         }
 965         else if (g_bugrigs && self.classname == "player")
 966         {
 967                 RaceCarPhysics();
 968         }
 969         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 970         {
 971                 // noclipping or flying
 972                 self.flags &~= FL_ONGROUND;
 973
 974                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
 975                 makevectors(self.v_angle);
 976                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 977                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 978                 // acceleration
 979                 wishdir = normalize(wishvel);
 980                 wishspeed = vlen(wishvel);
 981                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 982                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 983                 if (time >= self.teleport_time)
 984                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
 985         }
 986         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 987         {
 988                 // swimming
 989                 self.flags &~= FL_ONGROUND;
 990
 991                 makevectors(self.v_angle);
 992                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 993                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 994                 if (wishvel == '0 0 0')
 995                         wishvel = '0 0 -60'; // drift towards bottom
 996
 997                 wishdir = normalize(wishvel);
 998                 wishspeed = vlen(wishvel);
 999                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1000                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1001                 wishspeed = wishspeed * 0.7;
1002
1003                 // water friction
1004                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
1005
1006                 // water acceleration
1007                 PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
1008         }
1009         else if (time < self.ladder_time)
1010         {
1011                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1012                 self.flags &~= FL_ONGROUND;
1013
1014                 float g;
1015                 g = autocvar_sv_gravity * frametime;
1016                 if(self.gravity)
1017                         g *= self.gravity;
1018                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
1019                 {
1020                         g *= 0.5;
1021                         self.velocity_z += g;
1022                 }
1023
1024                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
1025                 makevectors(self.v_angle);
1026                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1027                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1028                 self.velocity_z += g;
1029                 if (self.ladder_entity.classname == "func_water")
1030                 {
1031                         f = vlen(wishvel);
1032                         if (f > self.ladder_entity.speed)
1033                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1034
1035                         self.watertype = self.ladder_entity.skin;
1036                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1037                         if ((self.origin_z + self.view_ofs_z) < f)
1038                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1039                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1040                                 self.waterlevel = WATERLEVEL_SWIMMING;
1041                         else if ((self.origin_z + self.mins_z + 1) < f)
1042                                 self.waterlevel = WATERLEVEL_WETFEET;
1043                         else
1044                         {
1045                                 self.waterlevel = WATERLEVEL_NONE;
1046                                 self.watertype = CONTENT_EMPTY;
1047                         }
1048                 }
1049                 // acceleration
1050                 wishdir = normalize(wishvel);
1051                 wishspeed = vlen(wishvel);
1052                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1053                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1054                 if (time >= self.teleport_time)
1055                 {
1056                         // water acceleration
1057                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
1058                 }
1059         }
1060         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!autocvar_g_jetpack_fuel || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
1061         {
1062                 //makevectors(self.v_angle_y * '0 1 0');
1063                 makevectors(self.v_angle);
1064                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1065                 // add remaining speed as Z component
1066                 maxairspd = autocvar_sv_maxairspeed*max(1, maxspd_mod);
1067                 // fix speedhacks :P
1068                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1069                 // add the unused velocity as up component
1070                 wishvel_z = 0;
1071
1072                 // if(self.BUTTON_JUMP)
1073                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1074
1075                 // it is now normalized, so...
1076                 float a_side, a_up, a_add, a_diff;
1077                 a_side = autocvar_g_jetpack_acceleration_side;
1078                 a_up = autocvar_g_jetpack_acceleration_up;
1079                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1080
1081                 wishvel_x *= a_side;
1082                 wishvel_y *= a_side;
1083                 wishvel_z *= a_up;
1084                 wishvel_z += a_add;
1085
1086                 float best;
1087                 best = 0;
1088                 //////////////////////////////////////////////////////////////////////////////////////
1089                 // finding the maximum over all vectors of above form
1090                 // with wishvel having an absolute value of 1
1091                 //////////////////////////////////////////////////////////////////////////////////////
1092                 // we're finding the maximum over
1093                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1094                 // for z in the range from -1 to 1
1095                 //////////////////////////////////////////////////////////////////////////////////////
1096                 // maximum is EITHER attained at the single extreme point:
1097                 a_diff = a_side * a_side - a_up * a_up;
1098                 if(a_diff != 0)
1099                 {
1100                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1101                         if(f > -1 && f < 1) // can it be attained?
1102                         {
1103                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1104                                 //print("middle\n");
1105                         }
1106                 }
1107                 // OR attained at z = 1:
1108                 f = (a_up + a_add) * (a_up + a_add);
1109                 if(f > best)
1110                 {
1111                         best = f;
1112                         //print("top\n");
1113                 }
1114                 // OR attained at z = -1:
1115                 f = (a_up - a_add) * (a_up - a_add);
1116                 if(f > best)
1117                 {
1118                         best = f;
1119                         //print("bottom\n");
1120                 }
1121                 best = sqrt(best);
1122                 //////////////////////////////////////////////////////////////////////////////////////
1123
1124                 //print("best possible acceleration: ", ftos(best), "\n");
1125
1126                 float fxy, fz;
1127                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1128                 if(wishvel_z - autocvar_sv_gravity > 0)
1129                         fz = bound(0, 1 - self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1130                 else
1131                         fz = bound(0, 1 + self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1132
1133                 float fvel;
1134                 fvel = vlen(wishvel);
1135                 wishvel_x *= fxy;
1136                 wishvel_y *= fxy;
1137                 wishvel_z = (wishvel_z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1138
1139                 fvel = min(1, vlen(wishvel) / best);
1140                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1141                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1142                 else
1143                         f = 1;
1144
1145                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1146
1147                 if (f > 0 && wishvel != '0 0 0')
1148                 {
1149                         self.velocity = self.velocity + wishvel * f * frametime;
1150                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1151                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1152                         self.flags &~= FL_ONGROUND;
1153                         self.items |= IT_USING_JETPACK;
1154
1155                         // jetpack also inhibits health regeneration, but only for 1 second
1156                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1157                 }
1158         }
1159         else if (self.flags & FL_ONGROUND)
1160         {
1161                 // we get here if we ran out of ammo
1162                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1163                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1164
1165                 // walking
1166                 makevectors(self.v_angle_y * '0 1 0');
1167                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1168
1169                 if(!(self.lastflags & FL_ONGROUND))
1170                 {
1171                         if(autocvar_speedmeter)
1172                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1173                         if(self.lastground < time - 0.3)
1174                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1175                         if(self.jumppadcount > 1)
1176                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1177                         self.jumppadcount = 0;
1178                 }
1179
1180 #ifdef LETS_TEST_FTEQCC
1181                 if(self.velocity_x || self.velocity_y)
1182                 {
1183                         // good
1184                 }
1185                 else
1186                 {
1187                         if(self.velocity_x)
1188                                 checkclient();
1189                         if(self.velocity_y)
1190                                 checkclient();
1191                 }
1192 #endif
1193
1194                 v = self.velocity;
1195                 v_z = 0;
1196                 f = vlen(v);
1197                 if(f > 0)
1198                 {
1199                         if (f < autocvar_sv_stopspeed)
1200                                 f = 1 - frametime * (autocvar_sv_stopspeed / f) * autocvar_sv_friction;
1201                         else
1202                                 f = 1 - frametime * autocvar_sv_friction;
1203                         if (f > 0)
1204                                 self.velocity = self.velocity * f;
1205                         else
1206                                 self.velocity = '0 0 0';
1207                 }
1208
1209                 // acceleration
1210                 wishdir = normalize(wishvel);
1211                 wishspeed = vlen(wishvel);
1212                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1213                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1214                 if (self.crouch)
1215                         wishspeed = wishspeed * 0.5;
1216                 if (time >= self.teleport_time)
1217                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
1218         }
1219         else
1220         {
1221                 float wishspeed0;
1222                 // we get here if we ran out of ammo
1223                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1224                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1225
1226                 if(maxspd_mod < 1)
1227                 {
1228                         maxairspd = autocvar_sv_maxairspeed*maxspd_mod;
1229                         airaccel = autocvar_sv_airaccelerate*maxspd_mod;
1230                 }
1231                 else
1232                 {
1233                         maxairspd = autocvar_sv_maxairspeed;
1234                         airaccel = autocvar_sv_airaccelerate;
1235                 }
1236                 // airborn
1237                 makevectors(self.v_angle_y * '0 1 0');
1238                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1239                 // acceleration
1240                 wishdir = normalize(wishvel);
1241                 wishspeed = wishspeed0 = vlen(wishvel);
1242                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1243                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1244                 if (wishspeed > maxairspd)
1245                         wishspeed = maxairspd;
1246                 if (self.crouch)
1247                         wishspeed = wishspeed * 0.5;
1248                 if (time >= self.teleport_time)
1249                 {
1250                         float accelerating;
1251                         float wishspeed2;
1252                         float airaccelqw;
1253                         float strafity;
1254
1255                         airaccelqw = self.stat_sv_airaccel_qw;
1256                         accelerating = (self.velocity * wishdir > 0);
1257                         wishspeed2 = wishspeed;
1258
1259                         // CPM
1260                         if(autocvar_sv_airstopaccelerate)
1261                         {
1262                                 vector curdir;
1263                                 curdir = self.velocity;
1264                                 curdir_z = 0;
1265                                 curdir = normalize(curdir);
1266                                 airaccel = airaccel + (autocvar_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1267                         }
1268                         // note that for straight forward jumping:
1269                         // step = accel * frametime * wishspeed0;
1270                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1271                         // -->
1272                         // dv/dt = accel * maxspeed (when slow)
1273                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1274                         // log dv/dt = logaccel + logmaxspeed (when slow)
1275                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1276                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1277                         if(autocvar_sv_maxairstrafespeed)
1278                                 wishspeed = min(wishspeed, GeomLerp(autocvar_sv_maxairspeed*maxspd_mod, strafity, autocvar_sv_maxairstrafespeed*maxspd_mod));
1279                         if(autocvar_sv_airstrafeaccelerate)
1280                                 airaccel = GeomLerp(airaccel, strafity, autocvar_sv_airstrafeaccelerate*maxspd_mod);
1281                         if(self.stat_sv_airstrafeaccel_qw)
1282                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1283                         // !CPM
1284
1285                         if(autocvar_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1286                                 PM_AirAccelerate(wishdir, wishspeed);
1287                         else
1288                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, autocvar_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1289
1290                         if(autocvar_sv_aircontrol)
1291                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1292                 }
1293         }
1294
1295         if((g_cts || g_race) && self.classname != "observer") {
1296                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1297                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1298                         speedaward_holder = self.netname;
1299                         speedaward_uid = self.crypto_idfp;
1300                         speedaward_lastupdate = time;
1301                 }
1302                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1303                         string rr;
1304                         if(g_cts)
1305                                 rr = CTS_RECORD;
1306                         else
1307                                 rr = RACE_RECORD;
1308                         race_send_speedaward(MSG_ALL);
1309                         speedaward_lastsent = speedaward_speed;
1310                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "") {
1311                                 speedaward_alltimebest = speedaward_speed;
1312                                 speedaward_alltimebest_holder = speedaward_holder;
1313                                 speedaward_alltimebest_uid = speedaward_uid;
1314                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1315                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1316                                 race_send_speedaward_alltimebest(MSG_ALL);
1317                         }
1318                 }
1319         }
1320
1321         float xyspeed;
1322         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1323         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge && autocvar_g_balance_nex_charge_velocity_rate && xyspeed > autocvar_g_balance_nex_charge_minspeed)
1324         {
1325                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1326                 xyspeed = min(xyspeed, autocvar_g_balance_nex_charge_maxspeed);
1327                 f = (xyspeed - autocvar_g_balance_nex_charge_minspeed) / (autocvar_g_balance_nex_charge_maxspeed - autocvar_g_balance_nex_charge_minspeed);
1328                 // add the extra charge
1329                 self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_velocity_rate * f * frametime);
1330         }
1331 :end
1332         if(self.flags & FL_ONGROUND)
1333                 self.lastground = time;
1334
1335         self.lastflags = self.flags;
1336         self.lastclassname = self.classname;
1337 };