Use the constants for player hitbox size when applicable (should fix observer hitbox)
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include <common/state.qh>
27
28 #include <common/effects/qc/globalsound.qh>
29
30 #include "../common/triggers/func/conveyor.qh"
31 #include "../common/triggers/teleporters.qh"
32
33 #include "../common/vehicles/all.qh"
34
35 #include "weapons/hitplot.qh"
36 #include "weapons/weaponsystem.qh"
37
38 #include "../common/net_notice.qh"
39 #include "../common/net_linked.qh"
40 #include "../common/physics/player.qh"
41
42 #include "../common/items/_mod.qh"
43
44 #include "../common/mutators/mutator/waypoints/all.qh"
45
46 #include "../common/triggers/subs.qh"
47 #include "../common/triggers/triggers.qh"
48 #include "../common/triggers/trigger/secret.qh"
49
50 #include "../common/minigames/sv_minigames.qh"
51
52 #include "../common/items/inventory.qh"
53
54 #include "../common/monsters/sv_monsters.qh"
55
56 #include "../lib/warpzone/server.qh"
57
58 STATIC_METHOD(Client, Add, void(Client this, int _team))
59 {
60     ClientConnect(this);
61     TRANSMUTE(Player, this);
62     this.frame = 12; // 7
63     this.team = _team;
64     PutClientInServer(this);
65 }
66
67 void PutObserverInServer(entity this);
68
69 STATIC_METHOD(Client, Remove, void(Client this))
70 {
71     TRANSMUTE(Observer, this);
72     PutClientInServer(this);
73     ClientDisconnect(this);
74 }
75
76 void send_CSQC_teamnagger() {
77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
78 }
79
80 int CountSpectators(entity player, entity to)
81 {
82         if(!player) { return 0; } // not sure how, but best to be safe
83
84         int spec_count = 0;
85
86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
87         {
88                 spec_count++;
89         });
90
91         return spec_count;
92 }
93
94 void WriteSpectators(entity player, entity to)
95 {
96         if(!player) { return; } // not sure how, but best to be safe
97
98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
99         {
100                 WriteByte(MSG_ENTITY, num_for_edict(it));
101         });
102 }
103
104 bool ClientData_Send(entity this, entity to, int sf)
105 {
106         assert(to == this.owner, return false);
107
108         entity e = to;
109         if (IS_SPEC(e)) e = e.enemy;
110
111         sf = 0;
112         if (e.race_completed)       sf |= 1; // forced scoreboard
113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
114         if (e.zoomstate)            sf |= 4; // zoomed
115         if (e.porto_v_angle_held)   sf |= 8; // angles held
116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
117
118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
119         WriteByte(MSG_ENTITY, sf);
120
121         if (sf & 2)
122         {
123                 WriteByte(MSG_ENTITY, to.spectatee_status);
124         }
125         if (sf & 8)
126         {
127                 WriteAngle(MSG_ENTITY, e.v_angle.x);
128                 WriteAngle(MSG_ENTITY, e.v_angle.y);
129         }
130
131         if(sf & 16)
132         {
133                 float specs = CountSpectators(e, to);
134                 WriteByte(MSG_ENTITY, specs);
135                 WriteSpectators(e, to);
136         }
137
138         return true;
139 }
140
141 void ClientData_Attach(entity this)
142 {
143         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
144         this.clientdata.drawonlytoclient = this;
145         this.clientdata.owner = this;
146 }
147
148 void ClientData_Detach(entity this)
149 {
150         delete(this.clientdata);
151         this.clientdata = NULL;
152 }
153
154 void ClientData_Touch(entity e)
155 {
156         e.clientdata.SendFlags = 1;
157
158         // make it spectatable
159         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
160 }
161
162 .string netname_previous;
163
164 void SetSpectatee(entity this, entity spectatee);
165 void SetSpectatee_status(entity this, int spectatee_num);
166
167
168 /*
169 =============
170 CheckPlayerModel
171
172 Checks if the argument string can be a valid playermodel.
173 Returns a valid one in doubt.
174 =============
175 */
176 string FallbackPlayerModel;
177 string CheckPlayerModel(string plyermodel) {
178         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
179         {
180                 // note: we cannot summon Don Strunzone here, some player may
181                 // still have the model string set. In case anyone manages how
182                 // to change a cvar default, we'll have a small leak here.
183                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
184         }
185         // only in right path
186         if( substring(plyermodel,0,14) != "models/player/")
187                 return FallbackPlayerModel;
188         // only good file extensions
189         if(substring(plyermodel,-4,4) != ".zym")
190         if(substring(plyermodel,-4,4) != ".dpm")
191         if(substring(plyermodel,-4,4) != ".iqm")
192         if(substring(plyermodel,-4,4) != ".md3")
193         if(substring(plyermodel,-4,4) != ".psk")
194                 return FallbackPlayerModel;
195         // forbid the LOD models
196         if(substring(plyermodel, -9,5) == "_lod1")
197                 return FallbackPlayerModel;
198         if(substring(plyermodel, -9,5) == "_lod2")
199                 return FallbackPlayerModel;
200         if(plyermodel != strtolower(plyermodel))
201                 return FallbackPlayerModel;
202         // also, restrict to server models
203         if(autocvar_sv_servermodelsonly)
204         {
205                 if(!fexists(plyermodel))
206                         return FallbackPlayerModel;
207         }
208         return plyermodel;
209 }
210
211 void setplayermodel(entity e, string modelname)
212 {
213         precache_model(modelname);
214         _setmodel(e, modelname);
215         player_setupanimsformodel(e);
216         if(!autocvar_g_debug_globalsounds)
217                 UpdatePlayerSounds(e);
218 }
219
220 void FixPlayermodel(entity player);
221 /** putting a client as observer in the server */
222 void PutObserverInServer(entity this)
223 {
224     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
225         PlayerState_detach(this);
226
227         if (IS_PLAYER(this) && this.health >= 1) {
228         // despawn effect
229                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
230     }
231
232     {
233         entity spot = SelectSpawnPoint(this, true);
234         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
235         this.angles = spot.angles;
236         this.angles_z = 0;
237         this.fixangle = true;
238         // offset it so that the spectator spawns higher off the ground, looks better this way
239         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
240         this.prevorigin = this.origin;
241         if (IS_REAL_CLIENT(this))
242         {
243             msg_entity = this;
244             WriteByte(MSG_ONE, SVC_SETVIEW);
245             WriteEntity(MSG_ONE, this);
246         }
247         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
248         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
249         if(!autocvar_g_debug_globalsounds)
250         {
251                 // needed for player sounds
252                 this.model = "";
253                 FixPlayermodel(this);
254         }
255         setmodel(this, MDL_Null);
256         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
257         this.view_ofs = '0 0 0';
258     }
259
260     RemoveGrapplingHook(this);
261         Portal_ClearAll(this);
262         Unfreeze(this);
263         SetSpectatee(this, NULL);
264
265         if (this.alivetime)
266         {
267                 if (!warmup_stage)
268                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
269                 this.alivetime = 0;
270         }
271
272         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
273
274         WaypointSprite_PlayerDead(this);
275
276         if (mutator_returnvalue) {
277             // mutator prevents resetting teams+score
278         } else {
279                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
280         this.frags = FRAGS_SPECTATOR;
281         PlayerScore_Clear(this);  // clear scores when needed
282     }
283
284         if (this.killcount != FRAGS_SPECTATOR)
285         {
286                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
287                 if(!gameover)
288                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
289                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
290
291                 if(this.just_joined == false) {
292                         LogTeamchange(this.playerid, -1, 4);
293                 } else
294                         this.just_joined = false;
295         }
296
297         accuracy_resend(this);
298
299         this.spectatortime = time;
300         if(this.bot_attack)
301                 IL_REMOVE(g_bot_targets, this);
302         this.bot_attack = false;
303     this.hud = HUD_NORMAL;
304         TRANSMUTE(Observer, this);
305         this.iscreature = false;
306         this.teleportable = TELEPORT_SIMPLE;
307         if(this.damagedbycontents)
308                 IL_REMOVE(g_damagedbycontents, this);
309         this.damagedbycontents = false;
310         this.health = FRAGS_SPECTATOR;
311         SetSpectatee_status(this, etof(this));
312         this.takedamage = DAMAGE_NO;
313         this.solid = SOLID_NOT;
314         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
315         this.flags = FL_CLIENT | FL_NOTARGET;
316         this.armorvalue = 666;
317         this.effects = 0;
318         this.armorvalue = autocvar_g_balance_armor_start;
319         this.pauserotarmor_finished = 0;
320         this.pauserothealth_finished = 0;
321         this.pauseregen_finished = 0;
322         this.damageforcescale = 0;
323         this.death_time = 0;
324         this.respawn_flags = 0;
325         this.respawn_time = 0;
326         this.stat_respawn_time = 0;
327         this.alpha = 0;
328         this.scale = 0;
329         this.fade_time = 0;
330         this.pain_frame = 0;
331         this.pain_finished = 0;
332         this.strength_finished = 0;
333         this.invincible_finished = 0;
334         this.superweapons_finished = 0;
335         this.pushltime = 0;
336         this.istypefrag = 0;
337         setthink(this, func_null);
338         this.nextthink = 0;
339         this.hook_time = 0;
340         this.deadflag = DEAD_NO;
341         this.crouch = false;
342         this.revive_progress = 0;
343         this.revival_time = 0;
344
345         this.items = 0;
346         this.weapons = '0 0 0';
347         this.drawonlytoclient = this;
348
349         this.weaponname = "";
350         this.weaponmodel = "";
351         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
352         {
353                 this.weaponentities[slot] = NULL;
354         }
355         this.exteriorweaponentity = NULL;
356         this.killcount = FRAGS_SPECTATOR;
357         this.velocity = '0 0 0';
358         this.avelocity = '0 0 0';
359         this.punchangle = '0 0 0';
360         this.punchvector = '0 0 0';
361         this.oldvelocity = this.velocity;
362         this.fire_endtime = -1;
363         this.event_damage = func_null;
364
365         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
366         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
367         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
368 }
369
370 int player_getspecies(entity this)
371 {
372         get_model_parameters(this.model, this.skin);
373         int s = get_model_parameters_species;
374         get_model_parameters(string_null, 0);
375         if (s < 0) return SPECIES_HUMAN;
376         return s;
377 }
378
379 .float model_randomizer;
380 void FixPlayermodel(entity player)
381 {
382         string defaultmodel = "";
383         int defaultskin = 0;
384         if(autocvar_sv_defaultcharacter)
385         {
386                 if(teamplay)
387                 {
388                         string s = Static_Team_ColorName_Lower(player.team);
389                         if (s != "neutral")
390                         {
391                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
392                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
393                         }
394                 }
395
396                 if(defaultmodel == "")
397                 {
398                         defaultmodel = autocvar_sv_defaultplayermodel;
399                         defaultskin = autocvar_sv_defaultplayerskin;
400                 }
401
402                 int n = tokenize_console(defaultmodel);
403                 if(n > 0)
404                 {
405                         defaultmodel = argv(floor(n * player.model_randomizer));
406                         // However, do NOT randomize if the player-selected model is in the list.
407                         for (int i = 0; i < n; ++i)
408                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
409                                         defaultmodel = argv(i);
410                 }
411
412                 int i = strstrofs(defaultmodel, ":", 0);
413                 if(i >= 0)
414                 {
415                         defaultskin = stof(substring(defaultmodel, i+1, -1));
416                         defaultmodel = substring(defaultmodel, 0, i);
417                 }
418         }
419         if(autocvar_sv_defaultcharacterskin && !defaultskin)
420         {
421                 if(teamplay)
422                 {
423                         string s = Static_Team_ColorName_Lower(player.team);
424                         if (s != "neutral")
425                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
426                 }
427
428                 if(!defaultskin)
429                         defaultskin = autocvar_sv_defaultplayerskin;
430         }
431
432         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
433         defaultmodel = M_ARGV(0, string);
434         defaultskin = M_ARGV(1, int);
435
436         bool chmdl = false;
437         int oldskin;
438         if(defaultmodel != "")
439         {
440                 if (defaultmodel != player.model)
441                 {
442                         vector m1 = player.mins;
443                         vector m2 = player.maxs;
444                         setplayermodel (player, defaultmodel);
445                         setsize (player, m1, m2);
446                         chmdl = true;
447                 }
448
449                 oldskin = player.skin;
450                 player.skin = defaultskin;
451         } else {
452                 if (player.playermodel != player.model || player.playermodel == "")
453                 {
454                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
455                         vector m1 = player.mins;
456                         vector m2 = player.maxs;
457                         setplayermodel (player, player.playermodel);
458                         setsize (player, m1, m2);
459                         chmdl = true;
460                 }
461
462                 if(!autocvar_sv_defaultcharacterskin)
463                 {
464                         oldskin = player.skin;
465                         player.skin = stof(player.playerskin);
466                 }
467                 else
468                 {
469                         oldskin = player.skin;
470                         player.skin = defaultskin;
471                 }
472         }
473
474         if(chmdl || oldskin != player.skin) // model or skin has changed
475         {
476                 player.species = player_getspecies(player); // update species
477                 if(!autocvar_g_debug_globalsounds)
478                         UpdatePlayerSounds(player); // update skin sounds
479         }
480
481         if(!teamplay)
482                 if(strlen(autocvar_sv_defaultplayercolors))
483                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
484                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
485 }
486
487
488 /** Called when a client spawns in the server */
489 void PutClientInServer(entity this)
490 {
491         if (IS_BOT_CLIENT(this)) {
492                 TRANSMUTE(Player, this);
493         } else if (IS_REAL_CLIENT(this)) {
494                 msg_entity = this;
495                 WriteByte(MSG_ONE, SVC_SETVIEW);
496                 WriteEntity(MSG_ONE, this);
497         }
498         if (gameover) {
499                 TRANSMUTE(Observer, this);
500         }
501
502         SetSpectatee(this, NULL);
503
504         // reset player keys
505         this.itemkeys = 0;
506
507         MUTATOR_CALLHOOK(PutClientInServer, this);
508
509         if (IS_OBSERVER(this)) {
510                 PutObserverInServer(this);
511         } else if (IS_PLAYER(this)) {
512                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
513
514                 PlayerState_attach(this);
515                 accuracy_resend(this);
516
517                 if (this.team < 0)
518                         JoinBestTeam(this, false, true);
519
520                 entity spot = SelectSpawnPoint(this, false);
521                 if (!spot) {
522                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
523                         return; // spawn failed
524                 }
525
526                 TRANSMUTE(Player, this);
527
528                 this.wasplayer = true;
529                 this.iscreature = true;
530                 this.teleportable = TELEPORT_NORMAL;
531                 if(!this.damagedbycontents)
532                         IL_PUSH(g_damagedbycontents, this);
533                 this.damagedbycontents = true;
534                 set_movetype(this, MOVETYPE_WALK);
535                 this.solid = SOLID_SLIDEBOX;
536                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
537                 if (autocvar_g_playerclip_collisions)
538                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
539                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
540                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
541                 this.frags = FRAGS_PLAYER;
542                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
543                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
544                 if (autocvar__notarget)
545                         this.flags |= FL_NOTARGET;
546                 this.takedamage = DAMAGE_AIM;
547                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
548                 this.dmg = 2; // WTF
549
550                 if (warmup_stage) {
551                         this.ammo_shells = warmup_start_ammo_shells;
552                         this.ammo_nails = warmup_start_ammo_nails;
553                         this.ammo_rockets = warmup_start_ammo_rockets;
554                         this.ammo_cells = warmup_start_ammo_cells;
555                         this.ammo_plasma = warmup_start_ammo_plasma;
556                         this.ammo_fuel = warmup_start_ammo_fuel;
557                         this.health = warmup_start_health;
558                         this.armorvalue = warmup_start_armorvalue;
559                         this.weapons = WARMUP_START_WEAPONS;
560                 } else {
561                         this.ammo_shells = start_ammo_shells;
562                         this.ammo_nails = start_ammo_nails;
563                         this.ammo_rockets = start_ammo_rockets;
564                         this.ammo_cells = start_ammo_cells;
565                         this.ammo_plasma = start_ammo_plasma;
566                         this.ammo_fuel = start_ammo_fuel;
567                         this.health = start_health;
568                         this.armorvalue = start_armorvalue;
569                         this.weapons = start_weapons;
570                 }
571                 SetSpectatee_status(this, 0);
572
573                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
574
575                 this.items = start_items;
576
577                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
578                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
579                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
580                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
581                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
582                 // extend the pause of rotting if client was reset at the beginning of the countdown
583                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
584                         float f = game_starttime - time;
585                         this.spawnshieldtime += f;
586                         this.pauserotarmor_finished += f;
587                         this.pauserothealth_finished += f;
588                         this.pauseregen_finished += f;
589                 }
590                 this.damageforcescale = 2;
591                 this.death_time = 0;
592                 this.respawn_flags = 0;
593                 this.respawn_time = 0;
594                 this.stat_respawn_time = 0;
595                 this.scale = autocvar_sv_player_scale;
596                 this.fade_time = 0;
597                 this.pain_frame = 0;
598                 this.pain_finished = 0;
599                 this.pushltime = 0;
600                 setthink(this, func_null); // players have no think function
601                 this.nextthink = 0;
602                 this.dmg_team = 0;
603                 this.ballistics_density = autocvar_g_ballistics_density_player;
604
605                 this.deadflag = DEAD_NO;
606
607                 this.angles = spot.angles;
608                 this.angles_z = 0; // never spawn tilted even if the spot says to
609                 if (IS_BOT_CLIENT(this))
610                         this.v_angle = this.angles;
611                 this.fixangle = true; // turn this way immediately
612                 this.oldvelocity = this.velocity = '0 0 0';
613                 this.avelocity = '0 0 0';
614                 this.punchangle = '0 0 0';
615                 this.punchvector = '0 0 0';
616
617                 this.strength_finished = 0;
618                 this.invincible_finished = 0;
619                 this.fire_endtime = -1;
620                 this.revive_progress = 0;
621                 this.revival_time = 0;
622                 this.air_finished = time + 12;
623
624                 entity spawnevent = new_pure(spawnevent);
625                 spawnevent.owner = this;
626                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
627
628                 // Cut off any still running player sounds.
629                 stopsound(this, CH_PLAYER_SINGLE);
630
631                 this.model = "";
632                 FixPlayermodel(this);
633                 this.drawonlytoclient = NULL;
634
635                 this.viewloc = NULL;
636
637                 this.crouch = false;
638                 this.view_ofs = STAT(PL_VIEW_OFS, this);
639                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
640                 this.spawnorigin = spot.origin;
641                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
642                 // don't reset back to last position, even if new position is stuck in solid
643                 this.oldorigin = this.origin;
644                 this.prevorigin = this.origin;
645                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
646                 if(this.conveyor)
647                         IL_REMOVE(g_conveyed, this);
648                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
649                 this.hud = HUD_NORMAL;
650
651                 this.event_damage = PlayerDamage;
652
653                 if(!this.bot_attack)
654                         IL_PUSH(g_bot_targets, this);
655                 this.bot_attack = true;
656                 this.monster_attack = true;
657
658                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
659
660                 if (this.killcount == FRAGS_SPECTATOR) {
661                         PlayerScore_Clear(this);
662                         this.killcount = 0;
663                 }
664
665                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
666                 {
667                         CL_SpawnWeaponentity(this, weaponentities[slot]);
668                 }
669                 this.alpha = default_player_alpha;
670                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
671                 this.exteriorweaponentity.alpha = default_weapon_alpha;
672
673                 this.speedrunning = false;
674
675                 target_voicescript_clear(this);
676
677                 // reset fields the weapons may use
678                 FOREACH(Weapons, true, LAMBDA(
679                         it.wr_resetplayer(it, this);
680                         // reload all reloadable weapons
681                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
682                                 this.weapon_load[it.m_id] = it.reloading_ammo;
683                         }
684                 ));
685
686                 {
687                         string s = spot.target;
688                         spot.target = string_null;
689                         SUB_UseTargets(spot, this, NULL);
690                         spot.target = s;
691                 }
692
693                 Unfreeze(this);
694
695                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
696
697                 if (autocvar_spawn_debug)
698                 {
699                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
700                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
701                 }
702
703                 PS(this).m_switchweapon = w_getbestweapon(this);
704                 this.cnt = -1; // W_LastWeapon will not complain
705                 PS(this).m_weapon = WEP_Null;
706                 this.weaponname = "";
707                 PS(this).m_switchingweapon = WEP_Null;
708
709                 if (!warmup_stage && !this.alivetime)
710                         this.alivetime = time;
711
712                 antilag_clear(this, CS(this));
713         }
714 }
715
716 void ClientInit_misc(entity this);
717
718 // TODO do we need all these fields, or should we stop autodetecting runtime
719 // changes and just have a console command to update this?
720 bool ClientInit_SendEntity(entity this, entity to, int sf)
721 {
722         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
723         return = true;
724         msg_entity = to;
725         // MSG_INIT replacement
726         // TODO: make easier to use
727         Registry_send_all();
728         W_PROP_reload(MSG_ONE, to);
729         ClientInit_misc(this);
730         MUTATOR_CALLHOOK(Ent_Init);
731 }
732 void ClientInit_misc(entity this)
733 {
734         int channel = MSG_ONE;
735         WriteHeader(channel, ENT_CLIENT_INIT);
736         WriteByte(channel, g_nexball_meter_period * 32);
737         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
738         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
739         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
741         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
742         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
743         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
745
746         if(sv_foginterval && world.fog != "")
747                 WriteString(channel, world.fog);
748         else
749                 WriteString(channel, "");
750         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
751         WriteByte(channel, serverflags);
752         WriteCoord(channel, autocvar_g_trueaim_minrange);
753 }
754
755 void ClientInit_CheckUpdate(entity this)
756 {
757         this.nextthink = time;
758         if(this.count != autocvar_g_balance_armor_blockpercent)
759         {
760                 this.count = autocvar_g_balance_armor_blockpercent;
761                 this.SendFlags |= 1;
762         }
763 }
764
765 void ClientInit_Spawn()
766 {
767         entity e = new_pure(clientinit);
768         setthink(e, ClientInit_CheckUpdate);
769         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
770
771         ClientInit_CheckUpdate(e);
772 }
773
774 /*
775 =============
776 SetNewParms
777 =============
778 */
779 void SetNewParms ()
780 {
781         // initialize parms for a new player
782         parm1 = -(86400 * 366);
783
784         MUTATOR_CALLHOOK(SetNewParms);
785 }
786
787 /*
788 =============
789 SetChangeParms
790 =============
791 */
792 void SetChangeParms (entity this)
793 {
794         // save parms for level change
795         parm1 = this.parm_idlesince - time;
796
797         MUTATOR_CALLHOOK(SetChangeParms);
798 }
799
800 /*
801 =============
802 DecodeLevelParms
803 =============
804 */
805 void DecodeLevelParms(entity this)
806 {
807         // load parms
808         this.parm_idlesince = parm1;
809         if (this.parm_idlesince == -(86400 * 366))
810                 this.parm_idlesince = time;
811
812         // whatever happens, allow 60 seconds of idling directly after connect for map loading
813         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
814
815         MUTATOR_CALLHOOK(DecodeLevelParms);
816 }
817
818 /*
819 =============
820 ClientKill
821
822 Called when a client types 'kill' in the console
823 =============
824 */
825
826 .float clientkill_nexttime;
827 void ClientKill_Now_TeamChange(entity this)
828 {
829         if(this.killindicator_teamchange == -1)
830         {
831                 JoinBestTeam( this, false, true );
832         }
833         else if(this.killindicator_teamchange == -2)
834         {
835                 if(blockSpectators)
836                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
837                 PutObserverInServer(this);
838         }
839         else
840                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
841         this.killindicator_teamchange = 0;
842 }
843
844 void ClientKill_Now(entity this)
845 {
846         if(this.vehicle)
847         {
848             vehicles_exit(this.vehicle, VHEF_RELEASE);
849             if(!this.killindicator_teamchange)
850             {
851             this.vehicle_health = -1;
852             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
853             }
854         }
855
856         if(this.killindicator && !wasfreed(this.killindicator))
857                 delete(this.killindicator);
858
859         this.killindicator = NULL;
860
861         if(this.killindicator_teamchange)
862                 ClientKill_Now_TeamChange(this);
863
864         if(!IS_SPEC(this) && !IS_OBSERVER(this))
865                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
866
867         // now I am sure the player IS dead
868 }
869 void KillIndicator_Think(entity this)
870 {
871         if (gameover)
872         {
873                 this.owner.killindicator = NULL;
874                 delete(this);
875                 return;
876         }
877
878         if (this.owner.alpha < 0 && !this.owner.vehicle)
879         {
880                 this.owner.killindicator = NULL;
881                 delete(this);
882                 return;
883         }
884
885         if(this.cnt <= 0)
886         {
887                 ClientKill_Now(this.owner);
888                 return;
889         }
890     else if(g_cts && this.health == 1) // health == 1 means that it's silent
891     {
892         this.nextthink = time + 1;
893         this.cnt -= 1;
894     }
895         else
896         {
897                 if(this.cnt <= 10)
898                         setmodel(this, MDL_NUM(this.cnt));
899                 if(IS_REAL_CLIENT(this.owner))
900                 {
901                         if(this.cnt <= 10)
902                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
903                 }
904                 this.nextthink = time + 1;
905                 this.cnt -= 1;
906         }
907 }
908
909 float clientkilltime;
910 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
911 {
912         float killtime;
913         float starttime;
914
915         if (gameover)
916                 return;
917
918         killtime = autocvar_g_balance_kill_delay;
919
920         if(g_race_qualifying || g_cts)
921                 killtime = 0;
922
923     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
924         return;
925
926         this.killindicator_teamchange = targetteam;
927
928     if(!this.killindicator)
929         {
930                 if(!IS_DEAD(this))
931                 {
932                         killtime = max(killtime, this.clientkill_nexttime - time);
933                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
934                 }
935
936                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
937                 {
938                         ClientKill_Now(this);
939                 }
940                 else
941                 {
942                         starttime = max(time, clientkilltime);
943
944                         this.killindicator = spawn();
945                         this.killindicator.owner = this;
946                         this.killindicator.scale = 0.5;
947                         setattachment(this.killindicator, this, "");
948                         setorigin(this.killindicator, '0 0 52');
949                         setthink(this.killindicator, KillIndicator_Think);
950                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
951                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
952                         this.killindicator.cnt = ceil(killtime);
953                         this.killindicator.count = bound(0, ceil(killtime), 10);
954                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
955
956                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
957                         {
958                                 it.killindicator = spawn();
959                                 it.killindicator.owner = it;
960                                 it.killindicator.scale = 0.5;
961                                 setattachment(it.killindicator, it, "");
962                                 setorigin(it.killindicator, '0 0 52');
963                                 setthink(it.killindicator, KillIndicator_Think);
964                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
965                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
966                                 it.killindicator.cnt = ceil(killtime);
967                         });
968                         this.lip = 0;
969                 }
970         }
971         if(this.killindicator)
972         {
973                 if(targetteam == 0) // just die
974                 {
975                         this.killindicator.colormod = '0 0 0';
976                         if(IS_REAL_CLIENT(this))
977                         if(this.killindicator.cnt > 0)
978                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
979                 }
980                 else if(targetteam == -1) // auto
981                 {
982                         this.killindicator.colormod = '0 1 0';
983                         if(IS_REAL_CLIENT(this))
984                         if(this.killindicator.cnt > 0)
985                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
986                 }
987                 else if(targetteam == -2) // spectate
988                 {
989                         this.killindicator.colormod = '0.5 0.5 0.5';
990                         if(IS_REAL_CLIENT(this))
991                         if(this.killindicator.cnt > 0)
992                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
993                 }
994                 else
995                 {
996                         this.killindicator.colormod = Team_ColorRGB(targetteam);
997                         if(IS_REAL_CLIENT(this))
998                         if(this.killindicator.cnt > 0)
999                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1000                 }
1001         }
1002
1003 }
1004
1005 void ClientKill (entity this)
1006 {
1007         if(gameover) return;
1008         if(this.player_blocked) return;
1009         if(STAT(FROZEN, this)) return;
1010
1011         ClientKill_TeamChange(this, 0);
1012 }
1013
1014 void FixClientCvars(entity e)
1015 {
1016         // send prediction settings to the client
1017         stuffcmd(e, "\nin_bindmap 0 0\n");
1018         if(autocvar_g_antilag == 3) // client side hitscan
1019                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1020         if(autocvar_sv_gentle)
1021                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1022
1023         MUTATOR_CALLHOOK(FixClientCvars, e);
1024 }
1025
1026 float PlayerInIDList(entity p, string idlist)
1027 {
1028         float n, i;
1029         string s;
1030
1031         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1032         if (!p.crypto_idfp)
1033                 return 0;
1034
1035         // this function allows abbreviated player IDs too!
1036         n = tokenize_console(idlist);
1037         for(i = 0; i < n; ++i)
1038         {
1039                 s = argv(i);
1040                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1041                         return 1;
1042         }
1043
1044         return 0;
1045 }
1046
1047 #ifdef DP_EXT_PRECONNECT
1048 /*
1049 =============
1050 ClientPreConnect
1051
1052 Called once (not at each match start) when a client begins a connection to the server
1053 =============
1054 */
1055 void ClientPreConnect(entity this)
1056 {
1057         if(autocvar_sv_eventlog)
1058         {
1059                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1060                         this.playerid,
1061                         etof(this),
1062                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1063                 ));
1064         }
1065 }
1066 #endif
1067
1068 /**
1069 =============
1070 ClientConnect
1071
1072 Called when a client connects to the server
1073 =============
1074 */
1075 void ClientConnect(entity this)
1076 {
1077         if (Ban_MaybeEnforceBanOnce(this)) return;
1078         assert(!IS_CLIENT(this), return);
1079         this.flags |= FL_CLIENT;
1080         assert(player_count >= 0, player_count = 0);
1081
1082 #ifdef WATERMARK
1083         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1084 #endif
1085         this.version_nagtime = time + 10 + random() * 10;
1086         TRANSMUTE(Client, this);
1087
1088         // identify the right forced team
1089         if (autocvar_g_campaign)
1090         {
1091                 if (IS_REAL_CLIENT(this)) // only players, not bots
1092                 {
1093                         switch (autocvar_g_campaign_forceteam)
1094                         {
1095                                 case 1: this.team_forced = NUM_TEAM_1; break;
1096                                 case 2: this.team_forced = NUM_TEAM_2; break;
1097                                 case 3: this.team_forced = NUM_TEAM_3; break;
1098                                 case 4: this.team_forced = NUM_TEAM_4; break;
1099                                 default: this.team_forced = 0;
1100                         }
1101                 }
1102         }
1103         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1104         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1105         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1107         else switch (autocvar_g_forced_team_otherwise)
1108         {
1109                 default: this.team_forced = 0; break;
1110                 case "red": this.team_forced = NUM_TEAM_1; break;
1111                 case "blue": this.team_forced = NUM_TEAM_2; break;
1112                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1113                 case "pink": this.team_forced = NUM_TEAM_4; break;
1114                 case "spectate":
1115                 case "spectator":
1116                         this.team_forced = -1;
1117                         break;
1118         }
1119         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1120
1121     {
1122         int id = this.playerid;
1123         this.playerid = 0; // silent
1124             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1125             this.playerid = id;
1126     }
1127
1128         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1129                 TRANSMUTE(Observer, this);
1130         } else {
1131                 if (!teamplay || autocvar_g_balance_teams) {
1132                         TRANSMUTE(Player, this);
1133                         campaign_bots_may_start = true;
1134                 } else {
1135                         TRANSMUTE(Observer, this); // do it anyway
1136                 }
1137         }
1138
1139         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1140
1141         // always track bots, don't ask for cl_allow_uidtracking
1142     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1143
1144         if (autocvar_sv_eventlog)
1145                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1146
1147         LogTeamchange(this.playerid, this.team, 1);
1148
1149         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1150
1151         this.netname_previous = strzone(this.netname);
1152
1153         if(teamplay && IS_PLAYER(this))
1154                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1155         else
1156                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1157
1158         stuffcmd(this, clientstuff, "\n");
1159         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1160
1161         FixClientCvars(this);
1162
1163         // get version info from player
1164         stuffcmd(this, "cmd clientversion $gameversion\n");
1165
1166         // notify about available teams
1167         if (teamplay)
1168         {
1169                 CheckAllowedTeams(this);
1170                 int t = 0;
1171                 if (c1 >= 0) t |= BIT(0);
1172                 if (c2 >= 0) t |= BIT(1);
1173                 if (c3 >= 0) t |= BIT(2);
1174                 if (c4 >= 0) t |= BIT(3);
1175                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1176         }
1177         else
1178         {
1179                 stuffcmd(this, "set _teams_available 0\n");
1180         }
1181
1182         bot_relinkplayerlist();
1183
1184         this.spectatortime = time;
1185         if (blockSpectators)
1186         {
1187                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1188         }
1189
1190         this.jointime = time;
1191         this.allowed_timeouts = autocvar_sv_timeout_number;
1192
1193         if (IS_REAL_CLIENT(this))
1194         {
1195                 if (g_weaponarena_weapons == WEPSET(TUBA))
1196                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1197         }
1198
1199         if (!sv_foginterval && world.fog != "")
1200                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1201
1202         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1203                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1204                         send_CSQC_teamnagger();
1205
1206         CSQCMODEL_AUTOINIT(this);
1207
1208         this.model_randomizer = random();
1209
1210         if (IS_REAL_CLIENT(this))
1211                 sv_notice_join(this);
1212
1213         // update physics stats (players can spawn before physics runs)
1214         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1215
1216         IL_EACH(g_initforplayer, it.init_for_player, {
1217                 it.init_for_player(it, this);
1218         });
1219
1220         MUTATOR_CALLHOOK(ClientConnect, this);
1221
1222         if (IS_REAL_CLIENT(this))
1223         {
1224                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1225                 {
1226                         this.motd_actived_time = -1;
1227                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1228                 }
1229         }
1230 }
1231 /*
1232 =============
1233 ClientDisconnect
1234
1235 Called when a client disconnects from the server
1236 =============
1237 */
1238 .entity chatbubbleentity;
1239 void ReadyCount();
1240 void ClientDisconnect(entity this)
1241 {
1242         assert(IS_CLIENT(this), return);
1243
1244         PlayerStats_GameReport_FinalizePlayer(this);
1245         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1246         if (this.active_minigame) part_minigame(this);
1247         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1248
1249         if (autocvar_sv_eventlog)
1250                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1251
1252         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1253
1254         SetSpectatee(this, NULL);
1255
1256     MUTATOR_CALLHOOK(ClientDisconnect, this);
1257
1258         ClientState_detach(this);
1259
1260         Portal_ClearAll(this);
1261
1262         Unfreeze(this);
1263
1264         RemoveGrapplingHook(this);
1265
1266         // Here, everything has been done that requires this player to be a client.
1267
1268         this.flags &= ~FL_CLIENT;
1269
1270         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1271         if (this.killindicator) delete(this.killindicator);
1272
1273         WaypointSprite_PlayerGone(this);
1274
1275         bot_relinkplayerlist();
1276
1277         if (this.netname_previous) strunzone(this.netname_previous);
1278         if (this.clientstatus) strunzone(this.clientstatus);
1279         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1280         if (this.personal) delete(this.personal);
1281
1282         this.playerid = 0;
1283         ReadyCount();
1284         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1285
1286         ONREMOVE(this);
1287 }
1288
1289 void ChatBubbleThink(entity this)
1290 {
1291         this.nextthink = time;
1292         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1293         {
1294                 if(this.owner) // but why can that ever be NULL?
1295                         this.owner.chatbubbleentity = NULL;
1296                 delete(this);
1297                 return;
1298         }
1299
1300         this.mdl = "";
1301
1302         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1303         {
1304                 if ( this.owner.active_minigame )
1305                         this.mdl = "models/sprites/minigame_busy.iqm";
1306                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1307                         this.mdl = "models/misc/chatbubble.spr";
1308         }
1309
1310         if ( this.model != this.mdl )
1311                 _setmodel(this, this.mdl);
1312
1313 }
1314
1315 void UpdateChatBubble(entity this)
1316 {
1317         if (this.alpha < 0)
1318                 return;
1319         // spawn a chatbubble entity if needed
1320         if (!this.chatbubbleentity)
1321         {
1322                 this.chatbubbleentity = new(chatbubbleentity);
1323                 this.chatbubbleentity.owner = this;
1324                 this.chatbubbleentity.exteriormodeltoclient = this;
1325                 setthink(this.chatbubbleentity, ChatBubbleThink);
1326                 this.chatbubbleentity.nextthink = time;
1327                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1328                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1329                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1330                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1331                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1332                 //this.chatbubbleentity.model = "";
1333                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1334         }
1335 }
1336
1337
1338 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1339 // added to the model skins
1340 /*void UpdateColorModHack()
1341 {
1342         float c;
1343         c = this.clientcolors & 15;
1344         // LordHavoc: only bothering to support white, green, red, yellow, blue
1345              if (!teamplay) this.colormod = '0 0 0';
1346         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1347         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1348         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1349         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1350         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1351         else this.colormod = '1 1 1';
1352 }*/
1353
1354 void respawn(entity this)
1355 {
1356         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1357         {
1358                 this.solid = SOLID_NOT;
1359                 this.takedamage = DAMAGE_NO;
1360                 set_movetype(this, MOVETYPE_FLY);
1361                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1362                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1363                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1364                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1365                 if(autocvar_g_respawn_ghosts_maxtime)
1366                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1367         }
1368
1369         CopyBody(this, 1);
1370
1371         this.effects |= EF_NODRAW; // prevent another CopyBody
1372         PutClientInServer(this);
1373 }
1374
1375 void play_countdown(entity this, float finished, Sound samp)
1376 {
1377     TC(Sound, samp);
1378         if(IS_REAL_CLIENT(this))
1379                 if(floor(finished - time - frametime) != floor(finished - time))
1380                         if(finished - time < 6)
1381                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1382 }
1383
1384 void player_powerups(entity this)
1385 {
1386         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1387         int items_prev = this.items;
1388
1389         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1390                 this.modelflags |= MF_ROCKET;
1391         else
1392                 this.modelflags &= ~MF_ROCKET;
1393
1394         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1395
1396         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1397                 return;
1398
1399         Fire_ApplyDamage(this);
1400         Fire_ApplyEffect(this);
1401
1402         if (!g_instagib)
1403         {
1404                 if (this.items & ITEM_Strength.m_itemid)
1405                 {
1406                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1407                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1408                         if (time > this.strength_finished)
1409                         {
1410                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1411                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1412                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1413                         }
1414                 }
1415                 else
1416                 {
1417                         if (time < this.strength_finished)
1418                         {
1419                                 this.items = this.items | ITEM_Strength.m_itemid;
1420                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1421                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1422                         }
1423                 }
1424                 if (this.items & ITEM_Shield.m_itemid)
1425                 {
1426                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1427                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1428                         if (time > this.invincible_finished)
1429                         {
1430                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1431                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1432                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1433                         }
1434                 }
1435                 else
1436                 {
1437                         if (time < this.invincible_finished)
1438                         {
1439                                 this.items = this.items | ITEM_Shield.m_itemid;
1440                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1441                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1442                         }
1443                 }
1444                 if (this.items & IT_SUPERWEAPON)
1445                 {
1446                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1447                         {
1448                                 this.superweapons_finished = 0;
1449                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1450                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1451                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1452                         }
1453                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1454                         {
1455                                 // don't let them run out
1456                         }
1457                         else
1458                         {
1459                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1460                                 if (time > this.superweapons_finished)
1461                                 {
1462                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1463                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1464                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1465                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1466                                 }
1467                         }
1468                 }
1469                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1470                 {
1471                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1472                         {
1473                                 this.items = this.items | IT_SUPERWEAPON;
1474                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1475                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1476                         }
1477                         else
1478                         {
1479                                 this.superweapons_finished = 0;
1480                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1481                         }
1482                 }
1483                 else
1484                 {
1485                         this.superweapons_finished = 0;
1486                 }
1487         }
1488
1489         if(autocvar_g_nodepthtestplayers)
1490                 this.effects = this.effects | EF_NODEPTHTEST;
1491
1492         if(autocvar_g_fullbrightplayers)
1493                 this.effects = this.effects | EF_FULLBRIGHT;
1494
1495         if (time >= game_starttime)
1496         if (time < this.spawnshieldtime)
1497                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1498
1499         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1500 }
1501
1502 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1503 {
1504         if(current > stable)
1505                 return current;
1506         else if(current > stable - 0.25) // when close enough, "snap"
1507                 return stable;
1508         else
1509                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1510 }
1511
1512 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1513 {
1514         if(current < stable)
1515                 return current;
1516         else if(current < stable + 0.25) // when close enough, "snap"
1517                 return stable;
1518         else
1519                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1520 }
1521
1522 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1523 {
1524         if(current > rotstable)
1525         {
1526                 if(rotframetime > 0)
1527                 {
1528                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1529                         current = max(rotstable, current - rotlinear * rotframetime);
1530                 }
1531         }
1532         else if(current < regenstable)
1533         {
1534                 if(regenframetime > 0)
1535                 {
1536                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1537                         current = min(regenstable, current + regenlinear * regenframetime);
1538                 }
1539         }
1540
1541         if(current > limit)
1542                 current = limit;
1543
1544         return current;
1545 }
1546
1547 void player_regen(entity this)
1548 {
1549         float max_mod, regen_mod, rot_mod, limit_mod;
1550         max_mod = regen_mod = rot_mod = limit_mod = 1;
1551
1552         float regen_health = autocvar_g_balance_health_regen;
1553         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1554         float regen_health_rot = autocvar_g_balance_health_rot;
1555         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1556         float regen_health_stable = autocvar_g_balance_health_regenstable;
1557         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1558         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1559                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1560         max_mod = M_ARGV(1, float);
1561         regen_mod = M_ARGV(2, float);
1562         rot_mod = M_ARGV(3, float);
1563         limit_mod = M_ARGV(4, float);
1564         regen_health = M_ARGV(5, float);
1565         regen_health_linear = M_ARGV(6, float);
1566         regen_health_rot = M_ARGV(7, float);
1567         regen_health_rotlinear = M_ARGV(8, float);
1568         regen_health_stable = M_ARGV(9, float);
1569         regen_health_rotstable = M_ARGV(10, float);
1570
1571
1572         if(!mutator_returnvalue)
1573         if(!STAT(FROZEN, this))
1574         {
1575                 float mina, maxa, limith, limita;
1576                 maxa = autocvar_g_balance_armor_rotstable;
1577                 mina = autocvar_g_balance_armor_regenstable;
1578                 limith = autocvar_g_balance_health_limit;
1579                 limita = autocvar_g_balance_armor_limit;
1580
1581                 regen_health_rotstable = regen_health_rotstable * max_mod;
1582                 regen_health_stable = regen_health_stable * max_mod;
1583                 limith = limith * limit_mod;
1584                 limita = limita * limit_mod;
1585
1586                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1587                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1588         }
1589
1590         // if player rotted to death...  die!
1591         // check this outside above checks, as player may still be able to rot to death
1592         if(this.health < 1)
1593         {
1594                 if(this.vehicle)
1595                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1596                 if(this.event_damage)
1597                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1598         }
1599
1600         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1601         {
1602                 float minf, maxf, limitf;
1603
1604                 maxf = autocvar_g_balance_fuel_rotstable;
1605                 minf = autocvar_g_balance_fuel_regenstable;
1606                 limitf = autocvar_g_balance_fuel_limit;
1607
1608                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1609         }
1610 }
1611
1612 bool zoomstate_set;
1613 void SetZoomState(entity this, float newzoom)
1614 {
1615         if(newzoom != this.zoomstate)
1616         {
1617                 this.zoomstate = newzoom;
1618                 ClientData_Touch(this);
1619         }
1620         zoomstate_set = true;
1621 }
1622
1623 void GetPressedKeys(entity this)
1624 {
1625         MUTATOR_CALLHOOK(GetPressedKeys, this);
1626         int keys = STAT(PRESSED_KEYS, this);
1627         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1628         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1629         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1630         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1631
1632         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1633         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1634         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1635         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1636         this.pressedkeys = keys; // store for other users
1637
1638         STAT(PRESSED_KEYS, this) = keys;
1639 }
1640
1641 /*
1642 ======================
1643 spectate mode routines
1644 ======================
1645 */
1646
1647 void SpectateCopy(entity this, entity spectatee)
1648 {
1649     TC(Client, this); TC(Client, spectatee);
1650
1651         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1652         PS(this) = PS(spectatee);
1653         this.armortype = spectatee.armortype;
1654         this.armorvalue = spectatee.armorvalue;
1655         this.ammo_cells = spectatee.ammo_cells;
1656         this.ammo_plasma = spectatee.ammo_plasma;
1657         this.ammo_shells = spectatee.ammo_shells;
1658         this.ammo_nails = spectatee.ammo_nails;
1659         this.ammo_rockets = spectatee.ammo_rockets;
1660         this.ammo_fuel = spectatee.ammo_fuel;
1661         this.clip_load = spectatee.clip_load;
1662         this.clip_size = spectatee.clip_size;
1663         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1664         this.health = spectatee.health;
1665         this.impulse = 0;
1666         this.items = spectatee.items;
1667         this.last_pickup = spectatee.last_pickup;
1668         this.hit_time = spectatee.hit_time;
1669         this.strength_finished = spectatee.strength_finished;
1670         this.invincible_finished = spectatee.invincible_finished;
1671         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1672         this.weapons = spectatee.weapons;
1673         this.vortex_charge = spectatee.vortex_charge;
1674         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1675         this.hagar_load = spectatee.hagar_load;
1676         this.arc_heat_percent = spectatee.arc_heat_percent;
1677         this.minelayer_mines = spectatee.minelayer_mines;
1678         this.punchangle = spectatee.punchangle;
1679         this.view_ofs = spectatee.view_ofs;
1680         this.velocity = spectatee.velocity;
1681         this.dmg_take = spectatee.dmg_take;
1682         this.dmg_save = spectatee.dmg_save;
1683         this.dmg_inflictor = spectatee.dmg_inflictor;
1684         this.v_angle = spectatee.v_angle;
1685         this.angles = spectatee.v_angle;
1686         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1687         this.revive_progress = spectatee.revive_progress;
1688         this.viewloc = spectatee.viewloc;
1689         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1690                 this.fixangle = true;
1691         setorigin(this, spectatee.origin);
1692         setsize(this, spectatee.mins, spectatee.maxs);
1693         SetZoomState(this, spectatee.zoomstate);
1694
1695     anticheat_spectatecopy(this, spectatee);
1696         this.hud = spectatee.hud;
1697         if(spectatee.vehicle)
1698     {
1699         this.angles = spectatee.v_angle;
1700
1701         //this.fixangle = false;
1702         //this.velocity = spectatee.vehicle.velocity;
1703         this.vehicle_health = spectatee.vehicle_health;
1704         this.vehicle_shield = spectatee.vehicle_shield;
1705         this.vehicle_energy = spectatee.vehicle_energy;
1706         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1707         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1708         this.vehicle_reload1 = spectatee.vehicle_reload1;
1709         this.vehicle_reload2 = spectatee.vehicle_reload2;
1710
1711         //msg_entity = this;
1712
1713        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1714             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1715            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1716            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1717
1718         //WriteByte (MSG_ONE, SVC_SETVIEW);
1719         //    WriteEntity(MSG_ONE, this);
1720         //makevectors(spectatee.v_angle);
1721         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1722     }
1723 }
1724
1725 bool SpectateUpdate(entity this)
1726 {
1727         if(!this.enemy)
1728                 return false;
1729
1730         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1731         {
1732                 SetSpectatee(this, NULL);
1733                 return false;
1734         }
1735
1736         SpectateCopy(this, this.enemy);
1737
1738         return true;
1739 }
1740
1741 bool SpectateSet(entity this)
1742 {
1743         if(!IS_PLAYER(this.enemy))
1744                 return false;
1745
1746         ClientData_Touch(this.enemy);
1747
1748         msg_entity = this;
1749         WriteByte(MSG_ONE, SVC_SETVIEW);
1750         WriteEntity(MSG_ONE, this.enemy);
1751         set_movetype(this, MOVETYPE_NONE);
1752         accuracy_resend(this);
1753
1754         if(!SpectateUpdate(this))
1755                 PutObserverInServer(this);
1756
1757         return true;
1758 }
1759
1760 void SetSpectatee_status(entity this, int spectatee_num)
1761 {
1762         int oldspectatee_status = this.spectatee_status;
1763         this.spectatee_status = spectatee_num;
1764
1765         if (this.spectatee_status != oldspectatee_status)
1766         {
1767                 ClientData_Touch(this);
1768                 if (g_race || g_cts) race_InitSpectator();
1769         }
1770 }
1771
1772 void SetSpectatee(entity this, entity spectatee)
1773 {
1774         entity old_spectatee = this.enemy;
1775
1776         this.enemy = spectatee;
1777
1778         // WEAPONTODO
1779         // these are required to fix the spectator bug with arc
1780         if(old_spectatee)
1781         {
1782                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1783                 {
1784                         .entity weaponentity = weaponentities[slot];
1785                         if(old_spectatee.(weaponentity).arc_beam)
1786                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1787                 }
1788         }
1789         if(this.enemy)
1790         {
1791                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1792                 {
1793                         .entity weaponentity = weaponentities[slot];
1794                         if(this.enemy.(weaponentity).arc_beam)
1795                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1796                 }
1797         }
1798
1799         if (this.enemy)
1800                 SetSpectatee_status(this, etof(this.enemy));
1801
1802         // needed to update spectator list
1803         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1804 }
1805
1806 bool Spectate(entity this, entity pl)
1807 {
1808         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1809                 return false;
1810         pl = M_ARGV(1, entity);
1811
1812         SetSpectatee(this, pl);
1813         return SpectateSet(this);
1814 }
1815
1816 bool SpectateNext(entity this)
1817 {
1818         entity ent = find(this.enemy, classname, STR_PLAYER);
1819
1820         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1821                 ent = M_ARGV(1, entity);
1822         else if (!ent)
1823                 ent = find(ent, classname, STR_PLAYER);
1824
1825         if(ent) { SetSpectatee(this, ent); }
1826
1827         return SpectateSet(this);
1828 }
1829
1830 bool SpectatePrev(entity this)
1831 {
1832         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1833         entity ent = findchain(classname, STR_PLAYER);
1834         if (!ent) // no player
1835                 return false;
1836
1837         entity first = ent;
1838         // skip players until current spectated player
1839         if(this.enemy)
1840         while(ent && ent != this.enemy)
1841                 ent = ent.chain;
1842
1843         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1844         {
1845                 case MUT_SPECPREV_FOUND:
1846                     ent = M_ARGV(1, entity);
1847                     break;
1848                 case MUT_SPECPREV_RETURN:
1849                     return true;
1850                 case MUT_SPECPREV_CONTINUE:
1851                 default:
1852                 {
1853                         if(ent.chain)
1854                                 ent = ent.chain;
1855                         else
1856                                 ent = first;
1857                         break;
1858                 }
1859         }
1860
1861         SetSpectatee(this, ent);
1862         return SpectateSet(this);
1863 }
1864
1865 /*
1866 =============
1867 ShowRespawnCountdown()
1868
1869 Update a respawn countdown display.
1870 =============
1871 */
1872 void ShowRespawnCountdown(entity this)
1873 {
1874         float number;
1875         if(!IS_DEAD(this)) // just respawned?
1876                 return;
1877         else
1878         {
1879                 number = ceil(this.respawn_time - time);
1880                 if(number <= 0)
1881                         return;
1882                 if(number <= this.respawn_countdown)
1883                 {
1884                         this.respawn_countdown = number - 1;
1885                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1886                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1887                 }
1888         }
1889 }
1890
1891 .bool team_selected;
1892 bool ShowTeamSelection(entity this)
1893 {
1894         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1895                 return false;
1896         stuffcmd(this, "menu_showteamselect\n");
1897         return true;
1898 }
1899 void Join(entity this)
1900 {
1901         TRANSMUTE(Player, this);
1902
1903         if(!this.team_selected)
1904         if(autocvar_g_campaign || autocvar_g_balance_teams)
1905                 JoinBestTeam(this, false, true);
1906
1907         if(autocvar_g_campaign)
1908                 campaign_bots_may_start = true;
1909
1910         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1911
1912         PutClientInServer(this);
1913
1914         if(teamplay && this.team != -1)
1915                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1916         else
1917                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1918         this.team_selected = false;
1919 }
1920
1921 /**
1922  * Determines whether the player is allowed to join. This depends on cvar
1923  * g_maxplayers, if it isn't used this function always return true, otherwise
1924  * it checks whether the number of currently playing players exceeds g_maxplayers.
1925  * @return int number of free slots for players, 0 if none
1926  */
1927 int nJoinAllowed(entity this, entity ignore)
1928 {
1929         if(!ignore)
1930         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1931         // so report 0 free slots if restricted
1932         {
1933                 if(autocvar_g_forced_team_otherwise == "spectate")
1934                         return 0;
1935                 if(autocvar_g_forced_team_otherwise == "spectator")
1936                         return 0;
1937         }
1938
1939         if(this && this.team_forced < 0)
1940                 return 0; // forced spectators can never join
1941
1942         // TODO simplify this
1943         int totalClients = 0;
1944         int currentlyPlaying = 0;
1945         FOREACH_CLIENT(true, LAMBDA(
1946                 if(it != ignore)
1947                         ++totalClients;
1948                 if(IS_REAL_CLIENT(it))
1949                 if(IS_PLAYER(it) || it.caplayer)
1950                         ++currentlyPlaying;
1951         ));
1952
1953         float free_slots = 0;
1954         if (!autocvar_g_maxplayers)
1955                 free_slots = maxclients - totalClients;
1956         else if(currentlyPlaying < autocvar_g_maxplayers)
1957                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1958
1959         static float join_prevent_msg_time = 0;
1960         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1961         {
1962                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1963                 join_prevent_msg_time = time + 3;
1964         }
1965
1966         return free_slots;
1967 }
1968
1969 /**
1970  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1971  * g_maxplayers_spectator_blocktime seconds
1972  */
1973 void checkSpectatorBlock(entity this)
1974 {
1975         if(IS_SPEC(this) || IS_OBSERVER(this))
1976         if(!this.caplayer)
1977         if(IS_REAL_CLIENT(this))
1978         {
1979                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1980                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1981                         dropclient(this);
1982                 }
1983         }
1984 }
1985
1986 void PrintWelcomeMessage(entity this)
1987 {
1988         if(this.motd_actived_time == 0)
1989         {
1990                 if (autocvar_g_campaign) {
1991                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1992                                 this.motd_actived_time = time;
1993                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1994                         }
1995                 } else {
1996                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1997                                 this.motd_actived_time = time;
1998                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1999                         }
2000                 }
2001         }
2002         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2003         {
2004                 if (autocvar_g_campaign) {
2005                         if (PHYS_INPUT_BUTTON_INFO(this))
2006                                 this.motd_actived_time = time;
2007                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2008                                 this.motd_actived_time = 0;
2009                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2010                         }
2011                 } else {
2012                         if (PHYS_INPUT_BUTTON_INFO(this))
2013                                 this.motd_actived_time = time;
2014                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2015                                 this.motd_actived_time = 0;
2016                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2017                         }
2018                 }
2019         }
2020         else //if(this.motd_actived_time < 0) // just connected, motd is active
2021         {
2022                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2023                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2024                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2025                 {
2026                         // instanctly hide MOTD
2027                         this.motd_actived_time = 0;
2028                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2029                 }
2030         }
2031 }
2032
2033 bool joinAllowed(entity this)
2034 {
2035         if (this.version_mismatch) return false;
2036         if (!nJoinAllowed(this, this)) return false;
2037         if (teamplay && lockteams) return false;
2038         if (ShowTeamSelection(this)) return false;
2039         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2040         return true;
2041 }
2042
2043 void ObserverThink(entity this)
2044 {
2045         if ( this.impulse )
2046         {
2047                 MinigameImpulse(this, this.impulse);
2048                 this.impulse = 0;
2049         }
2050
2051         if (this.flags & FL_JUMPRELEASED) {
2052                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2053                         this.flags &= ~FL_JUMPRELEASED;
2054                         this.flags |= FL_SPAWNING;
2055                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2056                         this.flags &= ~FL_JUMPRELEASED;
2057                         if(SpectateNext(this)) {
2058                                 TRANSMUTE(Spectator, this);
2059                         }
2060                 } else {
2061                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2062                         set_movetype(this, preferred_movetype);
2063                 }
2064         } else {
2065                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2066                         this.flags |= FL_JUMPRELEASED;
2067                         if(this.flags & FL_SPAWNING)
2068                         {
2069                                 this.flags &= ~FL_SPAWNING;
2070                                 Join(this);
2071                                 return;
2072                         }
2073                 }
2074         }
2075 }
2076
2077 void SpectatorThink(entity this)
2078 {
2079         if ( this.impulse )
2080         {
2081                 if(MinigameImpulse(this, this.impulse))
2082                         this.impulse = 0;
2083
2084                 if (this.impulse == IMP_weapon_drop.impulse)
2085                 {
2086                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2087                         this.impulse = 0;
2088                         return;
2089                 }
2090         }
2091
2092         if (this.flags & FL_JUMPRELEASED) {
2093                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2094                         this.flags &= ~FL_JUMPRELEASED;
2095                         this.flags |= FL_SPAWNING;
2096                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2097                         this.flags &= ~FL_JUMPRELEASED;
2098                         if(SpectateNext(this)) {
2099                                 TRANSMUTE(Spectator, this);
2100                         } else {
2101                                 TRANSMUTE(Observer, this);
2102                                 PutClientInServer(this);
2103                         }
2104                         this.impulse = 0;
2105                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2106                         this.flags &= ~FL_JUMPRELEASED;
2107                         if(SpectatePrev(this)) {
2108                                 TRANSMUTE(Spectator, this);
2109                         } else {
2110                                 TRANSMUTE(Observer, this);
2111                                 PutClientInServer(this);
2112                         }
2113                         this.impulse = 0;
2114                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2115                         this.flags &= ~FL_JUMPRELEASED;
2116                         TRANSMUTE(Observer, this);
2117                         PutClientInServer(this);
2118                 } else {
2119                         if(!SpectateUpdate(this))
2120                                 PutObserverInServer(this);
2121                 }
2122         } else {
2123                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2124                         this.flags |= FL_JUMPRELEASED;
2125                         if(this.flags & FL_SPAWNING)
2126                         {
2127                                 this.flags &= ~FL_SPAWNING;
2128                                 Join(this);
2129                                 return;
2130                         }
2131                 }
2132                 if(!SpectateUpdate(this))
2133                         PutObserverInServer(this);
2134         }
2135
2136         this.flags |= FL_CLIENT | FL_NOTARGET;
2137 }
2138
2139 void vehicles_enter (entity pl, entity veh);
2140 void PlayerUseKey(entity this)
2141 {
2142         if (!IS_PLAYER(this))
2143                 return;
2144
2145         if(this.vehicle)
2146         {
2147                 if(!gameover)
2148                 {
2149                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2150                         return;
2151                 }
2152         }
2153         else if(autocvar_g_vehicles_enter)
2154         {
2155                 if(!STAT(FROZEN, this))
2156                 if(!IS_DEAD(this))
2157                 if(!gameover)
2158                 {
2159                         entity head, closest_target = NULL;
2160                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2161
2162                         while(head) // find the closest acceptable target to enter
2163                         {
2164                                 if(IS_VEHICLE(head))
2165                                 if(!IS_DEAD(head))
2166                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2167                                 if(head.takedamage != DAMAGE_NO)
2168                                 {
2169                                         if(closest_target)
2170                                         {
2171                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2172                                                 { closest_target = head; }
2173                                         }
2174                                         else { closest_target = head; }
2175                                 }
2176
2177                                 head = head.chain;
2178                         }
2179
2180                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2181                 }
2182         }
2183
2184         // a use key was pressed; call handlers
2185         MUTATOR_CALLHOOK(PlayerUseKey, this);
2186 }
2187
2188
2189 /*
2190 =============
2191 PlayerPreThink
2192
2193 Called every frame for each client before the physics are run
2194 =============
2195 */
2196 .float usekeypressed;
2197 .float last_vehiclecheck;
2198 .int items_added;
2199 void PlayerPreThink (entity this)
2200 {
2201         WarpZone_PlayerPhysics_FixVAngle(this);
2202
2203     STAT(GAMESTARTTIME, this) = game_starttime;
2204         STAT(ROUNDSTARTTIME, this) = round_starttime;
2205         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2206         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2207
2208         STAT(WEAPONSINMAP, this) = weaponsInMap;
2209
2210         if (frametime) {
2211                 // physics frames: update anticheat stuff
2212                 anticheat_prethink(this);
2213         }
2214
2215         if (blockSpectators && frametime) {
2216                 // WORKAROUND: only use dropclient in server frames (frametime set).
2217                 // Never use it in cl_movement frames (frametime zero).
2218                 checkSpectatorBlock(this);
2219     }
2220
2221         zoomstate_set = false;
2222
2223         // Check for nameless players
2224         if (isInvisibleString(this.netname)) {
2225                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2226                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2227         }
2228         if (this.netname != this.netname_previous) {
2229                 if (autocvar_sv_eventlog) {
2230                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2231         }
2232                 if (this.netname_previous) strunzone(this.netname_previous);
2233                 this.netname_previous = strzone(this.netname);
2234         }
2235
2236         // version nagging
2237         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2238         this.version_nagtime = 0;
2239         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2240             // git client
2241         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2242             // git server
2243             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2244         } else {
2245             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2246             if (r < 0) { // old client
2247                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2248             } else if (r > 0) { // old server
2249                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2250             }
2251         }
2252     }
2253
2254         // GOD MODE info
2255         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2256         {
2257                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2258                 this.max_armorvalue = 0;
2259         }
2260
2261         if (STAT(FROZEN, this) == 2)
2262         {
2263                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2264                 this.health = max(1, this.revive_progress * start_health);
2265                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2266
2267                 if (this.revive_progress >= 1)
2268                         Unfreeze(this);
2269         }
2270         else if (STAT(FROZEN, this) == 3)
2271         {
2272                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2273                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2274
2275                 if (this.health < 1)
2276                 {
2277                         if (this.vehicle)
2278                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2279                         if(this.event_damage)
2280                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2281                 }
2282                 else if (this.revive_progress <= 0)
2283                         Unfreeze(this);
2284         }
2285
2286         MUTATOR_CALLHOOK(PlayerPreThink, this);
2287
2288         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2289         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2290         {
2291                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2292                 {
2293                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2294                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2295                         {
2296                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2297                         }
2298                         else if(!it.owner)
2299                         {
2300                                 if(!it.team || SAME_TEAM(this, it))
2301                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2302                                 else if(autocvar_g_vehicles_steal)
2303                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2304                         }
2305                 });
2306
2307                 this.last_vehiclecheck = time + 1;
2308         }
2309
2310         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2311         {
2312                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2313                         PlayerUseKey(this);
2314                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2315         }
2316
2317         if (IS_REAL_CLIENT(this))
2318                 PrintWelcomeMessage(this);
2319
2320         if (IS_PLAYER(this)) {
2321                 CheckRules_Player(this);
2322
2323                 if (gameover || intermission_running) {
2324                         if(intermission_running)
2325                                 IntermissionThink(this);
2326                         return;
2327                 }
2328
2329                 if (timeout_status == TIMEOUT_ACTIVE) {
2330             // don't allow the player to turn around while game is paused
2331                         // FIXME turn this into CSQC stuff
2332                         this.v_angle = this.lastV_angle;
2333                         this.angles = this.lastV_angle;
2334                         this.fixangle = true;
2335                 }
2336
2337                 if (frametime) player_powerups(this);
2338
2339                 if (IS_DEAD(this)) {
2340                         if (this.personal && g_race_qualifying) {
2341                                 if (time > this.respawn_time) {
2342                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2343                                         respawn(this);
2344                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2345                                 }
2346                         } else {
2347                                 if (frametime) player_anim(this);
2348                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2349
2350                                 switch(this.deadflag)
2351                                 {
2352                                         case DEAD_DYING:
2353                                         {
2354                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2355                                                         this.deadflag = DEAD_RESPAWNING;
2356                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2357                                                         this.deadflag = DEAD_DEAD;
2358                                                 break;
2359                                         }
2360                                         case DEAD_DEAD:
2361                                         {
2362                                                 if (button_pressed)
2363                                                         this.deadflag = DEAD_RESPAWNABLE;
2364                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2365                                                         this.deadflag = DEAD_RESPAWNING;
2366                                                 break;
2367                                         }
2368                                         case DEAD_RESPAWNABLE:
2369                                         {
2370                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2371                                                         this.deadflag = DEAD_RESPAWNING;
2372                                                 break;
2373                                         }
2374                                         case DEAD_RESPAWNING:
2375                                         {
2376                                                 if (time > this.respawn_time)
2377                                                 {
2378                                                         this.respawn_time = time + 1; // only retry once a second
2379                                                         this.respawn_time_max = this.respawn_time;
2380                                                         respawn(this);
2381                                                 }
2382                                                 break;
2383                                         }
2384                                 }
2385
2386                                 ShowRespawnCountdown(this);
2387
2388                                 if (this.respawn_flags & RESPAWN_SILENT)
2389                                         STAT(RESPAWN_TIME, this) = 0;
2390                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2391                                 {
2392                                         if (time < this.respawn_time)
2393                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2394                                         else if (this.deadflag != DEAD_RESPAWNING)
2395                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2396                                 }
2397                                 else
2398                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2399                         }
2400
2401                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2402                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2403                                 STAT(RESPAWN_TIME, this) *= -1;
2404
2405                         return;
2406                 }
2407
2408                 this.prevorigin = this.origin;
2409
2410                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2411                 if (this.hook.state) {
2412                         do_crouch = false;
2413                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2414                         do_crouch = false;
2415                 } else if (this.vehicle) {
2416                         do_crouch = false;
2417                 } else if (STAT(FROZEN, this)) {
2418                         do_crouch = false;
2419         }
2420
2421                 if (do_crouch) {
2422                         if (!this.crouch) {
2423                                 this.crouch = true;
2424                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2425                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2426                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2427                         }
2428                 } else if (this.crouch) {
2429             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2430             if (!trace_startsolid) {
2431                 this.crouch = false;
2432                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2433                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2434             }
2435                 }
2436
2437                 FixPlayermodel(this);
2438
2439                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2440                 //if(frametime)
2441                 {
2442                         this.items &= ~this.items_added;
2443
2444                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2445                         //{
2446                                 //.entity weaponentity = weaponentities[slot];
2447                                 //W_WeaponFrame(this, weaponentity);
2448                         //}
2449                         .entity weaponentity = weaponentities[0]; // TODO
2450                         W_WeaponFrame(this, weaponentity);
2451
2452                         this.items_added = 0;
2453                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2454                 this.items_added |= IT_FUEL;
2455
2456                         this.items |= this.items_added;
2457                 }
2458
2459                 player_regen(this);
2460
2461                 // WEAPONTODO: Add a weapon request for this
2462                 // rot vortex charge to the charge limit
2463                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2464                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2465
2466                 if (frametime) player_anim(this);
2467
2468                 // secret status
2469                 secrets_setstatus(this);
2470
2471                 // monsters status
2472                 monsters_setstatus(this);
2473
2474                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2475         }
2476         else if (gameover || intermission_running) {
2477                 if(intermission_running)
2478                         IntermissionThink(this);
2479                 return;
2480         }
2481         else if (IS_OBSERVER(this)) {
2482                 ObserverThink(this);
2483         }
2484         else if (IS_SPEC(this)) {
2485                 SpectatorThink(this);
2486         }
2487
2488         // WEAPONTODO: Add weapon request for this
2489         if (!zoomstate_set) {
2490                 SetZoomState(this,
2491                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2492                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2493                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2494                 );
2495     }
2496
2497         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2498         {
2499                 this.teamkill_soundtime = 0;
2500
2501                 entity e = this.teamkill_soundsource;
2502                 entity oldpusher = e.pusher;
2503                 e.pusher = this;
2504                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2505                 e.pusher = oldpusher;
2506         }
2507
2508         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2509                 this.taunt_soundtime = 0;
2510                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2511         }
2512
2513         target_voicescript_next(this);
2514
2515         // WEAPONTODO: Move into weaponsystem somehow
2516         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2517         if (PS(this).m_weapon == WEP_Null)
2518                 this.clip_load = this.clip_size = 0;
2519 }
2520
2521 void DrownPlayer(entity this)
2522 {
2523         if(IS_DEAD(this))
2524                 return;
2525
2526         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2527         {
2528                 if(this.air_finished < time)
2529                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2530                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2531                 this.dmg = 2;
2532         }
2533         else if (this.air_finished < time)
2534         {       // drown!
2535                 if (this.pain_finished < time)
2536                 {
2537                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2538                         this.pain_finished = time + 0.5;
2539                 }
2540         }
2541 }
2542
2543 .bool move_qcphysics;
2544
2545 void Player_Physics(entity this)
2546 {
2547         set_movetype(this, this.move_movetype);
2548
2549         if(!this.move_qcphysics)
2550                 return;
2551
2552         if(!frametime && !this.pm_frametime)
2553                 return;
2554
2555         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2556
2557         this.pm_frametime = 0;
2558 }
2559
2560 /*
2561 =============
2562 PlayerPostThink
2563
2564 Called every frame for each client after the physics are run
2565 =============
2566 */
2567 .float idlekick_lasttimeleft;
2568 void PlayerPostThink (entity this)
2569 {
2570         Player_Physics(this);
2571
2572         if (sv_maxidle > 0)
2573         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2574         if (IS_REAL_CLIENT(this))
2575         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2576         {
2577                 int totalClients = 0;
2578                 if(sv_maxidle_slots > 0)
2579                 {
2580                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2581                         {
2582                                 ++totalClients;
2583                         });
2584                 }
2585
2586                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2587                 { /* do nothing */ }
2588                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2589                 {
2590                         if (this.idlekick_lasttimeleft)
2591                         {
2592                                 this.idlekick_lasttimeleft = 0;
2593                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2594                         }
2595                 }
2596                 else
2597                 {
2598                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2599                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2600                                 if (!this.idlekick_lasttimeleft)
2601                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2602                         }
2603                         if (timeleft <= 0) {
2604                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2605                                 dropclient(this);
2606                                 return;
2607                         }
2608                         else if (timeleft <= 10) {
2609                                 if (timeleft != this.idlekick_lasttimeleft) {
2610                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2611                 }
2612                                 this.idlekick_lasttimeleft = timeleft;
2613                         }
2614                 }
2615         }
2616
2617         CheatFrame(this);
2618
2619         //CheckPlayerJump();
2620         if (gameover)
2621         {
2622                 this.solid = SOLID_NOT;
2623                 this.takedamage = DAMAGE_NO;
2624                 set_movetype(this, MOVETYPE_NONE);
2625         }
2626
2627         if (IS_PLAYER(this)) {
2628                 DrownPlayer(this);
2629                 CheckRules_Player(this);
2630                 UpdateChatBubble(this);
2631                 if (this.impulse) ImpulseCommands(this);
2632                 if (gameover)
2633                 {
2634                         CSQCMODEL_AUTOUPDATE(this);
2635                         return;
2636                 }
2637                 GetPressedKeys(this);
2638         }
2639
2640         if (this.waypointsprite_attachedforcarrier) {
2641             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2642                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2643     }
2644
2645         playerdemo_write(this);
2646
2647         CSQCMODEL_AUTOUPDATE(this);
2648 }