qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, ibot, jbot, idx;
  16         float fh;
  17         vector v;
  18         string prefix;
  19         if(weaponstats_buffer < 0)
  20                 return;
  21         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  22         if(autocvar_sv_weaponstats_file != "")
  23         {
  24                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  25                 if(fh >= 0)
  26                 {
  27                         fputs(fh, "#begin statsfile\n");
  28                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  29                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  30                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  31                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  32                                 {
  33                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  34                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  35                                         if(v != '0 0 0')
  36                                         {
  37                                                 //vector is: kills hits damage
  38                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  39                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  40                                         }
  41                                 }
  42                         fputs(fh, "#end\n\n");
  43                         fclose(fh);
  44                         print("Weapon stats written\n");
  45                 }
  46         }
  47         buf_del(weaponstats_buffer);
  48         weaponstats_buffer = -1;
  49 }
  50
  51 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  52 {
  53         float idx;
  54         if(weaponstats_buffer < 0)
  55                 return;
  56         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  57                 return;
  58         if(awep > WEP_LAST || vwep > WEP_LAST)
  59                 return;
  60         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  61         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  62 }
  63 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  64 {
  65         if(damage < 0)
  66                 error("negative damage?");
  67         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  68 }
  69 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  70 {
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  72 }
  73
  74 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  75 // merged player_run and player_stand to player_anim
  76 // added death animations to player_anim
  77 // can now spawn thrown weapons from anywhere, not just from players
  78 // thrown weapons now fade out after 20 seconds
  79 // created PlayerGib function
  80 // PlayerDie no longer uses hitloc or damage
  81 // PlayerDie now supports dying animations as well as gibbing
  82 // cleaned up PlayerDie a lot
  83 // added CopyBody
  84
  85 .entity pusher;
  86 .float pushltime;
  87
  88 void CopyBody(float keepvelocity)
  89 {
  90         local entity oldself;
  91         if (self.effects & EF_NODRAW)
  92                 return;
  93         oldself = self;
  94         self = spawn();
  95         self.enemy = oldself;
  96         self.lip = oldself.lip;
  97         self.colormap = oldself.colormap;
  98         self.glowmod = oldself.glowmod;
  99         self.iscreature = oldself.iscreature;
 100         self.angles = oldself.angles;
 101         self.avelocity = oldself.avelocity;
 102         self.classname = "body";
 103         self.damageforcescale = oldself.damageforcescale;
 104         self.effects = oldself.effects;
 105         self.event_damage = oldself.event_damage;
 106         self.animstate_startframe = oldself.animstate_startframe;
 107         self.animstate_numframes = oldself.animstate_numframes;
 108         self.animstate_framerate = oldself.animstate_framerate;
 109         self.animstate_starttime = oldself.animstate_starttime;
 110         self.animstate_endtime = oldself.animstate_endtime;
 111         self.animstate_override = oldself.animstate_override;
 112         self.animstate_looping = oldself.animstate_looping;
 113         self.frame = oldself.frame;
 114         self.dead_frame = oldself.dead_frame;
 115         self.pain_finished = oldself.pain_finished;
 116         self.health = oldself.health;
 117         self.armorvalue = oldself.armorvalue;
 118         self.armortype = oldself.armortype;
 119         self.model = oldself.model;
 120         self.modelindex = oldself.modelindex;
 121         self.modelindex_lod0 = oldself.modelindex_lod0;
 122         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 123         self.modelindex_lod1 = oldself.modelindex_lod1;
 124         self.modelindex_lod2 = oldself.modelindex_lod2;
 125         self.skinindex = oldself.skinindex;
 126         self.species = oldself.species;
 127         self.movetype = oldself.movetype;
 128         self.nextthink = oldself.nextthink;
 129         self.solid = oldself.solid;
 130         self.ballistics_density = oldself.ballistics_density;
 131         self.takedamage = oldself.takedamage;
 132         self.think = oldself.think;
 133         self.customizeentityforclient = oldself.customizeentityforclient;
 134         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 135         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 136         if (keepvelocity == 1)
 137                 self.velocity = oldself.velocity;
 138         self.oldvelocity = self.velocity;
 139         self.fade_time = oldself.fade_time;
 140         self.fade_rate = oldself.fade_rate;
 141         //self.weapon = oldself.weapon;
 142         setorigin(self, oldself.origin);
 143         setsize(self, oldself.mins, oldself.maxs);
 144         self.prevorigin = oldself.origin;
 145         self.reset = SUB_Remove;
 146
 147         Drag_MoveDrag(oldself, self);
 148
 149         Violence_DamageEffect_Copy(oldself, self);
 150
 151         self.owner = oldself;
 152         self = oldself;
 153 }
 154
 155 float player_getspecies()
 156 {
 157         float s;
 158         get_model_parameters(self.model, self.skinindex);
 159         s = get_model_parameters_species;
 160         get_model_parameters(string_null, 0);
 161         if(s < 0)
 162                 return SPECIES_HUMAN;
 163         return s;
 164 }
 165
 166 void player_setupanimsformodel()
 167 {
 168         local string animfilename;
 169         local float animfile;
 170         // defaults for legacy .zym models without animinfo files
 171         self.anim_die1 = '0 1 0.5'; // 2 seconds
 172         self.anim_die2 = '1 1 0.5'; // 2 seconds
 173         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 174         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 175         self.anim_duckwalk = '4 1 1';
 176         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 177         self.anim_duckidle = '6 1 1';
 178         self.anim_idle = '7 1 1';
 179         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 180         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 181         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 182         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 183         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 184         self.anim_run = '13 1 1';
 185         self.anim_runbackwards = '14 1 1';
 186         self.anim_strafeleft = '15 1 1';
 187         self.anim_straferight = '16 1 1';
 188         self.anim_dead1 = '17 1 1';
 189         self.anim_dead2 = '18 1 1';
 190         self.anim_forwardright = '19 1 1';
 191         self.anim_forwardleft = '20 1 1';
 192         self.anim_backright = '21 1 1';
 193         self.anim_backleft  = '22 1 1';
 194         self.anim_melee = '23 1 1';
 195         animparseerror = FALSE;
 196         animfilename = strcat(self.model, ".animinfo");
 197         animfile = fopen(animfilename, FILE_READ);
 198         if (animfile >= 0)
 199         {
 200                 self.anim_die1         = animparseline(animfile);
 201                 self.anim_die2         = animparseline(animfile);
 202                 self.anim_draw         = animparseline(animfile);
 203                 self.anim_duck         = animparseline(animfile);
 204                 self.anim_duckwalk     = animparseline(animfile);
 205                 self.anim_duckjump     = animparseline(animfile);
 206                 self.anim_duckidle     = animparseline(animfile);
 207                 self.anim_idle         = animparseline(animfile);
 208                 self.anim_jump         = animparseline(animfile);
 209                 self.anim_pain1        = animparseline(animfile);
 210                 self.anim_pain2        = animparseline(animfile);
 211                 self.anim_shoot        = animparseline(animfile);
 212                 self.anim_taunt        = animparseline(animfile);
 213                 self.anim_run          = animparseline(animfile);
 214                 self.anim_runbackwards = animparseline(animfile);
 215                 self.anim_strafeleft   = animparseline(animfile);
 216                 self.anim_straferight  = animparseline(animfile);
 217                 self.anim_forwardright = animparseline(animfile);
 218                 self.anim_forwardleft  = animparseline(animfile);
 219                 self.anim_backright    = animparseline(animfile);
 220                 self.anim_backleft     = animparseline(animfile);
 221                 self.anim_melee        = animparseline(animfile);
 222                 fclose(animfile);
 223
 224                 // derived anims
 225                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 226                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 227
 228                 if (animparseerror)
 229                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 230         }
 231         else
 232                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 233         // reset animstate now
 234         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 235 };
 236
 237 void player_anim (void)
 238 {
 239         updateanim(self);
 240         if (self.weaponentity)
 241                 updateanim(self.weaponentity);
 242
 243         if (self.deadflag != DEAD_NO)
 244         {
 245                 if (time > self.animstate_endtime)
 246                 {
 247                         if (self.maxs_z > 5)
 248                         {
 249                                 self.maxs_z = 5;
 250                                 setsize(self, self.mins, self.maxs);
 251                         }
 252                         self.frame = self.dead_frame;
 253                 }
 254                 return;
 255         }
 256
 257         if (!self.animstate_override)
 258         {
 259                 if (!(self.flags & FL_ONGROUND))
 260                 {
 261                         if (self.crouch)
 262                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 263                         else
 264                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 265                         self.restart_jump = FALSE;
 266                 }
 267                 else if (self.crouch)
 268                 {
 269                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 270                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 271                         else
 272                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 273                 }
 274                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 275                 {
 276                         if (self.movement_x > 0 && self.movement_y == 0)
 277                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 278                         else if (self.movement_x < 0 && self.movement_y == 0)
 279                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 280                         else if (self.movement_x == 0 && self.movement_y > 0)
 281                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 282                         else if (self.movement_x == 0 && self.movement_y < 0)
 283                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 284                         else if (self.movement_x > 0 && self.movement_y > 0)
 285                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 286                         else if (self.movement_x > 0 && self.movement_y < 0)
 287                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 288                         else if (self.movement_x < 0 && self.movement_y > 0)
 289                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 290                         else if (self.movement_x < 0 && self.movement_y < 0)
 291                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 292                         else
 293                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 294                 }
 295                 else
 296                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 297         }
 298
 299         if (self.weaponentity)
 300         if (!self.weaponentity.animstate_override)
 301                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 302 }
 303
 304 void SpawnThrownWeapon (vector org, float w)
 305 {
 306         if(g_minstagib)
 307         if(self.ammo_cells <= 0)
 308                 return;
 309
 310         if(g_pinata)
 311         {
 312                 float j;
 313                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 314                 {
 315                         if(self.weapons & W_WeaponBit(j))
 316                                 if(W_IsWeaponThrowable(j))
 317                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 318                 }
 319         }
 320         else
 321         {
 322                 if(W_IsWeaponThrowable(self.weapon))
 323                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 324         }
 325 }
 326
 327 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 328 {
 329         local float take, save;
 330         vector v;
 331         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 332
 333         // damage resistance (ignore most of the damage from a bullet or similar)
 334         damage = max(damage - 5, 1);
 335
 336         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 337         take = v_x;
 338         save = v_y;
 339
 340         if(sound_allowed(MSG_BROADCAST, attacker))
 341         {
 342                 if (save > 10)
 343                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 344                 else if (take > 30)
 345                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 346                 else if (take > 10)
 347                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 348         }
 349
 350         if (take > 50)
 351                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 352         if (take > 100)
 353                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 354
 355         if (!(self.flags & FL_GODMODE))
 356         {
 357                 self.armorvalue = self.armorvalue - save;
 358                 self.health = self.health - take;
 359                 // pause regeneration for 5 seconds
 360                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 361         }
 362         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 363         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 364         self.dmg_inflictor = inflictor;
 365
 366         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 367         {
 368                 // don't use any animations as a gib
 369                 self.frame = 0;
 370                 self.dead_frame = 0;
 371                 // view just above the floor
 372                 self.view_ofs = '0 0 4';
 373
 374                 Violence_GibSplash(self, 1, 1, attacker);
 375                 self.modelindex = 0; // restore later
 376                 self.solid = SOLID_NOT; // restore later
 377                 self.takedamage = DAMAGE_NO; // restore later
 378         }
 379 }
 380
 381 void ClientKill_Now_TeamChange();
 382 void freezetag_CheckWinner();
 383
 384 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 385 {
 386         local float take, save, waves, sdelay, dh, da, j;
 387         vector v;
 388         float valid_damage_for_weaponstats;
 389         float excess;
 390
 391         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 392                 return;
 393
 394         dh = max(self.health, 0);
 395         da = max(self.armorvalue, 0);
 396
 397         if(!DEATH_ISSPECIAL(deathtype))
 398         {
 399                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 400                 if(self != attacker)
 401                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 402         }
 403
 404         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 405         {
 406                 // tuba causes blood to come out of the ears
 407                 vector ear1, ear2;
 408                 vector d;
 409                 float f;
 410                 ear1 = self.origin;
 411                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 412                 ear2 = ear1;
 413                 makevectors(self.angles);
 414                 ear1 += v_right * -10;
 415                 ear2 += v_right * +10;
 416                 d = inflictor.origin - self.origin;
 417                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 418                 force = v_right * vlen(force);
 419                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 420                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 421                 if(f > 0)
 422                 {
 423                         hitloc = ear1;
 424                         force = force * -1;
 425                 }
 426                 else
 427                 {
 428                         hitloc = ear2;
 429                         // force is already good
 430                 }
 431         }
 432         else
 433                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 434
 435         if (!g_minstagib)
 436         {
 437                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 438                 take = v_x;
 439                 save = v_y;
 440         }
 441         else
 442         {
 443                 save = 0;
 444                 take = damage;
 445         }
 446
 447         frag_inflictor = inflictor;
 448         frag_attacker = attacker;
 449         frag_target = self;
 450         damage_take = take;
 451         damage_save = save;
 452         damage_force = force;
 453         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 454         take = bound(0, damage_take, self.health);
 455         save = bound(0, damage_save, self.armorvalue);
 456         excess = max(0, damage - take - save);
 457
 458         if(sound_allowed(MSG_BROADCAST, attacker))
 459         {
 460                 if (save > 10)
 461                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 462                 else if (take > 30)
 463                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 464                 else if (take > 10)
 465                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 466         }
 467
 468         if (take > 50)
 469                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 470         if (take > 100)
 471                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 472
 473         if (time >= self.spawnshieldtime)
 474         {
 475                 if (!(self.flags & FL_GODMODE))
 476                 {
 477                         self.armorvalue = self.armorvalue - save;
 478                         self.health = self.health - take;
 479                         // pause regeneration for 5 seconds
 480                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 481
 482                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 483                         {
 484                                 self.pain_finished = time + 0.5;        //Supajoe
 485
 486                                 if(sv_gentle < 1) {
 487                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 488                                         {
 489                                                 if (random() > 0.5)
 490                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 491                                                 else
 492                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 493                                         }
 494
 495                                         if(sound_allowed(MSG_BROADCAST, attacker))
 496                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 497                                         if(self.health > 1)
 498                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 499                                         {
 500                                                 if(deathtype == DEATH_FALL)
 501                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 502                                                 else if(self.health > 75) // TODO make a "gentle" version?
 503                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 504                                                 else if(self.health > 50)
 505                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 506                                                 else if(self.health > 25)
 507                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else
 509                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                         }
 511                                 }
 512
 513                                 // throw off bot aim temporarily
 514                                 local float shake;
 515                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 516                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 517                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 518                         }
 519                 }
 520                 else
 521                         self.max_armorvalue += (save + take);
 522         }
 523         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 524         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 525         self.dmg_inflictor = inflictor;
 526
 527         if(attacker == self)
 528         {
 529                 // don't reset pushltime for self damage as it may be an attempt to
 530                 // escape a lava pit or similar
 531                 //self.pushltime = 0;
 532         }
 533         else if(attacker.classname == "player" || attacker.classname == "gib")
 534         {
 535                 self.pusher = attacker;
 536                 self.pushltime = time + autocvar_g_maxpushtime;
 537         }
 538         else if(time < self.pushltime)
 539         {
 540                 attacker = self.pusher;
 541                 self.pushltime = max(self.pushltime, time + 0.6);
 542         }
 543         else
 544                 self.pushltime = 0;
 545
 546         float abot, vbot, awep;
 547         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 548         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 549
 550         valid_damage_for_weaponstats = 0;
 551         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 552         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 553         if(attacker && self != attacker)
 554         if(IsDifferentTeam(self, attacker))
 555         {
 556                 if(DEATH_ISSPECIAL(deathtype))
 557                         awep = attacker.weapon;
 558                 else
 559                         awep = DEATH_WEAPONOF(deathtype);
 560                 valid_damage_for_weaponstats = 1;
 561         }
 562
 563         if(valid_damage_for_weaponstats)
 564         {
 565                 dh = dh - max(self.health, 0);
 566                 da = da - max(self.armorvalue, 0);
 567                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 568         }
 569
 570         if (self.health < 1)
 571         {
 572                 float defer_ClientKill_Now_TeamChange;
 573                 defer_ClientKill_Now_TeamChange = FALSE;
 574
 575                 if(self.alivetime)
 576                 {
 577                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 578                         self.alivetime = 0;
 579                 }
 580
 581                 if(valid_damage_for_weaponstats)
 582                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 583
 584                 if(sv_gentle < 1) // TODO make a "gentle" version?
 585                 if(sound_allowed(MSG_BROADCAST, attacker))
 586                 {
 587                         if(deathtype == DEATH_DROWN)
 588                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 589                         else
 590                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 591                 }
 592
 593                 // get rid of kill indicator
 594                 if(self.killindicator)
 595                 {
 596                         remove(self.killindicator);
 597                         self.killindicator = world;
 598                         if(self.killindicator_teamchange)
 599                                 defer_ClientKill_Now_TeamChange = TRUE;
 600
 601                         if(self.classname == "body")
 602                         if(deathtype == DEATH_KILL)
 603                         {
 604                                 // for the lemmings fans, a small harmless explosion
 605                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 606                         }
 607                 }
 608
 609                 if(!g_freezetag)
 610                 {
 611                         // become fully visible
 612                         self.alpha = 1;
 613                         // clear selected player display
 614                         ClearSelectedPlayer();
 615                         // throw a weapon
 616                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 617                 }
 618
 619                 // print an obituary message
 620                 Obituary (attacker, inflictor, self, deathtype);
 621                 race_PreDie();
 622                 DropAllRunes(self);
 623
 624                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 625                 {
 626                         PutClientInServer();
 627                         count_alive_players(); // re-count players
 628                         freezetag_CheckWinner();
 629                         return;
 630                 }
 631
 632                 frag_attacker = attacker;
 633                 frag_inflictor = inflictor;
 634                 frag_target = self;
 635                 MUTATOR_CALLHOOK(PlayerDies);
 636
 637                 if(self.flagcarried)
 638                 {
 639                         if(attacker.classname != "player" && attacker.classname != "gib")
 640                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 641                         else if(attacker.team == self.team)
 642                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 643                         else
 644                                 DropFlag(self.flagcarried, world, attacker);
 645                 }
 646                 if(self.ballcarried && g_nexball)
 647                         DropBall(self.ballcarried, self.origin, self.velocity);
 648                 Portal_ClearAllLater(self);
 649
 650                 if(clienttype(self) == CLIENTTYPE_REAL)
 651                 {
 652                         stuffcmd(self, "-zoom\n");
 653                         self.fixangle = TRUE;
 654                         //msg_entity = self;
 655                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 656                         //WriteAngle (MSG_ONE, self.v_angle_x);
 657                         //WriteAngle (MSG_ONE, self.v_angle_y);
 658                         //WriteAngle (MSG_ONE, 80);
 659                 }
 660
 661                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 662                         ClientKill_Now_TeamChange();
 663
 664                 if(g_arena)
 665                         Spawnqueue_Unmark(self);
 666
 667                 if(g_freezetag)
 668                         return;
 669
 670                 // when we get here, player actually dies
 671                 // clear waypoints (do this AFTER FreezeTag)
 672                 WaypointSprite_PlayerDead();
 673
 674                 // make the corpse upright (not tilted)
 675                 self.angles_x = 0;
 676                 self.angles_z = 0;
 677                 // don't spin
 678                 self.avelocity = '0 0 0';
 679                 // view from the floor
 680                 self.view_ofs = '0 0 -8';
 681                 // toss the corpse
 682                 self.movetype = MOVETYPE_TOSS;
 683                 // shootable corpse
 684                 self.solid = SOLID_CORPSE;
 685                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 686                 // don't stick to the floor
 687                 self.flags &~= FL_ONGROUND;
 688                 // dying animation
 689                 self.deadflag = DEAD_DYING;
 690                 // when to allow respawn
 691                 sdelay = 0;
 692                 waves = 0;
 693                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 694                 if(!sdelay)
 695                 {
 696                         if(g_cts)
 697                                 sdelay = 0; // no respawn delay in CTS
 698                         else
 699                                 sdelay = autocvar_g_respawn_delay;
 700                 }
 701                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 702                 if(!waves)
 703                         waves = autocvar_g_respawn_waves;
 704                 if(waves)
 705                         self.death_time = ceil((time + sdelay) / waves) * waves;
 706                 else
 707                         self.death_time = time + sdelay;
 708                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 709                         self.respawn_countdown = 10; // first number to count down from is 10
 710                 else
 711                         self.respawn_countdown = -1; // do not count down
 712                 if (random() < 0.5)
 713                 {
 714                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 715                         self.dead_frame = self.anim_dead1_x;
 716                 }
 717                 else
 718                 {
 719                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 720                         self.dead_frame = self.anim_dead2_x;
 721                 }
 722                 // set damage function to corpse damage
 723                 self.event_damage = PlayerCorpseDamage;
 724                 // call the corpse damage function just in case it wants to gib
 725                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 726                 // set up to fade out later
 727                 SUB_SetFade (self, time + 6 + random (), 1);
 728
 729                 if(sv_gentle > 0 || autocvar_ekg) {
 730                         // remove corpse
 731                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 732                 }
 733
 734                 // reset fields the weapons may use just in case
 735                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 736                 {
 737                         weapon_action(j, WR_RESETPLAYER);
 738                         ATTACK_FINISHED_FOR(self, j) = 0;
 739                 }
 740         }
 741 }
 742
 743 float UpdateSelectedPlayer_countvalue(float v)
 744 {
 745         return max(0, (v - 1.0) / 0.5);
 746 }
 747
 748 // returns: -2 if no hit, otherwise cos of the angle
 749 // uses the global v_angle
 750 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 751 {
 752         vector so, d;
 753         float c;
 754
 755         if(p == self)
 756                 return -2;
 757
 758         if(p.deadflag)
 759                 return -2;
 760
 761         so = self.origin + self.view_ofs;
 762         d = p.origin - so;
 763
 764         // misaimed?
 765         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 766                 return -2;
 767
 768         // now find the cos of the angle...
 769         c = normalize(d) * v_forward;
 770
 771         if(c <= mincosangle)
 772                 return -2;
 773
 774         // not visible in any way? forget it
 775         if(!checkpvs(so, p))
 776                 return -2;
 777
 778         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 779         if(trace_fraction < 1)
 780                 return -2;
 781
 782         return c;
 783 }
 784
 785 void ClearSelectedPlayer()
 786 {
 787         if(self.selected_player)
 788         {
 789                 centerprint_expire(self, CENTERPRIO_POINT);
 790                 self.selected_player = world;
 791                 self.selected_player_display_needs_update = FALSE;
 792         }
 793 }
 794
 795 void UpdateSelectedPlayer()
 796 {
 797         entity selected;
 798         float selected_score;
 799         selected = world;
 800         selected_score = 0.95; // 18 degrees
 801
 802         if(!autocvar_sv_allow_shownames)
 803                 return;
 804
 805         if(clienttype(self) != CLIENTTYPE_REAL)
 806                 return;
 807
 808         if(self.cvar_cl_shownames == 0)
 809                 return;
 810
 811         if(self.cvar_cl_shownames == 1 && !teams_matter)
 812                 return;
 813
 814         makevectors(self.v_angle); // sets v_forward
 815
 816         // 1. cursor trace is always right
 817         WarpZone_crosshair_trace(self);
 818         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 819         {
 820                 selected = trace_ent;
 821         }
 822         else
 823         {
 824                 // 2. if we don't have a cursor trace, find the player which is least
 825                 //    mis-aimed at
 826                 entity p;
 827                 FOR_EACH_PLAYER(p)
 828                 {
 829                         float c;
 830                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 831                         if(c >= -1)
 832                         {
 833                                 selected = p;
 834                                 selected_score = c;
 835                         }
 836                 }
 837         }
 838
 839         if(selected)
 840         {
 841                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 842         }
 843         else
 844         {
 845                 if(time < self.selected_player_display_timeout)
 846                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 847                                 selected = self.selected_player;
 848         }
 849
 850         if(selected)
 851         {
 852                 if(selected == self.selected_player)
 853                 {
 854                         float save;
 855                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 856                         self.selected_player_count = self.selected_player_count + frametime;
 857                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 858                         {
 859                                 string namestr, healthstr;
 860                                 namestr = playername(selected);
 861                                 if(teams_matter)
 862                                 {
 863                                         healthstr = ftos(floor(selected.health));
 864                                         if(self.team == selected.team)
 865                                         {
 866                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 867                                                 self.selected_player_display_needs_update = TRUE;
 868                                         }
 869                                 }
 870                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 871                         }
 872                 }
 873                 else
 874                 {
 875                         ClearSelectedPlayer();
 876                         self.selected_player = selected;
 877                         self.selected_player_time = time;
 878                         self.selected_player_count = 0;
 879                         self.selected_player_display_needs_update = FALSE;
 880                 }
 881         }
 882         else
 883         {
 884                 ClearSelectedPlayer();
 885         }
 886
 887         if(self.selected_player)
 888                 self.last_selected_player = self.selected_player;
 889 }
 890
 891 .float muted; // to be used by prvm_edictset server playernumber muted 1
 892 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 893 // message "": do not say, just test flood control
 894 // return value:
 895 //   1 = accept
 896 //   0 = reject
 897 //  -1 = fake accept
 898 {
 899         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 900         float flood, privatemsgprefixlen;
 901         var .float flood_field;
 902         entity head;
 903         float ret;
 904
 905         if(Ban_MaybeEnforceBan(source))
 906                 return 0;
 907
 908         if(!teamsay && !privatesay)
 909                 if(substring(msgin, 0, 1) == " ")
 910                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 911
 912         msgin = formatmessage(msgin);
 913
 914         if(source.classname != "player")
 915                 colorstr = "^0"; // black for spectators
 916         else if(teams_matter)
 917                 colorstr = Team_ColorCode(source.team);
 918         else
 919                 teamsay = FALSE;
 920
 921         if(intermission_running)
 922                 teamsay = FALSE;
 923
 924         if(msgin != "")
 925                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 926
 927         /*
 928          * using bprint solves this... me stupid
 929         // how can we prevent the message from appearing in a listen server?
 930         // for now, just give "say" back and only handle say_team
 931         if(!teamsay)
 932         {
 933                 clientcommand(self, strcat("say ", msgin));
 934                 return;
 935         }
 936         */
 937
 938         if(autocvar_g_chat_teamcolors)
 939                 namestr = playername(source);
 940         else
 941                 namestr = source.netname;
 942
 943         if(msgin != "")
 944         {
 945                 if(privatesay)
 946                 {
 947                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 948                         privatemsgprefixlen = strlen(msgstr);
 949                         msgstr = strcat(msgstr, msgin);
 950                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 951                         if(autocvar_g_chat_teamcolors)
 952                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 953                         else
 954                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 955                 }
 956                 else if(teamsay)
 957                 {
 958                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 959                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 960                 }
 961                 else
 962                 {
 963                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 964                         cmsgstr = "";
 965                 }
 966                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 967         }
 968         else
 969         {
 970                 msgstr = cmsgstr = "";
 971         }
 972
 973         fullmsgstr = msgstr;
 974         fullcmsgstr = cmsgstr;
 975
 976         // FLOOD CONTROL
 977         flood = 0;
 978         if(floodcontrol)
 979         {
 980                 float flood_spl;
 981                 float flood_burst;
 982                 float flood_lmax;
 983                 float lines;
 984                 if(privatesay)
 985                 {
 986                         flood_spl = autocvar_g_chat_flood_spl_tell;
 987                         flood_burst = autocvar_g_chat_flood_burst_tell;
 988                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 989                         flood_field = floodcontrol_chattell;
 990                 }
 991                 else if(teamsay)
 992                 {
 993                         flood_spl = autocvar_g_chat_flood_spl_team;
 994                         flood_burst = autocvar_g_chat_flood_burst_team;
 995                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 996                         flood_field = floodcontrol_chatteam;
 997                 }
 998                 else
 999                 {
1000                         flood_spl = autocvar_g_chat_flood_spl;
1001                         flood_burst = autocvar_g_chat_flood_burst;
1002                         flood_lmax = autocvar_g_chat_flood_lmax;
1003                         flood_field = floodcontrol_chat;
1004                 }
1005                 flood_burst = max(0, flood_burst - 1);
1006                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1007
1008                 // do flood control for the default line size
1009                 if(msgstr != "")
1010                 {
1011                         getWrappedLine_remaining = msgstr;
1012                         msgstr = "";
1013                         lines = 0;
1014                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1015                         {
1016                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1017                                 ++lines;
1018                         }
1019                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1020
1021                         if(getWrappedLine_remaining != "")
1022                         {
1023                                 msgstr = strcat(msgstr, "\n");
1024                                 flood = 2;
1025                         }
1026
1027                         if(time >= source.flood_field)
1028                         {
1029                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1030                         }
1031                         else
1032                         {
1033                                 flood = 1;
1034                                 msgstr = fullmsgstr;
1035                         }
1036                 }
1037                 else
1038                 {
1039                         if(time >= source.flood_field)
1040                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1041                         else
1042                                 flood = 1;
1043                 }
1044
1045                 if (timeoutStatus == 2) //when game is paused, no flood protection
1046                         source.flood_field = flood = 0;
1047         }
1048
1049         if(flood == 2) // cannot happen for empty msgstr
1050         {
1051                 if(autocvar_g_chat_flood_notify_flooder)
1052                 {
1053                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1054                         sourcecmsgstr = "";
1055                 }
1056                 else
1057                 {
1058                         sourcemsgstr = fullmsgstr;
1059                         sourcecmsgstr = fullcmsgstr;
1060                 }
1061                 cmsgstr = "";
1062         }
1063         else
1064         {
1065                 sourcemsgstr = msgstr;
1066                 sourcecmsgstr = cmsgstr;
1067         }
1068
1069         if(!privatesay)
1070         if(source.classname != "player")
1071         {
1072                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1073                         teamsay = -1; // spectators
1074         }
1075
1076         if(flood)
1077                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1078
1079         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1080         if(privatesay)
1081                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1082
1083         if(source.muted)
1084         {
1085                 // always fake the message
1086                 ret = -1;
1087         }
1088         else if(flood == 1)
1089         {
1090                 if(autocvar_g_chat_flood_notify_flooder)
1091                 {
1092                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1093                         ret = 0;
1094                 }
1095                 else
1096                         ret = -1;
1097         }
1098         else
1099         {
1100                 ret = 1;
1101         }
1102
1103         if(sourcemsgstr != "" && ret != 0)
1104         {
1105                 if(ret < 0) // fake
1106                 {
1107                         sprint(source, sourcemsgstr);
1108                         if(sourcecmsgstr != "" && !privatesay)
1109                                 centerprint(source, sourcecmsgstr);
1110                 }
1111                 else if(privatesay)
1112                 {
1113                         sprint(source, sourcemsgstr);
1114                         sprint(privatesay, msgstr);
1115                         if(cmsgstr != "")
1116                                 centerprint(privatesay, cmsgstr);
1117                 }
1118                 else if(teamsay > 0)
1119                 {
1120                         sprint(source, sourcemsgstr);
1121                         if(sourcecmsgstr != "")
1122                                 centerprint(source, sourcecmsgstr);
1123                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1124                                 if(head != source)
1125                                 {
1126                                         sprint(head, msgstr);
1127                                         if(cmsgstr != "")
1128                                                 centerprint(head, cmsgstr);
1129                                 }
1130                 }
1131                 else if(teamsay < 0)
1132                 {
1133                         sprint(source, sourcemsgstr);
1134                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1135                                 if(head != source)
1136                                         sprint(head, msgstr);
1137                 }
1138                 else if(sourcemsgstr != msgstr)
1139                 {
1140                         sprint(source, sourcemsgstr);
1141                         FOR_EACH_REALCLIENT(head)
1142                                 if(head != source)
1143                                         sprint(head, msgstr);
1144                 }
1145                 else
1146                         bprint(msgstr);
1147         }
1148
1149         return ret;
1150 }
1151
1152 float GetVoiceMessageVoiceType(string type)
1153 {
1154         if(type == "taunt")
1155                 return VOICETYPE_TAUNT;
1156         if(type == "teamshoot")
1157                 return VOICETYPE_LASTATTACKER;
1158         return VOICETYPE_TEAMRADIO;
1159 }
1160
1161 string allvoicesamples;
1162 .string GetVoiceMessageSampleField(string type)
1163 {
1164         GetPlayerSoundSampleField_notFound = 0;
1165         switch(type)
1166         {
1167 #define _VOICEMSG(m) case #m: return playersound_##m;
1168                 ALLVOICEMSGS
1169 #undef _VOICEMSG
1170         }
1171         GetPlayerSoundSampleField_notFound = 1;
1172         return playersound_taunt;
1173 }
1174
1175 .string GetPlayerSoundSampleField(string type)
1176 {
1177         GetPlayerSoundSampleField_notFound = 0;
1178         switch(type)
1179         {
1180 #define _VOICEMSG(m) case #m: return playersound_##m;
1181                 ALLPLAYERSOUNDS
1182 #undef _VOICEMSG
1183         }
1184         GetPlayerSoundSampleField_notFound = 1;
1185         return playersound_taunt;
1186 }
1187
1188 void PrecacheGlobalSound(string samplestring)
1189 {
1190         float n, i;
1191         tokenize_console(samplestring);
1192         n = stof(argv(1));
1193         if(n > 0)
1194         {
1195                 for(i = 1; i <= n; ++i)
1196                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1197         }
1198         else
1199         {
1200                 precache_sound(strcat(argv(0), ".wav"));
1201         }
1202 }
1203
1204 void PrecachePlayerSounds(string f)
1205 {
1206         float fh;
1207         string s;
1208         fh = fopen(f, FILE_READ);
1209         if(fh < 0)
1210                 return;
1211         while((s = fgets(fh)))
1212         {
1213                 if(tokenize_console(s) != 3)
1214                 {
1215                         dprint("Invalid sound info line: ", s, "\n");
1216                         continue;
1217                 }
1218                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1219         }
1220         fclose(fh);
1221
1222         if not(allvoicesamples)
1223         {
1224 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1225                 ALLVOICEMSGS
1226 #undef _VOICEMSG
1227                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1228         }
1229 }
1230
1231 void ClearPlayerSounds()
1232 {
1233 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1234         ALLPLAYERSOUNDS
1235         ALLVOICEMSGS
1236 #undef _VOICEMSG
1237 }
1238
1239 float LoadPlayerSounds(string f, float first)
1240 {
1241         float fh;
1242         string s;
1243         var .string field;
1244         fh = fopen(f, FILE_READ);
1245         if(fh < 0)
1246         {
1247                 dprint("Player sound file not found: ", f, "\n");
1248                 return 0;
1249         }
1250         while((s = fgets(fh)))
1251         {
1252                 if(tokenize_console(s) != 3)
1253                         continue;
1254                 field = GetPlayerSoundSampleField(argv(0));
1255                 if(GetPlayerSoundSampleField_notFound)
1256                         field = GetVoiceMessageSampleField(argv(0));
1257                 if(GetPlayerSoundSampleField_notFound)
1258                         continue;
1259                 if(self.field)
1260                         strunzone(self.field);
1261                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1262         }
1263         fclose(fh);
1264         return 1;
1265 }
1266
1267 .float modelindex_for_playersound;
1268 .float skinindex_for_playersound;
1269 void UpdatePlayerSounds()
1270 {
1271         if(self.modelindex == self.modelindex_for_playersound)
1272         if(self.skinindex == self.skinindex_for_playersound)
1273                 return;
1274         self.modelindex_for_playersound = self.modelindex;
1275         self.skinindex_for_playersound = self.skinindex;
1276         ClearPlayerSounds();
1277         LoadPlayerSounds("sound/player/default.sounds", 1);
1278         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1279                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1280 }
1281
1282 void FakeGlobalSound(string sample, float chan, float voicetype)
1283 {
1284         float n;
1285         float tauntrand;
1286
1287         if(sample == "")
1288                 return;
1289
1290         tokenize_console(sample);
1291         n = stof(argv(1));
1292         if(n > 0)
1293                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1294         else
1295                 sample = strcat(argv(0), ".wav"); // randomization
1296
1297         switch(voicetype)
1298         {
1299                 case VOICETYPE_LASTATTACKER_ONLY:
1300                         break;
1301                 case VOICETYPE_LASTATTACKER:
1302                         if(self.pusher)
1303                         {
1304                                 msg_entity = self;
1305                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1306                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1307                         }
1308                         break;
1309                 case VOICETYPE_TEAMRADIO:
1310                         msg_entity = self;
1311                         if(msg_entity.cvar_cl_voice_directional == 1)
1312                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1313                         else
1314                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1315                         break;
1316                 case VOICETYPE_AUTOTAUNT:
1317                         if(!sv_autotaunt)
1318                                 break;
1319                         if(!sv_taunt)
1320                                 break;
1321                         if(sv_gentle)
1322                                 break;
1323                         tauntrand = random();
1324                         msg_entity = self;
1325                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1326                         {
1327                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1328                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1329                                 else
1330                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1331                         }
1332                         break;
1333                 case VOICETYPE_TAUNT:
1334                         if(self.classname == "player")
1335                                 if(self.deadflag == DEAD_NO)
1336                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1337                         if(!sv_taunt)
1338                                 break;
1339                         if(sv_gentle)
1340                                 break;
1341                         msg_entity = self;
1342                         if (msg_entity.cvar_cl_voice_directional >= 1)
1343                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1344                         else
1345                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1346                         break;
1347                 case VOICETYPE_PLAYERSOUND:
1348                         msg_entity = self;
1349                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1350                         break;
1351                 default:
1352                         backtrace("Invalid voice type!");
1353                         break;
1354         }
1355 }
1356
1357 void GlobalSound(string sample, float chan, float voicetype)
1358 {
1359         float n;
1360         float tauntrand;
1361
1362         if(sample == "")
1363                 return;
1364
1365         tokenize_console(sample);
1366         n = stof(argv(1));
1367         if(n > 0)
1368                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1369         else
1370                 sample = strcat(argv(0), ".wav"); // randomization
1371
1372         switch(voicetype)
1373         {
1374                 case VOICETYPE_LASTATTACKER_ONLY:
1375                         if(self.pusher)
1376                         {
1377                                 msg_entity = self.pusher;
1378                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1379                                 {
1380                                         if(msg_entity.cvar_cl_voice_directional == 1)
1381                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1382                                         else
1383                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1384                                 }
1385                         }
1386                         break;
1387                 case VOICETYPE_LASTATTACKER:
1388                         if(self.pusher)
1389                         {
1390                                 msg_entity = self.pusher;
1391                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1392                                 {
1393                                         if(msg_entity.cvar_cl_voice_directional == 1)
1394                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1395                                         else
1396                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1397                                 }
1398                                 msg_entity = self;
1399                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1400                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1401                         }
1402                         break;
1403                 case VOICETYPE_TEAMRADIO:
1404                         FOR_EACH_REALCLIENT(msg_entity)
1405                                 if(!teams_matter || msg_entity.team == self.team)
1406                                 {
1407                                         if(msg_entity.cvar_cl_voice_directional == 1)
1408                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1409                                         else
1410                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1411                                 }
1412                         break;
1413                 case VOICETYPE_AUTOTAUNT:
1414                         if(!sv_autotaunt)
1415                                 break;
1416                         if(!sv_taunt)
1417                                 break;
1418                         if(sv_gentle)
1419                                 break;
1420                         tauntrand = random();
1421                         FOR_EACH_REALCLIENT(msg_entity)
1422                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1423                                 {
1424                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1425                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1426                                         else
1427                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1428                                 }
1429                         break;
1430                 case VOICETYPE_TAUNT:
1431                         if(self.classname == "player")
1432                                 if(self.deadflag == DEAD_NO)
1433                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1434                         if(!sv_taunt)
1435                                 break;
1436                         if(sv_gentle)
1437                                 break;
1438                         FOR_EACH_REALCLIENT(msg_entity)
1439                         {
1440                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1441                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1442                                 else
1443                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1444                         }
1445                         break;
1446                 case VOICETYPE_PLAYERSOUND:
1447                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1448                         break;
1449                 default:
1450                         backtrace("Invalid voice type!");
1451                         break;
1452         }
1453 }
1454
1455 void PlayerSound(.string samplefield, float chan, float voicetype)
1456 {
1457         GlobalSound(self.samplefield, chan, voicetype);
1458 }
1459
1460 void VoiceMessage(string type, string msg)
1461 {
1462         var .string sample;
1463         float voicetype, ownteam;
1464         float flood;
1465         sample = GetVoiceMessageSampleField(type);
1466
1467         if(GetPlayerSoundSampleField_notFound)
1468         {
1469                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1470                 return;
1471         }
1472
1473         voicetype = GetVoiceMessageVoiceType(type);
1474         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1475
1476         flood = Say(self, ownteam, world, msg, 1);
1477
1478         if (flood > 0)
1479                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1480         else if (flood < 0)
1481                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1482 }
1483
1484 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1485 {
1486 //      show_message
1487 //      0 (00) automove centerprint, admin message
1488 //      1 (01) automove centerprint, no admin message
1489 //      2 (10) no centerprint, admin message
1490 //      3 (11) no centerprint, no admin message
1491
1492         float lockteams_backup;
1493
1494         lockteams_backup = lockteams;  // backup any team lock
1495
1496         lockteams = 0;  // disable locked teams
1497
1498         TeamchangeFrags(client);  // move the players frags
1499         SetPlayerColors(client, team_colour - 1);  // set the players colour
1500         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1501
1502         lockteams = lockteams_backup;  // restore the team lock
1503
1504         LogTeamchange(client.playerid, client.team, type);
1505
1506         if not(show_message & 1) // admin message
1507                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1508
1509         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1510 }