qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.animstate_startframe = oldself.animstate_startframe;
 165         self.animstate_numframes = oldself.animstate_numframes;
 166         self.animstate_framerate = oldself.animstate_framerate;
 167         self.animstate_starttime = oldself.animstate_starttime;
 168         self.animstate_endtime = oldself.animstate_endtime;
 169         self.animstate_override = oldself.animstate_override;
 170         self.animstate_looping = oldself.animstate_looping;
 171         self.dphitcontentsmask = oldself.dphitcontentsmask;
 172         self.death_time = oldself.death_time;
 173         self.frame = oldself.frame;
 174         self.pain_finished = oldself.pain_finished;
 175         self.health = oldself.health;
 176         self.armorvalue = oldself.armorvalue;
 177         self.armortype = oldself.armortype;
 178         self.model = oldself.model;
 179         self.modelindex = oldself.modelindex;
 180         self.skin = oldself.skin;
 181         self.species = oldself.species;
 182         self.movetype = oldself.movetype;
 183         self.solid = oldself.solid;
 184         self.ballistics_density = oldself.ballistics_density;
 185         self.takedamage = oldself.takedamage;
 186         self.customizeentityforclient = oldself.customizeentityforclient;
 187         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 188         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 189         if (keepvelocity == 1)
 190                 self.velocity = oldself.velocity;
 191         self.oldvelocity = self.velocity;
 192         self.alpha = oldself.alpha;
 193         self.fade_time = oldself.fade_time;
 194         self.fade_rate = oldself.fade_rate;
 195         //self.weapon = oldself.weapon;
 196         setorigin(self, oldself.origin);
 197         setsize(self, oldself.mins, oldself.maxs);
 198         self.prevorigin = oldself.origin;
 199         self.reset = SUB_Remove;
 200
 201         Drag_MoveDrag(oldself, self);
 202
 203         if(self.colormap <= maxclients && self.colormap > 0)
 204                 self.colormap = 1024 + oldself.clientcolors;
 205
 206         CSQCMODEL_AUTOINIT();
 207         self.CopyBody_nextthink = oldself.nextthink;
 208         self.CopyBody_think = oldself.think;
 209         self.nextthink = time;
 210         self.think = CopyBody_Think;
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // defaults for legacy .zym models without animinfo files
 229         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 230         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 231         self.anim_draw = animfixfps(self, '2 1 3');
 232         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 233         self.anim_duckwalk = animfixfps(self, '4 1 1');
 234         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 235         self.anim_duckidle = animfixfps(self, '6 1 1');
 236         self.anim_idle = animfixfps(self, '7 1 1');
 237         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 239         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 240         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 241         self.anim_taunt = animfixfps(self, '12 1 0.33');
 242         self.anim_run = animfixfps(self, '13 1 1');
 243         self.anim_runbackwards = animfixfps(self, '14 1 1');
 244         self.anim_strafeleft = animfixfps(self, '15 1 1');
 245         self.anim_straferight = animfixfps(self, '16 1 1');
 246         //self.anim_dead1 = animfixfps(self, '17 1 1');
 247         //self.anim_dead2 = animfixfps(self, '18 1 1');
 248         self.anim_forwardright = animfixfps(self, '19 1 1');
 249         self.anim_forwardleft = animfixfps(self, '20 1 1');
 250         self.anim_backright = animfixfps(self, '21 1 1');
 251         self.anim_backleft  = animfixfps(self, '22 1 1');
 252         self.anim_melee = animfixfps(self, '23 1 1');
 253         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 254         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 255         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 256         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 257         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 258         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 259         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 260         // TODO introspect models for finding right "fps" value (1/duration)
 261         // reset animstate now
 262         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 263 }
 264
 265 void player_anim (void)
 266 {
 267         updateanim(self);
 268         if (self.weaponentity)
 269                 updateanim(self.weaponentity);
 270
 271         if (self.deadflag != DEAD_NO)
 272                 return;
 273
 274         if (!self.animstate_override)
 275         {
 276                 if (self.freezetag_frozen)
 277                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 278                 else if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 279                 {
 280                         if (self.crouch)
 281                         {
 282                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 283                                 {
 284                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 285                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 286                                         {
 287                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 288                                                 self.restart_jump = FALSE;
 289                                         }
 290                                 }
 291                         }
 292                         else
 293                         {
 294                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 295                 {
 296                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 297                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 298                     {
 299                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 300                         self.restart_jump = FALSE;
 301                     }
 302                 }
 303                         }
 304                 }
 305                 else if (self.crouch)
 306                 {
 307                         if (self.movement_x > 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x < 0 && self.movement_y == 0)
 310                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x == 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x > 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y > 0)
 320                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x < 0 && self.movement_y < 0)
 322                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_minstagib)
 359         if(self.ammo_cells <= 0)
 360                 return;
 361
 362         if(g_pinata)
 363         {
 364                 float j;
 365                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 366                 {
 367                         if(WEPSET_CONTAINS_EW(self, j))
 368                                 if(W_IsWeaponThrowable(j))
 369                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 370                 }
 371         }
 372         else
 373         {
 374                 if(W_IsWeaponThrowable(self.weapon))
 375                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 376         }
 377 }
 378
 379 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 380 {
 381         float take, save;
 382         vector v;
 383         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 384
 385         // damage resistance (ignore most of the damage from a bullet or similar)
 386         damage = max(damage - 5, 1);
 387
 388         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 389         take = v_x;
 390         save = v_y;
 391
 392         if(sound_allowed(MSG_BROADCAST, attacker))
 393         {
 394                 if (save > 10)
 395                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 396                 else if (take > 30)
 397                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 398                 else if (take > 10)
 399                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 400         }
 401
 402         if (take > 50)
 403                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 404         if (take > 100)
 405                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 406
 407         if (!(self.flags & FL_GODMODE))
 408         {
 409                 self.armorvalue = self.armorvalue - save;
 410                 self.health = self.health - take;
 411                 // pause regeneration for 5 seconds
 412                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 413         }
 414         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 415         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 416         self.dmg_inflictor = inflictor;
 417
 418         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 419         {
 420                 // don't use any animations as a gib
 421                 self.frame = 0;
 422                 // view just above the floor
 423                 self.view_ofs = '0 0 4';
 424
 425                 Violence_GibSplash(self, 1, 1, attacker);
 426                 self.alpha = -1;
 427                 self.solid = SOLID_NOT; // restore later
 428                 self.takedamage = DAMAGE_NO; // restore later
 429                 self.damagedbycontents = FALSE;
 430         }
 431 }
 432
 433 void ClientKill_Now_TeamChange();
 434
 435 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 436 {
 437         float take, save, waves, sdelay, dh, da, j;
 438         vector v;
 439         float valid_damage_for_weaponstats;
 440         float excess;
 441
 442         dh = max(self.health, 0);
 443         da = max(self.armorvalue, 0);
 444
 445         if(!DEATH_ISSPECIAL(deathtype))
 446         {
 447                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 448                 if(self != attacker)
 449                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 450         }
 451
 452         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 453         {
 454                 // tuba causes blood to come out of the ears
 455                 vector ear1, ear2;
 456                 vector d;
 457                 float f;
 458                 ear1 = self.origin;
 459                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 460                 ear2 = ear1;
 461                 makevectors(self.angles);
 462                 ear1 += v_right * -10;
 463                 ear2 += v_right * +10;
 464                 d = inflictor.origin - self.origin;
 465                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 466                 force = v_right * vlen(force);
 467                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 468                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 469                 if(f > 0)
 470                 {
 471                         hitloc = ear1;
 472                         force = force * -1;
 473                 }
 474                 else
 475                 {
 476                         hitloc = ear2;
 477                         // force is already good
 478                 }
 479         }
 480         else
 481                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 482
 483         if (!g_minstagib)
 484         {
 485                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 486                 take = v_x;
 487                 save = v_y;
 488         }
 489         else
 490         {
 491                 save = 0;
 492                 take = damage;
 493         }
 494
 495         if(attacker == self)
 496         {
 497                 // don't reset pushltime for self damage as it may be an attempt to
 498                 // escape a lava pit or similar
 499                 //self.pushltime = 0;
 500                 self.istypefrag = 0;
 501         }
 502         else if(attacker.classname == "player")
 503         {
 504                 self.pusher = attacker;
 505                 self.pushltime = time + autocvar_g_maxpushtime;
 506                 self.istypefrag = self.BUTTON_CHAT;
 507         }
 508         else if(time < self.pushltime)
 509         {
 510                 attacker = self.pusher;
 511                 self.pushltime = max(self.pushltime, time + 0.6);
 512         }
 513         else
 514         {
 515                 self.pushltime = 0;
 516                 self.istypefrag = 0;
 517         }
 518
 519         frag_inflictor = inflictor;
 520         frag_attacker = attacker;
 521         frag_target = self;
 522         damage_take = take;
 523         damage_save = save;
 524         damage_force = force;
 525         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 526         take = bound(0, damage_take, self.health);
 527         save = bound(0, damage_save, self.armorvalue);
 528         excess = max(0, damage - take - save);
 529
 530         if(sound_allowed(MSG_BROADCAST, attacker))
 531         {
 532                 if (save > 10)
 533                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 534                 else if (take > 30)
 535                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 536                 else if (take > 10)
 537                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 538         }
 539
 540         if (take > 50)
 541                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 542         if (take > 100)
 543                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 544
 545         if (time >= self.spawnshieldtime)
 546         {
 547                 if (!(self.flags & FL_GODMODE))
 548                 {
 549                         self.armorvalue = self.armorvalue - save;
 550                         self.health = self.health - take;
 551                         // pause regeneration for 5 seconds
 552                         if(take)
 553                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 554
 555                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 556                         {
 557                                 self.pain_finished = time + 0.5;        //Supajoe
 558
 559                                 if(sv_gentle < 1) {
 560                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 561                                         {
 562                                                 if (!self.animstate_override)
 563                                                 {
 564                                                         if (random() > 0.5)
 565                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 566                                                         else
 567                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 568                                                 }
 569                                         }
 570
 571                                         if(sound_allowed(MSG_BROADCAST, attacker))
 572                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 573                                         if(self.health > 1)
 574                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 575                                         {
 576                                                 if(deathtype == DEATH_FALL)
 577                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 578                                                 else if(self.health > 75) // TODO make a "gentle" version?
 579                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 580                                                 else if(self.health > 50)
 581                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 582                                                 else if(self.health > 25)
 583                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 584                                                 else
 585                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 586                                         }
 587                                 }
 588
 589                                 // throw off bot aim temporarily
 590                                 float shake;
 591                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 592                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 593                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 594                         }
 595                 }
 596                 else
 597                         self.max_armorvalue += (save + take);
 598         }
 599         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 600         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 601         self.dmg_inflictor = inflictor;
 602
 603         if(g_ca && self != attacker && attacker.classname == "player")
 604                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 605
 606         float abot, vbot, awep;
 607         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 608         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 609
 610         valid_damage_for_weaponstats = 0;
 611         awep = 0;
 612
 613         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 614         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 615         if(attacker && self != attacker)
 616         if(IsDifferentTeam(self, attacker))
 617         {
 618                 if(DEATH_ISSPECIAL(deathtype))
 619                         awep = attacker.weapon;
 620                 else
 621                         awep = DEATH_WEAPONOF(deathtype);
 622                 valid_damage_for_weaponstats = 1;
 623         }
 624
 625         if(valid_damage_for_weaponstats)
 626         {
 627                 dh = dh - max(self.health, 0);
 628                 da = da - max(self.armorvalue, 0);
 629                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 630         }
 631
 632         if (self.health < 1)
 633         {
 634                 float defer_ClientKill_Now_TeamChange;
 635                 defer_ClientKill_Now_TeamChange = FALSE;
 636
 637                 if(self.alivetime)
 638                 {
 639                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 640                         self.alivetime = 0;
 641                 }
 642
 643                 if(valid_damage_for_weaponstats)
 644                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 645
 646                 if(sv_gentle < 1) // TODO make a "gentle" version?
 647                 if(sound_allowed(MSG_BROADCAST, attacker))
 648                 {
 649                         if(deathtype == DEATH_DROWN)
 650                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 651                         else
 652                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 653                 }
 654
 655                 // get rid of kill indicator
 656                 if(self.killindicator)
 657                 {
 658                         remove(self.killindicator);
 659                         self.killindicator = world;
 660                         if(self.killindicator_teamchange)
 661                                 defer_ClientKill_Now_TeamChange = TRUE;
 662
 663                         if(self.classname == "body")
 664                         if(deathtype == DEATH_KILL)
 665                         {
 666                                 // for the lemmings fans, a small harmless explosion
 667                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 668                         }
 669                 }
 670
 671                 // print an obituary message
 672                 Obituary (attacker, inflictor, self, deathtype);
 673                 race_PreDie();
 674                 DropAllRunes(self);
 675
 676         // increment frag counter for used weapon type
 677         float w;
 678         w = DEATH_WEAPONOF(deathtype);
 679         if(WEP_VALID(w))
 680         if(accuracy_isgooddamage(attacker, self))
 681         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 682
 683                 frag_attacker = attacker;
 684                 frag_inflictor = inflictor;
 685                 frag_target = self;
 686                 frag_deathtype = deathtype;
 687                 MUTATOR_CALLHOOK(PlayerDies);
 688
 689                 weapon_action(self.weapon, WR_PLAYERDEATH);
 690
 691                 RemoveGrapplingHook(self);
 692
 693                 Portal_ClearAllLater(self);
 694
 695                 if(clienttype(self) == CLIENTTYPE_REAL)
 696                 {
 697                         stuffcmd(self, "-zoom\n");
 698                         self.fixangle = TRUE;
 699                         //msg_entity = self;
 700                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 701                         //WriteAngle (MSG_ONE, self.v_angle_x);
 702                         //WriteAngle (MSG_ONE, self.v_angle_y);
 703                         //WriteAngle (MSG_ONE, 80);
 704                 }
 705
 706                 if(defer_ClientKill_Now_TeamChange)
 707                         ClientKill_Now_TeamChange(); // can turn player into spectator
 708
 709                 // player could have been miraculously resuscitated ;)
 710                 // e.g. players in freezetag get frozen, they don't really die
 711                 if(self.health >= 1 || self.classname != "player")
 712                         return;
 713
 714                 // when we get here, player actually dies
 715
 716                 // clear waypoints
 717                 WaypointSprite_PlayerDead();
 718                 // throw a weapon
 719                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 720
 721                 // become fully visible
 722                 self.alpha = default_player_alpha;
 723                 // make the corpse upright (not tilted)
 724                 self.angles_x = 0;
 725                 self.angles_z = 0;
 726                 // don't spin
 727                 self.avelocity = '0 0 0';
 728                 // view from the floor
 729                 self.view_ofs = '0 0 -8';
 730                 // toss the corpse
 731                 self.movetype = MOVETYPE_TOSS;
 732                 // shootable corpse
 733                 self.solid = SOLID_CORPSE;
 734                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 735                 // don't stick to the floor
 736                 self.flags &~= FL_ONGROUND;
 737                 // dying animation
 738                 self.deadflag = DEAD_DYING;
 739                 // when to allow respawn
 740                 sdelay = 0;
 741                 waves = 0;
 742                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 743                 if(!sdelay)
 744                 {
 745                         if(g_cts)
 746                                 sdelay = 0; // no respawn delay in CTS
 747                         else
 748                                 sdelay = autocvar_g_respawn_delay;
 749                 }
 750                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 751                 if(!waves)
 752                         waves = autocvar_g_respawn_waves;
 753                 if(waves)
 754                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 755                 else
 756                         self.respawn_time = time + sdelay;
 757                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 758                         self.respawn_countdown = 10; // first number to count down from is 10
 759                 else
 760                         self.respawn_countdown = -1; // do not count down
 761                 self.death_time = time;
 762                 if (random() < 0.5)
 763                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 764                 else
 765                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 766                 if (self.maxs_z > 5)
 767                 {
 768                         self.maxs_z = 5;
 769                         setsize(self, self.mins, self.maxs);
 770                 }
 771                 // set damage function to corpse damage
 772                 self.event_damage = PlayerCorpseDamage;
 773                 // call the corpse damage function just in case it wants to gib
 774                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 775                 // set up to fade out later
 776                 SUB_SetFade (self, time + 6 + random (), 1);
 777
 778                 if(sv_gentle > 0 || autocvar_ekg) {
 779                         // remove corpse
 780                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 781                 }
 782
 783                 // reset fields the weapons may use just in case
 784                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 785                 {
 786                         weapon_action(j, WR_RESETPLAYER);
 787                         ATTACK_FINISHED_FOR(self, j) = 0;
 788                 }
 789         }
 790 }
 791
 792 .float muted; // to be used by prvm_edictset server playernumber muted 1
 793 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 794 // message "": do not say, just test flood control
 795 // return value:
 796 //   1 = accept
 797 //   0 = reject
 798 //  -1 = fake accept
 799 {
 800         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 801         float flood;
 802         var .float flood_field;
 803         entity head;
 804         float ret;
 805         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 806
 807         if(!teamsay && !privatesay)
 808                 if(substring(msgin, 0, 1) == " ")
 809                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 810
 811         msgin = formatmessage(msgin);
 812
 813         if(source.classname != "player")
 814                 colorstr = "^0"; // black for spectators
 815         else if(teamplay)
 816                 colorstr = Team_ColorCode(source.team);
 817         else
 818         {
 819                 colorstr = "";
 820                 teamsay = FALSE;
 821         }
 822
 823         if(intermission_running)
 824                 teamsay = FALSE;
 825
 826         if(msgin != "")
 827                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 828
 829         /*
 830          * using bprint solves this... me stupid
 831         // how can we prevent the message from appearing in a listen server?
 832         // for now, just give "say" back and only handle say_team
 833         if(!teamsay)
 834         {
 835                 clientcommand(self, strcat("say ", msgin));
 836                 return;
 837         }
 838         */
 839
 840         if(autocvar_g_chat_teamcolors)
 841                 namestr = playername(source);
 842         else
 843                 namestr = source.netname;
 844
 845         if(msgin != "")
 846         {
 847                 if(privatesay)
 848                 {
 849                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 850                         privatemsgprefixlen = strlen(msgstr);
 851                         msgstr = strcat(msgstr, msgin);
 852                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 853                         if(autocvar_g_chat_teamcolors)
 854                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 855                         else
 856                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 857                 }
 858                 else if(teamsay)
 859                 {
 860                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 861                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 862                 }
 863                 else
 864                 {
 865                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 866                         cmsgstr = "";
 867                 }
 868                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 869         }
 870         else
 871         {
 872                 msgstr = cmsgstr = "";
 873         }
 874
 875         fullmsgstr = msgstr;
 876         fullcmsgstr = cmsgstr;
 877
 878         // FLOOD CONTROL
 879         flood = 0;
 880         flood_field = floodcontrol_chat;
 881         if(floodcontrol)
 882         {
 883                 float flood_spl;
 884                 float flood_burst;
 885                 float flood_lmax;
 886                 float lines;
 887                 if(privatesay)
 888                 {
 889                         flood_spl = autocvar_g_chat_flood_spl_tell;
 890                         flood_burst = autocvar_g_chat_flood_burst_tell;
 891                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 892                         flood_field = floodcontrol_chattell;
 893                 }
 894                 else if(teamsay)
 895                 {
 896                         flood_spl = autocvar_g_chat_flood_spl_team;
 897                         flood_burst = autocvar_g_chat_flood_burst_team;
 898                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 899                         flood_field = floodcontrol_chatteam;
 900                 }
 901                 else
 902                 {
 903                         flood_spl = autocvar_g_chat_flood_spl;
 904                         flood_burst = autocvar_g_chat_flood_burst;
 905                         flood_lmax = autocvar_g_chat_flood_lmax;
 906                         flood_field = floodcontrol_chat;
 907                 }
 908                 flood_burst = max(0, flood_burst - 1);
 909                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 910
 911                 // do flood control for the default line size
 912                 if(msgstr != "")
 913                 {
 914                         getWrappedLine_remaining = msgstr;
 915                         msgstr = "";
 916                         lines = 0;
 917                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 918                         {
 919                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 920                                 ++lines;
 921                         }
 922                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 923
 924                         if(getWrappedLine_remaining != "")
 925                         {
 926                                 msgstr = strcat(msgstr, "\n");
 927                                 flood = 2;
 928                         }
 929
 930                         if(time >= source.flood_field)
 931                         {
 932                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 933                         }
 934                         else
 935                         {
 936                                 flood = 1;
 937                                 msgstr = fullmsgstr;
 938                         }
 939                 }
 940                 else
 941                 {
 942                         if(time >= source.flood_field)
 943                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 944                         else
 945                                 flood = 1;
 946                 }
 947
 948                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 949                         source.flood_field = flood = 0;
 950         }
 951
 952         if(flood == 2) // cannot happen for empty msgstr
 953         {
 954                 if(autocvar_g_chat_flood_notify_flooder)
 955                 {
 956                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 957                         sourcecmsgstr = "";
 958                 }
 959                 else
 960                 {
 961                         sourcemsgstr = fullmsgstr;
 962                         sourcecmsgstr = fullcmsgstr;
 963                 }
 964                 cmsgstr = "";
 965         }
 966         else
 967         {
 968                 sourcemsgstr = msgstr;
 969                 sourcecmsgstr = cmsgstr;
 970         }
 971
 972         if(!privatesay)
 973         if(source.classname != "player")
 974         {
 975                 if not(intermission_running)
 976                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 977                                 teamsay = -1; // spectators
 978         }
 979
 980         if(flood)
 981                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 982
 983         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 984         if(privatesay)
 985                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 986
 987         if(source.muted)
 988         {
 989                 // always fake the message
 990                 ret = -1;
 991         }
 992         else if(flood == 1)
 993         {
 994                 if(autocvar_g_chat_flood_notify_flooder)
 995                 {
 996                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 997                         ret = 0;
 998                 }
 999                 else
1000                         ret = -1;
1001         }
1002         else
1003         {
1004                 ret = 1;
1005         }
1006
1007         if(sourcemsgstr != "" && ret != 0)
1008         {
1009                 if(ret < 0) // faked message, because the player is muted
1010                 {
1011                         sprint(source, sourcemsgstr);
1012                         if(sourcecmsgstr != "" && !privatesay)
1013                                 centerprint(source, sourcecmsgstr);
1014                 }
1015                 else if(privatesay) // private message, between 2 people only, not sent to server console
1016                 {
1017                         sprint(source, sourcemsgstr);
1018                         sprint(privatesay, msgstr);
1019                         if(cmsgstr != "")
1020                                 centerprint(privatesay, cmsgstr);
1021                 }
1022                 else if(teamsay > 0) // team message, only sent to team mates
1023                 {
1024                         sprint(source, sourcemsgstr);
1025                         //print(msgstr); // send to server console too
1026                         if(sourcecmsgstr != "")
1027                                 centerprint(source, sourcecmsgstr);
1028                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1029                                 if(head != source)
1030                                 {
1031                                         sprint(head, msgstr);
1032                                         if(cmsgstr != "")
1033                                                 centerprint(head, cmsgstr);
1034                                 }
1035                 }
1036                 else if(teamsay < 0) // spectator message, only sent to spectators
1037                 {
1038                         sprint(source, sourcemsgstr);
1039                         //print(msgstr); // send to server console too
1040                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1041                                 if(head != source)
1042                                         sprint(head, msgstr);
1043                 }
1044                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1045                 {
1046                         sprint(source, sourcemsgstr);
1047                         //print(msgstr); // send to server console too
1048                         FOR_EACH_REALCLIENT(head)
1049                                 if(head != source)
1050                                         sprint(head, msgstr);
1051                 }
1052                 else
1053                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1054         }
1055
1056         return ret;
1057 }
1058
1059 float GetVoiceMessageVoiceType(string type)
1060 {
1061         if(type == "taunt")
1062                 return VOICETYPE_TAUNT;
1063         if(type == "teamshoot")
1064                 return VOICETYPE_LASTATTACKER;
1065         return VOICETYPE_TEAMRADIO;
1066 }
1067
1068 string allvoicesamples;
1069 .string GetVoiceMessageSampleField(string type)
1070 {
1071         GetPlayerSoundSampleField_notFound = 0;
1072         switch(type)
1073         {
1074 #define _VOICEMSG(m) case #m: return playersound_##m;
1075                 ALLVOICEMSGS
1076 #undef _VOICEMSG
1077         }
1078         GetPlayerSoundSampleField_notFound = 1;
1079         return playersound_taunt;
1080 }
1081
1082 .string GetPlayerSoundSampleField(string type)
1083 {
1084         GetPlayerSoundSampleField_notFound = 0;
1085         switch(type)
1086         {
1087 #define _VOICEMSG(m) case #m: return playersound_##m;
1088                 ALLPLAYERSOUNDS
1089 #undef _VOICEMSG
1090         }
1091         GetPlayerSoundSampleField_notFound = 1;
1092         return playersound_taunt;
1093 }
1094
1095 void PrecacheGlobalSound(string samplestring)
1096 {
1097         float n, i;
1098         tokenize_console(samplestring);
1099         n = stof(argv(1));
1100         if(n > 0)
1101         {
1102                 for(i = 1; i <= n; ++i)
1103                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1104         }
1105         else
1106         {
1107                 precache_sound(strcat(argv(0), ".wav"));
1108         }
1109 }
1110
1111 void PrecachePlayerSounds(string f)
1112 {
1113         float fh;
1114         string s;
1115         fh = fopen(f, FILE_READ);
1116         if(fh < 0)
1117                 return;
1118         while((s = fgets(fh)))
1119         {
1120                 if(tokenize_console(s) != 3)
1121                 {
1122                         dprint("Invalid sound info line: ", s, "\n");
1123                         continue;
1124                 }
1125                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1126         }
1127         fclose(fh);
1128
1129         if not(allvoicesamples)
1130         {
1131 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1132                 ALLVOICEMSGS
1133 #undef _VOICEMSG
1134                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1135         }
1136 }
1137
1138 void ClearPlayerSounds()
1139 {
1140 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1141         ALLPLAYERSOUNDS
1142         ALLVOICEMSGS
1143 #undef _VOICEMSG
1144 }
1145
1146 float LoadPlayerSounds(string f, float first)
1147 {
1148         float fh;
1149         string s;
1150         var .string field;
1151         fh = fopen(f, FILE_READ);
1152         if(fh < 0)
1153         {
1154                 dprint("Player sound file not found: ", f, "\n");
1155                 return 0;
1156         }
1157         while((s = fgets(fh)))
1158         {
1159                 if(tokenize_console(s) != 3)
1160                         continue;
1161                 field = GetPlayerSoundSampleField(argv(0));
1162                 if(GetPlayerSoundSampleField_notFound)
1163                         field = GetVoiceMessageSampleField(argv(0));
1164                 if(GetPlayerSoundSampleField_notFound)
1165                         continue;
1166                 if(self.field)
1167                         strunzone(self.field);
1168                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1169         }
1170         fclose(fh);
1171         return 1;
1172 }
1173
1174 .float modelindex_for_playersound;
1175 .float skin_for_playersound;
1176 void UpdatePlayerSounds()
1177 {
1178         if(self.modelindex == self.modelindex_for_playersound)
1179         if(self.skin == self.skin_for_playersound)
1180                 return;
1181         self.modelindex_for_playersound = self.modelindex;
1182         self.skin_for_playersound = self.skin;
1183         ClearPlayerSounds();
1184         LoadPlayerSounds("sound/player/default.sounds", 1);
1185         if(!autocvar_g_debug_defaultsounds)
1186                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1187                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1188 }
1189
1190 void FakeGlobalSound(string sample, float chan, float voicetype)
1191 {
1192         float n;
1193         float tauntrand;
1194
1195         if(sample == "")
1196                 return;
1197
1198         tokenize_console(sample);
1199         n = stof(argv(1));
1200         if(n > 0)
1201                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1202         else
1203                 sample = strcat(argv(0), ".wav"); // randomization
1204
1205         switch(voicetype)
1206         {
1207                 case VOICETYPE_LASTATTACKER_ONLY:
1208                         break;
1209                 case VOICETYPE_LASTATTACKER:
1210                         if(self.pusher)
1211                         {
1212                                 msg_entity = self;
1213                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1214                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1215                         }
1216                         break;
1217                 case VOICETYPE_TEAMRADIO:
1218                         msg_entity = self;
1219                         if(msg_entity.cvar_cl_voice_directional == 1)
1220                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1221                         else
1222                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1223                         break;
1224                 case VOICETYPE_AUTOTAUNT:
1225                         if(!sv_autotaunt)
1226                                 break;
1227                         if(!sv_taunt)
1228                                 break;
1229                         if(sv_gentle)
1230                                 break;
1231                         tauntrand = random();
1232                         msg_entity = self;
1233                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1234                         {
1235                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1236                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1237                                 else
1238                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1239                         }
1240                         break;
1241                 case VOICETYPE_TAUNT:
1242                         if(self.classname == "player")
1243                                 if(self.deadflag == DEAD_NO)
1244                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1245                         if(!sv_taunt)
1246                                 break;
1247                         if(sv_gentle)
1248                                 break;
1249                         msg_entity = self;
1250                         if (msg_entity.cvar_cl_voice_directional >= 1)
1251                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1252                         else
1253                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1254                         break;
1255                 case VOICETYPE_PLAYERSOUND:
1256                         msg_entity = self;
1257                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1258                         break;
1259                 default:
1260                         backtrace("Invalid voice type!");
1261                         break;
1262         }
1263 }
1264
1265 void GlobalSound(string sample, float chan, float voicetype)
1266 {
1267         float n;
1268         float tauntrand;
1269
1270         if(sample == "")
1271                 return;
1272
1273         tokenize_console(sample);
1274         n = stof(argv(1));
1275         if(n > 0)
1276                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1277         else
1278                 sample = strcat(argv(0), ".wav"); // randomization
1279
1280         switch(voicetype)
1281         {
1282                 case VOICETYPE_LASTATTACKER_ONLY:
1283                         if(self.pusher)
1284                         {
1285                                 msg_entity = self.pusher;
1286                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1287                                 {
1288                                         if(msg_entity.cvar_cl_voice_directional == 1)
1289                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1290                                         else
1291                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1292                                 }
1293                         }
1294                         break;
1295                 case VOICETYPE_LASTATTACKER:
1296                         if(self.pusher)
1297                         {
1298                                 msg_entity = self.pusher;
1299                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1300                                 {
1301                                         if(msg_entity.cvar_cl_voice_directional == 1)
1302                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1303                                         else
1304                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1305                                 }
1306                                 msg_entity = self;
1307                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1308                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1309                         }
1310                         break;
1311                 case VOICETYPE_TEAMRADIO:
1312                         FOR_EACH_REALCLIENT(msg_entity)
1313                                 if(!teamplay || msg_entity.team == self.team)
1314                                 {
1315                                         if(msg_entity.cvar_cl_voice_directional == 1)
1316                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1317                                         else
1318                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1319                                 }
1320                         break;
1321                 case VOICETYPE_AUTOTAUNT:
1322                         if(!sv_autotaunt)
1323                                 break;
1324                         if(!sv_taunt)
1325                                 break;
1326                         if(sv_gentle)
1327                                 break;
1328                         tauntrand = random();
1329                         FOR_EACH_REALCLIENT(msg_entity)
1330                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1331                                 {
1332                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1333                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1334                                         else
1335                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1336                                 }
1337                         break;
1338                 case VOICETYPE_TAUNT:
1339                         if(self.classname == "player")
1340                                 if(self.deadflag == DEAD_NO)
1341                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1342                         if(!sv_taunt)
1343                                 break;
1344                         if(sv_gentle)
1345                                 break;
1346                         FOR_EACH_REALCLIENT(msg_entity)
1347                         {
1348                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1349                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1350                                 else
1351                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1352                         }
1353                         break;
1354                 case VOICETYPE_PLAYERSOUND:
1355                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1356                         break;
1357                 default:
1358                         backtrace("Invalid voice type!");
1359                         break;
1360         }
1361 }
1362
1363 void PlayerSound(.string samplefield, float chan, float voicetype)
1364 {
1365         GlobalSound(self.samplefield, chan, voicetype);
1366 }
1367
1368 void VoiceMessage(string type, string msg)
1369 {
1370         var .string sample;
1371         float voicetype, ownteam;
1372         float flood;
1373         sample = GetVoiceMessageSampleField(type);
1374
1375         if(GetPlayerSoundSampleField_notFound)
1376         {
1377                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1378                 return;
1379         }
1380
1381         voicetype = GetVoiceMessageVoiceType(type);
1382         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1383
1384         flood = Say(self, ownteam, world, msg, 1);
1385
1386         if (flood > 0)
1387                 GlobalSound(self.sample, CH_VOICE, voicetype);
1388         else if (flood < 0)
1389                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1390 }
1391
1392 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1393 {
1394 //      show_message
1395 //      0 (00) automove centerprint, admin message
1396 //      1 (01) automove centerprint, no admin message
1397 //      2 (10) no centerprint, admin message
1398 //      3 (11) no centerprint, no admin message
1399
1400         float lockteams_backup;
1401
1402         lockteams_backup = lockteams;  // backup any team lock
1403
1404         lockteams = 0;  // disable locked teams
1405
1406         TeamchangeFrags(client);  // move the players frags
1407         SetPlayerColors(client, team_colour - 1);  // set the players colour
1408         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1409
1410         lockteams = lockteams_backup;  // restore the team lock
1411
1412         LogTeamchange(client.playerid, client.team, type);
1413
1414         if not(show_message & 1) // admin message
1415                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1416
1417         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1418 }