qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         return t;
  18 }
  19
  20 void W_SwitchWeapon_Force(entity e, float w)
  21 {
  22         e.cnt = e.switchweapon;
  23         e.switchweapon = w;
  24         e.selectweapon = w;
  25 }
  26
  27 .float antilag_debug;
  28
  29 // VorteX: static frame globals
  30 float WFRAME_DONTCHANGE = -1;
  31 float WFRAME_FIRE1 = 0;
  32 float WFRAME_FIRE2 = 1;
  33 float WFRAME_IDLE = 2;
  34 float WFRAME_RELOAD = 3;
  35 .float wframe;
  36
  37 void(float fr, float t, void() func) weapon_thinkf;
  38
  39 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  40 {
  41         vector ret;
  42         ret_x = screenright * v;
  43         ret_y = screenup * v;
  44         ret_z = screenforward * v;
  45         return ret;
  46 }
  47
  48 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  49 {
  50         float i, j, k;
  51         vector mi, ma, thisv, myv, ret;
  52
  53         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  54
  55         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  56
  57         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  58         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  59         {
  60                 thisv = targ.origin;
  61                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  62                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  63                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  64                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  65                 if(i || j || k)
  66                 {
  67                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  68                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  69                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  70                 }
  71                 else
  72                 {
  73                         // first run
  74                         mi = ma = thisv;
  75                 }
  76         }
  77
  78         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  79         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  80         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  81         ret_z = thisv_z - myv_z;
  82         return ret;
  83 }
  84
  85 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  86 {
  87         vector hitplot;
  88         vector org;
  89         float lag;
  90
  91         if(player.hitplotfh >= 0 && !(player.flags & FL_MONSTER))
  92         {
  93                 lag = ANTILAG_LATENCY(player);
  94                 if(lag < 0.001)
  95                         lag = 0;
  96                 if not(IS_REAL_CLIENT(player))
  97                         lag = 0; // only antilag for clients
  98
  99                 org = player.origin + player.view_ofs;
 100                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 101                 if(IS_CLIENT(trace_ent))
 102                 {
 103                         antilag_takeback(trace_ent, time - lag);
 104                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 105                         antilag_restore(trace_ent);
 106                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 107                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 108                 }
 109         }
 110 }
 111
 112 vector w_shotorg;
 113 vector w_shotdir;
 114 vector w_shotend;
 115
 116 .float prevstrengthsound;
 117 .float prevstrengthsoundattempt;
 118 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 119 {
 120         if((player.items & IT_STRENGTH)
 121                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 122                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 123                 {
 124                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 125                         player.prevstrengthsound = time;
 126                 }
 127                 player.prevstrengthsoundattempt = time;
 128 }
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 134 {
 135         float nudge = 1; // added to traceline target and subtracted from result
 136         float oldsolid;
 137         vector vecs, dv;
 138         oldsolid = ent.dphitcontentsmask;
 139         if(ent.weapon == WEP_RIFLE)
 140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 141         else
 142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         if(antilag)
 144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 145                 // passing world, because we do NOT want it to touch dphitcontentsmask
 146         else
 147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 149
 150         vector vf, vr, vu;
 151         vf = v_forward;
 152         vr = v_right;
 153         vu = v_up;
 154         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 155         v_forward = vf;
 156         v_right = vr;
 157         v_up = vu;
 158
 159         // un-adjust trueaim if shotend is too close
 160         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 161                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 162
 163         // track max damage
 164         if(accuracy_canbegooddamage(ent))
 165                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 166
 167         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 168
 169         if(ent.weaponentity.movedir_x > 0)
 170                 vecs = ent.weaponentity.movedir;
 171         else
 172                 vecs = '0 0 0';
 173
 174         dv = v_right * -vecs_y + v_up * vecs_z;
 175         w_shotorg = ent.origin + ent.view_ofs + dv;
 176
 177         // now move the shotorg forward as much as requested if possible
 178         if(antilag)
 179         {
 180                 if(ent.antilag_debug)
 181                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 182                 else
 183                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 184         }
 185         else
 186                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 187         w_shotorg = trace_endpos - v_forward * nudge;
 188         // calculate the shotdir from the chosen shotorg
 189         w_shotdir = normalize(w_shotend - w_shotorg);
 190
 191         if (antilag)
 192         if (!ent.cvar_cl_noantilag)
 193         {
 194                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 195                 {
 196                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 197                         if (!trace_ent.takedamage)
 198                         {
 199                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 200                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 201                                 {
 202                                         entity e;
 203                                         e = trace_ent;
 204                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 205                                         if(trace_ent == e)
 206                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 207                                 }
 208                         }
 209                 }
 210                 else if(autocvar_g_antilag == 3) // client side hitscan
 211                 {
 212                         // this part MUST use prydon cursor
 213                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 214                         if (ent.cursor_trace_ent != ent)         // just to make sure
 215                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 216                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 217                         {
 218                                 // verify that the shot would miss without antilag
 219                                 // (avoids an issue where guns would always shoot at their origin)
 220                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 221                                 if (!trace_ent.takedamage)
 222                                 {
 223                                         // verify that the shot would hit if altered
 224                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 225                                         if (trace_ent == ent.cursor_trace_ent)
 226                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 227                                         else
 228                                                 print("antilag fail\n");
 229                                 }
 230                         }
 231                 }
 232         }
 233
 234         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 235
 236         if (!g_norecoil)
 237                 ent.punchangle_x = recoil * -1;
 238
 239         if (snd != "")
 240         {
 241                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 242                 W_PlayStrengthSound(ent);
 243         }
 244
 245         // nudge w_shotend so a trace to w_shotend hits
 246         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 247 }
 248
 249 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 250 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 251 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 252 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 253 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 254
 255 float CL_Weaponentity_CustomizeEntityForClient()
 256 {
 257         self.viewmodelforclient = self.owner;
 258         if(IS_SPEC(other))
 259                 if(other.enemy == self.owner)
 260                         self.viewmodelforclient = other;
 261         return TRUE;
 262 }
 263
 264 /*
 265  * supported formats:
 266  *
 267  * 1. simple animated model, muzzle flash handling on h_ model:
 268  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 269  *      tags:
 270  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 271  *        shell = casings ejection point (must be on the right hand side of the gun)
 272  *        weapon = attachment for v_tuba.md3
 273  *    v_tuba.md3 - first and third person model
 274  *    g_tuba.md3 - pickup model
 275  *
 276  * 2. simple animated model, muzzle flash handling on v_ model:
 277  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 278  *      tags:
 279  *        weapon = attachment for v_tuba.md3
 280  *    v_tuba.md3 - first and third person model
 281  *      tags:
 282  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 283  *        shell = casings ejection point (must be on the right hand side of the gun)
 284  *    g_tuba.md3 - pickup model
 285  *
 286  * 3. fully animated model, muzzle flash handling on h_ model:
 287  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 288  *      tags:
 289  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 290  *        shell = casings ejection point (must be on the right hand side of the gun)
 291  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 292  *    v_tuba.md3 - third person model
 293  *    g_tuba.md3 - pickup model
 294  *
 295  * 4. fully animated model, muzzle flash handling on v_ model:
 296  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 297  *      tags:
 298  *        shot = muzzle end (shot origin)
 299  *        shell = casings ejection point (must be on the right hand side of the gun)
 300  *    v_tuba.md3 - third person model
 301  *      tags:
 302  *        shot = muzzle end (for muzzle flashes)
 303  *    g_tuba.md3 - pickup model
 304  */
 305
 306 // writes:
 307 //   self.origin, self.angles
 308 //   self.weaponentity
 309 //   self.movedir, self.view_ofs
 310 //   attachment stuff
 311 //   anim stuff
 312 // to free:
 313 //   call again with ""
 314 //   remove the ent
 315 void CL_WeaponEntity_SetModel(string name)
 316 {
 317         float v_shot_idx;
 318         if (name != "")
 319         {
 320                 // if there is a child entity, hide it until we're sure we use it
 321                 if (self.weaponentity)
 322                         self.weaponentity.model = "";
 323                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 324                 v_shot_idx = gettagindex(self, "shot"); // used later
 325                 if(!v_shot_idx)
 326                         v_shot_idx = gettagindex(self, "tag_shot");
 327
 328                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 329                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 330                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
 331                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
 332                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
 333                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
 334
 335                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 336                 // if we don't, this is a "real" animated model
 337                 if(gettagindex(self, "weapon"))
 338                 {
 339                         if (!self.weaponentity)
 340                                 self.weaponentity = spawn();
 341                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 342                         setattachment(self.weaponentity, self, "weapon");
 343                 }
 344                 else if(gettagindex(self, "tag_weapon"))
 345                 {
 346                         if (!self.weaponentity)
 347                                 self.weaponentity = spawn();
 348                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 349                         setattachment(self.weaponentity, self, "tag_weapon");
 350                 }
 351                 else
 352                 {
 353                         if(self.weaponentity)
 354                                 remove(self.weaponentity);
 355                         self.weaponentity = world;
 356                 }
 357
 358                 setorigin(self,'0 0 0');
 359                 self.angles = '0 0 0';
 360                 self.frame = 0;
 361                 self.viewmodelforclient = world;
 362
 363                 float idx;
 364
 365                 if(v_shot_idx) // v_ model attached to invisible h_ model
 366                 {
 367                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 368                 }
 369                 else
 370                 {
 371                         idx = gettagindex(self, "shot");
 372                         if(!idx)
 373                                 idx = gettagindex(self, "tag_shot");
 374                         if(idx)
 375                                 self.movedir = gettaginfo(self, idx);
 376                         else
 377                         {
 378                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 379                                 self.movedir = '0 0 0';
 380                         }
 381                 }
 382
 383                 if(self.weaponentity) // v_ model attached to invisible h_ model
 384                 {
 385                         idx = gettagindex(self.weaponentity, "shell");
 386                         if(!idx)
 387                                 idx = gettagindex(self.weaponentity, "tag_shell");
 388                         if(idx)
 389                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 390                 }
 391                 else
 392                         idx = 0;
 393                 if(!idx)
 394                 {
 395                         idx = gettagindex(self, "shell");
 396                         if(!idx)
 397                                 idx = gettagindex(self, "tag_shell");
 398                         if(idx)
 399                                 self.spawnorigin = gettaginfo(self, idx);
 400                         else
 401                         {
 402                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 403                                 self.spawnorigin = self.movedir;
 404                         }
 405                 }
 406
 407                 if(v_shot_idx)
 408                 {
 409                         self.oldorigin = '0 0 0'; // use regular attachment
 410                 }
 411                 else
 412                 {
 413                         if(self.weaponentity)
 414                         {
 415                                 idx = gettagindex(self, "weapon");
 416                                 if(!idx)
 417                                         idx = gettagindex(self, "tag_weapon");
 418                         }
 419                         else
 420                         {
 421                                 idx = gettagindex(self, "handle");
 422                                 if(!idx)
 423                                         idx = gettagindex(self, "tag_handle");
 424                         }
 425                         if(idx)
 426                         {
 427                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 428                         }
 429                         else
 430                         {
 431                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 432                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 433                         }
 434                 }
 435
 436                 self.viewmodelforclient = self.owner;
 437         }
 438         else
 439         {
 440                 self.model = "";
 441                 if(self.weaponentity)
 442                         remove(self.weaponentity);
 443                 self.weaponentity = world;
 444                 self.movedir = '0 0 0';
 445                 self.spawnorigin = '0 0 0';
 446                 self.oldorigin = '0 0 0';
 447                 self.anim_fire1  = '0 1 0.01';
 448                 self.anim_fire2  = '0 1 0.01';
 449                 self.anim_idle   = '0 1 0.01';
 450                 self.anim_reload = '0 1 0.01';
 451         }
 452
 453         self.view_ofs = '0 0 0';
 454
 455         if(self.movedir_x >= 0)
 456         {
 457                 vector v0;
 458                 v0 = self.movedir;
 459                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 460                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 461         }
 462         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 463         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 464
 465         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 466
 467         // check if an instant weapon switch occurred
 468         setorigin(self, self.view_ofs);
 469         // reset animstate now
 470         self.wframe = WFRAME_IDLE;
 471         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 472 }
 473
 474 vector CL_Weapon_GetShotOrg(float wpn)
 475 {
 476         entity wi, oldself;
 477         vector ret;
 478         wi = get_weaponinfo(wpn);
 479         oldself = self;
 480         self = spawn();
 481         CL_WeaponEntity_SetModel(wi.mdl);
 482         ret = self.movedir;
 483         CL_WeaponEntity_SetModel("");
 484         remove(self);
 485         self = oldself;
 486         return ret;
 487 }
 488
 489 void CL_Weaponentity_Think()
 490 {
 491         float tb;
 492         self.nextthink = time;
 493         if (intermission_running)
 494                 self.frame = self.anim_idle_x;
 495         if (self.owner.weaponentity != self)
 496         {
 497                 if (self.weaponentity)
 498                         remove(self.weaponentity);
 499                 remove(self);
 500                 return;
 501         }
 502         if (self.owner.deadflag != DEAD_NO)
 503         {
 504                 self.model = "";
 505                 if (self.weaponentity)
 506                         self.weaponentity.model = "";
 507                 return;
 508         }
 509         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 510         {
 511                 self.weaponname = self.owner.weaponname;
 512                 self.dmg = self.owner.modelindex;
 513                 self.deadflag = self.owner.deadflag;
 514
 515                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 516         }
 517
 518         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 519         self.effects = self.owner.effects & EFMASK_CHEAP;
 520         self.effects &~= EF_LOWPRECISION;
 521         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 522         self.effects &~= EF_TELEPORT_BIT;
 523         self.effects &~= EF_RESTARTANIM_BIT;
 524         self.effects |= tb;
 525
 526         if(self.owner.alpha == default_player_alpha)
 527                 self.alpha = default_weapon_alpha;
 528         else if(self.owner.alpha != 0)
 529                 self.alpha = self.owner.alpha;
 530         else
 531                 self.alpha = 1;
 532
 533         self.glowmod = self.owner.weaponentity_glowmod;
 534         self.colormap = self.owner.colormap;
 535         if (self.weaponentity)
 536         {
 537                 self.weaponentity.effects = self.effects;
 538                 self.weaponentity.alpha = self.alpha;
 539                 self.weaponentity.colormap = self.colormap;
 540                 self.weaponentity.glowmod = self.glowmod;
 541         }
 542
 543         self.angles = '0 0 0';
 544
 545         float f = (self.owner.weapon_nextthink - time);
 546         if (self.state == WS_RAISE && !intermission_running)
 547         {
 548                 entity newwep = get_weaponinfo(self.owner.switchweapon);
 549                 f = f * g_weaponratefactor / max(f, cvar(sprintf("g_balance_%s_switchdelay_raise", newwep.netname)));
 550                 //print(sprintf("CL_Weaponentity_Think(): cvar: %s, value: %f, nextthink: %f\n", sprintf("g_balance_%s_switchdelay_raise", newwep.netname), cvar(sprintf("g_balance_%s_switchdelay_raise", newwep.netname)), (self.owner.weapon_nextthink - time)));
 551                 self.angles_x = -90 * f * f;
 552         }
 553         else if (self.state == WS_DROP && !intermission_running)
 554         {
 555                 entity oldwep = get_weaponinfo(self.owner.weapon);
 556                 f = 1 - f * g_weaponratefactor / max(f, cvar(sprintf("g_balance_%s_switchdelay_drop", oldwep.netname)));
 557                 //print(sprintf("CL_Weaponentity_Think(): cvar: %s, value: %f, nextthink: %f\n", sprintf("g_balance_%s_switchdelay_drop", oldwep.netname), cvar(sprintf("g_balance_%s_switchdelay_drop", oldwep.netname)), (self.owner.weapon_nextthink - time)));
 558                 self.angles_x = -90 * f * f;
 559         }
 560         else if (self.state == WS_CLEAR)
 561         {
 562                 f = 1;
 563                 self.angles_x = -90 * f * f;
 564         }
 565 }
 566
 567 void CL_ExteriorWeaponentity_Think()
 568 {
 569         float tag_found;
 570         self.nextthink = time;
 571         if (self.owner.exteriorweaponentity != self)
 572         {
 573                 remove(self);
 574                 return;
 575         }
 576         if (self.owner.deadflag != DEAD_NO)
 577         {
 578                 self.model = "";
 579                 return;
 580         }
 581         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 582         {
 583                 self.weaponname = self.owner.weaponname;
 584                 self.dmg = self.owner.modelindex;
 585                 self.deadflag = self.owner.deadflag;
 586                 if (self.owner.weaponname != "")
 587                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 588                 else
 589                         self.model = "";
 590
 591                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 592                 {
 593                         self.tag_index = tag_found;
 594                         self.tag_entity = self.owner;
 595                 }
 596                 else
 597                         setattachment(self, self.owner, "bip01 r hand");
 598         }
 599         self.effects = self.owner.effects;
 600         self.effects |= EF_LOWPRECISION;
 601         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 602         if(self.owner.alpha == default_player_alpha)
 603                 self.alpha = default_weapon_alpha;
 604         else if(self.owner.alpha != 0)
 605                 self.alpha = self.owner.alpha;
 606         else
 607                 self.alpha = 1;
 608
 609         self.glowmod = self.owner.weaponentity_glowmod;
 610         self.colormap = self.owner.colormap;
 611
 612         CSQCMODEL_AUTOUPDATE();
 613 }
 614
 615 // spawning weaponentity for client
 616 void CL_SpawnWeaponentity()
 617 {
 618         self.weaponentity = spawn();
 619         self.weaponentity.classname = "weaponentity";
 620         self.weaponentity.solid = SOLID_NOT;
 621         self.weaponentity.owner = self;
 622         setmodel(self.weaponentity, ""); // precision set when changed
 623         setorigin(self.weaponentity, '0 0 0');
 624         self.weaponentity.angles = '0 0 0';
 625         self.weaponentity.viewmodelforclient = self;
 626         self.weaponentity.flags = 0;
 627         self.weaponentity.think = CL_Weaponentity_Think;
 628         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 629         self.weaponentity.nextthink = time;
 630
 631         self.exteriorweaponentity = spawn();
 632         self.exteriorweaponentity.classname = "exteriorweaponentity";
 633         self.exteriorweaponentity.solid = SOLID_NOT;
 634         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 635         self.exteriorweaponentity.owner = self;
 636         setorigin(self.exteriorweaponentity, '0 0 0');
 637         self.exteriorweaponentity.angles = '0 0 0';
 638         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 639         self.exteriorweaponentity.nextthink = time;
 640
 641         {
 642                 entity oldself = self;
 643                 self = self.exteriorweaponentity;
 644                 CSQCMODEL_AUTOINIT();
 645                 self = oldself;
 646         }
 647 }
 648
 649 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 650 {
 651         msg_entity = e;
 652         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 653         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 654         WriteByte(MSG_ONE, wpn);
 655         WriteString(MSG_ONE, wpnname);
 656         WriteByte(MSG_ONE, type);
 657 }
 658
 659 .float hasweapon_complain_spam;
 660
 661 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 662 {
 663         float f;
 664         entity oldself;
 665
 666         if(time < self.hasweapon_complain_spam)
 667                 complain = 0;
 668         if(complain)
 669                 self.hasweapon_complain_spam = time + 0.2;
 670
 671         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 672         {
 673                 if (complain)
 674                         sprint(self, "Invalid weapon\n");
 675                 return FALSE;
 676         }
 677         if (WEPSET_CONTAINS_EW(cl, wpn))
 678         {
 679                 if (andammo)
 680                 {
 681                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 682                         {
 683                                 f = 1;
 684                         }
 685                         else
 686                         {
 687                                 oldself = self;
 688                                 self = cl;
 689                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 690                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 691
 692                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 693                                 entity mine;
 694                                 if(wpn == WEP_MINE_LAYER)
 695                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 696                                         f = 1;
 697
 698                                 self = oldself;
 699                         }
 700                         if (!f)
 701                         {
 702                                 if (complain)
 703                                 if(IS_REAL_CLIENT(cl))
 704                                 {
 705                                         play2(cl, "weapons/unavailable.wav");
 706                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 707                                 }
 708                                 return FALSE;
 709                         }
 710                 }
 711                 return TRUE;
 712         }
 713         if (complain)
 714         {
 715                 // DRESK - 3/16/07
 716                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 717                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 718                 {
 719                         Send_WeaponComplain(cl, wpn, W_Name(wpn), 1);
 720
 721                         if(autocvar_g_showweaponspawns)
 722                         {
 723                                 entity e;
 724                                 string s;
 725
 726                                 e = get_weaponinfo(wpn);
 727                                 s = e.model2;
 728
 729                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 730                                 {
 731                                         if(e.classname == "droppedweapon")
 732                                                 continue;
 733                                         if not(e.flags & FL_ITEM)
 734                                                 continue;
 735                                         WaypointSprite_Spawn(
 736                                                 s,
 737                                                 1, 0,
 738                                                 world, e.origin,
 739                                                 self, 0,
 740                                                 world, enemy,
 741                                                 0,
 742                                                 RADARICON_NONE, '0 0 0'
 743                                         );
 744                                 }
 745                         }
 746                 }
 747                 else
 748                 {
 749                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 750                 }
 751
 752                 play2(cl, "weapons/unavailable.wav");
 753         }
 754         return FALSE;
 755 }
 756
 757 // Weapon subs
 758 void w_clear()
 759 {
 760         if (self.weapon != -1)
 761         {
 762                 self.weapon = 0;
 763                 self.switchingweapon = 0;
 764         }
 765         if (self.weaponentity)
 766         {
 767                 self.weaponentity.state = WS_CLEAR;
 768                 self.weaponentity.effects = 0;
 769         }
 770 }
 771
 772 void w_ready()
 773 {
 774         if (self.weaponentity)
 775                 self.weaponentity.state = WS_READY;
 776         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 777 }
 778
 779 // Setup weapon for client (after this raise frame will be launched)
 780 void weapon_setup(float windex)
 781 {
 782         entity e;
 783         e = get_weaponinfo(windex);
 784         self.items &~= IT_AMMO;
 785         self.items = self.items | (e.items & IT_AMMO);
 786
 787         // the two weapon entities will notice this has changed and update their models
 788         self.weapon = windex;
 789         self.switchingweapon = windex; // to make sure
 790         self.weaponname = e.mdl;
 791         self.bulletcounter = 0;
 792 }
 793
 794 // perform weapon to attack (weaponstate and attack_finished check is here)
 795 void W_SwitchToOtherWeapon(entity pl)
 796 {
 797         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 798         float w, ww;
 799         w = pl.weapon;
 800         if(WEPSET_CONTAINS_EW(pl, w))
 801         {
 802                 WEPSET_ANDNOT_EW(pl, w);
 803                 ww = w_getbestweapon(pl);
 804                 WEPSET_OR_EW(pl, w);
 805         }
 806         else
 807                 ww = w_getbestweapon(pl);
 808         if(ww)
 809                 W_SwitchWeapon_Force(pl, ww);
 810 }
 811
 812 .float prevdryfire;
 813 .float prevwarntime;
 814 float weapon_prepareattack_checkammo(float secondary)
 815 {
 816         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 817         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 818         {
 819                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 820                 entity mine;
 821                 if(self.weapon == WEP_MINE_LAYER)
 822                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 823                         return FALSE;
 824
 825                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 826                 {
 827                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 828                         self.prevdryfire = time;
 829                 }
 830
 831                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 832                 {
 833                         if(time - self.prevwarntime > 1)
 834                         {
 835                                 Send_Notification(
 836                                         NOTIF_ONE,
 837                                         self,
 838                                         MSG_MULTI,
 839                                         ITEM_WEAPON_PRIMORSEC,
 840                                         self.weapon,
 841                                         secondary,
 842                                         (1 - secondary)
 843                                 );
 844                         }
 845                         self.prevwarntime = time;
 846                 }
 847                 else // this weapon is totally unable to fire, switch to another one
 848                 {
 849                         W_SwitchToOtherWeapon(self);
 850                 }
 851
 852                 return FALSE;
 853         }
 854         return TRUE;
 855 }
 856 .float race_penalty;
 857 float weapon_prepareattack_check(float secondary, float attacktime)
 858 {
 859         if(!weapon_prepareattack_checkammo(secondary))
 860                 return FALSE;
 861
 862         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 863         //if all players readied up and the countdown is running
 864         if(time < game_starttime || time < self.race_penalty) {
 865                 return FALSE;
 866         }
 867
 868         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 869                 return FALSE;
 870
 871         // do not even think about shooting if switching
 872         if(self.switchweapon != self.weapon)
 873                 return FALSE;
 874
 875         if(attacktime >= 0)
 876         {
 877                 // don't fire if previous attack is not finished
 878                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 879                         return FALSE;
 880                 // don't fire while changing weapon
 881                 if (self.weaponentity.state != WS_READY)
 882                         return FALSE;
 883         }
 884
 885         return TRUE;
 886 }
 887 float weapon_prepareattack_do(float secondary, float attacktime)
 888 {
 889         self.weaponentity.state = WS_INUSE;
 890
 891         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 892
 893         // if the weapon hasn't been firing continuously, reset the timer
 894         if(attacktime >= 0)
 895         {
 896                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 897                 {
 898                         ATTACK_FINISHED(self) = time;
 899                         //dprint("resetting attack finished to ", ftos(time), "\n");
 900                 }
 901                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 902         }
 903         self.bulletcounter += 1;
 904         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 905         return TRUE;
 906 }
 907 float weapon_prepareattack(float secondary, float attacktime)
 908 {
 909         if(weapon_prepareattack_check(secondary, attacktime))
 910         {
 911                 weapon_prepareattack_do(secondary, attacktime);
 912                 return TRUE;
 913         }
 914         else
 915                 return FALSE;
 916 }
 917
 918 void weapon_thinkf(float fr, float t, void() func)
 919 {
 920         vector a;
 921         vector of, or, ou;
 922         float restartanim;
 923
 924         if(fr == WFRAME_DONTCHANGE)
 925         {
 926                 fr = self.weaponentity.wframe;
 927                 restartanim = FALSE;
 928         }
 929         else if (fr == WFRAME_IDLE)
 930                 restartanim = FALSE;
 931         else
 932                 restartanim = TRUE;
 933
 934         of = v_forward;
 935         or = v_right;
 936         ou = v_up;
 937
 938         if (self.weaponentity)
 939         {
 940                 self.weaponentity.wframe = fr;
 941                 a = '0 0 0';
 942                 if (fr == WFRAME_IDLE)
 943                         a = self.weaponentity.anim_idle;
 944                 else if (fr == WFRAME_FIRE1)
 945                         a = self.weaponentity.anim_fire1;
 946                 else if (fr == WFRAME_FIRE2)
 947                         a = self.weaponentity.anim_fire2;
 948                 else // if (fr == WFRAME_RELOAD)
 949                         a = self.weaponentity.anim_reload;
 950                 a_z *= g_weaponratefactor;
 951                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 952         }
 953
 954         v_forward = of;
 955         v_right = or;
 956         v_up = ou;
 957
 958         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 959         {
 960                 backtrace("Tried to override initial weapon think function - should this really happen?");
 961         }
 962
 963         t *= W_WeaponRateFactor();
 964
 965         // VorteX: haste can be added here
 966         if (self.weapon_think == w_ready)
 967         {
 968                 self.weapon_nextthink = time;
 969                 //dprint("started firing at ", ftos(time), "\n");
 970         }
 971         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
 972         {
 973                 self.weapon_nextthink = time;
 974                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 975         }
 976         self.weapon_nextthink = self.weapon_nextthink + t;
 977         self.weapon_think = func;
 978         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 979
 980         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 981         {
 982                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
 983                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
 984                 else
 985                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
 986         }
 987         else
 988         {
 989                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
 990                         self.anim_upper_action = 0;
 991         }
 992 }
 993
 994 void weapon_boblayer1(float spd, vector org)
 995 {
 996         // VorteX: haste can be added here
 997 }
 998
 999 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1000 {
1001         vector mdirection;
1002         float mspeed;
1003         vector outvelocity;
1004
1005         mvelocity = mvelocity * g_weaponspeedfactor;
1006
1007         mdirection = normalize(mvelocity);
1008         mspeed = vlen(mvelocity);
1009
1010         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1011
1012         return outvelocity;
1013 }
1014
1015 void W_AttachToShotorg(entity flash, vector offset)
1016 {
1017         if(self.flags & FL_MONSTER)
1018                 return; // no flash for monsters
1019         entity xflash;
1020         flash.owner = self;
1021         flash.angles_z = random() * 360;
1022
1023         if(gettagindex(self.weaponentity, "shot"))
1024                 setattachment(flash, self.weaponentity, "shot");
1025         else
1026                 setattachment(flash, self.weaponentity, "tag_shot");
1027         setorigin(flash, offset);
1028
1029         xflash = spawn();
1030         copyentity(flash, xflash);
1031
1032         flash.viewmodelforclient = self;
1033
1034         if(self.weaponentity.oldorigin_x > 0)
1035         {
1036                 setattachment(xflash, self.exteriorweaponentity, "");
1037                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1038         }
1039         else
1040         {
1041                 if(gettagindex(self.exteriorweaponentity, "shot"))
1042                         setattachment(xflash, self.exteriorweaponentity, "shot");
1043                 else
1044                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1045                 setorigin(xflash, offset);
1046         }
1047 }
1048
1049 vector cliptoplane(vector v, vector p)
1050 {
1051         return v - (v * p) * p;
1052 }
1053
1054 vector solve_cubic_pq(float p, float q)
1055 {
1056         float D, u, v, a;
1057         D = q*q/4.0 + p*p*p/27.0;
1058         if(D < 0)
1059         {
1060                 // irreducibilis
1061                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1062                 u = sqrt(-4.0/3.0 * p);
1063                 // a in range 0..pi/3
1064                 // cos(a)
1065                 // cos(a + 2pi/3)
1066                 // cos(a + 4pi/3)
1067                 return
1068                         u *
1069                         (
1070                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1071                                 +
1072                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1073                                 +
1074                                 '0 0 1' * cos(a)
1075                         );
1076         }
1077         else if(D == 0)
1078         {
1079                 // simple
1080                 if(p == 0)
1081                         return '0 0 0';
1082                 u = 3*q/p;
1083                 v = -u/2;
1084                 if(u >= v)
1085                         return '1 1 0' * v + '0 0 1' * u;
1086                 else
1087                         return '0 1 1' * v + '1 0 0' * u;
1088         }
1089         else
1090         {
1091                 // cardano
1092                 u = cbrt(-q/2.0 + sqrt(D));
1093                 v = cbrt(-q/2.0 - sqrt(D));
1094                 return '1 1 1' * (u + v);
1095         }
1096 }
1097 vector solve_cubic_abcd(float a, float b, float c, float d)
1098 {
1099         // y = 3*a*x + b
1100         // x = (y - b) / 3a
1101         float p, q;
1102         vector v;
1103         p = (9*a*c - 3*b*b);
1104         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1105         v = solve_cubic_pq(p, q);
1106         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1107         if(a < 0)
1108                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1109         return v;
1110 }
1111
1112 vector findperpendicular(vector v)
1113 {
1114         vector p;
1115         p_x = v_z;
1116         p_y = -v_x;
1117         p_z = v_y;
1118         return normalize(cliptoplane(p, v));
1119 }
1120
1121 vector W_CalculateProjectileSpread(vector forward, float spread)
1122 {
1123         float sigma;
1124         vector v1 = '0 0 0', v2;
1125         float dx, dy, r;
1126         float sstyle;
1127         spread *= g_weaponspreadfactor;
1128         if(spread <= 0)
1129                 return forward;
1130         sstyle = autocvar_g_projectiles_spread_style;
1131
1132         if(sstyle == 0)
1133         {
1134                 // this is the baseline for the spread value!
1135                 // standard deviation: sqrt(2/5)
1136                 // density function: sqrt(1-r^2)
1137                 return forward + randomvec() * spread;
1138         }
1139         else if(sstyle == 1)
1140         {
1141                 // same thing, basically
1142                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1143         }
1144         else if(sstyle == 2)
1145         {
1146                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1147                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1148                 v1 = findperpendicular(forward);
1149                 v2 = cross(forward, v1);
1150                 // random point on unit circle
1151                 dx = random() * 2 * M_PI;
1152                 dy = sin(dx);
1153                 dx = cos(dx);
1154                 // radius in our dist function
1155                 r = random();
1156                 r = sqrt(r);
1157                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1158         }
1159         else if(sstyle == 3) // gauss 3d
1160         {
1161                 sigma = spread * 0.44721359549996; // match baseline stddev
1162                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1163                 v1 = forward;
1164                 v1_x += gsl_ran_gaussian(sigma);
1165                 v1_y += gsl_ran_gaussian(sigma);
1166                 v1_z += gsl_ran_gaussian(sigma);
1167                 return v1;
1168         }
1169         else if(sstyle == 4) // gauss 2d
1170         {
1171                 sigma = spread * 0.44721359549996; // match baseline stddev
1172                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1173                 v1_x = gsl_ran_gaussian(sigma);
1174                 v1_y = gsl_ran_gaussian(sigma);
1175                 v1_z = gsl_ran_gaussian(sigma);
1176                 return normalize(forward + cliptoplane(v1, forward));
1177         }
1178         else if(sstyle == 5) // 1-r
1179         {
1180                 sigma = spread * 1.154700538379252; // match baseline stddev
1181                 v1 = findperpendicular(forward);
1182                 v2 = cross(forward, v1);
1183                 // random point on unit circle
1184                 dx = random() * 2 * M_PI;
1185                 dy = sin(dx);
1186                 dx = cos(dx);
1187                 // radius in our dist function
1188                 r = random();
1189                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1190                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1191         }
1192         else if(sstyle == 6) // 1-r^2
1193         {
1194                 sigma = spread * 1.095445115010332; // match baseline stddev
1195                 v1 = findperpendicular(forward);
1196                 v2 = cross(forward, v1);
1197                 // random point on unit circle
1198                 dx = random() * 2 * M_PI;
1199                 dy = sin(dx);
1200                 dx = cos(dx);
1201                 // radius in our dist function
1202                 r = random();
1203                 r = sqrt(1 - r);
1204                 r = sqrt(1 - r);
1205                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1206         }
1207         else if(sstyle == 7) // (1-r) (2-r)
1208         {
1209                 sigma = spread * 1.224744871391589; // match baseline stddev
1210                 v1 = findperpendicular(forward);
1211                 v2 = cross(forward, v1);
1212                 // random point on unit circle
1213                 dx = random() * 2 * M_PI;
1214                 dy = sin(dx);
1215                 dx = cos(dx);
1216                 // radius in our dist function
1217                 r = random();
1218                 r = 1 - sqrt(r);
1219                 r = 1 - sqrt(r);
1220                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1221         }
1222         else
1223                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1224         return '0 0 0';
1225         /*
1226          * how to derive falloff functions:
1227          * rho(r) := (2-r) * (1-r);
1228          * a : 0;
1229          * b : 1;
1230          * rhor(r) := r * rho(r);
1231          * cr(t) := integrate(rhor(r), r, a, t);
1232          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1233          * variance : scr(b) / cr(b);
1234          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1235          * sqrt(0.4 / variance), numer;
1236          */
1237 }
1238
1239 #if 0
1240 float mspercallsum;
1241 float mspercallsstyle;
1242 float mspercallcount;
1243 #endif
1244 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1245 {
1246         if(missile.owner == world)
1247                 error("Unowned missile");
1248
1249         dir = dir + upDir * (pUpSpeed / pSpeed);
1250         dir_z += pZSpeed / pSpeed;
1251         pSpeed *= vlen(dir);
1252         dir = normalize(dir);
1253
1254 #if 0
1255         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1256         {
1257                 mspercallsum = mspercallcount = 0;
1258                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1259         }
1260         mspercallsum -= gettime(GETTIME_HIRES);
1261 #endif
1262         dir = W_CalculateProjectileSpread(dir, spread);
1263 #if 0
1264         mspercallsum += gettime(GETTIME_HIRES);
1265         mspercallcount += 1;
1266         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1267 #endif
1268
1269         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1270 }
1271
1272 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1273 {
1274         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1275 }
1276
1277 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1278 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1279
1280 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1281 {
1282         if(self.flags & FL_MONSTER) // no ammo for monsters... yet
1283                 return;
1284
1285         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1286                 return;
1287
1288         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1289         if(ammo_reload)
1290         {
1291                 self.clip_load -= ammo_use;
1292                 self.(weapon_load[self.weapon]) = self.clip_load;
1293         }
1294         else
1295                 self.(self.current_ammo) -= ammo_use;
1296 }
1297
1298 // weapon reloading code
1299
1300 .float reload_ammo_amount, reload_ammo_min, reload_time;
1301 .float reload_complain;
1302 .string reload_sound;
1303
1304 void W_ReloadedAndReady()
1305 {
1306         // finish the reloading process, and do the ammo transfer
1307
1308         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1309
1310         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1311         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1312                 self.clip_load = self.reload_ammo_amount;
1313         else
1314         {
1315                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1316                 {
1317                         self.clip_load += 1;
1318                         self.(self.current_ammo) -= 1;
1319                 }
1320         }
1321         self.(weapon_load[self.weapon]) = self.clip_load;
1322
1323         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1324         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1325         // so your weapon is disabled for a few seconds without reason
1326
1327         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1328
1329         w_ready();
1330 }
1331
1332 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1333 {
1334         // set global values to work with
1335
1336         self.reload_ammo_min = sent_ammo_min;
1337         self.reload_ammo_amount = sent_ammo_amount;
1338         self.reload_time = sent_time;
1339         self.reload_sound = sent_sound;
1340
1341         // check if we meet the necessary conditions to reload
1342
1343         entity e;
1344         e = get_weaponinfo(self.weapon);
1345
1346         // don't reload weapons that don't have the RELOADABLE flag
1347         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1348         {
1349                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1350                 return;
1351         }
1352
1353         // return if reloading is disabled for this weapon
1354         if(!self.reload_ammo_amount)
1355                 return;
1356
1357         // our weapon is fully loaded, no need to reload
1358         if (self.clip_load >= self.reload_ammo_amount)
1359                 return;
1360
1361         // no ammo, so nothing to load
1362         if(!self.(self.current_ammo) && self.reload_ammo_min)
1363         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1364         {
1365                 if(IS_REAL_CLIENT(self) && self.reload_complain < time)
1366                 {
1367                         play2(self, "weapons/unavailable.wav");
1368                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1369                         self.reload_complain = time + 1;
1370                 }
1371                 // switch away if the amount of ammo is not enough to keep using this weapon
1372                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1373                 {
1374                         self.clip_load = -1; // reload later
1375                         W_SwitchToOtherWeapon(self);
1376                 }
1377                 return;
1378         }
1379
1380         if (self.weaponentity)
1381         {
1382                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1383                         return;
1384
1385                 // allow switching away while reloading, but this will cause a new reload!
1386                 self.weaponentity.state = WS_READY;
1387         }
1388
1389         // now begin the reloading process
1390
1391         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1392
1393         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1394         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1395         // so your weapon is disabled for a few seconds without reason
1396
1397         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1398
1399         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1400
1401         if(self.clip_load < 0)
1402                 self.clip_load = 0;
1403         self.old_clip_load = self.clip_load;
1404         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1405 }