qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (CS(to).spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (CS(e).zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 void SetSpectatee(entity this, entity spectatee);
 158 void SetSpectatee_status(entity this, int spectatee_num);
 159
 160
 161 /*
 162 =============
 163 CheckPlayerModel
 164
 165 Checks if the argument string can be a valid playermodel.
 166 Returns a valid one in doubt.
 167 =============
 168 */
 169 string FallbackPlayerModel;
 170 string CheckPlayerModel(string plyermodel) {
 171         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 172         {
 173                 // note: we cannot summon Don Strunzone here, some player may
 174                 // still have the model string set. In case anyone manages how
 175                 // to change a cvar default, we'll have a small leak here.
 176                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 177         }
 178         // only in right path
 179         if( substring(plyermodel,0,14) != "models/player/")
 180                 return FallbackPlayerModel;
 181         // only good file extensions
 182         if(substring(plyermodel,-4,4) != ".zym")
 183         if(substring(plyermodel,-4,4) != ".dpm")
 184         if(substring(plyermodel,-4,4) != ".iqm")
 185         if(substring(plyermodel,-4,4) != ".md3")
 186         if(substring(plyermodel,-4,4) != ".psk")
 187                 return FallbackPlayerModel;
 188         // forbid the LOD models
 189         if(substring(plyermodel, -9,5) == "_lod1")
 190                 return FallbackPlayerModel;
 191         if(substring(plyermodel, -9,5) == "_lod2")
 192                 return FallbackPlayerModel;
 193         if(plyermodel != strtolower(plyermodel))
 194                 return FallbackPlayerModel;
 195         // also, restrict to server models
 196         if(autocvar_sv_servermodelsonly)
 197         {
 198                 if(!fexists(plyermodel))
 199                         return FallbackPlayerModel;
 200         }
 201         return plyermodel;
 202 }
 203
 204 void setplayermodel(entity e, string modelname)
 205 {
 206         precache_model(modelname);
 207         _setmodel(e, modelname);
 208         player_setupanimsformodel(e);
 209         if(!autocvar_g_debug_globalsounds)
 210                 UpdatePlayerSounds(e);
 211 }
 212
 213 void FixPlayermodel(entity player);
 214 /** putting a client as observer in the server */
 215 void PutObserverInServer(entity this)
 216 {
 217     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 218         PlayerState_detach(this);
 219
 220         if (IS_PLAYER(this) && this.health >= 1) {
 221         // despawn effect
 222                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 223     }
 224
 225     {
 226         entity spot = SelectSpawnPoint(this, true);
 227         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 228         this.angles = spot.angles;
 229         this.angles_z = 0;
 230         this.fixangle = true;
 231         // offset it so that the spectator spawns higher off the ground, looks better this way
 232         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 233         this.prevorigin = this.origin;
 234         if (IS_REAL_CLIENT(this))
 235         {
 236             msg_entity = this;
 237             WriteByte(MSG_ONE, SVC_SETVIEW);
 238             WriteEntity(MSG_ONE, this);
 239         }
 240         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 241         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 242         if(!autocvar_g_debug_globalsounds)
 243         {
 244                 // needed for player sounds
 245                 this.model = "";
 246                 FixPlayermodel(this);
 247         }
 248         setmodel(this, MDL_Null);
 249         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 250         this.view_ofs = '0 0 0';
 251     }
 252
 253     RemoveGrapplingHooks(this);
 254         Portal_ClearAll(this);
 255         Unfreeze(this);
 256         SetSpectatee(this, NULL);
 257
 258         if (this.alivetime)
 259         {
 260                 if (!warmup_stage)
 261                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 262                 this.alivetime = 0;
 263         }
 264
 265         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 266
 267         WaypointSprite_PlayerDead(this);
 268
 269         if (mutator_returnvalue) {
 270             // mutator prevents resetting teams+score
 271         } else {
 272                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 273         this.frags = FRAGS_SPECTATOR;
 274         PlayerScore_Clear(this);  // clear scores when needed
 275     }
 276
 277         if (CS(this).killcount != FRAGS_SPECTATOR)
 278         {
 279                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 280                 if(!game_stopped)
 281                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 282                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 283
 284                 if(this.just_joined == false) {
 285                         LogTeamchange(this.playerid, -1, 4);
 286                 } else
 287                         this.just_joined = false;
 288         }
 289
 290         accuracy_resend(this);
 291
 292         CS(this).spectatortime = time;
 293         if(this.bot_attack)
 294                 IL_REMOVE(g_bot_targets, this);
 295         this.bot_attack = false;
 296     this.hud = HUD_NORMAL;
 297         TRANSMUTE(Observer, this);
 298         this.iscreature = false;
 299         this.teleportable = TELEPORT_SIMPLE;
 300         if(this.damagedbycontents)
 301                 IL_REMOVE(g_damagedbycontents, this);
 302         this.damagedbycontents = false;
 303         this.health = FRAGS_SPECTATOR;
 304         SetSpectatee_status(this, etof(this));
 305         this.takedamage = DAMAGE_NO;
 306         this.solid = SOLID_NOT;
 307         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 308         this.flags = FL_CLIENT | FL_NOTARGET;
 309         this.armorvalue = 666;
 310         this.effects = 0;
 311         this.armorvalue = autocvar_g_balance_armor_start;
 312         this.pauserotarmor_finished = 0;
 313         this.pauserothealth_finished = 0;
 314         this.pauseregen_finished = 0;
 315         this.damageforcescale = 0;
 316         this.death_time = 0;
 317         this.respawn_flags = 0;
 318         this.respawn_time = 0;
 319         this.stat_respawn_time = 0;
 320         this.alpha = 0;
 321         this.scale = 0;
 322         this.fade_time = 0;
 323         this.pain_frame = 0;
 324         this.pain_finished = 0;
 325         this.strength_finished = 0;
 326         this.invincible_finished = 0;
 327         this.superweapons_finished = 0;
 328         this.pushltime = 0;
 329         this.istypefrag = 0;
 330         setthink(this, func_null);
 331         this.nextthink = 0;
 332         this.deadflag = DEAD_NO;
 333         this.crouch = false;
 334         this.revive_progress = 0;
 335         this.revival_time = 0;
 336
 337         this.items = 0;
 338         this.weapons = '0 0 0';
 339         this.dual_weapons = '0 0 0';
 340         this.drawonlytoclient = this;
 341
 342         this.weaponmodel = "";
 343         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 344         {
 345                 this.weaponentities[slot] = NULL;
 346         }
 347         this.exteriorweaponentity = NULL;
 348         CS(this).killcount = FRAGS_SPECTATOR;
 349         this.velocity = '0 0 0';
 350         this.avelocity = '0 0 0';
 351         this.punchangle = '0 0 0';
 352         this.punchvector = '0 0 0';
 353         this.oldvelocity = this.velocity;
 354         this.fire_endtime = -1;
 355         this.event_damage = func_null;
 356
 357         for(int slot = 0; slot < MAX_AXH; ++slot)
 358         {
 359                 entity axh = this.(AuxiliaryXhair[slot]);
 360                 this.(AuxiliaryXhair[slot]) = NULL;
 361
 362                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 363                         delete(axh);
 364         }
 365 }
 366
 367 int player_getspecies(entity this)
 368 {
 369         get_model_parameters(this.model, this.skin);
 370         int s = get_model_parameters_species;
 371         get_model_parameters(string_null, 0);
 372         if (s < 0) return SPECIES_HUMAN;
 373         return s;
 374 }
 375
 376 .float model_randomizer;
 377 void FixPlayermodel(entity player)
 378 {
 379         string defaultmodel = "";
 380         int defaultskin = 0;
 381         if(autocvar_sv_defaultcharacter)
 382         {
 383                 if(teamplay)
 384                 {
 385                         switch(player.team)
 386                         {
 387                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 388                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 389                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 390                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 391                         }
 392                 }
 393
 394                 if(defaultmodel == "")
 395                 {
 396                         defaultmodel = autocvar_sv_defaultplayermodel;
 397                         defaultskin = autocvar_sv_defaultplayerskin;
 398                 }
 399
 400                 int n = tokenize_console(defaultmodel);
 401                 if(n > 0)
 402                 {
 403                         defaultmodel = argv(floor(n * player.model_randomizer));
 404                         // However, do NOT randomize if the player-selected model is in the list.
 405                         for (int i = 0; i < n; ++i)
 406                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 407                                         defaultmodel = argv(i);
 408                 }
 409
 410                 int i = strstrofs(defaultmodel, ":", 0);
 411                 if(i >= 0)
 412                 {
 413                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 414                         defaultmodel = substring(defaultmodel, 0, i);
 415                 }
 416         }
 417         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(!defaultskin)
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432         }
 433
 434         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 435         defaultmodel = M_ARGV(0, string);
 436         defaultskin = M_ARGV(1, int);
 437
 438         bool chmdl = false;
 439         int oldskin;
 440         if(defaultmodel != "")
 441         {
 442                 if (defaultmodel != player.model)
 443                 {
 444                         vector m1 = player.mins;
 445                         vector m2 = player.maxs;
 446                         setplayermodel (player, defaultmodel);
 447                         setsize (player, m1, m2);
 448                         chmdl = true;
 449                 }
 450
 451                 oldskin = player.skin;
 452                 player.skin = defaultskin;
 453         } else {
 454                 if (player.playermodel != player.model || player.playermodel == "")
 455                 {
 456                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 457                         vector m1 = player.mins;
 458                         vector m2 = player.maxs;
 459                         setplayermodel (player, player.playermodel);
 460                         setsize (player, m1, m2);
 461                         chmdl = true;
 462                 }
 463
 464                 if(!autocvar_sv_defaultcharacterskin)
 465                 {
 466                         oldskin = player.skin;
 467                         player.skin = stof(player.playerskin);
 468                 }
 469                 else
 470                 {
 471                         oldskin = player.skin;
 472                         player.skin = defaultskin;
 473                 }
 474         }
 475
 476         if(chmdl || oldskin != player.skin) // model or skin has changed
 477         {
 478                 player.species = player_getspecies(player); // update species
 479                 if(!autocvar_g_debug_globalsounds)
 480                         UpdatePlayerSounds(player); // update skin sounds
 481         }
 482
 483         if(!teamplay)
 484                 if(strlen(autocvar_sv_defaultplayercolors))
 485                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 486                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 487 }
 488
 489 void PutPlayerInServer(entity this)
 490 {
 491         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 492
 493         PlayerState_attach(this);
 494         accuracy_resend(this);
 495
 496         if (this.team < 0)
 497                 JoinBestTeam(this, false, true);
 498
 499         entity spot = SelectSpawnPoint(this, false);
 500         if (!spot) {
 501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 502                 return; // spawn failed
 503         }
 504
 505         TRANSMUTE(Player, this);
 506
 507         this.wasplayer = true;
 508         this.iscreature = true;
 509         this.teleportable = TELEPORT_NORMAL;
 510         if(!this.damagedbycontents)
 511                 IL_PUSH(g_damagedbycontents, this);
 512         this.damagedbycontents = true;
 513         set_movetype(this, MOVETYPE_WALK);
 514         this.solid = SOLID_SLIDEBOX;
 515         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 516         if (autocvar_g_playerclip_collisions)
 517                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 518         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 519                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 520         this.frags = FRAGS_PLAYER;
 521         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 522         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 523         if (autocvar__notarget)
 524                 this.flags |= FL_NOTARGET;
 525         this.takedamage = DAMAGE_AIM;
 526         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 527         this.dmg = 2; // WTF
 528
 529         if (warmup_stage) {
 530                 this.ammo_shells = warmup_start_ammo_shells;
 531                 this.ammo_nails = warmup_start_ammo_nails;
 532                 this.ammo_rockets = warmup_start_ammo_rockets;
 533                 this.ammo_cells = warmup_start_ammo_cells;
 534                 this.ammo_plasma = warmup_start_ammo_plasma;
 535                 this.ammo_fuel = warmup_start_ammo_fuel;
 536                 this.health = warmup_start_health;
 537                 this.armorvalue = warmup_start_armorvalue;
 538                 this.weapons = WARMUP_START_WEAPONS;
 539         } else {
 540                 this.ammo_shells = start_ammo_shells;
 541                 this.ammo_nails = start_ammo_nails;
 542                 this.ammo_rockets = start_ammo_rockets;
 543                 this.ammo_cells = start_ammo_cells;
 544                 this.ammo_plasma = start_ammo_plasma;
 545                 this.ammo_fuel = start_ammo_fuel;
 546                 this.health = start_health;
 547                 this.armorvalue = start_armorvalue;
 548                 this.weapons = start_weapons;
 549         }
 550         SetSpectatee_status(this, 0);
 551
 552         this.dual_weapons = '0 0 0';
 553
 554         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 555
 556         this.items = start_items;
 557
 558         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 559         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 560         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 561         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 562         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 563         // extend the pause of rotting if client was reset at the beginning of the countdown
 564         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 565                 float f = game_starttime - time;
 566                 this.spawnshieldtime += f;
 567                 this.pauserotarmor_finished += f;
 568                 this.pauserothealth_finished += f;
 569                 this.pauseregen_finished += f;
 570         }
 571         this.damageforcescale = 2;
 572         this.death_time = 0;
 573         this.respawn_flags = 0;
 574         this.respawn_time = 0;
 575         this.stat_respawn_time = 0;
 576         this.scale = autocvar_sv_player_scale;
 577         this.fade_time = 0;
 578         this.pain_frame = 0;
 579         this.pain_finished = 0;
 580         this.pushltime = 0;
 581         setthink(this, func_null); // players have no think function
 582         this.nextthink = 0;
 583         this.dmg_team = 0;
 584         this.ballistics_density = autocvar_g_ballistics_density_player;
 585
 586         this.deadflag = DEAD_NO;
 587
 588         this.angles = spot.angles;
 589         this.angles_z = 0; // never spawn tilted even if the spot says to
 590         if (IS_BOT_CLIENT(this))
 591                 this.v_angle = this.angles;
 592         this.fixangle = true; // turn this way immediately
 593         this.oldvelocity = this.velocity = '0 0 0';
 594         this.avelocity = '0 0 0';
 595         this.punchangle = '0 0 0';
 596         this.punchvector = '0 0 0';
 597
 598         this.strength_finished = 0;
 599         this.invincible_finished = 0;
 600         this.fire_endtime = -1;
 601         this.revive_progress = 0;
 602         this.revival_time = 0;
 603         this.air_finished = time + 12;
 604
 605         entity spawnevent = new_pure(spawnevent);
 606         spawnevent.owner = this;
 607         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 608
 609         // Cut off any still running player sounds.
 610         stopsound(this, CH_PLAYER_SINGLE);
 611
 612         this.model = "";
 613         FixPlayermodel(this);
 614         this.drawonlytoclient = NULL;
 615
 616         this.viewloc = NULL;
 617
 618         this.crouch = false;
 619         this.view_ofs = STAT(PL_VIEW_OFS, this);
 620         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 621         this.spawnorigin = spot.origin;
 622         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 623         // don't reset back to last position, even if new position is stuck in solid
 624         this.oldorigin = this.origin;
 625         this.prevorigin = this.origin;
 626         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 627         if(this.conveyor)
 628                 IL_REMOVE(g_conveyed, this);
 629         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 630         this.hud = HUD_NORMAL;
 631
 632         this.event_damage = PlayerDamage;
 633
 634         if(!this.bot_attack)
 635                 IL_PUSH(g_bot_targets, this);
 636         this.bot_attack = true;
 637         if(!this.monster_attack)
 638                 IL_PUSH(g_monster_targets, this);
 639         this.monster_attack = true;
 640         navigation_dynamicgoal_init(this, false);
 641
 642         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 643
 644         if (CS(this).killcount == FRAGS_SPECTATOR) {
 645                 PlayerScore_Clear(this);
 646                 CS(this).killcount = 0;
 647         }
 648
 649         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 650         {
 651                 .entity weaponentity = weaponentities[slot];
 652                 entity oldwep = this.(weaponentity);
 653                 CL_SpawnWeaponentity(this, weaponentity);
 654                 if(oldwep && oldwep.owner == this)
 655                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 656         }
 657         this.alpha = default_player_alpha;
 658         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 659         this.exteriorweaponentity.alpha = default_weapon_alpha;
 660
 661         this.speedrunning = false;
 662
 663         target_voicescript_clear(this);
 664
 665         // reset fields the weapons may use
 666         FOREACH(Weapons, true, LAMBDA(
 667                 it.wr_resetplayer(it, this);
 668                         // reload all reloadable weapons
 669                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 670                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 671                         {
 672                                 .entity weaponentity = weaponentities[slot];
 673                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 674                         }
 675                 }
 676         ));
 677
 678         {
 679                 string s = spot.target;
 680                 spot.target = string_null;
 681                 SUB_UseTargets(spot, this, NULL);
 682                 spot.target = s;
 683         }
 684
 685         Unfreeze(this);
 686
 687         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 688
 689         if (autocvar_spawn_debug)
 690         {
 691                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 692                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 693         }
 694
 695         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 696         {
 697                 .entity weaponentity = weaponentities[slot];
 698                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 699                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 700                 else
 701                         this.(weaponentity).m_switchweapon = WEP_Null;
 702                 this.(weaponentity).m_weapon = WEP_Null;
 703                 this.(weaponentity).weaponname = "";
 704                 this.(weaponentity).m_switchingweapon = WEP_Null;
 705                 this.(weaponentity).cnt = -1;
 706         }
 707
 708         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 709
 710         if (!warmup_stage && !this.alivetime)
 711                 this.alivetime = time;
 712
 713         antilag_clear(this, CS(this));
 714 }
 715
 716 /** Called when a client spawns in the server */
 717 void PutClientInServer(entity this)
 718 {
 719         if (IS_BOT_CLIENT(this)) {
 720                 TRANSMUTE(Player, this);
 721         } else if (IS_REAL_CLIENT(this)) {
 722                 msg_entity = this;
 723                 WriteByte(MSG_ONE, SVC_SETVIEW);
 724                 WriteEntity(MSG_ONE, this);
 725         }
 726         if (game_stopped)
 727                 TRANSMUTE(Observer, this);
 728
 729         SetSpectatee(this, NULL);
 730
 731         // reset player keys
 732         this.itemkeys = 0;
 733
 734         MUTATOR_CALLHOOK(PutClientInServer, this);
 735
 736         if (IS_OBSERVER(this)) {
 737                 PutObserverInServer(this);
 738         } else if (IS_PLAYER(this)) {
 739                 PutPlayerInServer(this);
 740         }
 741 }
 742
 743 void ClientInit_misc(entity this);
 744
 745 // TODO do we need all these fields, or should we stop autodetecting runtime
 746 // changes and just have a console command to update this?
 747 bool ClientInit_SendEntity(entity this, entity to, int sf)
 748 {
 749         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 750         return = true;
 751         msg_entity = to;
 752         // MSG_INIT replacement
 753         // TODO: make easier to use
 754         Registry_send_all();
 755         W_PROP_reload(MSG_ONE, to);
 756         ClientInit_misc(this);
 757         MUTATOR_CALLHOOK(Ent_Init);
 758 }
 759 void ClientInit_misc(entity this)
 760 {
 761         int channel = MSG_ONE;
 762         WriteHeader(channel, ENT_CLIENT_INIT);
 763         WriteByte(channel, g_nexball_meter_period * 32);
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 766         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 767         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 770         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 771         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 772
 773         if(sv_foginterval && world.fog != "")
 774                 WriteString(channel, world.fog);
 775         else
 776                 WriteString(channel, "");
 777         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 778         WriteByte(channel, serverflags);
 779         WriteCoord(channel, autocvar_g_trueaim_minrange);
 780 }
 781
 782 void ClientInit_CheckUpdate(entity this)
 783 {
 784         this.nextthink = time;
 785         if(this.count != autocvar_g_balance_armor_blockpercent)
 786         {
 787                 this.count = autocvar_g_balance_armor_blockpercent;
 788                 this.SendFlags |= 1;
 789         }
 790 }
 791
 792 void ClientInit_Spawn()
 793 {
 794         entity e = new_pure(clientinit);
 795         setthink(e, ClientInit_CheckUpdate);
 796         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 797
 798         ClientInit_CheckUpdate(e);
 799 }
 800
 801 /*
 802 =============
 803 SetNewParms
 804 =============
 805 */
 806 void SetNewParms ()
 807 {
 808         // initialize parms for a new player
 809         parm1 = -(86400 * 366);
 810
 811         MUTATOR_CALLHOOK(SetNewParms);
 812 }
 813
 814 /*
 815 =============
 816 SetChangeParms
 817 =============
 818 */
 819 void SetChangeParms (entity this)
 820 {
 821         // save parms for level change
 822         parm1 = CS(this).parm_idlesince - time;
 823
 824         MUTATOR_CALLHOOK(SetChangeParms);
 825 }
 826
 827 /*
 828 =============
 829 DecodeLevelParms
 830 =============
 831 */
 832 void DecodeLevelParms(entity this)
 833 {
 834         // load parms
 835         CS(this).parm_idlesince = parm1;
 836         if (CS(this).parm_idlesince == -(86400 * 366))
 837                 CS(this).parm_idlesince = time;
 838
 839         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 840         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 841
 842         MUTATOR_CALLHOOK(DecodeLevelParms);
 843 }
 844
 845 /*
 846 =============
 847 ClientKill
 848
 849 Called when a client types 'kill' in the console
 850 =============
 851 */
 852
 853 .float clientkill_nexttime;
 854 void ClientKill_Now_TeamChange(entity this)
 855 {
 856         if(CS(this).killindicator_teamchange == -1)
 857         {
 858                 JoinBestTeam( this, false, true );
 859         }
 860         else if(CS(this).killindicator_teamchange == -2)
 861         {
 862                 if(blockSpectators)
 863                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 864                 PutObserverInServer(this);
 865         }
 866         else
 867                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 868         CS(this).killindicator_teamchange = 0;
 869 }
 870
 871 void ClientKill_Now(entity this)
 872 {
 873         if(this.vehicle)
 874         {
 875             vehicles_exit(this.vehicle, VHEF_RELEASE);
 876             if(!CS(this).killindicator_teamchange)
 877             {
 878             this.vehicle_health = -1;
 879             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 880             }
 881         }
 882
 883         if(this.killindicator && !wasfreed(this.killindicator))
 884                 delete(this.killindicator);
 885
 886         this.killindicator = NULL;
 887
 888         if(CS(this).killindicator_teamchange)
 889                 ClientKill_Now_TeamChange(this);
 890
 891         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 892                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 893
 894         // now I am sure the player IS dead
 895 }
 896 void KillIndicator_Think(entity this)
 897 {
 898         if (game_stopped)
 899         {
 900                 this.owner.killindicator = NULL;
 901                 delete(this);
 902                 return;
 903         }
 904
 905         if (this.owner.alpha < 0 && !this.owner.vehicle)
 906         {
 907                 this.owner.killindicator = NULL;
 908                 delete(this);
 909                 return;
 910         }
 911
 912         if(this.cnt <= 0)
 913         {
 914                 ClientKill_Now(this.owner);
 915                 return;
 916         }
 917     else if(this.health == 1) // health == 1 means that it's silent
 918     {
 919         this.nextthink = time + 1;
 920         this.cnt -= 1;
 921     }
 922         else
 923         {
 924                 if(this.cnt <= 10)
 925                         setmodel(this, MDL_NUM(this.cnt));
 926                 if(IS_REAL_CLIENT(this.owner))
 927                 {
 928                         if(this.cnt <= 10)
 929                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 930                 }
 931                 this.nextthink = time + 1;
 932                 this.cnt -= 1;
 933         }
 934 }
 935
 936 float clientkilltime;
 937 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 938 {
 939         float killtime;
 940         float starttime;
 941
 942         if (game_stopped)
 943                 return;
 944
 945         killtime = autocvar_g_balance_kill_delay;
 946
 947     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 948         return;
 949     killtime = M_ARGV(1, float);
 950
 951         CS(this).killindicator_teamchange = targetteam;
 952
 953     if(!this.killindicator)
 954         {
 955                 if(!IS_DEAD(this))
 956                 {
 957                         killtime = max(killtime, this.clientkill_nexttime - time);
 958                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 959                 }
 960
 961                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 962                 {
 963                         ClientKill_Now(this);
 964                 }
 965                 else
 966                 {
 967                         starttime = max(time, clientkilltime);
 968
 969                         this.killindicator = spawn();
 970                         this.killindicator.owner = this;
 971                         this.killindicator.scale = 0.5;
 972                         setattachment(this.killindicator, this, "");
 973                         setorigin(this.killindicator, '0 0 52');
 974                         setthink(this.killindicator, KillIndicator_Think);
 975                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 976                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 977                         this.killindicator.cnt = ceil(killtime);
 978                         this.killindicator.count = bound(0, ceil(killtime), 10);
 979                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 980
 981                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 982                         {
 983                                 it.killindicator = spawn();
 984                                 it.killindicator.owner = it;
 985                                 it.killindicator.scale = 0.5;
 986                                 setattachment(it.killindicator, it, "");
 987                                 setorigin(it.killindicator, '0 0 52');
 988                                 setthink(it.killindicator, KillIndicator_Think);
 989                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 990                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 991                                 it.killindicator.cnt = ceil(killtime);
 992                         });
 993                         this.lip = 0;
 994                 }
 995         }
 996         if(this.killindicator)
 997         {
 998                 if(targetteam == 0) // just die
 999                 {
1000                         this.killindicator.colormod = '0 0 0';
1001                         if(IS_REAL_CLIENT(this))
1002                         if(this.killindicator.cnt > 0)
1003                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1004                 }
1005                 else if(targetteam == -1) // auto
1006                 {
1007                         this.killindicator.colormod = '0 1 0';
1008                         if(IS_REAL_CLIENT(this))
1009                         if(this.killindicator.cnt > 0)
1010                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1011                 }
1012                 else if(targetteam == -2) // spectate
1013                 {
1014                         this.killindicator.colormod = '0.5 0.5 0.5';
1015                         if(IS_REAL_CLIENT(this))
1016                         if(this.killindicator.cnt > 0)
1017                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1018                 }
1019                 else
1020                 {
1021                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1022                         if(IS_REAL_CLIENT(this))
1023                         if(this.killindicator.cnt > 0)
1024                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1025                 }
1026         }
1027
1028 }
1029
1030 void ClientKill (entity this)
1031 {
1032         if(game_stopped) return;
1033         if(this.player_blocked) return;
1034         if(STAT(FROZEN, this)) return;
1035
1036         ClientKill_TeamChange(this, 0);
1037 }
1038
1039 void FixClientCvars(entity e)
1040 {
1041         // send prediction settings to the client
1042         stuffcmd(e, "\nin_bindmap 0 0\n");
1043         if(autocvar_g_antilag == 3) // client side hitscan
1044                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1045         if(autocvar_sv_gentle)
1046                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1047
1048         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1049         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1050
1051         MUTATOR_CALLHOOK(FixClientCvars, e);
1052 }
1053
1054 bool findinlist_abbrev(string tofind, string list)
1055 {
1056         if(list == "" || tofind == "")
1057                 return false; // empty list or search, just return
1058
1059         // this function allows abbreviated strings!
1060         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1061         {
1062                 return true;
1063         });
1064
1065         return false;
1066 }
1067
1068 bool PlayerInIPList(entity p, string iplist)
1069 {
1070         // some safety checks (never allow local?)
1071         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1072                 return false;
1073
1074         return findinlist_abbrev(p.netaddress, iplist);
1075 }
1076
1077 bool PlayerInIDList(entity p, string idlist)
1078 {
1079         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1080         if(!p.crypto_idfp)
1081                 return false;
1082
1083         return findinlist_abbrev(p.crypto_idfp, idlist);
1084 }
1085
1086 bool PlayerInList(entity player, string list)
1087 {
1088         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1089 }
1090
1091 #ifdef DP_EXT_PRECONNECT
1092 /*
1093 =============
1094 ClientPreConnect
1095
1096 Called once (not at each match start) when a client begins a connection to the server
1097 =============
1098 */
1099 void ClientPreConnect(entity this)
1100 {
1101         if(autocvar_sv_eventlog)
1102         {
1103                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1104                         this.playerid,
1105                         etof(this),
1106                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1107                 ));
1108         }
1109 }
1110 #endif
1111
1112 /**
1113 =============
1114 ClientConnect
1115
1116 Called when a client connects to the server
1117 =============
1118 */
1119 void ClientConnect(entity this)
1120 {
1121         if (Ban_MaybeEnforceBanOnce(this)) return;
1122         assert(!IS_CLIENT(this), return);
1123         this.flags |= FL_CLIENT;
1124         assert(player_count >= 0, player_count = 0);
1125
1126 #ifdef WATERMARK
1127         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1128 #endif
1129         TRANSMUTE(Client, this);
1130         CS(this).version_nagtime = time + 10 + random() * 10;
1131
1132         // identify the right forced team
1133         if (autocvar_g_campaign)
1134         {
1135                 if (IS_REAL_CLIENT(this)) // only players, not bots
1136                 {
1137                         switch (autocvar_g_campaign_forceteam)
1138                         {
1139                                 case 1: this.team_forced = NUM_TEAM_1; break;
1140                                 case 2: this.team_forced = NUM_TEAM_2; break;
1141                                 case 3: this.team_forced = NUM_TEAM_3; break;
1142                                 case 4: this.team_forced = NUM_TEAM_4; break;
1143                                 default: this.team_forced = 0;
1144                         }
1145                 }
1146         }
1147         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1148         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1149         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1150         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1151         else switch (autocvar_g_forced_team_otherwise)
1152         {
1153                 default: this.team_forced = 0; break;
1154                 case "red": this.team_forced = NUM_TEAM_1; break;
1155                 case "blue": this.team_forced = NUM_TEAM_2; break;
1156                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1157                 case "pink": this.team_forced = NUM_TEAM_4; break;
1158                 case "spectate":
1159                 case "spectator":
1160                         this.team_forced = -1;
1161                         break;
1162         }
1163         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1164
1165     {
1166         int id = this.playerid;
1167         this.playerid = 0; // silent
1168             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1169             this.playerid = id;
1170     }
1171
1172         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1173                 TRANSMUTE(Observer, this);
1174         } else {
1175                 if (!teamplay || autocvar_g_balance_teams) {
1176                         TRANSMUTE(Player, this);
1177                         campaign_bots_may_start = true;
1178                 } else {
1179                         TRANSMUTE(Observer, this); // do it anyway
1180                 }
1181         }
1182
1183         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1184
1185         // always track bots, don't ask for cl_allow_uidtracking
1186     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1187
1188         if (autocvar_sv_eventlog)
1189                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1190
1191         LogTeamchange(this.playerid, this.team, 1);
1192
1193         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1194
1195         CS(this).netname_previous = strzone(this.netname);
1196
1197         if(teamplay && IS_PLAYER(this))
1198                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1199         else
1200                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1201
1202         stuffcmd(this, clientstuff, "\n");
1203         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1204
1205         FixClientCvars(this);
1206
1207         // get version info from player
1208         stuffcmd(this, "cmd clientversion $gameversion\n");
1209
1210         // notify about available teams
1211         if (teamplay)
1212         {
1213                 CheckAllowedTeams(this);
1214                 int t = 0;
1215                 if (c1 >= 0) t |= BIT(0);
1216                 if (c2 >= 0) t |= BIT(1);
1217                 if (c3 >= 0) t |= BIT(2);
1218                 if (c4 >= 0) t |= BIT(3);
1219                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1220         }
1221         else
1222         {
1223                 stuffcmd(this, "set _teams_available 0\n");
1224         }
1225
1226         bot_relinkplayerlist();
1227
1228         CS(this).spectatortime = time;
1229         if (blockSpectators)
1230         {
1231                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1232         }
1233
1234         CS(this).jointime = time;
1235         CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1236
1237         if (IS_REAL_CLIENT(this))
1238         {
1239                 if (g_weaponarena_weapons == WEPSET(TUBA))
1240                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1241         }
1242
1243         if (!sv_foginterval && world.fog != "")
1244                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1245
1246         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1247                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1248                         send_CSQC_teamnagger();
1249
1250         CSQCMODEL_AUTOINIT(this);
1251
1252         this.model_randomizer = random();
1253
1254         if (IS_REAL_CLIENT(this))
1255                 sv_notice_join(this);
1256
1257         // update physics stats (players can spawn before physics runs)
1258         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1259         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1260         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1261
1262         IL_EACH(g_initforplayer, it.init_for_player, {
1263                 it.init_for_player(it, this);
1264         });
1265
1266         MUTATOR_CALLHOOK(ClientConnect, this);
1267
1268         if (IS_REAL_CLIENT(this))
1269         {
1270                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1271                 {
1272                         CS(this).motd_actived_time = -1;
1273                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1274                 }
1275         }
1276 }
1277 /*
1278 =============
1279 ClientDisconnect
1280
1281 Called when a client disconnects from the server
1282 =============
1283 */
1284 .entity chatbubbleentity;
1285 void ReadyCount();
1286 void ClientDisconnect(entity this)
1287 {
1288         assert(IS_CLIENT(this), return);
1289
1290         PlayerStats_GameReport_FinalizePlayer(this);
1291         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1292         if (CS(this).active_minigame) part_minigame(this);
1293         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1294
1295         if (autocvar_sv_eventlog)
1296                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1297
1298         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1299
1300         if(IS_SPEC(this))
1301                 SetSpectatee(this, NULL);
1302
1303     MUTATOR_CALLHOOK(ClientDisconnect, this);
1304
1305         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1306         ClientState_detach(this);
1307
1308         Portal_ClearAll(this);
1309
1310         Unfreeze(this);
1311
1312         RemoveGrapplingHooks(this);
1313
1314         // Here, everything has been done that requires this player to be a client.
1315
1316         this.flags &= ~FL_CLIENT;
1317
1318         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1319         if (this.killindicator) delete(this.killindicator);
1320
1321         WaypointSprite_PlayerGone(this);
1322
1323         bot_relinkplayerlist();
1324
1325         if (this.clientstatus) strunzone(this.clientstatus);
1326         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1327         if (this.personal) delete(this.personal);
1328
1329         this.playerid = 0;
1330         ReadyCount();
1331         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1332
1333         ONREMOVE(this);
1334 }
1335
1336 void ChatBubbleThink(entity this)
1337 {
1338         this.nextthink = time;
1339         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1340         {
1341                 if(this.owner) // but why can that ever be NULL?
1342                         this.owner.chatbubbleentity = NULL;
1343                 delete(this);
1344                 return;
1345         }
1346
1347         this.mdl = "";
1348
1349         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1350         {
1351                 if ( CS(this.owner).active_minigame )
1352                         this.mdl = "models/sprites/minigame_busy.iqm";
1353                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1354                         this.mdl = "models/misc/chatbubble.spr";
1355         }
1356
1357         if ( this.model != this.mdl )
1358                 _setmodel(this, this.mdl);
1359
1360 }
1361
1362 void UpdateChatBubble(entity this)
1363 {
1364         if (this.alpha < 0)
1365                 return;
1366         // spawn a chatbubble entity if needed
1367         if (!this.chatbubbleentity)
1368         {
1369                 this.chatbubbleentity = new(chatbubbleentity);
1370                 this.chatbubbleentity.owner = this;
1371                 this.chatbubbleentity.exteriormodeltoclient = this;
1372                 setthink(this.chatbubbleentity, ChatBubbleThink);
1373                 this.chatbubbleentity.nextthink = time;
1374                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1375                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1376                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1377                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1378                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1379                 //this.chatbubbleentity.model = "";
1380                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1381         }
1382 }
1383
1384
1385 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1386 // added to the model skins
1387 /*void UpdateColorModHack()
1388 {
1389         float c;
1390         c = this.clientcolors & 15;
1391         // LordHavoc: only bothering to support white, green, red, yellow, blue
1392              if (!teamplay) this.colormod = '0 0 0';
1393         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1394         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1395         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1396         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1397         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1398         else this.colormod = '1 1 1';
1399 }*/
1400
1401 void respawn(entity this)
1402 {
1403         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1404         {
1405                 this.solid = SOLID_NOT;
1406                 this.takedamage = DAMAGE_NO;
1407                 set_movetype(this, MOVETYPE_FLY);
1408                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1409                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1410                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1411                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1412                 if(autocvar_g_respawn_ghosts_maxtime)
1413                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1414         }
1415
1416         CopyBody(this, 1);
1417
1418         this.effects |= EF_NODRAW; // prevent another CopyBody
1419         PutClientInServer(this);
1420 }
1421
1422 void play_countdown(entity this, float finished, Sound samp)
1423 {
1424     TC(Sound, samp);
1425         if(IS_REAL_CLIENT(this))
1426                 if(floor(finished - time - frametime) != floor(finished - time))
1427                         if(finished - time < 6)
1428                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1429 }
1430
1431 void player_powerups(entity this)
1432 {
1433         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1434         int items_prev = this.items;
1435
1436         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1437                 this.modelflags |= MF_ROCKET;
1438         else
1439                 this.modelflags &= ~MF_ROCKET;
1440
1441         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1442
1443         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1444                 return;
1445
1446         Fire_ApplyDamage(this);
1447         Fire_ApplyEffect(this);
1448
1449         if (!g_instagib)
1450         {
1451                 if (this.items & ITEM_Strength.m_itemid)
1452                 {
1453                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1454                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1455                         if (time > this.strength_finished)
1456                         {
1457                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1458                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1459                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1460                         }
1461                 }
1462                 else
1463                 {
1464                         if (time < this.strength_finished)
1465                         {
1466                                 this.items = this.items | ITEM_Strength.m_itemid;
1467                                 if(!g_cts)
1468                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1469                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1470                         }
1471                 }
1472                 if (this.items & ITEM_Shield.m_itemid)
1473                 {
1474                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1475                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1476                         if (time > this.invincible_finished)
1477                         {
1478                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1479                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1480                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1481                         }
1482                 }
1483                 else
1484                 {
1485                         if (time < this.invincible_finished)
1486                         {
1487                                 this.items = this.items | ITEM_Shield.m_itemid;
1488                                 if(!g_cts)
1489                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1490                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1491                         }
1492                 }
1493                 if (this.items & IT_SUPERWEAPON)
1494                 {
1495                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1496                         {
1497                                 this.superweapons_finished = 0;
1498                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1499                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1500                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1501                         }
1502                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1503                         {
1504                                 // don't let them run out
1505                         }
1506                         else
1507                         {
1508                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1509                                 if (time > this.superweapons_finished)
1510                                 {
1511                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1512                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1513                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1514                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1515                                 }
1516                         }
1517                 }
1518                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1519                 {
1520                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1521                         {
1522                                 this.items = this.items | IT_SUPERWEAPON;
1523                                 if(!g_cts)
1524                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1525                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1526                         }
1527                         else
1528                         {
1529                                 this.superweapons_finished = 0;
1530                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1531                         }
1532                 }
1533                 else
1534                 {
1535                         this.superweapons_finished = 0;
1536                 }
1537         }
1538
1539         if(autocvar_g_nodepthtestplayers)
1540                 this.effects = this.effects | EF_NODEPTHTEST;
1541
1542         if(autocvar_g_fullbrightplayers)
1543                 this.effects = this.effects | EF_FULLBRIGHT;
1544
1545         if (time >= game_starttime)
1546         if (time < this.spawnshieldtime)
1547                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1548
1549         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1550 }
1551
1552 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1553 {
1554         if(current > stable)
1555                 return current;
1556         else if(current > stable - 0.25) // when close enough, "snap"
1557                 return stable;
1558         else
1559                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1560 }
1561
1562 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1563 {
1564         if(current < stable)
1565                 return current;
1566         else if(current < stable + 0.25) // when close enough, "snap"
1567                 return stable;
1568         else
1569                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1570 }
1571
1572 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1573 {
1574         if(current > rotstable)
1575         {
1576                 if(rotframetime > 0)
1577                 {
1578                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1579                         current = max(rotstable, current - rotlinear * rotframetime);
1580                 }
1581         }
1582         else if(current < regenstable)
1583         {
1584                 if(regenframetime > 0)
1585                 {
1586                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1587                         current = min(regenstable, current + regenlinear * regenframetime);
1588                 }
1589         }
1590
1591         if(current > limit)
1592                 current = limit;
1593
1594         return current;
1595 }
1596
1597 void player_regen(entity this)
1598 {
1599         float max_mod, regen_mod, rot_mod, limit_mod;
1600         max_mod = regen_mod = rot_mod = limit_mod = 1;
1601
1602         float regen_health = autocvar_g_balance_health_regen;
1603         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1604         float regen_health_rot = autocvar_g_balance_health_rot;
1605         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1606         float regen_health_stable = autocvar_g_balance_health_regenstable;
1607         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1608         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1609                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1610         max_mod = M_ARGV(1, float);
1611         regen_mod = M_ARGV(2, float);
1612         rot_mod = M_ARGV(3, float);
1613         limit_mod = M_ARGV(4, float);
1614         regen_health = M_ARGV(5, float);
1615         regen_health_linear = M_ARGV(6, float);
1616         regen_health_rot = M_ARGV(7, float);
1617         regen_health_rotlinear = M_ARGV(8, float);
1618         regen_health_stable = M_ARGV(9, float);
1619         regen_health_rotstable = M_ARGV(10, float);
1620
1621
1622         if(!mutator_returnvalue)
1623         if(!STAT(FROZEN, this))
1624         {
1625                 float mina, maxa, limith, limita;
1626                 maxa = autocvar_g_balance_armor_rotstable;
1627                 mina = autocvar_g_balance_armor_regenstable;
1628                 limith = autocvar_g_balance_health_limit;
1629                 limita = autocvar_g_balance_armor_limit;
1630
1631                 regen_health_rotstable = regen_health_rotstable * max_mod;
1632                 regen_health_stable = regen_health_stable * max_mod;
1633                 limith = limith * limit_mod;
1634                 limita = limita * limit_mod;
1635
1636                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1637                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1638         }
1639
1640         // if player rotted to death...  die!
1641         // check this outside above checks, as player may still be able to rot to death
1642         if(this.health < 1)
1643         {
1644                 if(this.vehicle)
1645                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1646                 if(this.event_damage)
1647                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1648         }
1649
1650         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1651         {
1652                 float minf, maxf, limitf;
1653
1654                 maxf = autocvar_g_balance_fuel_rotstable;
1655                 minf = autocvar_g_balance_fuel_regenstable;
1656                 limitf = autocvar_g_balance_fuel_limit;
1657
1658                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1659         }
1660 }
1661
1662 bool zoomstate_set;
1663 void SetZoomState(entity this, float newzoom)
1664 {
1665         if(newzoom != CS(this).zoomstate)
1666         {
1667                 CS(this).zoomstate = newzoom;
1668                 ClientData_Touch(this);
1669         }
1670         zoomstate_set = true;
1671 }
1672
1673 void GetPressedKeys(entity this)
1674 {
1675         MUTATOR_CALLHOOK(GetPressedKeys, this);
1676         int keys = STAT(PRESSED_KEYS, this);
1677         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1678         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1679         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1680         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1681
1682         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1683         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1684         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1685         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1686         CS(this).pressedkeys = keys; // store for other users
1687
1688         STAT(PRESSED_KEYS, this) = keys;
1689 }
1690
1691 /*
1692 ======================
1693 spectate mode routines
1694 ======================
1695 */
1696
1697 void SpectateCopy(entity this, entity spectatee)
1698 {
1699     TC(Client, this); TC(Client, spectatee);
1700
1701         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1702         PS(this) = PS(spectatee);
1703         this.armortype = spectatee.armortype;
1704         this.armorvalue = spectatee.armorvalue;
1705         this.ammo_cells = spectatee.ammo_cells;
1706         this.ammo_plasma = spectatee.ammo_plasma;
1707         this.ammo_shells = spectatee.ammo_shells;
1708         this.ammo_nails = spectatee.ammo_nails;
1709         this.ammo_rockets = spectatee.ammo_rockets;
1710         this.ammo_fuel = spectatee.ammo_fuel;
1711         this.clip_load = spectatee.clip_load;
1712         this.clip_size = spectatee.clip_size;
1713         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1714         this.health = spectatee.health;
1715         CS(this).impulse = 0;
1716         this.items = spectatee.items;
1717         this.last_pickup = spectatee.last_pickup;
1718         this.hit_time = spectatee.hit_time;
1719         this.strength_finished = spectatee.strength_finished;
1720         this.invincible_finished = spectatee.invincible_finished;
1721         this.superweapons_finished = spectatee.superweapons_finished;
1722         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1723         this.weapons = spectatee.weapons;
1724         this.dual_weapons = spectatee.dual_weapons;
1725         this.vortex_charge = spectatee.vortex_charge;
1726         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1727         this.hagar_load = spectatee.hagar_load;
1728         this.arc_heat_percent = spectatee.arc_heat_percent;
1729         this.minelayer_mines = spectatee.minelayer_mines;
1730         this.punchangle = spectatee.punchangle;
1731         this.view_ofs = spectatee.view_ofs;
1732         this.velocity = spectatee.velocity;
1733         this.dmg_take = spectatee.dmg_take;
1734         this.dmg_save = spectatee.dmg_save;
1735         this.dmg_inflictor = spectatee.dmg_inflictor;
1736         this.v_angle = spectatee.v_angle;
1737         this.angles = spectatee.v_angle;
1738         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1739         this.revive_progress = spectatee.revive_progress;
1740         this.viewloc = spectatee.viewloc;
1741         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1742                 this.fixangle = true;
1743         setorigin(this, spectatee.origin);
1744         setsize(this, spectatee.mins, spectatee.maxs);
1745         SetZoomState(this, CS(spectatee).zoomstate);
1746
1747         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1748         {
1749                 .entity weaponentity = weaponentities[slot];
1750                 this.(weaponentity) = spectatee.(weaponentity);
1751         }
1752
1753         for(int slot = 0; slot < MAX_AXH; ++slot)
1754         {
1755                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1756         }
1757
1758     anticheat_spectatecopy(this, spectatee);
1759         this.hud = spectatee.hud;
1760         if(spectatee.vehicle)
1761     {
1762         this.angles = spectatee.v_angle;
1763
1764         //this.fixangle = false;
1765         //this.velocity = spectatee.vehicle.velocity;
1766         this.vehicle_health = spectatee.vehicle_health;
1767         this.vehicle_shield = spectatee.vehicle_shield;
1768         this.vehicle_energy = spectatee.vehicle_energy;
1769         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1770         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1771         this.vehicle_reload1 = spectatee.vehicle_reload1;
1772         this.vehicle_reload2 = spectatee.vehicle_reload2;
1773
1774         //msg_entity = this;
1775
1776        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1777             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1778            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1779            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1780
1781         //WriteByte (MSG_ONE, SVC_SETVIEW);
1782         //    WriteEntity(MSG_ONE, this);
1783         //makevectors(spectatee.v_angle);
1784         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1785     }
1786 }
1787
1788 bool SpectateUpdate(entity this)
1789 {
1790         if(!this.enemy)
1791                 return false;
1792
1793         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1794         {
1795                 SetSpectatee(this, NULL);
1796                 return false;
1797         }
1798
1799         SpectateCopy(this, this.enemy);
1800
1801         return true;
1802 }
1803
1804 bool SpectateSet(entity this)
1805 {
1806         if(!IS_PLAYER(this.enemy))
1807                 return false;
1808
1809         ClientData_Touch(this.enemy);
1810
1811         msg_entity = this;
1812         WriteByte(MSG_ONE, SVC_SETVIEW);
1813         WriteEntity(MSG_ONE, this.enemy);
1814         set_movetype(this, MOVETYPE_NONE);
1815         accuracy_resend(this);
1816
1817         if(!SpectateUpdate(this))
1818                 PutObserverInServer(this);
1819
1820         return true;
1821 }
1822
1823 void SetSpectatee_status(entity this, int spectatee_num)
1824 {
1825         int oldspectatee_status = CS(this).spectatee_status;
1826         CS(this).spectatee_status = spectatee_num;
1827
1828         if (CS(this).spectatee_status != oldspectatee_status)
1829         {
1830                 ClientData_Touch(this);
1831                 if (g_race || g_cts) race_InitSpectator();
1832         }
1833 }
1834
1835 void SetSpectatee(entity this, entity spectatee)
1836 {
1837         if(IS_BOT_CLIENT(this))
1838                 return; // bots abuse .enemy, this code is useless to them
1839
1840         entity old_spectatee = this.enemy;
1841
1842         this.enemy = spectatee;
1843
1844         // WEAPONTODO
1845         // these are required to fix the spectator bug with arc
1846         if(old_spectatee)
1847         {
1848                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1849                 {
1850                         .entity weaponentity = weaponentities[slot];
1851                         if(old_spectatee.(weaponentity).arc_beam)
1852                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1853                 }
1854         }
1855         if(this.enemy)
1856         {
1857                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1858                 {
1859                         .entity weaponentity = weaponentities[slot];
1860                         if(this.enemy.(weaponentity).arc_beam)
1861                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1862                 }
1863         }
1864
1865         if (this.enemy)
1866                 SetSpectatee_status(this, etof(this.enemy));
1867
1868         // needed to update spectator list
1869         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1870 }
1871
1872 bool Spectate(entity this, entity pl)
1873 {
1874         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1875                 return false;
1876         pl = M_ARGV(1, entity);
1877
1878         SetSpectatee(this, pl);
1879         return SpectateSet(this);
1880 }
1881
1882 bool SpectateNext(entity this)
1883 {
1884         entity ent = find(this.enemy, classname, STR_PLAYER);
1885
1886         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1887                 ent = M_ARGV(1, entity);
1888         else if (!ent)
1889                 ent = find(ent, classname, STR_PLAYER);
1890
1891         if(ent) { SetSpectatee(this, ent); }
1892
1893         return SpectateSet(this);
1894 }
1895
1896 bool SpectatePrev(entity this)
1897 {
1898         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1899         entity ent = findchain(classname, STR_PLAYER);
1900         if (!ent) // no player
1901                 return false;
1902
1903         entity first = ent;
1904         // skip players until current spectated player
1905         if(this.enemy)
1906         while(ent && ent != this.enemy)
1907                 ent = ent.chain;
1908
1909         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1910         {
1911                 case MUT_SPECPREV_FOUND:
1912                     ent = M_ARGV(1, entity);
1913                     break;
1914                 case MUT_SPECPREV_RETURN:
1915                     return true;
1916                 case MUT_SPECPREV_CONTINUE:
1917                 default:
1918                 {
1919                         if(ent.chain)
1920                                 ent = ent.chain;
1921                         else
1922                                 ent = first;
1923                         break;
1924                 }
1925         }
1926
1927         SetSpectatee(this, ent);
1928         return SpectateSet(this);
1929 }
1930
1931 /*
1932 =============
1933 ShowRespawnCountdown()
1934
1935 Update a respawn countdown display.
1936 =============
1937 */
1938 void ShowRespawnCountdown(entity this)
1939 {
1940         float number;
1941         if(!IS_DEAD(this)) // just respawned?
1942                 return;
1943         else
1944         {
1945                 number = ceil(this.respawn_time - time);
1946                 if(number <= 0)
1947                         return;
1948                 if(number <= this.respawn_countdown)
1949                 {
1950                         this.respawn_countdown = number - 1;
1951                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1952                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1953                 }
1954         }
1955 }
1956
1957 .bool team_selected;
1958 bool ShowTeamSelection(entity this)
1959 {
1960         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1961                 return false;
1962         stuffcmd(this, "menu_showteamselect\n");
1963         return true;
1964 }
1965 void Join(entity this)
1966 {
1967         TRANSMUTE(Player, this);
1968
1969         if(!this.team_selected)
1970         if(autocvar_g_campaign || autocvar_g_balance_teams)
1971                 JoinBestTeam(this, false, true);
1972
1973         if(autocvar_g_campaign)
1974                 campaign_bots_may_start = true;
1975
1976         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1977
1978         PutClientInServer(this);
1979
1980         if(IS_PLAYER(this))
1981         if(teamplay && this.team != -1)
1982                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1983         else
1984                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1985         this.team_selected = false;
1986 }
1987
1988 /**
1989  * Determines whether the player is allowed to join. This depends on cvar
1990  * g_maxplayers, if it isn't used this function always return true, otherwise
1991  * it checks whether the number of currently playing players exceeds g_maxplayers.
1992  * @return int number of free slots for players, 0 if none
1993  */
1994 int nJoinAllowed(entity this, entity ignore)
1995 {
1996         if(!ignore)
1997         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1998         // so report 0 free slots if restricted
1999         {
2000                 if(autocvar_g_forced_team_otherwise == "spectate")
2001                         return 0;
2002                 if(autocvar_g_forced_team_otherwise == "spectator")
2003                         return 0;
2004         }
2005
2006         if(this && this.team_forced < 0)
2007                 return 0; // forced spectators can never join
2008
2009         // TODO simplify this
2010         int totalClients = 0;
2011         int currentlyPlaying = 0;
2012         FOREACH_CLIENT(true, LAMBDA(
2013                 if(it != ignore)
2014                         ++totalClients;
2015                 if(IS_REAL_CLIENT(it))
2016                 if(IS_PLAYER(it) || it.caplayer)
2017                         ++currentlyPlaying;
2018         ));
2019
2020         float free_slots = 0;
2021         if (!autocvar_g_maxplayers)
2022                 free_slots = maxclients - totalClients;
2023         else if(currentlyPlaying < autocvar_g_maxplayers)
2024                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2025
2026         static float join_prevent_msg_time = 0;
2027         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2028         {
2029                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2030                 join_prevent_msg_time = time + 3;
2031         }
2032
2033         return free_slots;
2034 }
2035
2036 /**
2037  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2038  * g_maxplayers_spectator_blocktime seconds
2039  */
2040 void checkSpectatorBlock(entity this)
2041 {
2042         if(IS_SPEC(this) || IS_OBSERVER(this))
2043         if(!this.caplayer)
2044         if(IS_REAL_CLIENT(this))
2045         {
2046                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2047                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2048                         dropclient(this);
2049                 }
2050         }
2051 }
2052
2053 void PrintWelcomeMessage(entity this)
2054 {
2055         if(CS(this).motd_actived_time == 0)
2056         {
2057                 if (autocvar_g_campaign) {
2058                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2059                                 CS(this).motd_actived_time = time;
2060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2061                         }
2062                 } else {
2063                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2064                                 CS(this).motd_actived_time = time;
2065                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2066                         }
2067                 }
2068         }
2069         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2070         {
2071                 if (autocvar_g_campaign) {
2072                         if (PHYS_INPUT_BUTTON_INFO(this))
2073                                 CS(this).motd_actived_time = time;
2074                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2075                                 CS(this).motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2077                         }
2078                 } else {
2079                         if (PHYS_INPUT_BUTTON_INFO(this))
2080                                 CS(this).motd_actived_time = time;
2081                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2082                                 CS(this).motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2084                         }
2085                 }
2086         }
2087         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2088         {
2089                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2090                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2091                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2092                 {
2093                         // instanctly hide MOTD
2094                         CS(this).motd_actived_time = 0;
2095                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2096                 }
2097         }
2098 }
2099
2100 bool joinAllowed(entity this)
2101 {
2102         if (CS(this).version_mismatch) return false;
2103         if (!nJoinAllowed(this, this)) return false;
2104         if (teamplay && lockteams) return false;
2105         if (ShowTeamSelection(this)) return false;
2106         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2107         return true;
2108 }
2109
2110 .int items_added;
2111 bool PlayerThink(entity this)
2112 {
2113         CheckRules_Player(this);
2114
2115         if (game_stopped || intermission_running) {
2116                 this.modelflags &= ~MF_ROCKET;
2117                 if(intermission_running)
2118                         IntermissionThink(this);
2119                 return false;
2120         }
2121
2122         if (timeout_status == TIMEOUT_ACTIVE) {
2123         // don't allow the player to turn around while game is paused
2124                 // FIXME turn this into CSQC stuff
2125                 this.v_angle = this.lastV_angle;
2126                 this.angles = this.lastV_angle;
2127                 this.fixangle = true;
2128         }
2129
2130         if (frametime) player_powerups(this);
2131
2132         if (IS_DEAD(this)) {
2133                 if (this.personal && g_race_qualifying) {
2134                         if (time > this.respawn_time) {
2135                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2136                                 respawn(this);
2137                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2138                         }
2139                 } else {
2140                         if (frametime) player_anim(this);
2141
2142                         if (this.respawn_flags & RESPAWN_DENY)
2143                         {
2144                                 STAT(RESPAWN_TIME, this) = 0;
2145                                 return false;
2146                         }
2147
2148                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2149
2150                         switch(this.deadflag)
2151                         {
2152                                 case DEAD_DYING:
2153                                 {
2154                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2155                                                 this.deadflag = DEAD_RESPAWNING;
2156                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2157                                                 this.deadflag = DEAD_DEAD;
2158                                         break;
2159                                 }
2160                                 case DEAD_DEAD:
2161                                 {
2162                                         if (button_pressed)
2163                                                 this.deadflag = DEAD_RESPAWNABLE;
2164                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2165                                                 this.deadflag = DEAD_RESPAWNING;
2166                                         break;
2167                                 }
2168                                 case DEAD_RESPAWNABLE:
2169                                 {
2170                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2171                                                 this.deadflag = DEAD_RESPAWNING;
2172                                         break;
2173                                 }
2174                                 case DEAD_RESPAWNING:
2175                                 {
2176                                         if (time > this.respawn_time)
2177                                         {
2178                                                 this.respawn_time = time + 1; // only retry once a second
2179                                                 this.respawn_time_max = this.respawn_time;
2180                                                 respawn(this);
2181                                         }
2182                                         break;
2183                                 }
2184                         }
2185
2186                         ShowRespawnCountdown(this);
2187
2188                         if (this.respawn_flags & RESPAWN_SILENT)
2189                                 STAT(RESPAWN_TIME, this) = 0;
2190                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2191                         {
2192                                 if (time < this.respawn_time)
2193                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2194                                 else if (this.deadflag != DEAD_RESPAWNING)
2195                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2196                         }
2197                         else
2198                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2199                 }
2200
2201                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2202                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2203                         STAT(RESPAWN_TIME, this) *= -1;
2204
2205                 return false;
2206         }
2207
2208         this.prevorigin = this.origin;
2209
2210         bool have_hook = false;
2211         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2212         {
2213                 .entity weaponentity = weaponentities[slot];
2214                 if(this.(weaponentity).hook.state)
2215                 {
2216                         have_hook = true;
2217                         break;
2218                 }
2219         }
2220         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2221         if (have_hook) {
2222                 do_crouch = false;
2223         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2224                 do_crouch = false;
2225         } else if (this.vehicle) {
2226                 do_crouch = false;
2227         } else if (STAT(FROZEN, this)) {
2228                 do_crouch = false;
2229     }
2230
2231         if (do_crouch) {
2232                 if (!this.crouch) {
2233                         this.crouch = true;
2234                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2235                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2236                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2237                 }
2238         } else if (this.crouch) {
2239         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2240         if (!trace_startsolid) {
2241             this.crouch = false;
2242             this.view_ofs = STAT(PL_VIEW_OFS, this);
2243             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2244         }
2245         }
2246
2247         FixPlayermodel(this);
2248
2249         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2250         //if(frametime)
2251         {
2252                 this.items &= ~this.items_added;
2253
2254                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2255                 {
2256                         .entity weaponentity = weaponentities[slot];
2257                         W_WeaponFrame(this, weaponentity);
2258
2259                         if(slot == 0)
2260                         {
2261                                 this.clip_load = this.(weaponentity).clip_load;
2262                                 this.clip_size = this.(weaponentity).clip_size;
2263                         }
2264                 }
2265
2266                 this.items_added = 0;
2267                 if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2268             this.items_added |= IT_FUEL;
2269
2270                 this.items |= this.items_added;
2271         }
2272
2273         player_regen(this);
2274
2275         // WEAPONTODO: Add a weapon request for this
2276         // rot vortex charge to the charge limit
2277         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2278         {
2279                 .entity weaponentity = weaponentities[slot];
2280                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2281                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2282         }
2283
2284         if (frametime) player_anim(this);
2285
2286         // secret status
2287         secrets_setstatus(this);
2288
2289         // monsters status
2290         monsters_setstatus(this);
2291
2292         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2293
2294         return true;
2295 }
2296
2297 void ObserverThink(entity this)
2298 {
2299         if ( CS(this).impulse )
2300         {
2301                 MinigameImpulse(this, CS(this).impulse);
2302                 CS(this).impulse = 0;
2303         }
2304
2305         if (this.flags & FL_JUMPRELEASED) {
2306                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2307                         this.flags &= ~FL_JUMPRELEASED;
2308                         this.flags |= FL_SPAWNING;
2309                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2310                         this.flags &= ~FL_JUMPRELEASED;
2311                         if(SpectateNext(this)) {
2312                                 TRANSMUTE(Spectator, this);
2313                         }
2314                 } else {
2315                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2316                         set_movetype(this, preferred_movetype);
2317                 }
2318         } else {
2319                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2320                         this.flags |= FL_JUMPRELEASED;
2321                         if(this.flags & FL_SPAWNING)
2322                         {
2323                                 this.flags &= ~FL_SPAWNING;
2324                                 Join(this);
2325                                 return;
2326                         }
2327                 }
2328         }
2329 }
2330
2331 void SpectatorThink(entity this)
2332 {
2333         if ( CS(this).impulse )
2334         {
2335                 if(MinigameImpulse(this, CS(this).impulse))
2336                         CS(this).impulse = 0;
2337
2338                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2339                 {
2340                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2341                         CS(this).impulse = 0;
2342                         return;
2343                 }
2344         }
2345
2346         if (this.flags & FL_JUMPRELEASED) {
2347                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2348                         this.flags &= ~FL_JUMPRELEASED;
2349                         this.flags |= FL_SPAWNING;
2350                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2351                         this.flags &= ~FL_JUMPRELEASED;
2352                         if(SpectateNext(this)) {
2353                                 TRANSMUTE(Spectator, this);
2354                         } else {
2355                                 TRANSMUTE(Observer, this);
2356                                 PutClientInServer(this);
2357                         }
2358                         CS(this).impulse = 0;
2359                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2360                         this.flags &= ~FL_JUMPRELEASED;
2361                         if(SpectatePrev(this)) {
2362                                 TRANSMUTE(Spectator, this);
2363                         } else {
2364                                 TRANSMUTE(Observer, this);
2365                                 PutClientInServer(this);
2366                         }
2367                         CS(this).impulse = 0;
2368                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2369                         this.flags &= ~FL_JUMPRELEASED;
2370                         TRANSMUTE(Observer, this);
2371                         PutClientInServer(this);
2372                 } else {
2373                         if(!SpectateUpdate(this))
2374                                 PutObserverInServer(this);
2375                 }
2376         } else {
2377                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2378                         this.flags |= FL_JUMPRELEASED;
2379                         if(this.flags & FL_SPAWNING)
2380                         {
2381                                 this.flags &= ~FL_SPAWNING;
2382                                 Join(this);
2383                                 return;
2384                         }
2385                 }
2386                 if(!SpectateUpdate(this))
2387                         PutObserverInServer(this);
2388         }
2389
2390         this.flags |= FL_CLIENT | FL_NOTARGET;
2391 }
2392
2393 void vehicles_enter (entity pl, entity veh);
2394 void PlayerUseKey(entity this)
2395 {
2396         if (!IS_PLAYER(this))
2397                 return;
2398
2399         if(this.vehicle)
2400         {
2401                 if(!game_stopped)
2402                 {
2403                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2404                         return;
2405                 }
2406         }
2407         else if(autocvar_g_vehicles_enter)
2408         {
2409                 if(!STAT(FROZEN, this))
2410                 if(!IS_DEAD(this))
2411                 if(!game_stopped)
2412                 {
2413                         entity head, closest_target = NULL;
2414                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2415
2416                         while(head) // find the closest acceptable target to enter
2417                         {
2418                                 if(IS_VEHICLE(head))
2419                                 if(!IS_DEAD(head))
2420                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2421                                 if(head.takedamage != DAMAGE_NO)
2422                                 {
2423                                         if(closest_target)
2424                                         {
2425                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2426                                                 { closest_target = head; }
2427                                         }
2428                                         else { closest_target = head; }
2429                                 }
2430
2431                                 head = head.chain;
2432                         }
2433
2434                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2435                 }
2436         }
2437
2438         // a use key was pressed; call handlers
2439         MUTATOR_CALLHOOK(PlayerUseKey, this);
2440 }
2441
2442
2443 /*
2444 =============
2445 PlayerPreThink
2446
2447 Called every frame for each client before the physics are run
2448 =============
2449 */
2450 .float last_vehiclecheck;
2451 void PlayerPreThink (entity this)
2452 {
2453         WarpZone_PlayerPhysics_FixVAngle(this);
2454
2455     STAT(GAMESTARTTIME, this) = game_starttime;
2456         STAT(ROUNDSTARTTIME, this) = round_starttime;
2457         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2458         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2459
2460         STAT(WEAPONSINMAP, this) = weaponsInMap;
2461
2462         if (frametime) {
2463                 // physics frames: update anticheat stuff
2464                 anticheat_prethink(this);
2465         }
2466
2467         if (blockSpectators && frametime) {
2468                 // WORKAROUND: only use dropclient in server frames (frametime set).
2469                 // Never use it in cl_movement frames (frametime zero).
2470                 checkSpectatorBlock(this);
2471     }
2472
2473         zoomstate_set = false;
2474
2475         // Check for nameless players
2476         if (isInvisibleString(this.netname)) {
2477                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2478                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2479         }
2480         if (this.netname != CS(this).netname_previous) {
2481                 if (autocvar_sv_eventlog) {
2482                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2483         }
2484                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2485                 CS(this).netname_previous = strzone(this.netname);
2486         }
2487
2488         // version nagging
2489         if (CS(this).version_nagtime && this.cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2490         CS(this).version_nagtime = 0;
2491         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2492             // git client
2493         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2494             // git server
2495             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2496         } else {
2497             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2498             if (r < 0) { // old client
2499                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2500             } else if (r > 0) { // old server
2501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2502             }
2503         }
2504     }
2505
2506         // GOD MODE info
2507         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2508         {
2509                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2510                 this.max_armorvalue = 0;
2511         }
2512
2513         if (STAT(FROZEN, this) == 2)
2514         {
2515                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2516                 this.health = max(1, this.revive_progress * start_health);
2517                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2518
2519                 if (this.revive_progress >= 1)
2520                         Unfreeze(this);
2521         }
2522         else if (STAT(FROZEN, this) == 3)
2523         {
2524                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2525                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2526
2527                 if (this.health < 1)
2528                 {
2529                         if (this.vehicle)
2530                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2531                         if(this.event_damage)
2532                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2533                 }
2534                 else if (this.revive_progress <= 0)
2535                         Unfreeze(this);
2536         }
2537
2538         MUTATOR_CALLHOOK(PlayerPreThink, this);
2539
2540         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2541         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2542         {
2543                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2544                 {
2545                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2546                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2547                         {
2548                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2549                         }
2550                         else if(!it.owner)
2551                         {
2552                                 if(!it.team || SAME_TEAM(this, it))
2553                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2554                                 else if(autocvar_g_vehicles_steal)
2555                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2556                         }
2557                 });
2558
2559                 this.last_vehiclecheck = time + 1;
2560         }
2561
2562         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2563         {
2564                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2565                         PlayerUseKey(this);
2566                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2567         }
2568
2569         if (IS_REAL_CLIENT(this))
2570                 PrintWelcomeMessage(this);
2571
2572         if (IS_PLAYER(this)) {
2573                 if(!PlayerThink(this))
2574                         return;
2575         }
2576         else if (game_stopped || intermission_running) {
2577                 if(intermission_running)
2578                         IntermissionThink(this);
2579                 return;
2580         }
2581         else if (IS_OBSERVER(this)) {
2582                 ObserverThink(this);
2583         }
2584         else if (IS_SPEC(this)) {
2585                 SpectatorThink(this);
2586         }
2587
2588         // WEAPONTODO: Add weapon request for this
2589         if (!zoomstate_set) {
2590                 bool wep_zoomed = false;
2591                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2592                 {
2593                         .entity weaponentity = weaponentities[slot];
2594                         Weapon thiswep = this.(weaponentity).m_weapon;
2595                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2596                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2597                 }
2598                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2599     }
2600
2601         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2602         {
2603                 CS(this).teamkill_soundtime = 0;
2604
2605                 entity e = CS(this).teamkill_soundsource;
2606                 entity oldpusher = e.pusher;
2607                 e.pusher = this;
2608                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2609                 e.pusher = oldpusher;
2610         }
2611
2612         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2613                 CS(this).taunt_soundtime = 0;
2614                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2615         }
2616
2617         target_voicescript_next(this);
2618
2619         // WEAPONTODO: Move into weaponsystem somehow
2620         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2621         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2622         {
2623                 .entity weaponentity = weaponentities[slot];
2624                 if(this.(weaponentity).m_weapon == WEP_Null)
2625                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2626         }
2627 }
2628
2629 void DrownPlayer(entity this)
2630 {
2631         if(IS_DEAD(this))
2632                 return;
2633
2634         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2635         {
2636                 if(this.air_finished < time)
2637                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2638                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2639                 this.dmg = 2;
2640         }
2641         else if (this.air_finished < time)
2642         {       // drown!
2643                 if (this.pain_finished < time)
2644                 {
2645                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2646                         this.pain_finished = time + 0.5;
2647                 }
2648         }
2649 }
2650
2651 .bool move_qcphysics;
2652
2653 void Player_Physics(entity this)
2654 {
2655         set_movetype(this, this.move_movetype);
2656
2657         if(!this.move_qcphysics)
2658                 return;
2659
2660         if(!frametime && !CS(this).pm_frametime)
2661                 return;
2662
2663         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2664
2665         CS(this).pm_frametime = 0;
2666 }
2667
2668 /*
2669 =============
2670 PlayerPostThink
2671
2672 Called every frame for each client after the physics are run
2673 =============
2674 */
2675 void PlayerPostThink (entity this)
2676 {
2677         Player_Physics(this);
2678
2679         if (sv_maxidle > 0)
2680         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2681         if (IS_REAL_CLIENT(this))
2682         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2683         {
2684                 int totalClients = 0;
2685                 if(sv_maxidle_slots > 0)
2686                 {
2687                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2688                         {
2689                                 ++totalClients;
2690                         });
2691                 }
2692
2693                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2694                 { /* do nothing */ }
2695                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2696                 {
2697                         if (CS(this).idlekick_lasttimeleft)
2698                         {
2699                                 CS(this).idlekick_lasttimeleft = 0;
2700                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2701                         }
2702                 }
2703                 else
2704                 {
2705                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2706                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2707                                 if (!CS(this).idlekick_lasttimeleft)
2708                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2709                         }
2710                         if (timeleft <= 0) {
2711                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2712                                 dropclient(this);
2713                                 return;
2714                         }
2715                         else if (timeleft <= 10) {
2716                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2717                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2718                 }
2719                                 CS(this).idlekick_lasttimeleft = timeleft;
2720                         }
2721                 }
2722         }
2723
2724         CheatFrame(this);
2725
2726         //CheckPlayerJump();
2727         if (game_stopped)
2728         {
2729                 this.solid = SOLID_NOT;
2730                 this.takedamage = DAMAGE_NO;
2731                 set_movetype(this, MOVETYPE_NONE);
2732         }
2733
2734         if (IS_PLAYER(this)) {
2735                 DrownPlayer(this);
2736                 CheckRules_Player(this);
2737                 UpdateChatBubble(this);
2738                 if (CS(this).impulse) ImpulseCommands(this);
2739                 if (game_stopped)
2740                 {
2741                         CSQCMODEL_AUTOUPDATE(this);
2742                         return;
2743                 }
2744                 GetPressedKeys(this);
2745         }
2746
2747         if (this.waypointsprite_attachedforcarrier) {
2748             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2749                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2750     }
2751
2752         playerdemo_write(this);
2753
2754         CSQCMODEL_AUTOUPDATE(this);
2755 }
2756
2757 // hack to copy the button fields from the client entity to the Client State
2758 void PM_UpdateButtons(entity this, entity store)
2759 {
2760         if(this.impulse)
2761                 store.impulse = this.impulse;
2762         this.impulse = 0;
2763
2764         store.button0 = this.button0;
2765         store.button2 = this.button2;
2766         store.button3 = this.button3;
2767         store.button4 = this.button4;
2768         store.button5 = this.button5;
2769         store.button6 = this.button6;
2770         store.button7 = this.button7;
2771         store.button8 = this.button8;
2772         store.button9 = this.button9;
2773         store.button10 = this.button10;
2774         store.button11 = this.button11;
2775         store.button12 = this.button12;
2776         store.button13 = this.button13;
2777         store.button14 = this.button14;
2778         store.button15 = this.button15;
2779         store.button16 = this.button16;
2780         store.buttonuse = this.buttonuse;
2781         store.buttonchat = this.buttonchat;
2782
2783         store.cursor_active = this.cursor_active;
2784         store.cursor_screen = this.cursor_screen;
2785         store.cursor_trace_start = this.cursor_trace_start;
2786         store.cursor_trace_endpos = this.cursor_trace_endpos;
2787         store.cursor_trace_ent = this.cursor_trace_ent;
2788
2789         store.ping = this.ping;
2790         store.ping_packetloss = this.ping_packetloss;
2791         store.ping_movementloss = this.ping_movementloss;
2792
2793         store.v_angle = this.v_angle;
2794         store.movement = this.movement;
2795 }