qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_killfile != "" || autocvar_sv_weaponstats_damagefile != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(autocvar_sv_weaponstats_killfile != "")
  22         {
  23                 fh = fopen(autocvar_sv_weaponstats_killfile, FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(autocvar_sv_weaponstats_damagefile != "")
  43         {
  44                 fh = fopen(autocvar_sv_weaponstats_damagefile, FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.model, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389 void freezetag_CheckWinner();
 390 void freezetag_Unfreeze();
 391
 392 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 393 {
 394         local float take, save, waves, sdelay, dh, da, j;
 395         vector v;
 396         float valid_damage_for_weaponstats;
 397
 398         dh = max(self.health, 0);
 399         da = max(self.armorvalue, 0);
 400
 401         if(!DEATH_ISSPECIAL(deathtype))
 402         {
 403                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 404                 if(self != attacker)
 405                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 406         }
 407
 408         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 409         {
 410                 // tuba causes blood to come out of the ears
 411                 vector ear1, ear2;
 412                 vector d;
 413                 float f;
 414                 ear1 = self.origin;
 415                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 416                 ear2 = ear1;
 417                 makevectors(self.angles);
 418                 ear1 += v_right * -10;
 419                 ear2 += v_right * +10;
 420                 d = inflictor.origin - self.origin;
 421                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 422                 force = v_right * vlen(force);
 423                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 424                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 425                 if(f > 0)
 426                 {
 427                         hitloc = ear1;
 428                         force = force * -1;
 429                 }
 430                 else
 431                 {
 432                         hitloc = ear2;
 433                         // force is already good
 434                 }
 435         }
 436         else
 437                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 438
 439         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 440                 return;
 441
 442         if (!g_minstagib)
 443         {
 444                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 445                 take = v_x;
 446                 save = v_y;
 447         }
 448         else
 449         {
 450                 save = 0;
 451                 take = damage;
 452         }
 453
 454         frag_inflictor = inflictor;
 455         frag_attacker = attacker;
 456         frag_target = self;
 457         damage_take = take;
 458         damage_save = save;
 459         damage_force = force;
 460         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 461         take = bound(0, damage_take, self.health);
 462         save = bound(0, damage_save, self.armorvalue);
 463
 464         if(sound_allowed(MSG_BROADCAST, attacker))
 465         {
 466                 if (save > 10)
 467                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 468                 else if (take > 30)
 469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 470                 else if (take > 10)
 471                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 472         }
 473
 474         if (take > 50)
 475                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 476         if (take > 100)
 477                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 478
 479         if (time >= self.spawnshieldtime)
 480         {
 481                 if (!(self.flags & FL_GODMODE))
 482                 {
 483                         self.armorvalue = self.armorvalue - save;
 484                         self.health = self.health - take;
 485                         // pause regeneration for 5 seconds
 486                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 487
 488                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 489                         {
 490                                 self.pain_finished = time + 0.5;        //Supajoe
 491
 492                                 if(sv_gentle < 1) {
 493                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 494                                         {
 495                                                 if (random() > 0.5)
 496                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 497                                                 else
 498                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 499                                         }
 500
 501                                         if(sound_allowed(MSG_BROADCAST, attacker))
 502                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 503                                         if(self.health > 1)
 504                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 505                                         {
 506                                                 if(deathtype == DEATH_FALL)
 507                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else if(self.health > 75) // TODO make a "gentle" version?
 509                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                                 else if(self.health > 50)
 511                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else if(self.health > 25)
 513                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                                 else
 515                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 516                                         }
 517                                 }
 518
 519                                 // throw off bot aim temporarily
 520                                 local float shake;
 521                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 522                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 523                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 524                         }
 525                 }
 526                 else
 527                         self.max_armorvalue += (save + take);
 528         }
 529         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 530         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 531         self.dmg_inflictor = inflictor;
 532
 533         if(attacker == self)
 534         {
 535                 // don't reset pushltime for self damage as it may be an attempt to
 536                 // escape a lava pit or similar
 537                 //self.pushltime = 0;
 538         }
 539         else if(attacker.classname == "player" || attacker.classname == "gib")
 540         {
 541                 self.pusher = attacker;
 542                 self.pushltime = time + autocvar_g_maxpushtime;
 543         }
 544         else if(time < self.pushltime)
 545         {
 546                 attacker = self.pusher;
 547                 self.pushltime = max(self.pushltime, time + 0.6);
 548         }
 549         else
 550                 self.pushltime = 0;
 551
 552         valid_damage_for_weaponstats = 0;
 553         if(clienttype(self) == CLIENTTYPE_REAL)
 554         if(clienttype(attacker) == CLIENTTYPE_REAL)
 555         if(self != attacker)
 556         if(!DEATH_ISSPECIAL(deathtype))
 557         if(IsDifferentTeam(self, attacker))
 558                 valid_damage_for_weaponstats = 1;
 559
 560         if(valid_damage_for_weaponstats)
 561         {
 562                 dh = dh - max(self.health, 0);
 563                 da = da - max(self.armorvalue, 0);
 564                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 565         }
 566
 567         if (self.health < 1)
 568         {
 569                 float defer_ClientKill_Now_TeamChange;
 570                 defer_ClientKill_Now_TeamChange = FALSE;
 571
 572                 if(self.alivetime)
 573                 {
 574                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 575                         self.alivetime = 0;
 576                 }
 577
 578                 if(valid_damage_for_weaponstats)
 579                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 580
 581                 if(sv_gentle < 1) // TODO make a "gentle" version?
 582                 if(sound_allowed(MSG_BROADCAST, attacker))
 583                 {
 584                         if(deathtype == DEATH_DROWN)
 585                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 586                         else
 587                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 588                 }
 589
 590                 // get rid of kill indicator
 591                 if(self.killindicator)
 592                 {
 593                         remove(self.killindicator);
 594                         self.killindicator = world;
 595                         if(self.killindicator_teamchange)
 596                                 defer_ClientKill_Now_TeamChange = TRUE;
 597
 598                         if(self.classname == "body")
 599                         if(deathtype == DEATH_KILL)
 600                         {
 601                                 // for the lemmings fans, a small harmless explosion
 602                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 603                         }
 604                 }
 605
 606                 if(!g_freezetag)
 607                 {
 608                         // become fully visible
 609                         self.alpha = 1;
 610                         // clear selected player display
 611                         ClearSelectedPlayer();
 612                         // throw a weapon
 613                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 614                 }
 615
 616                 // print an obituary message
 617                 Obituary (attacker, inflictor, self, deathtype);
 618                 race_PreDie();
 619                 DropAllRunes(self);
 620
 621                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 622                 {
 623                         PutClientInServer();
 624                         count_alive_players(); // re-count players
 625                         freezetag_CheckWinner();
 626                         return;
 627                 }
 628
 629                 frag_attacker = attacker;
 630                 frag_inflictor = inflictor;
 631                 frag_target = self;
 632                 MUTATOR_CALLHOOK(PlayerDies);
 633
 634                 if(self.flagcarried)
 635                 {
 636                         if(attacker.classname != "player" && attacker.classname != "gib")
 637                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 638                         else if(attacker.team == self.team)
 639                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 640                         else
 641                                 DropFlag(self.flagcarried, world, attacker);
 642                 }
 643                 if(self.ballcarried && g_nexball)
 644                         DropBall(self.ballcarried, self.origin, self.velocity);
 645                 Portal_ClearAllLater(self);
 646                 // clear waypoints
 647                 WaypointSprite_PlayerDead();
 648
 649                 if(clienttype(self) == CLIENTTYPE_REAL)
 650                 {
 651                         stuffcmd(self, "-zoom\n");
 652                         self.fixangle = TRUE;
 653                         //msg_entity = self;
 654                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 655                         //WriteAngle (MSG_ONE, self.v_angle_x);
 656                         //WriteAngle (MSG_ONE, self.v_angle_y);
 657                         //WriteAngle (MSG_ONE, 80);
 658                 }
 659
 660                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 661                         ClientKill_Now_TeamChange();
 662
 663                 if(g_arena)
 664                         Spawnqueue_Unmark(self);
 665
 666                 if(g_freezetag)
 667                         return;
 668
 669                 // make the corpse upright (not tilted)
 670                 self.angles_x = 0;
 671                 self.angles_z = 0;
 672                 // don't spin
 673                 self.avelocity = '0 0 0';
 674                 // view from the floor
 675                 self.view_ofs = '0 0 -8';
 676                 // toss the corpse
 677                 self.movetype = MOVETYPE_TOSS;
 678                 // shootable corpse
 679                 self.solid = SOLID_CORPSE;
 680                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 681                 // don't stick to the floor
 682                 self.flags &~= FL_ONGROUND;
 683                 // dying animation
 684                 self.deadflag = DEAD_DYING;
 685                 // when to allow respawn
 686                 sdelay = 0;
 687                 waves = 0;
 688                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 689                 if(!sdelay)
 690                 {
 691                         if(g_cts)
 692                                 sdelay = 0; // no respawn delay in CTS
 693                         else
 694                                 sdelay = autocvar_g_respawn_delay;
 695                 }
 696                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 697                 if(!waves)
 698                         waves = autocvar_g_respawn_waves;
 699                 if(waves)
 700                         self.death_time = ceil((time + sdelay) / waves) * waves;
 701                 else
 702                         self.death_time = time + sdelay;
 703                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 704                         self.respawn_countdown = 10; // first number to count down from is 10
 705                 else
 706                         self.respawn_countdown = -1; // do not count down
 707                 if (random() < 0.5)
 708                 {
 709                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 710                         self.dead_frame = self.anim_dead1_x;
 711                 }
 712                 else
 713                 {
 714                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 715                         self.dead_frame = self.anim_dead2_x;
 716                 }
 717                 // set damage function to corpse damage
 718                 self.event_damage = PlayerCorpseDamage;
 719                 // call the corpse damage function just in case it wants to gib
 720                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 721                 // set up to fade out later
 722                 SUB_SetFade (self, time + 6 + random (), 1);
 723
 724                 if(sv_gentle > 0 || autocvar_ekg) {
 725                         // remove corpse
 726                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 727                 }
 728
 729                 // reset fields the weapons may use just in case
 730                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 731                 {
 732                         weapon_action(j, WR_RESETPLAYER);
 733                         ATTACK_FINISHED_FOR(self, j) = 0;
 734                 }
 735         }
 736 }
 737
 738 float UpdateSelectedPlayer_countvalue(float v)
 739 {
 740         return max(0, (v - 1.0) / 0.5);
 741 }
 742
 743 // returns: -2 if no hit, otherwise cos of the angle
 744 // uses the global v_angle
 745 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 746 {
 747         vector so, d;
 748         float c;
 749
 750         if(p == self)
 751                 return -2;
 752
 753         if(p.deadflag)
 754                 return -2;
 755
 756         so = self.origin + self.view_ofs;
 757         d = p.origin - so;
 758
 759         // misaimed?
 760         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 761                 return -2;
 762
 763         // now find the cos of the angle...
 764         c = normalize(d) * v_forward;
 765
 766         if(c <= mincosangle)
 767                 return -2;
 768
 769         // not visible in any way? forget it
 770         if(!checkpvs(so, p))
 771                 return -2;
 772
 773         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 774         if(trace_fraction < 1)
 775                 return -2;
 776
 777         return c;
 778 }
 779
 780 void ClearSelectedPlayer()
 781 {
 782         if(self.selected_player)
 783         {
 784                 centerprint_expire(self, CENTERPRIO_POINT);
 785                 self.selected_player = world;
 786                 self.selected_player_display_needs_update = FALSE;
 787         }
 788 }
 789
 790 void UpdateSelectedPlayer()
 791 {
 792         entity selected;
 793         float selected_score;
 794         selected = world;
 795         selected_score = 0.95; // 18 degrees
 796
 797         if(!autocvar_sv_allow_shownames)
 798                 return;
 799
 800         if(clienttype(self) != CLIENTTYPE_REAL)
 801                 return;
 802
 803         if(self.cvar_cl_shownames == 0)
 804                 return;
 805
 806         if(self.cvar_cl_shownames == 1 && !teams_matter)
 807                 return;
 808
 809         makevectors(self.v_angle); // sets v_forward
 810
 811         // 1. cursor trace is always right
 812         WarpZone_crosshair_trace(self);
 813         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 814         {
 815                 selected = trace_ent;
 816         }
 817         else
 818         {
 819                 // 2. if we don't have a cursor trace, find the player which is least
 820                 //    mis-aimed at
 821                 entity p;
 822                 FOR_EACH_PLAYER(p)
 823                 {
 824                         float c;
 825                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 826                         if(c >= -1)
 827                         {
 828                                 selected = p;
 829                                 selected_score = c;
 830                         }
 831                 }
 832         }
 833
 834         if(selected)
 835         {
 836                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 837         }
 838         else
 839         {
 840                 if(time < self.selected_player_display_timeout)
 841                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 842                                 selected = self.selected_player;
 843         }
 844
 845         if(selected)
 846         {
 847                 if(selected == self.selected_player)
 848                 {
 849                         float save;
 850                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 851                         self.selected_player_count = self.selected_player_count + frametime;
 852                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 853                         {
 854                                 string namestr, healthstr;
 855                                 namestr = playername(selected);
 856                                 if(teams_matter)
 857                                 {
 858                                         healthstr = ftos(floor(selected.health));
 859                                         if(self.team == selected.team)
 860                                         {
 861                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 862                                                 self.selected_player_display_needs_update = TRUE;
 863                                         }
 864                                 }
 865                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 866                         }
 867                 }
 868                 else
 869                 {
 870                         ClearSelectedPlayer();
 871                         self.selected_player = selected;
 872                         self.selected_player_time = time;
 873                         self.selected_player_count = 0;
 874                         self.selected_player_display_needs_update = FALSE;
 875                 }
 876         }
 877         else
 878         {
 879                 ClearSelectedPlayer();
 880         }
 881
 882         if(self.selected_player)
 883                 self.last_selected_player = self.selected_player;
 884 }
 885
 886 .float muted; // to be used by prvm_edictset server playernumber muted 1
 887 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 888 // message "": do not say, just test flood control
 889 // return value:
 890 //   1 = accept
 891 //   0 = reject
 892 //  -1 = fake accept
 893 {
 894         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 895         float flood, privatemsgprefixlen;
 896         var .float flood_field;
 897         entity head;
 898         float ret;
 899
 900         if(Ban_MaybeEnforceBan(source))
 901                 return 0;
 902
 903         if(!teamsay && !privatesay)
 904                 if(substring(msgin, 0, 1) == " ")
 905                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 906
 907         msgin = formatmessage(msgin);
 908
 909         if(source.classname != "player")
 910                 colorstr = "^0"; // black for spectators
 911         else if(teams_matter)
 912                 colorstr = Team_ColorCode(source.team);
 913         else
 914                 teamsay = FALSE;
 915
 916         if(intermission_running)
 917                 teamsay = FALSE;
 918
 919         if(msgin != "")
 920                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 921
 922         /*
 923          * using bprint solves this... me stupid
 924         // how can we prevent the message from appearing in a listen server?
 925         // for now, just give "say" back and only handle say_team
 926         if(!teamsay)
 927         {
 928                 clientcommand(self, strcat("say ", msgin));
 929                 return;
 930         }
 931         */
 932
 933         if(autocvar_g_chat_teamcolors)
 934                 namestr = playername(source);
 935         else
 936                 namestr = source.netname;
 937
 938         if(msgin != "")
 939         {
 940                 if(privatesay)
 941                 {
 942                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 943                         privatemsgprefixlen = strlen(msgstr);
 944                         msgstr = strcat(msgstr, msgin);
 945                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 946                         if(autocvar_g_chat_teamcolors)
 947                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 948                         else
 949                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 950                 }
 951                 else if(teamsay)
 952                 {
 953                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 954                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 955                 }
 956                 else
 957                 {
 958                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 959                         cmsgstr = "";
 960                 }
 961                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 962         }
 963         else
 964         {
 965                 msgstr = cmsgstr = "";
 966         }
 967
 968         fullmsgstr = msgstr;
 969         fullcmsgstr = cmsgstr;
 970
 971         // FLOOD CONTROL
 972         flood = 0;
 973         if(floodcontrol)
 974         {
 975                 float flood_spl;
 976                 float flood_burst;
 977                 float flood_lmax;
 978                 float lines;
 979                 if(privatesay)
 980                 {
 981                         flood_spl = autocvar_g_chat_flood_spl_tell;
 982                         flood_burst = autocvar_g_chat_flood_burst_tell;
 983                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 984                         flood_field = floodcontrol_chattell;
 985                 }
 986                 else if(teamsay)
 987                 {
 988                         flood_spl = autocvar_g_chat_flood_spl_team;
 989                         flood_burst = autocvar_g_chat_flood_burst_team;
 990                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 991                         flood_field = floodcontrol_chatteam;
 992                 }
 993                 else
 994                 {
 995                         flood_spl = autocvar_g_chat_flood_spl;
 996                         flood_burst = autocvar_g_chat_flood_burst;
 997                         flood_lmax = autocvar_g_chat_flood_lmax;
 998                         flood_field = floodcontrol_chat;
 999                 }
1000                 flood_burst = max(0, flood_burst - 1);
1001                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1002
1003                 // do flood control for the default line size
1004                 if(msgstr != "")
1005                 {
1006                         getWrappedLine_remaining = msgstr;
1007                         msgstr = "";
1008                         lines = 0;
1009                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1010                         {
1011                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1012                                 ++lines;
1013                         }
1014                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1015
1016                         if(getWrappedLine_remaining != "")
1017                         {
1018                                 msgstr = strcat(msgstr, "\n");
1019                                 flood = 2;
1020                         }
1021
1022                         if(time >= source.flood_field)
1023                         {
1024                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1025                         }
1026                         else
1027                         {
1028                                 flood = 1;
1029                                 msgstr = fullmsgstr;
1030                         }
1031                 }
1032                 else
1033                 {
1034                         if(time >= source.flood_field)
1035                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1036                         else
1037                                 flood = 1;
1038                 }
1039
1040                 if (timeoutStatus == 2) //when game is paused, no flood protection
1041                         source.flood_field = flood = 0;
1042         }
1043
1044         if(flood == 2) // cannot happen for empty msgstr
1045         {
1046                 if(autocvar_g_chat_flood_notify_flooder)
1047                 {
1048                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1049                         sourcecmsgstr = "";
1050                 }
1051                 else
1052                 {
1053                         sourcemsgstr = fullmsgstr;
1054                         sourcecmsgstr = fullcmsgstr;
1055                 }
1056                 cmsgstr = "";
1057         }
1058         else
1059         {
1060                 sourcemsgstr = msgstr;
1061                 sourcecmsgstr = cmsgstr;
1062         }
1063
1064         if(!privatesay)
1065         if(source.classname != "player")
1066         {
1067                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1068                         teamsay = -1; // spectators
1069         }
1070
1071         if(flood)
1072                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1073
1074         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1075         if(privatesay)
1076                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1077
1078         if(source.muted)
1079         {
1080                 // always fake the message
1081                 ret = -1;
1082         }
1083         else if(flood == 1)
1084         {
1085                 if(autocvar_g_chat_flood_notify_flooder)
1086                 {
1087                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1088                         ret = 0;
1089                 }
1090                 else
1091                         ret = -1;
1092         }
1093         else
1094         {
1095                 ret = 1;
1096         }
1097
1098         if(sourcemsgstr != "" && ret != 0)
1099         {
1100                 if(ret < 0) // fake
1101                 {
1102                         sprint(source, sourcemsgstr);
1103                         if(sourcecmsgstr != "" && !privatesay)
1104                                 centerprint(source, sourcecmsgstr);
1105                 }
1106                 else if(privatesay)
1107                 {
1108                         sprint(source, sourcemsgstr);
1109                         sprint(privatesay, msgstr);
1110                         if(cmsgstr != "")
1111                                 centerprint(privatesay, cmsgstr);
1112                 }
1113                 else if(teamsay > 0)
1114                 {
1115                         sprint(source, sourcemsgstr);
1116                         if(sourcecmsgstr != "")
1117                                 centerprint(source, sourcecmsgstr);
1118                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1119                                 if(head != source)
1120                                 {
1121                                         sprint(head, msgstr);
1122                                         if(cmsgstr != "")
1123                                                 centerprint(head, cmsgstr);
1124                                 }
1125                 }
1126                 else if(teamsay < 0)
1127                 {
1128                         sprint(source, sourcemsgstr);
1129                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1130                                 if(head != source)
1131                                         sprint(head, msgstr);
1132                 }
1133                 else if(sourcemsgstr != msgstr)
1134                 {
1135                         sprint(source, sourcemsgstr);
1136                         FOR_EACH_REALCLIENT(head)
1137                                 if(head != source)
1138                                         sprint(head, msgstr);
1139                 }
1140                 else
1141                         bprint(msgstr);
1142         }
1143
1144         return ret;
1145 }
1146
1147 float GetVoiceMessageVoiceType(string type)
1148 {
1149         if(type == "taunt")
1150                 return VOICETYPE_TAUNT;
1151         if(type == "teamshoot")
1152                 return VOICETYPE_LASTATTACKER;
1153         return VOICETYPE_TEAMRADIO;
1154 }
1155
1156 string allvoicesamples;
1157 .string GetVoiceMessageSampleField(string type)
1158 {
1159         GetPlayerSoundSampleField_notFound = 0;
1160         switch(type)
1161         {
1162 #define _VOICEMSG(m) case #m: return playersound_##m;
1163                 ALLVOICEMSGS
1164 #undef _VOICEMSG
1165         }
1166         GetPlayerSoundSampleField_notFound = 1;
1167         return playersound_taunt;
1168 }
1169
1170 .string GetPlayerSoundSampleField(string type)
1171 {
1172         GetPlayerSoundSampleField_notFound = 0;
1173         switch(type)
1174         {
1175 #define _VOICEMSG(m) case #m: return playersound_##m;
1176                 ALLPLAYERSOUNDS
1177 #undef _VOICEMSG
1178         }
1179         GetPlayerSoundSampleField_notFound = 1;
1180         return playersound_taunt;
1181 }
1182
1183 void PrecacheGlobalSound(string samplestring)
1184 {
1185         float n, i;
1186         tokenize_console(samplestring);
1187         n = stof(argv(1));
1188         if(n > 0)
1189         {
1190                 for(i = 1; i <= n; ++i)
1191                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1192         }
1193         else
1194         {
1195                 precache_sound(strcat(argv(0), ".wav"));
1196         }
1197 }
1198
1199 void PrecachePlayerSounds(string f)
1200 {
1201         float fh;
1202         string s;
1203         fh = fopen(f, FILE_READ);
1204         if(fh < 0)
1205                 return;
1206         while((s = fgets(fh)))
1207         {
1208                 if(tokenize_console(s) != 3)
1209                 {
1210                         dprint("Invalid sound info line: ", s, "\n");
1211                         continue;
1212                 }
1213                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1214         }
1215         fclose(fh);
1216
1217         if not(allvoicesamples)
1218         {
1219 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1220                 ALLVOICEMSGS
1221 #undef _VOICEMSG
1222                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1223         }
1224 }
1225
1226 void ClearPlayerSounds()
1227 {
1228 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1229         ALLPLAYERSOUNDS
1230         ALLVOICEMSGS
1231 #undef _VOICEMSG
1232 }
1233
1234 float LoadPlayerSounds(string f, float first)
1235 {
1236         float fh;
1237         string s;
1238         var .string field;
1239         fh = fopen(f, FILE_READ);
1240         if(fh < 0)
1241         {
1242                 dprint("Player sound file not found: ", f, "\n");
1243                 return 0;
1244         }
1245         while((s = fgets(fh)))
1246         {
1247                 if(tokenize_console(s) != 3)
1248                         continue;
1249                 field = GetPlayerSoundSampleField(argv(0));
1250                 if(GetPlayerSoundSampleField_notFound)
1251                         field = GetVoiceMessageSampleField(argv(0));
1252                 if(GetPlayerSoundSampleField_notFound)
1253                         continue;
1254                 if(self.field)
1255                         strunzone(self.field);
1256                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1257         }
1258         fclose(fh);
1259         return 1;
1260 }
1261
1262 .float modelindex_for_playersound;
1263 .float skinindex_for_playersound;
1264 void UpdatePlayerSounds()
1265 {
1266         if(self.modelindex == self.modelindex_for_playersound)
1267         if(self.skinindex == self.skinindex_for_playersound)
1268                 return;
1269         self.modelindex_for_playersound = self.modelindex;
1270         self.skinindex_for_playersound = self.skinindex;
1271         ClearPlayerSounds();
1272         LoadPlayerSounds("sound/player/default.sounds", 1);
1273         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1274                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1275 }
1276
1277 void FakeGlobalSound(string sample, float chan, float voicetype)
1278 {
1279         float n;
1280         float tauntrand;
1281
1282         if(sample == "")
1283                 return;
1284
1285         tokenize_console(sample);
1286         n = stof(argv(1));
1287         if(n > 0)
1288                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1289         else
1290                 sample = strcat(argv(0), ".wav"); // randomization
1291
1292         switch(voicetype)
1293         {
1294                 case VOICETYPE_LASTATTACKER_ONLY:
1295                         break;
1296                 case VOICETYPE_LASTATTACKER:
1297                         if(self.pusher)
1298                         {
1299                                 msg_entity = self;
1300                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1301                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1302                         }
1303                         break;
1304                 case VOICETYPE_TEAMRADIO:
1305                         msg_entity = self;
1306                         if(msg_entity.cvar_cl_voice_directional == 1)
1307                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1308                         else
1309                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1310                         break;
1311                 case VOICETYPE_AUTOTAUNT:
1312                         if(!sv_autotaunt)
1313                                 break;
1314                         if(!sv_taunt)
1315                                 break;
1316                         if(sv_gentle)
1317                                 break;
1318                         tauntrand = random();
1319                         msg_entity = self;
1320                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1321                         {
1322                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1323                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1324                                 else
1325                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1326                         }
1327                         break;
1328                 case VOICETYPE_TAUNT:
1329                         if(self.classname == "player")
1330                                 if(self.deadflag == DEAD_NO)
1331                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1332                         if(!sv_taunt)
1333                                 break;
1334                         if(sv_gentle)
1335                                 break;
1336                         msg_entity = self;
1337                         if (msg_entity.cvar_cl_voice_directional >= 1)
1338                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1339                         else
1340                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1341                         break;
1342                 case VOICETYPE_PLAYERSOUND:
1343                         msg_entity = self;
1344                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1345                         break;
1346                 default:
1347                         backtrace("Invalid voice type!");
1348                         break;
1349         }
1350 }
1351
1352 void GlobalSound(string sample, float chan, float voicetype)
1353 {
1354         float n;
1355         float tauntrand;
1356
1357         if(sample == "")
1358                 return;
1359
1360         tokenize_console(sample);
1361         n = stof(argv(1));
1362         if(n > 0)
1363                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1364         else
1365                 sample = strcat(argv(0), ".wav"); // randomization
1366
1367         switch(voicetype)
1368         {
1369                 case VOICETYPE_LASTATTACKER_ONLY:
1370                         if(self.pusher)
1371                         {
1372                                 msg_entity = self.pusher;
1373                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1374                                 {
1375                                         if(msg_entity.cvar_cl_voice_directional == 1)
1376                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1377                                         else
1378                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1379                                 }
1380                         }
1381                         break;
1382                 case VOICETYPE_LASTATTACKER:
1383                         if(self.pusher)
1384                         {
1385                                 msg_entity = self.pusher;
1386                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1387                                 {
1388                                         if(msg_entity.cvar_cl_voice_directional == 1)
1389                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1390                                         else
1391                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1392                                 }
1393                                 msg_entity = self;
1394                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1395                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1396                         }
1397                         break;
1398                 case VOICETYPE_TEAMRADIO:
1399                         FOR_EACH_REALCLIENT(msg_entity)
1400                                 if(!teams_matter || msg_entity.team == self.team)
1401                                 {
1402                                         if(msg_entity.cvar_cl_voice_directional == 1)
1403                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1404                                         else
1405                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1406                                 }
1407                         break;
1408                 case VOICETYPE_AUTOTAUNT:
1409                         if(!sv_autotaunt)
1410                                 break;
1411                         if(!sv_taunt)
1412                                 break;
1413                         if(sv_gentle)
1414                                 break;
1415                         tauntrand = random();
1416                         FOR_EACH_REALCLIENT(msg_entity)
1417                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1418                                 {
1419                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1420                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1421                                         else
1422                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1423                                 }
1424                         break;
1425                 case VOICETYPE_TAUNT:
1426                         if(self.classname == "player")
1427                                 if(self.deadflag == DEAD_NO)
1428                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1429                         if(!sv_taunt)
1430                                 break;
1431                         if(sv_gentle)
1432                                 break;
1433                         FOR_EACH_REALCLIENT(msg_entity)
1434                         {
1435                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1436                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1437                                 else
1438                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1439                         }
1440                         break;
1441                 case VOICETYPE_PLAYERSOUND:
1442                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1443                         break;
1444                 default:
1445                         backtrace("Invalid voice type!");
1446                         break;
1447         }
1448 }
1449
1450 void PlayerSound(.string samplefield, float chan, float voicetype)
1451 {
1452         GlobalSound(self.samplefield, chan, voicetype);
1453 }
1454
1455 void VoiceMessage(string type, string msg)
1456 {
1457         var .string sample;
1458         float voicetype, ownteam;
1459         float flood;
1460         sample = GetVoiceMessageSampleField(type);
1461
1462         if(GetPlayerSoundSampleField_notFound)
1463         {
1464                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1465                 return;
1466         }
1467
1468         voicetype = GetVoiceMessageVoiceType(type);
1469         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1470
1471         flood = Say(self, ownteam, world, msg, 1);
1472
1473         if (flood > 0)
1474                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1475         else if (flood < 0)
1476                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1477 }
1478
1479 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1480 {
1481 //      show_message
1482 //      0 (00) automove centerprint, admin message
1483 //      1 (01) automove centerprint, no admin message
1484 //      2 (10) no centerprint, admin message
1485 //      3 (11) no centerprint, no admin message
1486
1487         float lockteams_backup;
1488
1489         lockteams_backup = lockteams;  // backup any team lock
1490
1491         lockteams = 0;  // disable locked teams
1492
1493         TeamchangeFrags(client);  // move the players frags
1494         SetPlayerColors(client, team_colour - 1);  // set the players colour
1495         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1496
1497         lockteams = lockteams_backup;  // restore the team lock
1498
1499         LogTeamchange(client.playerid, client.team, type);
1500
1501         if not(show_message & 1) // admin message
1502                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1503
1504         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1505 }