qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  73         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  74         {
  75                 thisv = targ.origin;
  76                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  77                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  78                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  79                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  80                 if(i || j || k)
  81                 {
  82                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  83                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  84                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  85                 }
  86                 else
  87                 {
  88                         // first run
  89                         mi = ma = thisv;
  90                 }
  91         }
  92
  93         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  94         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  95         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  96         ret_z = thisv_z - myv_z;
  97         return ret;
  98 }
  99
 100 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 101 {
 102         vector hitplot;
 103         vector org;
 104         float lag;
 105
 106         if(player.hitplotfh >= 0)
 107         {
 108                 lag = ANTILAG_LATENCY(player);
 109                 if(lag < 0.001)
 110                         lag = 0;
 111                 if(clienttype(player) != CLIENTTYPE_REAL)
 112                         lag = 0; // only antilag for clients
 113
 114                 org = player.origin + player.view_ofs;
 115                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 116                 if(trace_ent.flags & FL_CLIENT)
 117                 {
 118                         antilag_takeback(trace_ent, time - lag);
 119                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 120                         antilag_restore(trace_ent);
 121                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 122                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 123                 }
 124         }
 125 }
 126
 127 vector w_shotorg;
 128 vector w_shotdir;
 129 vector w_shotend;
 130
 131 .float prevstrengthsound;
 132 .float prevstrengthsoundattempt;
 133 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 134 {
 135                 if((!g_minstagib)
 136                         && (player.items & IT_STRENGTH)
 137                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 138                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 139                 {
 140                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 141                         player.prevstrengthsound = time;
 142                 }
 143                 player.prevstrengthsoundattempt = time;
 144 }
 145
 146 // this function calculates w_shotorg and w_shotdir based on the weapon model
 147 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 148 // make sure you call makevectors first (FIXME?)
 149 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 150 {
 151         float nudge = 1; // added to traceline target and subtracted from result
 152         float oldsolid;
 153         vector vecs, dv;
 154         oldsolid = ent.dphitcontentsmask;
 155         if(ent.weapon == WEP_RIFLE)
 156                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 157         else
 158                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 159         if(antilag)
 160                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 161                 // passing world, because we do NOT want it to touch dphitcontentsmask
 162         else
 163                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 164         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 165
 166         vector vf, vr, vu;
 167         vf = v_forward;
 168         vr = v_right;
 169         vu = v_up;
 170         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 171         v_forward = vf;
 172         v_right = vr;
 173         v_up = vu;
 174
 175         // un-adjust trueaim if shotend is too close
 176         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 177                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 178
 179         // track max damage
 180         if(accuracy_canbegooddamage(ent))
 181                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 182
 183         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 184
 185         if(ent.weaponentity.movedir_x > 0)
 186                 vecs = ent.weaponentity.movedir;
 187         else
 188                 vecs = '0 0 0';
 189
 190         dv = v_right * -vecs_y + v_up * vecs_z;
 191         w_shotorg = ent.origin + ent.view_ofs + dv;
 192
 193         // now move the shotorg forward as much as requested if possible
 194         if(antilag)
 195         {
 196                 if(ent.antilag_debug)
 197                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 198                 else
 199                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 200         }
 201         else
 202                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 203         w_shotorg = trace_endpos - v_forward * nudge;
 204         // calculate the shotdir from the chosen shotorg
 205         w_shotdir = normalize(w_shotend - w_shotorg);
 206
 207         if (antilag)
 208         if (!ent.cvar_cl_noantilag)
 209         {
 210                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 211                 {
 212                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 213                         if (!trace_ent.takedamage)
 214                         {
 215                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 216                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 217                                 {
 218                                         entity e;
 219                                         e = trace_ent;
 220                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 221                                         if(trace_ent == e)
 222                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 223                                 }
 224                         }
 225                 }
 226                 else if(autocvar_g_antilag == 3) // client side hitscan
 227                 {
 228                         // this part MUST use prydon cursor
 229                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 230                         if (ent.cursor_trace_ent != ent)         // just to make sure
 231                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 232                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 233                         {
 234                                 // verify that the shot would miss without antilag
 235                                 // (avoids an issue where guns would always shoot at their origin)
 236                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 237                                 if (!trace_ent.takedamage)
 238                                 {
 239                                         // verify that the shot would hit if altered
 240                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 241                                         if (trace_ent == ent.cursor_trace_ent)
 242                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 243                                         else
 244                                                 print("antilag fail\n");
 245                                 }
 246                         }
 247                 }
 248         }
 249
 250         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 251
 252         if (!g_norecoil)
 253                 ent.punchangle_x = recoil * -1;
 254
 255         if (snd != "")
 256         {
 257                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 258                 W_PlayStrengthSound(ent);
 259         }
 260
 261         // nudge w_shotend so a trace to w_shotend hits
 262         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 263 }
 264
 265 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 266 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 267 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 270
 271 float CL_Weaponentity_CustomizeEntityForClient()
 272 {
 273         self.viewmodelforclient = self.owner;
 274         if(other.classname == "spectator")
 275                 if(other.enemy == self.owner)
 276                         self.viewmodelforclient = other;
 277         return TRUE;
 278 }
 279
 280 /*
 281  * supported formats:
 282  *
 283  * 1. simple animated model, muzzle flash handling on h_ model:
 284  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 285  *      tags:
 286  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 287  *        shell = casings ejection point (must be on the right hand side of the gun)
 288  *        weapon = attachment for v_tuba.md3
 289  *    v_tuba.md3 - first and third person model
 290  *    g_tuba.md3 - pickup model
 291  *
 292  * 2. simple animated model, muzzle flash handling on v_ model:
 293  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 294  *      tags:
 295  *        weapon = attachment for v_tuba.md3
 296  *    v_tuba.md3 - first and third person model
 297  *      tags:
 298  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 299  *        shell = casings ejection point (must be on the right hand side of the gun)
 300  *    g_tuba.md3 - pickup model
 301  *
 302  * 3. fully animated model, muzzle flash handling on h_ model:
 303  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 304  *      tags:
 305  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 306  *        shell = casings ejection point (must be on the right hand side of the gun)
 307  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 308  *    v_tuba.md3 - third person model
 309  *    g_tuba.md3 - pickup model
 310  *
 311  * 4. fully animated model, muzzle flash handling on v_ model:
 312  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 313  *      tags:
 314  *        shot = muzzle end (shot origin)
 315  *        shell = casings ejection point (must be on the right hand side of the gun)
 316  *    v_tuba.md3 - third person model
 317  *      tags:
 318  *        shot = muzzle end (for muzzle flashes)
 319  *    g_tuba.md3 - pickup model
 320  */
 321
 322 // writes:
 323 //   self.origin, self.angles
 324 //   self.weaponentity
 325 //   self.movedir, self.view_ofs
 326 //   attachment stuff
 327 //   anim stuff
 328 // to free:
 329 //   call again with ""
 330 //   remove the ent
 331 void CL_WeaponEntity_SetModel(string name)
 332 {
 333         float v_shot_idx;
 334         if (name != "")
 335         {
 336                 // if there is a child entity, hide it until we're sure we use it
 337                 if (self.weaponentity)
 338                         self.weaponentity.model = "";
 339                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 340                 v_shot_idx = gettagindex(self, "shot"); // used later
 341                 if(!v_shot_idx)
 342                         v_shot_idx = gettagindex(self, "tag_shot");
 343
 344                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 345                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 346                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
 347                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
 348                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
 349                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
 350
 351                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 352                 // if we don't, this is a "real" animated model
 353                 if(gettagindex(self, "weapon"))
 354                 {
 355                         if (!self.weaponentity)
 356                                 self.weaponentity = spawn();
 357                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 358                         setattachment(self.weaponentity, self, "weapon");
 359                 }
 360                 else if(gettagindex(self, "tag_weapon"))
 361                 {
 362                         if (!self.weaponentity)
 363                                 self.weaponentity = spawn();
 364                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 365                         setattachment(self.weaponentity, self, "tag_weapon");
 366                 }
 367                 else
 368                 {
 369                         if(self.weaponentity)
 370                                 remove(self.weaponentity);
 371                         self.weaponentity = world;
 372                 }
 373
 374                 setorigin(self,'0 0 0');
 375                 self.angles = '0 0 0';
 376                 self.frame = 0;
 377                 self.viewmodelforclient = world;
 378
 379                 float idx;
 380
 381                 if(v_shot_idx) // v_ model attached to invisible h_ model
 382                 {
 383                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 384                 }
 385                 else
 386                 {
 387                         idx = gettagindex(self, "shot");
 388                         if(!idx)
 389                                 idx = gettagindex(self, "tag_shot");
 390                         if(idx)
 391                                 self.movedir = gettaginfo(self, idx);
 392                         else
 393                         {
 394                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 395                                 self.movedir = '0 0 0';
 396                         }
 397                 }
 398
 399                 if(self.weaponentity) // v_ model attached to invisible h_ model
 400                 {
 401                         idx = gettagindex(self.weaponentity, "shell");
 402                         if(!idx)
 403                                 idx = gettagindex(self.weaponentity, "tag_shell");
 404                         if(idx)
 405                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 406                 }
 407                 else
 408                         idx = 0;
 409                 if(!idx)
 410                 {
 411                         idx = gettagindex(self, "shell");
 412                         if(!idx)
 413                                 idx = gettagindex(self, "tag_shell");
 414                         if(idx)
 415                                 self.spawnorigin = gettaginfo(self, idx);
 416                         else
 417                         {
 418                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 419                                 self.spawnorigin = self.movedir;
 420                         }
 421                 }
 422
 423                 if(v_shot_idx)
 424                 {
 425                         self.oldorigin = '0 0 0'; // use regular attachment
 426                 }
 427                 else
 428                 {
 429                         if(self.weaponentity)
 430                         {
 431                                 idx = gettagindex(self, "weapon");
 432                                 if(!idx)
 433                                         idx = gettagindex(self, "tag_weapon");
 434                         }
 435                         else
 436                         {
 437                                 idx = gettagindex(self, "handle");
 438                                 if(!idx)
 439                                         idx = gettagindex(self, "tag_handle");
 440                         }
 441                         if(idx)
 442                         {
 443                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 444                         }
 445                         else
 446                         {
 447                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 448                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 449                         }
 450                 }
 451
 452                 self.viewmodelforclient = self.owner;
 453         }
 454         else
 455         {
 456                 self.model = "";
 457                 if(self.weaponentity)
 458                         remove(self.weaponentity);
 459                 self.weaponentity = world;
 460                 self.movedir = '0 0 0';
 461                 self.spawnorigin = '0 0 0';
 462                 self.oldorigin = '0 0 0';
 463                 self.anim_fire1  = '0 1 0.01';
 464                 self.anim_fire2  = '0 1 0.01';
 465                 self.anim_idle   = '0 1 0.01';
 466                 self.anim_reload = '0 1 0.01';
 467         }
 468
 469         self.view_ofs = '0 0 0';
 470
 471         if(self.movedir_x >= 0)
 472         {
 473                 vector v0;
 474                 v0 = self.movedir;
 475                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 476                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 477         }
 478         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 479         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 480
 481         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 482
 483         // check if an instant weapon switch occurred
 484         setorigin(self, self.view_ofs);
 485         // reset animstate now
 486         self.wframe = WFRAME_IDLE;
 487         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 488 }
 489
 490 vector CL_Weapon_GetShotOrg(float wpn)
 491 {
 492         entity wi, oldself;
 493         vector ret;
 494         wi = get_weaponinfo(wpn);
 495         oldself = self;
 496         self = spawn();
 497         CL_WeaponEntity_SetModel(wi.mdl);
 498         ret = self.movedir;
 499         CL_WeaponEntity_SetModel("");
 500         remove(self);
 501         self = oldself;
 502         return ret;
 503 }
 504
 505 void CL_Weaponentity_Think()
 506 {
 507         float tb;
 508         self.nextthink = time;
 509         if (intermission_running)
 510                 self.frame = self.anim_idle_x;
 511         if (self.owner.weaponentity != self)
 512         {
 513                 if (self.weaponentity)
 514                         remove(self.weaponentity);
 515                 remove(self);
 516                 return;
 517         }
 518         if (self.owner.deadflag != DEAD_NO)
 519         {
 520                 self.model = "";
 521                 if (self.weaponentity)
 522                         self.weaponentity.model = "";
 523                 return;
 524         }
 525         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 526         {
 527                 self.weaponname = self.owner.weaponname;
 528                 self.dmg = self.owner.modelindex;
 529                 self.deadflag = self.owner.deadflag;
 530
 531                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 532         }
 533
 534         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 535         self.effects = self.owner.effects & EFMASK_CHEAP;
 536         self.effects &~= EF_LOWPRECISION;
 537         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 538         self.effects &~= EF_TELEPORT_BIT;
 539         self.effects &~= EF_RESTARTANIM_BIT;
 540         self.effects |= tb;
 541
 542         if(self.owner.alpha == default_player_alpha)
 543                 self.alpha = default_weapon_alpha;
 544         else if(self.owner.alpha != 0)
 545                 self.alpha = self.owner.alpha;
 546         else
 547                 self.alpha = 1;
 548
 549         self.glowmod = self.owner.weaponentity_glowmod;
 550         self.colormap = self.owner.colormap;
 551         if (self.weaponentity)
 552         {
 553                 self.weaponentity.effects = self.effects;
 554                 self.weaponentity.alpha = self.alpha;
 555                 self.weaponentity.colormap = self.colormap;
 556                 self.weaponentity.glowmod = self.glowmod;
 557         }
 558
 559         self.angles = '0 0 0';
 560         float f;
 561         if (self.state == WS_RAISE && !intermission_running)
 562         {
 563                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 564                 self.angles_x = -90 * f * f;
 565         }
 566         else if (self.state == WS_DROP && !intermission_running)
 567         {
 568                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 569                 self.angles_x = -90 * f * f;
 570         }
 571         else if (self.state == WS_CLEAR)
 572         {
 573                 f = 1;
 574                 self.angles_x = -90 * f * f;
 575         }
 576 }
 577
 578 void CL_ExteriorWeaponentity_Think()
 579 {
 580         float tag_found;
 581         self.nextthink = time;
 582         if (self.owner.exteriorweaponentity != self)
 583         {
 584                 remove(self);
 585                 return;
 586         }
 587         if (self.owner.deadflag != DEAD_NO)
 588         {
 589                 self.model = "";
 590                 return;
 591         }
 592         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 593         {
 594                 self.weaponname = self.owner.weaponname;
 595                 self.dmg = self.owner.modelindex;
 596                 self.deadflag = self.owner.deadflag;
 597                 if (self.owner.weaponname != "")
 598                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 599                 else
 600                         self.model = "";
 601
 602                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 603                 {
 604                         self.tag_index = tag_found;
 605                         self.tag_entity = self.owner;
 606                 }
 607                 else
 608                         setattachment(self, self.owner, "bip01 r hand");
 609         }
 610         self.effects = self.owner.effects;
 611         self.effects |= EF_LOWPRECISION;
 612         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 613         if(self.owner.alpha == default_player_alpha)
 614                 self.alpha = default_weapon_alpha;
 615         else if(self.owner.alpha != 0)
 616                 self.alpha = self.owner.alpha;
 617         else
 618                 self.alpha = 1;
 619
 620         self.glowmod = self.owner.weaponentity_glowmod;
 621         self.colormap = self.owner.colormap;
 622
 623         CSQCMODEL_AUTOUPDATE();
 624 }
 625
 626 // spawning weaponentity for client
 627 void CL_SpawnWeaponentity()
 628 {
 629         self.weaponentity = spawn();
 630         self.weaponentity.classname = "weaponentity";
 631         self.weaponentity.solid = SOLID_NOT;
 632         self.weaponentity.owner = self;
 633         setmodel(self.weaponentity, ""); // precision set when changed
 634         setorigin(self.weaponentity, '0 0 0');
 635         self.weaponentity.angles = '0 0 0';
 636         self.weaponentity.viewmodelforclient = self;
 637         self.weaponentity.flags = 0;
 638         self.weaponentity.think = CL_Weaponentity_Think;
 639         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 640         self.weaponentity.nextthink = time;
 641
 642         self.exteriorweaponentity = spawn();
 643         self.exteriorweaponentity.classname = "exteriorweaponentity";
 644         self.exteriorweaponentity.solid = SOLID_NOT;
 645         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 646         self.exteriorweaponentity.owner = self;
 647         setorigin(self.exteriorweaponentity, '0 0 0');
 648         self.exteriorweaponentity.angles = '0 0 0';
 649         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 650         self.exteriorweaponentity.nextthink = time;
 651
 652         {
 653                 entity oldself = self;
 654                 self = self.exteriorweaponentity;
 655                 CSQCMODEL_AUTOINIT();
 656                 self = oldself;
 657         }
 658 }
 659
 660 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 661 {
 662         msg_entity = e;
 663         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 664         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 665         WriteByte(MSG_ONE, wpn);
 666         WriteString(MSG_ONE, wpnname);
 667         WriteByte(MSG_ONE, type);
 668 }
 669
 670 .float hasweapon_complain_spam;
 671
 672 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 673 {
 674         float f;
 675         entity oldself;
 676
 677         if(time < self.hasweapon_complain_spam)
 678                 complain = 0;
 679         if(complain)
 680                 self.hasweapon_complain_spam = time + 0.2;
 681
 682         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 683         {
 684                 if (complain)
 685                         sprint(self, "Invalid weapon\n");
 686                 return FALSE;
 687         }
 688         if (WEPSET_CONTAINS_EW(cl, wpn))
 689         {
 690                 if (andammo)
 691                 {
 692                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 693                         {
 694                                 f = 1;
 695                         }
 696                         else
 697                         {
 698                                 oldself = self;
 699                                 self = cl;
 700                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 701                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 702
 703                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 704                                 entity mine;
 705                                 if(wpn == WEP_MINE_LAYER)
 706                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 707                                         f = 1;
 708
 709                                 self = oldself;
 710                         }
 711                         if (!f)
 712                         {
 713                                 if (complain)
 714                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 715                                 {
 716                                         play2(cl, "weapons/unavailable.wav");
 717                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 718                                 }
 719                                 return FALSE;
 720                         }
 721                 }
 722                 return TRUE;
 723         }
 724         if (complain)
 725         {
 726                 // DRESK - 3/16/07
 727                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 728                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 729                 {
 730                         Send_WeaponComplain(cl, wpn, W_Name(wpn), 1);
 731
 732                         if(autocvar_g_showweaponspawns)
 733                         {
 734                                 entity e;
 735                                 string s;
 736
 737                                 e = get_weaponinfo(wpn);
 738                                 s = e.model2;
 739
 740                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 741                                 {
 742                                         if(e.classname == "droppedweapon")
 743                                                 continue;
 744                                         if not(e.flags & FL_ITEM)
 745                                                 continue;
 746                                         WaypointSprite_Spawn(
 747                                                 s,
 748                                                 1, 0,
 749                                                 world, e.origin,
 750                                                 self, 0,
 751                                                 world, enemy,
 752                                                 0,
 753                                                 RADARICON_NONE, '0 0 0'
 754                                         );
 755                                 }
 756                         }
 757                 }
 758                 else
 759                 {
 760                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 761                 }
 762
 763                 play2(cl, "weapons/unavailable.wav");
 764         }
 765         return FALSE;
 766 }
 767
 768 // Weapon subs
 769 void w_clear()
 770 {
 771         if (self.weapon != -1)
 772         {
 773                 self.weapon = 0;
 774                 self.switchingweapon = 0;
 775         }
 776         if (self.weaponentity)
 777         {
 778                 self.weaponentity.state = WS_CLEAR;
 779                 self.weaponentity.effects = 0;
 780         }
 781 }
 782
 783 void w_ready()
 784 {
 785         if (self.weaponentity)
 786                 self.weaponentity.state = WS_READY;
 787         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 788 }
 789
 790 // Setup weapon for client (after this raise frame will be launched)
 791 void weapon_setup(float windex)
 792 {
 793         entity e;
 794         e = get_weaponinfo(windex);
 795         self.items &~= IT_AMMO;
 796         self.items = self.items | (e.items & IT_AMMO);
 797
 798         // the two weapon entities will notice this has changed and update their models
 799         self.weapon = windex;
 800         self.switchingweapon = windex; // to make sure
 801         self.weaponname = e.mdl;
 802         self.bulletcounter = 0;
 803 }
 804
 805 // perform weapon to attack (weaponstate and attack_finished check is here)
 806 void W_SwitchToOtherWeapon(entity pl)
 807 {
 808         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 809         float w, ww;
 810         w = pl.weapon;
 811         if(WEPSET_CONTAINS_EW(pl, w))
 812         {
 813                 WEPSET_ANDNOT_EW(pl, w);
 814                 ww = w_getbestweapon(pl);
 815                 WEPSET_OR_EW(pl, w);
 816         }
 817         else
 818                 ww = w_getbestweapon(pl);
 819         if(ww)
 820                 W_SwitchWeapon_Force(pl, ww);
 821 }
 822
 823 .float prevdryfire;
 824 .float prevwarntime;
 825 float weapon_prepareattack_checkammo(float secondary)
 826 {
 827         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 828         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 829         {
 830                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 831                 entity mine;
 832                 if(self.weapon == WEP_MINE_LAYER)
 833                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 834                         return FALSE;
 835
 836                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 837                 {
 838                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 839                         self.prevdryfire = time;
 840                 }
 841
 842                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 843                 {
 844                         if(time - self.prevwarntime > 1)
 845                         {
 846                                 Send_Notification(
 847                                         NOTIF_ONE,
 848                                         self,
 849                                         MSG_MULTI,
 850                                         ITEM_WEAPON_PRIMORSEC,
 851                                         self.weapon,
 852                                         secondary,
 853                                         (1 - secondary)
 854                                 );
 855                         }
 856                         self.prevwarntime = time;
 857                 }
 858                 else // this weapon is totally unable to fire, switch to another one
 859                 {
 860                         W_SwitchToOtherWeapon(self);
 861                 }
 862
 863                 return FALSE;
 864         }
 865         return TRUE;
 866 }
 867 .float race_penalty;
 868 float weapon_prepareattack_check(float secondary, float attacktime)
 869 {
 870         if(!weapon_prepareattack_checkammo(secondary))
 871                 return FALSE;
 872
 873         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 874         //if all players readied up and the countdown is running
 875         if(time < game_starttime || time < self.race_penalty) {
 876                 return FALSE;
 877         }
 878
 879         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 880                 return FALSE;
 881
 882         // do not even think about shooting if switching
 883         if(self.switchweapon != self.weapon)
 884                 return FALSE;
 885
 886         if(attacktime >= 0)
 887         {
 888                 // don't fire if previous attack is not finished
 889                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 890                         return FALSE;
 891                 // don't fire while changing weapon
 892                 if (self.weaponentity.state != WS_READY)
 893                         return FALSE;
 894         }
 895
 896         return TRUE;
 897 }
 898 float weapon_prepareattack_do(float secondary, float attacktime)
 899 {
 900         self.weaponentity.state = WS_INUSE;
 901
 902         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 903
 904         // if the weapon hasn't been firing continuously, reset the timer
 905         if(attacktime >= 0)
 906         {
 907                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 908                 {
 909                         ATTACK_FINISHED(self) = time;
 910                         //dprint("resetting attack finished to ", ftos(time), "\n");
 911                 }
 912                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 913         }
 914         self.bulletcounter += 1;
 915         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 916         return TRUE;
 917 }
 918 float weapon_prepareattack(float secondary, float attacktime)
 919 {
 920         if(weapon_prepareattack_check(secondary, attacktime))
 921         {
 922                 weapon_prepareattack_do(secondary, attacktime);
 923                 return TRUE;
 924         }
 925         else
 926                 return FALSE;
 927 }
 928
 929 void weapon_thinkf(float fr, float t, void() func)
 930 {
 931         vector a;
 932         vector of, or, ou;
 933         float restartanim;
 934
 935         if(fr == WFRAME_DONTCHANGE)
 936         {
 937                 fr = self.weaponentity.wframe;
 938                 restartanim = FALSE;
 939         }
 940         else if (fr == WFRAME_IDLE)
 941                 restartanim = FALSE;
 942         else
 943                 restartanim = TRUE;
 944
 945         of = v_forward;
 946         or = v_right;
 947         ou = v_up;
 948
 949         if (self.weaponentity)
 950         {
 951                 self.weaponentity.wframe = fr;
 952                 a = '0 0 0';
 953                 if (fr == WFRAME_IDLE)
 954                         a = self.weaponentity.anim_idle;
 955                 else if (fr == WFRAME_FIRE1)
 956                         a = self.weaponentity.anim_fire1;
 957                 else if (fr == WFRAME_FIRE2)
 958                         a = self.weaponentity.anim_fire2;
 959                 else // if (fr == WFRAME_RELOAD)
 960                         a = self.weaponentity.anim_reload;
 961                 a_z *= g_weaponratefactor;
 962                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 963         }
 964
 965         v_forward = of;
 966         v_right = or;
 967         v_up = ou;
 968
 969         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 970         {
 971                 backtrace("Tried to override initial weapon think function - should this really happen?");
 972         }
 973
 974         t *= W_WeaponRateFactor();
 975
 976         // VorteX: haste can be added here
 977         if (self.weapon_think == w_ready)
 978         {
 979                 self.weapon_nextthink = time;
 980                 //dprint("started firing at ", ftos(time), "\n");
 981         }
 982         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
 983         {
 984                 self.weapon_nextthink = time;
 985                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 986         }
 987         self.weapon_nextthink = self.weapon_nextthink + t;
 988         self.weapon_think = func;
 989         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 990
 991         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 992         {
 993                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
 994                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
 995                 else
 996                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
 997         }
 998         else
 999         {
1000                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
1001                         self.anim_upper_action = 0;
1002         }
1003 }
1004
1005 void weapon_boblayer1(float spd, vector org)
1006 {
1007         // VorteX: haste can be added here
1008 }
1009
1010 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1011 {
1012         vector mdirection;
1013         float mspeed;
1014         vector outvelocity;
1015
1016         mvelocity = mvelocity * g_weaponspeedfactor;
1017
1018         mdirection = normalize(mvelocity);
1019         mspeed = vlen(mvelocity);
1020
1021         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1022
1023         return outvelocity;
1024 }
1025
1026 void W_AttachToShotorg(entity flash, vector offset)
1027 {
1028         entity xflash;
1029         flash.owner = self;
1030         flash.angles_z = random() * 360;
1031
1032         if(gettagindex(self.weaponentity, "shot"))
1033                 setattachment(flash, self.weaponentity, "shot");
1034         else
1035                 setattachment(flash, self.weaponentity, "tag_shot");
1036         setorigin(flash, offset);
1037
1038         xflash = spawn();
1039         copyentity(flash, xflash);
1040
1041         flash.viewmodelforclient = self;
1042
1043         if(self.weaponentity.oldorigin_x > 0)
1044         {
1045                 setattachment(xflash, self.exteriorweaponentity, "");
1046                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1047         }
1048         else
1049         {
1050                 if(gettagindex(self.exteriorweaponentity, "shot"))
1051                         setattachment(xflash, self.exteriorweaponentity, "shot");
1052                 else
1053                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1054                 setorigin(xflash, offset);
1055         }
1056 }
1057
1058 vector cliptoplane(vector v, vector p)
1059 {
1060         return v - (v * p) * p;
1061 }
1062
1063 vector solve_cubic_pq(float p, float q)
1064 {
1065         float D, u, v, a;
1066         D = q*q/4.0 + p*p*p/27.0;
1067         if(D < 0)
1068         {
1069                 // irreducibilis
1070                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1071                 u = sqrt(-4.0/3.0 * p);
1072                 // a in range 0..pi/3
1073                 // cos(a)
1074                 // cos(a + 2pi/3)
1075                 // cos(a + 4pi/3)
1076                 return
1077                         u *
1078                         (
1079                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1080                                 +
1081                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1082                                 +
1083                                 '0 0 1' * cos(a)
1084                         );
1085         }
1086         else if(D == 0)
1087         {
1088                 // simple
1089                 if(p == 0)
1090                         return '0 0 0';
1091                 u = 3*q/p;
1092                 v = -u/2;
1093                 if(u >= v)
1094                         return '1 1 0' * v + '0 0 1' * u;
1095                 else
1096                         return '0 1 1' * v + '1 0 0' * u;
1097         }
1098         else
1099         {
1100                 // cardano
1101                 u = cbrt(-q/2.0 + sqrt(D));
1102                 v = cbrt(-q/2.0 - sqrt(D));
1103                 return '1 1 1' * (u + v);
1104         }
1105 }
1106 vector solve_cubic_abcd(float a, float b, float c, float d)
1107 {
1108         // y = 3*a*x + b
1109         // x = (y - b) / 3a
1110         float p, q;
1111         vector v;
1112         p = (9*a*c - 3*b*b);
1113         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1114         v = solve_cubic_pq(p, q);
1115         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1116         if(a < 0)
1117                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1118         return v;
1119 }
1120
1121 vector findperpendicular(vector v)
1122 {
1123         vector p;
1124         p_x = v_z;
1125         p_y = -v_x;
1126         p_z = v_y;
1127         return normalize(cliptoplane(p, v));
1128 }
1129
1130 vector W_CalculateProjectileSpread(vector forward, float spread)
1131 {
1132         float sigma;
1133         vector v1 = '0 0 0', v2;
1134         float dx, dy, r;
1135         float sstyle;
1136         spread *= g_weaponspreadfactor;
1137         if(spread <= 0)
1138                 return forward;
1139         sstyle = autocvar_g_projectiles_spread_style;
1140
1141         if(sstyle == 0)
1142         {
1143                 // this is the baseline for the spread value!
1144                 // standard deviation: sqrt(2/5)
1145                 // density function: sqrt(1-r^2)
1146                 return forward + randomvec() * spread;
1147         }
1148         else if(sstyle == 1)
1149         {
1150                 // same thing, basically
1151                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1152         }
1153         else if(sstyle == 2)
1154         {
1155                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1156                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1157                 v1 = findperpendicular(forward);
1158                 v2 = cross(forward, v1);
1159                 // random point on unit circle
1160                 dx = random() * 2 * M_PI;
1161                 dy = sin(dx);
1162                 dx = cos(dx);
1163                 // radius in our dist function
1164                 r = random();
1165                 r = sqrt(r);
1166                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1167         }
1168         else if(sstyle == 3) // gauss 3d
1169         {
1170                 sigma = spread * 0.44721359549996; // match baseline stddev
1171                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1172                 v1 = forward;
1173                 v1_x += gsl_ran_gaussian(sigma);
1174                 v1_y += gsl_ran_gaussian(sigma);
1175                 v1_z += gsl_ran_gaussian(sigma);
1176                 return v1;
1177         }
1178         else if(sstyle == 4) // gauss 2d
1179         {
1180                 sigma = spread * 0.44721359549996; // match baseline stddev
1181                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1182                 v1_x = gsl_ran_gaussian(sigma);
1183                 v1_y = gsl_ran_gaussian(sigma);
1184                 v1_z = gsl_ran_gaussian(sigma);
1185                 return normalize(forward + cliptoplane(v1, forward));
1186         }
1187         else if(sstyle == 5) // 1-r
1188         {
1189                 sigma = spread * 1.154700538379252; // match baseline stddev
1190                 v1 = findperpendicular(forward);
1191                 v2 = cross(forward, v1);
1192                 // random point on unit circle
1193                 dx = random() * 2 * M_PI;
1194                 dy = sin(dx);
1195                 dx = cos(dx);
1196                 // radius in our dist function
1197                 r = random();
1198                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1199                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1200         }
1201         else if(sstyle == 6) // 1-r^2
1202         {
1203                 sigma = spread * 1.095445115010332; // match baseline stddev
1204                 v1 = findperpendicular(forward);
1205                 v2 = cross(forward, v1);
1206                 // random point on unit circle
1207                 dx = random() * 2 * M_PI;
1208                 dy = sin(dx);
1209                 dx = cos(dx);
1210                 // radius in our dist function
1211                 r = random();
1212                 r = sqrt(1 - r);
1213                 r = sqrt(1 - r);
1214                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1215         }
1216         else if(sstyle == 7) // (1-r) (2-r)
1217         {
1218                 sigma = spread * 1.224744871391589; // match baseline stddev
1219                 v1 = findperpendicular(forward);
1220                 v2 = cross(forward, v1);
1221                 // random point on unit circle
1222                 dx = random() * 2 * M_PI;
1223                 dy = sin(dx);
1224                 dx = cos(dx);
1225                 // radius in our dist function
1226                 r = random();
1227                 r = 1 - sqrt(r);
1228                 r = 1 - sqrt(r);
1229                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1230         }
1231         else
1232                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1233         return '0 0 0';
1234         /*
1235          * how to derive falloff functions:
1236          * rho(r) := (2-r) * (1-r);
1237          * a : 0;
1238          * b : 1;
1239          * rhor(r) := r * rho(r);
1240          * cr(t) := integrate(rhor(r), r, a, t);
1241          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1242          * variance : scr(b) / cr(b);
1243          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1244          * sqrt(0.4 / variance), numer;
1245          */
1246 }
1247
1248 #if 0
1249 float mspercallsum;
1250 float mspercallsstyle;
1251 float mspercallcount;
1252 #endif
1253 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1254 {
1255         if(missile.owner == world)
1256                 error("Unowned missile");
1257
1258         dir = dir + upDir * (pUpSpeed / pSpeed);
1259         dir_z += pZSpeed / pSpeed;
1260         pSpeed *= vlen(dir);
1261         dir = normalize(dir);
1262
1263 #if 0
1264         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1265         {
1266                 mspercallsum = mspercallcount = 0;
1267                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1268         }
1269         mspercallsum -= gettime(GETTIME_HIRES);
1270 #endif
1271         dir = W_CalculateProjectileSpread(dir, spread);
1272 #if 0
1273         mspercallsum += gettime(GETTIME_HIRES);
1274         mspercallcount += 1;
1275         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1276 #endif
1277
1278         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1279 }
1280
1281 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1282 {
1283         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1284 }
1285
1286 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1287 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1288
1289 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1290 {
1291         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1292                 return;
1293
1294         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1295         if(ammo_reload)
1296         {
1297                 self.clip_load -= ammo_use;
1298                 self.(weapon_load[self.weapon]) = self.clip_load;
1299         }
1300         else
1301                 self.(self.current_ammo) -= ammo_use;
1302 }
1303
1304 // weapon reloading code
1305
1306 .float reload_ammo_amount, reload_ammo_min, reload_time;
1307 .float reload_complain;
1308 .string reload_sound;
1309
1310 void W_ReloadedAndReady()
1311 {
1312         // finish the reloading process, and do the ammo transfer
1313
1314         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1315
1316         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1317         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1318                 self.clip_load = self.reload_ammo_amount;
1319         else
1320         {
1321                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1322                 {
1323                         self.clip_load += 1;
1324                         self.(self.current_ammo) -= 1;
1325                 }
1326         }
1327         self.(weapon_load[self.weapon]) = self.clip_load;
1328
1329         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1330         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1331         // so your weapon is disabled for a few seconds without reason
1332
1333         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1334
1335         w_ready();
1336 }
1337
1338 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1339 {
1340         // set global values to work with
1341
1342         self.reload_ammo_min = sent_ammo_min;
1343         self.reload_ammo_amount = sent_ammo_amount;
1344         self.reload_time = sent_time;
1345         self.reload_sound = sent_sound;
1346
1347         // check if we meet the necessary conditions to reload
1348
1349         entity e;
1350         e = get_weaponinfo(self.weapon);
1351
1352         // don't reload weapons that don't have the RELOADABLE flag
1353         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1354         {
1355                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1356                 return;
1357         }
1358
1359         // return if reloading is disabled for this weapon
1360         if(!self.reload_ammo_amount)
1361                 return;
1362
1363         // our weapon is fully loaded, no need to reload
1364         if (self.clip_load >= self.reload_ammo_amount)
1365                 return;
1366
1367         // no ammo, so nothing to load
1368         if(!self.(self.current_ammo) && self.reload_ammo_min)
1369         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1370         {
1371                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1372                 {
1373                         play2(self, "weapons/unavailable.wav");
1374                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1375                         self.reload_complain = time + 1;
1376                 }
1377                 // switch away if the amount of ammo is not enough to keep using this weapon
1378                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1379                 {
1380                         self.clip_load = -1; // reload later
1381                         W_SwitchToOtherWeapon(self);
1382                 }
1383                 return;
1384         }
1385
1386         if (self.weaponentity)
1387         {
1388                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1389                         return;
1390
1391                 // allow switching away while reloading, but this will cause a new reload!
1392                 self.weaponentity.state = WS_READY;
1393         }
1394
1395         // now begin the reloading process
1396
1397         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1398
1399         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1400         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1401         // so your weapon is disabled for a few seconds without reason
1402
1403         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1404
1405         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1406
1407         if(self.clip_load < 0)
1408                 self.clip_load = 0;
1409         self.old_clip_load = self.clip_load;
1410         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1411 }