qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.animstate_startframe = oldself.animstate_startframe;
 165         self.animstate_numframes = oldself.animstate_numframes;
 166         self.animstate_framerate = oldself.animstate_framerate;
 167         self.animstate_starttime = oldself.animstate_starttime;
 168         self.animstate_endtime = oldself.animstate_endtime;
 169         self.animstate_override = oldself.animstate_override;
 170         self.animstate_looping = oldself.animstate_looping;
 171         self.dphitcontentsmask = oldself.dphitcontentsmask;
 172         self.death_time = oldself.death_time;
 173         self.frame = oldself.frame;
 174         self.pain_finished = oldself.pain_finished;
 175         self.health = oldself.health;
 176         self.armorvalue = oldself.armorvalue;
 177         self.armortype = oldself.armortype;
 178         self.model = oldself.model;
 179         self.modelindex = oldself.modelindex;
 180         self.skin = oldself.skin;
 181         self.species = oldself.species;
 182         self.movetype = oldself.movetype;
 183         self.solid = oldself.solid;
 184         self.ballistics_density = oldself.ballistics_density;
 185         self.takedamage = oldself.takedamage;
 186         self.customizeentityforclient = oldself.customizeentityforclient;
 187         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 188         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 189         if (keepvelocity == 1)
 190                 self.velocity = oldself.velocity;
 191         self.oldvelocity = self.velocity;
 192         self.alpha = oldself.alpha;
 193         self.fade_time = oldself.fade_time;
 194         self.fade_rate = oldself.fade_rate;
 195         //self.weapon = oldself.weapon;
 196         setorigin(self, oldself.origin);
 197         setsize(self, oldself.mins, oldself.maxs);
 198         self.prevorigin = oldself.origin;
 199         self.reset = SUB_Remove;
 200
 201         Drag_MoveDrag(oldself, self);
 202
 203         if(self.colormap <= maxclients && self.colormap > 0)
 204                 self.colormap = 1024 + oldself.clientcolors;
 205
 206         CSQCMODEL_AUTOINIT();
 207         self.CopyBody_nextthink = oldself.nextthink;
 208         self.CopyBody_think = oldself.think;
 209         self.nextthink = time;
 210         self.think = CopyBody_Think;
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // defaults for legacy .zym models without animinfo files
 229         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 230         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 231         self.anim_draw = animfixfps(self, '2 1 3');
 232         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 233         self.anim_duckwalk = animfixfps(self, '4 1 1');
 234         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 235         self.anim_duckidle = animfixfps(self, '6 1 1');
 236         self.anim_idle = animfixfps(self, '7 1 1');
 237         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 239         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 240         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 241         self.anim_taunt = animfixfps(self, '12 1 0.33');
 242         self.anim_run = animfixfps(self, '13 1 1');
 243         self.anim_runbackwards = animfixfps(self, '14 1 1');
 244         self.anim_strafeleft = animfixfps(self, '15 1 1');
 245         self.anim_straferight = animfixfps(self, '16 1 1');
 246         //self.anim_dead1 = animfixfps(self, '17 1 1');
 247         //self.anim_dead2 = animfixfps(self, '18 1 1');
 248         self.anim_forwardright = animfixfps(self, '19 1 1');
 249         self.anim_forwardleft = animfixfps(self, '20 1 1');
 250         self.anim_backright = animfixfps(self, '21 1 1');
 251         self.anim_backleft  = animfixfps(self, '22 1 1');
 252         self.anim_melee = animfixfps(self, '23 1 1');
 253         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 254         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 255         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 256         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 257         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 258         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 259         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 260         // TODO introspect models for finding right "fps" value (1/duration)
 261         // reset animstate now
 262         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 263 }
 264
 265 void player_anim (void)
 266 {
 267         updateanim(self);
 268         if (self.weaponentity)
 269                 updateanim(self.weaponentity);
 270
 271         if (self.deadflag != DEAD_NO)
 272                 return;
 273
 274         if (!self.animstate_override)
 275         {
 276                 if (self.freezetag_frozen)
 277                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 278                 else if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 279                 {
 280                         if (self.crouch)
 281                         {
 282                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 283                                 {
 284                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 285                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 286                                         {
 287                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 288                                                 self.restart_jump = FALSE;
 289                                         }
 290                                 }
 291                         }
 292                         else
 293                         {
 294                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 295                 {
 296                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 297                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 298                     {
 299                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 300                         self.restart_jump = FALSE;
 301                     }
 302                 }
 303                         }
 304                 }
 305                 else if (self.crouch)
 306                 {
 307                         if (self.movement_x > 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x < 0 && self.movement_y == 0)
 310                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x == 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x > 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y > 0)
 320                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x < 0 && self.movement_y < 0)
 322                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_minstagib)
 359         if(self.ammo_cells <= 0)
 360                 return;
 361
 362         if(g_pinata)
 363         {
 364                 float j;
 365                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 366                 {
 367                         if(WEPSET_CONTAINS_EW(self, j))
 368                                 if(W_IsWeaponThrowable(j))
 369                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 370                 }
 371         }
 372         else
 373         {
 374                 if(W_IsWeaponThrowable(self.weapon))
 375                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 376         }
 377 }
 378
 379 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 380 {
 381         float take, save;
 382         vector v;
 383         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 384
 385         // damage resistance (ignore most of the damage from a bullet or similar)
 386         damage = max(damage - 5, 1);
 387
 388         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 389         take = v_x;
 390         save = v_y;
 391
 392         if(sound_allowed(MSG_BROADCAST, attacker))
 393         {
 394                 if (save > 10)
 395                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 396                 else if (take > 30)
 397                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 398                 else if (take > 10)
 399                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 400         }
 401
 402         if (take > 50)
 403                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 404         if (take > 100)
 405                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 406
 407         if (!(self.flags & FL_GODMODE))
 408         {
 409                 self.armorvalue = self.armorvalue - save;
 410                 self.health = self.health - take;
 411                 // pause regeneration for 5 seconds
 412                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 413         }
 414         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 415         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 416         self.dmg_inflictor = inflictor;
 417
 418         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 419         {
 420                 // don't use any animations as a gib
 421                 self.frame = 0;
 422                 // view just above the floor
 423                 self.view_ofs = '0 0 4';
 424
 425                 Violence_GibSplash(self, 1, 1, attacker);
 426                 self.alpha = -1;
 427                 self.solid = SOLID_NOT; // restore later
 428                 self.takedamage = DAMAGE_NO; // restore later
 429                 self.damagedbycontents = FALSE;
 430         }
 431 }
 432
 433 void ClientKill_Now_TeamChange();
 434 void freezetag_CheckWinner();
 435
 436 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 437 {
 438         float take, save, waves, sdelay, dh, da, j;
 439         vector v;
 440         float valid_damage_for_weaponstats;
 441         float excess;
 442
 443         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 444                 return;
 445
 446         dh = max(self.health, 0);
 447         da = max(self.armorvalue, 0);
 448
 449         if(!DEATH_ISSPECIAL(deathtype))
 450         {
 451                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 452                 if(self != attacker)
 453                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 454         }
 455
 456         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 457         {
 458                 // tuba causes blood to come out of the ears
 459                 vector ear1, ear2;
 460                 vector d;
 461                 float f;
 462                 ear1 = self.origin;
 463                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 464                 ear2 = ear1;
 465                 makevectors(self.angles);
 466                 ear1 += v_right * -10;
 467                 ear2 += v_right * +10;
 468                 d = inflictor.origin - self.origin;
 469                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 470                 force = v_right * vlen(force);
 471                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 472                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 473                 if(f > 0)
 474                 {
 475                         hitloc = ear1;
 476                         force = force * -1;
 477                 }
 478                 else
 479                 {
 480                         hitloc = ear2;
 481                         // force is already good
 482                 }
 483         }
 484         else
 485                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 486
 487         if (!g_minstagib)
 488         {
 489                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 490                 take = v_x;
 491                 save = v_y;
 492         }
 493         else
 494         {
 495                 save = 0;
 496                 take = damage;
 497         }
 498
 499         if(attacker == self)
 500         {
 501                 // don't reset pushltime for self damage as it may be an attempt to
 502                 // escape a lava pit or similar
 503                 //self.pushltime = 0;
 504                 self.istypefrag = 0;
 505         }
 506         else if(attacker.classname == "player")
 507         {
 508                 self.pusher = attacker;
 509                 self.pushltime = time + autocvar_g_maxpushtime;
 510                 self.istypefrag = self.BUTTON_CHAT;
 511         }
 512         else if(time < self.pushltime)
 513         {
 514                 attacker = self.pusher;
 515                 self.pushltime = max(self.pushltime, time + 0.6);
 516         }
 517         else
 518         {
 519                 self.pushltime = 0;
 520                 self.istypefrag = 0;
 521         }
 522
 523         frag_inflictor = inflictor;
 524         frag_attacker = attacker;
 525         frag_target = self;
 526         damage_take = take;
 527         damage_save = save;
 528         damage_force = force;
 529         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 530         take = bound(0, damage_take, self.health);
 531         save = bound(0, damage_save, self.armorvalue);
 532         excess = max(0, damage - take - save);
 533
 534         if(sound_allowed(MSG_BROADCAST, attacker))
 535         {
 536                 if (save > 10)
 537                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 538                 else if (take > 30)
 539                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 540                 else if (take > 10)
 541                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 542         }
 543
 544         if (take > 50)
 545                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 546         if (take > 100)
 547                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 548
 549         if (time >= self.spawnshieldtime)
 550         {
 551                 if (!(self.flags & FL_GODMODE))
 552                 {
 553                         self.armorvalue = self.armorvalue - save;
 554                         self.health = self.health - take;
 555                         // pause regeneration for 5 seconds
 556                         if(take)
 557                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 558
 559                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 560                         {
 561                                 self.pain_finished = time + 0.5;        //Supajoe
 562
 563                                 if(autocvar_sv_gentle < 1) {
 564                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 565                                         {
 566                                                 if (!self.animstate_override)
 567                                                 {
 568                                                         if (random() > 0.5)
 569                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 570                                                         else
 571                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 572                                                 }
 573                                         }
 574
 575                                         if(sound_allowed(MSG_BROADCAST, attacker))
 576                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 577                                         if(self.health > 1)
 578                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 579                                         {
 580                                                 if(deathtype == DEATH_FALL)
 581                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 582                                                 else if(self.health > 75) // TODO make a "gentle" version?
 583                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 584                                                 else if(self.health > 50)
 585                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 586                                                 else if(self.health > 25)
 587                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 588                                                 else
 589                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 590                                         }
 591                                 }
 592
 593                                 // throw off bot aim temporarily
 594                                 float shake;
 595                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 596                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 597                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 598                         }
 599                 }
 600                 else
 601                         self.max_armorvalue += (save + take);
 602         }
 603         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 604         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 605         self.dmg_inflictor = inflictor;
 606
 607         if(g_ca && self != attacker && attacker.classname == "player")
 608                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 609
 610         float abot, vbot, awep;
 611         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 612         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 613
 614         valid_damage_for_weaponstats = 0;
 615         awep = 0;
 616
 617         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 618         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 619         if(attacker && self != attacker)
 620         if(IsDifferentTeam(self, attacker))
 621         {
 622                 if(DEATH_ISSPECIAL(deathtype))
 623                         awep = attacker.weapon;
 624                 else
 625                         awep = DEATH_WEAPONOF(deathtype);
 626                 valid_damage_for_weaponstats = 1;
 627         }
 628
 629         if(valid_damage_for_weaponstats)
 630         {
 631                 dh = dh - max(self.health, 0);
 632                 da = da - max(self.armorvalue, 0);
 633                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 634         }
 635
 636         if (self.health < 1)
 637         {
 638                 float defer_ClientKill_Now_TeamChange;
 639                 defer_ClientKill_Now_TeamChange = FALSE;
 640
 641                 if(self.alivetime)
 642                 {
 643                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 644                         self.alivetime = 0;
 645                 }
 646
 647                 if(valid_damage_for_weaponstats)
 648                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 649
 650                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 651                 if(sound_allowed(MSG_BROADCAST, attacker))
 652                 {
 653                         if(deathtype == DEATH_DROWN)
 654                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 655                         else
 656                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 657                 }
 658
 659                 // get rid of kill indicator
 660                 if(self.killindicator)
 661                 {
 662                         remove(self.killindicator);
 663                         self.killindicator = world;
 664                         if(self.killindicator_teamchange)
 665                                 defer_ClientKill_Now_TeamChange = TRUE;
 666
 667                         if(self.classname == "body")
 668                         if(deathtype == DEATH_KILL)
 669                         {
 670                                 // for the lemmings fans, a small harmless explosion
 671                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 672                         }
 673                 }
 674
 675                 if(!g_freezetag)
 676                 {
 677                         // become fully visible
 678                         self.alpha = default_player_alpha;
 679                         // throw a weapon
 680                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 681                 }
 682
 683                 // print an obituary message
 684                 Obituary (attacker, inflictor, self, deathtype);
 685                 race_PreDie();
 686                 DropAllRunes(self);
 687
 688         // increment frag counter for used weapon type
 689         float w;
 690         w = DEATH_WEAPONOF(deathtype);
 691         if(WEP_VALID(w))
 692         if(accuracy_isgooddamage(attacker, self))
 693         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 694
 695                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 696                 {
 697                         PutClientInServer();
 698                         count_alive_players(); // re-count players
 699                         freezetag_CheckWinner();
 700                         return;
 701                 }
 702
 703                 frag_attacker = attacker;
 704                 frag_inflictor = inflictor;
 705                 frag_target = self;
 706                 MUTATOR_CALLHOOK(PlayerDies);
 707                 weapon_action(self.weapon, WR_PLAYERDEATH);
 708
 709                 RemoveGrapplingHook(self);
 710
 711                 Portal_ClearAllLater(self);
 712
 713                 if(clienttype(self) == CLIENTTYPE_REAL)
 714                 {
 715                         stuffcmd(self, "-zoom\n");
 716                         self.fixangle = TRUE;
 717                         //msg_entity = self;
 718                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 719                         //WriteAngle (MSG_ONE, self.v_angle_x);
 720                         //WriteAngle (MSG_ONE, self.v_angle_y);
 721                         //WriteAngle (MSG_ONE, 80);
 722                 }
 723
 724                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 725                         ClientKill_Now_TeamChange();
 726
 727                 if(g_arena)
 728                         Spawnqueue_Unmark(self);
 729
 730                 if(g_freezetag)
 731                         return;
 732
 733                 // when we get here, player actually dies
 734                 // clear waypoints (do this AFTER FreezeTag)
 735                 WaypointSprite_PlayerDead();
 736
 737                 // make the corpse upright (not tilted)
 738                 self.angles_x = 0;
 739                 self.angles_z = 0;
 740                 // don't spin
 741                 self.avelocity = '0 0 0';
 742                 // view from the floor
 743                 self.view_ofs = '0 0 -8';
 744                 // toss the corpse
 745                 self.movetype = MOVETYPE_TOSS;
 746                 // shootable corpse
 747                 self.solid = SOLID_CORPSE;
 748                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 749                 // don't stick to the floor
 750                 self.flags &~= FL_ONGROUND;
 751                 // dying animation
 752                 self.deadflag = DEAD_DYING;
 753                 // when to allow respawn
 754                 sdelay = 0;
 755                 waves = 0;
 756                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 757                 if(!sdelay)
 758                 {
 759                         if(g_cts)
 760                                 sdelay = 0; // no respawn delay in CTS
 761                         else
 762                                 sdelay = autocvar_g_respawn_delay;
 763                 }
 764                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 765                 if(!waves)
 766                         waves = autocvar_g_respawn_waves;
 767                 if(waves)
 768                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 769                 else
 770                         self.respawn_time = time + sdelay;
 771                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 772                         self.respawn_countdown = 10; // first number to count down from is 10
 773                 else
 774                         self.respawn_countdown = -1; // do not count down
 775                 self.death_time = time;
 776                 if (random() < 0.5)
 777                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 778                 else
 779                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 780                 if (self.maxs_z > 5)
 781                 {
 782                         self.maxs_z = 5;
 783                         setsize(self, self.mins, self.maxs);
 784                 }
 785                 // set damage function to corpse damage
 786                 self.event_damage = PlayerCorpseDamage;
 787                 // call the corpse damage function just in case it wants to gib
 788                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 789                 // set up to fade out later
 790                 SUB_SetFade (self, time + 6 + random (), 1);
 791
 792                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 793                         // remove corpse
 794                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 795                 }
 796
 797                 // reset fields the weapons may use just in case
 798                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 799                 {
 800                         weapon_action(j, WR_RESETPLAYER);
 801                         ATTACK_FINISHED_FOR(self, j) = 0;
 802                 }
 803         }
 804 }
 805
 806 .float muted; // to be used by prvm_edictset server playernumber muted 1
 807 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 808 // message "": do not say, just test flood control
 809 // return value:
 810 //   1 = accept
 811 //   0 = reject
 812 //  -1 = fake accept
 813 {
 814         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 815         float flood;
 816         var .float flood_field;
 817         entity head;
 818         float ret;
 819         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 820
 821         if(!teamsay && !privatesay)
 822                 if(substring(msgin, 0, 1) == " ")
 823                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 824
 825         msgin = formatmessage(msgin);
 826
 827         if(source.classname != "player")
 828                 colorstr = "^0"; // black for spectators
 829         else if(teamplay)
 830                 colorstr = Team_ColorCode(source.team);
 831         else
 832         {
 833                 colorstr = "";
 834                 teamsay = FALSE;
 835         }
 836
 837         if(intermission_running)
 838                 teamsay = FALSE;
 839
 840         if(msgin != "")
 841                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 842
 843         /*
 844          * using bprint solves this... me stupid
 845         // how can we prevent the message from appearing in a listen server?
 846         // for now, just give "say" back and only handle say_team
 847         if(!teamsay)
 848         {
 849                 clientcommand(self, strcat("say ", msgin));
 850                 return;
 851         }
 852         */
 853
 854         if(autocvar_g_chat_teamcolors)
 855                 namestr = playername(source);
 856         else
 857                 namestr = source.netname;
 858
 859         if(msgin != "")
 860         {
 861                 if(privatesay)
 862                 {
 863                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 864                         privatemsgprefixlen = strlen(msgstr);
 865                         msgstr = strcat(msgstr, msgin);
 866                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 867                         if(autocvar_g_chat_teamcolors)
 868                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 869                         else
 870                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 871                 }
 872                 else if(teamsay)
 873                 {
 874                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 875                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 876                 }
 877                 else
 878                 {
 879                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 880                         cmsgstr = "";
 881                 }
 882                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 883         }
 884         else
 885         {
 886                 msgstr = cmsgstr = "";
 887         }
 888
 889         fullmsgstr = msgstr;
 890         fullcmsgstr = cmsgstr;
 891
 892         // FLOOD CONTROL
 893         flood = 0;
 894         flood_field = floodcontrol_chat;
 895         if(floodcontrol)
 896         {
 897                 float flood_spl;
 898                 float flood_burst;
 899                 float flood_lmax;
 900                 float lines;
 901                 if(privatesay)
 902                 {
 903                         flood_spl = autocvar_g_chat_flood_spl_tell;
 904                         flood_burst = autocvar_g_chat_flood_burst_tell;
 905                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 906                         flood_field = floodcontrol_chattell;
 907                 }
 908                 else if(teamsay)
 909                 {
 910                         flood_spl = autocvar_g_chat_flood_spl_team;
 911                         flood_burst = autocvar_g_chat_flood_burst_team;
 912                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 913                         flood_field = floodcontrol_chatteam;
 914                 }
 915                 else
 916                 {
 917                         flood_spl = autocvar_g_chat_flood_spl;
 918                         flood_burst = autocvar_g_chat_flood_burst;
 919                         flood_lmax = autocvar_g_chat_flood_lmax;
 920                         flood_field = floodcontrol_chat;
 921                 }
 922                 flood_burst = max(0, flood_burst - 1);
 923                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 924
 925                 // do flood control for the default line size
 926                 if(msgstr != "")
 927                 {
 928                         getWrappedLine_remaining = msgstr;
 929                         msgstr = "";
 930                         lines = 0;
 931                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 932                         {
 933                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 934                                 ++lines;
 935                         }
 936                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 937
 938                         if(getWrappedLine_remaining != "")
 939                         {
 940                                 msgstr = strcat(msgstr, "\n");
 941                                 flood = 2;
 942                         }
 943
 944                         if(time >= source.flood_field)
 945                         {
 946                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 947                         }
 948                         else
 949                         {
 950                                 flood = 1;
 951                                 msgstr = fullmsgstr;
 952                         }
 953                 }
 954                 else
 955                 {
 956                         if(time >= source.flood_field)
 957                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 958                         else
 959                                 flood = 1;
 960                 }
 961
 962                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 963                         source.flood_field = flood = 0;
 964         }
 965
 966         if(flood == 2) // cannot happen for empty msgstr
 967         {
 968                 if(autocvar_g_chat_flood_notify_flooder)
 969                 {
 970                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 971                         sourcecmsgstr = "";
 972                 }
 973                 else
 974                 {
 975                         sourcemsgstr = fullmsgstr;
 976                         sourcecmsgstr = fullcmsgstr;
 977                 }
 978                 cmsgstr = "";
 979         }
 980         else
 981         {
 982                 sourcemsgstr = msgstr;
 983                 sourcecmsgstr = cmsgstr;
 984         }
 985
 986         if(!privatesay)
 987         if(source.classname != "player")
 988         {
 989                 if not(intermission_running)
 990                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 991                                 teamsay = -1; // spectators
 992         }
 993
 994         if(flood)
 995                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 996
 997         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 998         if(privatesay)
 999                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1000
1001         if(source.muted)
1002         {
1003                 // always fake the message
1004                 ret = -1;
1005         }
1006         else if(flood == 1)
1007         {
1008                 if(autocvar_g_chat_flood_notify_flooder)
1009                 {
1010                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1011                         ret = 0;
1012                 }
1013                 else
1014                         ret = -1;
1015         }
1016         else
1017         {
1018                 ret = 1;
1019         }
1020
1021         if(sourcemsgstr != "" && ret != 0)
1022         {
1023                 if(ret < 0) // faked message, because the player is muted
1024                 {
1025                         sprint(source, sourcemsgstr);
1026                         if(sourcecmsgstr != "" && !privatesay)
1027                                 centerprint(source, sourcecmsgstr);
1028                 }
1029                 else if(privatesay) // private message, between 2 people only
1030                 {
1031                         sprint(source, sourcemsgstr);
1032                         sprint(privatesay, msgstr);
1033                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
1034                         if(cmsgstr != "")
1035                                 centerprint(privatesay, cmsgstr);
1036                 }
1037                 else if(teamsay > 0) // team message, only sent to team mates
1038                 {
1039                         sprint(source, sourcemsgstr);
1040                         dedicated_print(msgstr); // send to server console too
1041                         if(sourcecmsgstr != "")
1042                                 centerprint(source, sourcecmsgstr);
1043                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1044                                 if(head != source)
1045                                 {
1046                                         sprint(head, msgstr);
1047                                         if(cmsgstr != "")
1048                                                 centerprint(head, cmsgstr);
1049                                 }
1050                 }
1051                 else if(teamsay < 0) // spectator message, only sent to spectators
1052                 {
1053                         sprint(source, sourcemsgstr);
1054                         dedicated_print(msgstr); // send to server console too
1055                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1056                                 if(head != source)
1057                                         sprint(head, msgstr);
1058                 }
1059                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1060                 {
1061                         sprint(source, sourcemsgstr);
1062                         dedicated_print(msgstr); // send to server console too
1063                         FOR_EACH_REALCLIENT(head)
1064                                 if(head != source)
1065                                         sprint(head, msgstr);
1066                 }
1067                 else
1068                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1069         }
1070
1071         return ret;
1072 }
1073
1074 float GetVoiceMessageVoiceType(string type)
1075 {
1076         if(type == "taunt")
1077                 return VOICETYPE_TAUNT;
1078         if(type == "teamshoot")
1079                 return VOICETYPE_LASTATTACKER;
1080         return VOICETYPE_TEAMRADIO;
1081 }
1082
1083 string allvoicesamples;
1084 .string GetVoiceMessageSampleField(string type)
1085 {
1086         GetPlayerSoundSampleField_notFound = 0;
1087         switch(type)
1088         {
1089 #define _VOICEMSG(m) case #m: return playersound_##m;
1090                 ALLVOICEMSGS
1091 #undef _VOICEMSG
1092         }
1093         GetPlayerSoundSampleField_notFound = 1;
1094         return playersound_taunt;
1095 }
1096
1097 .string GetPlayerSoundSampleField(string type)
1098 {
1099         GetPlayerSoundSampleField_notFound = 0;
1100         switch(type)
1101         {
1102 #define _VOICEMSG(m) case #m: return playersound_##m;
1103                 ALLPLAYERSOUNDS
1104 #undef _VOICEMSG
1105         }
1106         GetPlayerSoundSampleField_notFound = 1;
1107         return playersound_taunt;
1108 }
1109
1110 void PrecacheGlobalSound(string samplestring)
1111 {
1112         float n, i;
1113         tokenize_console(samplestring);
1114         n = stof(argv(1));
1115         if(n > 0)
1116         {
1117                 for(i = 1; i <= n; ++i)
1118                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1119         }
1120         else
1121         {
1122                 precache_sound(strcat(argv(0), ".wav"));
1123         }
1124 }
1125
1126 void PrecachePlayerSounds(string f)
1127 {
1128         float fh;
1129         string s;
1130         fh = fopen(f, FILE_READ);
1131         if(fh < 0)
1132                 return;
1133         while((s = fgets(fh)))
1134         {
1135                 if(tokenize_console(s) != 3)
1136                 {
1137                         dprint("Invalid sound info line: ", s, "\n");
1138                         continue;
1139                 }
1140                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1141         }
1142         fclose(fh);
1143
1144         if not(allvoicesamples)
1145         {
1146 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1147                 ALLVOICEMSGS
1148 #undef _VOICEMSG
1149                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1150         }
1151 }
1152
1153 void ClearPlayerSounds()
1154 {
1155 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1156         ALLPLAYERSOUNDS
1157         ALLVOICEMSGS
1158 #undef _VOICEMSG
1159 }
1160
1161 float LoadPlayerSounds(string f, float first)
1162 {
1163         float fh;
1164         string s;
1165         var .string field;
1166         fh = fopen(f, FILE_READ);
1167         if(fh < 0)
1168         {
1169                 dprint("Player sound file not found: ", f, "\n");
1170                 return 0;
1171         }
1172         while((s = fgets(fh)))
1173         {
1174                 if(tokenize_console(s) != 3)
1175                         continue;
1176                 field = GetPlayerSoundSampleField(argv(0));
1177                 if(GetPlayerSoundSampleField_notFound)
1178                         field = GetVoiceMessageSampleField(argv(0));
1179                 if(GetPlayerSoundSampleField_notFound)
1180                         continue;
1181                 if(self.field)
1182                         strunzone(self.field);
1183                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1184         }
1185         fclose(fh);
1186         return 1;
1187 }
1188
1189 .float modelindex_for_playersound;
1190 .float skin_for_playersound;
1191 void UpdatePlayerSounds()
1192 {
1193         if(self.modelindex == self.modelindex_for_playersound)
1194         if(self.skin == self.skin_for_playersound)
1195                 return;
1196         self.modelindex_for_playersound = self.modelindex;
1197         self.skin_for_playersound = self.skin;
1198         ClearPlayerSounds();
1199         LoadPlayerSounds("sound/player/default.sounds", 1);
1200         if(!autocvar_g_debug_defaultsounds)
1201                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1202                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1203 }
1204
1205 void FakeGlobalSound(string sample, float chan, float voicetype)
1206 {
1207         float n;
1208         float tauntrand;
1209
1210         if(sample == "")
1211                 return;
1212
1213         tokenize_console(sample);
1214         n = stof(argv(1));
1215         if(n > 0)
1216                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1217         else
1218                 sample = strcat(argv(0), ".wav"); // randomization
1219
1220         switch(voicetype)
1221         {
1222                 case VOICETYPE_LASTATTACKER_ONLY:
1223                         break;
1224                 case VOICETYPE_LASTATTACKER:
1225                         if(self.pusher)
1226                         {
1227                                 msg_entity = self;
1228                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1229                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1230                         }
1231                         break;
1232                 case VOICETYPE_TEAMRADIO:
1233                         msg_entity = self;
1234                         if(msg_entity.cvar_cl_voice_directional == 1)
1235                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1236                         else
1237                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1238                         break;
1239                 case VOICETYPE_AUTOTAUNT:
1240                         if(!sv_autotaunt)
1241                                 break;
1242                         if(!sv_taunt)
1243                                 break;
1244                         if(autocvar_sv_gentle)
1245                                 break;
1246                         tauntrand = random();
1247                         msg_entity = self;
1248                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1249                         {
1250                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1251                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1252                                 else
1253                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1254                         }
1255                         break;
1256                 case VOICETYPE_TAUNT:
1257                         if(self.classname == "player")
1258                                 if(self.deadflag == DEAD_NO)
1259                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1260                         if(!sv_taunt)
1261                                 break;
1262                         if(autocvar_sv_gentle)
1263                                 break;
1264                         msg_entity = self;
1265                         if (msg_entity.cvar_cl_voice_directional >= 1)
1266                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1267                         else
1268                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1269                         break;
1270                 case VOICETYPE_PLAYERSOUND:
1271                         msg_entity = self;
1272                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1273                         break;
1274                 default:
1275                         backtrace("Invalid voice type!");
1276                         break;
1277         }
1278 }
1279
1280 void GlobalSound(string sample, float chan, float voicetype)
1281 {
1282         float n;
1283         float tauntrand;
1284
1285         if(sample == "")
1286                 return;
1287
1288         tokenize_console(sample);
1289         n = stof(argv(1));
1290         if(n > 0)
1291                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1292         else
1293                 sample = strcat(argv(0), ".wav"); // randomization
1294
1295         switch(voicetype)
1296         {
1297                 case VOICETYPE_LASTATTACKER_ONLY:
1298                         if(self.pusher)
1299                         {
1300                                 msg_entity = self.pusher;
1301                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1302                                 {
1303                                         if(msg_entity.cvar_cl_voice_directional == 1)
1304                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1305                                         else
1306                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1307                                 }
1308                         }
1309                         break;
1310                 case VOICETYPE_LASTATTACKER:
1311                         if(self.pusher)
1312                         {
1313                                 msg_entity = self.pusher;
1314                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1315                                 {
1316                                         if(msg_entity.cvar_cl_voice_directional == 1)
1317                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1318                                         else
1319                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1320                                 }
1321                                 msg_entity = self;
1322                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1323                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1324                         }
1325                         break;
1326                 case VOICETYPE_TEAMRADIO:
1327                         FOR_EACH_REALCLIENT(msg_entity)
1328                                 if(!teamplay || msg_entity.team == self.team)
1329                                 {
1330                                         if(msg_entity.cvar_cl_voice_directional == 1)
1331                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1332                                         else
1333                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1334                                 }
1335                         break;
1336                 case VOICETYPE_AUTOTAUNT:
1337                         if(!sv_autotaunt)
1338                                 break;
1339                         if(!sv_taunt)
1340                                 break;
1341                         if(autocvar_sv_gentle)
1342                                 break;
1343                         tauntrand = random();
1344                         FOR_EACH_REALCLIENT(msg_entity)
1345                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1346                                 {
1347                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1348                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1349                                         else
1350                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1351                                 }
1352                         break;
1353                 case VOICETYPE_TAUNT:
1354                         if(self.classname == "player")
1355                                 if(self.deadflag == DEAD_NO)
1356                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1357                         if(!sv_taunt)
1358                                 break;
1359                         if(autocvar_sv_gentle)
1360                                 break;
1361                         FOR_EACH_REALCLIENT(msg_entity)
1362                         {
1363                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1364                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1365                                 else
1366                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1367                         }
1368                         break;
1369                 case VOICETYPE_PLAYERSOUND:
1370                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1371                         break;
1372                 default:
1373                         backtrace("Invalid voice type!");
1374                         break;
1375         }
1376 }
1377
1378 void PlayerSound(.string samplefield, float chan, float voicetype)
1379 {
1380         GlobalSound(self.samplefield, chan, voicetype);
1381 }
1382
1383 void VoiceMessage(string type, string msg)
1384 {
1385         var .string sample;
1386         float voicetype, ownteam;
1387         float flood;
1388         sample = GetVoiceMessageSampleField(type);
1389
1390         if(GetPlayerSoundSampleField_notFound)
1391         {
1392                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1393                 return;
1394         }
1395
1396         voicetype = GetVoiceMessageVoiceType(type);
1397         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1398
1399         flood = Say(self, ownteam, world, msg, 1);
1400
1401         if (flood > 0)
1402                 GlobalSound(self.sample, CH_VOICE, voicetype);
1403         else if (flood < 0)
1404                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1405 }
1406
1407 void MoveToTeam(entity client, float team_colour, float type)
1408 {
1409         float lockteams_backup;
1410
1411         lockteams_backup = lockteams;  // backup any team lock
1412
1413         lockteams = 0;  // disable locked teams
1414
1415         TeamchangeFrags(client);  // move the players frags
1416         SetPlayerColors(client, team_colour - 1);  // set the players colour
1417         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1418
1419         lockteams = lockteams_backup;  // restore the team lock
1420
1421         LogTeamchange(client.playerid, client.team, type);
1422 }