qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include <server/gamelog.qh>
  24 #include "race.qh"
  25 #include "antilag.qh"
  26 #include "campaign.qh"
  27 #include "command/common.qh"
  28 #include "scores_rules.qh"
  29 #include "weapons/common.qh"
  30
  31 #include "bot/api.qh"
  32
  33 #include "../common/ent_cs.qh"
  34 #include "../common/wepent.qh"
  35 #include <common/state.qh>
  36
  37 #include "compat/quake3.qh"
  38
  39 #include <common/effects/qc/globalsound.qh>
  40
  41 #include "../common/mapobjects/func/conveyor.qh"
  42 #include "../common/mapobjects/teleporters.qh"
  43 #include "../common/mapobjects/target/spawnpoint.qh"
  44 #include <common/mapobjects/trigger/counter.qh>
  45 #include <common/mapobjects/trigger/swamp.qh>
  46
  47 #include "../common/vehicles/all.qh"
  48
  49 #include "weapons/hitplot.qh"
  50 #include "weapons/weaponsystem.qh"
  51
  52 #include "../common/net_notice.qh"
  53 #include "../common/net_linked.qh"
  54 #include "../common/physics/player.qh"
  55
  56 #include <common/vehicles/sv_vehicles.qh>
  57
  58 #include "../common/items/_mod.qh"
  59
  60 #include "../common/mutators/mutator/waypoints/all.qh"
  61 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  62 #include <common/gamemodes/_mod.qh>
  63
  64 #include "../common/mapobjects/subs.qh"
  65 #include "../common/mapobjects/triggers.qh"
  66 #include "../common/mapobjects/trigger/secret.qh"
  67
  68 #include "../common/minigames/sv_minigames.qh"
  69
  70 #include "../common/items/inventory.qh"
  71
  72 #include "../common/monsters/sv_monsters.qh"
  73
  74 #include "../lib/warpzone/server.qh"
  75
  76 #include <common/mutators/mutator/overkill/oknex.qh>
  77
  78 STATIC_METHOD(Client, Add, void(Client this, int _team))
  79 {
  80     ClientConnect(this);
  81     TRANSMUTE(Player, this);
  82     this.frame = 12; // 7
  83     this.team = _team;
  84     PutClientInServer(this);
  85 }
  86
  87 STATIC_METHOD(Client, Remove, void(Client this))
  88 {
  89     TRANSMUTE(Observer, this);
  90     PutClientInServer(this);
  91     ClientDisconnect(this);
  92 }
  93
  94 void send_CSQC_teamnagger() {
  95         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  96 }
  97
  98 int CountSpectators(entity player, entity to)
  99 {
 100         if(!player) { return 0; } // not sure how, but best to be safe
 101
 102         int spec_count = 0;
 103
 104         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 105         {
 106                 spec_count++;
 107         });
 108
 109         return spec_count;
 110 }
 111
 112 void WriteSpectators(entity player, entity to)
 113 {
 114         if(!player) { return; } // not sure how, but best to be safe
 115
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 WriteByte(MSG_ENTITY, num_for_edict(it));
 119         });
 120 }
 121
 122 bool ClientData_Send(entity this, entity to, int sf)
 123 {
 124         assert(to == this.owner, return false);
 125
 126         entity e = to;
 127         if (IS_SPEC(e)) e = e.enemy;
 128
 129         sf = 0;
 130         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 131         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 132         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 133         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 134
 135         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 136         WriteByte(MSG_ENTITY, sf);
 137
 138         if (sf & BIT(1))
 139                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 140
 141         if(sf & BIT(4))
 142         {
 143                 float specs = CountSpectators(e, to);
 144                 WriteByte(MSG_ENTITY, specs);
 145                 WriteSpectators(e, to);
 146         }
 147
 148         return true;
 149 }
 150
 151 void ClientData_Attach(entity this)
 152 {
 153         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 154         CS(this).clientdata.drawonlytoclient = this;
 155         CS(this).clientdata.owner = this;
 156 }
 157
 158 void ClientData_Detach(entity this)
 159 {
 160         delete(CS(this).clientdata);
 161         CS(this).clientdata = NULL;
 162 }
 163
 164 void ClientData_Touch(entity e)
 165 {
 166         entity cd = CS(e).clientdata;
 167         if (cd) { cd.SendFlags = 1; }
 168
 169         // make it spectatable
 170         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 171         {
 172                 entity cd = CS(it).clientdata;
 173                 if (cd) { cd.SendFlags = 1; }
 174         });
 175 }
 176
 177
 178 /*
 179 =============
 180 CheckPlayerModel
 181
 182 Checks if the argument string can be a valid playermodel.
 183 Returns a valid one in doubt.
 184 =============
 185 */
 186 string FallbackPlayerModel;
 187 string CheckPlayerModel(string plyermodel) {
 188         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 189         {
 190                 // note: we cannot summon Don Strunzone here, some player may
 191                 // still have the model string set. In case anyone manages how
 192                 // to change a cvar default, we'll have a small leak here.
 193                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 194         }
 195         // only in right path
 196         if( substring(plyermodel,0,14) != "models/player/")
 197                 return FallbackPlayerModel;
 198         // only good file extensions
 199         if(substring(plyermodel,-4,4) != ".zym")
 200         if(substring(plyermodel,-4,4) != ".dpm")
 201         if(substring(plyermodel,-4,4) != ".iqm")
 202         if(substring(plyermodel,-4,4) != ".md3")
 203         if(substring(plyermodel,-4,4) != ".psk")
 204                 return FallbackPlayerModel;
 205         // forbid the LOD models
 206         if(substring(plyermodel, -9,5) == "_lod1")
 207                 return FallbackPlayerModel;
 208         if(substring(plyermodel, -9,5) == "_lod2")
 209                 return FallbackPlayerModel;
 210         if(plyermodel != strtolower(plyermodel))
 211                 return FallbackPlayerModel;
 212         // also, restrict to server models
 213         if(autocvar_sv_servermodelsonly)
 214         {
 215                 if(!fexists(plyermodel))
 216                         return FallbackPlayerModel;
 217         }
 218         return plyermodel;
 219 }
 220
 221 void setplayermodel(entity e, string modelname)
 222 {
 223         precache_model(modelname);
 224         _setmodel(e, modelname);
 225         player_setupanimsformodel(e);
 226         if(!autocvar_g_debug_globalsounds)
 227                 UpdatePlayerSounds(e);
 228 }
 229
 230 /** putting a client as observer in the server */
 231 void PutObserverInServer(entity this)
 232 {
 233     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 234         PlayerState_detach(this);
 235
 236         if (IS_PLAYER(this))
 237         {
 238                 if(GetResource(this, RES_HEALTH) >= 1)
 239                 {
 240                         // despawn effect
 241                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 242                 }
 243
 244                 // was a player, recount votes and ready status
 245                 if(IS_REAL_CLIENT(this))
 246                 {
 247                         if (vote_called) { VoteCount(false); }
 248                         ReadyCount();
 249                 }
 250     }
 251
 252     {
 253         entity spot = SelectSpawnPoint(this, true);
 254         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 255         this.angles = vec2(spot.angles);
 256         this.fixangle = true;
 257         // offset it so that the spectator spawns higher off the ground, looks better this way
 258         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 259         if (IS_REAL_CLIENT(this))
 260         {
 261             msg_entity = this;
 262             WriteByte(MSG_ONE, SVC_SETVIEW);
 263             WriteEntity(MSG_ONE, this);
 264         }
 265         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 266         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 267         if(!autocvar_g_debug_globalsounds)
 268         {
 269                 // needed for player sounds
 270                 this.model = "";
 271                 FixPlayermodel(this);
 272         }
 273         setmodel(this, MDL_Null);
 274         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 275         this.view_ofs = '0 0 0';
 276     }
 277
 278     RemoveGrapplingHooks(this);
 279         Portal_ClearAll(this);
 280         Unfreeze(this, false);
 281         SetSpectatee(this, NULL);
 282
 283         if (this.alivetime)
 284         {
 285                 if (!warmup_stage)
 286                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 287                 this.alivetime = 0;
 288         }
 289
 290         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 291
 292         WaypointSprite_PlayerDead(this);
 293
 294         if (CS(this).killcount != FRAGS_SPECTATOR)
 295         {
 296                 if(!game_stopped)
 297                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 298                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 299         }
 300
 301         accuracy_resend(this);
 302
 303         CS(this).spectatortime = time;
 304         if(this.bot_attack)
 305                 IL_REMOVE(g_bot_targets, this);
 306         this.bot_attack = false;
 307         if(this.monster_attack)
 308                 IL_REMOVE(g_monster_targets, this);
 309         this.monster_attack = false;
 310     STAT(HUD, this) = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.effects = 0;
 324         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 325         this.pauserotarmor_finished = 0;
 326         this.pauserothealth_finished = 0;
 327         this.pauseregen_finished = 0;
 328         this.damageforcescale = 0;
 329         this.death_time = 0;
 330         this.respawn_flags = 0;
 331         this.respawn_time = 0;
 332         STAT(RESPAWN_TIME, this) = 0;
 333         this.alpha = 0;
 334         this.scale = 0;
 335         this.fade_time = 0;
 336         this.pain_frame = 0;
 337         this.pain_finished = 0;
 338         STAT(STRENGTH_FINISHED, this) = 0;
 339         STAT(INVINCIBLE_FINISHED, this) = 0;
 340         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 341         this.air_finished = 0;
 342         //this.dphitcontentsmask = 0;
 343         this.dphitcontentsmask = DPCONTENTS_SOLID;
 344         if (autocvar_g_playerclip_collisions)
 345                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 346         this.pushltime = 0;
 347         this.istypefrag = 0;
 348         setthink(this, func_null);
 349         this.nextthink = 0;
 350         this.deadflag = DEAD_NO;
 351         this.crouch = false;
 352         STAT(REVIVE_PROGRESS, this) = 0;
 353         this.revival_time = 0;
 354         this.draggable = drag_undraggable;
 355
 356         this.items = 0;
 357         STAT(WEAPONS, this) = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378         this.event_heal = func_null;
 379
 380         for(int slot = 0; slot < MAX_AXH; ++slot)
 381         {
 382                 entity axh = this.(AuxiliaryXhair[slot]);
 383                 this.(AuxiliaryXhair[slot]) = NULL;
 384
 385                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 386                         delete(axh);
 387         }
 388
 389         if (mutator_returnvalue)
 390         {
 391                 // mutator prevents resetting teams+score
 392         }
 393         else
 394         {
 395                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 396                 this.frags = FRAGS_SPECTATOR;
 397         }
 398         if (CS(this).just_joined)
 399                 CS(this).just_joined = false;
 400 }
 401
 402 int player_getspecies(entity this)
 403 {
 404         get_model_parameters(this.model, this.skin);
 405         int s = get_model_parameters_species;
 406         get_model_parameters(string_null, 0);
 407         if (s < 0) return SPECIES_HUMAN;
 408         return s;
 409 }
 410
 411 .float model_randomizer;
 412 void FixPlayermodel(entity player)
 413 {
 414         string defaultmodel = "";
 415         int defaultskin = 0;
 416         if(autocvar_sv_defaultcharacter)
 417         {
 418                 if(teamplay)
 419                 {
 420                         switch(player.team)
 421                         {
 422                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 423                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 424                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 425                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 426                         }
 427                 }
 428
 429                 if(defaultmodel == "")
 430                 {
 431                         defaultmodel = autocvar_sv_defaultplayermodel;
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433                 }
 434
 435                 int n = tokenize_console(defaultmodel);
 436                 if(n > 0)
 437                 {
 438                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 439                         // However, do NOT randomize if the player-selected model is in the list.
 440                         for (int i = 0; i < n; ++i)
 441                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 442                                         defaultmodel = argv(i);
 443                 }
 444
 445                 int i = strstrofs(defaultmodel, ":", 0);
 446                 if(i >= 0)
 447                 {
 448                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 449                         defaultmodel = substring(defaultmodel, 0, i);
 450                 }
 451         }
 452         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 453         {
 454                 if(teamplay)
 455                 {
 456                         switch(player.team)
 457                         {
 458                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 459                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 460                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 461                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 462                         }
 463                 }
 464
 465                 if(!defaultskin)
 466                         defaultskin = autocvar_sv_defaultplayerskin;
 467         }
 468
 469         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 470         defaultmodel = M_ARGV(0, string);
 471         defaultskin = M_ARGV(1, int);
 472
 473         bool chmdl = false;
 474         int oldskin;
 475         if(defaultmodel != "")
 476         {
 477                 if (defaultmodel != player.model)
 478                 {
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, defaultmodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 oldskin = player.skin;
 487                 player.skin = defaultskin;
 488         } else {
 489                 if (player.playermodel != player.model || player.playermodel == "")
 490                 {
 491                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, player.playermodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 if(!autocvar_sv_defaultcharacterskin)
 500                 {
 501                         oldskin = player.skin;
 502                         player.skin = stof(player.playerskin);
 503                 }
 504                 else
 505                 {
 506                         oldskin = player.skin;
 507                         player.skin = defaultskin;
 508                 }
 509         }
 510
 511         if(chmdl || oldskin != player.skin) // model or skin has changed
 512         {
 513                 player.species = player_getspecies(player); // update species
 514                 if(!autocvar_g_debug_globalsounds)
 515                         UpdatePlayerSounds(player); // update skin sounds
 516         }
 517
 518         if(!teamplay)
 519                 if(strlen(autocvar_sv_defaultplayercolors))
 520                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 521                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 522 }
 523
 524 void PutPlayerInServer(entity this)
 525 {
 526         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 527
 528         PlayerState_attach(this);
 529         accuracy_resend(this);
 530
 531         if (this.team < 0)
 532                 TeamBalance_JoinBestTeam(this);
 533
 534         entity spot = SelectSpawnPoint(this, false);
 535         if (!spot) {
 536                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 537                 return; // spawn failed
 538         }
 539
 540         TRANSMUTE(Player, this);
 541
 542         CS(this).wasplayer = true;
 543         this.iscreature = true;
 544         this.teleportable = TELEPORT_NORMAL;
 545         if(!this.damagedbycontents)
 546                 IL_PUSH(g_damagedbycontents, this);
 547         this.damagedbycontents = true;
 548         set_movetype(this, MOVETYPE_WALK);
 549         this.solid = SOLID_SLIDEBOX;
 550         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 551         if (autocvar_g_playerclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 553         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 554                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 555         this.frags = FRAGS_PLAYER;
 556         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 557         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 558         if (autocvar__notarget)
 559                 this.flags |= FL_NOTARGET;
 560         this.takedamage = DAMAGE_AIM;
 561         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 562
 563         if (warmup_stage) {
 564                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 565                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 566                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 567                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 568                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 569                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 570                 SetResource(this, RES_HEALTH, warmup_start_health);
 571                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 572                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 573         } else {
 574                 SetResource(this, RES_SHELLS, start_ammo_shells);
 575                 SetResource(this, RES_BULLETS, start_ammo_nails);
 576                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 577                 SetResource(this, RES_CELLS, start_ammo_cells);
 578                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 579                 SetResource(this, RES_FUEL, start_ammo_fuel);
 580                 SetResource(this, RES_HEALTH, start_health);
 581                 SetResource(this, RES_ARMOR, start_armorvalue);
 582                 STAT(WEAPONS, this) = start_weapons;
 583                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 584                 {
 585                         GiveRandomWeapons(this, random_start_weapons_count,
 586                                 autocvar_g_random_start_weapons, random_start_ammo);
 587                 }
 588         }
 589         SetSpectatee_status(this, 0);
 590
 591         PS(this).dual_weapons = '0 0 0';
 592
 593         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 594
 595         this.items = start_items;
 596
 597         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 598         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 599         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 600         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 601         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 602         if (!sv_ready_restart_after_countdown && time < game_starttime)
 603         {
 604                 float f = game_starttime - time;
 605                 this.spawnshieldtime += f;
 606                 this.pauserotarmor_finished += f;
 607                 this.pauserothealth_finished += f;
 608                 this.pauseregen_finished += f;
 609         }
 610
 611         this.damageforcescale = autocvar_g_player_damageforcescale;
 612         this.death_time = 0;
 613         this.respawn_flags = 0;
 614         this.respawn_time = 0;
 615         STAT(RESPAWN_TIME, this) = 0;
 616         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 617         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 618         this.fade_time = 0;
 619         this.pain_frame = 0;
 620         this.pain_finished = 0;
 621         this.pushltime = 0;
 622         setthink(this, func_null); // players have no think function
 623         this.nextthink = 0;
 624         this.dmg_team = 0;
 625         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 626
 627         this.deadflag = DEAD_NO;
 628
 629         this.angles = spot.angles;
 630         this.angles_z = 0; // never spawn tilted even if the spot says to
 631         if (IS_BOT_CLIENT(this))
 632         {
 633                 this.v_angle = this.angles;
 634                 bot_aim_reset(this);
 635         }
 636         this.fixangle = true; // turn this way immediately
 637         this.oldvelocity = this.velocity = '0 0 0';
 638         this.avelocity = '0 0 0';
 639         this.punchangle = '0 0 0';
 640         this.punchvector = '0 0 0';
 641
 642         STAT(STRENGTH_FINISHED, this) = 0;
 643         STAT(INVINCIBLE_FINISHED, this) = 0;
 644         this.fire_endtime = -1;
 645         STAT(REVIVE_PROGRESS, this) = 0;
 646         this.revival_time = 0;
 647
 648         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 649         STAT(BUFFS, this) = 0;
 650         STAT(BUFF_TIME, this) = 0;
 651
 652         this.air_finished = 0;
 653         this.waterlevel = WATERLEVEL_NONE;
 654         this.watertype = CONTENT_EMPTY;
 655
 656         entity spawnevent = new_pure(spawnevent);
 657         spawnevent.owner = this;
 658         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 659
 660         // Cut off any still running player sounds.
 661         stopsound(this, CH_PLAYER_SINGLE);
 662
 663         this.model = "";
 664         FixPlayermodel(this);
 665         this.drawonlytoclient = NULL;
 666
 667         this.viewloc = NULL;
 668
 669         for(int slot = 0; slot < MAX_AXH; ++slot)
 670         {
 671                 entity axh = this.(AuxiliaryXhair[slot]);
 672                 this.(AuxiliaryXhair[slot]) = NULL;
 673
 674                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 675                         delete(axh);
 676         }
 677
 678         this.spawnpoint_targ = NULL;
 679
 680         this.crouch = false;
 681         this.view_ofs = STAT(PL_VIEW_OFS, this);
 682         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 683         this.spawnorigin = spot.origin;
 684         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 685         // don't reset back to last position, even if new position is stuck in solid
 686         this.oldorigin = this.origin;
 687         if(this.conveyor)
 688                 IL_REMOVE(g_conveyed, this);
 689         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 690         if(this.swampslug)
 691                 IL_REMOVE(g_swamped, this);
 692         this.swampslug = NULL;
 693         this.swamp_interval = 0;
 694         IL_EACH(g_counters, it.realowner == this,
 695         {
 696                 delete(it);
 697         });
 698         STAT(HUD, this) = HUD_NORMAL;
 699
 700         this.event_damage = PlayerDamage;
 701         this.event_heal = PlayerHeal;
 702
 703         this.draggable = func_null;
 704
 705         if(!this.bot_attack)
 706                 IL_PUSH(g_bot_targets, this);
 707         this.bot_attack = true;
 708         if(!this.monster_attack)
 709                 IL_PUSH(g_monster_targets, this);
 710         this.monster_attack = true;
 711         navigation_dynamicgoal_init(this, false);
 712
 713         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 714
 715         // player was spectator
 716         if (CS(this).killcount == FRAGS_SPECTATOR) {
 717                 PlayerScore_Clear(this);
 718                 CS(this).killcount = 0;
 719                 CS(this).startplaytime = time;
 720         }
 721
 722         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 723         {
 724                 .entity weaponentity = weaponentities[slot];
 725                 CL_SpawnWeaponentity(this, weaponentity);
 726         }
 727         this.alpha = default_player_alpha;
 728         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 729         this.exteriorweaponentity.alpha = default_weapon_alpha;
 730
 731         this.speedrunning = false;
 732
 733         this.counter_cnt = 0;
 734         this.fragsfilter_cnt = 0;
 735
 736         target_voicescript_clear(this);
 737
 738         // reset fields the weapons may use
 739         FOREACH(Weapons, true, {
 740                 it.wr_resetplayer(it, this);
 741                         // reload all reloadable weapons
 742                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 743                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744                         {
 745                                 .entity weaponentity = weaponentities[slot];
 746                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 747                         }
 748                 }
 749         });
 750
 751         {
 752                 string s = spot.target;
 753                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 754                         spot.target = string_null;
 755                 SUB_UseTargets(spot, this, NULL);
 756                 if(g_assault || g_race)
 757                         spot.target = s;
 758         }
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         if (autocvar_spawn_debug)
 765         {
 766                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 767                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 768         }
 769
 770         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 771         {
 772                 .entity weaponentity = weaponentities[slot];
 773                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 774                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 775                 else
 776                         this.(weaponentity).m_switchweapon = WEP_Null;
 777                 this.(weaponentity).m_weapon = WEP_Null;
 778                 this.(weaponentity).weaponname = "";
 779                 this.(weaponentity).m_switchingweapon = WEP_Null;
 780                 this.(weaponentity).cnt = -1;
 781         }
 782
 783         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 784
 785         if (CS(this).impulse) ImpulseCommands(this);
 786
 787         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 788         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 789         {
 790                 .entity weaponentity = weaponentities[slot];
 791                 W_WeaponFrame(this, weaponentity);
 792         }
 793
 794         if (!warmup_stage && !this.alivetime)
 795                 this.alivetime = time;
 796
 797         antilag_clear(this, CS(this));
 798 }
 799
 800 /** Called when a client spawns in the server */
 801 void PutClientInServer(entity this)
 802 {
 803         if (IS_BOT_CLIENT(this)) {
 804                 TRANSMUTE(Player, this);
 805         } else if (IS_REAL_CLIENT(this)) {
 806                 msg_entity = this;
 807                 WriteByte(MSG_ONE, SVC_SETVIEW);
 808                 WriteEntity(MSG_ONE, this);
 809         }
 810         if (game_stopped)
 811                 TRANSMUTE(Observer, this);
 812
 813         SetSpectatee(this, NULL);
 814
 815         // reset player keys
 816         if(PS(this))
 817                 PS(this).itemkeys = 0;
 818
 819         MUTATOR_CALLHOOK(PutClientInServer, this);
 820
 821         if (IS_OBSERVER(this)) {
 822                 PutObserverInServer(this);
 823         } else if (IS_PLAYER(this)) {
 824                 PutPlayerInServer(this);
 825         }
 826 }
 827
 828 // TODO do we need all these fields, or should we stop autodetecting runtime
 829 // changes and just have a console command to update this?
 830 bool ClientInit_SendEntity(entity this, entity to, int sf)
 831 {
 832         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 833         return = true;
 834         msg_entity = to;
 835         // MSG_INIT replacement
 836         // TODO: make easier to use
 837         Registry_send_all();
 838         W_PROP_reload(MSG_ONE, to);
 839         ClientInit_misc(this);
 840         MUTATOR_CALLHOOK(Ent_Init);
 841 }
 842 void ClientInit_misc(entity this)
 843 {
 844         int channel = MSG_ONE;
 845         WriteHeader(channel, ENT_CLIENT_INIT);
 846         WriteByte(channel, g_nexball_meter_period * 32);
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 855
 856         if(sv_foginterval && world.fog != "")
 857                 WriteString(channel, world.fog);
 858         else
 859                 WriteString(channel, "");
 860         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 861         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 862         WriteByte(channel, serverflags);
 863         WriteCoord(channel, autocvar_g_trueaim_minrange);
 864 }
 865
 866 void ClientInit_CheckUpdate(entity this)
 867 {
 868         this.nextthink = time;
 869         if(this.count != autocvar_g_balance_armor_blockpercent)
 870         {
 871                 this.count = autocvar_g_balance_armor_blockpercent;
 872                 this.SendFlags |= 1;
 873         }
 874         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 875         {
 876                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 877                 this.SendFlags |= 1;
 878         }
 879 }
 880
 881 void ClientInit_Spawn()
 882 {
 883         entity e = new_pure(clientinit);
 884         setthink(e, ClientInit_CheckUpdate);
 885         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 886
 887         ClientInit_CheckUpdate(e);
 888 }
 889
 890 /*
 891 =============
 892 SetNewParms
 893 =============
 894 */
 895 void SetNewParms ()
 896 {
 897         // initialize parms for a new player
 898         parm1 = -(86400 * 366);
 899
 900         MUTATOR_CALLHOOK(SetNewParms);
 901 }
 902
 903 /*
 904 =============
 905 SetChangeParms
 906 =============
 907 */
 908 void SetChangeParms (entity this)
 909 {
 910         // save parms for level change
 911         parm1 = CS(this).parm_idlesince - time;
 912
 913         MUTATOR_CALLHOOK(SetChangeParms);
 914 }
 915
 916 /*
 917 =============
 918 DecodeLevelParms
 919 =============
 920 */
 921 void DecodeLevelParms(entity this)
 922 {
 923         // load parms
 924         CS(this).parm_idlesince = parm1;
 925         if (CS(this).parm_idlesince == -(86400 * 366))
 926                 CS(this).parm_idlesince = time;
 927
 928         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 929         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 930
 931         MUTATOR_CALLHOOK(DecodeLevelParms);
 932 }
 933
 934 void FixClientCvars(entity e)
 935 {
 936         // send prediction settings to the client
 937         stuffcmd(e, "\nin_bindmap 0 0\n");
 938         if(autocvar_g_antilag == 3) // client side hitscan
 939                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 940         if(autocvar_sv_gentle)
 941                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 942
 943         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 944         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 945
 946         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 947
 948         MUTATOR_CALLHOOK(FixClientCvars, e);
 949 }
 950
 951 bool findinlist_abbrev(string tofind, string list)
 952 {
 953         if(list == "" || tofind == "")
 954                 return false; // empty list or search, just return
 955
 956         // this function allows abbreviated strings!
 957         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 958         {
 959                 return true;
 960         });
 961
 962         return false;
 963 }
 964
 965 bool PlayerInIPList(entity p, string iplist)
 966 {
 967         // some safety checks (never allow local?)
 968         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 969                 return false;
 970
 971         return findinlist_abbrev(p.netaddress, iplist);
 972 }
 973
 974 bool PlayerInIDList(entity p, string idlist)
 975 {
 976         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 977         if(!p.crypto_idfp)
 978                 return false;
 979
 980         return findinlist_abbrev(p.crypto_idfp, idlist);
 981 }
 982
 983 bool PlayerInList(entity player, string list)
 984 {
 985         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 986 }
 987
 988 #ifdef DP_EXT_PRECONNECT
 989 /*
 990 =============
 991 ClientPreConnect
 992
 993 Called once (not at each match start) when a client begins a connection to the server
 994 =============
 995 */
 996 void ClientPreConnect(entity this)
 997 {
 998         if(autocvar_sv_eventlog)
 999         {
1000                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1001                         this.playerid,
1002                         etof(this),
1003                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1004                 ));
1005         }
1006 }
1007 #endif
1008
1009 string GetClientVersionMessage(entity this)
1010 {
1011         if (CS(this).version_mismatch) {
1012                 if(CS(this).version < autocvar_gameversion) {
1013                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1014                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1015                 } else {
1016                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1017                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1018                 }
1019         } else {
1020                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1021         }
1022 }
1023
1024 string getwelcomemessage(entity this)
1025 {
1026         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1027         string modifications = M_ARGV(0, string);
1028
1029         if(g_weaponarena)
1030         {
1031                 if(g_weaponarena_random)
1032                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1033                 else
1034                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1035         }
1036         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1037                 modifications = strcat(modifications, ", No start weapons");
1038         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1039                 modifications = strcat(modifications, ", Low gravity");
1040         if(g_weapon_stay && !g_cts)
1041                 modifications = strcat(modifications, ", Weapons stay");
1042         if(g_jetpack)
1043                 modifications = strcat(modifications, ", Jet pack");
1044         if(autocvar_g_powerups == 0)
1045                 modifications = strcat(modifications, ", No powerups");
1046         if(autocvar_g_powerups > 0)
1047                 modifications = strcat(modifications, ", Powerups");
1048         modifications = substring(modifications, 2, strlen(modifications) - 2);
1049
1050         string versionmessage = GetClientVersionMessage(this);
1051         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1052
1053         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1054
1055         if(modifications != "")
1056                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1057
1058         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1059         {
1060                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1061                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1062         }
1063
1064         if (cache_mutatormsg != "") {
1065                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1066         }
1067
1068         string mutator_msg = "";
1069         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1070         mutator_msg = M_ARGV(0, string);
1071
1072         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1073
1074         string motd = autocvar_sv_motd;
1075         if (motd != "") {
1076                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1077         }
1078         return s;
1079 }
1080
1081 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1082
1083 /**
1084 =============
1085 ClientConnect
1086
1087 Called when a client connects to the server
1088 =============
1089 */
1090 void ClientConnect(entity this)
1091 {
1092         if (Ban_MaybeEnforceBanOnce(this)) return;
1093         assert(!IS_CLIENT(this), return);
1094         this.flags |= FL_CLIENT;
1095         assert(player_count >= 0, player_count = 0);
1096
1097 #ifdef WATERMARK
1098         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1099 #endif
1100         TRANSMUTE(Client, this);
1101         CS(this).version_nagtime = time + 10 + random() * 10;
1102
1103         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1104
1105         bot_clientconnect(this);
1106
1107         Player_DetermineForcedTeam(this);
1108
1109         TRANSMUTE(Observer, this);
1110
1111         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1112
1113         // always track bots, don't ask for cl_allow_uidtracking
1114         if (IS_BOT_CLIENT(this))
1115                 PlayerStats_GameReport_AddPlayer(this);
1116         else
1117                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1118
1119         if (autocvar_sv_eventlog)
1120                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1121
1122         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1123
1124         stuffcmd(this, clientstuff, "\n");
1125         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1126
1127         FixClientCvars(this);
1128
1129         // get version info from player
1130         stuffcmd(this, "cmd clientversion $gameversion\n");
1131
1132         // notify about available teams
1133         if (teamplay)
1134         {
1135                 entity balance = TeamBalance_CheckAllowedTeams(this);
1136                 int t = TeamBalance_GetAllowedTeams(balance);
1137                 TeamBalance_Destroy(balance);
1138                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1139         }
1140         else
1141         {
1142                 stuffcmd(this, "set _teams_available 0\n");
1143         }
1144
1145         bot_relinkplayerlist();
1146
1147         CS(this).spectatortime = time;
1148         if (blockSpectators)
1149         {
1150                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1151         }
1152
1153         CS(this).jointime = time;
1154
1155         if (IS_REAL_CLIENT(this))
1156         {
1157                 if (g_weaponarena_weapons == WEPSET(TUBA))
1158                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1159         }
1160
1161         if (!sv_foginterval && world.fog != "")
1162                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1163
1164         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1165                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1166                         send_CSQC_teamnagger();
1167
1168         CSQCMODEL_AUTOINIT(this);
1169
1170         CS(this).model_randomizer = random();
1171
1172         if (IS_REAL_CLIENT(this))
1173                 sv_notice_join(this);
1174
1175         this.move_qcphysics = autocvar_sv_qcphysics;
1176
1177         // update physics stats (players can spawn before physics runs)
1178         Physics_UpdateStats(this);
1179
1180         IL_EACH(g_initforplayer, it.init_for_player, {
1181                 it.init_for_player(it, this);
1182         });
1183
1184         Handicap_Initialize(this);
1185
1186         MUTATOR_CALLHOOK(ClientConnect, this);
1187
1188         if (IS_REAL_CLIENT(this))
1189         {
1190                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1191                 {
1192                         CS(this).motd_actived_time = -1;
1193                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1194                 }
1195         }
1196 }
1197 /*
1198 =============
1199 ClientDisconnect
1200
1201 Called when a client disconnects from the server
1202 =============
1203 */
1204 .entity chatbubbleentity;
1205 void ClientDisconnect(entity this)
1206 {
1207         assert(IS_CLIENT(this), return);
1208
1209         PlayerStats_GameReport_FinalizePlayer(this);
1210         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1211         if (CS(this).active_minigame) part_minigame(this);
1212         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1213
1214         if (autocvar_sv_eventlog)
1215                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1216
1217         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1218
1219         if(IS_SPEC(this))
1220                 SetSpectatee(this, NULL);
1221
1222     MUTATOR_CALLHOOK(ClientDisconnect, this);
1223
1224         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1225         strfree(CS(this).weaponorder_byimpulse);
1226         ClientState_detach(this);
1227
1228         Portal_ClearAll(this);
1229
1230         Unfreeze(this, false);
1231
1232         RemoveGrapplingHooks(this);
1233
1234         // Here, everything has been done that requires this player to be a client.
1235
1236         this.flags &= ~FL_CLIENT;
1237
1238         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1239         if (this.killindicator) delete(this.killindicator);
1240
1241         IL_EACH(g_counters, it.realowner == this,
1242         {
1243                 delete(it);
1244         });
1245
1246         WaypointSprite_PlayerGone(this);
1247
1248         bot_relinkplayerlist();
1249
1250         strfree(this.clientstatus);
1251         if (this.personal) delete(this.personal);
1252
1253         this.playerid = 0;
1254         ReadyCount();
1255         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1256
1257         ONREMOVE(this);
1258 }
1259
1260 void ChatBubbleThink(entity this)
1261 {
1262         this.nextthink = time;
1263         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1264         {
1265                 if(this.owner) // but why can that ever be NULL?
1266                         this.owner.chatbubbleentity = NULL;
1267                 delete(this);
1268                 return;
1269         }
1270
1271         this.mdl = "";
1272
1273         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1274         {
1275                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1276                         this.mdl = "models/sprites/minigame_busy.iqm";
1277                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1278                         this.mdl = "models/misc/chatbubble.spr";
1279         }
1280
1281         if ( this.model != this.mdl )
1282                 _setmodel(this, this.mdl);
1283
1284 }
1285
1286 void UpdateChatBubble(entity this)
1287 {
1288         if (this.alpha < 0)
1289                 return;
1290         // spawn a chatbubble entity if needed
1291         if (!this.chatbubbleentity)
1292         {
1293                 this.chatbubbleentity = new(chatbubbleentity);
1294                 this.chatbubbleentity.owner = this;
1295                 this.chatbubbleentity.exteriormodeltoclient = this;
1296                 setthink(this.chatbubbleentity, ChatBubbleThink);
1297                 this.chatbubbleentity.nextthink = time;
1298                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1299                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1300                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1301                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1302                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1303                 //this.chatbubbleentity.model = "";
1304                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1305         }
1306 }
1307
1308
1309 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1310 // added to the model skins
1311 /*void UpdateColorModHack()
1312 {
1313         float c;
1314         c = this.clientcolors & 15;
1315         // LordHavoc: only bothering to support white, green, red, yellow, blue
1316              if (!teamplay) this.colormod = '0 0 0';
1317         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1318         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1319         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1320         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1321         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1322         else this.colormod = '1 1 1';
1323 }*/
1324
1325 void respawn(entity this)
1326 {
1327         bool damagedbycontents_prev = this.damagedbycontents;
1328         if(this.alpha >= 0)
1329         {
1330                 if(autocvar_g_respawn_ghosts)
1331                 {
1332                         this.solid = SOLID_NOT;
1333                         this.takedamage = DAMAGE_NO;
1334                         this.damagedbycontents = false;
1335                         set_movetype(this, MOVETYPE_FLY);
1336                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1337                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1338                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1339                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1340                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1341                         if(autocvar_g_respawn_ghosts_time > 0)
1342                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1343                 }
1344                 else
1345                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1346         }
1347
1348         CopyBody(this, 1);
1349         this.damagedbycontents = damagedbycontents_prev;
1350
1351         this.effects |= EF_NODRAW; // prevent another CopyBody
1352         PutClientInServer(this);
1353 }
1354
1355 ERASEABLE
1356 void PrintToChat(entity client, string text)
1357 {
1358         text = strcat("\{1}^7", text, "\n");
1359         sprint(client, text);
1360 }
1361
1362 ERASEABLE
1363 void DebugPrintToChat(entity client, string text)
1364 {
1365         if (autocvar_developer > 0)
1366         {
1367                 PrintToChat(client, text);
1368         }
1369 }
1370
1371 ERASEABLE
1372 void PrintToChatAll(string text)
1373 {
1374         text = strcat("\{1}^7", text, "\n");
1375         bprint(text);
1376 }
1377
1378 ERASEABLE
1379 void DebugPrintToChatAll(string text)
1380 {
1381         if (autocvar_developer > 0)
1382         {
1383                 PrintToChatAll(text);
1384         }
1385 }
1386
1387 ERASEABLE
1388 void PrintToChatTeam(int team_num, string text)
1389 {
1390         text = strcat("\{1}^7", text, "\n");
1391         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1392         {
1393                 if (it.team == team_num)
1394                 {
1395                         sprint(it, text);
1396                 }
1397         });
1398 }
1399
1400 ERASEABLE
1401 void DebugPrintToChatTeam(int team_num, string text)
1402 {
1403         if (autocvar_developer > 0)
1404         {
1405                 PrintToChatTeam(team_num, text);
1406         }
1407 }
1408
1409 void play_countdown(entity this, float finished, Sound samp)
1410 {
1411         TC(Sound, samp);
1412         if(IS_REAL_CLIENT(this))
1413                 if(floor(finished - time - frametime) != floor(finished - time))
1414                         if(finished - time < 6)
1415                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1416 }
1417
1418 void player_powerups(entity this)
1419 {
1420         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1421                 this.modelflags |= MF_ROCKET;
1422         else
1423                 this.modelflags &= ~MF_ROCKET;
1424
1425         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1426
1427         if (IS_DEAD(this))
1428         {
1429                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1430                 {
1431                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1432                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1433                         this.items &= ~ITEM_Strength.m_itemid;
1434                         this.items &= ~ITEM_Shield.m_itemid;
1435                         this.items -= (this.items & IT_SUPERWEAPON);
1436                 }
1437         }
1438
1439         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1440                 return;
1441
1442         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1443         int items_prev = this.items;
1444
1445         Fire_ApplyDamage(this);
1446         Fire_ApplyEffect(this);
1447
1448         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1449         {
1450                 if (this.items & ITEM_Strength.m_itemid)
1451                 {
1452                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1453                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1454                         if (time > STAT(STRENGTH_FINISHED, this))
1455                         {
1456                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1457                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1458                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1459                         }
1460                 }
1461                 else
1462                 {
1463                         if (time < STAT(STRENGTH_FINISHED, this))
1464                         {
1465                                 this.items = this.items | ITEM_Strength.m_itemid;
1466                                 if(!g_cts)
1467                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1468                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1469                         }
1470                 }
1471                 if (this.items & ITEM_Shield.m_itemid)
1472                 {
1473                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1474                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1475                         if (time > STAT(INVINCIBLE_FINISHED, this))
1476                         {
1477                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1478                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1479                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1480                         }
1481                 }
1482                 else
1483                 {
1484                         if (time < STAT(INVINCIBLE_FINISHED, this))
1485                         {
1486                                 this.items = this.items | ITEM_Shield.m_itemid;
1487                                 if(!g_cts)
1488                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1489                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1490                         }
1491                 }
1492                 if (this.items & IT_SUPERWEAPON)
1493                 {
1494                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1495                         {
1496                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1497                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1498                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1499                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1500                         }
1501                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1502                         {
1503                                 // don't let them run out
1504                         }
1505                         else
1506                         {
1507                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1508                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1509                                 {
1510                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1511                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1512                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1514                                 }
1515                         }
1516                 }
1517                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1518                 {
1519                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1520                         {
1521                                 this.items = this.items | IT_SUPERWEAPON;
1522                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1523                                 {
1524                                         if(!g_cts)
1525                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1526                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1527                                 }
1528                         }
1529                         else
1530                         {
1531                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1532                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1533                         }
1534                 }
1535                 else
1536                 {
1537                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1538                 }
1539         }
1540
1541         if(autocvar_g_nodepthtestplayers)
1542                 this.effects = this.effects | EF_NODEPTHTEST;
1543
1544         if(autocvar_g_fullbrightplayers)
1545                 this.effects = this.effects | EF_FULLBRIGHT;
1546
1547         if (time >= game_starttime)
1548         if (time < this.spawnshieldtime)
1549                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1550
1551         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1552 }
1553
1554 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1555 {
1556         if(current > stable)
1557                 return current;
1558         else if(current > stable - 0.25) // when close enough, "snap"
1559                 return stable;
1560         else
1561                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1562 }
1563
1564 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1565 {
1566         if(current < stable)
1567                 return current;
1568         else if(current < stable + 0.25) // when close enough, "snap"
1569                 return stable;
1570         else
1571                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1572 }
1573
1574 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1575 {
1576         float old = GetResource(this, res);
1577         float current = old;
1578         if(current > rotstable)
1579         {
1580                 if(rotframetime > 0)
1581                 {
1582                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1583                         current = max(rotstable, current - rotlinear * rotframetime);
1584                 }
1585         }
1586         else if(current < regenstable)
1587         {
1588                 if(regenframetime > 0)
1589                 {
1590                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1591                         current = min(regenstable, current + regenlinear * regenframetime);
1592                 }
1593         }
1594
1595         float limit = GetResourceLimit(this, res) * limit_mod;
1596         if(current > limit)
1597                 current = limit;
1598
1599         if (current != old)
1600                 SetResource(this, res, current);
1601 }
1602
1603 void player_regen(entity this)
1604 {
1605         float max_mod, regen_mod, rot_mod, limit_mod;
1606         max_mod = regen_mod = rot_mod = limit_mod = 1;
1607
1608         float regen_health = autocvar_g_balance_health_regen;
1609         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1610         float regen_health_rot = autocvar_g_balance_health_rot;
1611         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1612         float regen_health_stable = autocvar_g_balance_health_regenstable;
1613         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1614         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1615                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1616         max_mod = M_ARGV(1, float);
1617         regen_mod = M_ARGV(2, float);
1618         rot_mod = M_ARGV(3, float);
1619         limit_mod = M_ARGV(4, float);
1620         regen_health = M_ARGV(5, float);
1621         regen_health_linear = M_ARGV(6, float);
1622         regen_health_rot = M_ARGV(7, float);
1623         regen_health_rotlinear = M_ARGV(8, float);
1624         regen_health_stable = M_ARGV(9, float);
1625         regen_health_rotstable = M_ARGV(10, float);
1626
1627         if(!mutator_returnvalue)
1628         if(!STAT(FROZEN, this))
1629         {
1630                 float maxa = autocvar_g_balance_armor_rotstable;
1631                 float mina = autocvar_g_balance_armor_regenstable;
1632
1633                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1634                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1635                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1636
1637                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1638                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1639                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1640         }
1641
1642         // if player rotted to death...  die!
1643         // check this outside above checks, as player may still be able to rot to death
1644         if(GetResource(this, RES_HEALTH) < 1)
1645         {
1646                 if(this.vehicle)
1647                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1648                 if(this.event_damage)
1649                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1650         }
1651
1652         if (!(this.items & IT_UNLIMITED_AMMO))
1653         {
1654                 float maxf = autocvar_g_balance_fuel_rotstable;
1655                 float minf = autocvar_g_balance_fuel_regenstable;
1656
1657                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1658                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1659                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1660         }
1661 }
1662
1663 bool zoomstate_set;
1664 void SetZoomState(entity this, float newzoom)
1665 {
1666         if(newzoom != CS(this).zoomstate)
1667         {
1668                 CS(this).zoomstate = newzoom;
1669                 ClientData_Touch(this);
1670         }
1671         zoomstate_set = true;
1672 }
1673
1674 void GetPressedKeys(entity this)
1675 {
1676         MUTATOR_CALLHOOK(GetPressedKeys, this);
1677         int keys = STAT(PRESSED_KEYS, this);
1678         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1679         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1680         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1681         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1682
1683         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1684         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1685         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1686         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1687         CS(this).pressedkeys = keys; // store for other users
1688
1689         STAT(PRESSED_KEYS, this) = keys;
1690 }
1691
1692 /*
1693 ======================
1694 spectate mode routines
1695 ======================
1696 */
1697
1698 void SpectateCopy(entity this, entity spectatee)
1699 {
1700         TC(Client, this); TC(Client, spectatee);
1701
1702         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1703         PS(this) = PS(spectatee);
1704         this.armortype = spectatee.armortype;
1705         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1706         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1707         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1708         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1709         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1710         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1711         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1712         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1713         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1714         CS(this).impulse = 0;
1715         this.disableclientprediction = 1; // no need to run prediction on a spectator
1716         this.items = spectatee.items;
1717         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1718         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1719         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1720         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1721         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1722         this.air_finished = spectatee.air_finished;
1723         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1724         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1725         this.punchangle = spectatee.punchangle;
1726         this.view_ofs = spectatee.view_ofs;
1727         this.velocity = spectatee.velocity;
1728         this.dmg_take = spectatee.dmg_take;
1729         this.dmg_save = spectatee.dmg_save;
1730         this.dmg_inflictor = spectatee.dmg_inflictor;
1731         this.v_angle = spectatee.v_angle;
1732         this.angles = spectatee.v_angle;
1733         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1734         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1735         this.viewloc = spectatee.viewloc;
1736         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1737                 this.fixangle = true;
1738         setorigin(this, spectatee.origin);
1739         setsize(this, spectatee.mins, spectatee.maxs);
1740         SetZoomState(this, CS(spectatee).zoomstate);
1741
1742     anticheat_spectatecopy(this, spectatee);
1743         STAT(HUD, this) = STAT(HUD, spectatee);
1744         if(spectatee.vehicle)
1745     {
1746         this.angles = spectatee.v_angle;
1747
1748         //this.fixangle = false;
1749         //this.velocity = spectatee.vehicle.velocity;
1750         this.vehicle_health = spectatee.vehicle_health;
1751         this.vehicle_shield = spectatee.vehicle_shield;
1752         this.vehicle_energy = spectatee.vehicle_energy;
1753         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1754         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1755         this.vehicle_reload1 = spectatee.vehicle_reload1;
1756         this.vehicle_reload2 = spectatee.vehicle_reload2;
1757
1758         //msg_entity = this;
1759
1760        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1761             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1762            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1763            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1764
1765         //WriteByte (MSG_ONE, SVC_SETVIEW);
1766         //    WriteEntity(MSG_ONE, this);
1767         //makevectors(spectatee.v_angle);
1768         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1769     }
1770 }
1771
1772 bool SpectateUpdate(entity this)
1773 {
1774         if(!this.enemy)
1775                 return false;
1776
1777         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1778         {
1779                 SetSpectatee(this, NULL);
1780                 return false;
1781         }
1782
1783         SpectateCopy(this, this.enemy);
1784
1785         return true;
1786 }
1787
1788 bool SpectateSet(entity this)
1789 {
1790         if(!IS_PLAYER(this.enemy))
1791                 return false;
1792
1793         ClientData_Touch(this.enemy);
1794
1795         msg_entity = this;
1796         WriteByte(MSG_ONE, SVC_SETVIEW);
1797         WriteEntity(MSG_ONE, this.enemy);
1798         set_movetype(this, MOVETYPE_NONE);
1799         accuracy_resend(this);
1800
1801         if(!SpectateUpdate(this))
1802                 PutObserverInServer(this);
1803
1804         return true;
1805 }
1806
1807 void SetSpectatee_status(entity this, int spectatee_num)
1808 {
1809         int oldspectatee_status = CS(this).spectatee_status;
1810         CS(this).spectatee_status = spectatee_num;
1811
1812         if (CS(this).spectatee_status != oldspectatee_status)
1813         {
1814                 if (STAT(PRESSED_KEYS, this))
1815                 {
1816                         CS(this).pressedkeys = 0;
1817                         STAT(PRESSED_KEYS, this) = 0;
1818                 }
1819                 ClientData_Touch(this);
1820                 if (g_race || g_cts) race_InitSpectator();
1821         }
1822 }
1823
1824 void SetSpectatee(entity this, entity spectatee)
1825 {
1826         if(IS_BOT_CLIENT(this))
1827                 return; // bots abuse .enemy, this code is useless to them
1828
1829         entity old_spectatee = this.enemy;
1830
1831         this.enemy = spectatee;
1832
1833         // WEAPONTODO
1834         // these are required to fix the spectator bug with arc
1835         if(old_spectatee)
1836         {
1837                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1838                 {
1839                         .entity weaponentity = weaponentities[slot];
1840                         if(old_spectatee.(weaponentity).arc_beam)
1841                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1842                 }
1843         }
1844         if(this.enemy)
1845         {
1846                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1847                 {
1848                         .entity weaponentity = weaponentities[slot];
1849                         if(this.enemy.(weaponentity).arc_beam)
1850                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1851                 }
1852         }
1853
1854         if (this.enemy)
1855                 SetSpectatee_status(this, etof(this.enemy));
1856
1857         // needed to update spectator list
1858         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1859 }
1860
1861 bool Spectate(entity this, entity pl)
1862 {
1863         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1864                 return false;
1865         pl = M_ARGV(1, entity);
1866
1867         SetSpectatee(this, pl);
1868         return SpectateSet(this);
1869 }
1870
1871 bool SpectateNext(entity this)
1872 {
1873         entity ent = find(this.enemy, classname, STR_PLAYER);
1874
1875         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1876                 ent = M_ARGV(1, entity);
1877         else if (!ent)
1878                 ent = find(ent, classname, STR_PLAYER);
1879
1880         if(ent) { SetSpectatee(this, ent); }
1881
1882         return SpectateSet(this);
1883 }
1884
1885 bool SpectatePrev(entity this)
1886 {
1887         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1888         entity ent = findchain(classname, STR_PLAYER);
1889         if (!ent) // no player
1890                 return false;
1891
1892         entity first = ent;
1893         // skip players until current spectated player
1894         if(this.enemy)
1895         while(ent && ent != this.enemy)
1896                 ent = ent.chain;
1897
1898         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1899         {
1900                 case MUT_SPECPREV_FOUND:
1901                     ent = M_ARGV(1, entity);
1902                     break;
1903                 case MUT_SPECPREV_RETURN:
1904                     return true;
1905                 case MUT_SPECPREV_CONTINUE:
1906                 default:
1907                 {
1908                         if(ent.chain)
1909                                 ent = ent.chain;
1910                         else
1911                                 ent = first;
1912                         break;
1913                 }
1914         }
1915
1916         SetSpectatee(this, ent);
1917         return SpectateSet(this);
1918 }
1919
1920 /*
1921 =============
1922 ShowRespawnCountdown()
1923
1924 Update a respawn countdown display.
1925 =============
1926 */
1927 void ShowRespawnCountdown(entity this)
1928 {
1929         float number;
1930         if(!IS_DEAD(this)) // just respawned?
1931                 return;
1932         else
1933         {
1934                 number = ceil(this.respawn_time - time);
1935                 if(number <= 0)
1936                         return;
1937                 if(number <= this.respawn_countdown)
1938                 {
1939                         this.respawn_countdown = number - 1;
1940                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1941                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1942                 }
1943         }
1944 }
1945
1946 .bool team_selected;
1947 bool ShowTeamSelection(entity this)
1948 {
1949         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1950                 return false;
1951         stuffcmd(this, "menu_showteamselect\n");
1952         return true;
1953 }
1954 void Join(entity this)
1955 {
1956         TRANSMUTE(Player, this);
1957
1958         if(!this.team_selected)
1959         if(autocvar_g_campaign || autocvar_g_balance_teams)
1960                 TeamBalance_JoinBestTeam(this);
1961
1962         if(autocvar_g_campaign)
1963                 campaign_bots_may_start = true;
1964
1965         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1966
1967         PutClientInServer(this);
1968
1969         if(IS_PLAYER(this))
1970         if(teamplay && this.team != -1)
1971         {
1972         }
1973         else
1974                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1975         this.team_selected = false;
1976 }
1977
1978 int GetPlayerLimit()
1979 {
1980         if(g_duel)
1981                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1982         int player_limit = autocvar_g_maxplayers;
1983         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1984         player_limit = M_ARGV(0, int);
1985         return player_limit;
1986 }
1987
1988 /**
1989  * Determines whether the player is allowed to join. This depends on cvar
1990  * g_maxplayers, if it isn't used this function always return true, otherwise
1991  * it checks whether the number of currently playing players exceeds g_maxplayers.
1992  * @return int number of free slots for players, 0 if none
1993  */
1994 int nJoinAllowed(entity this, entity ignore)
1995 {
1996         if(!ignore)
1997         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1998         // so report 0 free slots if restricted
1999         {
2000                 if(autocvar_g_forced_team_otherwise == "spectate")
2001                         return 0;
2002                 if(autocvar_g_forced_team_otherwise == "spectator")
2003                         return 0;
2004         }
2005
2006         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2007                 return 0; // forced spectators can never join
2008
2009         // TODO simplify this
2010         int totalClients = 0;
2011         int currentlyPlaying = 0;
2012         FOREACH_CLIENT(true, {
2013                 if(it != ignore)
2014                         ++totalClients;
2015                 if(IS_REAL_CLIENT(it))
2016                 if(IS_PLAYER(it) || it.caplayer)
2017                         ++currentlyPlaying;
2018         });
2019
2020         int player_limit = GetPlayerLimit();
2021
2022         int free_slots = 0;
2023         if (!player_limit)
2024                 free_slots = maxclients - totalClients;
2025         else if(player_limit > 0 && currentlyPlaying < player_limit)
2026                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2027
2028         static float msg_time = 0;
2029         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2030         {
2031                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2032                 msg_time = time + 0.5;
2033         }
2034
2035         return free_slots;
2036 }
2037
2038 /**
2039  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2040  * g_maxplayers_spectator_blocktime seconds
2041  */
2042 void checkSpectatorBlock(entity this)
2043 {
2044         if(IS_SPEC(this) || IS_OBSERVER(this))
2045         if(!this.caplayer)
2046         if(IS_REAL_CLIENT(this))
2047         {
2048                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2049                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2050                         dropclient(this);
2051                 }
2052         }
2053 }
2054
2055 void PrintWelcomeMessage(entity this)
2056 {
2057         if(CS(this).motd_actived_time == 0)
2058         {
2059                 if (autocvar_g_campaign) {
2060                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2061                                 CS(this).motd_actived_time = time;
2062                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2063                         }
2064                 } else {
2065                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2066                                 CS(this).motd_actived_time = time;
2067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2068                         }
2069                 }
2070         }
2071         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2072         {
2073                 if (autocvar_g_campaign) {
2074                         if (PHYS_INPUT_BUTTON_INFO(this))
2075                                 CS(this).motd_actived_time = time;
2076                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2077                                 CS(this).motd_actived_time = 0;
2078                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2079                         }
2080                 } else {
2081                         if (PHYS_INPUT_BUTTON_INFO(this))
2082                                 CS(this).motd_actived_time = time;
2083                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2084                                 CS(this).motd_actived_time = 0;
2085                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2086                         }
2087                 }
2088         }
2089         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2090         {
2091                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2092                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2093                 else if (CS(this).motd_actived_time == -2)
2094                 {
2095                         // instantly hide MOTD
2096                         CS(this).motd_actived_time = 0;
2097                         if (autocvar_g_campaign)
2098                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2099                         else
2100                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2101                 }
2102                 else if (IS_PLAYER(this) || IS_SPEC(this))
2103                 {
2104                         // FIXME occasionally for some reason MOTD never goes away
2105                         // delay MOTD removal a little bit in the hope it fixes this bug
2106                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2107                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2108                         else //if (CS(this).motd_actived_time < -2)
2109                                 CS(this).motd_actived_time++;
2110                 }
2111         }
2112 }
2113
2114 bool joinAllowed(entity this)
2115 {
2116         if (CS(this).version_mismatch) return false;
2117         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2118         if (!nJoinAllowed(this, this)) return false;
2119         if (teamplay && lockteams) return false;
2120         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2121         if (ShowTeamSelection(this)) return false;
2122         return true;
2123 }
2124
2125 .string shootfromfixedorigin;
2126 .bool dualwielding_prev;
2127 bool PlayerThink(entity this)
2128 {
2129         if (game_stopped || intermission_running) {
2130                 this.modelflags &= ~MF_ROCKET;
2131                 if(intermission_running)
2132                         IntermissionThink(this);
2133                 return false;
2134         }
2135
2136         if (timeout_status == TIMEOUT_ACTIVE) {
2137         // don't allow the player to turn around while game is paused
2138                 // FIXME turn this into CSQC stuff
2139                 this.v_angle = this.lastV_angle;
2140                 this.angles = this.lastV_angle;
2141                 this.fixangle = true;
2142         }
2143
2144         if (frametime) player_powerups(this);
2145
2146         if (IS_DEAD(this)) {
2147                 if (this.personal && g_race_qualifying) {
2148                         if (time > this.respawn_time) {
2149                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2150                                 respawn(this);
2151                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2152                         }
2153                 } else {
2154                         if (frametime) player_anim(this);
2155
2156                         if (this.respawn_flags & RESPAWN_DENY)
2157                         {
2158                                 STAT(RESPAWN_TIME, this) = 0;
2159                                 return false;
2160                         }
2161
2162                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2163
2164                         switch(this.deadflag)
2165                         {
2166                                 case DEAD_DYING:
2167                                 {
2168                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2169                                                 this.deadflag = DEAD_RESPAWNING;
2170                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2171                                                 this.deadflag = DEAD_DEAD;
2172                                         break;
2173                                 }
2174                                 case DEAD_DEAD:
2175                                 {
2176                                         if (button_pressed)
2177                                                 this.deadflag = DEAD_RESPAWNABLE;
2178                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2179                                                 this.deadflag = DEAD_RESPAWNING;
2180                                         break;
2181                                 }
2182                                 case DEAD_RESPAWNABLE:
2183                                 {
2184                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2185                                                 this.deadflag = DEAD_RESPAWNING;
2186                                         break;
2187                                 }
2188                                 case DEAD_RESPAWNING:
2189                                 {
2190                                         if (time > this.respawn_time)
2191                                         {
2192                                                 this.respawn_time = time + 1; // only retry once a second
2193                                                 this.respawn_time_max = this.respawn_time;
2194                                                 respawn(this);
2195                                         }
2196                                         break;
2197                                 }
2198                         }
2199
2200                         ShowRespawnCountdown(this);
2201
2202                         if (this.respawn_flags & RESPAWN_SILENT)
2203                                 STAT(RESPAWN_TIME, this) = 0;
2204                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2205                         {
2206                                 if (time < this.respawn_time)
2207                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2208                                 else if (this.deadflag != DEAD_RESPAWNING)
2209                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2210                         }
2211                         else
2212                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2213                 }
2214
2215                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2216                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2217                         STAT(RESPAWN_TIME, this) *= -1;
2218
2219                 return false;
2220         }
2221
2222         FixPlayermodel(this);
2223
2224         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2225                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2226                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2227         }
2228
2229         // reset gun alignment when dual wielding status changes
2230         // to ensure guns are always aligned right and left
2231         bool dualwielding = W_DualWielding(this);
2232         if(this.dualwielding_prev != dualwielding)
2233         {
2234                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2235                 this.dualwielding_prev = dualwielding;
2236         }
2237
2238         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2239         //if(frametime)
2240         {
2241                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2242                 {
2243                         .entity weaponentity = weaponentities[slot];
2244                         if(WEP_CVAR(vortex, charge_always))
2245                                 W_Vortex_Charge(this, weaponentity, frametime);
2246                         W_WeaponFrame(this, weaponentity);
2247                 }
2248         }
2249
2250         if (frametime)
2251         {
2252                 // WEAPONTODO: Add a weapon request for this
2253                 // rot vortex charge to the charge limit
2254                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2255                 {
2256                         .entity weaponentity = weaponentities[slot];
2257                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2258                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2259                 }
2260
2261                 player_regen(this);
2262                 player_anim(this);
2263                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2264         }
2265
2266         secrets_setstatus(this);
2267         monsters_setstatus(this);
2268
2269         return true;
2270 }
2271
2272 .bool would_spectate;
2273 void ObserverOrSpectatorThink(entity this)
2274 {
2275         bool is_spec = IS_SPEC(this);
2276         if ( CS(this).impulse )
2277         {
2278                 int r = MinigameImpulse(this, CS(this).impulse);
2279                 if (!is_spec || r)
2280                         CS(this).impulse = 0;
2281
2282                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2283                 {
2284                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2285                         CS(this).impulse = 0;
2286                         return;
2287                 }
2288         }
2289
2290         if (this.flags & FL_JUMPRELEASED) {
2291                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2292                         this.flags &= ~FL_JUMPRELEASED;
2293                         this.flags |= FL_SPAWNING;
2294                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2295                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2296                         this.flags &= ~FL_JUMPRELEASED;
2297                         if(SpectateNext(this)) {
2298                                 TRANSMUTE(Spectator, this);
2299                         } else if (is_spec) {
2300                                 TRANSMUTE(Observer, this);
2301                                 PutClientInServer(this);
2302                         }
2303                         if (is_spec)
2304                                 CS(this).impulse = 0;
2305                 } else if (is_spec) {
2306                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2307                                 this.flags &= ~FL_JUMPRELEASED;
2308                                 if(SpectatePrev(this)) {
2309                                         TRANSMUTE(Spectator, this);
2310                                 } else {
2311                                         TRANSMUTE(Observer, this);
2312                                         PutClientInServer(this);
2313                                 }
2314                                 CS(this).impulse = 0;
2315                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2316                                 this.would_spectate = false;
2317                                 this.flags &= ~FL_JUMPRELEASED;
2318                                 TRANSMUTE(Observer, this);
2319                                 PutClientInServer(this);
2320                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2321                                 PutObserverInServer(this);
2322                                 this.would_spectate = true;
2323                         }
2324                 }
2325                 else {
2326                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2327                         set_movetype(this, preferred_movetype);
2328                 }
2329         } else {
2330                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2331                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2332                         this.flags |= FL_JUMPRELEASED;
2333                         if(this.flags & FL_SPAWNING)
2334                         {
2335                                 this.flags &= ~FL_SPAWNING;
2336                                 if(joinAllowed(this))
2337                                         Join(this);
2338                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2339                                         CS(this).autojoin_checked = -1;
2340                                 return;
2341                         }
2342                 }
2343                 if(is_spec && !SpectateUpdate(this))
2344                         PutObserverInServer(this);
2345         }
2346         if (is_spec)
2347                 this.flags |= FL_CLIENT | FL_NOTARGET;
2348 }
2349
2350 void PlayerUseKey(entity this)
2351 {
2352         if (!IS_PLAYER(this))
2353                 return;
2354
2355         if(this.vehicle)
2356         {
2357                 if(!game_stopped)
2358                 {
2359                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2360                         return;
2361                 }
2362         }
2363         else if(autocvar_g_vehicles_enter)
2364         {
2365                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2366                 {
2367                         entity head, closest_target = NULL;
2368                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2369
2370                         while(head) // find the closest acceptable target to enter
2371                         {
2372                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2373                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2374                                 {
2375                                         if(closest_target)
2376                                         {
2377                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2378                                                 { closest_target = head; }
2379                                         }
2380                                         else { closest_target = head; }
2381                                 }
2382
2383                                 head = head.chain;
2384                         }
2385
2386                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2387                 }
2388         }
2389
2390         // a use key was pressed; call handlers
2391         MUTATOR_CALLHOOK(PlayerUseKey, this);
2392 }
2393
2394
2395 /*
2396 =============
2397 PlayerPreThink
2398
2399 Called every frame for each client before the physics are run
2400 =============
2401 */
2402 .float last_vehiclecheck;
2403 void PlayerPreThink (entity this)
2404 {
2405         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2406         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2407
2408         WarpZone_PlayerPhysics_FixVAngle(this);
2409
2410         if (frametime) {
2411                 // physics frames: update anticheat stuff
2412                 anticheat_prethink(this);
2413         }
2414
2415         if (blockSpectators && frametime) {
2416                 // WORKAROUND: only use dropclient in server frames (frametime set).
2417                 // Never use it in cl_movement frames (frametime zero).
2418                 checkSpectatorBlock(this);
2419         }
2420
2421         zoomstate_set = false;
2422
2423         // Check for nameless players
2424         if (this.netname == "" || this.netname != CS(this).netname_previous)
2425         {
2426                 bool assume_unchanged = (CS(this).netname_previous == "");
2427                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2428                 {
2429                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2430                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2431                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2432                         assume_unchanged = false;
2433                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2434                 }
2435                 if (isInvisibleString(this.netname))
2436                 {
2437                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2438                         sprint(this, "Warning: invisible names are not allowed.\n");
2439                         assume_unchanged = false;
2440                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2441                 }
2442                 if (!assume_unchanged && autocvar_sv_eventlog)
2443                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2444                 strcpy(CS(this).netname_previous, this.netname);
2445         }
2446
2447         // version nagging
2448         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2449         CS(this).version_nagtime = 0;
2450         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2451             // git client
2452         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2453             // git server
2454             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2455         } else {
2456             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2457             if (r < 0) { // old client
2458                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2459             } else if (r > 0) { // old server
2460                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2461             }
2462         }
2463     }
2464
2465         // GOD MODE info
2466         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2467         {
2468                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2469                 this.max_armorvalue = 0;
2470         }
2471
2472         if (frametime && IS_PLAYER(this))
2473         {
2474                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2475                 {
2476                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2477                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2478                         if (this.iceblock)
2479                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2480
2481                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2482                                 Unfreeze(this, false);
2483                 }
2484                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2485                 {
2486                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2487                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2488
2489                         if (GetResource(this, RES_HEALTH) < 1)
2490                         {
2491                                 if (this.vehicle)
2492                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2493                                 if(this.event_damage)
2494                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2495                         }
2496                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2497                                 Unfreeze(this, false);
2498                 }
2499         }
2500
2501         MUTATOR_CALLHOOK(PlayerPreThink, this);
2502
2503         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2504         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2505         {
2506                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2507                 {
2508                         if(!it.owner)
2509                         {
2510                                 if(!it.team || SAME_TEAM(this, it))
2511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2512                                 else if(autocvar_g_vehicles_steal)
2513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2514                         }
2515                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2516                         {
2517                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2518                         }
2519                 });
2520
2521                 this.last_vehiclecheck = time + 1;
2522         }
2523
2524         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2525         {
2526                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2527                         PlayerUseKey(this);
2528                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2529         }
2530
2531         if (IS_REAL_CLIENT(this))
2532                 PrintWelcomeMessage(this);
2533
2534         if (IS_PLAYER(this)) {
2535                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2536                         error("Client can't be spawned as player on connection!");
2537                 if(!PlayerThink(this))
2538                         return;
2539         }
2540         else if (game_stopped || intermission_running) {
2541                 if(intermission_running)
2542                         IntermissionThink(this);
2543                 return;
2544         }
2545         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2546         {
2547                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2548                 CS(this).autojoin_checked = 1;
2549                 // don't do this in ClientConnect
2550                 // many things can go wrong if a client is spawned as player on connection
2551                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2552                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2553                                 && (!teamplay || autocvar_g_balance_teams)))
2554                 {
2555                         campaign_bots_may_start = true;
2556                         if(joinAllowed(this))
2557                                 Join(this);
2558                         return;
2559                 }
2560         }
2561         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2562                 ObserverOrSpectatorThink(this);
2563         }
2564
2565         // WEAPONTODO: Add weapon request for this
2566         if (!zoomstate_set) {
2567                 bool wep_zoomed = false;
2568                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2569                 {
2570                         .entity weaponentity = weaponentities[slot];
2571                         Weapon thiswep = this.(weaponentity).m_weapon;
2572                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2573                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2574                 }
2575                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2576         }
2577
2578         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2579         {
2580                 CS(this).teamkill_soundtime = 0;
2581
2582                 entity e = CS(this).teamkill_soundsource;
2583                 entity oldpusher = e.pusher;
2584                 e.pusher = this;
2585                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2586                 e.pusher = oldpusher;
2587         }
2588
2589         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2590                 CS(this).taunt_soundtime = 0;
2591                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2592         }
2593
2594         target_voicescript_next(this);
2595
2596         // WEAPONTODO: Move into weaponsystem somehow
2597         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2598         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2599         {
2600                 .entity weaponentity = weaponentities[slot];
2601                 if(this.(weaponentity).m_weapon == WEP_Null)
2602                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2603         }
2604 }
2605
2606 void DrownPlayer(entity this)
2607 {
2608         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2609                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2610         {
2611                 this.air_finished = 0;
2612                 return;
2613         }
2614
2615         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2616         {
2617                 if(this.air_finished && this.air_finished < time)
2618                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2619                 this.air_finished = 0;
2620         }
2621         else
2622         {
2623                 if (!this.air_finished)
2624                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2625                 if (this.air_finished < time)
2626                 {       // drown!
2627                         if (this.pain_finished < time)
2628                         {
2629                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2630                                 this.pain_finished = time + 0.5;
2631                         }
2632                 }
2633         }
2634 }
2635
2636 .bool move_qcphysics;
2637
2638 void Player_Physics(entity this)
2639 {
2640         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2641
2642         if(!this.move_qcphysics)
2643                 return;
2644
2645         if(!frametime && !CS(this).pm_frametime)
2646                 return;
2647
2648         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2649
2650         CS(this).pm_frametime = 0;
2651 }
2652
2653 /*
2654 =============
2655 PlayerPostThink
2656
2657 Called every frame for each client after the physics are run
2658 =============
2659 */
2660 void PlayerPostThink (entity this)
2661 {
2662         Player_Physics(this);
2663
2664         if (sv_maxidle > 0)
2665         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2666         if (IS_REAL_CLIENT(this))
2667         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2668         {
2669                 int totalClients = 0;
2670                 if(sv_maxidle_slots > 0)
2671                 {
2672                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2673                         {
2674                                 ++totalClients;
2675                         });
2676                 }
2677
2678                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2679                 { /* do nothing */ }
2680                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2681                 {
2682                         if (CS(this).idlekick_lasttimeleft)
2683                         {
2684                                 CS(this).idlekick_lasttimeleft = 0;
2685                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2686                         }
2687                 }
2688                 else
2689                 {
2690                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2691                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2692                                 if (!CS(this).idlekick_lasttimeleft)
2693                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2694                         }
2695                         if (timeleft <= 0) {
2696                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2697                                 dropclient(this);
2698                                 return;
2699                         }
2700                         else if (timeleft <= 10) {
2701                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2702                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2703                 }
2704                                 CS(this).idlekick_lasttimeleft = timeleft;
2705                         }
2706                 }
2707         }
2708
2709         CheatFrame(this);
2710
2711         if (game_stopped)
2712         {
2713                 this.solid = SOLID_NOT;
2714                 this.takedamage = DAMAGE_NO;
2715                 set_movetype(this, MOVETYPE_NONE);
2716                 CS(this).teamkill_complain = 0;
2717                 CS(this).teamkill_soundtime = 0;
2718                 CS(this).teamkill_soundsource = NULL;
2719         }
2720
2721         if (IS_PLAYER(this)) {
2722                 if(this.death_time == time && IS_DEAD(this))
2723                 {
2724                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2725                         // once all the damage events of this frame have been processed with normal size
2726                         this.maxs.z = 5;
2727                         setsize(this, this.mins, this.maxs);
2728                 }
2729                 DrownPlayer(this);
2730                 UpdateChatBubble(this);
2731                 if (CS(this).impulse) ImpulseCommands(this);
2732                 if (game_stopped)
2733                 {
2734                         CSQCMODEL_AUTOUPDATE(this);
2735                         return;
2736                 }
2737                 GetPressedKeys(this);
2738         }
2739         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2740         {
2741                 CS(this).pressedkeys = 0;
2742                 STAT(PRESSED_KEYS, this) = 0;
2743         }
2744
2745         if (this.waypointsprite_attachedforcarrier) {
2746                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2747                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2748         }
2749
2750         CSQCMODEL_AUTOUPDATE(this);
2751 }
2752
2753 /**
2754  * message "": do not say, just test flood control
2755  * return value:
2756  *   1 = accept
2757  *   0 = reject
2758  *  -1 = fake accept
2759  */
2760 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2761 {
2762         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2763                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2764
2765         if (source)
2766                 msgin = formatmessage(source, msgin);
2767
2768         string colorstr;
2769         if (!(IS_PLAYER(source) || source.caplayer))
2770                 colorstr = "^0"; // black for spectators
2771         else if(teamplay)
2772                 colorstr = Team_ColorCode(source.team);
2773         else
2774         {
2775                 colorstr = "";
2776                 teamsay = false;
2777         }
2778
2779         if (!source) {
2780                 colorstr = "";
2781                 teamsay = false;
2782         }
2783
2784         if(msgin != "")
2785                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2786
2787         /*
2788          * using bprint solves this... me stupid
2789         // how can we prevent the message from appearing in a listen server?
2790         // for now, just give "say" back and only handle say_team
2791         if(!teamsay)
2792         {
2793                 clientcommand(source, strcat("say ", msgin));
2794                 return;
2795         }
2796         */
2797
2798         string namestr = "";
2799         if (source)
2800                 namestr = playername(source, autocvar_g_chat_teamcolors);
2801
2802         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2803
2804         string msgstr = "", cmsgstr = "";
2805         string privatemsgprefix = string_null;
2806         int privatemsgprefixlen = 0;
2807         if (msgin != "")
2808         {
2809                 bool found_me = false;
2810                 if(strstrofs(msgin, "/me", 0) >= 0)
2811                 {
2812                         string newmsgin = "";
2813                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2814                         FOREACH_WORD(msgin, true,
2815                         {
2816                                 if(strdecolorize(it) == "/me")
2817                                 {
2818                                         found_me = true;
2819                                         newmsgin = cons(newmsgin, newnamestr);
2820                                 }
2821                                 else
2822                                         newmsgin = cons(newmsgin, it);
2823                         });
2824                         msgin = newmsgin;
2825                 }
2826
2827                 if(privatesay)
2828                 {
2829                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2830                         privatemsgprefixlen = strlen(msgstr);
2831                         msgstr = strcat(msgstr, msgin);
2832                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2833                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2834                 }
2835                 else if(teamsay)
2836                 {
2837                         if(found_me)
2838                         {
2839                                 //msgin = strreplace("/me", "", msgin);
2840                                 //msgin = substring(msgin, 3, strlen(msgin));
2841                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2842                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2843                         }
2844                         else
2845                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2846                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2847                 }
2848                 else
2849                 {
2850                         if(found_me)
2851                         {
2852                                 //msgin = strreplace("/me", "", msgin);
2853                                 //msgin = substring(msgin, 3, strlen(msgin));
2854                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2855                                 msgstr = strcat("\{1}^4* ^7", msgin);
2856                         }
2857                         else {
2858                                 msgstr = "\{1}";
2859                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2860                                 msgstr = strcat(msgstr, msgin);
2861                         }
2862                         cmsgstr = "";
2863                 }
2864                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2865         }
2866
2867         string fullmsgstr = msgstr;
2868         string fullcmsgstr = cmsgstr;
2869
2870         // FLOOD CONTROL
2871         int flood = 0;
2872         var .float flood_field = floodcontrol_chat;
2873         if(floodcontrol && source)
2874         {
2875                 float flood_spl;
2876                 float flood_burst;
2877                 float flood_lmax;
2878                 float lines;
2879                 if(privatesay)
2880                 {
2881                         flood_spl = autocvar_g_chat_flood_spl_tell;
2882                         flood_burst = autocvar_g_chat_flood_burst_tell;
2883                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2884                         flood_field = floodcontrol_chattell;
2885                 }
2886                 else if(teamsay)
2887                 {
2888                         flood_spl = autocvar_g_chat_flood_spl_team;
2889                         flood_burst = autocvar_g_chat_flood_burst_team;
2890                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2891                         flood_field = floodcontrol_chatteam;
2892                 }
2893                 else
2894                 {
2895                         flood_spl = autocvar_g_chat_flood_spl;
2896                         flood_burst = autocvar_g_chat_flood_burst;
2897                         flood_lmax = autocvar_g_chat_flood_lmax;
2898                         flood_field = floodcontrol_chat;
2899                 }
2900                 flood_burst = max(0, flood_burst - 1);
2901                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2902
2903                 // do flood control for the default line size
2904                 if(msgstr != "")
2905                 {
2906                         getWrappedLine_remaining = msgstr;
2907                         msgstr = "";
2908                         lines = 0;
2909                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2910                         {
2911                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2912                                 ++lines;
2913                         }
2914                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2915
2916                         if(getWrappedLine_remaining != "")
2917                         {
2918                                 msgstr = strcat(msgstr, "\n");
2919                                 flood = 2;
2920                         }
2921
2922                         if (time >= source.(flood_field))
2923                         {
2924                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2925                         }
2926                         else
2927                         {
2928                                 flood = 1;
2929                                 msgstr = fullmsgstr;
2930                         }
2931                 }
2932                 else
2933                 {
2934                         if (time >= source.(flood_field))
2935                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2936                         else
2937                                 flood = 1;
2938                 }
2939
2940                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2941                         source.(flood_field) = flood = 0;
2942         }
2943
2944         string sourcemsgstr, sourcecmsgstr;
2945         if(flood == 2) // cannot happen for empty msgstr
2946         {
2947                 if(autocvar_g_chat_flood_notify_flooder)
2948                 {
2949                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2950                         sourcecmsgstr = "";
2951                 }
2952                 else
2953                 {
2954                         sourcemsgstr = fullmsgstr;
2955                         sourcecmsgstr = fullcmsgstr;
2956                 }
2957                 cmsgstr = "";
2958         }
2959         else
2960         {
2961                 sourcemsgstr = msgstr;
2962                 sourcecmsgstr = cmsgstr;
2963         }
2964
2965         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2966         {
2967                 if (!game_stopped)
2968                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2969                         teamsay = -1; // spectators
2970         }
2971
2972         if(flood)
2973                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2974
2975         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2976         if(privatesay)
2977                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2978
2979         int ret;
2980         if(source && CS(source).muted)
2981         {
2982                 // always fake the message
2983                 ret = -1;
2984         }
2985         else if(flood == 1)
2986         {
2987                 if (autocvar_g_chat_flood_notify_flooder)
2988                 {
2989                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2990                         ret = 0;
2991                 }
2992                 else
2993                         ret = -1;
2994         }
2995         else
2996         {
2997                 ret = 1;
2998         }
2999
3000         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3001         {
3002                 if (!game_stopped)
3003                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3004                         ret = -1; // just hide the message completely
3005         }
3006
3007         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3008         ret = M_ARGV(1, int);
3009
3010         string event_log_msg = "";
3011
3012         if(sourcemsgstr != "" && ret != 0)
3013         {
3014                 if(ret < 0) // faked message, because the player is muted
3015                 {
3016                         sprint(source, sourcemsgstr);
3017                         if(sourcecmsgstr != "" && !privatesay)
3018                                 centerprint(source, sourcecmsgstr);
3019                 }
3020                 else if(privatesay) // private message, between 2 people only
3021                 {
3022                         sprint(source, sourcemsgstr);
3023                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3024                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3025                         {
3026                                 sprint(privatesay, msgstr);
3027                                 if(cmsgstr != "")
3028                                         centerprint(privatesay, cmsgstr);
3029                         }
3030                 }
3031                 else if ( teamsay && CS(source).active_minigame )
3032                 {
3033                         sprint(source, sourcemsgstr);
3034                         dedicated_print(msgstr); // send to server console too
3035                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3036                                 sprint(it, msgstr);
3037                         });
3038                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3039
3040                 }
3041                 else if(teamsay > 0) // team message, only sent to team mates
3042                 {
3043                         sprint(source, sourcemsgstr);
3044                         dedicated_print(msgstr); // send to server console too
3045                         if(sourcecmsgstr != "")
3046                                 centerprint(source, sourcecmsgstr);
3047                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3048                                 sprint(it, msgstr);
3049                                 if(cmsgstr != "")
3050                                         centerprint(it, cmsgstr);
3051                         });
3052                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3053                 }
3054                 else if(teamsay < 0) // spectator message, only sent to spectators
3055                 {
3056                         sprint(source, sourcemsgstr);
3057                         dedicated_print(msgstr); // send to server console too
3058                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3059                                 sprint(it, msgstr);
3060                         });
3061                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3062                 }
3063                 else
3064                 {
3065                         if (source) {
3066                                 sprint(source, sourcemsgstr);
3067                                 dedicated_print(msgstr); // send to server console too
3068                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3069                         }
3070                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3071                                 sprint(it, msgstr);
3072                         });
3073                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3074                 }
3075         }
3076
3077         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3078                 GameLogEcho(event_log_msg);
3079         }
3080
3081         return ret;
3082 }
3083
3084 // hack to copy the button fields from the client entity to the Client State
3085 void PM_UpdateButtons(entity this, entity store)
3086 {
3087         if(this.impulse)
3088                 store.impulse = this.impulse;
3089         this.impulse = 0;
3090
3091         bool typing = this.buttonchat || this.button12;
3092
3093         store.button0 = (typing) ? 0 : this.button0;
3094         //button1?!
3095         store.button2 = (typing) ? 0 : this.button2;
3096         store.button3 = (typing) ? 0 : this.button3;
3097         store.button4 = this.button4;
3098         store.button5 = (typing) ? 0 : this.button5;
3099         store.button6 = this.button6;
3100         store.button7 = this.button7;
3101         store.button8 = this.button8;
3102         store.button9 = this.button9;
3103         store.button10 = this.button10;
3104         store.button11 = this.button11;
3105         store.button12 = this.button12;
3106         store.button13 = this.button13;
3107         store.button14 = this.button14;
3108         store.button15 = this.button15;
3109         store.button16 = this.button16;
3110         store.buttonuse = this.buttonuse;
3111         store.buttonchat = this.buttonchat;
3112
3113         store.cursor_active = this.cursor_active;
3114         store.cursor_screen = this.cursor_screen;
3115         store.cursor_trace_start = this.cursor_trace_start;
3116         store.cursor_trace_endpos = this.cursor_trace_endpos;
3117         store.cursor_trace_ent = this.cursor_trace_ent;
3118
3119         store.ping = this.ping;
3120         store.ping_packetloss = this.ping_packetloss;
3121         store.ping_movementloss = this.ping_movementloss;
3122
3123         store.v_angle = this.v_angle;
3124         store.movement = this.movement;
3125 }
3126
3127 NET_HANDLE(fpsreport, bool)
3128 {
3129         int fps = ReadShort();
3130         PlayerScore_Set(sender, SP_FPS, fps);
3131         return true;
3132 }