Merge branch 'master' into Lyberta/TeamplayOverhaul
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "playerdemo.qh"
14 #include "spawnpoints.qh"
15 #include "resources.qh"
16 #include "g_damage.qh"
17 #include "handicap.qh"
18 #include "g_hook.qh"
19 #include "command/common.qh"
20 #include "cheats.qh"
21 #include "g_world.qh"
22 #include "race.qh"
23 #include "antilag.qh"
24 #include "campaign.qh"
25 #include "command/common.qh"
26 #include "scores_rules.qh"
27
28 #include "bot/api.qh"
29
30 #include "../common/ent_cs.qh"
31 #include "../common/wepent.qh"
32 #include <common/state.qh>
33
34 #include <common/effects/qc/globalsound.qh>
35
36 #include "../common/triggers/func/conveyor.qh"
37 #include "../common/triggers/teleporters.qh"
38 #include "../common/triggers/target/spawnpoint.qh"
39
40 #include "../common/vehicles/all.qh"
41
42 #include "weapons/hitplot.qh"
43 #include "weapons/weaponsystem.qh"
44
45 #include "../common/net_notice.qh"
46 #include "../common/net_linked.qh"
47 #include "../common/physics/player.qh"
48
49 #include "../common/items/_mod.qh"
50
51 #include "../common/mutators/mutator/waypoints/all.qh"
52 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
53
54 #include "../common/triggers/subs.qh"
55 #include "../common/triggers/triggers.qh"
56 #include "../common/triggers/trigger/secret.qh"
57
58 #include "../common/minigames/sv_minigames.qh"
59
60 #include "../common/items/inventory.qh"
61
62 #include "../common/monsters/sv_monsters.qh"
63
64 #include "../lib/warpzone/server.qh"
65
66 #include <common/mutators/mutator/overkill/oknex.qh>
67
68 STATIC_METHOD(Client, Add, void(Client this, int _team))
69 {
70     ClientConnect(this);
71     TRANSMUTE(Player, this);
72     this.frame = 12; // 7
73     this.team = _team;
74     PutClientInServer(this);
75 }
76
77 void PutObserverInServer(entity this);
78
79 STATIC_METHOD(Client, Remove, void(Client this))
80 {
81     TRANSMUTE(Observer, this);
82     PutClientInServer(this);
83     ClientDisconnect(this);
84 }
85
86 void send_CSQC_teamnagger() {
87         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
88 }
89
90 int CountSpectators(entity player, entity to)
91 {
92         if(!player) { return 0; } // not sure how, but best to be safe
93
94         int spec_count = 0;
95
96         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
97         {
98                 spec_count++;
99         });
100
101         return spec_count;
102 }
103
104 void WriteSpectators(entity player, entity to)
105 {
106         if(!player) { return; } // not sure how, but best to be safe
107
108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
109         {
110                 WriteByte(MSG_ENTITY, num_for_edict(it));
111         });
112 }
113
114 bool ClientData_Send(entity this, entity to, int sf)
115 {
116         assert(to == this.owner, return false);
117
118         entity e = to;
119         if (IS_SPEC(e)) e = e.enemy;
120
121         sf = 0;
122         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
123         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
124         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
125         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
126
127         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
128         WriteByte(MSG_ENTITY, sf);
129
130         if (sf & BIT(1))
131                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
132
133         if(sf & BIT(4))
134         {
135                 float specs = CountSpectators(e, to);
136                 WriteByte(MSG_ENTITY, specs);
137                 WriteSpectators(e, to);
138         }
139
140         return true;
141 }
142
143 void ClientData_Attach(entity this)
144 {
145         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
146         CS(this).clientdata.drawonlytoclient = this;
147         CS(this).clientdata.owner = this;
148 }
149
150 void ClientData_Detach(entity this)
151 {
152         delete(CS(this).clientdata);
153         CS(this).clientdata = NULL;
154 }
155
156 void ClientData_Touch(entity e)
157 {
158         entity cd = CS(e).clientdata;
159         if (cd) { cd.SendFlags = 1; }
160
161         // make it spectatable
162         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
163         {
164                 entity cd = CS(it).clientdata;
165                 if (cd) { cd.SendFlags = 1; }
166         });
167 }
168
169 void SetSpectatee(entity this, entity spectatee);
170 void SetSpectatee_status(entity this, int spectatee_num);
171
172
173 /*
174 =============
175 CheckPlayerModel
176
177 Checks if the argument string can be a valid playermodel.
178 Returns a valid one in doubt.
179 =============
180 */
181 string FallbackPlayerModel;
182 string CheckPlayerModel(string plyermodel) {
183         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
184         {
185                 // note: we cannot summon Don Strunzone here, some player may
186                 // still have the model string set. In case anyone manages how
187                 // to change a cvar default, we'll have a small leak here.
188                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
189         }
190         // only in right path
191         if( substring(plyermodel,0,14) != "models/player/")
192                 return FallbackPlayerModel;
193         // only good file extensions
194         if(substring(plyermodel,-4,4) != ".zym")
195         if(substring(plyermodel,-4,4) != ".dpm")
196         if(substring(plyermodel,-4,4) != ".iqm")
197         if(substring(plyermodel,-4,4) != ".md3")
198         if(substring(plyermodel,-4,4) != ".psk")
199                 return FallbackPlayerModel;
200         // forbid the LOD models
201         if(substring(plyermodel, -9,5) == "_lod1")
202                 return FallbackPlayerModel;
203         if(substring(plyermodel, -9,5) == "_lod2")
204                 return FallbackPlayerModel;
205         if(plyermodel != strtolower(plyermodel))
206                 return FallbackPlayerModel;
207         // also, restrict to server models
208         if(autocvar_sv_servermodelsonly)
209         {
210                 if(!fexists(plyermodel))
211                         return FallbackPlayerModel;
212         }
213         return plyermodel;
214 }
215
216 void setplayermodel(entity e, string modelname)
217 {
218         precache_model(modelname);
219         _setmodel(e, modelname);
220         player_setupanimsformodel(e);
221         if(!autocvar_g_debug_globalsounds)
222                 UpdatePlayerSounds(e);
223 }
224
225 void FixPlayermodel(entity player);
226 /** putting a client as observer in the server */
227 void PutObserverInServer(entity this)
228 {
229     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
230         PlayerState_detach(this);
231
232         if (IS_PLAYER(this))
233         {
234                 if(this.health >= 1)
235                 {
236                         // despawn effect
237                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
238                 }
239
240                 // was a player, recount votes and ready status
241                 if(IS_REAL_CLIENT(this))
242                 {
243                         if (vote_called) { VoteCount(false); }
244                         ReadyCount();
245                 }
246     }
247
248     {
249         entity spot = SelectSpawnPoint(this, true);
250         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
251         this.angles = vec2(spot.angles);
252         this.fixangle = true;
253         // offset it so that the spectator spawns higher off the ground, looks better this way
254         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
255         if (IS_REAL_CLIENT(this))
256         {
257             msg_entity = this;
258             WriteByte(MSG_ONE, SVC_SETVIEW);
259             WriteEntity(MSG_ONE, this);
260         }
261         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
262         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
263         if(!autocvar_g_debug_globalsounds)
264         {
265                 // needed for player sounds
266                 this.model = "";
267                 FixPlayermodel(this);
268         }
269         setmodel(this, MDL_Null);
270         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
271         this.view_ofs = '0 0 0';
272     }
273
274     RemoveGrapplingHooks(this);
275         Portal_ClearAll(this);
276         Unfreeze(this);
277         SetSpectatee(this, NULL);
278
279         if (this.alivetime)
280         {
281                 if (!warmup_stage)
282                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
283                 this.alivetime = 0;
284         }
285
286         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
287
288         WaypointSprite_PlayerDead(this);
289
290         if (mutator_returnvalue) {
291             // mutator prevents resetting teams+score
292         } else {
293                 Player_SetTeamIndex(this, -1);
294                 this.frags = FRAGS_SPECTATOR;
295         PlayerScore_Clear(this);  // clear scores when needed
296     }
297
298         if (CS(this).killcount != FRAGS_SPECTATOR)
299         {
300                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
301                 if(!game_stopped)
302                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
303                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
304
305                 if(!CS(this).just_joined)
306                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
307                 else
308                         CS(this).just_joined = false;
309         }
310
311         accuracy_resend(this);
312
313         CS(this).spectatortime = time;
314         if(this.bot_attack)
315                 IL_REMOVE(g_bot_targets, this);
316         this.bot_attack = false;
317         if(this.monster_attack)
318                 IL_REMOVE(g_monster_targets, this);
319         this.monster_attack = false;
320     STAT(HUD, this) = HUD_NORMAL;
321         TRANSMUTE(Observer, this);
322         this.iscreature = false;
323         this.teleportable = TELEPORT_SIMPLE;
324         if(this.damagedbycontents)
325                 IL_REMOVE(g_damagedbycontents, this);
326         this.damagedbycontents = false;
327         this.health = FRAGS_SPECTATOR;
328         SetSpectatee_status(this, etof(this));
329         this.takedamage = DAMAGE_NO;
330         this.solid = SOLID_NOT;
331         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
332         this.flags = FL_CLIENT | FL_NOTARGET;
333         this.armorvalue = 666;
334         this.effects = 0;
335         this.armorvalue = autocvar_g_balance_armor_start;
336         this.pauserotarmor_finished = 0;
337         this.pauserothealth_finished = 0;
338         this.pauseregen_finished = 0;
339         this.damageforcescale = 0;
340         this.death_time = 0;
341         this.respawn_flags = 0;
342         this.respawn_time = 0;
343         STAT(RESPAWN_TIME, this) = 0;
344         this.alpha = 0;
345         this.scale = 0;
346         this.fade_time = 0;
347         this.pain_frame = 0;
348         this.pain_finished = 0;
349         this.strength_finished = 0;
350         this.invincible_finished = 0;
351         this.superweapons_finished = 0;
352         this.dphitcontentsmask = 0;
353         this.pushltime = 0;
354         this.istypefrag = 0;
355         setthink(this, func_null);
356         this.nextthink = 0;
357         this.deadflag = DEAD_NO;
358         this.crouch = false;
359         STAT(REVIVE_PROGRESS, this) = 0;
360         this.revival_time = 0;
361
362         this.items = 0;
363         STAT(WEAPONS, this) = '0 0 0';
364         this.drawonlytoclient = this;
365
366         this.viewloc = NULL;
367
368         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
369
370         this.weaponmodel = "";
371         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
372         {
373                 this.weaponentities[slot] = NULL;
374         }
375         this.exteriorweaponentity = NULL;
376         CS(this).killcount = FRAGS_SPECTATOR;
377         this.velocity = '0 0 0';
378         this.avelocity = '0 0 0';
379         this.punchangle = '0 0 0';
380         this.punchvector = '0 0 0';
381         this.oldvelocity = this.velocity;
382         this.fire_endtime = -1;
383         this.event_damage = func_null;
384
385         for(int slot = 0; slot < MAX_AXH; ++slot)
386         {
387                 entity axh = this.(AuxiliaryXhair[slot]);
388                 this.(AuxiliaryXhair[slot]) = NULL;
389
390                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
391                         delete(axh);
392         }
393 }
394
395 int player_getspecies(entity this)
396 {
397         get_model_parameters(this.model, this.skin);
398         int s = get_model_parameters_species;
399         get_model_parameters(string_null, 0);
400         if (s < 0) return SPECIES_HUMAN;
401         return s;
402 }
403
404 .float model_randomizer;
405 void FixPlayermodel(entity player)
406 {
407         string defaultmodel = "";
408         int defaultskin = 0;
409         if(autocvar_sv_defaultcharacter)
410         {
411                 if(teamplay)
412                 {
413                         switch(player.team)
414                         {
415                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
416                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
417                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
418                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
419                         }
420                 }
421
422                 if(defaultmodel == "")
423                 {
424                         defaultmodel = autocvar_sv_defaultplayermodel;
425                         defaultskin = autocvar_sv_defaultplayerskin;
426                 }
427
428                 int n = tokenize_console(defaultmodel);
429                 if(n > 0)
430                 {
431                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
432                         // However, do NOT randomize if the player-selected model is in the list.
433                         for (int i = 0; i < n; ++i)
434                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
435                                         defaultmodel = argv(i);
436                 }
437
438                 int i = strstrofs(defaultmodel, ":", 0);
439                 if(i >= 0)
440                 {
441                         defaultskin = stof(substring(defaultmodel, i+1, -1));
442                         defaultmodel = substring(defaultmodel, 0, i);
443                 }
444         }
445         if(autocvar_sv_defaultcharacterskin && !defaultskin)
446         {
447                 if(teamplay)
448                 {
449                         switch(player.team)
450                         {
451                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
452                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
453                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
454                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
455                         }
456                 }
457
458                 if(!defaultskin)
459                         defaultskin = autocvar_sv_defaultplayerskin;
460         }
461
462         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
463         defaultmodel = M_ARGV(0, string);
464         defaultskin = M_ARGV(1, int);
465
466         bool chmdl = false;
467         int oldskin;
468         if(defaultmodel != "")
469         {
470                 if (defaultmodel != player.model)
471                 {
472                         vector m1 = player.mins;
473                         vector m2 = player.maxs;
474                         setplayermodel (player, defaultmodel);
475                         setsize (player, m1, m2);
476                         chmdl = true;
477                 }
478
479                 oldskin = player.skin;
480                 player.skin = defaultskin;
481         } else {
482                 if (player.playermodel != player.model || player.playermodel == "")
483                 {
484                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
485                         vector m1 = player.mins;
486                         vector m2 = player.maxs;
487                         setplayermodel (player, player.playermodel);
488                         setsize (player, m1, m2);
489                         chmdl = true;
490                 }
491
492                 if(!autocvar_sv_defaultcharacterskin)
493                 {
494                         oldskin = player.skin;
495                         player.skin = stof(player.playerskin);
496                 }
497                 else
498                 {
499                         oldskin = player.skin;
500                         player.skin = defaultskin;
501                 }
502         }
503
504         if(chmdl || oldskin != player.skin) // model or skin has changed
505         {
506                 player.species = player_getspecies(player); // update species
507                 if(!autocvar_g_debug_globalsounds)
508                         UpdatePlayerSounds(player); // update skin sounds
509         }
510
511         if(!teamplay)
512                 if(strlen(autocvar_sv_defaultplayercolors))
513                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
514                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
515 }
516
517 void PutPlayerInServer(entity this)
518 {
519         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
520
521         PlayerState_attach(this);
522         accuracy_resend(this);
523
524         if (this.team < 0)
525                 TeamBalance_JoinBestTeam(this, true);
526
527         entity spot = SelectSpawnPoint(this, false);
528         if (!spot) {
529                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
530                 return; // spawn failed
531         }
532
533         TRANSMUTE(Player, this);
534
535         CS(this).wasplayer = true;
536         this.iscreature = true;
537         this.teleportable = TELEPORT_NORMAL;
538         if(!this.damagedbycontents)
539                 IL_PUSH(g_damagedbycontents, this);
540         this.damagedbycontents = true;
541         set_movetype(this, MOVETYPE_WALK);
542         this.solid = SOLID_SLIDEBOX;
543         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
544         if (autocvar_g_playerclip_collisions)
545                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
546         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
547                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
548         this.frags = FRAGS_PLAYER;
549         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
550         this.flags = FL_CLIENT | FL_PICKUPITEMS;
551         if (autocvar__notarget)
552                 this.flags |= FL_NOTARGET;
553         this.takedamage = DAMAGE_AIM;
554         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
555
556         if (warmup_stage) {
557                 this.ammo_shells = warmup_start_ammo_shells;
558                 this.ammo_nails = warmup_start_ammo_nails;
559                 this.ammo_rockets = warmup_start_ammo_rockets;
560                 this.ammo_cells = warmup_start_ammo_cells;
561                 this.ammo_plasma = warmup_start_ammo_plasma;
562                 this.ammo_fuel = warmup_start_ammo_fuel;
563                 this.health = warmup_start_health;
564                 this.armorvalue = warmup_start_armorvalue;
565                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
566         } else {
567                 this.ammo_shells = start_ammo_shells;
568                 this.ammo_nails = start_ammo_nails;
569                 this.ammo_rockets = start_ammo_rockets;
570                 this.ammo_cells = start_ammo_cells;
571                 this.ammo_plasma = start_ammo_plasma;
572                 this.ammo_fuel = start_ammo_fuel;
573                 this.health = start_health;
574                 this.armorvalue = start_armorvalue;
575                 STAT(WEAPONS, this) = start_weapons;
576                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
577                 {
578                         GiveRandomWeapons(this, random_start_weapons_count,
579                                 autocvar_g_random_start_weapons, random_start_ammo);
580                 }
581         }
582         SetSpectatee_status(this, 0);
583
584         PS(this).dual_weapons = '0 0 0';
585
586         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
587
588         this.items = start_items;
589
590         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
591         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
592         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
593         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
594         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
595         if (!sv_ready_restart_after_countdown && time < game_starttime)
596         {
597                 float f = game_starttime - time;
598                 this.spawnshieldtime += f;
599                 this.pauserotarmor_finished += f;
600                 this.pauserothealth_finished += f;
601                 this.pauseregen_finished += f;
602         }
603
604         this.damageforcescale = 2;
605         this.death_time = 0;
606         this.respawn_flags = 0;
607         this.respawn_time = 0;
608         STAT(RESPAWN_TIME, this) = 0;
609         this.scale = autocvar_sv_player_scale;
610         this.fade_time = 0;
611         this.pain_frame = 0;
612         this.pain_finished = 0;
613         this.pushltime = 0;
614         setthink(this, func_null); // players have no think function
615         this.nextthink = 0;
616         this.dmg_team = 0;
617         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
618
619         this.deadflag = DEAD_NO;
620
621         this.angles = spot.angles;
622         this.angles_z = 0; // never spawn tilted even if the spot says to
623         if (IS_BOT_CLIENT(this))
624                 this.v_angle = this.angles;
625         this.fixangle = true; // turn this way immediately
626         this.oldvelocity = this.velocity = '0 0 0';
627         this.avelocity = '0 0 0';
628         this.punchangle = '0 0 0';
629         this.punchvector = '0 0 0';
630
631         this.strength_finished = 0;
632         this.invincible_finished = 0;
633         this.fire_endtime = -1;
634         STAT(REVIVE_PROGRESS, this) = 0;
635         this.revival_time = 0;
636
637         this.air_finished = time + 12;
638         this.waterlevel = WATERLEVEL_NONE;
639         this.watertype = CONTENT_EMPTY;
640
641         entity spawnevent = new_pure(spawnevent);
642         spawnevent.owner = this;
643         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
644
645         // Cut off any still running player sounds.
646         stopsound(this, CH_PLAYER_SINGLE);
647
648         this.model = "";
649         FixPlayermodel(this);
650         this.drawonlytoclient = NULL;
651
652         this.viewloc = NULL;
653
654         for(int slot = 0; slot < MAX_AXH; ++slot)
655         {
656                 entity axh = this.(AuxiliaryXhair[slot]);
657                 this.(AuxiliaryXhair[slot]) = NULL;
658
659                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
660                         delete(axh);
661         }
662
663         this.spawnpoint_targ = NULL;
664
665         this.crouch = false;
666         this.view_ofs = STAT(PL_VIEW_OFS, this);
667         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
668         this.spawnorigin = spot.origin;
669         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
670         // don't reset back to last position, even if new position is stuck in solid
671         this.oldorigin = this.origin;
672         if(this.conveyor)
673                 IL_REMOVE(g_conveyed, this);
674         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
675         STAT(HUD, this) = HUD_NORMAL;
676
677         this.event_damage = PlayerDamage;
678
679         if(!this.bot_attack)
680                 IL_PUSH(g_bot_targets, this);
681         this.bot_attack = true;
682         if(!this.monster_attack)
683                 IL_PUSH(g_monster_targets, this);
684         this.monster_attack = true;
685         navigation_dynamicgoal_init(this, false);
686
687         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
688
689         // player was spectator
690         if (CS(this).killcount == FRAGS_SPECTATOR) {
691                 PlayerScore_Clear(this);
692                 CS(this).killcount = 0;
693                 CS(this).startplaytime = time;
694         }
695
696         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
697         {
698                 .entity weaponentity = weaponentities[slot];
699                 entity oldwep = this.(weaponentity);
700                 CL_SpawnWeaponentity(this, weaponentity);
701                 if(oldwep && oldwep.owner == this)
702                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
703         }
704         this.alpha = default_player_alpha;
705         this.colormod = '1 1 1' * autocvar_g_player_brightness;
706         this.exteriorweaponentity.alpha = default_weapon_alpha;
707
708         this.speedrunning = false;
709
710         target_voicescript_clear(this);
711
712         // reset fields the weapons may use
713         FOREACH(Weapons, true, {
714                 it.wr_resetplayer(it, this);
715                         // reload all reloadable weapons
716                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
717                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
718                         {
719                                 .entity weaponentity = weaponentities[slot];
720                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
721                         }
722                 }
723         });
724
725         {
726                 string s = spot.target;
727                 spot.target = string_null;
728                 SUB_UseTargets(spot, this, NULL);
729                 spot.target = s;
730         }
731
732         Unfreeze(this);
733
734         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
735
736         if (autocvar_spawn_debug)
737         {
738                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
739                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
740         }
741
742         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
743         {
744                 .entity weaponentity = weaponentities[slot];
745                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
746                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
747                 else
748                         this.(weaponentity).m_switchweapon = WEP_Null;
749                 this.(weaponentity).m_weapon = WEP_Null;
750                 this.(weaponentity).weaponname = "";
751                 this.(weaponentity).m_switchingweapon = WEP_Null;
752                 this.(weaponentity).cnt = -1;
753         }
754
755         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
756
757         if (!warmup_stage && !this.alivetime)
758                 this.alivetime = time;
759
760         antilag_clear(this, CS(this));
761 }
762
763 /** Called when a client spawns in the server */
764 void PutClientInServer(entity this)
765 {
766         if (IS_BOT_CLIENT(this)) {
767                 TRANSMUTE(Player, this);
768         } else if (IS_REAL_CLIENT(this)) {
769                 msg_entity = this;
770                 WriteByte(MSG_ONE, SVC_SETVIEW);
771                 WriteEntity(MSG_ONE, this);
772         }
773         if (game_stopped)
774                 TRANSMUTE(Observer, this);
775
776         SetSpectatee(this, NULL);
777
778         // reset player keys
779         if(PS(this))
780                 PS(this).itemkeys = 0;
781
782         MUTATOR_CALLHOOK(PutClientInServer, this);
783
784         if (IS_OBSERVER(this)) {
785                 PutObserverInServer(this);
786         } else if (IS_PLAYER(this)) {
787                 PutPlayerInServer(this);
788         }
789 }
790
791 void ClientInit_misc(entity this);
792
793 // TODO do we need all these fields, or should we stop autodetecting runtime
794 // changes and just have a console command to update this?
795 bool ClientInit_SendEntity(entity this, entity to, int sf)
796 {
797         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
798         return = true;
799         msg_entity = to;
800         // MSG_INIT replacement
801         // TODO: make easier to use
802         Registry_send_all();
803         W_PROP_reload(MSG_ONE, to);
804         ClientInit_misc(this);
805         MUTATOR_CALLHOOK(Ent_Init);
806 }
807 void ClientInit_misc(entity this)
808 {
809         int channel = MSG_ONE;
810         WriteHeader(channel, ENT_CLIENT_INIT);
811         WriteByte(channel, g_nexball_meter_period * 32);
812         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
813         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
814         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
815         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
816         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
817         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
818         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
819         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
820
821         if(sv_foginterval && world.fog != "")
822                 WriteString(channel, world.fog);
823         else
824                 WriteString(channel, "");
825         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
826         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
827         WriteByte(channel, serverflags);
828         WriteCoord(channel, autocvar_g_trueaim_minrange);
829 }
830
831 void ClientInit_CheckUpdate(entity this)
832 {
833         this.nextthink = time;
834         if(this.count != autocvar_g_balance_armor_blockpercent)
835         {
836                 this.count = autocvar_g_balance_armor_blockpercent;
837                 this.SendFlags |= 1;
838         }
839         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
840         {
841                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
842                 this.SendFlags |= 1;
843         }
844 }
845
846 void ClientInit_Spawn()
847 {
848         entity e = new_pure(clientinit);
849         setthink(e, ClientInit_CheckUpdate);
850         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
851
852         ClientInit_CheckUpdate(e);
853 }
854
855 /*
856 =============
857 SetNewParms
858 =============
859 */
860 void SetNewParms ()
861 {
862         // initialize parms for a new player
863         parm1 = -(86400 * 366);
864
865         MUTATOR_CALLHOOK(SetNewParms);
866 }
867
868 /*
869 =============
870 SetChangeParms
871 =============
872 */
873 void SetChangeParms (entity this)
874 {
875         // save parms for level change
876         parm1 = CS(this).parm_idlesince - time;
877
878         MUTATOR_CALLHOOK(SetChangeParms);
879 }
880
881 /*
882 =============
883 DecodeLevelParms
884 =============
885 */
886 void DecodeLevelParms(entity this)
887 {
888         // load parms
889         CS(this).parm_idlesince = parm1;
890         if (CS(this).parm_idlesince == -(86400 * 366))
891                 CS(this).parm_idlesince = time;
892
893         // whatever happens, allow 60 seconds of idling directly after connect for map loading
894         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
895
896         MUTATOR_CALLHOOK(DecodeLevelParms);
897 }
898
899 /*
900 =============
901 ClientKill
902
903 Called when a client types 'kill' in the console
904 =============
905 */
906
907 .float clientkill_nexttime;
908 void ClientKill_Now_TeamChange(entity this)
909 {
910         if(this.killindicator_teamchange == -1)
911         {
912                 TeamBalance_JoinBestTeam(this, true);
913         }
914         else if(this.killindicator_teamchange == -2)
915         {
916                 if(blockSpectators)
917                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
918                 PutObserverInServer(this);
919         }
920         else
921                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
922         this.killindicator_teamchange = 0;
923 }
924
925 void ClientKill_Now(entity this)
926 {
927         if(this.vehicle)
928         {
929             vehicles_exit(this.vehicle, VHEF_RELEASE);
930             if(!this.killindicator_teamchange)
931             {
932             this.vehicle_health = -1;
933             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
934             }
935         }
936
937         if(this.killindicator && !wasfreed(this.killindicator))
938                 delete(this.killindicator);
939
940         this.killindicator = NULL;
941
942         if(this.killindicator_teamchange)
943                 ClientKill_Now_TeamChange(this);
944
945         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
946         {
947                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
948         }
949
950         // now I am sure the player IS dead
951 }
952 void KillIndicator_Think(entity this)
953 {
954         if (game_stopped)
955         {
956                 this.owner.killindicator = NULL;
957                 delete(this);
958                 return;
959         }
960
961         if (this.owner.alpha < 0 && !this.owner.vehicle)
962         {
963                 this.owner.killindicator = NULL;
964                 delete(this);
965                 return;
966         }
967
968         if(this.cnt <= 0)
969         {
970                 ClientKill_Now(this.owner);
971                 return;
972         }
973     else if(this.health == 1) // health == 1 means that it's silent
974     {
975         this.nextthink = time + 1;
976         this.cnt -= 1;
977     }
978         else
979         {
980                 if(this.cnt <= 10)
981                         setmodel(this, MDL_NUM(this.cnt));
982                 if(IS_REAL_CLIENT(this.owner))
983                 {
984                         if(this.cnt <= 10)
985                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
986                 }
987                 this.nextthink = time + 1;
988                 this.cnt -= 1;
989         }
990 }
991
992 float clientkilltime;
993 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
994 {
995         float killtime;
996         float starttime;
997
998         if (game_stopped)
999                 return;
1000
1001         killtime = autocvar_g_balance_kill_delay;
1002
1003     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1004         return;
1005     killtime = M_ARGV(1, float);
1006
1007         this.killindicator_teamchange = targetteam;
1008
1009     if(!this.killindicator)
1010         {
1011                 if(!IS_DEAD(this))
1012                 {
1013                         killtime = max(killtime, this.clientkill_nexttime - time);
1014                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1015                 }
1016
1017                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1018                 {
1019                         ClientKill_Now(this);
1020                 }
1021                 else
1022                 {
1023                         starttime = max(time, clientkilltime);
1024
1025                         this.killindicator = spawn();
1026                         this.killindicator.owner = this;
1027                         this.killindicator.scale = 0.5;
1028                         setattachment(this.killindicator, this, "");
1029                         setorigin(this.killindicator, '0 0 52');
1030                         setthink(this.killindicator, KillIndicator_Think);
1031                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1032                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1033                         this.killindicator.cnt = ceil(killtime);
1034                         this.killindicator.count = bound(0, ceil(killtime), 10);
1035                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1036
1037                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1038                         {
1039                                 it.killindicator = spawn();
1040                                 it.killindicator.owner = it;
1041                                 it.killindicator.scale = 0.5;
1042                                 setattachment(it.killindicator, it, "");
1043                                 setorigin(it.killindicator, '0 0 52');
1044                                 setthink(it.killindicator, KillIndicator_Think);
1045                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1046                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1047                                 it.killindicator.cnt = ceil(killtime);
1048                         });
1049                         this.lip = 0;
1050                 }
1051         }
1052         if(this.killindicator)
1053         {
1054                 if(targetteam == 0) // just die
1055                 {
1056                         this.killindicator.colormod = '0 0 0';
1057                         if(IS_REAL_CLIENT(this))
1058                         if(this.killindicator.cnt > 0)
1059                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1060                 }
1061                 else if(targetteam == -1) // auto
1062                 {
1063                         this.killindicator.colormod = '0 1 0';
1064                         if(IS_REAL_CLIENT(this))
1065                         if(this.killindicator.cnt > 0)
1066                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1067                 }
1068                 else if(targetteam == -2) // spectate
1069                 {
1070                         this.killindicator.colormod = '0.5 0.5 0.5';
1071                         if(IS_REAL_CLIENT(this))
1072                         if(this.killindicator.cnt > 0)
1073                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1074                 }
1075                 else
1076                 {
1077                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1078                         if(IS_REAL_CLIENT(this))
1079                         if(this.killindicator.cnt > 0)
1080                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1081                 }
1082         }
1083
1084 }
1085
1086 void ClientKill (entity this)
1087 {
1088         if(game_stopped) return;
1089         if(this.player_blocked) return;
1090         if(STAT(FROZEN, this)) return;
1091
1092         ClientKill_TeamChange(this, 0);
1093 }
1094
1095 void FixClientCvars(entity e)
1096 {
1097         // send prediction settings to the client
1098         stuffcmd(e, "\nin_bindmap 0 0\n");
1099         if(autocvar_g_antilag == 3) // client side hitscan
1100                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1101         if(autocvar_sv_gentle)
1102                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1103
1104         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1105         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1106
1107         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1108
1109         MUTATOR_CALLHOOK(FixClientCvars, e);
1110 }
1111
1112 bool findinlist_abbrev(string tofind, string list)
1113 {
1114         if(list == "" || tofind == "")
1115                 return false; // empty list or search, just return
1116
1117         // this function allows abbreviated strings!
1118         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1119         {
1120                 return true;
1121         });
1122
1123         return false;
1124 }
1125
1126 bool PlayerInIPList(entity p, string iplist)
1127 {
1128         // some safety checks (never allow local?)
1129         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1130                 return false;
1131
1132         return findinlist_abbrev(p.netaddress, iplist);
1133 }
1134
1135 bool PlayerInIDList(entity p, string idlist)
1136 {
1137         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1138         if(!p.crypto_idfp)
1139                 return false;
1140
1141         return findinlist_abbrev(p.crypto_idfp, idlist);
1142 }
1143
1144 bool PlayerInList(entity player, string list)
1145 {
1146         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1147 }
1148
1149 #ifdef DP_EXT_PRECONNECT
1150 /*
1151 =============
1152 ClientPreConnect
1153
1154 Called once (not at each match start) when a client begins a connection to the server
1155 =============
1156 */
1157 void ClientPreConnect(entity this)
1158 {
1159         if(autocvar_sv_eventlog)
1160         {
1161                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1162                         this.playerid,
1163                         etof(this),
1164                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1165                 ));
1166         }
1167 }
1168 #endif
1169
1170 string GetClientVersionMessage(entity this)
1171 {
1172         if (CS(this).version_mismatch) {
1173                 if(CS(this).version < autocvar_gameversion) {
1174                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1175                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1176                 } else {
1177                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1178                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1179                 }
1180         } else {
1181                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1182         }
1183 }
1184
1185 string getwelcomemessage(entity this)
1186 {
1187         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1188         string modifications = M_ARGV(0, string);
1189
1190         if(g_weaponarena)
1191         {
1192                 if(g_weaponarena_random)
1193                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1194                 else
1195                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1196         }
1197         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1198                 modifications = strcat(modifications, ", No start weapons");
1199         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1200                 modifications = strcat(modifications, ", Low gravity");
1201         if(g_weapon_stay && !g_cts)
1202                 modifications = strcat(modifications, ", Weapons stay");
1203         if(g_jetpack)
1204                 modifications = strcat(modifications, ", Jet pack");
1205         if(autocvar_g_powerups == 0)
1206                 modifications = strcat(modifications, ", No powerups");
1207         if(autocvar_g_powerups > 0)
1208                 modifications = strcat(modifications, ", Powerups");
1209         modifications = substring(modifications, 2, strlen(modifications) - 2);
1210
1211         string versionmessage = GetClientVersionMessage(this);
1212         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1213
1214         if(modifications != "")
1215                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1216
1217         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1218         {
1219                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1220                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1221         }
1222
1223         if (cache_mutatormsg != "") {
1224                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1225         }
1226
1227         string mutator_msg = "";
1228         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1229         mutator_msg = M_ARGV(0, string);
1230
1231         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1232
1233         string motd = autocvar_sv_motd;
1234         if (motd != "") {
1235                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1236         }
1237         return s;
1238 }
1239
1240 /**
1241 =============
1242 ClientConnect
1243
1244 Called when a client connects to the server
1245 =============
1246 */
1247 void ClientConnect(entity this)
1248 {
1249         if (Ban_MaybeEnforceBanOnce(this)) return;
1250         assert(!IS_CLIENT(this), return);
1251         this.flags |= FL_CLIENT;
1252         assert(player_count >= 0, player_count = 0);
1253
1254 #ifdef WATERMARK
1255         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1256 #endif
1257         TRANSMUTE(Client, this);
1258         CS(this).version_nagtime = time + 10 + random() * 10;
1259
1260         // identify the right forced team
1261         if (autocvar_g_campaign)
1262         {
1263                 if (IS_REAL_CLIENT(this)) // only players, not bots
1264                 {
1265                         switch (autocvar_g_campaign_forceteam)
1266                         {
1267                                 case 1: this.team_forced = NUM_TEAM_1; break;
1268                                 case 2: this.team_forced = NUM_TEAM_2; break;
1269                                 case 3: this.team_forced = NUM_TEAM_3; break;
1270                                 case 4: this.team_forced = NUM_TEAM_4; break;
1271                                 default: this.team_forced = 0;
1272                         }
1273                 }
1274         }
1275         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1276         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1277         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1278         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1279         else switch (autocvar_g_forced_team_otherwise)
1280         {
1281                 default: this.team_forced = 0; break;
1282                 case "red": this.team_forced = NUM_TEAM_1; break;
1283                 case "blue": this.team_forced = NUM_TEAM_2; break;
1284                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1285                 case "pink": this.team_forced = NUM_TEAM_4; break;
1286                 case "spectate":
1287                 case "spectator":
1288                         this.team_forced = -1;
1289                         break;
1290         }
1291         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1292
1293         int playerid_save = this.playerid;
1294         this.playerid = 0; // silent
1295         TeamBalance_JoinBestTeam(this, false); // if the team number is valid, keep it
1296         this.playerid = playerid_save;
1297
1298         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1299                 TRANSMUTE(Observer, this);
1300         } else {
1301                 if (!teamplay || autocvar_g_balance_teams) {
1302                         TRANSMUTE(Player, this);
1303                         campaign_bots_may_start = true;
1304                 } else {
1305                         TRANSMUTE(Observer, this); // do it anyway
1306                 }
1307         }
1308
1309         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1310
1311         // always track bots, don't ask for cl_allow_uidtracking
1312         if (IS_BOT_CLIENT(this))
1313                 PlayerStats_GameReport_AddPlayer(this);
1314         else
1315                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1316
1317         if (autocvar_sv_eventlog)
1318                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1319
1320         LogTeamchange(this.playerid, this.team, TEAM_CHANGE_CONNECT);
1321
1322         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1323
1324         if(teamplay && IS_PLAYER(this))
1325                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1326         else
1327                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1328
1329         stuffcmd(this, clientstuff, "\n");
1330         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1331
1332         FixClientCvars(this);
1333
1334         // get version info from player
1335         stuffcmd(this, "cmd clientversion $gameversion\n");
1336
1337         // notify about available teams
1338         if (teamplay)
1339         {
1340                 entity balance = TeamBalance_CheckAllowedTeams(this);
1341                 int t = TeamBalance_GetAllowedTeams(balance);
1342                 TeamBalance_Destroy(balance);
1343                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1344         }
1345         else
1346         {
1347                 stuffcmd(this, "set _teams_available 0\n");
1348         }
1349
1350         bot_relinkplayerlist();
1351
1352         CS(this).spectatortime = time;
1353         if (blockSpectators)
1354         {
1355                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1356         }
1357
1358         CS(this).jointime = time;
1359
1360         if (IS_REAL_CLIENT(this))
1361         {
1362                 if (g_weaponarena_weapons == WEPSET(TUBA))
1363                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1364         }
1365
1366         if (!sv_foginterval && world.fog != "")
1367                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1368
1369         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1370                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1371                         send_CSQC_teamnagger();
1372
1373         CSQCMODEL_AUTOINIT(this);
1374
1375         CS(this).model_randomizer = random();
1376
1377         if (IS_REAL_CLIENT(this))
1378                 sv_notice_join(this);
1379
1380         // update physics stats (players can spawn before physics runs)
1381         Physics_UpdateStats(this);
1382
1383         IL_EACH(g_initforplayer, it.init_for_player, {
1384                 it.init_for_player(it, this);
1385         });
1386
1387         Handicap_Initialize(this);
1388
1389         MUTATOR_CALLHOOK(ClientConnect, this);
1390
1391         if (IS_REAL_CLIENT(this))
1392         {
1393                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1394                 {
1395                         CS(this).motd_actived_time = -1;
1396                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1397                 }
1398         }
1399 }
1400 /*
1401 =============
1402 ClientDisconnect
1403
1404 Called when a client disconnects from the server
1405 =============
1406 */
1407 .entity chatbubbleentity;
1408 void ReadyCount();
1409 void ClientDisconnect(entity this)
1410 {
1411         assert(IS_CLIENT(this), return);
1412
1413         PlayerStats_GameReport_FinalizePlayer(this);
1414         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1415         if (CS(this).active_minigame) part_minigame(this);
1416         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1417
1418         if (autocvar_sv_eventlog)
1419                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1420
1421         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1422
1423         if(IS_SPEC(this))
1424                 SetSpectatee(this, NULL);
1425
1426     MUTATOR_CALLHOOK(ClientDisconnect, this);
1427
1428         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1429         strfree(CS(this).weaponorder_byimpulse);
1430         ClientState_detach(this);
1431
1432         Portal_ClearAll(this);
1433
1434         Unfreeze(this);
1435
1436         RemoveGrapplingHooks(this);
1437
1438         // Here, everything has been done that requires this player to be a client.
1439
1440         this.flags &= ~FL_CLIENT;
1441
1442         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1443         if (this.killindicator) delete(this.killindicator);
1444
1445         WaypointSprite_PlayerGone(this);
1446
1447         bot_relinkplayerlist();
1448
1449         strfree(this.clientstatus);
1450         if (this.personal) delete(this.personal);
1451
1452         this.playerid = 0;
1453         ReadyCount();
1454         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1455
1456         ONREMOVE(this);
1457 }
1458
1459 void ChatBubbleThink(entity this)
1460 {
1461         this.nextthink = time;
1462         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1463         {
1464                 if(this.owner) // but why can that ever be NULL?
1465                         this.owner.chatbubbleentity = NULL;
1466                 delete(this);
1467                 return;
1468         }
1469
1470         this.mdl = "";
1471
1472         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1473         {
1474                 if ( CS(this.owner).active_minigame )
1475                         this.mdl = "models/sprites/minigame_busy.iqm";
1476                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1477                         this.mdl = "models/misc/chatbubble.spr";
1478         }
1479
1480         if ( this.model != this.mdl )
1481                 _setmodel(this, this.mdl);
1482
1483 }
1484
1485 void UpdateChatBubble(entity this)
1486 {
1487         if (this.alpha < 0)
1488                 return;
1489         // spawn a chatbubble entity if needed
1490         if (!this.chatbubbleentity)
1491         {
1492                 this.chatbubbleentity = new(chatbubbleentity);
1493                 this.chatbubbleentity.owner = this;
1494                 this.chatbubbleentity.exteriormodeltoclient = this;
1495                 setthink(this.chatbubbleentity, ChatBubbleThink);
1496                 this.chatbubbleentity.nextthink = time;
1497                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1498                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1499                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1500                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1501                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1502                 //this.chatbubbleentity.model = "";
1503                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1504         }
1505 }
1506
1507
1508 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1509 // added to the model skins
1510 /*void UpdateColorModHack()
1511 {
1512         float c;
1513         c = this.clientcolors & 15;
1514         // LordHavoc: only bothering to support white, green, red, yellow, blue
1515              if (!teamplay) this.colormod = '0 0 0';
1516         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1517         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1518         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1519         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1520         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1521         else this.colormod = '1 1 1';
1522 }*/
1523
1524 void respawn(entity this)
1525 {
1526         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1527         {
1528                 this.solid = SOLID_NOT;
1529                 this.takedamage = DAMAGE_NO;
1530                 set_movetype(this, MOVETYPE_FLY);
1531                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1532                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1533                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1534                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1535                 if(autocvar_g_respawn_ghosts_maxtime)
1536                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1537         }
1538
1539         CopyBody(this, 1);
1540
1541         this.effects |= EF_NODRAW; // prevent another CopyBody
1542         PutClientInServer(this);
1543 }
1544
1545 void play_countdown(entity this, float finished, Sound samp)
1546 {
1547     TC(Sound, samp);
1548         if(IS_REAL_CLIENT(this))
1549                 if(floor(finished - time - frametime) != floor(finished - time))
1550                         if(finished - time < 6)
1551                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1552 }
1553
1554 void player_powerups(entity this)
1555 {
1556         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1557         int items_prev = this.items;
1558
1559         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1560                 this.modelflags |= MF_ROCKET;
1561         else
1562                 this.modelflags &= ~MF_ROCKET;
1563
1564         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1565
1566         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1567                 return;
1568
1569         Fire_ApplyDamage(this);
1570         Fire_ApplyEffect(this);
1571
1572         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1573         {
1574                 if (this.items & ITEM_Strength.m_itemid)
1575                 {
1576                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1577                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1578                         if (time > this.strength_finished)
1579                         {
1580                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1581                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1582                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1583                         }
1584                 }
1585                 else
1586                 {
1587                         if (time < this.strength_finished)
1588                         {
1589                                 this.items = this.items | ITEM_Strength.m_itemid;
1590                                 if(!g_cts)
1591                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1592                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1593                         }
1594                 }
1595                 if (this.items & ITEM_Shield.m_itemid)
1596                 {
1597                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1598                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1599                         if (time > this.invincible_finished)
1600                         {
1601                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1602                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1603                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1604                         }
1605                 }
1606                 else
1607                 {
1608                         if (time < this.invincible_finished)
1609                         {
1610                                 this.items = this.items | ITEM_Shield.m_itemid;
1611                                 if(!g_cts)
1612                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1613                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1614                         }
1615                 }
1616                 if (this.items & IT_SUPERWEAPON)
1617                 {
1618                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1619                         {
1620                                 this.superweapons_finished = 0;
1621                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1622                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1623                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1624                         }
1625                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1626                         {
1627                                 // don't let them run out
1628                         }
1629                         else
1630                         {
1631                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1632                                 if (time > this.superweapons_finished)
1633                                 {
1634                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1635                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1636                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1637                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1638                                 }
1639                         }
1640                 }
1641                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1642                 {
1643                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1644                         {
1645                                 this.items = this.items | IT_SUPERWEAPON;
1646                                 if(!g_cts)
1647                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1648                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1649                         }
1650                         else
1651                         {
1652                                 this.superweapons_finished = 0;
1653                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1654                         }
1655                 }
1656                 else
1657                 {
1658                         this.superweapons_finished = 0;
1659                 }
1660         }
1661
1662         if(autocvar_g_nodepthtestplayers)
1663                 this.effects = this.effects | EF_NODEPTHTEST;
1664
1665         if(autocvar_g_fullbrightplayers)
1666                 this.effects = this.effects | EF_FULLBRIGHT;
1667
1668         if (time >= game_starttime)
1669         if (time < this.spawnshieldtime)
1670                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1671
1672         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1673 }
1674
1675 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1676 {
1677         if(current > stable)
1678                 return current;
1679         else if(current > stable - 0.25) // when close enough, "snap"
1680                 return stable;
1681         else
1682                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1683 }
1684
1685 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1686 {
1687         if(current < stable)
1688                 return current;
1689         else if(current < stable + 0.25) // when close enough, "snap"
1690                 return stable;
1691         else
1692                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1693 }
1694
1695 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1696 {
1697         if(current > rotstable)
1698         {
1699                 if(rotframetime > 0)
1700                 {
1701                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1702                         current = max(rotstable, current - rotlinear * rotframetime);
1703                 }
1704         }
1705         else if(current < regenstable)
1706         {
1707                 if(regenframetime > 0)
1708                 {
1709                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1710                         current = min(regenstable, current + regenlinear * regenframetime);
1711                 }
1712         }
1713
1714         if(current > limit)
1715                 current = limit;
1716
1717         return current;
1718 }
1719
1720 void player_regen(entity this)
1721 {
1722         float max_mod, regen_mod, rot_mod, limit_mod;
1723         max_mod = regen_mod = rot_mod = limit_mod = 1;
1724
1725         float regen_health = autocvar_g_balance_health_regen;
1726         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1727         float regen_health_rot = autocvar_g_balance_health_rot;
1728         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1729         float regen_health_stable = autocvar_g_balance_health_regenstable;
1730         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1731         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1732                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1733         max_mod = M_ARGV(1, float);
1734         regen_mod = M_ARGV(2, float);
1735         rot_mod = M_ARGV(3, float);
1736         limit_mod = M_ARGV(4, float);
1737         regen_health = M_ARGV(5, float);
1738         regen_health_linear = M_ARGV(6, float);
1739         regen_health_rot = M_ARGV(7, float);
1740         regen_health_rotlinear = M_ARGV(8, float);
1741         regen_health_stable = M_ARGV(9, float);
1742         regen_health_rotstable = M_ARGV(10, float);
1743
1744         if(!mutator_returnvalue)
1745         if(!STAT(FROZEN, this))
1746         {
1747                 float mina, maxa, limith, limita;
1748                 maxa = autocvar_g_balance_armor_rotstable;
1749                 mina = autocvar_g_balance_armor_regenstable;
1750                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1751                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1752
1753                 regen_health_rotstable = regen_health_rotstable * max_mod;
1754                 regen_health_stable = regen_health_stable * max_mod;
1755                 limith = limith * limit_mod;
1756                 limita = limita * limit_mod;
1757
1758                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1759                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1760         }
1761
1762         // if player rotted to death...  die!
1763         // check this outside above checks, as player may still be able to rot to death
1764         if(this.health < 1)
1765         {
1766                 if(this.vehicle)
1767                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1768                 if(this.event_damage)
1769                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1770         }
1771
1772         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1773         {
1774                 float minf, maxf, limitf;
1775
1776                 maxf = autocvar_g_balance_fuel_rotstable;
1777                 minf = autocvar_g_balance_fuel_regenstable;
1778                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1779
1780                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1781         }
1782         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1783         // TODO: Remove this hack when all code uses GivePlayerHealth and
1784         // GivePlayerArmor.
1785         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1786         {
1787                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1788         }
1789         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1790         {
1791                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1792         }
1793         // End hack.
1794 }
1795
1796 bool zoomstate_set;
1797 void SetZoomState(entity this, float newzoom)
1798 {
1799         if(newzoom != CS(this).zoomstate)
1800         {
1801                 CS(this).zoomstate = newzoom;
1802                 ClientData_Touch(this);
1803         }
1804         zoomstate_set = true;
1805 }
1806
1807 void GetPressedKeys(entity this)
1808 {
1809         MUTATOR_CALLHOOK(GetPressedKeys, this);
1810         int keys = STAT(PRESSED_KEYS, this);
1811         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1812         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1813         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1814         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1815
1816         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1817         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1818         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1819         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1820         CS(this).pressedkeys = keys; // store for other users
1821
1822         STAT(PRESSED_KEYS, this) = keys;
1823 }
1824
1825 /*
1826 ======================
1827 spectate mode routines
1828 ======================
1829 */
1830
1831 void SpectateCopy(entity this, entity spectatee)
1832 {
1833     TC(Client, this); TC(Client, spectatee);
1834
1835         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1836         PS(this) = PS(spectatee);
1837         this.armortype = spectatee.armortype;
1838         this.armorvalue = spectatee.armorvalue;
1839         this.ammo_cells = spectatee.ammo_cells;
1840         this.ammo_plasma = spectatee.ammo_plasma;
1841         this.ammo_shells = spectatee.ammo_shells;
1842         this.ammo_nails = spectatee.ammo_nails;
1843         this.ammo_rockets = spectatee.ammo_rockets;
1844         this.ammo_fuel = spectatee.ammo_fuel;
1845         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1846         this.health = spectatee.health;
1847         CS(this).impulse = 0;
1848         this.items = spectatee.items;
1849         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1850         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1851         this.strength_finished = spectatee.strength_finished;
1852         this.invincible_finished = spectatee.invincible_finished;
1853         this.superweapons_finished = spectatee.superweapons_finished;
1854         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1855         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1856         this.punchangle = spectatee.punchangle;
1857         this.view_ofs = spectatee.view_ofs;
1858         this.velocity = spectatee.velocity;
1859         this.dmg_take = spectatee.dmg_take;
1860         this.dmg_save = spectatee.dmg_save;
1861         this.dmg_inflictor = spectatee.dmg_inflictor;
1862         this.v_angle = spectatee.v_angle;
1863         this.angles = spectatee.v_angle;
1864         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1865         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1866         this.viewloc = spectatee.viewloc;
1867         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1868                 this.fixangle = true;
1869         setorigin(this, spectatee.origin);
1870         setsize(this, spectatee.mins, spectatee.maxs);
1871         SetZoomState(this, CS(spectatee).zoomstate);
1872
1873     anticheat_spectatecopy(this, spectatee);
1874         STAT(HUD, this) = STAT(HUD, spectatee);
1875         if(spectatee.vehicle)
1876     {
1877         this.angles = spectatee.v_angle;
1878
1879         //this.fixangle = false;
1880         //this.velocity = spectatee.vehicle.velocity;
1881         this.vehicle_health = spectatee.vehicle_health;
1882         this.vehicle_shield = spectatee.vehicle_shield;
1883         this.vehicle_energy = spectatee.vehicle_energy;
1884         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1885         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1886         this.vehicle_reload1 = spectatee.vehicle_reload1;
1887         this.vehicle_reload2 = spectatee.vehicle_reload2;
1888
1889         //msg_entity = this;
1890
1891        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1892             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1893            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1894            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1895
1896         //WriteByte (MSG_ONE, SVC_SETVIEW);
1897         //    WriteEntity(MSG_ONE, this);
1898         //makevectors(spectatee.v_angle);
1899         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1900     }
1901 }
1902
1903 bool SpectateUpdate(entity this)
1904 {
1905         if(!this.enemy)
1906                 return false;
1907
1908         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1909         {
1910                 SetSpectatee(this, NULL);
1911                 return false;
1912         }
1913
1914         SpectateCopy(this, this.enemy);
1915
1916         return true;
1917 }
1918
1919 bool SpectateSet(entity this)
1920 {
1921         if(!IS_PLAYER(this.enemy))
1922                 return false;
1923
1924         ClientData_Touch(this.enemy);
1925
1926         msg_entity = this;
1927         WriteByte(MSG_ONE, SVC_SETVIEW);
1928         WriteEntity(MSG_ONE, this.enemy);
1929         set_movetype(this, MOVETYPE_NONE);
1930         accuracy_resend(this);
1931
1932         if(!SpectateUpdate(this))
1933                 PutObserverInServer(this);
1934
1935         return true;
1936 }
1937
1938 void SetSpectatee_status(entity this, int spectatee_num)
1939 {
1940         int oldspectatee_status = CS(this).spectatee_status;
1941         CS(this).spectatee_status = spectatee_num;
1942
1943         if (CS(this).spectatee_status != oldspectatee_status)
1944         {
1945                 ClientData_Touch(this);
1946                 if (g_race || g_cts) race_InitSpectator();
1947         }
1948 }
1949
1950 void SetSpectatee(entity this, entity spectatee)
1951 {
1952         if(IS_BOT_CLIENT(this))
1953                 return; // bots abuse .enemy, this code is useless to them
1954
1955         entity old_spectatee = this.enemy;
1956
1957         this.enemy = spectatee;
1958
1959         // WEAPONTODO
1960         // these are required to fix the spectator bug with arc
1961         if(old_spectatee)
1962         {
1963                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1964                 {
1965                         .entity weaponentity = weaponentities[slot];
1966                         if(old_spectatee.(weaponentity).arc_beam)
1967                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1968                 }
1969         }
1970         if(this.enemy)
1971         {
1972                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1973                 {
1974                         .entity weaponentity = weaponentities[slot];
1975                         if(this.enemy.(weaponentity).arc_beam)
1976                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1977                 }
1978         }
1979
1980         if (this.enemy)
1981                 SetSpectatee_status(this, etof(this.enemy));
1982
1983         // needed to update spectator list
1984         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1985 }
1986
1987 bool Spectate(entity this, entity pl)
1988 {
1989         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1990                 return false;
1991         pl = M_ARGV(1, entity);
1992
1993         SetSpectatee(this, pl);
1994         return SpectateSet(this);
1995 }
1996
1997 bool SpectateNext(entity this)
1998 {
1999         entity ent = find(this.enemy, classname, STR_PLAYER);
2000
2001         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2002                 ent = M_ARGV(1, entity);
2003         else if (!ent)
2004                 ent = find(ent, classname, STR_PLAYER);
2005
2006         if(ent) { SetSpectatee(this, ent); }
2007
2008         return SpectateSet(this);
2009 }
2010
2011 bool SpectatePrev(entity this)
2012 {
2013         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2014         entity ent = findchain(classname, STR_PLAYER);
2015         if (!ent) // no player
2016                 return false;
2017
2018         entity first = ent;
2019         // skip players until current spectated player
2020         if(this.enemy)
2021         while(ent && ent != this.enemy)
2022                 ent = ent.chain;
2023
2024         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2025         {
2026                 case MUT_SPECPREV_FOUND:
2027                     ent = M_ARGV(1, entity);
2028                     break;
2029                 case MUT_SPECPREV_RETURN:
2030                     return true;
2031                 case MUT_SPECPREV_CONTINUE:
2032                 default:
2033                 {
2034                         if(ent.chain)
2035                                 ent = ent.chain;
2036                         else
2037                                 ent = first;
2038                         break;
2039                 }
2040         }
2041
2042         SetSpectatee(this, ent);
2043         return SpectateSet(this);
2044 }
2045
2046 /*
2047 =============
2048 ShowRespawnCountdown()
2049
2050 Update a respawn countdown display.
2051 =============
2052 */
2053 void ShowRespawnCountdown(entity this)
2054 {
2055         float number;
2056         if(!IS_DEAD(this)) // just respawned?
2057                 return;
2058         else
2059         {
2060                 number = ceil(this.respawn_time - time);
2061                 if(number <= 0)
2062                         return;
2063                 if(number <= this.respawn_countdown)
2064                 {
2065                         this.respawn_countdown = number - 1;
2066                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2067                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2068                 }
2069         }
2070 }
2071
2072 .bool team_selected;
2073 bool ShowTeamSelection(entity this)
2074 {
2075         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2076                 return false;
2077         stuffcmd(this, "menu_showteamselect\n");
2078         return true;
2079 }
2080 void Join(entity this)
2081 {
2082         TRANSMUTE(Player, this);
2083
2084         if(!this.team_selected)
2085         if(autocvar_g_campaign || autocvar_g_balance_teams)
2086                 TeamBalance_JoinBestTeam(this, true);
2087
2088         if(autocvar_g_campaign)
2089                 campaign_bots_may_start = true;
2090
2091         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2092
2093         PutClientInServer(this);
2094
2095         if(IS_PLAYER(this))
2096         if(teamplay && this.team != -1)
2097         {
2098                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2099         }
2100         else
2101                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2102         this.team_selected = false;
2103 }
2104
2105 /**
2106  * Determines whether the player is allowed to join. This depends on cvar
2107  * g_maxplayers, if it isn't used this function always return true, otherwise
2108  * it checks whether the number of currently playing players exceeds g_maxplayers.
2109  * @return int number of free slots for players, 0 if none
2110  */
2111 int nJoinAllowed(entity this, entity ignore)
2112 {
2113         if(!ignore)
2114         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2115         // so report 0 free slots if restricted
2116         {
2117                 if(autocvar_g_forced_team_otherwise == "spectate")
2118                         return 0;
2119                 if(autocvar_g_forced_team_otherwise == "spectator")
2120                         return 0;
2121         }
2122
2123         if(this && this.team_forced < 0)
2124                 return 0; // forced spectators can never join
2125
2126         // TODO simplify this
2127         int totalClients = 0;
2128         int currentlyPlaying = 0;
2129         FOREACH_CLIENT(true, {
2130                 if(it != ignore)
2131                         ++totalClients;
2132                 if(IS_REAL_CLIENT(it))
2133                 if(IS_PLAYER(it) || it.caplayer)
2134                         ++currentlyPlaying;
2135         });
2136
2137         float free_slots = 0;
2138         if (!autocvar_g_maxplayers)
2139                 free_slots = maxclients - totalClients;
2140         else if(currentlyPlaying < autocvar_g_maxplayers)
2141                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2142
2143         static float join_prevent_msg_time = 0;
2144         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2145         {
2146                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2147                 join_prevent_msg_time = time + 3;
2148         }
2149
2150         return free_slots;
2151 }
2152
2153 /**
2154  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2155  * g_maxplayers_spectator_blocktime seconds
2156  */
2157 void checkSpectatorBlock(entity this)
2158 {
2159         if(IS_SPEC(this) || IS_OBSERVER(this))
2160         if(!this.caplayer)
2161         if(IS_REAL_CLIENT(this))
2162         {
2163                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2164                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2165                         dropclient(this);
2166                 }
2167         }
2168 }
2169
2170 void PrintWelcomeMessage(entity this)
2171 {
2172         if(CS(this).motd_actived_time == 0)
2173         {
2174                 if (autocvar_g_campaign) {
2175                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2176                                 CS(this).motd_actived_time = time;
2177                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2178                         }
2179                 } else {
2180                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2181                                 CS(this).motd_actived_time = time;
2182                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2183                         }
2184                 }
2185         }
2186         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2187         {
2188                 if (autocvar_g_campaign) {
2189                         if (PHYS_INPUT_BUTTON_INFO(this))
2190                                 CS(this).motd_actived_time = time;
2191                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2192                                 CS(this).motd_actived_time = 0;
2193                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2194                         }
2195                 } else {
2196                         if (PHYS_INPUT_BUTTON_INFO(this))
2197                                 CS(this).motd_actived_time = time;
2198                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2199                                 CS(this).motd_actived_time = 0;
2200                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2201                         }
2202                 }
2203         }
2204         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2205         {
2206                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2207                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2208                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2209                 {
2210                         // instanctly hide MOTD
2211                         CS(this).motd_actived_time = 0;
2212                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2213                 }
2214         }
2215 }
2216
2217 bool joinAllowed(entity this)
2218 {
2219         if (CS(this).version_mismatch) return false;
2220         if (!nJoinAllowed(this, this)) return false;
2221         if (teamplay && lockteams) return false;
2222         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2223         if (ShowTeamSelection(this)) return false;
2224         return true;
2225 }
2226
2227 .int items_added;
2228 .string shootfromfixedorigin;
2229 bool PlayerThink(entity this)
2230 {
2231         if (game_stopped || intermission_running) {
2232                 this.modelflags &= ~MF_ROCKET;
2233                 if(intermission_running)
2234                         IntermissionThink(this);
2235                 return false;
2236         }
2237
2238         if (timeout_status == TIMEOUT_ACTIVE) {
2239         // don't allow the player to turn around while game is paused
2240                 // FIXME turn this into CSQC stuff
2241                 this.v_angle = this.lastV_angle;
2242                 this.angles = this.lastV_angle;
2243                 this.fixangle = true;
2244         }
2245
2246         if (frametime) player_powerups(this);
2247
2248         if (IS_DEAD(this)) {
2249                 if (this.personal && g_race_qualifying) {
2250                         if (time > this.respawn_time) {
2251                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2252                                 respawn(this);
2253                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2254                         }
2255                 } else {
2256                         if (frametime) player_anim(this);
2257
2258                         if (this.respawn_flags & RESPAWN_DENY)
2259                         {
2260                                 STAT(RESPAWN_TIME, this) = 0;
2261                                 return false;
2262                         }
2263
2264                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2265
2266                         switch(this.deadflag)
2267                         {
2268                                 case DEAD_DYING:
2269                                 {
2270                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2271                                                 this.deadflag = DEAD_RESPAWNING;
2272                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2273                                                 this.deadflag = DEAD_DEAD;
2274                                         break;
2275                                 }
2276                                 case DEAD_DEAD:
2277                                 {
2278                                         if (button_pressed)
2279                                                 this.deadflag = DEAD_RESPAWNABLE;
2280                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2281                                                 this.deadflag = DEAD_RESPAWNING;
2282                                         break;
2283                                 }
2284                                 case DEAD_RESPAWNABLE:
2285                                 {
2286                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2287                                                 this.deadflag = DEAD_RESPAWNING;
2288                                         break;
2289                                 }
2290                                 case DEAD_RESPAWNING:
2291                                 {
2292                                         if (time > this.respawn_time)
2293                                         {
2294                                                 this.respawn_time = time + 1; // only retry once a second
2295                                                 this.respawn_time_max = this.respawn_time;
2296                                                 respawn(this);
2297                                         }
2298                                         break;
2299                                 }
2300                         }
2301
2302                         ShowRespawnCountdown(this);
2303
2304                         if (this.respawn_flags & RESPAWN_SILENT)
2305                                 STAT(RESPAWN_TIME, this) = 0;
2306                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2307                         {
2308                                 if (time < this.respawn_time)
2309                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2310                                 else if (this.deadflag != DEAD_RESPAWNING)
2311                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2312                         }
2313                         else
2314                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2315                 }
2316
2317                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2318                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2319                         STAT(RESPAWN_TIME, this) *= -1;
2320
2321                 return false;
2322         }
2323
2324         FixPlayermodel(this);
2325
2326         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2327                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2328                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2329         }
2330
2331         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2332         //if(frametime)
2333         {
2334                 this.items &= ~this.items_added;
2335
2336                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2337                 {
2338                         .entity weaponentity = weaponentities[slot];
2339                         W_WeaponFrame(this, weaponentity);
2340                 }
2341
2342                 this.items_added = 0;
2343                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2344             this.items_added |= IT_FUEL;
2345
2346                 this.items |= this.items_added;
2347         }
2348
2349         player_regen(this);
2350
2351         // WEAPONTODO: Add a weapon request for this
2352         // rot vortex charge to the charge limit
2353         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2354         {
2355                 .entity weaponentity = weaponentities[slot];
2356                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2357                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2358         }
2359
2360         if (frametime) player_anim(this);
2361
2362         // secret status
2363         secrets_setstatus(this);
2364
2365         // monsters status
2366         monsters_setstatus(this);
2367
2368         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2369
2370         return true;
2371 }
2372
2373 .bool would_spectate;
2374 void ObserverThink(entity this)
2375 {
2376         if ( CS(this).impulse )
2377         {
2378                 MinigameImpulse(this, CS(this).impulse);
2379                 CS(this).impulse = 0;
2380         }
2381
2382         if (this.flags & FL_JUMPRELEASED) {
2383                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2384                         this.flags &= ~FL_JUMPRELEASED;
2385                         this.flags |= FL_SPAWNING;
2386                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2387                         this.flags &= ~FL_JUMPRELEASED;
2388                         if(SpectateNext(this)) {
2389                                 TRANSMUTE(Spectator, this);
2390                         }
2391                 } else {
2392                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2393                         set_movetype(this, preferred_movetype);
2394                 }
2395         } else {
2396                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2397                         this.flags |= FL_JUMPRELEASED;
2398                         if(this.flags & FL_SPAWNING)
2399                         {
2400                                 this.flags &= ~FL_SPAWNING;
2401                                 Join(this);
2402                                 return;
2403                         }
2404                 }
2405         }
2406 }
2407
2408 void SpectatorThink(entity this)
2409 {
2410         if ( CS(this).impulse )
2411         {
2412                 if(MinigameImpulse(this, CS(this).impulse))
2413                         CS(this).impulse = 0;
2414
2415                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2416                 {
2417                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2418                         CS(this).impulse = 0;
2419                         return;
2420                 }
2421         }
2422
2423         if (this.flags & FL_JUMPRELEASED) {
2424                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2425                         this.flags &= ~FL_JUMPRELEASED;
2426                         this.flags |= FL_SPAWNING;
2427                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2428                         this.flags &= ~FL_JUMPRELEASED;
2429                         if(SpectateNext(this)) {
2430                                 TRANSMUTE(Spectator, this);
2431                         } else {
2432                                 TRANSMUTE(Observer, this);
2433                                 PutClientInServer(this);
2434                         }
2435                         CS(this).impulse = 0;
2436                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2437                         this.flags &= ~FL_JUMPRELEASED;
2438                         if(SpectatePrev(this)) {
2439                                 TRANSMUTE(Spectator, this);
2440                         } else {
2441                                 TRANSMUTE(Observer, this);
2442                                 PutClientInServer(this);
2443                         }
2444                         CS(this).impulse = 0;
2445                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2446                         this.would_spectate = false;
2447                         this.flags &= ~FL_JUMPRELEASED;
2448                         TRANSMUTE(Observer, this);
2449                         PutClientInServer(this);
2450                 } else {
2451                         if(!SpectateUpdate(this))
2452                         {
2453                                 if(!SpectateNext(this))
2454                                 {
2455                                         PutObserverInServer(this);
2456                                         this.would_spectate = true;
2457                                 }
2458                         }
2459                 }
2460         } else {
2461                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2462                         this.flags |= FL_JUMPRELEASED;
2463                         if(this.flags & FL_SPAWNING)
2464                         {
2465                                 this.flags &= ~FL_SPAWNING;
2466                                 Join(this);
2467                                 return;
2468                         }
2469                 }
2470                 if(!SpectateUpdate(this))
2471                         PutObserverInServer(this);
2472         }
2473
2474         this.flags |= FL_CLIENT | FL_NOTARGET;
2475 }
2476
2477 void vehicles_enter (entity pl, entity veh);
2478 void PlayerUseKey(entity this)
2479 {
2480         if (!IS_PLAYER(this))
2481                 return;
2482
2483         if(this.vehicle)
2484         {
2485                 if(!game_stopped)
2486                 {
2487                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2488                         return;
2489                 }
2490         }
2491         else if(autocvar_g_vehicles_enter)
2492         {
2493                 if(!STAT(FROZEN, this))
2494                 if(!IS_DEAD(this))
2495                 if(!game_stopped)
2496                 {
2497                         entity head, closest_target = NULL;
2498                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2499
2500                         while(head) // find the closest acceptable target to enter
2501                         {
2502                                 if(IS_VEHICLE(head))
2503                                 if(!IS_DEAD(head))
2504                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2505                                 if(head.takedamage != DAMAGE_NO)
2506                                 {
2507                                         if(closest_target)
2508                                         {
2509                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2510                                                 { closest_target = head; }
2511                                         }
2512                                         else { closest_target = head; }
2513                                 }
2514
2515                                 head = head.chain;
2516                         }
2517
2518                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2519                 }
2520         }
2521
2522         // a use key was pressed; call handlers
2523         MUTATOR_CALLHOOK(PlayerUseKey, this);
2524 }
2525
2526
2527 /*
2528 =============
2529 PlayerPreThink
2530
2531 Called every frame for each client before the physics are run
2532 =============
2533 */
2534 .float last_vehiclecheck;
2535 void PlayerPreThink (entity this)
2536 {
2537         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2538         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2539
2540         WarpZone_PlayerPhysics_FixVAngle(this);
2541
2542         if (frametime) {
2543                 // physics frames: update anticheat stuff
2544                 anticheat_prethink(this);
2545         }
2546
2547         if (blockSpectators && frametime) {
2548                 // WORKAROUND: only use dropclient in server frames (frametime set).
2549                 // Never use it in cl_movement frames (frametime zero).
2550                 checkSpectatorBlock(this);
2551         }
2552
2553         zoomstate_set = false;
2554
2555         // Check for nameless players
2556         if (this.netname == "" || this.netname != CS(this).netname_previous)
2557         {
2558                 bool assume_unchanged = (CS(this).netname_previous == "");
2559                 if (isInvisibleString(this.netname))
2560                 {
2561                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2562                         assume_unchanged = false;
2563                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2564                 }
2565                 if (!assume_unchanged && autocvar_sv_eventlog)
2566                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2567                 strcpy(CS(this).netname_previous, this.netname);
2568         }
2569
2570         // version nagging
2571         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2572         CS(this).version_nagtime = 0;
2573         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2574             // git client
2575         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2576             // git server
2577             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2578         } else {
2579             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2580             if (r < 0) { // old client
2581                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2582             } else if (r > 0) { // old server
2583                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2584             }
2585         }
2586     }
2587
2588         // GOD MODE info
2589         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2590         {
2591                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2592                 this.max_armorvalue = 0;
2593         }
2594
2595         if(IS_PLAYER(this))
2596         {
2597                 if (STAT(FROZEN, this) == 2)
2598                 {
2599                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2600                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2601                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2602
2603                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2604                                 Unfreeze(this);
2605                 }
2606                 else if (STAT(FROZEN, this) == 3)
2607                 {
2608                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2609                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2610
2611                         if (this.health < 1)
2612                         {
2613                                 if (this.vehicle)
2614                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2615                                 if(this.event_damage)
2616                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2617                         }
2618                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2619                                 Unfreeze(this);
2620                 }
2621         }
2622
2623         MUTATOR_CALLHOOK(PlayerPreThink, this);
2624
2625         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2626         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2627         {
2628                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2629                 {
2630                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2631                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2632                         {
2633                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2634                         }
2635                         else if(!it.owner)
2636                         {
2637                                 if(!it.team || SAME_TEAM(this, it))
2638                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2639                                 else if(autocvar_g_vehicles_steal)
2640                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2641                         }
2642                 });
2643
2644                 this.last_vehiclecheck = time + 1;
2645         }
2646
2647         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2648         {
2649                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2650                         PlayerUseKey(this);
2651                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2652         }
2653
2654         if (IS_REAL_CLIENT(this))
2655                 PrintWelcomeMessage(this);
2656
2657         if (IS_PLAYER(this)) {
2658                 if(!PlayerThink(this))
2659                         return;
2660         }
2661         else if (game_stopped || intermission_running) {
2662                 if(intermission_running)
2663                         IntermissionThink(this);
2664                 return;
2665         }
2666         else if (IS_OBSERVER(this)) {
2667                 ObserverThink(this);
2668         }
2669         else if (IS_SPEC(this)) {
2670                 SpectatorThink(this);
2671         }
2672
2673         // WEAPONTODO: Add weapon request for this
2674         if (!zoomstate_set) {
2675                 bool wep_zoomed = false;
2676                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2677                 {
2678                         .entity weaponentity = weaponentities[slot];
2679                         Weapon thiswep = this.(weaponentity).m_weapon;
2680                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2681                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2682                 }
2683                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2684     }
2685
2686         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2687         {
2688                 CS(this).teamkill_soundtime = 0;
2689
2690                 entity e = CS(this).teamkill_soundsource;
2691                 entity oldpusher = e.pusher;
2692                 e.pusher = this;
2693                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2694                 e.pusher = oldpusher;
2695         }
2696
2697         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2698                 CS(this).taunt_soundtime = 0;
2699                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2700         }
2701
2702         target_voicescript_next(this);
2703
2704         // WEAPONTODO: Move into weaponsystem somehow
2705         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2706         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2707         {
2708                 .entity weaponentity = weaponentities[slot];
2709                 if(this.(weaponentity).m_weapon == WEP_Null)
2710                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2711         }
2712 }
2713
2714 void DrownPlayer(entity this)
2715 {
2716         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2717                 return;
2718
2719         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2720         {
2721                 if(this.air_finished < time)
2722                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2723                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2724         }
2725         else if (this.air_finished < time)
2726         {       // drown!
2727                 if (this.pain_finished < time)
2728                 {
2729                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2730                         this.pain_finished = time + 0.5;
2731                 }
2732         }
2733 }
2734
2735 .bool move_qcphysics;
2736
2737 void Player_Physics(entity this)
2738 {
2739         set_movetype(this, this.move_movetype);
2740
2741         if(!this.move_qcphysics)
2742                 return;
2743
2744         if(!frametime && !CS(this).pm_frametime)
2745                 return;
2746
2747         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2748
2749         CS(this).pm_frametime = 0;
2750 }
2751
2752 /*
2753 =============
2754 PlayerPostThink
2755
2756 Called every frame for each client after the physics are run
2757 =============
2758 */
2759 void PlayerPostThink (entity this)
2760 {
2761         Player_Physics(this);
2762
2763         if (sv_maxidle > 0)
2764         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2765         if (IS_REAL_CLIENT(this))
2766         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2767         {
2768                 int totalClients = 0;
2769                 if(sv_maxidle_slots > 0)
2770                 {
2771                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2772                         {
2773                                 ++totalClients;
2774                         });
2775                 }
2776
2777                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2778                 { /* do nothing */ }
2779                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2780                 {
2781                         if (CS(this).idlekick_lasttimeleft)
2782                         {
2783                                 CS(this).idlekick_lasttimeleft = 0;
2784                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2785                         }
2786                 }
2787                 else
2788                 {
2789                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2790                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2791                                 if (!CS(this).idlekick_lasttimeleft)
2792                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2793                         }
2794                         if (timeleft <= 0) {
2795                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2796                                 dropclient(this);
2797                                 return;
2798                         }
2799                         else if (timeleft <= 10) {
2800                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2801                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2802                 }
2803                                 CS(this).idlekick_lasttimeleft = timeleft;
2804                         }
2805                 }
2806         }
2807
2808         CheatFrame(this);
2809
2810         if (game_stopped)
2811         {
2812                 this.solid = SOLID_NOT;
2813                 this.takedamage = DAMAGE_NO;
2814                 set_movetype(this, MOVETYPE_NONE);
2815         }
2816
2817         if (IS_PLAYER(this)) {
2818                 if(this.death_time == time && IS_DEAD(this))
2819                 {
2820                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2821                         // once all the damage events of this frame have been processed with normal size
2822                         this.maxs.z = 5;
2823                         setsize(this, this.mins, this.maxs);
2824                 }
2825                 DrownPlayer(this);
2826                 UpdateChatBubble(this);
2827                 if (CS(this).impulse) ImpulseCommands(this);
2828                 if (game_stopped)
2829                 {
2830                         CSQCMODEL_AUTOUPDATE(this);
2831                         return;
2832                 }
2833                 GetPressedKeys(this);
2834         }
2835
2836         if (this.waypointsprite_attachedforcarrier) {
2837             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2838                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2839     }
2840
2841         playerdemo_write(this);
2842
2843         CSQCMODEL_AUTOUPDATE(this);
2844 }
2845
2846 // hack to copy the button fields from the client entity to the Client State
2847 void PM_UpdateButtons(entity this, entity store)
2848 {
2849         if(this.impulse)
2850                 store.impulse = this.impulse;
2851         this.impulse = 0;
2852
2853         bool typing = this.buttonchat;
2854
2855         store.button0 = (typing) ? 0 : this.button0;
2856         //button1?!
2857         store.button2 = (typing) ? 0 : this.button2;
2858         store.button3 = (typing) ? 0 : this.button3;
2859         store.button4 = this.button4;
2860         store.button5 = (typing) ? 0 : this.button5;
2861         store.button6 = this.button6;
2862         store.button7 = this.button7;
2863         store.button8 = this.button8;
2864         store.button9 = this.button9;
2865         store.button10 = this.button10;
2866         store.button11 = this.button11;
2867         store.button12 = this.button12;
2868         store.button13 = this.button13;
2869         store.button14 = this.button14;
2870         store.button15 = this.button15;
2871         store.button16 = this.button16;
2872         store.buttonuse = this.buttonuse;
2873         store.buttonchat = this.buttonchat;
2874
2875         store.cursor_active = this.cursor_active;
2876         store.cursor_screen = this.cursor_screen;
2877         store.cursor_trace_start = this.cursor_trace_start;
2878         store.cursor_trace_endpos = this.cursor_trace_endpos;
2879         store.cursor_trace_ent = this.cursor_trace_ent;
2880
2881         store.ping = this.ping;
2882         store.ping_packetloss = this.ping_packetloss;
2883         store.ping_movementloss = this.ping_movementloss;
2884
2885         store.v_angle = this.v_angle;
2886         store.movement = (typing) ? '0 0 0' : this.movement;
2887 }
2888
2889 NET_HANDLE(fpsreport, bool)
2890 {
2891         int fps = ReadShort();
2892         PlayerScore_Set(sender, SP_FPS, fps);
2893         return true;
2894 }