qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_minstagib)
 266         if(self.ammo_cells <= 0)
 267                 return;
 268
 269         if(g_pinata)
 270         {
 271                 float j;
 272                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 273                 {
 274                         if(WEPSET_CONTAINS_EW(self, j))
 275                                 if(W_IsWeaponThrowable(j))
 276                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 277                 }
 278         }
 279         else
 280         {
 281                 if(W_IsWeaponThrowable(self.weapon))
 282                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 283         }
 284 }
 285
 286 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 287 {
 288         float take, save;
 289         vector v;
 290         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 291
 292         // damage resistance (ignore most of the damage from a bullet or similar)
 293         damage = max(damage - 5, 1);
 294
 295         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 296         take = v_x;
 297         save = v_y;
 298
 299         if(sound_allowed(MSG_BROADCAST, attacker))
 300         {
 301                 if (save > 10)
 302                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 303                 else if (take > 30)
 304                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 305                 else if (take > 10)
 306                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 307         }
 308
 309         if (take > 50)
 310                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 311         if (take > 100)
 312                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 313
 314         if (!(self.flags & FL_GODMODE))
 315         {
 316                 self.armorvalue = self.armorvalue - save;
 317                 self.health = self.health - take;
 318                 // pause regeneration for 5 seconds
 319                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 320         }
 321         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 322         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 323         self.dmg_inflictor = inflictor;
 324
 325         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 326         {
 327                 // don't use any animations as a gib
 328                 self.frame = 0;
 329                 // view just above the floor
 330                 self.view_ofs = '0 0 4';
 331
 332                 Violence_GibSplash(self, 1, 1, attacker);
 333                 self.alpha = -1;
 334                 self.solid = SOLID_NOT; // restore later
 335                 self.takedamage = DAMAGE_NO; // restore later
 336                 self.damagedbycontents = FALSE;
 337         }
 338 }
 339
 340 void ClientKill_Now_TeamChange();
 341 void freezetag_CheckWinner();
 342
 343 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 344 {
 345         float take, save, waves, sdelay, dh, da, j;
 346         vector v;
 347         float valid_damage_for_weaponstats;
 348         float excess;
 349
 350         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 351                 return;
 352
 353         dh = max(self.health, 0);
 354         da = max(self.armorvalue, 0);
 355
 356         if(!DEATH_ISSPECIAL(deathtype))
 357         {
 358                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 359                 if(self != attacker)
 360                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 361         }
 362
 363         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 364         {
 365                 // tuba causes blood to come out of the ears
 366                 vector ear1, ear2;
 367                 vector d;
 368                 float f;
 369                 ear1 = self.origin;
 370                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 371                 ear2 = ear1;
 372                 makevectors(self.angles);
 373                 ear1 += v_right * -10;
 374                 ear2 += v_right * +10;
 375                 d = inflictor.origin - self.origin;
 376                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 377                 force = v_right * vlen(force);
 378                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 379                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 380                 if(f > 0)
 381                 {
 382                         hitloc = ear1;
 383                         force = force * -1;
 384                 }
 385                 else
 386                 {
 387                         hitloc = ear2;
 388                         // force is already good
 389                 }
 390         }
 391         else
 392                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 393
 394         if (!g_minstagib)
 395         {
 396                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 397                 take = v_x;
 398                 save = v_y;
 399         }
 400         else
 401         {
 402                 save = 0;
 403                 take = damage;
 404         }
 405
 406         if(attacker == self)
 407         {
 408                 // don't reset pushltime for self damage as it may be an attempt to
 409                 // escape a lava pit or similar
 410                 //self.pushltime = 0;
 411                 self.istypefrag = 0;
 412         }
 413         else if(attacker.classname == "player")
 414         {
 415                 self.pusher = attacker;
 416                 self.pushltime = time + autocvar_g_maxpushtime;
 417                 self.istypefrag = self.BUTTON_CHAT;
 418         }
 419         else if(time < self.pushltime)
 420         {
 421                 attacker = self.pusher;
 422                 self.pushltime = max(self.pushltime, time + 0.6);
 423         }
 424         else
 425         {
 426                 self.pushltime = 0;
 427                 self.istypefrag = 0;
 428         }
 429
 430         frag_inflictor = inflictor;
 431         frag_attacker = attacker;
 432         frag_target = self;
 433         damage_take = take;
 434         damage_save = save;
 435         damage_force = force;
 436         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 437         take = bound(0, damage_take, self.health);
 438         save = bound(0, damage_save, self.armorvalue);
 439         excess = max(0, damage - take - save);
 440
 441         if(sound_allowed(MSG_BROADCAST, attacker))
 442         {
 443                 if (save > 10)
 444                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 445                 else if (take > 30)
 446                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 447                 else if (take > 10)
 448                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 449         }
 450
 451         if (take > 50)
 452                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 453         if (take > 100)
 454                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 455
 456         if (time >= self.spawnshieldtime)
 457         {
 458                 if (!(self.flags & FL_GODMODE))
 459                 {
 460                         self.armorvalue = self.armorvalue - save;
 461                         self.health = self.health - take;
 462                         // pause regeneration for 5 seconds
 463                         if(take)
 464                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 465
 466                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 467                         {
 468                                 self.pain_finished = time + 0.5;        //Supajoe
 469
 470                                 if(autocvar_sv_gentle < 1) {
 471                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 472                                         {
 473                                                 if (!self.animstate_override)
 474                                                 {
 475                                                         if (random() > 0.5)
 476                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 477                                                         else
 478                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 479                                                 }
 480                                         }
 481
 482                                         if(sound_allowed(MSG_BROADCAST, attacker))
 483                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 484                                         if(self.health > 1)
 485                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 486                                         {
 487                                                 if(deathtype == DEATH_FALL)
 488                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 489                                                 else if(self.health > 75) // TODO make a "gentle" version?
 490                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 491                                                 else if(self.health > 50)
 492                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 493                                                 else if(self.health > 25)
 494                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 495                                                 else
 496                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 497                                         }
 498                                 }
 499
 500                                 // throw off bot aim temporarily
 501                                 float shake;
 502                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 503                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 504                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 505                         }
 506                 }
 507                 else
 508                         self.max_armorvalue += (save + take);
 509         }
 510         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 511         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 512         self.dmg_inflictor = inflictor;
 513
 514         if(g_ca && self != attacker && attacker.classname == "player")
 515                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 516
 517         float abot, vbot, awep;
 518         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 519         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 520
 521         valid_damage_for_weaponstats = 0;
 522         awep = 0;
 523
 524         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 525         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 526         if(attacker && self != attacker)
 527         if(IsDifferentTeam(self, attacker))
 528         {
 529                 if(DEATH_ISSPECIAL(deathtype))
 530                         awep = attacker.weapon;
 531                 else
 532                         awep = DEATH_WEAPONOF(deathtype);
 533                 valid_damage_for_weaponstats = 1;
 534         }
 535
 536         if(valid_damage_for_weaponstats)
 537         {
 538                 dh = dh - max(self.health, 0);
 539                 da = da - max(self.armorvalue, 0);
 540                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 541         }
 542
 543         if (self.health < 1)
 544         {
 545                 float defer_ClientKill_Now_TeamChange;
 546                 defer_ClientKill_Now_TeamChange = FALSE;
 547
 548                 if(self.alivetime)
 549                 {
 550                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 551                         self.alivetime = 0;
 552                 }
 553
 554                 if(valid_damage_for_weaponstats)
 555                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 556
 557                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 558                 if(sound_allowed(MSG_BROADCAST, attacker))
 559                 {
 560                         if(deathtype == DEATH_DROWN)
 561                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 562                         else
 563                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 564                 }
 565
 566                 // get rid of kill indicator
 567                 if(self.killindicator)
 568                 {
 569                         remove(self.killindicator);
 570                         self.killindicator = world;
 571                         if(self.killindicator_teamchange)
 572                                 defer_ClientKill_Now_TeamChange = TRUE;
 573
 574                         if(self.classname == "body")
 575                         if(deathtype == DEATH_KILL)
 576                         {
 577                                 // for the lemmings fans, a small harmless explosion
 578                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 579                         }
 580                 }
 581
 582                 if(!g_freezetag)
 583                 {
 584                         // become fully visible
 585                         self.alpha = default_player_alpha;
 586                         // throw a weapon
 587                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 588                 }
 589
 590                 // print an obituary message
 591                 Obituary (attacker, inflictor, self, deathtype);
 592                 race_PreDie();
 593
 594         // increment frag counter for used weapon type
 595         float w;
 596         w = DEATH_WEAPONOF(deathtype);
 597         if(WEP_VALID(w))
 598         if(accuracy_isgooddamage(attacker, self))
 599         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 600
 601                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 602                 {
 603                         PutClientInServer();
 604                         count_alive_players(); // re-count players
 605                         freezetag_CheckWinner();
 606                         return;
 607                 }
 608
 609                 frag_attacker = attacker;
 610                 frag_inflictor = inflictor;
 611                 frag_target = self;
 612                 MUTATOR_CALLHOOK(PlayerDies);
 613                 weapon_action(self.weapon, WR_PLAYERDEATH);
 614
 615                 RemoveGrapplingHook(self);
 616
 617                 Portal_ClearAllLater(self);
 618
 619                 if(clienttype(self) == CLIENTTYPE_REAL)
 620                 {
 621                         self.fixangle = TRUE;
 622                         //msg_entity = self;
 623                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 624                         //WriteAngle (MSG_ONE, self.v_angle_x);
 625                         //WriteAngle (MSG_ONE, self.v_angle_y);
 626                         //WriteAngle (MSG_ONE, 80);
 627                 }
 628
 629                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 630                         ClientKill_Now_TeamChange();
 631
 632                 if(g_arena)
 633                         Spawnqueue_Unmark(self);
 634
 635                 if(g_freezetag)
 636                         return;
 637
 638                 // when we get here, player actually dies
 639                 // clear waypoints (do this AFTER FreezeTag)
 640                 WaypointSprite_PlayerDead();
 641
 642                 // make the corpse upright (not tilted)
 643                 self.angles_x = 0;
 644                 self.angles_z = 0;
 645                 // don't spin
 646                 self.avelocity = '0 0 0';
 647                 // view from the floor
 648                 self.view_ofs = '0 0 -8';
 649                 // toss the corpse
 650                 self.movetype = MOVETYPE_TOSS;
 651                 // shootable corpse
 652                 self.solid = SOLID_CORPSE;
 653                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 654                 // don't stick to the floor
 655                 self.flags &~= FL_ONGROUND;
 656                 // dying animation
 657                 self.deadflag = DEAD_DYING;
 658                 // when to allow respawn
 659                 sdelay = 0;
 660                 waves = 0;
 661                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 662                 if(!sdelay)
 663                 {
 664                         if(g_cts)
 665                                 sdelay = 0; // no respawn delay in CTS
 666                         else
 667                                 sdelay = autocvar_g_respawn_delay;
 668                 }
 669                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 670                 if(!waves)
 671                         waves = autocvar_g_respawn_waves;
 672                 if(waves)
 673                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 674                 else
 675                         self.respawn_time = time + sdelay;
 676                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 677                         self.respawn_countdown = 10; // first number to count down from is 10
 678                 else
 679                         self.respawn_countdown = -1; // do not count down
 680                 self.death_time = time;
 681                 if (random() < 0.5)
 682                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 683                 else
 684                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 685                 if (self.maxs_z > 5)
 686                 {
 687                         self.maxs_z = 5;
 688                         setsize(self, self.mins, self.maxs);
 689                 }
 690                 // set damage function to corpse damage
 691                 self.event_damage = PlayerCorpseDamage;
 692                 // call the corpse damage function just in case it wants to gib
 693                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 694                 // set up to fade out later
 695                 SUB_SetFade (self, time + 6 + random (), 1);
 696
 697                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 698                         // remove corpse
 699                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 700                 }
 701
 702                 // reset fields the weapons may use just in case
 703                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 704                 {
 705                         weapon_action(j, WR_RESETPLAYER);
 706                         ATTACK_FINISHED_FOR(self, j) = 0;
 707                 }
 708         }
 709 }
 710
 711 .float muted; // to be used by prvm_edictset server playernumber muted 1
 712 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 713 // message "": do not say, just test flood control
 714 // return value:
 715 //   1 = accept
 716 //   0 = reject
 717 //  -1 = fake accept
 718 {
 719         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 720         float flood;
 721         var .float flood_field;
 722         entity head;
 723         float ret;
 724         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 725
 726         if(!teamsay && !privatesay)
 727                 if(substring(msgin, 0, 1) == " ")
 728                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 729
 730         msgin = formatmessage(msgin);
 731
 732         if(source.classname != "player")
 733                 colorstr = "^0"; // black for spectators
 734         else if(teamplay)
 735                 colorstr = Team_ColorCode(source.team);
 736         else
 737         {
 738                 colorstr = "";
 739                 teamsay = FALSE;
 740         }
 741
 742         if(intermission_running)
 743                 teamsay = FALSE;
 744
 745         if(msgin != "")
 746                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 747
 748         /*
 749          * using bprint solves this... me stupid
 750         // how can we prevent the message from appearing in a listen server?
 751         // for now, just give "say" back and only handle say_team
 752         if(!teamsay)
 753         {
 754                 clientcommand(self, strcat("say ", msgin));
 755                 return;
 756         }
 757         */
 758
 759         if(autocvar_g_chat_teamcolors)
 760                 namestr = playername(source);
 761         else
 762                 namestr = source.netname;
 763
 764         if(msgin != "")
 765         {
 766                 if(privatesay)
 767                 {
 768                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 769                         privatemsgprefixlen = strlen(msgstr);
 770                         msgstr = strcat(msgstr, msgin);
 771                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 772                         if(autocvar_g_chat_teamcolors)
 773                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 774                         else
 775                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 776                 }
 777                 else if(teamsay)
 778                 {
 779                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 780                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 781                 }
 782                 else
 783                 {
 784                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 785                         cmsgstr = "";
 786                 }
 787                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 788         }
 789         else
 790         {
 791                 msgstr = cmsgstr = "";
 792         }
 793
 794         fullmsgstr = msgstr;
 795         fullcmsgstr = cmsgstr;
 796
 797         // FLOOD CONTROL
 798         flood = 0;
 799         flood_field = floodcontrol_chat;
 800         if(floodcontrol)
 801         {
 802                 float flood_spl;
 803                 float flood_burst;
 804                 float flood_lmax;
 805                 float lines;
 806                 if(privatesay)
 807                 {
 808                         flood_spl = autocvar_g_chat_flood_spl_tell;
 809                         flood_burst = autocvar_g_chat_flood_burst_tell;
 810                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 811                         flood_field = floodcontrol_chattell;
 812                 }
 813                 else if(teamsay)
 814                 {
 815                         flood_spl = autocvar_g_chat_flood_spl_team;
 816                         flood_burst = autocvar_g_chat_flood_burst_team;
 817                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 818                         flood_field = floodcontrol_chatteam;
 819                 }
 820                 else
 821                 {
 822                         flood_spl = autocvar_g_chat_flood_spl;
 823                         flood_burst = autocvar_g_chat_flood_burst;
 824                         flood_lmax = autocvar_g_chat_flood_lmax;
 825                         flood_field = floodcontrol_chat;
 826                 }
 827                 flood_burst = max(0, flood_burst - 1);
 828                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 829
 830                 // do flood control for the default line size
 831                 if(msgstr != "")
 832                 {
 833                         getWrappedLine_remaining = msgstr;
 834                         msgstr = "";
 835                         lines = 0;
 836                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 837                         {
 838                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 839                                 ++lines;
 840                         }
 841                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 842
 843                         if(getWrappedLine_remaining != "")
 844                         {
 845                                 msgstr = strcat(msgstr, "\n");
 846                                 flood = 2;
 847                         }
 848
 849                         if(time >= source.flood_field)
 850                         {
 851                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 852                         }
 853                         else
 854                         {
 855                                 flood = 1;
 856                                 msgstr = fullmsgstr;
 857                         }
 858                 }
 859                 else
 860                 {
 861                         if(time >= source.flood_field)
 862                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 863                         else
 864                                 flood = 1;
 865                 }
 866
 867                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 868                         source.flood_field = flood = 0;
 869         }
 870
 871         if(flood == 2) // cannot happen for empty msgstr
 872         {
 873                 if(autocvar_g_chat_flood_notify_flooder)
 874                 {
 875                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 876                         sourcecmsgstr = "";
 877                 }
 878                 else
 879                 {
 880                         sourcemsgstr = fullmsgstr;
 881                         sourcecmsgstr = fullcmsgstr;
 882                 }
 883                 cmsgstr = "";
 884         }
 885         else
 886         {
 887                 sourcemsgstr = msgstr;
 888                 sourcecmsgstr = cmsgstr;
 889         }
 890
 891         if(!privatesay)
 892         if(source.classname != "player")
 893         {
 894                 if not(intermission_running)
 895                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 896                                 teamsay = -1; // spectators
 897         }
 898
 899         if(flood)
 900                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 901
 902         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 903         if(privatesay)
 904                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 905
 906         if(source.muted)
 907         {
 908                 // always fake the message
 909                 ret = -1;
 910         }
 911         else if(flood == 1)
 912         {
 913                 if(autocvar_g_chat_flood_notify_flooder)
 914                 {
 915                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 916                         ret = 0;
 917                 }
 918                 else
 919                         ret = -1;
 920         }
 921         else
 922         {
 923                 ret = 1;
 924         }
 925
 926         if(sourcemsgstr != "" && ret != 0)
 927         {
 928                 if(ret < 0) // faked message, because the player is muted
 929                 {
 930                         sprint(source, sourcemsgstr);
 931                         if(sourcecmsgstr != "" && !privatesay)
 932                                 centerprint(source, sourcecmsgstr);
 933                 }
 934                 else if(privatesay) // private message, between 2 people only
 935                 {
 936                         sprint(source, sourcemsgstr);
 937                         sprint(privatesay, msgstr);
 938                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 939                         if(cmsgstr != "")
 940                                 centerprint(privatesay, cmsgstr);
 941                 }
 942                 else if(teamsay > 0) // team message, only sent to team mates
 943                 {
 944                         sprint(source, sourcemsgstr);
 945                         dedicated_print(msgstr); // send to server console too
 946                         if(sourcecmsgstr != "")
 947                                 centerprint(source, sourcecmsgstr);
 948                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 949                                 if(head != source)
 950                                 {
 951                                         sprint(head, msgstr);
 952                                         if(cmsgstr != "")
 953                                                 centerprint(head, cmsgstr);
 954                                 }
 955                 }
 956                 else if(teamsay < 0) // spectator message, only sent to spectators
 957                 {
 958                         sprint(source, sourcemsgstr);
 959                         dedicated_print(msgstr); // send to server console too
 960                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 961                                 if(head != source)
 962                                         sprint(head, msgstr);
 963                 }
 964                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 965                 {
 966                         sprint(source, sourcemsgstr);
 967                         dedicated_print(msgstr); // send to server console too
 968                         FOR_EACH_REALCLIENT(head)
 969                                 if(head != source)
 970                                         sprint(head, msgstr);
 971                 }
 972                 else
 973                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 974         }
 975
 976         return ret;
 977 }
 978
 979 float GetVoiceMessageVoiceType(string type)
 980 {
 981         if(type == "taunt")
 982                 return VOICETYPE_TAUNT;
 983         if(type == "teamshoot")
 984                 return VOICETYPE_LASTATTACKER;
 985         return VOICETYPE_TEAMRADIO;
 986 }
 987
 988 string allvoicesamples;
 989 .string GetVoiceMessageSampleField(string type)
 990 {
 991         GetPlayerSoundSampleField_notFound = 0;
 992         switch(type)
 993         {
 994 #define _VOICEMSG(m) case #m: return playersound_##m;
 995                 ALLVOICEMSGS
 996 #undef _VOICEMSG
 997         }
 998         GetPlayerSoundSampleField_notFound = 1;
 999         return playersound_taunt;
1000 }
1001
1002 .string GetPlayerSoundSampleField(string type)
1003 {
1004         GetPlayerSoundSampleField_notFound = 0;
1005         switch(type)
1006         {
1007 #define _VOICEMSG(m) case #m: return playersound_##m;
1008                 ALLPLAYERSOUNDS
1009 #undef _VOICEMSG
1010         }
1011         GetPlayerSoundSampleField_notFound = 1;
1012         return playersound_taunt;
1013 }
1014
1015 void PrecacheGlobalSound(string samplestring)
1016 {
1017         float n, i;
1018         tokenize_console(samplestring);
1019         n = stof(argv(1));
1020         if(n > 0)
1021         {
1022                 for(i = 1; i <= n; ++i)
1023                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1024         }
1025         else
1026         {
1027                 precache_sound(strcat(argv(0), ".wav"));
1028         }
1029 }
1030
1031 void PrecachePlayerSounds(string f)
1032 {
1033         float fh;
1034         string s;
1035         fh = fopen(f, FILE_READ);
1036         if(fh < 0)
1037                 return;
1038         while((s = fgets(fh)))
1039         {
1040                 if(tokenize_console(s) != 3)
1041                 {
1042                         dprint("Invalid sound info line: ", s, "\n");
1043                         continue;
1044                 }
1045                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1046         }
1047         fclose(fh);
1048
1049         if not(allvoicesamples)
1050         {
1051 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1052                 ALLVOICEMSGS
1053 #undef _VOICEMSG
1054                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1055         }
1056 }
1057
1058 void ClearPlayerSounds()
1059 {
1060 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1061         ALLPLAYERSOUNDS
1062         ALLVOICEMSGS
1063 #undef _VOICEMSG
1064 }
1065
1066 float LoadPlayerSounds(string f, float first)
1067 {
1068         float fh;
1069         string s;
1070         var .string field;
1071         fh = fopen(f, FILE_READ);
1072         if(fh < 0)
1073         {
1074                 dprint("Player sound file not found: ", f, "\n");
1075                 return 0;
1076         }
1077         while((s = fgets(fh)))
1078         {
1079                 if(tokenize_console(s) != 3)
1080                         continue;
1081                 field = GetPlayerSoundSampleField(argv(0));
1082                 if(GetPlayerSoundSampleField_notFound)
1083                         field = GetVoiceMessageSampleField(argv(0));
1084                 if(GetPlayerSoundSampleField_notFound)
1085                         continue;
1086                 if(self.field)
1087                         strunzone(self.field);
1088                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1089         }
1090         fclose(fh);
1091         return 1;
1092 }
1093
1094 .float modelindex_for_playersound;
1095 .float skin_for_playersound;
1096 void UpdatePlayerSounds()
1097 {
1098         if(self.modelindex == self.modelindex_for_playersound)
1099         if(self.skin == self.skin_for_playersound)
1100                 return;
1101         self.modelindex_for_playersound = self.modelindex;
1102         self.skin_for_playersound = self.skin;
1103         ClearPlayerSounds();
1104         LoadPlayerSounds("sound/player/default.sounds", 1);
1105         if(!autocvar_g_debug_defaultsounds)
1106                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1107                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1108 }
1109
1110 void FakeGlobalSound(string sample, float chan, float voicetype)
1111 {
1112         float n;
1113         float tauntrand;
1114
1115         if(sample == "")
1116                 return;
1117
1118         tokenize_console(sample);
1119         n = stof(argv(1));
1120         if(n > 0)
1121                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1122         else
1123                 sample = strcat(argv(0), ".wav"); // randomization
1124
1125         switch(voicetype)
1126         {
1127                 case VOICETYPE_LASTATTACKER_ONLY:
1128                         break;
1129                 case VOICETYPE_LASTATTACKER:
1130                         if(self.pusher)
1131                         {
1132                                 msg_entity = self;
1133                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1134                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1135                         }
1136                         break;
1137                 case VOICETYPE_TEAMRADIO:
1138                         msg_entity = self;
1139                         if(msg_entity.cvar_cl_voice_directional == 1)
1140                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1141                         else
1142                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1143                         break;
1144                 case VOICETYPE_AUTOTAUNT:
1145                         if(!sv_autotaunt)
1146                                 break;
1147                         if(!sv_taunt)
1148                                 break;
1149                         if(autocvar_sv_gentle)
1150                                 break;
1151                         tauntrand = random();
1152                         msg_entity = self;
1153                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1154                         {
1155                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1156                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1157                                 else
1158                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1159                         }
1160                         break;
1161                 case VOICETYPE_TAUNT:
1162                         if(self.classname == "player")
1163                                 if(self.deadflag == DEAD_NO)
1164                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1165                         if(!sv_taunt)
1166                                 break;
1167                         if(autocvar_sv_gentle)
1168                                 break;
1169                         msg_entity = self;
1170                         if (msg_entity.cvar_cl_voice_directional >= 1)
1171                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1172                         else
1173                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1174                         break;
1175                 case VOICETYPE_PLAYERSOUND:
1176                         msg_entity = self;
1177                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1178                         break;
1179                 default:
1180                         backtrace("Invalid voice type!");
1181                         break;
1182         }
1183 }
1184
1185 void GlobalSound(string sample, float chan, float voicetype)
1186 {
1187         float n;
1188         float tauntrand;
1189
1190         if(sample == "")
1191                 return;
1192
1193         tokenize_console(sample);
1194         n = stof(argv(1));
1195         if(n > 0)
1196                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1197         else
1198                 sample = strcat(argv(0), ".wav"); // randomization
1199
1200         switch(voicetype)
1201         {
1202                 case VOICETYPE_LASTATTACKER_ONLY:
1203                         if(self.pusher)
1204                         {
1205                                 msg_entity = self.pusher;
1206                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1207                                 {
1208                                         if(msg_entity.cvar_cl_voice_directional == 1)
1209                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1210                                         else
1211                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1212                                 }
1213                         }
1214                         break;
1215                 case VOICETYPE_LASTATTACKER:
1216                         if(self.pusher)
1217                         {
1218                                 msg_entity = self.pusher;
1219                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1220                                 {
1221                                         if(msg_entity.cvar_cl_voice_directional == 1)
1222                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1223                                         else
1224                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1225                                 }
1226                                 msg_entity = self;
1227                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1228                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1229                         }
1230                         break;
1231                 case VOICETYPE_TEAMRADIO:
1232                         FOR_EACH_REALCLIENT(msg_entity)
1233                                 if(!teamplay || msg_entity.team == self.team)
1234                                 {
1235                                         if(msg_entity.cvar_cl_voice_directional == 1)
1236                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1237                                         else
1238                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1239                                 }
1240                         break;
1241                 case VOICETYPE_AUTOTAUNT:
1242                         if(!sv_autotaunt)
1243                                 break;
1244                         if(!sv_taunt)
1245                                 break;
1246                         if(autocvar_sv_gentle)
1247                                 break;
1248                         tauntrand = random();
1249                         FOR_EACH_REALCLIENT(msg_entity)
1250                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1251                                 {
1252                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1253                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1254                                         else
1255                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1256                                 }
1257                         break;
1258                 case VOICETYPE_TAUNT:
1259                         if(self.classname == "player")
1260                                 if(self.deadflag == DEAD_NO)
1261                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1262                         if(!sv_taunt)
1263                                 break;
1264                         if(autocvar_sv_gentle)
1265                                 break;
1266                         FOR_EACH_REALCLIENT(msg_entity)
1267                         {
1268                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1269                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1270                                 else
1271                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1272                         }
1273                         break;
1274                 case VOICETYPE_PLAYERSOUND:
1275                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1276                         break;
1277                 default:
1278                         backtrace("Invalid voice type!");
1279                         break;
1280         }
1281 }
1282
1283 void PlayerSound(.string samplefield, float chan, float voicetype)
1284 {
1285         GlobalSound(self.samplefield, chan, voicetype);
1286 }
1287
1288 void VoiceMessage(string type, string msg)
1289 {
1290         var .string sample;
1291         float voicetype, ownteam;
1292         float flood;
1293         sample = GetVoiceMessageSampleField(type);
1294
1295         if(GetPlayerSoundSampleField_notFound)
1296         {
1297                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1298                 return;
1299         }
1300
1301         voicetype = GetVoiceMessageVoiceType(type);
1302         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1303
1304         flood = Say(self, ownteam, world, msg, 1);
1305
1306         if (flood > 0)
1307                 GlobalSound(self.sample, CH_VOICE, voicetype);
1308         else if (flood < 0)
1309                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1310 }
1311
1312 void MoveToTeam(entity client, float team_colour, float type)
1313 {
1314         float lockteams_backup;
1315
1316         lockteams_backup = lockteams;  // backup any team lock
1317
1318         lockteams = 0;  // disable locked teams
1319
1320         TeamchangeFrags(client);  // move the players frags
1321         SetPlayerColors(client, team_colour - 1);  // set the players colour
1322         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1323
1324         lockteams = lockteams_backup;  // restore the team lock
1325
1326         LogTeamchange(client.playerid, client.team, type);
1327 }