qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_killfile != "" || autocvar_sv_weaponstats_damagefile != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(autocvar_sv_weaponstats_killfile != "")
  22         {
  23                 fh = fopen(autocvar_sv_weaponstats_killfile, FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(autocvar_sv_weaponstats_damagefile != "")
  43         {
  44                 fh = fopen(autocvar_sv_weaponstats_damagefile, FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.model, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389 void freezetag_CheckWinner();
 390 void freezetag_Unfreeze();
 391
 392 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 393 {
 394         local float take, save, waves, sdelay, dh, da, j;
 395         vector v;
 396         float valid_damage_for_weaponstats;
 397
 398         dh = max(self.health, 0);
 399         da = max(self.armorvalue, 0);
 400
 401         if(!DEATH_ISSPECIAL(deathtype))
 402         {
 403                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 404                 if(self != attacker)
 405                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 406         }
 407
 408         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 409         {
 410                 // tuba causes blood to come out of the ears
 411                 vector ear1, ear2;
 412                 vector d;
 413                 float f;
 414                 ear1 = self.origin;
 415                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 416                 ear2 = ear1;
 417                 makevectors(self.angles);
 418                 ear1 += v_right * -10;
 419                 ear2 += v_right * +10;
 420                 d = inflictor.origin - self.origin;
 421                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 422                 force = v_right * vlen(force);
 423                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 424                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 425                 if(f > 0)
 426                 {
 427                         hitloc = ear1;
 428                         force = force * -1;
 429                 }
 430                 else
 431                 {
 432                         hitloc = ear2;
 433                         // force is already good
 434                 }
 435         }
 436         else
 437                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 438
 439         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 440                 return;
 441
 442         if (!g_minstagib)
 443         {
 444                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 445                 take = v_x;
 446                 save = v_y;
 447         }
 448         else
 449         {
 450                 save = 0;
 451                 take = damage;
 452         }
 453
 454         frag_inflictor = inflictor;
 455         frag_attacker = attacker;
 456         frag_target = self;
 457         damage_take = take;
 458         damage_save = save;
 459         damage_force = force;
 460         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 461         take = bound(0, damage_take, self.health);
 462         save = bound(0, damage_save, self.armorvalue);
 463
 464         if(sound_allowed(MSG_BROADCAST, attacker))
 465         {
 466                 if (save > 10)
 467                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 468                 else if (take > 30)
 469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 470                 else if (take > 10)
 471                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 472         }
 473
 474         if (take > 50)
 475                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 476         if (take > 100)
 477                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 478
 479         if (time >= self.spawnshieldtime)
 480         {
 481                 if (!(self.flags & FL_GODMODE))
 482                 {
 483                         self.armorvalue = self.armorvalue - save;
 484                         self.health = self.health - take;
 485                         // pause regeneration for 5 seconds
 486                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 487
 488                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 489                         {
 490                                 self.pain_finished = time + 0.5;        //Supajoe
 491
 492                                 if(sv_gentle < 1) {
 493                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 494                                         {
 495                                                 if (random() > 0.5)
 496                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 497                                                 else
 498                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 499                                         }
 500
 501                                         if(sound_allowed(MSG_BROADCAST, attacker))
 502                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 503                                         if(self.health > 1)
 504                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 505                                         {
 506                                                 if(deathtype == DEATH_FALL)
 507                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else if(self.health > 75) // TODO make a "gentle" version?
 509                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                                 else if(self.health > 50)
 511                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else if(self.health > 25)
 513                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                                 else
 515                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 516                                         }
 517                                 }
 518
 519                                 // throw off bot aim temporarily
 520                                 local float shake;
 521                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 522                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 523                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 524                         }
 525                 }
 526                 else
 527                         self.max_armorvalue += (save + take);
 528         }
 529         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 530         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 531         self.dmg_inflictor = inflictor;
 532
 533         if(attacker == self)
 534         {
 535                 // don't reset pushltime for self damage as it may be an attempt to
 536                 // escape a lava pit or similar
 537                 //self.pushltime = 0;
 538         }
 539         else if(attacker.classname == "player" || attacker.classname == "gib")
 540         {
 541                 self.pusher = attacker;
 542                 self.pushltime = time + autocvar_g_maxpushtime;
 543         }
 544         else if(time < self.pushltime)
 545         {
 546                 attacker = self.pusher;
 547                 self.pushltime = max(self.pushltime, time + 0.6);
 548         }
 549         else
 550                 self.pushltime = 0;
 551
 552         valid_damage_for_weaponstats = 0;
 553         if(clienttype(self) == CLIENTTYPE_REAL)
 554         if(clienttype(attacker) == CLIENTTYPE_REAL)
 555         if(self != attacker)
 556         if(!DEATH_ISSPECIAL(deathtype))
 557         if(IsDifferentTeam(self, attacker))
 558                 valid_damage_for_weaponstats = 1;
 559
 560         if(valid_damage_for_weaponstats)
 561         {
 562                 dh = dh - max(self.health, 0);
 563                 da = da - max(self.armorvalue, 0);
 564                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 565         }
 566
 567         if (self.health < 1)
 568         {
 569                 float defer_ClientKill_Now_TeamChange;
 570                 defer_ClientKill_Now_TeamChange = FALSE;
 571
 572                 if(self.alivetime)
 573                 {
 574                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 575                         self.alivetime = 0;
 576                 }
 577
 578                 if(valid_damage_for_weaponstats)
 579                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 580
 581                 if(sv_gentle < 1) // TODO make a "gentle" version?
 582                 if(sound_allowed(MSG_BROADCAST, attacker))
 583                 {
 584                         if(deathtype == DEATH_DROWN)
 585                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 586                         else
 587                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 588                 }
 589
 590                 // get rid of kill indicator
 591                 if(self.killindicator)
 592                 {
 593                         remove(self.killindicator);
 594                         self.killindicator = world;
 595                         if(self.killindicator_teamchange)
 596                                 defer_ClientKill_Now_TeamChange = TRUE;
 597
 598                         if(self.classname == "body")
 599                         if(deathtype == DEATH_KILL)
 600                         {
 601                                 // for the lemmings fans, a small harmless explosion
 602                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 603                         }
 604                 }
 605
 606                 if(!g_freezetag)
 607                 {
 608                         // become fully visible
 609                         self.alpha = 1;
 610                         // clear selected player display
 611                         ClearSelectedPlayer();
 612                         // throw a weapon
 613                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 614                 }
 615
 616                 // print an obituary message
 617                 Obituary (attacker, inflictor, self, deathtype);
 618                 race_PreDie();
 619                 DropAllRunes(self);
 620
 621                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 622                 {
 623                         PutClientInServer();
 624                         count_alive_players(); // re-count players
 625                         freezetag_CheckWinner();
 626                         return;
 627                 }
 628
 629                 frag_attacker = attacker;
 630                 frag_inflictor = inflictor;
 631                 frag_target = self;
 632                 MUTATOR_CALLHOOK(PlayerDies);
 633
 634                 if(self.flagcarried)
 635                 {
 636                         if(attacker.classname != "player" && attacker.classname != "gib")
 637                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 638                         else if(attacker.team == self.team)
 639                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 640                         else
 641                                 DropFlag(self.flagcarried, world, attacker);
 642                 }
 643                 if(self.ballcarried && g_nexball)
 644                         DropBall(self.ballcarried, self.origin, self.velocity);
 645                 Portal_ClearAllLater(self);
 646
 647                 if(clienttype(self) == CLIENTTYPE_REAL)
 648                 {
 649                         stuffcmd(self, "-zoom\n");
 650                         self.fixangle = TRUE;
 651                         //msg_entity = self;
 652                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 653                         //WriteAngle (MSG_ONE, self.v_angle_x);
 654                         //WriteAngle (MSG_ONE, self.v_angle_y);
 655                         //WriteAngle (MSG_ONE, 80);
 656                 }
 657
 658                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 659                         ClientKill_Now_TeamChange();
 660
 661                 if(g_arena)
 662                         Spawnqueue_Unmark(self);
 663
 664                 if(g_freezetag)
 665                         return;
 666
 667                 // when we get here, player actually dies
 668                 // clear waypoints (do this AFTER FreezeTag)
 669                 WaypointSprite_PlayerDead();
 670
 671                 // make the corpse upright (not tilted)
 672                 self.angles_x = 0;
 673                 self.angles_z = 0;
 674                 // don't spin
 675                 self.avelocity = '0 0 0';
 676                 // view from the floor
 677                 self.view_ofs = '0 0 -8';
 678                 // toss the corpse
 679                 self.movetype = MOVETYPE_TOSS;
 680                 // shootable corpse
 681                 self.solid = SOLID_CORPSE;
 682                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 683                 // don't stick to the floor
 684                 self.flags &~= FL_ONGROUND;
 685                 // dying animation
 686                 self.deadflag = DEAD_DYING;
 687                 // when to allow respawn
 688                 sdelay = 0;
 689                 waves = 0;
 690                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 691                 if(!sdelay)
 692                 {
 693                         if(g_cts)
 694                                 sdelay = 0; // no respawn delay in CTS
 695                         else
 696                                 sdelay = autocvar_g_respawn_delay;
 697                 }
 698                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 699                 if(!waves)
 700                         waves = autocvar_g_respawn_waves;
 701                 if(waves)
 702                         self.death_time = ceil((time + sdelay) / waves) * waves;
 703                 else
 704                         self.death_time = time + sdelay;
 705                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 706                         self.respawn_countdown = 10; // first number to count down from is 10
 707                 else
 708                         self.respawn_countdown = -1; // do not count down
 709                 if (random() < 0.5)
 710                 {
 711                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 712                         self.dead_frame = self.anim_dead1_x;
 713                 }
 714                 else
 715                 {
 716                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 717                         self.dead_frame = self.anim_dead2_x;
 718                 }
 719                 // set damage function to corpse damage
 720                 self.event_damage = PlayerCorpseDamage;
 721                 // call the corpse damage function just in case it wants to gib
 722                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 723                 // set up to fade out later
 724                 SUB_SetFade (self, time + 6 + random (), 1);
 725
 726                 if(sv_gentle > 0 || autocvar_ekg) {
 727                         // remove corpse
 728                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 729                 }
 730
 731                 // reset fields the weapons may use just in case
 732                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 733                 {
 734                         weapon_action(j, WR_RESETPLAYER);
 735                         ATTACK_FINISHED_FOR(self, j) = 0;
 736                 }
 737         }
 738 }
 739
 740 float UpdateSelectedPlayer_countvalue(float v)
 741 {
 742         return max(0, (v - 1.0) / 0.5);
 743 }
 744
 745 // returns: -2 if no hit, otherwise cos of the angle
 746 // uses the global v_angle
 747 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 748 {
 749         vector so, d;
 750         float c;
 751
 752         if(p == self)
 753                 return -2;
 754
 755         if(p.deadflag)
 756                 return -2;
 757
 758         so = self.origin + self.view_ofs;
 759         d = p.origin - so;
 760
 761         // misaimed?
 762         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 763                 return -2;
 764
 765         // now find the cos of the angle...
 766         c = normalize(d) * v_forward;
 767
 768         if(c <= mincosangle)
 769                 return -2;
 770
 771         // not visible in any way? forget it
 772         if(!checkpvs(so, p))
 773                 return -2;
 774
 775         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 776         if(trace_fraction < 1)
 777                 return -2;
 778
 779         return c;
 780 }
 781
 782 void ClearSelectedPlayer()
 783 {
 784         if(self.selected_player)
 785         {
 786                 centerprint_expire(self, CENTERPRIO_POINT);
 787                 self.selected_player = world;
 788                 self.selected_player_display_needs_update = FALSE;
 789         }
 790 }
 791
 792 void UpdateSelectedPlayer()
 793 {
 794         entity selected;
 795         float selected_score;
 796         selected = world;
 797         selected_score = 0.95; // 18 degrees
 798
 799         if(!autocvar_sv_allow_shownames)
 800                 return;
 801
 802         if(clienttype(self) != CLIENTTYPE_REAL)
 803                 return;
 804
 805         if(self.cvar_cl_shownames == 0)
 806                 return;
 807
 808         if(self.cvar_cl_shownames == 1 && !teams_matter)
 809                 return;
 810
 811         makevectors(self.v_angle); // sets v_forward
 812
 813         // 1. cursor trace is always right
 814         WarpZone_crosshair_trace(self);
 815         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 816         {
 817                 selected = trace_ent;
 818         }
 819         else
 820         {
 821                 // 2. if we don't have a cursor trace, find the player which is least
 822                 //    mis-aimed at
 823                 entity p;
 824                 FOR_EACH_PLAYER(p)
 825                 {
 826                         float c;
 827                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 828                         if(c >= -1)
 829                         {
 830                                 selected = p;
 831                                 selected_score = c;
 832                         }
 833                 }
 834         }
 835
 836         if(selected)
 837         {
 838                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 839         }
 840         else
 841         {
 842                 if(time < self.selected_player_display_timeout)
 843                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 844                                 selected = self.selected_player;
 845         }
 846
 847         if(selected)
 848         {
 849                 if(selected == self.selected_player)
 850                 {
 851                         float save;
 852                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 853                         self.selected_player_count = self.selected_player_count + frametime;
 854                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 855                         {
 856                                 string namestr, healthstr;
 857                                 namestr = playername(selected);
 858                                 if(teams_matter)
 859                                 {
 860                                         healthstr = ftos(floor(selected.health));
 861                                         if(self.team == selected.team)
 862                                         {
 863                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 864                                                 self.selected_player_display_needs_update = TRUE;
 865                                         }
 866                                 }
 867                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 868                         }
 869                 }
 870                 else
 871                 {
 872                         ClearSelectedPlayer();
 873                         self.selected_player = selected;
 874                         self.selected_player_time = time;
 875                         self.selected_player_count = 0;
 876                         self.selected_player_display_needs_update = FALSE;
 877                 }
 878         }
 879         else
 880         {
 881                 ClearSelectedPlayer();
 882         }
 883
 884         if(self.selected_player)
 885                 self.last_selected_player = self.selected_player;
 886 }
 887
 888 .float muted; // to be used by prvm_edictset server playernumber muted 1
 889 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 890 // message "": do not say, just test flood control
 891 // return value:
 892 //   1 = accept
 893 //   0 = reject
 894 //  -1 = fake accept
 895 {
 896         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 897         float flood, privatemsgprefixlen;
 898         var .float flood_field;
 899         entity head;
 900         float ret;
 901
 902         if(Ban_MaybeEnforceBan(source))
 903                 return 0;
 904
 905         if(!teamsay && !privatesay)
 906                 if(substring(msgin, 0, 1) == " ")
 907                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 908
 909         msgin = formatmessage(msgin);
 910
 911         if(source.classname != "player")
 912                 colorstr = "^0"; // black for spectators
 913         else if(teams_matter)
 914                 colorstr = Team_ColorCode(source.team);
 915         else
 916                 teamsay = FALSE;
 917
 918         if(intermission_running)
 919                 teamsay = FALSE;
 920
 921         if(msgin != "")
 922                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 923
 924         /*
 925          * using bprint solves this... me stupid
 926         // how can we prevent the message from appearing in a listen server?
 927         // for now, just give "say" back and only handle say_team
 928         if(!teamsay)
 929         {
 930                 clientcommand(self, strcat("say ", msgin));
 931                 return;
 932         }
 933         */
 934
 935         if(autocvar_g_chat_teamcolors)
 936                 namestr = playername(source);
 937         else
 938                 namestr = source.netname;
 939
 940         if(msgin != "")
 941         {
 942                 if(privatesay)
 943                 {
 944                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 945                         privatemsgprefixlen = strlen(msgstr);
 946                         msgstr = strcat(msgstr, msgin);
 947                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 948                         if(autocvar_g_chat_teamcolors)
 949                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 950                         else
 951                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 952                 }
 953                 else if(teamsay)
 954                 {
 955                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 956                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 957                 }
 958                 else
 959                 {
 960                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 961                         cmsgstr = "";
 962                 }
 963                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 964         }
 965         else
 966         {
 967                 msgstr = cmsgstr = "";
 968         }
 969
 970         fullmsgstr = msgstr;
 971         fullcmsgstr = cmsgstr;
 972
 973         // FLOOD CONTROL
 974         flood = 0;
 975         if(floodcontrol)
 976         {
 977                 float flood_spl;
 978                 float flood_burst;
 979                 float flood_lmax;
 980                 float lines;
 981                 if(privatesay)
 982                 {
 983                         flood_spl = autocvar_g_chat_flood_spl_tell;
 984                         flood_burst = autocvar_g_chat_flood_burst_tell;
 985                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 986                         flood_field = floodcontrol_chattell;
 987                 }
 988                 else if(teamsay)
 989                 {
 990                         flood_spl = autocvar_g_chat_flood_spl_team;
 991                         flood_burst = autocvar_g_chat_flood_burst_team;
 992                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 993                         flood_field = floodcontrol_chatteam;
 994                 }
 995                 else
 996                 {
 997                         flood_spl = autocvar_g_chat_flood_spl;
 998                         flood_burst = autocvar_g_chat_flood_burst;
 999                         flood_lmax = autocvar_g_chat_flood_lmax;
1000                         flood_field = floodcontrol_chat;
1001                 }
1002                 flood_burst = max(0, flood_burst - 1);
1003                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1004
1005                 // do flood control for the default line size
1006                 if(msgstr != "")
1007                 {
1008                         getWrappedLine_remaining = msgstr;
1009                         msgstr = "";
1010                         lines = 0;
1011                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1012                         {
1013                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1014                                 ++lines;
1015                         }
1016                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1017
1018                         if(getWrappedLine_remaining != "")
1019                         {
1020                                 msgstr = strcat(msgstr, "\n");
1021                                 flood = 2;
1022                         }
1023
1024                         if(time >= source.flood_field)
1025                         {
1026                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1027                         }
1028                         else
1029                         {
1030                                 flood = 1;
1031                                 msgstr = fullmsgstr;
1032                         }
1033                 }
1034                 else
1035                 {
1036                         if(time >= source.flood_field)
1037                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1038                         else
1039                                 flood = 1;
1040                 }
1041
1042                 if (timeoutStatus == 2) //when game is paused, no flood protection
1043                         source.flood_field = flood = 0;
1044         }
1045
1046         if(flood == 2) // cannot happen for empty msgstr
1047         {
1048                 if(autocvar_g_chat_flood_notify_flooder)
1049                 {
1050                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1051                         sourcecmsgstr = "";
1052                 }
1053                 else
1054                 {
1055                         sourcemsgstr = fullmsgstr;
1056                         sourcecmsgstr = fullcmsgstr;
1057                 }
1058                 cmsgstr = "";
1059         }
1060         else
1061         {
1062                 sourcemsgstr = msgstr;
1063                 sourcecmsgstr = cmsgstr;
1064         }
1065
1066         if(!privatesay)
1067         if(source.classname != "player")
1068         {
1069                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1070                         teamsay = -1; // spectators
1071         }
1072
1073         if(flood)
1074                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1075
1076         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1077         if(privatesay)
1078                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1079
1080         if(source.muted)
1081         {
1082                 // always fake the message
1083                 ret = -1;
1084         }
1085         else if(flood == 1)
1086         {
1087                 if(autocvar_g_chat_flood_notify_flooder)
1088                 {
1089                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1090                         ret = 0;
1091                 }
1092                 else
1093                         ret = -1;
1094         }
1095         else
1096         {
1097                 ret = 1;
1098         }
1099
1100         if(sourcemsgstr != "" && ret != 0)
1101         {
1102                 if(ret < 0) // fake
1103                 {
1104                         sprint(source, sourcemsgstr);
1105                         if(sourcecmsgstr != "" && !privatesay)
1106                                 centerprint(source, sourcecmsgstr);
1107                 }
1108                 else if(privatesay)
1109                 {
1110                         sprint(source, sourcemsgstr);
1111                         sprint(privatesay, msgstr);
1112                         if(cmsgstr != "")
1113                                 centerprint(privatesay, cmsgstr);
1114                 }
1115                 else if(teamsay > 0)
1116                 {
1117                         sprint(source, sourcemsgstr);
1118                         if(sourcecmsgstr != "")
1119                                 centerprint(source, sourcecmsgstr);
1120                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1121                                 if(head != source)
1122                                 {
1123                                         sprint(head, msgstr);
1124                                         if(cmsgstr != "")
1125                                                 centerprint(head, cmsgstr);
1126                                 }
1127                 }
1128                 else if(teamsay < 0)
1129                 {
1130                         sprint(source, sourcemsgstr);
1131                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1132                                 if(head != source)
1133                                         sprint(head, msgstr);
1134                 }
1135                 else if(sourcemsgstr != msgstr)
1136                 {
1137                         sprint(source, sourcemsgstr);
1138                         FOR_EACH_REALCLIENT(head)
1139                                 if(head != source)
1140                                         sprint(head, msgstr);
1141                 }
1142                 else
1143                         bprint(msgstr);
1144         }
1145
1146         return ret;
1147 }
1148
1149 float GetVoiceMessageVoiceType(string type)
1150 {
1151         if(type == "taunt")
1152                 return VOICETYPE_TAUNT;
1153         if(type == "teamshoot")
1154                 return VOICETYPE_LASTATTACKER;
1155         return VOICETYPE_TEAMRADIO;
1156 }
1157
1158 string allvoicesamples;
1159 .string GetVoiceMessageSampleField(string type)
1160 {
1161         GetPlayerSoundSampleField_notFound = 0;
1162         switch(type)
1163         {
1164 #define _VOICEMSG(m) case #m: return playersound_##m;
1165                 ALLVOICEMSGS
1166 #undef _VOICEMSG
1167         }
1168         GetPlayerSoundSampleField_notFound = 1;
1169         return playersound_taunt;
1170 }
1171
1172 .string GetPlayerSoundSampleField(string type)
1173 {
1174         GetPlayerSoundSampleField_notFound = 0;
1175         switch(type)
1176         {
1177 #define _VOICEMSG(m) case #m: return playersound_##m;
1178                 ALLPLAYERSOUNDS
1179 #undef _VOICEMSG
1180         }
1181         GetPlayerSoundSampleField_notFound = 1;
1182         return playersound_taunt;
1183 }
1184
1185 void PrecacheGlobalSound(string samplestring)
1186 {
1187         float n, i;
1188         tokenize_console(samplestring);
1189         n = stof(argv(1));
1190         if(n > 0)
1191         {
1192                 for(i = 1; i <= n; ++i)
1193                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1194         }
1195         else
1196         {
1197                 precache_sound(strcat(argv(0), ".wav"));
1198         }
1199 }
1200
1201 void PrecachePlayerSounds(string f)
1202 {
1203         float fh;
1204         string s;
1205         fh = fopen(f, FILE_READ);
1206         if(fh < 0)
1207                 return;
1208         while((s = fgets(fh)))
1209         {
1210                 if(tokenize_console(s) != 3)
1211                 {
1212                         dprint("Invalid sound info line: ", s, "\n");
1213                         continue;
1214                 }
1215                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1216         }
1217         fclose(fh);
1218
1219         if not(allvoicesamples)
1220         {
1221 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1222                 ALLVOICEMSGS
1223 #undef _VOICEMSG
1224                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1225         }
1226 }
1227
1228 void ClearPlayerSounds()
1229 {
1230 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1231         ALLPLAYERSOUNDS
1232         ALLVOICEMSGS
1233 #undef _VOICEMSG
1234 }
1235
1236 float LoadPlayerSounds(string f, float first)
1237 {
1238         float fh;
1239         string s;
1240         var .string field;
1241         fh = fopen(f, FILE_READ);
1242         if(fh < 0)
1243         {
1244                 dprint("Player sound file not found: ", f, "\n");
1245                 return 0;
1246         }
1247         while((s = fgets(fh)))
1248         {
1249                 if(tokenize_console(s) != 3)
1250                         continue;
1251                 field = GetPlayerSoundSampleField(argv(0));
1252                 if(GetPlayerSoundSampleField_notFound)
1253                         field = GetVoiceMessageSampleField(argv(0));
1254                 if(GetPlayerSoundSampleField_notFound)
1255                         continue;
1256                 if(self.field)
1257                         strunzone(self.field);
1258                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1259         }
1260         fclose(fh);
1261         return 1;
1262 }
1263
1264 .float modelindex_for_playersound;
1265 .float skinindex_for_playersound;
1266 void UpdatePlayerSounds()
1267 {
1268         if(self.modelindex == self.modelindex_for_playersound)
1269         if(self.skinindex == self.skinindex_for_playersound)
1270                 return;
1271         self.modelindex_for_playersound = self.modelindex;
1272         self.skinindex_for_playersound = self.skinindex;
1273         ClearPlayerSounds();
1274         LoadPlayerSounds("sound/player/default.sounds", 1);
1275         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1276                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1277 }
1278
1279 void FakeGlobalSound(string sample, float chan, float voicetype)
1280 {
1281         float n;
1282         float tauntrand;
1283
1284         if(sample == "")
1285                 return;
1286
1287         tokenize_console(sample);
1288         n = stof(argv(1));
1289         if(n > 0)
1290                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1291         else
1292                 sample = strcat(argv(0), ".wav"); // randomization
1293
1294         switch(voicetype)
1295         {
1296                 case VOICETYPE_LASTATTACKER_ONLY:
1297                         break;
1298                 case VOICETYPE_LASTATTACKER:
1299                         if(self.pusher)
1300                         {
1301                                 msg_entity = self;
1302                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1303                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1304                         }
1305                         break;
1306                 case VOICETYPE_TEAMRADIO:
1307                         msg_entity = self;
1308                         if(msg_entity.cvar_cl_voice_directional == 1)
1309                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1310                         else
1311                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1312                         break;
1313                 case VOICETYPE_AUTOTAUNT:
1314                         if(!sv_autotaunt)
1315                                 break;
1316                         if(!sv_taunt)
1317                                 break;
1318                         if(sv_gentle)
1319                                 break;
1320                         tauntrand = random();
1321                         msg_entity = self;
1322                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1323                         {
1324                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1325                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1326                                 else
1327                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1328                         }
1329                         break;
1330                 case VOICETYPE_TAUNT:
1331                         if(self.classname == "player")
1332                                 if(self.deadflag == DEAD_NO)
1333                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1334                         if(!sv_taunt)
1335                                 break;
1336                         if(sv_gentle)
1337                                 break;
1338                         msg_entity = self;
1339                         if (msg_entity.cvar_cl_voice_directional >= 1)
1340                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1341                         else
1342                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1343                         break;
1344                 case VOICETYPE_PLAYERSOUND:
1345                         msg_entity = self;
1346                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1347                         break;
1348                 default:
1349                         backtrace("Invalid voice type!");
1350                         break;
1351         }
1352 }
1353
1354 void GlobalSound(string sample, float chan, float voicetype)
1355 {
1356         float n;
1357         float tauntrand;
1358
1359         if(sample == "")
1360                 return;
1361
1362         tokenize_console(sample);
1363         n = stof(argv(1));
1364         if(n > 0)
1365                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1366         else
1367                 sample = strcat(argv(0), ".wav"); // randomization
1368
1369         switch(voicetype)
1370         {
1371                 case VOICETYPE_LASTATTACKER_ONLY:
1372                         if(self.pusher)
1373                         {
1374                                 msg_entity = self.pusher;
1375                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1376                                 {
1377                                         if(msg_entity.cvar_cl_voice_directional == 1)
1378                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1379                                         else
1380                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1381                                 }
1382                         }
1383                         break;
1384                 case VOICETYPE_LASTATTACKER:
1385                         if(self.pusher)
1386                         {
1387                                 msg_entity = self.pusher;
1388                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1389                                 {
1390                                         if(msg_entity.cvar_cl_voice_directional == 1)
1391                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1392                                         else
1393                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1394                                 }
1395                                 msg_entity = self;
1396                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1397                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1398                         }
1399                         break;
1400                 case VOICETYPE_TEAMRADIO:
1401                         FOR_EACH_REALCLIENT(msg_entity)
1402                                 if(!teams_matter || msg_entity.team == self.team)
1403                                 {
1404                                         if(msg_entity.cvar_cl_voice_directional == 1)
1405                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1406                                         else
1407                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1408                                 }
1409                         break;
1410                 case VOICETYPE_AUTOTAUNT:
1411                         if(!sv_autotaunt)
1412                                 break;
1413                         if(!sv_taunt)
1414                                 break;
1415                         if(sv_gentle)
1416                                 break;
1417                         tauntrand = random();
1418                         FOR_EACH_REALCLIENT(msg_entity)
1419                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1420                                 {
1421                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1422                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1423                                         else
1424                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1425                                 }
1426                         break;
1427                 case VOICETYPE_TAUNT:
1428                         if(self.classname == "player")
1429                                 if(self.deadflag == DEAD_NO)
1430                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1431                         if(!sv_taunt)
1432                                 break;
1433                         if(sv_gentle)
1434                                 break;
1435                         FOR_EACH_REALCLIENT(msg_entity)
1436                         {
1437                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1438                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1439                                 else
1440                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1441                         }
1442                         break;
1443                 case VOICETYPE_PLAYERSOUND:
1444                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1445                         break;
1446                 default:
1447                         backtrace("Invalid voice type!");
1448                         break;
1449         }
1450 }
1451
1452 void PlayerSound(.string samplefield, float chan, float voicetype)
1453 {
1454         GlobalSound(self.samplefield, chan, voicetype);
1455 }
1456
1457 void VoiceMessage(string type, string msg)
1458 {
1459         var .string sample;
1460         float voicetype, ownteam;
1461         float flood;
1462         sample = GetVoiceMessageSampleField(type);
1463
1464         if(GetPlayerSoundSampleField_notFound)
1465         {
1466                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1467                 return;
1468         }
1469
1470         voicetype = GetVoiceMessageVoiceType(type);
1471         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1472
1473         flood = Say(self, ownteam, world, msg, 1);
1474
1475         if (flood > 0)
1476                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1477         else if (flood < 0)
1478                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1479 }
1480
1481 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1482 {
1483 //      show_message
1484 //      0 (00) automove centerprint, admin message
1485 //      1 (01) automove centerprint, no admin message
1486 //      2 (10) no centerprint, admin message
1487 //      3 (11) no centerprint, no admin message
1488
1489         float lockteams_backup;
1490
1491         lockteams_backup = lockteams;  // backup any team lock
1492
1493         lockteams = 0;  // disable locked teams
1494
1495         TeamchangeFrags(client);  // move the players frags
1496         SetPlayerColors(client, team_colour - 1);  // set the players colour
1497         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1498
1499         lockteams = lockteams_backup;  // restore the team lock
1500
1501         LogTeamchange(client.playerid, client.team, type);
1502
1503         if not(show_message & 1) // admin message
1504                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1505
1506         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1507 }