qcsrc/server/cl_player.qc

   1 .entity pusher;
   2 .float pushltime;
   3 .float istypefrag;
   4
   5 .float CopyBody_nextthink;
   6 .void(void) CopyBody_think;
   7 void CopyBody_Think(void)
   8 {
   9         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
  10         {
  11                 self.CopyBody_think();
  12                 if(wasfreed(self))
  13                         return;
  14                 self.CopyBody_nextthink = self.nextthink;
  15                 self.CopyBody_think = self.think;
  16                 self.think = CopyBody_Think;
  17         }
  18         CSQCMODEL_AUTOUPDATE();
  19         self.nextthink = time;
  20 }
  21 void CopyBody(float keepvelocity)
  22 {
  23         entity oldself;
  24         if (self.effects & EF_NODRAW)
  25                 return;
  26         oldself = self;
  27         self = spawn();
  28         self.enemy = oldself;
  29         self.lip = oldself.lip;
  30         self.colormap = oldself.colormap;
  31         self.iscreature = oldself.iscreature;
  32         self.teleportable = oldself.teleportable;
  33         self.damagedbycontents = oldself.damagedbycontents;
  34         self.angles = oldself.angles;
  35         self.v_angle = oldself.v_angle;
  36         self.avelocity = oldself.avelocity;
  37         self.classname = "body";
  38         self.damageforcescale = oldself.damageforcescale;
  39         self.effects = oldself.effects;
  40         self.glowmod = oldself.glowmod;
  41         self.event_damage = oldself.event_damage;
  42         self.anim_state = oldself.anim_state;
  43         self.anim_time = oldself.anim_time;
  44         self.anim_lower_action = oldself.anim_lower_action;
  45         self.anim_lower_time = oldself.anim_lower_time;
  46         self.anim_upper_action = oldself.anim_upper_action;
  47         self.anim_upper_time = oldself.anim_upper_time;
  48         self.anim_implicit_state = oldself.anim_implicit_state;
  49         self.anim_implicit_time = oldself.anim_implicit_time;
  50         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
  51         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
  52         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
  53         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
  54         self.dphitcontentsmask = oldself.dphitcontentsmask;
  55         self.death_time = oldself.death_time;
  56         self.pain_finished = oldself.pain_finished;
  57         self.health = oldself.health;
  58         self.armorvalue = oldself.armorvalue;
  59         self.armortype = oldself.armortype;
  60         self.model = oldself.model;
  61         self.modelindex = oldself.modelindex;
  62         self.skin = oldself.skin;
  63         self.species = oldself.species;
  64         self.movetype = oldself.movetype;
  65         self.solid = oldself.solid;
  66         self.ballistics_density = oldself.ballistics_density;
  67         self.takedamage = oldself.takedamage;
  68         self.customizeentityforclient = oldself.customizeentityforclient;
  69         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
  70         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
  71         if (keepvelocity == 1)
  72                 self.velocity = oldself.velocity;
  73         self.oldvelocity = self.velocity;
  74         self.alpha = oldself.alpha;
  75         self.fade_time = oldself.fade_time;
  76         self.fade_rate = oldself.fade_rate;
  77         //self.weapon = oldself.weapon;
  78         setorigin(self, oldself.origin);
  79         setsize(self, oldself.mins, oldself.maxs);
  80         self.prevorigin = oldself.origin;
  81         self.reset = SUB_Remove;
  82
  83         Drag_MoveDrag(oldself, self);
  84
  85         if(self.colormap <= maxclients && self.colormap > 0)
  86                 self.colormap = 1024 + oldself.clientcolors;
  87
  88         CSQCMODEL_AUTOINIT();
  89         self.CopyBody_nextthink = oldself.nextthink;
  90         self.CopyBody_think = oldself.think;
  91         self.nextthink = time;
  92         self.think = CopyBody_Think;
  93         // "bake" the current animation frame for clones (they don't get clientside animation)
  94         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
  95
  96         self = oldself;
  97 }
  98
  99 float player_getspecies()
 100 {
 101         float s;
 102         get_model_parameters(self.model, self.skin);
 103         s = get_model_parameters_species;
 104         get_model_parameters(string_null, 0);
 105         if(s < 0)
 106                 return SPECIES_HUMAN;
 107         return s;
 108 }
 109
 110 void player_setupanimsformodel()
 111 {
 112         // load animation info
 113         animdecide_init(self);
 114         animdecide_setstate(self, 0, FALSE);
 115 }
 116
 117 void player_anim (void)
 118 {
 119         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 120         if(self.deadflag && !deadbits)
 121                 if(random() < 0.5)
 122                         deadbits = ANIMSTATE_DEAD1;
 123                 else
 124                         deadbits = ANIMSTATE_DEAD2;
 125         float animbits = deadbits;
 126         if(self.freezetag_frozen)
 127                 animbits |= ANIMSTATE_FROZEN;
 128         if(self.crouch)
 129                 animbits |= ANIMSTATE_DUCK;
 130         animdecide_setstate(self, animbits, FALSE);
 131         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 132
 133         if (self.weaponentity)
 134         {
 135                 updateanim(self.weaponentity);
 136                 if (!self.weaponentity.animstate_override)
 137                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 138         }
 139 }
 140
 141 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 142 {
 143         float take, save;
 144         vector v;
 145         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 146
 147         // damage resistance (ignore most of the damage from a bullet or similar)
 148         damage = max(damage - 5, 1);
 149
 150         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 151         take = v_x;
 152         save = v_y;
 153
 154         if(sound_allowed(MSG_BROADCAST, attacker))
 155         {
 156                 if (save > 10)
 157                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 158                 else if (take > 30)
 159                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 160                 else if (take > 10)
 161                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 162         }
 163
 164         if (take > 50)
 165                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 166         if (take > 100)
 167                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 168
 169         if (!(self.flags & FL_GODMODE))
 170         {
 171                 self.armorvalue = self.armorvalue - save;
 172                 self.health = self.health - take;
 173                 // pause regeneration for 5 seconds
 174                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 175         }
 176         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 177         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 178         self.dmg_inflictor = inflictor;
 179
 180         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 181         {
 182                 // don't use any animations as a gib
 183                 self.frame = 0;
 184                 // view just above the floor
 185                 self.view_ofs = '0 0 4';
 186
 187                 Violence_GibSplash(self, 1, 1, attacker);
 188                 self.alpha = -1;
 189                 self.solid = SOLID_NOT; // restore later
 190                 self.takedamage = DAMAGE_NO; // restore later
 191                 self.damagedbycontents = FALSE;
 192         }
 193 }
 194
 195 // g_<gametype>_str:
 196 // If 0, default is used.
 197 // If <0, 0 is used.
 198 // Otherwise, g_str (default value) is used.
 199 // For consistency, negative values there are mapped to zero too.
 200 #define GAMETYPE_DEFAULTED_SETTING(str) \
 201         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 202          (gametype_setting_tmp < 0) ? 0 : \
 203          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 204          gametype_setting_tmp)
 205
 206
 207 void calculate_player_respawn_time()
 208 {
 209         float gametype_setting_tmp;
 210         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 211         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 212         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 213         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 214         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 215         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 216
 217         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 218         entity pl;
 219         if (teamplay)
 220         {
 221                 FOR_EACH_PLAYER(pl)
 222                         if (pl != self)
 223                                 if (pl.team == self.team)
 224                                         ++pcount;
 225                 if (sdelay_small_count == 0)
 226                         sdelay_small_count = 1;
 227                 if (sdelay_large_count == 0)
 228                         sdelay_large_count = 1;
 229         }
 230         else
 231         {
 232                 FOR_EACH_PLAYER(pl)
 233                         if (pl != self)
 234                                 ++pcount;
 235                 if (sdelay_small_count == 0)
 236                 {
 237                         if (g_cts)
 238                         {
 239                                 // Players play independently. No point in requiring enemies.
 240                                 sdelay_small_count = 1;
 241                         }
 242                         else
 243                         {
 244                                 // Players play AGAINST each other. Enemies required.
 245                                 sdelay_small_count = 2;
 246                         }
 247                 }
 248                 if (sdelay_large_count == 0)
 249                 {
 250                         if (g_cts)
 251                         {
 252                                 // Players play independently. No point in requiring enemies.
 253                                 sdelay_large_count = 1;
 254                         }
 255                         else
 256                         {
 257                                 // Players play AGAINST each other. Enemies required.
 258                                 sdelay_large_count = 2;
 259                         }
 260                 }
 261         }
 262
 263         float sdelay;
 264
 265         if (pcount <= sdelay_small_count)
 266                 sdelay = sdelay_small;
 267         else if (pcount >= sdelay_large_count)
 268                 sdelay = sdelay_large;
 269         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 270                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 271
 272         if(waves)
 273                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 274         else
 275                 self.respawn_time = time + sdelay;
 276
 277         if(sdelay < sdelay_max)
 278                 self.respawn_time_max = time + sdelay_max;
 279         else
 280                 self.respawn_time_max = self.respawn_time;
 281
 282         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 283                 self.respawn_countdown = 10; // first number to count down from is 10
 284         else
 285                 self.respawn_countdown = -1; // do not count down
 286
 287         if(g_cts || autocvar_g_forced_respawn)
 288                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 289 }
 290
 291 void ClientKill_Now_TeamChange();
 292
 293 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 294 {
 295         float take, save, dh, da, j;
 296         vector v;
 297         float valid_damage_for_weaponstats;
 298         float excess;
 299
 300         dh = max(self.health, 0);
 301         da = max(self.armorvalue, 0);
 302
 303         if(!DEATH_ISSPECIAL(deathtype))
 304         {
 305                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 306                 if(self != attacker)
 307                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 308         }
 309
 310         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 311         {
 312                 // tuba causes blood to come out of the ears
 313                 vector ear1, ear2;
 314                 vector d;
 315                 float f;
 316                 ear1 = self.origin;
 317                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 318                 ear2 = ear1;
 319                 makevectors(self.angles);
 320                 ear1 += v_right * -10;
 321                 ear2 += v_right * +10;
 322                 d = inflictor.origin - self.origin;
 323                 if (d)
 324                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 325                 else
 326                         f = 0;  // Assum ecenter.
 327                 force = v_right * vlen(force);
 328                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 329                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 330                 if(f > 0)
 331                 {
 332                         hitloc = ear1;
 333                         force = force * -1;
 334                 }
 335                 else
 336                 {
 337                         hitloc = ear2;
 338                         // force is already good
 339                 }
 340         }
 341         else
 342                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 343
 344
 345         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 346         take = v_x;
 347         save = v_y;
 348
 349         if(attacker == self)
 350         {
 351                 // don't reset pushltime for self damage as it may be an attempt to
 352                 // escape a lava pit or similar
 353                 //self.pushltime = 0;
 354                 self.istypefrag = 0;
 355         }
 356         else if(IS_PLAYER(attacker))
 357         {
 358                 self.pusher = attacker;
 359                 self.pushltime = time + autocvar_g_maxpushtime;
 360                 self.istypefrag = self.BUTTON_CHAT;
 361         }
 362         else if(time < self.pushltime)
 363         {
 364                 attacker = self.pusher;
 365                 self.pushltime = max(self.pushltime, time + 0.6);
 366         }
 367         else
 368         {
 369                 self.pushltime = 0;
 370                 self.istypefrag = 0;
 371         }
 372
 373         frag_inflictor = inflictor;
 374         frag_attacker = attacker;
 375         frag_target = self;
 376         frag_damage = damage;
 377         damage_take = take;
 378         damage_save = save;
 379         damage_force = force;
 380         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 381         take = bound(0, damage_take, self.health);
 382         save = bound(0, damage_save, self.armorvalue);
 383         excess = max(0, damage - take - save);
 384
 385         if(sound_allowed(MSG_BROADCAST, attacker))
 386         {
 387                 if (save > 10)
 388                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 389                 else if (take > 30)
 390                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 391                 else if (take > 10)
 392                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 393         }
 394
 395         if (take > 50)
 396                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 397         if (take > 100)
 398                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 399
 400         if (time >= self.spawnshieldtime)
 401         {
 402                 if (!(self.flags & FL_GODMODE))
 403                 {
 404                         self.armorvalue = self.armorvalue - save;
 405                         self.health = self.health - take;
 406                         // pause regeneration for 5 seconds
 407                         if(take)
 408                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 409
 410                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 411                         {
 412                                 self.pain_finished = time + 0.5;        //Supajoe
 413
 414                                 if(autocvar_sv_gentle < 1) {
 415                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 416                                         {
 417                                                 if (!self.animstate_override)
 418                                                 {
 419                                                         if (random() > 0.5)
 420                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 421                                                         else
 422                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 423                                                 }
 424                                         }
 425
 426                                         if(sound_allowed(MSG_BROADCAST, attacker))
 427                                         if(!DEATH_ISWEAPON(deathtype, WEP_BLASTER) || attacker != self || self.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) // WEAPONTODO: create separate limit for pain notification with laser
 428                                         if(self.health > 1)
 429                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 430                                         {
 431                                                 if(deathtype == DEATH_FALL)
 432                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 433                                                 else if(self.health > 75) // TODO make a "gentle" version?
 434                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 435                                                 else if(self.health > 50)
 436                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 437                                                 else if(self.health > 25)
 438                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 439                                                 else
 440                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 441                                         }
 442                                 }
 443
 444                                 // throw off bot aim temporarily
 445                                 float shake;
 446                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 447                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 448                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 449                         }
 450                 }
 451                 else
 452                         self.max_armorvalue += (save + take);
 453         }
 454         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 455         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 456         self.dmg_inflictor = inflictor;
 457
 458         float abot, vbot, awep;
 459         abot = (IS_BOT_CLIENT(attacker));
 460         vbot = (IS_BOT_CLIENT(self));
 461
 462         valid_damage_for_weaponstats = 0;
 463         awep = 0;
 464
 465         if(vbot || IS_REAL_CLIENT(self))
 466         if(abot || IS_REAL_CLIENT(attacker))
 467         if(attacker && self != attacker)
 468         if(DIFF_TEAM(self, attacker))
 469         {
 470                 if(DEATH_ISSPECIAL(deathtype))
 471                         awep = attacker.weapon;
 472                 else
 473                         awep = DEATH_WEAPONOF(deathtype);
 474                 valid_damage_for_weaponstats = 1;
 475         }
 476
 477         if(valid_damage_for_weaponstats)
 478         {
 479                 dh = dh - max(self.health, 0);
 480                 da = da - max(self.armorvalue, 0);
 481                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 482         }
 483
 484         if (self.health < 1)
 485         {
 486                 float defer_ClientKill_Now_TeamChange;
 487                 defer_ClientKill_Now_TeamChange = FALSE;
 488
 489                 if(self.alivetime)
 490                 {
 491                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 492                         self.alivetime = 0;
 493                 }
 494
 495                 if(valid_damage_for_weaponstats)
 496                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 497
 498                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 499                 if(sound_allowed(MSG_BROADCAST, attacker))
 500                 {
 501                         if(deathtype == DEATH_DROWN)
 502                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 503                         else
 504                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 505                 }
 506
 507                 // get rid of kill indicator
 508                 if(self.killindicator)
 509                 {
 510                         remove(self.killindicator);
 511                         self.killindicator = world;
 512                         if(self.killindicator_teamchange)
 513                                 defer_ClientKill_Now_TeamChange = TRUE;
 514
 515                         if(self.classname == "body")
 516                         if(deathtype == DEATH_KILL)
 517                         {
 518                                 // for the lemmings fans, a small harmless explosion
 519                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 520                         }
 521                 }
 522
 523                 // print an obituary message
 524                 Obituary (attacker, inflictor, self, deathtype);
 525                 race_PreDie();
 526
 527         // increment frag counter for used weapon type
 528         float w;
 529         w = DEATH_WEAPONOF(deathtype);
 530         if(WEP_VALID(w))
 531         if(accuracy_isgooddamage(attacker, self))
 532         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 533
 534                 frag_attacker = attacker;
 535                 frag_inflictor = inflictor;
 536                 frag_target = self;
 537                 frag_deathtype = deathtype;
 538                 MUTATOR_CALLHOOK(PlayerDies);
 539
 540                 WEP_ACTION(self.weapon, WR_PLAYERDEATH);
 541
 542                 RemoveGrapplingHook(self);
 543
 544                 Portal_ClearAllLater(self);
 545
 546                 self.fixangle = TRUE;
 547
 548                 if(defer_ClientKill_Now_TeamChange)
 549                         ClientKill_Now_TeamChange(); // can turn player into spectator
 550
 551                 // player could have been miraculously resuscitated ;)
 552                 // e.g. players in freezetag get frozen, they don't really die
 553                 if(self.health >= 1 || !IS_PLAYER(self))
 554                         return;
 555
 556                 // when we get here, player actually dies
 557
 558                 // clear waypoints
 559                 WaypointSprite_PlayerDead();
 560                 // throw a weapon
 561                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 562
 563                 // become fully visible
 564                 self.alpha = default_player_alpha;
 565                 // make the corpse upright (not tilted)
 566                 self.angles_x = 0;
 567                 self.angles_z = 0;
 568                 // don't spin
 569                 self.avelocity = '0 0 0';
 570                 // view from the floor
 571                 self.view_ofs = '0 0 -8';
 572                 // toss the corpse
 573                 self.movetype = MOVETYPE_TOSS;
 574                 // shootable corpse
 575                 self.solid = SOLID_CORPSE;
 576                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 577                 // don't stick to the floor
 578                 self.flags &= ~FL_ONGROUND;
 579                 // dying animation
 580                 self.deadflag = DEAD_DYING;
 581                 // when to allow respawn
 582                 calculate_player_respawn_time();
 583
 584                 self.death_time = time;
 585                 if (random() < 0.5)
 586                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 587                 else
 588                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 589                 if (self.maxs_z > 5)
 590                 {
 591                         self.maxs_z = 5;
 592                         setsize(self, self.mins, self.maxs);
 593                 }
 594                 // set damage function to corpse damage
 595                 self.event_damage = PlayerCorpseDamage;
 596                 // call the corpse damage function just in case it wants to gib
 597                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 598                 // set up to fade out later
 599                 SUB_SetFade (self, time + 6 + random (), 1);
 600
 601                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 602                         // remove corpse
 603                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 604                 }
 605
 606                 // reset fields the weapons may use just in case
 607                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 608                 {
 609                         WEP_ACTION(j, WR_RESETPLAYER);
 610                         ATTACK_FINISHED_FOR(self, j) = 0;
 611                 }
 612         }
 613 }
 614
 615 .float muted; // to be used by prvm_edictset server playernumber muted 1
 616 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 617 // message "": do not say, just test flood control
 618 // return value:
 619 //   1 = accept
 620 //   0 = reject
 621 //  -1 = fake accept
 622 {
 623         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 624         float flood;
 625         var .float flood_field;
 626         entity head;
 627         float ret;
 628         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 629
 630         if(!teamsay && !privatesay)
 631                 if(substring(msgin, 0, 1) == " ")
 632                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 633
 634         msgin = formatmessage(msgin);
 635
 636         if (!IS_PLAYER(source))
 637                 colorstr = "^0"; // black for spectators
 638         else if(teamplay)
 639                 colorstr = Team_ColorCode(source.team);
 640         else
 641         {
 642                 colorstr = "";
 643                 teamsay = FALSE;
 644         }
 645
 646         if(intermission_running)
 647                 teamsay = FALSE;
 648
 649         if(msgin != "")
 650                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 651
 652         /*
 653          * using bprint solves this... me stupid
 654         // how can we prevent the message from appearing in a listen server?
 655         // for now, just give "say" back and only handle say_team
 656         if(!teamsay)
 657         {
 658                 clientcommand(self, strcat("say ", msgin));
 659                 return;
 660         }
 661         */
 662
 663         if(autocvar_g_chat_teamcolors)
 664                 namestr = playername(source);
 665         else
 666                 namestr = source.netname;
 667
 668         if(strdecolorize(namestr) == namestr)
 669                 colorprefix = "^3";
 670         else
 671                 colorprefix = "^7";
 672
 673         if(msgin != "")
 674         {
 675                 if(privatesay)
 676                 {
 677                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 678                         privatemsgprefixlen = strlen(msgstr);
 679                         msgstr = strcat(msgstr, msgin);
 680                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 681                         if(autocvar_g_chat_teamcolors)
 682                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 683                         else
 684                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 685                 }
 686                 else if(teamsay)
 687                 {
 688                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 689                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 690                 }
 691                 else
 692                 {
 693                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 694                         cmsgstr = "";
 695                 }
 696                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 697         }
 698         else
 699         {
 700                 msgstr = cmsgstr = "";
 701         }
 702
 703         fullmsgstr = msgstr;
 704         fullcmsgstr = cmsgstr;
 705
 706         // FLOOD CONTROL
 707         flood = 0;
 708         flood_field = floodcontrol_chat;
 709         if(floodcontrol)
 710         {
 711                 float flood_spl;
 712                 float flood_burst;
 713                 float flood_lmax;
 714                 float lines;
 715                 if(privatesay)
 716                 {
 717                         flood_spl = autocvar_g_chat_flood_spl_tell;
 718                         flood_burst = autocvar_g_chat_flood_burst_tell;
 719                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 720                         flood_field = floodcontrol_chattell;
 721                 }
 722                 else if(teamsay)
 723                 {
 724                         flood_spl = autocvar_g_chat_flood_spl_team;
 725                         flood_burst = autocvar_g_chat_flood_burst_team;
 726                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 727                         flood_field = floodcontrol_chatteam;
 728                 }
 729                 else
 730                 {
 731                         flood_spl = autocvar_g_chat_flood_spl;
 732                         flood_burst = autocvar_g_chat_flood_burst;
 733                         flood_lmax = autocvar_g_chat_flood_lmax;
 734                         flood_field = floodcontrol_chat;
 735                 }
 736                 flood_burst = max(0, flood_burst - 1);
 737                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 738
 739                 // do flood control for the default line size
 740                 if(msgstr != "")
 741                 {
 742                         getWrappedLine_remaining = msgstr;
 743                         msgstr = "";
 744                         lines = 0;
 745                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 746                         {
 747                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 748                                 ++lines;
 749                         }
 750                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 751
 752                         if(getWrappedLine_remaining != "")
 753                         {
 754                                 msgstr = strcat(msgstr, "\n");
 755                                 flood = 2;
 756                         }
 757
 758                         if(time >= source.flood_field)
 759                         {
 760                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 761                         }
 762                         else
 763                         {
 764                                 flood = 1;
 765                                 msgstr = fullmsgstr;
 766                         }
 767                 }
 768                 else
 769                 {
 770                         if(time >= source.flood_field)
 771                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 772                         else
 773                                 flood = 1;
 774                 }
 775
 776                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 777                         source.flood_field = flood = 0;
 778         }
 779
 780         if(flood == 2) // cannot happen for empty msgstr
 781         {
 782                 if(autocvar_g_chat_flood_notify_flooder)
 783                 {
 784                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 785                         sourcecmsgstr = "";
 786                 }
 787                 else
 788                 {
 789                         sourcemsgstr = fullmsgstr;
 790                         sourcecmsgstr = fullcmsgstr;
 791                 }
 792                 cmsgstr = "";
 793         }
 794         else
 795         {
 796                 sourcemsgstr = msgstr;
 797                 sourcecmsgstr = cmsgstr;
 798         }
 799
 800         if(!privatesay)
 801         if (!IS_PLAYER(source))
 802         {
 803                 if (!intermission_running)
 804                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 805                                 teamsay = -1; // spectators
 806         }
 807
 808         if(flood)
 809                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 810
 811         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 812         if(privatesay)
 813                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 814
 815         if(source.muted)
 816         {
 817                 // always fake the message
 818                 ret = -1;
 819         }
 820         else if(flood == 1)
 821         {
 822                 if(autocvar_g_chat_flood_notify_flooder)
 823                 {
 824                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 825                         ret = 0;
 826                 }
 827                 else
 828                         ret = -1;
 829         }
 830         else
 831         {
 832                 ret = 1;
 833         }
 834
 835         if(sourcemsgstr != "" && ret != 0)
 836         {
 837                 if(ret < 0) // faked message, because the player is muted
 838                 {
 839                         sprint(source, sourcemsgstr);
 840                         if(sourcecmsgstr != "" && !privatesay)
 841                                 centerprint(source, sourcecmsgstr);
 842                 }
 843                 else if(privatesay) // private message, between 2 people only
 844                 {
 845                         sprint(source, sourcemsgstr);
 846                         sprint(privatesay, msgstr);
 847                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 848                         if(cmsgstr != "")
 849                                 centerprint(privatesay, cmsgstr);
 850                 }
 851                 else if(teamsay > 0) // team message, only sent to team mates
 852                 {
 853                         sprint(source, sourcemsgstr);
 854                         dedicated_print(msgstr); // send to server console too
 855                         if(sourcecmsgstr != "")
 856                                 centerprint(source, sourcecmsgstr);
 857                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 858                                 if(head != source)
 859                                 {
 860                                         sprint(head, msgstr);
 861                                         if(cmsgstr != "")
 862                                                 centerprint(head, cmsgstr);
 863                                 }
 864                 }
 865                 else if(teamsay < 0) // spectator message, only sent to spectators
 866                 {
 867                         sprint(source, sourcemsgstr);
 868                         dedicated_print(msgstr); // send to server console too
 869                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
 870                                 if(head != source)
 871                                         sprint(head, msgstr);
 872                 }
 873                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 874                 {
 875                         sprint(source, sourcemsgstr);
 876                         dedicated_print(msgstr); // send to server console too
 877                         FOR_EACH_REALCLIENT(head)
 878                                 if(head != source)
 879                                         sprint(head, msgstr);
 880                 }
 881                 else
 882                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 883         }
 884
 885         return ret;
 886 }
 887
 888 float GetVoiceMessageVoiceType(string type)
 889 {
 890         if(type == "taunt")
 891                 return VOICETYPE_TAUNT;
 892         if(type == "teamshoot")
 893                 return VOICETYPE_LASTATTACKER;
 894         return VOICETYPE_TEAMRADIO;
 895 }
 896
 897 string allvoicesamples;
 898 .string GetVoiceMessageSampleField(string type)
 899 {
 900         GetPlayerSoundSampleField_notFound = 0;
 901         switch(type)
 902         {
 903 #define _VOICEMSG(m) case #m: return playersound_##m;
 904                 ALLVOICEMSGS
 905 #undef _VOICEMSG
 906         }
 907         GetPlayerSoundSampleField_notFound = 1;
 908         return playersound_taunt;
 909 }
 910
 911 .string GetPlayerSoundSampleField(string type)
 912 {
 913         GetPlayerSoundSampleField_notFound = 0;
 914         switch(type)
 915         {
 916 #define _VOICEMSG(m) case #m: return playersound_##m;
 917                 ALLPLAYERSOUNDS
 918 #undef _VOICEMSG
 919         }
 920         GetPlayerSoundSampleField_notFound = 1;
 921         return playersound_taunt;
 922 }
 923
 924 void PrecacheGlobalSound(string samplestring)
 925 {
 926         float n, i;
 927         tokenize_console(samplestring);
 928         n = stof(argv(1));
 929         if(n > 0)
 930         {
 931                 for(i = 1; i <= n; ++i)
 932                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 933         }
 934         else
 935         {
 936                 precache_sound(strcat(argv(0), ".wav"));
 937         }
 938 }
 939
 940 void PrecachePlayerSounds(string f)
 941 {
 942         float fh;
 943         string s;
 944         fh = fopen(f, FILE_READ);
 945         if(fh < 0)
 946                 return;
 947         while((s = fgets(fh)))
 948         {
 949                 if(tokenize_console(s) != 3)
 950                 {
 951                         dprint("Invalid sound info line: ", s, "\n");
 952                         continue;
 953                 }
 954                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 955         }
 956         fclose(fh);
 957
 958         if (!allvoicesamples)
 959         {
 960 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
 961                 ALLVOICEMSGS
 962 #undef _VOICEMSG
 963                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
 964         }
 965 }
 966
 967 void ClearPlayerSounds()
 968 {
 969 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 970         ALLPLAYERSOUNDS
 971         ALLVOICEMSGS
 972 #undef _VOICEMSG
 973 }
 974
 975 float LoadPlayerSounds(string f, float first)
 976 {
 977         float fh;
 978         string s;
 979         var .string field;
 980         fh = fopen(f, FILE_READ);
 981         if(fh < 0)
 982         {
 983                 dprint("Player sound file not found: ", f, "\n");
 984                 return 0;
 985         }
 986         while((s = fgets(fh)))
 987         {
 988                 if(tokenize_console(s) != 3)
 989                         continue;
 990                 field = GetPlayerSoundSampleField(argv(0));
 991                 if(GetPlayerSoundSampleField_notFound)
 992                         field = GetVoiceMessageSampleField(argv(0));
 993                 if(GetPlayerSoundSampleField_notFound)
 994                         continue;
 995                 if(self.field)
 996                         strunzone(self.field);
 997                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 998         }
 999         fclose(fh);
1000         return 1;
1001 }
1002
1003 .float modelindex_for_playersound;
1004 .float skin_for_playersound;
1005 void UpdatePlayerSounds()
1006 {
1007         if(self.modelindex == self.modelindex_for_playersound)
1008         if(self.skin == self.skin_for_playersound)
1009                 return;
1010         self.modelindex_for_playersound = self.modelindex;
1011         self.skin_for_playersound = self.skin;
1012         ClearPlayerSounds();
1013         LoadPlayerSounds("sound/player/default.sounds", 1);
1014         if(!autocvar_g_debug_defaultsounds)
1015                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1016                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1017 }
1018
1019 void FakeGlobalSound(string sample, float chan, float voicetype)
1020 {
1021         float n;
1022         float tauntrand;
1023
1024         if(sample == "")
1025                 return;
1026
1027         tokenize_console(sample);
1028         n = stof(argv(1));
1029         if(n > 0)
1030                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1031         else
1032                 sample = strcat(argv(0), ".wav"); // randomization
1033
1034         switch(voicetype)
1035         {
1036                 case VOICETYPE_LASTATTACKER_ONLY:
1037                         break;
1038                 case VOICETYPE_LASTATTACKER:
1039                         if(self.pusher)
1040                         {
1041                                 msg_entity = self;
1042                                 if(IS_REAL_CLIENT(msg_entity))
1043                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1044                         }
1045                         break;
1046                 case VOICETYPE_TEAMRADIO:
1047                         msg_entity = self;
1048                         if(msg_entity.cvar_cl_voice_directional == 1)
1049                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1050                         else
1051                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1052                         break;
1053                 case VOICETYPE_AUTOTAUNT:
1054                         if(!sv_autotaunt)
1055                                 break;
1056                         if(!sv_taunt)
1057                                 break;
1058                         if(autocvar_sv_gentle)
1059                                 break;
1060                         tauntrand = random();
1061                         msg_entity = self;
1062                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1063                         {
1064                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1065                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1066                                 else
1067                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1068                         }
1069                         break;
1070                 case VOICETYPE_TAUNT:
1071                         if(IS_PLAYER(self))
1072                                 if(self.deadflag == DEAD_NO)
1073                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1074                         if(!sv_taunt)
1075                                 break;
1076                         if(autocvar_sv_gentle)
1077                                 break;
1078                         msg_entity = self;
1079                         if (msg_entity.cvar_cl_voice_directional >= 1)
1080                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1081                         else
1082                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1083                         break;
1084                 case VOICETYPE_PLAYERSOUND:
1085                         msg_entity = self;
1086                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1087                         break;
1088                 default:
1089                         backtrace("Invalid voice type!");
1090                         break;
1091         }
1092 }
1093
1094 void GlobalSound(string sample, float chan, float voicetype)
1095 {
1096         float n;
1097         float tauntrand;
1098
1099         if(sample == "")
1100                 return;
1101
1102         tokenize_console(sample);
1103         n = stof(argv(1));
1104         if(n > 0)
1105                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1106         else
1107                 sample = strcat(argv(0), ".wav"); // randomization
1108
1109         switch(voicetype)
1110         {
1111                 case VOICETYPE_LASTATTACKER_ONLY:
1112                         if(self.pusher)
1113                         {
1114                                 msg_entity = self.pusher;
1115                                 if(IS_REAL_CLIENT(msg_entity))
1116                                 {
1117                                         if(msg_entity.cvar_cl_voice_directional == 1)
1118                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1119                                         else
1120                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1121                                 }
1122                         }
1123                         break;
1124                 case VOICETYPE_LASTATTACKER:
1125                         if(self.pusher)
1126                         {
1127                                 msg_entity = self.pusher;
1128                                 if(IS_REAL_CLIENT(msg_entity))
1129                                 {
1130                                         if(msg_entity.cvar_cl_voice_directional == 1)
1131                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1132                                         else
1133                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1134                                 }
1135                                 msg_entity = self;
1136                                 if(IS_REAL_CLIENT(msg_entity))
1137                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1138                         }
1139                         break;
1140                 case VOICETYPE_TEAMRADIO:
1141                         FOR_EACH_REALCLIENT(msg_entity)
1142                                 if(!teamplay || msg_entity.team == self.team)
1143                                 {
1144                                         if(msg_entity.cvar_cl_voice_directional == 1)
1145                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1146                                         else
1147                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1148                                 }
1149                         break;
1150                 case VOICETYPE_AUTOTAUNT:
1151                         if(!sv_autotaunt)
1152                                 break;
1153                         if(!sv_taunt)
1154                                 break;
1155                         if(autocvar_sv_gentle)
1156                                 break;
1157                         tauntrand = random();
1158                         FOR_EACH_REALCLIENT(msg_entity)
1159                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1160                                 {
1161                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1162                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1163                                         else
1164                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1165                                 }
1166                         break;
1167                 case VOICETYPE_TAUNT:
1168                         if(IS_PLAYER(self))
1169                                 if(self.deadflag == DEAD_NO)
1170                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1171                         if(!sv_taunt)
1172                                 break;
1173                         if(autocvar_sv_gentle)
1174                                 break;
1175                         FOR_EACH_REALCLIENT(msg_entity)
1176                         {
1177                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1178                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1179                                 else
1180                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1181                         }
1182                         break;
1183                 case VOICETYPE_PLAYERSOUND:
1184                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1185                         break;
1186                 default:
1187                         backtrace("Invalid voice type!");
1188                         break;
1189         }
1190 }
1191
1192 void PlayerSound(.string samplefield, float chan, float voicetype)
1193 {
1194         GlobalSound(self.samplefield, chan, voicetype);
1195 }
1196
1197 void VoiceMessage(string type, string msg)
1198 {
1199         var .string sample;
1200         float voicetype, ownteam;
1201         float flood;
1202         sample = GetVoiceMessageSampleField(type);
1203
1204         if(GetPlayerSoundSampleField_notFound)
1205         {
1206                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1207                 return;
1208         }
1209
1210         voicetype = GetVoiceMessageVoiceType(type);
1211         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1212
1213         flood = Say(self, ownteam, world, msg, 1);
1214
1215         if (flood > 0)
1216                 GlobalSound(self.sample, CH_VOICE, voicetype);
1217         else if (flood < 0)
1218                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1219 }
1220
1221 void MoveToTeam(entity client, float team_colour, float type)
1222 {
1223         float lockteams_backup;
1224
1225         lockteams_backup = lockteams;  // backup any team lock
1226
1227         lockteams = 0;  // disable locked teams
1228
1229         TeamchangeFrags(client);  // move the players frags
1230         SetPlayerColors(client, team_colour - 1);  // set the players colour
1231         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1232
1233         lockteams = lockteams_backup;  // restore the team lock
1234
1235         LogTeamchange(client.playerid, client.team, type);
1236 }