qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_minstagib)
 266         if(self.ammo_cells <= 0)
 267                 return;
 268
 269         if(g_pinata)
 270         {
 271                 float j;
 272                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 273                 {
 274                         if(WEPSET_CONTAINS_EW(self, j))
 275                                 if(W_IsWeaponThrowable(j))
 276                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 277                 }
 278         }
 279         else
 280         {
 281                 if(W_IsWeaponThrowable(self.weapon))
 282                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 283         }
 284 }
 285
 286 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 287 {
 288         float take, save;
 289         vector v;
 290         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 291
 292         // damage resistance (ignore most of the damage from a bullet or similar)
 293         damage = max(damage - 5, 1);
 294
 295         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 296         take = v_x;
 297         save = v_y;
 298
 299         if(sound_allowed(MSG_BROADCAST, attacker))
 300         {
 301                 if (save > 10)
 302                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 303                 else if (take > 30)
 304                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 305                 else if (take > 10)
 306                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 307         }
 308
 309         if (take > 50)
 310                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 311         if (take > 100)
 312                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 313
 314         if (!(self.flags & FL_GODMODE))
 315         {
 316                 self.armorvalue = self.armorvalue - save;
 317                 self.health = self.health - take;
 318                 // pause regeneration for 5 seconds
 319                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 320         }
 321         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 322         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 323         self.dmg_inflictor = inflictor;
 324
 325         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 326         {
 327                 // don't use any animations as a gib
 328                 self.frame = 0;
 329                 // view just above the floor
 330                 self.view_ofs = '0 0 4';
 331
 332                 Violence_GibSplash(self, 1, 1, attacker);
 333                 self.alpha = -1;
 334                 self.solid = SOLID_NOT; // restore later
 335                 self.takedamage = DAMAGE_NO; // restore later
 336                 self.damagedbycontents = FALSE;
 337         }
 338 }
 339
 340 void ClientKill_Now_TeamChange();
 341 void freezetag_CheckWinner();
 342
 343 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 344 {
 345         float take, save, waves, sdelay, dh, da, j;
 346         vector v;
 347         float valid_damage_for_weaponstats;
 348         float excess;
 349
 350         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 351                 return;
 352
 353         dh = max(self.health, 0);
 354         da = max(self.armorvalue, 0);
 355
 356         if(!DEATH_ISSPECIAL(deathtype))
 357         {
 358                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 359                 if(self != attacker)
 360                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 361         }
 362
 363         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 364         {
 365                 // tuba causes blood to come out of the ears
 366                 vector ear1, ear2;
 367                 vector d;
 368                 float f;
 369                 ear1 = self.origin;
 370                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 371                 ear2 = ear1;
 372                 makevectors(self.angles);
 373                 ear1 += v_right * -10;
 374                 ear2 += v_right * +10;
 375                 d = inflictor.origin - self.origin;
 376                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 377                 force = v_right * vlen(force);
 378                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 379                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 380                 if(f > 0)
 381                 {
 382                         hitloc = ear1;
 383                         force = force * -1;
 384                 }
 385                 else
 386                 {
 387                         hitloc = ear2;
 388                         // force is already good
 389                 }
 390         }
 391         else
 392                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 393
 394         if (!g_minstagib)
 395         {
 396                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 397                 take = v_x;
 398                 save = v_y;
 399         }
 400         else
 401         {
 402                 save = 0;
 403                 take = damage;
 404         }
 405
 406         if(attacker == self)
 407         {
 408                 // don't reset pushltime for self damage as it may be an attempt to
 409                 // escape a lava pit or similar
 410                 //self.pushltime = 0;
 411                 self.istypefrag = 0;
 412         }
 413         else if(attacker.classname == "player")
 414         {
 415                 self.pusher = attacker;
 416                 self.pushltime = time + autocvar_g_maxpushtime;
 417                 self.istypefrag = self.BUTTON_CHAT;
 418         }
 419         else if(time < self.pushltime)
 420         {
 421                 attacker = self.pusher;
 422                 self.pushltime = max(self.pushltime, time + 0.6);
 423         }
 424         else
 425         {
 426                 self.pushltime = 0;
 427                 self.istypefrag = 0;
 428         }
 429
 430         frag_inflictor = inflictor;
 431         frag_attacker = attacker;
 432         frag_target = self;
 433         damage_take = take;
 434         damage_save = save;
 435         damage_force = force;
 436         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 437         take = bound(0, damage_take, self.health);
 438         save = bound(0, damage_save, self.armorvalue);
 439         excess = max(0, damage - take - save);
 440
 441         if(sound_allowed(MSG_BROADCAST, attacker))
 442         {
 443                 if (save > 10)
 444                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 445                 else if (take > 30)
 446                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 447                 else if (take > 10)
 448                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 449         }
 450
 451         if (take > 50)
 452                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 453         if (take > 100)
 454                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 455
 456         if (time >= self.spawnshieldtime)
 457         {
 458                 if (!(self.flags & FL_GODMODE))
 459                 {
 460                         self.armorvalue = self.armorvalue - save;
 461                         self.health = self.health - take;
 462                         // pause regeneration for 5 seconds
 463                         if(take)
 464                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 465
 466                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 467                         {
 468                                 self.pain_finished = time + 0.5;        //Supajoe
 469
 470                                 if(autocvar_sv_gentle < 1) {
 471                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 472                                         {
 473                                                 if (!self.animstate_override)
 474                                                 {
 475                                                         if (random() > 0.5)
 476                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 477                                                         else
 478                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 479                                                 }
 480                                         }
 481
 482                                         if(sound_allowed(MSG_BROADCAST, attacker))
 483                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 484                                         if(self.health > 1)
 485                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 486                                         {
 487                                                 if(deathtype == DEATH_FALL)
 488                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 489                                                 else if(self.health > 75) // TODO make a "gentle" version?
 490                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 491                                                 else if(self.health > 50)
 492                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 493                                                 else if(self.health > 25)
 494                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 495                                                 else
 496                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 497                                         }
 498                                 }
 499
 500                                 // throw off bot aim temporarily
 501                                 float shake;
 502                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 503                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 504                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 505                         }
 506                 }
 507                 else
 508                         self.max_armorvalue += (save + take);
 509         }
 510         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 511         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 512         self.dmg_inflictor = inflictor;
 513
 514         if(g_ca && self != attacker && attacker.classname == "player")
 515                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 516
 517         float abot, vbot, awep;
 518         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 519         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 520
 521         valid_damage_for_weaponstats = 0;
 522         awep = 0;
 523
 524         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 525         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 526         if(attacker && self != attacker)
 527         if(IsDifferentTeam(self, attacker))
 528         {
 529                 if(DEATH_ISSPECIAL(deathtype))
 530                         awep = attacker.weapon;
 531                 else
 532                         awep = DEATH_WEAPONOF(deathtype);
 533                 valid_damage_for_weaponstats = 1;
 534         }
 535
 536         if(valid_damage_for_weaponstats)
 537         {
 538                 dh = dh - max(self.health, 0);
 539                 da = da - max(self.armorvalue, 0);
 540                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 541         }
 542
 543         if (self.health < 1)
 544         {
 545                 float defer_ClientKill_Now_TeamChange;
 546                 defer_ClientKill_Now_TeamChange = FALSE;
 547
 548                 if(self.alivetime)
 549                 {
 550                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 551                         self.alivetime = 0;
 552                 }
 553
 554                 if(valid_damage_for_weaponstats)
 555                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 556
 557                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 558                 if(sound_allowed(MSG_BROADCAST, attacker))
 559                 {
 560                         if(deathtype == DEATH_DROWN)
 561                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 562                         else
 563                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 564                 }
 565
 566                 // get rid of kill indicator
 567                 if(self.killindicator)
 568                 {
 569                         remove(self.killindicator);
 570                         self.killindicator = world;
 571                         if(self.killindicator_teamchange)
 572                                 defer_ClientKill_Now_TeamChange = TRUE;
 573
 574                         if(self.classname == "body")
 575                         if(deathtype == DEATH_KILL)
 576                         {
 577                                 // for the lemmings fans, a small harmless explosion
 578                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 579                         }
 580                 }
 581
 582                 if(!g_freezetag)
 583                 {
 584                         // become fully visible
 585                         self.alpha = default_player_alpha;
 586                         // throw a weapon
 587                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 588                 }
 589
 590                 // print an obituary message
 591                 Obituary (attacker, inflictor, self, deathtype);
 592                 race_PreDie();
 593                 DropAllRunes(self);
 594
 595         // increment frag counter for used weapon type
 596         float w;
 597         w = DEATH_WEAPONOF(deathtype);
 598         if(WEP_VALID(w))
 599         if(accuracy_isgooddamage(attacker, self))
 600         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 601
 602                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 603                 {
 604                         PutClientInServer();
 605                         count_alive_players(); // re-count players
 606                         freezetag_CheckWinner();
 607                         return;
 608                 }
 609
 610                 frag_attacker = attacker;
 611                 frag_inflictor = inflictor;
 612                 frag_target = self;
 613                 MUTATOR_CALLHOOK(PlayerDies);
 614                 weapon_action(self.weapon, WR_PLAYERDEATH);
 615
 616                 RemoveGrapplingHook(self);
 617
 618                 Portal_ClearAllLater(self);
 619
 620                 if(clienttype(self) == CLIENTTYPE_REAL)
 621                 {
 622                         stuffcmd(self, "-zoom\n");
 623                         self.fixangle = TRUE;
 624                         //msg_entity = self;
 625                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 626                         //WriteAngle (MSG_ONE, self.v_angle_x);
 627                         //WriteAngle (MSG_ONE, self.v_angle_y);
 628                         //WriteAngle (MSG_ONE, 80);
 629                 }
 630
 631                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 632                         ClientKill_Now_TeamChange();
 633
 634                 if(g_arena)
 635                         Spawnqueue_Unmark(self);
 636
 637                 if(g_freezetag)
 638                         return;
 639
 640                 // when we get here, player actually dies
 641                 // clear waypoints (do this AFTER FreezeTag)
 642                 WaypointSprite_PlayerDead();
 643
 644                 // make the corpse upright (not tilted)
 645                 self.angles_x = 0;
 646                 self.angles_z = 0;
 647                 // don't spin
 648                 self.avelocity = '0 0 0';
 649                 // view from the floor
 650                 self.view_ofs = '0 0 -8';
 651                 // toss the corpse
 652                 self.movetype = MOVETYPE_TOSS;
 653                 // shootable corpse
 654                 self.solid = SOLID_CORPSE;
 655                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 656                 // don't stick to the floor
 657                 self.flags &~= FL_ONGROUND;
 658                 // dying animation
 659                 self.deadflag = DEAD_DYING;
 660                 // when to allow respawn
 661                 sdelay = 0;
 662                 waves = 0;
 663                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 664                 if(!sdelay)
 665                 {
 666                         if(g_cts)
 667                                 sdelay = 0; // no respawn delay in CTS
 668                         else
 669                                 sdelay = autocvar_g_respawn_delay;
 670                 }
 671                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 672                 if(!waves)
 673                         waves = autocvar_g_respawn_waves;
 674                 if(waves)
 675                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 676                 else
 677                         self.respawn_time = time + sdelay;
 678                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 679                         self.respawn_countdown = 10; // first number to count down from is 10
 680                 else
 681                         self.respawn_countdown = -1; // do not count down
 682                 self.death_time = time;
 683                 if (random() < 0.5)
 684                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 685                 else
 686                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 687                 if (self.maxs_z > 5)
 688                 {
 689                         self.maxs_z = 5;
 690                         setsize(self, self.mins, self.maxs);
 691                 }
 692                 // set damage function to corpse damage
 693                 self.event_damage = PlayerCorpseDamage;
 694                 // call the corpse damage function just in case it wants to gib
 695                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 696                 // set up to fade out later
 697                 SUB_SetFade (self, time + 6 + random (), 1);
 698
 699                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 700                         // remove corpse
 701                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 702                 }
 703
 704                 // reset fields the weapons may use just in case
 705                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 706                 {
 707                         weapon_action(j, WR_RESETPLAYER);
 708                         ATTACK_FINISHED_FOR(self, j) = 0;
 709                 }
 710         }
 711 }
 712
 713 .float muted; // to be used by prvm_edictset server playernumber muted 1
 714 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 715 // message "": do not say, just test flood control
 716 // return value:
 717 //   1 = accept
 718 //   0 = reject
 719 //  -1 = fake accept
 720 {
 721         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 722         float flood;
 723         var .float flood_field;
 724         entity head;
 725         float ret;
 726         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 727
 728         if(!teamsay && !privatesay)
 729                 if(substring(msgin, 0, 1) == " ")
 730                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 731
 732         msgin = formatmessage(msgin);
 733
 734         if(source.classname != "player")
 735                 colorstr = "^0"; // black for spectators
 736         else if(teamplay)
 737                 colorstr = Team_ColorCode(source.team);
 738         else
 739         {
 740                 colorstr = "";
 741                 teamsay = FALSE;
 742         }
 743
 744         if(intermission_running)
 745                 teamsay = FALSE;
 746
 747         if(msgin != "")
 748                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 749
 750         /*
 751          * using bprint solves this... me stupid
 752         // how can we prevent the message from appearing in a listen server?
 753         // for now, just give "say" back and only handle say_team
 754         if(!teamsay)
 755         {
 756                 clientcommand(self, strcat("say ", msgin));
 757                 return;
 758         }
 759         */
 760
 761         if(autocvar_g_chat_teamcolors)
 762                 namestr = playername(source);
 763         else
 764                 namestr = source.netname;
 765
 766         if(msgin != "")
 767         {
 768                 if(privatesay)
 769                 {
 770                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 771                         privatemsgprefixlen = strlen(msgstr);
 772                         msgstr = strcat(msgstr, msgin);
 773                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 774                         if(autocvar_g_chat_teamcolors)
 775                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 776                         else
 777                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 778                 }
 779                 else if(teamsay)
 780                 {
 781                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 782                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 783                 }
 784                 else
 785                 {
 786                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 787                         cmsgstr = "";
 788                 }
 789                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 790         }
 791         else
 792         {
 793                 msgstr = cmsgstr = "";
 794         }
 795
 796         fullmsgstr = msgstr;
 797         fullcmsgstr = cmsgstr;
 798
 799         // FLOOD CONTROL
 800         flood = 0;
 801         flood_field = floodcontrol_chat;
 802         if(floodcontrol)
 803         {
 804                 float flood_spl;
 805                 float flood_burst;
 806                 float flood_lmax;
 807                 float lines;
 808                 if(privatesay)
 809                 {
 810                         flood_spl = autocvar_g_chat_flood_spl_tell;
 811                         flood_burst = autocvar_g_chat_flood_burst_tell;
 812                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 813                         flood_field = floodcontrol_chattell;
 814                 }
 815                 else if(teamsay)
 816                 {
 817                         flood_spl = autocvar_g_chat_flood_spl_team;
 818                         flood_burst = autocvar_g_chat_flood_burst_team;
 819                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 820                         flood_field = floodcontrol_chatteam;
 821                 }
 822                 else
 823                 {
 824                         flood_spl = autocvar_g_chat_flood_spl;
 825                         flood_burst = autocvar_g_chat_flood_burst;
 826                         flood_lmax = autocvar_g_chat_flood_lmax;
 827                         flood_field = floodcontrol_chat;
 828                 }
 829                 flood_burst = max(0, flood_burst - 1);
 830                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 831
 832                 // do flood control for the default line size
 833                 if(msgstr != "")
 834                 {
 835                         getWrappedLine_remaining = msgstr;
 836                         msgstr = "";
 837                         lines = 0;
 838                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 839                         {
 840                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 841                                 ++lines;
 842                         }
 843                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 844
 845                         if(getWrappedLine_remaining != "")
 846                         {
 847                                 msgstr = strcat(msgstr, "\n");
 848                                 flood = 2;
 849                         }
 850
 851                         if(time >= source.flood_field)
 852                         {
 853                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 854                         }
 855                         else
 856                         {
 857                                 flood = 1;
 858                                 msgstr = fullmsgstr;
 859                         }
 860                 }
 861                 else
 862                 {
 863                         if(time >= source.flood_field)
 864                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 865                         else
 866                                 flood = 1;
 867                 }
 868
 869                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 870                         source.flood_field = flood = 0;
 871         }
 872
 873         if(flood == 2) // cannot happen for empty msgstr
 874         {
 875                 if(autocvar_g_chat_flood_notify_flooder)
 876                 {
 877                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 878                         sourcecmsgstr = "";
 879                 }
 880                 else
 881                 {
 882                         sourcemsgstr = fullmsgstr;
 883                         sourcecmsgstr = fullcmsgstr;
 884                 }
 885                 cmsgstr = "";
 886         }
 887         else
 888         {
 889                 sourcemsgstr = msgstr;
 890                 sourcecmsgstr = cmsgstr;
 891         }
 892
 893         if(!privatesay)
 894         if(source.classname != "player")
 895         {
 896                 if not(intermission_running)
 897                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 898                                 teamsay = -1; // spectators
 899         }
 900
 901         if(flood)
 902                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 903
 904         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 905         if(privatesay)
 906                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 907
 908         if(source.muted)
 909         {
 910                 // always fake the message
 911                 ret = -1;
 912         }
 913         else if(flood == 1)
 914         {
 915                 if(autocvar_g_chat_flood_notify_flooder)
 916                 {
 917                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 918                         ret = 0;
 919                 }
 920                 else
 921                         ret = -1;
 922         }
 923         else
 924         {
 925                 ret = 1;
 926         }
 927
 928         if(sourcemsgstr != "" && ret != 0)
 929         {
 930                 if(ret < 0) // faked message, because the player is muted
 931                 {
 932                         sprint(source, sourcemsgstr);
 933                         if(sourcecmsgstr != "" && !privatesay)
 934                                 centerprint(source, sourcecmsgstr);
 935                 }
 936                 else if(privatesay) // private message, between 2 people only
 937                 {
 938                         sprint(source, sourcemsgstr);
 939                         sprint(privatesay, msgstr);
 940                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 941                         if(cmsgstr != "")
 942                                 centerprint(privatesay, cmsgstr);
 943                 }
 944                 else if(teamsay > 0) // team message, only sent to team mates
 945                 {
 946                         sprint(source, sourcemsgstr);
 947                         dedicated_print(msgstr); // send to server console too
 948                         if(sourcecmsgstr != "")
 949                                 centerprint(source, sourcecmsgstr);
 950                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 951                                 if(head != source)
 952                                 {
 953                                         sprint(head, msgstr);
 954                                         if(cmsgstr != "")
 955                                                 centerprint(head, cmsgstr);
 956                                 }
 957                 }
 958                 else if(teamsay < 0) // spectator message, only sent to spectators
 959                 {
 960                         sprint(source, sourcemsgstr);
 961                         dedicated_print(msgstr); // send to server console too
 962                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 963                                 if(head != source)
 964                                         sprint(head, msgstr);
 965                 }
 966                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 967                 {
 968                         sprint(source, sourcemsgstr);
 969                         dedicated_print(msgstr); // send to server console too
 970                         FOR_EACH_REALCLIENT(head)
 971                                 if(head != source)
 972                                         sprint(head, msgstr);
 973                 }
 974                 else
 975                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 976         }
 977
 978         return ret;
 979 }
 980
 981 float GetVoiceMessageVoiceType(string type)
 982 {
 983         if(type == "taunt")
 984                 return VOICETYPE_TAUNT;
 985         if(type == "teamshoot")
 986                 return VOICETYPE_LASTATTACKER;
 987         return VOICETYPE_TEAMRADIO;
 988 }
 989
 990 string allvoicesamples;
 991 .string GetVoiceMessageSampleField(string type)
 992 {
 993         GetPlayerSoundSampleField_notFound = 0;
 994         switch(type)
 995         {
 996 #define _VOICEMSG(m) case #m: return playersound_##m;
 997                 ALLVOICEMSGS
 998 #undef _VOICEMSG
 999         }
1000         GetPlayerSoundSampleField_notFound = 1;
1001         return playersound_taunt;
1002 }
1003
1004 .string GetPlayerSoundSampleField(string type)
1005 {
1006         GetPlayerSoundSampleField_notFound = 0;
1007         switch(type)
1008         {
1009 #define _VOICEMSG(m) case #m: return playersound_##m;
1010                 ALLPLAYERSOUNDS
1011 #undef _VOICEMSG
1012         }
1013         GetPlayerSoundSampleField_notFound = 1;
1014         return playersound_taunt;
1015 }
1016
1017 void PrecacheGlobalSound(string samplestring)
1018 {
1019         float n, i;
1020         tokenize_console(samplestring);
1021         n = stof(argv(1));
1022         if(n > 0)
1023         {
1024                 for(i = 1; i <= n; ++i)
1025                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1026         }
1027         else
1028         {
1029                 precache_sound(strcat(argv(0), ".wav"));
1030         }
1031 }
1032
1033 void PrecachePlayerSounds(string f)
1034 {
1035         float fh;
1036         string s;
1037         fh = fopen(f, FILE_READ);
1038         if(fh < 0)
1039                 return;
1040         while((s = fgets(fh)))
1041         {
1042                 if(tokenize_console(s) != 3)
1043                 {
1044                         dprint("Invalid sound info line: ", s, "\n");
1045                         continue;
1046                 }
1047                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1048         }
1049         fclose(fh);
1050
1051         if not(allvoicesamples)
1052         {
1053 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1054                 ALLVOICEMSGS
1055 #undef _VOICEMSG
1056                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1057         }
1058 }
1059
1060 void ClearPlayerSounds()
1061 {
1062 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1063         ALLPLAYERSOUNDS
1064         ALLVOICEMSGS
1065 #undef _VOICEMSG
1066 }
1067
1068 float LoadPlayerSounds(string f, float first)
1069 {
1070         float fh;
1071         string s;
1072         var .string field;
1073         fh = fopen(f, FILE_READ);
1074         if(fh < 0)
1075         {
1076                 dprint("Player sound file not found: ", f, "\n");
1077                 return 0;
1078         }
1079         while((s = fgets(fh)))
1080         {
1081                 if(tokenize_console(s) != 3)
1082                         continue;
1083                 field = GetPlayerSoundSampleField(argv(0));
1084                 if(GetPlayerSoundSampleField_notFound)
1085                         field = GetVoiceMessageSampleField(argv(0));
1086                 if(GetPlayerSoundSampleField_notFound)
1087                         continue;
1088                 if(self.field)
1089                         strunzone(self.field);
1090                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1091         }
1092         fclose(fh);
1093         return 1;
1094 }
1095
1096 .float modelindex_for_playersound;
1097 .float skin_for_playersound;
1098 void UpdatePlayerSounds()
1099 {
1100         if(self.modelindex == self.modelindex_for_playersound)
1101         if(self.skin == self.skin_for_playersound)
1102                 return;
1103         self.modelindex_for_playersound = self.modelindex;
1104         self.skin_for_playersound = self.skin;
1105         ClearPlayerSounds();
1106         LoadPlayerSounds("sound/player/default.sounds", 1);
1107         if(!autocvar_g_debug_defaultsounds)
1108                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1109                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1110 }
1111
1112 void FakeGlobalSound(string sample, float chan, float voicetype)
1113 {
1114         float n;
1115         float tauntrand;
1116
1117         if(sample == "")
1118                 return;
1119
1120         tokenize_console(sample);
1121         n = stof(argv(1));
1122         if(n > 0)
1123                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1124         else
1125                 sample = strcat(argv(0), ".wav"); // randomization
1126
1127         switch(voicetype)
1128         {
1129                 case VOICETYPE_LASTATTACKER_ONLY:
1130                         break;
1131                 case VOICETYPE_LASTATTACKER:
1132                         if(self.pusher)
1133                         {
1134                                 msg_entity = self;
1135                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1136                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1137                         }
1138                         break;
1139                 case VOICETYPE_TEAMRADIO:
1140                         msg_entity = self;
1141                         if(msg_entity.cvar_cl_voice_directional == 1)
1142                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1143                         else
1144                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1145                         break;
1146                 case VOICETYPE_AUTOTAUNT:
1147                         if(!sv_autotaunt)
1148                                 break;
1149                         if(!sv_taunt)
1150                                 break;
1151                         if(autocvar_sv_gentle)
1152                                 break;
1153                         tauntrand = random();
1154                         msg_entity = self;
1155                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1156                         {
1157                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1158                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1159                                 else
1160                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1161                         }
1162                         break;
1163                 case VOICETYPE_TAUNT:
1164                         if(self.classname == "player")
1165                                 if(self.deadflag == DEAD_NO)
1166                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1167                         if(!sv_taunt)
1168                                 break;
1169                         if(autocvar_sv_gentle)
1170                                 break;
1171                         msg_entity = self;
1172                         if (msg_entity.cvar_cl_voice_directional >= 1)
1173                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1174                         else
1175                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1176                         break;
1177                 case VOICETYPE_PLAYERSOUND:
1178                         msg_entity = self;
1179                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1180                         break;
1181                 default:
1182                         backtrace("Invalid voice type!");
1183                         break;
1184         }
1185 }
1186
1187 void GlobalSound(string sample, float chan, float voicetype)
1188 {
1189         float n;
1190         float tauntrand;
1191
1192         if(sample == "")
1193                 return;
1194
1195         tokenize_console(sample);
1196         n = stof(argv(1));
1197         if(n > 0)
1198                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1199         else
1200                 sample = strcat(argv(0), ".wav"); // randomization
1201
1202         switch(voicetype)
1203         {
1204                 case VOICETYPE_LASTATTACKER_ONLY:
1205                         if(self.pusher)
1206                         {
1207                                 msg_entity = self.pusher;
1208                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1209                                 {
1210                                         if(msg_entity.cvar_cl_voice_directional == 1)
1211                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1212                                         else
1213                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1214                                 }
1215                         }
1216                         break;
1217                 case VOICETYPE_LASTATTACKER:
1218                         if(self.pusher)
1219                         {
1220                                 msg_entity = self.pusher;
1221                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1222                                 {
1223                                         if(msg_entity.cvar_cl_voice_directional == 1)
1224                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1225                                         else
1226                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1227                                 }
1228                                 msg_entity = self;
1229                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1230                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1231                         }
1232                         break;
1233                 case VOICETYPE_TEAMRADIO:
1234                         FOR_EACH_REALCLIENT(msg_entity)
1235                                 if(!teamplay || msg_entity.team == self.team)
1236                                 {
1237                                         if(msg_entity.cvar_cl_voice_directional == 1)
1238                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1239                                         else
1240                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1241                                 }
1242                         break;
1243                 case VOICETYPE_AUTOTAUNT:
1244                         if(!sv_autotaunt)
1245                                 break;
1246                         if(!sv_taunt)
1247                                 break;
1248                         if(autocvar_sv_gentle)
1249                                 break;
1250                         tauntrand = random();
1251                         FOR_EACH_REALCLIENT(msg_entity)
1252                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1253                                 {
1254                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1255                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1256                                         else
1257                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1258                                 }
1259                         break;
1260                 case VOICETYPE_TAUNT:
1261                         if(self.classname == "player")
1262                                 if(self.deadflag == DEAD_NO)
1263                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1264                         if(!sv_taunt)
1265                                 break;
1266                         if(autocvar_sv_gentle)
1267                                 break;
1268                         FOR_EACH_REALCLIENT(msg_entity)
1269                         {
1270                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1271                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1272                                 else
1273                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1274                         }
1275                         break;
1276                 case VOICETYPE_PLAYERSOUND:
1277                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1278                         break;
1279                 default:
1280                         backtrace("Invalid voice type!");
1281                         break;
1282         }
1283 }
1284
1285 void PlayerSound(.string samplefield, float chan, float voicetype)
1286 {
1287         GlobalSound(self.samplefield, chan, voicetype);
1288 }
1289
1290 void VoiceMessage(string type, string msg)
1291 {
1292         var .string sample;
1293         float voicetype, ownteam;
1294         float flood;
1295         sample = GetVoiceMessageSampleField(type);
1296
1297         if(GetPlayerSoundSampleField_notFound)
1298         {
1299                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1300                 return;
1301         }
1302
1303         voicetype = GetVoiceMessageVoiceType(type);
1304         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1305
1306         flood = Say(self, ownteam, world, msg, 1);
1307
1308         if (flood > 0)
1309                 GlobalSound(self.sample, CH_VOICE, voicetype);
1310         else if (flood < 0)
1311                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1312 }
1313
1314 void MoveToTeam(entity client, float team_colour, float type)
1315 {
1316         float lockteams_backup;
1317
1318         lockteams_backup = lockteams;  // backup any team lock
1319
1320         lockteams = 0;  // disable locked teams
1321
1322         TeamchangeFrags(client);  // move the players frags
1323         SetPlayerColors(client, team_colour - 1);  // set the players colour
1324         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1325
1326         lockteams = lockteams_backup;  // restore the team lock
1327
1328         LogTeamchange(client.playerid, client.team, type);
1329 }