qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 .float prevstrengthsound;
 131 .float prevstrengthsoundattempt;
 132 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 133 {
 134                 if((!g_minstagib)
 135                         && (player.items & IT_STRENGTH)
 136                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 137                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 138                 {
 139                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 140                         player.prevstrengthsound = time;
 141                 }
 142                 player.prevstrengthsoundattempt = time;
 143 }
 144
 145 // this function calculates w_shotorg and w_shotdir based on the weapon model
 146 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 147 // make sure you call makevectors first (FIXME?)
 148 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 149 {
 150         float nudge = 1; // added to traceline target and subtracted from result
 151         float oldsolid;
 152         vector vecs, dv;
 153         oldsolid = ent.dphitcontentsmask;
 154         if(ent.weapon == WEP_RIFLE)
 155                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 156         else
 157                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 158         if(antilag)
 159                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 160                 // passing world, because we do NOT want it to touch dphitcontentsmask
 161         else
 162                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 163         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 164
 165         vector vf, vr, vu;
 166         vf = v_forward;
 167         vr = v_right;
 168         vu = v_up;
 169         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 170         v_forward = vf;
 171         v_right = vr;
 172         v_up = vu;
 173
 174         // un-adjust trueaim if shotend is too close
 175         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 176                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 177
 178         // track max damage
 179         if(accuracy_canbegooddamage(ent))
 180                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 181
 182         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 183
 184         if(ent.weaponentity.movedir_x > 0)
 185                 vecs = ent.weaponentity.movedir;
 186         else
 187                 vecs = '0 0 0';
 188
 189         dv = v_right * -vecs_y + v_up * vecs_z;
 190         w_shotorg = ent.origin + ent.view_ofs + dv;
 191
 192         // now move the shotorg forward as much as requested if possible
 193         if(antilag)
 194         {
 195                 if(ent.antilag_debug)
 196                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 197                 else
 198                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 199         }
 200         else
 201                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 202         w_shotorg = trace_endpos - v_forward * nudge;
 203         // calculate the shotdir from the chosen shotorg
 204         w_shotdir = normalize(w_shotend - w_shotorg);
 205
 206         if (antilag)
 207         if (!ent.cvar_cl_noantilag)
 208         {
 209                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 210                 {
 211                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 212                         if (!trace_ent.takedamage)
 213                         {
 214                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 215                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 216                                 {
 217                                         entity e;
 218                                         e = trace_ent;
 219                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 220                                         if(trace_ent == e)
 221                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 222                                 }
 223                         }
 224                 }
 225                 else if(autocvar_g_antilag == 3) // client side hitscan
 226                 {
 227                         // this part MUST use prydon cursor
 228                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 229                         if (ent.cursor_trace_ent != ent)         // just to make sure
 230                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 231                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 232                         {
 233                                 // verify that the shot would miss without antilag
 234                                 // (avoids an issue where guns would always shoot at their origin)
 235                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 236                                 if (!trace_ent.takedamage)
 237                                 {
 238                                         // verify that the shot would hit if altered
 239                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 240                                         if (trace_ent == ent.cursor_trace_ent)
 241                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 242                                         else
 243                                                 print("antilag fail\n");
 244                                 }
 245                         }
 246                 }
 247         }
 248
 249         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 250
 251         if (!g_norecoil)
 252                 ent.punchangle_x = recoil * -1;
 253
 254         if (snd != "")
 255         {
 256                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 257                 W_PlayStrengthSound(ent);
 258         }
 259
 260         // nudge w_shotend so a trace to w_shotend hits
 261         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 262 }
 263
 264 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 265 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 266 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 267 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 269
 270 float CL_Weaponentity_CustomizeEntityForClient()
 271 {
 272         self.viewmodelforclient = self.owner;
 273         if(other.classname == "spectator")
 274                 if(other.enemy == self.owner)
 275                         self.viewmodelforclient = other;
 276         return TRUE;
 277 }
 278
 279 /*
 280  * supported formats:
 281  *
 282  * 1. simple animated model, muzzle flash handling on h_ model:
 283  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 284  *      tags:
 285  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 286  *        shell = casings ejection point (must be on the right hand side of the gun)
 287  *        weapon = attachment for v_tuba.md3
 288  *    v_tuba.md3 - first and third person model
 289  *    g_tuba.md3 - pickup model
 290  *
 291  * 2. simple animated model, muzzle flash handling on v_ model:
 292  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 293  *      tags:
 294  *        weapon = attachment for v_tuba.md3
 295  *    v_tuba.md3 - first and third person model
 296  *      tags:
 297  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 298  *        shell = casings ejection point (must be on the right hand side of the gun)
 299  *    g_tuba.md3 - pickup model
 300  *
 301  * 3. fully animated model, muzzle flash handling on h_ model:
 302  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 303  *      tags:
 304  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 305  *        shell = casings ejection point (must be on the right hand side of the gun)
 306  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 307  *    v_tuba.md3 - third person model
 308  *    g_tuba.md3 - pickup model
 309  *
 310  * 4. fully animated model, muzzle flash handling on v_ model:
 311  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 312  *      tags:
 313  *        shot = muzzle end (shot origin)
 314  *        shell = casings ejection point (must be on the right hand side of the gun)
 315  *    v_tuba.md3 - third person model
 316  *      tags:
 317  *        shot = muzzle end (for muzzle flashes)
 318  *    g_tuba.md3 - pickup model
 319  */
 320
 321 // writes:
 322 //   self.origin, self.angles
 323 //   self.weaponentity
 324 //   self.movedir, self.view_ofs
 325 //   attachment stuff
 326 //   anim stuff
 327 // to free:
 328 //   call again with ""
 329 //   remove the ent
 330 void CL_WeaponEntity_SetModel(string name)
 331 {
 332         float v_shot_idx;
 333         if (name != "")
 334         {
 335                 // if there is a child entity, hide it until we're sure we use it
 336                 if (self.weaponentity)
 337                         self.weaponentity.model = "";
 338                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 339                 v_shot_idx = gettagindex(self, "shot"); // used later
 340                 if(!v_shot_idx)
 341                         v_shot_idx = gettagindex(self, "tag_shot");
 342
 343                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 344                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 345                 self.anim_fire1  = animfixfps(self, '0 1 0.01');
 346                 self.anim_fire2  = animfixfps(self, '1 1 0.01');
 347                 self.anim_idle   = animfixfps(self, '2 1 0.01');
 348                 self.anim_reload = animfixfps(self, '3 1 0.01');
 349
 350                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 351                 // if we don't, this is a "real" animated model
 352                 if(gettagindex(self, "weapon"))
 353                 {
 354                         if (!self.weaponentity)
 355                                 self.weaponentity = spawn();
 356                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 357                         setattachment(self.weaponentity, self, "weapon");
 358                 }
 359                 else if(gettagindex(self, "tag_weapon"))
 360                 {
 361                         if (!self.weaponentity)
 362                                 self.weaponentity = spawn();
 363                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 364                         setattachment(self.weaponentity, self, "tag_weapon");
 365                 }
 366                 else
 367                 {
 368                         if(self.weaponentity)
 369                                 remove(self.weaponentity);
 370                         self.weaponentity = world;
 371                 }
 372
 373                 setorigin(self,'0 0 0');
 374                 self.angles = '0 0 0';
 375                 self.frame = 0;
 376                 self.viewmodelforclient = world;
 377
 378                 float idx;
 379
 380                 if(v_shot_idx) // v_ model attached to invisible h_ model
 381                 {
 382                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 383                 }
 384                 else
 385                 {
 386                         idx = gettagindex(self, "shot");
 387                         if(!idx)
 388                                 idx = gettagindex(self, "tag_shot");
 389                         if(idx)
 390                                 self.movedir = gettaginfo(self, idx);
 391                         else
 392                         {
 393                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 394                                 self.movedir = '0 0 0';
 395                         }
 396                 }
 397
 398                 if(self.weaponentity) // v_ model attached to invisible h_ model
 399                 {
 400                         idx = gettagindex(self.weaponentity, "shell");
 401                         if(!idx)
 402                                 idx = gettagindex(self.weaponentity, "tag_shell");
 403                         if(idx)
 404                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 405                 }
 406                 else
 407                         idx = 0;
 408                 if(!idx)
 409                 {
 410                         idx = gettagindex(self, "shell");
 411                         if(!idx)
 412                                 idx = gettagindex(self, "tag_shell");
 413                         if(idx)
 414                                 self.spawnorigin = gettaginfo(self, idx);
 415                         else
 416                         {
 417                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 418                                 self.spawnorigin = self.movedir;
 419                         }
 420                 }
 421
 422                 if(v_shot_idx)
 423                 {
 424                         self.oldorigin = '0 0 0'; // use regular attachment
 425                 }
 426                 else
 427                 {
 428                         if(self.weaponentity)
 429                         {
 430                                 idx = gettagindex(self, "weapon");
 431                                 if(!idx)
 432                                         idx = gettagindex(self, "tag_weapon");
 433                         }
 434                         else
 435                         {
 436                                 idx = gettagindex(self, "handle");
 437                                 if(!idx)
 438                                         idx = gettagindex(self, "tag_handle");
 439                         }
 440                         if(idx)
 441                         {
 442                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 443                         }
 444                         else
 445                         {
 446                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 447                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 448                         }
 449                 }
 450
 451                 self.viewmodelforclient = self.owner;
 452         }
 453         else
 454         {
 455                 self.model = "";
 456                 if(self.weaponentity)
 457                         remove(self.weaponentity);
 458                 self.weaponentity = world;
 459                 self.movedir = '0 0 0';
 460                 self.spawnorigin = '0 0 0';
 461                 self.oldorigin = '0 0 0';
 462                 self.anim_fire1  = '0 1 0.01';
 463                 self.anim_fire2  = '0 1 0.01';
 464                 self.anim_idle   = '0 1 0.01';
 465                 self.anim_reload = '0 1 0.01';
 466         }
 467
 468         self.view_ofs = '0 0 0';
 469
 470         if(self.movedir_x >= 0)
 471         {
 472                 vector v0;
 473                 v0 = self.movedir;
 474                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 475                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 476         }
 477         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 478         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 479
 480         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 481
 482         // check if an instant weapon switch occurred
 483         setorigin(self, self.view_ofs);
 484         // reset animstate now
 485         self.wframe = WFRAME_IDLE;
 486         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 487 }
 488
 489 vector CL_Weapon_GetShotOrg(float wpn)
 490 {
 491         entity wi, oldself;
 492         vector ret;
 493         wi = get_weaponinfo(wpn);
 494         oldself = self;
 495         self = spawn();
 496         CL_WeaponEntity_SetModel(wi.mdl);
 497         ret = self.movedir;
 498         CL_WeaponEntity_SetModel("");
 499         remove(self);
 500         self = oldself;
 501         return ret;
 502 }
 503
 504 void CL_Weaponentity_Think()
 505 {
 506         float tb;
 507         self.nextthink = time;
 508         if (intermission_running)
 509                 self.frame = self.anim_idle_x;
 510         if (self.owner.weaponentity != self)
 511         {
 512                 if (self.weaponentity)
 513                         remove(self.weaponentity);
 514                 remove(self);
 515                 return;
 516         }
 517         if (self.owner.deadflag != DEAD_NO)
 518         {
 519                 self.model = "";
 520                 if (self.weaponentity)
 521                         self.weaponentity.model = "";
 522                 return;
 523         }
 524         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 525         {
 526                 self.weaponname = self.owner.weaponname;
 527                 self.dmg = self.owner.modelindex;
 528                 self.deadflag = self.owner.deadflag;
 529
 530                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 531         }
 532
 533         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 534         self.effects = self.owner.effects & EFMASK_CHEAP;
 535         self.effects &~= EF_LOWPRECISION;
 536         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 537         self.effects &~= EF_TELEPORT_BIT;
 538         self.effects &~= EF_RESTARTANIM_BIT;
 539         self.effects |= tb;
 540
 541         if(self.owner.alpha == default_player_alpha)
 542                 self.alpha = default_weapon_alpha;
 543         else if(self.owner.alpha != 0)
 544                 self.alpha = self.owner.alpha;
 545         else
 546                 self.alpha = 1;
 547
 548         self.glowmod = self.owner.weaponentity_glowmod;
 549         self.colormap = self.owner.colormap;
 550         if (self.weaponentity)
 551         {
 552                 self.weaponentity.effects = self.effects;
 553                 self.weaponentity.alpha = self.alpha;
 554                 self.weaponentity.colormap = self.colormap;
 555                 self.weaponentity.glowmod = self.glowmod;
 556         }
 557
 558         self.angles = '0 0 0';
 559         float f;
 560         f = 0;
 561         if (self.state == WS_RAISE && !intermission_running)
 562         {
 563                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 564                 self.angles_x = -90 * f * f;
 565         }
 566         else if (self.state == WS_DROP && !intermission_running)
 567         {
 568                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 569                 self.angles_x = -90 * f * f;
 570         }
 571         else if (self.state == WS_CLEAR)
 572         {
 573                 f = 1;
 574                 self.angles_x = -90 * f * f;
 575         }
 576 }
 577
 578 void CL_ExteriorWeaponentity_Think()
 579 {
 580         float tag_found;
 581         vector ang;
 582         self.nextthink = time;
 583         if (self.owner.exteriorweaponentity != self)
 584         {
 585                 remove(self);
 586                 return;
 587         }
 588         if (self.owner.deadflag != DEAD_NO)
 589         {
 590                 self.model = "";
 591                 return;
 592         }
 593         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 594         {
 595                 self.weaponname = self.owner.weaponname;
 596                 self.dmg = self.owner.modelindex;
 597                 self.deadflag = self.owner.deadflag;
 598                 if (self.owner.weaponname != "")
 599                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 600                 else
 601                         self.model = "";
 602
 603                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 604                 {
 605                         self.tag_index = tag_found;
 606                         self.tag_entity = self.owner;
 607                 }
 608                 else
 609                         setattachment(self, self.owner, "bip01 r hand");
 610
 611                 // if that didn't find a tag, hide the exterior weapon model
 612                 if (!self.tag_index)
 613                         self.model = "";
 614         }
 615         self.effects = self.owner.effects;
 616         if(sv_pitch_min == sv_pitch_max)
 617                 self.effects |= EF_LOWPRECISION;
 618         else
 619                 self.effects &~= EF_LOWPRECISION;
 620         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 621         if(self.owner.alpha == default_player_alpha)
 622                 self.alpha = default_weapon_alpha;
 623         else if(self.owner.alpha != 0)
 624                 self.alpha = self.owner.alpha;
 625         else
 626                 self.alpha = 1;
 627
 628         if (!intermission_running)
 629         {
 630                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 631                 ang_y = 0;
 632                 ang_z = 0;
 633
 634                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 635                 {
 636                         ang_y = self.owner.v_angle_y;
 637                         makevectors(ang);
 638                         var vector v = v_forward;
 639                         var float t = self.tag_entity.frame1time;
 640                         var float f = self.tag_entity.frame;
 641                         self.tag_entity.frame1time = time;
 642                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 643                         gettaginfo(self.tag_entity, self.tag_index);
 644                         self.tag_entity.frame1time = t;
 645                         self.tag_entity.frame = f;
 646                         // untransform v according to this coordinate space
 647                         vector w;
 648                         w_x = v_forward * v;
 649                         w_y = -v_right * v;
 650                         w_z = v_up * v;
 651                         self.angles = vectoangles(w);
 652                 }
 653                 else
 654                 {
 655                         ang_x = -/* don't ask */ang_x;
 656                         self.angles = ang;
 657                 }
 658
 659                 if(autocvar_g_loituma)
 660                 {
 661                         vector modangles;
 662                         float t;
 663
 664                         t = time * autocvar_g_loituma;
 665
 666                         modangles_x = t * 360;
 667                         modangles_y = 90;
 668                         modangles_z = 0;
 669
 670                         self.angles =
 671                                 AnglesTransform_ToAngles(
 672                                         AnglesTransform_Multiply(
 673                                                 AnglesTransform_FromAngles(self.angles),
 674                                                 AnglesTransform_FromAngles(modangles)
 675                                         )
 676                                 );
 677                 }
 678         }
 679
 680         self.glowmod = self.owner.weaponentity_glowmod;
 681         self.colormap = self.owner.colormap;
 682 }
 683
 684 // spawning weaponentity for client
 685 void CL_SpawnWeaponentity()
 686 {
 687         self.weaponentity = spawn();
 688         self.weaponentity.classname = "weaponentity";
 689         self.weaponentity.solid = SOLID_NOT;
 690         self.weaponentity.owner = self;
 691         setmodel(self.weaponentity, ""); // precision set when changed
 692         setorigin(self.weaponentity, '0 0 0');
 693         self.weaponentity.angles = '0 0 0';
 694         self.weaponentity.viewmodelforclient = self;
 695         self.weaponentity.flags = 0;
 696         self.weaponentity.think = CL_Weaponentity_Think;
 697         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 698         self.weaponentity.nextthink = time;
 699
 700         self.exteriorweaponentity = spawn();
 701         self.exteriorweaponentity.classname = "exteriorweaponentity";
 702         self.exteriorweaponentity.solid = SOLID_NOT;
 703         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 704         self.exteriorweaponentity.owner = self;
 705         setorigin(self.exteriorweaponentity, '0 0 0');
 706         self.exteriorweaponentity.angles = '0 0 0';
 707         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 708         self.exteriorweaponentity.nextthink = time;
 709 }
 710
 711 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 712 {
 713         msg_entity = e;
 714         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 715         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 716         WriteByte(MSG_ONE, wpn);
 717         WriteString(MSG_ONE, wpnname);
 718         WriteByte(MSG_ONE, type);
 719 }
 720
 721 .float hasweapon_complain_spam;
 722
 723 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 724 {
 725         float weaponbit, f;
 726         entity oldself;
 727
 728         if(time < self.hasweapon_complain_spam)
 729                 complain = 0;
 730         if(complain)
 731                 self.hasweapon_complain_spam = time + 0.2;
 732
 733         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 734         {
 735                 if (complain)
 736                         sprint(self, "Invalid weapon\n");
 737                 return FALSE;
 738         }
 739         weaponbit = W_WeaponBit(wpn);
 740         if (cl.weapons & weaponbit)
 741         {
 742                 if (andammo)
 743                 {
 744                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 745                         {
 746                                 f = 1;
 747                         }
 748                         else
 749                         {
 750                                 oldself = self;
 751                                 self = cl;
 752                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 753                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 754
 755                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 756                                 entity mine;
 757                                 if(wpn == WEP_MINE_LAYER)
 758                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 759                                         f = 1;
 760
 761                                 self = oldself;
 762                         }
 763                         if (!f)
 764                         {
 765                                 if (complain)
 766                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 767                                 {
 768                                         play2(cl, "weapons/unavailable.wav");
 769                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 770                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 771                                 }
 772                                 return FALSE;
 773                         }
 774                 }
 775                 return TRUE;
 776         }
 777         if (complain)
 778         {
 779                 // DRESK - 3/16/07
 780                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 781                 if(weaponsInMap & weaponbit)
 782                 {
 783                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 784                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 785
 786                         if(autocvar_g_showweaponspawns)
 787                         {
 788                                 entity e;
 789                                 string s;
 790
 791                                 e = get_weaponinfo(wpn);
 792                                 s = e.model2;
 793
 794                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 795                                 {
 796                                         if(e.classname == "droppedweapon")
 797                                                 continue;
 798                                         if not(e.flags & FL_ITEM)
 799                                                 continue;
 800                                         WaypointSprite_Spawn(
 801                                                 s,
 802                                                 1, 0,
 803                                                 world, e.origin,
 804                                                 self, 0,
 805                                                 world, enemy,
 806                                                 0,
 807                                                 RADARICON_NONE, '0 0 0'
 808                                         );
 809                                 }
 810                         }
 811                 }
 812                 else
 813                 {
 814                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 815                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 816                 }
 817
 818                 play2(cl, "weapons/unavailable.wav");
 819         }
 820         return FALSE;
 821 }
 822
 823 // Weapon subs
 824 void w_clear()
 825 {
 826         if (self.weapon != -1)
 827         {
 828                 self.weapon = 0;
 829                 self.switchingweapon = 0;
 830         }
 831         if (self.weaponentity)
 832         {
 833                 self.weaponentity.state = WS_CLEAR;
 834                 self.weaponentity.effects = 0;
 835         }
 836 }
 837
 838 void w_ready()
 839 {
 840         if (self.weaponentity)
 841                 self.weaponentity.state = WS_READY;
 842         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 843 }
 844
 845 // Setup weapon for client (after this raise frame will be launched)
 846 void weapon_setup(float windex)
 847 {
 848         entity e;
 849         e = get_weaponinfo(windex);
 850         self.items &~= IT_AMMO;
 851         self.items = self.items | e.items;
 852
 853         // the two weapon entities will notice this has changed and update their models
 854         self.weapon = windex;
 855         self.switchingweapon = windex; // to make sure
 856         self.weaponname = e.mdl;
 857         self.bulletcounter = 0;
 858 }
 859
 860 // perform weapon to attack (weaponstate and attack_finished check is here)
 861 void W_SwitchToOtherWeapon(entity pl)
 862 {
 863         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 864         float w, ww;
 865         w = W_WeaponBit(pl.weapon);
 866         pl.weapons &~= w;
 867         ww = w_getbestweapon(pl);
 868         pl.weapons |= w;
 869         if(ww)
 870                 W_SwitchWeapon_Force(pl, ww);
 871 }
 872 .float prevdryfire;
 873 float weapon_prepareattack_checkammo(float secondary)
 874 {
 875         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 876         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 877         {
 878                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 879                 entity mine;
 880                 if(self.weapon == WEP_MINE_LAYER)
 881                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 882                         return FALSE;
 883
 884                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 885                 {
 886                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 887                         self.prevdryfire = time;
 888                 }
 889
 890                 W_SwitchToOtherWeapon(self);
 891                 return FALSE;
 892         }
 893         return TRUE;
 894 }
 895 .float race_penalty;
 896 float weapon_prepareattack_check(float secondary, float attacktime)
 897 {
 898         if(!weapon_prepareattack_checkammo(secondary))
 899                 return FALSE;
 900
 901         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 902         //if all players readied up and the countdown is running
 903         if(time < game_starttime || time < self.race_penalty) {
 904                 return FALSE;
 905         }
 906
 907         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 908                 return FALSE;
 909
 910         // do not even think about shooting if switching
 911         if(self.switchweapon != self.weapon)
 912                 return FALSE;
 913
 914         if(attacktime >= 0)
 915         {
 916                 // don't fire if previous attack is not finished
 917                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 918                         return FALSE;
 919                 // don't fire while changing weapon
 920                 if (self.weaponentity.state != WS_READY)
 921                         return FALSE;
 922         }
 923
 924         return TRUE;
 925 }
 926 float weapon_prepareattack_do(float secondary, float attacktime)
 927 {
 928         self.weaponentity.state = WS_INUSE;
 929
 930         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 931
 932         // if the weapon hasn't been firing continuously, reset the timer
 933         if(attacktime >= 0)
 934         {
 935                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 936                 {
 937                         ATTACK_FINISHED(self) = time;
 938                         //dprint("resetting attack finished to ", ftos(time), "\n");
 939                 }
 940                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 941         }
 942         self.bulletcounter += 1;
 943         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 944         return TRUE;
 945 }
 946 float weapon_prepareattack(float secondary, float attacktime)
 947 {
 948         if(weapon_prepareattack_check(secondary, attacktime))
 949         {
 950                 weapon_prepareattack_do(secondary, attacktime);
 951                 return TRUE;
 952         }
 953         else
 954                 return FALSE;
 955 }
 956
 957 void weapon_thinkf(float fr, float t, void() func)
 958 {
 959         vector a;
 960         vector of, or, ou;
 961         float restartanim;
 962
 963         if(fr == WFRAME_DONTCHANGE)
 964         {
 965                 fr = self.weaponentity.wframe;
 966                 restartanim = FALSE;
 967         }
 968         else if (fr == WFRAME_IDLE)
 969                 restartanim = FALSE;
 970         else
 971                 restartanim = TRUE;
 972
 973         of = v_forward;
 974         or = v_right;
 975         ou = v_up;
 976
 977         if (self.weaponentity)
 978         {
 979                 self.weaponentity.wframe = fr;
 980                 if (fr == WFRAME_IDLE)
 981                         a = self.weaponentity.anim_idle;
 982                 else if (fr == WFRAME_FIRE1)
 983                         a = self.weaponentity.anim_fire1;
 984                 else if (fr == WFRAME_FIRE2)
 985                         a = self.weaponentity.anim_fire2;
 986                 else if (fr == WFRAME_RELOAD)
 987                         a = self.weaponentity.anim_reload;
 988                 a_z *= g_weaponratefactor;
 989                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 990         }
 991
 992         v_forward = of;
 993         v_right = or;
 994         v_up = ou;
 995
 996         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 997         {
 998                 backtrace("Tried to override initial weapon think function - should this really happen?");
 999         }
1000
1001         t *= W_WeaponRateFactor();
1002
1003         // VorteX: haste can be added here
1004         if (self.weapon_think == w_ready)
1005         {
1006                 self.weapon_nextthink = time;
1007                 //dprint("started firing at ", ftos(time), "\n");
1008         }
1009         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1010         {
1011                 self.weapon_nextthink = time;
1012                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1013         }
1014         self.weapon_nextthink = self.weapon_nextthink + t;
1015         self.weapon_think = func;
1016         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1017
1018         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1019         //anim = self.anim_shoot;
1020         if (restartanim)
1021         if (t)
1022         if (!self.crouch) // shoot anim stands up, this looks bad
1023         {
1024                 vector anim;
1025                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1026                 {
1027                         anim = self.anim_melee;
1028                         anim_z = anim_y / (t + sys_frametime);
1029                         setanim(self, anim, FALSE, TRUE, TRUE);
1030                 }
1031                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1032                 {
1033                         anim = self.anim_shoot;
1034                         anim_z = anim_y / (t + sys_frametime);
1035                         setanim(self, anim, FALSE, TRUE, TRUE);
1036                 }
1037         }
1038 }
1039
1040 void weapon_boblayer1(float spd, vector org)
1041 {
1042         // VorteX: haste can be added here
1043 }
1044
1045 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1046 {
1047         vector mdirection;
1048         float mspeed;
1049         float outspeed;
1050         float nstyle;
1051         vector outvelocity;
1052
1053         mvelocity = mvelocity * g_weaponspeedfactor;
1054
1055         mdirection = normalize(mvelocity);
1056         mspeed = vlen(mvelocity);
1057
1058         nstyle = autocvar_g_projectiles_newton_style;
1059         if(nstyle == 0 || forceAbsolute)
1060         {
1061                 // absolute velocity
1062                 outvelocity = mvelocity;
1063         }
1064         else if(nstyle == 1)
1065         {
1066                 // true Newtonian projectiles
1067                 outvelocity = pvelocity + mvelocity;
1068         }
1069         else if(nstyle == 2)
1070         {
1071                 // true Newtonian projectiles with automatic aim adjustment
1072                 //
1073                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1074                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1075                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1076                 // PLUS SIGN!
1077                 // not defined?
1078                 // then...
1079                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1080                 // velocity without mdirection component > mspeed
1081                 // fire at smallest possible mspeed that works?
1082                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1083
1084                 vector solution;
1085                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1086                 if(solution_z)
1087                         outspeed = solution_y; // the larger one
1088                 else
1089                 {
1090                         //outspeed = 0; // slowest possible shot
1091                         outspeed = solution_x; // the real part (that is, the average!)
1092                         //dprint("impossible shot, adjusting\n");
1093                 }
1094
1095                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1096                 outvelocity = mdirection * outspeed;
1097         }
1098         else if(nstyle == 3)
1099         {
1100                 // pseudo-Newtonian:
1101                 outspeed = mspeed + mdirection * pvelocity;
1102                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1103                 outvelocity = mdirection * outspeed;
1104         }
1105         else if(nstyle == 4)
1106         {
1107                 // tZorkian:
1108                 outspeed = mspeed + vlen(pvelocity);
1109                 outvelocity = mdirection * outspeed;
1110         }
1111         else
1112                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1113
1114         return outvelocity;
1115 }
1116
1117 void W_AttachToShotorg(entity flash, vector offset)
1118 {
1119         entity xflash;
1120         flash.owner = self;
1121         flash.angles_z = random() * 360;
1122
1123         if(gettagindex(self.weaponentity, "shot"))
1124                 setattachment(flash, self.weaponentity, "shot");
1125         else
1126                 setattachment(flash, self.weaponentity, "tag_shot");
1127         setorigin(flash, offset);
1128
1129         xflash = spawn();
1130         copyentity(flash, xflash);
1131
1132         flash.viewmodelforclient = self;
1133
1134         if(self.weaponentity.oldorigin_x > 0)
1135         {
1136                 setattachment(xflash, self.exteriorweaponentity, "");
1137                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1138         }
1139         else
1140         {
1141                 if(gettagindex(self.exteriorweaponentity, "shot"))
1142                         setattachment(xflash, self.exteriorweaponentity, "shot");
1143                 else
1144                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1145                 setorigin(xflash, offset);
1146         }
1147 }
1148
1149 vector cliptoplane(vector v, vector p)
1150 {
1151         return v - (v * p) * p;
1152 }
1153
1154 vector solve_cubic_pq(float p, float q)
1155 {
1156         float D, u, v, a;
1157         D = q*q/4.0 + p*p*p/27.0;
1158         if(D < 0)
1159         {
1160                 // irreducibilis
1161                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1162                 u = sqrt(-4.0/3.0 * p);
1163                 // a in range 0..pi/3
1164                 // cos(a)
1165                 // cos(a + 2pi/3)
1166                 // cos(a + 4pi/3)
1167                 return
1168                         u *
1169                         (
1170                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1171                                 +
1172                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1173                                 +
1174                                 '0 0 1' * cos(a)
1175                         );
1176         }
1177         else if(D == 0)
1178         {
1179                 // simple
1180                 if(p == 0)
1181                         return '0 0 0';
1182                 u = 3*q/p;
1183                 v = -u/2;
1184                 if(u >= v)
1185                         return '1 1 0' * v + '0 0 1' * u;
1186                 else
1187                         return '0 1 1' * v + '1 0 0' * u;
1188         }
1189         else
1190         {
1191                 // cardano
1192                 u = cbrt(-q/2.0 + sqrt(D));
1193                 v = cbrt(-q/2.0 - sqrt(D));
1194                 return '1 1 1' * (u + v);
1195         }
1196 }
1197 vector solve_cubic_abcd(float a, float b, float c, float d)
1198 {
1199         // y = 3*a*x + b
1200         // x = (y - b) / 3a
1201         float p, q;
1202         vector v;
1203         p = (9*a*c - 3*b*b);
1204         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1205         v = solve_cubic_pq(p, q);
1206         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1207         if(a < 0)
1208                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1209         return v;
1210 }
1211
1212 vector findperpendicular(vector v)
1213 {
1214         vector p;
1215         p_x = v_z;
1216         p_y = -v_x;
1217         p_z = v_y;
1218         return normalize(cliptoplane(p, v));
1219 }
1220
1221 vector W_CalculateProjectileSpread(vector forward, float spread)
1222 {
1223         float sigma;
1224         vector v1, v2;
1225         float dx, dy, r;
1226         float sstyle;
1227         spread *= g_weaponspreadfactor;
1228         if(spread <= 0)
1229                 return forward;
1230         sstyle = autocvar_g_projectiles_spread_style;
1231
1232         if(sstyle == 0)
1233         {
1234                 // this is the baseline for the spread value!
1235                 // standard deviation: sqrt(2/5)
1236                 // density function: sqrt(1-r^2)
1237                 return forward + randomvec() * spread;
1238         }
1239         else if(sstyle == 1)
1240         {
1241                 // same thing, basically
1242                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1243         }
1244         else if(sstyle == 2)
1245         {
1246                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1247                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1248                 v1 = findperpendicular(forward);
1249                 v2 = cross(forward, v1);
1250                 // random point on unit circle
1251                 dx = random() * 2 * M_PI;
1252                 dy = sin(dx);
1253                 dx = cos(dx);
1254                 // radius in our dist function
1255                 r = random();
1256                 r = sqrt(r);
1257                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1258         }
1259         else if(sstyle == 3) // gauss 3d
1260         {
1261                 sigma = spread * 0.44721359549996; // match baseline stddev
1262                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1263                 v1 = forward;
1264                 v1_x += gsl_ran_gaussian(sigma);
1265                 v1_y += gsl_ran_gaussian(sigma);
1266                 v1_z += gsl_ran_gaussian(sigma);
1267                 return v1;
1268         }
1269         else if(sstyle == 4) // gauss 2d
1270         {
1271                 sigma = spread * 0.44721359549996; // match baseline stddev
1272                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1273                 v1_x = gsl_ran_gaussian(sigma);
1274                 v1_y = gsl_ran_gaussian(sigma);
1275                 v1_z = gsl_ran_gaussian(sigma);
1276                 return normalize(forward + cliptoplane(v1, forward));
1277         }
1278         else if(sstyle == 5) // 1-r
1279         {
1280                 sigma = spread * 1.154700538379252; // match baseline stddev
1281                 v1 = findperpendicular(forward);
1282                 v2 = cross(forward, v1);
1283                 // random point on unit circle
1284                 dx = random() * 2 * M_PI;
1285                 dy = sin(dx);
1286                 dx = cos(dx);
1287                 // radius in our dist function
1288                 r = random();
1289                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1290                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1291         }
1292         else if(sstyle == 6) // 1-r^2
1293         {
1294                 sigma = spread * 1.095445115010332; // match baseline stddev
1295                 v1 = findperpendicular(forward);
1296                 v2 = cross(forward, v1);
1297                 // random point on unit circle
1298                 dx = random() * 2 * M_PI;
1299                 dy = sin(dx);
1300                 dx = cos(dx);
1301                 // radius in our dist function
1302                 r = random();
1303                 r = sqrt(1 - r);
1304                 r = sqrt(1 - r);
1305                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1306         }
1307         else if(sstyle == 7) // (1-r) (2-r)
1308         {
1309                 sigma = spread * 1.224744871391589; // match baseline stddev
1310                 v1 = findperpendicular(forward);
1311                 v2 = cross(forward, v1);
1312                 // random point on unit circle
1313                 dx = random() * 2 * M_PI;
1314                 dy = sin(dx);
1315                 dx = cos(dx);
1316                 // radius in our dist function
1317                 r = random();
1318                 r = 1 - sqrt(r);
1319                 r = 1 - sqrt(r);
1320                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1321         }
1322         else
1323                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1324         return '0 0 0';
1325         /*
1326          * how to derive falloff functions:
1327          * rho(r) := (2-r) * (1-r);
1328          * a : 0;
1329          * b : 1;
1330          * rhor(r) := r * rho(r);
1331          * cr(t) := integrate(rhor(r), r, a, t);
1332          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1333          * variance : scr(b) / cr(b);
1334          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1335          * sqrt(0.4 / variance), numer;
1336          */
1337 }
1338
1339 #if 0
1340 float mspercallsum;
1341 float mspercallsstyle;
1342 float mspercallcount;
1343 #endif
1344 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1345 {
1346         if(missile.owner == world)
1347                 error("Unowned missile");
1348
1349         dir = dir + upDir * (pUpSpeed / pSpeed);
1350         dir_z += pZSpeed / pSpeed;
1351         pSpeed *= vlen(dir);
1352         dir = normalize(dir);
1353
1354 #if 0
1355         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1356         {
1357                 mspercallsum = mspercallcount = 0;
1358                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1359         }
1360         mspercallsum -= gettime(GETTIME_HIRES);
1361 #endif
1362         dir = W_CalculateProjectileSpread(dir, spread);
1363 #if 0
1364         mspercallsum += gettime(GETTIME_HIRES);
1365         mspercallcount += 1;
1366         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1367 #endif
1368
1369         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1370 }
1371
1372 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1373 {
1374         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1375 }
1376
1377 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1378 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1379
1380 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1381 {
1382         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1383                 return;
1384
1385         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1386         if(ammo_reload)
1387         {
1388                 self.clip_load -= ammo_use;
1389                 self.(weapon_load[self.weapon]) = self.clip_load;
1390         }
1391         else
1392                 self.(self.current_ammo) -= ammo_use;
1393 }
1394
1395 // weapon reloading code
1396
1397 .float reload_ammo_amount, reload_ammo_min, reload_time;
1398 .float reload_complain;
1399 .string reload_sound;
1400
1401 void W_ReloadedAndReady()
1402 {
1403         // finish the reloading process, and do the ammo transfer
1404
1405         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1406
1407         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1408         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1409                 self.clip_load = self.reload_ammo_amount;
1410         else
1411         {
1412                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1413                 {
1414                         self.clip_load += 1;
1415                         self.(self.current_ammo) -= 1;
1416                 }
1417         }
1418         self.(weapon_load[self.weapon]) = self.clip_load;
1419
1420         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1421         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1422         // so your weapon is disabled for a few seconds without reason
1423
1424         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1425
1426         w_ready();
1427 }
1428
1429 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1430 {
1431         // set global values to work with
1432
1433         self.reload_ammo_min = sent_ammo_min;
1434         self.reload_ammo_amount = sent_ammo_amount;
1435         self.reload_time = sent_time;
1436         self.reload_sound = sent_sound;
1437
1438         // check if we meet the necessary conditions to reload
1439
1440         entity e;
1441         e = get_weaponinfo(self.weapon);
1442
1443         // don't reload weapons that don't have the RELOADABLE flag
1444         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1445         {
1446                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1447                 return;
1448         }
1449
1450         // return if reloading is disabled for this weapon
1451         if(!self.reload_ammo_amount)
1452                 return;
1453
1454         // our weapon is fully loaded, no need to reload
1455         if (self.clip_load >= self.reload_ammo_amount)
1456                 return;
1457
1458         // no ammo, so nothing to load
1459         if(!self.(self.current_ammo) && self.reload_ammo_min)
1460         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1461         {
1462                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1463                 {
1464                         play2(self, "weapons/unavailable.wav");
1465                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1466                         self.reload_complain = time + 1;
1467                 }
1468                 // switch away if the amount of ammo is not enough to keep using this weapon
1469                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1470                 {
1471                         self.clip_load = -1; // reload later
1472                         W_SwitchToOtherWeapon(self);
1473                 }
1474                 return;
1475         }
1476
1477         if (self.weaponentity)
1478         {
1479                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1480                         return;
1481
1482                 // allow switching away while reloading, but this will cause a new reload!
1483                 self.weaponentity.state = WS_READY;
1484         }
1485
1486         // now begin the reloading process
1487
1488         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1489
1490         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1491         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1492         // so your weapon is disabled for a few seconds without reason
1493
1494         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1495
1496         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1497
1498         if(self.clip_load < 0)
1499                 self.clip_load = 0;
1500         self.old_clip_load = self.clip_load;
1501         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1502 }