qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, ibot, jbot, idx;
  16         float fh;
  17         vector v;
  18         string prefix;
  19         if(weaponstats_buffer < 0)
  20                 return;
  21         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  22         if(autocvar_sv_weaponstats_file != "")
  23         {
  24                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  25                 if(fh >= 0)
  26                 {
  27                         fputs(fh, "#begin statsfile\n");
  28                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  29                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  30                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  31                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  32                                 {
  33                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  34                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  35                                         if(v != '0 0 0')
  36                                         {
  37                                                 //vector is: kills hits damage
  38                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  39                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  40                                         }
  41                                 }
  42                         fputs(fh, "#end\n\n");
  43                         fclose(fh);
  44                         print("Weapon stats written\n");
  45                 }
  46         }
  47         buf_del(weaponstats_buffer);
  48         weaponstats_buffer = -1;
  49 }
  50
  51 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  52 {
  53         float idx;
  54         if(weaponstats_buffer < 0)
  55                 return;
  56         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  57                 return;
  58         if(awep > WEP_LAST || vwep > WEP_LAST)
  59                 return;
  60         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  61         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  62 }
  63 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  64 {
  65         if(damage < 0)
  66                 error("negative damage?");
  67         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  68 }
  69 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  70 {
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  72 }
  73
  74 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  75 // merged player_run and player_stand to player_anim
  76 // added death animations to player_anim
  77 // can now spawn thrown weapons from anywhere, not just from players
  78 // thrown weapons now fade out after 20 seconds
  79 // created PlayerGib function
  80 // PlayerDie no longer uses hitloc or damage
  81 // PlayerDie now supports dying animations as well as gibbing
  82 // cleaned up PlayerDie a lot
  83 // added CopyBody
  84
  85 .entity pusher;
  86 .float pushltime;
  87
  88 void CopyBody(float keepvelocity)
  89 {
  90         local entity oldself;
  91         if (self.effects & EF_NODRAW)
  92                 return;
  93         oldself = self;
  94         self = spawn();
  95         self.enemy = oldself;
  96         self.lip = oldself.lip;
  97         self.colormap = oldself.colormap;
  98         self.glowmod = oldself.glowmod;
  99         self.iscreature = oldself.iscreature;
 100         self.angles = oldself.angles;
 101         self.avelocity = oldself.avelocity;
 102         self.classname = "body";
 103         self.damageforcescale = oldself.damageforcescale;
 104         self.effects = oldself.effects;
 105         self.event_damage = oldself.event_damage;
 106         self.animstate_startframe = oldself.animstate_startframe;
 107         self.animstate_numframes = oldself.animstate_numframes;
 108         self.animstate_framerate = oldself.animstate_framerate;
 109         self.animstate_starttime = oldself.animstate_starttime;
 110         self.animstate_endtime = oldself.animstate_endtime;
 111         self.animstate_override = oldself.animstate_override;
 112         self.animstate_looping = oldself.animstate_looping;
 113         self.frame = oldself.frame;
 114         self.dead_frame = oldself.dead_frame;
 115         self.pain_finished = oldself.pain_finished;
 116         self.health = oldself.health;
 117         self.armorvalue = oldself.armorvalue;
 118         self.armortype = oldself.armortype;
 119         self.model = oldself.model;
 120         self.modelindex = oldself.modelindex;
 121         self.modelindex_lod0 = oldself.modelindex_lod0;
 122         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 123         self.modelindex_lod1 = oldself.modelindex_lod1;
 124         self.modelindex_lod2 = oldself.modelindex_lod2;
 125         self.skinindex = oldself.skinindex;
 126         self.species = oldself.species;
 127         self.movetype = oldself.movetype;
 128         self.nextthink = oldself.nextthink;
 129         self.solid = oldself.solid;
 130         self.ballistics_density = oldself.ballistics_density;
 131         self.takedamage = oldself.takedamage;
 132         self.think = oldself.think;
 133         self.customizeentityforclient = oldself.customizeentityforclient;
 134         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 135         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 136         if (keepvelocity == 1)
 137                 self.velocity = oldself.velocity;
 138         self.oldvelocity = self.velocity;
 139         self.fade_time = oldself.fade_time;
 140         self.fade_rate = oldself.fade_rate;
 141         //self.weapon = oldself.weapon;
 142         setorigin(self, oldself.origin);
 143         setsize(self, oldself.mins, oldself.maxs);
 144         self.prevorigin = oldself.origin;
 145         self.reset = SUB_Remove;
 146
 147         Drag_MoveDrag(oldself, self);
 148
 149         Violence_DamageEffect_Copy(oldself, self);
 150
 151         self = oldself;
 152 }
 153
 154 float player_getspecies()
 155 {
 156         float s;
 157         get_model_parameters(self.model, self.skinindex);
 158         s = get_model_parameters_species;
 159         get_model_parameters(string_null, 0);
 160         if(s < 0)
 161                 return SPECIES_HUMAN;
 162         return s;
 163 }
 164
 165 void player_setupanimsformodel()
 166 {
 167         local string animfilename;
 168         local float animfile;
 169         // defaults for legacy .zym models without animinfo files
 170         self.anim_die1 = '0 1 0.5'; // 2 seconds
 171         self.anim_die2 = '1 1 0.5'; // 2 seconds
 172         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 173         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 174         self.anim_duckwalk = '4 1 1';
 175         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 176         self.anim_duckidle = '6 1 1';
 177         self.anim_idle = '7 1 1';
 178         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 179         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 180         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 181         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 182         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 183         self.anim_run = '13 1 1';
 184         self.anim_runbackwards = '14 1 1';
 185         self.anim_strafeleft = '15 1 1';
 186         self.anim_straferight = '16 1 1';
 187         self.anim_dead1 = '17 1 1';
 188         self.anim_dead2 = '18 1 1';
 189         self.anim_forwardright = '19 1 1';
 190         self.anim_forwardleft = '20 1 1';
 191         self.anim_backright = '21 1 1';
 192         self.anim_backleft  = '22 1 1';
 193         animparseerror = FALSE;
 194         animfilename = strcat(self.model, ".animinfo");
 195         animfile = fopen(animfilename, FILE_READ);
 196         if (animfile >= 0)
 197         {
 198                 self.anim_die1         = animparseline(animfile);
 199                 self.anim_die2         = animparseline(animfile);
 200                 self.anim_draw         = animparseline(animfile);
 201                 self.anim_duck         = animparseline(animfile);
 202                 self.anim_duckwalk     = animparseline(animfile);
 203                 self.anim_duckjump     = animparseline(animfile);
 204                 self.anim_duckidle     = animparseline(animfile);
 205                 self.anim_idle         = animparseline(animfile);
 206                 self.anim_jump         = animparseline(animfile);
 207                 self.anim_pain1        = animparseline(animfile);
 208                 self.anim_pain2        = animparseline(animfile);
 209                 self.anim_shoot        = animparseline(animfile);
 210                 self.anim_taunt        = animparseline(animfile);
 211                 self.anim_run          = animparseline(animfile);
 212                 self.anim_runbackwards = animparseline(animfile);
 213                 self.anim_strafeleft   = animparseline(animfile);
 214                 self.anim_straferight  = animparseline(animfile);
 215                 self.anim_forwardright = animparseline(animfile);
 216                 self.anim_forwardleft  = animparseline(animfile);
 217                 self.anim_backright    = animparseline(animfile);
 218                 self.anim_backleft     = animparseline(animfile);
 219                 fclose(animfile);
 220
 221                 // derived anims
 222                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 223                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 224
 225                 if (animparseerror)
 226                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 227         }
 228         else
 229                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 230         // reset animstate now
 231         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 232 };
 233
 234 void player_anim (void)
 235 {
 236         updateanim(self);
 237         if (self.weaponentity)
 238                 updateanim(self.weaponentity);
 239
 240         if (self.deadflag != DEAD_NO)
 241         {
 242                 if (time > self.animstate_endtime)
 243                 {
 244                         if (self.maxs_z > 5)
 245                         {
 246                                 self.maxs_z = 5;
 247                                 setsize(self, self.mins, self.maxs);
 248                         }
 249                         self.frame = self.dead_frame;
 250                 }
 251                 return;
 252         }
 253
 254         if (!self.animstate_override)
 255         {
 256                 if (!(self.flags & FL_ONGROUND))
 257                 {
 258                         if (self.crouch)
 259                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 260                         else
 261                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 262                         self.restart_jump = FALSE;
 263                 }
 264                 else if (self.crouch)
 265                 {
 266                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 267                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 268                         else
 269                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 270                 }
 271                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 272                 {
 273                         if (self.movement_x > 0 && self.movement_y == 0)
 274                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 275                         else if (self.movement_x < 0 && self.movement_y == 0)
 276                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 277                         else if (self.movement_x == 0 && self.movement_y > 0)
 278                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 279                         else if (self.movement_x == 0 && self.movement_y < 0)
 280                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 281                         else if (self.movement_x > 0 && self.movement_y > 0)
 282                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 283                         else if (self.movement_x > 0 && self.movement_y < 0)
 284                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 285                         else if (self.movement_x < 0 && self.movement_y > 0)
 286                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 287                         else if (self.movement_x < 0 && self.movement_y < 0)
 288                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 289                         else
 290                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 291                 }
 292                 else
 293                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 294         }
 295
 296         if (self.weaponentity)
 297         if (!self.weaponentity.animstate_override)
 298                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 299 }
 300
 301 void SpawnThrownWeapon (vector org, float w)
 302 {
 303         if(g_minstagib)
 304         if(self.ammo_cells <= 0)
 305                 return;
 306
 307         if(g_pinata)
 308         {
 309                 float j;
 310                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 311                 {
 312                         if(self.weapons & W_WeaponBit(j))
 313                                 if(W_IsWeaponThrowable(j))
 314                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 315                 }
 316         }
 317         else
 318         {
 319                 if(W_IsWeaponThrowable(self.weapon))
 320                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 321         }
 322 }
 323
 324 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 325 {
 326         local float take, save;
 327         vector v;
 328         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 329
 330         // damage resistance (ignore most of the damage from a bullet or similar)
 331         damage = max(damage - 5, 1);
 332
 333         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 334         take = v_x;
 335         save = v_y;
 336
 337         if(sound_allowed(MSG_BROADCAST, attacker))
 338         {
 339                 if (save > 10)
 340                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 341                 else if (take > 30)
 342                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 343                 else if (take > 10)
 344                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 345         }
 346
 347         if (take > 50)
 348                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 349         if (take > 100)
 350                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 351
 352         if (!(self.flags & FL_GODMODE))
 353         {
 354                 self.armorvalue = self.armorvalue - save;
 355                 self.health = self.health - take;
 356                 // pause regeneration for 5 seconds
 357                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 358         }
 359         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 360         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 361         self.dmg_inflictor = inflictor;
 362
 363         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 364         {
 365                 // don't use any animations as a gib
 366                 self.frame = 0;
 367                 self.dead_frame = 0;
 368                 // view just above the floor
 369                 self.view_ofs = '0 0 4';
 370
 371                 Violence_GibSplash(self, 1, 1, attacker);
 372                 self.modelindex = 0; // restore later
 373                 self.solid = SOLID_NOT; // restore later
 374         }
 375 }
 376
 377 void ClientKill_Now_TeamChange();
 378 void freezetag_CheckWinner();
 379
 380 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 381 {
 382         local float take, save, waves, sdelay, dh, da, j;
 383         vector v;
 384         float valid_damage_for_weaponstats;
 385         float excess;
 386
 387         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 388                 return;
 389
 390         dh = max(self.health, 0);
 391         da = max(self.armorvalue, 0);
 392
 393         if(!DEATH_ISSPECIAL(deathtype))
 394         {
 395                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 396                 if(self != attacker)
 397                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 398         }
 399
 400         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 401         {
 402                 // tuba causes blood to come out of the ears
 403                 vector ear1, ear2;
 404                 vector d;
 405                 float f;
 406                 ear1 = self.origin;
 407                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 408                 ear2 = ear1;
 409                 makevectors(self.angles);
 410                 ear1 += v_right * -10;
 411                 ear2 += v_right * +10;
 412                 d = inflictor.origin - self.origin;
 413                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 414                 force = v_right * vlen(force);
 415                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 416                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 417                 if(f > 0)
 418                 {
 419                         hitloc = ear1;
 420                         force = force * -1;
 421                 }
 422                 else
 423                 {
 424                         hitloc = ear2;
 425                         // force is already good
 426                 }
 427         }
 428         else
 429                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 430
 431         if (!g_minstagib)
 432         {
 433                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 434                 take = v_x;
 435                 save = v_y;
 436         }
 437         else
 438         {
 439                 save = 0;
 440                 take = damage;
 441         }
 442
 443         frag_inflictor = inflictor;
 444         frag_attacker = attacker;
 445         frag_target = self;
 446         damage_take = take;
 447         damage_save = save;
 448         damage_force = force;
 449         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 450         take = bound(0, damage_take, self.health);
 451         save = bound(0, damage_save, self.armorvalue);
 452         excess = max(0, damage - take - save);
 453
 454         if(sound_allowed(MSG_BROADCAST, attacker))
 455         {
 456                 if (save > 10)
 457                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 458                 else if (take > 30)
 459                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 460                 else if (take > 10)
 461                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 462         }
 463
 464         if (take > 50)
 465                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 466         if (take > 100)
 467                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 468
 469         if (time >= self.spawnshieldtime)
 470         {
 471                 if (!(self.flags & FL_GODMODE))
 472                 {
 473                         self.armorvalue = self.armorvalue - save;
 474                         self.health = self.health - take;
 475                         // pause regeneration for 5 seconds
 476                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 477
 478                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 479                         {
 480                                 self.pain_finished = time + 0.5;        //Supajoe
 481
 482                                 if(sv_gentle < 1) {
 483                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 484                                         {
 485                                                 if (random() > 0.5)
 486                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 487                                                 else
 488                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 489                                         }
 490
 491                                         if(sound_allowed(MSG_BROADCAST, attacker))
 492                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 493                                         if(self.health > 1)
 494                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 495                                         {
 496                                                 if(deathtype == DEATH_FALL)
 497                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 498                                                 else if(self.health > 75) // TODO make a "gentle" version?
 499                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 500                                                 else if(self.health > 50)
 501                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 502                                                 else if(self.health > 25)
 503                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 504                                                 else
 505                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 506                                         }
 507                                 }
 508
 509                                 // throw off bot aim temporarily
 510                                 local float shake;
 511                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 512                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 513                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 514                         }
 515                 }
 516                 else
 517                         self.max_armorvalue += (save + take);
 518         }
 519         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 520         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 521         self.dmg_inflictor = inflictor;
 522
 523         if(attacker == self)
 524         {
 525                 // don't reset pushltime for self damage as it may be an attempt to
 526                 // escape a lava pit or similar
 527                 //self.pushltime = 0;
 528         }
 529         else if(attacker.classname == "player" || attacker.classname == "gib")
 530         {
 531                 self.pusher = attacker;
 532                 self.pushltime = time + autocvar_g_maxpushtime;
 533         }
 534         else if(time < self.pushltime)
 535         {
 536                 attacker = self.pusher;
 537                 self.pushltime = max(self.pushltime, time + 0.6);
 538         }
 539         else
 540                 self.pushltime = 0;
 541
 542         float abot, vbot, awep;
 543         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 544         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 545
 546         valid_damage_for_weaponstats = 0;
 547         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 548         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 549         if(attacker && self != attacker)
 550         if(IsDifferentTeam(self, attacker))
 551         {
 552                 if(DEATH_ISSPECIAL(deathtype))
 553                         awep = attacker.weapon;
 554                 else
 555                         awep = DEATH_WEAPONOF(deathtype);
 556                 valid_damage_for_weaponstats = 1;
 557         }
 558
 559         if(valid_damage_for_weaponstats)
 560         {
 561                 dh = dh - max(self.health, 0);
 562                 da = da - max(self.armorvalue, 0);
 563                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 564         }
 565
 566         if (self.health < 1)
 567         {
 568                 float defer_ClientKill_Now_TeamChange;
 569                 defer_ClientKill_Now_TeamChange = FALSE;
 570
 571                 if(self.alivetime)
 572                 {
 573                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 574                         self.alivetime = 0;
 575                 }
 576
 577                 if(valid_damage_for_weaponstats)
 578                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 579
 580                 if(sv_gentle < 1) // TODO make a "gentle" version?
 581                 if(sound_allowed(MSG_BROADCAST, attacker))
 582                 {
 583                         if(deathtype == DEATH_DROWN)
 584                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 585                         else
 586                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 587                 }
 588
 589                 // get rid of kill indicator
 590                 if(self.killindicator)
 591                 {
 592                         remove(self.killindicator);
 593                         self.killindicator = world;
 594                         if(self.killindicator_teamchange)
 595                                 defer_ClientKill_Now_TeamChange = TRUE;
 596
 597                         if(self.classname == "body")
 598                         if(deathtype == DEATH_KILL)
 599                         {
 600                                 // for the lemmings fans, a small harmless explosion
 601                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 602                         }
 603                 }
 604
 605                 if(!g_freezetag)
 606                 {
 607                         // become fully visible
 608                         self.alpha = 1;
 609                         // clear selected player display
 610                         ClearSelectedPlayer();
 611                         // throw a weapon
 612                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 613                 }
 614
 615                 // print an obituary message
 616                 Obituary (attacker, inflictor, self, deathtype);
 617                 race_PreDie();
 618                 DropAllRunes(self);
 619
 620                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 621                 {
 622                         PutClientInServer();
 623                         count_alive_players(); // re-count players
 624                         freezetag_CheckWinner();
 625                         return;
 626                 }
 627
 628                 frag_attacker = attacker;
 629                 frag_inflictor = inflictor;
 630                 frag_target = self;
 631                 MUTATOR_CALLHOOK(PlayerDies);
 632
 633                 if(self.flagcarried)
 634                 {
 635                         if(attacker.classname != "player" && attacker.classname != "gib")
 636                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 637                         else if(attacker.team == self.team)
 638                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 639                         else
 640                                 DropFlag(self.flagcarried, world, attacker);
 641                 }
 642                 if(self.ballcarried && g_nexball)
 643                         DropBall(self.ballcarried, self.origin, self.velocity);
 644                 Portal_ClearAllLater(self);
 645
 646                 if(clienttype(self) == CLIENTTYPE_REAL)
 647                 {
 648                         stuffcmd(self, "-zoom\n");
 649                         self.fixangle = TRUE;
 650                         //msg_entity = self;
 651                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 652                         //WriteAngle (MSG_ONE, self.v_angle_x);
 653                         //WriteAngle (MSG_ONE, self.v_angle_y);
 654                         //WriteAngle (MSG_ONE, 80);
 655                 }
 656
 657                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 658                         ClientKill_Now_TeamChange();
 659
 660                 if(g_arena)
 661                         Spawnqueue_Unmark(self);
 662
 663                 if(g_freezetag)
 664                         return;
 665
 666                 // when we get here, player actually dies
 667                 // clear waypoints (do this AFTER FreezeTag)
 668                 WaypointSprite_PlayerDead();
 669
 670                 // make the corpse upright (not tilted)
 671                 self.angles_x = 0;
 672                 self.angles_z = 0;
 673                 // don't spin
 674                 self.avelocity = '0 0 0';
 675                 // view from the floor
 676                 self.view_ofs = '0 0 -8';
 677                 // toss the corpse
 678                 self.movetype = MOVETYPE_TOSS;
 679                 // shootable corpse
 680                 self.solid = SOLID_CORPSE;
 681                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 682                 // don't stick to the floor
 683                 self.flags &~= FL_ONGROUND;
 684                 // dying animation
 685                 self.deadflag = DEAD_DYING;
 686                 // when to allow respawn
 687                 sdelay = 0;
 688                 waves = 0;
 689                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 690                 if(!sdelay)
 691                 {
 692                         if(g_cts)
 693                                 sdelay = 0; // no respawn delay in CTS
 694                         else
 695                                 sdelay = autocvar_g_respawn_delay;
 696                 }
 697                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 698                 if(!waves)
 699                         waves = autocvar_g_respawn_waves;
 700                 if(waves)
 701                         self.death_time = ceil((time + sdelay) / waves) * waves;
 702                 else
 703                         self.death_time = time + sdelay;
 704                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 705                         self.respawn_countdown = 10; // first number to count down from is 10
 706                 else
 707                         self.respawn_countdown = -1; // do not count down
 708                 if (random() < 0.5)
 709                 {
 710                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 711                         self.dead_frame = self.anim_dead1_x;
 712                 }
 713                 else
 714                 {
 715                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 716                         self.dead_frame = self.anim_dead2_x;
 717                 }
 718                 // set damage function to corpse damage
 719                 self.event_damage = PlayerCorpseDamage;
 720                 // call the corpse damage function just in case it wants to gib
 721                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 722                 // set up to fade out later
 723                 SUB_SetFade (self, time + 6 + random (), 1);
 724
 725                 if(sv_gentle > 0 || autocvar_ekg) {
 726                         // remove corpse
 727                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 728                 }
 729
 730                 // reset fields the weapons may use just in case
 731                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 732                 {
 733                         weapon_action(j, WR_RESETPLAYER);
 734                         ATTACK_FINISHED_FOR(self, j) = 0;
 735                 }
 736         }
 737 }
 738
 739 float UpdateSelectedPlayer_countvalue(float v)
 740 {
 741         return max(0, (v - 1.0) / 0.5);
 742 }
 743
 744 // returns: -2 if no hit, otherwise cos of the angle
 745 // uses the global v_angle
 746 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 747 {
 748         vector so, d;
 749         float c;
 750
 751         if(p == self)
 752                 return -2;
 753
 754         if(p.deadflag)
 755                 return -2;
 756
 757         so = self.origin + self.view_ofs;
 758         d = p.origin - so;
 759
 760         // misaimed?
 761         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 762                 return -2;
 763
 764         // now find the cos of the angle...
 765         c = normalize(d) * v_forward;
 766
 767         if(c <= mincosangle)
 768                 return -2;
 769
 770         // not visible in any way? forget it
 771         if(!checkpvs(so, p))
 772                 return -2;
 773
 774         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 775         if(trace_fraction < 1)
 776                 return -2;
 777
 778         return c;
 779 }
 780
 781 void ClearSelectedPlayer()
 782 {
 783         if(self.selected_player)
 784         {
 785                 centerprint_expire(self, CENTERPRIO_POINT);
 786                 self.selected_player = world;
 787                 self.selected_player_display_needs_update = FALSE;
 788         }
 789 }
 790
 791 void UpdateSelectedPlayer()
 792 {
 793         entity selected;
 794         float selected_score;
 795         selected = world;
 796         selected_score = 0.95; // 18 degrees
 797
 798         if(!autocvar_sv_allow_shownames)
 799                 return;
 800
 801         if(clienttype(self) != CLIENTTYPE_REAL)
 802                 return;
 803
 804         if(self.cvar_cl_shownames == 0)
 805                 return;
 806
 807         if(self.cvar_cl_shownames == 1 && !teams_matter)
 808                 return;
 809
 810         makevectors(self.v_angle); // sets v_forward
 811
 812         // 1. cursor trace is always right
 813         WarpZone_crosshair_trace(self);
 814         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 815         {
 816                 selected = trace_ent;
 817         }
 818         else
 819         {
 820                 // 2. if we don't have a cursor trace, find the player which is least
 821                 //    mis-aimed at
 822                 entity p;
 823                 FOR_EACH_PLAYER(p)
 824                 {
 825                         float c;
 826                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 827                         if(c >= -1)
 828                         {
 829                                 selected = p;
 830                                 selected_score = c;
 831                         }
 832                 }
 833         }
 834
 835         if(selected)
 836         {
 837                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 838         }
 839         else
 840         {
 841                 if(time < self.selected_player_display_timeout)
 842                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 843                                 selected = self.selected_player;
 844         }
 845
 846         if(selected)
 847         {
 848                 if(selected == self.selected_player)
 849                 {
 850                         float save;
 851                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 852                         self.selected_player_count = self.selected_player_count + frametime;
 853                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 854                         {
 855                                 string namestr, healthstr;
 856                                 namestr = playername(selected);
 857                                 if(teams_matter)
 858                                 {
 859                                         healthstr = ftos(floor(selected.health));
 860                                         if(self.team == selected.team)
 861                                         {
 862                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 863                                                 self.selected_player_display_needs_update = TRUE;
 864                                         }
 865                                 }
 866                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 867                         }
 868                 }
 869                 else
 870                 {
 871                         ClearSelectedPlayer();
 872                         self.selected_player = selected;
 873                         self.selected_player_time = time;
 874                         self.selected_player_count = 0;
 875                         self.selected_player_display_needs_update = FALSE;
 876                 }
 877         }
 878         else
 879         {
 880                 ClearSelectedPlayer();
 881         }
 882
 883         if(self.selected_player)
 884                 self.last_selected_player = self.selected_player;
 885 }
 886
 887 .float muted; // to be used by prvm_edictset server playernumber muted 1
 888 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 889 // message "": do not say, just test flood control
 890 // return value:
 891 //   1 = accept
 892 //   0 = reject
 893 //  -1 = fake accept
 894 {
 895         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 896         float flood, privatemsgprefixlen;
 897         var .float flood_field;
 898         entity head;
 899         float ret;
 900
 901         if(Ban_MaybeEnforceBan(source))
 902                 return 0;
 903
 904         if(!teamsay && !privatesay)
 905                 if(substring(msgin, 0, 1) == " ")
 906                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 907
 908         msgin = formatmessage(msgin);
 909
 910         if(source.classname != "player")
 911                 colorstr = "^0"; // black for spectators
 912         else if(teams_matter)
 913                 colorstr = Team_ColorCode(source.team);
 914         else
 915                 teamsay = FALSE;
 916
 917         if(intermission_running)
 918                 teamsay = FALSE;
 919
 920         if(msgin != "")
 921                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 922
 923         /*
 924          * using bprint solves this... me stupid
 925         // how can we prevent the message from appearing in a listen server?
 926         // for now, just give "say" back and only handle say_team
 927         if(!teamsay)
 928         {
 929                 clientcommand(self, strcat("say ", msgin));
 930                 return;
 931         }
 932         */
 933
 934         if(autocvar_g_chat_teamcolors)
 935                 namestr = playername(source);
 936         else
 937                 namestr = source.netname;
 938
 939         if(msgin != "")
 940         {
 941                 if(privatesay)
 942                 {
 943                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 944                         privatemsgprefixlen = strlen(msgstr);
 945                         msgstr = strcat(msgstr, msgin);
 946                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 947                         if(autocvar_g_chat_teamcolors)
 948                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 949                         else
 950                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 951                 }
 952                 else if(teamsay)
 953                 {
 954                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 955                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 956                 }
 957                 else
 958                 {
 959                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 960                         cmsgstr = "";
 961                 }
 962                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 963         }
 964         else
 965         {
 966                 msgstr = cmsgstr = "";
 967         }
 968
 969         fullmsgstr = msgstr;
 970         fullcmsgstr = cmsgstr;
 971
 972         // FLOOD CONTROL
 973         flood = 0;
 974         if(floodcontrol)
 975         {
 976                 float flood_spl;
 977                 float flood_burst;
 978                 float flood_lmax;
 979                 float lines;
 980                 if(privatesay)
 981                 {
 982                         flood_spl = autocvar_g_chat_flood_spl_tell;
 983                         flood_burst = autocvar_g_chat_flood_burst_tell;
 984                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 985                         flood_field = floodcontrol_chattell;
 986                 }
 987                 else if(teamsay)
 988                 {
 989                         flood_spl = autocvar_g_chat_flood_spl_team;
 990                         flood_burst = autocvar_g_chat_flood_burst_team;
 991                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 992                         flood_field = floodcontrol_chatteam;
 993                 }
 994                 else
 995                 {
 996                         flood_spl = autocvar_g_chat_flood_spl;
 997                         flood_burst = autocvar_g_chat_flood_burst;
 998                         flood_lmax = autocvar_g_chat_flood_lmax;
 999                         flood_field = floodcontrol_chat;
1000                 }
1001                 flood_burst = max(0, flood_burst - 1);
1002                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1003
1004                 // do flood control for the default line size
1005                 if(msgstr != "")
1006                 {
1007                         getWrappedLine_remaining = msgstr;
1008                         msgstr = "";
1009                         lines = 0;
1010                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1011                         {
1012                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1013                                 ++lines;
1014                         }
1015                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1016
1017                         if(getWrappedLine_remaining != "")
1018                         {
1019                                 msgstr = strcat(msgstr, "\n");
1020                                 flood = 2;
1021                         }
1022
1023                         if(time >= source.flood_field)
1024                         {
1025                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1026                         }
1027                         else
1028                         {
1029                                 flood = 1;
1030                                 msgstr = fullmsgstr;
1031                         }
1032                 }
1033                 else
1034                 {
1035                         if(time >= source.flood_field)
1036                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1037                         else
1038                                 flood = 1;
1039                 }
1040
1041                 if (timeoutStatus == 2) //when game is paused, no flood protection
1042                         source.flood_field = flood = 0;
1043         }
1044
1045         if(flood == 2) // cannot happen for empty msgstr
1046         {
1047                 if(autocvar_g_chat_flood_notify_flooder)
1048                 {
1049                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1050                         sourcecmsgstr = "";
1051                 }
1052                 else
1053                 {
1054                         sourcemsgstr = fullmsgstr;
1055                         sourcecmsgstr = fullcmsgstr;
1056                 }
1057                 cmsgstr = "";
1058         }
1059         else
1060         {
1061                 sourcemsgstr = msgstr;
1062                 sourcecmsgstr = cmsgstr;
1063         }
1064
1065         if(!privatesay)
1066         if(source.classname != "player")
1067         {
1068                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1069                         teamsay = -1; // spectators
1070         }
1071
1072         if(flood)
1073                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1074
1075         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1076         if(privatesay)
1077                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1078
1079         if(source.muted)
1080         {
1081                 // always fake the message
1082                 ret = -1;
1083         }
1084         else if(flood == 1)
1085         {
1086                 if(autocvar_g_chat_flood_notify_flooder)
1087                 {
1088                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1089                         ret = 0;
1090                 }
1091                 else
1092                         ret = -1;
1093         }
1094         else
1095         {
1096                 ret = 1;
1097         }
1098
1099         if(sourcemsgstr != "" && ret != 0)
1100         {
1101                 if(ret < 0) // fake
1102                 {
1103                         sprint(source, sourcemsgstr);
1104                         if(sourcecmsgstr != "" && !privatesay)
1105                                 centerprint(source, sourcecmsgstr);
1106                 }
1107                 else if(privatesay)
1108                 {
1109                         sprint(source, sourcemsgstr);
1110                         sprint(privatesay, msgstr);
1111                         if(cmsgstr != "")
1112                                 centerprint(privatesay, cmsgstr);
1113                 }
1114                 else if(teamsay > 0)
1115                 {
1116                         sprint(source, sourcemsgstr);
1117                         if(sourcecmsgstr != "")
1118                                 centerprint(source, sourcecmsgstr);
1119                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1120                                 if(head != source)
1121                                 {
1122                                         sprint(head, msgstr);
1123                                         if(cmsgstr != "")
1124                                                 centerprint(head, cmsgstr);
1125                                 }
1126                 }
1127                 else if(teamsay < 0)
1128                 {
1129                         sprint(source, sourcemsgstr);
1130                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1131                                 if(head != source)
1132                                         sprint(head, msgstr);
1133                 }
1134                 else if(sourcemsgstr != msgstr)
1135                 {
1136                         sprint(source, sourcemsgstr);
1137                         FOR_EACH_REALCLIENT(head)
1138                                 if(head != source)
1139                                         sprint(head, msgstr);
1140                 }
1141                 else
1142                         bprint(msgstr);
1143         }
1144
1145         return ret;
1146 }
1147
1148 float GetVoiceMessageVoiceType(string type)
1149 {
1150         if(type == "taunt")
1151                 return VOICETYPE_TAUNT;
1152         if(type == "teamshoot")
1153                 return VOICETYPE_LASTATTACKER;
1154         return VOICETYPE_TEAMRADIO;
1155 }
1156
1157 string allvoicesamples;
1158 .string GetVoiceMessageSampleField(string type)
1159 {
1160         GetPlayerSoundSampleField_notFound = 0;
1161         switch(type)
1162         {
1163 #define _VOICEMSG(m) case #m: return playersound_##m;
1164                 ALLVOICEMSGS
1165 #undef _VOICEMSG
1166         }
1167         GetPlayerSoundSampleField_notFound = 1;
1168         return playersound_taunt;
1169 }
1170
1171 .string GetPlayerSoundSampleField(string type)
1172 {
1173         GetPlayerSoundSampleField_notFound = 0;
1174         switch(type)
1175         {
1176 #define _VOICEMSG(m) case #m: return playersound_##m;
1177                 ALLPLAYERSOUNDS
1178 #undef _VOICEMSG
1179         }
1180         GetPlayerSoundSampleField_notFound = 1;
1181         return playersound_taunt;
1182 }
1183
1184 void PrecacheGlobalSound(string samplestring)
1185 {
1186         float n, i;
1187         tokenize_console(samplestring);
1188         n = stof(argv(1));
1189         if(n > 0)
1190         {
1191                 for(i = 1; i <= n; ++i)
1192                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1193         }
1194         else
1195         {
1196                 precache_sound(strcat(argv(0), ".wav"));
1197         }
1198 }
1199
1200 void PrecachePlayerSounds(string f)
1201 {
1202         float fh;
1203         string s;
1204         fh = fopen(f, FILE_READ);
1205         if(fh < 0)
1206                 return;
1207         while((s = fgets(fh)))
1208         {
1209                 if(tokenize_console(s) != 3)
1210                 {
1211                         dprint("Invalid sound info line: ", s, "\n");
1212                         continue;
1213                 }
1214                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1215         }
1216         fclose(fh);
1217
1218         if not(allvoicesamples)
1219         {
1220 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1221                 ALLVOICEMSGS
1222 #undef _VOICEMSG
1223                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1224         }
1225 }
1226
1227 void ClearPlayerSounds()
1228 {
1229 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1230         ALLPLAYERSOUNDS
1231         ALLVOICEMSGS
1232 #undef _VOICEMSG
1233 }
1234
1235 float LoadPlayerSounds(string f, float first)
1236 {
1237         float fh;
1238         string s;
1239         var .string field;
1240         fh = fopen(f, FILE_READ);
1241         if(fh < 0)
1242         {
1243                 dprint("Player sound file not found: ", f, "\n");
1244                 return 0;
1245         }
1246         while((s = fgets(fh)))
1247         {
1248                 if(tokenize_console(s) != 3)
1249                         continue;
1250                 field = GetPlayerSoundSampleField(argv(0));
1251                 if(GetPlayerSoundSampleField_notFound)
1252                         field = GetVoiceMessageSampleField(argv(0));
1253                 if(GetPlayerSoundSampleField_notFound)
1254                         continue;
1255                 if(self.field)
1256                         strunzone(self.field);
1257                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1258         }
1259         fclose(fh);
1260         return 1;
1261 }
1262
1263 .float modelindex_for_playersound;
1264 .float skinindex_for_playersound;
1265 void UpdatePlayerSounds()
1266 {
1267         if(self.modelindex == self.modelindex_for_playersound)
1268         if(self.skinindex == self.skinindex_for_playersound)
1269                 return;
1270         self.modelindex_for_playersound = self.modelindex;
1271         self.skinindex_for_playersound = self.skinindex;
1272         ClearPlayerSounds();
1273         LoadPlayerSounds("sound/player/default.sounds", 1);
1274         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1275                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1276 }
1277
1278 void FakeGlobalSound(string sample, float chan, float voicetype)
1279 {
1280         float n;
1281         float tauntrand;
1282
1283         if(sample == "")
1284                 return;
1285
1286         tokenize_console(sample);
1287         n = stof(argv(1));
1288         if(n > 0)
1289                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1290         else
1291                 sample = strcat(argv(0), ".wav"); // randomization
1292
1293         switch(voicetype)
1294         {
1295                 case VOICETYPE_LASTATTACKER_ONLY:
1296                         break;
1297                 case VOICETYPE_LASTATTACKER:
1298                         if(self.pusher)
1299                         {
1300                                 msg_entity = self;
1301                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1302                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1303                         }
1304                         break;
1305                 case VOICETYPE_TEAMRADIO:
1306                         msg_entity = self;
1307                         if(msg_entity.cvar_cl_voice_directional == 1)
1308                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1309                         else
1310                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1311                         break;
1312                 case VOICETYPE_AUTOTAUNT:
1313                         if(!sv_autotaunt)
1314                                 break;
1315                         if(!sv_taunt)
1316                                 break;
1317                         if(sv_gentle)
1318                                 break;
1319                         tauntrand = random();
1320                         msg_entity = self;
1321                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1322                         {
1323                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1324                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1325                                 else
1326                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1327                         }
1328                         break;
1329                 case VOICETYPE_TAUNT:
1330                         if(self.classname == "player")
1331                                 if(self.deadflag == DEAD_NO)
1332                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1333                         if(!sv_taunt)
1334                                 break;
1335                         if(sv_gentle)
1336                                 break;
1337                         msg_entity = self;
1338                         if (msg_entity.cvar_cl_voice_directional >= 1)
1339                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1340                         else
1341                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1342                         break;
1343                 case VOICETYPE_PLAYERSOUND:
1344                         msg_entity = self;
1345                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1346                         break;
1347                 default:
1348                         backtrace("Invalid voice type!");
1349                         break;
1350         }
1351 }
1352
1353 void GlobalSound(string sample, float chan, float voicetype)
1354 {
1355         float n;
1356         float tauntrand;
1357
1358         if(sample == "")
1359                 return;
1360
1361         tokenize_console(sample);
1362         n = stof(argv(1));
1363         if(n > 0)
1364                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1365         else
1366                 sample = strcat(argv(0), ".wav"); // randomization
1367
1368         switch(voicetype)
1369         {
1370                 case VOICETYPE_LASTATTACKER_ONLY:
1371                         if(self.pusher)
1372                         {
1373                                 msg_entity = self.pusher;
1374                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1375                                 {
1376                                         if(msg_entity.cvar_cl_voice_directional == 1)
1377                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1378                                         else
1379                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1380                                 }
1381                         }
1382                         break;
1383                 case VOICETYPE_LASTATTACKER:
1384                         if(self.pusher)
1385                         {
1386                                 msg_entity = self.pusher;
1387                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1388                                 {
1389                                         if(msg_entity.cvar_cl_voice_directional == 1)
1390                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1391                                         else
1392                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1393                                 }
1394                                 msg_entity = self;
1395                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1396                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1397                         }
1398                         break;
1399                 case VOICETYPE_TEAMRADIO:
1400                         FOR_EACH_REALCLIENT(msg_entity)
1401                                 if(!teams_matter || msg_entity.team == self.team)
1402                                 {
1403                                         if(msg_entity.cvar_cl_voice_directional == 1)
1404                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1405                                         else
1406                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1407                                 }
1408                         break;
1409                 case VOICETYPE_AUTOTAUNT:
1410                         if(!sv_autotaunt)
1411                                 break;
1412                         if(!sv_taunt)
1413                                 break;
1414                         if(sv_gentle)
1415                                 break;
1416                         tauntrand = random();
1417                         FOR_EACH_REALCLIENT(msg_entity)
1418                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1419                                 {
1420                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1421                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1422                                         else
1423                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1424                                 }
1425                         break;
1426                 case VOICETYPE_TAUNT:
1427                         if(self.classname == "player")
1428                                 if(self.deadflag == DEAD_NO)
1429                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1430                         if(!sv_taunt)
1431                                 break;
1432                         if(sv_gentle)
1433                                 break;
1434                         FOR_EACH_REALCLIENT(msg_entity)
1435                         {
1436                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1437                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1438                                 else
1439                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1440                         }
1441                         break;
1442                 case VOICETYPE_PLAYERSOUND:
1443                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1444                         break;
1445                 default:
1446                         backtrace("Invalid voice type!");
1447                         break;
1448         }
1449 }
1450
1451 void PlayerSound(.string samplefield, float chan, float voicetype)
1452 {
1453         GlobalSound(self.samplefield, chan, voicetype);
1454 }
1455
1456 void VoiceMessage(string type, string msg)
1457 {
1458         var .string sample;
1459         float voicetype, ownteam;
1460         float flood;
1461         sample = GetVoiceMessageSampleField(type);
1462
1463         if(GetPlayerSoundSampleField_notFound)
1464         {
1465                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1466                 return;
1467         }
1468
1469         voicetype = GetVoiceMessageVoiceType(type);
1470         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1471
1472         flood = Say(self, ownteam, world, msg, 1);
1473
1474         if (flood > 0)
1475                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1476         else if (flood < 0)
1477                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1478 }
1479
1480 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1481 {
1482 //      show_message
1483 //      0 (00) automove centerprint, admin message
1484 //      1 (01) automove centerprint, no admin message
1485 //      2 (10) no centerprint, admin message
1486 //      3 (11) no centerprint, no admin message
1487
1488         float lockteams_backup;
1489
1490         lockteams_backup = lockteams;  // backup any team lock
1491
1492         lockteams = 0;  // disable locked teams
1493
1494         TeamchangeFrags(client);  // move the players frags
1495         SetPlayerColors(client, team_colour - 1);  // set the players colour
1496         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1497
1498         lockteams = lockteams_backup;  // restore the team lock
1499
1500         LogTeamchange(client.playerid, client.team, type);
1501
1502         if not(show_message & 1) // admin message
1503                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1504
1505         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1506 }