qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.iscreature = oldself.iscreature;
 115         self.angles = oldself.angles;
 116         self.avelocity = oldself.avelocity;
 117         self.classname = "body";
 118         self.damageforcescale = oldself.damageforcescale;
 119         self.effects = oldself.effects;
 120         self.event_damage = oldself.event_damage;
 121         self.animstate_startframe = oldself.animstate_startframe;
 122         self.animstate_numframes = oldself.animstate_numframes;
 123         self.animstate_framerate = oldself.animstate_framerate;
 124         self.animstate_starttime = oldself.animstate_starttime;
 125         self.animstate_endtime = oldself.animstate_endtime;
 126         self.animstate_override = oldself.animstate_override;
 127         self.animstate_looping = oldself.animstate_looping;
 128         self.frame = oldself.frame;
 129         self.dead_frame = oldself.dead_frame;
 130         self.pain_finished = oldself.pain_finished;
 131         self.health = oldself.health;
 132         self.armorvalue = oldself.armorvalue;
 133         self.armortype = oldself.armortype;
 134         self.model = oldself.model;
 135         self.modelindex = oldself.modelindex;
 136         self.modelindex_lod0 = oldself.modelindex_lod0;
 137         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 138         self.modelindex_lod1 = oldself.modelindex_lod1;
 139         self.modelindex_lod2 = oldself.modelindex_lod2;
 140         self.skinindex = oldself.skinindex;
 141         self.species = oldself.species;
 142         self.movetype = oldself.movetype;
 143         self.nextthink = oldself.nextthink;
 144         self.solid = oldself.solid;
 145         self.takedamage = oldself.takedamage;
 146         self.think = oldself.think;
 147         self.customizeentityforclient = oldself.customizeentityforclient;
 148         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 149         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 150         if (keepvelocity == 1)
 151                 self.velocity = oldself.velocity;
 152         self.oldvelocity = self.velocity;
 153         self.fade_time = oldself.fade_time;
 154         self.fade_rate = oldself.fade_rate;
 155         //self.weapon = oldself.weapon;
 156         setorigin(self, oldself.origin);
 157         setsize(self, oldself.mins, oldself.maxs);
 158         self.prevorigin = oldself.origin;
 159         self.reset = SUB_Remove;
 160
 161         Drag_MoveDrag(oldself, self);
 162
 163         self = oldself;
 164 }
 165
 166 float player_getspecies()
 167 {
 168         local float glob, i, j, fh, len, s, sk;
 169         local string fn, l;
 170
 171         s = -1;
 172
 173         glob = search_begin("models/player/*.txt", TRUE, TRUE);
 174         if(glob < 0)
 175                 return s;
 176         for(j = 0; j <= 1; ++j)
 177         {
 178                 for(i = 0; i < search_getsize(glob); ++i)
 179                 {
 180                         fn = search_getfilename(glob, i);
 181                         fh = fopen(fn, FILE_READ);
 182                         if(fh < 0)
 183                                 continue;
 184                         fgets(fh); fgets(fh);
 185                         sk = stof(fgets(fh));
 186                         if(sk == (j ? 0 : self.skinindex)) // 2nd pass skips the skin test
 187                         if(fgets(fh) == self.model)
 188                         {
 189                                 l = fgets(fh);
 190                                 len = tokenize_console(l);
 191                                 if (len != 2)
 192                                         goto nospecies;
 193                                 if (argv(0) != "species")
 194                                         goto nospecies;
 195                                 switch(argv(1))
 196                                 {
 197                                         case "human":       s = SPECIES_HUMAN;       break;
 198                                         case "alien":       s = SPECIES_ALIEN;       break;
 199                                         case "robot_shiny": s = SPECIES_ROBOT_SHINY; break;
 200                                         case "robot_rusty": s = SPECIES_ROBOT_RUSTY; break;
 201                                         case "robot_solid": s = SPECIES_ROBOT_SOLID; break;
 202                                         case "animal":      s = SPECIES_ANIMAL;      break;
 203                                         case "reserved":    s = SPECIES_RESERVED;    break;
 204                                 }
 205                         }
 206 :nospecies
 207                         fclose(fh);
 208                 }
 209                 if (s >= 0)
 210                         break;
 211         }
 212         search_end(glob);
 213
 214         if (s < 0)
 215                 s = SPECIES_HUMAN;
 216
 217         return s;
 218 }
 219
 220 void player_setupanimsformodel()
 221 {
 222         local string animfilename;
 223         local float animfile;
 224         // defaults for legacy .zym models without animinfo files
 225         self.anim_die1 = '0 1 0.5'; // 2 seconds
 226         self.anim_die2 = '1 1 0.5'; // 2 seconds
 227         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 228         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 229         self.anim_duckwalk = '4 1 1';
 230         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 231         self.anim_duckidle = '6 1 1';
 232         self.anim_idle = '7 1 1';
 233         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 234         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 235         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 236         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 237         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 238         self.anim_run = '13 1 1';
 239         self.anim_runbackwards = '14 1 1';
 240         self.anim_strafeleft = '15 1 1';
 241         self.anim_straferight = '16 1 1';
 242         self.anim_dead1 = '17 1 1';
 243         self.anim_dead2 = '18 1 1';
 244         self.anim_forwardright = '19 1 1';
 245         self.anim_forwardleft = '20 1 1';
 246         self.anim_backright = '21 1 1';
 247         self.anim_backleft  = '22 1 1';
 248         animparseerror = FALSE;
 249         animfilename = strcat(self.model, ".animinfo");
 250         animfile = fopen(animfilename, FILE_READ);
 251         if (animfile >= 0)
 252         {
 253                 self.anim_die1         = animparseline(animfile);
 254                 self.anim_die2         = animparseline(animfile);
 255                 self.anim_draw         = animparseline(animfile);
 256                 self.anim_duck         = animparseline(animfile);
 257                 self.anim_duckwalk     = animparseline(animfile);
 258                 self.anim_duckjump     = animparseline(animfile);
 259                 self.anim_duckidle     = animparseline(animfile);
 260                 self.anim_idle         = animparseline(animfile);
 261                 self.anim_jump         = animparseline(animfile);
 262                 self.anim_pain1        = animparseline(animfile);
 263                 self.anim_pain2        = animparseline(animfile);
 264                 self.anim_shoot        = animparseline(animfile);
 265                 self.anim_taunt        = animparseline(animfile);
 266                 self.anim_run          = animparseline(animfile);
 267                 self.anim_runbackwards = animparseline(animfile);
 268                 self.anim_strafeleft   = animparseline(animfile);
 269                 self.anim_straferight  = animparseline(animfile);
 270                 self.anim_forwardright = animparseline(animfile);
 271                 self.anim_forwardleft  = animparseline(animfile);
 272                 self.anim_backright    = animparseline(animfile);
 273                 self.anim_backleft     = animparseline(animfile);
 274                 fclose(animfile);
 275
 276                 // derived anims
 277                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 278                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 279
 280                 if (animparseerror)
 281                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 282         }
 283         else
 284                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 285         // reset animstate now
 286         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 287 };
 288
 289 void player_anim (void)
 290 {
 291         updateanim(self);
 292         if (self.weaponentity)
 293                 updateanim(self.weaponentity);
 294
 295         if (self.deadflag != DEAD_NO)
 296         {
 297                 if (time > self.animstate_endtime)
 298                 {
 299                         if (self.maxs_z > 5)
 300                         {
 301                                 self.maxs_z = 5;
 302                                 setsize(self, self.mins, self.maxs);
 303                         }
 304                         self.frame = self.dead_frame;
 305                 }
 306                 return;
 307         }
 308
 309         if (!self.animstate_override)
 310         {
 311                 if (!(self.flags & FL_ONGROUND))
 312                 {
 313                         if (self.crouch)
 314                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 315                         else
 316                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 317                         self.restart_jump = FALSE;
 318                 }
 319                 else if (self.crouch)
 320                 {
 321                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 322                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_minstagib)
 359         if(self.ammo_cells <= 0)
 360                 return;
 361
 362         if(g_pinata)
 363         {
 364                 float j;
 365                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 366                 {
 367                         if(self.weapons & W_WeaponBit(j))
 368                                 if(W_IsWeaponThrowable(j))
 369                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 370                 }
 371         }
 372         else
 373                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 374 }
 375
 376 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 377 {
 378         local float take, save;
 379         vector v;
 380         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 381
 382         // damage resistance (ignore most of the damage from a bullet or similar)
 383         damage = max(damage - 5, 1);
 384
 385         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 386         take = v_x;
 387         save = v_y;
 388
 389         if(sound_allowed(MSG_BROADCAST, attacker))
 390         {
 391                 if (save > 10)
 392                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 393                 else if (take > 30)
 394                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 395                 else if (take > 10)
 396                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 397         }
 398
 399         if (take > 50)
 400                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 401         if (take > 100)
 402                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 403
 404         if (!(self.flags & FL_GODMODE))
 405         {
 406                 self.armorvalue = self.armorvalue - save;
 407                 self.health = self.health - take;
 408                 // pause regeneration for 5 seconds
 409                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 410         }
 411         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 412         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 413         self.dmg_inflictor = inflictor;
 414
 415         if (self.health <= -75 && self.modelindex != 0)
 416         {
 417                 // don't use any animations as a gib
 418                 self.frame = 0;
 419                 self.dead_frame = 0;
 420                 // view just above the floor
 421                 self.view_ofs = '0 0 4';
 422
 423                 Violence_GibSplash(self, 1, 1, attacker);
 424                 self.modelindex = 0; // restore later
 425                 self.solid = SOLID_NOT; // restore later
 426         }
 427 }
 428
 429 void ClientKill_Now_TeamChange();
 430
 431 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 432 {
 433         local float take, save, waves, sdelay, dh, da, j;
 434         vector v;
 435         float valid_damage_for_weaponstats;
 436
 437         dh = max(self.health, 0);
 438         da = max(self.armorvalue, 0);
 439
 440         if(!DEATH_ISSPECIAL(deathtype))
 441         {
 442                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 443                 if(self != attacker)
 444                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 445         }
 446
 447         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 448         {
 449                 // tuba causes blood to come out of the ears
 450                 vector ear1, ear2;
 451                 vector d;
 452                 float f;
 453                 ear1 = self.origin;
 454                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 455                 ear2 = ear1;
 456                 makevectors(self.angles);
 457                 ear1 += v_right * -10;
 458                 ear2 += v_right * +10;
 459                 d = inflictor.origin - self.origin;
 460                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 461                 force = v_right * vlen(force);
 462                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 463                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 464                 if(f > 0)
 465                 {
 466                         hitloc = ear1;
 467                         force = force * -1;
 468                 }
 469                 else
 470                 {
 471                         hitloc = ear2;
 472                         // force is already good
 473                 }
 474         }
 475         else
 476                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 477
 478         if((g_arena && numspawned < 2) || (g_ca && player_cnt < 2) && !inWarmupStage)
 479                 return;
 480
 481         if (!g_minstagib)
 482         {
 483                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 484                 take = v_x;
 485                 save = v_y;
 486         }
 487         else
 488         {
 489                 save = 0;
 490                 take = damage;
 491         }
 492
 493         if(sound_allowed(MSG_BROADCAST, attacker))
 494         {
 495                 if (save > 10)
 496                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 497                 else if (take > 30)
 498                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 499                 else if (take > 10)
 500                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 501         }
 502
 503         if (take > 50)
 504                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 505         if (take > 100)
 506                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 507
 508         if (time >= self.spawnshieldtime)
 509         {
 510                 if (!(self.flags & FL_GODMODE))
 511                 {
 512                         self.armorvalue = self.armorvalue - save;
 513                         self.health = self.health - take;
 514                         // pause regeneration for 5 seconds
 515                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 516
 517                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 518                         {
 519                                 self.pain_finished = time + 0.5;        //Supajoe
 520
 521                                 if(sv_gentle < 1) {
 522                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 523                                         {
 524                                                 if (random() > 0.5)
 525                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 526                                                 else
 527                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 528                                         }
 529
 530                                         if(sound_allowed(MSG_BROADCAST, attacker))
 531                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 532                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 533                                         {
 534                                                 if(self.health > 75) // TODO make a "gentle" version?
 535                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 536                                                 else if(self.health > 50)
 537                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 538                                                 else if(self.health > 25)
 539                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 540                                                 else if(self.health > 1)
 541                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 542                                         }
 543                                 }
 544
 545                                 // throw off bot aim temporarily
 546                                 local float shake;
 547                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 548                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 549                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 550                         }
 551                 }
 552                 else
 553                         self.max_armorvalue += (save + take);
 554         }
 555         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 556         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 557         self.dmg_inflictor = inflictor;
 558
 559         if(attacker == self)
 560         {
 561                 // don't reset pushltime for self damage as it may be an attempt to
 562                 // escape a lava pit or similar
 563                 //self.pushltime = 0;
 564         }
 565         else if(attacker.classname == "player" || attacker.classname == "gib")
 566         {
 567                 self.pusher = attacker;
 568                 self.pushltime = time + cvar("g_maxpushtime");
 569         }
 570         else if(time < self.pushltime)
 571         {
 572                 attacker = self.pusher;
 573                 self.pushltime = max(self.pushltime, time + 0.6);
 574         }
 575         else
 576                 self.pushltime = 0;
 577
 578         valid_damage_for_weaponstats = 0;
 579         if(clienttype(self) == CLIENTTYPE_REAL)
 580         if(clienttype(attacker) == CLIENTTYPE_REAL)
 581         if(self != attacker)
 582         if(!DEATH_ISSPECIAL(deathtype))
 583         if(IsDifferentTeam(self, attacker))
 584                 valid_damage_for_weaponstats = 1;
 585
 586         if(valid_damage_for_weaponstats)
 587         {
 588                 dh = dh - max(self.health, 0);
 589                 da = da - max(self.armorvalue, 0);
 590                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 591         }
 592
 593         if (self.health < 1)
 594         {
 595                 float defer_ClientKill_Now_TeamChange;
 596                 defer_ClientKill_Now_TeamChange = FALSE;
 597
 598                 if(valid_damage_for_weaponstats)
 599                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 600
 601                 if(sv_gentle < 1) // TODO make a "gentle" version?
 602                 if(sound_allowed(MSG_BROADCAST, attacker))
 603                 {
 604                         if(deathtype == DEATH_DROWN)
 605                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 606                         else
 607                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 608                 }
 609
 610                 // get rid of kill indicator
 611                 if(self.killindicator)
 612                 {
 613                         remove(self.killindicator);
 614                         self.killindicator = world;
 615                         if(self.killindicator_teamchange)
 616                                 defer_ClientKill_Now_TeamChange = TRUE;
 617
 618                         if(self.classname == "body")
 619                         if(deathtype == DEATH_KILL)
 620                         {
 621                                 // for the lemmings fans, a small harmless explosion
 622                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 623                         }
 624                 }
 625
 626                 // become fully visible
 627                 self.alpha = 1;
 628                 // clear selected player display
 629                 ClearSelectedPlayer();
 630                 // throw a weapon
 631                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 632                 // print an obituary message
 633                 Obituary (attacker, inflictor, self, deathtype);
 634                 race_PreDie();
 635                 DropAllRunes(self);
 636                 frag_attacker = attacker; MUTATOR_CALLHOOK(PlayerDies);
 637                 if(self.flagcarried)
 638                 {
 639                         if(attacker.classname != "player" && attacker.classname != "gib")
 640                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 641                         else if(attacker.team == self.team)
 642                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 643                         else
 644                                 DropFlag(self.flagcarried, world, attacker);
 645                 }
 646                 if(self.ballcarried)
 647                         DropBall(self.ballcarried, self.origin, self.velocity);
 648                 Portal_ClearAllLater(self);
 649                 // clear waypoints
 650                 WaypointSprite_PlayerDead();
 651                 // make the corpse upright (not tilted)
 652                 self.angles_x = 0;
 653                 self.angles_z = 0;
 654                 // don't spin
 655                 self.avelocity = '0 0 0';
 656                 // view from the floor
 657                 self.view_ofs = '0 0 -8';
 658                 // toss the corpse
 659                 self.movetype = MOVETYPE_TOSS;
 660                 // shootable corpse
 661                 self.solid = SOLID_CORPSE;
 662                 // don't stick to the floor
 663                 self.flags &~= FL_ONGROUND;
 664                 // dying animation
 665                 self.deadflag = DEAD_DYING;
 666                 // when to allow respawn
 667                 sdelay = 0;
 668                 waves = 0;
 669                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 670                 if(!sdelay)
 671                         sdelay = cvar("g_respawn_delay");
 672                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 673                 if(!waves)
 674                         waves = cvar("g_respawn_waves");
 675                 if(waves)
 676                         self.death_time = ceil((time + sdelay) / waves) * waves;
 677                 else
 678                         self.death_time = time + sdelay;
 679                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 680                         self.respawn_countdown = 10; // first number to count down from is 10
 681                 else
 682                         self.respawn_countdown = -1; // do not count down
 683                 if (random() < 0.5)
 684                 {
 685                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 686                         self.dead_frame = self.anim_dead1_x;
 687                 }
 688                 else
 689                 {
 690                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 691                         self.dead_frame = self.anim_dead2_x;
 692                 }
 693                 // set damage function to corpse damage
 694                 self.event_damage = PlayerCorpseDamage;
 695                 // call the corpse damage function just in case it wants to gib
 696                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 697                 // set up to fade out later
 698                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 699
 700                 // remove laserdot
 701                 if(self.weaponentity)
 702                         if(self.weaponentity.lasertarget)
 703                                 remove(self.weaponentity.lasertarget);
 704
 705                 if(clienttype(self) == CLIENTTYPE_REAL)
 706                 {
 707                         self.fixangle = TRUE;
 708                         //msg_entity = self;
 709                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 710                         //WriteAngle (MSG_ONE, self.v_angle_x);
 711                         //WriteAngle (MSG_ONE, self.v_angle_y);
 712                         //WriteAngle (MSG_ONE, 80);
 713                 }
 714
 715                 if(g_arena)
 716                         Spawnqueue_Unmark(self);
 717
 718                 if(defer_ClientKill_Now_TeamChange)
 719                         ClientKill_Now_TeamChange();
 720
 721                 if(sv_gentle > 0 || cvar("ekg")) {
 722                         // remove corpse
 723                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 724                 }
 725
 726                 // reset fields the weapons may use just in case
 727         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 728                 {
 729             weapon_action(j, WR_RESETPLAYER);
 730                         ATTACK_FINISHED_FOR(self, j) = 0;
 731                 }
 732         }
 733 }
 734
 735 float UpdateSelectedPlayer_countvalue(float v)
 736 {
 737         return max(0, (v - 1.0) / 0.5);
 738 }
 739
 740 // returns: -2 if no hit, otherwise cos of the angle
 741 // uses the global v_angle
 742 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 743 {
 744         vector so, d;
 745         float c;
 746
 747         if(p == self)
 748                 return -2;
 749
 750         if(p.deadflag)
 751                 return -2;
 752
 753         so = self.origin + self.view_ofs;
 754         d = p.origin - so;
 755
 756         // misaimed?
 757         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 758                 return -2;
 759
 760         // now find the cos of the angle...
 761         c = normalize(d) * v_forward;
 762
 763         if(c <= mincosangle)
 764                 return -2;
 765
 766         // not visible in any way? forget it
 767         if(!checkpvs(so, p))
 768                 return -2;
 769
 770         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 771         if(trace_fraction < 1)
 772                 return -2;
 773
 774         return c;
 775 }
 776
 777 void ClearSelectedPlayer()
 778 {
 779         if(self.selected_player)
 780         {
 781                 centerprint_expire(self, CENTERPRIO_POINT);
 782                 self.selected_player = world;
 783                 self.selected_player_display_needs_update = FALSE;
 784         }
 785 }
 786
 787 void UpdateSelectedPlayer()
 788 {
 789         entity selected;
 790         float selected_score;
 791         selected = world;
 792         selected_score = 0.95; // 18 degrees
 793
 794         if(!cvar("sv_allow_shownames"))
 795                 return;
 796
 797         if(clienttype(self) != CLIENTTYPE_REAL)
 798                 return;
 799
 800         if(self.cvar_cl_shownames == 0)
 801                 return;
 802
 803         if(self.cvar_cl_shownames == 1 && !teams_matter)
 804                 return;
 805
 806         makevectors(self.v_angle); // sets v_forward
 807
 808         // 1. cursor trace is always right
 809         WarpZone_crosshair_trace(self);
 810         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 811         {
 812                 selected = trace_ent;
 813         }
 814         else
 815         {
 816                 // 2. if we don't have a cursor trace, find the player which is least
 817                 //    mis-aimed at
 818                 entity p;
 819                 FOR_EACH_PLAYER(p)
 820                 {
 821                         float c;
 822                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 823                         if(c >= -1)
 824                         {
 825                                 selected = p;
 826                                 selected_score = c;
 827                         }
 828                 }
 829         }
 830
 831         if(selected)
 832         {
 833                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 834         }
 835         else
 836         {
 837                 if(time < self.selected_player_display_timeout)
 838                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 839                                 selected = self.selected_player;
 840         }
 841
 842         if(selected)
 843         {
 844                 if(selected == self.selected_player)
 845                 {
 846                         float save;
 847                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 848                         self.selected_player_count = self.selected_player_count + frametime;
 849                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 850                         {
 851                                 string namestr, healthstr;
 852                                 namestr = playername(selected);
 853                                 if(teams_matter)
 854                                 {
 855                                         healthstr = ftos(floor(selected.health));
 856                                         if(self.team == selected.team)
 857                                         {
 858                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 859                                                 self.selected_player_display_needs_update = TRUE;
 860                                         }
 861                                 }
 862                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 863                         }
 864                 }
 865                 else
 866                 {
 867                         ClearSelectedPlayer();
 868                         self.selected_player = selected;
 869                         self.selected_player_time = time;
 870                         self.selected_player_count = 0;
 871                         self.selected_player_display_needs_update = FALSE;
 872                 }
 873         }
 874         else
 875         {
 876                 ClearSelectedPlayer();
 877         }
 878
 879         if(self.selected_player)
 880                 self.last_selected_player = self.selected_player;
 881 }
 882
 883 .float muted; // to be used by prvm_edictset server playernumber muted 1
 884 void Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 885 {
 886         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 887         float flood, privatemsgprefixlen;
 888         entity head;
 889
 890         if(Ban_MaybeEnforceBan(source))
 891                 return;
 892
 893         if(!teamsay && !privatesay)
 894                 if(substring(msgin, 0, 1) == " ")
 895                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 896
 897         msgin = formatmessage(msgin);
 898
 899         if(msgin == "")
 900                 return;
 901
 902         if(source.classname != "player")
 903                 colorstr = "^0"; // black for spectators
 904         else if(teams_matter)
 905                 colorstr = Team_ColorCode(source.team);
 906         else
 907                 teamsay = FALSE;
 908
 909         if(intermission_running)
 910                 teamsay = FALSE;
 911
 912         msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 913         if(msgin == "")
 914                 return;
 915
 916         /*
 917          * using bprint solves this... me stupid
 918         // how can we prevent the message from appearing in a listen server?
 919         // for now, just give "say" back and only handle say_team
 920         if(!teamsay)
 921         {
 922                 clientcommand(self, strcat("say ", msgin));
 923                 return;
 924         }
 925         */
 926
 927         if(cvar("g_chat_teamcolors"))
 928                 namestr = playername(source);
 929         else
 930                 namestr = source.netname;
 931
 932         if(privatesay)
 933         {
 934                 msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 935                 privatemsgprefixlen = strlen(msgstr);
 936                 msgstr = strcat(msgstr, msgin);
 937                 cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 938                 if(cvar("g_chat_teamcolors"))
 939                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 940                 else
 941                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 942         }
 943         else if(teamsay)
 944         {
 945                 msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 946                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 947         }
 948         else
 949         {
 950                 msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 951                 cmsgstr = "";
 952         }
 953
 954         msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 955         fullmsgstr = msgstr;
 956         fullcmsgstr = cmsgstr;
 957
 958         // FLOOD CONTROL
 959         flood = 0;
 960         if(floodcontrol)
 961         {
 962                 float flood_spl;
 963                 float flood_burst;
 964                 float flood_lmax;
 965                 var .float flood_field;
 966                 float lines;
 967                 if(privatesay)
 968                 {
 969                         flood_spl = cvar("g_chat_flood_spl_tell");
 970                         flood_burst = cvar("g_chat_flood_burst_tell");
 971                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 972                         flood_field = floodcontrol_chattell;
 973                 }
 974                 else if(teamsay)
 975                 {
 976                         flood_spl = cvar("g_chat_flood_spl_team");
 977                         flood_burst = cvar("g_chat_flood_burst_team");
 978                         flood_lmax = cvar("g_chat_flood_lmax_team");
 979                         flood_field = floodcontrol_chatteam;
 980                 }
 981                 else
 982                 {
 983                         flood_spl = cvar("g_chat_flood_spl");
 984                         flood_burst = cvar("g_chat_flood_burst");
 985                         flood_lmax = cvar("g_chat_flood_lmax");
 986                         flood_field = floodcontrol_chat;
 987                 }
 988                 flood_burst = max(0, flood_burst - 1);
 989                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 990
 991                 // do flood control for the default line size
 992                 getWrappedLine_remaining = msgstr;
 993                 msgstr = "";
 994                 lines = 0;
 995                 while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 996                 {
 997                         msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 998                         ++lines;
 999                 }
1000                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1001
1002                 if(getWrappedLine_remaining != "")
1003                 {
1004                         msgstr = strcat(msgstr, "\n");
1005                         flood = 2;
1006                 }
1007
1008                 if(time >= source.flood_field)
1009                 {
1010                         source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1011                 }
1012                 else
1013                 {
1014                         flood = 1;
1015                         msgstr = fullmsgstr;
1016                 }
1017         }
1018
1019         if (timeoutStatus == 2) //when game is paused, no flood protection
1020                 source.flood_field = flood = 0;
1021
1022         if(flood == 2)
1023         {
1024                 if(cvar("g_chat_flood_notify_flooder"))
1025                 {
1026                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1027                         sourcecmsgstr = "";
1028                 }
1029                 else
1030                 {
1031                         sourcemsgstr = fullmsgstr;
1032                         sourcecmsgstr = fullcmsgstr;
1033                 }
1034                 cmsgstr = "";
1035         }
1036         else
1037         {
1038                 sourcemsgstr = msgstr;
1039                 sourcecmsgstr = cmsgstr;
1040         }
1041
1042         if(!privatesay)
1043         if(source.classname != "player")
1044         {
1045                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1046                         teamsay = -1; // spectators
1047         }
1048
1049         if(flood)
1050                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1051
1052         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1053         if(privatesay)
1054                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1055
1056         if(source.muted)
1057         {
1058                 // always fake the message
1059                 sprint(source, sourcemsgstr);
1060                 if(cmsgstr != "" && !privatesay)
1061                         centerprint(source, sourcecmsgstr);
1062         }
1063         else if(flood == 1)
1064         {
1065                 if(cvar("g_chat_flood_notify_flooder"))
1066                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1067                 else
1068                 {
1069                         sprint(source, sourcemsgstr);
1070                         if(cmsgstr != "" && !privatesay)
1071                                 centerprint(source, sourcecmsgstr);
1072                 }
1073         }
1074         else if(privatesay)
1075         {
1076                 sprint(source, sourcemsgstr);
1077                 sprint(privatesay, msgstr);
1078                 if(cmsgstr != "")
1079                         centerprint(privatesay, cmsgstr);
1080         }
1081         else if(teamsay > 0)
1082         {
1083                 sprint(source, sourcemsgstr);
1084                 if(sourcecmsgstr != "")
1085                         centerprint(source, sourcecmsgstr);
1086                 FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1087                         if(head != source)
1088                         {
1089                                 sprint(head, msgstr);
1090                                 if(cmsgstr != "")
1091                                         centerprint(head, cmsgstr);
1092                         }
1093         }
1094         else if(teamsay < 0)
1095         {
1096                 sprint(source, sourcemsgstr);
1097                 FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1098                         if(head != source)
1099                                 sprint(head, msgstr);
1100         }
1101         else if(sourcemsgstr != msgstr)
1102         {
1103                 sprint(source, sourcemsgstr);
1104                 FOR_EACH_REALCLIENT(head)
1105                         if(head != source)
1106                                 sprint(head, msgstr);
1107         }
1108         else
1109                 bprint(msgstr);
1110 }
1111
1112 float GetVoiceMessageVoiceType(string type)
1113 {
1114         if(type == "taunt")
1115                 return VOICETYPE_TAUNT;
1116         if(type == "teamshoot")
1117                 return VOICETYPE_LASTATTACKER;
1118         return VOICETYPE_TEAMRADIO;
1119 }
1120
1121 string allvoicesamples;
1122 float GetPlayerSoundSampleField_notFound;
1123 float GetPlayerSoundSampleField_fixed;
1124 .string GetVoiceMessageSampleField(string type)
1125 {
1126         GetPlayerSoundSampleField_notFound = 0;
1127         GetPlayerSoundSampleField_fixed = 0;
1128         switch(type)
1129         {
1130 #define _VOICEMSG(m) case #m: return playersound_##m;
1131                 ALLVOICEMSGS
1132 #undef _VOICEMSG
1133         }
1134         GetPlayerSoundSampleField_notFound = 1;
1135         return playersound_taunt;
1136 }
1137
1138 .string GetPlayerSoundSampleField(string type)
1139 {
1140         GetPlayerSoundSampleField_notFound = 0;
1141         GetPlayerSoundSampleField_fixed = 0;
1142         switch(type)
1143         {
1144 #define _VOICEMSG(m) case #m: return playersound_##m;
1145                 ALLPLAYERSOUNDS
1146 #undef _VOICEMSG
1147         }
1148         GetPlayerSoundSampleField_notFound = 1;
1149         return playersound_taunt;
1150 }
1151
1152 void PrecacheGlobalSound(string samplestring)
1153 {
1154         float n, i;
1155         tokenize_console(samplestring);
1156         n = stof(argv(1));
1157         if(n > 0)
1158         {
1159                 for(i = 1; i <= n; ++i)
1160                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1161         }
1162         else
1163         {
1164                 precache_sound(strcat(argv(0), ".wav"));
1165         }
1166 }
1167
1168 void PrecachePlayerSounds(string f)
1169 {
1170         float fh;
1171         string s;
1172         fh = fopen(f, FILE_READ);
1173         if(fh < 0)
1174                 return;
1175         while((s = fgets(fh)))
1176         {
1177                 if(tokenize_console(s) != 3)
1178                 {
1179                         dprint("Invalid sound info line: ", s, "\n");
1180                         continue;
1181                 }
1182                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1183         }
1184         fclose(fh);
1185
1186         if not(allvoicesamples)
1187         {
1188 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1189                 ALLVOICEMSGS
1190 #undef _VOICEMSG
1191                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1192         }
1193 }
1194
1195 void ClearPlayerSounds()
1196 {
1197 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1198         ALLPLAYERSOUNDS
1199         ALLVOICEMSGS
1200 #undef _VOICEMSG
1201 }
1202
1203 void LoadPlayerSounds(string f, float first)
1204 {
1205         float fh;
1206         string s;
1207         var .string field;
1208         fh = fopen(f, FILE_READ);
1209         if(fh < 0)
1210                 return;
1211         while((s = fgets(fh)))
1212         {
1213                 if(tokenize_console(s) != 3)
1214                         continue;
1215                 field = GetPlayerSoundSampleField(argv(0));
1216                 if(GetPlayerSoundSampleField_notFound)
1217                         field = GetVoiceMessageSampleField(argv(0));
1218                 if(GetPlayerSoundSampleField_notFound)
1219                         continue;
1220                 if(GetPlayerSoundSampleField_fixed)
1221                         if not(first)
1222                                 continue;
1223                 if(self.field)
1224                         strunzone(self.field);
1225                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1226         }
1227         fclose(fh);
1228 }
1229
1230 .float modelindex_for_playersound;
1231 void UpdatePlayerSounds()
1232 {
1233         if(self.modelindex == self.modelindex_for_playersound)
1234                 return;
1235         self.modelindex_for_playersound = self.modelindex;
1236         ClearPlayerSounds();
1237         LoadPlayerSounds("sound/player/default.sounds", 1);
1238         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
1239 }
1240
1241 void GlobalSound(string sample, float chan, float voicetype)
1242 {
1243         float n;
1244         float tauntrand;
1245
1246         if(sample == "")
1247                 return;
1248
1249         tokenize_console(sample);
1250         n = stof(argv(1));
1251         if(n > 0)
1252                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1253         else
1254                 sample = strcat(argv(0), ".wav"); // randomization
1255
1256         switch(voicetype)
1257         {
1258                 case VOICETYPE_LASTATTACKER_ONLY:
1259                         if(self.pusher)
1260                                 if(self.pusher.team == self.team)
1261                                 {
1262                                         msg_entity = self.pusher;
1263                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1264                                         {
1265                                                 if(msg_entity.cvar_cl_voice_directional == 1)
1266                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1267                                                 else
1268                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1269                                         }
1270                                 }
1271                         break;
1272                 case VOICETYPE_LASTATTACKER:
1273                         if(self.pusher)
1274                                 if(self.pusher.team == self.team)
1275                                 {
1276                                         msg_entity = self.pusher;
1277                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1278                                         {
1279                                                 if(msg_entity.cvar_cl_voice_directional == 1)
1280                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1281                                                 else
1282                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1283                                         }
1284                                         msg_entity = self;
1285                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1286                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1287                                 }
1288                         break;
1289                 case VOICETYPE_TEAMRADIO:
1290                         FOR_EACH_REALCLIENT(msg_entity)
1291                                 if(!teams_matter || msg_entity.team == self.team)
1292                                 {
1293                                         if(msg_entity.cvar_cl_voice_directional == 1)
1294                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1295                                         else
1296                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1297                                 }
1298                         break;
1299                 case VOICETYPE_AUTOTAUNT:
1300                         if(!sv_autotaunt)
1301                                 break;
1302                         if(!sv_taunt)
1303                                 break;
1304                         if(sv_gentle)
1305                                 break;
1306                         tauntrand = random();
1307                         FOR_EACH_REALCLIENT(msg_entity)
1308                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1309                                 {
1310                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1311                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1312                                         else
1313                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1314                                 }
1315                         break;
1316                 case VOICETYPE_TAUNT:
1317                         if(self.classname == "player")
1318                                 if(self.deadflag == DEAD_NO)
1319                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1320                         if(!sv_taunt)
1321                                 break;
1322                         if(sv_gentle)
1323                                 break;
1324                         FOR_EACH_REALCLIENT(msg_entity)
1325                         {
1326                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1327                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1328                                 else
1329                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1330                         }
1331                 case VOICETYPE_PLAYERSOUND:
1332                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1333                         break;
1334                 default:
1335                         backtrace("Invalid voice type!");
1336                         break;
1337         }
1338 }
1339
1340 void PlayerSound(.string samplefield, float chan, float voicetype)
1341 {
1342         string sample;
1343         sample = self.samplefield;
1344         GlobalSound(sample, chan, voicetype);
1345 }
1346
1347 void VoiceMessage(string type, string msg)
1348 {
1349         var .string sample;
1350         var float voicetype, ownteam;
1351         sample = GetVoiceMessageSampleField(type);
1352
1353         if(GetPlayerSoundSampleField_notFound)
1354         {
1355                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1356                 return;
1357         }
1358
1359         voicetype = GetVoiceMessageVoiceType(type);
1360         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1361
1362         float flood;
1363         float flood_spv;
1364         var .float flood_field;
1365
1366         flood = 0;
1367         if(ownteam)
1368         {
1369                 flood_spv = cvar("g_voice_flood_spv_team");
1370                 flood_field = floodcontrol_voiceteam;
1371         }
1372         else
1373         {
1374                 flood_spv = cvar("g_voice_flood_spv");
1375                 flood_field = floodcontrol_voice;
1376         }
1377
1378         if(time >= self.flood_field)
1379                 self.flood_field = max(time, self.flood_field) + flood_spv;
1380         else
1381                 flood = 1;
1382
1383         if (timeoutStatus == 2) //when game is paused, no flood protection
1384                 self.flood_field = flood = 0;
1385
1386         if (msg != "")
1387                 Say(self, ownteam, world, msg, 0);
1388
1389         if (!flood)
1390                 PlayerSound(sample, CHAN_VOICE, voicetype);
1391 }
1392
1393 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1394 {
1395 //      show_message
1396 //      0 (00) automove centerprint, admin message
1397 //      1 (01) automove centerprint, no admin message
1398 //      2 (10) no centerprint, admin message
1399 //      3 (11) no centerprint, no admin message
1400
1401         float lockteams_backup;
1402
1403         lockteams_backup = lockteams;  // backup any team lock
1404
1405         lockteams = 0;  // disable locked teams
1406
1407         TeamchangeFrags(client);  // move the players frags
1408         SetPlayerColors(client, team_colour - 1);  // set the players colour
1409         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1410
1411         lockteams = lockteams_backup;  // restore the team lock
1412
1413         LogTeamchange(client.playerid, client.team, type);
1414
1415         if not(show_message & 1) // admin message
1416                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1417
1418         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1419 }