qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24 #include "scores_rules.qh"
  25
  26 #include "bot/api.qh"
  27
  28 #include "../common/ent_cs.qh"
  29 #include "../common/wepent.qh"
  30 #include <common/state.qh>
  31
  32 #include <common/effects/qc/globalsound.qh>
  33
  34 #include "../common/triggers/func/conveyor.qh"
  35 #include "../common/triggers/teleporters.qh"
  36
  37 #include "../common/vehicles/all.qh"
  38
  39 #include "weapons/hitplot.qh"
  40 #include "weapons/weaponsystem.qh"
  41
  42 #include "../common/net_notice.qh"
  43 #include "../common/net_linked.qh"
  44 #include "../common/physics/player.qh"
  45
  46 #include "../common/items/_mod.qh"
  47
  48 #include "../common/mutators/mutator/waypoints/all.qh"
  49
  50 #include "../common/triggers/subs.qh"
  51 #include "../common/triggers/triggers.qh"
  52 #include "../common/triggers/trigger/secret.qh"
  53
  54 #include "../common/minigames/sv_minigames.qh"
  55
  56 #include "../common/items/inventory.qh"
  57
  58 #include "../common/monsters/sv_monsters.qh"
  59
  60 #include "../lib/warpzone/server.qh"
  61
  62 STATIC_METHOD(Client, Add, void(Client this, int _team))
  63 {
  64     ClientConnect(this);
  65     TRANSMUTE(Player, this);
  66     this.frame = 12; // 7
  67     this.team = _team;
  68     PutClientInServer(this);
  69 }
  70
  71 void PutObserverInServer(entity this);
  72
  73 STATIC_METHOD(Client, Remove, void(Client this))
  74 {
  75     TRANSMUTE(Observer, this);
  76     PutClientInServer(this);
  77     ClientDisconnect(this);
  78 }
  79
  80 void send_CSQC_teamnagger() {
  81         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  82 }
  83
  84 int CountSpectators(entity player, entity to)
  85 {
  86         if(!player) { return 0; } // not sure how, but best to be safe
  87
  88         int spec_count = 0;
  89
  90         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  91         {
  92                 spec_count++;
  93         });
  94
  95         return spec_count;
  96 }
  97
  98 void WriteSpectators(entity player, entity to)
  99 {
 100         if(!player) { return; } // not sure how, but best to be safe
 101
 102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 103         {
 104                 WriteByte(MSG_ENTITY, num_for_edict(it));
 105         });
 106 }
 107
 108 bool ClientData_Send(entity this, entity to, int sf)
 109 {
 110         assert(to == this.owner, return false);
 111
 112         entity e = to;
 113         if (IS_SPEC(e)) e = e.enemy;
 114
 115         sf = 0;
 116         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 117         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 118         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 119         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 120
 121         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 122         WriteByte(MSG_ENTITY, sf);
 123
 124         if (sf & BIT(1))
 125                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 126
 127         if(sf & BIT(4))
 128         {
 129                 float specs = CountSpectators(e, to);
 130                 WriteByte(MSG_ENTITY, specs);
 131                 WriteSpectators(e, to);
 132         }
 133
 134         return true;
 135 }
 136
 137 void ClientData_Attach(entity this)
 138 {
 139         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 140         CS(this).clientdata.drawonlytoclient = this;
 141         CS(this).clientdata.owner = this;
 142 }
 143
 144 void ClientData_Detach(entity this)
 145 {
 146         delete(CS(this).clientdata);
 147         CS(this).clientdata = NULL;
 148 }
 149
 150 void ClientData_Touch(entity e)
 151 {
 152         CS(e).clientdata.SendFlags = 1;
 153
 154         // make it spectatable
 155         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 156 }
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = vec2(spot.angles);
 230         this.fixangle = true;
 231         // offset it so that the spectator spawns higher off the ground, looks better this way
 232         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 233         if (IS_REAL_CLIENT(this))
 234         {
 235             msg_entity = this;
 236             WriteByte(MSG_ONE, SVC_SETVIEW);
 237             WriteEntity(MSG_ONE, this);
 238         }
 239         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 240         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 241         if(!autocvar_g_debug_globalsounds)
 242         {
 243                 // needed for player sounds
 244                 this.model = "";
 245                 FixPlayermodel(this);
 246         }
 247         setmodel(this, MDL_Null);
 248         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 249         this.view_ofs = '0 0 0';
 250     }
 251
 252     RemoveGrapplingHooks(this);
 253         Portal_ClearAll(this);
 254         Unfreeze(this);
 255         SetSpectatee(this, NULL);
 256
 257         if (this.alivetime)
 258         {
 259                 if (!warmup_stage)
 260                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 261                 this.alivetime = 0;
 262         }
 263
 264         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 265
 266         WaypointSprite_PlayerDead(this);
 267
 268         if (mutator_returnvalue) {
 269             // mutator prevents resetting teams+score
 270         } else {
 271                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 272         this.frags = FRAGS_SPECTATOR;
 273         PlayerScore_Clear(this);  // clear scores when needed
 274     }
 275
 276         if (CS(this).killcount != FRAGS_SPECTATOR)
 277         {
 278                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 279                 if(!game_stopped)
 280                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 281                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 282
 283                 if(!CS(this).just_joined)
 284                         LogTeamchange(this.playerid, -1, 4);
 285                 else
 286                         CS(this).just_joined = false;
 287         }
 288
 289         accuracy_resend(this);
 290
 291         CS(this).spectatortime = time;
 292         if(this.bot_attack)
 293                 IL_REMOVE(g_bot_targets, this);
 294         this.bot_attack = false;
 295     this.hud = HUD_NORMAL;
 296         TRANSMUTE(Observer, this);
 297         this.iscreature = false;
 298         this.teleportable = TELEPORT_SIMPLE;
 299         if(this.damagedbycontents)
 300                 IL_REMOVE(g_damagedbycontents, this);
 301         this.damagedbycontents = false;
 302         this.health = FRAGS_SPECTATOR;
 303         SetSpectatee_status(this, etof(this));
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.deadflag = DEAD_NO;
 332         this.crouch = false;
 333         this.revive_progress = 0;
 334         this.revival_time = 0;
 335
 336         this.items = 0;
 337         this.weapons = '0 0 0';
 338         this.drawonlytoclient = this;
 339
 340         this.weaponmodel = "";
 341         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 342         {
 343                 this.weaponentities[slot] = NULL;
 344         }
 345         this.exteriorweaponentity = NULL;
 346         CS(this).killcount = FRAGS_SPECTATOR;
 347         this.velocity = '0 0 0';
 348         this.avelocity = '0 0 0';
 349         this.punchangle = '0 0 0';
 350         this.punchvector = '0 0 0';
 351         this.oldvelocity = this.velocity;
 352         this.fire_endtime = -1;
 353         this.event_damage = func_null;
 354
 355         for(int slot = 0; slot < MAX_AXH; ++slot)
 356         {
 357                 entity axh = this.(AuxiliaryXhair[slot]);
 358                 this.(AuxiliaryXhair[slot]) = NULL;
 359
 360                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 361                         delete(axh);
 362         }
 363 }
 364
 365 int player_getspecies(entity this)
 366 {
 367         get_model_parameters(this.model, this.skin);
 368         int s = get_model_parameters_species;
 369         get_model_parameters(string_null, 0);
 370         if (s < 0) return SPECIES_HUMAN;
 371         return s;
 372 }
 373
 374 .float model_randomizer;
 375 void FixPlayermodel(entity player)
 376 {
 377         string defaultmodel = "";
 378         int defaultskin = 0;
 379         if(autocvar_sv_defaultcharacter)
 380         {
 381                 if(teamplay)
 382                 {
 383                         switch(player.team)
 384                         {
 385                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 386                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 387                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 388                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 389                         }
 390                 }
 391
 392                 if(defaultmodel == "")
 393                 {
 394                         defaultmodel = autocvar_sv_defaultplayermodel;
 395                         defaultskin = autocvar_sv_defaultplayerskin;
 396                 }
 397
 398                 int n = tokenize_console(defaultmodel);
 399                 if(n > 0)
 400                 {
 401                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 402                         // However, do NOT randomize if the player-selected model is in the list.
 403                         for (int i = 0; i < n; ++i)
 404                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 405                                         defaultmodel = argv(i);
 406                 }
 407
 408                 int i = strstrofs(defaultmodel, ":", 0);
 409                 if(i >= 0)
 410                 {
 411                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 412                         defaultmodel = substring(defaultmodel, 0, i);
 413                 }
 414         }
 415         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(!defaultskin)
 429                         defaultskin = autocvar_sv_defaultplayerskin;
 430         }
 431
 432         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 433         defaultmodel = M_ARGV(0, string);
 434         defaultskin = M_ARGV(1, int);
 435
 436         bool chmdl = false;
 437         int oldskin;
 438         if(defaultmodel != "")
 439         {
 440                 if (defaultmodel != player.model)
 441                 {
 442                         vector m1 = player.mins;
 443                         vector m2 = player.maxs;
 444                         setplayermodel (player, defaultmodel);
 445                         setsize (player, m1, m2);
 446                         chmdl = true;
 447                 }
 448
 449                 oldskin = player.skin;
 450                 player.skin = defaultskin;
 451         } else {
 452                 if (player.playermodel != player.model || player.playermodel == "")
 453                 {
 454                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 455                         vector m1 = player.mins;
 456                         vector m2 = player.maxs;
 457                         setplayermodel (player, player.playermodel);
 458                         setsize (player, m1, m2);
 459                         chmdl = true;
 460                 }
 461
 462                 if(!autocvar_sv_defaultcharacterskin)
 463                 {
 464                         oldskin = player.skin;
 465                         player.skin = stof(player.playerskin);
 466                 }
 467                 else
 468                 {
 469                         oldskin = player.skin;
 470                         player.skin = defaultskin;
 471                 }
 472         }
 473
 474         if(chmdl || oldskin != player.skin) // model or skin has changed
 475         {
 476                 player.species = player_getspecies(player); // update species
 477                 if(!autocvar_g_debug_globalsounds)
 478                         UpdatePlayerSounds(player); // update skin sounds
 479         }
 480
 481         if(!teamplay)
 482                 if(strlen(autocvar_sv_defaultplayercolors))
 483                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 484                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 485 }
 486
 487 void PutPlayerInServer(entity this)
 488 {
 489         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 490
 491         PlayerState_attach(this);
 492         accuracy_resend(this);
 493
 494         if (this.team < 0)
 495                 JoinBestTeam(this, false, true);
 496
 497         entity spot = SelectSpawnPoint(this, false);
 498         if (!spot) {
 499                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 500                 return; // spawn failed
 501         }
 502
 503         TRANSMUTE(Player, this);
 504
 505         CS(this).wasplayer = true;
 506         this.iscreature = true;
 507         this.teleportable = TELEPORT_NORMAL;
 508         if(!this.damagedbycontents)
 509                 IL_PUSH(g_damagedbycontents, this);
 510         this.damagedbycontents = true;
 511         set_movetype(this, MOVETYPE_WALK);
 512         this.solid = SOLID_SLIDEBOX;
 513         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 514         if (autocvar_g_playerclip_collisions)
 515                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 516         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 517                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 518         this.frags = FRAGS_PLAYER;
 519         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 520         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 521         if (autocvar__notarget)
 522                 this.flags |= FL_NOTARGET;
 523         this.takedamage = DAMAGE_AIM;
 524         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 525         this.dmg = 2; // WTF
 526
 527         if (warmup_stage) {
 528                 this.ammo_shells = warmup_start_ammo_shells;
 529                 this.ammo_nails = warmup_start_ammo_nails;
 530                 this.ammo_rockets = warmup_start_ammo_rockets;
 531                 this.ammo_cells = warmup_start_ammo_cells;
 532                 this.ammo_plasma = warmup_start_ammo_plasma;
 533                 this.ammo_fuel = warmup_start_ammo_fuel;
 534                 this.health = warmup_start_health;
 535                 this.armorvalue = warmup_start_armorvalue;
 536                 this.weapons = WARMUP_START_WEAPONS;
 537         } else {
 538                 this.ammo_shells = start_ammo_shells;
 539                 this.ammo_nails = start_ammo_nails;
 540                 this.ammo_rockets = start_ammo_rockets;
 541                 this.ammo_cells = start_ammo_cells;
 542                 this.ammo_plasma = start_ammo_plasma;
 543                 this.ammo_fuel = start_ammo_fuel;
 544                 this.health = start_health;
 545                 this.armorvalue = start_armorvalue;
 546                 this.weapons = start_weapons;
 547         }
 548         SetSpectatee_status(this, 0);
 549
 550         PS(this).dual_weapons = '0 0 0';
 551
 552         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 553
 554         this.items = start_items;
 555
 556         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 557         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 558         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 559         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 560         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 561         // extend the pause of rotting if client was reset at the beginning of the countdown
 562         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 563                 float f = game_starttime - time;
 564                 this.spawnshieldtime += f;
 565                 this.pauserotarmor_finished += f;
 566                 this.pauserothealth_finished += f;
 567                 this.pauseregen_finished += f;
 568         }
 569         this.damageforcescale = 2;
 570         this.death_time = 0;
 571         this.respawn_flags = 0;
 572         this.respawn_time = 0;
 573         this.stat_respawn_time = 0;
 574         this.scale = autocvar_sv_player_scale;
 575         this.fade_time = 0;
 576         this.pain_frame = 0;
 577         this.pain_finished = 0;
 578         this.pushltime = 0;
 579         setthink(this, func_null); // players have no think function
 580         this.nextthink = 0;
 581         this.dmg_team = 0;
 582         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 583
 584         this.deadflag = DEAD_NO;
 585
 586         this.angles = spot.angles;
 587         this.angles_z = 0; // never spawn tilted even if the spot says to
 588         if (IS_BOT_CLIENT(this))
 589                 this.v_angle = this.angles;
 590         this.fixangle = true; // turn this way immediately
 591         this.oldvelocity = this.velocity = '0 0 0';
 592         this.avelocity = '0 0 0';
 593         this.punchangle = '0 0 0';
 594         this.punchvector = '0 0 0';
 595
 596         this.strength_finished = 0;
 597         this.invincible_finished = 0;
 598         this.fire_endtime = -1;
 599         this.revive_progress = 0;
 600         this.revival_time = 0;
 601         this.air_finished = time + 12;
 602
 603         entity spawnevent = new_pure(spawnevent);
 604         spawnevent.owner = this;
 605         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 606
 607         // Cut off any still running player sounds.
 608         stopsound(this, CH_PLAYER_SINGLE);
 609
 610         this.model = "";
 611         FixPlayermodel(this);
 612         this.drawonlytoclient = NULL;
 613
 614         this.viewloc = NULL;
 615
 616         this.crouch = false;
 617         this.view_ofs = STAT(PL_VIEW_OFS, this);
 618         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 619         this.spawnorigin = spot.origin;
 620         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 621         // don't reset back to last position, even if new position is stuck in solid
 622         this.oldorigin = this.origin;
 623         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 624         if(this.conveyor)
 625                 IL_REMOVE(g_conveyed, this);
 626         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 627         this.hud = HUD_NORMAL;
 628
 629         this.event_damage = PlayerDamage;
 630
 631         if(!this.bot_attack)
 632                 IL_PUSH(g_bot_targets, this);
 633         this.bot_attack = true;
 634         if(!this.monster_attack)
 635                 IL_PUSH(g_monster_targets, this);
 636         this.monster_attack = true;
 637         navigation_dynamicgoal_init(this, false);
 638
 639         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 640
 641         if (CS(this).killcount == FRAGS_SPECTATOR) {
 642                 PlayerScore_Clear(this);
 643                 CS(this).killcount = 0;
 644         }
 645
 646         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 647         {
 648                 .entity weaponentity = weaponentities[slot];
 649                 entity oldwep = this.(weaponentity);
 650                 CL_SpawnWeaponentity(this, weaponentity);
 651                 if(oldwep && oldwep.owner == this)
 652                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 653         }
 654         this.alpha = default_player_alpha;
 655         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 656         this.exteriorweaponentity.alpha = default_weapon_alpha;
 657
 658         this.speedrunning = false;
 659
 660         target_voicescript_clear(this);
 661
 662         // reset fields the weapons may use
 663         FOREACH(Weapons, true, {
 664                 it.wr_resetplayer(it, this);
 665                         // reload all reloadable weapons
 666                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 667                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 668                         {
 669                                 .entity weaponentity = weaponentities[slot];
 670                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 671                         }
 672                 }
 673         });
 674
 675         {
 676                 string s = spot.target;
 677                 spot.target = string_null;
 678                 SUB_UseTargets(spot, this, NULL);
 679                 spot.target = s;
 680         }
 681
 682         Unfreeze(this);
 683
 684         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 685
 686         if (autocvar_spawn_debug)
 687         {
 688                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 689                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 690         }
 691
 692         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693         {
 694                 .entity weaponentity = weaponentities[slot];
 695                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 696                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 697                 else
 698                         this.(weaponentity).m_switchweapon = WEP_Null;
 699                 this.(weaponentity).m_weapon = WEP_Null;
 700                 this.(weaponentity).weaponname = "";
 701                 this.(weaponentity).m_switchingweapon = WEP_Null;
 702                 this.(weaponentity).cnt = -1;
 703         }
 704
 705         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 706
 707         if (!warmup_stage && !this.alivetime)
 708                 this.alivetime = time;
 709
 710         antilag_clear(this, CS(this));
 711 }
 712
 713 /** Called when a client spawns in the server */
 714 void PutClientInServer(entity this)
 715 {
 716         if (IS_BOT_CLIENT(this)) {
 717                 TRANSMUTE(Player, this);
 718         } else if (IS_REAL_CLIENT(this)) {
 719                 msg_entity = this;
 720                 WriteByte(MSG_ONE, SVC_SETVIEW);
 721                 WriteEntity(MSG_ONE, this);
 722         }
 723         if (game_stopped)
 724                 TRANSMUTE(Observer, this);
 725
 726         SetSpectatee(this, NULL);
 727
 728         // reset player keys
 729         if(PS(this))
 730                 PS(this).itemkeys = 0;
 731
 732         MUTATOR_CALLHOOK(PutClientInServer, this);
 733
 734         if (IS_OBSERVER(this)) {
 735                 PutObserverInServer(this);
 736         } else if (IS_PLAYER(this)) {
 737                 PutPlayerInServer(this);
 738         }
 739 }
 740
 741 void ClientInit_misc(entity this);
 742
 743 // TODO do we need all these fields, or should we stop autodetecting runtime
 744 // changes and just have a console command to update this?
 745 bool ClientInit_SendEntity(entity this, entity to, int sf)
 746 {
 747         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 748         return = true;
 749         msg_entity = to;
 750         // MSG_INIT replacement
 751         // TODO: make easier to use
 752         Registry_send_all();
 753         W_PROP_reload(MSG_ONE, to);
 754         ClientInit_misc(this);
 755         MUTATOR_CALLHOOK(Ent_Init);
 756 }
 757 void ClientInit_misc(entity this)
 758 {
 759         int channel = MSG_ONE;
 760         WriteHeader(channel, ENT_CLIENT_INIT);
 761         WriteByte(channel, g_nexball_meter_period * 32);
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 770
 771         if(sv_foginterval && world.fog != "")
 772                 WriteString(channel, world.fog);
 773         else
 774                 WriteString(channel, "");
 775         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 776         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 777         WriteByte(channel, serverflags);
 778         WriteCoord(channel, autocvar_g_trueaim_minrange);
 779 }
 780
 781 void ClientInit_CheckUpdate(entity this)
 782 {
 783         this.nextthink = time;
 784         if(this.count != autocvar_g_balance_armor_blockpercent)
 785         {
 786                 this.count = autocvar_g_balance_armor_blockpercent;
 787                 this.SendFlags |= 1;
 788         }
 789         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 790         {
 791                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 792                 this.SendFlags |= 1;
 793         }
 794 }
 795
 796 void ClientInit_Spawn()
 797 {
 798         entity e = new_pure(clientinit);
 799         setthink(e, ClientInit_CheckUpdate);
 800         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 801
 802         ClientInit_CheckUpdate(e);
 803 }
 804
 805 /*
 806 =============
 807 SetNewParms
 808 =============
 809 */
 810 void SetNewParms ()
 811 {
 812         // initialize parms for a new player
 813         parm1 = -(86400 * 366);
 814
 815         MUTATOR_CALLHOOK(SetNewParms);
 816 }
 817
 818 /*
 819 =============
 820 SetChangeParms
 821 =============
 822 */
 823 void SetChangeParms (entity this)
 824 {
 825         // save parms for level change
 826         parm1 = CS(this).parm_idlesince - time;
 827
 828         MUTATOR_CALLHOOK(SetChangeParms);
 829 }
 830
 831 /*
 832 =============
 833 DecodeLevelParms
 834 =============
 835 */
 836 void DecodeLevelParms(entity this)
 837 {
 838         // load parms
 839         CS(this).parm_idlesince = parm1;
 840         if (CS(this).parm_idlesince == -(86400 * 366))
 841                 CS(this).parm_idlesince = time;
 842
 843         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 844         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 845
 846         MUTATOR_CALLHOOK(DecodeLevelParms);
 847 }
 848
 849 /*
 850 =============
 851 ClientKill
 852
 853 Called when a client types 'kill' in the console
 854 =============
 855 */
 856
 857 .float clientkill_nexttime;
 858 void ClientKill_Now_TeamChange(entity this)
 859 {
 860         if(CS(this).killindicator_teamchange == -1)
 861         {
 862                 JoinBestTeam( this, false, true );
 863         }
 864         else if(CS(this).killindicator_teamchange == -2)
 865         {
 866                 if(blockSpectators)
 867                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 868                 PutObserverInServer(this);
 869         }
 870         else
 871                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 872         CS(this).killindicator_teamchange = 0;
 873 }
 874
 875 void ClientKill_Now(entity this)
 876 {
 877         if(this.vehicle)
 878         {
 879             vehicles_exit(this.vehicle, VHEF_RELEASE);
 880             if(!CS(this).killindicator_teamchange)
 881             {
 882             this.vehicle_health = -1;
 883             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 884             }
 885         }
 886
 887         if(this.killindicator && !wasfreed(this.killindicator))
 888                 delete(this.killindicator);
 889
 890         this.killindicator = NULL;
 891
 892         if(CS(this).killindicator_teamchange)
 893                 ClientKill_Now_TeamChange(this);
 894
 895         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 896                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 897
 898         // now I am sure the player IS dead
 899 }
 900 void KillIndicator_Think(entity this)
 901 {
 902         if (game_stopped)
 903         {
 904                 this.owner.killindicator = NULL;
 905                 delete(this);
 906                 return;
 907         }
 908
 909         if (this.owner.alpha < 0 && !this.owner.vehicle)
 910         {
 911                 this.owner.killindicator = NULL;
 912                 delete(this);
 913                 return;
 914         }
 915
 916         if(this.cnt <= 0)
 917         {
 918                 ClientKill_Now(this.owner);
 919                 return;
 920         }
 921     else if(this.health == 1) // health == 1 means that it's silent
 922     {
 923         this.nextthink = time + 1;
 924         this.cnt -= 1;
 925     }
 926         else
 927         {
 928                 if(this.cnt <= 10)
 929                         setmodel(this, MDL_NUM(this.cnt));
 930                 if(IS_REAL_CLIENT(this.owner))
 931                 {
 932                         if(this.cnt <= 10)
 933                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 934                 }
 935                 this.nextthink = time + 1;
 936                 this.cnt -= 1;
 937         }
 938 }
 939
 940 float clientkilltime;
 941 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 942 {
 943         float killtime;
 944         float starttime;
 945
 946         if (game_stopped)
 947                 return;
 948
 949         killtime = autocvar_g_balance_kill_delay;
 950
 951     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 952         return;
 953     killtime = M_ARGV(1, float);
 954
 955         CS(this).killindicator_teamchange = targetteam;
 956
 957     if(!this.killindicator)
 958         {
 959                 if(!IS_DEAD(this))
 960                 {
 961                         killtime = max(killtime, this.clientkill_nexttime - time);
 962                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 963                 }
 964
 965                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 966                 {
 967                         ClientKill_Now(this);
 968                 }
 969                 else
 970                 {
 971                         starttime = max(time, clientkilltime);
 972
 973                         this.killindicator = spawn();
 974                         this.killindicator.owner = this;
 975                         this.killindicator.scale = 0.5;
 976                         setattachment(this.killindicator, this, "");
 977                         setorigin(this.killindicator, '0 0 52');
 978                         setthink(this.killindicator, KillIndicator_Think);
 979                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 980                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 981                         this.killindicator.cnt = ceil(killtime);
 982                         this.killindicator.count = bound(0, ceil(killtime), 10);
 983                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 984
 985                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 986                         {
 987                                 it.killindicator = spawn();
 988                                 it.killindicator.owner = it;
 989                                 it.killindicator.scale = 0.5;
 990                                 setattachment(it.killindicator, it, "");
 991                                 setorigin(it.killindicator, '0 0 52');
 992                                 setthink(it.killindicator, KillIndicator_Think);
 993                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 994                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 995                                 it.killindicator.cnt = ceil(killtime);
 996                         });
 997                         this.lip = 0;
 998                 }
 999         }
1000         if(this.killindicator)
1001         {
1002                 if(targetteam == 0) // just die
1003                 {
1004                         this.killindicator.colormod = '0 0 0';
1005                         if(IS_REAL_CLIENT(this))
1006                         if(this.killindicator.cnt > 0)
1007                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1008                 }
1009                 else if(targetteam == -1) // auto
1010                 {
1011                         this.killindicator.colormod = '0 1 0';
1012                         if(IS_REAL_CLIENT(this))
1013                         if(this.killindicator.cnt > 0)
1014                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1015                 }
1016                 else if(targetteam == -2) // spectate
1017                 {
1018                         this.killindicator.colormod = '0.5 0.5 0.5';
1019                         if(IS_REAL_CLIENT(this))
1020                         if(this.killindicator.cnt > 0)
1021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1022                 }
1023                 else
1024                 {
1025                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1026                         if(IS_REAL_CLIENT(this))
1027                         if(this.killindicator.cnt > 0)
1028                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1029                 }
1030         }
1031
1032 }
1033
1034 void ClientKill (entity this)
1035 {
1036         if(game_stopped) return;
1037         if(this.player_blocked) return;
1038         if(STAT(FROZEN, this)) return;
1039
1040         ClientKill_TeamChange(this, 0);
1041 }
1042
1043 void FixClientCvars(entity e)
1044 {
1045         // send prediction settings to the client
1046         stuffcmd(e, "\nin_bindmap 0 0\n");
1047         if(autocvar_g_antilag == 3) // client side hitscan
1048                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1049         if(autocvar_sv_gentle)
1050                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1051
1052         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1053         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1054
1055         MUTATOR_CALLHOOK(FixClientCvars, e);
1056 }
1057
1058 bool findinlist_abbrev(string tofind, string list)
1059 {
1060         if(list == "" || tofind == "")
1061                 return false; // empty list or search, just return
1062
1063         // this function allows abbreviated strings!
1064         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1065         {
1066                 return true;
1067         });
1068
1069         return false;
1070 }
1071
1072 bool PlayerInIPList(entity p, string iplist)
1073 {
1074         // some safety checks (never allow local?)
1075         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1076                 return false;
1077
1078         return findinlist_abbrev(p.netaddress, iplist);
1079 }
1080
1081 bool PlayerInIDList(entity p, string idlist)
1082 {
1083         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1084         if(!p.crypto_idfp)
1085                 return false;
1086
1087         return findinlist_abbrev(p.crypto_idfp, idlist);
1088 }
1089
1090 bool PlayerInList(entity player, string list)
1091 {
1092         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1093 }
1094
1095 #ifdef DP_EXT_PRECONNECT
1096 /*
1097 =============
1098 ClientPreConnect
1099
1100 Called once (not at each match start) when a client begins a connection to the server
1101 =============
1102 */
1103 void ClientPreConnect(entity this)
1104 {
1105         if(autocvar_sv_eventlog)
1106         {
1107                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1108                         this.playerid,
1109                         etof(this),
1110                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1111                 ));
1112         }
1113 }
1114 #endif
1115
1116 /**
1117 =============
1118 ClientConnect
1119
1120 Called when a client connects to the server
1121 =============
1122 */
1123 void ClientConnect(entity this)
1124 {
1125         if (Ban_MaybeEnforceBanOnce(this)) return;
1126         assert(!IS_CLIENT(this), return);
1127         this.flags |= FL_CLIENT;
1128         assert(player_count >= 0, player_count = 0);
1129
1130 #ifdef WATERMARK
1131         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1132 #endif
1133         TRANSMUTE(Client, this);
1134         CS(this).version_nagtime = time + 10 + random() * 10;
1135
1136         // identify the right forced team
1137         if (autocvar_g_campaign)
1138         {
1139                 if (IS_REAL_CLIENT(this)) // only players, not bots
1140                 {
1141                         switch (autocvar_g_campaign_forceteam)
1142                         {
1143                                 case 1: this.team_forced = NUM_TEAM_1; break;
1144                                 case 2: this.team_forced = NUM_TEAM_2; break;
1145                                 case 3: this.team_forced = NUM_TEAM_3; break;
1146                                 case 4: this.team_forced = NUM_TEAM_4; break;
1147                                 default: this.team_forced = 0;
1148                         }
1149                 }
1150         }
1151         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1152         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1153         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1154         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1155         else switch (autocvar_g_forced_team_otherwise)
1156         {
1157                 default: this.team_forced = 0; break;
1158                 case "red": this.team_forced = NUM_TEAM_1; break;
1159                 case "blue": this.team_forced = NUM_TEAM_2; break;
1160                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1161                 case "pink": this.team_forced = NUM_TEAM_4; break;
1162                 case "spectate":
1163                 case "spectator":
1164                         this.team_forced = -1;
1165                         break;
1166         }
1167         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1168
1169     {
1170         int id = this.playerid;
1171         this.playerid = 0; // silent
1172             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1173             this.playerid = id;
1174     }
1175
1176         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1177                 TRANSMUTE(Observer, this);
1178         } else {
1179                 if (!teamplay || autocvar_g_balance_teams) {
1180                         TRANSMUTE(Player, this);
1181                         campaign_bots_may_start = true;
1182                 } else {
1183                         TRANSMUTE(Observer, this); // do it anyway
1184                 }
1185         }
1186
1187         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1188
1189         // always track bots, don't ask for cl_allow_uidtracking
1190     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1191
1192         if (autocvar_sv_eventlog)
1193                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1194
1195         LogTeamchange(this.playerid, this.team, 1);
1196
1197         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1198
1199         CS(this).netname_previous = strzone(this.netname);
1200
1201         if(teamplay && IS_PLAYER(this))
1202                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1203         else
1204                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1205
1206         stuffcmd(this, clientstuff, "\n");
1207         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1208
1209         FixClientCvars(this);
1210
1211         // get version info from player
1212         stuffcmd(this, "cmd clientversion $gameversion\n");
1213
1214         // notify about available teams
1215         if (teamplay)
1216         {
1217                 CheckAllowedTeams(this);
1218                 int t = 0;
1219                 if (c1 >= 0) t |= BIT(0);
1220                 if (c2 >= 0) t |= BIT(1);
1221                 if (c3 >= 0) t |= BIT(2);
1222                 if (c4 >= 0) t |= BIT(3);
1223                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1224         }
1225         else
1226         {
1227                 stuffcmd(this, "set _teams_available 0\n");
1228         }
1229
1230         bot_relinkplayerlist();
1231
1232         CS(this).spectatortime = time;
1233         if (blockSpectators)
1234         {
1235                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1236         }
1237
1238         CS(this).jointime = time;
1239         CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1240
1241         if (IS_REAL_CLIENT(this))
1242         {
1243                 if (g_weaponarena_weapons == WEPSET(TUBA))
1244                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1245         }
1246
1247         if (!sv_foginterval && world.fog != "")
1248                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1249
1250         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1251                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1252                         send_CSQC_teamnagger();
1253
1254         CSQCMODEL_AUTOINIT(this);
1255
1256         CS(this).model_randomizer = random();
1257
1258         if (IS_REAL_CLIENT(this))
1259                 sv_notice_join(this);
1260
1261         // update physics stats (players can spawn before physics runs)
1262         Physics_UpdateStats(this);
1263
1264         IL_EACH(g_initforplayer, it.init_for_player, {
1265                 it.init_for_player(it, this);
1266         });
1267
1268         MUTATOR_CALLHOOK(ClientConnect, this);
1269
1270         if (IS_REAL_CLIENT(this))
1271         {
1272                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1273                 {
1274                         CS(this).motd_actived_time = -1;
1275                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1276                 }
1277         }
1278 }
1279 /*
1280 =============
1281 ClientDisconnect
1282
1283 Called when a client disconnects from the server
1284 =============
1285 */
1286 .entity chatbubbleentity;
1287 void ReadyCount();
1288 void ClientDisconnect(entity this)
1289 {
1290         assert(IS_CLIENT(this), return);
1291
1292         PlayerStats_GameReport_FinalizePlayer(this);
1293         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1294         if (CS(this).active_minigame) part_minigame(this);
1295         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1296
1297         if (autocvar_sv_eventlog)
1298                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1299
1300         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1301
1302         if(IS_SPEC(this))
1303                 SetSpectatee(this, NULL);
1304
1305     MUTATOR_CALLHOOK(ClientDisconnect, this);
1306
1307         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1308         ClientState_detach(this);
1309
1310         Portal_ClearAll(this);
1311
1312         Unfreeze(this);
1313
1314         RemoveGrapplingHooks(this);
1315
1316         // Here, everything has been done that requires this player to be a client.
1317
1318         this.flags &= ~FL_CLIENT;
1319
1320         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1321         if (this.killindicator) delete(this.killindicator);
1322
1323         WaypointSprite_PlayerGone(this);
1324
1325         bot_relinkplayerlist();
1326
1327         if (this.clientstatus) strunzone(this.clientstatus);
1328         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1329         if (this.personal) delete(this.personal);
1330
1331         this.playerid = 0;
1332         ReadyCount();
1333         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1334
1335         ONREMOVE(this);
1336 }
1337
1338 void ChatBubbleThink(entity this)
1339 {
1340         this.nextthink = time;
1341         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1342         {
1343                 if(this.owner) // but why can that ever be NULL?
1344                         this.owner.chatbubbleentity = NULL;
1345                 delete(this);
1346                 return;
1347         }
1348
1349         this.mdl = "";
1350
1351         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1352         {
1353                 if ( CS(this.owner).active_minigame )
1354                         this.mdl = "models/sprites/minigame_busy.iqm";
1355                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1356                         this.mdl = "models/misc/chatbubble.spr";
1357         }
1358
1359         if ( this.model != this.mdl )
1360                 _setmodel(this, this.mdl);
1361
1362 }
1363
1364 void UpdateChatBubble(entity this)
1365 {
1366         if (this.alpha < 0)
1367                 return;
1368         // spawn a chatbubble entity if needed
1369         if (!this.chatbubbleentity)
1370         {
1371                 this.chatbubbleentity = new(chatbubbleentity);
1372                 this.chatbubbleentity.owner = this;
1373                 this.chatbubbleentity.exteriormodeltoclient = this;
1374                 setthink(this.chatbubbleentity, ChatBubbleThink);
1375                 this.chatbubbleentity.nextthink = time;
1376                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1377                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1378                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1379                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1380                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1381                 //this.chatbubbleentity.model = "";
1382                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1383         }
1384 }
1385
1386
1387 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1388 // added to the model skins
1389 /*void UpdateColorModHack()
1390 {
1391         float c;
1392         c = this.clientcolors & 15;
1393         // LordHavoc: only bothering to support white, green, red, yellow, blue
1394              if (!teamplay) this.colormod = '0 0 0';
1395         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1396         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1397         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1398         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1399         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1400         else this.colormod = '1 1 1';
1401 }*/
1402
1403 void respawn(entity this)
1404 {
1405         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1406         {
1407                 this.solid = SOLID_NOT;
1408                 this.takedamage = DAMAGE_NO;
1409                 set_movetype(this, MOVETYPE_FLY);
1410                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1411                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1412                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1413                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1414                 if(autocvar_g_respawn_ghosts_maxtime)
1415                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1416         }
1417
1418         CopyBody(this, 1);
1419
1420         this.effects |= EF_NODRAW; // prevent another CopyBody
1421         PutClientInServer(this);
1422 }
1423
1424 void play_countdown(entity this, float finished, Sound samp)
1425 {
1426     TC(Sound, samp);
1427         if(IS_REAL_CLIENT(this))
1428                 if(floor(finished - time - frametime) != floor(finished - time))
1429                         if(finished - time < 6)
1430                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1431 }
1432
1433 void player_powerups(entity this)
1434 {
1435         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1436         int items_prev = this.items;
1437
1438         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1439                 this.modelflags |= MF_ROCKET;
1440         else
1441                 this.modelflags &= ~MF_ROCKET;
1442
1443         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1444
1445         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1446                 return;
1447
1448         Fire_ApplyDamage(this);
1449         Fire_ApplyEffect(this);
1450
1451         if (!g_instagib)
1452         {
1453                 if (this.items & ITEM_Strength.m_itemid)
1454                 {
1455                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1456                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1457                         if (time > this.strength_finished)
1458                         {
1459                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1460                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1461                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1462                         }
1463                 }
1464                 else
1465                 {
1466                         if (time < this.strength_finished)
1467                         {
1468                                 this.items = this.items | ITEM_Strength.m_itemid;
1469                                 if(!g_cts)
1470                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1471                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1472                         }
1473                 }
1474                 if (this.items & ITEM_Shield.m_itemid)
1475                 {
1476                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1477                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1478                         if (time > this.invincible_finished)
1479                         {
1480                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1481                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1482                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1483                         }
1484                 }
1485                 else
1486                 {
1487                         if (time < this.invincible_finished)
1488                         {
1489                                 this.items = this.items | ITEM_Shield.m_itemid;
1490                                 if(!g_cts)
1491                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1492                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1493                         }
1494                 }
1495                 if (this.items & IT_SUPERWEAPON)
1496                 {
1497                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1498                         {
1499                                 this.superweapons_finished = 0;
1500                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1501                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1502                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1503                         }
1504                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1505                         {
1506                                 // don't let them run out
1507                         }
1508                         else
1509                         {
1510                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1511                                 if (time > this.superweapons_finished)
1512                                 {
1513                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1514                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1515                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1517                                 }
1518                         }
1519                 }
1520                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1521                 {
1522                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1523                         {
1524                                 this.items = this.items | IT_SUPERWEAPON;
1525                                 if(!g_cts)
1526                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1527                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1528                         }
1529                         else
1530                         {
1531                                 this.superweapons_finished = 0;
1532                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1533                         }
1534                 }
1535                 else
1536                 {
1537                         this.superweapons_finished = 0;
1538                 }
1539         }
1540
1541         if(autocvar_g_nodepthtestplayers)
1542                 this.effects = this.effects | EF_NODEPTHTEST;
1543
1544         if(autocvar_g_fullbrightplayers)
1545                 this.effects = this.effects | EF_FULLBRIGHT;
1546
1547         if (time >= game_starttime)
1548         if (time < this.spawnshieldtime)
1549                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1550
1551         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1552 }
1553
1554 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1555 {
1556         if(current > stable)
1557                 return current;
1558         else if(current > stable - 0.25) // when close enough, "snap"
1559                 return stable;
1560         else
1561                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1562 }
1563
1564 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1565 {
1566         if(current < stable)
1567                 return current;
1568         else if(current < stable + 0.25) // when close enough, "snap"
1569                 return stable;
1570         else
1571                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1572 }
1573
1574 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1575 {
1576         if(current > rotstable)
1577         {
1578                 if(rotframetime > 0)
1579                 {
1580                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1581                         current = max(rotstable, current - rotlinear * rotframetime);
1582                 }
1583         }
1584         else if(current < regenstable)
1585         {
1586                 if(regenframetime > 0)
1587                 {
1588                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1589                         current = min(regenstable, current + regenlinear * regenframetime);
1590                 }
1591         }
1592
1593         if(current > limit)
1594                 current = limit;
1595
1596         return current;
1597 }
1598
1599 void player_regen(entity this)
1600 {
1601         float max_mod, regen_mod, rot_mod, limit_mod;
1602         max_mod = regen_mod = rot_mod = limit_mod = 1;
1603
1604         float regen_health = autocvar_g_balance_health_regen;
1605         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1606         float regen_health_rot = autocvar_g_balance_health_rot;
1607         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1608         float regen_health_stable = autocvar_g_balance_health_regenstable;
1609         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1610         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1611                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1612         max_mod = M_ARGV(1, float);
1613         regen_mod = M_ARGV(2, float);
1614         rot_mod = M_ARGV(3, float);
1615         limit_mod = M_ARGV(4, float);
1616         regen_health = M_ARGV(5, float);
1617         regen_health_linear = M_ARGV(6, float);
1618         regen_health_rot = M_ARGV(7, float);
1619         regen_health_rotlinear = M_ARGV(8, float);
1620         regen_health_stable = M_ARGV(9, float);
1621         regen_health_rotstable = M_ARGV(10, float);
1622
1623
1624         if(!mutator_returnvalue)
1625         if(!STAT(FROZEN, this))
1626         {
1627                 float mina, maxa, limith, limita;
1628                 maxa = autocvar_g_balance_armor_rotstable;
1629                 mina = autocvar_g_balance_armor_regenstable;
1630                 limith = autocvar_g_balance_health_limit;
1631                 limita = autocvar_g_balance_armor_limit;
1632
1633                 regen_health_rotstable = regen_health_rotstable * max_mod;
1634                 regen_health_stable = regen_health_stable * max_mod;
1635                 limith = limith * limit_mod;
1636                 limita = limita * limit_mod;
1637
1638                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1639                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1640         }
1641
1642         // if player rotted to death...  die!
1643         // check this outside above checks, as player may still be able to rot to death
1644         if(this.health < 1)
1645         {
1646                 if(this.vehicle)
1647                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1648                 if(this.event_damage)
1649                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1650         }
1651
1652         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1653         {
1654                 float minf, maxf, limitf;
1655
1656                 maxf = autocvar_g_balance_fuel_rotstable;
1657                 minf = autocvar_g_balance_fuel_regenstable;
1658                 limitf = autocvar_g_balance_fuel_limit;
1659
1660                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1661         }
1662 }
1663
1664 bool zoomstate_set;
1665 void SetZoomState(entity this, float newzoom)
1666 {
1667         if(newzoom != CS(this).zoomstate)
1668         {
1669                 CS(this).zoomstate = newzoom;
1670                 ClientData_Touch(this);
1671         }
1672         zoomstate_set = true;
1673 }
1674
1675 void GetPressedKeys(entity this)
1676 {
1677         MUTATOR_CALLHOOK(GetPressedKeys, this);
1678         int keys = STAT(PRESSED_KEYS, this);
1679         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1680         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1681         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1682         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1683
1684         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1685         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1686         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1687         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1688         CS(this).pressedkeys = keys; // store for other users
1689
1690         STAT(PRESSED_KEYS, this) = keys;
1691 }
1692
1693 /*
1694 ======================
1695 spectate mode routines
1696 ======================
1697 */
1698
1699 void SpectateCopy(entity this, entity spectatee)
1700 {
1701     TC(Client, this); TC(Client, spectatee);
1702
1703         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1704         PS(this) = PS(spectatee);
1705         this.armortype = spectatee.armortype;
1706         this.armorvalue = spectatee.armorvalue;
1707         this.ammo_cells = spectatee.ammo_cells;
1708         this.ammo_plasma = spectatee.ammo_plasma;
1709         this.ammo_shells = spectatee.ammo_shells;
1710         this.ammo_nails = spectatee.ammo_nails;
1711         this.ammo_rockets = spectatee.ammo_rockets;
1712         this.ammo_fuel = spectatee.ammo_fuel;
1713         this.clip_load = spectatee.clip_load;
1714         this.clip_size = spectatee.clip_size;
1715         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1716         this.health = spectatee.health;
1717         CS(this).impulse = 0;
1718         this.items = spectatee.items;
1719         this.last_pickup = spectatee.last_pickup;
1720         this.hit_time = spectatee.hit_time;
1721         this.strength_finished = spectatee.strength_finished;
1722         this.invincible_finished = spectatee.invincible_finished;
1723         this.superweapons_finished = spectatee.superweapons_finished;
1724         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1725         this.weapons = spectatee.weapons;
1726         this.vortex_charge = spectatee.vortex_charge;
1727         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1728         this.hagar_load = spectatee.hagar_load;
1729         this.arc_heat_percent = spectatee.arc_heat_percent;
1730         this.minelayer_mines = spectatee.minelayer_mines;
1731         this.punchangle = spectatee.punchangle;
1732         this.view_ofs = spectatee.view_ofs;
1733         this.velocity = spectatee.velocity;
1734         this.dmg_take = spectatee.dmg_take;
1735         this.dmg_save = spectatee.dmg_save;
1736         this.dmg_inflictor = spectatee.dmg_inflictor;
1737         this.v_angle = spectatee.v_angle;
1738         this.angles = spectatee.v_angle;
1739         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1740         this.revive_progress = spectatee.revive_progress;
1741         this.viewloc = spectatee.viewloc;
1742         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1743                 this.fixangle = true;
1744         setorigin(this, spectatee.origin);
1745         setsize(this, spectatee.mins, spectatee.maxs);
1746         SetZoomState(this, CS(spectatee).zoomstate);
1747
1748         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1749         {
1750                 .entity weaponentity = weaponentities[slot];
1751                 this.(weaponentity) = spectatee.(weaponentity);
1752         }
1753
1754         for(int slot = 0; slot < MAX_AXH; ++slot)
1755         {
1756                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1757         }
1758
1759     anticheat_spectatecopy(this, spectatee);
1760         this.hud = spectatee.hud;
1761         if(spectatee.vehicle)
1762     {
1763         this.angles = spectatee.v_angle;
1764
1765         //this.fixangle = false;
1766         //this.velocity = spectatee.vehicle.velocity;
1767         this.vehicle_health = spectatee.vehicle_health;
1768         this.vehicle_shield = spectatee.vehicle_shield;
1769         this.vehicle_energy = spectatee.vehicle_energy;
1770         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1771         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1772         this.vehicle_reload1 = spectatee.vehicle_reload1;
1773         this.vehicle_reload2 = spectatee.vehicle_reload2;
1774
1775         //msg_entity = this;
1776
1777        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1778             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1779            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1780            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1781
1782         //WriteByte (MSG_ONE, SVC_SETVIEW);
1783         //    WriteEntity(MSG_ONE, this);
1784         //makevectors(spectatee.v_angle);
1785         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1786     }
1787 }
1788
1789 bool SpectateUpdate(entity this)
1790 {
1791         if(!this.enemy)
1792                 return false;
1793
1794         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1795         {
1796                 SetSpectatee(this, NULL);
1797                 return false;
1798         }
1799
1800         SpectateCopy(this, this.enemy);
1801
1802         return true;
1803 }
1804
1805 bool SpectateSet(entity this)
1806 {
1807         if(!IS_PLAYER(this.enemy))
1808                 return false;
1809
1810         ClientData_Touch(this.enemy);
1811
1812         msg_entity = this;
1813         WriteByte(MSG_ONE, SVC_SETVIEW);
1814         WriteEntity(MSG_ONE, this.enemy);
1815         set_movetype(this, MOVETYPE_NONE);
1816         accuracy_resend(this);
1817
1818         if(!SpectateUpdate(this))
1819                 PutObserverInServer(this);
1820
1821         return true;
1822 }
1823
1824 void SetSpectatee_status(entity this, int spectatee_num)
1825 {
1826         int oldspectatee_status = CS(this).spectatee_status;
1827         CS(this).spectatee_status = spectatee_num;
1828
1829         if (CS(this).spectatee_status != oldspectatee_status)
1830         {
1831                 ClientData_Touch(this);
1832                 if (g_race || g_cts) race_InitSpectator();
1833         }
1834 }
1835
1836 void SetSpectatee(entity this, entity spectatee)
1837 {
1838         if(IS_BOT_CLIENT(this))
1839                 return; // bots abuse .enemy, this code is useless to them
1840
1841         entity old_spectatee = this.enemy;
1842
1843         this.enemy = spectatee;
1844
1845         // WEAPONTODO
1846         // these are required to fix the spectator bug with arc
1847         if(old_spectatee)
1848         {
1849                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1850                 {
1851                         .entity weaponentity = weaponentities[slot];
1852                         if(old_spectatee.(weaponentity).arc_beam)
1853                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1854                 }
1855         }
1856         if(this.enemy)
1857         {
1858                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1859                 {
1860                         .entity weaponentity = weaponentities[slot];
1861                         if(this.enemy.(weaponentity).arc_beam)
1862                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1863                 }
1864         }
1865
1866         if (this.enemy)
1867                 SetSpectatee_status(this, etof(this.enemy));
1868
1869         // needed to update spectator list
1870         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1871 }
1872
1873 bool Spectate(entity this, entity pl)
1874 {
1875         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1876                 return false;
1877         pl = M_ARGV(1, entity);
1878
1879         SetSpectatee(this, pl);
1880         return SpectateSet(this);
1881 }
1882
1883 bool SpectateNext(entity this)
1884 {
1885         entity ent = find(this.enemy, classname, STR_PLAYER);
1886
1887         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1888                 ent = M_ARGV(1, entity);
1889         else if (!ent)
1890                 ent = find(ent, classname, STR_PLAYER);
1891
1892         if(ent) { SetSpectatee(this, ent); }
1893
1894         return SpectateSet(this);
1895 }
1896
1897 bool SpectatePrev(entity this)
1898 {
1899         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1900         entity ent = findchain(classname, STR_PLAYER);
1901         if (!ent) // no player
1902                 return false;
1903
1904         entity first = ent;
1905         // skip players until current spectated player
1906         if(this.enemy)
1907         while(ent && ent != this.enemy)
1908                 ent = ent.chain;
1909
1910         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1911         {
1912                 case MUT_SPECPREV_FOUND:
1913                     ent = M_ARGV(1, entity);
1914                     break;
1915                 case MUT_SPECPREV_RETURN:
1916                     return true;
1917                 case MUT_SPECPREV_CONTINUE:
1918                 default:
1919                 {
1920                         if(ent.chain)
1921                                 ent = ent.chain;
1922                         else
1923                                 ent = first;
1924                         break;
1925                 }
1926         }
1927
1928         SetSpectatee(this, ent);
1929         return SpectateSet(this);
1930 }
1931
1932 /*
1933 =============
1934 ShowRespawnCountdown()
1935
1936 Update a respawn countdown display.
1937 =============
1938 */
1939 void ShowRespawnCountdown(entity this)
1940 {
1941         float number;
1942         if(!IS_DEAD(this)) // just respawned?
1943                 return;
1944         else
1945         {
1946                 number = ceil(this.respawn_time - time);
1947                 if(number <= 0)
1948                         return;
1949                 if(number <= this.respawn_countdown)
1950                 {
1951                         this.respawn_countdown = number - 1;
1952                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1953                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1954                 }
1955         }
1956 }
1957
1958 .bool team_selected;
1959 bool ShowTeamSelection(entity this)
1960 {
1961         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1962                 return false;
1963         stuffcmd(this, "menu_showteamselect\n");
1964         return true;
1965 }
1966 void Join(entity this)
1967 {
1968         TRANSMUTE(Player, this);
1969
1970         if(!this.team_selected)
1971         if(autocvar_g_campaign || autocvar_g_balance_teams)
1972                 JoinBestTeam(this, false, true);
1973
1974         if(autocvar_g_campaign)
1975                 campaign_bots_may_start = true;
1976
1977         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1978
1979         PutClientInServer(this);
1980
1981         if(IS_PLAYER(this))
1982         if(teamplay && this.team != -1)
1983                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1984         else
1985                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1986         this.team_selected = false;
1987 }
1988
1989 /**
1990  * Determines whether the player is allowed to join. This depends on cvar
1991  * g_maxplayers, if it isn't used this function always return true, otherwise
1992  * it checks whether the number of currently playing players exceeds g_maxplayers.
1993  * @return int number of free slots for players, 0 if none
1994  */
1995 int nJoinAllowed(entity this, entity ignore)
1996 {
1997         if(!ignore)
1998         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1999         // so report 0 free slots if restricted
2000         {
2001                 if(autocvar_g_forced_team_otherwise == "spectate")
2002                         return 0;
2003                 if(autocvar_g_forced_team_otherwise == "spectator")
2004                         return 0;
2005         }
2006
2007         if(this && this.team_forced < 0)
2008                 return 0; // forced spectators can never join
2009
2010         // TODO simplify this
2011         int totalClients = 0;
2012         int currentlyPlaying = 0;
2013         FOREACH_CLIENT(true, {
2014                 if(it != ignore)
2015                         ++totalClients;
2016                 if(IS_REAL_CLIENT(it))
2017                 if(IS_PLAYER(it) || it.caplayer)
2018                         ++currentlyPlaying;
2019         });
2020
2021         float free_slots = 0;
2022         if (!autocvar_g_maxplayers)
2023                 free_slots = maxclients - totalClients;
2024         else if(currentlyPlaying < autocvar_g_maxplayers)
2025                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2026
2027         static float join_prevent_msg_time = 0;
2028         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2029         {
2030                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2031                 join_prevent_msg_time = time + 3;
2032         }
2033
2034         return free_slots;
2035 }
2036
2037 /**
2038  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2039  * g_maxplayers_spectator_blocktime seconds
2040  */
2041 void checkSpectatorBlock(entity this)
2042 {
2043         if(IS_SPEC(this) || IS_OBSERVER(this))
2044         if(!this.caplayer)
2045         if(IS_REAL_CLIENT(this))
2046         {
2047                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2048                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2049                         dropclient(this);
2050                 }
2051         }
2052 }
2053
2054 void PrintWelcomeMessage(entity this)
2055 {
2056         if(CS(this).motd_actived_time == 0)
2057         {
2058                 if (autocvar_g_campaign) {
2059                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2060                                 CS(this).motd_actived_time = time;
2061                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2062                         }
2063                 } else {
2064                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2065                                 CS(this).motd_actived_time = time;
2066                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2067                         }
2068                 }
2069         }
2070         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2071         {
2072                 if (autocvar_g_campaign) {
2073                         if (PHYS_INPUT_BUTTON_INFO(this))
2074                                 CS(this).motd_actived_time = time;
2075                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2076                                 CS(this).motd_actived_time = 0;
2077                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2078                         }
2079                 } else {
2080                         if (PHYS_INPUT_BUTTON_INFO(this))
2081                                 CS(this).motd_actived_time = time;
2082                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2083                                 CS(this).motd_actived_time = 0;
2084                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2085                         }
2086                 }
2087         }
2088         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2089         {
2090                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2091                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2092                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2093                 {
2094                         // instanctly hide MOTD
2095                         CS(this).motd_actived_time = 0;
2096                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2097                 }
2098         }
2099 }
2100
2101 bool joinAllowed(entity this)
2102 {
2103         if (CS(this).version_mismatch) return false;
2104         if (!nJoinAllowed(this, this)) return false;
2105         if (teamplay && lockteams) return false;
2106         if (ShowTeamSelection(this)) return false;
2107         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2108         return true;
2109 }
2110
2111 .int items_added;
2112 bool PlayerThink(entity this)
2113 {
2114         if (game_stopped || intermission_running) {
2115                 this.modelflags &= ~MF_ROCKET;
2116                 if(intermission_running)
2117                         IntermissionThink(this);
2118                 return false;
2119         }
2120
2121         if (timeout_status == TIMEOUT_ACTIVE) {
2122         // don't allow the player to turn around while game is paused
2123                 // FIXME turn this into CSQC stuff
2124                 this.v_angle = this.lastV_angle;
2125                 this.angles = this.lastV_angle;
2126                 this.fixangle = true;
2127         }
2128
2129         if (frametime) player_powerups(this);
2130
2131         if (IS_DEAD(this)) {
2132                 if (this.personal && g_race_qualifying) {
2133                         if (time > this.respawn_time) {
2134                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2135                                 respawn(this);
2136                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2137                         }
2138                 } else {
2139                         if (frametime) player_anim(this);
2140
2141                         if (this.respawn_flags & RESPAWN_DENY)
2142                         {
2143                                 STAT(RESPAWN_TIME, this) = 0;
2144                                 return false;
2145                         }
2146
2147                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2148
2149                         switch(this.deadflag)
2150                         {
2151                                 case DEAD_DYING:
2152                                 {
2153                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2154                                                 this.deadflag = DEAD_RESPAWNING;
2155                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2156                                                 this.deadflag = DEAD_DEAD;
2157                                         break;
2158                                 }
2159                                 case DEAD_DEAD:
2160                                 {
2161                                         if (button_pressed)
2162                                                 this.deadflag = DEAD_RESPAWNABLE;
2163                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2164                                                 this.deadflag = DEAD_RESPAWNING;
2165                                         break;
2166                                 }
2167                                 case DEAD_RESPAWNABLE:
2168                                 {
2169                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2170                                                 this.deadflag = DEAD_RESPAWNING;
2171                                         break;
2172                                 }
2173                                 case DEAD_RESPAWNING:
2174                                 {
2175                                         if (time > this.respawn_time)
2176                                         {
2177                                                 this.respawn_time = time + 1; // only retry once a second
2178                                                 this.respawn_time_max = this.respawn_time;
2179                                                 respawn(this);
2180                                         }
2181                                         break;
2182                                 }
2183                         }
2184
2185                         ShowRespawnCountdown(this);
2186
2187                         if (this.respawn_flags & RESPAWN_SILENT)
2188                                 STAT(RESPAWN_TIME, this) = 0;
2189                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2190                         {
2191                                 if (time < this.respawn_time)
2192                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2193                                 else if (this.deadflag != DEAD_RESPAWNING)
2194                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2195                         }
2196                         else
2197                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2198                 }
2199
2200                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2201                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2202                         STAT(RESPAWN_TIME, this) *= -1;
2203
2204                 return false;
2205         }
2206
2207         bool have_hook = false;
2208         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2209         {
2210                 .entity weaponentity = weaponentities[slot];
2211                 if(this.(weaponentity).hook.state)
2212                 {
2213                         have_hook = true;
2214                         break;
2215                 }
2216         }
2217         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2218         if (have_hook) {
2219                 do_crouch = false;
2220         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2221                 do_crouch = false;
2222         } else if (this.vehicle) {
2223                 do_crouch = false;
2224         } else if (STAT(FROZEN, this)) {
2225                 do_crouch = false;
2226     }
2227
2228         if (do_crouch) {
2229                 if (!this.crouch) {
2230                         this.crouch = true;
2231                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2232                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2233                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2234                 }
2235         } else if (this.crouch) {
2236         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2237         if (!trace_startsolid) {
2238             this.crouch = false;
2239             this.view_ofs = STAT(PL_VIEW_OFS, this);
2240             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2241         }
2242         }
2243
2244         FixPlayermodel(this);
2245
2246         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2247         //if(frametime)
2248         {
2249                 this.items &= ~this.items_added;
2250
2251                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2252                 {
2253                         .entity weaponentity = weaponentities[slot];
2254                         W_WeaponFrame(this, weaponentity);
2255
2256                         if(slot == 0)
2257                         {
2258                                 this.clip_load = this.(weaponentity).clip_load;
2259                                 this.clip_size = this.(weaponentity).clip_size;
2260                         }
2261                 }
2262
2263                 this.items_added = 0;
2264                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2265             this.items_added |= IT_FUEL;
2266
2267                 this.items |= this.items_added;
2268         }
2269
2270         player_regen(this);
2271
2272         // WEAPONTODO: Add a weapon request for this
2273         // rot vortex charge to the charge limit
2274         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2275         {
2276                 .entity weaponentity = weaponentities[slot];
2277                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2278                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2279         }
2280
2281         if (frametime) player_anim(this);
2282
2283         // secret status
2284         secrets_setstatus(this);
2285
2286         // monsters status
2287         monsters_setstatus(this);
2288
2289         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2290
2291         return true;
2292 }
2293
2294 void ObserverThink(entity this)
2295 {
2296         if ( CS(this).impulse )
2297         {
2298                 MinigameImpulse(this, CS(this).impulse);
2299                 CS(this).impulse = 0;
2300         }
2301
2302         if (this.flags & FL_JUMPRELEASED) {
2303                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2304                         this.flags &= ~FL_JUMPRELEASED;
2305                         this.flags |= FL_SPAWNING;
2306                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2307                         this.flags &= ~FL_JUMPRELEASED;
2308                         if(SpectateNext(this)) {
2309                                 TRANSMUTE(Spectator, this);
2310                         }
2311                 } else {
2312                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2313                         set_movetype(this, preferred_movetype);
2314                 }
2315         } else {
2316                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2317                         this.flags |= FL_JUMPRELEASED;
2318                         if(this.flags & FL_SPAWNING)
2319                         {
2320                                 this.flags &= ~FL_SPAWNING;
2321                                 Join(this);
2322                                 return;
2323                         }
2324                 }
2325         }
2326 }
2327
2328 void SpectatorThink(entity this)
2329 {
2330         if ( CS(this).impulse )
2331         {
2332                 if(MinigameImpulse(this, CS(this).impulse))
2333                         CS(this).impulse = 0;
2334
2335                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2336                 {
2337                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2338                         CS(this).impulse = 0;
2339                         return;
2340                 }
2341         }
2342
2343         if (this.flags & FL_JUMPRELEASED) {
2344                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2345                         this.flags &= ~FL_JUMPRELEASED;
2346                         this.flags |= FL_SPAWNING;
2347                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2348                         this.flags &= ~FL_JUMPRELEASED;
2349                         if(SpectateNext(this)) {
2350                                 TRANSMUTE(Spectator, this);
2351                         } else {
2352                                 TRANSMUTE(Observer, this);
2353                                 PutClientInServer(this);
2354                         }
2355                         CS(this).impulse = 0;
2356                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2357                         this.flags &= ~FL_JUMPRELEASED;
2358                         if(SpectatePrev(this)) {
2359                                 TRANSMUTE(Spectator, this);
2360                         } else {
2361                                 TRANSMUTE(Observer, this);
2362                                 PutClientInServer(this);
2363                         }
2364                         CS(this).impulse = 0;
2365                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2366                         this.flags &= ~FL_JUMPRELEASED;
2367                         TRANSMUTE(Observer, this);
2368                         PutClientInServer(this);
2369                 } else {
2370                         if(!SpectateUpdate(this))
2371                                 PutObserverInServer(this);
2372                 }
2373         } else {
2374                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2375                         this.flags |= FL_JUMPRELEASED;
2376                         if(this.flags & FL_SPAWNING)
2377                         {
2378                                 this.flags &= ~FL_SPAWNING;
2379                                 Join(this);
2380                                 return;
2381                         }
2382                 }
2383                 if(!SpectateUpdate(this))
2384                         PutObserverInServer(this);
2385         }
2386
2387         this.flags |= FL_CLIENT | FL_NOTARGET;
2388 }
2389
2390 void vehicles_enter (entity pl, entity veh);
2391 void PlayerUseKey(entity this)
2392 {
2393         if (!IS_PLAYER(this))
2394                 return;
2395
2396         if(this.vehicle)
2397         {
2398                 if(!game_stopped)
2399                 {
2400                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2401                         return;
2402                 }
2403         }
2404         else if(autocvar_g_vehicles_enter)
2405         {
2406                 if(!STAT(FROZEN, this))
2407                 if(!IS_DEAD(this))
2408                 if(!game_stopped)
2409                 {
2410                         entity head, closest_target = NULL;
2411                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2412
2413                         while(head) // find the closest acceptable target to enter
2414                         {
2415                                 if(IS_VEHICLE(head))
2416                                 if(!IS_DEAD(head))
2417                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2418                                 if(head.takedamage != DAMAGE_NO)
2419                                 {
2420                                         if(closest_target)
2421                                         {
2422                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2423                                                 { closest_target = head; }
2424                                         }
2425                                         else { closest_target = head; }
2426                                 }
2427
2428                                 head = head.chain;
2429                         }
2430
2431                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2432                 }
2433         }
2434
2435         // a use key was pressed; call handlers
2436         MUTATOR_CALLHOOK(PlayerUseKey, this);
2437 }
2438
2439
2440 /*
2441 =============
2442 PlayerPreThink
2443
2444 Called every frame for each client before the physics are run
2445 =============
2446 */
2447 .float last_vehiclecheck;
2448 void PlayerPreThink (entity this)
2449 {
2450         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2451         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2452
2453         WarpZone_PlayerPhysics_FixVAngle(this);
2454
2455         if (frametime) {
2456                 // physics frames: update anticheat stuff
2457                 anticheat_prethink(this);
2458         }
2459
2460         if (blockSpectators && frametime) {
2461                 // WORKAROUND: only use dropclient in server frames (frametime set).
2462                 // Never use it in cl_movement frames (frametime zero).
2463                 checkSpectatorBlock(this);
2464     }
2465
2466         zoomstate_set = false;
2467
2468         // Check for nameless players
2469         if (isInvisibleString(this.netname)) {
2470                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2471                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2472         }
2473         if (this.netname != CS(this).netname_previous) {
2474                 if (autocvar_sv_eventlog) {
2475                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2476         }
2477                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2478                 CS(this).netname_previous = strzone(this.netname);
2479         }
2480
2481         // version nagging
2482         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2483         CS(this).version_nagtime = 0;
2484         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2485             // git client
2486         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2487             // git server
2488             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2489         } else {
2490             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2491             if (r < 0) { // old client
2492                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2493             } else if (r > 0) { // old server
2494                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2495             }
2496         }
2497     }
2498
2499         // GOD MODE info
2500         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2501         {
2502                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2503                 this.max_armorvalue = 0;
2504         }
2505
2506         if(IS_PLAYER(this))
2507         {
2508                 if (STAT(FROZEN, this) == 2)
2509                 {
2510                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2511                         this.health = max(1, this.revive_progress * start_health);
2512                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2513
2514                         if (this.revive_progress >= 1)
2515                                 Unfreeze(this);
2516                 }
2517                 else if (STAT(FROZEN, this) == 3)
2518                 {
2519                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2520                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2521
2522                         if (this.health < 1)
2523                         {
2524                                 if (this.vehicle)
2525                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2526                                 if(this.event_damage)
2527                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2528                         }
2529                         else if (this.revive_progress <= 0)
2530                                 Unfreeze(this);
2531                 }
2532         }
2533
2534         MUTATOR_CALLHOOK(PlayerPreThink, this);
2535
2536         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2537         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2538         {
2539                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2540                 {
2541                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2542                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2543                         {
2544                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2545                         }
2546                         else if(!it.owner)
2547                         {
2548                                 if(!it.team || SAME_TEAM(this, it))
2549                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2550                                 else if(autocvar_g_vehicles_steal)
2551                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2552                         }
2553                 });
2554
2555                 this.last_vehiclecheck = time + 1;
2556         }
2557
2558         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2559         {
2560                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2561                         PlayerUseKey(this);
2562                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2563         }
2564
2565         if (IS_REAL_CLIENT(this))
2566                 PrintWelcomeMessage(this);
2567
2568         if (IS_PLAYER(this)) {
2569                 if(!PlayerThink(this))
2570                         return;
2571         }
2572         else if (game_stopped || intermission_running) {
2573                 if(intermission_running)
2574                         IntermissionThink(this);
2575                 return;
2576         }
2577         else if (IS_OBSERVER(this)) {
2578                 ObserverThink(this);
2579         }
2580         else if (IS_SPEC(this)) {
2581                 SpectatorThink(this);
2582         }
2583
2584         // WEAPONTODO: Add weapon request for this
2585         if (!zoomstate_set) {
2586                 bool wep_zoomed = false;
2587                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2588                 {
2589                         .entity weaponentity = weaponentities[slot];
2590                         Weapon thiswep = this.(weaponentity).m_weapon;
2591                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2592                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2593                 }
2594                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2595     }
2596
2597         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2598         {
2599                 CS(this).teamkill_soundtime = 0;
2600
2601                 entity e = CS(this).teamkill_soundsource;
2602                 entity oldpusher = e.pusher;
2603                 e.pusher = this;
2604                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2605                 e.pusher = oldpusher;
2606         }
2607
2608         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2609                 CS(this).taunt_soundtime = 0;
2610                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2611         }
2612
2613         target_voicescript_next(this);
2614
2615         // WEAPONTODO: Move into weaponsystem somehow
2616         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2617         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2618         {
2619                 .entity weaponentity = weaponentities[slot];
2620                 if(this.(weaponentity).m_weapon == WEP_Null)
2621                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2622         }
2623 }
2624
2625 void DrownPlayer(entity this)
2626 {
2627         if(IS_DEAD(this))
2628                 return;
2629
2630         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2631         {
2632                 if(this.air_finished < time)
2633                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2634                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2635                 this.dmg = 2;
2636         }
2637         else if (this.air_finished < time)
2638         {       // drown!
2639                 if (this.pain_finished < time)
2640                 {
2641                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2642                         this.pain_finished = time + 0.5;
2643                 }
2644         }
2645 }
2646
2647 .bool move_qcphysics;
2648
2649 void Player_Physics(entity this)
2650 {
2651         set_movetype(this, this.move_movetype);
2652
2653         if(!this.move_qcphysics)
2654                 return;
2655
2656         if(!frametime && !CS(this).pm_frametime)
2657                 return;
2658
2659         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2660
2661         CS(this).pm_frametime = 0;
2662 }
2663
2664 /*
2665 =============
2666 PlayerPostThink
2667
2668 Called every frame for each client after the physics are run
2669 =============
2670 */
2671 void PlayerPostThink (entity this)
2672 {
2673         Player_Physics(this);
2674
2675         if (sv_maxidle > 0)
2676         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2677         if (IS_REAL_CLIENT(this))
2678         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2679         {
2680                 int totalClients = 0;
2681                 if(sv_maxidle_slots > 0)
2682                 {
2683                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2684                         {
2685                                 ++totalClients;
2686                         });
2687                 }
2688
2689                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2690                 { /* do nothing */ }
2691                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2692                 {
2693                         if (CS(this).idlekick_lasttimeleft)
2694                         {
2695                                 CS(this).idlekick_lasttimeleft = 0;
2696                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2697                         }
2698                 }
2699                 else
2700                 {
2701                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2702                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2703                                 if (!CS(this).idlekick_lasttimeleft)
2704                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2705                         }
2706                         if (timeleft <= 0) {
2707                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2708                                 dropclient(this);
2709                                 return;
2710                         }
2711                         else if (timeleft <= 10) {
2712                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2713                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2714                 }
2715                                 CS(this).idlekick_lasttimeleft = timeleft;
2716                         }
2717                 }
2718         }
2719
2720         CheatFrame(this);
2721
2722         if (game_stopped)
2723         {
2724                 this.solid = SOLID_NOT;
2725                 this.takedamage = DAMAGE_NO;
2726                 set_movetype(this, MOVETYPE_NONE);
2727         }
2728
2729         if (IS_PLAYER(this)) {
2730                 DrownPlayer(this);
2731                 UpdateChatBubble(this);
2732                 if (CS(this).impulse) ImpulseCommands(this);
2733                 if (game_stopped)
2734                 {
2735                         CSQCMODEL_AUTOUPDATE(this);
2736                         return;
2737                 }
2738                 GetPressedKeys(this);
2739         }
2740
2741         if (this.waypointsprite_attachedforcarrier) {
2742             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2743                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2744     }
2745
2746         playerdemo_write(this);
2747
2748         CSQCMODEL_AUTOUPDATE(this);
2749 }
2750
2751 // hack to copy the button fields from the client entity to the Client State
2752 void PM_UpdateButtons(entity this, entity store)
2753 {
2754         if(this.impulse)
2755                 store.impulse = this.impulse;
2756         this.impulse = 0;
2757
2758         store.button0 = this.button0;
2759         store.button2 = this.button2;
2760         store.button3 = this.button3;
2761         store.button4 = this.button4;
2762         store.button5 = this.button5;
2763         store.button6 = this.button6;
2764         store.button7 = this.button7;
2765         store.button8 = this.button8;
2766         store.button9 = this.button9;
2767         store.button10 = this.button10;
2768         store.button11 = this.button11;
2769         store.button12 = this.button12;
2770         store.button13 = this.button13;
2771         store.button14 = this.button14;
2772         store.button15 = this.button15;
2773         store.button16 = this.button16;
2774         store.buttonuse = this.buttonuse;
2775         store.buttonchat = this.buttonchat;
2776
2777         store.cursor_active = this.cursor_active;
2778         store.cursor_screen = this.cursor_screen;
2779         store.cursor_trace_start = this.cursor_trace_start;
2780         store.cursor_trace_endpos = this.cursor_trace_endpos;
2781         store.cursor_trace_ent = this.cursor_trace_ent;
2782
2783         store.ping = this.ping;
2784         store.ping_packetloss = this.ping_packetloss;
2785         store.ping_movementloss = this.ping_movementloss;
2786
2787         store.v_angle = this.v_angle;
2788         store.movement = this.movement;
2789 }