qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/lms/sv_lms.qh>
  10 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  11 #include <common/items/_mod.qh>
  12 #include <common/items/inventory.qh>
  13 #include <common/mapobjects/func/conveyor.qh>
  14 #include <common/mapobjects/func/ladder.qh>
  15 #include <common/mapobjects/subs.qh>
  16 #include <common/mapobjects/target/spawnpoint.qh>
  17 #include <common/mapobjects/teleporters.qh>
  18 #include <common/mapobjects/trigger/counter.qh>
  19 #include <common/mapobjects/trigger/secret.qh>
  20 #include <common/mapobjects/trigger/swamp.qh>
  21 #include <common/mapobjects/triggers.qh>
  22 #include <common/minigames/sv_minigames.qh>
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  25 #include <common/mutators/mutator/nades/nades.qh>
  26 #include <common/mutators/mutator/overkill/oknex.qh>
  27 #include <common/mutators/mutator/status_effects/_mod.qh>
  28 #include <common/mutators/mutator/waypoints/all.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/playerstats.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/resources.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 /** putting a client as observer in the server */
 239 void PutObserverInServer(entity this)
 240 {
 241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         ReadyCount();
 257                 }
 258                 entcs_update_players(this);
 259         }
 260
 261         entity spot = SelectSpawnPoint(this, true);
 262         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 263         this.angles = vec2(spot.angles);
 264         this.fixangle = true;
 265         // offset it so that the spectator spawns higher off the ground, looks better this way
 266         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 267         if (IS_REAL_CLIENT(this))
 268         {
 269                 msg_entity = this;
 270                 WriteByte(MSG_ONE, SVC_SETVIEW);
 271                 WriteEntity(MSG_ONE, this);
 272         }
 273         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 274         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 275         if(!autocvar_g_debug_globalsounds)
 276         {
 277                 // needed for player sounds
 278                 this.model = "";
 279                 FixPlayermodel(this);
 280         }
 281         setmodel(this, MDL_Null);
 282         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 283         this.view_ofs = '0 0 0';
 284
 285         RemoveGrapplingHooks(this);
 286         Portal_ClearAll(this);
 287         Unfreeze(this, false);
 288         SetSpectatee(this, NULL);
 289
 290         if (this.alivetime)
 291         {
 292                 if (!warmup_stage)
 293                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 294                 this.alivetime = 0;
 295         }
 296
 297         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 298
 299         WaypointSprite_PlayerDead(this);
 300
 301         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 302                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310         if(this.monster_attack)
 311                 IL_REMOVE(g_monster_targets, this);
 312         this.monster_attack = false;
 313         STAT(HUD, this) = HUD_NORMAL;
 314         TRANSMUTE(Observer, this);
 315         this.iscreature = false;
 316         this.teleportable = TELEPORT_SIMPLE;
 317         if(this.damagedbycontents)
 318                 IL_REMOVE(g_damagedbycontents, this);
 319         this.damagedbycontents = false;
 320         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 321         SetSpectatee_status(this, etof(this));
 322         this.takedamage = DAMAGE_NO;
 323         this.solid = SOLID_NOT;
 324         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 325         this.flags = FL_CLIENT | FL_NOTARGET;
 326         this.effects = 0;
 327         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 328         this.pauserotarmor_finished = 0;
 329         this.pauserothealth_finished = 0;
 330         this.pauseregen_finished = 0;
 331         this.damageforcescale = 0;
 332         this.death_time = 0;
 333         this.respawn_flags = 0;
 334         this.respawn_time = 0;
 335         STAT(RESPAWN_TIME, this) = 0;
 336         this.alpha = 0;
 337         this.scale = 0;
 338         this.fade_time = 0;
 339         this.pain_finished = 0;
 340         STAT(AIR_FINISHED, this) = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         UNSET_DUCKED(this);
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.event_damage = func_null;
 376         this.event_heal = func_null;
 377
 378         for(int slot = 0; slot < MAX_AXH; ++slot)
 379         {
 380                 entity axh = this.(AuxiliaryXhair[slot]);
 381                 this.(AuxiliaryXhair[slot]) = NULL;
 382
 383                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 384                         delete(axh);
 385         }
 386
 387         if (mutator_returnvalue)
 388         {
 389                 // mutator prevents resetting teams+score
 390         }
 391         else
 392         {
 393                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 394                 this.frags = FRAGS_SPECTATOR;
 395         }
 396
 397         bot_relinkplayerlist();
 398
 399         if (CS(this).just_joined)
 400                 CS(this).just_joined = false;
 401 }
 402
 403 int player_getspecies(entity this)
 404 {
 405         get_model_parameters(this.model, this.skin);
 406         int s = get_model_parameters_species;
 407         get_model_parameters(string_null, 0);
 408         if (s < 0) return SPECIES_HUMAN;
 409         return s;
 410 }
 411
 412 .float model_randomizer;
 413 void FixPlayermodel(entity player)
 414 {
 415         string defaultmodel = "";
 416         int defaultskin = 0;
 417         if(autocvar_sv_defaultcharacter)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(defaultmodel == "")
 431                 {
 432                         defaultmodel = autocvar_sv_defaultplayermodel;
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434                 }
 435
 436                 int n = tokenize_console(defaultmodel);
 437                 if(n > 0)
 438                 {
 439                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 440                         // However, do NOT randomize if the player-selected model is in the list.
 441                         for (int i = 0; i < n; ++i)
 442                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 443                                         defaultmodel = argv(i);
 444                 }
 445
 446                 int i = strstrofs(defaultmodel, ":", 0);
 447                 if(i >= 0)
 448                 {
 449                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 450                         defaultmodel = substring(defaultmodel, 0, i);
 451                 }
 452         }
 453         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 454         {
 455                 if(teamplay)
 456                 {
 457                         switch(player.team)
 458                         {
 459                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 460                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 461                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 462                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 463                         }
 464                 }
 465
 466                 if(!defaultskin)
 467                         defaultskin = autocvar_sv_defaultplayerskin;
 468         }
 469
 470         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 471         defaultmodel = M_ARGV(0, string);
 472         defaultskin = M_ARGV(1, int);
 473
 474         bool chmdl = false;
 475         int oldskin;
 476         if(defaultmodel != "")
 477         {
 478                 if (defaultmodel != player.model)
 479                 {
 480                         vector m1 = player.mins;
 481                         vector m2 = player.maxs;
 482                         setplayermodel (player, defaultmodel);
 483                         setsize (player, m1, m2);
 484                         chmdl = true;
 485                 }
 486
 487                 oldskin = player.skin;
 488                 player.skin = defaultskin;
 489         } else {
 490                 if (player.playermodel != player.model || player.playermodel == "")
 491                 {
 492                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 493                         vector m1 = player.mins;
 494                         vector m2 = player.maxs;
 495                         setplayermodel (player, player.playermodel);
 496                         setsize (player, m1, m2);
 497                         chmdl = true;
 498                 }
 499
 500                 if(!autocvar_sv_defaultcharacterskin)
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = stof(player.playerskin);
 504                 }
 505                 else
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = defaultskin;
 509                 }
 510         }
 511
 512         if(chmdl || oldskin != player.skin) // model or skin has changed
 513         {
 514                 player.species = player_getspecies(player); // update species
 515                 if(!autocvar_g_debug_globalsounds)
 516                         UpdatePlayerSounds(player); // update skin sounds
 517         }
 518
 519         if(!teamplay)
 520                 if(strlen(autocvar_sv_defaultplayercolors))
 521                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 522                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 523 }
 524
 525 void PutPlayerInServer(entity this)
 526 {
 527         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 528
 529         PlayerState_attach(this);
 530         accuracy_resend(this);
 531
 532         if (this.team < 0)
 533                 TeamBalance_JoinBestTeam(this);
 534
 535         entity spot = SelectSpawnPoint(this, false);
 536         if (!spot) {
 537                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 538                 return; // spawn failed
 539         }
 540
 541         TRANSMUTE(Player, this);
 542
 543         CS(this).wasplayer = true;
 544         this.iscreature = true;
 545         this.teleportable = TELEPORT_NORMAL;
 546         if(!this.damagedbycontents)
 547                 IL_PUSH(g_damagedbycontents, this);
 548         this.damagedbycontents = true;
 549         set_movetype(this, MOVETYPE_WALK);
 550         this.solid = SOLID_SLIDEBOX;
 551         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 552         if (autocvar_g_playerclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 554         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 556         this.frags = FRAGS_PLAYER;
 557         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 558         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 559         if (autocvar__notarget)
 560                 this.flags |= FL_NOTARGET;
 561         this.takedamage = DAMAGE_AIM;
 562         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 563
 564         if (warmup_stage) {
 565                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 566                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 567                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 568                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 569                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 570                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 571                 SetResource(this, RES_HEALTH, warmup_start_health);
 572                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 573                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 574         } else {
 575                 SetResource(this, RES_SHELLS, start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, start_health);
 582                 SetResource(this, RES_ARMOR, start_armorvalue);
 583                 STAT(WEAPONS, this) = start_weapons;
 584                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 585                 {
 586                         GiveRandomWeapons(this, random_start_weapons_count,
 587                                 autocvar_g_random_start_weapons, random_start_ammo);
 588                 }
 589         }
 590         SetSpectatee_status(this, 0);
 591
 592         PS(this).dual_weapons = '0 0 0';
 593
 594         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 595                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 596
 597         this.items = start_items;
 598
 599         float shieldtime = time + autocvar_g_spawnshieldtime;
 600
 601         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 602         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 603         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 604         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 605         if (!sv_ready_restart_after_countdown && time < game_starttime)
 606         {
 607                 float f = game_starttime - time;
 608                 shieldtime += f;
 609                 this.pauserotarmor_finished += f;
 610                 this.pauserothealth_finished += f;
 611                 this.pauseregen_finished += f;
 612         }
 613
 614         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 615
 616         this.damageforcescale = autocvar_g_player_damageforcescale;
 617         this.death_time = 0;
 618         this.respawn_flags = 0;
 619         this.respawn_time = 0;
 620         STAT(RESPAWN_TIME, this) = 0;
 621         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 622         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 623         this.fade_time = 0;
 624         this.pain_finished = 0;
 625         this.pushltime = 0;
 626         setthink(this, func_null); // players have no think function
 627         this.nextthink = 0;
 628         this.dmg_team = 0;
 629         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 630
 631         this.deadflag = DEAD_NO;
 632
 633         this.angles = spot.angles;
 634         this.angles_z = 0; // never spawn tilted even if the spot says to
 635         if (IS_BOT_CLIENT(this))
 636         {
 637                 this.v_angle = this.angles;
 638                 bot_aim_reset(this);
 639         }
 640         this.fixangle = true; // turn this way immediately
 641         this.oldvelocity = this.velocity = '0 0 0';
 642         this.avelocity = '0 0 0';
 643         this.punchangle = '0 0 0';
 644         this.punchvector = '0 0 0';
 645
 646         STAT(REVIVE_PROGRESS, this) = 0;
 647         this.revival_time = 0;
 648
 649         STAT(AIR_FINISHED, this) = 0;
 650         this.waterlevel = WATERLEVEL_NONE;
 651         this.watertype = CONTENT_EMPTY;
 652
 653         entity spawnevent = new_pure(spawnevent);
 654         spawnevent.owner = this;
 655         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 656
 657         // Cut off any still running player sounds.
 658         stopsound(this, CH_PLAYER_SINGLE);
 659
 660         this.model = "";
 661         FixPlayermodel(this);
 662         this.drawonlytoclient = NULL;
 663
 664         this.viewloc = NULL;
 665
 666         for(int slot = 0; slot < MAX_AXH; ++slot)
 667         {
 668                 entity axh = this.(AuxiliaryXhair[slot]);
 669                 this.(AuxiliaryXhair[slot]) = NULL;
 670
 671                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 672                         delete(axh);
 673         }
 674
 675         this.spawnpoint_targ = NULL;
 676
 677         UNSET_DUCKED(this);
 678         this.view_ofs = STAT(PL_VIEW_OFS, this);
 679         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 680         this.spawnorigin = spot.origin;
 681         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 682         // don't reset back to last position, even if new position is stuck in solid
 683         this.oldorigin = this.origin;
 684         if(this.conveyor)
 685                 IL_REMOVE(g_conveyed, this);
 686         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 687         if(this.swampslug)
 688                 IL_REMOVE(g_swamped, this);
 689         this.swampslug = NULL;
 690         this.swamp_interval = 0;
 691         if(this.ladder_entity)
 692                 IL_REMOVE(g_ladderents, this);
 693         this.ladder_entity = NULL;
 694         IL_EACH(g_counters, it.realowner == this,
 695         {
 696                 delete(it);
 697         });
 698         STAT(HUD, this) = HUD_NORMAL;
 699
 700         this.event_damage = PlayerDamage;
 701         this.event_heal = PlayerHeal;
 702
 703         this.draggable = func_null;
 704
 705         if(!this.bot_attack)
 706                 IL_PUSH(g_bot_targets, this);
 707         this.bot_attack = true;
 708         if(!this.monster_attack)
 709                 IL_PUSH(g_monster_targets, this);
 710         this.monster_attack = true;
 711         navigation_dynamicgoal_init(this, false);
 712
 713         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 714
 715         // player was spectator
 716         if (CS(this).killcount == FRAGS_SPECTATOR) {
 717                 PlayerScore_Clear(this);
 718                 CS(this).killcount = 0;
 719                 CS(this).startplaytime = time;
 720         }
 721
 722         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 723         {
 724                 .entity weaponentity = weaponentities[slot];
 725                 CL_SpawnWeaponentity(this, weaponentity);
 726         }
 727         this.alpha = default_player_alpha;
 728         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 729         this.exteriorweaponentity.alpha = default_weapon_alpha;
 730
 731         this.speedrunning = false;
 732
 733         this.counter_cnt = 0;
 734         this.fragsfilter_cnt = 0;
 735
 736         target_voicescript_clear(this);
 737
 738         // reset fields the weapons may use
 739         FOREACH(Weapons, true, {
 740                 it.wr_resetplayer(it, this);
 741                         // reload all reloadable weapons
 742                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 743                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744                         {
 745                                 .entity weaponentity = weaponentities[slot];
 746                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 747                         }
 748                 }
 749         });
 750
 751         Unfreeze(this, false);
 752
 753         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 754
 755         {
 756                 string s = spot.target;
 757                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 758                         spot.target = string_null;
 759                 SUB_UseTargets(spot, this, NULL);
 760                 if(g_assault || g_race)
 761                         spot.target = s;
 762         }
 763
 764         if (autocvar_spawn_debug)
 765         {
 766                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 767                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 768         }
 769
 770         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 771         {
 772                 .entity weaponentity = weaponentities[slot];
 773                 entity w_ent = this.(weaponentity);
 774                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 775                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 776                 else
 777                         w_ent.m_switchweapon = WEP_Null;
 778                 w_ent.m_weapon = WEP_Null;
 779                 w_ent.weaponname = "";
 780                 w_ent.m_switchingweapon = WEP_Null;
 781                 w_ent.cnt = -1;
 782         }
 783
 784         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 785
 786         if (CS(this).impulse) ImpulseCommands(this);
 787
 788         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 789         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 790         {
 791                 .entity weaponentity = weaponentities[slot];
 792                 W_WeaponFrame(this, weaponentity);
 793         }
 794
 795         if (!warmup_stage && !this.alivetime)
 796                 this.alivetime = time;
 797
 798         antilag_clear(this, CS(this));
 799 }
 800
 801 /** Called when a client spawns in the server */
 802 void PutClientInServer(entity this)
 803 {
 804         if (IS_BOT_CLIENT(this)) {
 805                 TRANSMUTE(Player, this);
 806         } else if (IS_REAL_CLIENT(this)) {
 807                 msg_entity = this;
 808                 WriteByte(MSG_ONE, SVC_SETVIEW);
 809                 WriteEntity(MSG_ONE, this);
 810         }
 811         if (game_stopped)
 812                 TRANSMUTE(Observer, this);
 813
 814         SetSpectatee(this, NULL);
 815
 816         // reset player keys
 817         if(PS(this))
 818                 PS(this).itemkeys = 0;
 819
 820         MUTATOR_CALLHOOK(PutClientInServer, this);
 821
 822         if (IS_OBSERVER(this)) {
 823                 PutObserverInServer(this);
 824         } else if (IS_PLAYER(this)) {
 825                 PutPlayerInServer(this);
 826         }
 827
 828         bot_relinkplayerlist();
 829 }
 830
 831 // TODO do we need all these fields, or should we stop autodetecting runtime
 832 // changes and just have a console command to update this?
 833 bool ClientInit_SendEntity(entity this, entity to, int sf)
 834 {
 835         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 836         return = true;
 837         msg_entity = to;
 838         // MSG_INIT replacement
 839         // TODO: make easier to use
 840         Registry_send_all();
 841         W_PROP_reload(MSG_ONE, to);
 842         ClientInit_misc(this);
 843         MUTATOR_CALLHOOK(Ent_Init);
 844 }
 845 void ClientInit_misc(entity this)
 846 {
 847         int channel = MSG_ONE;
 848         WriteHeader(channel, ENT_CLIENT_INIT);
 849         WriteByte(channel, g_nexball_meter_period * 32);
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 852         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 853         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 856         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 857         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 858
 859         if(autocvar_sv_foginterval && world.fog != "")
 860                 WriteString(channel, world.fog);
 861         else
 862                 WriteString(channel, "");
 863         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 864         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 865         WriteByte(channel, serverflags);
 866         WriteCoord(channel, autocvar_g_trueaim_minrange);
 867 }
 868
 869 void ClientInit_CheckUpdate(entity this)
 870 {
 871         this.nextthink = time;
 872         if(this.count != autocvar_g_balance_armor_blockpercent)
 873         {
 874                 this.count = autocvar_g_balance_armor_blockpercent;
 875                 this.SendFlags |= 1;
 876         }
 877         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 878         {
 879                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 880                 this.SendFlags |= 1;
 881         }
 882 }
 883
 884 void ClientInit_Spawn()
 885 {
 886         entity e = new_pure(clientinit);
 887         setthink(e, ClientInit_CheckUpdate);
 888         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 889
 890         ClientInit_CheckUpdate(e);
 891 }
 892
 893 /*
 894 =============
 895 SetNewParms
 896 =============
 897 */
 898 void SetNewParms ()
 899 {
 900         // initialize parms for a new player
 901         parm1 = -(86400 * 366);
 902
 903         MUTATOR_CALLHOOK(SetNewParms);
 904 }
 905
 906 /*
 907 =============
 908 SetChangeParms
 909 =============
 910 */
 911 void SetChangeParms (entity this)
 912 {
 913         // save parms for level change
 914         parm1 = CS(this).parm_idlesince - time;
 915
 916         MUTATOR_CALLHOOK(SetChangeParms);
 917 }
 918
 919 /*
 920 =============
 921 DecodeLevelParms
 922 =============
 923 */
 924 void DecodeLevelParms(entity this)
 925 {
 926         // load parms
 927         CS(this).parm_idlesince = parm1;
 928         if (CS(this).parm_idlesince == -(86400 * 366))
 929                 CS(this).parm_idlesince = time;
 930
 931         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 932         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 933
 934         MUTATOR_CALLHOOK(DecodeLevelParms);
 935 }
 936
 937 void FixClientCvars(entity e)
 938 {
 939         // send prediction settings to the client
 940         stuffcmd(e, "\nin_bindmap 0 0\n");
 941         if(autocvar_g_antilag == 3) // client side hitscan
 942                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 943         if(autocvar_sv_gentle)
 944                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 945
 946         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 947         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 948
 949         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 950
 951         MUTATOR_CALLHOOK(FixClientCvars, e);
 952 }
 953
 954 bool findinlist_abbrev(string tofind, string list)
 955 {
 956         if(list == "" || tofind == "")
 957                 return false; // empty list or search, just return
 958
 959         // this function allows abbreviated strings!
 960         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 961         {
 962                 return true;
 963         });
 964
 965         return false;
 966 }
 967
 968 bool PlayerInIPList(entity p, string iplist)
 969 {
 970         // some safety checks (never allow local?)
 971         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 972                 return false;
 973
 974         return findinlist_abbrev(p.netaddress, iplist);
 975 }
 976
 977 bool PlayerInIDList(entity p, string idlist)
 978 {
 979         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 980         if(!p.crypto_idfp)
 981                 return false;
 982
 983         return findinlist_abbrev(p.crypto_idfp, idlist);
 984 }
 985
 986 bool PlayerInList(entity player, string list)
 987 {
 988         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 989 }
 990
 991 #ifdef DP_EXT_PRECONNECT
 992 /*
 993 =============
 994 ClientPreConnect
 995
 996 Called once (not at each match start) when a client begins a connection to the server
 997 =============
 998 */
 999 void ClientPreConnect(entity this)
1000 {
1001         if(autocvar_sv_eventlog)
1002         {
1003                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1004                         this.playerid,
1005                         etof(this),
1006                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1007                 ));
1008         }
1009 }
1010 #endif
1011
1012 string GetClientVersionMessage(entity this)
1013 {
1014         if (CS(this).version_mismatch) {
1015                 if(CS(this).version < autocvar_gameversion) {
1016                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1017                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1018                 } else {
1019                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1020                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1021                 }
1022         } else {
1023                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1024         }
1025 }
1026
1027 string getwelcomemessage(entity this)
1028 {
1029         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1030         string modifications = M_ARGV(0, string);
1031
1032         if(g_weaponarena)
1033         {
1034                 if(g_weaponarena_random)
1035                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1036                 else
1037                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1038         }
1039         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1040                 modifications = strcat(modifications, ", No start weapons");
1041         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1042                 modifications = strcat(modifications, ", Low gravity");
1043         if(g_weapon_stay && !g_cts)
1044                 modifications = strcat(modifications, ", Weapons stay");
1045         if(autocvar_g_jetpack)
1046                 modifications = strcat(modifications, ", Jet pack");
1047         modifications = substring(modifications, 2, strlen(modifications) - 2);
1048
1049         string versionmessage = GetClientVersionMessage(this);
1050         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1051
1052         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1053
1054         if(modifications != "")
1055                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1056
1057         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1058         {
1059                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1060                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1061         }
1062
1063         if (cache_mutatormsg != "") {
1064                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1065         }
1066
1067         string mutator_msg = "";
1068         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1069         mutator_msg = M_ARGV(0, string);
1070
1071         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1072
1073         string motd = autocvar_sv_motd;
1074         if (motd != "") {
1075                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1076         }
1077         return s;
1078 }
1079
1080 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1081
1082 /**
1083 =============
1084 ClientConnect
1085
1086 Called when a client connects to the server
1087 =============
1088 */
1089 void ClientConnect(entity this)
1090 {
1091         if (Ban_MaybeEnforceBanOnce(this)) return;
1092         assert(!IS_CLIENT(this), return);
1093         this.flags |= FL_CLIENT;
1094         assert(player_count >= 0, player_count = 0);
1095
1096         TRANSMUTE(Client, this);
1097         CS(this).version_nagtime = time + 10 + random() * 10;
1098
1099         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1100
1101         bot_clientconnect(this);
1102
1103         Player_DetermineForcedTeam(this);
1104
1105         TRANSMUTE(Observer, this);
1106
1107         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1108
1109         // always track bots, don't ask for cl_allow_uidtracking
1110         if (IS_BOT_CLIENT(this))
1111                 PlayerStats_GameReport_AddPlayer(this);
1112         else
1113                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1114
1115         if (autocvar_sv_eventlog)
1116                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1117
1118         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1119
1120         stuffcmd(this, clientstuff, "\n");
1121         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1122
1123         FixClientCvars(this);
1124
1125         // get version info from player
1126         stuffcmd(this, "cmd clientversion $gameversion\n");
1127
1128         // notify about available teams
1129         if (teamplay)
1130         {
1131                 entity balance = TeamBalance_CheckAllowedTeams(this);
1132                 int t = TeamBalance_GetAllowedTeams(balance);
1133                 TeamBalance_Destroy(balance);
1134                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1135         }
1136         else
1137         {
1138                 stuffcmd(this, "set _teams_available 0\n");
1139         }
1140
1141         bot_relinkplayerlist();
1142
1143         CS(this).spectatortime = time;
1144         if (blockSpectators)
1145         {
1146                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1147         }
1148
1149         CS(this).jointime = time;
1150
1151         if (IS_REAL_CLIENT(this))
1152         {
1153                 if (g_weaponarena_weapons == WEPSET(TUBA))
1154                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1155         }
1156
1157         if (!autocvar_sv_foginterval && world.fog != "")
1158                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1159
1160         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1161                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1162                         send_CSQC_teamnagger();
1163
1164         CSQCMODEL_AUTOINIT(this);
1165
1166         CS(this).model_randomizer = random();
1167
1168         if (IS_REAL_CLIENT(this))
1169                 sv_notice_join(this);
1170
1171         this.move_qcphysics = autocvar_sv_qcphysics;
1172
1173         // update physics stats (players can spawn before physics runs)
1174         Physics_UpdateStats(this);
1175
1176         IL_EACH(g_initforplayer, it.init_for_player, {
1177                 it.init_for_player(it, this);
1178         });
1179
1180         Handicap_Initialize(this);
1181
1182         MUTATOR_CALLHOOK(ClientConnect, this);
1183
1184         if (IS_REAL_CLIENT(this))
1185         {
1186                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1187                 {
1188                         CS(this).motd_actived_time = -1;
1189                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1190                 }
1191         }
1192 }
1193 /*
1194 =============
1195 ClientDisconnect
1196
1197 Called when a client disconnects from the server
1198 =============
1199 */
1200 .entity chatbubbleentity;
1201 void player_powerups_remove_all(entity this);
1202
1203 void ClientDisconnect(entity this)
1204 {
1205         assert(IS_CLIENT(this), return);
1206
1207         PlayerStats_GameReport_FinalizePlayer(this);
1208         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1209         if (CS(this).active_minigame) part_minigame(this);
1210         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1211
1212         if (autocvar_sv_eventlog)
1213                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1214
1215         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1216
1217         if(IS_SPEC(this))
1218                 SetSpectatee(this, NULL);
1219
1220         MUTATOR_CALLHOOK(ClientDisconnect, this);
1221
1222         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1223         strfree(CS_CVAR(this).weaponorder_byimpulse);
1224         ClientState_detach(this);
1225
1226         Portal_ClearAll(this);
1227
1228         Unfreeze(this, false);
1229
1230         RemoveGrapplingHooks(this);
1231
1232         // Here, everything has been done that requires this player to be a client.
1233
1234         this.flags &= ~FL_CLIENT;
1235
1236         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1237         if (this.killindicator) delete(this.killindicator);
1238
1239         IL_EACH(g_counters, it.realowner == this,
1240         {
1241                 delete(it);
1242         });
1243
1244         WaypointSprite_PlayerGone(this);
1245
1246         bot_relinkplayerlist();
1247
1248         strfree(this.clientstatus);
1249         if (this.personal) delete(this.personal);
1250
1251         this.playerid = 0;
1252         ReadyCount();
1253         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1254
1255         player_powerups_remove_all(this); // stop powerup sound
1256
1257         ONREMOVE(this);
1258 }
1259
1260 void ChatBubbleThink(entity this)
1261 {
1262         this.nextthink = time;
1263         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1264         {
1265                 if(this.owner) // but why can that ever be NULL?
1266                         this.owner.chatbubbleentity = NULL;
1267                 delete(this);
1268                 return;
1269         }
1270
1271         this.mdl = "";
1272
1273         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1274         {
1275                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1276                         this.mdl = "models/sprites/minigame_busy.iqm";
1277                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1278                         this.mdl = "models/misc/chatbubble.spr";
1279         }
1280
1281         if ( this.model != this.mdl )
1282                 _setmodel(this, this.mdl);
1283
1284 }
1285
1286 void UpdateChatBubble(entity this)
1287 {
1288         if (this.alpha < 0)
1289                 return;
1290         // spawn a chatbubble entity if needed
1291         if (!this.chatbubbleentity)
1292         {
1293                 this.chatbubbleentity = new(chatbubbleentity);
1294                 this.chatbubbleentity.owner = this;
1295                 this.chatbubbleentity.exteriormodeltoclient = this;
1296                 setthink(this.chatbubbleentity, ChatBubbleThink);
1297                 this.chatbubbleentity.nextthink = time;
1298                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1299                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1300                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1301                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1302                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1303                 //this.chatbubbleentity.model = "";
1304                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1305         }
1306 }
1307
1308 void calculate_player_respawn_time(entity this)
1309 {
1310         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1311                 return;
1312
1313         float gametype_setting_tmp;
1314         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1315         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1316         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1317         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1318         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1319         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1320
1321         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1322         if (teamplay)
1323         {
1324                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1325                         if(it.team == this.team)
1326                                 ++pcount;
1327                 });
1328                 if (sdelay_small_count == 0)
1329                         sdelay_small_count = 1;
1330                 if (sdelay_large_count == 0)
1331                         sdelay_large_count = 1;
1332         }
1333         else
1334         {
1335                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1336                         ++pcount;
1337                 });
1338                 if (sdelay_small_count == 0)
1339                 {
1340                         if (IS_INDEPENDENT_PLAYER(this))
1341                         {
1342                                 // Players play independently. No point in requiring enemies.
1343                                 sdelay_small_count = 1;
1344                         }
1345                         else
1346                         {
1347                                 // Players play AGAINST each other. Enemies required.
1348                                 sdelay_small_count = 2;
1349                         }
1350                 }
1351                 if (sdelay_large_count == 0)
1352                 {
1353                         if (IS_INDEPENDENT_PLAYER(this))
1354                         {
1355                                 // Players play independently. No point in requiring enemies.
1356                                 sdelay_large_count = 1;
1357                         }
1358                         else
1359                         {
1360                                 // Players play AGAINST each other. Enemies required.
1361                                 sdelay_large_count = 2;
1362                         }
1363                 }
1364         }
1365
1366         float sdelay;
1367
1368         if (pcount <= sdelay_small_count)
1369                 sdelay = sdelay_small;
1370         else if (pcount >= sdelay_large_count)
1371                 sdelay = sdelay_large;
1372         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1373                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1374
1375         if(waves)
1376                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1377         else
1378                 this.respawn_time = time + sdelay;
1379
1380         if(sdelay < sdelay_max)
1381                 this.respawn_time_max = time + sdelay_max;
1382         else
1383                 this.respawn_time_max = this.respawn_time;
1384
1385         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1386                 this.respawn_countdown = 10; // first number to count down from is 10
1387         else
1388                 this.respawn_countdown = -1; // do not count down
1389
1390         if(autocvar_g_forced_respawn)
1391                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1392 }
1393
1394 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1395 // added to the model skins
1396 /*void UpdateColorModHack()
1397 {
1398         float c;
1399         c = this.clientcolors & 15;
1400         // LordHavoc: only bothering to support white, green, red, yellow, blue
1401              if (!teamplay) this.colormod = '0 0 0';
1402         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1403         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1404         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1405         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1406         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1407         else this.colormod = '1 1 1';
1408 }*/
1409
1410 void respawn(entity this)
1411 {
1412         bool damagedbycontents_prev = this.damagedbycontents;
1413         if(this.alpha >= 0)
1414         {
1415                 if(autocvar_g_respawn_ghosts)
1416                 {
1417                         this.solid = SOLID_NOT;
1418                         this.takedamage = DAMAGE_NO;
1419                         this.damagedbycontents = false;
1420                         set_movetype(this, MOVETYPE_FLY);
1421                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1422                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1423                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1424                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1425                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1426                         if(autocvar_g_respawn_ghosts_time > 0)
1427                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1428                 }
1429                 else
1430                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1431         }
1432
1433         CopyBody(this, 1);
1434         this.damagedbycontents = damagedbycontents_prev;
1435
1436         this.effects |= EF_NODRAW; // prevent another CopyBody
1437         PutClientInServer(this);
1438 }
1439
1440 void play_countdown(entity this, float finished, Sound samp)
1441 {
1442         TC(Sound, samp);
1443         if(IS_REAL_CLIENT(this))
1444                 if(floor(finished - time - frametime) != floor(finished - time))
1445                         if(finished - time < 6)
1446                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1447 }
1448
1449 void player_powerups_remove_all(entity this)
1450 {
1451         if (this.items & IT_SUPERWEAPON)
1452         {
1453                 // don't play the poweroff sound when the game restarts or the player disconnects
1454                 if (time > game_starttime + 1 && IS_CLIENT(this))
1455                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1456                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1457                 this.items -= (this.items & IT_SUPERWEAPON);
1458         }
1459 }
1460
1461 void player_powerups(entity this)
1462 {
1463         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1464                 this.modelflags |= MF_ROCKET;
1465         else
1466                 this.modelflags &= ~MF_ROCKET;
1467
1468         this.effects &= ~EF_NODEPTHTEST;
1469
1470         if (IS_DEAD(this))
1471                 player_powerups_remove_all(this);
1472
1473         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1474                 return;
1475
1476         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1477         int items_prev = this.items;
1478
1479         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1480         {
1481                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1482                 if (this.items & IT_SUPERWEAPON)
1483                 {
1484                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1485                         {
1486                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1487                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1488                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1489                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1490                         }
1491                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1492                         {
1493                                 // don't let them run out
1494                         }
1495                         else
1496                         {
1497                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1498                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1499                                 {
1500                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1501                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1502                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1503                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1504                                 }
1505                         }
1506                 }
1507                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1508                 {
1509                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1510                         {
1511                                 this.items = this.items | IT_SUPERWEAPON;
1512                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1513                                 {
1514                                         if(!g_cts)
1515                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1517                                 }
1518                         }
1519                         else
1520                         {
1521                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1522                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1523                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1524                         }
1525                 }
1526                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1527                 {
1528                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1529                 }
1530         }
1531
1532         if(autocvar_g_nodepthtestplayers)
1533                 this.effects = this.effects | EF_NODEPTHTEST;
1534
1535         if(autocvar_g_fullbrightplayers)
1536                 this.effects = this.effects | EF_FULLBRIGHT;
1537
1538         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1539 }
1540
1541 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1542 {
1543         if(current > stable)
1544                 return current;
1545         else if(current > stable - 0.25) // when close enough, "snap"
1546                 return stable;
1547         else
1548                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1549 }
1550
1551 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1552 {
1553         if(current < stable)
1554                 return current;
1555         else if(current < stable + 0.25) // when close enough, "snap"
1556                 return stable;
1557         else
1558                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1559 }
1560
1561 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1562 {
1563         float old = GetResource(this, res);
1564         float current = old;
1565         if(current > rotstable)
1566         {
1567                 if(rotframetime > 0)
1568                 {
1569                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1570                         current = max(rotstable, current - rotlinear * rotframetime);
1571                 }
1572         }
1573         else if(current < regenstable)
1574         {
1575                 if(regenframetime > 0)
1576                 {
1577                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1578                         current = min(regenstable, current + regenlinear * regenframetime);
1579                 }
1580         }
1581
1582         float limit = GetResourceLimit(this, res) * limit_mod;
1583         if(current > limit)
1584                 current = limit;
1585
1586         if (current != old)
1587                 SetResource(this, res, current);
1588 }
1589
1590 void player_regen(entity this)
1591 {
1592         float max_mod, regen_mod, rot_mod, limit_mod;
1593         max_mod = regen_mod = rot_mod = limit_mod = 1;
1594
1595         float regen_health = autocvar_g_balance_health_regen;
1596         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1597         float regen_health_rot = autocvar_g_balance_health_rot;
1598         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1599         float regen_health_stable = autocvar_g_balance_health_regenstable;
1600         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1601         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1602                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1603         max_mod = M_ARGV(1, float);
1604         regen_mod = M_ARGV(2, float);
1605         rot_mod = M_ARGV(3, float);
1606         limit_mod = M_ARGV(4, float);
1607         regen_health = M_ARGV(5, float);
1608         regen_health_linear = M_ARGV(6, float);
1609         regen_health_rot = M_ARGV(7, float);
1610         regen_health_rotlinear = M_ARGV(8, float);
1611         regen_health_stable = M_ARGV(9, float);
1612         regen_health_rotstable = M_ARGV(10, float);
1613
1614         if(!mutator_returnvalue)
1615         if(!STAT(FROZEN, this))
1616         {
1617                 float maxa = autocvar_g_balance_armor_rotstable;
1618                 float mina = autocvar_g_balance_armor_regenstable;
1619
1620                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1621                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1622                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1623
1624                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1625                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1626                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1627         }
1628
1629         // if player rotted to death...  die!
1630         // check this outside above checks, as player may still be able to rot to death
1631         if(GetResource(this, RES_HEALTH) < 1)
1632         {
1633                 if(this.vehicle)
1634                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1635                 if(this.event_damage)
1636                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1637         }
1638
1639         if (!(this.items & IT_UNLIMITED_AMMO))
1640         {
1641                 float maxf = autocvar_g_balance_fuel_rotstable;
1642                 float minf = autocvar_g_balance_fuel_regenstable;
1643
1644                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1645                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1646                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1647         }
1648 }
1649
1650 bool zoomstate_set;
1651 void SetZoomState(entity this, float newzoom)
1652 {
1653         if(newzoom != CS(this).zoomstate)
1654         {
1655                 CS(this).zoomstate = newzoom;
1656                 ClientData_Touch(this);
1657         }
1658         zoomstate_set = true;
1659 }
1660
1661 void GetPressedKeys(entity this)
1662 {
1663         MUTATOR_CALLHOOK(GetPressedKeys, this);
1664         if (game_stopped)
1665         {
1666                 CS(this).pressedkeys = 0;
1667                 STAT(PRESSED_KEYS, this) = 0;
1668                 return;
1669         }
1670
1671         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1672         int keys = STAT(PRESSED_KEYS, this);
1673         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1674         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1675         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1676         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1677
1678         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1679         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1680         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1681         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1682         CS(this).pressedkeys = keys; // store for other users
1683
1684         STAT(PRESSED_KEYS, this) = keys;
1685 }
1686
1687 /*
1688 ======================
1689 spectate mode routines
1690 ======================
1691 */
1692
1693 void SpectateCopy(entity this, entity spectatee)
1694 {
1695         TC(Client, this); TC(Client, spectatee);
1696
1697         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1698         PS(this) = PS(spectatee);
1699         this.armortype = spectatee.armortype;
1700         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1701         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1702         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1703         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1704         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1705         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1706         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1707         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1708         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1709         CS(this).impulse = 0;
1710         this.disableclientprediction = 1; // no need to run prediction on a spectator
1711         this.items = spectatee.items;
1712         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1713         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1714         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1715         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1716         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1717         this.punchangle = spectatee.punchangle;
1718         this.view_ofs = spectatee.view_ofs;
1719         this.velocity = spectatee.velocity;
1720         this.dmg_take = spectatee.dmg_take;
1721         this.dmg_save = spectatee.dmg_save;
1722         this.dmg_inflictor = spectatee.dmg_inflictor;
1723         this.v_angle = spectatee.v_angle;
1724         this.angles = spectatee.v_angle;
1725         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1726         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1727         this.viewloc = spectatee.viewloc;
1728         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1729                 this.fixangle = true;
1730         setorigin(this, spectatee.origin);
1731         setsize(this, spectatee.mins, spectatee.maxs);
1732         SetZoomState(this, CS(spectatee).zoomstate);
1733
1734     anticheat_spectatecopy(this, spectatee);
1735         STAT(HUD, this) = STAT(HUD, spectatee);
1736         if(spectatee.vehicle)
1737     {
1738         this.angles = spectatee.v_angle;
1739
1740         //this.fixangle = false;
1741         //this.velocity = spectatee.vehicle.velocity;
1742         this.vehicle_health = spectatee.vehicle_health;
1743         this.vehicle_shield = spectatee.vehicle_shield;
1744         this.vehicle_energy = spectatee.vehicle_energy;
1745         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1746         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1747         this.vehicle_reload1 = spectatee.vehicle_reload1;
1748         this.vehicle_reload2 = spectatee.vehicle_reload2;
1749
1750         //msg_entity = this;
1751
1752        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1753             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1754            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1755            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1756
1757         //WriteByte (MSG_ONE, SVC_SETVIEW);
1758         //    WriteEntity(MSG_ONE, this);
1759         //makevectors(spectatee.v_angle);
1760         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1761     }
1762 }
1763
1764 bool SpectateUpdate(entity this)
1765 {
1766         if(!this.enemy)
1767                 return false;
1768
1769         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1770         {
1771                 SetSpectatee(this, NULL);
1772                 return false;
1773         }
1774
1775         SpectateCopy(this, this.enemy);
1776
1777         return true;
1778 }
1779
1780 bool SpectateSet(entity this)
1781 {
1782         if(!IS_PLAYER(this.enemy))
1783                 return false;
1784
1785         ClientData_Touch(this.enemy);
1786
1787         msg_entity = this;
1788         WriteByte(MSG_ONE, SVC_SETVIEW);
1789         WriteEntity(MSG_ONE, this.enemy);
1790         set_movetype(this, MOVETYPE_NONE);
1791         accuracy_resend(this);
1792
1793         if(!SpectateUpdate(this))
1794                 PutObserverInServer(this);
1795
1796         return true;
1797 }
1798
1799 void SetSpectatee_status(entity this, int spectatee_num)
1800 {
1801         int oldspectatee_status = CS(this).spectatee_status;
1802         CS(this).spectatee_status = spectatee_num;
1803
1804         if (CS(this).spectatee_status != oldspectatee_status)
1805         {
1806                 if (STAT(PRESSED_KEYS, this))
1807                 {
1808                         CS(this).pressedkeys = 0;
1809                         STAT(PRESSED_KEYS, this) = 0;
1810                 }
1811                 ClientData_Touch(this);
1812                 if (g_race || g_cts) race_InitSpectator();
1813         }
1814 }
1815
1816 void SetSpectatee(entity this, entity spectatee)
1817 {
1818         if(IS_BOT_CLIENT(this))
1819                 return; // bots abuse .enemy, this code is useless to them
1820
1821         entity old_spectatee = this.enemy;
1822
1823         this.enemy = spectatee;
1824
1825         // WEAPONTODO
1826         // these are required to fix the spectator bug with arc
1827         if(old_spectatee)
1828         {
1829                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1830                 {
1831                         .entity weaponentity = weaponentities[slot];
1832                         if(old_spectatee.(weaponentity).arc_beam)
1833                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1834                 }
1835         }
1836         if(this.enemy)
1837         {
1838                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1839                 {
1840                         .entity weaponentity = weaponentities[slot];
1841                         if(this.enemy.(weaponentity).arc_beam)
1842                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1843                 }
1844         }
1845
1846         if (this.enemy)
1847                 SetSpectatee_status(this, etof(this.enemy));
1848
1849         // needed to update spectator list
1850         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1851 }
1852
1853 bool Spectate(entity this, entity pl)
1854 {
1855         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1856                 return false;
1857         pl = M_ARGV(1, entity);
1858
1859         SetSpectatee(this, pl);
1860         return SpectateSet(this);
1861 }
1862
1863 bool SpectateNext(entity this)
1864 {
1865         entity ent = find(this.enemy, classname, STR_PLAYER);
1866
1867         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1868                 ent = M_ARGV(1, entity);
1869         else if (!ent)
1870                 ent = find(ent, classname, STR_PLAYER);
1871
1872         if(ent) { SetSpectatee(this, ent); }
1873
1874         return SpectateSet(this);
1875 }
1876
1877 bool SpectatePrev(entity this)
1878 {
1879         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1880         entity ent = findchain(classname, STR_PLAYER);
1881         if (!ent) // no player
1882                 return false;
1883
1884         entity first = ent;
1885         // skip players until current spectated player
1886         if(this.enemy)
1887         while(ent && ent != this.enemy)
1888                 ent = ent.chain;
1889
1890         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1891         {
1892                 case MUT_SPECPREV_FOUND:
1893                         ent = M_ARGV(1, entity);
1894                         break;
1895                 case MUT_SPECPREV_RETURN:
1896                         return true;
1897                 case MUT_SPECPREV_CONTINUE:
1898                 default:
1899                 {
1900                         if(ent.chain)
1901                                 ent = ent.chain;
1902                         else
1903                                 ent = first;
1904                         break;
1905                 }
1906         }
1907
1908         SetSpectatee(this, ent);
1909         return SpectateSet(this);
1910 }
1911
1912 /*
1913 =============
1914 ShowRespawnCountdown()
1915
1916 Update a respawn countdown display.
1917 =============
1918 */
1919 void ShowRespawnCountdown(entity this)
1920 {
1921         float number;
1922         if(!IS_DEAD(this)) // just respawned?
1923                 return;
1924         else
1925         {
1926                 number = ceil(this.respawn_time - time);
1927                 if(number <= 0)
1928                         return;
1929                 if(number <= this.respawn_countdown)
1930                 {
1931                         this.respawn_countdown = number - 1;
1932                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1933                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1934                 }
1935         }
1936 }
1937
1938 .bool team_selected;
1939 bool ShowTeamSelection(entity this)
1940 {
1941         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1942                 return false;
1943         stuffcmd(this, "menu_showteamselect\n");
1944         return true;
1945 }
1946 void Join(entity this)
1947 {
1948         TRANSMUTE(Player, this);
1949
1950         if(!this.team_selected)
1951         if(autocvar_g_campaign || autocvar_g_balance_teams)
1952                 TeamBalance_JoinBestTeam(this);
1953
1954         if(autocvar_g_campaign)
1955                 campaign_bots_may_start = true;
1956
1957         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1958
1959         PutClientInServer(this);
1960
1961         if(IS_PLAYER(this))
1962         if(teamplay && this.team != -1)
1963         {
1964         }
1965         else
1966                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1967         this.team_selected = false;
1968 }
1969
1970 int GetPlayerLimit()
1971 {
1972         if(g_duel)
1973                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1974         int player_limit = autocvar_g_maxplayers;
1975         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1976         player_limit = M_ARGV(0, int);
1977         return player_limit;
1978 }
1979
1980 /**
1981  * Determines whether the player is allowed to join. This depends on cvar
1982  * g_maxplayers, if it isn't used this function always return true, otherwise
1983  * it checks whether the number of currently playing players exceeds g_maxplayers.
1984  * @return int number of free slots for players, 0 if none
1985  */
1986 int nJoinAllowed(entity this, entity ignore)
1987 {
1988         if(!ignore)
1989         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1990         // so report 0 free slots if restricted
1991         {
1992                 if(autocvar_g_forced_team_otherwise == "spectate")
1993                         return 0;
1994                 if(autocvar_g_forced_team_otherwise == "spectator")
1995                         return 0;
1996         }
1997
1998         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1999                 return 0; // forced spectators can never join
2000
2001         // TODO simplify this
2002         int totalClients = 0;
2003         int currentlyPlaying = 0;
2004         FOREACH_CLIENT(true, {
2005                 if(it != ignore)
2006                         ++totalClients;
2007                 if(IS_REAL_CLIENT(it))
2008                 if(IS_PLAYER(it) || it.caplayer)
2009                         ++currentlyPlaying;
2010         });
2011
2012         int player_limit = GetPlayerLimit();
2013
2014         int free_slots = 0;
2015         if (!player_limit)
2016                 free_slots = maxclients - totalClients;
2017         else if(player_limit > 0 && currentlyPlaying < player_limit)
2018                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2019
2020         static float msg_time = 0;
2021         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2022         {
2023                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2024                 msg_time = time + 0.5;
2025         }
2026
2027         return free_slots;
2028 }
2029
2030 void PrintWelcomeMessage(entity this)
2031 {
2032         if(CS(this).motd_actived_time == 0)
2033         {
2034                 if (autocvar_g_campaign) {
2035                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2036                                 CS(this).motd_actived_time = time;
2037                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2038                         }
2039                 } else {
2040                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2041                                 CS(this).motd_actived_time = time;
2042                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2043                         }
2044                 }
2045         }
2046         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2047         {
2048                 if (autocvar_g_campaign) {
2049                         if (PHYS_INPUT_BUTTON_INFO(this))
2050                                 CS(this).motd_actived_time = time;
2051                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2052                                 CS(this).motd_actived_time = 0;
2053                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2054                         }
2055                 } else {
2056                         if (PHYS_INPUT_BUTTON_INFO(this))
2057                                 CS(this).motd_actived_time = time;
2058                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2059                                 CS(this).motd_actived_time = 0;
2060                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2061                         }
2062                 }
2063         }
2064         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2065         {
2066                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2067                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2068                 else if (CS(this).motd_actived_time == -2)
2069                 {
2070                         // instantly hide MOTD
2071                         CS(this).motd_actived_time = 0;
2072                         if (autocvar_g_campaign)
2073                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2074                         else
2075                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2076                 }
2077                 else if (IS_PLAYER(this) || IS_SPEC(this))
2078                 {
2079                         // FIXME occasionally for some reason MOTD never goes away
2080                         // delay MOTD removal a little bit in the hope it fixes this bug
2081                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2082                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2083                         else //if (CS(this).motd_actived_time < -2)
2084                                 CS(this).motd_actived_time++;
2085                 }
2086         }
2087 }
2088
2089 bool joinAllowed(entity this)
2090 {
2091         if (CS(this).version_mismatch) return false;
2092         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2093         if (!nJoinAllowed(this, this)) return false;
2094         if (teamplay && lockteams) return false;
2095         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2096         if (ShowTeamSelection(this)) return false;
2097         return true;
2098 }
2099
2100 .string shootfromfixedorigin;
2101 .bool dualwielding_prev;
2102 bool PlayerThink(entity this)
2103 {
2104         if (game_stopped || intermission_running) {
2105                 this.modelflags &= ~MF_ROCKET;
2106                 if(intermission_running)
2107                         IntermissionThink(this);
2108                 return false;
2109         }
2110
2111         if (timeout_status == TIMEOUT_ACTIVE) {
2112                 // don't allow the player to turn around while game is paused
2113                 // FIXME turn this into CSQC stuff
2114                 this.v_angle = this.lastV_angle;
2115                 this.angles = this.lastV_angle;
2116                 this.fixangle = true;
2117         }
2118
2119         if (frametime) player_powerups(this);
2120
2121         if (IS_DEAD(this)) {
2122                 if (this.personal && g_race_qualifying) {
2123                         if (time > this.respawn_time) {
2124                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2125                                 respawn(this);
2126                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2127                         }
2128                 } else {
2129                         if (frametime) player_anim(this);
2130
2131                         if (this.respawn_flags & RESPAWN_DENY)
2132                         {
2133                                 STAT(RESPAWN_TIME, this) = 0;
2134                                 return false;
2135                         }
2136
2137                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2138
2139                         switch(this.deadflag)
2140                         {
2141                                 case DEAD_DYING:
2142                                 {
2143                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2144                                                 this.deadflag = DEAD_RESPAWNING;
2145                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2146                                                 this.deadflag = DEAD_DEAD;
2147                                         break;
2148                                 }
2149                                 case DEAD_DEAD:
2150                                 {
2151                                         if (button_pressed)
2152                                                 this.deadflag = DEAD_RESPAWNABLE;
2153                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2154                                                 this.deadflag = DEAD_RESPAWNING;
2155                                         break;
2156                                 }
2157                                 case DEAD_RESPAWNABLE:
2158                                 {
2159                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2160                                                 this.deadflag = DEAD_RESPAWNING;
2161                                         break;
2162                                 }
2163                                 case DEAD_RESPAWNING:
2164                                 {
2165                                         if (time > this.respawn_time)
2166                                         {
2167                                                 this.respawn_time = time + 1; // only retry once a second
2168                                                 this.respawn_time_max = this.respawn_time;
2169                                                 respawn(this);
2170                                         }
2171                                         break;
2172                                 }
2173                         }
2174
2175                         ShowRespawnCountdown(this);
2176
2177                         if (this.respawn_flags & RESPAWN_SILENT)
2178                                 STAT(RESPAWN_TIME, this) = 0;
2179                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2180                         {
2181                                 if (time < this.respawn_time)
2182                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2183                                 else if (this.deadflag != DEAD_RESPAWNING)
2184                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2185                         }
2186                         else
2187                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2188                 }
2189
2190                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2191                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2192                         STAT(RESPAWN_TIME, this) *= -1;
2193
2194                 return false;
2195         }
2196
2197         FixPlayermodel(this);
2198
2199         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2200                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2201                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2202         }
2203
2204         // reset gun alignment when dual wielding status changes
2205         // to ensure guns are always aligned right and left
2206         bool dualwielding = W_DualWielding(this);
2207         if(this.dualwielding_prev != dualwielding)
2208         {
2209                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2210                 this.dualwielding_prev = dualwielding;
2211         }
2212
2213         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2214         //if(frametime)
2215         {
2216                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2217                 {
2218                         .entity weaponentity = weaponentities[slot];
2219                         if(WEP_CVAR(vortex, charge_always))
2220                                 W_Vortex_Charge(this, weaponentity, frametime);
2221                         W_WeaponFrame(this, weaponentity);
2222                 }
2223         }
2224
2225         if (frametime)
2226         {
2227                 // WEAPONTODO: Add a weapon request for this
2228                 // rot vortex charge to the charge limit
2229                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2230                 {
2231                         .entity weaponentity = weaponentities[slot];
2232                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2233                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2234                 }
2235
2236                 player_regen(this);
2237                 player_anim(this);
2238                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2239         }
2240
2241         monsters_setstatus(this);
2242
2243         return true;
2244 }
2245
2246 .bool would_spectate;
2247 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2248 void ObserverOrSpectatorThink(entity this)
2249 {
2250         bool is_spec = IS_SPEC(this);
2251         if ( CS(this).impulse )
2252         {
2253                 int r = MinigameImpulse(this, CS(this).impulse);
2254                 if (!is_spec || r)
2255                         CS(this).impulse = 0;
2256
2257                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2258                 {
2259                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2260                         CS(this).impulse = 0;
2261                         return;
2262                 }
2263         }
2264
2265         if (this.flags & FL_JUMPRELEASED) {
2266                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2267                         this.flags &= ~FL_JUMPRELEASED;
2268                         this.flags |= FL_SPAWNING;
2269                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2270                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2271                         this.flags &= ~FL_JUMPRELEASED;
2272                         if(SpectateNext(this)) {
2273                                 TRANSMUTE(Spectator, this);
2274                         } else if (is_spec) {
2275                                 TRANSMUTE(Observer, this);
2276                                 PutClientInServer(this);
2277                         }
2278                         else
2279                                 this.would_spectate = false; // unable to spectate anyone
2280                         if (is_spec)
2281                                 CS(this).impulse = 0;
2282                 } else if (is_spec) {
2283                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2284                                 this.flags &= ~FL_JUMPRELEASED;
2285                                 if(SpectatePrev(this)) {
2286                                         TRANSMUTE(Spectator, this);
2287                                 } else {
2288                                         TRANSMUTE(Observer, this);
2289                                         PutClientInServer(this);
2290                                 }
2291                                 CS(this).impulse = 0;
2292                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2293                                 this.would_spectate = false;
2294                                 this.flags &= ~FL_JUMPRELEASED;
2295                                 TRANSMUTE(Observer, this);
2296                                 PutClientInServer(this);
2297                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2298                                 PutObserverInServer(this);
2299                                 this.would_spectate = true;
2300                         }
2301                 }
2302                 else {
2303                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2304                         if (PHYS_INPUT_BUTTON_USE(this))
2305                                 wouldclip = !wouldclip;
2306                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2307                         set_movetype(this, preferred_movetype);
2308                 }
2309         } else { // jump pressed
2310                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2311                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2312                         this.flags |= FL_JUMPRELEASED;
2313                         if(this.flags & FL_SPAWNING)
2314                         {
2315                                 this.flags &= ~FL_SPAWNING;
2316                                 if(joinAllowed(this))
2317                                         Join(this);
2318                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2319                                         CS(this).autojoin_checked = -1;
2320                                 return;
2321                         }
2322                 }
2323                 if(is_spec && !SpectateUpdate(this))
2324                         PutObserverInServer(this);
2325         }
2326         if (is_spec)
2327                 this.flags |= FL_CLIENT | FL_NOTARGET;
2328 }
2329
2330 void PlayerUseKey(entity this)
2331 {
2332         if (!IS_PLAYER(this))
2333                 return;
2334
2335         if(this.vehicle)
2336         {
2337                 if(!game_stopped)
2338                 {
2339                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2340                         return;
2341                 }
2342         }
2343         else if(autocvar_g_vehicles_enter)
2344         {
2345                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2346                 {
2347                         entity head, closest_target = NULL;
2348                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2349
2350                         while(head) // find the closest acceptable target to enter
2351                         {
2352                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2353                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2354                                 {
2355                                         if(closest_target)
2356                                         {
2357                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2358                                                 { closest_target = head; }
2359                                         }
2360                                         else { closest_target = head; }
2361                                 }
2362
2363                                 head = head.chain;
2364                         }
2365
2366                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2367                 }
2368         }
2369
2370         // a use key was pressed; call handlers
2371         MUTATOR_CALLHOOK(PlayerUseKey, this);
2372 }
2373
2374
2375 /*
2376 =============
2377 PlayerPreThink
2378
2379 Called every frame for each client before the physics are run
2380 =============
2381 */
2382 .float last_vehiclecheck;
2383 void PlayerPreThink (entity this)
2384 {
2385         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2386         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2387
2388         WarpZone_PlayerPhysics_FixVAngle(this);
2389
2390         if (frametime) {
2391                 // physics frames: update anticheat stuff
2392                 anticheat_prethink(this);
2393
2394                 // WORKAROUND: only use dropclient in server frames (frametime set).
2395                 // Never use it in cl_movement frames (frametime zero).
2396                 if (blockSpectators && IS_REAL_CLIENT(this)
2397                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2398                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2399                 {
2400                         if (dropclient_schedule(this))
2401                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2402                 }
2403         }
2404
2405         zoomstate_set = false;
2406
2407         // Check for nameless players
2408         if (this.netname == "" || this.netname != CS(this).netname_previous)
2409         {
2410                 bool assume_unchanged = (CS(this).netname_previous == "");
2411                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2412                 {
2413                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2414                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2415                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2416                         assume_unchanged = false;
2417                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2418                 }
2419                 if (isInvisibleString(this.netname))
2420                 {
2421                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2422                         sprint(this, "Warning: invisible names are not allowed.\n");
2423                         assume_unchanged = false;
2424                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2425                 }
2426                 if (!assume_unchanged && autocvar_sv_eventlog)
2427                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2428                 strcpy(CS(this).netname_previous, this.netname);
2429         }
2430
2431         // version nagging
2432         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2433         CS(this).version_nagtime = 0;
2434         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2435             // git client
2436         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2437             // git server
2438             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2439         } else {
2440             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2441             if (r < 0) { // old client
2442                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2443             } else if (r > 0) { // old server
2444                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2445             }
2446         }
2447     }
2448
2449         // GOD MODE info
2450         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2451         {
2452                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2453                 this.max_armorvalue = 0;
2454         }
2455
2456         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2457         {
2458                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2459                 {
2460                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2461                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2462                         if (this.iceblock)
2463                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2464
2465                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2466                                 Unfreeze(this, false);
2467                 }
2468                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2469                 {
2470                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2471                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2472
2473                         if (GetResource(this, RES_HEALTH) < 1)
2474                         {
2475                                 if (this.vehicle)
2476                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2477                                 if(this.event_damage)
2478                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2479                         }
2480                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2481                                 Unfreeze(this, false);
2482                 }
2483         }
2484
2485         MUTATOR_CALLHOOK(PlayerPreThink, this);
2486
2487         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2488         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2489         {
2490                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2491                 {
2492                         if(!it.owner)
2493                         {
2494                                 if(!it.team || SAME_TEAM(this, it))
2495                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2496                                 else if(autocvar_g_vehicles_steal)
2497                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2498                         }
2499                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2500                         {
2501                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2502                         }
2503                 });
2504
2505                 this.last_vehiclecheck = time + 1;
2506         }
2507
2508         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2509         {
2510                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2511                         PlayerUseKey(this);
2512                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2513         }
2514
2515         if (IS_REAL_CLIENT(this))
2516                 PrintWelcomeMessage(this);
2517
2518         if (IS_PLAYER(this)) {
2519                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2520                         error("Client can't be spawned as player on connection!");
2521                 if(!PlayerThink(this))
2522                         return;
2523         }
2524         else if (game_stopped || intermission_running) {
2525                 if(intermission_running)
2526                         IntermissionThink(this);
2527                 return;
2528         }
2529         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2530         {
2531                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2532                 CS(this).autojoin_checked = 1;
2533                 // don't do this in ClientConnect
2534                 // many things can go wrong if a client is spawned as player on connection
2535                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2536                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2537                                 && (!teamplay || autocvar_g_balance_teams)))
2538                 {
2539                         campaign_bots_may_start = true;
2540                         if(joinAllowed(this))
2541                                 Join(this);
2542                         return;
2543                 }
2544         }
2545         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2546                 ObserverOrSpectatorThink(this);
2547         }
2548
2549         // WEAPONTODO: Add weapon request for this
2550         if (!zoomstate_set) {
2551                 bool wep_zoomed = false;
2552                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2553                 {
2554                         .entity weaponentity = weaponentities[slot];
2555                         Weapon thiswep = this.(weaponentity).m_weapon;
2556                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2557                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2558                 }
2559                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2560         }
2561
2562         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2563         {
2564                 CS(this).teamkill_soundtime = 0;
2565
2566                 entity e = CS(this).teamkill_soundsource;
2567                 entity oldpusher = e.pusher;
2568                 e.pusher = this;
2569                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2570                 e.pusher = oldpusher;
2571         }
2572
2573         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2574                 CS(this).taunt_soundtime = 0;
2575                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2576         }
2577
2578         target_voicescript_next(this);
2579 }
2580
2581 void DrownPlayer(entity this)
2582 {
2583         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2584                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2585         {
2586                 STAT(AIR_FINISHED, this) = 0;
2587                 return;
2588         }
2589
2590         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2591         {
2592                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2593                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2594                 STAT(AIR_FINISHED, this) = 0;
2595         }
2596         else
2597         {
2598                 if (!STAT(AIR_FINISHED, this))
2599                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2600                 if (STAT(AIR_FINISHED, this) < time)
2601                 {       // drown!
2602                         if (this.pain_finished < time)
2603                         {
2604                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2605                                 this.pain_finished = time + 0.5;
2606                         }
2607                 }
2608         }
2609 }
2610
2611 .bool move_qcphysics;
2612
2613 void Player_Physics(entity this)
2614 {
2615         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2616
2617         if(!this.move_qcphysics)
2618                 return;
2619
2620         if(!frametime && !CS(this).pm_frametime)
2621                 return;
2622
2623         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2624
2625         CS(this).pm_frametime = 0;
2626 }
2627
2628 /*
2629 =============
2630 PlayerPostThink
2631
2632 Called every frame for each client after the physics are run
2633 =============
2634 */
2635 void PlayerPostThink (entity this)
2636 {
2637         Player_Physics(this);
2638
2639         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2640         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2641         if (IS_REAL_CLIENT(this))
2642         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2643         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2644         {
2645                 int totalClients = 0;
2646                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2647                 {
2648                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2649                         {
2650                                 ++totalClients;
2651                         });
2652                 }
2653
2654                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2655                 { /* do nothing */ }
2656                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2657                 {
2658                         if (CS(this).idlekick_lasttimeleft)
2659                         {
2660                                 CS(this).idlekick_lasttimeleft = 0;
2661                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2662                         }
2663                 }
2664                 else
2665                 {
2666                         float maxidle_time = autocvar_sv_maxidle;
2667                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2668                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2669                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2670                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2671                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2672                         {
2673                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2674                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2675                                 else
2676                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2677                         }
2678                         if (timeleft <= 0) {
2679                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2680                                 {
2681                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2682                                         if (this.caplayer)
2683                                                 this.caplayer = 0;
2684                                         this.lms_spectate_warning = 2; // TODO: mutator hook for players forcibly moved to spectator?
2685                                         PutObserverInServer(this);
2686                                 }
2687                                 else
2688                                 {
2689                                         if (dropclient_schedule(this))
2690                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2691                                 }
2692                                 return;
2693                         }
2694                         else if (timeleft <= countdown_time) {
2695                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2696                                         play2(this, SND(TALK2));
2697                                 CS(this).idlekick_lasttimeleft = timeleft;
2698                         }
2699                 }
2700         }
2701
2702         CheatFrame(this);
2703
2704         if (game_stopped)
2705         {
2706                 this.solid = SOLID_NOT;
2707                 this.takedamage = DAMAGE_NO;
2708                 set_movetype(this, MOVETYPE_NONE);
2709                 CS(this).teamkill_complain = 0;
2710                 CS(this).teamkill_soundtime = 0;
2711                 CS(this).teamkill_soundsource = NULL;
2712         }
2713
2714         if (IS_PLAYER(this)) {
2715                 if(this.death_time == time && IS_DEAD(this))
2716                 {
2717                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2718                         // once all the damage events of this frame have been processed with normal size
2719                         this.maxs.z = 5;
2720                         setsize(this, this.mins, this.maxs);
2721                 }
2722                 DrownPlayer(this);
2723                 UpdateChatBubble(this);
2724                 if (CS(this).impulse) ImpulseCommands(this);
2725                 GetPressedKeys(this);
2726                 if (game_stopped)
2727                 {
2728                         CSQCMODEL_AUTOUPDATE(this);
2729                         return;
2730                 }
2731         }
2732         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2733         {
2734                 CS(this).pressedkeys = 0;
2735                 STAT(PRESSED_KEYS, this) = 0;
2736         }
2737
2738         if (this.waypointsprite_attachedforcarrier) {
2739                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2740                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2741         }
2742
2743         CSQCMODEL_AUTOUPDATE(this);
2744 }
2745
2746 // hack to copy the button fields from the client entity to the Client State
2747 void PM_UpdateButtons(entity this, entity store)
2748 {
2749         if(this.impulse)
2750                 store.impulse = this.impulse;
2751         this.impulse = 0;
2752
2753         bool typing = this.buttonchat || this.button12;
2754
2755         store.button0 = (typing) ? 0 : this.button0;
2756         //button1?!
2757         store.button2 = (typing) ? 0 : this.button2;
2758         store.button3 = (typing) ? 0 : this.button3;
2759         store.button4 = this.button4;
2760         store.button5 = (typing) ? 0 : this.button5;
2761         store.button6 = this.button6;
2762         store.button7 = this.button7;
2763         store.button8 = this.button8;
2764         store.button9 = this.button9;
2765         store.button10 = this.button10;
2766         store.button11 = this.button11;
2767         store.button12 = this.button12;
2768         store.button13 = this.button13;
2769         store.button14 = this.button14;
2770         store.button15 = this.button15;
2771         store.button16 = this.button16;
2772         store.buttonuse = this.buttonuse;
2773         store.buttonchat = this.buttonchat;
2774
2775         store.cursor_active = this.cursor_active;
2776         store.cursor_screen = this.cursor_screen;
2777         store.cursor_trace_start = this.cursor_trace_start;
2778         store.cursor_trace_endpos = this.cursor_trace_endpos;
2779         store.cursor_trace_ent = this.cursor_trace_ent;
2780
2781         store.ping = this.ping;
2782         store.ping_packetloss = this.ping_packetloss;
2783         store.ping_movementloss = this.ping_movementloss;
2784
2785         store.v_angle = this.v_angle;
2786         store.movement = this.movement;
2787 }
2788
2789 NET_HANDLE(fpsreport, bool)
2790 {
2791         int fps = ReadShort();
2792         PlayerScore_Set(sender, SP_FPS, fps);
2793         return true;
2794 }