qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.dphitcontentsmask = oldself.dphitcontentsmask;
 170         self.death_time = oldself.death_time;
 171         self.frame = oldself.frame;
 172         self.pain_finished = oldself.pain_finished;
 173         self.health = oldself.health;
 174         self.armorvalue = oldself.armorvalue;
 175         self.armortype = oldself.armortype;
 176         self.model = oldself.model;
 177         self.modelindex = oldself.modelindex;
 178         self.skin = oldself.skin;
 179         self.species = oldself.species;
 180         self.movetype = oldself.movetype;
 181         self.solid = oldself.solid;
 182         self.ballistics_density = oldself.ballistics_density;
 183         self.takedamage = oldself.takedamage;
 184         self.customizeentityforclient = oldself.customizeentityforclient;
 185         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 186         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 187         if (keepvelocity == 1)
 188                 self.velocity = oldself.velocity;
 189         self.oldvelocity = self.velocity;
 190         self.alpha = oldself.alpha;
 191         self.fade_time = oldself.fade_time;
 192         self.fade_rate = oldself.fade_rate;
 193         //self.weapon = oldself.weapon;
 194         setorigin(self, oldself.origin);
 195         setsize(self, oldself.mins, oldself.maxs);
 196         self.prevorigin = oldself.origin;
 197         self.reset = SUB_Remove;
 198
 199         Drag_MoveDrag(oldself, self);
 200
 201         self.owner = oldself;
 202
 203         if(self.colormap <= maxclients && self.colormap > 0)
 204                 self.colormap = 1024 + oldself.clientcolors;
 205
 206         CSQCMODEL_AUTOINIT();
 207         self.CopyBody_nextthink = oldself.nextthink;
 208         self.CopyBody_think = oldself.think;
 209         self.nextthink = time;
 210         self.think = CopyBody_Think;
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // defaults for legacy .zym models without animinfo files
 229         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 230         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 231         self.anim_draw = animfixfps(self, '2 1 3');
 232         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 233         self.anim_duckwalk = animfixfps(self, '4 1 1');
 234         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 235         self.anim_duckidle = animfixfps(self, '6 1 1');
 236         self.anim_idle = animfixfps(self, '7 1 1');
 237         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 239         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 240         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 241         self.anim_taunt = animfixfps(self, '12 1 0.33');
 242         self.anim_run = animfixfps(self, '13 1 1');
 243         self.anim_runbackwards = animfixfps(self, '14 1 1');
 244         self.anim_strafeleft = animfixfps(self, '15 1 1');
 245         self.anim_straferight = animfixfps(self, '16 1 1');
 246         //self.anim_dead1 = animfixfps(self, '17 1 1');
 247         //self.anim_dead2 = animfixfps(self, '18 1 1');
 248         self.anim_forwardright = animfixfps(self, '19 1 1');
 249         self.anim_forwardleft = animfixfps(self, '20 1 1');
 250         self.anim_backright = animfixfps(self, '21 1 1');
 251         self.anim_backleft  = animfixfps(self, '22 1 1');
 252         self.anim_melee = animfixfps(self, '23 1 1');
 253         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 254         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 255         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 256         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 257         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 258         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 259         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 260         // TODO introspect models for finding right "fps" value (1/duration)
 261         // reset animstate now
 262         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 263 }
 264
 265 void player_anim (void)
 266 {
 267         updateanim(self);
 268         if (self.weaponentity)
 269                 updateanim(self.weaponentity);
 270
 271         if (self.deadflag != DEAD_NO)
 272                 return;
 273
 274         if (!self.animstate_override)
 275         {
 276                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 277                 {
 278                         if (self.crouch)
 279                         {
 280                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 281                                 {
 282                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 283                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 284                                         {
 285                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 286                                                 self.restart_jump = FALSE;
 287                                         }
 288                                 }
 289                         }
 290                         else
 291                         {
 292                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 293                 {
 294                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 295                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 296                     {
 297                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 298                         self.restart_jump = FALSE;
 299                     }
 300                 }
 301                         }
 302                 }
 303                 else if (self.crouch)
 304                 {
 305                         if (self.movement_x > 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x < 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y > 0)
 310                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y < 0)
 312                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y > 0)
 314                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y < 0)
 316                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y > 0)
 318                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y < 0)
 320                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 321                         else
 322                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 323                 }
 324                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 325                 {
 326                         if (self.movement_x > 0 && self.movement_y == 0)
 327                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 328                         else if (self.movement_x < 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x == 0 && self.movement_y > 0)
 331                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y < 0)
 333                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x > 0 && self.movement_y > 0)
 335                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y < 0)
 337                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x < 0 && self.movement_y > 0)
 339                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y < 0)
 341                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 342                         else
 343                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 344                 }
 345                 else
 346                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 347         }
 348
 349         if (self.weaponentity)
 350         if (!self.weaponentity.animstate_override)
 351                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 352 }
 353
 354 void SpawnThrownWeapon (vector org, float w)
 355 {
 356         if(g_minstagib)
 357         if(self.ammo_cells <= 0)
 358                 return;
 359
 360         if(g_pinata)
 361         {
 362                 float j;
 363                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 364                 {
 365                         if(self.weapons & W_WeaponBit(j))
 366                                 if(W_IsWeaponThrowable(j))
 367                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 368                 }
 369         }
 370         else
 371         {
 372                 if(W_IsWeaponThrowable(self.weapon))
 373                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 374         }
 375 }
 376
 377 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 378 {
 379         float take, save;
 380         vector v;
 381         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 382
 383         // damage resistance (ignore most of the damage from a bullet or similar)
 384         damage = max(damage - 5, 1);
 385
 386         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 387         take = v_x;
 388         save = v_y;
 389
 390         if(sound_allowed(MSG_BROADCAST, attacker))
 391         {
 392                 if (save > 10)
 393                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 394                 else if (take > 30)
 395                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 396                 else if (take > 10)
 397                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 398         }
 399
 400         if (take > 50)
 401                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 402         if (take > 100)
 403                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 404
 405         if (!(self.flags & FL_GODMODE))
 406         {
 407                 self.armorvalue = self.armorvalue - save;
 408                 self.health = self.health - take;
 409                 // pause regeneration for 5 seconds
 410                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 411         }
 412         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 413         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 414         self.dmg_inflictor = inflictor;
 415
 416         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 417         {
 418                 // don't use any animations as a gib
 419                 self.frame = 0;
 420                 // view just above the floor
 421                 self.view_ofs = '0 0 4';
 422
 423                 Violence_GibSplash(self, 1, 1, attacker);
 424                 self.alpha = -1;
 425                 self.solid = SOLID_NOT; // restore later
 426                 self.takedamage = DAMAGE_NO; // restore later
 427         }
 428 }
 429
 430 void ClientKill_Now_TeamChange();
 431 void freezetag_CheckWinner();
 432
 433 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 434 {
 435         float take, save, waves, sdelay, dh, da, j;
 436         vector v;
 437         float valid_damage_for_weaponstats;
 438         float excess;
 439
 440         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 441                 return;
 442
 443         dh = max(self.health, 0);
 444         da = max(self.armorvalue, 0);
 445
 446         if(!DEATH_ISSPECIAL(deathtype))
 447         {
 448                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 449                 if(self != attacker)
 450                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 451         }
 452
 453         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 454         {
 455                 // tuba causes blood to come out of the ears
 456                 vector ear1, ear2;
 457                 vector d;
 458                 float f;
 459                 ear1 = self.origin;
 460                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 461                 ear2 = ear1;
 462                 makevectors(self.angles);
 463                 ear1 += v_right * -10;
 464                 ear2 += v_right * +10;
 465                 d = inflictor.origin - self.origin;
 466                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 467                 force = v_right * vlen(force);
 468                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 469                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 470                 if(f > 0)
 471                 {
 472                         hitloc = ear1;
 473                         force = force * -1;
 474                 }
 475                 else
 476                 {
 477                         hitloc = ear2;
 478                         // force is already good
 479                 }
 480         }
 481         else
 482                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 483
 484         if (!g_minstagib)
 485         {
 486                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 487                 take = v_x;
 488                 save = v_y;
 489         }
 490         else
 491         {
 492                 save = 0;
 493                 take = damage;
 494         }
 495
 496         frag_inflictor = inflictor;
 497         frag_attacker = attacker;
 498         frag_target = self;
 499         damage_take = take;
 500         damage_save = save;
 501         damage_force = force;
 502         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 503         take = bound(0, damage_take, self.health);
 504         save = bound(0, damage_save, self.armorvalue);
 505         excess = max(0, damage - take - save);
 506
 507         if(sound_allowed(MSG_BROADCAST, attacker))
 508         {
 509                 if (save > 10)
 510                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 511                 else if (take > 30)
 512                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 513                 else if (take > 10)
 514                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 515         }
 516
 517         if (take > 50)
 518                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 519         if (take > 100)
 520                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 521
 522         if (time >= self.spawnshieldtime)
 523         {
 524                 if (!(self.flags & FL_GODMODE))
 525                 {
 526                         self.armorvalue = self.armorvalue - save;
 527                         self.health = self.health - take;
 528                         // pause regeneration for 5 seconds
 529                         if(take)
 530                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 531
 532                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 533                         {
 534                                 self.pain_finished = time + 0.5;        //Supajoe
 535
 536                                 if(sv_gentle < 1) {
 537                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 538                                         {
 539                                                 if (!self.animstate_override)
 540                                                 {
 541                                                         if (random() > 0.5)
 542                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 543                                                         else
 544                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 545                                                 }
 546                                         }
 547
 548                                         if(sound_allowed(MSG_BROADCAST, attacker))
 549                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 550                                         if(self.health > 1)
 551                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 552                                         {
 553                                                 if(deathtype == DEATH_FALL)
 554                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 555                                                 else if(self.health > 75) // TODO make a "gentle" version?
 556                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                                 else if(self.health > 50)
 558                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 559                                                 else if(self.health > 25)
 560                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 561                                                 else
 562                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 563                                         }
 564                                 }
 565
 566                                 // throw off bot aim temporarily
 567                                 float shake;
 568                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 569                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 570                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 571                         }
 572                 }
 573                 else
 574                         self.max_armorvalue += (save + take);
 575         }
 576         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 577         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 578         self.dmg_inflictor = inflictor;
 579
 580         if(attacker == self)
 581         {
 582                 // don't reset pushltime for self damage as it may be an attempt to
 583                 // escape a lava pit or similar
 584                 //self.pushltime = 0;
 585         }
 586         else if(attacker.classname == "player")
 587         {
 588                 self.pusher = attacker;
 589                 self.pushltime = time + autocvar_g_maxpushtime;
 590         }
 591         else if(time < self.pushltime)
 592         {
 593                 attacker = self.pusher;
 594                 self.pushltime = max(self.pushltime, time + 0.6);
 595         }
 596         else
 597                 self.pushltime = 0;
 598
 599         float abot, vbot, awep;
 600         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 601         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 602
 603         valid_damage_for_weaponstats = 0;
 604         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 605         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 606         if(attacker && self != attacker)
 607         if(IsDifferentTeam(self, attacker))
 608         {
 609                 if(DEATH_ISSPECIAL(deathtype))
 610                         awep = attacker.weapon;
 611                 else
 612                         awep = DEATH_WEAPONOF(deathtype);
 613                 valid_damage_for_weaponstats = 1;
 614         }
 615
 616         if(valid_damage_for_weaponstats)
 617         {
 618                 dh = dh - max(self.health, 0);
 619                 da = da - max(self.armorvalue, 0);
 620                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 621         }
 622
 623         if (self.health < 1)
 624         {
 625                 float defer_ClientKill_Now_TeamChange;
 626                 defer_ClientKill_Now_TeamChange = FALSE;
 627
 628                 if(self.alivetime)
 629                 {
 630                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 631                         self.alivetime = 0;
 632                 }
 633
 634                 if(valid_damage_for_weaponstats)
 635                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 636
 637                 if(sv_gentle < 1) // TODO make a "gentle" version?
 638                 if(sound_allowed(MSG_BROADCAST, attacker))
 639                 {
 640                         if(deathtype == DEATH_DROWN)
 641                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 642                         else
 643                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 644                 }
 645
 646                 // get rid of kill indicator
 647                 if(self.killindicator)
 648                 {
 649                         remove(self.killindicator);
 650                         self.killindicator = world;
 651                         if(self.killindicator_teamchange)
 652                                 defer_ClientKill_Now_TeamChange = TRUE;
 653
 654                         if(self.classname == "body")
 655                         if(deathtype == DEATH_KILL)
 656                         {
 657                                 // for the lemmings fans, a small harmless explosion
 658                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 659                         }
 660                 }
 661
 662                 if(!g_freezetag)
 663                 {
 664                         // become fully visible
 665                         self.alpha = default_player_alpha;
 666                         // throw a weapon
 667                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 668                 }
 669
 670                 // print an obituary message
 671                 Obituary (attacker, inflictor, self, deathtype);
 672                 race_PreDie();
 673                 DropAllRunes(self);
 674
 675         // increment frag counter for used weapon type
 676         float w;
 677         w = DEATH_WEAPONOF(deathtype);
 678         if(WEP_VALID(w))
 679         if(accuracy_isgooddamage(attacker, self))
 680         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 681
 682                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 683                 {
 684                         PutClientInServer();
 685                         count_alive_players(); // re-count players
 686                         freezetag_CheckWinner();
 687                         return;
 688                 }
 689
 690                 frag_attacker = attacker;
 691                 frag_inflictor = inflictor;
 692                 frag_target = self;
 693                 MUTATOR_CALLHOOK(PlayerDies);
 694                 weapon_action(self.weapon, WR_PLAYERDEATH);
 695
 696                 RemoveGrapplingHook(self);
 697
 698                 if(self.flagcarried)
 699                 {
 700                         if(attacker.classname != "player")
 701                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 702                         else if(attacker.team == self.team)
 703                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 704                         else
 705                                 DropFlag(self.flagcarried, world, attacker);
 706                 }
 707                 if(self.ballcarried && g_nexball)
 708                         DropBall(self.ballcarried, self.origin, self.velocity);
 709                 Portal_ClearAllLater(self);
 710
 711                 if(clienttype(self) == CLIENTTYPE_REAL)
 712                 {
 713                         stuffcmd(self, "-zoom\n");
 714                         self.fixangle = TRUE;
 715                         //msg_entity = self;
 716                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 717                         //WriteAngle (MSG_ONE, self.v_angle_x);
 718                         //WriteAngle (MSG_ONE, self.v_angle_y);
 719                         //WriteAngle (MSG_ONE, 80);
 720                 }
 721
 722                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 723                         ClientKill_Now_TeamChange();
 724
 725                 if(g_arena)
 726                         Spawnqueue_Unmark(self);
 727
 728                 if(g_freezetag)
 729                         return;
 730
 731                 // when we get here, player actually dies
 732                 // clear waypoints (do this AFTER FreezeTag)
 733                 WaypointSprite_PlayerDead();
 734
 735                 // make the corpse upright (not tilted)
 736                 self.angles_x = 0;
 737                 self.angles_z = 0;
 738                 // don't spin
 739                 self.avelocity = '0 0 0';
 740                 // view from the floor
 741                 self.view_ofs = '0 0 -8';
 742                 // toss the corpse
 743                 self.movetype = MOVETYPE_TOSS;
 744                 // shootable corpse
 745                 self.solid = SOLID_CORPSE;
 746                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 747                 // don't stick to the floor
 748                 self.flags &~= FL_ONGROUND;
 749                 // dying animation
 750                 self.deadflag = DEAD_DYING;
 751                 // when to allow respawn
 752                 sdelay = 0;
 753                 waves = 0;
 754                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 755                 if(!sdelay)
 756                 {
 757                         if(g_cts)
 758                                 sdelay = 0; // no respawn delay in CTS
 759                         else
 760                                 sdelay = autocvar_g_respawn_delay;
 761                 }
 762                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 763                 if(!waves)
 764                         waves = autocvar_g_respawn_waves;
 765                 if(waves)
 766                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 767                 else
 768                         self.respawn_time = time + sdelay;
 769                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 770                         self.respawn_countdown = 10; // first number to count down from is 10
 771                 else
 772                         self.respawn_countdown = -1; // do not count down
 773                 self.death_time = time;
 774                 if (random() < 0.5)
 775                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 776                 else
 777                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 778                 if (self.maxs_z > 5)
 779                 {
 780                         self.maxs_z = 5;
 781                         setsize(self, self.mins, self.maxs);
 782                 }
 783                 // set damage function to corpse damage
 784                 self.event_damage = PlayerCorpseDamage;
 785                 // call the corpse damage function just in case it wants to gib
 786                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 787                 // set up to fade out later
 788                 SUB_SetFade (self, time + 6 + random (), 1);
 789
 790                 if(sv_gentle > 0 || autocvar_ekg) {
 791                         // remove corpse
 792                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 793                 }
 794
 795                 // reset fields the weapons may use just in case
 796                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 797                 {
 798                         weapon_action(j, WR_RESETPLAYER);
 799                         ATTACK_FINISHED_FOR(self, j) = 0;
 800                 }
 801         }
 802 }
 803
 804 .float muted; // to be used by prvm_edictset server playernumber muted 1
 805 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 806 // message "": do not say, just test flood control
 807 // return value:
 808 //   1 = accept
 809 //   0 = reject
 810 //  -1 = fake accept
 811 {
 812         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 813         float flood, privatemsgprefixlen;
 814         var .float flood_field;
 815         entity head;
 816         float ret;
 817
 818         if(Ban_MaybeEnforceBan(source))
 819                 return 0;
 820
 821         if(!teamsay && !privatesay)
 822                 if(substring(msgin, 0, 1) == " ")
 823                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 824
 825         msgin = formatmessage(msgin);
 826
 827         if(source.classname != "player")
 828                 colorstr = "^0"; // black for spectators
 829         else if(teamplay)
 830                 colorstr = Team_ColorCode(source.team);
 831         else
 832                 teamsay = FALSE;
 833
 834         if(intermission_running)
 835                 teamsay = FALSE;
 836
 837         if(msgin != "")
 838                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 839
 840         /*
 841          * using bprint solves this... me stupid
 842         // how can we prevent the message from appearing in a listen server?
 843         // for now, just give "say" back and only handle say_team
 844         if(!teamsay)
 845         {
 846                 clientcommand(self, strcat("say ", msgin));
 847                 return;
 848         }
 849         */
 850
 851         if(autocvar_g_chat_teamcolors)
 852                 namestr = playername(source);
 853         else
 854                 namestr = source.netname;
 855
 856         if(msgin != "")
 857         {
 858                 if(privatesay)
 859                 {
 860                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 861                         privatemsgprefixlen = strlen(msgstr);
 862                         msgstr = strcat(msgstr, msgin);
 863                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 864                         if(autocvar_g_chat_teamcolors)
 865                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 866                         else
 867                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 868                 }
 869                 else if(teamsay)
 870                 {
 871                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 872                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 873                 }
 874                 else
 875                 {
 876                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 877                         cmsgstr = "";
 878                 }
 879                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 880         }
 881         else
 882         {
 883                 msgstr = cmsgstr = "";
 884         }
 885
 886         fullmsgstr = msgstr;
 887         fullcmsgstr = cmsgstr;
 888
 889         // FLOOD CONTROL
 890         flood = 0;
 891         if(floodcontrol)
 892         {
 893                 float flood_spl;
 894                 float flood_burst;
 895                 float flood_lmax;
 896                 float lines;
 897                 if(privatesay)
 898                 {
 899                         flood_spl = autocvar_g_chat_flood_spl_tell;
 900                         flood_burst = autocvar_g_chat_flood_burst_tell;
 901                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 902                         flood_field = floodcontrol_chattell;
 903                 }
 904                 else if(teamsay)
 905                 {
 906                         flood_spl = autocvar_g_chat_flood_spl_team;
 907                         flood_burst = autocvar_g_chat_flood_burst_team;
 908                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 909                         flood_field = floodcontrol_chatteam;
 910                 }
 911                 else
 912                 {
 913                         flood_spl = autocvar_g_chat_flood_spl;
 914                         flood_burst = autocvar_g_chat_flood_burst;
 915                         flood_lmax = autocvar_g_chat_flood_lmax;
 916                         flood_field = floodcontrol_chat;
 917                 }
 918                 flood_burst = max(0, flood_burst - 1);
 919                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 920
 921                 // do flood control for the default line size
 922                 if(msgstr != "")
 923                 {
 924                         getWrappedLine_remaining = msgstr;
 925                         msgstr = "";
 926                         lines = 0;
 927                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 928                         {
 929                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 930                                 ++lines;
 931                         }
 932                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 933
 934                         if(getWrappedLine_remaining != "")
 935                         {
 936                                 msgstr = strcat(msgstr, "\n");
 937                                 flood = 2;
 938                         }
 939
 940                         if(time >= source.flood_field)
 941                         {
 942                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 943                         }
 944                         else
 945                         {
 946                                 flood = 1;
 947                                 msgstr = fullmsgstr;
 948                         }
 949                 }
 950                 else
 951                 {
 952                         if(time >= source.flood_field)
 953                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 954                         else
 955                                 flood = 1;
 956                 }
 957
 958                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 959                         source.flood_field = flood = 0;
 960         }
 961
 962         if(flood == 2) // cannot happen for empty msgstr
 963         {
 964                 if(autocvar_g_chat_flood_notify_flooder)
 965                 {
 966                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 967                         sourcecmsgstr = "";
 968                 }
 969                 else
 970                 {
 971                         sourcemsgstr = fullmsgstr;
 972                         sourcecmsgstr = fullcmsgstr;
 973                 }
 974                 cmsgstr = "";
 975         }
 976         else
 977         {
 978                 sourcemsgstr = msgstr;
 979                 sourcecmsgstr = cmsgstr;
 980         }
 981
 982         if(!privatesay)
 983         if(source.classname != "player")
 984         {
 985                 if not(intermission_running)
 986                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 987                                 teamsay = -1; // spectators
 988         }
 989
 990         if(flood)
 991                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 992
 993         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 994         if(privatesay)
 995                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 996
 997         if(source.muted)
 998         {
 999                 // always fake the message
1000                 ret = -1;
1001         }
1002         else if(flood == 1)
1003         {
1004                 if(autocvar_g_chat_flood_notify_flooder)
1005                 {
1006                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1007                         ret = 0;
1008                 }
1009                 else
1010                         ret = -1;
1011         }
1012         else
1013         {
1014                 ret = 1;
1015         }
1016
1017         if(sourcemsgstr != "" && ret != 0)
1018         {
1019                 if(ret < 0) // faked message, because the player is muted
1020                 {
1021                         sprint(source, sourcemsgstr);
1022                         if(sourcecmsgstr != "" && !privatesay)
1023                                 centerprint(source, sourcecmsgstr);
1024                 }
1025                 else if(privatesay) // private message, between 2 people only, not sent to server console
1026                 {
1027                         sprint(source, sourcemsgstr);
1028                         sprint(privatesay, msgstr);
1029                         if(cmsgstr != "")
1030                                 centerprint(privatesay, cmsgstr);
1031                 }
1032                 else if(teamsay > 0) // team message, only sent to team mates
1033                 {
1034                         sprint(source, sourcemsgstr);
1035                         //print(msgstr); // send to server console too
1036                         if(sourcecmsgstr != "")
1037                                 centerprint(source, sourcecmsgstr);
1038                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1039                                 if(head != source)
1040                                 {
1041                                         sprint(head, msgstr);
1042                                         if(cmsgstr != "")
1043                                                 centerprint(head, cmsgstr);
1044                                 }
1045                 }
1046                 else if(teamsay < 0) // spectator message, only sent to spectators
1047                 {
1048                         sprint(source, sourcemsgstr);
1049                         //print(msgstr); // send to server console too
1050                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1051                                 if(head != source)
1052                                         sprint(head, msgstr);
1053                 }
1054                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1055                 {
1056                         sprint(source, sourcemsgstr);
1057                         //print(msgstr); // send to server console too
1058                         FOR_EACH_REALCLIENT(head)
1059                                 if(head != source)
1060                                         sprint(head, msgstr);
1061                 }
1062                 else
1063                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1064         }
1065
1066         return ret;
1067 }
1068
1069 float GetVoiceMessageVoiceType(string type)
1070 {
1071         if(type == "taunt")
1072                 return VOICETYPE_TAUNT;
1073         if(type == "teamshoot")
1074                 return VOICETYPE_LASTATTACKER;
1075         return VOICETYPE_TEAMRADIO;
1076 }
1077
1078 string allvoicesamples;
1079 .string GetVoiceMessageSampleField(string type)
1080 {
1081         GetPlayerSoundSampleField_notFound = 0;
1082         switch(type)
1083         {
1084 #define _VOICEMSG(m) case #m: return playersound_##m;
1085                 ALLVOICEMSGS
1086 #undef _VOICEMSG
1087         }
1088         GetPlayerSoundSampleField_notFound = 1;
1089         return playersound_taunt;
1090 }
1091
1092 .string GetPlayerSoundSampleField(string type)
1093 {
1094         GetPlayerSoundSampleField_notFound = 0;
1095         switch(type)
1096         {
1097 #define _VOICEMSG(m) case #m: return playersound_##m;
1098                 ALLPLAYERSOUNDS
1099 #undef _VOICEMSG
1100         }
1101         GetPlayerSoundSampleField_notFound = 1;
1102         return playersound_taunt;
1103 }
1104
1105 void PrecacheGlobalSound(string samplestring)
1106 {
1107         float n, i;
1108         tokenize_console(samplestring);
1109         n = stof(argv(1));
1110         if(n > 0)
1111         {
1112                 for(i = 1; i <= n; ++i)
1113                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1114         }
1115         else
1116         {
1117                 precache_sound(strcat(argv(0), ".wav"));
1118         }
1119 }
1120
1121 void PrecachePlayerSounds(string f)
1122 {
1123         float fh;
1124         string s;
1125         fh = fopen(f, FILE_READ);
1126         if(fh < 0)
1127                 return;
1128         while((s = fgets(fh)))
1129         {
1130                 if(tokenize_console(s) != 3)
1131                 {
1132                         dprint("Invalid sound info line: ", s, "\n");
1133                         continue;
1134                 }
1135                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1136         }
1137         fclose(fh);
1138
1139         if not(allvoicesamples)
1140         {
1141 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1142                 ALLVOICEMSGS
1143 #undef _VOICEMSG
1144                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1145         }
1146 }
1147
1148 void ClearPlayerSounds()
1149 {
1150 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1151         ALLPLAYERSOUNDS
1152         ALLVOICEMSGS
1153 #undef _VOICEMSG
1154 }
1155
1156 float LoadPlayerSounds(string f, float first)
1157 {
1158         float fh;
1159         string s;
1160         var .string field;
1161         fh = fopen(f, FILE_READ);
1162         if(fh < 0)
1163         {
1164                 dprint("Player sound file not found: ", f, "\n");
1165                 return 0;
1166         }
1167         while((s = fgets(fh)))
1168         {
1169                 if(tokenize_console(s) != 3)
1170                         continue;
1171                 field = GetPlayerSoundSampleField(argv(0));
1172                 if(GetPlayerSoundSampleField_notFound)
1173                         field = GetVoiceMessageSampleField(argv(0));
1174                 if(GetPlayerSoundSampleField_notFound)
1175                         continue;
1176                 if(self.field)
1177                         strunzone(self.field);
1178                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1179         }
1180         fclose(fh);
1181         return 1;
1182 }
1183
1184 .float modelindex_for_playersound;
1185 .float skin_for_playersound;
1186 void UpdatePlayerSounds()
1187 {
1188         if(self.modelindex == self.modelindex_for_playersound)
1189         if(self.skin == self.skin_for_playersound)
1190                 return;
1191         self.modelindex_for_playersound = self.modelindex;
1192         self.skin_for_playersound = self.skin;
1193         ClearPlayerSounds();
1194         LoadPlayerSounds("sound/player/default.sounds", 1);
1195         if(!autocvar_g_debug_defaultsounds)
1196                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1197                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1198 }
1199
1200 void FakeGlobalSound(string sample, float chan, float voicetype)
1201 {
1202         float n;
1203         float tauntrand;
1204
1205         if(sample == "")
1206                 return;
1207
1208         tokenize_console(sample);
1209         n = stof(argv(1));
1210         if(n > 0)
1211                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1212         else
1213                 sample = strcat(argv(0), ".wav"); // randomization
1214
1215         switch(voicetype)
1216         {
1217                 case VOICETYPE_LASTATTACKER_ONLY:
1218                         break;
1219                 case VOICETYPE_LASTATTACKER:
1220                         if(self.pusher)
1221                         {
1222                                 msg_entity = self;
1223                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1224                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1225                         }
1226                         break;
1227                 case VOICETYPE_TEAMRADIO:
1228                         msg_entity = self;
1229                         if(msg_entity.cvar_cl_voice_directional == 1)
1230                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1231                         else
1232                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1233                         break;
1234                 case VOICETYPE_AUTOTAUNT:
1235                         if(!sv_autotaunt)
1236                                 break;
1237                         if(!sv_taunt)
1238                                 break;
1239                         if(sv_gentle)
1240                                 break;
1241                         tauntrand = random();
1242                         msg_entity = self;
1243                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1244                         {
1245                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1246                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1247                                 else
1248                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1249                         }
1250                         break;
1251                 case VOICETYPE_TAUNT:
1252                         if(self.classname == "player")
1253                                 if(self.deadflag == DEAD_NO)
1254                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1255                         if(!sv_taunt)
1256                                 break;
1257                         if(sv_gentle)
1258                                 break;
1259                         msg_entity = self;
1260                         if (msg_entity.cvar_cl_voice_directional >= 1)
1261                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1262                         else
1263                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1264                         break;
1265                 case VOICETYPE_PLAYERSOUND:
1266                         msg_entity = self;
1267                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1268                         break;
1269                 default:
1270                         backtrace("Invalid voice type!");
1271                         break;
1272         }
1273 }
1274
1275 void GlobalSound(string sample, float chan, float voicetype)
1276 {
1277         float n;
1278         float tauntrand;
1279
1280         if(sample == "")
1281                 return;
1282
1283         tokenize_console(sample);
1284         n = stof(argv(1));
1285         if(n > 0)
1286                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1287         else
1288                 sample = strcat(argv(0), ".wav"); // randomization
1289
1290         switch(voicetype)
1291         {
1292                 case VOICETYPE_LASTATTACKER_ONLY:
1293                         if(self.pusher)
1294                         {
1295                                 msg_entity = self.pusher;
1296                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1297                                 {
1298                                         if(msg_entity.cvar_cl_voice_directional == 1)
1299                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1300                                         else
1301                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1302                                 }
1303                         }
1304                         break;
1305                 case VOICETYPE_LASTATTACKER:
1306                         if(self.pusher)
1307                         {
1308                                 msg_entity = self.pusher;
1309                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1310                                 {
1311                                         if(msg_entity.cvar_cl_voice_directional == 1)
1312                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1313                                         else
1314                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1315                                 }
1316                                 msg_entity = self;
1317                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1318                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1319                         }
1320                         break;
1321                 case VOICETYPE_TEAMRADIO:
1322                         FOR_EACH_REALCLIENT(msg_entity)
1323                                 if(!teamplay || msg_entity.team == self.team)
1324                                 {
1325                                         if(msg_entity.cvar_cl_voice_directional == 1)
1326                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1327                                         else
1328                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1329                                 }
1330                         break;
1331                 case VOICETYPE_AUTOTAUNT:
1332                         if(!sv_autotaunt)
1333                                 break;
1334                         if(!sv_taunt)
1335                                 break;
1336                         if(sv_gentle)
1337                                 break;
1338                         tauntrand = random();
1339                         FOR_EACH_REALCLIENT(msg_entity)
1340                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1341                                 {
1342                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1343                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1344                                         else
1345                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1346                                 }
1347                         break;
1348                 case VOICETYPE_TAUNT:
1349                         if(self.classname == "player")
1350                                 if(self.deadflag == DEAD_NO)
1351                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1352                         if(!sv_taunt)
1353                                 break;
1354                         if(sv_gentle)
1355                                 break;
1356                         FOR_EACH_REALCLIENT(msg_entity)
1357                         {
1358                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1359                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1360                                 else
1361                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1362                         }
1363                         break;
1364                 case VOICETYPE_PLAYERSOUND:
1365                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1366                         break;
1367                 default:
1368                         backtrace("Invalid voice type!");
1369                         break;
1370         }
1371 }
1372
1373 void PlayerSound(.string samplefield, float chan, float voicetype)
1374 {
1375         GlobalSound(self.samplefield, chan, voicetype);
1376 }
1377
1378 void VoiceMessage(string type, string msg)
1379 {
1380         var .string sample;
1381         float voicetype, ownteam;
1382         float flood;
1383         sample = GetVoiceMessageSampleField(type);
1384
1385         if(GetPlayerSoundSampleField_notFound)
1386         {
1387                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1388                 return;
1389         }
1390
1391         voicetype = GetVoiceMessageVoiceType(type);
1392         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1393
1394         flood = Say(self, ownteam, world, msg, 1);
1395
1396         if (flood > 0)
1397                 GlobalSound(self.sample, CH_VOICE, voicetype);
1398         else if (flood < 0)
1399                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1400 }
1401
1402 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1403 {
1404 //      show_message
1405 //      0 (00) automove centerprint, admin message
1406 //      1 (01) automove centerprint, no admin message
1407 //      2 (10) no centerprint, admin message
1408 //      3 (11) no centerprint, no admin message
1409
1410         float lockteams_backup;
1411
1412         lockteams_backup = lockteams;  // backup any team lock
1413
1414         lockteams = 0;  // disable locked teams
1415
1416         TeamchangeFrags(client);  // move the players frags
1417         SetPlayerColors(client, team_colour - 1);  // set the players colour
1418         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1419
1420         lockteams = lockteams_backup;  // restore the team lock
1421
1422         LogTeamchange(client.playerid, client.team, type);
1423
1424         if not(show_message & 1) // admin message
1425                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1426
1427         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1428 }