qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, ibot, jbot, idx;
  16         float fh;
  17         vector v;
  18         string prefix;
  19         if(weaponstats_buffer < 0)
  20                 return;
  21         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  22         if(autocvar_sv_weaponstats_file != "")
  23         {
  24                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  25                 if(fh >= 0)
  26                 {
  27                         fputs(fh, "#begin statsfile\n");
  28                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  29                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  30                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  31                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  32                                 {
  33                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  34                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  35                                         if(v != '0 0 0')
  36                                         {
  37                                                 //vector is: kills hits damage
  38                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  39                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  40                                         }
  41                                 }
  42                         fputs(fh, "#end\n\n");
  43                         fclose(fh);
  44                         print("Weapon stats written\n");
  45                 }
  46         }
  47         buf_del(weaponstats_buffer);
  48         weaponstats_buffer = -1;
  49 }
  50
  51 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  52 {
  53         float idx;
  54         if(weaponstats_buffer < 0)
  55                 return;
  56         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  57                 return;
  58         if(awep > WEP_LAST || vwep > WEP_LAST)
  59                 return;
  60         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  61         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  62 }
  63 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  64 {
  65         if(damage < 0)
  66                 error("negative damage?");
  67         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  68 }
  69 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  70 {
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  72 }
  73
  74 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  75 // merged player_run and player_stand to player_anim
  76 // added death animations to player_anim
  77 // can now spawn thrown weapons from anywhere, not just from players
  78 // thrown weapons now fade out after 20 seconds
  79 // created PlayerGib function
  80 // PlayerDie no longer uses hitloc or damage
  81 // PlayerDie now supports dying animations as well as gibbing
  82 // cleaned up PlayerDie a lot
  83 // added CopyBody
  84
  85 .entity pusher;
  86 .float pushltime;
  87
  88 void CopyBody(float keepvelocity)
  89 {
  90         local entity oldself;
  91         if (self.effects & EF_NODRAW)
  92                 return;
  93         oldself = self;
  94         self = spawn();
  95         self.enemy = oldself;
  96         self.lip = oldself.lip;
  97         self.colormap = oldself.colormap;
  98         self.glowmod = oldself.glowmod;
  99         self.iscreature = oldself.iscreature;
 100         self.angles = oldself.angles;
 101         self.avelocity = oldself.avelocity;
 102         self.classname = "body";
 103         self.damageforcescale = oldself.damageforcescale;
 104         self.effects = oldself.effects;
 105         self.event_damage = oldself.event_damage;
 106         self.animstate_startframe = oldself.animstate_startframe;
 107         self.animstate_numframes = oldself.animstate_numframes;
 108         self.animstate_framerate = oldself.animstate_framerate;
 109         self.animstate_starttime = oldself.animstate_starttime;
 110         self.animstate_endtime = oldself.animstate_endtime;
 111         self.animstate_override = oldself.animstate_override;
 112         self.animstate_looping = oldself.animstate_looping;
 113         self.frame = oldself.frame;
 114         self.dead_frame = oldself.dead_frame;
 115         self.pain_finished = oldself.pain_finished;
 116         self.health = oldself.health;
 117         self.armorvalue = oldself.armorvalue;
 118         self.armortype = oldself.armortype;
 119         self.model = oldself.model;
 120         self.modelindex = oldself.modelindex;
 121         self.modelindex_lod0 = oldself.modelindex_lod0;
 122         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 123         self.modelindex_lod1 = oldself.modelindex_lod1;
 124         self.modelindex_lod2 = oldself.modelindex_lod2;
 125         self.skinindex = oldself.skinindex;
 126         self.species = oldself.species;
 127         self.movetype = oldself.movetype;
 128         self.nextthink = oldself.nextthink;
 129         self.solid = oldself.solid;
 130         self.ballistics_density = oldself.ballistics_density;
 131         self.takedamage = oldself.takedamage;
 132         self.think = oldself.think;
 133         self.customizeentityforclient = oldself.customizeentityforclient;
 134         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 135         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 136         if (keepvelocity == 1)
 137                 self.velocity = oldself.velocity;
 138         self.oldvelocity = self.velocity;
 139         self.fade_time = oldself.fade_time;
 140         self.fade_rate = oldself.fade_rate;
 141         //self.weapon = oldself.weapon;
 142         setorigin(self, oldself.origin);
 143         setsize(self, oldself.mins, oldself.maxs);
 144         self.prevorigin = oldself.origin;
 145         self.reset = SUB_Remove;
 146
 147         Drag_MoveDrag(oldself, self);
 148
 149         Violence_DamageEffect_Copy(oldself, self);
 150
 151         self.owner = oldself;
 152         self = oldself;
 153 }
 154
 155 float player_getspecies()
 156 {
 157         float s;
 158         get_model_parameters(self.model, self.skinindex);
 159         s = get_model_parameters_species;
 160         get_model_parameters(string_null, 0);
 161         if(s < 0)
 162                 return SPECIES_HUMAN;
 163         return s;
 164 }
 165
 166 void player_setupanimsformodel()
 167 {
 168         local string animfilename;
 169         local float animfile;
 170         // defaults for legacy .zym models without animinfo files
 171         self.anim_die1 = '0 1 0.5'; // 2 seconds
 172         self.anim_die2 = '1 1 0.5'; // 2 seconds
 173         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 174         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 175         self.anim_duckwalk = '4 1 1';
 176         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 177         self.anim_duckidle = '6 1 1';
 178         self.anim_idle = '7 1 1';
 179         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 180         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 181         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 182         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 183         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 184         self.anim_run = '13 1 1';
 185         self.anim_runbackwards = '14 1 1';
 186         self.anim_strafeleft = '15 1 1';
 187         self.anim_straferight = '16 1 1';
 188         self.anim_dead1 = '17 1 1';
 189         self.anim_dead2 = '18 1 1';
 190         self.anim_forwardright = '19 1 1';
 191         self.anim_forwardleft = '20 1 1';
 192         self.anim_backright = '21 1 1';
 193         self.anim_backleft  = '22 1 1';
 194         animparseerror = FALSE;
 195         animfilename = strcat(self.model, ".animinfo");
 196         animfile = fopen(animfilename, FILE_READ);
 197         if (animfile >= 0)
 198         {
 199                 self.anim_die1         = animparseline(animfile);
 200                 self.anim_die2         = animparseline(animfile);
 201                 self.anim_draw         = animparseline(animfile);
 202                 self.anim_duck         = animparseline(animfile);
 203                 self.anim_duckwalk     = animparseline(animfile);
 204                 self.anim_duckjump     = animparseline(animfile);
 205                 self.anim_duckidle     = animparseline(animfile);
 206                 self.anim_idle         = animparseline(animfile);
 207                 self.anim_jump         = animparseline(animfile);
 208                 self.anim_pain1        = animparseline(animfile);
 209                 self.anim_pain2        = animparseline(animfile);
 210                 self.anim_shoot        = animparseline(animfile);
 211                 self.anim_taunt        = animparseline(animfile);
 212                 self.anim_run          = animparseline(animfile);
 213                 self.anim_runbackwards = animparseline(animfile);
 214                 self.anim_strafeleft   = animparseline(animfile);
 215                 self.anim_straferight  = animparseline(animfile);
 216                 self.anim_forwardright = animparseline(animfile);
 217                 self.anim_forwardleft  = animparseline(animfile);
 218                 self.anim_backright    = animparseline(animfile);
 219                 self.anim_backleft     = animparseline(animfile);
 220                 fclose(animfile);
 221
 222                 // derived anims
 223                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 224                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 225
 226                 if (animparseerror)
 227                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 228         }
 229         else
 230                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 231         // reset animstate now
 232         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 233 };
 234
 235 void player_anim (void)
 236 {
 237         updateanim(self);
 238         if (self.weaponentity)
 239                 updateanim(self.weaponentity);
 240
 241         if (self.deadflag != DEAD_NO)
 242         {
 243                 if (time > self.animstate_endtime)
 244                 {
 245                         if (self.maxs_z > 5)
 246                         {
 247                                 self.maxs_z = 5;
 248                                 setsize(self, self.mins, self.maxs);
 249                         }
 250                         self.frame = self.dead_frame;
 251                 }
 252                 return;
 253         }
 254
 255         if (!self.animstate_override)
 256         {
 257                 if (!(self.flags & FL_ONGROUND))
 258                 {
 259                         if (self.crouch)
 260                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 261                         else
 262                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 263                         self.restart_jump = FALSE;
 264                 }
 265                 else if (self.crouch)
 266                 {
 267                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 268                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 269                         else
 270                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 271                 }
 272                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 273                 {
 274                         if (self.movement_x > 0 && self.movement_y == 0)
 275                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 276                         else if (self.movement_x < 0 && self.movement_y == 0)
 277                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 278                         else if (self.movement_x == 0 && self.movement_y > 0)
 279                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 280                         else if (self.movement_x == 0 && self.movement_y < 0)
 281                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 282                         else if (self.movement_x > 0 && self.movement_y > 0)
 283                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 284                         else if (self.movement_x > 0 && self.movement_y < 0)
 285                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 286                         else if (self.movement_x < 0 && self.movement_y > 0)
 287                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 288                         else if (self.movement_x < 0 && self.movement_y < 0)
 289                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 290                         else
 291                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 292                 }
 293                 else
 294                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 295         }
 296
 297         if (self.weaponentity)
 298         if (!self.weaponentity.animstate_override)
 299                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 300 }
 301
 302 void SpawnThrownWeapon (vector org, float w)
 303 {
 304         if(g_minstagib)
 305         if(self.ammo_cells <= 0)
 306                 return;
 307
 308         if(g_pinata)
 309         {
 310                 float j;
 311                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 312                 {
 313                         if(self.weapons & W_WeaponBit(j))
 314                                 if(W_IsWeaponThrowable(j))
 315                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 316                 }
 317         }
 318         else
 319         {
 320                 if(W_IsWeaponThrowable(self.weapon))
 321                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 322         }
 323 }
 324
 325 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 326 {
 327         local float take, save;
 328         vector v;
 329         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 330
 331         // damage resistance (ignore most of the damage from a bullet or similar)
 332         damage = max(damage - 5, 1);
 333
 334         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 335         take = v_x;
 336         save = v_y;
 337
 338         if(sound_allowed(MSG_BROADCAST, attacker))
 339         {
 340                 if (save > 10)
 341                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 342                 else if (take > 30)
 343                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 344                 else if (take > 10)
 345                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 346         }
 347
 348         if (take > 50)
 349                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 350         if (take > 100)
 351                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 352
 353         if (!(self.flags & FL_GODMODE))
 354         {
 355                 self.armorvalue = self.armorvalue - save;
 356                 self.health = self.health - take;
 357                 // pause regeneration for 5 seconds
 358                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 359         }
 360         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 361         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 362         self.dmg_inflictor = inflictor;
 363
 364         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 365         {
 366                 // don't use any animations as a gib
 367                 self.frame = 0;
 368                 self.dead_frame = 0;
 369                 // view just above the floor
 370                 self.view_ofs = '0 0 4';
 371
 372                 Violence_GibSplash(self, 1, 1, attacker);
 373                 self.modelindex = 0; // restore later
 374                 self.solid = SOLID_NOT; // restore later
 375                 self.takedamage = DAMAGE_NO; // restore later
 376         }
 377 }
 378
 379 void ClientKill_Now_TeamChange();
 380 void freezetag_CheckWinner();
 381
 382 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 383 {
 384         local float take, save, waves, sdelay, dh, da, j;
 385         vector v;
 386         float valid_damage_for_weaponstats;
 387         float excess;
 388
 389         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 390                 return;
 391
 392         dh = max(self.health, 0);
 393         da = max(self.armorvalue, 0);
 394
 395         if(!DEATH_ISSPECIAL(deathtype))
 396         {
 397                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 398                 if(self != attacker)
 399                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 400         }
 401
 402         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 403         {
 404                 // tuba causes blood to come out of the ears
 405                 vector ear1, ear2;
 406                 vector d;
 407                 float f;
 408                 ear1 = self.origin;
 409                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 410                 ear2 = ear1;
 411                 makevectors(self.angles);
 412                 ear1 += v_right * -10;
 413                 ear2 += v_right * +10;
 414                 d = inflictor.origin - self.origin;
 415                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 416                 force = v_right * vlen(force);
 417                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 418                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 419                 if(f > 0)
 420                 {
 421                         hitloc = ear1;
 422                         force = force * -1;
 423                 }
 424                 else
 425                 {
 426                         hitloc = ear2;
 427                         // force is already good
 428                 }
 429         }
 430         else
 431                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 432
 433         if (!g_minstagib)
 434         {
 435                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 436                 take = v_x;
 437                 save = v_y;
 438         }
 439         else
 440         {
 441                 save = 0;
 442                 take = damage;
 443         }
 444
 445         frag_inflictor = inflictor;
 446         frag_attacker = attacker;
 447         frag_target = self;
 448         damage_take = take;
 449         damage_save = save;
 450         damage_force = force;
 451         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 452         take = bound(0, damage_take, self.health);
 453         save = bound(0, damage_save, self.armorvalue);
 454         excess = max(0, damage - take - save);
 455
 456         if(sound_allowed(MSG_BROADCAST, attacker))
 457         {
 458                 if (save > 10)
 459                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 460                 else if (take > 30)
 461                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 462                 else if (take > 10)
 463                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 464         }
 465
 466         if (take > 50)
 467                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 468         if (take > 100)
 469                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 470
 471         if (time >= self.spawnshieldtime)
 472         {
 473                 if (!(self.flags & FL_GODMODE))
 474                 {
 475                         self.armorvalue = self.armorvalue - save;
 476                         self.health = self.health - take;
 477                         // pause regeneration for 5 seconds
 478                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 479
 480                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 481                         {
 482                                 self.pain_finished = time + 0.5;        //Supajoe
 483
 484                                 if(sv_gentle < 1) {
 485                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 486                                         {
 487                                                 if (random() > 0.5)
 488                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 489                                                 else
 490                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 491                                         }
 492
 493                                         if(sound_allowed(MSG_BROADCAST, attacker))
 494                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 495                                         if(self.health > 1)
 496                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 497                                         {
 498                                                 if(deathtype == DEATH_FALL)
 499                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 500                                                 else if(self.health > 75) // TODO make a "gentle" version?
 501                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 502                                                 else if(self.health > 50)
 503                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 504                                                 else if(self.health > 25)
 505                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 506                                                 else
 507                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                         }
 509                                 }
 510
 511                                 // throw off bot aim temporarily
 512                                 local float shake;
 513                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 514                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 515                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 516                         }
 517                 }
 518                 else
 519                         self.max_armorvalue += (save + take);
 520         }
 521         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 522         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 523         self.dmg_inflictor = inflictor;
 524
 525         if(attacker == self)
 526         {
 527                 // don't reset pushltime for self damage as it may be an attempt to
 528                 // escape a lava pit or similar
 529                 //self.pushltime = 0;
 530         }
 531         else if(attacker.classname == "player" || attacker.classname == "gib")
 532         {
 533                 self.pusher = attacker;
 534                 self.pushltime = time + autocvar_g_maxpushtime;
 535         }
 536         else if(time < self.pushltime)
 537         {
 538                 attacker = self.pusher;
 539                 self.pushltime = max(self.pushltime, time + 0.6);
 540         }
 541         else
 542                 self.pushltime = 0;
 543
 544         float abot, vbot, awep;
 545         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 546         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 547
 548         valid_damage_for_weaponstats = 0;
 549         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 550         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 551         if(attacker && self != attacker)
 552         if(IsDifferentTeam(self, attacker))
 553         {
 554                 if(DEATH_ISSPECIAL(deathtype))
 555                         awep = attacker.weapon;
 556                 else
 557                         awep = DEATH_WEAPONOF(deathtype);
 558                 valid_damage_for_weaponstats = 1;
 559         }
 560
 561         if(valid_damage_for_weaponstats)
 562         {
 563                 dh = dh - max(self.health, 0);
 564                 da = da - max(self.armorvalue, 0);
 565                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 566         }
 567
 568         if (self.health < 1)
 569         {
 570                 float defer_ClientKill_Now_TeamChange;
 571                 defer_ClientKill_Now_TeamChange = FALSE;
 572
 573                 if(self.alivetime)
 574                 {
 575                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 576                         self.alivetime = 0;
 577                 }
 578
 579                 if(valid_damage_for_weaponstats)
 580                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 581
 582                 if(sv_gentle < 1) // TODO make a "gentle" version?
 583                 if(sound_allowed(MSG_BROADCAST, attacker))
 584                 {
 585                         if(deathtype == DEATH_DROWN)
 586                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 587                         else
 588                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 589                 }
 590
 591                 // get rid of kill indicator
 592                 if(self.killindicator)
 593                 {
 594                         remove(self.killindicator);
 595                         self.killindicator = world;
 596                         if(self.killindicator_teamchange)
 597                                 defer_ClientKill_Now_TeamChange = TRUE;
 598
 599                         if(self.classname == "body")
 600                         if(deathtype == DEATH_KILL)
 601                         {
 602                                 // for the lemmings fans, a small harmless explosion
 603                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 604                         }
 605                 }
 606
 607                 if(!g_freezetag)
 608                 {
 609                         // become fully visible
 610                         self.alpha = 1;
 611                         // clear selected player display
 612                         ClearSelectedPlayer();
 613                         // throw a weapon
 614                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 615                 }
 616
 617                 // print an obituary message
 618                 Obituary (attacker, inflictor, self, deathtype);
 619                 race_PreDie();
 620                 DropAllRunes(self);
 621
 622                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 623                 {
 624                         PutClientInServer();
 625                         count_alive_players(); // re-count players
 626                         freezetag_CheckWinner();
 627                         return;
 628                 }
 629
 630                 frag_attacker = attacker;
 631                 frag_inflictor = inflictor;
 632                 frag_target = self;
 633                 MUTATOR_CALLHOOK(PlayerDies);
 634
 635                 if(self.flagcarried)
 636                 {
 637                         if(attacker.classname != "player" && attacker.classname != "gib")
 638                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 639                         else if(attacker.team == self.team)
 640                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 641                         else
 642                                 DropFlag(self.flagcarried, world, attacker);
 643                 }
 644                 if(self.ballcarried && g_nexball)
 645                         DropBall(self.ballcarried, self.origin, self.velocity);
 646                 Portal_ClearAllLater(self);
 647
 648                 if(clienttype(self) == CLIENTTYPE_REAL)
 649                 {
 650                         stuffcmd(self, "-zoom\n");
 651                         self.fixangle = TRUE;
 652                         //msg_entity = self;
 653                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 654                         //WriteAngle (MSG_ONE, self.v_angle_x);
 655                         //WriteAngle (MSG_ONE, self.v_angle_y);
 656                         //WriteAngle (MSG_ONE, 80);
 657                 }
 658
 659                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 660                         ClientKill_Now_TeamChange();
 661
 662                 if(g_arena)
 663                         Spawnqueue_Unmark(self);
 664
 665                 if(g_freezetag)
 666                         return;
 667
 668                 // when we get here, player actually dies
 669                 // clear waypoints (do this AFTER FreezeTag)
 670                 WaypointSprite_PlayerDead();
 671
 672                 // make the corpse upright (not tilted)
 673                 self.angles_x = 0;
 674                 self.angles_z = 0;
 675                 // don't spin
 676                 self.avelocity = '0 0 0';
 677                 // view from the floor
 678                 self.view_ofs = '0 0 -8';
 679                 // toss the corpse
 680                 self.movetype = MOVETYPE_TOSS;
 681                 // shootable corpse
 682                 self.solid = SOLID_CORPSE;
 683                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 684                 // don't stick to the floor
 685                 self.flags &~= FL_ONGROUND;
 686                 // dying animation
 687                 self.deadflag = DEAD_DYING;
 688                 // when to allow respawn
 689                 sdelay = 0;
 690                 waves = 0;
 691                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 692                 if(!sdelay)
 693                 {
 694                         if(g_cts)
 695                                 sdelay = 0; // no respawn delay in CTS
 696                         else
 697                                 sdelay = autocvar_g_respawn_delay;
 698                 }
 699                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 700                 if(!waves)
 701                         waves = autocvar_g_respawn_waves;
 702                 if(waves)
 703                         self.death_time = ceil((time + sdelay) / waves) * waves;
 704                 else
 705                         self.death_time = time + sdelay;
 706                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 707                         self.respawn_countdown = 10; // first number to count down from is 10
 708                 else
 709                         self.respawn_countdown = -1; // do not count down
 710                 if (random() < 0.5)
 711                 {
 712                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 713                         self.dead_frame = self.anim_dead1_x;
 714                 }
 715                 else
 716                 {
 717                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 718                         self.dead_frame = self.anim_dead2_x;
 719                 }
 720                 // set damage function to corpse damage
 721                 self.event_damage = PlayerCorpseDamage;
 722                 // call the corpse damage function just in case it wants to gib
 723                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 724                 // set up to fade out later
 725                 SUB_SetFade (self, time + 6 + random (), 1);
 726
 727                 if(sv_gentle > 0 || autocvar_ekg) {
 728                         // remove corpse
 729                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 730                 }
 731
 732                 // reset fields the weapons may use just in case
 733                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 734                 {
 735                         weapon_action(j, WR_RESETPLAYER);
 736                         ATTACK_FINISHED_FOR(self, j) = 0;
 737                 }
 738         }
 739 }
 740
 741 float UpdateSelectedPlayer_countvalue(float v)
 742 {
 743         return max(0, (v - 1.0) / 0.5);
 744 }
 745
 746 // returns: -2 if no hit, otherwise cos of the angle
 747 // uses the global v_angle
 748 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 749 {
 750         vector so, d;
 751         float c;
 752
 753         if(p == self)
 754                 return -2;
 755
 756         if(p.deadflag)
 757                 return -2;
 758
 759         so = self.origin + self.view_ofs;
 760         d = p.origin - so;
 761
 762         // misaimed?
 763         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 764                 return -2;
 765
 766         // now find the cos of the angle...
 767         c = normalize(d) * v_forward;
 768
 769         if(c <= mincosangle)
 770                 return -2;
 771
 772         // not visible in any way? forget it
 773         if(!checkpvs(so, p))
 774                 return -2;
 775
 776         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 777         if(trace_fraction < 1)
 778                 return -2;
 779
 780         return c;
 781 }
 782
 783 void ClearSelectedPlayer()
 784 {
 785         if(self.selected_player)
 786         {
 787                 centerprint_expire(self, CENTERPRIO_POINT);
 788                 self.selected_player = world;
 789                 self.selected_player_display_needs_update = FALSE;
 790         }
 791 }
 792
 793 void UpdateSelectedPlayer()
 794 {
 795         entity selected;
 796         float selected_score;
 797         selected = world;
 798         selected_score = 0.95; // 18 degrees
 799
 800         if(!autocvar_sv_allow_shownames)
 801                 return;
 802
 803         if(clienttype(self) != CLIENTTYPE_REAL)
 804                 return;
 805
 806         if(self.cvar_cl_shownames == 0)
 807                 return;
 808
 809         if(self.cvar_cl_shownames == 1 && !teams_matter)
 810                 return;
 811
 812         makevectors(self.v_angle); // sets v_forward
 813
 814         // 1. cursor trace is always right
 815         WarpZone_crosshair_trace(self);
 816         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 817         {
 818                 selected = trace_ent;
 819         }
 820         else
 821         {
 822                 // 2. if we don't have a cursor trace, find the player which is least
 823                 //    mis-aimed at
 824                 entity p;
 825                 FOR_EACH_PLAYER(p)
 826                 {
 827                         float c;
 828                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 829                         if(c >= -1)
 830                         {
 831                                 selected = p;
 832                                 selected_score = c;
 833                         }
 834                 }
 835         }
 836
 837         if(selected)
 838         {
 839                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 840         }
 841         else
 842         {
 843                 if(time < self.selected_player_display_timeout)
 844                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 845                                 selected = self.selected_player;
 846         }
 847
 848         if(selected)
 849         {
 850                 if(selected == self.selected_player)
 851                 {
 852                         float save;
 853                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 854                         self.selected_player_count = self.selected_player_count + frametime;
 855                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 856                         {
 857                                 string namestr, healthstr;
 858                                 namestr = playername(selected);
 859                                 if(teams_matter)
 860                                 {
 861                                         healthstr = ftos(floor(selected.health));
 862                                         if(self.team == selected.team)
 863                                         {
 864                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 865                                                 self.selected_player_display_needs_update = TRUE;
 866                                         }
 867                                 }
 868                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 869                         }
 870                 }
 871                 else
 872                 {
 873                         ClearSelectedPlayer();
 874                         self.selected_player = selected;
 875                         self.selected_player_time = time;
 876                         self.selected_player_count = 0;
 877                         self.selected_player_display_needs_update = FALSE;
 878                 }
 879         }
 880         else
 881         {
 882                 ClearSelectedPlayer();
 883         }
 884
 885         if(self.selected_player)
 886                 self.last_selected_player = self.selected_player;
 887 }
 888
 889 .float muted; // to be used by prvm_edictset server playernumber muted 1
 890 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 891 // message "": do not say, just test flood control
 892 // return value:
 893 //   1 = accept
 894 //   0 = reject
 895 //  -1 = fake accept
 896 {
 897         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 898         float flood, privatemsgprefixlen;
 899         var .float flood_field;
 900         entity head;
 901         float ret;
 902
 903         if(Ban_MaybeEnforceBan(source))
 904                 return 0;
 905
 906         if(!teamsay && !privatesay)
 907                 if(substring(msgin, 0, 1) == " ")
 908                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 909
 910         msgin = formatmessage(msgin);
 911
 912         if(source.classname != "player")
 913                 colorstr = "^0"; // black for spectators
 914         else if(teams_matter)
 915                 colorstr = Team_ColorCode(source.team);
 916         else
 917                 teamsay = FALSE;
 918
 919         if(intermission_running)
 920                 teamsay = FALSE;
 921
 922         if(msgin != "")
 923                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 924
 925         /*
 926          * using bprint solves this... me stupid
 927         // how can we prevent the message from appearing in a listen server?
 928         // for now, just give "say" back and only handle say_team
 929         if(!teamsay)
 930         {
 931                 clientcommand(self, strcat("say ", msgin));
 932                 return;
 933         }
 934         */
 935
 936         if(autocvar_g_chat_teamcolors)
 937                 namestr = playername(source);
 938         else
 939                 namestr = source.netname;
 940
 941         if(msgin != "")
 942         {
 943                 if(privatesay)
 944                 {
 945                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 946                         privatemsgprefixlen = strlen(msgstr);
 947                         msgstr = strcat(msgstr, msgin);
 948                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 949                         if(autocvar_g_chat_teamcolors)
 950                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 951                         else
 952                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 953                 }
 954                 else if(teamsay)
 955                 {
 956                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 957                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 958                 }
 959                 else
 960                 {
 961                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 962                         cmsgstr = "";
 963                 }
 964                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 965         }
 966         else
 967         {
 968                 msgstr = cmsgstr = "";
 969         }
 970
 971         fullmsgstr = msgstr;
 972         fullcmsgstr = cmsgstr;
 973
 974         // FLOOD CONTROL
 975         flood = 0;
 976         if(floodcontrol)
 977         {
 978                 float flood_spl;
 979                 float flood_burst;
 980                 float flood_lmax;
 981                 float lines;
 982                 if(privatesay)
 983                 {
 984                         flood_spl = autocvar_g_chat_flood_spl_tell;
 985                         flood_burst = autocvar_g_chat_flood_burst_tell;
 986                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 987                         flood_field = floodcontrol_chattell;
 988                 }
 989                 else if(teamsay)
 990                 {
 991                         flood_spl = autocvar_g_chat_flood_spl_team;
 992                         flood_burst = autocvar_g_chat_flood_burst_team;
 993                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 994                         flood_field = floodcontrol_chatteam;
 995                 }
 996                 else
 997                 {
 998                         flood_spl = autocvar_g_chat_flood_spl;
 999                         flood_burst = autocvar_g_chat_flood_burst;
1000                         flood_lmax = autocvar_g_chat_flood_lmax;
1001                         flood_field = floodcontrol_chat;
1002                 }
1003                 flood_burst = max(0, flood_burst - 1);
1004                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1005
1006                 // do flood control for the default line size
1007                 if(msgstr != "")
1008                 {
1009                         getWrappedLine_remaining = msgstr;
1010                         msgstr = "";
1011                         lines = 0;
1012                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1013                         {
1014                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1015                                 ++lines;
1016                         }
1017                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1018
1019                         if(getWrappedLine_remaining != "")
1020                         {
1021                                 msgstr = strcat(msgstr, "\n");
1022                                 flood = 2;
1023                         }
1024
1025                         if(time >= source.flood_field)
1026                         {
1027                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1028                         }
1029                         else
1030                         {
1031                                 flood = 1;
1032                                 msgstr = fullmsgstr;
1033                         }
1034                 }
1035                 else
1036                 {
1037                         if(time >= source.flood_field)
1038                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1039                         else
1040                                 flood = 1;
1041                 }
1042
1043                 if (timeoutStatus == 2) //when game is paused, no flood protection
1044                         source.flood_field = flood = 0;
1045         }
1046
1047         if(flood == 2) // cannot happen for empty msgstr
1048         {
1049                 if(autocvar_g_chat_flood_notify_flooder)
1050                 {
1051                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1052                         sourcecmsgstr = "";
1053                 }
1054                 else
1055                 {
1056                         sourcemsgstr = fullmsgstr;
1057                         sourcecmsgstr = fullcmsgstr;
1058                 }
1059                 cmsgstr = "";
1060         }
1061         else
1062         {
1063                 sourcemsgstr = msgstr;
1064                 sourcecmsgstr = cmsgstr;
1065         }
1066
1067         if(!privatesay)
1068         if(source.classname != "player")
1069         {
1070                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1071                         teamsay = -1; // spectators
1072         }
1073
1074         if(flood)
1075                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1076
1077         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1078         if(privatesay)
1079                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1080
1081         if(source.muted)
1082         {
1083                 // always fake the message
1084                 ret = -1;
1085         }
1086         else if(flood == 1)
1087         {
1088                 if(autocvar_g_chat_flood_notify_flooder)
1089                 {
1090                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1091                         ret = 0;
1092                 }
1093                 else
1094                         ret = -1;
1095         }
1096         else
1097         {
1098                 ret = 1;
1099         }
1100
1101         if(sourcemsgstr != "" && ret != 0)
1102         {
1103                 if(ret < 0) // fake
1104                 {
1105                         sprint(source, sourcemsgstr);
1106                         if(sourcecmsgstr != "" && !privatesay)
1107                                 centerprint(source, sourcecmsgstr);
1108                 }
1109                 else if(privatesay)
1110                 {
1111                         sprint(source, sourcemsgstr);
1112                         sprint(privatesay, msgstr);
1113                         if(cmsgstr != "")
1114                                 centerprint(privatesay, cmsgstr);
1115                 }
1116                 else if(teamsay > 0)
1117                 {
1118                         sprint(source, sourcemsgstr);
1119                         if(sourcecmsgstr != "")
1120                                 centerprint(source, sourcecmsgstr);
1121                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1122                                 if(head != source)
1123                                 {
1124                                         sprint(head, msgstr);
1125                                         if(cmsgstr != "")
1126                                                 centerprint(head, cmsgstr);
1127                                 }
1128                 }
1129                 else if(teamsay < 0)
1130                 {
1131                         sprint(source, sourcemsgstr);
1132                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1133                                 if(head != source)
1134                                         sprint(head, msgstr);
1135                 }
1136                 else if(sourcemsgstr != msgstr)
1137                 {
1138                         sprint(source, sourcemsgstr);
1139                         FOR_EACH_REALCLIENT(head)
1140                                 if(head != source)
1141                                         sprint(head, msgstr);
1142                 }
1143                 else
1144                         bprint(msgstr);
1145         }
1146
1147         return ret;
1148 }
1149
1150 float GetVoiceMessageVoiceType(string type)
1151 {
1152         if(type == "taunt")
1153                 return VOICETYPE_TAUNT;
1154         if(type == "teamshoot")
1155                 return VOICETYPE_LASTATTACKER;
1156         return VOICETYPE_TEAMRADIO;
1157 }
1158
1159 string allvoicesamples;
1160 .string GetVoiceMessageSampleField(string type)
1161 {
1162         GetPlayerSoundSampleField_notFound = 0;
1163         switch(type)
1164         {
1165 #define _VOICEMSG(m) case #m: return playersound_##m;
1166                 ALLVOICEMSGS
1167 #undef _VOICEMSG
1168         }
1169         GetPlayerSoundSampleField_notFound = 1;
1170         return playersound_taunt;
1171 }
1172
1173 .string GetPlayerSoundSampleField(string type)
1174 {
1175         GetPlayerSoundSampleField_notFound = 0;
1176         switch(type)
1177         {
1178 #define _VOICEMSG(m) case #m: return playersound_##m;
1179                 ALLPLAYERSOUNDS
1180 #undef _VOICEMSG
1181         }
1182         GetPlayerSoundSampleField_notFound = 1;
1183         return playersound_taunt;
1184 }
1185
1186 void PrecacheGlobalSound(string samplestring)
1187 {
1188         float n, i;
1189         tokenize_console(samplestring);
1190         n = stof(argv(1));
1191         if(n > 0)
1192         {
1193                 for(i = 1; i <= n; ++i)
1194                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1195         }
1196         else
1197         {
1198                 precache_sound(strcat(argv(0), ".wav"));
1199         }
1200 }
1201
1202 void PrecachePlayerSounds(string f)
1203 {
1204         float fh;
1205         string s;
1206         fh = fopen(f, FILE_READ);
1207         if(fh < 0)
1208                 return;
1209         while((s = fgets(fh)))
1210         {
1211                 if(tokenize_console(s) != 3)
1212                 {
1213                         dprint("Invalid sound info line: ", s, "\n");
1214                         continue;
1215                 }
1216                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1217         }
1218         fclose(fh);
1219
1220         if not(allvoicesamples)
1221         {
1222 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1223                 ALLVOICEMSGS
1224 #undef _VOICEMSG
1225                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1226         }
1227 }
1228
1229 void ClearPlayerSounds()
1230 {
1231 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1232         ALLPLAYERSOUNDS
1233         ALLVOICEMSGS
1234 #undef _VOICEMSG
1235 }
1236
1237 float LoadPlayerSounds(string f, float first)
1238 {
1239         float fh;
1240         string s;
1241         var .string field;
1242         fh = fopen(f, FILE_READ);
1243         if(fh < 0)
1244         {
1245                 dprint("Player sound file not found: ", f, "\n");
1246                 return 0;
1247         }
1248         while((s = fgets(fh)))
1249         {
1250                 if(tokenize_console(s) != 3)
1251                         continue;
1252                 field = GetPlayerSoundSampleField(argv(0));
1253                 if(GetPlayerSoundSampleField_notFound)
1254                         field = GetVoiceMessageSampleField(argv(0));
1255                 if(GetPlayerSoundSampleField_notFound)
1256                         continue;
1257                 if(self.field)
1258                         strunzone(self.field);
1259                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1260         }
1261         fclose(fh);
1262         return 1;
1263 }
1264
1265 .float modelindex_for_playersound;
1266 .float skinindex_for_playersound;
1267 void UpdatePlayerSounds()
1268 {
1269         if(self.modelindex == self.modelindex_for_playersound)
1270         if(self.skinindex == self.skinindex_for_playersound)
1271                 return;
1272         self.modelindex_for_playersound = self.modelindex;
1273         self.skinindex_for_playersound = self.skinindex;
1274         ClearPlayerSounds();
1275         LoadPlayerSounds("sound/player/default.sounds", 1);
1276         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1277                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1278 }
1279
1280 void FakeGlobalSound(string sample, float chan, float voicetype)
1281 {
1282         float n;
1283         float tauntrand;
1284
1285         if(sample == "")
1286                 return;
1287
1288         tokenize_console(sample);
1289         n = stof(argv(1));
1290         if(n > 0)
1291                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1292         else
1293                 sample = strcat(argv(0), ".wav"); // randomization
1294
1295         switch(voicetype)
1296         {
1297                 case VOICETYPE_LASTATTACKER_ONLY:
1298                         break;
1299                 case VOICETYPE_LASTATTACKER:
1300                         if(self.pusher)
1301                         {
1302                                 msg_entity = self;
1303                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1304                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1305                         }
1306                         break;
1307                 case VOICETYPE_TEAMRADIO:
1308                         msg_entity = self;
1309                         if(msg_entity.cvar_cl_voice_directional == 1)
1310                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1311                         else
1312                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1313                         break;
1314                 case VOICETYPE_AUTOTAUNT:
1315                         if(!sv_autotaunt)
1316                                 break;
1317                         if(!sv_taunt)
1318                                 break;
1319                         if(sv_gentle)
1320                                 break;
1321                         tauntrand = random();
1322                         msg_entity = self;
1323                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1324                         {
1325                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1326                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1327                                 else
1328                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1329                         }
1330                         break;
1331                 case VOICETYPE_TAUNT:
1332                         if(self.classname == "player")
1333                                 if(self.deadflag == DEAD_NO)
1334                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1335                         if(!sv_taunt)
1336                                 break;
1337                         if(sv_gentle)
1338                                 break;
1339                         msg_entity = self;
1340                         if (msg_entity.cvar_cl_voice_directional >= 1)
1341                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1342                         else
1343                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1344                         break;
1345                 case VOICETYPE_PLAYERSOUND:
1346                         msg_entity = self;
1347                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1348                         break;
1349                 default:
1350                         backtrace("Invalid voice type!");
1351                         break;
1352         }
1353 }
1354
1355 void GlobalSound(string sample, float chan, float voicetype)
1356 {
1357         float n;
1358         float tauntrand;
1359
1360         if(sample == "")
1361                 return;
1362
1363         tokenize_console(sample);
1364         n = stof(argv(1));
1365         if(n > 0)
1366                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1367         else
1368                 sample = strcat(argv(0), ".wav"); // randomization
1369
1370         switch(voicetype)
1371         {
1372                 case VOICETYPE_LASTATTACKER_ONLY:
1373                         if(self.pusher)
1374                         {
1375                                 msg_entity = self.pusher;
1376                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1377                                 {
1378                                         if(msg_entity.cvar_cl_voice_directional == 1)
1379                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1380                                         else
1381                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1382                                 }
1383                         }
1384                         break;
1385                 case VOICETYPE_LASTATTACKER:
1386                         if(self.pusher)
1387                         {
1388                                 msg_entity = self.pusher;
1389                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1390                                 {
1391                                         if(msg_entity.cvar_cl_voice_directional == 1)
1392                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1393                                         else
1394                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1395                                 }
1396                                 msg_entity = self;
1397                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1398                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1399                         }
1400                         break;
1401                 case VOICETYPE_TEAMRADIO:
1402                         FOR_EACH_REALCLIENT(msg_entity)
1403                                 if(!teams_matter || msg_entity.team == self.team)
1404                                 {
1405                                         if(msg_entity.cvar_cl_voice_directional == 1)
1406                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1407                                         else
1408                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1409                                 }
1410                         break;
1411                 case VOICETYPE_AUTOTAUNT:
1412                         if(!sv_autotaunt)
1413                                 break;
1414                         if(!sv_taunt)
1415                                 break;
1416                         if(sv_gentle)
1417                                 break;
1418                         tauntrand = random();
1419                         FOR_EACH_REALCLIENT(msg_entity)
1420                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1421                                 {
1422                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1423                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1424                                         else
1425                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1426                                 }
1427                         break;
1428                 case VOICETYPE_TAUNT:
1429                         if(self.classname == "player")
1430                                 if(self.deadflag == DEAD_NO)
1431                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1432                         if(!sv_taunt)
1433                                 break;
1434                         if(sv_gentle)
1435                                 break;
1436                         FOR_EACH_REALCLIENT(msg_entity)
1437                         {
1438                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1439                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1440                                 else
1441                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1442                         }
1443                         break;
1444                 case VOICETYPE_PLAYERSOUND:
1445                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1446                         break;
1447                 default:
1448                         backtrace("Invalid voice type!");
1449                         break;
1450         }
1451 }
1452
1453 void PlayerSound(.string samplefield, float chan, float voicetype)
1454 {
1455         GlobalSound(self.samplefield, chan, voicetype);
1456 }
1457
1458 void VoiceMessage(string type, string msg)
1459 {
1460         var .string sample;
1461         float voicetype, ownteam;
1462         float flood;
1463         sample = GetVoiceMessageSampleField(type);
1464
1465         if(GetPlayerSoundSampleField_notFound)
1466         {
1467                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1468                 return;
1469         }
1470
1471         voicetype = GetVoiceMessageVoiceType(type);
1472         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1473
1474         flood = Say(self, ownteam, world, msg, 1);
1475
1476         if (flood > 0)
1477                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1478         else if (flood < 0)
1479                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1480 }
1481
1482 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1483 {
1484 //      show_message
1485 //      0 (00) automove centerprint, admin message
1486 //      1 (01) automove centerprint, no admin message
1487 //      2 (10) no centerprint, admin message
1488 //      3 (11) no centerprint, no admin message
1489
1490         float lockteams_backup;
1491
1492         lockteams_backup = lockteams;  // backup any team lock
1493
1494         lockteams = 0;  // disable locked teams
1495
1496         TeamchangeFrags(client);  // move the players frags
1497         SetPlayerColors(client, team_colour - 1);  // set the players colour
1498         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1499
1500         lockteams = lockteams_backup;  // restore the team lock
1501
1502         LogTeamchange(client.playerid, client.team, type);
1503
1504         if not(show_message & 1) // admin message
1505                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1506
1507         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1508 }