qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.dphitcontentsmask = oldself.dphitcontentsmask;
 170         self.death_time = oldself.death_time;
 171         self.frame = oldself.frame;
 172         self.pain_finished = oldself.pain_finished;
 173         self.health = oldself.health;
 174         self.armorvalue = oldself.armorvalue;
 175         self.armortype = oldself.armortype;
 176         self.model = oldself.model;
 177         self.modelindex = oldself.modelindex;
 178         self.skin = oldself.skin;
 179         self.species = oldself.species;
 180         self.movetype = oldself.movetype;
 181         self.solid = oldself.solid;
 182         self.ballistics_density = oldself.ballistics_density;
 183         self.takedamage = oldself.takedamage;
 184         self.customizeentityforclient = oldself.customizeentityforclient;
 185         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 186         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 187         if (keepvelocity == 1)
 188                 self.velocity = oldself.velocity;
 189         self.oldvelocity = self.velocity;
 190         self.alpha = oldself.alpha;
 191         self.fade_time = oldself.fade_time;
 192         self.fade_rate = oldself.fade_rate;
 193         //self.weapon = oldself.weapon;
 194         setorigin(self, oldself.origin);
 195         setsize(self, oldself.mins, oldself.maxs);
 196         self.prevorigin = oldself.origin;
 197         self.reset = SUB_Remove;
 198
 199         Drag_MoveDrag(oldself, self);
 200
 201         if(self.colormap <= maxclients && self.colormap > 0)
 202                 self.colormap = 1024 + oldself.clientcolors;
 203
 204         CSQCMODEL_AUTOINIT();
 205         self.CopyBody_nextthink = oldself.nextthink;
 206         self.CopyBody_think = oldself.think;
 207         self.nextthink = time;
 208         self.think = CopyBody_Think;
 209
 210         self = oldself;
 211 }
 212
 213 float player_getspecies()
 214 {
 215         float s;
 216         get_model_parameters(self.model, self.skin);
 217         s = get_model_parameters_species;
 218         get_model_parameters(string_null, 0);
 219         if(s < 0)
 220                 return SPECIES_HUMAN;
 221         return s;
 222 }
 223
 224 void player_setupanimsformodel()
 225 {
 226         // defaults for legacy .zym models without animinfo files
 227         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 228         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 229         self.anim_draw = animfixfps(self, '2 1 3');
 230         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 231         self.anim_duckwalk = animfixfps(self, '4 1 1');
 232         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 233         self.anim_duckidle = animfixfps(self, '6 1 1');
 234         self.anim_idle = animfixfps(self, '7 1 1');
 235         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 236         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 237         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 238         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 239         self.anim_taunt = animfixfps(self, '12 1 0.33');
 240         self.anim_run = animfixfps(self, '13 1 1');
 241         self.anim_runbackwards = animfixfps(self, '14 1 1');
 242         self.anim_strafeleft = animfixfps(self, '15 1 1');
 243         self.anim_straferight = animfixfps(self, '16 1 1');
 244         //self.anim_dead1 = animfixfps(self, '17 1 1');
 245         //self.anim_dead2 = animfixfps(self, '18 1 1');
 246         self.anim_forwardright = animfixfps(self, '19 1 1');
 247         self.anim_forwardleft = animfixfps(self, '20 1 1');
 248         self.anim_backright = animfixfps(self, '21 1 1');
 249         self.anim_backleft  = animfixfps(self, '22 1 1');
 250         self.anim_melee = animfixfps(self, '23 1 1');
 251         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 252         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 253         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 254         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 255         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 256         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 257         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 258         // TODO introspect models for finding right "fps" value (1/duration)
 259         // reset animstate now
 260         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 261 }
 262
 263 void player_anim (void)
 264 {
 265         updateanim(self);
 266         if (self.weaponentity)
 267                 updateanim(self.weaponentity);
 268
 269         if (self.deadflag != DEAD_NO)
 270                 return;
 271
 272         if (!self.animstate_override)
 273         {
 274                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 275                 {
 276                         if (self.crouch)
 277                         {
 278                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 279                                 {
 280                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 281                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 282                                         {
 283                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 284                                                 self.restart_jump = FALSE;
 285                                         }
 286                                 }
 287                         }
 288                         else
 289                         {
 290                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 291                 {
 292                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 293                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 294                     {
 295                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 296                         self.restart_jump = FALSE;
 297                     }
 298                 }
 299                         }
 300                 }
 301                 else if (self.crouch)
 302                 {
 303                         if (self.movement_x > 0 && self.movement_y == 0)
 304                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x < 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x == 0 && self.movement_y > 0)
 308                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y < 0)
 310                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x > 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x < 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 319                         else
 320                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 321                 }
 322                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 323                 {
 324                         if (self.movement_x > 0 && self.movement_y == 0)
 325                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 326                         else if (self.movement_x < 0 && self.movement_y == 0)
 327                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 328                         else if (self.movement_x == 0 && self.movement_y > 0)
 329                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x == 0 && self.movement_y < 0)
 331                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x > 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x > 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x < 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x < 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 340                         else
 341                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 342                 }
 343                 else
 344                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 345         }
 346
 347         if (self.weaponentity)
 348         if (!self.weaponentity.animstate_override)
 349                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 350 }
 351
 352 void SpawnThrownWeapon (vector org, float w)
 353 {
 354         if(g_minstagib)
 355         if(self.ammo_cells <= 0)
 356                 return;
 357
 358         if(g_pinata)
 359         {
 360                 float j;
 361                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 362                 {
 363                         if(self.weapons & W_WeaponBit(j))
 364                                 if(W_IsWeaponThrowable(j))
 365                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 366                 }
 367         }
 368         else
 369         {
 370                 if(W_IsWeaponThrowable(self.weapon))
 371                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 372         }
 373 }
 374
 375 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 376 {
 377         float take, save;
 378         vector v;
 379         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 380
 381         // damage resistance (ignore most of the damage from a bullet or similar)
 382         damage = max(damage - 5, 1);
 383
 384         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 385         take = v_x;
 386         save = v_y;
 387
 388         if(sound_allowed(MSG_BROADCAST, attacker))
 389         {
 390                 if (save > 10)
 391                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 392                 else if (take > 30)
 393                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 394                 else if (take > 10)
 395                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 396         }
 397
 398         if (take > 50)
 399                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 400         if (take > 100)
 401                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 402
 403         if (!(self.flags & FL_GODMODE))
 404         {
 405                 self.armorvalue = self.armorvalue - save;
 406                 self.health = self.health - take;
 407                 // pause regeneration for 5 seconds
 408                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 409         }
 410         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 411         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 412         self.dmg_inflictor = inflictor;
 413
 414         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 415         {
 416                 // don't use any animations as a gib
 417                 self.frame = 0;
 418                 // view just above the floor
 419                 self.view_ofs = '0 0 4';
 420
 421                 Violence_GibSplash(self, 1, 1, attacker);
 422                 self.alpha = -1;
 423                 self.solid = SOLID_NOT; // restore later
 424         }
 425 }
 426
 427 void ClientKill_Now_TeamChange();
 428 void freezetag_CheckWinner();
 429
 430 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 431 {
 432         float take, save, waves, sdelay, dh, da, j;
 433         vector v;
 434         float valid_damage_for_weaponstats;
 435         float excess;
 436
 437         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 438                 return;
 439
 440         dh = max(self.health, 0);
 441         da = max(self.armorvalue, 0);
 442
 443         if(!DEATH_ISSPECIAL(deathtype))
 444         {
 445                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 446                 if(self != attacker)
 447                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 448         }
 449
 450         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 451         {
 452                 // tuba causes blood to come out of the ears
 453                 vector ear1, ear2;
 454                 vector d;
 455                 float f;
 456                 ear1 = self.origin;
 457                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 458                 ear2 = ear1;
 459                 makevectors(self.angles);
 460                 ear1 += v_right * -10;
 461                 ear2 += v_right * +10;
 462                 d = inflictor.origin - self.origin;
 463                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 464                 force = v_right * vlen(force);
 465                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 466                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 467                 if(f > 0)
 468                 {
 469                         hitloc = ear1;
 470                         force = force * -1;
 471                 }
 472                 else
 473                 {
 474                         hitloc = ear2;
 475                         // force is already good
 476                 }
 477         }
 478         else
 479                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 480
 481         if (!g_minstagib)
 482         {
 483                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 484                 take = v_x;
 485                 save = v_y;
 486         }
 487         else
 488         {
 489                 save = 0;
 490                 take = damage;
 491         }
 492
 493         frag_inflictor = inflictor;
 494         frag_attacker = attacker;
 495         frag_target = self;
 496         damage_take = take;
 497         damage_save = save;
 498         damage_force = force;
 499         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 500         take = bound(0, damage_take, self.health);
 501         save = bound(0, damage_save, self.armorvalue);
 502         excess = max(0, damage - take - save);
 503
 504         if(sound_allowed(MSG_BROADCAST, attacker))
 505         {
 506                 if (save > 10)
 507                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 508                 else if (take > 30)
 509                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 510                 else if (take > 10)
 511                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 512         }
 513
 514         if (take > 50)
 515                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 516         if (take > 100)
 517                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 518
 519         if (time >= self.spawnshieldtime)
 520         {
 521                 if (!(self.flags & FL_GODMODE))
 522                 {
 523                         self.armorvalue = self.armorvalue - save;
 524                         self.health = self.health - take;
 525                         // pause regeneration for 5 seconds
 526                         if(take)
 527                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 528
 529                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 530                         {
 531                                 self.pain_finished = time + 0.5;        //Supajoe
 532
 533                                 if(sv_gentle < 1) {
 534                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 535                                         {
 536                                                 if (!self.animstate_override)
 537                                                 {
 538                                                         if (random() > 0.5)
 539                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 540                                                         else
 541                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 542                                                 }
 543                                         }
 544
 545                                         if(sound_allowed(MSG_BROADCAST, attacker))
 546                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 547                                         if(self.health > 1)
 548                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 549                                         {
 550                                                 if(deathtype == DEATH_FALL)
 551                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 552                                                 else if(self.health > 75) // TODO make a "gentle" version?
 553                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 554                                                 else if(self.health > 50)
 555                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 556                                                 else if(self.health > 25)
 557                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 558                                                 else
 559                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 560                                         }
 561                                 }
 562
 563                                 // throw off bot aim temporarily
 564                                 float shake;
 565                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 566                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 567                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 568                         }
 569                 }
 570                 else
 571                         self.max_armorvalue += (save + take);
 572         }
 573         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 574         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 575         self.dmg_inflictor = inflictor;
 576
 577         if(attacker == self)
 578         {
 579                 // don't reset pushltime for self damage as it may be an attempt to
 580                 // escape a lava pit or similar
 581                 //self.pushltime = 0;
 582         }
 583         else if(attacker.classname == "player")
 584         {
 585                 self.pusher = attacker;
 586                 self.pushltime = time + autocvar_g_maxpushtime;
 587         }
 588         else if(time < self.pushltime)
 589         {
 590                 attacker = self.pusher;
 591                 self.pushltime = max(self.pushltime, time + 0.6);
 592         }
 593         else
 594                 self.pushltime = 0;
 595
 596         float abot, vbot, awep;
 597         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 598         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 599
 600         valid_damage_for_weaponstats = 0;
 601         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 602         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 603         if(attacker && self != attacker)
 604         if(IsDifferentTeam(self, attacker))
 605         {
 606                 if(DEATH_ISSPECIAL(deathtype))
 607                         awep = attacker.weapon;
 608                 else
 609                         awep = DEATH_WEAPONOF(deathtype);
 610                 valid_damage_for_weaponstats = 1;
 611         }
 612
 613         if(valid_damage_for_weaponstats)
 614         {
 615                 dh = dh - max(self.health, 0);
 616                 da = da - max(self.armorvalue, 0);
 617                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 618         }
 619
 620         if (self.health < 1)
 621         {
 622                 float defer_ClientKill_Now_TeamChange;
 623                 defer_ClientKill_Now_TeamChange = FALSE;
 624
 625                 if(self.alivetime)
 626                 {
 627                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 628                         self.alivetime = 0;
 629                 }
 630
 631                 if(valid_damage_for_weaponstats)
 632                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 633
 634                 if(sv_gentle < 1) // TODO make a "gentle" version?
 635                 if(sound_allowed(MSG_BROADCAST, attacker))
 636                 {
 637                         if(deathtype == DEATH_DROWN)
 638                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 639                         else
 640                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 641                 }
 642
 643                 // get rid of kill indicator
 644                 if(self.killindicator)
 645                 {
 646                         remove(self.killindicator);
 647                         self.killindicator = world;
 648                         if(self.killindicator_teamchange)
 649                                 defer_ClientKill_Now_TeamChange = TRUE;
 650
 651                         if(self.classname == "body")
 652                         if(deathtype == DEATH_KILL)
 653                         {
 654                                 // for the lemmings fans, a small harmless explosion
 655                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 656                         }
 657                 }
 658
 659                 if(!g_freezetag)
 660                 {
 661                         // become fully visible
 662                         self.alpha = default_player_alpha;
 663                         // throw a weapon
 664                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 665                 }
 666
 667                 // print an obituary message
 668                 Obituary (attacker, inflictor, self, deathtype);
 669                 race_PreDie();
 670                 DropAllRunes(self);
 671
 672         // increment frag counter for used weapon type
 673         float w;
 674         w = DEATH_WEAPONOF(deathtype);
 675         if(WEP_VALID(w))
 676         if(accuracy_isgooddamage(attacker, self))
 677         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 678
 679                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 680                 {
 681                         PutClientInServer();
 682                         count_alive_players(); // re-count players
 683                         freezetag_CheckWinner();
 684                         return;
 685                 }
 686
 687                 frag_attacker = attacker;
 688                 frag_inflictor = inflictor;
 689                 frag_target = self;
 690                 MUTATOR_CALLHOOK(PlayerDies);
 691                 weapon_action(self.weapon, WR_PLAYERDEATH);
 692
 693                 RemoveGrapplingHook(self);
 694
 695                 if(self.flagcarried)
 696                 {
 697                         if(attacker.classname != "player")
 698                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 699                         else if(attacker.team == self.team)
 700                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 701                         else
 702                                 DropFlag(self.flagcarried, world, attacker);
 703                 }
 704                 if(self.ballcarried && g_nexball)
 705                         DropBall(self.ballcarried, self.origin, self.velocity);
 706                 Portal_ClearAllLater(self);
 707
 708                 if(clienttype(self) == CLIENTTYPE_REAL)
 709                 {
 710                         stuffcmd(self, "-zoom\n");
 711                         self.fixangle = TRUE;
 712                         //msg_entity = self;
 713                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 714                         //WriteAngle (MSG_ONE, self.v_angle_x);
 715                         //WriteAngle (MSG_ONE, self.v_angle_y);
 716                         //WriteAngle (MSG_ONE, 80);
 717                 }
 718
 719                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 720                         ClientKill_Now_TeamChange();
 721
 722                 if(g_arena)
 723                         Spawnqueue_Unmark(self);
 724
 725                 if(g_freezetag)
 726                         return;
 727
 728                 // when we get here, player actually dies
 729                 // clear waypoints (do this AFTER FreezeTag)
 730                 WaypointSprite_PlayerDead();
 731
 732                 // make the corpse upright (not tilted)
 733                 self.angles_x = 0;
 734                 self.angles_z = 0;
 735                 // don't spin
 736                 self.avelocity = '0 0 0';
 737                 // view from the floor
 738                 self.view_ofs = '0 0 -8';
 739                 // toss the corpse
 740                 self.movetype = MOVETYPE_TOSS;
 741                 // shootable corpse
 742                 self.solid = SOLID_CORPSE;
 743                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 744                 // don't stick to the floor
 745                 self.flags &~= FL_ONGROUND;
 746                 // dying animation
 747                 self.deadflag = DEAD_DYING;
 748                 // when to allow respawn
 749                 sdelay = 0;
 750                 waves = 0;
 751                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 752                 if(!sdelay)
 753                 {
 754                         if(g_cts)
 755                                 sdelay = 0; // no respawn delay in CTS
 756                         else
 757                                 sdelay = autocvar_g_respawn_delay;
 758                 }
 759                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 760                 if(!waves)
 761                         waves = autocvar_g_respawn_waves;
 762                 if(waves)
 763                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 764                 else
 765                         self.respawn_time = time + sdelay;
 766                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 767                         self.respawn_countdown = 10; // first number to count down from is 10
 768                 else
 769                         self.respawn_countdown = -1; // do not count down
 770                 self.death_time = time;
 771                 if (random() < 0.5)
 772                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 773                 else
 774                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 775                 if (self.maxs_z > 5)
 776                 {
 777                         self.maxs_z = 5;
 778                         setsize(self, self.mins, self.maxs);
 779                 }
 780                 // set damage function to corpse damage
 781                 self.event_damage = PlayerCorpseDamage;
 782                 // call the corpse damage function just in case it wants to gib
 783                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 784                 // set up to fade out later
 785                 SUB_SetFade (self, time + 6 + random (), 1);
 786
 787                 if(sv_gentle > 0 || autocvar_ekg) {
 788                         // remove corpse
 789                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 790                 }
 791
 792                 // reset fields the weapons may use just in case
 793                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 794                 {
 795                         weapon_action(j, WR_RESETPLAYER);
 796                         ATTACK_FINISHED_FOR(self, j) = 0;
 797                 }
 798         }
 799 }
 800
 801 .float muted; // to be used by prvm_edictset server playernumber muted 1
 802 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 803 // message "": do not say, just test flood control
 804 // return value:
 805 //   1 = accept
 806 //   0 = reject
 807 //  -1 = fake accept
 808 {
 809         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 810         float flood, privatemsgprefixlen;
 811         var .float flood_field;
 812         entity head;
 813         float ret;
 814
 815         if(Ban_MaybeEnforceBan(source))
 816                 return 0;
 817
 818         if(!teamsay && !privatesay)
 819                 if(substring(msgin, 0, 1) == " ")
 820                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 821
 822         msgin = formatmessage(msgin);
 823
 824         if(source.classname != "player")
 825                 colorstr = "^0"; // black for spectators
 826         else if(teamplay)
 827                 colorstr = Team_ColorCode(source.team);
 828         else
 829                 teamsay = FALSE;
 830
 831         if(intermission_running)
 832                 teamsay = FALSE;
 833
 834         if(msgin != "")
 835                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 836
 837         /*
 838          * using bprint solves this... me stupid
 839         // how can we prevent the message from appearing in a listen server?
 840         // for now, just give "say" back and only handle say_team
 841         if(!teamsay)
 842         {
 843                 clientcommand(self, strcat("say ", msgin));
 844                 return;
 845         }
 846         */
 847
 848         if(autocvar_g_chat_teamcolors)
 849                 namestr = playername(source);
 850         else
 851                 namestr = source.netname;
 852
 853         if(msgin != "")
 854         {
 855                 if(privatesay)
 856                 {
 857                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 858                         privatemsgprefixlen = strlen(msgstr);
 859                         msgstr = strcat(msgstr, msgin);
 860                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 861                         if(autocvar_g_chat_teamcolors)
 862                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 863                         else
 864                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 865                 }
 866                 else if(teamsay)
 867                 {
 868                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 869                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 870                 }
 871                 else
 872                 {
 873                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 874                         cmsgstr = "";
 875                 }
 876                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 877         }
 878         else
 879         {
 880                 msgstr = cmsgstr = "";
 881         }
 882
 883         fullmsgstr = msgstr;
 884         fullcmsgstr = cmsgstr;
 885
 886         // FLOOD CONTROL
 887         flood = 0;
 888         if(floodcontrol)
 889         {
 890                 float flood_spl;
 891                 float flood_burst;
 892                 float flood_lmax;
 893                 float lines;
 894                 if(privatesay)
 895                 {
 896                         flood_spl = autocvar_g_chat_flood_spl_tell;
 897                         flood_burst = autocvar_g_chat_flood_burst_tell;
 898                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 899                         flood_field = floodcontrol_chattell;
 900                 }
 901                 else if(teamsay)
 902                 {
 903                         flood_spl = autocvar_g_chat_flood_spl_team;
 904                         flood_burst = autocvar_g_chat_flood_burst_team;
 905                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 906                         flood_field = floodcontrol_chatteam;
 907                 }
 908                 else
 909                 {
 910                         flood_spl = autocvar_g_chat_flood_spl;
 911                         flood_burst = autocvar_g_chat_flood_burst;
 912                         flood_lmax = autocvar_g_chat_flood_lmax;
 913                         flood_field = floodcontrol_chat;
 914                 }
 915                 flood_burst = max(0, flood_burst - 1);
 916                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 917
 918                 // do flood control for the default line size
 919                 if(msgstr != "")
 920                 {
 921                         getWrappedLine_remaining = msgstr;
 922                         msgstr = "";
 923                         lines = 0;
 924                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 925                         {
 926                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 927                                 ++lines;
 928                         }
 929                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 930
 931                         if(getWrappedLine_remaining != "")
 932                         {
 933                                 msgstr = strcat(msgstr, "\n");
 934                                 flood = 2;
 935                         }
 936
 937                         if(time >= source.flood_field)
 938                         {
 939                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 940                         }
 941                         else
 942                         {
 943                                 flood = 1;
 944                                 msgstr = fullmsgstr;
 945                         }
 946                 }
 947                 else
 948                 {
 949                         if(time >= source.flood_field)
 950                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 951                         else
 952                                 flood = 1;
 953                 }
 954
 955                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 956                         source.flood_field = flood = 0;
 957         }
 958
 959         if(flood == 2) // cannot happen for empty msgstr
 960         {
 961                 if(autocvar_g_chat_flood_notify_flooder)
 962                 {
 963                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 964                         sourcecmsgstr = "";
 965                 }
 966                 else
 967                 {
 968                         sourcemsgstr = fullmsgstr;
 969                         sourcecmsgstr = fullcmsgstr;
 970                 }
 971                 cmsgstr = "";
 972         }
 973         else
 974         {
 975                 sourcemsgstr = msgstr;
 976                 sourcecmsgstr = cmsgstr;
 977         }
 978
 979         if(!privatesay)
 980         if(source.classname != "player")
 981         {
 982                 if not(intermission_running)
 983                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 984                                 teamsay = -1; // spectators
 985         }
 986
 987         if(flood)
 988                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 989
 990         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 991         if(privatesay)
 992                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 993
 994         if(source.muted)
 995         {
 996                 // always fake the message
 997                 ret = -1;
 998         }
 999         else if(flood == 1)
1000         {
1001                 if(autocvar_g_chat_flood_notify_flooder)
1002                 {
1003                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1004                         ret = 0;
1005                 }
1006                 else
1007                         ret = -1;
1008         }
1009         else
1010         {
1011                 ret = 1;
1012         }
1013
1014         if(sourcemsgstr != "" && ret != 0)
1015         {
1016                 if(ret < 0) // faked message, because the player is muted
1017                 {
1018                         sprint(source, sourcemsgstr);
1019                         if(sourcecmsgstr != "" && !privatesay)
1020                                 centerprint(source, sourcecmsgstr);
1021                 }
1022                 else if(privatesay) // private message, between 2 people only, not sent to server console
1023                 {
1024                         sprint(source, sourcemsgstr);
1025                         sprint(privatesay, msgstr);
1026                         if(cmsgstr != "")
1027                                 centerprint(privatesay, cmsgstr);
1028                 }
1029                 else if(teamsay > 0) // team message, only sent to team mates
1030                 {
1031                         sprint(source, sourcemsgstr);
1032                         //print(msgstr); // send to server console too
1033                         if(sourcecmsgstr != "")
1034                                 centerprint(source, sourcecmsgstr);
1035                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1036                                 if(head != source)
1037                                 {
1038                                         sprint(head, msgstr);
1039                                         if(cmsgstr != "")
1040                                                 centerprint(head, cmsgstr);
1041                                 }
1042                 }
1043                 else if(teamsay < 0) // spectator message, only sent to spectators
1044                 {
1045                         sprint(source, sourcemsgstr);
1046                         //print(msgstr); // send to server console too
1047                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1048                                 if(head != source)
1049                                         sprint(head, msgstr);
1050                 }
1051                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1052                 {
1053                         sprint(source, sourcemsgstr);
1054                         //print(msgstr); // send to server console too
1055                         FOR_EACH_REALCLIENT(head)
1056                                 if(head != source)
1057                                         sprint(head, msgstr);
1058                 }
1059                 else
1060                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1061         }
1062
1063         return ret;
1064 }
1065
1066 float GetVoiceMessageVoiceType(string type)
1067 {
1068         if(type == "taunt")
1069                 return VOICETYPE_TAUNT;
1070         if(type == "teamshoot")
1071                 return VOICETYPE_LASTATTACKER;
1072         return VOICETYPE_TEAMRADIO;
1073 }
1074
1075 string allvoicesamples;
1076 .string GetVoiceMessageSampleField(string type)
1077 {
1078         GetPlayerSoundSampleField_notFound = 0;
1079         switch(type)
1080         {
1081 #define _VOICEMSG(m) case #m: return playersound_##m;
1082                 ALLVOICEMSGS
1083 #undef _VOICEMSG
1084         }
1085         GetPlayerSoundSampleField_notFound = 1;
1086         return playersound_taunt;
1087 }
1088
1089 .string GetPlayerSoundSampleField(string type)
1090 {
1091         GetPlayerSoundSampleField_notFound = 0;
1092         switch(type)
1093         {
1094 #define _VOICEMSG(m) case #m: return playersound_##m;
1095                 ALLPLAYERSOUNDS
1096 #undef _VOICEMSG
1097         }
1098         GetPlayerSoundSampleField_notFound = 1;
1099         return playersound_taunt;
1100 }
1101
1102 void PrecacheGlobalSound(string samplestring)
1103 {
1104         float n, i;
1105         tokenize_console(samplestring);
1106         n = stof(argv(1));
1107         if(n > 0)
1108         {
1109                 for(i = 1; i <= n; ++i)
1110                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1111         }
1112         else
1113         {
1114                 precache_sound(strcat(argv(0), ".wav"));
1115         }
1116 }
1117
1118 void PrecachePlayerSounds(string f)
1119 {
1120         float fh;
1121         string s;
1122         fh = fopen(f, FILE_READ);
1123         if(fh < 0)
1124                 return;
1125         while((s = fgets(fh)))
1126         {
1127                 if(tokenize_console(s) != 3)
1128                 {
1129                         dprint("Invalid sound info line: ", s, "\n");
1130                         continue;
1131                 }
1132                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1133         }
1134         fclose(fh);
1135
1136         if not(allvoicesamples)
1137         {
1138 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1139                 ALLVOICEMSGS
1140 #undef _VOICEMSG
1141                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1142         }
1143 }
1144
1145 void ClearPlayerSounds()
1146 {
1147 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1148         ALLPLAYERSOUNDS
1149         ALLVOICEMSGS
1150 #undef _VOICEMSG
1151 }
1152
1153 float LoadPlayerSounds(string f, float first)
1154 {
1155         float fh;
1156         string s;
1157         var .string field;
1158         fh = fopen(f, FILE_READ);
1159         if(fh < 0)
1160         {
1161                 dprint("Player sound file not found: ", f, "\n");
1162                 return 0;
1163         }
1164         while((s = fgets(fh)))
1165         {
1166                 if(tokenize_console(s) != 3)
1167                         continue;
1168                 field = GetPlayerSoundSampleField(argv(0));
1169                 if(GetPlayerSoundSampleField_notFound)
1170                         field = GetVoiceMessageSampleField(argv(0));
1171                 if(GetPlayerSoundSampleField_notFound)
1172                         continue;
1173                 if(self.field)
1174                         strunzone(self.field);
1175                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1176         }
1177         fclose(fh);
1178         return 1;
1179 }
1180
1181 .float modelindex_for_playersound;
1182 .float skin_for_playersound;
1183 void UpdatePlayerSounds()
1184 {
1185         if(self.modelindex == self.modelindex_for_playersound)
1186         if(self.skin == self.skin_for_playersound)
1187                 return;
1188         self.modelindex_for_playersound = self.modelindex;
1189         self.skin_for_playersound = self.skin;
1190         ClearPlayerSounds();
1191         LoadPlayerSounds("sound/player/default.sounds", 1);
1192         if(!autocvar_g_debug_defaultsounds)
1193                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1194                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1195 }
1196
1197 void FakeGlobalSound(string sample, float chan, float voicetype)
1198 {
1199         float n;
1200         float tauntrand;
1201
1202         if(sample == "")
1203                 return;
1204
1205         tokenize_console(sample);
1206         n = stof(argv(1));
1207         if(n > 0)
1208                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1209         else
1210                 sample = strcat(argv(0), ".wav"); // randomization
1211
1212         switch(voicetype)
1213         {
1214                 case VOICETYPE_LASTATTACKER_ONLY:
1215                         break;
1216                 case VOICETYPE_LASTATTACKER:
1217                         if(self.pusher)
1218                         {
1219                                 msg_entity = self;
1220                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1221                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1222                         }
1223                         break;
1224                 case VOICETYPE_TEAMRADIO:
1225                         msg_entity = self;
1226                         if(msg_entity.cvar_cl_voice_directional == 1)
1227                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1228                         else
1229                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1230                         break;
1231                 case VOICETYPE_AUTOTAUNT:
1232                         if(!sv_autotaunt)
1233                                 break;
1234                         if(!sv_taunt)
1235                                 break;
1236                         if(sv_gentle)
1237                                 break;
1238                         tauntrand = random();
1239                         msg_entity = self;
1240                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1241                         {
1242                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1243                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1244                                 else
1245                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1246                         }
1247                         break;
1248                 case VOICETYPE_TAUNT:
1249                         if(self.classname == "player")
1250                                 if(self.deadflag == DEAD_NO)
1251                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1252                         if(!sv_taunt)
1253                                 break;
1254                         if(sv_gentle)
1255                                 break;
1256                         msg_entity = self;
1257                         if (msg_entity.cvar_cl_voice_directional >= 1)
1258                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1259                         else
1260                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1261                         break;
1262                 case VOICETYPE_PLAYERSOUND:
1263                         msg_entity = self;
1264                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1265                         break;
1266                 default:
1267                         backtrace("Invalid voice type!");
1268                         break;
1269         }
1270 }
1271
1272 void GlobalSound(string sample, float chan, float voicetype)
1273 {
1274         float n;
1275         float tauntrand;
1276
1277         if(sample == "")
1278                 return;
1279
1280         tokenize_console(sample);
1281         n = stof(argv(1));
1282         if(n > 0)
1283                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1284         else
1285                 sample = strcat(argv(0), ".wav"); // randomization
1286
1287         switch(voicetype)
1288         {
1289                 case VOICETYPE_LASTATTACKER_ONLY:
1290                         if(self.pusher)
1291                         {
1292                                 msg_entity = self.pusher;
1293                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1294                                 {
1295                                         if(msg_entity.cvar_cl_voice_directional == 1)
1296                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1297                                         else
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1299                                 }
1300                         }
1301                         break;
1302                 case VOICETYPE_LASTATTACKER:
1303                         if(self.pusher)
1304                         {
1305                                 msg_entity = self.pusher;
1306                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1307                                 {
1308                                         if(msg_entity.cvar_cl_voice_directional == 1)
1309                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1310                                         else
1311                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1312                                 }
1313                                 msg_entity = self;
1314                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1315                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1316                         }
1317                         break;
1318                 case VOICETYPE_TEAMRADIO:
1319                         FOR_EACH_REALCLIENT(msg_entity)
1320                                 if(!teamplay || msg_entity.team == self.team)
1321                                 {
1322                                         if(msg_entity.cvar_cl_voice_directional == 1)
1323                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1324                                         else
1325                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1326                                 }
1327                         break;
1328                 case VOICETYPE_AUTOTAUNT:
1329                         if(!sv_autotaunt)
1330                                 break;
1331                         if(!sv_taunt)
1332                                 break;
1333                         if(sv_gentle)
1334                                 break;
1335                         tauntrand = random();
1336                         FOR_EACH_REALCLIENT(msg_entity)
1337                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1338                                 {
1339                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1340                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1341                                         else
1342                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1343                                 }
1344                         break;
1345                 case VOICETYPE_TAUNT:
1346                         if(self.classname == "player")
1347                                 if(self.deadflag == DEAD_NO)
1348                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1349                         if(!sv_taunt)
1350                                 break;
1351                         if(sv_gentle)
1352                                 break;
1353                         FOR_EACH_REALCLIENT(msg_entity)
1354                         {
1355                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1356                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1357                                 else
1358                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1359                         }
1360                         break;
1361                 case VOICETYPE_PLAYERSOUND:
1362                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1363                         break;
1364                 default:
1365                         backtrace("Invalid voice type!");
1366                         break;
1367         }
1368 }
1369
1370 void PlayerSound(.string samplefield, float chan, float voicetype)
1371 {
1372         GlobalSound(self.samplefield, chan, voicetype);
1373 }
1374
1375 void VoiceMessage(string type, string msg)
1376 {
1377         var .string sample;
1378         float voicetype, ownteam;
1379         float flood;
1380         sample = GetVoiceMessageSampleField(type);
1381
1382         if(GetPlayerSoundSampleField_notFound)
1383         {
1384                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1385                 return;
1386         }
1387
1388         voicetype = GetVoiceMessageVoiceType(type);
1389         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1390
1391         flood = Say(self, ownteam, world, msg, 1);
1392
1393         if (flood > 0)
1394                 GlobalSound(self.sample, CH_VOICE, voicetype);
1395         else if (flood < 0)
1396                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1397 }
1398
1399 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1400 {
1401 //      show_message
1402 //      0 (00) automove centerprint, admin message
1403 //      1 (01) automove centerprint, no admin message
1404 //      2 (10) no centerprint, admin message
1405 //      3 (11) no centerprint, no admin message
1406
1407         float lockteams_backup;
1408
1409         lockteams_backup = lockteams;  // backup any team lock
1410
1411         lockteams = 0;  // disable locked teams
1412
1413         TeamchangeFrags(client);  // move the players frags
1414         SetPlayerColors(client, team_colour - 1);  // set the players colour
1415         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1416
1417         lockteams = lockteams_backup;  // restore the team lock
1418
1419         LogTeamchange(client.playerid, client.team, type);
1420
1421         if not(show_message & 1) // admin message
1422                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1423
1424         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1425 }