Don't attempt to network more than the maximum number of shown spectators, fixes...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <common/weapons/_all.qh>
4 #include <common/stats.qh>
5 #include <server/miscfunctions.qh>
6 #include <common/effects/all.qh>
7 #include "anticheat.qh"
8 #include "impulse.qh"
9 #include "player.qh"
10 #include "ipban.qh"
11 #include "miscfunctions.qh"
12 #include "portals.qh"
13 #include "teamplay.qh"
14 #include "spawnpoints.qh"
15 #include "resources.qh"
16 #include "g_damage.qh"
17 #include "handicap.qh"
18 #include "g_hook.qh"
19 #include "command/common.qh"
20 #include "command/vote.qh"
21 #include "clientkill.qh"
22 #include "cheats.qh"
23 #include "g_world.qh"
24 #include <server/gamelog.qh>
25 #include "race.qh"
26 #include <server/sv_main.qh>
27 #include "antilag.qh"
28 #include "campaign.qh"
29 #include "command/common.qh"
30 #include "scores_rules.qh"
31 #include "weapons/common.qh"
32
33 #include "bot/api.qh"
34
35 #include "../common/ent_cs.qh"
36 #include "../common/wepent.qh"
37 #include <common/state.qh>
38
39 #include "compat/quake3.qh"
40
41 #include <common/effects/qc/globalsound.qh>
42
43 #include "../common/mapobjects/func/conveyor.qh"
44 #include <common/mapobjects/func/ladder.qh>
45 #include "../common/mapobjects/teleporters.qh"
46 #include "../common/mapobjects/target/spawnpoint.qh"
47 #include <common/mapobjects/trigger/counter.qh>
48 #include <common/mapobjects/trigger/swamp.qh>
49
50 #include "../common/vehicles/all.qh"
51
52 #include "weapons/hitplot.qh"
53 #include "weapons/selection.qh"
54 #include "weapons/weaponsystem.qh"
55
56 #include "../common/net_notice.qh"
57 #include "../common/net_linked.qh"
58 #include "../common/physics/player.qh"
59
60 #include <common/vehicles/sv_vehicles.qh>
61
62 #include "../common/items/_mod.qh"
63
64 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
65
66 #include "../common/mutators/mutator/waypoints/all.qh"
67 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
68 #include <common/gamemodes/_mod.qh>
69
70 #include "../common/mapobjects/subs.qh"
71 #include "../common/mapobjects/triggers.qh"
72 #include "../common/mapobjects/trigger/secret.qh"
73
74 #include "../common/minigames/sv_minigames.qh"
75
76 #include "../common/items/inventory.qh"
77
78 #include "../common/monsters/sv_monsters.qh"
79
80 #include "../lib/warpzone/server.qh"
81
82 #include <common/mutators/mutator/overkill/oknex.qh>
83
84 #include <common/weapons/weapon/vortex.qh>
85
86 STATIC_METHOD(Client, Add, void(Client this, int _team))
87 {
88     ClientConnect(this);
89     TRANSMUTE(Player, this);
90     this.frame = 12; // 7
91     this.team = _team;
92     PutClientInServer(this);
93 }
94
95 STATIC_METHOD(Client, Remove, void(Client this))
96 {
97     TRANSMUTE(Observer, this);
98     PutClientInServer(this);
99     ClientDisconnect(this);
100 }
101
102 void send_CSQC_teamnagger() {
103         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
104 }
105
106 int CountSpectators(entity player, entity to)
107 {
108         if(!player) { return 0; } // not sure how, but best to be safe
109
110         int spec_count = 0;
111
112         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
113         {
114                 spec_count++;
115         });
116
117         return spec_count;
118 }
119
120 void WriteSpectators(entity player, entity to)
121 {
122         if(!player) { return; } // not sure how, but best to be safe
123
124         int spec_count = 0;
125         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
126         {
127                 if(spec_count >= MAX_SPECTATORS)
128                         break;
129                 WriteByte(MSG_ENTITY, num_for_edict(it));
130                 ++spec_count;
131         });
132 }
133
134 bool ClientData_Send(entity this, entity to, int sf)
135 {
136         assert(to == this.owner, return false);
137
138         entity e = to;
139         if (IS_SPEC(e)) e = e.enemy;
140
141         sf = 0;
142         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
143         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
144         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
145         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
146
147         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
148         WriteByte(MSG_ENTITY, sf);
149
150         if (sf & BIT(1))
151                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
152
153         if(sf & BIT(4))
154         {
155                 float specs = CountSpectators(e, to);
156                 WriteByte(MSG_ENTITY, specs);
157                 WriteSpectators(e, to);
158         }
159
160         return true;
161 }
162
163 void ClientData_Attach(entity this)
164 {
165         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
166         CS(this).clientdata.drawonlytoclient = this;
167         CS(this).clientdata.owner = this;
168 }
169
170 void ClientData_Detach(entity this)
171 {
172         delete(CS(this).clientdata);
173         CS(this).clientdata = NULL;
174 }
175
176 void ClientData_Touch(entity e)
177 {
178         entity cd = CS(e).clientdata;
179         if (cd) { cd.SendFlags = 1; }
180
181         // make it spectatable
182         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
183         {
184                 entity cd = CS(it).clientdata;
185                 if (cd) { cd.SendFlags = 1; }
186         });
187 }
188
189
190 /*
191 =============
192 CheckPlayerModel
193
194 Checks if the argument string can be a valid playermodel.
195 Returns a valid one in doubt.
196 =============
197 */
198 string FallbackPlayerModel;
199 string CheckPlayerModel(string plyermodel) {
200         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
201         {
202                 // note: we cannot summon Don Strunzone here, some player may
203                 // still have the model string set. In case anyone manages how
204                 // to change a cvar default, we'll have a small leak here.
205                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
206         }
207         // only in right path
208         if( substring(plyermodel,0,14) != "models/player/")
209                 return FallbackPlayerModel;
210         // only good file extensions
211         if(substring(plyermodel,-4,4) != ".zym")
212         if(substring(plyermodel,-4,4) != ".dpm")
213         if(substring(plyermodel,-4,4) != ".iqm")
214         if(substring(plyermodel,-4,4) != ".md3")
215         if(substring(plyermodel,-4,4) != ".psk")
216                 return FallbackPlayerModel;
217         // forbid the LOD models
218         if(substring(plyermodel, -9,5) == "_lod1")
219                 return FallbackPlayerModel;
220         if(substring(plyermodel, -9,5) == "_lod2")
221                 return FallbackPlayerModel;
222         if(plyermodel != strtolower(plyermodel))
223                 return FallbackPlayerModel;
224         // also, restrict to server models
225         if(autocvar_sv_servermodelsonly)
226         {
227                 if(!fexists(plyermodel))
228                         return FallbackPlayerModel;
229         }
230         return plyermodel;
231 }
232
233 void setplayermodel(entity e, string modelname)
234 {
235         precache_model(modelname);
236         _setmodel(e, modelname);
237         player_setupanimsformodel(e);
238         if(!autocvar_g_debug_globalsounds)
239                 UpdatePlayerSounds(e);
240 }
241
242 /** putting a client as observer in the server */
243 void PutObserverInServer(entity this)
244 {
245     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
246         PlayerState_detach(this);
247
248         if (IS_PLAYER(this))
249         {
250                 if(GetResource(this, RES_HEALTH) >= 1)
251                 {
252                         // despawn effect
253                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
254                 }
255
256                 // was a player, recount votes and ready status
257                 if(IS_REAL_CLIENT(this))
258                 {
259                         if (vote_called) { VoteCount(false); }
260                         ReadyCount();
261                 }
262     }
263
264     {
265         entity spot = SelectSpawnPoint(this, true);
266         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
267         this.angles = vec2(spot.angles);
268         this.fixangle = true;
269         // offset it so that the spectator spawns higher off the ground, looks better this way
270         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
271         if (IS_REAL_CLIENT(this))
272         {
273             msg_entity = this;
274             WriteByte(MSG_ONE, SVC_SETVIEW);
275             WriteEntity(MSG_ONE, this);
276         }
277         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
278         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
279         if(!autocvar_g_debug_globalsounds)
280         {
281                 // needed for player sounds
282                 this.model = "";
283                 FixPlayermodel(this);
284         }
285         setmodel(this, MDL_Null);
286         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
287         this.view_ofs = '0 0 0';
288     }
289
290     RemoveGrapplingHooks(this);
291         Portal_ClearAll(this);
292         Unfreeze(this, false);
293         SetSpectatee(this, NULL);
294
295         if (this.alivetime)
296         {
297                 if (!warmup_stage)
298                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
299                 this.alivetime = 0;
300         }
301
302         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
303
304         WaypointSprite_PlayerDead(this);
305
306         if (CS(this).killcount != FRAGS_SPECTATOR)
307         {
308                 if(!game_stopped)
309                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
310                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
311         }
312
313         accuracy_resend(this);
314
315         CS(this).spectatortime = time;
316         if(this.bot_attack)
317                 IL_REMOVE(g_bot_targets, this);
318         this.bot_attack = false;
319         if(this.monster_attack)
320                 IL_REMOVE(g_monster_targets, this);
321         this.monster_attack = false;
322     STAT(HUD, this) = HUD_NORMAL;
323         TRANSMUTE(Observer, this);
324         this.iscreature = false;
325         this.teleportable = TELEPORT_SIMPLE;
326         if(this.damagedbycontents)
327                 IL_REMOVE(g_damagedbycontents, this);
328         this.damagedbycontents = false;
329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
330         SetSpectatee_status(this, etof(this));
331         this.takedamage = DAMAGE_NO;
332         this.solid = SOLID_NOT;
333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
334         this.flags = FL_CLIENT | FL_NOTARGET;
335         this.effects = 0;
336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
337         this.pauserotarmor_finished = 0;
338         this.pauserothealth_finished = 0;
339         this.pauseregen_finished = 0;
340         this.damageforcescale = 0;
341         this.death_time = 0;
342         this.respawn_flags = 0;
343         this.respawn_time = 0;
344         STAT(RESPAWN_TIME, this) = 0;
345         this.alpha = 0;
346         this.scale = 0;
347         this.fade_time = 0;
348         this.pain_finished = 0;
349         STAT(STRENGTH_FINISHED, this) = 0;
350         STAT(INVINCIBLE_FINISHED, this) = 0;
351         STAT(SUPERWEAPONS_FINISHED, this) = 0;
352         STAT(AIR_FINISHED, this) = 0;
353         //this.dphitcontentsmask = 0;
354         this.dphitcontentsmask = DPCONTENTS_SOLID;
355         if (autocvar_g_playerclip_collisions)
356                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
357         this.pushltime = 0;
358         this.istypefrag = 0;
359         setthink(this, func_null);
360         this.nextthink = 0;
361         this.deadflag = DEAD_NO;
362         UNSET_DUCKED(this);
363         STAT(REVIVE_PROGRESS, this) = 0;
364         this.revival_time = 0;
365         this.draggable = drag_undraggable;
366
367         this.items = 0;
368         STAT(WEAPONS, this) = '0 0 0';
369         this.drawonlytoclient = this;
370
371         this.viewloc = NULL;
372
373         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
374
375         this.weaponmodel = "";
376         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
377         {
378                 this.weaponentities[slot] = NULL;
379         }
380         this.exteriorweaponentity = NULL;
381         CS(this).killcount = FRAGS_SPECTATOR;
382         this.velocity = '0 0 0';
383         this.avelocity = '0 0 0';
384         this.punchangle = '0 0 0';
385         this.punchvector = '0 0 0';
386         this.oldvelocity = this.velocity;
387         this.fire_endtime = -1;
388         this.event_damage = func_null;
389         this.event_heal = func_null;
390
391         for(int slot = 0; slot < MAX_AXH; ++slot)
392         {
393                 entity axh = this.(AuxiliaryXhair[slot]);
394                 this.(AuxiliaryXhair[slot]) = NULL;
395
396                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
397                         delete(axh);
398         }
399
400         if (mutator_returnvalue)
401         {
402                 // mutator prevents resetting teams+score
403         }
404         else
405         {
406                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
407                 this.frags = FRAGS_SPECTATOR;
408         }
409         if (CS(this).just_joined)
410                 CS(this).just_joined = false;
411 }
412
413 int player_getspecies(entity this)
414 {
415         get_model_parameters(this.model, this.skin);
416         int s = get_model_parameters_species;
417         get_model_parameters(string_null, 0);
418         if (s < 0) return SPECIES_HUMAN;
419         return s;
420 }
421
422 .float model_randomizer;
423 void FixPlayermodel(entity player)
424 {
425         string defaultmodel = "";
426         int defaultskin = 0;
427         if(autocvar_sv_defaultcharacter)
428         {
429                 if(teamplay)
430                 {
431                         switch(player.team)
432                         {
433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
437                         }
438                 }
439
440                 if(defaultmodel == "")
441                 {
442                         defaultmodel = autocvar_sv_defaultplayermodel;
443                         defaultskin = autocvar_sv_defaultplayerskin;
444                 }
445
446                 int n = tokenize_console(defaultmodel);
447                 if(n > 0)
448                 {
449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
450                         // However, do NOT randomize if the player-selected model is in the list.
451                         for (int i = 0; i < n; ++i)
452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
453                                         defaultmodel = argv(i);
454                 }
455
456                 int i = strstrofs(defaultmodel, ":", 0);
457                 if(i >= 0)
458                 {
459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
460                         defaultmodel = substring(defaultmodel, 0, i);
461                 }
462         }
463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
464         {
465                 if(teamplay)
466                 {
467                         switch(player.team)
468                         {
469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
473                         }
474                 }
475
476                 if(!defaultskin)
477                         defaultskin = autocvar_sv_defaultplayerskin;
478         }
479
480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
481         defaultmodel = M_ARGV(0, string);
482         defaultskin = M_ARGV(1, int);
483
484         bool chmdl = false;
485         int oldskin;
486         if(defaultmodel != "")
487         {
488                 if (defaultmodel != player.model)
489                 {
490                         vector m1 = player.mins;
491                         vector m2 = player.maxs;
492                         setplayermodel (player, defaultmodel);
493                         setsize (player, m1, m2);
494                         chmdl = true;
495                 }
496
497                 oldskin = player.skin;
498                 player.skin = defaultskin;
499         } else {
500                 if (player.playermodel != player.model || player.playermodel == "")
501                 {
502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
503                         vector m1 = player.mins;
504                         vector m2 = player.maxs;
505                         setplayermodel (player, player.playermodel);
506                         setsize (player, m1, m2);
507                         chmdl = true;
508                 }
509
510                 if(!autocvar_sv_defaultcharacterskin)
511                 {
512                         oldskin = player.skin;
513                         player.skin = stof(player.playerskin);
514                 }
515                 else
516                 {
517                         oldskin = player.skin;
518                         player.skin = defaultskin;
519                 }
520         }
521
522         if(chmdl || oldskin != player.skin) // model or skin has changed
523         {
524                 player.species = player_getspecies(player); // update species
525                 if(!autocvar_g_debug_globalsounds)
526                         UpdatePlayerSounds(player); // update skin sounds
527         }
528
529         if(!teamplay)
530                 if(strlen(autocvar_sv_defaultplayercolors))
531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
533 }
534
535 void PutPlayerInServer(entity this)
536 {
537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
538
539         PlayerState_attach(this);
540         accuracy_resend(this);
541
542         if (this.team < 0)
543                 TeamBalance_JoinBestTeam(this);
544
545         entity spot = SelectSpawnPoint(this, false);
546         if (!spot) {
547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
548                 return; // spawn failed
549         }
550
551         TRANSMUTE(Player, this);
552
553         CS(this).wasplayer = true;
554         this.iscreature = true;
555         this.teleportable = TELEPORT_NORMAL;
556         if(!this.damagedbycontents)
557                 IL_PUSH(g_damagedbycontents, this);
558         this.damagedbycontents = true;
559         set_movetype(this, MOVETYPE_WALK);
560         this.solid = SOLID_SLIDEBOX;
561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
562         if (autocvar_g_playerclip_collisions)
563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
566         this.frags = FRAGS_PLAYER;
567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
569         if (autocvar__notarget)
570                 this.flags |= FL_NOTARGET;
571         this.takedamage = DAMAGE_AIM;
572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
573
574         if (warmup_stage) {
575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
581                 SetResource(this, RES_HEALTH, warmup_start_health);
582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
584         } else {
585                 SetResource(this, RES_SHELLS, start_ammo_shells);
586                 SetResource(this, RES_BULLETS, start_ammo_nails);
587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
588                 SetResource(this, RES_CELLS, start_ammo_cells);
589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
590                 SetResource(this, RES_FUEL, start_ammo_fuel);
591                 SetResource(this, RES_HEALTH, start_health);
592                 SetResource(this, RES_ARMOR, start_armorvalue);
593                 STAT(WEAPONS, this) = start_weapons;
594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
595                 {
596                         GiveRandomWeapons(this, random_start_weapons_count,
597                                 autocvar_g_random_start_weapons, random_start_ammo);
598                 }
599         }
600         SetSpectatee_status(this, 0);
601
602         PS(this).dual_weapons = '0 0 0';
603
604         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
605
606         this.items = start_items;
607
608         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
609         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
610         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
611         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
612         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
613         if (!sv_ready_restart_after_countdown && time < game_starttime)
614         {
615                 float f = game_starttime - time;
616                 this.spawnshieldtime += f;
617                 this.pauserotarmor_finished += f;
618                 this.pauserothealth_finished += f;
619                 this.pauseregen_finished += f;
620         }
621
622         this.damageforcescale = autocvar_g_player_damageforcescale;
623         this.death_time = 0;
624         this.respawn_flags = 0;
625         this.respawn_time = 0;
626         STAT(RESPAWN_TIME, this) = 0;
627         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
628         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
629         this.fade_time = 0;
630         this.pain_finished = 0;
631         this.pushltime = 0;
632         setthink(this, func_null); // players have no think function
633         this.nextthink = 0;
634         this.dmg_team = 0;
635         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
636
637         this.deadflag = DEAD_NO;
638
639         this.angles = spot.angles;
640         this.angles_z = 0; // never spawn tilted even if the spot says to
641         if (IS_BOT_CLIENT(this))
642         {
643                 this.v_angle = this.angles;
644                 bot_aim_reset(this);
645         }
646         this.fixangle = true; // turn this way immediately
647         this.oldvelocity = this.velocity = '0 0 0';
648         this.avelocity = '0 0 0';
649         this.punchangle = '0 0 0';
650         this.punchvector = '0 0 0';
651
652         STAT(STRENGTH_FINISHED, this) = 0;
653         STAT(INVINCIBLE_FINISHED, this) = 0;
654         this.fire_endtime = -1;
655         STAT(REVIVE_PROGRESS, this) = 0;
656         this.revival_time = 0;
657
658         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
659         STAT(BUFFS, this) = 0;
660         STAT(BUFF_TIME, this) = 0;
661
662         STAT(AIR_FINISHED, this) = 0;
663         this.waterlevel = WATERLEVEL_NONE;
664         this.watertype = CONTENT_EMPTY;
665
666         entity spawnevent = new_pure(spawnevent);
667         spawnevent.owner = this;
668         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
669
670         // Cut off any still running player sounds.
671         stopsound(this, CH_PLAYER_SINGLE);
672
673         this.model = "";
674         FixPlayermodel(this);
675         this.drawonlytoclient = NULL;
676
677         this.viewloc = NULL;
678
679         for(int slot = 0; slot < MAX_AXH; ++slot)
680         {
681                 entity axh = this.(AuxiliaryXhair[slot]);
682                 this.(AuxiliaryXhair[slot]) = NULL;
683
684                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
685                         delete(axh);
686         }
687
688         this.spawnpoint_targ = NULL;
689
690         UNSET_DUCKED(this);
691         this.view_ofs = STAT(PL_VIEW_OFS, this);
692         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
693         this.spawnorigin = spot.origin;
694         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
695         // don't reset back to last position, even if new position is stuck in solid
696         this.oldorigin = this.origin;
697         if(this.conveyor)
698                 IL_REMOVE(g_conveyed, this);
699         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
700         if(this.swampslug)
701                 IL_REMOVE(g_swamped, this);
702         this.swampslug = NULL;
703         this.swamp_interval = 0;
704         if(this.ladder_entity)
705                 IL_REMOVE(g_ladderents, this);
706         this.ladder_entity = NULL;
707         IL_EACH(g_counters, it.realowner == this,
708         {
709                 delete(it);
710         });
711         STAT(HUD, this) = HUD_NORMAL;
712
713         this.event_damage = PlayerDamage;
714         this.event_heal = PlayerHeal;
715
716         this.draggable = func_null;
717
718         if(!this.bot_attack)
719                 IL_PUSH(g_bot_targets, this);
720         this.bot_attack = true;
721         if(!this.monster_attack)
722                 IL_PUSH(g_monster_targets, this);
723         this.monster_attack = true;
724         navigation_dynamicgoal_init(this, false);
725
726         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
727
728         // player was spectator
729         if (CS(this).killcount == FRAGS_SPECTATOR) {
730                 PlayerScore_Clear(this);
731                 CS(this).killcount = 0;
732                 CS(this).startplaytime = time;
733         }
734
735         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
736         {
737                 .entity weaponentity = weaponentities[slot];
738                 CL_SpawnWeaponentity(this, weaponentity);
739         }
740         this.alpha = default_player_alpha;
741         this.colormod = '1 1 1' * autocvar_g_player_brightness;
742         this.exteriorweaponentity.alpha = default_weapon_alpha;
743
744         this.speedrunning = false;
745
746         this.counter_cnt = 0;
747         this.fragsfilter_cnt = 0;
748
749         target_voicescript_clear(this);
750
751         // reset fields the weapons may use
752         FOREACH(Weapons, true, {
753                 it.wr_resetplayer(it, this);
754                         // reload all reloadable weapons
755                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
756                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
757                         {
758                                 .entity weaponentity = weaponentities[slot];
759                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
760                         }
761                 }
762         });
763
764         {
765                 string s = spot.target;
766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
767                         spot.target = string_null;
768                 SUB_UseTargets(spot, this, NULL);
769                 if(g_assault || g_race)
770                         spot.target = s;
771         }
772
773         Unfreeze(this, false);
774
775         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
776
777         if (autocvar_spawn_debug)
778         {
779                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
780                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
781         }
782
783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
784         {
785                 .entity weaponentity = weaponentities[slot];
786                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
787                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
788                 else
789                         this.(weaponentity).m_switchweapon = WEP_Null;
790                 this.(weaponentity).m_weapon = WEP_Null;
791                 this.(weaponentity).weaponname = "";
792                 this.(weaponentity).m_switchingweapon = WEP_Null;
793                 this.(weaponentity).cnt = -1;
794         }
795
796         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
797
798         if (CS(this).impulse) ImpulseCommands(this);
799
800         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
801         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
802         {
803                 .entity weaponentity = weaponentities[slot];
804                 W_WeaponFrame(this, weaponentity);
805         }
806
807         if (!warmup_stage && !this.alivetime)
808                 this.alivetime = time;
809
810         antilag_clear(this, CS(this));
811 }
812
813 /** Called when a client spawns in the server */
814 void PutClientInServer(entity this)
815 {
816         if (IS_BOT_CLIENT(this)) {
817                 TRANSMUTE(Player, this);
818         } else if (IS_REAL_CLIENT(this)) {
819                 msg_entity = this;
820                 WriteByte(MSG_ONE, SVC_SETVIEW);
821                 WriteEntity(MSG_ONE, this);
822         }
823         if (game_stopped)
824                 TRANSMUTE(Observer, this);
825
826         SetSpectatee(this, NULL);
827
828         // reset player keys
829         if(PS(this))
830                 PS(this).itemkeys = 0;
831
832         MUTATOR_CALLHOOK(PutClientInServer, this);
833
834         if (IS_OBSERVER(this)) {
835                 PutObserverInServer(this);
836         } else if (IS_PLAYER(this)) {
837                 PutPlayerInServer(this);
838         }
839 }
840
841 // TODO do we need all these fields, or should we stop autodetecting runtime
842 // changes and just have a console command to update this?
843 bool ClientInit_SendEntity(entity this, entity to, int sf)
844 {
845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
846         return = true;
847         msg_entity = to;
848         // MSG_INIT replacement
849         // TODO: make easier to use
850         Registry_send_all();
851         W_PROP_reload(MSG_ONE, to);
852         ClientInit_misc(this);
853         MUTATOR_CALLHOOK(Ent_Init);
854 }
855 void ClientInit_misc(entity this)
856 {
857         int channel = MSG_ONE;
858         WriteHeader(channel, ENT_CLIENT_INIT);
859         WriteByte(channel, g_nexball_meter_period * 32);
860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
868
869         if(sv_foginterval && world.fog != "")
870                 WriteString(channel, world.fog);
871         else
872                 WriteString(channel, "");
873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
875         WriteByte(channel, serverflags);
876         WriteCoord(channel, autocvar_g_trueaim_minrange);
877 }
878
879 void ClientInit_CheckUpdate(entity this)
880 {
881         this.nextthink = time;
882         if(this.count != autocvar_g_balance_armor_blockpercent)
883         {
884                 this.count = autocvar_g_balance_armor_blockpercent;
885                 this.SendFlags |= 1;
886         }
887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
888         {
889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
890                 this.SendFlags |= 1;
891         }
892 }
893
894 void ClientInit_Spawn()
895 {
896         entity e = new_pure(clientinit);
897         setthink(e, ClientInit_CheckUpdate);
898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
899
900         ClientInit_CheckUpdate(e);
901 }
902
903 /*
904 =============
905 SetNewParms
906 =============
907 */
908 void SetNewParms ()
909 {
910         // initialize parms for a new player
911         parm1 = -(86400 * 366);
912
913         MUTATOR_CALLHOOK(SetNewParms);
914 }
915
916 /*
917 =============
918 SetChangeParms
919 =============
920 */
921 void SetChangeParms (entity this)
922 {
923         // save parms for level change
924         parm1 = CS(this).parm_idlesince - time;
925
926         MUTATOR_CALLHOOK(SetChangeParms);
927 }
928
929 /*
930 =============
931 DecodeLevelParms
932 =============
933 */
934 void DecodeLevelParms(entity this)
935 {
936         // load parms
937         CS(this).parm_idlesince = parm1;
938         if (CS(this).parm_idlesince == -(86400 * 366))
939                 CS(this).parm_idlesince = time;
940
941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
943
944         MUTATOR_CALLHOOK(DecodeLevelParms);
945 }
946
947 void FixClientCvars(entity e)
948 {
949         // send prediction settings to the client
950         stuffcmd(e, "\nin_bindmap 0 0\n");
951         if(autocvar_g_antilag == 3) // client side hitscan
952                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
953         if(autocvar_sv_gentle)
954                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
955
956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
957         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
958
959         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
960
961         MUTATOR_CALLHOOK(FixClientCvars, e);
962 }
963
964 bool findinlist_abbrev(string tofind, string list)
965 {
966         if(list == "" || tofind == "")
967                 return false; // empty list or search, just return
968
969         // this function allows abbreviated strings!
970         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
971         {
972                 return true;
973         });
974
975         return false;
976 }
977
978 bool PlayerInIPList(entity p, string iplist)
979 {
980         // some safety checks (never allow local?)
981         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
982                 return false;
983
984         return findinlist_abbrev(p.netaddress, iplist);
985 }
986
987 bool PlayerInIDList(entity p, string idlist)
988 {
989         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
990         if(!p.crypto_idfp)
991                 return false;
992
993         return findinlist_abbrev(p.crypto_idfp, idlist);
994 }
995
996 bool PlayerInList(entity player, string list)
997 {
998         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
999 }
1000
1001 #ifdef DP_EXT_PRECONNECT
1002 /*
1003 =============
1004 ClientPreConnect
1005
1006 Called once (not at each match start) when a client begins a connection to the server
1007 =============
1008 */
1009 void ClientPreConnect(entity this)
1010 {
1011         if(autocvar_sv_eventlog)
1012         {
1013                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1014                         this.playerid,
1015                         etof(this),
1016                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1017                 ));
1018         }
1019 }
1020 #endif
1021
1022 string GetClientVersionMessage(entity this)
1023 {
1024         if (CS(this).version_mismatch) {
1025                 if(CS(this).version < autocvar_gameversion) {
1026                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1027                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1028                 } else {
1029                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1030                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1031                 }
1032         } else {
1033                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1034         }
1035 }
1036
1037 string getwelcomemessage(entity this)
1038 {
1039         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1040         string modifications = M_ARGV(0, string);
1041
1042         if(g_weaponarena)
1043         {
1044                 if(g_weaponarena_random)
1045                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1046                 else
1047                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1048         }
1049         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1050                 modifications = strcat(modifications, ", No start weapons");
1051         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1052                 modifications = strcat(modifications, ", Low gravity");
1053         if(g_weapon_stay && !g_cts)
1054                 modifications = strcat(modifications, ", Weapons stay");
1055         if(g_jetpack)
1056                 modifications = strcat(modifications, ", Jet pack");
1057         if(autocvar_g_powerups == 0)
1058                 modifications = strcat(modifications, ", No powerups");
1059         if(autocvar_g_powerups > 0)
1060                 modifications = strcat(modifications, ", Powerups");
1061         modifications = substring(modifications, 2, strlen(modifications) - 2);
1062
1063         string versionmessage = GetClientVersionMessage(this);
1064         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1065
1066         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1067
1068         if(modifications != "")
1069                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1070
1071         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1072         {
1073                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1074                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1075         }
1076
1077         if (cache_mutatormsg != "") {
1078                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1079         }
1080
1081         string mutator_msg = "";
1082         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1083         mutator_msg = M_ARGV(0, string);
1084
1085         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1086
1087         string motd = autocvar_sv_motd;
1088         if (motd != "") {
1089                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1090         }
1091         return s;
1092 }
1093
1094 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1095
1096 /**
1097 =============
1098 ClientConnect
1099
1100 Called when a client connects to the server
1101 =============
1102 */
1103 void ClientConnect(entity this)
1104 {
1105         if (Ban_MaybeEnforceBanOnce(this)) return;
1106         assert(!IS_CLIENT(this), return);
1107         this.flags |= FL_CLIENT;
1108         assert(player_count >= 0, player_count = 0);
1109
1110 #ifdef WATERMARK
1111         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1112 #endif
1113         TRANSMUTE(Client, this);
1114         CS(this).version_nagtime = time + 10 + random() * 10;
1115
1116         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1117
1118         bot_clientconnect(this);
1119
1120         Player_DetermineForcedTeam(this);
1121
1122         TRANSMUTE(Observer, this);
1123
1124         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1125
1126         // always track bots, don't ask for cl_allow_uidtracking
1127         if (IS_BOT_CLIENT(this))
1128                 PlayerStats_GameReport_AddPlayer(this);
1129         else
1130                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1131
1132         if (autocvar_sv_eventlog)
1133                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1134
1135         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1136
1137         stuffcmd(this, clientstuff, "\n");
1138         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1139
1140         FixClientCvars(this);
1141
1142         // get version info from player
1143         stuffcmd(this, "cmd clientversion $gameversion\n");
1144
1145         // notify about available teams
1146         if (teamplay)
1147         {
1148                 entity balance = TeamBalance_CheckAllowedTeams(this);
1149                 int t = TeamBalance_GetAllowedTeams(balance);
1150                 TeamBalance_Destroy(balance);
1151                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1152         }
1153         else
1154         {
1155                 stuffcmd(this, "set _teams_available 0\n");
1156         }
1157
1158         bot_relinkplayerlist();
1159
1160         CS(this).spectatortime = time;
1161         if (blockSpectators)
1162         {
1163                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1164         }
1165
1166         CS(this).jointime = time;
1167
1168         if (IS_REAL_CLIENT(this))
1169         {
1170                 if (g_weaponarena_weapons == WEPSET(TUBA))
1171                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1172         }
1173
1174         if (!sv_foginterval && world.fog != "")
1175                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1176
1177         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1178                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1179                         send_CSQC_teamnagger();
1180
1181         CSQCMODEL_AUTOINIT(this);
1182
1183         CS(this).model_randomizer = random();
1184
1185         if (IS_REAL_CLIENT(this))
1186                 sv_notice_join(this);
1187
1188         this.move_qcphysics = autocvar_sv_qcphysics;
1189
1190         // update physics stats (players can spawn before physics runs)
1191         Physics_UpdateStats(this);
1192
1193         IL_EACH(g_initforplayer, it.init_for_player, {
1194                 it.init_for_player(it, this);
1195         });
1196
1197         Handicap_Initialize(this);
1198
1199         MUTATOR_CALLHOOK(ClientConnect, this);
1200
1201         if (IS_REAL_CLIENT(this))
1202         {
1203                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1204                 {
1205                         CS(this).motd_actived_time = -1;
1206                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1207                 }
1208         }
1209 }
1210 /*
1211 =============
1212 ClientDisconnect
1213
1214 Called when a client disconnects from the server
1215 =============
1216 */
1217 .entity chatbubbleentity;
1218 void ClientDisconnect(entity this)
1219 {
1220         assert(IS_CLIENT(this), return);
1221
1222         PlayerStats_GameReport_FinalizePlayer(this);
1223         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1224         if (CS(this).active_minigame) part_minigame(this);
1225         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1226
1227         if (autocvar_sv_eventlog)
1228                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1229
1230         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1231
1232         if(IS_SPEC(this))
1233                 SetSpectatee(this, NULL);
1234
1235     MUTATOR_CALLHOOK(ClientDisconnect, this);
1236
1237         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1238         strfree(CS(this).weaponorder_byimpulse);
1239         ClientState_detach(this);
1240
1241         Portal_ClearAll(this);
1242
1243         Unfreeze(this, false);
1244
1245         RemoveGrapplingHooks(this);
1246
1247         // Here, everything has been done that requires this player to be a client.
1248
1249         this.flags &= ~FL_CLIENT;
1250
1251         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1252         if (this.killindicator) delete(this.killindicator);
1253
1254         IL_EACH(g_counters, it.realowner == this,
1255         {
1256                 delete(it);
1257         });
1258
1259         WaypointSprite_PlayerGone(this);
1260
1261         bot_relinkplayerlist();
1262
1263         strfree(this.clientstatus);
1264         if (this.personal) delete(this.personal);
1265
1266         this.playerid = 0;
1267         ReadyCount();
1268         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1269
1270         ONREMOVE(this);
1271 }
1272
1273 void ChatBubbleThink(entity this)
1274 {
1275         this.nextthink = time;
1276         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1277         {
1278                 if(this.owner) // but why can that ever be NULL?
1279                         this.owner.chatbubbleentity = NULL;
1280                 delete(this);
1281                 return;
1282         }
1283
1284         this.mdl = "";
1285
1286         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1287         {
1288                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1289                         this.mdl = "models/sprites/minigame_busy.iqm";
1290                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1291                         this.mdl = "models/misc/chatbubble.spr";
1292         }
1293
1294         if ( this.model != this.mdl )
1295                 _setmodel(this, this.mdl);
1296
1297 }
1298
1299 void UpdateChatBubble(entity this)
1300 {
1301         if (this.alpha < 0)
1302                 return;
1303         // spawn a chatbubble entity if needed
1304         if (!this.chatbubbleentity)
1305         {
1306                 this.chatbubbleentity = new(chatbubbleentity);
1307                 this.chatbubbleentity.owner = this;
1308                 this.chatbubbleentity.exteriormodeltoclient = this;
1309                 setthink(this.chatbubbleentity, ChatBubbleThink);
1310                 this.chatbubbleentity.nextthink = time;
1311                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1312                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1313                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1314                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1315                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1316                 //this.chatbubbleentity.model = "";
1317                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1318         }
1319 }
1320
1321 void calculate_player_respawn_time(entity this)
1322 {
1323         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1324                 return;
1325
1326         float gametype_setting_tmp;
1327         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1328         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1329         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1330         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1331         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1332         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1333
1334         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1335         if (teamplay)
1336         {
1337                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1338                         if(it.team == this.team)
1339                                 ++pcount;
1340                 });
1341                 if (sdelay_small_count == 0)
1342                         sdelay_small_count = 1;
1343                 if (sdelay_large_count == 0)
1344                         sdelay_large_count = 1;
1345         }
1346         else
1347         {
1348                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1349                         ++pcount;
1350                 });
1351                 if (sdelay_small_count == 0)
1352                 {
1353                         if (IS_INDEPENDENT_PLAYER(this))
1354                         {
1355                                 // Players play independently. No point in requiring enemies.
1356                                 sdelay_small_count = 1;
1357                         }
1358                         else
1359                         {
1360                                 // Players play AGAINST each other. Enemies required.
1361                                 sdelay_small_count = 2;
1362                         }
1363                 }
1364                 if (sdelay_large_count == 0)
1365                 {
1366                         if (IS_INDEPENDENT_PLAYER(this))
1367                         {
1368                                 // Players play independently. No point in requiring enemies.
1369                                 sdelay_large_count = 1;
1370                         }
1371                         else
1372                         {
1373                                 // Players play AGAINST each other. Enemies required.
1374                                 sdelay_large_count = 2;
1375                         }
1376                 }
1377         }
1378
1379         float sdelay;
1380
1381         if (pcount <= sdelay_small_count)
1382                 sdelay = sdelay_small;
1383         else if (pcount >= sdelay_large_count)
1384                 sdelay = sdelay_large;
1385         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1386                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1387
1388         if(waves)
1389                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1390         else
1391                 this.respawn_time = time + sdelay;
1392
1393         if(sdelay < sdelay_max)
1394                 this.respawn_time_max = time + sdelay_max;
1395         else
1396                 this.respawn_time_max = this.respawn_time;
1397
1398         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1399                 this.respawn_countdown = 10; // first number to count down from is 10
1400         else
1401                 this.respawn_countdown = -1; // do not count down
1402
1403         if(autocvar_g_forced_respawn)
1404                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1405 }
1406
1407 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1408 // added to the model skins
1409 /*void UpdateColorModHack()
1410 {
1411         float c;
1412         c = this.clientcolors & 15;
1413         // LordHavoc: only bothering to support white, green, red, yellow, blue
1414              if (!teamplay) this.colormod = '0 0 0';
1415         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1416         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1417         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1418         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1419         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1420         else this.colormod = '1 1 1';
1421 }*/
1422
1423 void respawn(entity this)
1424 {
1425         bool damagedbycontents_prev = this.damagedbycontents;
1426         if(this.alpha >= 0)
1427         {
1428                 if(autocvar_g_respawn_ghosts)
1429                 {
1430                         this.solid = SOLID_NOT;
1431                         this.takedamage = DAMAGE_NO;
1432                         this.damagedbycontents = false;
1433                         set_movetype(this, MOVETYPE_FLY);
1434                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1435                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1436                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1437                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1438                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1439                         if(autocvar_g_respawn_ghosts_time > 0)
1440                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1441                 }
1442                 else
1443                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1444         }
1445
1446         CopyBody(this, 1);
1447         this.damagedbycontents = damagedbycontents_prev;
1448
1449         this.effects |= EF_NODRAW; // prevent another CopyBody
1450         PutClientInServer(this);
1451 }
1452
1453 ERASEABLE
1454 void PrintToChat(entity client, string text)
1455 {
1456         text = strcat("\{1}^7", text, "\n");
1457         sprint(client, text);
1458 }
1459
1460 ERASEABLE
1461 void DebugPrintToChat(entity client, string text)
1462 {
1463         if (autocvar_developer > 0)
1464         {
1465                 PrintToChat(client, text);
1466         }
1467 }
1468
1469 ERASEABLE
1470 void PrintToChatAll(string text)
1471 {
1472         text = strcat("\{1}^7", text, "\n");
1473         bprint(text);
1474 }
1475
1476 ERASEABLE
1477 void DebugPrintToChatAll(string text)
1478 {
1479         if (autocvar_developer > 0)
1480         {
1481                 PrintToChatAll(text);
1482         }
1483 }
1484
1485 ERASEABLE
1486 void PrintToChatTeam(int team_num, string text)
1487 {
1488         text = strcat("\{1}^7", text, "\n");
1489         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1490         {
1491                 if (it.team == team_num)
1492                 {
1493                         sprint(it, text);
1494                 }
1495         });
1496 }
1497
1498 ERASEABLE
1499 void DebugPrintToChatTeam(int team_num, string text)
1500 {
1501         if (autocvar_developer > 0)
1502         {
1503                 PrintToChatTeam(team_num, text);
1504         }
1505 }
1506
1507 void play_countdown(entity this, float finished, Sound samp)
1508 {
1509         TC(Sound, samp);
1510         if(IS_REAL_CLIENT(this))
1511                 if(floor(finished - time - frametime) != floor(finished - time))
1512                         if(finished - time < 6)
1513                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1514 }
1515
1516 void player_powerups(entity this)
1517 {
1518         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1519                 this.modelflags |= MF_ROCKET;
1520         else
1521                 this.modelflags &= ~MF_ROCKET;
1522
1523         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1524
1525         if (IS_DEAD(this))
1526         {
1527                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1528                 {
1529                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1530                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1531                         this.items &= ~ITEM_Strength.m_itemid;
1532                         this.items &= ~ITEM_Shield.m_itemid;
1533                         this.items -= (this.items & IT_SUPERWEAPON);
1534                 }
1535         }
1536
1537         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1538                 return;
1539
1540         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1541         int items_prev = this.items;
1542
1543         Fire_ApplyDamage(this);
1544         Fire_ApplyEffect(this);
1545
1546         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1547         {
1548                 if (this.items & ITEM_Strength.m_itemid)
1549                 {
1550                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1551                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1552                         if (time > STAT(STRENGTH_FINISHED, this))
1553                         {
1554                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1555                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1556                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1557                         }
1558                 }
1559                 else
1560                 {
1561                         if (time < STAT(STRENGTH_FINISHED, this))
1562                         {
1563                                 this.items = this.items | ITEM_Strength.m_itemid;
1564                                 if(!g_cts)
1565                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1566                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1567                         }
1568                 }
1569                 if (this.items & ITEM_Shield.m_itemid)
1570                 {
1571                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1572                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1573                         if (time > STAT(INVINCIBLE_FINISHED, this))
1574                         {
1575                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1576                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1577                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1578                         }
1579                 }
1580                 else
1581                 {
1582                         if (time < STAT(INVINCIBLE_FINISHED, this))
1583                         {
1584                                 this.items = this.items | ITEM_Shield.m_itemid;
1585                                 if(!g_cts)
1586                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1587                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1588                         }
1589                 }
1590                 if (this.items & IT_SUPERWEAPON)
1591                 {
1592                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1593                         {
1594                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1595                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1596                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1597                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1598                         }
1599                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1600                         {
1601                                 // don't let them run out
1602                         }
1603                         else
1604                         {
1605                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1606                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1607                                 {
1608                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1609                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1610                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1611                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1612                                 }
1613                         }
1614                 }
1615                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1616                 {
1617                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1618                         {
1619                                 this.items = this.items | IT_SUPERWEAPON;
1620                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1621                                 {
1622                                         if(!g_cts)
1623                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1624                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1625                                 }
1626                         }
1627                         else
1628                         {
1629                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1630                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1631                         }
1632                 }
1633                 else
1634                 {
1635                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1636                 }
1637         }
1638
1639         if(autocvar_g_nodepthtestplayers)
1640                 this.effects = this.effects | EF_NODEPTHTEST;
1641
1642         if(autocvar_g_fullbrightplayers)
1643                 this.effects = this.effects | EF_FULLBRIGHT;
1644
1645         if (time >= game_starttime)
1646         if (time < this.spawnshieldtime)
1647                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1648
1649         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1650 }
1651
1652 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1653 {
1654         if(current > stable)
1655                 return current;
1656         else if(current > stable - 0.25) // when close enough, "snap"
1657                 return stable;
1658         else
1659                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1660 }
1661
1662 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1663 {
1664         if(current < stable)
1665                 return current;
1666         else if(current < stable + 0.25) // when close enough, "snap"
1667                 return stable;
1668         else
1669                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1670 }
1671
1672 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1673 {
1674         float old = GetResource(this, res);
1675         float current = old;
1676         if(current > rotstable)
1677         {
1678                 if(rotframetime > 0)
1679                 {
1680                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1681                         current = max(rotstable, current - rotlinear * rotframetime);
1682                 }
1683         }
1684         else if(current < regenstable)
1685         {
1686                 if(regenframetime > 0)
1687                 {
1688                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1689                         current = min(regenstable, current + regenlinear * regenframetime);
1690                 }
1691         }
1692
1693         float limit = GetResourceLimit(this, res) * limit_mod;
1694         if(current > limit)
1695                 current = limit;
1696
1697         if (current != old)
1698                 SetResource(this, res, current);
1699 }
1700
1701 void player_regen(entity this)
1702 {
1703         float max_mod, regen_mod, rot_mod, limit_mod;
1704         max_mod = regen_mod = rot_mod = limit_mod = 1;
1705
1706         float regen_health = autocvar_g_balance_health_regen;
1707         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1708         float regen_health_rot = autocvar_g_balance_health_rot;
1709         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1710         float regen_health_stable = autocvar_g_balance_health_regenstable;
1711         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1712         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1713                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1714         max_mod = M_ARGV(1, float);
1715         regen_mod = M_ARGV(2, float);
1716         rot_mod = M_ARGV(3, float);
1717         limit_mod = M_ARGV(4, float);
1718         regen_health = M_ARGV(5, float);
1719         regen_health_linear = M_ARGV(6, float);
1720         regen_health_rot = M_ARGV(7, float);
1721         regen_health_rotlinear = M_ARGV(8, float);
1722         regen_health_stable = M_ARGV(9, float);
1723         regen_health_rotstable = M_ARGV(10, float);
1724
1725         if(!mutator_returnvalue)
1726         if(!STAT(FROZEN, this))
1727         {
1728                 float maxa = autocvar_g_balance_armor_rotstable;
1729                 float mina = autocvar_g_balance_armor_regenstable;
1730
1731                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1732                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1733                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1734
1735                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1736                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1737                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1738         }
1739
1740         // if player rotted to death...  die!
1741         // check this outside above checks, as player may still be able to rot to death
1742         if(GetResource(this, RES_HEALTH) < 1)
1743         {
1744                 if(this.vehicle)
1745                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1746                 if(this.event_damage)
1747                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1748         }
1749
1750         if (!(this.items & IT_UNLIMITED_AMMO))
1751         {
1752                 float maxf = autocvar_g_balance_fuel_rotstable;
1753                 float minf = autocvar_g_balance_fuel_regenstable;
1754
1755                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1756                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1757                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1758         }
1759 }
1760
1761 bool zoomstate_set;
1762 void SetZoomState(entity this, float newzoom)
1763 {
1764         if(newzoom != CS(this).zoomstate)
1765         {
1766                 CS(this).zoomstate = newzoom;
1767                 ClientData_Touch(this);
1768         }
1769         zoomstate_set = true;
1770 }
1771
1772 void GetPressedKeys(entity this)
1773 {
1774         MUTATOR_CALLHOOK(GetPressedKeys, this);
1775         int keys = STAT(PRESSED_KEYS, this);
1776         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1777         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1778         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1779         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1780
1781         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1782         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1783         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1784         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1785         CS(this).pressedkeys = keys; // store for other users
1786
1787         STAT(PRESSED_KEYS, this) = keys;
1788 }
1789
1790 /*
1791 ======================
1792 spectate mode routines
1793 ======================
1794 */
1795
1796 void SpectateCopy(entity this, entity spectatee)
1797 {
1798         TC(Client, this); TC(Client, spectatee);
1799
1800         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1801         PS(this) = PS(spectatee);
1802         this.armortype = spectatee.armortype;
1803         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1804         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1805         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1806         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1807         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1808         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1809         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1810         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1811         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1812         CS(this).impulse = 0;
1813         this.disableclientprediction = 1; // no need to run prediction on a spectator
1814         this.items = spectatee.items;
1815         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1816         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1817         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1818         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1819         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1820         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1821         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1822         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1823         this.punchangle = spectatee.punchangle;
1824         this.view_ofs = spectatee.view_ofs;
1825         this.velocity = spectatee.velocity;
1826         this.dmg_take = spectatee.dmg_take;
1827         this.dmg_save = spectatee.dmg_save;
1828         this.dmg_inflictor = spectatee.dmg_inflictor;
1829         this.v_angle = spectatee.v_angle;
1830         this.angles = spectatee.v_angle;
1831         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1832         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1833         this.viewloc = spectatee.viewloc;
1834         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1835                 this.fixangle = true;
1836         setorigin(this, spectatee.origin);
1837         setsize(this, spectatee.mins, spectatee.maxs);
1838         SetZoomState(this, CS(spectatee).zoomstate);
1839
1840     anticheat_spectatecopy(this, spectatee);
1841         STAT(HUD, this) = STAT(HUD, spectatee);
1842         if(spectatee.vehicle)
1843     {
1844         this.angles = spectatee.v_angle;
1845
1846         //this.fixangle = false;
1847         //this.velocity = spectatee.vehicle.velocity;
1848         this.vehicle_health = spectatee.vehicle_health;
1849         this.vehicle_shield = spectatee.vehicle_shield;
1850         this.vehicle_energy = spectatee.vehicle_energy;
1851         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1852         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1853         this.vehicle_reload1 = spectatee.vehicle_reload1;
1854         this.vehicle_reload2 = spectatee.vehicle_reload2;
1855
1856         //msg_entity = this;
1857
1858        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1859             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1860            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1861            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1862
1863         //WriteByte (MSG_ONE, SVC_SETVIEW);
1864         //    WriteEntity(MSG_ONE, this);
1865         //makevectors(spectatee.v_angle);
1866         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1867     }
1868 }
1869
1870 bool SpectateUpdate(entity this)
1871 {
1872         if(!this.enemy)
1873                 return false;
1874
1875         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1876         {
1877                 SetSpectatee(this, NULL);
1878                 return false;
1879         }
1880
1881         SpectateCopy(this, this.enemy);
1882
1883         return true;
1884 }
1885
1886 bool SpectateSet(entity this)
1887 {
1888         if(!IS_PLAYER(this.enemy))
1889                 return false;
1890
1891         ClientData_Touch(this.enemy);
1892
1893         msg_entity = this;
1894         WriteByte(MSG_ONE, SVC_SETVIEW);
1895         WriteEntity(MSG_ONE, this.enemy);
1896         set_movetype(this, MOVETYPE_NONE);
1897         accuracy_resend(this);
1898
1899         if(!SpectateUpdate(this))
1900                 PutObserverInServer(this);
1901
1902         return true;
1903 }
1904
1905 void SetSpectatee_status(entity this, int spectatee_num)
1906 {
1907         int oldspectatee_status = CS(this).spectatee_status;
1908         CS(this).spectatee_status = spectatee_num;
1909
1910         if (CS(this).spectatee_status != oldspectatee_status)
1911         {
1912                 if (STAT(PRESSED_KEYS, this))
1913                 {
1914                         CS(this).pressedkeys = 0;
1915                         STAT(PRESSED_KEYS, this) = 0;
1916                 }
1917                 ClientData_Touch(this);
1918                 if (g_race || g_cts) race_InitSpectator();
1919         }
1920 }
1921
1922 void SetSpectatee(entity this, entity spectatee)
1923 {
1924         if(IS_BOT_CLIENT(this))
1925                 return; // bots abuse .enemy, this code is useless to them
1926
1927         entity old_spectatee = this.enemy;
1928
1929         this.enemy = spectatee;
1930
1931         // WEAPONTODO
1932         // these are required to fix the spectator bug with arc
1933         if(old_spectatee)
1934         {
1935                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1936                 {
1937                         .entity weaponentity = weaponentities[slot];
1938                         if(old_spectatee.(weaponentity).arc_beam)
1939                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1940                 }
1941         }
1942         if(this.enemy)
1943         {
1944                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1945                 {
1946                         .entity weaponentity = weaponentities[slot];
1947                         if(this.enemy.(weaponentity).arc_beam)
1948                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1949                 }
1950         }
1951
1952         if (this.enemy)
1953                 SetSpectatee_status(this, etof(this.enemy));
1954
1955         // needed to update spectator list
1956         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1957 }
1958
1959 bool Spectate(entity this, entity pl)
1960 {
1961         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1962                 return false;
1963         pl = M_ARGV(1, entity);
1964
1965         SetSpectatee(this, pl);
1966         return SpectateSet(this);
1967 }
1968
1969 bool SpectateNext(entity this)
1970 {
1971         entity ent = find(this.enemy, classname, STR_PLAYER);
1972
1973         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1974                 ent = M_ARGV(1, entity);
1975         else if (!ent)
1976                 ent = find(ent, classname, STR_PLAYER);
1977
1978         if(ent) { SetSpectatee(this, ent); }
1979
1980         return SpectateSet(this);
1981 }
1982
1983 bool SpectatePrev(entity this)
1984 {
1985         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1986         entity ent = findchain(classname, STR_PLAYER);
1987         if (!ent) // no player
1988                 return false;
1989
1990         entity first = ent;
1991         // skip players until current spectated player
1992         if(this.enemy)
1993         while(ent && ent != this.enemy)
1994                 ent = ent.chain;
1995
1996         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1997         {
1998                 case MUT_SPECPREV_FOUND:
1999                     ent = M_ARGV(1, entity);
2000                     break;
2001                 case MUT_SPECPREV_RETURN:
2002                     return true;
2003                 case MUT_SPECPREV_CONTINUE:
2004                 default:
2005                 {
2006                         if(ent.chain)
2007                                 ent = ent.chain;
2008                         else
2009                                 ent = first;
2010                         break;
2011                 }
2012         }
2013
2014         SetSpectatee(this, ent);
2015         return SpectateSet(this);
2016 }
2017
2018 /*
2019 =============
2020 ShowRespawnCountdown()
2021
2022 Update a respawn countdown display.
2023 =============
2024 */
2025 void ShowRespawnCountdown(entity this)
2026 {
2027         float number;
2028         if(!IS_DEAD(this)) // just respawned?
2029                 return;
2030         else
2031         {
2032                 number = ceil(this.respawn_time - time);
2033                 if(number <= 0)
2034                         return;
2035                 if(number <= this.respawn_countdown)
2036                 {
2037                         this.respawn_countdown = number - 1;
2038                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2039                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2040                 }
2041         }
2042 }
2043
2044 .bool team_selected;
2045 bool ShowTeamSelection(entity this)
2046 {
2047         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2048                 return false;
2049         stuffcmd(this, "menu_showteamselect\n");
2050         return true;
2051 }
2052 void Join(entity this)
2053 {
2054         TRANSMUTE(Player, this);
2055
2056         if(!this.team_selected)
2057         if(autocvar_g_campaign || autocvar_g_balance_teams)
2058                 TeamBalance_JoinBestTeam(this);
2059
2060         if(autocvar_g_campaign)
2061                 campaign_bots_may_start = true;
2062
2063         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2064
2065         PutClientInServer(this);
2066
2067         if(IS_PLAYER(this))
2068         if(teamplay && this.team != -1)
2069         {
2070         }
2071         else
2072                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2073         this.team_selected = false;
2074 }
2075
2076 int GetPlayerLimit()
2077 {
2078         if(g_duel)
2079                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2080         int player_limit = autocvar_g_maxplayers;
2081         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2082         player_limit = M_ARGV(0, int);
2083         return player_limit;
2084 }
2085
2086 /**
2087  * Determines whether the player is allowed to join. This depends on cvar
2088  * g_maxplayers, if it isn't used this function always return true, otherwise
2089  * it checks whether the number of currently playing players exceeds g_maxplayers.
2090  * @return int number of free slots for players, 0 if none
2091  */
2092 int nJoinAllowed(entity this, entity ignore)
2093 {
2094         if(!ignore)
2095         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2096         // so report 0 free slots if restricted
2097         {
2098                 if(autocvar_g_forced_team_otherwise == "spectate")
2099                         return 0;
2100                 if(autocvar_g_forced_team_otherwise == "spectator")
2101                         return 0;
2102         }
2103
2104         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2105                 return 0; // forced spectators can never join
2106
2107         // TODO simplify this
2108         int totalClients = 0;
2109         int currentlyPlaying = 0;
2110         FOREACH_CLIENT(true, {
2111                 if(it != ignore)
2112                         ++totalClients;
2113                 if(IS_REAL_CLIENT(it))
2114                 if(IS_PLAYER(it) || it.caplayer)
2115                         ++currentlyPlaying;
2116         });
2117
2118         int player_limit = GetPlayerLimit();
2119
2120         int free_slots = 0;
2121         if (!player_limit)
2122                 free_slots = maxclients - totalClients;
2123         else if(player_limit > 0 && currentlyPlaying < player_limit)
2124                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2125
2126         static float msg_time = 0;
2127         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2128         {
2129                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2130                 msg_time = time + 0.5;
2131         }
2132
2133         return free_slots;
2134 }
2135
2136 /**
2137  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2138  * g_maxplayers_spectator_blocktime seconds
2139  */
2140 void checkSpectatorBlock(entity this)
2141 {
2142         if(IS_SPEC(this) || IS_OBSERVER(this))
2143         if(!this.caplayer)
2144         if(IS_REAL_CLIENT(this))
2145         {
2146                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2147                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2148                         dropclient(this);
2149                 }
2150         }
2151 }
2152
2153 void PrintWelcomeMessage(entity this)
2154 {
2155         if(CS(this).motd_actived_time == 0)
2156         {
2157                 if (autocvar_g_campaign) {
2158                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2159                                 CS(this).motd_actived_time = time;
2160                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2161                         }
2162                 } else {
2163                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2164                                 CS(this).motd_actived_time = time;
2165                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2166                         }
2167                 }
2168         }
2169         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2170         {
2171                 if (autocvar_g_campaign) {
2172                         if (PHYS_INPUT_BUTTON_INFO(this))
2173                                 CS(this).motd_actived_time = time;
2174                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2175                                 CS(this).motd_actived_time = 0;
2176                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2177                         }
2178                 } else {
2179                         if (PHYS_INPUT_BUTTON_INFO(this))
2180                                 CS(this).motd_actived_time = time;
2181                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2182                                 CS(this).motd_actived_time = 0;
2183                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2184                         }
2185                 }
2186         }
2187         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2188         {
2189                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2190                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2191                 else if (CS(this).motd_actived_time == -2)
2192                 {
2193                         // instantly hide MOTD
2194                         CS(this).motd_actived_time = 0;
2195                         if (autocvar_g_campaign)
2196                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2197                         else
2198                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2199                 }
2200                 else if (IS_PLAYER(this) || IS_SPEC(this))
2201                 {
2202                         // FIXME occasionally for some reason MOTD never goes away
2203                         // delay MOTD removal a little bit in the hope it fixes this bug
2204                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2205                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2206                         else //if (CS(this).motd_actived_time < -2)
2207                                 CS(this).motd_actived_time++;
2208                 }
2209         }
2210 }
2211
2212 bool joinAllowed(entity this)
2213 {
2214         if (CS(this).version_mismatch) return false;
2215         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2216         if (!nJoinAllowed(this, this)) return false;
2217         if (teamplay && lockteams) return false;
2218         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2219         if (ShowTeamSelection(this)) return false;
2220         return true;
2221 }
2222
2223 .string shootfromfixedorigin;
2224 .bool dualwielding_prev;
2225 bool PlayerThink(entity this)
2226 {
2227         if (game_stopped || intermission_running) {
2228                 this.modelflags &= ~MF_ROCKET;
2229                 if(intermission_running)
2230                         IntermissionThink(this);
2231                 return false;
2232         }
2233
2234         if (timeout_status == TIMEOUT_ACTIVE) {
2235         // don't allow the player to turn around while game is paused
2236                 // FIXME turn this into CSQC stuff
2237                 this.v_angle = this.lastV_angle;
2238                 this.angles = this.lastV_angle;
2239                 this.fixangle = true;
2240         }
2241
2242         if (frametime) player_powerups(this);
2243
2244         if (IS_DEAD(this)) {
2245                 if (this.personal && g_race_qualifying) {
2246                         if (time > this.respawn_time) {
2247                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2248                                 respawn(this);
2249                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2250                         }
2251                 } else {
2252                         if (frametime) player_anim(this);
2253
2254                         if (this.respawn_flags & RESPAWN_DENY)
2255                         {
2256                                 STAT(RESPAWN_TIME, this) = 0;
2257                                 return false;
2258                         }
2259
2260                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2261
2262                         switch(this.deadflag)
2263                         {
2264                                 case DEAD_DYING:
2265                                 {
2266                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2267                                                 this.deadflag = DEAD_RESPAWNING;
2268                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2269                                                 this.deadflag = DEAD_DEAD;
2270                                         break;
2271                                 }
2272                                 case DEAD_DEAD:
2273                                 {
2274                                         if (button_pressed)
2275                                                 this.deadflag = DEAD_RESPAWNABLE;
2276                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2277                                                 this.deadflag = DEAD_RESPAWNING;
2278                                         break;
2279                                 }
2280                                 case DEAD_RESPAWNABLE:
2281                                 {
2282                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2283                                                 this.deadflag = DEAD_RESPAWNING;
2284                                         break;
2285                                 }
2286                                 case DEAD_RESPAWNING:
2287                                 {
2288                                         if (time > this.respawn_time)
2289                                         {
2290                                                 this.respawn_time = time + 1; // only retry once a second
2291                                                 this.respawn_time_max = this.respawn_time;
2292                                                 respawn(this);
2293                                         }
2294                                         break;
2295                                 }
2296                         }
2297
2298                         ShowRespawnCountdown(this);
2299
2300                         if (this.respawn_flags & RESPAWN_SILENT)
2301                                 STAT(RESPAWN_TIME, this) = 0;
2302                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2303                         {
2304                                 if (time < this.respawn_time)
2305                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2306                                 else if (this.deadflag != DEAD_RESPAWNING)
2307                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2308                         }
2309                         else
2310                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2311                 }
2312
2313                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2314                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2315                         STAT(RESPAWN_TIME, this) *= -1;
2316
2317                 return false;
2318         }
2319
2320         FixPlayermodel(this);
2321
2322         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2323                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2324                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2325         }
2326
2327         // reset gun alignment when dual wielding status changes
2328         // to ensure guns are always aligned right and left
2329         bool dualwielding = W_DualWielding(this);
2330         if(this.dualwielding_prev != dualwielding)
2331         {
2332                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2333                 this.dualwielding_prev = dualwielding;
2334         }
2335
2336         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2337         //if(frametime)
2338         {
2339                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2340                 {
2341                         .entity weaponentity = weaponentities[slot];
2342                         if(WEP_CVAR(vortex, charge_always))
2343                                 W_Vortex_Charge(this, weaponentity, frametime);
2344                         W_WeaponFrame(this, weaponentity);
2345                 }
2346         }
2347
2348         if (frametime)
2349         {
2350                 // WEAPONTODO: Add a weapon request for this
2351                 // rot vortex charge to the charge limit
2352                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2353                 {
2354                         .entity weaponentity = weaponentities[slot];
2355                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2356                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2357                 }
2358
2359                 player_regen(this);
2360                 player_anim(this);
2361                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2362         }
2363
2364         monsters_setstatus(this);
2365
2366         return true;
2367 }
2368
2369 .bool would_spectate;
2370 void ObserverOrSpectatorThink(entity this)
2371 {
2372         bool is_spec = IS_SPEC(this);
2373         if ( CS(this).impulse )
2374         {
2375                 int r = MinigameImpulse(this, CS(this).impulse);
2376                 if (!is_spec || r)
2377                         CS(this).impulse = 0;
2378
2379                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2380                 {
2381                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2382                         CS(this).impulse = 0;
2383                         return;
2384                 }
2385         }
2386
2387         if (this.flags & FL_JUMPRELEASED) {
2388                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2389                         this.flags &= ~FL_JUMPRELEASED;
2390                         this.flags |= FL_SPAWNING;
2391                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2392                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2393                         this.flags &= ~FL_JUMPRELEASED;
2394                         if(SpectateNext(this)) {
2395                                 TRANSMUTE(Spectator, this);
2396                         } else if (is_spec) {
2397                                 TRANSMUTE(Observer, this);
2398                                 PutClientInServer(this);
2399                         }
2400                         if (is_spec)
2401                                 CS(this).impulse = 0;
2402                 } else if (is_spec) {
2403                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2404                                 this.flags &= ~FL_JUMPRELEASED;
2405                                 if(SpectatePrev(this)) {
2406                                         TRANSMUTE(Spectator, this);
2407                                 } else {
2408                                         TRANSMUTE(Observer, this);
2409                                         PutClientInServer(this);
2410                                 }
2411                                 CS(this).impulse = 0;
2412                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2413                                 this.would_spectate = false;
2414                                 this.flags &= ~FL_JUMPRELEASED;
2415                                 TRANSMUTE(Observer, this);
2416                                 PutClientInServer(this);
2417                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2418                                 PutObserverInServer(this);
2419                                 this.would_spectate = true;
2420                         }
2421                 }
2422                 else {
2423                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2424                         set_movetype(this, preferred_movetype);
2425                 }
2426         } else {
2427                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2428                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2429                         this.flags |= FL_JUMPRELEASED;
2430                         if(this.flags & FL_SPAWNING)
2431                         {
2432                                 this.flags &= ~FL_SPAWNING;
2433                                 if(joinAllowed(this))
2434                                         Join(this);
2435                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2436                                         CS(this).autojoin_checked = -1;
2437                                 return;
2438                         }
2439                 }
2440                 if(is_spec && !SpectateUpdate(this))
2441                         PutObserverInServer(this);
2442         }
2443         if (is_spec)
2444                 this.flags |= FL_CLIENT | FL_NOTARGET;
2445 }
2446
2447 void PlayerUseKey(entity this)
2448 {
2449         if (!IS_PLAYER(this))
2450                 return;
2451
2452         if(this.vehicle)
2453         {
2454                 if(!game_stopped)
2455                 {
2456                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2457                         return;
2458                 }
2459         }
2460         else if(autocvar_g_vehicles_enter)
2461         {
2462                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2463                 {
2464                         entity head, closest_target = NULL;
2465                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2466
2467                         while(head) // find the closest acceptable target to enter
2468                         {
2469                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2470                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2471                                 {
2472                                         if(closest_target)
2473                                         {
2474                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2475                                                 { closest_target = head; }
2476                                         }
2477                                         else { closest_target = head; }
2478                                 }
2479
2480                                 head = head.chain;
2481                         }
2482
2483                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2484                 }
2485         }
2486
2487         // a use key was pressed; call handlers
2488         MUTATOR_CALLHOOK(PlayerUseKey, this);
2489 }
2490
2491
2492 /*
2493 =============
2494 PlayerPreThink
2495
2496 Called every frame for each client before the physics are run
2497 =============
2498 */
2499 .float last_vehiclecheck;
2500 void PlayerPreThink (entity this)
2501 {
2502         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2503         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2504
2505         WarpZone_PlayerPhysics_FixVAngle(this);
2506
2507         if (frametime) {
2508                 // physics frames: update anticheat stuff
2509                 anticheat_prethink(this);
2510         }
2511
2512         if (blockSpectators && frametime) {
2513                 // WORKAROUND: only use dropclient in server frames (frametime set).
2514                 // Never use it in cl_movement frames (frametime zero).
2515                 checkSpectatorBlock(this);
2516         }
2517
2518         zoomstate_set = false;
2519
2520         // Check for nameless players
2521         if (this.netname == "" || this.netname != CS(this).netname_previous)
2522         {
2523                 bool assume_unchanged = (CS(this).netname_previous == "");
2524                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2525                 {
2526                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2527                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2528                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2529                         assume_unchanged = false;
2530                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2531                 }
2532                 if (isInvisibleString(this.netname))
2533                 {
2534                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2535                         sprint(this, "Warning: invisible names are not allowed.\n");
2536                         assume_unchanged = false;
2537                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2538                 }
2539                 if (!assume_unchanged && autocvar_sv_eventlog)
2540                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2541                 strcpy(CS(this).netname_previous, this.netname);
2542         }
2543
2544         // version nagging
2545         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2546         CS(this).version_nagtime = 0;
2547         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2548             // git client
2549         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2550             // git server
2551             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2552         } else {
2553             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2554             if (r < 0) { // old client
2555                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2556             } else if (r > 0) { // old server
2557                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2558             }
2559         }
2560     }
2561
2562         // GOD MODE info
2563         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2564         {
2565                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2566                 this.max_armorvalue = 0;
2567         }
2568
2569         if (frametime && IS_PLAYER(this))
2570         {
2571                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2572                 {
2573                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2574                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2575                         if (this.iceblock)
2576                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2577
2578                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2579                                 Unfreeze(this, false);
2580                 }
2581                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2582                 {
2583                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2584                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2585
2586                         if (GetResource(this, RES_HEALTH) < 1)
2587                         {
2588                                 if (this.vehicle)
2589                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2590                                 if(this.event_damage)
2591                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2592                         }
2593                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2594                                 Unfreeze(this, false);
2595                 }
2596         }
2597
2598         MUTATOR_CALLHOOK(PlayerPreThink, this);
2599
2600         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2601         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2602         {
2603                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2604                 {
2605                         if(!it.owner)
2606                         {
2607                                 if(!it.team || SAME_TEAM(this, it))
2608                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2609                                 else if(autocvar_g_vehicles_steal)
2610                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2611                         }
2612                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2613                         {
2614                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2615                         }
2616                 });
2617
2618                 this.last_vehiclecheck = time + 1;
2619         }
2620
2621         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2622         {
2623                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2624                         PlayerUseKey(this);
2625                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2626         }
2627
2628         if (IS_REAL_CLIENT(this))
2629                 PrintWelcomeMessage(this);
2630
2631         if (IS_PLAYER(this)) {
2632                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2633                         error("Client can't be spawned as player on connection!");
2634                 if(!PlayerThink(this))
2635                         return;
2636         }
2637         else if (game_stopped || intermission_running) {
2638                 if(intermission_running)
2639                         IntermissionThink(this);
2640                 return;
2641         }
2642         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2643         {
2644                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2645                 CS(this).autojoin_checked = 1;
2646                 // don't do this in ClientConnect
2647                 // many things can go wrong if a client is spawned as player on connection
2648                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2649                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2650                                 && (!teamplay || autocvar_g_balance_teams)))
2651                 {
2652                         campaign_bots_may_start = true;
2653                         if(joinAllowed(this))
2654                                 Join(this);
2655                         return;
2656                 }
2657         }
2658         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2659                 ObserverOrSpectatorThink(this);
2660         }
2661
2662         // WEAPONTODO: Add weapon request for this
2663         if (!zoomstate_set) {
2664                 bool wep_zoomed = false;
2665                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2666                 {
2667                         .entity weaponentity = weaponentities[slot];
2668                         Weapon thiswep = this.(weaponentity).m_weapon;
2669                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2670                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2671                 }
2672                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2673         }
2674
2675         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2676         {
2677                 CS(this).teamkill_soundtime = 0;
2678
2679                 entity e = CS(this).teamkill_soundsource;
2680                 entity oldpusher = e.pusher;
2681                 e.pusher = this;
2682                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2683                 e.pusher = oldpusher;
2684         }
2685
2686         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2687                 CS(this).taunt_soundtime = 0;
2688                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2689         }
2690
2691         target_voicescript_next(this);
2692
2693         // WEAPONTODO: Move into weaponsystem somehow
2694         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2695         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2696         {
2697                 .entity weaponentity = weaponentities[slot];
2698                 if(this.(weaponentity).m_weapon == WEP_Null)
2699                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2700         }
2701 }
2702
2703 void DrownPlayer(entity this)
2704 {
2705         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2706                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2707         {
2708                 STAT(AIR_FINISHED, this) = 0;
2709                 return;
2710         }
2711
2712         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2713         {
2714                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2715                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2716                 STAT(AIR_FINISHED, this) = 0;
2717         }
2718         else
2719         {
2720                 if (!STAT(AIR_FINISHED, this))
2721                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2722                 if (STAT(AIR_FINISHED, this) < time)
2723                 {       // drown!
2724                         if (this.pain_finished < time)
2725                         {
2726                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2727                                 this.pain_finished = time + 0.5;
2728                         }
2729                 }
2730         }
2731 }
2732
2733 .bool move_qcphysics;
2734
2735 void Player_Physics(entity this)
2736 {
2737         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2738
2739         if(!this.move_qcphysics)
2740                 return;
2741
2742         if(!frametime && !CS(this).pm_frametime)
2743                 return;
2744
2745         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2746
2747         CS(this).pm_frametime = 0;
2748 }
2749
2750 /*
2751 =============
2752 PlayerPostThink
2753
2754 Called every frame for each client after the physics are run
2755 =============
2756 */
2757 void PlayerPostThink (entity this)
2758 {
2759         Player_Physics(this);
2760
2761         if (sv_maxidle > 0)
2762         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2763         if (IS_REAL_CLIENT(this))
2764         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2765         {
2766                 int totalClients = 0;
2767                 if(sv_maxidle_slots > 0)
2768                 {
2769                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2770                         {
2771                                 ++totalClients;
2772                         });
2773                 }
2774
2775                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2776                 { /* do nothing */ }
2777                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2778                 {
2779                         if (CS(this).idlekick_lasttimeleft)
2780                         {
2781                                 CS(this).idlekick_lasttimeleft = 0;
2782                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2783                         }
2784                 }
2785                 else
2786                 {
2787                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2788                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2789                                 if (!CS(this).idlekick_lasttimeleft)
2790                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2791                         }
2792                         if (timeleft <= 0) {
2793                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2794                                 dropclient(this);
2795                                 return;
2796                         }
2797                         else if (timeleft <= 10) {
2798                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2799                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2800                 }
2801                                 CS(this).idlekick_lasttimeleft = timeleft;
2802                         }
2803                 }
2804         }
2805
2806         CheatFrame(this);
2807
2808         if (game_stopped)
2809         {
2810                 this.solid = SOLID_NOT;
2811                 this.takedamage = DAMAGE_NO;
2812                 set_movetype(this, MOVETYPE_NONE);
2813                 CS(this).teamkill_complain = 0;
2814                 CS(this).teamkill_soundtime = 0;
2815                 CS(this).teamkill_soundsource = NULL;
2816         }
2817
2818         if (IS_PLAYER(this)) {
2819                 if(this.death_time == time && IS_DEAD(this))
2820                 {
2821                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2822                         // once all the damage events of this frame have been processed with normal size
2823                         this.maxs.z = 5;
2824                         setsize(this, this.mins, this.maxs);
2825                 }
2826                 DrownPlayer(this);
2827                 UpdateChatBubble(this);
2828                 if (CS(this).impulse) ImpulseCommands(this);
2829                 if (game_stopped)
2830                 {
2831                         CSQCMODEL_AUTOUPDATE(this);
2832                         return;
2833                 }
2834                 GetPressedKeys(this);
2835         }
2836         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2837         {
2838                 CS(this).pressedkeys = 0;
2839                 STAT(PRESSED_KEYS, this) = 0;
2840         }
2841
2842         if (this.waypointsprite_attachedforcarrier) {
2843                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2844                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2845         }
2846
2847         CSQCMODEL_AUTOUPDATE(this);
2848 }
2849
2850 /**
2851  * message "": do not say, just test flood control
2852  * return value:
2853  *   1 = accept
2854  *   0 = reject
2855  *  -1 = fake accept
2856  */
2857 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2858 {
2859         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2860                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2861
2862         if (source)
2863                 msgin = formatmessage(source, msgin);
2864
2865         string colorstr;
2866         if (!(IS_PLAYER(source) || source.caplayer))
2867                 colorstr = "^0"; // black for spectators
2868         else if(teamplay)
2869                 colorstr = Team_ColorCode(source.team);
2870         else
2871         {
2872                 colorstr = "";
2873                 teamsay = false;
2874         }
2875
2876         if (!source) {
2877                 colorstr = "";
2878                 teamsay = false;
2879         }
2880
2881         if(msgin != "")
2882                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2883
2884         /*
2885          * using bprint solves this... me stupid
2886         // how can we prevent the message from appearing in a listen server?
2887         // for now, just give "say" back and only handle say_team
2888         if(!teamsay)
2889         {
2890                 clientcommand(source, strcat("say ", msgin));
2891                 return;
2892         }
2893         */
2894
2895         string namestr = "";
2896         if (source)
2897                 namestr = playername(source, autocvar_g_chat_teamcolors);
2898
2899         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2900
2901         string msgstr = "", cmsgstr = "";
2902         string privatemsgprefix = string_null;
2903         int privatemsgprefixlen = 0;
2904         if (msgin != "")
2905         {
2906                 bool found_me = false;
2907                 if(strstrofs(msgin, "/me", 0) >= 0)
2908                 {
2909                         string newmsgin = "";
2910                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2911                         FOREACH_WORD(msgin, true,
2912                         {
2913                                 if(strdecolorize(it) == "/me")
2914                                 {
2915                                         found_me = true;
2916                                         newmsgin = cons(newmsgin, newnamestr);
2917                                 }
2918                                 else
2919                                         newmsgin = cons(newmsgin, it);
2920                         });
2921                         msgin = newmsgin;
2922                 }
2923
2924                 if(privatesay)
2925                 {
2926                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2927                         privatemsgprefixlen = strlen(msgstr);
2928                         msgstr = strcat(msgstr, msgin);
2929                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2930                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2931                 }
2932                 else if(teamsay)
2933                 {
2934                         if(found_me)
2935                         {
2936                                 //msgin = strreplace("/me", "", msgin);
2937                                 //msgin = substring(msgin, 3, strlen(msgin));
2938                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2939                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2940                         }
2941                         else
2942                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2943                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2944                 }
2945                 else
2946                 {
2947                         if(found_me)
2948                         {
2949                                 //msgin = strreplace("/me", "", msgin);
2950                                 //msgin = substring(msgin, 3, strlen(msgin));
2951                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2952                                 msgstr = strcat("\{1}^4* ^7", msgin);
2953                         }
2954                         else {
2955                                 msgstr = "\{1}";
2956                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2957                                 msgstr = strcat(msgstr, msgin);
2958                         }
2959                         cmsgstr = "";
2960                 }
2961                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2962         }
2963
2964         string fullmsgstr = msgstr;
2965         string fullcmsgstr = cmsgstr;
2966
2967         // FLOOD CONTROL
2968         int flood = 0;
2969         var .float flood_field = floodcontrol_chat;
2970         if(floodcontrol && source)
2971         {
2972                 float flood_spl;
2973                 float flood_burst;
2974                 float flood_lmax;
2975                 float lines;
2976                 if(privatesay)
2977                 {
2978                         flood_spl = autocvar_g_chat_flood_spl_tell;
2979                         flood_burst = autocvar_g_chat_flood_burst_tell;
2980                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2981                         flood_field = floodcontrol_chattell;
2982                 }
2983                 else if(teamsay)
2984                 {
2985                         flood_spl = autocvar_g_chat_flood_spl_team;
2986                         flood_burst = autocvar_g_chat_flood_burst_team;
2987                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2988                         flood_field = floodcontrol_chatteam;
2989                 }
2990                 else
2991                 {
2992                         flood_spl = autocvar_g_chat_flood_spl;
2993                         flood_burst = autocvar_g_chat_flood_burst;
2994                         flood_lmax = autocvar_g_chat_flood_lmax;
2995                         flood_field = floodcontrol_chat;
2996                 }
2997                 flood_burst = max(0, flood_burst - 1);
2998                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2999
3000                 // do flood control for the default line size
3001                 if(msgstr != "")
3002                 {
3003                         getWrappedLine_remaining = msgstr;
3004                         msgstr = "";
3005                         lines = 0;
3006                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
3007                         {
3008                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
3009                                 ++lines;
3010                         }
3011                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3012
3013                         if(getWrappedLine_remaining != "")
3014                         {
3015                                 msgstr = strcat(msgstr, "\n");
3016                                 flood = 2;
3017                         }
3018
3019                         if (time >= source.(flood_field))
3020                         {
3021                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3022                         }
3023                         else
3024                         {
3025                                 flood = 1;
3026                                 msgstr = fullmsgstr;
3027                         }
3028                 }
3029                 else
3030                 {
3031                         if (time >= source.(flood_field))
3032                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3033                         else
3034                                 flood = 1;
3035                 }
3036
3037                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3038                         source.(flood_field) = flood = 0;
3039         }
3040
3041         string sourcemsgstr, sourcecmsgstr;
3042         if(flood == 2) // cannot happen for empty msgstr
3043         {
3044                 if(autocvar_g_chat_flood_notify_flooder)
3045                 {
3046                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3047                         sourcecmsgstr = "";
3048                 }
3049                 else
3050                 {
3051                         sourcemsgstr = fullmsgstr;
3052                         sourcecmsgstr = fullcmsgstr;
3053                 }
3054                 cmsgstr = "";
3055         }
3056         else
3057         {
3058                 sourcemsgstr = msgstr;
3059                 sourcecmsgstr = cmsgstr;
3060         }
3061
3062         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3063         {
3064                 if (!game_stopped)
3065                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
3066                         teamsay = -1; // spectators
3067         }
3068
3069         if(flood)
3070                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3071
3072         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3073         if(privatesay)
3074                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3075
3076         int ret;
3077         if(source && CS(source).muted)
3078         {
3079                 // always fake the message
3080                 ret = -1;
3081         }
3082         else if(flood == 1)
3083         {
3084                 if (autocvar_g_chat_flood_notify_flooder)
3085                 {
3086                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3087                         ret = 0;
3088                 }
3089                 else
3090                         ret = -1;
3091         }
3092         else
3093         {
3094                 ret = 1;
3095         }
3096
3097         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3098         {
3099                 if (!game_stopped)
3100                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3101                         ret = -1; // just hide the message completely
3102         }
3103
3104         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3105         ret = M_ARGV(1, int);
3106
3107         string event_log_msg = "";
3108
3109         if(sourcemsgstr != "" && ret != 0)
3110         {
3111                 if(ret < 0) // faked message, because the player is muted
3112                 {
3113                         sprint(source, sourcemsgstr);
3114                         if(sourcecmsgstr != "" && !privatesay)
3115</