qcsrc/server/cl_player.qc

   1 #include "cl_player.qh"
   2
   3 #include "bot/bot.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27
  28 #include "weapons/weaponstats.qh"
  29
  30 #include "../common/animdecide.qh"
  31
  32 void Drop_Special_Items(entity player)
  33 {
  34         // called when the player has become stuck or frozen
  35         // so objective items aren't stuck with the player
  36
  37         MUTATOR_CALLHOOK(DropSpecialItems, player);
  38 }
  39
  40 void CopyBody_Think(entity this)
  41 {
  42         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  43         {
  44                 this.CopyBody_think(this);
  45                 if(wasfreed(this))
  46                         return;
  47                 this.CopyBody_nextthink = this.nextthink;
  48                 this.CopyBody_think = getthink(this);
  49                 setthink(this, CopyBody_Think);
  50         }
  51         CSQCMODEL_AUTOUPDATE(this);
  52         this.nextthink = time;
  53 }
  54 void CopyBody(entity this, float keepvelocity)
  55 {
  56         if (this.effects & EF_NODRAW)
  57                 return;
  58         entity clone = new(body);
  59         clone.enemy = this;
  60         clone.lip = this.lip;
  61         clone.colormap = this.colormap;
  62         clone.iscreature = this.iscreature;
  63         clone.teleportable = this.teleportable;
  64         clone.damagedbycontents = this.damagedbycontents;
  65         clone.angles = this.angles;
  66         clone.v_angle = this.v_angle;
  67         clone.avelocity = this.avelocity;
  68         clone.damageforcescale = this.damageforcescale;
  69         clone.effects = this.effects;
  70         clone.glowmod = this.glowmod;
  71         clone.event_damage = this.event_damage;
  72         clone.anim_state = this.anim_state;
  73         clone.anim_time = this.anim_time;
  74         clone.anim_lower_action = this.anim_lower_action;
  75         clone.anim_lower_time = this.anim_lower_time;
  76         clone.anim_upper_action = this.anim_upper_action;
  77         clone.anim_upper_time = this.anim_upper_time;
  78         clone.anim_implicit_state = this.anim_implicit_state;
  79         clone.anim_implicit_time = this.anim_implicit_time;
  80         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  81         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  82         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  83         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  84         clone.dphitcontentsmask = this.dphitcontentsmask;
  85         clone.death_time = this.death_time;
  86         clone.pain_finished = this.pain_finished;
  87         clone.health = this.health;
  88         clone.armorvalue = this.armorvalue;
  89         clone.armortype = this.armortype;
  90         clone.model = this.model;
  91         clone.modelindex = this.modelindex;
  92         clone.skin = this.skin;
  93         clone.species = this.species;
  94         clone.movetype = this.movetype;
  95         clone.solid = this.solid;
  96         clone.ballistics_density = this.ballistics_density;
  97         clone.takedamage = this.takedamage;
  98         setcefc(clone, getcefc(this));
  99         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 100         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 101         if (keepvelocity == 1)
 102                 clone.velocity = this.velocity;
 103         clone.oldvelocity = clone.velocity;
 104         clone.alpha = this.alpha;
 105         clone.fade_time = this.fade_time;
 106         clone.fade_rate = this.fade_rate;
 107         //clone.weapon = this.weapon;
 108         setorigin(clone, this.origin);
 109         setsize(clone, this.mins, this.maxs);
 110         clone.prevorigin = this.origin;
 111         clone.reset = SUB_Remove;
 112         clone._ps = this._ps;
 113
 114         Drag_MoveDrag(this, clone);
 115
 116         if(clone.colormap <= maxclients && clone.colormap > 0)
 117                 clone.colormap = 1024 + this.clientcolors;
 118
 119         CSQCMODEL_AUTOINIT(clone);
 120         clone.CopyBody_nextthink = this.nextthink;
 121         clone.CopyBody_think = getthink(this);
 122         clone.nextthink = time;
 123         setthink(clone, CopyBody_Think);
 124         // "bake" the current animation frame for clones (they don't get clientside animation)
 125         animdecide_load_if_needed(clone);
 126         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 127 }
 128
 129 void player_setupanimsformodel(entity this)
 130 {
 131         // load animation info
 132         animdecide_load_if_needed(this);
 133         animdecide_setstate(this, 0, false);
 134 }
 135
 136 void player_anim(entity this)
 137 {
 138         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 139         if(IS_DEAD(this)) {
 140                 if (!deadbits) {
 141                         // Decide on which death animation to use.
 142                         if(random() < 0.5)
 143                                 deadbits = ANIMSTATE_DEAD1;
 144                         else
 145                                 deadbits = ANIMSTATE_DEAD2;
 146                 }
 147         } else {
 148                 // Clear a previous death animation.
 149                 deadbits = 0;
 150         }
 151         int animbits = deadbits;
 152         if(STAT(FROZEN, this))
 153                 animbits |= ANIMSTATE_FROZEN;
 154         if(this.movetype == MOVETYPE_FOLLOW)
 155                 animbits |= ANIMSTATE_FOLLOW;
 156         if(this.crouch)
 157                 animbits |= ANIMSTATE_DUCK;
 158         animdecide_setstate(this, animbits, false);
 159         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 160 }
 161
 162 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 163 {
 164         float take, save;
 165         vector v;
 166         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 167
 168         // damage resistance (ignore most of the damage from a bullet or similar)
 169         damage = max(damage - 5, 1);
 170
 171         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 172         take = v.x;
 173         save = v.y;
 174
 175         if(sound_allowed(MSG_BROADCAST, attacker))
 176         {
 177                 if (save > 10)
 178                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 179                 else if (take > 30)
 180                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 181                 else if (take > 10)
 182                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 183         }
 184
 185         if (take > 50)
 186                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 187         if (take > 100)
 188                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 189
 190         this.armorvalue = this.armorvalue - save;
 191         this.health = this.health - take;
 192         // pause regeneration for 5 seconds
 193         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 194
 195         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 196         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 197         this.dmg_inflictor = inflictor;
 198
 199         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 200         {
 201                 // don't use any animations as a gib
 202                 this.frame = 0;
 203                 // view just above the floor
 204                 this.view_ofs = '0 0 4';
 205
 206                 Violence_GibSplash(this, 1, 1, attacker);
 207                 this.alpha = -1;
 208                 this.solid = SOLID_NOT; // restore later
 209                 this.takedamage = DAMAGE_NO; // restore later
 210                 this.damagedbycontents = false;
 211         }
 212 }
 213
 214 void calculate_player_respawn_time(entity this)
 215 {
 216         if(g_ca)
 217                 return;
 218
 219         float gametype_setting_tmp;
 220         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 221         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 222         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 223         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 224         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 225         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 226
 227         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 228         if (teamplay)
 229         {
 230                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 231                         if(it.team == this.team)
 232                                 ++pcount;
 233                 ));
 234                 if (sdelay_small_count == 0)
 235                         sdelay_small_count = 1;
 236                 if (sdelay_large_count == 0)
 237                         sdelay_large_count = 1;
 238         }
 239         else
 240         {
 241                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 242                         ++pcount;
 243                 ));
 244                 if (sdelay_small_count == 0)
 245                 {
 246                         if (g_cts)
 247                         {
 248                                 // Players play independently. No point in requiring enemies.
 249                                 sdelay_small_count = 1;
 250                         }
 251                         else
 252                         {
 253                                 // Players play AGAINST each other. Enemies required.
 254                                 sdelay_small_count = 2;
 255                         }
 256                 }
 257                 if (sdelay_large_count == 0)
 258                 {
 259                         if (g_cts)
 260                         {
 261                                 // Players play independently. No point in requiring enemies.
 262                                 sdelay_large_count = 1;
 263                         }
 264                         else
 265                         {
 266                                 // Players play AGAINST each other. Enemies required.
 267                                 sdelay_large_count = 2;
 268                         }
 269                 }
 270         }
 271
 272         float sdelay;
 273
 274         if (pcount <= sdelay_small_count)
 275                 sdelay = sdelay_small;
 276         else if (pcount >= sdelay_large_count)
 277                 sdelay = sdelay_large;
 278         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 279                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 280
 281         if(waves)
 282                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 283         else
 284                 this.respawn_time = time + sdelay;
 285
 286         if(sdelay < sdelay_max)
 287                 this.respawn_time_max = time + sdelay_max;
 288         else
 289                 this.respawn_time_max = this.respawn_time;
 290
 291         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 292                 this.respawn_countdown = 10; // first number to count down from is 10
 293         else
 294                 this.respawn_countdown = -1; // do not count down
 295
 296         if(autocvar_g_forced_respawn)
 297                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 298 }
 299
 300 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 301 {
 302         float take, save, dh, da;
 303         vector v;
 304         float valid_damage_for_weaponstats;
 305         float excess;
 306
 307         dh = max(this.health, 0);
 308         da = max(this.armorvalue, 0);
 309
 310         if(!DEATH_ISSPECIAL(deathtype))
 311         {
 312                 damage *= sqrt(bound(1.0, this.cvar_cl_handicap, 100.0));
 313                 if(this != attacker)
 314                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 315         }
 316
 317         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 318         {
 319                 // tuba causes blood to come out of the ears
 320                 vector ear1, ear2;
 321                 vector d;
 322                 float f;
 323                 ear1 = this.origin;
 324                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 325                 ear2 = ear1;
 326                 makevectors(this.angles);
 327                 ear1 += v_right * -10;
 328                 ear2 += v_right * +10;
 329                 d = inflictor.origin - this.origin;
 330                 if (d)
 331                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 332                 else
 333                         f = 0;  // Assum ecenter.
 334                 force = v_right * vlen(force);
 335                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 336                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 337                 if(f > 0)
 338                 {
 339                         hitloc = ear1;
 340                         force = force * -1;
 341                 }
 342                 else
 343                 {
 344                         hitloc = ear2;
 345                         // force is already good
 346                 }
 347         }
 348         else
 349                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 350
 351
 352         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 353         take = v.x;
 354         save = v.y;
 355
 356         if(attacker == this)
 357         {
 358                 // don't reset pushltime for this damage as it may be an attempt to
 359                 // escape a lava pit or similar
 360                 //this.pushltime = 0;
 361                 this.istypefrag = 0;
 362         }
 363         else if(IS_PLAYER(attacker))
 364         {
 365                 this.pusher = attacker;
 366                 this.pushltime = time + autocvar_g_maxpushtime;
 367                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 368         }
 369         else if(time < this.pushltime)
 370         {
 371                 attacker = this.pusher;
 372                 this.pushltime = max(this.pushltime, time + 0.6);
 373         }
 374         else
 375         {
 376                 this.pushltime = 0;
 377                 this.istypefrag = 0;
 378         }
 379
 380         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 381         {
 382                 vector v = healtharmor_applydamage(this.armorvalue, max(0, autocvar_g_spawnshield_blockdamage), deathtype, damage);
 383                 take = v.x;
 384                 save = v.y;
 385         }
 386
 387         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 388         take = bound(0, M_ARGV(4, float), this.health);
 389         save = bound(0, M_ARGV(5, float), this.armorvalue);
 390         excess = max(0, damage - take - save);
 391
 392         if(sound_allowed(MSG_BROADCAST, attacker))
 393         {
 394                 if (save > 10)
 395                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 396                 else if (take > 30)
 397                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 398                 else if (take > 10)
 399                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 400         }
 401
 402         if (take > 50)
 403                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 404         if (take > 100)
 405                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 406
 407         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 408         {
 409                 if (!(this.flags & FL_GODMODE))
 410                 {
 411                         this.armorvalue = this.armorvalue - save;
 412                         this.health = this.health - take;
 413                         // pause regeneration for 5 seconds
 414                         if(take)
 415                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 416
 417                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 418                         {
 419                                 this.pain_finished = time + 0.5;        //Supajoe
 420
 421                                 if(autocvar_sv_gentle < 1) {
 422                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 423                                         {
 424                                                 if (!this.animstate_override)
 425                                                 {
 426                                                         if (random() > 0.5)
 427                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 428                                                         else
 429                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 430                                                 }
 431                                         }
 432
 433                                         if(sound_allowed(MSG_BROADCAST, attacker))
 434                                         if((this.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != this) // WEAPONTODO: create separate limit for pain notification with laser
 435                                         if(this.health > 1)
 436                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 437                                         {
 438                                                 if(deathtype == DEATH_FALL.m_id)
 439                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 440                                                 else if(this.health > 75)
 441                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 442                                                 else if(this.health > 50)
 443                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 444                                                 else if(this.health > 25)
 445                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 446                                                 else
 447                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 448                                         }
 449                                 }
 450                         }
 451
 452                         // throw off bot aim temporarily
 453                         float shake;
 454                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 455                         {
 456                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 457                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 458                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 459                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 460                         }
 461                 }
 462                 else
 463                         this.max_armorvalue += (save + take);
 464         }
 465         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 466         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 467         this.dmg_inflictor = inflictor;
 468
 469         if (this != attacker) {
 470                 float realdmg = damage - excess;
 471                 if (IS_PLAYER(attacker)) {
 472                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 473                 }
 474                 if (IS_PLAYER(this)) {
 475                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 476                 }
 477         }
 478
 479         bool abot = (IS_BOT_CLIENT(attacker));
 480         bool vbot = (IS_BOT_CLIENT(this));
 481
 482         valid_damage_for_weaponstats = 0;
 483         Weapon awep = WEP_Null;
 484
 485         if(vbot || IS_REAL_CLIENT(this))
 486         if(abot || IS_REAL_CLIENT(attacker))
 487         if(attacker && this != attacker)
 488         if(DIFF_TEAM(this, attacker))
 489         {
 490                 if(DEATH_ISSPECIAL(deathtype))
 491                         awep = PS(attacker).m_weapon;
 492                 else
 493                         awep = DEATH_WEAPONOF(deathtype);
 494                 valid_damage_for_weaponstats = 1;
 495         }
 496
 497         dh = dh - max(this.health, 0);
 498         da = da - max(this.armorvalue, 0);
 499         if(valid_damage_for_weaponstats)
 500         {
 501                 WeaponStats_LogDamage(awep.m_id, abot, PS(this).m_weapon.m_id, vbot, dh + da);
 502         }
 503         if (dh + da)
 504         {
 505                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype);
 506         }
 507
 508         if (this.health < 1)
 509         {
 510                 float defer_ClientKill_Now_TeamChange;
 511                 defer_ClientKill_Now_TeamChange = false;
 512
 513                 if(this.alivetime)
 514                 {
 515                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 516                         this.alivetime = 0;
 517                 }
 518
 519                 if(valid_damage_for_weaponstats)
 520                         WeaponStats_LogKill(awep.m_id, abot, PS(this).m_weapon.m_id, vbot);
 521
 522                 if(autocvar_sv_gentle < 1)
 523                 if(sound_allowed(MSG_BROADCAST, attacker))
 524                 {
 525                         if(deathtype == DEATH_DROWN.m_id)
 526                                 PlayerSound(this, playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 527                         else
 528                                 PlayerSound(this, playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 529                 }
 530
 531                 // get rid of kill indicator
 532                 if(this.killindicator)
 533                 {
 534                         remove(this.killindicator);
 535                         this.killindicator = NULL;
 536                         if(this.killindicator_teamchange)
 537                                 defer_ClientKill_Now_TeamChange = true;
 538
 539                         if(this.classname == "body")
 540                         if(deathtype == DEATH_KILL.m_id)
 541                         {
 542                                 // for the lemmings fans, a small harmless explosion
 543                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 544                         }
 545                 }
 546
 547                 // print an obituary message
 548                 if(this.classname != "body")
 549                         Obituary (attacker, inflictor, this, deathtype);
 550
 551         // increment frag counter for used weapon type
 552         Weapon w = DEATH_WEAPONOF(deathtype);
 553         if(w != WEP_Null)
 554         if(accuracy_isgooddamage(attacker, this))
 555         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 556
 557                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 558                 excess = M_ARGV(4, float);
 559
 560                 Weapon wep = PS(this).m_weapon;
 561                 wep.wr_playerdeath(wep, this);
 562
 563                 RemoveGrapplingHook(this);
 564
 565                 Portal_ClearAllLater(this);
 566
 567                 this.fixangle = true;
 568
 569                 if(defer_ClientKill_Now_TeamChange)
 570                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 571
 572                 // player could have been miraculously resuscitated ;)
 573                 // e.g. players in freezetag get frozen, they don't really die
 574                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 575                         return;
 576
 577                 // when we get here, player actually dies
 578
 579                 Unfreeze(this); // remove any icy remains
 580                 this.health = 0; // Unfreeze resets health, so we need to set it back
 581
 582                 // clear waypoints
 583                 WaypointSprite_PlayerDead(this);
 584                 // throw a weapon
 585                 SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, PS(this).m_switchweapon.m_id);
 586
 587                 // become fully visible
 588                 this.alpha = default_player_alpha;
 589                 // make the corpse upright (not tilted)
 590                 this.angles_x = 0;
 591                 this.angles_z = 0;
 592                 // don't spin
 593                 this.avelocity = '0 0 0';
 594                 // view from the floor
 595                 this.view_ofs = '0 0 -8';
 596                 // toss the corpse
 597                 this.movetype = MOVETYPE_TOSS;
 598                 // shootable corpse
 599                 this.solid = SOLID_CORPSE;
 600                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 601                 // don't stick to the floor
 602                 UNSET_ONGROUND(this);
 603                 // dying animation
 604                 this.deadflag = DEAD_DYING;
 605
 606                 // when to allow respawn
 607                 calculate_player_respawn_time(this);
 608
 609                 this.death_time = time;
 610                 if (random() < 0.5)
 611                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 612                 else
 613                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 614                 if (this.maxs.z > 5)
 615                 {
 616                         this.maxs_z = 5;
 617                         setsize(this, this.mins, this.maxs);
 618                 }
 619                 // set damage function to corpse damage
 620                 this.event_damage = PlayerCorpseDamage;
 621                 // call the corpse damage function just in case it wants to gib
 622                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 623
 624                 // set up to fade out later
 625                 SUB_SetFade (this, time + 6 + random (), 1);
 626                 // reset body think wrapper broken by SUB_SetFade
 627                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 628                         this.CopyBody_think = getthink(this);
 629                         this.CopyBody_nextthink = this.nextthink;
 630                         setthink(this, CopyBody_Think);
 631                         this.nextthink = time;
 632                 }
 633
 634                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 635                         // remove corpse
 636                         // clones don't run any animation code any more, so we must gib them when they die :(
 637                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 638                 }
 639
 640                 // reset fields the weapons may use just in case
 641                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 642                         it.wr_resetplayer(it, this);
 643                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 644                         {
 645                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 646                         }
 647                 ));
 648         }
 649 }
 650
 651 void MoveToTeam(entity client, int team_colour, int type)
 652 {
 653         int lockteams_backup = lockteams;  // backup any team lock
 654         lockteams = 0;  // disable locked teams
 655         TeamchangeFrags(client);  // move the players frags
 656         SetPlayerColors(client, team_colour - 1);  // set the players colour
 657         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 658         lockteams = lockteams_backup;  // restore the team lock
 659         LogTeamchange(client.playerid, client.team, type);
 660 }
 661
 662 /** print(), but only print if the server is not local */
 663 void dedicated_print(string input)
 664 {
 665         if (server_is_dedicated) print(input);
 666 }
 667
 668 /**
 669  * message "": do not say, just test flood control
 670  * return value:
 671  *   1 = accept
 672  *   0 = reject
 673  *  -1 = fake accept
 674  */
 675 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 676 {
 677         if (!teamsay && !privatesay) if (substring(msgin, 0, 1) == " ")
 678         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 679
 680         msgin = formatmessage(source, msgin);
 681
 682     string colorstr;
 683         if (!IS_PLAYER(source))
 684                 colorstr = "^0"; // black for spectators
 685         else if(teamplay)
 686                 colorstr = Team_ColorCode(source.team);
 687         else
 688         {
 689                 colorstr = "";
 690                 teamsay = false;
 691         }
 692
 693         if(intermission_running)
 694                 teamsay = false;
 695
 696     if (!source) {
 697                 colorstr = "";
 698                 teamsay = false;
 699     }
 700
 701         if(msgin != "")
 702                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 703
 704         /*
 705          * using bprint solves this... me stupid
 706         // how can we prevent the message from appearing in a listen server?
 707         // for now, just give "say" back and only handle say_team
 708         if(!teamsay)
 709         {
 710                 clientcommand(source, strcat("say ", msgin));
 711                 return;
 712         }
 713         */
 714
 715     string namestr = "";
 716     if (source)
 717         namestr = autocvar_g_chat_teamcolors ? playername(source) : source.netname;
 718
 719     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 720
 721     string msgstr, cmsgstr;
 722     string privatemsgprefix = string_null;
 723     int privatemsgprefixlen = 0;
 724         if (msgin == "") {
 725         msgstr = cmsgstr = "";
 726         } else {
 727                 if(privatesay)
 728                 {
 729                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 730                         privatemsgprefixlen = strlen(msgstr);
 731                         msgstr = strcat(msgstr, msgin);
 732                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 733                         if(autocvar_g_chat_teamcolors)
 734                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 735                         else
 736                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 737                 }
 738                 else if(teamsay)
 739                 {
 740                         if(strstrofs(msgin, "/me", 0) >= 0)
 741                         {
 742                                 //msgin = strreplace("/me", "", msgin);
 743                                 //msgin = substring(msgin, 3, strlen(msgin));
 744                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 745                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 746                         }
 747                         else
 748                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 749                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 750                 }
 751                 else
 752                 {
 753                         if(strstrofs(msgin, "/me", 0) >= 0)
 754                         {
 755                                 //msgin = strreplace("/me", "", msgin);
 756                                 //msgin = substring(msgin, 3, strlen(msgin));
 757                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 758                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 759                         }
 760                         else {
 761                 msgstr = "\{1}";
 762                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 763                 msgstr = strcat(msgstr, msgin);
 764             }
 765                         cmsgstr = "";
 766                 }
 767                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 768         }
 769
 770         string fullmsgstr = msgstr;
 771         string fullcmsgstr = cmsgstr;
 772
 773         // FLOOD CONTROL
 774         int flood = 0;
 775         var .float flood_field = floodcontrol_chat;
 776         if(floodcontrol)
 777         {
 778                 float flood_spl;
 779                 float flood_burst;
 780                 float flood_lmax;
 781                 float lines;
 782                 if(privatesay)
 783                 {
 784                         flood_spl = autocvar_g_chat_flood_spl_tell;
 785                         flood_burst = autocvar_g_chat_flood_burst_tell;
 786                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 787                         flood_field = floodcontrol_chattell;
 788                 }
 789                 else if(teamsay)
 790                 {
 791                         flood_spl = autocvar_g_chat_flood_spl_team;
 792                         flood_burst = autocvar_g_chat_flood_burst_team;
 793                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 794                         flood_field = floodcontrol_chatteam;
 795                 }
 796                 else
 797                 {
 798                         flood_spl = autocvar_g_chat_flood_spl;
 799                         flood_burst = autocvar_g_chat_flood_burst;
 800                         flood_lmax = autocvar_g_chat_flood_lmax;
 801                         flood_field = floodcontrol_chat;
 802                 }
 803                 flood_burst = max(0, flood_burst - 1);
 804                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 805
 806                 // do flood control for the default line size
 807                 if(msgstr != "")
 808                 {
 809                         getWrappedLine_remaining = msgstr;
 810                         msgstr = "";
 811                         lines = 0;
 812                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 813                         {
 814                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 815                                 ++lines;
 816                         }
 817                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 818
 819                         if(getWrappedLine_remaining != "")
 820                         {
 821                                 msgstr = strcat(msgstr, "\n");
 822                                 flood = 2;
 823                         }
 824
 825                         if (time >= source.(flood_field))
 826                         {
 827                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 828                         }
 829                         else
 830                         {
 831                                 flood = 1;
 832                                 msgstr = fullmsgstr;
 833                         }
 834                 }
 835                 else
 836                 {
 837                         if (time >= source.(flood_field))
 838                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 839                         else
 840                                 flood = 1;
 841                 }
 842
 843                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 844                         source.(flood_field) = flood = 0;
 845         }
 846
 847     string sourcemsgstr, sourcecmsgstr;
 848         if(flood == 2) // cannot happen for empty msgstr
 849         {
 850                 if(autocvar_g_chat_flood_notify_flooder)
 851                 {
 852                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 853                         sourcecmsgstr = "";
 854                 }
 855                 else
 856                 {
 857                         sourcemsgstr = fullmsgstr;
 858                         sourcecmsgstr = fullcmsgstr;
 859                 }
 860                 cmsgstr = "";
 861         }
 862         else
 863         {
 864                 sourcemsgstr = msgstr;
 865                 sourcecmsgstr = cmsgstr;
 866         }
 867
 868         if (!privatesay && source && !IS_PLAYER(source))
 869         {
 870                 if (!intermission_running)
 871                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 872                                 teamsay = -1; // spectators
 873         }
 874
 875         if(flood)
 876                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
 877
 878         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 879         if(privatesay)
 880                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 881
 882     int ret;
 883         if(source.muted)
 884         {
 885                 // always fake the message
 886                 ret = -1;
 887         }
 888         else if(flood == 1)
 889         {
 890                 if (autocvar_g_chat_flood_notify_flooder)
 891                 {
 892                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 893                         ret = 0;
 894                 }
 895                 else
 896                         ret = -1;
 897         }
 898         else
 899         {
 900                 ret = 1;
 901         }
 902
 903         if(sourcemsgstr != "" && ret != 0)
 904         {
 905                 if(ret < 0) // faked message, because the player is muted
 906                 {
 907                         sprint(source, sourcemsgstr);
 908                         if(sourcecmsgstr != "" && !privatesay)
 909                                 centerprint(source, sourcecmsgstr);
 910                 }
 911                 else if(privatesay) // private message, between 2 people only
 912                 {
 913                         sprint(source, sourcemsgstr);
 914                         sprint(privatesay, msgstr);
 915                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 916                         if(cmsgstr != "")
 917                                 centerprint(privatesay, cmsgstr);
 918                 }
 919                 else if ( teamsay && source.active_minigame )
 920                 {
 921                         sprint(source, sourcemsgstr);
 922                         dedicated_print(msgstr); // send to server console too
 923                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame, sprint(it, msgstr));
 924                 }
 925                 else if(teamsay > 0) // team message, only sent to team mates
 926                 {
 927                         sprint(source, sourcemsgstr);
 928                         dedicated_print(msgstr); // send to server console too
 929                         if(sourcecmsgstr != "")
 930                                 centerprint(source, sourcecmsgstr);
 931                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team, {
 932                                 sprint(it, msgstr);
 933                                 if(cmsgstr != "")
 934                                         centerprint(it, cmsgstr);
 935                         });
 936                 }
 937                 else if(teamsay < 0) // spectator message, only sent to spectators
 938                 {
 939                         sprint(source, sourcemsgstr);
 940                         dedicated_print(msgstr); // send to server console too
 941                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 942                 }
 943                 else
 944                 {
 945             if (source) {
 946                 sprint(source, sourcemsgstr);
 947                 dedicated_print(msgstr); // send to server console too
 948                 MX_Say(strcat(playername(source), "^7: ", msgin));
 949             }
 950             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 951         }
 952         }
 953
 954         return ret;
 955 }