qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  73         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  74         {
  75                 thisv = targ.origin;
  76                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  77                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  78                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  79                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  80                 if(i || j || k)
  81                 {
  82                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  83                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  84                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  85                 }
  86                 else
  87                 {
  88                         // first run
  89                         mi = ma = thisv;
  90                 }
  91         }
  92
  93         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  94         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  95         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  96         ret_z = thisv_z - myv_z;
  97         return ret;
  98 }
  99
 100 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 101 {
 102         vector hitplot;
 103         vector org;
 104         float lag;
 105
 106         if(player.hitplotfh >= 0)
 107         {
 108                 lag = ANTILAG_LATENCY(player);
 109                 if(lag < 0.001)
 110                         lag = 0;
 111                 if(clienttype(player) != CLIENTTYPE_REAL)
 112                         lag = 0; // only antilag for clients
 113
 114                 org = player.origin + player.view_ofs;
 115                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 116                 if(trace_ent.flags & FL_CLIENT)
 117                 {
 118                         antilag_takeback(trace_ent, time - lag);
 119                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 120                         antilag_restore(trace_ent);
 121                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 122                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 123                 }
 124         }
 125 }
 126
 127 vector w_shotorg;
 128 vector w_shotdir;
 129 vector w_shotend;
 130
 131 .float prevstrengthsound;
 132 .float prevstrengthsoundattempt;
 133 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 134 {
 135                 if((!g_minstagib)
 136                         && (player.items & IT_STRENGTH)
 137                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 138                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 139                 {
 140                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 141                         player.prevstrengthsound = time;
 142                 }
 143                 player.prevstrengthsoundattempt = time;
 144 }
 145
 146 // this function calculates w_shotorg and w_shotdir based on the weapon model
 147 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 148 // make sure you call makevectors first (FIXME?)
 149 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 150 {
 151         float nudge = 1; // added to traceline target and subtracted from result
 152         float oldsolid;
 153         vector vecs, dv;
 154         oldsolid = ent.dphitcontentsmask;
 155         if(ent.weapon == WEP_RIFLE)
 156                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 157         else
 158                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 159         if(antilag)
 160                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 161                 // passing world, because we do NOT want it to touch dphitcontentsmask
 162         else
 163                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 164         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 165
 166         vector vf, vr, vu;
 167         vf = v_forward;
 168         vr = v_right;
 169         vu = v_up;
 170         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 171         v_forward = vf;
 172         v_right = vr;
 173         v_up = vu;
 174
 175         // un-adjust trueaim if shotend is too close
 176         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 177                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 178
 179         // track max damage
 180         if(accuracy_canbegooddamage(ent))
 181                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 182
 183         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 184
 185         if(ent.weaponentity.movedir_x > 0)
 186                 vecs = ent.weaponentity.movedir;
 187         else
 188                 vecs = '0 0 0';
 189
 190         dv = v_right * -vecs_y + v_up * vecs_z;
 191         w_shotorg = ent.origin + ent.view_ofs + dv;
 192
 193         // now move the shotorg forward as much as requested if possible
 194         if(antilag)
 195         {
 196                 if(ent.antilag_debug)
 197                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 198                 else
 199                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 200         }
 201         else
 202                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 203         w_shotorg = trace_endpos - v_forward * nudge;
 204         // calculate the shotdir from the chosen shotorg
 205         w_shotdir = normalize(w_shotend - w_shotorg);
 206
 207         if (antilag)
 208         if (!ent.cvar_cl_noantilag)
 209         {
 210                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 211                 {
 212                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 213                         if (!trace_ent.takedamage)
 214                         {
 215                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 216                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 217                                 {
 218                                         entity e;
 219                                         e = trace_ent;
 220                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 221                                         if(trace_ent == e)
 222                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 223                                 }
 224                         }
 225                 }
 226                 else if(autocvar_g_antilag == 3) // client side hitscan
 227                 {
 228                         // this part MUST use prydon cursor
 229                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 230                         if (ent.cursor_trace_ent != ent)         // just to make sure
 231                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 232                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 233                         {
 234                                 // verify that the shot would miss without antilag
 235                                 // (avoids an issue where guns would always shoot at their origin)
 236                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 237                                 if (!trace_ent.takedamage)
 238                                 {
 239                                         // verify that the shot would hit if altered
 240                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 241                                         if (trace_ent == ent.cursor_trace_ent)
 242                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 243                                         else
 244                                                 print("antilag fail\n");
 245                                 }
 246                         }
 247                 }
 248         }
 249
 250         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 251
 252         if (!g_norecoil)
 253                 ent.punchangle_x = recoil * -1;
 254
 255         if (snd != "")
 256         {
 257                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 258                 W_PlayStrengthSound(ent);
 259         }
 260
 261         // nudge w_shotend so a trace to w_shotend hits
 262         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 263 }
 264
 265 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 266 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 267 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 270
 271 float CL_Weaponentity_CustomizeEntityForClient()
 272 {
 273         self.viewmodelforclient = self.owner;
 274         if(other.classname == "spectator")
 275                 if(other.enemy == self.owner)
 276                         self.viewmodelforclient = other;
 277         return TRUE;
 278 }
 279
 280 /*
 281  * supported formats:
 282  *
 283  * 1. simple animated model, muzzle flash handling on h_ model:
 284  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 285  *      tags:
 286  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 287  *        shell = casings ejection point (must be on the right hand side of the gun)
 288  *        weapon = attachment for v_tuba.md3
 289  *    v_tuba.md3 - first and third person model
 290  *    g_tuba.md3 - pickup model
 291  *
 292  * 2. simple animated model, muzzle flash handling on v_ model:
 293  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 294  *      tags:
 295  *        weapon = attachment for v_tuba.md3
 296  *    v_tuba.md3 - first and third person model
 297  *      tags:
 298  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 299  *        shell = casings ejection point (must be on the right hand side of the gun)
 300  *    g_tuba.md3 - pickup model
 301  *
 302  * 3. fully animated model, muzzle flash handling on h_ model:
 303  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 304  *      tags:
 305  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 306  *        shell = casings ejection point (must be on the right hand side of the gun)
 307  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 308  *    v_tuba.md3 - third person model
 309  *    g_tuba.md3 - pickup model
 310  *
 311  * 4. fully animated model, muzzle flash handling on v_ model:
 312  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 313  *      tags:
 314  *        shot = muzzle end (shot origin)
 315  *        shell = casings ejection point (must be on the right hand side of the gun)
 316  *    v_tuba.md3 - third person model
 317  *      tags:
 318  *        shot = muzzle end (for muzzle flashes)
 319  *    g_tuba.md3 - pickup model
 320  */
 321
 322 // writes:
 323 //   self.origin, self.angles
 324 //   self.weaponentity
 325 //   self.movedir, self.view_ofs
 326 //   attachment stuff
 327 //   anim stuff
 328 // to free:
 329 //   call again with ""
 330 //   remove the ent
 331 void CL_WeaponEntity_SetModel(string name)
 332 {
 333         float v_shot_idx;
 334         if (name != "")
 335         {
 336                 // if there is a child entity, hide it until we're sure we use it
 337                 if (self.weaponentity)
 338                         self.weaponentity.model = "";
 339                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 340                 v_shot_idx = gettagindex(self, "shot"); // used later
 341                 if(!v_shot_idx)
 342                         v_shot_idx = gettagindex(self, "tag_shot");
 343
 344                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 345                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 346                 self.anim_fire1  = animfixfps(self, '0 1 0.01');
 347                 self.anim_fire2  = animfixfps(self, '1 1 0.01');
 348                 self.anim_idle   = animfixfps(self, '2 1 0.01');
 349                 self.anim_reload = animfixfps(self, '3 1 0.01');
 350
 351                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 352                 // if we don't, this is a "real" animated model
 353                 if(gettagindex(self, "weapon"))
 354                 {
 355                         if (!self.weaponentity)
 356                                 self.weaponentity = spawn();
 357                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 358                         setattachment(self.weaponentity, self, "weapon");
 359                 }
 360                 else if(gettagindex(self, "tag_weapon"))
 361                 {
 362                         if (!self.weaponentity)
 363                                 self.weaponentity = spawn();
 364                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 365                         setattachment(self.weaponentity, self, "tag_weapon");
 366                 }
 367                 else
 368                 {
 369                         if(self.weaponentity)
 370                                 remove(self.weaponentity);
 371                         self.weaponentity = world;
 372                 }
 373
 374                 setorigin(self,'0 0 0');
 375                 self.angles = '0 0 0';
 376                 self.frame = 0;
 377                 self.viewmodelforclient = world;
 378
 379                 float idx;
 380
 381                 if(v_shot_idx) // v_ model attached to invisible h_ model
 382                 {
 383                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 384                 }
 385                 else
 386                 {
 387                         idx = gettagindex(self, "shot");
 388                         if(!idx)
 389                                 idx = gettagindex(self, "tag_shot");
 390                         if(idx)
 391                                 self.movedir = gettaginfo(self, idx);
 392                         else
 393                         {
 394                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 395                                 self.movedir = '0 0 0';
 396                         }
 397                 }
 398
 399                 if(self.weaponentity) // v_ model attached to invisible h_ model
 400                 {
 401                         idx = gettagindex(self.weaponentity, "shell");
 402                         if(!idx)
 403                                 idx = gettagindex(self.weaponentity, "tag_shell");
 404                         if(idx)
 405                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 406                 }
 407                 else
 408                         idx = 0;
 409                 if(!idx)
 410                 {
 411                         idx = gettagindex(self, "shell");
 412                         if(!idx)
 413                                 idx = gettagindex(self, "tag_shell");
 414                         if(idx)
 415                                 self.spawnorigin = gettaginfo(self, idx);
 416                         else
 417                         {
 418                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 419                                 self.spawnorigin = self.movedir;
 420                         }
 421                 }
 422
 423                 if(v_shot_idx)
 424                 {
 425                         self.oldorigin = '0 0 0'; // use regular attachment
 426                 }
 427                 else
 428                 {
 429                         if(self.weaponentity)
 430                         {
 431                                 idx = gettagindex(self, "weapon");
 432                                 if(!idx)
 433                                         idx = gettagindex(self, "tag_weapon");
 434                         }
 435                         else
 436                         {
 437                                 idx = gettagindex(self, "handle");
 438                                 if(!idx)
 439                                         idx = gettagindex(self, "tag_handle");
 440                         }
 441                         if(idx)
 442                         {
 443                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 444                         }
 445                         else
 446                         {
 447                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 448                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 449                         }
 450                 }
 451
 452                 self.viewmodelforclient = self.owner;
 453         }
 454         else
 455         {
 456                 self.model = "";
 457                 if(self.weaponentity)
 458                         remove(self.weaponentity);
 459                 self.weaponentity = world;
 460                 self.movedir = '0 0 0';
 461                 self.spawnorigin = '0 0 0';
 462                 self.oldorigin = '0 0 0';
 463                 self.anim_fire1  = '0 1 0.01';
 464                 self.anim_fire2  = '0 1 0.01';
 465                 self.anim_idle   = '0 1 0.01';
 466                 self.anim_reload = '0 1 0.01';
 467         }
 468
 469         self.view_ofs = '0 0 0';
 470
 471         if(self.movedir_x >= 0)
 472         {
 473                 vector v0;
 474                 v0 = self.movedir;
 475                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 476                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 477         }
 478         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 479         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 480
 481         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 482
 483         // check if an instant weapon switch occurred
 484         setorigin(self, self.view_ofs);
 485         // reset animstate now
 486         self.wframe = WFRAME_IDLE;
 487         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 488 }
 489
 490 vector CL_Weapon_GetShotOrg(float wpn)
 491 {
 492         entity wi, oldself;
 493         vector ret;
 494         wi = get_weaponinfo(wpn);
 495         oldself = self;
 496         self = spawn();
 497         CL_WeaponEntity_SetModel(wi.mdl);
 498         ret = self.movedir;
 499         CL_WeaponEntity_SetModel("");
 500         remove(self);
 501         self = oldself;
 502         return ret;
 503 }
 504
 505 void CL_Weaponentity_Think()
 506 {
 507         float tb;
 508         self.nextthink = time;
 509         if (intermission_running)
 510                 self.frame = self.anim_idle_x;
 511         if (self.owner.weaponentity != self)
 512         {
 513                 if (self.weaponentity)
 514                         remove(self.weaponentity);
 515                 remove(self);
 516                 return;
 517         }
 518         if (self.owner.deadflag != DEAD_NO)
 519         {
 520                 self.model = "";
 521                 if (self.weaponentity)
 522                         self.weaponentity.model = "";
 523                 return;
 524         }
 525         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 526         {
 527                 self.weaponname = self.owner.weaponname;
 528                 self.dmg = self.owner.modelindex;
 529                 self.deadflag = self.owner.deadflag;
 530
 531                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 532         }
 533
 534         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 535         self.effects = self.owner.effects & EFMASK_CHEAP;
 536         self.effects &~= EF_LOWPRECISION;
 537         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 538         self.effects &~= EF_TELEPORT_BIT;
 539         self.effects &~= EF_RESTARTANIM_BIT;
 540         self.effects |= tb;
 541
 542         if(self.owner.alpha == default_player_alpha)
 543                 self.alpha = default_weapon_alpha;
 544         else if(self.owner.alpha != 0)
 545                 self.alpha = self.owner.alpha;
 546         else
 547                 self.alpha = 1;
 548
 549         self.glowmod = self.owner.weaponentity_glowmod;
 550         self.colormap = self.owner.colormap;
 551         if (self.weaponentity)
 552         {
 553                 self.weaponentity.effects = self.effects;
 554                 self.weaponentity.alpha = self.alpha;
 555                 self.weaponentity.colormap = self.colormap;
 556                 self.weaponentity.glowmod = self.glowmod;
 557         }
 558
 559         self.angles = '0 0 0';
 560         float f;
 561         f = 0;
 562         if (self.state == WS_RAISE && !intermission_running)
 563         {
 564                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 565                 self.angles_x = -90 * f * f;
 566         }
 567         else if (self.state == WS_DROP && !intermission_running)
 568         {
 569                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 570                 self.angles_x = -90 * f * f;
 571         }
 572         else if (self.state == WS_CLEAR)
 573         {
 574                 f = 1;
 575                 self.angles_x = -90 * f * f;
 576         }
 577 }
 578
 579 void CL_ExteriorWeaponentity_Think()
 580 {
 581         float tag_found;
 582         vector ang;
 583         self.nextthink = time;
 584         if (self.owner.exteriorweaponentity != self)
 585         {
 586                 remove(self);
 587                 return;
 588         }
 589         if (self.owner.deadflag != DEAD_NO)
 590         {
 591                 self.model = "";
 592                 return;
 593         }
 594         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 595         {
 596                 self.weaponname = self.owner.weaponname;
 597                 self.dmg = self.owner.modelindex;
 598                 self.deadflag = self.owner.deadflag;
 599                 if (self.owner.weaponname != "")
 600                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 601                 else
 602                         self.model = "";
 603
 604                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 605                 {
 606                         self.tag_index = tag_found;
 607                         self.tag_entity = self.owner;
 608                 }
 609                 else
 610                         setattachment(self, self.owner, "bip01 r hand");
 611         }
 612         self.effects = self.owner.effects;
 613         if(sv_pitch_min == sv_pitch_max)
 614                 self.effects |= EF_LOWPRECISION;
 615         else
 616                 self.effects &~= EF_LOWPRECISION;
 617         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 618         if(self.owner.alpha == default_player_alpha)
 619                 self.alpha = default_weapon_alpha;
 620         else if(self.owner.alpha != 0)
 621                 self.alpha = self.owner.alpha;
 622         else
 623                 self.alpha = 1;
 624
 625         if (!intermission_running)
 626         {
 627                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 628                 ang_y = 0;
 629                 ang_z = 0;
 630
 631                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 632                 {
 633                         ang_y = self.owner.v_angle_y;
 634                         makevectors(ang);
 635                         var vector v = v_forward;
 636                         var float t = self.tag_entity.frame1time;
 637                         var float f = self.tag_entity.frame;
 638                         self.tag_entity.frame1time = time;
 639                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 640                         gettaginfo(self.tag_entity, self.tag_index);
 641                         self.tag_entity.frame1time = t;
 642                         self.tag_entity.frame = f;
 643                         // untransform v according to this coordinate space
 644                         vector w;
 645                         w_x = v_forward * v;
 646                         w_y = -v_right * v;
 647                         w_z = v_up * v;
 648                         self.angles = vectoangles(w);
 649                 }
 650                 else
 651                 {
 652                         ang_x = -/* don't ask */ang_x;
 653                         self.angles = ang;
 654                 }
 655
 656                 if(autocvar_g_loituma)
 657                 {
 658                         vector modangles;
 659                         float t;
 660
 661                         t = time * autocvar_g_loituma;
 662
 663                         modangles_x = t * 360;
 664                         modangles_y = 90;
 665                         modangles_z = 0;
 666
 667                         self.angles =
 668                                 AnglesTransform_ToAngles(
 669                                         AnglesTransform_Multiply(
 670                                                 AnglesTransform_FromAngles(self.angles),
 671                                                 AnglesTransform_FromAngles(modangles)
 672                                         )
 673                                 );
 674                 }
 675         }
 676
 677         self.glowmod = self.owner.weaponentity_glowmod;
 678         self.colormap = self.owner.colormap;
 679
 680         CSQCMODEL_AUTOUPDATE();
 681 }
 682
 683 // spawning weaponentity for client
 684 void CL_SpawnWeaponentity()
 685 {
 686         self.weaponentity = spawn();
 687         self.weaponentity.classname = "weaponentity";
 688         self.weaponentity.solid = SOLID_NOT;
 689         self.weaponentity.owner = self;
 690         setmodel(self.weaponentity, ""); // precision set when changed
 691         setorigin(self.weaponentity, '0 0 0');
 692         self.weaponentity.angles = '0 0 0';
 693         self.weaponentity.viewmodelforclient = self;
 694         self.weaponentity.flags = 0;
 695         self.weaponentity.think = CL_Weaponentity_Think;
 696         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 697         self.weaponentity.nextthink = time;
 698
 699         self.exteriorweaponentity = spawn();
 700         self.exteriorweaponentity.classname = "exteriorweaponentity";
 701         self.exteriorweaponentity.solid = SOLID_NOT;
 702         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 703         self.exteriorweaponentity.owner = self;
 704         setorigin(self.exteriorweaponentity, '0 0 0');
 705         self.exteriorweaponentity.angles = '0 0 0';
 706         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 707         self.exteriorweaponentity.nextthink = time;
 708
 709         {
 710                 entity oldself = self;
 711                 self = self.exteriorweaponentity;
 712                 CSQCMODEL_AUTOINIT();
 713                 self = oldself;
 714         }
 715 }
 716
 717 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 718 {
 719         msg_entity = e;
 720         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 721         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 722         WriteByte(MSG_ONE, wpn);
 723         WriteString(MSG_ONE, wpnname);
 724         WriteByte(MSG_ONE, type);
 725 }
 726
 727 .float hasweapon_complain_spam;
 728
 729 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 730 {
 731         float f;
 732         entity oldself;
 733
 734         if(time < self.hasweapon_complain_spam)
 735                 complain = 0;
 736         if(complain)
 737                 self.hasweapon_complain_spam = time + 0.2;
 738
 739         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 740         {
 741                 if (complain)
 742                         sprint(self, "Invalid weapon\n");
 743                 return FALSE;
 744         }
 745         if (WEPSET_CONTAINS_EW(cl, wpn))
 746         {
 747                 if (andammo)
 748                 {
 749                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 750                         {
 751                                 f = 1;
 752                         }
 753                         else
 754                         {
 755                                 oldself = self;
 756                                 self = cl;
 757                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 758                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 759
 760                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 761                                 entity mine;
 762                                 if(wpn == WEP_MINE_LAYER)
 763                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 764                                         f = 1;
 765
 766                                 self = oldself;
 767                         }
 768                         if (!f)
 769                         {
 770                                 if (complain)
 771                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 772                                 {
 773                                         play2(cl, "weapons/unavailable.wav");
 774                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 775                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 776                                 }
 777                                 return FALSE;
 778                         }
 779                 }
 780                 return TRUE;
 781         }
 782         if (complain)
 783         {
 784                 // DRESK - 3/16/07
 785                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 786                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 787                 {
 788                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 789                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 790
 791                         if(autocvar_g_showweaponspawns)
 792                         {
 793                                 entity e;
 794                                 string s;
 795
 796                                 e = get_weaponinfo(wpn);
 797                                 s = e.model2;
 798
 799                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 800                                 {
 801                                         if(e.classname == "droppedweapon")
 802                                                 continue;
 803                                         if not(e.flags & FL_ITEM)
 804                                                 continue;
 805                                         WaypointSprite_Spawn(
 806                                                 s,
 807                                                 1, 0,
 808                                                 world, e.origin,
 809                                                 self, 0,
 810                                                 world, enemy,
 811                                                 0,
 812                                                 RADARICON_NONE, '0 0 0'
 813                                         );
 814                                 }
 815                         }
 816                 }
 817                 else
 818                 {
 819                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 820                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 821                 }
 822
 823                 play2(cl, "weapons/unavailable.wav");
 824         }
 825         return FALSE;
 826 }
 827
 828 // Weapon subs
 829 void w_clear()
 830 {
 831         if (self.weapon != -1)
 832         {
 833                 self.weapon = 0;
 834                 self.switchingweapon = 0;
 835         }
 836         if (self.weaponentity)
 837         {
 838                 self.weaponentity.state = WS_CLEAR;
 839                 self.weaponentity.effects = 0;
 840         }
 841 }
 842
 843 void w_ready()
 844 {
 845         if (self.weaponentity)
 846                 self.weaponentity.state = WS_READY;
 847         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 848 }
 849
 850 // Setup weapon for client (after this raise frame will be launched)
 851 void weapon_setup(float windex)
 852 {
 853         entity e;
 854         e = get_weaponinfo(windex);
 855         self.items &~= IT_AMMO;
 856         self.items = self.items | (e.items & IT_AMMO);
 857
 858         // the two weapon entities will notice this has changed and update their models
 859         self.weapon = windex;
 860         self.switchingweapon = windex; // to make sure
 861         self.weaponname = e.mdl;
 862         self.bulletcounter = 0;
 863 }
 864
 865 // perform weapon to attack (weaponstate and attack_finished check is here)
 866 void W_SwitchToOtherWeapon(entity pl)
 867 {
 868         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 869         float w, ww;
 870         w = pl.weapon;
 871         if(WEPSET_CONTAINS_EW(pl, w))
 872         {
 873                 WEPSET_ANDNOT_EW(pl, w);
 874                 ww = w_getbestweapon(pl);
 875                 WEPSET_OR_EW(pl, w);
 876         }
 877         else
 878                 ww = w_getbestweapon(pl);
 879         if(ww)
 880                 W_SwitchWeapon_Force(pl, ww);
 881 }
 882
 883 string PrimaryOrSecondary(float secondary)
 884 {
 885         if(secondary)
 886                 return "secondary";
 887         else
 888                 return "primary";
 889 }
 890
 891 .float prevdryfire;
 892 .float prevwarntime;
 893 float weapon_prepareattack_checkammo(float secondary)
 894 {
 895         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 896         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 897         {
 898                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 899                 entity mine;
 900                 if(self.weapon == WEP_MINE_LAYER)
 901                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 902                         return FALSE;
 903
 904                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 905                 {
 906                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 907                         self.prevdryfire = time;
 908                 }
 909
 910                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 911                 {
 912                         if(time - self.prevwarntime > 1)
 913                         {
 914                                 sprint(self, strcat("^2", W_Name(self.weapon), " ", PrimaryOrSecondary(secondary), "^7 is unable to fire, but its ^2", PrimaryOrSecondary(1 - secondary), "^7 can.\n"));
 915                         }
 916                         self.prevwarntime = time;
 917                 }
 918                 else // this weapon is totally unable to fire, switch to another one
 919                 {
 920                         W_SwitchToOtherWeapon(self);
 921                 }
 922
 923                 return FALSE;
 924         }
 925         return TRUE;
 926 }
 927 .float race_penalty;
 928 float weapon_prepareattack_check(float secondary, float attacktime)
 929 {
 930         if(!weapon_prepareattack_checkammo(secondary))
 931                 return FALSE;
 932
 933         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 934         //if all players readied up and the countdown is running
 935         if(time < game_starttime || time < self.race_penalty) {
 936                 return FALSE;
 937         }
 938
 939         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 940                 return FALSE;
 941
 942         // do not even think about shooting if switching
 943         if(self.switchweapon != self.weapon)
 944                 return FALSE;
 945
 946         if(attacktime >= 0)
 947         {
 948                 // don't fire if previous attack is not finished
 949                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 950                         return FALSE;
 951                 // don't fire while changing weapon
 952                 if (self.weaponentity.state != WS_READY)
 953                         return FALSE;
 954         }
 955
 956         return TRUE;
 957 }
 958 float weapon_prepareattack_do(float secondary, float attacktime)
 959 {
 960         self.weaponentity.state = WS_INUSE;
 961
 962         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 963
 964         // if the weapon hasn't been firing continuously, reset the timer
 965         if(attacktime >= 0)
 966         {
 967                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 968                 {
 969                         ATTACK_FINISHED(self) = time;
 970                         //dprint("resetting attack finished to ", ftos(time), "\n");
 971                 }
 972                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 973         }
 974         self.bulletcounter += 1;
 975         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 976         return TRUE;
 977 }
 978 float weapon_prepareattack(float secondary, float attacktime)
 979 {
 980         if(weapon_prepareattack_check(secondary, attacktime))
 981         {
 982                 weapon_prepareattack_do(secondary, attacktime);
 983                 return TRUE;
 984         }
 985         else
 986                 return FALSE;
 987 }
 988
 989 void weapon_thinkf(float fr, float t, void() func)
 990 {
 991         vector a;
 992         vector of, or, ou;
 993         float restartanim;
 994
 995         if(fr == WFRAME_DONTCHANGE)
 996         {
 997                 fr = self.weaponentity.wframe;
 998                 restartanim = FALSE;
 999         }
1000         else if (fr == WFRAME_IDLE)
1001                 restartanim = FALSE;
1002         else
1003                 restartanim = TRUE;
1004
1005         of = v_forward;
1006         or = v_right;
1007         ou = v_up;
1008
1009         if (self.weaponentity)
1010         {
1011                 self.weaponentity.wframe = fr;
1012                 if (fr == WFRAME_IDLE)
1013                         a = self.weaponentity.anim_idle;
1014                 else if (fr == WFRAME_FIRE1)
1015                         a = self.weaponentity.anim_fire1;
1016                 else if (fr == WFRAME_FIRE2)
1017                         a = self.weaponentity.anim_fire2;
1018                 else if (fr == WFRAME_RELOAD)
1019                         a = self.weaponentity.anim_reload;
1020                 a_z *= g_weaponratefactor;
1021                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1022         }
1023
1024         v_forward = of;
1025         v_right = or;
1026         v_up = ou;
1027
1028         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1029         {
1030                 backtrace("Tried to override initial weapon think function - should this really happen?");
1031         }
1032
1033         t *= W_WeaponRateFactor();
1034
1035         // VorteX: haste can be added here
1036         if (self.weapon_think == w_ready)
1037         {
1038                 self.weapon_nextthink = time;
1039                 //dprint("started firing at ", ftos(time), "\n");
1040         }
1041         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1042         {
1043                 self.weapon_nextthink = time;
1044                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1045         }
1046         self.weapon_nextthink = self.weapon_nextthink + t;
1047         self.weapon_think = func;
1048         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1049
1050         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1051         //anim = self.anim_shoot;
1052         if (restartanim)
1053         if (t)
1054         if (!self.crouch) // shoot anim stands up, this looks bad
1055         {
1056                 vector anim;
1057                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1058                 {
1059                         anim = self.anim_melee;
1060                         anim_z = anim_y / (t + sys_frametime);
1061                         setanim(self, anim, FALSE, TRUE, TRUE);
1062                 }
1063                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1064                 {
1065                         anim = self.anim_shoot;
1066                         anim_z = anim_y / (t + sys_frametime);
1067                         setanim(self, anim, FALSE, TRUE, TRUE);
1068                 }
1069         }
1070 }
1071
1072 void weapon_boblayer1(float spd, vector org)
1073 {
1074         // VorteX: haste can be added here
1075 }
1076
1077 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1078 {
1079         vector mdirection;
1080         float mspeed;
1081         float outspeed;
1082         float nstyle;
1083         vector outvelocity;
1084
1085         mvelocity = mvelocity * g_weaponspeedfactor;
1086
1087         mdirection = normalize(mvelocity);
1088         mspeed = vlen(mvelocity);
1089
1090         nstyle = autocvar_g_projectiles_newton_style;
1091         if(nstyle == 0 || forceAbsolute)
1092         {
1093                 // absolute velocity
1094                 outvelocity = mvelocity;
1095         }
1096         else if(nstyle == 1)
1097         {
1098                 // true Newtonian projectiles
1099                 outvelocity = pvelocity + mvelocity;
1100         }
1101         else if(nstyle == 2)
1102         {
1103                 // true Newtonian projectiles with automatic aim adjustment
1104                 //
1105                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1106                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1107                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1108                 // PLUS SIGN!
1109                 // not defined?
1110                 // then...
1111                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1112                 // velocity without mdirection component > mspeed
1113                 // fire at smallest possible mspeed that works?
1114                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1115
1116                 vector solution;
1117                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1118                 if(solution_z)
1119                         outspeed = solution_y; // the larger one
1120                 else
1121                 {
1122                         //outspeed = 0; // slowest possible shot
1123                         outspeed = solution_x; // the real part (that is, the average!)
1124                         //dprint("impossible shot, adjusting\n");
1125                 }
1126
1127                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1128                 outvelocity = mdirection * outspeed;
1129         }
1130         else if(nstyle == 3)
1131         {
1132                 // pseudo-Newtonian:
1133                 outspeed = mspeed + mdirection * pvelocity;
1134                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1135                 outvelocity = mdirection * outspeed;
1136         }
1137         else if(nstyle == 4)
1138         {
1139                 // tZorkian:
1140                 outspeed = mspeed + vlen(pvelocity);
1141                 outvelocity = mdirection * outspeed;
1142         }
1143         else
1144                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1145
1146         return outvelocity;
1147 }
1148
1149 void W_AttachToShotorg(entity flash, vector offset)
1150 {
1151         entity xflash;
1152         flash.owner = self;
1153         flash.angles_z = random() * 360;
1154
1155         if(gettagindex(self.weaponentity, "shot"))
1156                 setattachment(flash, self.weaponentity, "shot");
1157         else
1158                 setattachment(flash, self.weaponentity, "tag_shot");
1159         setorigin(flash, offset);
1160
1161         xflash = spawn();
1162         copyentity(flash, xflash);
1163
1164         flash.viewmodelforclient = self;
1165
1166         if(self.weaponentity.oldorigin_x > 0)
1167         {
1168                 setattachment(xflash, self.exteriorweaponentity, "");
1169                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1170         }
1171         else
1172         {
1173                 if(gettagindex(self.exteriorweaponentity, "shot"))
1174                         setattachment(xflash, self.exteriorweaponentity, "shot");
1175                 else
1176                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1177                 setorigin(xflash, offset);
1178         }
1179 }
1180
1181 vector cliptoplane(vector v, vector p)
1182 {
1183         return v - (v * p) * p;
1184 }
1185
1186 vector solve_cubic_pq(float p, float q)
1187 {
1188         float D, u, v, a;
1189         D = q*q/4.0 + p*p*p/27.0;
1190         if(D < 0)
1191         {
1192                 // irreducibilis
1193                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1194                 u = sqrt(-4.0/3.0 * p);
1195                 // a in range 0..pi/3
1196                 // cos(a)
1197                 // cos(a + 2pi/3)
1198                 // cos(a + 4pi/3)
1199                 return
1200                         u *
1201                         (
1202                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1203                                 +
1204                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1205                                 +
1206                                 '0 0 1' * cos(a)
1207                         );
1208         }
1209         else if(D == 0)
1210         {
1211                 // simple
1212                 if(p == 0)
1213                         return '0 0 0';
1214                 u = 3*q/p;
1215                 v = -u/2;
1216                 if(u >= v)
1217                         return '1 1 0' * v + '0 0 1' * u;
1218                 else
1219                         return '0 1 1' * v + '1 0 0' * u;
1220         }
1221         else
1222         {
1223                 // cardano
1224                 u = cbrt(-q/2.0 + sqrt(D));
1225                 v = cbrt(-q/2.0 - sqrt(D));
1226                 return '1 1 1' * (u + v);
1227         }
1228 }
1229 vector solve_cubic_abcd(float a, float b, float c, float d)
1230 {
1231         // y = 3*a*x + b
1232         // x = (y - b) / 3a
1233         float p, q;
1234         vector v;
1235         p = (9*a*c - 3*b*b);
1236         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1237         v = solve_cubic_pq(p, q);
1238         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1239         if(a < 0)
1240                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1241         return v;
1242 }
1243
1244 vector findperpendicular(vector v)
1245 {
1246         vector p;
1247         p_x = v_z;
1248         p_y = -v_x;
1249         p_z = v_y;
1250         return normalize(cliptoplane(p, v));
1251 }
1252
1253 vector W_CalculateProjectileSpread(vector forward, float spread)
1254 {
1255         float sigma;
1256         vector v1, v2;
1257         float dx, dy, r;
1258         float sstyle;
1259         spread *= g_weaponspreadfactor;
1260         if(spread <= 0)
1261                 return forward;
1262         sstyle = autocvar_g_projectiles_spread_style;
1263
1264         if(sstyle == 0)
1265         {
1266                 // this is the baseline for the spread value!
1267                 // standard deviation: sqrt(2/5)
1268                 // density function: sqrt(1-r^2)
1269                 return forward + randomvec() * spread;
1270         }
1271         else if(sstyle == 1)
1272         {
1273                 // same thing, basically
1274                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1275         }
1276         else if(sstyle == 2)
1277         {
1278                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1279                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1280                 v1 = findperpendicular(forward);
1281                 v2 = cross(forward, v1);
1282                 // random point on unit circle
1283                 dx = random() * 2 * M_PI;
1284                 dy = sin(dx);
1285                 dx = cos(dx);
1286                 // radius in our dist function
1287                 r = random();
1288                 r = sqrt(r);
1289                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1290         }
1291         else if(sstyle == 3) // gauss 3d
1292         {
1293                 sigma = spread * 0.44721359549996; // match baseline stddev
1294                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1295                 v1 = forward;
1296                 v1_x += gsl_ran_gaussian(sigma);
1297                 v1_y += gsl_ran_gaussian(sigma);
1298                 v1_z += gsl_ran_gaussian(sigma);
1299                 return v1;
1300         }
1301         else if(sstyle == 4) // gauss 2d
1302         {
1303                 sigma = spread * 0.44721359549996; // match baseline stddev
1304                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1305                 v1_x = gsl_ran_gaussian(sigma);
1306                 v1_y = gsl_ran_gaussian(sigma);
1307                 v1_z = gsl_ran_gaussian(sigma);
1308                 return normalize(forward + cliptoplane(v1, forward));
1309         }
1310         else if(sstyle == 5) // 1-r
1311         {
1312                 sigma = spread * 1.154700538379252; // match baseline stddev
1313                 v1 = findperpendicular(forward);
1314                 v2 = cross(forward, v1);
1315                 // random point on unit circle
1316                 dx = random() * 2 * M_PI;
1317                 dy = sin(dx);
1318                 dx = cos(dx);
1319                 // radius in our dist function
1320                 r = random();
1321                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1322                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1323         }
1324         else if(sstyle == 6) // 1-r^2
1325         {
1326                 sigma = spread * 1.095445115010332; // match baseline stddev
1327                 v1 = findperpendicular(forward);
1328                 v2 = cross(forward, v1);
1329                 // random point on unit circle
1330                 dx = random() * 2 * M_PI;
1331                 dy = sin(dx);
1332                 dx = cos(dx);
1333                 // radius in our dist function
1334                 r = random();
1335                 r = sqrt(1 - r);
1336                 r = sqrt(1 - r);
1337                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1338         }
1339         else if(sstyle == 7) // (1-r) (2-r)
1340         {
1341                 sigma = spread * 1.224744871391589; // match baseline stddev
1342                 v1 = findperpendicular(forward);
1343                 v2 = cross(forward, v1);
1344                 // random point on unit circle
1345                 dx = random() * 2 * M_PI;
1346                 dy = sin(dx);
1347                 dx = cos(dx);
1348                 // radius in our dist function
1349                 r = random();
1350                 r = 1 - sqrt(r);
1351                 r = 1 - sqrt(r);
1352                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1353         }
1354         else
1355                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1356         return '0 0 0';
1357         /*
1358          * how to derive falloff functions:
1359          * rho(r) := (2-r) * (1-r);
1360          * a : 0;
1361          * b : 1;
1362          * rhor(r) := r * rho(r);
1363          * cr(t) := integrate(rhor(r), r, a, t);
1364          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1365          * variance : scr(b) / cr(b);
1366          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1367          * sqrt(0.4 / variance), numer;
1368          */
1369 }
1370
1371 #if 0
1372 float mspercallsum;
1373 float mspercallsstyle;
1374 float mspercallcount;
1375 #endif
1376 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1377 {
1378         if(missile.owner == world)
1379                 error("Unowned missile");
1380
1381         dir = dir + upDir * (pUpSpeed / pSpeed);
1382         dir_z += pZSpeed / pSpeed;
1383         pSpeed *= vlen(dir);
1384         dir = normalize(dir);
1385
1386 #if 0
1387         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1388         {
1389                 mspercallsum = mspercallcount = 0;
1390                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1391         }
1392         mspercallsum -= gettime(GETTIME_HIRES);
1393 #endif
1394         dir = W_CalculateProjectileSpread(dir, spread);
1395 #if 0
1396         mspercallsum += gettime(GETTIME_HIRES);
1397         mspercallcount += 1;
1398         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1399 #endif
1400
1401         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1402 }
1403
1404 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1405 {
1406         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1407 }
1408
1409 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1410 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1411
1412 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1413 {
1414         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1415                 return;
1416
1417         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1418         if(ammo_reload)
1419         {
1420                 self.clip_load -= ammo_use;
1421                 self.(weapon_load[self.weapon]) = self.clip_load;
1422         }
1423         else
1424                 self.(self.current_ammo) -= ammo_use;
1425 }
1426
1427 // weapon reloading code
1428
1429 .float reload_ammo_amount, reload_ammo_min, reload_time;
1430 .float reload_complain;
1431 .string reload_sound;
1432
1433 void W_ReloadedAndReady()
1434 {
1435         // finish the reloading process, and do the ammo transfer
1436
1437         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1438
1439         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1440         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1441                 self.clip_load = self.reload_ammo_amount;
1442         else
1443         {
1444                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1445                 {
1446                         self.clip_load += 1;
1447                         self.(self.current_ammo) -= 1;
1448                 }
1449         }
1450         self.(weapon_load[self.weapon]) = self.clip_load;
1451
1452         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1453         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1454         // so your weapon is disabled for a few seconds without reason
1455
1456         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1457
1458         w_ready();
1459 }
1460
1461 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1462 {
1463         // set global values to work with
1464
1465         self.reload_ammo_min = sent_ammo_min;
1466         self.reload_ammo_amount = sent_ammo_amount;
1467         self.reload_time = sent_time;
1468         self.reload_sound = sent_sound;
1469
1470         // check if we meet the necessary conditions to reload
1471
1472         entity e;
1473         e = get_weaponinfo(self.weapon);
1474
1475         // don't reload weapons that don't have the RELOADABLE flag
1476         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1477         {
1478                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1479                 return;
1480         }
1481
1482         // return if reloading is disabled for this weapon
1483         if(!self.reload_ammo_amount)
1484                 return;
1485
1486         // our weapon is fully loaded, no need to reload
1487         if (self.clip_load >= self.reload_ammo_amount)
1488                 return;
1489
1490         // no ammo, so nothing to load
1491         if(!self.(self.current_ammo) && self.reload_ammo_min)
1492         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1493         {
1494                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1495                 {
1496                         play2(self, "weapons/unavailable.wav");
1497                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1498                         self.reload_complain = time + 1;
1499                 }
1500                 // switch away if the amount of ammo is not enough to keep using this weapon
1501                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1502                 {
1503                         self.clip_load = -1; // reload later
1504                         W_SwitchToOtherWeapon(self);
1505                 }
1506                 return;
1507         }
1508
1509         if (self.weaponentity)
1510         {
1511                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1512                         return;
1513
1514                 // allow switching away while reloading, but this will cause a new reload!
1515                 self.weaponentity.state = WS_READY;
1516         }
1517
1518         // now begin the reloading process
1519
1520         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1521
1522         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1523         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1524         // so your weapon is disabled for a few seconds without reason
1525
1526         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1527
1528         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1529
1530         if(self.clip_load < 0)
1531                 self.clip_load = 0;
1532         self.old_clip_load = self.clip_load;
1533         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1534 }